qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void Map_MarkAsRecent(string m);
 562 float world_already_spawned;
 563 void Nagger_Init();
 564 void ClientInit_Spawn();
 565 void WeaponStats_Init();
 566 void WeaponStats_Shutdown();
 567 void spawnfunc_worldspawn (void)
 568 {
 569         float fd, l, i, j, n;
 570         string s, col;
 571
 572         cvar = cvar_normal;
 573         cvar_string = cvar_string_normal;
 574         cvar_set = cvar_set_normal;
 575
 576         if(world_already_spawned)
 577                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 578         world_already_spawned = TRUE;
 579
 580         remove = remove_safely; // during spawning, watch what you remove!
 581
 582         check_unacceptable_compiler_bugs();
 583
 584         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 585
 586         compressShortVector_init();
 587
 588         allowed_to_spawn = TRUE;
 589
 590         entity head;
 591         head = nextent(world);
 592         maxclients = 0;
 593         while(head)
 594         {
 595                 ++maxclients;
 596                 head = nextent(head);
 597         }
 598
 599         // needs to be done so early because of the constants they create
 600         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 601         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 602
 603         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 604
 605         TemporaryDB = db_create();
 606
 607         // 0 normal
 608         lightstyle(0, "m");
 609
 610         // 1 FLICKER (first variety)
 611         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 612
 613         // 2 SLOW STRONG PULSE
 614         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 615
 616         // 3 CANDLE (first variety)
 617         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 618
 619         // 4 FAST STROBE
 620         lightstyle(4, "mamamamamama");
 621
 622         // 5 GENTLE PULSE 1
 623         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 624
 625         // 6 FLICKER (second variety)
 626         lightstyle(6, "nmonqnmomnmomomno");
 627
 628         // 7 CANDLE (second variety)
 629         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 630
 631         // 8 CANDLE (third variety)
 632         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 633
 634         // 9 SLOW STROBE (fourth variety)
 635         lightstyle(9, "aaaaaaaazzzzzzzz");
 636
 637         // 10 FLUORESCENT FLICKER
 638         lightstyle(10, "mmamammmmammamamaaamammma");
 639
 640         // 11 SLOW PULSE NOT FADE TO BLACK
 641         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 642
 643         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 644
 645         // 63 testing
 646         lightstyle(63, "a");
 647
 648         if(autocvar_g_campaign)
 649                 CampaignPreInit();
 650
 651         Map_MarkAsRecent(mapname);
 652
 653         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 654
 655         precache_model ("null"); // we need this one before InitGameplayMode
 656         InitGameplayMode();
 657         readlevelcvars();
 658         GrappleHookInit();
 659         ElectroInit();
 660         LaserInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 ret_string = s;
 686                 MUTATOR_CALLHOOK(BuildMutatorsString);
 687                 s = ret_string;
 688
 689                 // simple, probably not good in the mutator system
 690                 if(autocvar_g_grappling_hook)
 691                         s = strcat(s, ":grappling_hook");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(!autocvar_g_use_ammunition)
 695                         s = strcat(s, ":no_use_ammunition");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_pickup_items == 0)
 699                         s = strcat(s, ":no_pickup_items");
 700                 if(autocvar_g_pickup_items > 0)
 701                         s = strcat(s, ":pickup_items");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(autocvar_g_weaponarena != "0")
 705                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_norecoil)
 709                         s = strcat(s, ":norecoil");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_midair)
 713                         s = strcat(s, ":midair");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_minstagib)
 717                         s = strcat(s, ":minstagib");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_powerups == 0)
 721                         s = strcat(s, ":no_powerups");
 722                 if(autocvar_g_powerups > 0)
 723                         s = strcat(s, ":powerups");
 724
 725                 GameLogEcho(s);
 726                 GameLogEcho(":gameinfo:end");
 727         }
 728         else
 729                 matchid = strzone(ftos(random()));
 730
 731         cvar_set("nextmap", "");
 732
 733         SetDefaultAlpha();
 734
 735         if(autocvar_g_campaign)
 736                 CampaignPostInit();
 737
 738         fteqcc_testbugs();
 739
 740         Ban_LoadBans();
 741
 742         MapInfo_Enumerate();
 743         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 744
 745         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 746         {
 747                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 748                 if(fd != -1)
 749                 {
 750                         while((s = fgets(fd)))
 751                         {
 752                                 l = tokenize_console(s);
 753                                 if(l < 2)
 754                                         continue;
 755                                 if(argv(0) == "cd")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  cdtrack ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) == "fog")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 763                                         print("  \"fog\" \"", s, "\"\n");
 764                                 }
 765                                 else if(argv(0) == "set")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 768                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 769                                 }
 770                                 else if(argv(0) != "//")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 774                                 }
 775                         }
 776                         fclose(fd);
 777                 }
 778         }
 779
 780         WeaponStats_Init();
 781
 782         WEPSET_ADDSTAT();
 783         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 784         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 785         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 786         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 787         Nagger_Init();
 788
 789         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 790         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 791         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 792         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 793         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 794         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 795         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 796         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 797         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 798         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 799         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 800         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 801         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 802
 803         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 804         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 805
 806         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 807
 808         if(g_ca || g_freezetag)
 809         {
 810                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 811                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 812                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 813                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 814         }
 815         if(g_freezetag)
 816         {
 817                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 818                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 819         }
 820
 821         // g_movementspeed hack
 822         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 823         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 824         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 825         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 826
 827         // secrets
 828         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 829         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 830
 831         // misc
 832         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 833
 834         next_pingtime = time + 5;
 835
 836         detect_maptype();
 837
 838         // set up information replies for clients and server to use
 839         lsmaps_reply = "^7Maps available: ";
 840         lsnewmaps_reply = "^7Maps without a record set: ";
 841         for(i = 0, j = 0; i < MapInfo_count; ++i)
 842         {
 843                 if(MapInfo_Get_ByID(i))
 844                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 845                         {
 846                                 if(mod(i, 2))
 847                                         col = "^2";
 848                                 else
 849                                         col = "^3";
 850
 851                                 ++j;
 852
 853                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 854
 855                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 856                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 857                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 858                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 859                         }
 860         }
 861
 862         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 863         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 864
 865         maplist_reply = "^7Maps in list: ";
 866         n = tokenize_console(autocvar_g_maplist);
 867         for(i = 0, j = 0; i < n; ++i)
 868         {
 869                 if(MapInfo_CheckMap(argv(i)))
 870                 {
 871                         if(mod(j, 2))
 872                                 col = "^2";
 873                         else
 874                                 col = "^3";
 875                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 876                         ++j;
 877                 }
 878         }
 879         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 880         MapInfo_ClearTemps();
 881
 882         for(i = 0; i < 10; ++i)
 883         {
 884                 s = getrecords(i);
 885                 if (s)
 886                         records_reply[i] = strzone(s);
 887         }
 888
 889         ladder_reply = strzone(getladder());
 890
 891         rankings_reply = strzone(getrankings());
 892
 893         // begin other init
 894         ClientInit_Spawn();
 895         RandomSeed_Spawn();
 896         PingPLReport_Spawn();
 897
 898         CheatInit();
 899
 900         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 901
 902         // fill sv_curl_serverpackages from .serverpackage files
 903         if(autocvar_sv_curl_serverpackages_auto)
 904         {
 905                 s = "";
 906                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 907                 for(i = 0; i < n; ++i)
 908                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 909                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 910                                 s = strcat(s, " ", argv(i));
 911                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 912                 if(fd >= 0)
 913                 {
 914                         j = search_getsize(fd);
 915                         for(i = 0; i < j; ++i)
 916                                 s = strcat(s, " ", search_getfilename(fd, i));
 917                         search_end(fd);
 918                 }
 919                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 920                 if(fd >= 0)
 921                 {
 922                         j = search_getsize(fd);
 923                         for(i = 0; i < j; ++i)
 924                                 s = strcat(s, " ", search_getfilename(fd, i));
 925                         search_end(fd);
 926                 }
 927                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 928         }
 929
 930         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 931         modname = "Xonotic";
 932         // physics/balance/config changes that count as mod
 933         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 934                 modname = cvar_string("g_mod_physics");
 935         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 936                 modname = cvar_string("g_mod_balance");
 937         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 938                 modname = cvar_string("g_mod_config");
 939         // weird mutators that deserve to count as mod
 940         if(autocvar_g_minstagib)
 941                 modname = "MinstaGib";
 942         // extra mutators that deserve to count as mod
 943         MUTATOR_CALLHOOK(SetModname);
 944         // weird game types that deserve to count as mod
 945         if(g_cts)
 946                 modname = "CTS";
 947         // save it for later
 948         modname = strzone(modname);
 949
 950         WinningConditionHelper(); // set worldstatus
 951
 952         world_initialized = 1;
 953 }
 954
 955 void spawnfunc_light (void)
 956 {
 957         //makestatic (self); // Who the f___ did that?
 958         remove(self);
 959 }
 960
 961 string GetGametype()
 962 {
 963         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 964 }
 965
 966 string getmapname_stored;
 967 string GetMapname()
 968 {
 969         return mapname;
 970 }
 971
 972 float Map_Count, Map_Current;
 973 string Map_Current_Name;
 974
 975 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 976 float GetMaplistPosition()
 977 {
 978         float pos, idx;
 979         string map;
 980
 981         map = GetMapname();
 982         idx = autocvar_g_maplist_index;
 983
 984         if(idx >= 0)
 985                 if(idx < Map_Count)
 986                         if(map == argv(idx))
 987                                 return idx;
 988
 989         for(pos = 0; pos < Map_Count; ++pos)
 990                 if(map == argv(pos))
 991                         return pos;
 992
 993         // resume normal maplist rotation if current map is not in g_maplist
 994         return idx;
 995 }
 996
 997 float MapHasRightSize(string map)
 998 {
 999         float fh;
1000         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1001         if(autocvar_g_maplist_check_waypoints)
1002         {
1003                 dprint("checkwp "); dprint(map);
1004                 if(!fexists(strcat("maps/", map, ".waypoints")))
1005                 {
1006                         dprint(": no waypoints\n");
1007                         return FALSE;
1008                 }
1009                 dprint(": has waypoints\n");
1010         }
1011
1012         // open map size restriction file
1013         dprint("opensize "); dprint(map);
1014         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1015         if(fh >= 0)
1016         {
1017                 float mapmin, mapmax;
1018                 dprint(": ok, ");
1019                 mapmin = stof(fgets(fh));
1020                 mapmax = stof(fgets(fh));
1021                 fclose(fh);
1022                 if(player_count < mapmin)
1023                 {
1024                         dprint("not enough\n");
1025                         return FALSE;
1026                 }
1027                 if(player_count > mapmax)
1028                 {
1029                         dprint("too many\n");
1030                         return FALSE;
1031                 }
1032                 dprint("right size\n");
1033                 return TRUE;
1034         }
1035         dprint(": not found\n");
1036         return TRUE;
1037 }
1038
1039 string Map_Filename(float position)
1040 {
1041         return strcat("maps/", argv(position), ".bsp");
1042 }
1043
1044 string strwords(string s, float w)
1045 {
1046         float endpos;
1047         for(endpos = 0; w && endpos >= 0; --w)
1048                 endpos = strstrofs(s, " ", endpos + 1);
1049         if(endpos < 0)
1050                 return s;
1051         else
1052                 return substring(s, 0, endpos);
1053 }
1054
1055 float strhasword(string s, string w)
1056 {
1057         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1058 }
1059
1060 void Map_MarkAsRecent(string m)
1061 {
1062         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1063 }
1064
1065 float Map_IsRecent(string m)
1066 {
1067         return strhasword(autocvar_g_maplist_mostrecent, m);
1068 }
1069
1070 float Map_Check(float position, float pass)
1071 {
1072         string filename;
1073         string map_next;
1074         map_next = argv(position);
1075         if(pass <= 1)
1076         {
1077                 if(Map_IsRecent(map_next))
1078                         return 0;
1079         }
1080         filename = Map_Filename(position);
1081         if(MapInfo_CheckMap(map_next))
1082         {
1083                 if(pass == 2)
1084                         return 1;
1085                 if(MapHasRightSize(map_next))
1086                         return 1;
1087                 return 0;
1088         }
1089         else
1090                 dprint( "Couldn't select '", filename, "'..\n" );
1091
1092         return 0;
1093 }
1094
1095 void Map_Goto_SetStr(string nextmapname)
1096 {
1097         if(getmapname_stored != "")
1098                 strunzone(getmapname_stored);
1099         if(nextmapname == "")
1100                 getmapname_stored = "";
1101         else
1102                 getmapname_stored = strzone(nextmapname);
1103 }
1104
1105 void Map_Goto_SetFloat(float position)
1106 {
1107         cvar_set("g_maplist_index", ftos(position));
1108         Map_Goto_SetStr(argv(position));
1109 }
1110
1111 void Map_Goto(float reinit)
1112 {
1113         MapInfo_LoadMap(getmapname_stored, reinit);
1114 }
1115
1116 // return codes of map selectors:
1117 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1118 //   -2 = permanent failure
1119 float() MaplistMethod_Iterate = // usual method
1120 {
1121         float pass, i;
1122
1123         for(pass = 1; pass <= 2; ++pass)
1124         {
1125                 for(i = 1; i < Map_Count; ++i)
1126                 {
1127                         float mapindex;
1128                         mapindex = mod(i + Map_Current, Map_Count);
1129                         if(Map_Check(mapindex, pass))
1130                                 return mapindex;
1131                 }
1132         }
1133         return -1;
1134 }
1135
1136 float() MaplistMethod_Repeat = // fallback method
1137 {
1138         if(Map_Check(Map_Current, 2))
1139                 return Map_Current;
1140         return -2;
1141 }
1142
1143 float() MaplistMethod_Random = // random map selection
1144 {
1145         float i, imax;
1146
1147         imax = 42;
1148
1149         for(i = 0; i <= imax; ++i)
1150         {
1151                 float mapindex;
1152                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1153                 if(Map_Check(mapindex, 1))
1154                         return mapindex;
1155         }
1156         return -1;
1157 }
1158
1159 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1160 // the exponent sets a bias on the map selection:
1161 // the higher the exponent, the less likely "shortly repeated" same maps are
1162 {
1163         float i, j, imax, insertpos;
1164
1165         imax = 42;
1166
1167         for(i = 0; i <= imax; ++i)
1168         {
1169                 string newlist;
1170
1171                 // now reinsert this at another position
1172                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1173                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1174                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1175                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1176
1177                 // insert the current map there
1178                 newlist = "";
1179                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1180                         newlist = strcat(newlist, " ", argv(j));
1181                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1182                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1183                         newlist = strcat(newlist, " ", argv(j));
1184                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1185                 cvar_set("g_maplist", newlist);
1186                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187
1188                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1189                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1190                 if(Map_Check(Map_Current, 1))
1191                         return Map_Current;
1192         }
1193         return -1;
1194 }
1195
1196 void Maplist_Init()
1197 {
1198         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1199         if(Map_Count == 0)
1200         {
1201                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1202                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1203                 if(autocvar_g_maplist_shuffle)
1204                         ShuffleMaplist();
1205                 localcmd("\nmenu_cmd sync\n");
1206                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207         }
1208         if(Map_Count == 0)
1209                 error("empty maplist, cannot select a new map");
1210         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1211
1212         if(Map_Current_Name)
1213                 strunzone(Map_Current_Name);
1214         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1215         // this may or may not be correct, but who cares, in the worst case a map
1216         // isn't chosen in the first pass that should have been
1217 }
1218
1219 string GetNextMap()
1220 {
1221         float nextMap;
1222
1223         Maplist_Init();
1224         nextMap = -1;
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_shuffle > 0)
1228                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1229
1230         if(nextMap == -1)
1231                 if(autocvar_g_maplist_selectrandom)
1232                         nextMap = MaplistMethod_Random();
1233
1234         if(nextMap == -1)
1235                 nextMap = MaplistMethod_Iterate();
1236
1237         if(nextMap == -1)
1238                 nextMap = MaplistMethod_Repeat();
1239
1240         if(nextMap >= 0)
1241         {
1242                 Map_Goto_SetFloat(nextMap);
1243                 return getmapname_stored;
1244         }
1245
1246         return "";
1247 }
1248
1249 float DoNextMapOverride(float reinit)
1250 {
1251         if(autocvar_g_campaign)
1252         {
1253                 CampaignPostIntermission();
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         if(autocvar_quit_when_empty)
1258         {
1259                 if(player_count <= currentbots)
1260                 {
1261                         localcmd("quit\n");
1262                         alreadychangedlevel = TRUE;
1263                         return TRUE;
1264                 }
1265         }
1266         if(autocvar_quit_and_redirect != "")
1267         {
1268                 redirection_target = strzone(autocvar_quit_and_redirect);
1269                 alreadychangedlevel = TRUE;
1270                 return TRUE;
1271         }
1272         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1273         {
1274                 localcmd("restart\n");
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         if(autocvar_nextmap != "")
1279                 if(MapInfo_CheckMap(autocvar_nextmap))
1280                 {
1281                         Map_Goto_SetStr(autocvar_nextmap);
1282                         Map_Goto(reinit);
1283                         alreadychangedlevel = TRUE;
1284                         return TRUE;
1285                 }
1286         if(!reinit && autocvar_lastlevel)
1287         {
1288                 cvar_settemp_restore();
1289                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         return FALSE;
1294 }
1295
1296 void GotoNextMap(float reinit)
1297 {
1298         //string nextmap;
1299         //float n, nummaps;
1300         //string s;
1301         if (alreadychangedlevel)
1302                 return;
1303         alreadychangedlevel = TRUE;
1304
1305         {
1306                 string nextMap;
1307                 float allowReset;
1308
1309                 for(allowReset = 1; allowReset >= 0; --allowReset)
1310                 {
1311                         nextMap = GetNextMap();
1312                         if(nextMap != "")
1313                                 break;
1314
1315                         if(allowReset)
1316                         {
1317                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1318                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1319                                 if(autocvar_g_maplist_shuffle)
1320                                         ShuffleMaplist();
1321                                 localcmd("\nmenu_cmd sync\n");
1322                         }
1323                         else
1324                         {
1325                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1326                         }
1327                 }
1328                 Map_Goto(reinit);
1329         }
1330 }
1331
1332
1333 /*
1334 ============
1335 IntermissionThink
1336
1337 When the player presses attack or jump, change to the next level
1338 ============
1339 */
1340 .float autoscreenshot;
1341 void() MapVote_Start;
1342 void() MapVote_Think;
1343 float mapvote_initialized;
1344 void IntermissionThink()
1345 {
1346         FixIntermissionClient(self);
1347
1348         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1349         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1350
1351         if( (server_screenshot || client_screenshot)
1352                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1353         {
1354                 self.autoscreenshot = -1;
1355                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1356                 return;
1357         }
1358
1359         if (time < intermission_exittime)
1360                 return;
1361
1362         if(!mapvote_initialized)
1363                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1364                         return;
1365
1366         MapVote_Start();
1367 }
1368
1369 /*
1370 ============
1371 FindIntermission
1372
1373 Returns the entity to view from
1374 ============
1375 */
1376 /*
1377 entity FindIntermission()
1378 {
1379         local   entity spot;
1380         local   float cyc;
1381
1382 // look for info_intermission first
1383         spot = find (world, classname, "info_intermission");
1384         if (spot)
1385         {       // pick a random one
1386                 cyc = random() * 4;
1387                 while (cyc > 1)
1388                 {
1389                         spot = find (spot, classname, "info_intermission");
1390                         if (!spot)
1391                                 spot = find (spot, classname, "info_intermission");
1392                         cyc = cyc - 1;
1393                 }
1394                 return spot;
1395         }
1396
1397 // then look for the start position
1398         spot = find (world, classname, "info_player_start");
1399         if (spot)
1400                 return spot;
1401
1402 // testinfo_player_start is only found in regioned levels
1403         spot = find (world, classname, "testplayerstart");
1404         if (spot)
1405                 return spot;
1406
1407 // then look for the start position
1408         spot = find (world, classname, "info_player_deathmatch");
1409         if (spot)
1410                 return spot;
1411
1412         //objerror ("FindIntermission: no spot");
1413         return world;
1414 }
1415 */
1416
1417 /*
1418 ===============================================================================
1419
1420 RULES
1421
1422 ===============================================================================
1423 */
1424
1425 void DumpStats(float final)
1426 {
1427         float file;
1428         string s;
1429         float to_console;
1430         float to_eventlog;
1431         float to_file;
1432         float i;
1433
1434         to_console = autocvar_sv_logscores_console;
1435         to_eventlog = autocvar_sv_eventlog;
1436         to_file = autocvar_sv_logscores_file;
1437
1438         if(!final)
1439         {
1440                 to_console = TRUE; // always print printstats replies
1441                 to_eventlog = FALSE; // but never print them to the event log
1442         }
1443
1444         if(to_eventlog)
1445                 if(autocvar_sv_eventlog_console)
1446                         to_console = FALSE; // otherwise we get the output twice
1447
1448         if(final)
1449                 s = ":scores:";
1450         else
1451                 s = ":status:";
1452         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1453
1454         if(to_console)
1455                 print(s, "\n");
1456         if(to_eventlog)
1457                 GameLogEcho(s);
1458
1459         file = -1;
1460         if(to_file)
1461         {
1462                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1463                 if(file == -1)
1464                         to_file = FALSE;
1465                 else
1466                         fputs(file, strcat(s, "\n"));
1467         }
1468
1469         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1470         if(to_console)
1471                 print(s, "\n");
1472         if(to_eventlog)
1473                 GameLogEcho(s);
1474         if(to_file)
1475                 fputs(file, strcat(s, "\n"));
1476
1477         FOR_EACH_CLIENT(other)
1478         {
1479                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1480                 {
1481                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1482                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1483                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1484                                 s = strcat(s, ftos(other.team), ":");
1485                         else
1486                                 s = strcat(s, "spectator:");
1487
1488                         if(to_console)
1489                                 print(s, other.netname, "\n");
1490                         if(to_eventlog)
1491                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1492                         if(to_file)
1493                                 fputs(file, strcat(s, other.netname, "\n"));
1494                 }
1495         }
1496
1497         if(teamplay)
1498         {
1499                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1500                 if(to_console)
1501                         print(s, "\n");
1502                 if(to_eventlog)
1503                         GameLogEcho(s);
1504                 if(to_file)
1505                         fputs(file, strcat(s, "\n"));
1506
1507                 for(i = 1; i < 16; ++i)
1508                 {
1509                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1510                         s = strcat(s, ":", ftos(i));
1511                         if(to_console)
1512                                 print(s, "\n");
1513                         if(to_eventlog)
1514                                 GameLogEcho(s);
1515                         if(to_file)
1516                                 fputs(file, strcat(s, "\n"));
1517                 }
1518         }
1519
1520         if(to_console)
1521                 print(":end\n");
1522         if(to_eventlog)
1523                 GameLogEcho(":end");
1524         if(to_file)
1525         {
1526                 fputs(file, ":end\n");
1527                 fclose(file);
1528         }
1529 }
1530
1531 void FixIntermissionClient(entity e)
1532 {
1533         string s;
1534         if(!e.autoscreenshot) // initial call
1535         {
1536                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1537                 e.health = -2342;
1538                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1539                 e.solid = SOLID_NOT;
1540                 e.movetype = MOVETYPE_NONE;
1541                 e.takedamage = DAMAGE_NO;
1542                 if(e.weaponentity)
1543                 {
1544                         e.weaponentity.effects = EF_NODRAW;
1545                         if (e.weaponentity.weaponentity)
1546                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1547                 }
1548                 if(clienttype(e) == CLIENTTYPE_REAL)
1549                 {
1550                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1551                         s = autocvar_sv_intermission_cdtrack;
1552                         if(s != "")
1553                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1554                         msg_entity = e;
1555                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1556                 }
1557         }
1558 }
1559
1560 void minstagib_stop_countdown(entity e);
1561 /*
1562 go to the next level for deathmatch
1563 only called if a time or frag limit has expired
1564 */
1565 void NextLevel()
1566 {
1567         gameover = TRUE;
1568
1569         intermission_running = 1;
1570
1571 // enforce a wait time before allowing changelevel
1572         if(player_count > 0)
1573                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1574         else
1575                 intermission_exittime = -1;
1576
1577         /*
1578         WriteByte (MSG_ALL, SVC_CDTRACK);
1579         WriteByte (MSG_ALL, 3);
1580         WriteByte (MSG_ALL, 3);
1581         // done in FixIntermission
1582         */
1583
1584         //pos = FindIntermission ();
1585
1586         VoteReset();
1587
1588         DumpStats(TRUE);
1589
1590         // send statistics
1591         entity e;
1592         PlayerStats_EndMatch(1);
1593         FOR_EACH_CLIENT(e)
1594                 PlayerStats_AddGlobalInfo(e);
1595         PlayerStats_Shutdown();
1596         WeaponStats_Shutdown();
1597
1598         if(autocvar_sv_eventlog)
1599                 GameLogEcho(":gameover");
1600
1601         GameLogClose();
1602
1603         FOR_EACH_PLAYER(other) {
1604                 minstagib_stop_countdown(other);
1605                 FixIntermissionClient(other);
1606                 if(other.winning)
1607                         bprint(other.netname, " ^7wins.\n");
1608         }
1609
1610         if(autocvar_g_campaign)
1611                 CampaignPreIntermission();
1612
1613         MUTATOR_CALLHOOK(MatchEnd);
1614
1615         localcmd("\nsv_hook_gameend\n");
1616 }
1617
1618 /*
1619 ============
1620 CheckRules_Player
1621
1622 Exit deathmatch games upon conditions
1623 ============
1624 */
1625 void CheckRules_Player()
1626 {
1627         if (gameover)   // someone else quit the game already
1628                 return;
1629
1630         if(self.deadflag == DEAD_NO)
1631                 self.play_time += frametime;
1632
1633         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1634         //   (div0: and that in CheckRules_World please)
1635 }
1636
1637 float checkrules_equality;
1638 float checkrules_suddendeathwarning;
1639 float checkrules_suddendeathend;
1640 float checkrules_overtimesadded; //how many overtimes have been already added
1641
1642 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1643 float WINNING_YES = 1; // winner found
1644 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1645 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1646
1647 float InitiateSuddenDeath()
1648 {
1649         // Check first whether normal overtimes could be added before initiating suddendeath mode
1650         // - for this timelimit_overtime needs to be >0 of course
1651         // - also check the winning condition calculated in the previous frame and only add normal overtime
1652         //   again, if at the point at which timelimit would be extended again, still no winner was found
1653         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1654         {
1655                 return 1; // need to call InitiateOvertime later
1656         }
1657         else
1658         {
1659                 if(!checkrules_suddendeathend)
1660                 {
1661                         if(autocvar_g_campaign)
1662                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1663                         else
1664                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1665                         if(g_race && !g_race_qualifying)
1666                                 race_StartCompleting();
1667                 }
1668                 return 0;
1669         }
1670 }
1671
1672 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1673 {
1674         ++checkrules_overtimesadded;
1675         //add one more overtime by simply extending the timelimit
1676         float tl;
1677         tl = autocvar_timelimit;
1678         tl += autocvar_timelimit_overtime;
1679         cvar_set("timelimit", ftos(tl));
1680         string minutesPlural;
1681         if (autocvar_timelimit_overtime == 1)
1682                 minutesPlural = " ^3minute";
1683         else
1684                 minutesPlural = " ^3minutes";
1685
1686         bcenterprint(
1687                 strcat(
1688                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1689                         ftos(autocvar_timelimit_overtime),
1690                         minutesPlural,
1691                         " to the game!"
1692                 )
1693         );
1694 }
1695
1696 float GetWinningCode(float fraglimitreached, float equality)
1697 {
1698         if(autocvar_g_campaign == 1)
1699                 if(fraglimitreached)
1700                         return WINNING_YES;
1701                 else
1702                         return WINNING_NO;
1703
1704         else
1705                 if(equality)
1706                         if(fraglimitreached)
1707                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1708                         else
1709                                 return WINNING_NEVER;
1710                 else
1711                         if(fraglimitreached)
1712                                 return WINNING_YES;
1713                         else
1714                                 return WINNING_NO;
1715 }
1716
1717 // set the .winning flag for exactly those players with a given field value
1718 void SetWinners(.float field, float value)
1719 {
1720         entity head;
1721         FOR_EACH_PLAYER(head)
1722                 head.winning = (head.field == value);
1723 }
1724
1725 // set the .winning flag for those players with a given field value
1726 void AddWinners(.float field, float value)
1727 {
1728         entity head;
1729         FOR_EACH_PLAYER(head)
1730                 if(head.field == value)
1731                         head.winning = 1;
1732 }
1733
1734 // clear the .winning flags
1735 void ClearWinners(void)
1736 {
1737         entity head;
1738         FOR_EACH_PLAYER(head)
1739                 head.winning = 0;
1740 }
1741
1742 // Onslaught winning condition:
1743 // game terminates if only one team has a working generator (or none)
1744 float WinningCondition_Onslaught()
1745 {
1746         entity head;
1747         float t1, t2, t3, t4;
1748
1749         WinningConditionHelper(); // set worldstatus
1750
1751         if(inWarmupStage)
1752                 return WINNING_NO;
1753
1754         // first check if the game has ended
1755         t1 = t2 = t3 = t4 = 0;
1756         head = find(world, classname, "onslaught_generator");
1757         while (head)
1758         {
1759                 if (head.health > 0)
1760                 {
1761                         if (head.team == COLOR_TEAM1) t1 = 1;
1762                         if (head.team == COLOR_TEAM2) t2 = 1;
1763                         if (head.team == COLOR_TEAM3) t3 = 1;
1764                         if (head.team == COLOR_TEAM4) t4 = 1;
1765                 }
1766                 head = find(head, classname, "onslaught_generator");
1767         }
1768         if (t1 + t2 + t3 + t4 < 2)
1769         {
1770                 // game over, only one team remains (or none)
1771                 ClearWinners();
1772                 if (t1) SetWinners(team, COLOR_TEAM1);
1773                 if (t2) SetWinners(team, COLOR_TEAM2);
1774                 if (t3) SetWinners(team, COLOR_TEAM3);
1775                 if (t4) SetWinners(team, COLOR_TEAM4);
1776                 dprint("Have a winner, ending game.\n");
1777                 return WINNING_YES;
1778         }
1779
1780         // Two or more teams remain
1781         return WINNING_NO;
1782 }
1783
1784 float LMS_NewPlayerLives()
1785 {
1786         float fl;
1787         fl = autocvar_fraglimit;
1788         if(fl == 0)
1789                 fl = 999;
1790
1791         // first player has left the game for dying too much? Nobody else can get in.
1792         if(lms_lowest_lives < 1)
1793                 return 0;
1794
1795         if(!autocvar_g_lms_join_anytime)
1796                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1797                         return 0;
1798
1799         return bound(1, lms_lowest_lives, fl);
1800 }
1801
1802 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1803 // they win. Otherwise the defending team wins once the timelimit passes.
1804 void assault_new_round();
1805 float WinningCondition_Assault()
1806 {
1807         float status;
1808
1809         WinningConditionHelper(); // set worldstatus
1810
1811         status = WINNING_NO;
1812         // as the timelimit has not yet passed just assume the defending team will win
1813         if(assault_attacker_team == COLOR_TEAM1)
1814         {
1815                 SetWinners(team, COLOR_TEAM2);
1816         }
1817         else
1818         {
1819                 SetWinners(team, COLOR_TEAM1);
1820         }
1821
1822         entity ent;
1823         ent = find(world, classname, "target_assault_roundend");
1824         if(ent)
1825         {
1826                 if(ent.winning) // round end has been triggered by attacking team
1827                 {
1828                         bprint("ASSAULT: round completed...\n");
1829                         SetWinners(team, assault_attacker_team);
1830
1831                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1832
1833                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1834                         {
1835                                 status = WINNING_YES;
1836                         }
1837                         else
1838                         {
1839                                 entity oldself;
1840                                 oldself = self;
1841                                 self = ent;
1842                                 assault_new_round();
1843                                 self = oldself;
1844                         }
1845                 }
1846         }
1847
1848         return status;
1849 }
1850
1851 // LMS winning condition: game terminates if and only if there's at most one
1852 // one player who's living lives. Top two scores being equal cancels the time
1853 // limit.
1854 float WinningCondition_LMS()
1855 {
1856         entity head, head2;
1857         float have_player;
1858         float have_players;
1859         float l;
1860
1861         have_player = FALSE;
1862         have_players = FALSE;
1863         l = LMS_NewPlayerLives();
1864
1865         head = find(world, classname, "player");
1866         if(head)
1867                 have_player = TRUE;
1868         head2 = find(head, classname, "player");
1869         if(head2)
1870                 have_players = TRUE;
1871
1872         if(have_player)
1873         {
1874                 // we have at least one player
1875                 if(have_players)
1876                 {
1877                         // two or more active players - continue with the game
1878                 }
1879                 else
1880                 {
1881                         // exactly one player?
1882
1883                         ClearWinners();
1884                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1885
1886                         if(l)
1887                         {
1888                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1889                                 return WINNING_NO;
1890                         }
1891                         else
1892                         {
1893                                 // a winner!
1894                                 // and assign him his first place
1895                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1896                                 return WINNING_YES;
1897                         }
1898                 }
1899         }
1900         else
1901         {
1902                 // nobody is playing at all...
1903                 if(l)
1904                 {
1905                         // wait for players...
1906                 }
1907                 else
1908                 {
1909                         // SNAFU (maybe a draw game?)
1910                         ClearWinners();
1911                         dprint("No players, ending game.\n");
1912                         return WINNING_YES;
1913                 }
1914         }
1915
1916         // When we get here, we have at least two players who are actually LIVING,
1917         // now check if the top two players have equal score.
1918         WinningConditionHelper();
1919
1920         ClearWinners();
1921         if(WinningConditionHelper_winner)
1922                 WinningConditionHelper_winner.winning = TRUE;
1923         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1924                 return WINNING_NEVER;
1925
1926         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1927         return WINNING_NO;
1928 }
1929
1930 void ShuffleMaplist()
1931 {
1932         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1933 }
1934
1935 float leaderfrags;
1936 float WinningCondition_Scores(float limit, float leadlimit)
1937 {
1938         float limitreached;
1939
1940         // TODO make everything use THIS winning condition (except LMS)
1941         WinningConditionHelper();
1942
1943         if(teamplay)
1944         {
1945                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1946                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1947                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1948                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1949         }
1950
1951         ClearWinners();
1952         if(WinningConditionHelper_winner)
1953                 WinningConditionHelper_winner.winning = 1;
1954         if(WinningConditionHelper_winnerteam >= 0)
1955                 SetWinners(team, WinningConditionHelper_winnerteam);
1956
1957         if(WinningConditionHelper_lowerisbetter)
1958         {
1959                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1960                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1961                 limit = -limit;
1962         }
1963
1964         if(WinningConditionHelper_zeroisworst)
1965                 leadlimit = 0; // not supported in this mode
1966
1967         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1968         // these modes always score in increments of 1, thus this makes sense
1969         {
1970                 if(leaderfrags != WinningConditionHelper_topscore)
1971                 {
1972                         leaderfrags = WinningConditionHelper_topscore;
1973
1974                         if (limit)
1975                         if (leaderfrags == limit - 1)
1976                                 Announce("1fragleft");
1977                         else if (leaderfrags == limit - 2)
1978                                 Announce("2fragsleft");
1979                         else if (leaderfrags == limit - 3)
1980                                 Announce("3fragsleft");
1981                 }
1982         }
1983
1984         limitreached = FALSE;
1985         if(limit)
1986                 if(WinningConditionHelper_topscore >= limit)
1987                         limitreached = TRUE;
1988         if(leadlimit)
1989         {
1990                 float leadlimitreached;
1991                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1992                 if(autocvar_leadlimit_and_fraglimit)
1993                         limitreached = (limitreached && leadlimitreached);
1994                 else
1995                         limitreached = (limitreached || leadlimitreached);
1996         }
1997
1998         if(limit)
1999                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2000
2001         return GetWinningCode(
2002                 WinningConditionHelper_topscore && limitreached,
2003                 WinningConditionHelper_equality
2004         );
2005 }
2006
2007 float WinningCondition_Race(float fraglimit)
2008 {
2009         float wc;
2010         entity p;
2011         float n, c;
2012
2013         n = 0;
2014         c = 0;
2015         FOR_EACH_PLAYER(p)
2016         {
2017                 ++n;
2018                 if(p.race_completed)
2019                         ++c;
2020         }
2021         if(n && (n == c))
2022                 return WINNING_YES;
2023         wc = WinningCondition_Scores(fraglimit, 0);
2024
2025         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2026         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2027         // do NOT support equality when the laps are all raced!
2028                 return WINNING_STARTSUDDENDEATHOVERTIME;
2029         else
2030                 return WINNING_NEVER;
2031 }
2032
2033 float WinningCondition_QualifyingThenRace(float limit)
2034 {
2035         float wc;
2036         wc = WinningCondition_Scores(limit, 0);
2037
2038         // NEVER initiate overtime
2039         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2040         {
2041                 return WINNING_YES;
2042         }
2043
2044         return wc;
2045 }
2046
2047 float WinningCondition_RanOutOfSpawns()
2048 {
2049         entity head;
2050
2051         if(have_team_spawns <= 0)
2052                 return WINNING_NO;
2053
2054         if(autocvar_g_spawn_useallspawns <= 0)
2055                 return WINNING_NO;
2056
2057         if(!some_spawn_has_been_used)
2058                 return WINNING_NO;
2059
2060         team1_score = team2_score = team3_score = team4_score = 0;
2061
2062         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2063         {
2064                 if(head.team == COLOR_TEAM1)
2065                         team1_score = 1;
2066                 else if(head.team == COLOR_TEAM2)
2067                         team2_score = 1;
2068                 else if(head.team == COLOR_TEAM3)
2069                         team3_score = 1;
2070                 else if(head.team == COLOR_TEAM4)
2071                         team4_score = 1;
2072         }
2073
2074         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2075         {
2076                 if(head.team == COLOR_TEAM1)
2077                         team1_score = 1;
2078                 else if(head.team == COLOR_TEAM2)
2079                         team2_score = 1;
2080                 else if(head.team == COLOR_TEAM3)
2081                         team3_score = 1;
2082                 else if(head.team == COLOR_TEAM4)
2083                         team4_score = 1;
2084         }
2085
2086         ClearWinners();
2087         if(team1_score + team2_score + team3_score + team4_score == 0)
2088         {
2089                 checkrules_equality = TRUE;
2090                 return WINNING_YES;
2091         }
2092         else if(team1_score + team2_score + team3_score + team4_score == 1)
2093         {
2094                 float t, i;
2095                 if(team1_score)
2096                         t = COLOR_TEAM1;
2097                 else if(team2_score)
2098                         t = COLOR_TEAM2;
2099                 else if(team3_score)
2100                         t = COLOR_TEAM3;
2101                 else // if(team4_score)
2102                         t = COLOR_TEAM4;
2103                 CheckAllowedTeams(world);
2104                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2105                 {
2106                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2107                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2108                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2109                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2110                 }
2111
2112                 AddWinners(team, t);
2113                 return WINNING_YES;
2114         }
2115         else
2116                 return WINNING_NO;
2117 }
2118
2119 /*
2120 ============
2121 CheckRules_World
2122
2123 Exit deathmatch games upon conditions
2124 ============
2125 */
2126 void ReadyRestart();
2127 void CheckRules_World()
2128 {
2129         float timelimit;
2130         float fraglimit;
2131         float leadlimit;
2132
2133         VoteThink();
2134         MapVote_Think();
2135
2136         SetDefaultAlpha();
2137
2138         /*
2139         MapVote_Think should now do that part
2140         if (intermission_running)
2141                 if (time >= intermission_exittime + 60)
2142                 {
2143                         if(!DoNextMapOverride())
2144                                 GotoNextMap();
2145                         return;
2146                 }
2147         */
2148
2149         if (gameover)   // someone else quit the game already
2150         {
2151                 if(player_count == 0) // Nobody there? Then let's go to the next map
2152                         MapVote_Start();
2153                         // this will actually check the player count in the next frame
2154                         // again, but this shouldn't hurt
2155                 return;
2156         }
2157
2158         timelimit = autocvar_timelimit * 60;
2159         fraglimit = autocvar_fraglimit;
2160         leadlimit = autocvar_leadlimit;
2161
2162         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2163         {
2164                 if(timelimit > 0)
2165                         timelimit = 0; // timelimit is not made for warmup
2166                 if(fraglimit > 0)
2167                         fraglimit = 0; // no fraglimit for now
2168                 leadlimit = 0; // no leadlimit for now
2169         }
2170
2171         if(timelimit > 0)
2172         {
2173                 timelimit += game_starttime;
2174         }
2175         else if (timelimit < 0)
2176         {
2177                 // endmatch
2178                 NextLevel();
2179                 return;
2180         }
2181
2182         if(g_onslaught)
2183                 timelimit = 0; // ONS has its own overtime rule
2184
2185         float wantovertime;
2186         wantovertime = 0;
2187
2188         if(timelimit > game_starttime)
2189                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2190         else
2191                 game_completion_ratio = 0;
2192
2193         if(checkrules_suddendeathend)
2194         {
2195                 if(!checkrules_suddendeathwarning)
2196                 {
2197                         checkrules_suddendeathwarning = TRUE;
2198                         if(g_race && !g_race_qualifying)
2199                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2200                         else
2201                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2202                 }
2203         }
2204         else
2205         {
2206                 if (timelimit && time >= timelimit)
2207                 {
2208                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2209                         {
2210                                 float totalplayers;
2211                                 float playerswithlaps;
2212                                 float readyplayers;
2213                                 entity head;
2214                                 totalplayers = playerswithlaps = readyplayers = 0;
2215                                 FOR_EACH_PLAYER(head)
2216                                 {
2217                                         ++totalplayers;
2218                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2219                                                 ++playerswithlaps;
2220                                         if(head.ready)
2221                                                 ++readyplayers;
2222                                 }
2223
2224                                 // at least 2 of the players have completed a lap: start the RACE
2225                                 // otherwise, the players should end the qualifying on their own
2226                                 if(readyplayers || playerswithlaps >= 2)
2227                                 {
2228                                         checkrules_suddendeathend = 0;
2229                                         ReadyRestart(); // go to race
2230                                         return;
2231                                 }
2232                                 else
2233                                         wantovertime |= InitiateSuddenDeath();
2234                         }
2235                         else
2236                                 wantovertime |= InitiateSuddenDeath();
2237                 }
2238         }
2239
2240         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2241         {
2242                 NextLevel();
2243                 return;
2244         }
2245
2246         float checkrules_status;
2247         checkrules_status = WinningCondition_RanOutOfSpawns();
2248         if(checkrules_status == WINNING_YES)
2249         {
2250                 bprint("Hey! Someone ran out of spawns!\n");
2251         }
2252         else if(g_race && !g_race_qualifying && timelimit >= 0)
2253         {
2254                 checkrules_status = WinningCondition_Race(fraglimit);
2255                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2256         }
2257         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2258         {
2259                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2260                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2261         }
2262         else if(g_assault)
2263         {
2264                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2265         }
2266         else if(g_lms)
2267         {
2268                 checkrules_status = WinningCondition_LMS();
2269         }
2270         else if (g_onslaught)
2271         {
2272                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2273         }
2274         else
2275         {
2276                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2277                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2278         }
2279
2280         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2281         {
2282                 checkrules_status = WINNING_NEVER;
2283                 checkrules_overtimesadded = -1;
2284                 wantovertime |= InitiateSuddenDeath();
2285         }
2286
2287         if(checkrules_status == WINNING_NEVER)
2288                 // equality cases! Nobody wins if the overtime ends in a draw.
2289                 ClearWinners();
2290
2291         if(wantovertime)
2292         {
2293                 if(checkrules_status == WINNING_NEVER)
2294                         InitiateOvertime();
2295                 else
2296                         checkrules_status = WINNING_YES;
2297         }
2298
2299         if(checkrules_suddendeathend)
2300                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2301                         checkrules_status = WINNING_YES;
2302
2303         if(checkrules_status == WINNING_YES)
2304         {
2305                 //print("WINNING\n");
2306                 NextLevel();
2307         }
2308 }
2309
2310 float mapvote_nextthink;
2311 float mapvote_initialized;
2312 float mapvote_keeptwotime;
2313 float mapvote_timeout;
2314 string mapvote_message;
2315 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2316 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2317 float mapvote_screenshot_dirs_count;
2318
2319 float mapvote_count;
2320 float mapvote_count_real;
2321 string mapvote_maps[MAPVOTE_COUNT];
2322 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2323 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2324 float mapvote_maps_suggested[MAPVOTE_COUNT];
2325 string mapvote_suggestions[MAPVOTE_COUNT];
2326 float mapvote_suggestion_ptr;
2327 float mapvote_voters;
2328 float mapvote_selections[MAPVOTE_COUNT];
2329 float mapvote_run;
2330 float mapvote_detail;
2331 float mapvote_abstain;
2332 .float mapvote;
2333
2334 void MapVote_ClearAllVotes()
2335 {
2336         FOR_EACH_CLIENT(other)
2337                 other.mapvote = 0;
2338 }
2339
2340 string MapVote_Suggest(string m)
2341 {
2342         float i;
2343         if(m == "")
2344                 return "That's not how to use this command.";
2345         if(!autocvar_g_maplist_votable_suggestions)
2346                 return "Suggestions are not accepted on this server.";
2347         if(mapvote_initialized)
2348                 return "Can't suggest - voting is already in progress!";
2349         m = MapInfo_FixName(m);
2350         if not(m)
2351                 return "The map you suggested is not available on this server.";
2352         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2353                 if(Map_IsRecent(m))
2354                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2355
2356         if(!MapInfo_CheckMap(m))
2357                 return "The map you suggested does not support the current game mode.";
2358         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2359                 if(mapvote_suggestions[i] == m)
2360                         return "This map was already suggested.";
2361         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2362         {
2363                 i = floor(random() * mapvote_suggestion_ptr);
2364         }
2365         else
2366         {
2367                 i = mapvote_suggestion_ptr;
2368                 mapvote_suggestion_ptr += 1;
2369         }
2370         if(mapvote_suggestions[i] != "")
2371                 strunzone(mapvote_suggestions[i]);
2372         mapvote_suggestions[i] = strzone(m);
2373         if(autocvar_sv_eventlog)
2374                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2375         return strcat("Suggestion of ", m, " accepted.");
2376 }
2377
2378 void MapVote_AddVotable(string nextMap, float isSuggestion)
2379 {
2380         float j, i, o;
2381         string pakfile, mapfile;
2382
2383         if(nextMap == "")
2384                 return;
2385         for(j = 0; j < mapvote_count; ++j)
2386                 if(mapvote_maps[j] == nextMap)
2387                         return;
2388         // suggestions might be no longer valid/allowed after gametype switch!
2389         if(isSuggestion)
2390                 if(!MapInfo_CheckMap(nextMap))
2391                         return;
2392         mapvote_maps[mapvote_count] = strzone(nextMap);
2393         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2394
2395         pakfile = string_null;
2396         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2397         {
2398                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2399                 pakfile = whichpack(strcat(mapfile, ".tga"));
2400                 if(pakfile == "")
2401                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2402                 if(pakfile == "")
2403                         pakfile = whichpack(strcat(mapfile, ".png"));
2404                 if(pakfile != "")
2405                         break;
2406         }
2407         if(i >= mapvote_screenshot_dirs_count)
2408                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2409         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2410                 pakfile = substring(pakfile, o, -1);
2411
2412         mapvote_maps_screenshot_dir[mapvote_count] = i;
2413         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2414
2415         mapvote_count += 1;
2416 }
2417
2418 void MapVote_Spawn();
2419 void MapVote_Init()
2420 {
2421         float i;
2422         float nmax, smax;
2423
2424         MapVote_ClearAllVotes();
2425
2426         mapvote_count = 0;
2427         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2428         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2429
2430         if(mapvote_abstain)
2431                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2432         else
2433                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2434         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2435
2436         // we need this for AddVotable, as that cycles through the screenshot dirs
2437         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2438         if(mapvote_screenshot_dirs_count == 0)
2439                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2440         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2441         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2442                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2443
2444         if(mapvote_suggestion_ptr)
2445                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2446                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2447
2448         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2449                 MapVote_AddVotable(GetNextMap(), FALSE);
2450
2451         if(mapvote_count == 0)
2452         {
2453                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2454                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2455                 if(autocvar_g_maplist_shuffle)
2456                         ShuffleMaplist();
2457                 localcmd("\nmenu_cmd sync\n");
2458                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2459                         MapVote_AddVotable(GetNextMap(), FALSE);
2460         }
2461
2462         mapvote_count_real = mapvote_count;
2463         if(mapvote_abstain)
2464                 MapVote_AddVotable("don't care", 0);
2465
2466         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2467
2468         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2469         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2470         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2471                 mapvote_keeptwotime = 0;
2472         mapvote_message = "Choose a map and press its key!";
2473
2474         MapVote_Spawn();
2475 }
2476
2477 void MapVote_SendPicture(float id)
2478 {
2479         msg_entity = self;
2480         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2481         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2482         WriteByte(MSG_ONE, id);
2483         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2484 }
2485
2486 float MapVote_GetMapMask()
2487 {
2488         float mask, i, power;
2489         mask = 0;
2490         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2491                 if(mapvote_maps[i] != "")
2492                         mask |= power;
2493         return mask;
2494 }
2495
2496 entity mapvote_ent;
2497 float MapVote_SendEntity(entity to, float sf)
2498 {
2499         float i;
2500
2501         if(sf & 1)
2502                 sf &~= 2; // if we send 1, we don't need to also send 2
2503
2504         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2505         WriteByte(MSG_ENTITY, sf);
2506
2507         if(sf & 1)
2508         {
2509                 // flag 1 == initialization
2510                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2511                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2512                 WriteString(MSG_ENTITY, "");
2513                 WriteByte(MSG_ENTITY, mapvote_count);
2514                 WriteByte(MSG_ENTITY, mapvote_abstain);
2515                 WriteByte(MSG_ENTITY, mapvote_detail);
2516                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2517                 if(mapvote_count <= 8)
2518                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2519                 else
2520                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2521                 for(i = 0; i < mapvote_count; ++i)
2522                         if(mapvote_maps[i] != "")
2523                         {
2524                                 if(mapvote_abstain && i == mapvote_count - 1)
2525                                 {
2526                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2527                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2528                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2529                                 }
2530                                 else
2531                                 {
2532                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2533                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2534                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2535                                 }
2536                         }
2537         }
2538
2539         if(sf & 2)
2540         {
2541                 // flag 2 == update of mask
2542                 if(mapvote_count <= 8)
2543                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2544                 else
2545                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2546         }
2547
2548         if(sf & 4)
2549         {
2550                 if(mapvote_detail)
2551                         for(i = 0; i < mapvote_count; ++i)
2552                                 if(mapvote_maps[i] != "")
2553                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2554
2555                 WriteByte(MSG_ENTITY, to.mapvote);
2556         }
2557
2558         return TRUE;
2559 }
2560
2561 void MapVote_Spawn()
2562 {
2563         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2564 }
2565
2566 void MapVote_TouchMask()
2567 {
2568         mapvote_ent.SendFlags |= 2;
2569 }
2570
2571 void MapVote_TouchVotes(entity voter)
2572 {
2573         mapvote_ent.SendFlags |= 4;
2574 }
2575
2576 float MapVote_Finished(float mappos)
2577 {
2578         string result;
2579         float i;
2580         float didntvote;
2581
2582         if(autocvar_sv_eventlog)
2583         {
2584                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2585                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2586                 didntvote = mapvote_voters;
2587                 for(i = 0; i < mapvote_count; ++i)
2588                         if(mapvote_maps[i] != "")
2589                         {
2590                                 didntvote -= mapvote_selections[i];
2591                                 if(i != mappos)
2592                                 {
2593                                         result = strcat(result, ":", mapvote_maps[i]);
2594                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2595                                 }
2596                         }
2597                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2598
2599                 GameLogEcho(result);
2600                 if(mapvote_maps_suggested[mappos])
2601                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2602         }
2603
2604         FOR_EACH_REALCLIENT(other)
2605                 FixClientCvars(other);
2606
2607         Map_Goto_SetStr(mapvote_maps[mappos]);
2608         Map_Goto(0);
2609         alreadychangedlevel = TRUE;
2610         return TRUE;
2611 }
2612 void MapVote_CheckRules_1()
2613 {
2614         float i;
2615
2616         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2617         {
2618                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2619                 mapvote_selections[i] = 0;
2620         }
2621
2622         mapvote_voters = 0;
2623         FOR_EACH_REALCLIENT(other)
2624         {
2625                 ++mapvote_voters;
2626                 if(other.mapvote)
2627                 {
2628                         i = other.mapvote - 1;
2629                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2630                         mapvote_selections[i] = mapvote_selections[i] + 1;
2631                 }
2632         }
2633 }
2634
2635 float MapVote_CheckRules_2()
2636 {
2637         float i;
2638         float firstPlace, secondPlace;
2639         float firstPlaceVotes, secondPlaceVotes;
2640         float mapvote_voters_real;
2641         string result;
2642
2643         if(mapvote_count_real == 1)
2644                 return MapVote_Finished(0);
2645
2646         mapvote_voters_real = mapvote_voters;
2647         if(mapvote_abstain)
2648                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2649
2650         RandomSelection_Init();
2651         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2652                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2653         firstPlace = RandomSelection_chosen_float;
2654         firstPlaceVotes = RandomSelection_best_priority;
2655         //dprint("First place: ", ftos(firstPlace), "\n");
2656         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2657
2658         RandomSelection_Init();
2659         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2660                 if(i != firstPlace)
2661                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2662         secondPlace = RandomSelection_chosen_float;
2663         secondPlaceVotes = RandomSelection_best_priority;
2664         //dprint("Second place: ", ftos(secondPlace), "\n");
2665         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2666
2667         if(firstPlace == -1)
2668                 error("No first place in map vote... WTF?");
2669
2670         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2671                 return MapVote_Finished(firstPlace);
2672
2673         if(mapvote_keeptwotime)
2674                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2675                 {
2676                         float didntvote;
2677                         MapVote_TouchMask();
2678                         mapvote_message = "Now decide between the TOP TWO!";
2679                         mapvote_keeptwotime = 0;
2680                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2681                         result = strcat(result, ":", ftos(firstPlaceVotes));
2682                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2683                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2684                         didntvote = mapvote_voters;
2685                         for(i = 0; i < mapvote_count; ++i)
2686                                 if(mapvote_maps[i] != "")
2687                                 {
2688                                         didntvote -= mapvote_selections[i];
2689                                         if(i != firstPlace)
2690                                                 if(i != secondPlace)
2691                                                 {
2692                                                         result = strcat(result, ":", mapvote_maps[i]);
2693                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2694                                                         if(i < mapvote_count_real)
2695                                                         {
2696                                                                 strunzone(mapvote_maps[i]);
2697                                                                 mapvote_maps[i] = "";
2698                                                                 strunzone(mapvote_maps_pakfile[i]);
2699                                                                 mapvote_maps_pakfile[i] = "";
2700                                                         }
2701                                                 }
2702                                 }
2703                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2704                         if(autocvar_sv_eventlog)
2705                                 GameLogEcho(result);
2706                 }
2707
2708         return FALSE;
2709 }
2710 void MapVote_Tick()
2711 {
2712         float keeptwo;
2713         float totalvotes;
2714
2715         keeptwo = mapvote_keeptwotime;
2716         MapVote_CheckRules_1(); // count
2717         if(MapVote_CheckRules_2()) // decide
2718                 return;
2719
2720         totalvotes = 0;
2721         FOR_EACH_REALCLIENT(other)
2722         {
2723                 // hide scoreboard again
2724                 if(other.health != 2342)
2725                 {
2726                         other.health = 2342;
2727                         other.impulse = 0;
2728                         if(clienttype(other) == CLIENTTYPE_REAL)
2729                         {
2730                                 msg_entity = other;
2731                                 WriteByte(MSG_ONE, SVC_FINALE);
2732                                 WriteString(MSG_ONE, "");
2733                         }
2734                 }
2735
2736                 // clear possibly invalid votes
2737                 if(mapvote_maps[other.mapvote - 1] == "")
2738                         other.mapvote = 0;
2739                 // use impulses as new vote
2740                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2741                         if(mapvote_maps[other.impulse - 1] != "")
2742                         {
2743                                 other.mapvote = other.impulse;
2744                                 MapVote_TouchVotes(other);
2745                         }
2746                 other.impulse = 0;
2747
2748                 if(other.mapvote)
2749                         ++totalvotes;
2750         }
2751
2752         MapVote_CheckRules_1(); // just count
2753 }
2754 void MapVote_Start()
2755 {
2756         if(mapvote_run)
2757                 return;
2758
2759         // wait for stats to be sent first
2760         if(!playerstats_waitforme)
2761                 return;
2762
2763         MapInfo_Enumerate();
2764         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2765                 mapvote_run = TRUE;
2766 }
2767 void MapVote_Think()
2768 {
2769         if(!mapvote_run)
2770                 return;
2771
2772         if(alreadychangedlevel)
2773                 return;
2774
2775         if(time < mapvote_nextthink)
2776                 return;
2777         //dprint("tick\n");
2778
2779         mapvote_nextthink = time + 0.5;
2780
2781         if(!mapvote_initialized)
2782         {
2783                 if(autocvar_rescan_pending == 1)
2784                 {
2785                         cvar_set("rescan_pending", "2");
2786                         localcmd("fs_rescan\nrescan_pending 3\n");
2787                         return;
2788                 }
2789                 else if(autocvar_rescan_pending == 2)
2790                 {
2791                         return;
2792                 }
2793                 else if(autocvar_rescan_pending == 3)
2794                 {
2795                         // now build missing mapinfo files
2796                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2797                                 return;
2798
2799                         // we're done, start the timer
2800                         cvar_set("rescan_pending", "0");
2801                 }
2802
2803                 mapvote_initialized = TRUE;
2804                 if(DoNextMapOverride(0))
2805                         return;
2806                 if(!autocvar_g_maplist_votable || player_count <= 0)
2807                 {
2808                         GotoNextMap(0);
2809                         return;
2810                 }
2811                 MapVote_Init();
2812         }
2813
2814         MapVote_Tick();
2815 }
2816
2817 string GotoMap(string m)
2818 {
2819         if(!MapInfo_CheckMap(m))
2820                 return "The map you chose is not available on this server.";
2821         cvar_set("nextmap", m);
2822         cvar_set("timelimit", "-1");
2823         if(mapvote_initialized || alreadychangedlevel)
2824         {
2825                 if(DoNextMapOverride(0))
2826                         return "Map switch initiated.";
2827                 else
2828                         return "Hm... no. For some reason I like THIS map more.";
2829         }
2830         else
2831                 return "Map switch will happen after scoreboard.";
2832 }
2833
2834
2835 void EndFrame()
2836 {
2837         float altime;
2838         FOR_EACH_REALCLIENT(self)
2839         {
2840                 if(self.classname == "spectator")
2841                 {
2842                         if(self.enemy.typehitsound)
2843                                 self.typehit_time = time;
2844                         else if(self.enemy.hitsound)
2845                                 self.hit_time = time;
2846                 }
2847                 else
2848                 {
2849                         if(self.typehitsound)
2850                                 self.typehit_time = time;
2851                         else if(self.hitsound)
2852                                 self.hit_time = time;
2853                 }
2854         }
2855         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2856         // add 1 frametime because after this, engine SV_Physics
2857         // increases time by a frametime and then networks the frame
2858         // add another frametime because client shows everything with
2859         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2860         // needed!
2861         FOR_EACH_CLIENT(self)
2862         {
2863                 self.hitsound = FALSE;
2864                 self.typehitsound = FALSE;
2865                 antilag_record(self, altime);
2866         }
2867 }
2868
2869
2870 /*
2871  * RedirectionThink:
2872  * returns TRUE if redirecting
2873  */
2874 float redirection_timeout;
2875 float redirection_nextthink;
2876 float RedirectionThink()
2877 {
2878         float clients_found;
2879
2880         if(redirection_target == "")
2881                 return FALSE;
2882
2883         if(!redirection_timeout)
2884         {
2885                 cvar_set("sv_public", "-2");
2886                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2887                 if(redirection_target == "self")
2888                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2889                 else
2890                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2891         }
2892
2893         if(time < redirection_nextthink)
2894                 return TRUE;
2895
2896         redirection_nextthink = time + 1;
2897
2898         clients_found = 0;
2899         FOR_EACH_REALCLIENT(self)
2900         {
2901                 // TODO add timer
2902                 print("Redirecting: sending connect command to ", self.netname, "\n");
2903                 if(redirection_target == "self")
2904                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2905                 else
2906                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2907                 ++clients_found;
2908         }
2909
2910         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2911
2912         if(time > redirection_timeout || clients_found == 0)
2913                 localcmd("\nwait; wait; wait; quit\n");
2914
2915         return TRUE;
2916 }
2917
2918 void TargetMusic_RestoreGame();
2919 void RestoreGame()
2920 {
2921         // Loaded from a save game
2922         // some things then break, so let's work around them...
2923
2924         // Progs DB (capture records)
2925         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2926
2927         // Mapinfo
2928         MapInfo_Shutdown();
2929         MapInfo_Enumerate();
2930         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2931         WeaponStats_Init();
2932
2933         TargetMusic_RestoreGame();
2934 }
2935
2936 void Shutdown()
2937 {
2938         entity e;
2939
2940         gameover = 2;
2941
2942         if(world_initialized > 0)
2943         {
2944                 world_initialized = 0;
2945                 print("Saving persistent data...\n");
2946                 Ban_SaveBans();
2947
2948                 PlayerStats_EndMatch(0);
2949                 FOR_EACH_CLIENT(e)
2950                         PlayerStats_AddGlobalInfo(e);
2951                 PlayerStats_Shutdown();
2952
2953                 if(!cheatcount_total)
2954                 {
2955                         if(autocvar_sv_db_saveasdump)
2956                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2957                         else
2958                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2959                 }
2960                 if(autocvar_developer)
2961                 {
2962                         if(autocvar_sv_db_saveasdump)
2963                                 db_dump(TemporaryDB, "server-temp.db");
2964                         else
2965                                 db_save(TemporaryDB, "server-temp.db");
2966                 }
2967                 CheatShutdown(); // must be after cheatcount check
2968                 db_close(ServerProgsDB);
2969                 db_close(TemporaryDB);
2970                 print("done!\n");
2971                 // tell the bot system the game is ending now
2972                 bot_endgame();
2973
2974                 WeaponStats_Shutdown();
2975                 MapInfo_Shutdown();
2976         }
2977         else if(world_initialized == 0)
2978         {
2979                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2980         }
2981 }