qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "secret.qh"
  21 #include "teamplay.qh"
  22 #include "waypointsprites.qh"
  23 #include "weapons/weaponstats.qh"
  24 #include "../common/buffs.qh"
  25 #include "../common/constants.qh"
  26 #include "../common/deathtypes.qh"
  27 #include "../common/mapinfo.qh"
  28 #include "../common/monsters/all.qh"
  29 #include "../common/monsters/sv_monsters.qh"
  30 #include "../common/notifications.qh"
  31 #include "../common/playerstats.qh"
  32 #include "../common/stats.qh"
  33 #include "../common/teams.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void ShuffleMaplist();
  97
  98 void SetDefaultAlpha()
  99 {
 100         if(autocvar_g_running_guns)
 101         {
 102                 default_player_alpha = -1;
 103                 default_weapon_alpha = +1;
 104         }
 105         else if(g_cloaked)
 106         {
 107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 108                 default_weapon_alpha = default_player_alpha;
 109         }
 110         else
 111         {
 112                 default_player_alpha = autocvar_g_player_alpha;
 113                 if(default_player_alpha == 0)
 114                         default_player_alpha = 1;
 115                 default_weapon_alpha = default_player_alpha;
 116         }
 117 }
 118
 119 void GotoFirstMap()
 120 {
 121         float n;
 122         if(autocvar__sv_init)
 123         {
 124                 // cvar_set("_sv_init", "0");
 125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 126                 // to this "init" map on a dedicated server will cause no permanent
 127                 // harm
 128                 if(autocvar_g_maplist_shuffle)
 129                         ShuffleMaplist();
 130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 132
 133                 MapInfo_Enumerate();
 134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 135
 136                 if(!DoNextMapOverride(1))
 137                         GotoNextMap(1);
 138
 139                 return;
 140         }
 141
 142         if(time < 5)
 143         {
 144                 self.nextthink = time;
 145         }
 146         else
 147         {
 148                 self.nextthink = time + 1;
 149                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 150         }
 151 }
 152
 153 void cvar_changes_init()
 154 {
 155         float h;
 156         string k, v, d;
 157         float n, i, adding, pureadding;
 158
 159         if(cvar_changes)
 160                 strunzone(cvar_changes);
 161         cvar_changes = string_null;
 162         if(cvar_purechanges)
 163                 strunzone(cvar_purechanges);
 164         cvar_purechanges = string_null;
 165         cvar_purechanges_count = 0;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         adding = true;
 172         pureadding = true;
 173
 174         for(i = 0; i < n; ++i)
 175         {
 176                 k = bufstr_get(h, i);
 177
 178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 180 #define BADCVAR(p) if(k == p) continue
 181
 182                 // general excludes and namespaces for server admin used cvars
 183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 184
 185                 // internal
 186                 BADPREFIX("csqc_");
 187                 BADPREFIX("cvar_check_");
 188                 BADCVAR("gamecfg");
 189                 BADCVAR("g_configversion");
 190                 BADCVAR("g_maplist_index");
 191                 BADCVAR("halflifebsp");
 192                 BADCVAR("sv_mapformat_is_quake2");
 193                 BADCVAR("sv_mapformat_is_quake3");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_invasion_teams");
 277                 BADCVAR("g_keepaway");
 278                 BADCVAR("g_keyhunt");
 279                 BADCVAR("g_keyhunt_teams");
 280                 BADCVAR("g_lms");
 281                 BADCVAR("g_nexball");
 282                 BADCVAR("g_onslaught");
 283                 BADCVAR("g_race");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_tdm");
 286                 BADCVAR("g_tdm_teams");
 287                 BADCVAR("leadlimit");
 288                 BADCVAR("nextmap");
 289                 BADCVAR("teamplay");
 290                 BADCVAR("timelimit");
 291
 292                 // long
 293                 BADCVAR("hostname");
 294                 BADCVAR("g_maplist");
 295                 BADCVAR("g_maplist_mostrecent");
 296                 BADCVAR("sv_motd");
 297
 298                 v = cvar_string(k);
 299                 d = cvar_defstring(k);
 300                 if(v == d)
 301                         continue;
 302
 303                 if(adding)
 304                 {
 305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 306                         if(strlen(cvar_changes) > 16384)
 307                         {
 308                                 cvar_changes = "// too many settings have been changed to show them here\n";
 309                                 adding = 0;
 310                         }
 311                 }
 312
 313                 // now check if the changes are actually gameplay relevant
 314
 315                 // does nothing visible
 316                 BADCVAR("captureleadlimit_override");
 317                 BADCVAR("g_balance_kill_delay");
 318                 BADCVAR("g_ca_point_limit");
 319                 BADCVAR("g_ca_point_leadlimit");
 320                 BADCVAR("g_ctf_captimerecord_always");
 321                 BADCVAR("g_ctf_flag_glowtrails");
 322                 BADCVAR("g_ctf_flag_pickup_verbosename");
 323                 BADCVAR("g_domination_point_leadlimit");
 324                 BADCVAR("g_forced_respawn");
 325                 BADCVAR("g_freezetag_point_limit");
 326                 BADCVAR("g_freezetag_point_leadlimit");
 327                 BADCVAR("g_keyhunt_point_leadlimit");
 328                 BADPREFIX("g_mod_");
 329                 BADCVAR("g_invasion_point_limit");
 330                 BADCVAR("g_nexball_goalleadlimit");
 331                 BADCVAR("g_tdm_point_limit");
 332                 BADCVAR("g_tdm_point_leadlimit");
 333                 BADCVAR("leadlimit_and_fraglimit");
 334                 BADCVAR("leadlimit_override");
 335                 BADCVAR("pausable");
 336                 BADCVAR("sv_allow_fullbright");
 337                 BADCVAR("sv_checkforpacketsduringsleep");
 338                 BADCVAR("sv_fraginfo");
 339                 BADCVAR("sv_timeout");
 340                 BADPREFIX("sv_timeout_");
 341                 BADPREFIX("crypto_");
 342                 BADPREFIX("g_chat_");
 343                 BADPREFIX("g_ctf_captimerecord_");
 344                 BADPREFIX("g_maplist_votable_");
 345                 BADPREFIX("net_");
 346                 BADPREFIX("prvm_");
 347                 BADPREFIX("skill_");
 348                 BADPREFIX("sv_cullentities_");
 349                 BADPREFIX("sv_fraginfo_");
 350                 BADPREFIX("sv_maxidle_");
 351                 BADPREFIX("sv_vote_");
 352                 BADPREFIX("timelimit_");
 353                 BADCVAR("gameversion");
 354                 BADPREFIX("gameversion_");
 355                 BADCVAR("sv_namechangetimer");
 356
 357                 // allowed changes to server admins (please sync this to server.cfg)
 358                 // vi commands:
 359                 //   :/"impure"/,$d
 360                 //   :g!,^\/\/[^ /],d
 361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 362                 //   :%!sort
 363                 // yes, this does contain some redundant stuff, don't really care
 364                 BADCVAR("bot_config_file");
 365                 BADCVAR("bot_number");
 366                 BADCVAR("bot_prefix");
 367                 BADCVAR("bot_suffix");
 368                 BADCVAR("capturelimit_override");
 369                 BADCVAR("fraglimit_override");
 370                 BADCVAR("gametype");
 371                 BADCVAR("g_antilag");
 372                 BADCVAR("g_balance_teams");
 373                 BADCVAR("g_balance_teams_prevent_imbalance");
 374                 BADCVAR("g_balance_teams_scorefactor");
 375                 BADCVAR("g_ban_sync_trusted_servers");
 376                 BADCVAR("g_ban_sync_uri");
 377                 BADCVAR("g_ca_teams_override");
 378                 BADCVAR("g_ctf_ignore_frags");
 379                 BADCVAR("g_domination_point_limit");
 380                 BADCVAR("g_domination_teams_override");
 381                 BADCVAR("g_freezetag_teams_override");
 382                 BADCVAR("g_friendlyfire");
 383                 BADCVAR("g_fullbrightitems");
 384                 BADCVAR("g_fullbrightplayers");
 385                 BADCVAR("g_keyhunt_point_limit");
 386                 BADCVAR("g_keyhunt_teams_override");
 387                 BADCVAR("g_lms_lives_override");
 388                 BADCVAR("g_maplist");
 389                 BADCVAR("g_maplist_check_waypoints");
 390                 BADCVAR("g_maplist_mostrecent_count");
 391                 BADCVAR("g_maplist_shuffle");
 392                 BADCVAR("g_maplist_votable");
 393                 BADCVAR("g_maplist_votable_abstain");
 394                 BADCVAR("g_maplist_votable_nodetail");
 395                 BADCVAR("g_maplist_votable_suggestions");
 396                 BADCVAR("g_maxplayers");
 397                 BADCVAR("g_mirrordamage");
 398                 BADCVAR("g_nexball_goallimit");
 399                 BADCVAR("g_powerups");
 400                 BADCVAR("g_start_delay");
 401                 BADCVAR("g_tdm_teams_override");
 402                 BADCVAR("g_warmup");
 403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 404                 BADCVAR("hostname");
 405                 BADCVAR("log_file");
 406                 BADCVAR("maxplayers");
 407                 BADCVAR("minplayers");
 408                 BADCVAR("net_address");
 409                 BADCVAR("port");
 410                 BADCVAR("rcon_password");
 411                 BADCVAR("rcon_restricted_commands");
 412                 BADCVAR("rcon_restricted_password");
 413                 BADCVAR("skill");
 414                 BADCVAR("sv_adminnick");
 415                 BADCVAR("sv_autoscreenshot");
 416                 BADCVAR("sv_autotaunt");
 417                 BADCVAR("sv_curl_defaulturl");
 418                 BADCVAR("sv_defaultcharacter");
 419                 BADCVAR("sv_defaultplayercolors");
 420                 BADCVAR("sv_defaultplayermodel");
 421                 BADCVAR("sv_defaultplayerskin");
 422                 BADCVAR("sv_maxidle");
 423                 BADCVAR("sv_maxrate");
 424                 BADCVAR("sv_motd");
 425                 BADCVAR("sv_public");
 426                 BADCVAR("sv_ready_restart");
 427                 BADCVAR("sv_status_privacy");
 428                 BADCVAR("sv_taunt");
 429                 BADCVAR("sv_vote_call");
 430                 BADCVAR("sv_vote_commands");
 431                 BADCVAR("sv_vote_majority_factor");
 432                 BADCVAR("sv_vote_master");
 433                 BADCVAR("sv_vote_master_commands");
 434                 BADCVAR("sv_vote_master_password");
 435                 BADCVAR("sv_vote_simple_majority_factor");
 436                 BADCVAR("teamplay_mode");
 437                 BADCVAR("timelimit_override");
 438                 BADCVAR("g_spawnshieldtime");
 439                 BADPREFIX("g_warmup_");
 440                 BADPREFIX("sv_ready_restart_");
 441
 442                 // mutators that announce themselves properly to the server browser
 443                 BADCVAR("g_instagib");
 444                 BADCVAR("g_new_toys");
 445                 BADCVAR("g_nix");
 446                 BADCVAR("g_grappling_hook");
 447                 BADCVAR("g_jetpack");
 448
 449 #undef BADPREFIX
 450 #undef BADCVAR
 451
 452                 if(pureadding)
 453                 {
 454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 455                         if(strlen(cvar_purechanges) > 16384)
 456                         {
 457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 458                                 pureadding = 0;
 459                         }
 460                 }
 461                 ++cvar_purechanges_count;
 462                 // WARNING: this variable is used for the server list
 463                 // NEVER dare to skip this code!
 464                 // Hacks to intentionally appearing as "pure server" even though you DO have
 465                 // modified settings may be punished by removal from the server list.
 466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 467                 // though.
 468         }
 469         buf_del(h);
 470         if(cvar_changes == "")
 471                 cvar_changes = "// this server runs at default server settings\n";
 472         else
 473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 474         cvar_changes = strzone(cvar_changes);
 475         if(cvar_purechanges == "")
 476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 477         else
 478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 479         cvar_purechanges = strzone(cvar_purechanges);
 480 }
 481
 482 void detect_maptype()
 483 {
 484 #if 0
 485         vector o, v;
 486         float i;
 487
 488         for (;;)
 489         {
 490                 o = world.mins;
 491                 o.x += random() * (world.maxs.x - world.mins.x);
 492                 o.y += random() * (world.maxs.y - world.mins.y);
 493                 o.z += random() * (world.maxs.z - world.mins.z);
 494
 495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 496                 if(trace_fraction == 1)
 497                         continue;
 498
 499                 v = trace_endpos;
 500
 501                 for(i = 0; i < 64; i += 4)
 502                 {
 503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 504         if(trace_fraction == 1)
 505                 continue;
 506                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 507                 }
 508
 509                 break;
 510         }
 511 #endif
 512 }
 513
 514 entity randomseed;
 515 float RandomSeed_Send(entity to, int sf)
 516 {
 517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 518         WriteShort(MSG_ENTITY, self.cnt);
 519         return true;
 520 }
 521 void RandomSeed_Think()
 522 {
 523         self.cnt = bound(0, floor(random() * 65536), 65535);
 524         self.nextthink = time + 5;
 525
 526         self.SendFlags |= 1;
 527 }
 528 void RandomSeed_Spawn()
 529 {
 530         randomseed = spawn();
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 533
 534         entity oldself;
 535         oldself = self;
 536         self = randomseed;
 537         self.think(); // sets random seed and nextthink
 538         self = oldself;
 539 }
 540
 541 void spawnfunc___init_dedicated_server(void)
 542 {
 543         // handler for _init/_init map (only for dedicated server initialization)
 544
 545         world_initialized = -1; // don't complain
 546         cvar = cvar_normal;
 547         cvar_string = cvar_string_normal;
 548         cvar_set = cvar_set_normal;
 549
 550         remove = remove_unsafely;
 551
 552         entity e;
 553         e = spawn();
 554         e.think = GotoFirstMap;
 555         e.nextthink = time; // this is usually 1 at this point
 556
 557         e = spawn();
 558         e.classname = "info_player_deathmatch"; // safeguard against player joining
 559
 560         self.classname = "worldspawn"; // safeguard against various stuff ;)
 561
 562         // needs to be done so early because of the constants they create
 563         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 564         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 565         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 566         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 567         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 568         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 569         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 570
 571         MapInfo_Enumerate();
 572         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 573 }
 574
 575 void Map_MarkAsRecent(string m);
 576 float world_already_spawned;
 577 void Nagger_Init();
 578 void ClientInit_Spawn();
 579 void WeaponStats_Init();
 580 void WeaponStats_Shutdown();
 581 void spawnfunc_worldspawn (void)
 582 {
 583         float fd, l, j, n;
 584         string s;
 585
 586         cvar = cvar_normal;
 587         cvar_string = cvar_string_normal;
 588         cvar_set = cvar_set_normal;
 589
 590         if(world_already_spawned)
 591                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 592         world_already_spawned = true;
 593
 594         remove = remove_safely; // during spawning, watch what you remove!
 595
 596         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 597
 598         compressShortVector_init();
 599
 600         entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 610
 611         // needs to be done so early because of the constants they create
 612         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 613         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 614         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 615         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 616         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 617         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 618         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 619
 620         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 621
 622         TemporaryDB = db_create();
 623
 624         // 0 normal
 625         lightstyle(0, "m");
 626
 627         // 1 FLICKER (first variety)
 628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 629
 630         // 2 SLOW STRONG PULSE
 631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 632
 633         // 3 CANDLE (first variety)
 634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 635
 636         // 4 FAST STROBE
 637         lightstyle(4, "mamamamamama");
 638
 639         // 5 GENTLE PULSE 1
 640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 641
 642         // 6 FLICKER (second variety)
 643         lightstyle(6, "nmonqnmomnmomomno");
 644
 645         // 7 CANDLE (second variety)
 646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 647
 648         // 8 CANDLE (third variety)
 649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 650
 651         // 9 SLOW STROBE (fourth variety)
 652         lightstyle(9, "aaaaaaaazzzzzzzz");
 653
 654         // 10 FLUORESCENT FLICKER
 655         lightstyle(10, "mmamammmmammamamaaamammma");
 656
 657         // 11 SLOW PULSE NOT FADE TO BLACK
 658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 659
 660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 661
 662         // 63 testing
 663         lightstyle(63, "a");
 664
 665         if(autocvar_g_campaign)
 666                 CampaignPreInit();
 667
 668         Map_MarkAsRecent(mapname);
 669
 670         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 671
 672         precache_model ("null"); // we need this one before InitGameplayMode
 673         InitGameplayMode();
 674         readlevelcvars();
 675         GrappleHookInit();
 676
 677         player_count = 0;
 678         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 679         if(bot_waypoints_for_items == 1)
 680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 681                         bot_waypoints_for_items = 0;
 682
 683         precache();
 684
 685         WaypointSprite_Init();
 686
 687         GameLogInit(); // prepare everything
 688         // NOTE for matchid:
 689         // changing the logic generating it is okay. But:
 690         // it HAS to stay <= 64 chars
 691         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 692         if(autocvar_sv_eventlog)
 693         {
 694                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 695                 matchid = strzone(s);
 696
 697                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 698                 s = ":gameinfo:mutators:LIST";
 699
 700                 ret_string = s;
 701                 MUTATOR_CALLHOOK(BuildMutatorsString);
 702                 s = ret_string;
 703
 704                 // simple, probably not good in the mutator system
 705                 if(autocvar_g_grappling_hook)
 706                         s = strcat(s, ":grappling_hook");
 707
 708                 // initialiation stuff, not good in the mutator system
 709                 if(!autocvar_g_use_ammunition)
 710                         s = strcat(s, ":no_use_ammunition");
 711
 712                 // initialiation stuff, not good in the mutator system
 713                 if(autocvar_g_pickup_items == 0)
 714                         s = strcat(s, ":no_pickup_items");
 715                 if(autocvar_g_pickup_items > 0)
 716                         s = strcat(s, ":pickup_items");
 717
 718                 // initialiation stuff, not good in the mutator system
 719                 if(autocvar_g_weaponarena != "0")
 720                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_norecoil)
 724                         s = strcat(s, ":norecoil");
 725
 726                 // TODO to mutator system
 727                 if(autocvar_g_powerups == 0)
 728                         s = strcat(s, ":no_powerups");
 729                 if(autocvar_g_powerups > 0)
 730                         s = strcat(s, ":powerups");
 731
 732                 GameLogEcho(s);
 733                 GameLogEcho(":gameinfo:end");
 734         }
 735         else
 736                 matchid = strzone(ftos(random()));
 737
 738         cvar_set("nextmap", "");
 739
 740         SetDefaultAlpha();
 741
 742         if(autocvar_g_campaign)
 743                 CampaignPostInit();
 744
 745         Ban_LoadBans();
 746
 747         MapInfo_Enumerate();
 748         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 749
 750         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 751         {
 752                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 753                 if(fd != -1)
 754                 {
 755                         while((s = fgets(fd)))
 756                         {
 757                                 l = tokenize_console(s);
 758                                 if(l < 2)
 759                                         continue;
 760                                 if(argv(0) == "cd")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  cdtrack ", argv(2), "\n");
 764                                 }
 765                                 else if(argv(0) == "fog")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 768                                         print("  \"fog\" \"", s, "\"\n");
 769                                 }
 770                                 else if(argv(0) == "set")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 774                                 }
 775                                 else if(argv(0) != "//")
 776                                 {
 777                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 778                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 779                                 }
 780                         }
 781                         fclose(fd);
 782                 }
 783         }
 784
 785         WeaponStats_Init();
 786
 787         WepSet_AddStat();
 788         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 789         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 790         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 791         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 792         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 793         Nagger_Init();
 794
 795         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 796         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 797         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 798         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 799         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 800         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 801         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 802         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 803         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 804         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 807         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 808         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 809         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 810
 811         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 812         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 813
 814         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 815
 816         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 817
 818         // freeze attacks
 819         addstat(STAT_FROZEN, AS_INT, frozen);
 820         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 821
 822         // g_movementspeed hack
 823         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 824         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 825         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 826         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 827
 828         // new properties
 829         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 830         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 831         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 832         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 833         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 834         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 835         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 836         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 837         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 838         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 839         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 840         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 841         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 842         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 843         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 844         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 845         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 846         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 847         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 848
 849         // secrets
 850         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 851         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 852
 853         // monsters
 854         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 855         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 856
 857         // misc
 858         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 859
 860         next_pingtime = time + 5;
 861
 862         detect_maptype();
 863
 864         // set up information replies for clients and server to use
 865         maplist_reply = strzone(getmaplist());
 866         lsmaps_reply = strzone(getlsmaps());
 867         monsterlist_reply = strzone(getmonsterlist());
 868         for(int i = 0; i < 10; ++i)
 869         {
 870                 s = getrecords(i);
 871                 if (s)
 872                         records_reply[i] = strzone(s);
 873         }
 874         ladder_reply = strzone(getladder());
 875         rankings_reply = strzone(getrankings());
 876
 877         // begin other init
 878         ClientInit_Spawn();
 879         RandomSeed_Spawn();
 880         PingPLReport_Spawn();
 881
 882         CheatInit();
 883
 884         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 885
 886         // fill sv_curl_serverpackages from .serverpackage files
 887         if(autocvar_sv_curl_serverpackages_auto)
 888         {
 889                 s = "";
 890                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 891                 for(int i = 0; i < n; ++i)
 892                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 893                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 894                                 s = strcat(s, " ", argv(i));
 895                 fd = search_begin("*-serverpackage.txt", true, false);
 896                 if(fd >= 0)
 897                 {
 898                         j = search_getsize(fd);
 899                         for(int i = 0; i < j; ++i)
 900                                 s = strcat(s, " ", search_getfilename(fd, i));
 901                         search_end(fd);
 902                 }
 903                 fd = search_begin("*.serverpackage", true, false);
 904                 if(fd >= 0)
 905                 {
 906                         j = search_getsize(fd);
 907                         for(int i = 0; i < j; ++i)
 908                                 s = strcat(s, " ", search_getfilename(fd, i));
 909                         search_end(fd);
 910                 }
 911                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 912         }
 913
 914         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 915         modname = "Xonotic";
 916         // physics/balance/config changes that count as mod
 917         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 918                 modname = cvar_string("g_mod_physics");
 919         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 920                 modname = cvar_string("g_mod_balance");
 921         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 922                 modname = cvar_string("g_mod_config");
 923         // extra mutators that deserve to count as mod
 924         MUTATOR_CALLHOOK(SetModname);
 925
 926         // save it for later
 927         modname = strzone(modname);
 928
 929         WinningConditionHelper(); // set worldstatus
 930
 931         world_initialized = 1;
 932 }
 933
 934 void spawnfunc_light (void)
 935 {
 936         //makestatic (self); // Who the f___ did that?
 937         remove(self);
 938 }
 939
 940 string GetGametype()
 941 {
 942         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 943 }
 944
 945 string GetMapname()
 946 {
 947         return mapname;
 948 }
 949
 950 float Map_Count, Map_Current;
 951 string Map_Current_Name;
 952
 953 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 954 float GetMaplistPosition()
 955 {
 956         float pos, idx;
 957         string map;
 958
 959         map = GetMapname();
 960         idx = autocvar_g_maplist_index;
 961
 962         if(idx >= 0)
 963                 if(idx < Map_Count)
 964                         if(map == argv(idx))
 965                                 return idx;
 966
 967         for(pos = 0; pos < Map_Count; ++pos)
 968                 if(map == argv(pos))
 969                         return pos;
 970
 971         // resume normal maplist rotation if current map is not in g_maplist
 972         return idx;
 973 }
 974
 975 float MapHasRightSize(string map)
 976 {
 977         float fh;
 978         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 979         if(autocvar_g_maplist_check_waypoints)
 980         {
 981                 dprint("checkwp "); dprint(map);
 982                 if(!fexists(strcat("maps/", map, ".waypoints")))
 983                 {
 984                         dprint(": no waypoints\n");
 985                         return false;
 986                 }
 987                 dprint(": has waypoints\n");
 988         }
 989
 990         // open map size restriction file
 991         dprint("opensize "); dprint(map);
 992         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 993         if(fh >= 0)
 994         {
 995                 float mapmin, mapmax;
 996                 dprint(": ok, ");
 997                 mapmin = stof(fgets(fh));
 998                 mapmax = stof(fgets(fh));
 999                 fclose(fh);
1000                 if(player_count < mapmin)
1001                 {
1002                         dprint("not enough\n");
1003                         return false;
1004                 }
1005                 if(player_count > mapmax)
1006                 {
1007                         dprint("too many\n");
1008                         return false;
1009                 }
1010                 dprint("right size\n");
1011                 return true;
1012         }
1013         dprint(": not found\n");
1014         return true;
1015 }
1016
1017 string Map_Filename(float position)
1018 {
1019         return strcat("maps/", argv(position), ".bsp");
1020 }
1021
1022 string strwords(string s, float w)
1023 {
1024         float endpos;
1025         for(endpos = 0; w && endpos >= 0; --w)
1026                 endpos = strstrofs(s, " ", endpos + 1);
1027         if(endpos < 0)
1028                 return s;
1029         else
1030                 return substring(s, 0, endpos);
1031 }
1032
1033 float strhasword(string s, string w)
1034 {
1035         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1036 }
1037
1038 void Map_MarkAsRecent(string m)
1039 {
1040         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1041 }
1042
1043 float Map_IsRecent(string m)
1044 {
1045         return strhasword(autocvar_g_maplist_mostrecent, m);
1046 }
1047
1048 float Map_Check(float position, float pass)
1049 {
1050         string filename;
1051         string map_next;
1052         map_next = argv(position);
1053         if(pass <= 1)
1054         {
1055                 if(Map_IsRecent(map_next))
1056                         return 0;
1057         }
1058         filename = Map_Filename(position);
1059         if(MapInfo_CheckMap(map_next))
1060         {
1061                 if(pass == 2)
1062                         return 1;
1063                 if(MapHasRightSize(map_next))
1064                         return 1;
1065                 return 0;
1066         }
1067         else
1068                 dprint( "Couldn't select '", filename, "'..\n" );
1069
1070         return 0;
1071 }
1072
1073 void Map_Goto_SetStr(string nextmapname)
1074 {
1075         if(getmapname_stored != "")
1076                 strunzone(getmapname_stored);
1077         if(nextmapname == "")
1078                 getmapname_stored = "";
1079         else
1080                 getmapname_stored = strzone(nextmapname);
1081 }
1082
1083 void Map_Goto_SetFloat(float position)
1084 {
1085         cvar_set("g_maplist_index", ftos(position));
1086         Map_Goto_SetStr(argv(position));
1087 }
1088
1089 void Map_Goto(float reinit)
1090 {
1091         MapInfo_LoadMap(getmapname_stored, reinit);
1092 }
1093
1094 // return codes of map selectors:
1095 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1096 //   -2 = permanent failure
1097 float() MaplistMethod_Iterate = // usual method
1098 {
1099         float pass, i;
1100
1101         dprint("Trying MaplistMethod_Iterate\n");
1102
1103         for(pass = 1; pass <= 2; ++pass)
1104         {
1105                 for(i = 1; i < Map_Count; ++i)
1106                 {
1107                         float mapindex;
1108                         mapindex = (i + Map_Current) % Map_Count;
1109                         if(Map_Check(mapindex, pass))
1110                                 return mapindex;
1111                 }
1112         }
1113         return -1;
1114 }
1115
1116 float() MaplistMethod_Repeat = // fallback method
1117 {
1118         dprint("Trying MaplistMethod_Repeat\n");
1119
1120         if(Map_Check(Map_Current, 2))
1121                 return Map_Current;
1122         return -2;
1123 }
1124
1125 float() MaplistMethod_Random = // random map selection
1126 {
1127         float i, imax;
1128
1129         dprint("Trying MaplistMethod_Random\n");
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 float mapindex;
1136                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1137                 if(Map_Check(mapindex, 1))
1138                         return mapindex;
1139         }
1140         return -1;
1141 }
1142
1143 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1144 // the exponent sets a bias on the map selection:
1145 // the higher the exponent, the less likely "shortly repeated" same maps are
1146 {
1147         float i, j, imax, insertpos;
1148
1149         dprint("Trying MaplistMethod_Shuffle\n");
1150
1151         imax = 42;
1152
1153         for(i = 0; i <= imax; ++i)
1154         {
1155                 string newlist;
1156
1157                 // now reinsert this at another position
1158                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1159                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1160                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1161                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1162
1163                 // insert the current map there
1164                 newlist = "";
1165                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1166                         newlist = strcat(newlist, " ", argv(j));
1167                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1168                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1169                         newlist = strcat(newlist, " ", argv(j));
1170                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1171                 cvar_set("g_maplist", newlist);
1172                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1173
1174                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1175                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1176                 if(Map_Check(Map_Current, 1))
1177                         return Map_Current;
1178         }
1179         return -1;
1180 }
1181
1182 void Maplist_Init()
1183 {
1184         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1185         float i;
1186         for (i = 0; i < Map_Count; ++i)
1187                 if (Map_Check(i, 2))
1188                         break;
1189         if (i == Map_Count)
1190         {
1191                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1192                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1193                 if(autocvar_g_maplist_shuffle)
1194                         ShuffleMaplist();
1195                 localcmd("\nmenu_cmd sync\n");
1196                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1197         }
1198         if(Map_Count == 0)
1199                 error("empty maplist, cannot select a new map");
1200         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1201
1202         if(Map_Current_Name)
1203                 strunzone(Map_Current_Name);
1204         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1205         // this may or may not be correct, but who cares, in the worst case a map
1206         // isn't chosen in the first pass that should have been
1207 }
1208
1209 string GetNextMap()
1210 {
1211         float nextMap;
1212
1213         Maplist_Init();
1214         nextMap = -1;
1215
1216         if(nextMap == -1)
1217                 if(autocvar_g_maplist_shuffle > 0)
1218                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_selectrandom)
1222                         nextMap = MaplistMethod_Random();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Iterate();
1226
1227         if(nextMap == -1)
1228                 nextMap = MaplistMethod_Repeat();
1229
1230         if(nextMap >= 0)
1231         {
1232                 Map_Goto_SetFloat(nextMap);
1233                 return getmapname_stored;
1234         }
1235
1236         return "";
1237 }
1238
1239 float DoNextMapOverride(float reinit)
1240 {
1241         if(autocvar_g_campaign)
1242         {
1243                 CampaignPostIntermission();
1244                 alreadychangedlevel = true;
1245                 return true;
1246         }
1247         if(autocvar_quit_when_empty)
1248         {
1249                 if(player_count <= currentbots)
1250                 {
1251                         localcmd("quit\n");
1252                         alreadychangedlevel = true;
1253                         return true;
1254                 }
1255         }
1256         if(autocvar_quit_and_redirect != "")
1257         {
1258                 redirection_target = strzone(autocvar_quit_and_redirect);
1259                 alreadychangedlevel = true;
1260                 return true;
1261         }
1262         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1263         {
1264                 localcmd("restart\n");
1265                 alreadychangedlevel = true;
1266                 return true;
1267         }
1268         if(autocvar_nextmap != "")
1269         {
1270                 string m;
1271                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1272                 cvar_set("nextmap",m);
1273
1274                 if(!m || gametypevote)
1275                         return false;
1276                 if(autocvar_sv_vote_gametype)
1277                 {
1278                         Map_Goto_SetStr(m);
1279                         return false;
1280                 }
1281
1282                 if(MapInfo_CheckMap(m))
1283                 {
1284                         Map_Goto_SetStr(m);
1285                         Map_Goto(reinit);
1286                         alreadychangedlevel = true;
1287                         return true;
1288                 }
1289         }
1290         if(!reinit && autocvar_lastlevel)
1291         {
1292                 cvar_settemp_restore();
1293                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1294                 alreadychangedlevel = true;
1295                 return true;
1296         }
1297         return false;
1298 }
1299
1300 void GotoNextMap(float reinit)
1301 {
1302         //string nextmap;
1303         //float n, nummaps;
1304         //string s;
1305         if (alreadychangedlevel)
1306                 return;
1307         alreadychangedlevel = true;
1308
1309         string nextMap;
1310
1311         nextMap = GetNextMap();
1312         if(nextMap == "")
1313                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1314         Map_Goto(reinit);
1315 }
1316
1317
1318 /*
1319 ============
1320 IntermissionThink
1321
1322 When the player presses attack or jump, change to the next level
1323 ============
1324 */
1325 .float autoscreenshot;
1326 void IntermissionThink()
1327 {
1328         FixIntermissionClient(self);
1329
1330         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1331         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1332
1333         if( (server_screenshot || client_screenshot)
1334                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1335         {
1336                 self.autoscreenshot = -1;
1337                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1338                 return;
1339         }
1340
1341         if (time < intermission_exittime)
1342                 return;
1343
1344         if(!mapvote_initialized)
1345                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1346                         return;
1347
1348         MapVote_Start();
1349 }
1350
1351 /*
1352 ============
1353 FindIntermission
1354
1355 Returns the entity to view from
1356 ============
1357 */
1358 /*
1359 entity FindIntermission()
1360 {
1361         local   entity spot;
1362         local   float cyc;
1363
1364 // look for info_intermission first
1365         spot = find (world, classname, "info_intermission");
1366         if (spot)
1367         {       // pick a random one
1368                 cyc = random() * 4;
1369                 while (cyc > 1)
1370                 {
1371                         spot = find (spot, classname, "info_intermission");
1372                         if (!spot)
1373                                 spot = find (spot, classname, "info_intermission");
1374                         cyc = cyc - 1;
1375                 }
1376                 return spot;
1377         }
1378
1379 // then look for the start position
1380         spot = find (world, classname, "info_player_start");
1381         if (spot)
1382                 return spot;
1383
1384 // testinfo_player_start is only found in regioned levels
1385         spot = find (world, classname, "testplayerstart");
1386         if (spot)
1387                 return spot;
1388
1389 // then look for the start position
1390         spot = find (world, classname, "info_player_deathmatch");
1391         if (spot)
1392                 return spot;
1393
1394         //objerror ("FindIntermission: no spot");
1395         return world;
1396 }
1397 */
1398
1399 /*
1400 ===============================================================================
1401
1402 RULES
1403
1404 ===============================================================================
1405 */
1406
1407 void DumpStats(float final)
1408 {
1409         float file;
1410         string s;
1411         float to_console;
1412         float to_eventlog;
1413         float to_file;
1414         float i;
1415
1416         to_console = autocvar_sv_logscores_console;
1417         to_eventlog = autocvar_sv_eventlog;
1418         to_file = autocvar_sv_logscores_file;
1419
1420         if(!final)
1421         {
1422                 to_console = true; // always print printstats replies
1423                 to_eventlog = false; // but never print them to the event log
1424         }
1425
1426         if(to_eventlog)
1427                 if(autocvar_sv_eventlog_console)
1428                         to_console = false; // otherwise we get the output twice
1429
1430         if(final)
1431                 s = ":scores:";
1432         else
1433                 s = ":status:";
1434         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1435
1436         if(to_console)
1437                 print(s, "\n");
1438         if(to_eventlog)
1439                 GameLogEcho(s);
1440
1441         file = -1;
1442         if(to_file)
1443         {
1444                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1445                 if(file == -1)
1446                         to_file = false;
1447                 else
1448                         fputs(file, strcat(s, "\n"));
1449         }
1450
1451         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1452         if(to_console)
1453                 print(s, "\n");
1454         if(to_eventlog)
1455                 GameLogEcho(s);
1456         if(to_file)
1457                 fputs(file, strcat(s, "\n"));
1458
1459         FOR_EACH_CLIENT(other)
1460         {
1461                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1462                 {
1463                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1464                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1465                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1466                                 s = strcat(s, ftos(other.team), ":");
1467                         else
1468                                 s = strcat(s, "spectator:");
1469
1470                         if(to_console)
1471                                 print(s, other.netname, "\n");
1472                         if(to_eventlog)
1473                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1474                         if(to_file)
1475                                 fputs(file, strcat(s, other.netname, "\n"));
1476                 }
1477         }
1478
1479         if(teamplay)
1480         {
1481                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1482                 if(to_console)
1483                         print(s, "\n");
1484                 if(to_eventlog)
1485                         GameLogEcho(s);
1486                 if(to_file)
1487                         fputs(file, strcat(s, "\n"));
1488
1489                 for(i = 1; i < 16; ++i)
1490                 {
1491                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1492                         s = strcat(s, ":", ftos(i));
1493                         if(to_console)
1494                                 print(s, "\n");
1495                         if(to_eventlog)
1496                                 GameLogEcho(s);
1497                         if(to_file)
1498                                 fputs(file, strcat(s, "\n"));
1499                 }
1500         }
1501
1502         if(to_console)
1503                 print(":end\n");
1504         if(to_eventlog)
1505                 GameLogEcho(":end");
1506         if(to_file)
1507         {
1508                 fputs(file, ":end\n");
1509                 fclose(file);
1510         }
1511 }
1512
1513 void FixIntermissionClient(entity e)
1514 {
1515         string s;
1516         if(!e.autoscreenshot) // initial call
1517         {
1518                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1519                 e.health = -2342;
1520                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1521                 e.solid = SOLID_NOT;
1522                 e.movetype = MOVETYPE_NONE;
1523                 e.takedamage = DAMAGE_NO;
1524                 if(e.weaponentity)
1525                 {
1526                         e.weaponentity.effects = EF_NODRAW;
1527                         if (e.weaponentity.weaponentity)
1528                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1529                 }
1530                 if(IS_REAL_CLIENT(e))
1531                 {
1532                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1533                         s = autocvar_sv_intermission_cdtrack;
1534                         if(s != "")
1535                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1536                         msg_entity = e;
1537                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1538                 }
1539         }
1540 }
1541
1542 /*
1543 go to the next level for deathmatch
1544 only called if a time or frag limit has expired
1545 */
1546 void NextLevel()
1547 {
1548         gameover = true;
1549
1550         intermission_running = 1;
1551
1552 // enforce a wait time before allowing changelevel
1553         if(player_count > 0)
1554                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1555         else
1556                 intermission_exittime = -1;
1557
1558         /*
1559         WriteByte (MSG_ALL, SVC_CDTRACK);
1560         WriteByte (MSG_ALL, 3);
1561         WriteByte (MSG_ALL, 3);
1562         // done in FixIntermission
1563         */
1564
1565         //pos = FindIntermission ();
1566
1567         VoteReset();
1568
1569         DumpStats(true);
1570
1571         // send statistics
1572         PlayerStats_GameReport(true);
1573         WeaponStats_Shutdown();
1574
1575         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1576
1577         if(autocvar_sv_eventlog)
1578                 GameLogEcho(":gameover");
1579
1580         GameLogClose();
1581
1582         FOR_EACH_PLAYER(other) {
1583                 FixIntermissionClient(other);
1584                 if(other.winning)
1585                         bprint(other.netname, " ^7wins.\n");
1586         }
1587
1588         if(autocvar_g_campaign)
1589                 CampaignPreIntermission();
1590
1591         MUTATOR_CALLHOOK(MatchEnd);
1592
1593         localcmd("\nsv_hook_gameend\n");
1594 }
1595
1596 /*
1597 ============
1598 CheckRules_Player
1599
1600 Exit deathmatch games upon conditions
1601 ============
1602 */
1603 void CheckRules_Player()
1604 {
1605         if (gameover)   // someone else quit the game already
1606                 return;
1607
1608         if(self.deadflag == DEAD_NO)
1609                 self.play_time += frametime;
1610
1611         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1612         //   (div0: and that in CheckRules_World please)
1613 }
1614
1615
1616 float InitiateSuddenDeath()
1617 {
1618         // Check first whether normal overtimes could be added before initiating suddendeath mode
1619         // - for this timelimit_overtime needs to be >0 of course
1620         // - also check the winning condition calculated in the previous frame and only add normal overtime
1621         //   again, if at the point at which timelimit would be extended again, still no winner was found
1622         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1623         {
1624                 return 1; // need to call InitiateOvertime later
1625         }
1626         else
1627         {
1628                 if(!checkrules_suddendeathend)
1629                 {
1630                         if(autocvar_g_campaign)
1631                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1632                         else
1633                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1634                         if(g_race && !g_race_qualifying)
1635                                 race_StartCompleting();
1636                 }
1637                 return 0;
1638         }
1639 }
1640
1641 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1642 {
1643         ++checkrules_overtimesadded;
1644         //add one more overtime by simply extending the timelimit
1645         float tl;
1646         tl = autocvar_timelimit;
1647         tl += autocvar_timelimit_overtime;
1648         cvar_set("timelimit", ftos(tl));
1649
1650         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1651 }
1652
1653 float GetWinningCode(float fraglimitreached, float equality)
1654 {
1655         if(autocvar_g_campaign == 1)
1656                 if(fraglimitreached)
1657                         return WINNING_YES;
1658                 else
1659                         return WINNING_NO;
1660
1661         else
1662                 if(equality)
1663                         if(fraglimitreached)
1664                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1665                         else
1666                                 return WINNING_NEVER;
1667                 else
1668                         if(fraglimitreached)
1669                                 return WINNING_YES;
1670                         else
1671                                 return WINNING_NO;
1672 }
1673
1674 // set the .winning flag for exactly those players with a given field value
1675 void SetWinners(.float field, float value)
1676 {
1677         entity head;
1678         FOR_EACH_PLAYER(head)
1679                 head.winning = (head.(field) == value);
1680 }
1681
1682 // set the .winning flag for those players with a given field value
1683 void AddWinners(.float field, float value)
1684 {
1685         entity head;
1686         FOR_EACH_PLAYER(head)
1687                 if (head.(field) == value)
1688                         head.winning = 1;
1689 }
1690
1691 // clear the .winning flags
1692 void ClearWinners(void)
1693 {
1694         entity head;
1695         FOR_EACH_PLAYER(head)
1696                 head.winning = 0;
1697 }
1698
1699 // Onslaught winning condition:
1700 // game terminates if only one team has a working generator (or none)
1701 float WinningCondition_Onslaught()
1702 {
1703         entity head;
1704         float t1, t2, t3, t4;
1705
1706         WinningConditionHelper(); // set worldstatus
1707
1708         if(warmup_stage)
1709                 return WINNING_NO;
1710
1711         // first check if the game has ended
1712         t1 = t2 = t3 = t4 = 0;
1713         head = find(world, classname, "onslaught_generator");
1714         while (head)
1715         {
1716                 if (head.health > 0)
1717                 {
1718                         if (head.team == NUM_TEAM_1) t1 = 1;
1719                         if (head.team == NUM_TEAM_2) t2 = 1;
1720                         if (head.team == NUM_TEAM_3) t3 = 1;
1721                         if (head.team == NUM_TEAM_4) t4 = 1;
1722                 }
1723                 head = find(head, classname, "onslaught_generator");
1724         }
1725         if (t1 + t2 + t3 + t4 < 2)
1726         {
1727                 // game over, only one team remains (or none)
1728                 ClearWinners();
1729                 if (t1) SetWinners(team, NUM_TEAM_1);
1730                 if (t2) SetWinners(team, NUM_TEAM_2);
1731                 if (t3) SetWinners(team, NUM_TEAM_3);
1732                 if (t4) SetWinners(team, NUM_TEAM_4);
1733                 dprint("Have a winner, ending game.\n");
1734                 return WINNING_YES;
1735         }
1736
1737         // Two or more teams remain
1738         return WINNING_NO;
1739 }
1740
1741 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1742 // they win. Otherwise the defending team wins once the timelimit passes.
1743 void assault_new_round();
1744 float WinningCondition_Assault()
1745 {
1746         float status;
1747
1748         WinningConditionHelper(); // set worldstatus
1749
1750         status = WINNING_NO;
1751         // as the timelimit has not yet passed just assume the defending team will win
1752         if(assault_attacker_team == NUM_TEAM_1)
1753         {
1754                 SetWinners(team, NUM_TEAM_2);
1755         }
1756         else
1757         {
1758                 SetWinners(team, NUM_TEAM_1);
1759         }
1760
1761         entity ent;
1762         ent = find(world, classname, "target_assault_roundend");
1763         if(ent)
1764         {
1765                 if(ent.winning) // round end has been triggered by attacking team
1766                 {
1767                         bprint("ASSAULT: round completed...\n");
1768                         SetWinners(team, assault_attacker_team);
1769
1770                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1771
1772                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1773                         {
1774                                 status = WINNING_YES;
1775                         }
1776                         else
1777                         {
1778                                 entity oldself;
1779                                 oldself = self;
1780                                 self = ent;
1781                                 assault_new_round();
1782                                 self = oldself;
1783                         }
1784                 }
1785         }
1786
1787         return status;
1788 }
1789
1790 // LMS winning condition: game terminates if and only if there's at most one
1791 // one player who's living lives. Top two scores being equal cancels the time
1792 // limit.
1793 float WinningCondition_LMS()
1794 {
1795         entity head, head2;
1796         float have_player;
1797         float have_players;
1798         float l;
1799
1800         have_player = false;
1801         have_players = false;
1802         l = LMS_NewPlayerLives();
1803
1804         head = find(world, classname, "player");
1805         if(head)
1806                 have_player = true;
1807         head2 = find(head, classname, "player");
1808         if(head2)
1809                 have_players = true;
1810
1811         if(have_player)
1812         {
1813                 // we have at least one player
1814                 if(have_players)
1815                 {
1816                         // two or more active players - continue with the game
1817                 }
1818                 else
1819                 {
1820                         // exactly one player?
1821
1822                         ClearWinners();
1823                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1824
1825                         if(l)
1826                         {
1827                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1828                                 return WINNING_NO;
1829                         }
1830                         else
1831                         {
1832                                 // a winner!
1833                                 // and assign him his first place
1834                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1835                                 return WINNING_YES;
1836                         }
1837                 }
1838         }
1839         else
1840         {
1841                 // nobody is playing at all...
1842                 if(l)
1843                 {
1844                         // wait for players...
1845                 }
1846                 else
1847                 {
1848                         // SNAFU (maybe a draw game?)
1849                         ClearWinners();
1850                         dprint("No players, ending game.\n");
1851                         return WINNING_YES;
1852                 }
1853         }
1854
1855         // When we get here, we have at least two players who are actually LIVING,
1856         // now check if the top two players have equal score.
1857         WinningConditionHelper();
1858
1859         ClearWinners();
1860         if(WinningConditionHelper_winner)
1861                 WinningConditionHelper_winner.winning = true;
1862         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1863                 return WINNING_NEVER;
1864
1865         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1866         return WINNING_NO;
1867 }
1868
1869 void ShuffleMaplist()
1870 {
1871         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1872 }
1873
1874 float leaderfrags;
1875 float WinningCondition_Scores(float limit, float leadlimit)
1876 {
1877         float limitreached;
1878
1879         // TODO make everything use THIS winning condition (except LMS)
1880         WinningConditionHelper();
1881
1882         if(teamplay)
1883         {
1884                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1885                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1886                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1887                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1888         }
1889
1890         ClearWinners();
1891         if(WinningConditionHelper_winner)
1892                 WinningConditionHelper_winner.winning = 1;
1893         if(WinningConditionHelper_winnerteam >= 0)
1894                 SetWinners(team, WinningConditionHelper_winnerteam);
1895
1896         if(WinningConditionHelper_lowerisbetter)
1897         {
1898                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1899                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1900                 limit = -limit;
1901         }
1902
1903         if(WinningConditionHelper_zeroisworst)
1904                 leadlimit = 0; // not supported in this mode
1905
1906         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1907         // these modes always score in increments of 1, thus this makes sense
1908         {
1909                 if(leaderfrags != WinningConditionHelper_topscore)
1910                 {
1911                         leaderfrags = WinningConditionHelper_topscore;
1912
1913                         if (limit)
1914                         if (leaderfrags == limit - 1)
1915                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1916                         else if (leaderfrags == limit - 2)
1917                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1918                         else if (leaderfrags == limit - 3)
1919                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1920                 }
1921         }
1922
1923         limitreached = false;
1924         if(limit)
1925                 if(WinningConditionHelper_topscore >= limit)
1926                         limitreached = true;
1927         if(leadlimit)
1928         {
1929                 float leadlimitreached;
1930                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1931                 if(autocvar_leadlimit_and_fraglimit)
1932                         limitreached = (limitreached && leadlimitreached);
1933                 else
1934                         limitreached = (limitreached || leadlimitreached);
1935         }
1936
1937         if(limit)
1938                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1939
1940         return GetWinningCode(
1941                 WinningConditionHelper_topscore && limitreached,
1942                 WinningConditionHelper_equality
1943         );
1944 }
1945
1946 float WinningCondition_Race(float fraglimit)
1947 {
1948         float wc;
1949         entity p;
1950         float n, c;
1951
1952         n = 0;
1953         c = 0;
1954         FOR_EACH_PLAYER(p)
1955         {
1956                 ++n;
1957                 if(p.race_completed)
1958                         ++c;
1959         }
1960         if(n && (n == c))
1961                 return WINNING_YES;
1962         wc = WinningCondition_Scores(fraglimit, 0);
1963
1964         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1965         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1966         // do NOT support equality when the laps are all raced!
1967                 return WINNING_STARTSUDDENDEATHOVERTIME;
1968         else
1969                 return WINNING_NEVER;
1970 }
1971
1972 float WinningCondition_QualifyingThenRace(float limit)
1973 {
1974         float wc;
1975         wc = WinningCondition_Scores(limit, 0);
1976
1977         // NEVER initiate overtime
1978         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1979         {
1980                 return WINNING_YES;
1981         }
1982
1983         return wc;
1984 }
1985
1986 float WinningCondition_RanOutOfSpawns()
1987 {
1988         entity head;
1989
1990         if(have_team_spawns <= 0)
1991                 return WINNING_NO;
1992
1993         if(!autocvar_g_spawn_useallspawns)
1994                 return WINNING_NO;
1995
1996         if(!some_spawn_has_been_used)
1997                 return WINNING_NO;
1998
1999         team1_score = team2_score = team3_score = team4_score = 0;
2000
2001         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2002         {
2003                 if(head.team == NUM_TEAM_1)
2004                         team1_score = 1;
2005                 else if(head.team == NUM_TEAM_2)
2006                         team2_score = 1;
2007                 else if(head.team == NUM_TEAM_3)
2008                         team3_score = 1;
2009                 else if(head.team == NUM_TEAM_4)
2010                         team4_score = 1;
2011         }
2012
2013         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2014         {
2015                 if(head.team == NUM_TEAM_1)
2016                         team1_score = 1;
2017                 else if(head.team == NUM_TEAM_2)
2018                         team2_score = 1;
2019                 else if(head.team == NUM_TEAM_3)
2020                         team3_score = 1;
2021                 else if(head.team == NUM_TEAM_4)
2022                         team4_score = 1;
2023         }
2024
2025         ClearWinners();
2026         if(team1_score + team2_score + team3_score + team4_score == 0)
2027         {
2028                 checkrules_equality = true;
2029                 return WINNING_YES;
2030         }
2031         else if(team1_score + team2_score + team3_score + team4_score == 1)
2032         {
2033                 float t, i;
2034                 if(team1_score)
2035                         t = NUM_TEAM_1;
2036                 else if(team2_score)
2037                         t = NUM_TEAM_2;
2038                 else if(team3_score)
2039                         t = NUM_TEAM_3;
2040                 else // if(team4_score)
2041                         t = NUM_TEAM_4;
2042                 CheckAllowedTeams(world);
2043                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2044                 {
2045                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2046                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2047                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2048                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2049                 }
2050
2051                 AddWinners(team, t);
2052                 return WINNING_YES;
2053         }
2054         else
2055                 return WINNING_NO;
2056 }
2057
2058 /*
2059 ============
2060 CheckRules_World
2061
2062 Exit deathmatch games upon conditions
2063 ============
2064 */
2065 void CheckRules_World()
2066 {
2067         float timelimit;
2068         float fraglimit;
2069         float leadlimit;
2070
2071         VoteThink();
2072         MapVote_Think();
2073
2074         SetDefaultAlpha();
2075
2076         if (gameover)   // someone else quit the game already
2077         {
2078                 if(player_count == 0) // Nobody there? Then let's go to the next map
2079                         MapVote_Start();
2080                         // this will actually check the player count in the next frame
2081                         // again, but this shouldn't hurt
2082                 return;
2083         }
2084
2085         timelimit = autocvar_timelimit * 60;
2086         fraglimit = autocvar_fraglimit;
2087         leadlimit = autocvar_leadlimit;
2088
2089         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2090         {
2091                 if(timelimit > 0)
2092                         timelimit = 0; // timelimit is not made for warmup
2093                 if(fraglimit > 0)
2094                         fraglimit = 0; // no fraglimit for now
2095                 leadlimit = 0; // no leadlimit for now
2096         }
2097
2098         if(timelimit > 0)
2099         {
2100                 timelimit += game_starttime;
2101         }
2102         else if (timelimit < 0)
2103         {
2104                 // endmatch
2105                 NextLevel();
2106                 return;
2107         }
2108
2109         if(g_onslaught)
2110                 timelimit = 0; // ONS has its own overtime rule
2111
2112         float wantovertime;
2113         wantovertime = 0;
2114
2115         if(timelimit > game_starttime)
2116                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2117         else
2118                 game_completion_ratio = 0;
2119
2120         if(checkrules_suddendeathend)
2121         {
2122                 if(!checkrules_suddendeathwarning)
2123                 {
2124                         checkrules_suddendeathwarning = true;
2125                         if(g_race && !g_race_qualifying)
2126                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2127                         else
2128                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2129                 }
2130         }
2131         else
2132         {
2133                 if (timelimit && time >= timelimit)
2134                 {
2135                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2136                         {
2137                                 float totalplayers;
2138                                 float playerswithlaps;
2139                                 float readyplayers;
2140                                 entity head;
2141                                 totalplayers = playerswithlaps = readyplayers = 0;
2142                                 FOR_EACH_PLAYER(head)
2143                                 {
2144                                         ++totalplayers;
2145                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2146                                                 ++playerswithlaps;
2147                                         if(head.ready)
2148                                                 ++readyplayers;
2149                                 }
2150
2151                                 // at least 2 of the players have completed a lap: start the RACE
2152                                 // otherwise, the players should end the qualifying on their own
2153                                 if(readyplayers || playerswithlaps >= 2)
2154                                 {
2155                                         checkrules_suddendeathend = 0;
2156                                         ReadyRestart(); // go to race
2157                                         return;
2158                                 }
2159                                 else
2160                                         wantovertime |= InitiateSuddenDeath();
2161                         }
2162                         else
2163                                 wantovertime |= InitiateSuddenDeath();
2164                 }
2165         }
2166
2167         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2168         {
2169                 NextLevel();
2170                 return;
2171         }
2172
2173         float checkrules_status;
2174         checkrules_status = WinningCondition_RanOutOfSpawns();
2175         if(checkrules_status == WINNING_YES)
2176         {
2177                 bprint("Hey! Someone ran out of spawns!\n");
2178         }
2179         else if(g_race && !g_race_qualifying && timelimit >= 0)
2180         {
2181                 checkrules_status = WinningCondition_Race(fraglimit);
2182                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2183         }
2184         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2185         {
2186                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2187                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2188         }
2189         else if(g_assault)
2190         {
2191                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2192         }
2193         else if(g_lms)
2194         {
2195                 checkrules_status = WinningCondition_LMS();
2196         }
2197         else if (g_onslaught)
2198         {
2199                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2200         }
2201         else
2202         {
2203                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2204                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2205         }
2206
2207         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2208         {
2209                 checkrules_status = WINNING_NEVER;
2210                 checkrules_overtimesadded = -1;
2211                 wantovertime |= InitiateSuddenDeath();
2212         }
2213
2214         if(checkrules_status == WINNING_NEVER)
2215                 // equality cases! Nobody wins if the overtime ends in a draw.
2216                 ClearWinners();
2217
2218         if(wantovertime)
2219         {
2220                 if(checkrules_status == WINNING_NEVER)
2221                         InitiateOvertime();
2222                 else
2223                         checkrules_status = WINNING_YES;
2224         }
2225
2226         if(checkrules_suddendeathend)
2227                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2228                         checkrules_status = WINNING_YES;
2229
2230         if(checkrules_status == WINNING_YES)
2231         {
2232                 //print("WINNING\n");
2233                 NextLevel();
2234         }
2235 }
2236
2237 string GotoMap(string m)
2238 {
2239         m = GameTypeVote_MapInfo_FixName(m);
2240         if (!m)
2241                 return "The map you suggested is not available on this server.";
2242         if (!autocvar_sv_vote_gametype)
2243         if(!MapInfo_CheckMap(m))
2244                 return "The map you suggested does not support the current game mode.";
2245         cvar_set("nextmap", m);
2246         cvar_set("timelimit", "-1");
2247         if(mapvote_initialized || alreadychangedlevel)
2248         {
2249                 if(DoNextMapOverride(0))
2250                         return "Map switch initiated.";
2251                 else
2252                         return "Hm... no. For some reason I like THIS map more.";
2253         }
2254         else
2255                 return "Map switch will happen after scoreboard.";
2256 }
2257
2258
2259 void EndFrame()
2260 {
2261         anticheat_endframe();
2262
2263         float altime;
2264         FOR_EACH_REALCLIENT(self)
2265         {
2266                 entity e = IS_SPEC(self) ? self.enemy : self;
2267                 if(e.typehitsound)
2268                         self.typehit_time = time;
2269                 else if(e.damage_dealt)
2270                 {
2271                         self.hit_time = time;
2272                         self.damage_dealt_total += ceil(e.damage_dealt);
2273                 }
2274         }
2275         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2276         // add 1 frametime because after this, engine SV_Physics
2277         // increases time by a frametime and then networks the frame
2278         // add another frametime because client shows everything with
2279         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2280         // needed!
2281         FOR_EACH_CLIENT(self)
2282         {
2283                 self.typehitsound = false;
2284                 self.damage_dealt = 0;
2285                 antilag_record(self, altime);
2286         }
2287         FOR_EACH_MONSTER(self)
2288                 antilag_record(self, altime);
2289 }
2290
2291
2292 /*
2293  * RedirectionThink:
2294  * returns true if redirecting
2295  */
2296 float redirection_timeout;
2297 float redirection_nextthink;
2298 float RedirectionThink()
2299 {
2300         float clients_found;
2301
2302         if(redirection_target == "")
2303                 return false;
2304
2305         if(!redirection_timeout)
2306         {
2307                 cvar_set("sv_public", "-2");
2308                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2309                 if(redirection_target == "self")
2310                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2311                 else
2312                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2313         }
2314
2315         if(time < redirection_nextthink)
2316                 return true;
2317
2318         redirection_nextthink = time + 1;
2319
2320         clients_found = 0;
2321         FOR_EACH_REALCLIENT(self)
2322         {
2323                 // TODO add timer
2324                 print("Redirecting: sending connect command to ", self.netname, "\n");
2325                 if(redirection_target == "self")
2326                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2327                 else
2328                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2329                 ++clients_found;
2330         }
2331
2332         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2333
2334         if(time > redirection_timeout || clients_found == 0)
2335                 localcmd("\nwait; wait; wait; quit\n");
2336
2337         return true;
2338 }
2339
2340 void TargetMusic_RestoreGame();
2341 void RestoreGame()
2342 {
2343         // Loaded from a save game
2344         // some things then break, so let's work around them...
2345
2346         // Progs DB (capture records)
2347         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2348
2349         // Mapinfo
2350         MapInfo_Shutdown();
2351         MapInfo_Enumerate();
2352         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2353         WeaponStats_Init();
2354
2355         TargetMusic_RestoreGame();
2356 }
2357
2358 void Shutdown()
2359 {
2360         gameover = 2;
2361
2362         if(world_initialized > 0)
2363         {
2364                 world_initialized = 0;
2365                 print("Saving persistent data...\n");
2366                 Ban_SaveBans();
2367
2368                 // playerstats with unfinished match
2369                 PlayerStats_GameReport(false);
2370
2371                 if(!cheatcount_total)
2372                 {
2373                         if(autocvar_sv_db_saveasdump)
2374                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2375                         else
2376                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2377                 }
2378                 if(autocvar_developer)
2379                 {
2380                         if(autocvar_sv_db_saveasdump)
2381                                 db_dump(TemporaryDB, "server-temp.db");
2382                         else
2383                                 db_save(TemporaryDB, "server-temp.db");
2384                 }
2385                 CheatShutdown(); // must be after cheatcount check
2386                 db_close(ServerProgsDB);
2387                 db_close(TemporaryDB);
2388                 print("done!\n");
2389                 // tell the bot system the game is ending now
2390                 bot_endgame();
2391
2392                 WeaponStats_Shutdown();
2393                 MapInfo_Shutdown();
2394         }
2395         else if(world_initialized == 0)
2396         {
2397                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2398         }
2399 }