qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434                 BADCVAR("g_grappling_hook");
 435                 BADCVAR("g_jetpack");
 436
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for(;;)
 477         {
 478                 o = world.mins;
 479                 o_x += random() * (world.maxs_x - world.mins_x);
 480                 o_y += random() * (world.maxs_y - world.mins_y);
 481                 o_z += random() * (world.maxs_z - world.mins_z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 float RandomSeed_Send(entity to, float sf)
 504 {
 505         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return TRUE;
 508 }
 509 void RandomSeed_Think()
 510 {
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {
 518         randomseed = spawn();
 519         randomseed.think = RandomSeed_Think;
 520         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 521
 522         entity oldself;
 523         oldself = self;
 524         self = randomseed;
 525         self.think(); // sets random seed and nextthink
 526         self = oldself;
 527 }
 528
 529 void spawnfunc___init_dedicated_server(void)
 530 {
 531         // handler for _init/_init map (only for dedicated server initialization)
 532
 533         world_initialized = -1; // don't complain
 534         cvar = cvar_normal;
 535         cvar_string = cvar_string_normal;
 536         cvar_set = cvar_set_normal;
 537
 538         remove = remove_unsafely;
 539
 540         entity e;
 541         e = spawn();
 542         e.think = GotoFirstMap;
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = spawn();
 546         e.classname = "info_player_deathmatch"; // safeguard against player joining
 547
 548         self.classname = "worldspawn"; // safeguard against various stuff ;)
 549
 550         // needs to be done so early because of the constants they create
 551         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 552         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s, col;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         allowed_to_spawn = TRUE;
 586
 587         entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         // needs to be done so early because of the constants they create
 597         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 598         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         //if (g_domination)
 670         //      dom_init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 ret_string = s;
 686                 MUTATOR_CALLHOOK(BuildMutatorsString);
 687                 s = ret_string;
 688
 689                 // simple, probably not good in the mutator system
 690                 if(autocvar_g_grappling_hook)
 691                         s = strcat(s, ":grappling_hook");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(!autocvar_g_use_ammunition)
 695                         s = strcat(s, ":no_use_ammunition");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_pickup_items == 0)
 699                         s = strcat(s, ":no_pickup_items");
 700                 if(autocvar_g_pickup_items > 0)
 701                         s = strcat(s, ":pickup_items");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(autocvar_g_weaponarena != "0")
 705                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_norecoil)
 709                         s = strcat(s, ":norecoil");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_midair)
 713                         s = strcat(s, ":midair");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_powerups == 0)
 717                         s = strcat(s, ":no_powerups");
 718                 if(autocvar_g_powerups > 0)
 719                         s = strcat(s, ":powerups");
 720
 721                 GameLogEcho(s);
 722                 GameLogEcho(":gameinfo:end");
 723         }
 724         else
 725                 matchid = strzone(ftos(random()));
 726
 727         cvar_set("nextmap", "");
 728
 729         SetDefaultAlpha();
 730
 731         if(autocvar_g_campaign)
 732                 CampaignPostInit();
 733
 734         fteqcc_testbugs();
 735
 736         Ban_LoadBans();
 737
 738         MapInfo_Enumerate();
 739         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 740
 741         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 742         {
 743                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 744                 if(fd != -1)
 745                 {
 746                         while((s = fgets(fd)))
 747                         {
 748                                 l = tokenize_console(s);
 749                                 if(l < 2)
 750                                         continue;
 751                                 if(argv(0) == "cd")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  cdtrack ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) == "fog")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 759                                         print("  \"fog\" \"", s, "\"\n");
 760                                 }
 761                                 else if(argv(0) == "set")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 764                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 765                                 }
 766                                 else if(argv(0) != "//")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 770                                 }
 771                         }
 772                         fclose(fd);
 773                 }
 774         }
 775
 776         WeaponStats_Init();
 777
 778         WEPSET_ADDSTAT();
 779         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 780         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 781         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 782         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 783         Nagger_Init();
 784
 785         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 786         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 787         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 788         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 789         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 790         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 791         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 792         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 793         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 794         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 795         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 796         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 797         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 798
 799         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 800         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 801
 802         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 803
 804         if(g_ca || g_freezetag)
 805         {
 806                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 807                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 808                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 809                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 810         }
 811         if(g_freezetag)
 812         {
 813                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 814                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 815         }
 816
 817         // g_movementspeed hack
 818         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 819         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 820         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 821         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 822
 823         // secrets
 824         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 825         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 826
 827         // misc
 828         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 829
 830         next_pingtime = time + 5;
 831
 832         detect_maptype();
 833
 834         // set up information replies for clients and server to use
 835         lsmaps_reply = "^7Maps available: ";
 836         lsnewmaps_reply = "^7Maps without a record set: ";
 837         for(i = 0, j = 0; i < MapInfo_count; ++i)
 838         {
 839                 if(MapInfo_Get_ByID(i))
 840                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 841                         {
 842                                 if(mod(i, 2))
 843                                         col = "^2";
 844                                 else
 845                                         col = "^3";
 846
 847                                 ++j;
 848
 849                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 850
 851                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 852                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 853                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 854                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 855                         }
 856         }
 857
 858         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 859         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 860
 861         maplist_reply = "^7Maps in list: ";
 862         n = tokenize_console(autocvar_g_maplist);
 863         for(i = 0, j = 0; i < n; ++i)
 864         {
 865                 if(MapInfo_CheckMap(argv(i)))
 866                 {
 867                         if(mod(j, 2))
 868                                 col = "^2";
 869                         else
 870                                 col = "^3";
 871                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 872                         ++j;
 873                 }
 874         }
 875         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 876         MapInfo_ClearTemps();
 877
 878         for(i = 0; i < 10; ++i)
 879         {
 880                 s = getrecords(i);
 881                 if (s)
 882                         records_reply[i] = strzone(s);
 883         }
 884
 885         ladder_reply = strzone(getladder());
 886
 887         rankings_reply = strzone(getrankings());
 888
 889         // begin other init
 890         ClientInit_Spawn();
 891         RandomSeed_Spawn();
 892         PingPLReport_Spawn();
 893
 894         CheatInit();
 895
 896         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 897
 898         // fill sv_curl_serverpackages from .serverpackage files
 899         if(autocvar_sv_curl_serverpackages_auto)
 900         {
 901                 s = "";
 902                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 903                 for(i = 0; i < n; ++i)
 904                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 905                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 906                                 s = strcat(s, " ", argv(i));
 907                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 908                 if(fd >= 0)
 909                 {
 910                         j = search_getsize(fd);
 911                         for(i = 0; i < j; ++i)
 912                                 s = strcat(s, " ", search_getfilename(fd, i));
 913                         search_end(fd);
 914                 }
 915                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 916                 if(fd >= 0)
 917                 {
 918                         j = search_getsize(fd);
 919                         for(i = 0; i < j; ++i)
 920                                 s = strcat(s, " ", search_getfilename(fd, i));
 921                         search_end(fd);
 922                 }
 923                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 924         }
 925
 926         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 927         modname = "Xonotic";
 928         // physics/balance/config changes that count as mod
 929         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 930                 modname = cvar_string("g_mod_physics");
 931         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 932                 modname = cvar_string("g_mod_balance");
 933         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 934                 modname = cvar_string("g_mod_config");
 935         // extra mutators that deserve to count as mod
 936         MUTATOR_CALLHOOK(SetModname);
 937         // weird game types that deserve to count as mod
 938         if(g_cts)
 939                 modname = "CTS";
 940         // save it for later
 941         modname = strzone(modname);
 942
 943         WinningConditionHelper(); // set worldstatus
 944
 945         world_initialized = 1;
 946 }
 947
 948 void spawnfunc_light (void)
 949 {
 950         //makestatic (self); // Who the f___ did that?
 951         remove(self);
 952 }
 953
 954 string GetGametype()
 955 {
 956         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 957 }
 958
 959 string getmapname_stored;
 960 string GetMapname()
 961 {
 962         return mapname;
 963 }
 964
 965 float Map_Count, Map_Current;
 966 string Map_Current_Name;
 967
 968 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 969 float GetMaplistPosition()
 970 {
 971         float pos, idx;
 972         string map;
 973
 974         map = GetMapname();
 975         idx = autocvar_g_maplist_index;
 976
 977         if(idx >= 0)
 978                 if(idx < Map_Count)
 979                         if(map == argv(idx))
 980                                 return idx;
 981
 982         for(pos = 0; pos < Map_Count; ++pos)
 983                 if(map == argv(pos))
 984                         return pos;
 985
 986         // resume normal maplist rotation if current map is not in g_maplist
 987         return idx;
 988 }
 989
 990 float MapHasRightSize(string map)
 991 {
 992         float fh;
 993         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 994         if(autocvar_g_maplist_check_waypoints)
 995         {
 996                 dprint("checkwp "); dprint(map);
 997                 if(!fexists(strcat("maps/", map, ".waypoints")))
 998                 {
 999                         dprint(": no waypoints\n");
1000                         return FALSE;
1001                 }
1002                 dprint(": has waypoints\n");
1003         }
1004
1005         // open map size restriction file
1006         dprint("opensize "); dprint(map);
1007         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1008         if(fh >= 0)
1009         {
1010                 float mapmin, mapmax;
1011                 dprint(": ok, ");
1012                 mapmin = stof(fgets(fh));
1013                 mapmax = stof(fgets(fh));
1014                 fclose(fh);
1015                 if(player_count < mapmin)
1016                 {
1017                         dprint("not enough\n");
1018                         return FALSE;
1019                 }
1020                 if(player_count > mapmax)
1021                 {
1022                         dprint("too many\n");
1023                         return FALSE;
1024                 }
1025                 dprint("right size\n");
1026                 return TRUE;
1027         }
1028         dprint(": not found\n");
1029         return TRUE;
1030 }
1031
1032 string Map_Filename(float position)
1033 {
1034         return strcat("maps/", argv(position), ".bsp");
1035 }
1036
1037 string strwords(string s, float w)
1038 {
1039         float endpos;
1040         for(endpos = 0; w && endpos >= 0; --w)
1041                 endpos = strstrofs(s, " ", endpos + 1);
1042         if(endpos < 0)
1043                 return s;
1044         else
1045                 return substring(s, 0, endpos);
1046 }
1047
1048 float strhasword(string s, string w)
1049 {
1050         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1051 }
1052
1053 void Map_MarkAsRecent(string m)
1054 {
1055         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1056 }
1057
1058 float Map_IsRecent(string m)
1059 {
1060         return strhasword(autocvar_g_maplist_mostrecent, m);
1061 }
1062
1063 float Map_Check(float position, float pass)
1064 {
1065         string filename;
1066         string map_next;
1067         map_next = argv(position);
1068         if(pass <= 1)
1069         {
1070                 if(Map_IsRecent(map_next))
1071                         return 0;
1072         }
1073         filename = Map_Filename(position);
1074         if(MapInfo_CheckMap(map_next))
1075         {
1076                 if(pass == 2)
1077                         return 1;
1078                 if(MapHasRightSize(map_next))
1079                         return 1;
1080                 return 0;
1081         }
1082         else
1083                 dprint( "Couldn't select '", filename, "'..\n" );
1084
1085         return 0;
1086 }
1087
1088 void Map_Goto_SetStr(string nextmapname)
1089 {
1090         if(getmapname_stored != "")
1091                 strunzone(getmapname_stored);
1092         if(nextmapname == "")
1093                 getmapname_stored = "";
1094         else
1095                 getmapname_stored = strzone(nextmapname);
1096 }
1097
1098 void Map_Goto_SetFloat(float position)
1099 {
1100         cvar_set("g_maplist_index", ftos(position));
1101         Map_Goto_SetStr(argv(position));
1102 }
1103
1104 void Map_Goto(float reinit)
1105 {
1106         MapInfo_LoadMap(getmapname_stored, reinit);
1107 }
1108
1109 // return codes of map selectors:
1110 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1111 //   -2 = permanent failure
1112 float() MaplistMethod_Iterate = // usual method
1113 {
1114         float pass, i;
1115
1116         for(pass = 1; pass <= 2; ++pass)
1117         {
1118                 for(i = 1; i < Map_Count; ++i)
1119                 {
1120                         float mapindex;
1121                         mapindex = mod(i + Map_Current, Map_Count);
1122                         if(Map_Check(mapindex, pass))
1123                                 return mapindex;
1124                 }
1125         }
1126         return -1;
1127 }
1128
1129 float() MaplistMethod_Repeat = // fallback method
1130 {
1131         if(Map_Check(Map_Current, 2))
1132                 return Map_Current;
1133         return -2;
1134 }
1135
1136 float() MaplistMethod_Random = // random map selection
1137 {
1138         float i, imax;
1139
1140         imax = 42;
1141
1142         for(i = 0; i <= imax; ++i)
1143         {
1144                 float mapindex;
1145                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1146                 if(Map_Check(mapindex, 1))
1147                         return mapindex;
1148         }
1149         return -1;
1150 }
1151
1152 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1153 // the exponent sets a bias on the map selection:
1154 // the higher the exponent, the less likely "shortly repeated" same maps are
1155 {
1156         float i, j, imax, insertpos;
1157
1158         imax = 42;
1159
1160         for(i = 0; i <= imax; ++i)
1161         {
1162                 string newlist;
1163
1164                 // now reinsert this at another position
1165                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1166                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1167                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1168                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1169
1170                 // insert the current map there
1171                 newlist = "";
1172                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1173                         newlist = strcat(newlist, " ", argv(j));
1174                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1175                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1178                 cvar_set("g_maplist", newlist);
1179                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180
1181                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1182                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1183                 if(Map_Check(Map_Current, 1))
1184                         return Map_Current;
1185         }
1186         return -1;
1187 }
1188
1189 void Maplist_Init()
1190 {
1191         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         if(Map_Count == 0)
1193         {
1194                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1195                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1196                 if(autocvar_g_maplist_shuffle)
1197                         ShuffleMaplist();
1198                 localcmd("\nmenu_cmd sync\n");
1199                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1200         }
1201         if(Map_Count == 0)
1202                 error("empty maplist, cannot select a new map");
1203         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1204
1205         if(Map_Current_Name)
1206                 strunzone(Map_Current_Name);
1207         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1208         // this may or may not be correct, but who cares, in the worst case a map
1209         // isn't chosen in the first pass that should have been
1210 }
1211
1212 string GetNextMap()
1213 {
1214         float nextMap;
1215
1216         Maplist_Init();
1217         nextMap = -1;
1218
1219         if(nextMap == -1)
1220                 if(autocvar_g_maplist_shuffle > 0)
1221                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1222
1223         if(nextMap == -1)
1224                 if(autocvar_g_maplist_selectrandom)
1225                         nextMap = MaplistMethod_Random();
1226
1227         if(nextMap == -1)
1228                 nextMap = MaplistMethod_Iterate();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Repeat();
1232
1233         if(nextMap >= 0)
1234         {
1235                 Map_Goto_SetFloat(nextMap);
1236                 return getmapname_stored;
1237         }
1238
1239         return "";
1240 }
1241
1242 float DoNextMapOverride(float reinit)
1243 {
1244         if(autocvar_g_campaign)
1245         {
1246                 CampaignPostIntermission();
1247                 alreadychangedlevel = TRUE;
1248                 return TRUE;
1249         }
1250         if(autocvar_quit_when_empty)
1251         {
1252                 if(player_count <= currentbots)
1253                 {
1254                         localcmd("quit\n");
1255                         alreadychangedlevel = TRUE;
1256                         return TRUE;
1257                 }
1258         }
1259         if(autocvar_quit_and_redirect != "")
1260         {
1261                 redirection_target = strzone(autocvar_quit_and_redirect);
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1266         {
1267                 localcmd("restart\n");
1268                 alreadychangedlevel = TRUE;
1269                 return TRUE;
1270         }
1271         if(autocvar_nextmap != "")
1272                 if(MapInfo_CheckMap(autocvar_nextmap))
1273                 {
1274                         Map_Goto_SetStr(autocvar_nextmap);
1275                         Map_Goto(reinit);
1276                         alreadychangedlevel = TRUE;
1277                         return TRUE;
1278                 }
1279         if(!reinit && autocvar_lastlevel)
1280         {
1281                 cvar_settemp_restore();
1282                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1283                 alreadychangedlevel = TRUE;
1284                 return TRUE;
1285         }
1286         return FALSE;
1287 }
1288
1289 void GotoNextMap(float reinit)
1290 {
1291         //string nextmap;
1292         //float n, nummaps;
1293         //string s;
1294         if (alreadychangedlevel)
1295                 return;
1296         alreadychangedlevel = TRUE;
1297
1298         {
1299                 string nextMap;
1300                 float allowReset;
1301
1302                 for(allowReset = 1; allowReset >= 0; --allowReset)
1303                 {
1304                         nextMap = GetNextMap();
1305                         if(nextMap != "")
1306                                 break;
1307
1308                         if(allowReset)
1309                         {
1310                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1311                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1312                                 if(autocvar_g_maplist_shuffle)
1313                                         ShuffleMaplist();
1314                                 localcmd("\nmenu_cmd sync\n");
1315                         }
1316                         else
1317                         {
1318                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1319                         }
1320                 }
1321                 Map_Goto(reinit);
1322         }
1323 }
1324
1325
1326 /*
1327 ============
1328 IntermissionThink
1329
1330 When the player presses attack or jump, change to the next level
1331 ============
1332 */
1333 .float autoscreenshot;
1334 void() MapVote_Start;
1335 void() MapVote_Think;
1336 float mapvote_initialized;
1337 void IntermissionThink()
1338 {
1339         FixIntermissionClient(self);
1340
1341         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1342         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1343
1344         if( (server_screenshot || client_screenshot)
1345                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1346         {
1347                 self.autoscreenshot = -1;
1348                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1349                 return;
1350         }
1351
1352         if (time < intermission_exittime)
1353                 return;
1354
1355         if(!mapvote_initialized)
1356                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1357                         return;
1358
1359         MapVote_Start();
1360 }
1361
1362 /*
1363 ============
1364 FindIntermission
1365
1366 Returns the entity to view from
1367 ============
1368 */
1369 /*
1370 entity FindIntermission()
1371 {
1372         local   entity spot;
1373         local   float cyc;
1374
1375 // look for info_intermission first
1376         spot = find (world, classname, "info_intermission");
1377         if (spot)
1378         {       // pick a random one
1379                 cyc = random() * 4;
1380                 while (cyc > 1)
1381                 {
1382                         spot = find (spot, classname, "info_intermission");
1383                         if (!spot)
1384                                 spot = find (spot, classname, "info_intermission");
1385                         cyc = cyc - 1;
1386                 }
1387                 return spot;
1388         }
1389
1390 // then look for the start position
1391         spot = find (world, classname, "info_player_start");
1392         if (spot)
1393                 return spot;
1394
1395 // testinfo_player_start is only found in regioned levels
1396         spot = find (world, classname, "testplayerstart");
1397         if (spot)
1398                 return spot;
1399
1400 // then look for the start position
1401         spot = find (world, classname, "info_player_deathmatch");
1402         if (spot)
1403                 return spot;
1404
1405         //objerror ("FindIntermission: no spot");
1406         return world;
1407 }
1408 */
1409
1410 /*
1411 ===============================================================================
1412
1413 RULES
1414
1415 ===============================================================================
1416 */
1417
1418 void DumpStats(float final)
1419 {
1420         float file;
1421         string s;
1422         float to_console;
1423         float to_eventlog;
1424         float to_file;
1425         float i;
1426
1427         to_console = autocvar_sv_logscores_console;
1428         to_eventlog = autocvar_sv_eventlog;
1429         to_file = autocvar_sv_logscores_file;
1430
1431         if(!final)
1432         {
1433                 to_console = TRUE; // always print printstats replies
1434                 to_eventlog = FALSE; // but never print them to the event log
1435         }
1436
1437         if(to_eventlog)
1438                 if(autocvar_sv_eventlog_console)
1439                         to_console = FALSE; // otherwise we get the output twice
1440
1441         if(final)
1442                 s = ":scores:";
1443         else
1444                 s = ":status:";
1445         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1446
1447         if(to_console)
1448                 print(s, "\n");
1449         if(to_eventlog)
1450                 GameLogEcho(s);
1451
1452         file = -1;
1453         if(to_file)
1454         {
1455                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1456                 if(file == -1)
1457                         to_file = FALSE;
1458                 else
1459                         fputs(file, strcat(s, "\n"));
1460         }
1461
1462         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1463         if(to_console)
1464                 print(s, "\n");
1465         if(to_eventlog)
1466                 GameLogEcho(s);
1467         if(to_file)
1468                 fputs(file, strcat(s, "\n"));
1469
1470         FOR_EACH_CLIENT(other)
1471         {
1472                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1473                 {
1474                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1475                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1476                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1477                                 s = strcat(s, ftos(other.team), ":");
1478                         else
1479                                 s = strcat(s, "spectator:");
1480
1481                         if(to_console)
1482                                 print(s, other.netname, "\n");
1483                         if(to_eventlog)
1484                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1485                         if(to_file)
1486                                 fputs(file, strcat(s, other.netname, "\n"));
1487                 }
1488         }
1489
1490         if(teamplay)
1491         {
1492                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1493                 if(to_console)
1494                         print(s, "\n");
1495                 if(to_eventlog)
1496                         GameLogEcho(s);
1497                 if(to_file)
1498                         fputs(file, strcat(s, "\n"));
1499
1500                 for(i = 1; i < 16; ++i)
1501                 {
1502                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1503                         s = strcat(s, ":", ftos(i));
1504                         if(to_console)
1505                                 print(s, "\n");
1506                         if(to_eventlog)
1507                                 GameLogEcho(s);
1508                         if(to_file)
1509                                 fputs(file, strcat(s, "\n"));
1510                 }
1511         }
1512
1513         if(to_console)
1514                 print(":end\n");
1515         if(to_eventlog)
1516                 GameLogEcho(":end");
1517         if(to_file)
1518         {
1519                 fputs(file, ":end\n");
1520                 fclose(file);
1521         }
1522 }
1523
1524 void FixIntermissionClient(entity e)
1525 {
1526         string s;
1527         if(!e.autoscreenshot) // initial call
1528         {
1529                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1530                 e.health = -2342;
1531                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1532                 e.solid = SOLID_NOT;
1533                 e.movetype = MOVETYPE_NONE;
1534                 e.takedamage = DAMAGE_NO;
1535                 if(e.weaponentity)
1536                 {
1537                         e.weaponentity.effects = EF_NODRAW;
1538                         if (e.weaponentity.weaponentity)
1539                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1540                 }
1541                 if(clienttype(e) == CLIENTTYPE_REAL)
1542                 {
1543                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1544                         s = autocvar_sv_intermission_cdtrack;
1545                         if(s != "")
1546                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1547                         msg_entity = e;
1548                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1549                 }
1550         }
1551 }
1552
1553 void minstagib_stop_countdown(entity e);
1554 /*
1555 go to the next level for deathmatch
1556 only called if a time or frag limit has expired
1557 */
1558 void NextLevel()
1559 {
1560         gameover = TRUE;
1561
1562         intermission_running = 1;
1563
1564 // enforce a wait time before allowing changelevel
1565         if(player_count > 0)
1566                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1567         else
1568                 intermission_exittime = -1;
1569
1570         /*
1571         WriteByte (MSG_ALL, SVC_CDTRACK);
1572         WriteByte (MSG_ALL, 3);
1573         WriteByte (MSG_ALL, 3);
1574         // done in FixIntermission
1575         */
1576
1577         //pos = FindIntermission ();
1578
1579         VoteReset();
1580
1581         DumpStats(TRUE);
1582
1583         // send statistics
1584         entity e;
1585         PlayerStats_EndMatch(1);
1586         FOR_EACH_CLIENT(e)
1587                 PlayerStats_AddGlobalInfo(e);
1588         PlayerStats_Shutdown();
1589         WeaponStats_Shutdown();
1590
1591         if(autocvar_sv_eventlog)
1592                 GameLogEcho(":gameover");
1593
1594         GameLogClose();
1595
1596         FOR_EACH_PLAYER(other) {
1597                 minstagib_stop_countdown(other);
1598                 FixIntermissionClient(other);
1599                 if(other.winning)
1600                         bprint(other.netname, " ^7wins.\n");
1601         }
1602
1603         if(autocvar_g_campaign)
1604                 CampaignPreIntermission();
1605
1606         MUTATOR_CALLHOOK(MatchEnd);
1607
1608         localcmd("\nsv_hook_gameend\n");
1609 }
1610
1611 /*
1612 ============
1613 CheckRules_Player
1614
1615 Exit deathmatch games upon conditions
1616 ============
1617 */
1618 void CheckRules_Player()
1619 {
1620         if (gameover)   // someone else quit the game already
1621                 return;
1622
1623         if(self.deadflag == DEAD_NO)
1624                 self.play_time += frametime;
1625
1626         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1627         //   (div0: and that in CheckRules_World please)
1628 }
1629
1630 float checkrules_equality;
1631 float checkrules_suddendeathwarning;
1632 float checkrules_suddendeathend;
1633 float checkrules_overtimesadded; //how many overtimes have been already added
1634
1635 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1636 float WINNING_YES = 1; // winner found
1637 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1638 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1639
1640 float InitiateSuddenDeath()
1641 {
1642         // Check first whether normal overtimes could be added before initiating suddendeath mode
1643         // - for this timelimit_overtime needs to be >0 of course
1644         // - also check the winning condition calculated in the previous frame and only add normal overtime
1645         //   again, if at the point at which timelimit would be extended again, still no winner was found
1646         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1647         {
1648                 return 1; // need to call InitiateOvertime later
1649         }
1650         else
1651         {
1652                 if(!checkrules_suddendeathend)
1653                 {
1654                         if(autocvar_g_campaign)
1655                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1656                         else
1657                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1658                         if(g_race && !g_race_qualifying)
1659                                 race_StartCompleting();
1660                 }
1661                 return 0;
1662         }
1663 }
1664
1665 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1666 {
1667         ++checkrules_overtimesadded;
1668         //add one more overtime by simply extending the timelimit
1669         float tl;
1670         tl = autocvar_timelimit;
1671         tl += autocvar_timelimit_overtime;
1672         cvar_set("timelimit", ftos(tl));
1673         string minutesPlural;
1674         if (autocvar_timelimit_overtime == 1)
1675                 minutesPlural = " ^3minute";
1676         else
1677                 minutesPlural = " ^3minutes";
1678
1679         bcenterprint(
1680                 strcat(
1681                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1682                         ftos(autocvar_timelimit_overtime),
1683                         minutesPlural,
1684                         " to the game!"
1685                 )
1686         );
1687 }
1688
1689 float GetWinningCode(float fraglimitreached, float equality)
1690 {
1691         if(autocvar_g_campaign == 1)
1692                 if(fraglimitreached)
1693                         return WINNING_YES;
1694                 else
1695                         return WINNING_NO;
1696
1697         else
1698                 if(equality)
1699                         if(fraglimitreached)
1700                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1701                         else
1702                                 return WINNING_NEVER;
1703                 else
1704                         if(fraglimitreached)
1705                                 return WINNING_YES;
1706                         else
1707                                 return WINNING_NO;
1708 }
1709
1710 // set the .winning flag for exactly those players with a given field value
1711 void SetWinners(.float field, float value)
1712 {
1713         entity head;
1714         FOR_EACH_PLAYER(head)
1715                 head.winning = (head.field == value);
1716 }
1717
1718 // set the .winning flag for those players with a given field value
1719 void AddWinners(.float field, float value)
1720 {
1721         entity head;
1722         FOR_EACH_PLAYER(head)
1723                 if(head.field == value)
1724                         head.winning = 1;
1725 }
1726
1727 // clear the .winning flags
1728 void ClearWinners(void)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 head.winning = 0;
1733 }
1734
1735 // Onslaught winning condition:
1736 // game terminates if only one team has a working generator (or none)
1737 float WinningCondition_Onslaught()
1738 {
1739         entity head;
1740         float t1, t2, t3, t4;
1741
1742         WinningConditionHelper(); // set worldstatus
1743
1744         if(inWarmupStage)
1745                 return WINNING_NO;
1746
1747         // first check if the game has ended
1748         t1 = t2 = t3 = t4 = 0;
1749         head = find(world, classname, "onslaught_generator");
1750         while (head)
1751         {
1752                 if (head.health > 0)
1753                 {
1754                         if (head.team == COLOR_TEAM1) t1 = 1;
1755                         if (head.team == COLOR_TEAM2) t2 = 1;
1756                         if (head.team == COLOR_TEAM3) t3 = 1;
1757                         if (head.team == COLOR_TEAM4) t4 = 1;
1758                 }
1759                 head = find(head, classname, "onslaught_generator");
1760         }
1761         if (t1 + t2 + t3 + t4 < 2)
1762         {
1763                 // game over, only one team remains (or none)
1764                 ClearWinners();
1765                 if (t1) SetWinners(team, COLOR_TEAM1);
1766                 if (t2) SetWinners(team, COLOR_TEAM2);
1767                 if (t3) SetWinners(team, COLOR_TEAM3);
1768                 if (t4) SetWinners(team, COLOR_TEAM4);
1769                 dprint("Have a winner, ending game.\n");
1770                 return WINNING_YES;
1771         }
1772
1773         // Two or more teams remain
1774         return WINNING_NO;
1775 }
1776
1777 float LMS_NewPlayerLives()
1778 {
1779         float fl;
1780         fl = autocvar_fraglimit;
1781         if(fl == 0)
1782                 fl = 999;
1783
1784         // first player has left the game for dying too much? Nobody else can get in.
1785         if(lms_lowest_lives < 1)
1786                 return 0;
1787
1788         if(!autocvar_g_lms_join_anytime)
1789                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1790                         return 0;
1791
1792         return bound(1, lms_lowest_lives, fl);
1793 }
1794
1795 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1796 // they win. Otherwise the defending team wins once the timelimit passes.
1797 void assault_new_round();
1798 float WinningCondition_Assault()
1799 {
1800         float status;
1801
1802         WinningConditionHelper(); // set worldstatus
1803
1804         status = WINNING_NO;
1805         // as the timelimit has not yet passed just assume the defending team will win
1806         if(assault_attacker_team == COLOR_TEAM1)
1807         {
1808                 SetWinners(team, COLOR_TEAM2);
1809         }
1810         else
1811         {
1812                 SetWinners(team, COLOR_TEAM1);
1813         }
1814
1815         entity ent;
1816         ent = find(world, classname, "target_assault_roundend");
1817         if(ent)
1818         {
1819                 if(ent.winning) // round end has been triggered by attacking team
1820                 {
1821                         bprint("ASSAULT: round completed...\n");
1822                         SetWinners(team, assault_attacker_team);
1823
1824                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1825
1826                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1827                         {
1828                                 status = WINNING_YES;
1829                         }
1830                         else
1831                         {
1832                                 entity oldself;
1833                                 oldself = self;
1834                                 self = ent;
1835                                 assault_new_round();
1836                                 self = oldself;
1837                         }
1838                 }
1839         }
1840
1841         return status;
1842 }
1843
1844 // LMS winning condition: game terminates if and only if there's at most one
1845 // one player who's living lives. Top two scores being equal cancels the time
1846 // limit.
1847 float WinningCondition_LMS()
1848 {
1849         entity head, head2;
1850         float have_player;
1851         float have_players;
1852         float l;
1853
1854         have_player = FALSE;
1855         have_players = FALSE;
1856         l = LMS_NewPlayerLives();
1857
1858         head = find(world, classname, "player");
1859         if(head)
1860                 have_player = TRUE;
1861         head2 = find(head, classname, "player");
1862         if(head2)
1863                 have_players = TRUE;
1864
1865         if(have_player)
1866         {
1867                 // we have at least one player
1868                 if(have_players)
1869                 {
1870                         // two or more active players - continue with the game
1871                 }
1872                 else
1873                 {
1874                         // exactly one player?
1875
1876                         ClearWinners();
1877                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1878
1879                         if(l)
1880                         {
1881                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1882                                 return WINNING_NO;
1883                         }
1884                         else
1885                         {
1886                                 // a winner!
1887                                 // and assign him his first place
1888                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1889                                 return WINNING_YES;
1890                         }
1891                 }
1892         }
1893         else
1894         {
1895                 // nobody is playing at all...
1896                 if(l)
1897                 {
1898                         // wait for players...
1899                 }
1900                 else
1901                 {
1902                         // SNAFU (maybe a draw game?)
1903                         ClearWinners();
1904                         dprint("No players, ending game.\n");
1905                         return WINNING_YES;
1906                 }
1907         }
1908
1909         // When we get here, we have at least two players who are actually LIVING,
1910         // now check if the top two players have equal score.
1911         WinningConditionHelper();
1912
1913         ClearWinners();
1914         if(WinningConditionHelper_winner)
1915                 WinningConditionHelper_winner.winning = TRUE;
1916         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1917                 return WINNING_NEVER;
1918
1919         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1920         return WINNING_NO;
1921 }
1922
1923 void ShuffleMaplist()
1924 {
1925         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1926 }
1927
1928 float leaderfrags;
1929 float WinningCondition_Scores(float limit, float leadlimit)
1930 {
1931         float limitreached;
1932
1933         // TODO make everything use THIS winning condition (except LMS)
1934         WinningConditionHelper();
1935
1936         if(teamplay)
1937         {
1938                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1939                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1940                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1941                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1942         }
1943
1944         ClearWinners();
1945         if(WinningConditionHelper_winner)
1946                 WinningConditionHelper_winner.winning = 1;
1947         if(WinningConditionHelper_winnerteam >= 0)
1948                 SetWinners(team, WinningConditionHelper_winnerteam);
1949
1950         if(WinningConditionHelper_lowerisbetter)
1951         {
1952                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1953                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1954                 limit = -limit;
1955         }
1956
1957         if(WinningConditionHelper_zeroisworst)
1958                 leadlimit = 0; // not supported in this mode
1959
1960         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1961         // these modes always score in increments of 1, thus this makes sense
1962         {
1963                 if(leaderfrags != WinningConditionHelper_topscore)
1964                 {
1965                         leaderfrags = WinningConditionHelper_topscore;
1966
1967                         if (limit)
1968                         if (leaderfrags == limit - 1)
1969                                 Announce("1fragleft");
1970                         else if (leaderfrags == limit - 2)
1971                                 Announce("2fragsleft");
1972                         else if (leaderfrags == limit - 3)
1973                                 Announce("3fragsleft");
1974                 }
1975         }
1976
1977         limitreached = FALSE;
1978         if(limit)
1979                 if(WinningConditionHelper_topscore >= limit)
1980                         limitreached = TRUE;
1981         if(leadlimit)
1982         {
1983                 float leadlimitreached;
1984                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1985                 if(autocvar_leadlimit_and_fraglimit)
1986                         limitreached = (limitreached && leadlimitreached);
1987                 else
1988                         limitreached = (limitreached || leadlimitreached);
1989         }
1990
1991         if(limit)
1992                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1993
1994         return GetWinningCode(
1995                 WinningConditionHelper_topscore && limitreached,
1996                 WinningConditionHelper_equality
1997         );
1998 }
1999
2000 float WinningCondition_Race(float fraglimit)
2001 {
2002         float wc;
2003         entity p;
2004         float n, c;
2005
2006         n = 0;
2007         c = 0;
2008         FOR_EACH_PLAYER(p)
2009         {
2010                 ++n;
2011                 if(p.race_completed)
2012                         ++c;
2013         }
2014         if(n && (n == c))
2015                 return WINNING_YES;
2016         wc = WinningCondition_Scores(fraglimit, 0);
2017
2018         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2019         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2020         // do NOT support equality when the laps are all raced!
2021                 return WINNING_STARTSUDDENDEATHOVERTIME;
2022         else
2023                 return WINNING_NEVER;
2024 }
2025
2026 float WinningCondition_QualifyingThenRace(float limit)
2027 {
2028         float wc;
2029         wc = WinningCondition_Scores(limit, 0);
2030
2031         // NEVER initiate overtime
2032         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2033         {
2034                 return WINNING_YES;
2035         }
2036
2037         return wc;
2038 }
2039
2040 float WinningCondition_RanOutOfSpawns()
2041 {
2042         entity head;
2043
2044         if(have_team_spawns <= 0)
2045                 return WINNING_NO;
2046
2047         if(autocvar_g_spawn_useallspawns <= 0)
2048                 return WINNING_NO;
2049
2050         if(!some_spawn_has_been_used)
2051                 return WINNING_NO;
2052
2053         team1_score = team2_score = team3_score = team4_score = 0;
2054
2055         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2056         {
2057                 if(head.team == COLOR_TEAM1)
2058                         team1_score = 1;
2059                 else if(head.team == COLOR_TEAM2)
2060                         team2_score = 1;
2061                 else if(head.team == COLOR_TEAM3)
2062                         team3_score = 1;
2063                 else if(head.team == COLOR_TEAM4)
2064                         team4_score = 1;
2065         }
2066
2067         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2068         {
2069                 if(head.team == COLOR_TEAM1)
2070                         team1_score = 1;
2071                 else if(head.team == COLOR_TEAM2)
2072                         team2_score = 1;
2073                 else if(head.team == COLOR_TEAM3)
2074                         team3_score = 1;
2075                 else if(head.team == COLOR_TEAM4)
2076                         team4_score = 1;
2077         }
2078
2079         ClearWinners();
2080         if(team1_score + team2_score + team3_score + team4_score == 0)
2081         {
2082                 checkrules_equality = TRUE;
2083                 return WINNING_YES;
2084         }
2085         else if(team1_score + team2_score + team3_score + team4_score == 1)
2086         {
2087                 float t, i;
2088                 if(team1_score)
2089                         t = COLOR_TEAM1;
2090                 else if(team2_score)
2091                         t = COLOR_TEAM2;
2092                 else if(team3_score)
2093                         t = COLOR_TEAM3;
2094                 else // if(team4_score)
2095                         t = COLOR_TEAM4;
2096                 CheckAllowedTeams(world);
2097                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2098                 {
2099                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2100                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2101                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2102                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2103                 }
2104
2105                 AddWinners(team, t);
2106                 return WINNING_YES;
2107         }
2108         else
2109                 return WINNING_NO;
2110 }
2111
2112 /*
2113 ============
2114 CheckRules_World
2115
2116 Exit deathmatch games upon conditions
2117 ============
2118 */
2119 void ReadyRestart();
2120 void CheckRules_World()
2121 {
2122         float timelimit;
2123         float fraglimit;
2124         float leadlimit;
2125
2126         VoteThink();
2127         MapVote_Think();
2128
2129         SetDefaultAlpha();
2130
2131         /*
2132         MapVote_Think should now do that part
2133         if (intermission_running)
2134                 if (time >= intermission_exittime + 60)
2135                 {
2136                         if(!DoNextMapOverride())
2137                                 GotoNextMap();
2138                         return;
2139                 }
2140         */
2141
2142         if (gameover)   // someone else quit the game already
2143         {
2144                 if(player_count == 0) // Nobody there? Then let's go to the next map
2145                         MapVote_Start();
2146                         // this will actually check the player count in the next frame
2147                         // again, but this shouldn't hurt
2148                 return;
2149         }
2150
2151         timelimit = autocvar_timelimit * 60;
2152         fraglimit = autocvar_fraglimit;
2153         leadlimit = autocvar_leadlimit;
2154
2155         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2156         {
2157                 if(timelimit > 0)
2158                         timelimit = 0; // timelimit is not made for warmup
2159                 if(fraglimit > 0)
2160                         fraglimit = 0; // no fraglimit for now
2161                 leadlimit = 0; // no leadlimit for now
2162         }
2163
2164         if(timelimit > 0)
2165         {
2166                 timelimit += game_starttime;
2167         }
2168         else if (timelimit < 0)
2169         {
2170                 // endmatch
2171                 NextLevel();
2172                 return;
2173         }
2174
2175         if(g_onslaught)
2176                 timelimit = 0; // ONS has its own overtime rule
2177
2178         float wantovertime;
2179         wantovertime = 0;
2180
2181         if(timelimit > game_starttime)
2182                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2183         else
2184                 game_completion_ratio = 0;
2185
2186         if(checkrules_suddendeathend)
2187         {
2188                 if(!checkrules_suddendeathwarning)
2189                 {
2190                         checkrules_suddendeathwarning = TRUE;
2191                         if(g_race && !g_race_qualifying)
2192                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2193                         else
2194                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2195                 }
2196         }
2197         else
2198         {
2199                 if (timelimit && time >= timelimit)
2200                 {
2201                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2202                         {
2203                                 float totalplayers;
2204                                 float playerswithlaps;
2205                                 float readyplayers;
2206                                 entity head;
2207                                 totalplayers = playerswithlaps = readyplayers = 0;
2208                                 FOR_EACH_PLAYER(head)
2209                                 {
2210                                         ++totalplayers;
2211                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2212                                                 ++playerswithlaps;
2213                                         if(head.ready)
2214                                                 ++readyplayers;
2215                                 }
2216
2217                                 // at least 2 of the players have completed a lap: start the RACE
2218                                 // otherwise, the players should end the qualifying on their own
2219                                 if(readyplayers || playerswithlaps >= 2)
2220                                 {
2221                                         checkrules_suddendeathend = 0;
2222                                         ReadyRestart(); // go to race
2223                                         return;
2224                                 }
2225                                 else
2226                                         wantovertime |= InitiateSuddenDeath();
2227                         }
2228                         else
2229                                 wantovertime |= InitiateSuddenDeath();
2230                 }
2231         }
2232
2233         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2234         {
2235                 NextLevel();
2236                 return;
2237         }
2238
2239         float checkrules_status;
2240         checkrules_status = WinningCondition_RanOutOfSpawns();
2241         if(checkrules_status == WINNING_YES)
2242         {
2243                 bprint("Hey! Someone ran out of spawns!\n");
2244         }
2245         else if(g_race && !g_race_qualifying && timelimit >= 0)
2246         {
2247                 checkrules_status = WinningCondition_Race(fraglimit);
2248                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2249         }
2250         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2251         {
2252                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2253                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2254         }
2255         else if(g_assault)
2256         {
2257                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2258         }
2259         else if(g_lms)
2260         {
2261                 checkrules_status = WinningCondition_LMS();
2262         }
2263         else if (g_onslaught)
2264         {
2265                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2266         }
2267         else
2268         {
2269                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2270                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2271         }
2272
2273         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2274         {
2275                 checkrules_status = WINNING_NEVER;
2276                 checkrules_overtimesadded = -1;
2277                 wantovertime |= InitiateSuddenDeath();
2278         }
2279
2280         if(checkrules_status == WINNING_NEVER)
2281                 // equality cases! Nobody wins if the overtime ends in a draw.
2282                 ClearWinners();
2283
2284         if(wantovertime)
2285         {
2286                 if(checkrules_status == WINNING_NEVER)
2287                         InitiateOvertime();
2288                 else
2289                         checkrules_status = WINNING_YES;
2290         }
2291
2292         if(checkrules_suddendeathend)
2293                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2294                         checkrules_status = WINNING_YES;
2295
2296         if(checkrules_status == WINNING_YES)
2297         {
2298                 //print("WINNING\n");
2299                 NextLevel();
2300         }
2301 }
2302
2303 float mapvote_nextthink;
2304 float mapvote_initialized;
2305 float mapvote_keeptwotime;
2306 float mapvote_timeout;
2307 string mapvote_message;
2308 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2309 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2310 float mapvote_screenshot_dirs_count;
2311
2312 float mapvote_count;
2313 float mapvote_count_real;
2314 string mapvote_maps[MAPVOTE_COUNT];
2315 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2316 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2317 float mapvote_maps_suggested[MAPVOTE_COUNT];
2318 string mapvote_suggestions[MAPVOTE_COUNT];
2319 float mapvote_suggestion_ptr;
2320 float mapvote_voters;
2321 float mapvote_selections[MAPVOTE_COUNT];
2322 float mapvote_run;
2323 float mapvote_detail;
2324 float mapvote_abstain;
2325 .float mapvote;
2326
2327 void MapVote_ClearAllVotes()
2328 {
2329         FOR_EACH_CLIENT(other)
2330                 other.mapvote = 0;
2331 }
2332
2333 string MapVote_Suggest(string m)
2334 {
2335         float i;
2336         if(m == "")
2337                 return "That's not how to use this command.";
2338         if(!autocvar_g_maplist_votable_suggestions)
2339                 return "Suggestions are not accepted on this server.";
2340         if(mapvote_initialized)
2341                 return "Can't suggest - voting is already in progress!";
2342         m = MapInfo_FixName(m);
2343         if not(m)
2344                 return "The map you suggested is not available on this server.";
2345         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2346                 if(Map_IsRecent(m))
2347                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2348
2349         if(!MapInfo_CheckMap(m))
2350                 return "The map you suggested does not support the current game mode.";
2351         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2352                 if(mapvote_suggestions[i] == m)
2353                         return "This map was already suggested.";
2354         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2355         {
2356                 i = floor(random() * mapvote_suggestion_ptr);
2357         }
2358         else
2359         {
2360                 i = mapvote_suggestion_ptr;
2361                 mapvote_suggestion_ptr += 1;
2362         }
2363         if(mapvote_suggestions[i] != "")
2364                 strunzone(mapvote_suggestions[i]);
2365         mapvote_suggestions[i] = strzone(m);
2366         if(autocvar_sv_eventlog)
2367                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2368         return strcat("Suggestion of ", m, " accepted.");
2369 }
2370
2371 void MapVote_AddVotable(string nextMap, float isSuggestion)
2372 {
2373         float j, i, o;
2374         string pakfile, mapfile;
2375
2376         if(nextMap == "")
2377                 return;
2378         for(j = 0; j < mapvote_count; ++j)
2379                 if(mapvote_maps[j] == nextMap)
2380                         return;
2381         // suggestions might be no longer valid/allowed after gametype switch!
2382         if(isSuggestion)
2383                 if(!MapInfo_CheckMap(nextMap))
2384                         return;
2385         mapvote_maps[mapvote_count] = strzone(nextMap);
2386         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2387
2388         pakfile = string_null;
2389         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2390         {
2391                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2392                 pakfile = whichpack(strcat(mapfile, ".tga"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2395                 if(pakfile == "")
2396                         pakfile = whichpack(strcat(mapfile, ".png"));
2397                 if(pakfile != "")
2398                         break;
2399         }
2400         if(i >= mapvote_screenshot_dirs_count)
2401                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2402         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2403                 pakfile = substring(pakfile, o, -1);
2404
2405         mapvote_maps_screenshot_dir[mapvote_count] = i;
2406         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2407
2408         mapvote_count += 1;
2409 }
2410
2411 void MapVote_Spawn();
2412 void MapVote_Init()
2413 {
2414         float i;
2415         float nmax, smax;
2416
2417         MapVote_ClearAllVotes();
2418
2419         mapvote_count = 0;
2420         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2421         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2422
2423         if(mapvote_abstain)
2424                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2425         else
2426                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2427         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2428
2429         // we need this for AddVotable, as that cycles through the screenshot dirs
2430         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2431         if(mapvote_screenshot_dirs_count == 0)
2432                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2433         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2434         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2435                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2436
2437         if(mapvote_suggestion_ptr)
2438                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2439                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2440
2441         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2442                 MapVote_AddVotable(GetNextMap(), FALSE);
2443
2444         if(mapvote_count == 0)
2445         {
2446                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2447                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2448                 if(autocvar_g_maplist_shuffle)
2449                         ShuffleMaplist();
2450                 localcmd("\nmenu_cmd sync\n");
2451                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2452                         MapVote_AddVotable(GetNextMap(), FALSE);
2453         }
2454
2455         mapvote_count_real = mapvote_count;
2456         if(mapvote_abstain)
2457                 MapVote_AddVotable("don't care", 0);
2458
2459         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2460
2461         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2462         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2463         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2464                 mapvote_keeptwotime = 0;
2465         mapvote_message = "Choose a map and press its key!";
2466
2467         MapVote_Spawn();
2468 }
2469
2470 void MapVote_SendPicture(float id)
2471 {
2472         msg_entity = self;
2473         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2474         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2475         WriteByte(MSG_ONE, id);
2476         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2477 }
2478
2479 float MapVote_GetMapMask()
2480 {
2481         float mask, i, power;
2482         mask = 0;
2483         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2484                 if(mapvote_maps[i] != "")
2485                         mask |= power;
2486         return mask;
2487 }
2488
2489 entity mapvote_ent;
2490 float MapVote_SendEntity(entity to, float sf)
2491 {
2492         float i;
2493
2494         if(sf & 1)
2495                 sf &~= 2; // if we send 1, we don't need to also send 2
2496
2497         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2498         WriteByte(MSG_ENTITY, sf);
2499
2500         if(sf & 1)
2501         {
2502                 // flag 1 == initialization
2503                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2504                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2505                 WriteString(MSG_ENTITY, "");
2506                 WriteByte(MSG_ENTITY, mapvote_count);
2507                 WriteByte(MSG_ENTITY, mapvote_abstain);
2508                 WriteByte(MSG_ENTITY, mapvote_detail);
2509                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2510                 if(mapvote_count <= 8)
2511                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2512                 else
2513                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2514                 for(i = 0; i < mapvote_count; ++i)
2515                         if(mapvote_maps[i] != "")
2516                         {
2517                                 if(mapvote_abstain && i == mapvote_count - 1)
2518                                 {
2519                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2520                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2521                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2522                                 }
2523                                 else
2524                                 {
2525                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2526                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2527                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2528                                 }
2529                         }
2530         }
2531
2532         if(sf & 2)
2533         {
2534                 // flag 2 == update of mask
2535                 if(mapvote_count <= 8)
2536                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2537                 else
2538                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2539         }
2540
2541         if(sf & 4)
2542         {
2543                 if(mapvote_detail)
2544                         for(i = 0; i < mapvote_count; ++i)
2545                                 if(mapvote_maps[i] != "")
2546                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2547
2548                 WriteByte(MSG_ENTITY, to.mapvote);
2549         }
2550
2551         return TRUE;
2552 }
2553
2554 void MapVote_Spawn()
2555 {
2556         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2557 }
2558
2559 void MapVote_TouchMask()
2560 {
2561         mapvote_ent.SendFlags |= 2;
2562 }
2563
2564 void MapVote_TouchVotes(entity voter)
2565 {
2566         mapvote_ent.SendFlags |= 4;
2567 }
2568
2569 float MapVote_Finished(float mappos)
2570 {
2571         string result;
2572         float i;
2573         float didntvote;
2574
2575         if(autocvar_sv_eventlog)
2576         {
2577                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2578                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2579                 didntvote = mapvote_voters;
2580                 for(i = 0; i < mapvote_count; ++i)
2581                         if(mapvote_maps[i] != "")
2582                         {
2583                                 didntvote -= mapvote_selections[i];
2584                                 if(i != mappos)
2585                                 {
2586                                         result = strcat(result, ":", mapvote_maps[i]);
2587                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2588                                 }
2589                         }
2590                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2591
2592                 GameLogEcho(result);
2593                 if(mapvote_maps_suggested[mappos])
2594                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2595         }
2596
2597         FOR_EACH_REALCLIENT(other)
2598                 FixClientCvars(other);
2599
2600         Map_Goto_SetStr(mapvote_maps[mappos]);
2601         Map_Goto(0);
2602         alreadychangedlevel = TRUE;
2603         return TRUE;
2604 }
2605 void MapVote_CheckRules_1()
2606 {
2607         float i;
2608
2609         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2610         {
2611                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2612                 mapvote_selections[i] = 0;
2613         }
2614
2615         mapvote_voters = 0;
2616         FOR_EACH_REALCLIENT(other)
2617         {
2618                 ++mapvote_voters;
2619                 if(other.mapvote)
2620                 {
2621                         i = other.mapvote - 1;
2622                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2623                         mapvote_selections[i] = mapvote_selections[i] + 1;
2624                 }
2625         }
2626 }
2627
2628 float MapVote_CheckRules_2()
2629 {
2630         float i;
2631         float firstPlace, secondPlace;
2632         float firstPlaceVotes, secondPlaceVotes;
2633         float mapvote_voters_real;
2634         string result;
2635
2636         if(mapvote_count_real == 1)
2637                 return MapVote_Finished(0);
2638
2639         mapvote_voters_real = mapvote_voters;
2640         if(mapvote_abstain)
2641                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2642
2643         RandomSelection_Init();
2644         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2645                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2646         firstPlace = RandomSelection_chosen_float;
2647         firstPlaceVotes = RandomSelection_best_priority;
2648         //dprint("First place: ", ftos(firstPlace), "\n");
2649         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2650
2651         RandomSelection_Init();
2652         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2653                 if(i != firstPlace)
2654                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2655         secondPlace = RandomSelection_chosen_float;
2656         secondPlaceVotes = RandomSelection_best_priority;
2657         //dprint("Second place: ", ftos(secondPlace), "\n");
2658         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2659
2660         if(firstPlace == -1)
2661                 error("No first place in map vote... WTF?");
2662
2663         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2664                 return MapVote_Finished(firstPlace);
2665
2666         if(mapvote_keeptwotime)
2667                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2668                 {
2669                         float didntvote;
2670                         MapVote_TouchMask();
2671                         mapvote_message = "Now decide between the TOP TWO!";
2672                         mapvote_keeptwotime = 0;
2673                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2674                         result = strcat(result, ":", ftos(firstPlaceVotes));
2675                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2676                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2677                         didntvote = mapvote_voters;
2678                         for(i = 0; i < mapvote_count; ++i)
2679                                 if(mapvote_maps[i] != "")
2680                                 {
2681                                         didntvote -= mapvote_selections[i];
2682                                         if(i != firstPlace)
2683                                                 if(i != secondPlace)
2684                                                 {
2685                                                         result = strcat(result, ":", mapvote_maps[i]);
2686                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2687                                                         if(i < mapvote_count_real)
2688                                                         {
2689                                                                 strunzone(mapvote_maps[i]);
2690                                                                 mapvote_maps[i] = "";
2691                                                                 strunzone(mapvote_maps_pakfile[i]);
2692                                                                 mapvote_maps_pakfile[i] = "";
2693                                                         }
2694                                                 }
2695                                 }
2696                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2697                         if(autocvar_sv_eventlog)
2698                                 GameLogEcho(result);
2699                 }
2700
2701         return FALSE;
2702 }
2703 void MapVote_Tick()
2704 {
2705         float keeptwo;
2706         float totalvotes;
2707
2708         keeptwo = mapvote_keeptwotime;
2709         MapVote_CheckRules_1(); // count
2710         if(MapVote_CheckRules_2()) // decide
2711                 return;
2712
2713         totalvotes = 0;
2714         FOR_EACH_REALCLIENT(other)
2715         {
2716                 // hide scoreboard again
2717                 if(other.health != 2342)
2718                 {
2719                         other.health = 2342;
2720                         other.impulse = 0;
2721                         if(clienttype(other) == CLIENTTYPE_REAL)
2722                         {
2723                                 msg_entity = other;
2724                                 WriteByte(MSG_ONE, SVC_FINALE);
2725                                 WriteString(MSG_ONE, "");
2726                         }
2727                 }
2728
2729                 // clear possibly invalid votes
2730                 if(mapvote_maps[other.mapvote - 1] == "")
2731                         other.mapvote = 0;
2732                 // use impulses as new vote
2733                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2734                         if(mapvote_maps[other.impulse - 1] != "")
2735                         {
2736                                 other.mapvote = other.impulse;
2737                                 MapVote_TouchVotes(other);
2738                         }
2739                 other.impulse = 0;
2740
2741                 if(other.mapvote)
2742                         ++totalvotes;
2743         }
2744
2745         MapVote_CheckRules_1(); // just count
2746 }
2747 void MapVote_Start()
2748 {
2749         if(mapvote_run)
2750                 return;
2751
2752         // wait for stats to be sent first
2753         if(!playerstats_waitforme)
2754                 return;
2755
2756         MapInfo_Enumerate();
2757         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2758                 mapvote_run = TRUE;
2759 }
2760 void MapVote_Think()
2761 {
2762         if(!mapvote_run)
2763                 return;
2764
2765         if(alreadychangedlevel)
2766                 return;
2767
2768         if(time < mapvote_nextthink)
2769                 return;
2770         //dprint("tick\n");
2771
2772         mapvote_nextthink = time + 0.5;
2773
2774         if(!mapvote_initialized)
2775         {
2776                 if(autocvar_rescan_pending == 1)
2777                 {
2778                         cvar_set("rescan_pending", "2");
2779                         localcmd("fs_rescan\nrescan_pending 3\n");
2780                         return;
2781                 }
2782                 else if(autocvar_rescan_pending == 2)
2783                 {
2784                         return;
2785                 }
2786                 else if(autocvar_rescan_pending == 3)
2787                 {
2788                         // now build missing mapinfo files
2789                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2790                                 return;
2791
2792                         // we're done, start the timer
2793                         cvar_set("rescan_pending", "0");
2794                 }
2795
2796                 mapvote_initialized = TRUE;
2797                 if(DoNextMapOverride(0))
2798                         return;
2799                 if(!autocvar_g_maplist_votable || player_count <= 0)
2800                 {
2801                         GotoNextMap(0);
2802                         return;
2803                 }
2804                 MapVote_Init();
2805         }
2806
2807         MapVote_Tick();
2808 }
2809
2810 string GotoMap(string m)
2811 {
2812         if(!MapInfo_CheckMap(m))
2813                 return "The map you chose is not available on this server.";
2814         cvar_set("nextmap", m);
2815         cvar_set("timelimit", "-1");
2816         if(mapvote_initialized || alreadychangedlevel)
2817         {
2818                 if(DoNextMapOverride(0))
2819                         return "Map switch initiated.";
2820                 else
2821                         return "Hm... no. For some reason I like THIS map more.";
2822         }
2823         else
2824                 return "Map switch will happen after scoreboard.";
2825 }
2826
2827
2828 void EndFrame()
2829 {
2830         float altime;
2831         FOR_EACH_REALCLIENT(self)
2832         {
2833                 if(self.classname == "spectator")
2834                 {
2835                         if(self.enemy.typehitsound)
2836                                 self.typehit_time = time;
2837                         else if(self.enemy.hitsound)
2838                                 self.hit_time = time;
2839                 }
2840                 else
2841                 {
2842                         if(self.typehitsound)
2843                                 self.typehit_time = time;
2844                         else if(self.hitsound)
2845                                 self.hit_time = time;
2846                 }
2847         }
2848         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2849         // add 1 frametime because after this, engine SV_Physics
2850         // increases time by a frametime and then networks the frame
2851         // add another frametime because client shows everything with
2852         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2853         // needed!
2854         FOR_EACH_CLIENT(self)
2855         {
2856                 self.hitsound = FALSE;
2857                 self.typehitsound = FALSE;
2858                 antilag_record(self, altime);
2859         }
2860 }
2861
2862
2863 /*
2864  * RedirectionThink:
2865  * returns TRUE if redirecting
2866  */
2867 float redirection_timeout;
2868 float redirection_nextthink;
2869 float RedirectionThink()
2870 {
2871         float clients_found;
2872
2873         if(redirection_target == "")
2874                 return FALSE;
2875
2876         if(!redirection_timeout)
2877         {
2878                 cvar_set("sv_public", "-2");
2879                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2880                 if(redirection_target == "self")
2881                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2882                 else
2883                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2884         }
2885
2886         if(time < redirection_nextthink)
2887                 return TRUE;
2888
2889         redirection_nextthink = time + 1;
2890
2891         clients_found = 0;
2892         FOR_EACH_REALCLIENT(self)
2893         {
2894                 // TODO add timer
2895                 print("Redirecting: sending connect command to ", self.netname, "\n");
2896                 if(redirection_target == "self")
2897                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2898                 else
2899                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2900                 ++clients_found;
2901         }
2902
2903         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2904
2905         if(time > redirection_timeout || clients_found == 0)
2906                 localcmd("\nwait; wait; wait; quit\n");
2907
2908         return TRUE;
2909 }
2910
2911 void TargetMusic_RestoreGame();
2912 void RestoreGame()
2913 {
2914         // Loaded from a save game
2915         // some things then break, so let's work around them...
2916
2917         // Progs DB (capture records)
2918         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2919
2920         // Mapinfo
2921         MapInfo_Shutdown();
2922         MapInfo_Enumerate();
2923         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2924         WeaponStats_Init();
2925
2926         TargetMusic_RestoreGame();
2927 }
2928
2929 void Shutdown()
2930 {
2931         entity e;
2932
2933         gameover = 2;
2934
2935         if(world_initialized > 0)
2936         {
2937                 world_initialized = 0;
2938                 print("Saving persistent data...\n");
2939                 Ban_SaveBans();
2940
2941                 PlayerStats_EndMatch(0);
2942                 FOR_EACH_CLIENT(e)
2943                         PlayerStats_AddGlobalInfo(e);
2944                 PlayerStats_Shutdown();
2945
2946                 if(!cheatcount_total)
2947                 {
2948                         if(autocvar_sv_db_saveasdump)
2949                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2950                         else
2951                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2952                 }
2953                 if(autocvar_developer)
2954                 {
2955                         if(autocvar_sv_db_saveasdump)
2956                                 db_dump(TemporaryDB, "server-temp.db");
2957                         else
2958                                 db_save(TemporaryDB, "server-temp.db");
2959                 }
2960                 CheatShutdown(); // must be after cheatcount check
2961                 db_close(ServerProgsDB);
2962                 db_close(TemporaryDB);
2963                 print("done!\n");
2964                 // tell the bot system the game is ending now
2965                 bot_endgame();
2966
2967                 WeaponStats_Shutdown();
2968                 MapInfo_Shutdown();
2969         }
2970         else if(world_initialized == 0)
2971         {
2972                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2973         }
2974 }