qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_runematch");
 276                 BADCVAR("g_tdm");
 277                 BADCVAR("g_tdm_teams");
 278                 BADCVAR("leadlimit");
 279                 BADCVAR("nextmap");
 280                 BADCVAR("teamplay");
 281                 BADCVAR("timelimit");
 282
 283                 // long
 284                 BADCVAR("hostname");
 285                 BADCVAR("g_maplist");
 286                 BADCVAR("g_maplist_mostrecent");
 287                 BADCVAR("sv_motd");
 288
 289                 v = cvar_string(k);
 290                 d = cvar_defstring(k);
 291                 if(v == d)
 292                         continue;
 293
 294                 if(adding)
 295                 {
 296                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 297                         if(strlen(cvar_changes) > 16384)
 298                         {
 299                                 cvar_changes = "// too many settings have been changed to show them here\n";
 300                                 adding = 0;
 301                         }
 302                 }
 303
 304                 // now check if the changes are actually gameplay relevant
 305
 306                 // does nothing visible
 307                 BADCVAR("captureleadlimit_override");
 308                 BADCVAR("g_arena_point_leadlimit");
 309                 BADCVAR("g_balance_kill_delay");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ctf_captimerecord_always");
 312                 BADCVAR("g_ctf_flag_glowtrails");
 313                 BADCVAR("g_ctf_flag_pickup_verbosename");
 314                 BADCVAR("g_domination_point_leadlimit");
 315                 BADCVAR("g_forced_respawn");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_runematch_point_leadlimit");
 320                 BADCVAR("leadlimit_and_fraglimit");
 321                 BADCVAR("leadlimit_override");
 322                 BADCVAR("pausable");
 323                 BADCVAR("sv_allow_fullbright");
 324                 BADCVAR("sv_checkforpacketsduringsleep");
 325                 BADCVAR("sv_fraginfo");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADCVAR("welcome_message_time");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_fraginfo_");
 338                 BADPREFIX("sv_maxidle_");
 339                 BADPREFIX("sv_vote_");
 340                 BADPREFIX("timelimit_");
 341                 BADCVAR("gameversion");
 342                 BADPREFIX("gameversion_");
 343                 BADCVAR("sv_namechangetimer");
 344 #ifndef NO_LEGACY_NETWORKING
 345                 BADCVAR("sv_use_csqc_players"); // transition
 346 #endif
 347
 348                 // allowed changes to server admins (please sync this to server.cfg)
 349                 // vi commands:
 350                 //   :/"impure"/,$d
 351                 //   :g!,^\/\/[^ /],d
 352                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 353                 //   :%!sort
 354                 // yes, this does contain some redundant stuff, don't really care
 355                 BADCVAR("bot_config_file");
 356                 BADCVAR("bot_number");
 357                 BADCVAR("bot_prefix");
 358                 BADCVAR("bot_suffix");
 359                 BADCVAR("capturelimit_override");
 360                 BADCVAR("fraglimit_override");
 361                 BADCVAR("gametype");
 362                 BADCVAR("g_antilag");
 363                 BADCVAR("g_balance_teams");
 364                 BADCVAR("g_balance_teams_prevent_imbalance");
 365                 BADCVAR("g_balance_teams_scorefactor");
 366                 BADCVAR("g_ban_sync_trusted_servers");
 367                 BADCVAR("g_ban_sync_uri");
 368                 BADCVAR("g_ca_teams_override");
 369                 BADCVAR("g_ctf_ignore_frags");
 370                 BADCVAR("g_domination_point_limit");
 371                 BADCVAR("g_freezetag_teams_override");
 372                 BADCVAR("g_friendlyfire");
 373                 BADCVAR("g_fullbrightitems");
 374                 BADCVAR("g_fullbrightplayers");
 375                 BADCVAR("g_keyhunt_point_limit");
 376                 BADCVAR("g_keyhunt_teams_override");
 377                 BADCVAR("g_lms_lives_override");
 378                 BADCVAR("g_maplist");
 379                 BADCVAR("g_maplist_check_waypoints");
 380                 BADCVAR("g_maplist_mostrecent_count");
 381                 BADCVAR("g_maplist_shuffle");
 382                 BADCVAR("g_maplist_votable");
 383                 BADCVAR("g_maplist_votable_abstain");
 384                 BADCVAR("g_maplist_votable_nodetail");
 385                 BADCVAR("g_maplist_votable_suggestions");
 386                 BADCVAR("g_maxplayers");
 387                 BADCVAR("g_mirrordamage");
 388                 BADCVAR("g_nexball_goallimit");
 389                 BADCVAR("g_powerups");
 390                 BADCVAR("g_runematch_point_limit");
 391                 BADCVAR("g_start_delay");
 392                 BADCVAR("g_warmup");
 393                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 394                 BADCVAR("hostname");
 395                 BADCVAR("log_file");
 396                 BADCVAR("maxplayers");
 397                 BADCVAR("minplayers");
 398                 BADCVAR("net_address");
 399                 BADCVAR("port");
 400                 BADCVAR("rcon_password");
 401                 BADCVAR("rcon_restricted_commands");
 402                 BADCVAR("rcon_restricted_password");
 403                 BADCVAR("skill");
 404                 BADCVAR("sv_adminnick");
 405                 BADCVAR("sv_autoscreenshot");
 406                 BADCVAR("sv_autotaunt");
 407                 BADCVAR("sv_curl_defaulturl");
 408                 BADCVAR("sv_defaultcharacter");
 409                 BADCVAR("sv_defaultplayercolors");
 410                 BADCVAR("sv_defaultplayermodel");
 411                 BADCVAR("sv_defaultplayerskin");
 412                 BADCVAR("sv_maxidle");
 413                 BADCVAR("sv_maxrate");
 414                 BADCVAR("sv_motd");
 415                 BADCVAR("sv_public");
 416                 BADCVAR("sv_ready_restart");
 417                 BADCVAR("sv_status_privacy");
 418                 BADCVAR("sv_taunt");
 419                 BADCVAR("sv_vote_call");
 420                 BADCVAR("sv_vote_commands");
 421                 BADCVAR("sv_vote_majority_factor");
 422                 BADCVAR("sv_vote_master");
 423                 BADCVAR("sv_vote_master_commands");
 424                 BADCVAR("sv_vote_master_password");
 425                 BADCVAR("sv_vote_simple_majority_factor");
 426                 BADCVAR("sys_ticrate");
 427                 BADCVAR("teamplay_mode");
 428                 BADCVAR("timelimit_override");
 429                 BADCVAR("g_spawnshieldtime");
 430                 BADPREFIX("g_warmup_");
 431                 BADPREFIX("sv_ready_restart_");
 432
 433                 // mutators that announce themselves properly to the server browser
 434                 BADCVAR("g_minstagib");
 435                 BADCVAR("g_new_toys");
 436                 BADCVAR("g_nix");
 437
 438                 if(autocvar_g_minstagib)
 439                 {
 440                         BADCVAR("g_grappling_hook");
 441                         BADCVAR("g_jetpack");
 442                 }
 443 #undef BADPREFIX
 444 #undef BADCVAR
 445
 446                 if(pureadding)
 447                 {
 448                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 449                         if(strlen(cvar_purechanges) > 16384)
 450                         {
 451                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 452                                 pureadding = 0;
 453                         }
 454                 }
 455                 ++cvar_purechanges_count;
 456                 // WARNING: this variable is used for the server list
 457                 // NEVER dare to skip this code!
 458                 // Hacks to intentionally appearing as "pure server" even though you DO have
 459                 // modified settings may be punished by removal from the server list.
 460                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 461                 // though.
 462         }
 463         buf_del(h);
 464         if(cvar_changes == "")
 465                 cvar_changes = "// this server runs at default server settings\n";
 466         else
 467                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 468         cvar_changes = strzone(cvar_changes);
 469         if(cvar_purechanges == "")
 470                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 471         else
 472                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 473         cvar_purechanges = strzone(cvar_purechanges);
 474 }
 475
 476 void detect_maptype()
 477 {
 478 #if 0
 479         vector o, v;
 480         float i;
 481
 482         for(;;)
 483         {
 484                 o = world.mins;
 485                 o_x += random() * (world.maxs_x - world.mins_x);
 486                 o_y += random() * (world.maxs_y - world.mins_y);
 487                 o_z += random() * (world.maxs_z - world.mins_z);
 488
 489                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 490                 if(trace_fraction == 1)
 491                         continue;
 492
 493                 v = trace_endpos;
 494
 495                 for(i = 0; i < 64; i += 4)
 496                 {
 497                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 498         if(trace_fraction == 1)
 499                 continue;
 500                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 501                 }
 502
 503                 break;
 504         }
 505 #endif
 506 }
 507
 508 entity randomseed;
 509 float RandomSeed_Send(entity to, float sf)
 510 {
 511         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 512         WriteShort(MSG_ENTITY, self.cnt);
 513         return TRUE;
 514 }
 515 void RandomSeed_Think()
 516 {
 517         self.cnt = bound(0, floor(random() * 65536), 65535);
 518         self.nextthink = time + 5;
 519
 520         self.SendFlags |= 1;
 521 }
 522 void RandomSeed_Spawn()
 523 {
 524         randomseed = spawn();
 525         randomseed.think = RandomSeed_Think;
 526         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 527
 528         entity oldself;
 529         oldself = self;
 530         self = randomseed;
 531         self.think(); // sets random seed and nextthink
 532         self = oldself;
 533 }
 534
 535 void spawnfunc___init_dedicated_server(void)
 536 {
 537         // handler for _init/_init map (only for dedicated server initialization)
 538
 539         world_initialized = -1; // don't complain
 540         cvar = cvar_normal;
 541         cvar_string = cvar_string_normal;
 542         cvar_set = cvar_set_normal;
 543
 544         remove = remove_unsafely;
 545
 546         entity e;
 547         e = spawn();
 548         e.think = GotoFirstMap;
 549         e.nextthink = time; // this is usually 1 at this point
 550
 551         e = spawn();
 552         e.classname = "info_player_deathmatch"; // safeguard against player joining
 553
 554         self.classname = "worldspawn"; // safeguard against various stuff ;)
 555
 556         // needs to be done so early because of the constants they create
 557         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 558         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 559
 560         MapInfo_Enumerate();
 561         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 562 }
 563
 564 void Map_MarkAsRecent(string m);
 565 float world_already_spawned;
 566 void Nagger_Init();
 567 void ClientInit_Spawn();
 568 void WeaponStats_Init();
 569 void WeaponStats_Shutdown();
 570 void spawnfunc_worldspawn (void)
 571 {
 572         float fd, l, i, j, n;
 573         string s, col;
 574
 575         cvar = cvar_normal;
 576         cvar_string = cvar_string_normal;
 577         cvar_set = cvar_set_normal;
 578
 579         if(world_already_spawned)
 580                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 581         world_already_spawned = TRUE;
 582
 583         remove = remove_safely; // during spawning, watch what you remove!
 584
 585         check_unacceptable_compiler_bugs();
 586
 587         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 588
 589         compressShortVector_init();
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         // needs to be done so early because of the constants they create
 601         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 602         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 788         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 789         Nagger_Init();
 790
 791         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 792         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 793         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 794         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 795         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 796         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 797         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 798         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 799         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 800         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 801         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 802         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 803         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 804
 805         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 806         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 807
 808         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         // misc
 821         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 822
 823         next_pingtime = time + 5;
 824
 825         detect_maptype();
 826
 827         // set up information replies for clients and server to use
 828         lsmaps_reply = "^7Maps available: ";
 829         lsnewmaps_reply = "^7Maps without a record set: ";
 830         for(i = 0, j = 0; i < MapInfo_count; ++i)
 831         {
 832                 if(MapInfo_Get_ByID(i))
 833                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 834                         {
 835                                 if(mod(i, 2))
 836                                         col = "^2";
 837                                 else
 838                                         col = "^3";
 839
 840                                 ++j;
 841
 842                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 843
 844                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 845                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 846                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 847                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 848                         }
 849         }
 850
 851         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 852         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 853
 854         maplist_reply = "^7Maps in list: ";
 855         n = tokenize_console(autocvar_g_maplist);
 856         for(i = 0, j = 0; i < n; ++i)
 857         {
 858                 if(MapInfo_CheckMap(argv(i)))
 859                 {
 860                         if(mod(j, 2))
 861                                 col = "^2";
 862                         else
 863                                 col = "^3";
 864                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 865                         ++j;
 866                 }
 867         }
 868         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 869         MapInfo_ClearTemps();
 870
 871         for(i = 0; i < 10; ++i)
 872         {
 873                 s = getrecords(i);
 874                 if (s)
 875                         records_reply[i] = strzone(s);
 876         }
 877
 878         ladder_reply = strzone(getladder());
 879
 880         rankings_reply = strzone(getrankings());
 881
 882         // begin other init
 883         ClientInit_Spawn();
 884         RandomSeed_Spawn();
 885         PingPLReport_Spawn();
 886
 887         CheatInit();
 888
 889         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 890
 891         // fill sv_curl_serverpackages from .serverpackage files
 892         if(autocvar_sv_curl_serverpackages_auto)
 893         {
 894                 s = "";
 895                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 896                 for(i = 0; i < n; ++i)
 897                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 898                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 899                                 s = strcat(s, " ", argv(i));
 900                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 901                 if(fd >= 0)
 902                 {
 903                         j = search_getsize(fd);
 904                         for(i = 0; i < j; ++i)
 905                                 s = strcat(s, " ", search_getfilename(fd, i));
 906                         search_end(fd);
 907                 }
 908                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 909                 if(fd >= 0)
 910                 {
 911                         j = search_getsize(fd);
 912                         for(i = 0; i < j; ++i)
 913                                 s = strcat(s, " ", search_getfilename(fd, i));
 914                         search_end(fd);
 915                 }
 916                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 917         }
 918
 919         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 920         modname = "Xonotic";
 921         // physics/balance/config changes that count as mod
 922         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 923                 modname = cvar_string("g_mod_physics");
 924         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 925                 modname = cvar_string("g_mod_balance");
 926         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 927                 modname = cvar_string("g_mod_config");
 928         // weird mutators that deserve to count as mod
 929         if(autocvar_g_minstagib)
 930                 modname = "MinstaGib";
 931         // extra mutators that deserve to count as mod
 932         MUTATOR_CALLHOOK(SetModname);
 933
 934         // save it for later
 935         modname = strzone(modname);
 936
 937         WinningConditionHelper(); // set worldstatus
 938
 939         world_initialized = 1;
 940 }
 941
 942 void spawnfunc_light (void)
 943 {
 944         //makestatic (self); // Who the f___ did that?
 945         remove(self);
 946 }
 947
 948 string GetGametype()
 949 {
 950         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         dprint(": no waypoints\n");
 994                         return FALSE;
 995                 }
 996                 dprint(": has waypoints\n");
 997         }
 998
 999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return FALSE;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return FALSE;
1018                 }
1019                 dprint("right size\n");
1020                 return TRUE;
1021         }
1022         dprint(": not found\n");
1023         return TRUE;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void Map_Goto(float reinit)
1099 {
1100         MapInfo_LoadMap(getmapname_stored, reinit);
1101 }
1102
1103 // return codes of map selectors:
1104 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1105 //   -2 = permanent failure
1106 float() MaplistMethod_Iterate = // usual method
1107 {
1108         float pass, i;
1109
1110         for(pass = 1; pass <= 2; ++pass)
1111         {
1112                 for(i = 1; i < Map_Count; ++i)
1113                 {
1114                         float mapindex;
1115                         mapindex = mod(i + Map_Current, Map_Count);
1116                         if(Map_Check(mapindex, pass))
1117                                 return mapindex;
1118                 }
1119         }
1120         return -1;
1121 }
1122
1123 float() MaplistMethod_Repeat = // fallback method
1124 {
1125         if(Map_Check(Map_Current, 2))
1126                 return Map_Current;
1127         return -2;
1128 }
1129
1130 float() MaplistMethod_Random = // random map selection
1131 {
1132         float i, imax;
1133
1134         imax = 42;
1135
1136         for(i = 0; i <= imax; ++i)
1137         {
1138                 float mapindex;
1139                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1140                 if(Map_Check(mapindex, 1))
1141                         return mapindex;
1142         }
1143         return -1;
1144 }
1145
1146 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1147 // the exponent sets a bias on the map selection:
1148 // the higher the exponent, the less likely "shortly repeated" same maps are
1149 {
1150         float i, j, imax, insertpos;
1151
1152         imax = 42;
1153
1154         for(i = 0; i <= imax; ++i)
1155         {
1156                 string newlist;
1157
1158                 // now reinsert this at another position
1159                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1160                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1161                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1162                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1163
1164                 // insert the current map there
1165                 newlist = "";
1166                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1167                         newlist = strcat(newlist, " ", argv(j));
1168                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1169                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1170                         newlist = strcat(newlist, " ", argv(j));
1171                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1172                 cvar_set("g_maplist", newlist);
1173                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1174
1175                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1176                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1177                 if(Map_Check(Map_Current, 1))
1178                         return Map_Current;
1179         }
1180         return -1;
1181 }
1182
1183 void Maplist_Init()
1184 {
1185         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1186         if(Map_Count == 0)
1187         {
1188                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1189                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1190                 if(autocvar_g_maplist_shuffle)
1191                         ShuffleMaplist();
1192                 localcmd("\nmenu_cmd sync\n");
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         }
1195         if(Map_Count == 0)
1196                 error("empty maplist, cannot select a new map");
1197         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1198
1199         if(Map_Current_Name)
1200                 strunzone(Map_Current_Name);
1201         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1202         // this may or may not be correct, but who cares, in the worst case a map
1203         // isn't chosen in the first pass that should have been
1204 }
1205
1206 string GetNextMap()
1207 {
1208         float nextMap;
1209
1210         Maplist_Init();
1211         nextMap = -1;
1212
1213         if(nextMap == -1)
1214                 if(autocvar_g_maplist_shuffle > 0)
1215                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1216
1217         if(nextMap == -1)
1218                 if(autocvar_g_maplist_selectrandom)
1219                         nextMap = MaplistMethod_Random();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Iterate();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Repeat();
1226
1227         if(nextMap >= 0)
1228         {
1229                 Map_Goto_SetFloat(nextMap);
1230                 return getmapname_stored;
1231         }
1232
1233         return "";
1234 }
1235
1236 float DoNextMapOverride(float reinit)
1237 {
1238         if(autocvar_g_campaign)
1239         {
1240                 CampaignPostIntermission();
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         if(autocvar_quit_when_empty)
1245         {
1246                 if(player_count <= currentbots)
1247                 {
1248                         localcmd("quit\n");
1249                         alreadychangedlevel = TRUE;
1250                         return TRUE;
1251                 }
1252         }
1253         if(autocvar_quit_and_redirect != "")
1254         {
1255                 redirection_target = strzone(autocvar_quit_and_redirect);
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1260         {
1261                 localcmd("restart\n");
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if(autocvar_nextmap != "")
1266                 if(MapInfo_CheckMap(autocvar_nextmap))
1267                 {
1268                         Map_Goto_SetStr(autocvar_nextmap);
1269                         Map_Goto(reinit);
1270                         alreadychangedlevel = TRUE;
1271                         return TRUE;
1272                 }
1273         if(!reinit && autocvar_lastlevel)
1274         {
1275                 cvar_settemp_restore();
1276                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         return FALSE;
1281 }
1282
1283 void GotoNextMap(float reinit)
1284 {
1285         //string nextmap;
1286         //float n, nummaps;
1287         //string s;
1288         if (alreadychangedlevel)
1289                 return;
1290         alreadychangedlevel = TRUE;
1291
1292         {
1293                 string nextMap;
1294                 float allowReset;
1295
1296                 for(allowReset = 1; allowReset >= 0; --allowReset)
1297                 {
1298                         nextMap = GetNextMap();
1299                         if(nextMap != "")
1300                                 break;
1301
1302                         if(allowReset)
1303                         {
1304                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1305                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1306                                 if(autocvar_g_maplist_shuffle)
1307                                         ShuffleMaplist();
1308                                 localcmd("\nmenu_cmd sync\n");
1309                         }
1310                         else
1311                         {
1312                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1313                         }
1314                 }
1315                 Map_Goto(reinit);
1316         }
1317 }
1318
1319
1320 /*
1321 ============
1322 IntermissionThink
1323
1324 When the player presses attack or jump, change to the next level
1325 ============
1326 */
1327 .float autoscreenshot;
1328 void() MapVote_Start;
1329 void() MapVote_Think;
1330 float mapvote_initialized;
1331 void IntermissionThink()
1332 {
1333         FixIntermissionClient(self);
1334
1335         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1336         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1337
1338         if( (server_screenshot || client_screenshot)
1339                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1340         {
1341                 self.autoscreenshot = -1;
1342                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1343                 return;
1344         }
1345
1346         if (time < intermission_exittime)
1347                 return;
1348
1349         if(!mapvote_initialized)
1350                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1351                         return;
1352
1353         MapVote_Start();
1354 }
1355
1356 /*
1357 ============
1358 FindIntermission
1359
1360 Returns the entity to view from
1361 ============
1362 */
1363 /*
1364 entity FindIntermission()
1365 {
1366         local   entity spot;
1367         local   float cyc;
1368
1369 // look for info_intermission first
1370         spot = find (world, classname, "info_intermission");
1371         if (spot)
1372         {       // pick a random one
1373                 cyc = random() * 4;
1374                 while (cyc > 1)
1375                 {
1376                         spot = find (spot, classname, "info_intermission");
1377                         if (!spot)
1378                                 spot = find (spot, classname, "info_intermission");
1379                         cyc = cyc - 1;
1380                 }
1381                 return spot;
1382         }
1383
1384 // then look for the start position
1385         spot = find (world, classname, "info_player_start");
1386         if (spot)
1387                 return spot;
1388
1389 // testinfo_player_start is only found in regioned levels
1390         spot = find (world, classname, "testplayerstart");
1391         if (spot)
1392                 return spot;
1393
1394 // then look for the start position
1395         spot = find (world, classname, "info_player_deathmatch");
1396         if (spot)
1397                 return spot;
1398
1399         //objerror ("FindIntermission: no spot");
1400         return world;
1401 }
1402 */
1403
1404 /*
1405 ===============================================================================
1406
1407 RULES
1408
1409 ===============================================================================
1410 */
1411
1412 void DumpStats(float final)
1413 {
1414         float file;
1415         string s;
1416         float to_console;
1417         float to_eventlog;
1418         float to_file;
1419         float i;
1420
1421         to_console = autocvar_sv_logscores_console;
1422         to_eventlog = autocvar_sv_eventlog;
1423         to_file = autocvar_sv_logscores_file;
1424
1425         if(!final)
1426         {
1427                 to_console = TRUE; // always print printstats replies
1428                 to_eventlog = FALSE; // but never print them to the event log
1429         }
1430
1431         if(to_eventlog)
1432                 if(autocvar_sv_eventlog_console)
1433                         to_console = FALSE; // otherwise we get the output twice
1434
1435         if(final)
1436                 s = ":scores:";
1437         else
1438                 s = ":status:";
1439         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1440
1441         if(to_console)
1442                 print(s, "\n");
1443         if(to_eventlog)
1444                 GameLogEcho(s);
1445
1446         file = -1;
1447         if(to_file)
1448         {
1449                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1450                 if(file == -1)
1451                         to_file = FALSE;
1452                 else
1453                         fputs(file, strcat(s, "\n"));
1454         }
1455
1456         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1457         if(to_console)
1458                 print(s, "\n");
1459         if(to_eventlog)
1460                 GameLogEcho(s);
1461         if(to_file)
1462                 fputs(file, strcat(s, "\n"));
1463
1464         FOR_EACH_CLIENT(other)
1465         {
1466                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1467                 {
1468                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1469                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1470                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1471                                 s = strcat(s, ftos(other.team), ":");
1472                         else
1473                                 s = strcat(s, "spectator:");
1474
1475                         if(to_console)
1476                                 print(s, other.netname, "\n");
1477                         if(to_eventlog)
1478                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1479                         if(to_file)
1480                                 fputs(file, strcat(s, other.netname, "\n"));
1481                 }
1482         }
1483
1484         if(teamplay)
1485         {
1486                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1487                 if(to_console)
1488                         print(s, "\n");
1489                 if(to_eventlog)
1490                         GameLogEcho(s);
1491                 if(to_file)
1492                         fputs(file, strcat(s, "\n"));
1493
1494                 for(i = 1; i < 16; ++i)
1495                 {
1496                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1497                         s = strcat(s, ":", ftos(i));
1498                         if(to_console)
1499                                 print(s, "\n");
1500                         if(to_eventlog)
1501                                 GameLogEcho(s);
1502                         if(to_file)
1503                                 fputs(file, strcat(s, "\n"));
1504                 }
1505         }
1506
1507         if(to_console)
1508                 print(":end\n");
1509         if(to_eventlog)
1510                 GameLogEcho(":end");
1511         if(to_file)
1512         {
1513                 fputs(file, ":end\n");
1514                 fclose(file);
1515         }
1516 }
1517
1518 void FixIntermissionClient(entity e)
1519 {
1520         string s;
1521         if(!e.autoscreenshot) // initial call
1522         {
1523                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1524                 e.health = -2342;
1525                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1526                 e.solid = SOLID_NOT;
1527                 e.movetype = MOVETYPE_NONE;
1528                 e.takedamage = DAMAGE_NO;
1529                 if(e.weaponentity)
1530                 {
1531                         e.weaponentity.effects = EF_NODRAW;
1532                         if (e.weaponentity.weaponentity)
1533                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1534                 }
1535                 if(clienttype(e) == CLIENTTYPE_REAL)
1536                 {
1537                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1538                         s = autocvar_sv_intermission_cdtrack;
1539                         if(s != "")
1540                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1541                         msg_entity = e;
1542                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1543                 }
1544         }
1545 }
1546
1547 void minstagib_stop_countdown(entity e);
1548 /*
1549 go to the next level for deathmatch
1550 only called if a time or frag limit has expired
1551 */
1552 void NextLevel()
1553 {
1554         gameover = TRUE;
1555
1556         intermission_running = 1;
1557
1558 // enforce a wait time before allowing changelevel
1559         if(player_count > 0)
1560                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1561         else
1562                 intermission_exittime = -1;
1563
1564         /*
1565         WriteByte (MSG_ALL, SVC_CDTRACK);
1566         WriteByte (MSG_ALL, 3);
1567         WriteByte (MSG_ALL, 3);
1568         // done in FixIntermission
1569         */
1570
1571         //pos = FindIntermission ();
1572
1573         VoteReset();
1574
1575         DumpStats(TRUE);
1576
1577         // send statistics
1578         entity e;
1579         PlayerStats_EndMatch(1);
1580         FOR_EACH_CLIENT(e)
1581                 PlayerStats_AddGlobalInfo(e);
1582         PlayerStats_Shutdown();
1583         WeaponStats_Shutdown();
1584
1585         if(autocvar_sv_eventlog)
1586                 GameLogEcho(":gameover");
1587
1588         GameLogClose();
1589
1590         FOR_EACH_PLAYER(other) {
1591                 minstagib_stop_countdown(other);
1592                 FixIntermissionClient(other);
1593                 if(other.winning)
1594                         bprint(other.netname, " ^7wins.\n");
1595         }
1596
1597         if(autocvar_g_campaign)
1598                 CampaignPreIntermission();
1599
1600         MUTATOR_CALLHOOK(MatchEnd);
1601
1602         localcmd("\nsv_hook_gameend\n");
1603 }
1604
1605 /*
1606 ============
1607 CheckRules_Player
1608
1609 Exit deathmatch games upon conditions
1610 ============
1611 */
1612 void CheckRules_Player()
1613 {
1614         if (gameover)   // someone else quit the game already
1615                 return;
1616
1617         if(self.deadflag == DEAD_NO)
1618                 self.play_time += frametime;
1619
1620         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1621         //   (div0: and that in CheckRules_World please)
1622 }
1623
1624 float checkrules_equality;
1625 float checkrules_suddendeathwarning;
1626 float checkrules_suddendeathend;
1627 float checkrules_overtimesadded; //how many overtimes have been already added
1628
1629 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1630 float WINNING_YES = 1; // winner found
1631 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1632 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1633
1634 float InitiateSuddenDeath()
1635 {
1636         // Check first whether normal overtimes could be added before initiating suddendeath mode
1637         // - for this timelimit_overtime needs to be >0 of course
1638         // - also check the winning condition calculated in the previous frame and only add normal overtime
1639         //   again, if at the point at which timelimit would be extended again, still no winner was found
1640         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1641         {
1642                 return 1; // need to call InitiateOvertime later
1643         }
1644         else
1645         {
1646                 if(!checkrules_suddendeathend)
1647                 {
1648                         if(autocvar_g_campaign)
1649                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1650                         else
1651                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1652                         if(g_race && !g_race_qualifying)
1653                                 race_StartCompleting();
1654                 }
1655                 return 0;
1656         }
1657 }
1658
1659 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1660 {
1661         ++checkrules_overtimesadded;
1662         //add one more overtime by simply extending the timelimit
1663         float tl;
1664         tl = autocvar_timelimit;
1665         tl += autocvar_timelimit_overtime;
1666         cvar_set("timelimit", ftos(tl));
1667         string minutesPlural;
1668         if (autocvar_timelimit_overtime == 1)
1669                 minutesPlural = " ^3minute";
1670         else
1671                 minutesPlural = " ^3minutes";
1672
1673         bcenterprint(
1674                 strcat(
1675                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1676                         ftos(autocvar_timelimit_overtime),
1677                         minutesPlural,
1678                         " to the game!"
1679                 )
1680         );
1681 }
1682
1683 float GetWinningCode(float fraglimitreached, float equality)
1684 {
1685         if(autocvar_g_campaign == 1)
1686                 if(fraglimitreached)
1687                         return WINNING_YES;
1688                 else
1689                         return WINNING_NO;
1690
1691         else
1692                 if(equality)
1693                         if(fraglimitreached)
1694                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1695                         else
1696                                 return WINNING_NEVER;
1697                 else
1698                         if(fraglimitreached)
1699                                 return WINNING_YES;
1700                         else
1701                                 return WINNING_NO;
1702 }
1703
1704 // set the .winning flag for exactly those players with a given field value
1705 void SetWinners(.float field, float value)
1706 {
1707         entity head;
1708         FOR_EACH_PLAYER(head)
1709                 head.winning = (head.field == value);
1710 }
1711
1712 // set the .winning flag for those players with a given field value
1713 void AddWinners(.float field, float value)
1714 {
1715         entity head;
1716         FOR_EACH_PLAYER(head)
1717                 if(head.field == value)
1718                         head.winning = 1;
1719 }
1720
1721 // clear the .winning flags
1722 void ClearWinners(void)
1723 {
1724         entity head;
1725         FOR_EACH_PLAYER(head)
1726                 head.winning = 0;
1727 }
1728
1729 // Onslaught winning condition:
1730 // game terminates if only one team has a working generator (or none)
1731 float WinningCondition_Onslaught()
1732 {
1733         entity head;
1734         float t1, t2, t3, t4;
1735
1736         WinningConditionHelper(); // set worldstatus
1737
1738         if(inWarmupStage)
1739                 return WINNING_NO;
1740
1741         // first check if the game has ended
1742         t1 = t2 = t3 = t4 = 0;
1743         head = find(world, classname, "onslaught_generator");
1744         while (head)
1745         {
1746                 if (head.health > 0)
1747                 {
1748                         if (head.team == COLOR_TEAM1) t1 = 1;
1749                         if (head.team == COLOR_TEAM2) t2 = 1;
1750                         if (head.team == COLOR_TEAM3) t3 = 1;
1751                         if (head.team == COLOR_TEAM4) t4 = 1;
1752                 }
1753                 head = find(head, classname, "onslaught_generator");
1754         }
1755         if (t1 + t2 + t3 + t4 < 2)
1756         {
1757                 // game over, only one team remains (or none)
1758                 ClearWinners();
1759                 if (t1) SetWinners(team, COLOR_TEAM1);
1760                 if (t2) SetWinners(team, COLOR_TEAM2);
1761                 if (t3) SetWinners(team, COLOR_TEAM3);
1762                 if (t4) SetWinners(team, COLOR_TEAM4);
1763                 dprint("Have a winner, ending game.\n");
1764                 return WINNING_YES;
1765         }
1766
1767         // Two or more teams remain
1768         return WINNING_NO;
1769 }
1770
1771 float LMS_NewPlayerLives()
1772 {
1773         float fl;
1774         fl = autocvar_fraglimit;
1775         if(fl == 0)
1776                 fl = 999;
1777
1778         // first player has left the game for dying too much? Nobody else can get in.
1779         if(lms_lowest_lives < 1)
1780                 return 0;
1781
1782         if(!autocvar_g_lms_join_anytime)
1783                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1784                         return 0;
1785
1786         return bound(1, lms_lowest_lives, fl);
1787 }
1788
1789 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1790 // they win. Otherwise the defending team wins once the timelimit passes.
1791 void assault_new_round();
1792 float WinningCondition_Assault()
1793 {
1794         float status;
1795
1796         WinningConditionHelper(); // set worldstatus
1797
1798         status = WINNING_NO;
1799         // as the timelimit has not yet passed just assume the defending team will win
1800         if(assault_attacker_team == COLOR_TEAM1)
1801         {
1802                 SetWinners(team, COLOR_TEAM2);
1803         }
1804         else
1805         {
1806                 SetWinners(team, COLOR_TEAM1);
1807         }
1808
1809         entity ent;
1810         ent = find(world, classname, "target_assault_roundend");
1811         if(ent)
1812         {
1813                 if(ent.winning) // round end has been triggered by attacking team
1814                 {
1815                         bprint("ASSAULT: round completed...\n");
1816                         SetWinners(team, assault_attacker_team);
1817
1818                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1819
1820                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1821                         {
1822                                 status = WINNING_YES;
1823                         }
1824                         else
1825                         {
1826                                 entity oldself;
1827                                 oldself = self;
1828                                 self = ent;
1829                                 assault_new_round();
1830                                 self = oldself;
1831                         }
1832                 }
1833         }
1834
1835         return status;
1836 }
1837
1838 // LMS winning condition: game terminates if and only if there's at most one
1839 // one player who's living lives. Top two scores being equal cancels the time
1840 // limit.
1841 float WinningCondition_LMS()
1842 {
1843         entity head, head2;
1844         float have_player;
1845         float have_players;
1846         float l;
1847
1848         have_player = FALSE;
1849         have_players = FALSE;
1850         l = LMS_NewPlayerLives();
1851
1852         head = find(world, classname, "player");
1853         if(head)
1854                 have_player = TRUE;
1855         head2 = find(head, classname, "player");
1856         if(head2)
1857                 have_players = TRUE;
1858
1859         if(have_player)
1860         {
1861                 // we have at least one player
1862                 if(have_players)
1863                 {
1864                         // two or more active players - continue with the game
1865                 }
1866                 else
1867                 {
1868                         // exactly one player?
1869
1870                         ClearWinners();
1871                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1872
1873                         if(l)
1874                         {
1875                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1876                                 return WINNING_NO;
1877                         }
1878                         else
1879                         {
1880                                 // a winner!
1881                                 // and assign him his first place
1882                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1883                                 return WINNING_YES;
1884                         }
1885                 }
1886         }
1887         else
1888         {
1889                 // nobody is playing at all...
1890                 if(l)
1891                 {
1892                         // wait for players...
1893                 }
1894                 else
1895                 {
1896                         // SNAFU (maybe a draw game?)
1897                         ClearWinners();
1898                         dprint("No players, ending game.\n");
1899                         return WINNING_YES;
1900                 }
1901         }
1902
1903         // When we get here, we have at least two players who are actually LIVING,
1904         // now check if the top two players have equal score.
1905         WinningConditionHelper();
1906
1907         ClearWinners();
1908         if(WinningConditionHelper_winner)
1909                 WinningConditionHelper_winner.winning = TRUE;
1910         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1911                 return WINNING_NEVER;
1912
1913         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1914         return WINNING_NO;
1915 }
1916
1917 void ShuffleMaplist()
1918 {
1919         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1920 }
1921
1922 float leaderfrags;
1923 float WinningCondition_Scores(float limit, float leadlimit)
1924 {
1925         float limitreached;
1926
1927         // TODO make everything use THIS winning condition (except LMS)
1928         WinningConditionHelper();
1929
1930         if(teamplay)
1931         {
1932                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1933                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1934                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1935                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1936         }
1937
1938         ClearWinners();
1939         if(WinningConditionHelper_winner)
1940                 WinningConditionHelper_winner.winning = 1;
1941         if(WinningConditionHelper_winnerteam >= 0)
1942                 SetWinners(team, WinningConditionHelper_winnerteam);
1943
1944         if(WinningConditionHelper_lowerisbetter)
1945         {
1946                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1947                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1948                 limit = -limit;
1949         }
1950
1951         if(WinningConditionHelper_zeroisworst)
1952                 leadlimit = 0; // not supported in this mode
1953
1954         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1955         // these modes always score in increments of 1, thus this makes sense
1956         {
1957                 if(leaderfrags != WinningConditionHelper_topscore)
1958                 {
1959                         leaderfrags = WinningConditionHelper_topscore;
1960
1961                         if (limit)
1962                         if (leaderfrags == limit - 1)
1963                                 Announce("1fragleft");
1964                         else if (leaderfrags == limit - 2)
1965                                 Announce("2fragsleft");
1966                         else if (leaderfrags == limit - 3)
1967                                 Announce("3fragsleft");
1968                 }
1969         }
1970
1971         limitreached = FALSE;
1972         if(limit)
1973                 if(WinningConditionHelper_topscore >= limit)
1974                         limitreached = TRUE;
1975         if(leadlimit)
1976         {
1977                 float leadlimitreached;
1978                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1979                 if(autocvar_leadlimit_and_fraglimit)
1980                         limitreached = (limitreached && leadlimitreached);
1981                 else
1982                         limitreached = (limitreached || leadlimitreached);
1983         }
1984
1985         if(limit)
1986                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1987
1988         return GetWinningCode(
1989                 WinningConditionHelper_topscore && limitreached,
1990                 WinningConditionHelper_equality
1991         );
1992 }
1993
1994 float WinningCondition_Race(float fraglimit)
1995 {
1996         float wc;
1997         entity p;
1998         float n, c;
1999
2000         n = 0;
2001         c = 0;
2002         FOR_EACH_PLAYER(p)
2003         {
2004                 ++n;
2005                 if(p.race_completed)
2006                         ++c;
2007         }
2008         if(n && (n == c))
2009                 return WINNING_YES;
2010         wc = WinningCondition_Scores(fraglimit, 0);
2011
2012         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2013         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2014         // do NOT support equality when the laps are all raced!
2015                 return WINNING_STARTSUDDENDEATHOVERTIME;
2016         else
2017                 return WINNING_NEVER;
2018 }
2019
2020 float WinningCondition_QualifyingThenRace(float limit)
2021 {
2022         float wc;
2023         wc = WinningCondition_Scores(limit, 0);
2024
2025         // NEVER initiate overtime
2026         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2027         {
2028                 return WINNING_YES;
2029         }
2030
2031         return wc;
2032 }
2033
2034 float WinningCondition_RanOutOfSpawns()
2035 {
2036         entity head;
2037
2038         if(have_team_spawns <= 0)
2039                 return WINNING_NO;
2040
2041         if(autocvar_g_spawn_useallspawns <= 0)
2042                 return WINNING_NO;
2043
2044         if(!some_spawn_has_been_used)
2045                 return WINNING_NO;
2046
2047         team1_score = team2_score = team3_score = team4_score = 0;
2048
2049         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2050         {
2051                 if(head.team == COLOR_TEAM1)
2052                         team1_score = 1;
2053                 else if(head.team == COLOR_TEAM2)
2054                         team2_score = 1;
2055                 else if(head.team == COLOR_TEAM3)
2056                         team3_score = 1;
2057                 else if(head.team == COLOR_TEAM4)
2058                         team4_score = 1;
2059         }
2060
2061         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2062         {
2063                 if(head.team == COLOR_TEAM1)
2064                         team1_score = 1;
2065                 else if(head.team == COLOR_TEAM2)
2066                         team2_score = 1;
2067                 else if(head.team == COLOR_TEAM3)
2068                         team3_score = 1;
2069                 else if(head.team == COLOR_TEAM4)
2070                         team4_score = 1;
2071         }
2072
2073         ClearWinners();
2074         if(team1_score + team2_score + team3_score + team4_score == 0)
2075         {
2076                 checkrules_equality = TRUE;
2077                 return WINNING_YES;
2078         }
2079         else if(team1_score + team2_score + team3_score + team4_score == 1)
2080         {
2081                 float t, i;
2082                 if(team1_score)
2083                         t = COLOR_TEAM1;
2084                 else if(team2_score)
2085                         t = COLOR_TEAM2;
2086                 else if(team3_score)
2087                         t = COLOR_TEAM3;
2088                 else // if(team4_score)
2089                         t = COLOR_TEAM4;
2090                 CheckAllowedTeams(world);
2091                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2092                 {
2093                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2094                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2095                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2096                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2097                 }
2098
2099                 AddWinners(team, t);
2100                 return WINNING_YES;
2101         }
2102         else
2103                 return WINNING_NO;
2104 }
2105
2106 /*
2107 ============
2108 CheckRules_World
2109
2110 Exit deathmatch games upon conditions
2111 ============
2112 */
2113 void ReadyRestart();
2114 void CheckRules_World()
2115 {
2116         float timelimit;
2117         float fraglimit;
2118         float leadlimit;
2119
2120         VoteThink();
2121         MapVote_Think();
2122
2123         SetDefaultAlpha();
2124
2125         /*
2126         MapVote_Think should now do that part
2127         if (intermission_running)
2128                 if (time >= intermission_exittime + 60)
2129                 {
2130                         if(!DoNextMapOverride())
2131                                 GotoNextMap();
2132                         return;
2133                 }
2134         */
2135
2136         if (gameover)   // someone else quit the game already
2137         {
2138                 if(player_count == 0) // Nobody there? Then let's go to the next map
2139                         MapVote_Start();
2140                         // this will actually check the player count in the next frame
2141                         // again, but this shouldn't hurt
2142                 return;
2143         }
2144
2145         timelimit = autocvar_timelimit * 60;
2146         fraglimit = autocvar_fraglimit;
2147         leadlimit = autocvar_leadlimit;
2148
2149         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2150         {
2151                 if(timelimit > 0)
2152                         timelimit = 0; // timelimit is not made for warmup
2153                 if(fraglimit > 0)
2154                         fraglimit = 0; // no fraglimit for now
2155                 leadlimit = 0; // no leadlimit for now
2156         }
2157
2158         if(timelimit > 0)
2159         {
2160                 timelimit += game_starttime;
2161         }
2162         else if (timelimit < 0)
2163         {
2164                 // endmatch
2165                 NextLevel();
2166                 return;
2167         }
2168
2169         if(g_onslaught)
2170                 timelimit = 0; // ONS has its own overtime rule
2171
2172         float wantovertime;
2173         wantovertime = 0;
2174
2175         if(timelimit > game_starttime)
2176                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2177         else
2178                 game_completion_ratio = 0;
2179
2180         if(checkrules_suddendeathend)
2181         {
2182                 if(!checkrules_suddendeathwarning)
2183                 {
2184                         checkrules_suddendeathwarning = TRUE;
2185                         if(g_race && !g_race_qualifying)
2186                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2187                         else
2188                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2189                 }
2190         }
2191         else
2192         {
2193                 if (timelimit && time >= timelimit)
2194                 {
2195                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2196                         {
2197                                 float totalplayers;
2198                                 float playerswithlaps;
2199                                 float readyplayers;
2200                                 entity head;
2201                                 totalplayers = playerswithlaps = readyplayers = 0;
2202                                 FOR_EACH_PLAYER(head)
2203                                 {
2204                                         ++totalplayers;
2205                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2206                                                 ++playerswithlaps;
2207                                         if(head.ready)
2208                                                 ++readyplayers;
2209                                 }
2210
2211                                 // at least 2 of the players have completed a lap: start the RACE
2212                                 // otherwise, the players should end the qualifying on their own
2213                                 if(readyplayers || playerswithlaps >= 2)
2214                                 {
2215                                         checkrules_suddendeathend = 0;
2216                                         ReadyRestart(); // go to race
2217                                         return;
2218                                 }
2219                                 else
2220                                         wantovertime |= InitiateSuddenDeath();
2221                         }
2222                         else
2223                                 wantovertime |= InitiateSuddenDeath();
2224                 }
2225         }
2226
2227         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2228         {
2229                 NextLevel();
2230                 return;
2231         }
2232
2233         float checkrules_status;
2234         checkrules_status = WinningCondition_RanOutOfSpawns();
2235         if(checkrules_status == WINNING_YES)
2236         {
2237                 bprint("Hey! Someone ran out of spawns!\n");
2238         }
2239         else if(g_race && !g_race_qualifying && timelimit >= 0)
2240         {
2241                 checkrules_status = WinningCondition_Race(fraglimit);
2242                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2243         }
2244         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2245         {
2246                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2247                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2248         }
2249         else if(g_assault)
2250         {
2251                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2252         }
2253         else if(g_lms)
2254         {
2255                 checkrules_status = WinningCondition_LMS();
2256         }
2257         else if (g_onslaught)
2258         {
2259                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2260         }
2261         else
2262         {
2263                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2264                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2265         }
2266
2267         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2268         {
2269                 checkrules_status = WINNING_NEVER;
2270                 checkrules_overtimesadded = -1;
2271                 wantovertime |= InitiateSuddenDeath();
2272         }
2273
2274         if(checkrules_status == WINNING_NEVER)
2275                 // equality cases! Nobody wins if the overtime ends in a draw.
2276                 ClearWinners();
2277
2278         if(wantovertime)
2279         {
2280                 if(checkrules_status == WINNING_NEVER)
2281                         InitiateOvertime();
2282                 else
2283                         checkrules_status = WINNING_YES;
2284         }
2285
2286         if(checkrules_suddendeathend)
2287                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2288                         checkrules_status = WINNING_YES;
2289
2290         if(checkrules_status == WINNING_YES)
2291         {
2292                 //print("WINNING\n");
2293                 NextLevel();
2294         }
2295 }
2296
2297 float mapvote_nextthink;
2298 float mapvote_initialized;
2299 float mapvote_keeptwotime;
2300 float mapvote_timeout;
2301 string mapvote_message;
2302 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2303 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2304 float mapvote_screenshot_dirs_count;
2305
2306 float mapvote_count;
2307 float mapvote_count_real;
2308 string mapvote_maps[MAPVOTE_COUNT];
2309 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2310 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2311 float mapvote_maps_suggested[MAPVOTE_COUNT];
2312 string mapvote_suggestions[MAPVOTE_COUNT];
2313 float mapvote_suggestion_ptr;
2314 float mapvote_voters;
2315 float mapvote_selections[MAPVOTE_COUNT];
2316 float mapvote_run;
2317 float mapvote_detail;
2318 float mapvote_abstain;
2319 .float mapvote;
2320
2321 void MapVote_ClearAllVotes()
2322 {
2323         FOR_EACH_CLIENT(other)
2324                 other.mapvote = 0;
2325 }
2326
2327 string MapVote_Suggest(string m)
2328 {
2329         float i;
2330         if(m == "")
2331                 return "That's not how to use this command.";
2332         if(!autocvar_g_maplist_votable_suggestions)
2333                 return "Suggestions are not accepted on this server.";
2334         if(mapvote_initialized)
2335                 return "Can't suggest - voting is already in progress!";
2336         m = MapInfo_FixName(m);
2337         if not(m)
2338                 return "The map you suggested is not available on this server.";
2339         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2340                 if(Map_IsRecent(m))
2341                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2342
2343         if(!MapInfo_CheckMap(m))
2344                 return "The map you suggested does not support the current game mode.";
2345         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2346                 if(mapvote_suggestions[i] == m)
2347                         return "This map was already suggested.";
2348         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2349         {
2350                 i = floor(random() * mapvote_suggestion_ptr);
2351         }
2352         else
2353         {
2354                 i = mapvote_suggestion_ptr;
2355                 mapvote_suggestion_ptr += 1;
2356         }
2357         if(mapvote_suggestions[i] != "")
2358                 strunzone(mapvote_suggestions[i]);
2359         mapvote_suggestions[i] = strzone(m);
2360         if(autocvar_sv_eventlog)
2361                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2362         return strcat("Suggestion of ", m, " accepted.");
2363 }
2364
2365 void MapVote_AddVotable(string nextMap, float isSuggestion)
2366 {
2367         float j, i, o;
2368         string pakfile, mapfile;
2369
2370         if(nextMap == "")
2371                 return;
2372         for(j = 0; j < mapvote_count; ++j)
2373                 if(mapvote_maps[j] == nextMap)
2374                         return;
2375         // suggestions might be no longer valid/allowed after gametype switch!
2376         if(isSuggestion)
2377                 if(!MapInfo_CheckMap(nextMap))
2378                         return;
2379         mapvote_maps[mapvote_count] = strzone(nextMap);
2380         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2381
2382         pakfile = string_null;
2383         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2384         {
2385                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2386                 pakfile = whichpack(strcat(mapfile, ".tga"));
2387                 if(pakfile == "")
2388                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2389                 if(pakfile == "")
2390                         pakfile = whichpack(strcat(mapfile, ".png"));
2391                 if(pakfile != "")
2392                         break;
2393         }
2394         if(i >= mapvote_screenshot_dirs_count)
2395                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2396         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2397                 pakfile = substring(pakfile, o, -1);
2398
2399         mapvote_maps_screenshot_dir[mapvote_count] = i;
2400         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2401
2402         mapvote_count += 1;
2403 }
2404
2405 void MapVote_Spawn();
2406 void MapVote_Init()
2407 {
2408         float i;
2409         float nmax, smax;
2410
2411         MapVote_ClearAllVotes();
2412
2413         mapvote_count = 0;
2414         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2415         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2416
2417         if(mapvote_abstain)
2418                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2419         else
2420                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2421         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2422
2423         // we need this for AddVotable, as that cycles through the screenshot dirs
2424         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2425         if(mapvote_screenshot_dirs_count == 0)
2426                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2427         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2428         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2429                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2430
2431         if(mapvote_suggestion_ptr)
2432                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2433                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2434
2435         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2436                 MapVote_AddVotable(GetNextMap(), FALSE);
2437
2438         if(mapvote_count == 0)
2439         {
2440                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2441                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2442                 if(autocvar_g_maplist_shuffle)
2443                         ShuffleMaplist();
2444                 localcmd("\nmenu_cmd sync\n");
2445                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2446                         MapVote_AddVotable(GetNextMap(), FALSE);
2447         }
2448
2449         mapvote_count_real = mapvote_count;
2450         if(mapvote_abstain)
2451                 MapVote_AddVotable("don't care", 0);
2452
2453         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2454
2455         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2456         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2457         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2458                 mapvote_keeptwotime = 0;
2459         mapvote_message = "Choose a map and press its key!";
2460
2461         MapVote_Spawn();
2462 }
2463
2464 void MapVote_SendPicture(float id)
2465 {
2466         msg_entity = self;
2467         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2468         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2469         WriteByte(MSG_ONE, id);
2470         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2471 }
2472
2473 float MapVote_GetMapMask()
2474 {
2475         float mask, i, power;
2476         mask = 0;
2477         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2478                 if(mapvote_maps[i] != "")
2479                         mask |= power;
2480         return mask;
2481 }
2482
2483 entity mapvote_ent;
2484 float MapVote_SendEntity(entity to, float sf)
2485 {
2486         float i;
2487
2488         if(sf & 1)
2489                 sf &~= 2; // if we send 1, we don't need to also send 2
2490
2491         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2492         WriteByte(MSG_ENTITY, sf);
2493
2494         if(sf & 1)
2495         {
2496                 // flag 1 == initialization
2497                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2498                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2499                 WriteString(MSG_ENTITY, "");
2500                 WriteByte(MSG_ENTITY, mapvote_count);
2501                 WriteByte(MSG_ENTITY, mapvote_abstain);
2502                 WriteByte(MSG_ENTITY, mapvote_detail);
2503                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2504                 if(mapvote_count <= 8)
2505                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2506                 else
2507                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2508                 for(i = 0; i < mapvote_count; ++i)
2509                         if(mapvote_maps[i] != "")
2510                         {
2511                                 if(mapvote_abstain && i == mapvote_count - 1)
2512                                 {
2513                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2514                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2515                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2516                                 }
2517                                 else
2518                                 {
2519                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2520                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2521                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2522                                 }
2523                         }
2524         }
2525
2526         if(sf & 2)
2527         {
2528                 // flag 2 == update of mask
2529                 if(mapvote_count <= 8)
2530                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2531                 else
2532                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2533         }
2534
2535         if(sf & 4)
2536         {
2537                 if(mapvote_detail)
2538                         for(i = 0; i < mapvote_count; ++i)
2539                                 if(mapvote_maps[i] != "")
2540                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2541
2542                 WriteByte(MSG_ENTITY, to.mapvote);
2543         }
2544
2545         return TRUE;
2546 }
2547
2548 void MapVote_Spawn()
2549 {
2550         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2551 }
2552
2553 void MapVote_TouchMask()
2554 {
2555         mapvote_ent.SendFlags |= 2;
2556 }
2557
2558 void MapVote_TouchVotes(entity voter)
2559 {
2560         mapvote_ent.SendFlags |= 4;
2561 }
2562
2563 float MapVote_Finished(float mappos)
2564 {
2565         string result;
2566         float i;
2567         float didntvote;
2568
2569         if(autocvar_sv_eventlog)
2570         {
2571                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2572                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2573                 didntvote = mapvote_voters;
2574                 for(i = 0; i < mapvote_count; ++i)
2575                         if(mapvote_maps[i] != "")
2576                         {
2577                                 didntvote -= mapvote_selections[i];
2578                                 if(i != mappos)
2579                                 {
2580                                         result = strcat(result, ":", mapvote_maps[i]);
2581                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2582                                 }
2583                         }
2584                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2585
2586                 GameLogEcho(result);
2587                 if(mapvote_maps_suggested[mappos])
2588                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2589         }
2590
2591         FOR_EACH_REALCLIENT(other)
2592                 FixClientCvars(other);
2593
2594         Map_Goto_SetStr(mapvote_maps[mappos]);
2595         Map_Goto(0);
2596         alreadychangedlevel = TRUE;
2597         return TRUE;
2598 }
2599 void MapVote_CheckRules_1()
2600 {
2601         float i;
2602
2603         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2604         {
2605                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2606                 mapvote_selections[i] = 0;
2607         }
2608
2609         mapvote_voters = 0;
2610         FOR_EACH_REALCLIENT(other)
2611         {
2612                 ++mapvote_voters;
2613                 if(other.mapvote)
2614                 {
2615                         i = other.mapvote - 1;
2616                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2617                         mapvote_selections[i] = mapvote_selections[i] + 1;
2618                 }
2619         }
2620 }
2621
2622 float MapVote_CheckRules_2()
2623 {
2624         float i;
2625         float firstPlace, secondPlace;
2626         float firstPlaceVotes, secondPlaceVotes;
2627         float mapvote_voters_real;
2628         string result;
2629
2630         if(mapvote_count_real == 1)
2631                 return MapVote_Finished(0);
2632
2633         mapvote_voters_real = mapvote_voters;
2634         if(mapvote_abstain)
2635                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2636
2637         RandomSelection_Init();
2638         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2639                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2640         firstPlace = RandomSelection_chosen_float;
2641         firstPlaceVotes = RandomSelection_best_priority;
2642         //dprint("First place: ", ftos(firstPlace), "\n");
2643         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2644
2645         RandomSelection_Init();
2646         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2647                 if(i != firstPlace)
2648                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2649         secondPlace = RandomSelection_chosen_float;
2650         secondPlaceVotes = RandomSelection_best_priority;
2651         //dprint("Second place: ", ftos(secondPlace), "\n");
2652         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2653
2654         if(firstPlace == -1)
2655                 error("No first place in map vote... WTF?");
2656
2657         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2658                 return MapVote_Finished(firstPlace);
2659
2660         if(mapvote_keeptwotime)
2661                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2662                 {
2663                         float didntvote;
2664                         MapVote_TouchMask();
2665                         mapvote_message = "Now decide between the TOP TWO!";
2666                         mapvote_keeptwotime = 0;
2667                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2668                         result = strcat(result, ":", ftos(firstPlaceVotes));
2669                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2670                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2671                         didntvote = mapvote_voters;
2672                         for(i = 0; i < mapvote_count; ++i)
2673                                 if(mapvote_maps[i] != "")
2674                                 {
2675                                         didntvote -= mapvote_selections[i];
2676                                         if(i != firstPlace)
2677                                                 if(i != secondPlace)
2678                                                 {
2679                                                         result = strcat(result, ":", mapvote_maps[i]);
2680                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2681                                                         if(i < mapvote_count_real)
2682                                                         {
2683                                                                 strunzone(mapvote_maps[i]);
2684                                                                 mapvote_maps[i] = "";
2685                                                                 strunzone(mapvote_maps_pakfile[i]);
2686                                                                 mapvote_maps_pakfile[i] = "";
2687                                                         }
2688                                                 }
2689                                 }
2690                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2691                         if(autocvar_sv_eventlog)
2692                                 GameLogEcho(result);
2693                 }
2694
2695         return FALSE;
2696 }
2697 void MapVote_Tick()
2698 {
2699         float keeptwo;
2700         float totalvotes;
2701
2702         keeptwo = mapvote_keeptwotime;
2703         MapVote_CheckRules_1(); // count
2704         if(MapVote_CheckRules_2()) // decide
2705                 return;
2706
2707         totalvotes = 0;
2708         FOR_EACH_REALCLIENT(other)
2709         {
2710                 // hide scoreboard again
2711                 if(other.health != 2342)
2712                 {
2713                         other.health = 2342;
2714                         other.impulse = 0;
2715                         if(clienttype(other) == CLIENTTYPE_REAL)
2716                         {
2717                                 msg_entity = other;
2718                                 WriteByte(MSG_ONE, SVC_FINALE);
2719                                 WriteString(MSG_ONE, "");
2720                         }
2721                 }
2722
2723                 // clear possibly invalid votes
2724                 if(mapvote_maps[other.mapvote - 1] == "")
2725                         other.mapvote = 0;
2726                 // use impulses as new vote
2727                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2728                         if(mapvote_maps[other.impulse - 1] != "")
2729                         {
2730                                 other.mapvote = other.impulse;
2731                                 MapVote_TouchVotes(other);
2732                         }
2733                 other.impulse = 0;
2734
2735                 if(other.mapvote)
2736                         ++totalvotes;
2737         }
2738
2739         MapVote_CheckRules_1(); // just count
2740 }
2741 void MapVote_Start()
2742 {
2743         if(mapvote_run)
2744                 return;
2745
2746         // wait for stats to be sent first
2747         if(!playerstats_waitforme)
2748                 return;
2749
2750         MapInfo_Enumerate();
2751         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2752                 mapvote_run = TRUE;
2753 }
2754 void MapVote_Think()
2755 {
2756         if(!mapvote_run)
2757                 return;
2758
2759         if(alreadychangedlevel)
2760                 return;
2761
2762         if(time < mapvote_nextthink)
2763                 return;
2764         //dprint("tick\n");
2765
2766         mapvote_nextthink = time + 0.5;
2767
2768         if(!mapvote_initialized)
2769         {
2770                 if(autocvar_rescan_pending == 1)
2771                 {
2772                         cvar_set("rescan_pending", "2");
2773                         localcmd("fs_rescan\nrescan_pending 3\n");
2774                         return;
2775                 }
2776                 else if(autocvar_rescan_pending == 2)
2777                 {
2778                         return;
2779                 }
2780                 else if(autocvar_rescan_pending == 3)
2781                 {
2782                         // now build missing mapinfo files
2783                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2784                                 return;
2785
2786                         // we're done, start the timer
2787                         cvar_set("rescan_pending", "0");
2788                 }
2789
2790                 mapvote_initialized = TRUE;
2791                 if(DoNextMapOverride(0))
2792                         return;
2793                 if(!autocvar_g_maplist_votable || player_count <= 0)
2794                 {
2795                         GotoNextMap(0);
2796                         return;
2797                 }
2798                 MapVote_Init();
2799         }
2800
2801         MapVote_Tick();
2802 }
2803
2804 string GotoMap(string m)
2805 {
2806         if(!MapInfo_CheckMap(m))
2807                 return "The map you chose is not available on this server.";
2808         cvar_set("nextmap", m);
2809         cvar_set("timelimit", "-1");
2810         if(mapvote_initialized || alreadychangedlevel)
2811         {
2812                 if(DoNextMapOverride(0))
2813                         return "Map switch initiated.";
2814                 else
2815                         return "Hm... no. For some reason I like THIS map more.";
2816         }
2817         else
2818                 return "Map switch will happen after scoreboard.";
2819 }
2820
2821
2822 void EndFrame()
2823 {
2824         float altime;
2825         FOR_EACH_REALCLIENT(self)
2826         {
2827                 if(self.classname == "spectator")
2828                 {
2829                         if(self.enemy.typehitsound)
2830                                 self.typehit_time = time;
2831                         else if(self.enemy.hitsound)
2832                                 self.hit_time = time;
2833                 }
2834                 else
2835                 {
2836                         if(self.typehitsound)
2837                                 self.typehit_time = time;
2838                         else if(self.hitsound)
2839                                 self.hit_time = time;
2840                 }
2841         }
2842         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2843         // add 1 frametime because after this, engine SV_Physics
2844         // increases time by a frametime and then networks the frame
2845         // add another frametime because client shows everything with
2846         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2847         // needed!
2848         FOR_EACH_CLIENT(self)
2849         {
2850                 self.hitsound = FALSE;
2851                 self.typehitsound = FALSE;
2852                 antilag_record(self, altime);
2853         }
2854 }
2855
2856
2857 /*
2858  * RedirectionThink:
2859  * returns TRUE if redirecting
2860  */
2861 float redirection_timeout;
2862 float redirection_nextthink;
2863 float RedirectionThink()
2864 {
2865         float clients_found;
2866
2867         if(redirection_target == "")
2868                 return FALSE;
2869
2870         if(!redirection_timeout)
2871         {
2872                 cvar_set("sv_public", "-2");
2873                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2874                 if(redirection_target == "self")
2875                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2876                 else
2877                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2878         }
2879
2880         if(time < redirection_nextthink)
2881                 return TRUE;
2882
2883         redirection_nextthink = time + 1;
2884
2885         clients_found = 0;
2886         FOR_EACH_REALCLIENT(self)
2887         {
2888                 // TODO add timer
2889                 print("Redirecting: sending connect command to ", self.netname, "\n");
2890                 if(redirection_target == "self")
2891                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2892                 else
2893                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2894                 ++clients_found;
2895         }
2896
2897         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2898
2899         if(time > redirection_timeout || clients_found == 0)
2900                 localcmd("\nwait; wait; wait; quit\n");
2901
2902         return TRUE;
2903 }
2904
2905 void TargetMusic_RestoreGame();
2906 void RestoreGame()
2907 {
2908         // Loaded from a save game
2909         // some things then break, so let's work around them...
2910
2911         // Progs DB (capture records)
2912         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2913
2914         // Mapinfo
2915         MapInfo_Shutdown();
2916         MapInfo_Enumerate();
2917         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2918         WeaponStats_Init();
2919
2920         TargetMusic_RestoreGame();
2921 }
2922
2923 void Shutdown()
2924 {
2925         entity e;
2926
2927         gameover = 2;
2928
2929         if(world_initialized > 0)
2930         {
2931                 world_initialized = 0;
2932                 print("Saving persistent data...\n");
2933                 Ban_SaveBans();
2934
2935                 PlayerStats_EndMatch(0);
2936                 FOR_EACH_CLIENT(e)
2937                         PlayerStats_AddGlobalInfo(e);
2938                 PlayerStats_Shutdown();
2939
2940                 if(!cheatcount_total)
2941                 {
2942                         if(autocvar_sv_db_saveasdump)
2943                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2944                         else
2945                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2946                 }
2947                 if(autocvar_developer)
2948                 {
2949                         if(autocvar_sv_db_saveasdump)
2950                                 db_dump(TemporaryDB, "server-temp.db");
2951                         else
2952                                 db_save(TemporaryDB, "server-temp.db");
2953                 }
2954                 CheatShutdown(); // must be after cheatcount check
2955                 db_close(ServerProgsDB);
2956                 db_close(TemporaryDB);
2957                 print("done!\n");
2958                 // tell the bot system the game is ending now
2959                 bot_endgame();
2960
2961                 WeaponStats_Shutdown();
2962                 MapInfo_Shutdown();
2963         }
2964         else if(world_initialized == 0)
2965         {
2966                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2967         }
2968 }