qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 761         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 762         Nagger_Init();
 763
 764         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 765         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 766         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 767         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 768         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 769         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 770         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 771         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 772         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 773
 774         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 775         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 776
 777         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 778
 779         // freeze attacks
 780         addstat(STAT_FROZEN, AS_INT, frozen);
 781         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 782
 783         // physics
 784         Physics_AddStats();
 785
 786         // new properties
 787         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 788         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 789         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 790         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 791         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 792         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 793         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 794         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 795         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 796         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 797         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 798         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 799         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 800         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 801         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 802         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 803         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 804         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 805         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 806
 807         // secrets
 808         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 809         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 810
 811         // monsters
 812         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 813         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 814
 815         // misc
 816         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 817
 818         next_pingtime = time + 5;
 819
 820         detect_maptype();
 821
 822         // set up information replies for clients and server to use
 823         maplist_reply = strzone(getmaplist());
 824         lsmaps_reply = strzone(getlsmaps());
 825         monsterlist_reply = strzone(getmonsterlist());
 826         for(int i = 0; i < 10; ++i)
 827         {
 828                 s = getrecords(i);
 829                 if (s)
 830                         records_reply[i] = strzone(s);
 831         }
 832         ladder_reply = strzone(getladder());
 833         rankings_reply = strzone(getrankings());
 834
 835         // begin other init
 836         ClientInit_Spawn();
 837         RandomSeed_Spawn();
 838         PingPLReport_Spawn();
 839
 840         CheatInit();
 841
 842         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 843
 844         // fill sv_curl_serverpackages from .serverpackage files
 845         if(autocvar_sv_curl_serverpackages_auto)
 846         {
 847                 s = "";
 848                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 849                 for(int i = 0; i < n; ++i)
 850                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 851                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 852                                 s = strcat(s, " ", argv(i));
 853                 fd = search_begin("*-serverpackage.txt", true, false);
 854                 if(fd >= 0)
 855                 {
 856                         j = search_getsize(fd);
 857                         for(int i = 0; i < j; ++i)
 858                                 s = strcat(s, " ", search_getfilename(fd, i));
 859                         search_end(fd);
 860                 }
 861                 fd = search_begin("*.serverpackage", true, false);
 862                 if(fd >= 0)
 863                 {
 864                         j = search_getsize(fd);
 865                         for(int i = 0; i < j; ++i)
 866                                 s = strcat(s, " ", search_getfilename(fd, i));
 867                         search_end(fd);
 868                 }
 869                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 870         }
 871
 872         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 873         modname = "Xonotic";
 874         // physics/balance/config changes that count as mod
 875         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 876                 modname = cvar_string("g_mod_physics");
 877         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 878                 modname = cvar_string("g_mod_balance");
 879         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 880                 modname = cvar_string("g_mod_config");
 881         // extra mutators that deserve to count as mod
 882         MUTATOR_CALLHOOK(SetModname);
 883
 884         // save it for later
 885         modname = strzone(modname);
 886
 887         WinningConditionHelper(); // set worldstatus
 888
 889         world_initialized = 1;
 890 }
 891
 892 spawnfunc(light)
 893 {
 894         //makestatic (self); // Who the f___ did that?
 895         remove(self);
 896 }
 897
 898 string GetGametype()
 899 {
 900         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 901 }
 902
 903 string GetMapname()
 904 {
 905         return mapname;
 906 }
 907
 908 float Map_Count, Map_Current;
 909 string Map_Current_Name;
 910
 911 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 912 float GetMaplistPosition()
 913 {
 914         float pos, idx;
 915         string map;
 916
 917         map = GetMapname();
 918         idx = autocvar_g_maplist_index;
 919
 920         if(idx >= 0)
 921                 if(idx < Map_Count)
 922                         if(map == argv(idx))
 923                                 return idx;
 924
 925         for(pos = 0; pos < Map_Count; ++pos)
 926                 if(map == argv(pos))
 927                         return pos;
 928
 929         // resume normal maplist rotation if current map is not in g_maplist
 930         return idx;
 931 }
 932
 933 float MapHasRightSize(string map)
 934 {
 935         float fh;
 936         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 937         if(autocvar_g_maplist_check_waypoints)
 938         {
 939                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 940                 if(!fexists(strcat("maps/", map, ".waypoints")))
 941                 {
 942                         LOG_TRACE(": no waypoints\n");
 943                         return false;
 944                 }
 945                 LOG_TRACE(": has waypoints\n");
 946         }
 947
 948         // open map size restriction file
 949         LOG_TRACE("opensize "); LOG_TRACE(map);
 950         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 951         if(fh >= 0)
 952         {
 953                 float mapmin, mapmax;
 954                 LOG_TRACE(": ok, ");
 955                 mapmin = stof(fgets(fh));
 956                 mapmax = stof(fgets(fh));
 957                 fclose(fh);
 958                 if(player_count < mapmin)
 959                 {
 960                         LOG_TRACE("not enough\n");
 961                         return false;
 962                 }
 963                 if(player_count > mapmax)
 964                 {
 965                         LOG_TRACE("too many\n");
 966                         return false;
 967                 }
 968                 LOG_TRACE("right size\n");
 969                 return true;
 970         }
 971         LOG_TRACE(": not found\n");
 972         return true;
 973 }
 974
 975 string Map_Filename(float position)
 976 {
 977         return strcat("maps/", argv(position), ".bsp");
 978 }
 979
 980 void Map_MarkAsRecent(string m)
 981 {
 982         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 983 }
 984
 985 float Map_IsRecent(string m)
 986 {
 987         return strhasword(autocvar_g_maplist_mostrecent, m);
 988 }
 989
 990 float Map_Check(float position, float pass)
 991 {
 992         string filename;
 993         string map_next;
 994         map_next = argv(position);
 995         if(pass <= 1)
 996         {
 997                 if(Map_IsRecent(map_next))
 998                         return 0;
 999         }
1000         filename = Map_Filename(position);
1001         if(MapInfo_CheckMap(map_next))
1002         {
1003                 if(pass == 2)
1004                         return 1;
1005                 if(MapHasRightSize(map_next))
1006                         return 1;
1007                 return 0;
1008         }
1009         else
1010                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1011
1012         return 0;
1013 }
1014
1015 void Map_Goto_SetStr(string nextmapname)
1016 {
1017         if(getmapname_stored != "")
1018                 strunzone(getmapname_stored);
1019         if(nextmapname == "")
1020                 getmapname_stored = "";
1021         else
1022                 getmapname_stored = strzone(nextmapname);
1023 }
1024
1025 void Map_Goto_SetFloat(float position)
1026 {
1027         cvar_set("g_maplist_index", ftos(position));
1028         Map_Goto_SetStr(argv(position));
1029 }
1030
1031 void Map_Goto(float reinit)
1032 {
1033         MapInfo_LoadMap(getmapname_stored, reinit);
1034 }
1035
1036 // return codes of map selectors:
1037 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1038 //   -2 = permanent failure
1039 float() MaplistMethod_Iterate = // usual method
1040 {
1041         float pass, i;
1042
1043         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1044
1045         for(pass = 1; pass <= 2; ++pass)
1046         {
1047                 for(i = 1; i < Map_Count; ++i)
1048                 {
1049                         float mapindex;
1050                         mapindex = (i + Map_Current) % Map_Count;
1051                         if(Map_Check(mapindex, pass))
1052                                 return mapindex;
1053                 }
1054         }
1055         return -1;
1056 }
1057
1058 float() MaplistMethod_Repeat = // fallback method
1059 {
1060         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1061
1062         if(Map_Check(Map_Current, 2))
1063                 return Map_Current;
1064         return -2;
1065 }
1066
1067 float() MaplistMethod_Random = // random map selection
1068 {
1069         float i, imax;
1070
1071         LOG_TRACE("Trying MaplistMethod_Random\n");
1072
1073         imax = 42;
1074
1075         for(i = 0; i <= imax; ++i)
1076         {
1077                 float mapindex;
1078                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1079                 if(Map_Check(mapindex, 1))
1080                         return mapindex;
1081         }
1082         return -1;
1083 }
1084
1085 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1086 // the exponent sets a bias on the map selection:
1087 // the higher the exponent, the less likely "shortly repeated" same maps are
1088 {
1089         float i, j, imax, insertpos;
1090
1091         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1092
1093         imax = 42;
1094
1095         for(i = 0; i <= imax; ++i)
1096         {
1097                 string newlist;
1098
1099                 // now reinsert this at another position
1100                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1101                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1102                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1103                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1104
1105                 // insert the current map there
1106                 newlist = "";
1107                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1108                         newlist = strcat(newlist, " ", argv(j));
1109                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1110                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1111                         newlist = strcat(newlist, " ", argv(j));
1112                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1113                 cvar_set("g_maplist", newlist);
1114                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1115
1116                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1117                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1118                 if(Map_Check(Map_Current, 1))
1119                         return Map_Current;
1120         }
1121         return -1;
1122 }
1123
1124 void Maplist_Init()
1125 {
1126         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127         float i;
1128         for (i = 0; i < Map_Count; ++i)
1129                 if (Map_Check(i, 2))
1130                         break;
1131         if (i == Map_Count)
1132         {
1133                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1134                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1135                 if(autocvar_g_maplist_shuffle)
1136                         ShuffleMaplist();
1137                 localcmd("\nmenu_cmd sync\n");
1138                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139         }
1140         if(Map_Count == 0)
1141                 error("empty maplist, cannot select a new map");
1142         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1143
1144         if(Map_Current_Name)
1145                 strunzone(Map_Current_Name);
1146         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1147         // this may or may not be correct, but who cares, in the worst case a map
1148         // isn't chosen in the first pass that should have been
1149 }
1150
1151 string GetNextMap()
1152 {
1153         float nextMap;
1154
1155         Maplist_Init();
1156         nextMap = -1;
1157
1158         if(nextMap == -1)
1159                 if(autocvar_g_maplist_shuffle > 0)
1160                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1161
1162         if(nextMap == -1)
1163                 if(autocvar_g_maplist_selectrandom)
1164                         nextMap = MaplistMethod_Random();
1165
1166         if(nextMap == -1)
1167                 nextMap = MaplistMethod_Iterate();
1168
1169         if(nextMap == -1)
1170                 nextMap = MaplistMethod_Repeat();
1171
1172         if(nextMap >= 0)
1173         {
1174                 Map_Goto_SetFloat(nextMap);
1175                 return getmapname_stored;
1176         }
1177
1178         return "";
1179 }
1180
1181 float DoNextMapOverride(float reinit)
1182 {
1183         if(autocvar_g_campaign)
1184         {
1185                 CampaignPostIntermission();
1186                 alreadychangedlevel = true;
1187                 return true;
1188         }
1189         if(autocvar_quit_when_empty)
1190         {
1191                 if(player_count <= currentbots)
1192                 {
1193                         localcmd("quit\n");
1194                         alreadychangedlevel = true;
1195                         return true;
1196                 }
1197         }
1198         if(autocvar_quit_and_redirect != "")
1199         {
1200                 redirection_target = strzone(autocvar_quit_and_redirect);
1201                 alreadychangedlevel = true;
1202                 return true;
1203         }
1204         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1205         {
1206                 localcmd("restart\n");
1207                 alreadychangedlevel = true;
1208                 return true;
1209         }
1210         if(autocvar_nextmap != "")
1211         {
1212                 string m;
1213                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1214                 cvar_set("nextmap",m);
1215
1216                 if(!m || gametypevote)
1217                         return false;
1218                 if(autocvar_sv_vote_gametype)
1219                 {
1220                         Map_Goto_SetStr(m);
1221                         return false;
1222                 }
1223
1224                 if(MapInfo_CheckMap(m))
1225                 {
1226                         Map_Goto_SetStr(m);
1227                         Map_Goto(reinit);
1228                         alreadychangedlevel = true;
1229                         return true;
1230                 }
1231         }
1232         if(!reinit && autocvar_lastlevel)
1233         {
1234                 cvar_settemp_restore();
1235                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1236                 alreadychangedlevel = true;
1237                 return true;
1238         }
1239         return false;
1240 }
1241
1242 void GotoNextMap(float reinit)
1243 {
1244         //string nextmap;
1245         //float n, nummaps;
1246         //string s;
1247         if (alreadychangedlevel)
1248                 return;
1249         alreadychangedlevel = true;
1250
1251         string nextMap;
1252
1253         nextMap = GetNextMap();
1254         if(nextMap == "")
1255                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1256         Map_Goto(reinit);
1257 }
1258
1259
1260 /*
1261 ============
1262 IntermissionThink
1263
1264 When the player presses attack or jump, change to the next level
1265 ============
1266 */
1267 .float autoscreenshot;
1268 void IntermissionThink()
1269 {SELFPARAM();
1270         FixIntermissionClient(self);
1271
1272         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1273         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1274
1275         if( (server_screenshot || client_screenshot)
1276                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1277         {
1278                 self.autoscreenshot = -1;
1279                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1280                 return;
1281         }
1282
1283         if (time < intermission_exittime)
1284                 return;
1285
1286         if(!mapvote_initialized)
1287                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1288                         return;
1289
1290         MapVote_Start();
1291 }
1292
1293 /*
1294 ============
1295 FindIntermission
1296
1297 Returns the entity to view from
1298 ============
1299 */
1300 /*
1301 entity FindIntermission()
1302 {
1303         local   entity spot;
1304         local   float cyc;
1305
1306 // look for info_intermission first
1307         spot = find (world, classname, "info_intermission");
1308         if (spot)
1309         {       // pick a random one
1310                 cyc = random() * 4;
1311                 while (cyc > 1)
1312                 {
1313                         spot = find (spot, classname, "info_intermission");
1314                         if (!spot)
1315                                 spot = find (spot, classname, "info_intermission");
1316                         cyc = cyc - 1;
1317                 }
1318                 return spot;
1319         }
1320
1321 // then look for the start position
1322         spot = find (world, classname, "info_player_start");
1323         if (spot)
1324                 return spot;
1325
1326 // testinfo_player_start is only found in regioned levels
1327         spot = find (world, classname, "testplayerstart");
1328         if (spot)
1329                 return spot;
1330
1331 // then look for the start position
1332         spot = find (world, classname, "info_player_deathmatch");
1333         if (spot)
1334                 return spot;
1335
1336         //objerror ("FindIntermission: no spot");
1337         return world;
1338 }
1339 */
1340
1341 /*
1342 ===============================================================================
1343
1344 RULES
1345
1346 ===============================================================================
1347 */
1348
1349 void DumpStats(float final)
1350 {
1351         float file;
1352         string s;
1353         float to_console;
1354         float to_eventlog;
1355         float to_file;
1356         float i;
1357
1358         to_console = autocvar_sv_logscores_console;
1359         to_eventlog = autocvar_sv_eventlog;
1360         to_file = autocvar_sv_logscores_file;
1361
1362         if(!final)
1363         {
1364                 to_console = true; // always print printstats replies
1365                 to_eventlog = false; // but never print them to the event log
1366         }
1367
1368         if(to_eventlog)
1369                 if(autocvar_sv_eventlog_console)
1370                         to_console = false; // otherwise we get the output twice
1371
1372         if(final)
1373                 s = ":scores:";
1374         else
1375                 s = ":status:";
1376         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1377
1378         if(to_console)
1379                 LOG_INFO(s, "\n");
1380         if(to_eventlog)
1381                 GameLogEcho(s);
1382
1383         file = -1;
1384         if(to_file)
1385         {
1386                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1387                 if(file == -1)
1388                         to_file = false;
1389                 else
1390                         fputs(file, strcat(s, "\n"));
1391         }
1392
1393         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1394         if(to_console)
1395                 LOG_INFO(s, "\n");
1396         if(to_eventlog)
1397                 GameLogEcho(s);
1398         if(to_file)
1399                 fputs(file, strcat(s, "\n"));
1400
1401         FOR_EACH_CLIENT(other)
1402         {
1403                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1404                 {
1405                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1406                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1407                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1408                                 s = strcat(s, ftos(other.team), ":");
1409                         else
1410                                 s = strcat(s, "spectator:");
1411
1412                         if(to_console)
1413                                 LOG_INFO(s, other.netname, "\n");
1414                         if(to_eventlog)
1415                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1416                         if(to_file)
1417                                 fputs(file, strcat(s, other.netname, "\n"));
1418                 }
1419         }
1420
1421         if(teamplay)
1422         {
1423                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1424                 if(to_console)
1425                         LOG_INFO(s, "\n");
1426                 if(to_eventlog)
1427                         GameLogEcho(s);
1428                 if(to_file)
1429                         fputs(file, strcat(s, "\n"));
1430
1431                 for(i = 1; i < 16; ++i)
1432                 {
1433                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1434                         s = strcat(s, ":", ftos(i));
1435                         if(to_console)
1436                                 LOG_INFO(s, "\n");
1437                         if(to_eventlog)
1438                                 GameLogEcho(s);
1439                         if(to_file)
1440                                 fputs(file, strcat(s, "\n"));
1441                 }
1442         }
1443
1444         if(to_console)
1445                 LOG_INFO(":end\n");
1446         if(to_eventlog)
1447                 GameLogEcho(":end");
1448         if(to_file)
1449         {
1450                 fputs(file, ":end\n");
1451                 fclose(file);
1452         }
1453 }
1454
1455 void FixIntermissionClient(entity e)
1456 {
1457         string s;
1458         if(!e.autoscreenshot) // initial call
1459         {
1460                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1461                 e.health = -2342;
1462                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1463                 e.solid = SOLID_NOT;
1464                 e.movetype = MOVETYPE_NONE;
1465                 e.takedamage = DAMAGE_NO;
1466                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1467                 {
1468                     .entity weaponentity = weaponentities[slot];
1469                         if(e.(weaponentity))
1470                         {
1471                                 e.(weaponentity).effects = EF_NODRAW;
1472                                 if (e.(weaponentity).(weaponentity))
1473                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1474                         }
1475                 }
1476                 if(IS_REAL_CLIENT(e))
1477                 {
1478                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1479                         s = autocvar_sv_intermission_cdtrack;
1480                         if(s != "")
1481                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1482                         msg_entity = e;
1483                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1484                 }
1485         }
1486 }
1487
1488 /*
1489 go to the next level for deathmatch
1490 only called if a time or frag limit has expired
1491 */
1492 void NextLevel()
1493 {
1494         gameover = true;
1495
1496         intermission_running = 1;
1497
1498 // enforce a wait time before allowing changelevel
1499         if(player_count > 0)
1500                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1501         else
1502                 intermission_exittime = -1;
1503
1504         /*
1505         WriteByte (MSG_ALL, SVC_CDTRACK);
1506         WriteByte (MSG_ALL, 3);
1507         WriteByte (MSG_ALL, 3);
1508         // done in FixIntermission
1509         */
1510
1511         //pos = FindIntermission ();
1512
1513         VoteReset();
1514
1515         DumpStats(true);
1516
1517         // send statistics
1518         PlayerStats_GameReport(true);
1519         WeaponStats_Shutdown();
1520
1521         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1522
1523         if(autocvar_sv_eventlog)
1524                 GameLogEcho(":gameover");
1525
1526         GameLogClose();
1527
1528         FOR_EACH_PLAYER(other) {
1529                 FixIntermissionClient(other);
1530                 if(other.winning)
1531                         bprint(other.netname, " ^7wins.\n");
1532         }
1533
1534         entity oldself = self;
1535         target_music_kill();
1536         self = oldself;
1537
1538         if(autocvar_g_campaign)
1539                 CampaignPreIntermission();
1540
1541         MUTATOR_CALLHOOK(MatchEnd);
1542
1543         localcmd("\nsv_hook_gameend\n");
1544 }
1545
1546 /*
1547 ============
1548 CheckRules_Player
1549
1550 Exit deathmatch games upon conditions
1551 ============
1552 */
1553 void CheckRules_Player()
1554 {SELFPARAM();
1555         if (gameover)   // someone else quit the game already
1556                 return;
1557
1558         if(self.deadflag == DEAD_NO)
1559                 self.play_time += frametime;
1560
1561         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1562         //   (div0: and that in CheckRules_World please)
1563 }
1564
1565
1566 float InitiateSuddenDeath()
1567 {
1568         // Check first whether normal overtimes could be added before initiating suddendeath mode
1569         // - for this timelimit_overtime needs to be >0 of course
1570         // - also check the winning condition calculated in the previous frame and only add normal overtime
1571         //   again, if at the point at which timelimit would be extended again, still no winner was found
1572         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1573         {
1574                 return 1; // need to call InitiateOvertime later
1575         }
1576         else
1577         {
1578                 if(!checkrules_suddendeathend)
1579                 {
1580                         if(autocvar_g_campaign)
1581                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1582                         else
1583                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1584                         if(g_race && !g_race_qualifying)
1585                                 race_StartCompleting();
1586                 }
1587                 return 0;
1588         }
1589 }
1590
1591 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1592 {
1593         ++checkrules_overtimesadded;
1594         //add one more overtime by simply extending the timelimit
1595         float tl;
1596         tl = autocvar_timelimit;
1597         tl += autocvar_timelimit_overtime;
1598         cvar_set("timelimit", ftos(tl));
1599
1600         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1601 }
1602
1603 float GetWinningCode(float fraglimitreached, float equality)
1604 {
1605         if(autocvar_g_campaign == 1)
1606                 if(fraglimitreached)
1607                         return WINNING_YES;
1608                 else
1609                         return WINNING_NO;
1610
1611         else
1612                 if(equality)
1613                         if(fraglimitreached)
1614                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1615                         else
1616                                 return WINNING_NEVER;
1617                 else
1618                         if(fraglimitreached)
1619                                 return WINNING_YES;
1620                         else
1621                                 return WINNING_NO;
1622 }
1623
1624 // set the .winning flag for exactly those players with a given field value
1625 void SetWinners(.float field, float value)
1626 {
1627         entity head;
1628         FOR_EACH_PLAYER(head)
1629                 head.winning = (head.(field) == value);
1630 }
1631
1632 // set the .winning flag for those players with a given field value
1633 void AddWinners(.float field, float value)
1634 {
1635         entity head;
1636         FOR_EACH_PLAYER(head)
1637                 if (head.(field) == value)
1638                         head.winning = 1;
1639 }
1640
1641 // clear the .winning flags
1642 void ClearWinners()
1643 {
1644         entity head;
1645         FOR_EACH_PLAYER(head)
1646                 head.winning = 0;
1647 }
1648
1649 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1650 // they win. Otherwise the defending team wins once the timelimit passes.
1651 void assault_new_round();
1652 float WinningCondition_Assault()
1653 {SELFPARAM();
1654         float status;
1655
1656         WinningConditionHelper(); // set worldstatus
1657
1658         status = WINNING_NO;
1659         // as the timelimit has not yet passed just assume the defending team will win
1660         if(assault_attacker_team == NUM_TEAM_1)
1661         {
1662                 SetWinners(team, NUM_TEAM_2);
1663         }
1664         else
1665         {
1666                 SetWinners(team, NUM_TEAM_1);
1667         }
1668
1669         entity ent;
1670         ent = find(world, classname, "target_assault_roundend");
1671         if(ent)
1672         {
1673                 if(ent.winning) // round end has been triggered by attacking team
1674                 {
1675                         bprint("ASSAULT: round completed...\n");
1676                         SetWinners(team, assault_attacker_team);
1677
1678                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1679
1680                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1681                         {
1682                                 status = WINNING_YES;
1683                         }
1684                         else
1685                         {
1686                                 WITH(entity, self, ent, assault_new_round());
1687                         }
1688                 }
1689         }
1690
1691         return status;
1692 }
1693
1694 void ShuffleMaplist()
1695 {
1696         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1697 }
1698
1699 float leaderfrags;
1700 float WinningCondition_Scores(float limit, float leadlimit)
1701 {
1702         float limitreached;
1703
1704         // TODO make everything use THIS winning condition (except LMS)
1705         WinningConditionHelper();
1706
1707         if(teamplay)
1708         {
1709                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1710                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1711                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1712                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1713         }
1714
1715         ClearWinners();
1716         if(WinningConditionHelper_winner)
1717                 WinningConditionHelper_winner.winning = 1;
1718         if(WinningConditionHelper_winnerteam >= 0)
1719                 SetWinners(team, WinningConditionHelper_winnerteam);
1720
1721         if(WinningConditionHelper_lowerisbetter)
1722         {
1723                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1724                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1725                 limit = -limit;
1726         }
1727
1728         if(WinningConditionHelper_zeroisworst)
1729                 leadlimit = 0; // not supported in this mode
1730
1731         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1732         // these modes always score in increments of 1, thus this makes sense
1733         {
1734                 if(leaderfrags != WinningConditionHelper_topscore)
1735                 {
1736                         leaderfrags = WinningConditionHelper_topscore;
1737
1738                         if (limit)
1739                         if (leaderfrags == limit - 1)
1740                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1741                         else if (leaderfrags == limit - 2)
1742                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1743                         else if (leaderfrags == limit - 3)
1744                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1745                 }
1746         }
1747
1748         limitreached = false;
1749         if(limit)
1750                 if(WinningConditionHelper_topscore >= limit)
1751                         limitreached = true;
1752         if(leadlimit)
1753         {
1754                 float leadlimitreached;
1755                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1756                 if(autocvar_leadlimit_and_fraglimit)
1757                         limitreached = (limitreached && leadlimitreached);
1758                 else
1759                         limitreached = (limitreached || leadlimitreached);
1760         }
1761
1762         if(limit)
1763                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1764
1765         return GetWinningCode(
1766                 WinningConditionHelper_topscore && limitreached,
1767                 WinningConditionHelper_equality
1768         );
1769 }
1770
1771 float WinningCondition_Race(float fraglimit)
1772 {
1773         float wc;
1774         entity p;
1775         float n, c;
1776
1777         n = 0;
1778         c = 0;
1779         FOR_EACH_PLAYER(p)
1780         {
1781                 ++n;
1782                 if(p.race_completed)
1783                         ++c;
1784         }
1785         if(n && (n == c))
1786                 return WINNING_YES;
1787         wc = WinningCondition_Scores(fraglimit, 0);
1788
1789         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1790         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1791         // do NOT support equality when the laps are all raced!
1792                 return WINNING_STARTSUDDENDEATHOVERTIME;
1793         else
1794                 return WINNING_NEVER;
1795 }
1796
1797 float WinningCondition_QualifyingThenRace(float limit)
1798 {
1799         float wc;
1800         wc = WinningCondition_Scores(limit, 0);
1801
1802         // NEVER initiate overtime
1803         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1804         {
1805                 return WINNING_YES;
1806         }
1807
1808         return wc;
1809 }
1810
1811 float WinningCondition_RanOutOfSpawns()
1812 {
1813         entity head;
1814
1815         if(have_team_spawns <= 0)
1816                 return WINNING_NO;
1817
1818         if(!autocvar_g_spawn_useallspawns)
1819                 return WINNING_NO;
1820
1821         if(!some_spawn_has_been_used)
1822                 return WINNING_NO;
1823
1824         team1_score = team2_score = team3_score = team4_score = 0;
1825
1826         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1827         {
1828                 if(head.team == NUM_TEAM_1)
1829                         team1_score = 1;
1830                 else if(head.team == NUM_TEAM_2)
1831                         team2_score = 1;
1832                 else if(head.team == NUM_TEAM_3)
1833                         team3_score = 1;
1834                 else if(head.team == NUM_TEAM_4)
1835                         team4_score = 1;
1836         }
1837
1838         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1839         {
1840                 if(head.team == NUM_TEAM_1)
1841                         team1_score = 1;
1842                 else if(head.team == NUM_TEAM_2)
1843                         team2_score = 1;
1844                 else if(head.team == NUM_TEAM_3)
1845                         team3_score = 1;
1846                 else if(head.team == NUM_TEAM_4)
1847                         team4_score = 1;
1848         }
1849
1850         ClearWinners();
1851         if(team1_score + team2_score + team3_score + team4_score == 0)
1852         {
1853                 checkrules_equality = true;
1854                 return WINNING_YES;
1855         }
1856         else if(team1_score + team2_score + team3_score + team4_score == 1)
1857         {
1858                 float t, i;
1859                 if(team1_score)
1860                         t = NUM_TEAM_1;
1861                 else if(team2_score)
1862                         t = NUM_TEAM_2;
1863                 else if(team3_score)
1864                         t = NUM_TEAM_3;
1865                 else // if(team4_score)
1866                         t = NUM_TEAM_4;
1867                 CheckAllowedTeams(world);
1868                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1869                 {
1870                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1871                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1872                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1873                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1874                 }
1875
1876                 AddWinners(team, t);
1877                 return WINNING_YES;
1878         }
1879         else
1880                 return WINNING_NO;
1881 }
1882
1883 /*
1884 ============
1885 CheckRules_World
1886
1887 Exit deathmatch games upon conditions
1888 ============
1889 */
1890 void CheckRules_World()
1891 {
1892         float timelimit;
1893         float fraglimit;
1894         float leadlimit;
1895
1896         VoteThink();
1897         MapVote_Think();
1898
1899         SetDefaultAlpha();
1900
1901         if (gameover)   // someone else quit the game already
1902         {
1903                 if(player_count == 0) // Nobody there? Then let's go to the next map
1904                         MapVote_Start();
1905                         // this will actually check the player count in the next frame
1906                         // again, but this shouldn't hurt
1907                 return;
1908         }
1909
1910         timelimit = autocvar_timelimit * 60;
1911         fraglimit = autocvar_fraglimit;
1912         leadlimit = autocvar_leadlimit;
1913
1914         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1915         {
1916                 if(timelimit > 0)
1917                         timelimit = 0; // timelimit is not made for warmup
1918                 if(fraglimit > 0)
1919                         fraglimit = 0; // no fraglimit for now
1920                 leadlimit = 0; // no leadlimit for now
1921         }
1922
1923         if(timelimit > 0)
1924         {
1925                 timelimit += game_starttime;
1926         }
1927         else if (timelimit < 0)
1928         {
1929                 // endmatch
1930                 NextLevel();
1931                 return;
1932         }
1933
1934         float wantovertime;
1935         wantovertime = 0;
1936
1937         if(timelimit > game_starttime)
1938                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1939         else
1940                 game_completion_ratio = 0;
1941
1942         if(checkrules_suddendeathend)
1943         {
1944                 if(!checkrules_suddendeathwarning)
1945                 {
1946                         checkrules_suddendeathwarning = true;
1947                         if(g_race && !g_race_qualifying)
1948                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1949                         else
1950                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1951                 }
1952         }
1953         else
1954         {
1955                 if (timelimit && time >= timelimit)
1956                 {
1957                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1958                         {
1959                                 float totalplayers;
1960                                 float playerswithlaps;
1961                                 float readyplayers;
1962                                 entity head;
1963                                 totalplayers = playerswithlaps = readyplayers = 0;
1964                                 FOR_EACH_PLAYER(head)
1965                                 {
1966                                         ++totalplayers;
1967                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1968                                                 ++playerswithlaps;
1969                                         if(head.ready)
1970                                                 ++readyplayers;
1971                                 }
1972
1973                                 // at least 2 of the players have completed a lap: start the RACE
1974                                 // otherwise, the players should end the qualifying on their own
1975                                 if(readyplayers || playerswithlaps >= 2)
1976                                 {
1977                                         checkrules_suddendeathend = 0;
1978                                         ReadyRestart(); // go to race
1979                                         return;
1980                                 }
1981                                 else
1982                                         wantovertime |= InitiateSuddenDeath();
1983                         }
1984                         else
1985                                 wantovertime |= InitiateSuddenDeath();
1986                 }
1987         }
1988
1989         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1990         {
1991                 NextLevel();
1992                 return;
1993         }
1994
1995         int checkrules_status = WinningCondition_RanOutOfSpawns();
1996         if(checkrules_status == WINNING_YES)
1997                 bprint("Hey! Someone ran out of spawns!\n");
1998         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1999                 checkrules_status = ret_float;
2000         else
2001                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2002
2003         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2004         {
2005                 checkrules_status = WINNING_NEVER;
2006                 checkrules_overtimesadded = -1;
2007                 wantovertime |= InitiateSuddenDeath();
2008         }
2009
2010         if(checkrules_status == WINNING_NEVER)
2011                 // equality cases! Nobody wins if the overtime ends in a draw.
2012                 ClearWinners();
2013
2014         if(wantovertime)
2015         {
2016                 if(checkrules_status == WINNING_NEVER)
2017                         InitiateOvertime();
2018                 else
2019                         checkrules_status = WINNING_YES;
2020         }
2021
2022         if(checkrules_suddendeathend)
2023                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2024                         checkrules_status = WINNING_YES;
2025
2026         if(checkrules_status == WINNING_YES)
2027         {
2028                 //print("WINNING\n");
2029                 NextLevel();
2030         }
2031 }
2032
2033 string GotoMap(string m)
2034 {
2035         m = GameTypeVote_MapInfo_FixName(m);
2036         if (!m)
2037                 return "The map you suggested is not available on this server.";
2038         if (!autocvar_sv_vote_gametype)
2039         if(!MapInfo_CheckMap(m))
2040                 return "The map you suggested does not support the current game mode.";
2041         cvar_set("nextmap", m);
2042         cvar_set("timelimit", "-1");
2043         if(mapvote_initialized || alreadychangedlevel)
2044         {
2045                 if(DoNextMapOverride(0))
2046                         return "Map switch initiated.";
2047                 else
2048                         return "Hm... no. For some reason I like THIS map more.";
2049         }
2050         else
2051                 return "Map switch will happen after scoreboard.";
2052 }
2053
2054
2055 void EndFrame()
2056 {SELFPARAM();
2057         anticheat_endframe();
2058
2059         float altime;
2060         entity e_;
2061         FOR_EACH_REALCLIENT(e_)
2062         {
2063                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2064                 if(e.typehitsound)
2065                         e_.typehit_time = time;
2066                 else if(e.damage_dealt)
2067                 {
2068                         e_.hit_time = time;
2069                         e_.damage_dealt_total += ceil(e.damage_dealt);
2070                 }
2071         }
2072         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2073         // add 1 frametime because after this, engine SV_Physics
2074         // increases time by a frametime and then networks the frame
2075         // add another frametime because client shows everything with
2076         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2077         // needed!
2078         FOR_EACH_CLIENT(e_)
2079         {
2080                 e_.typehitsound = false;
2081                 e_.damage_dealt = 0;
2082                 setself(e_);
2083                 antilag_record(e_, altime);
2084         }
2085         FOR_EACH_MONSTER(e_)
2086         {
2087                 setself(e_);
2088                 antilag_record(e_, altime);
2089         }
2090 }
2091
2092
2093 /*
2094  * RedirectionThink:
2095  * returns true if redirecting
2096  */
2097 float redirection_timeout;
2098 float redirection_nextthink;
2099 float RedirectionThink()
2100 {SELFPARAM();
2101         float clients_found;
2102
2103         if(redirection_target == "")
2104                 return false;
2105
2106         if(!redirection_timeout)
2107         {
2108                 cvar_set("sv_public", "-2");
2109                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2110                 if(redirection_target == "self")
2111                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2112                 else
2113                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2114         }
2115
2116         if(time < redirection_nextthink)
2117                 return true;
2118
2119         redirection_nextthink = time + 1;
2120
2121         clients_found = 0;
2122         entity e;
2123         FOR_EACH_REALCLIENT(e)
2124         {
2125                 setself(e);
2126                 // TODO add timer
2127                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2128                 if(redirection_target == "self")
2129                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2130                 else
2131                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2132                 ++clients_found;
2133         }
2134
2135         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2136
2137         if(time > redirection_timeout || clients_found == 0)
2138                 localcmd("\nwait; wait; wait; quit\n");
2139
2140         return true;
2141 }
2142
2143 void TargetMusic_RestoreGame();
2144 void RestoreGame()
2145 {
2146         // Loaded from a save game
2147         // some things then break, so let's work around them...
2148
2149         // Progs DB (capture records)
2150         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2151
2152         // Mapinfo
2153         MapInfo_Shutdown();
2154         MapInfo_Enumerate();
2155         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2156         WeaponStats_Init();
2157
2158         TargetMusic_RestoreGame();
2159 }
2160
2161 void Shutdown()
2162 {
2163         gameover = 2;
2164
2165         if(world_initialized > 0)
2166         {
2167                 world_initialized = 0;
2168                 LOG_INFO("Saving persistent data...\n");
2169                 Ban_SaveBans();
2170
2171                 // playerstats with unfinished match
2172                 PlayerStats_GameReport(false);
2173
2174                 if(!cheatcount_total)
2175                 {
2176                         if(autocvar_sv_db_saveasdump)
2177                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2178                         else
2179                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                 }
2181                 if(autocvar_developer)
2182                 {
2183                         if(autocvar_sv_db_saveasdump)
2184                                 db_dump(TemporaryDB, "server-temp.db");
2185                         else
2186                                 db_save(TemporaryDB, "server-temp.db");
2187                 }
2188                 CheatShutdown(); // must be after cheatcount check
2189                 db_close(ServerProgsDB);
2190                 db_close(TemporaryDB);
2191                 LOG_INFO("done!\n");
2192                 // tell the bot system the game is ending now
2193                 bot_endgame();
2194
2195                 WeaponStats_Shutdown();
2196                 MapInfo_Shutdown();
2197         }
2198         else if(world_initialized == 0)
2199         {
2200                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2201         }
2202 }