qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("teamplay_mode");
 421                 BADCVAR("timelimit_override");
 422                 BADCVAR("g_spawnshieldtime");
 423                 BADPREFIX("g_warmup_");
 424                 BADPREFIX("sv_ready_restart_");
 425
 426                 // mutators that announce themselves properly to the server browser
 427                 BADCVAR("g_minstagib");
 428                 BADCVAR("g_new_toys");
 429                 BADCVAR("g_nix");
 430                 BADCVAR("g_grappling_hook");
 431                 BADCVAR("g_jetpack");
 432
 433 #undef BADPREFIX
 434 #undef BADCVAR
 435
 436                 if(pureadding)
 437                 {
 438                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 439                         if(strlen(cvar_purechanges) > 16384)
 440                         {
 441                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 442                                 pureadding = 0;
 443                         }
 444                 }
 445                 ++cvar_purechanges_count;
 446                 // WARNING: this variable is used for the server list
 447                 // NEVER dare to skip this code!
 448                 // Hacks to intentionally appearing as "pure server" even though you DO have
 449                 // modified settings may be punished by removal from the server list.
 450                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 451                 // though.
 452         }
 453         buf_del(h);
 454         if(cvar_changes == "")
 455                 cvar_changes = "// this server runs at default server settings\n";
 456         else
 457                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 458         cvar_changes = strzone(cvar_changes);
 459         if(cvar_purechanges == "")
 460                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 461         else
 462                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 463         cvar_purechanges = strzone(cvar_purechanges);
 464 }
 465
 466 void detect_maptype()
 467 {
 468 #if 0
 469         vector o, v;
 470         float i;
 471
 472         for(;;)
 473         {
 474                 o = world.mins;
 475                 o_x += random() * (world.maxs_x - world.mins_x);
 476                 o_y += random() * (world.maxs_y - world.mins_y);
 477                 o_z += random() * (world.maxs_z - world.mins_z);
 478
 479                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 480                 if(trace_fraction == 1)
 481                         continue;
 482
 483                 v = trace_endpos;
 484
 485                 for(i = 0; i < 64; i += 4)
 486                 {
 487                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 488         if(trace_fraction == 1)
 489                 continue;
 490                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 491                 }
 492
 493                 break;
 494         }
 495 #endif
 496 }
 497
 498 entity randomseed;
 499 float RandomSeed_Send(entity to, float sf)
 500 {
 501         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 502         WriteShort(MSG_ENTITY, self.cnt);
 503         return TRUE;
 504 }
 505 void RandomSeed_Think()
 506 {
 507         self.cnt = bound(0, floor(random() * 65536), 65535);
 508         self.nextthink = time + 5;
 509
 510         self.SendFlags |= 1;
 511 }
 512 void RandomSeed_Spawn()
 513 {
 514         randomseed = spawn();
 515         randomseed.think = RandomSeed_Think;
 516         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 517
 518         entity oldself;
 519         oldself = self;
 520         self = randomseed;
 521         self.think(); // sets random seed and nextthink
 522         self = oldself;
 523 }
 524
 525 void spawnfunc___init_dedicated_server(void)
 526 {
 527         // handler for _init/_init map (only for dedicated server initialization)
 528
 529         world_initialized = -1; // don't complain
 530         cvar = cvar_normal;
 531         cvar_string = cvar_string_normal;
 532         cvar_set = cvar_set_normal;
 533
 534         remove = remove_unsafely;
 535
 536         entity e;
 537         e = spawn();
 538         e.think = GotoFirstMap;
 539         e.nextthink = time; // this is usually 1 at this point
 540
 541         e = spawn();
 542         e.classname = "info_player_deathmatch"; // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 548         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 549         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 550         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 551
 552         MapInfo_Enumerate();
 553         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 554 }
 555
 556 void Map_MarkAsRecent(string m);
 557 float world_already_spawned;
 558 void Nagger_Init();
 559 void ClientInit_Spawn();
 560 void WeaponStats_Init();
 561 void WeaponStats_Shutdown();
 562 void spawnfunc_worldspawn (void)
 563 {
 564         float fd, l, i, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = TRUE;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         check_unacceptable_compiler_bugs();
 578
 579         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 580
 581         compressShortVector_init();
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 597         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 598         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WepSet_AddStat();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 776         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 777         Nagger_Init();
 778
 779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 794         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         // g_movementspeed hack
 799         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 800         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 801         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 802         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 803
 804         // secrets
 805         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 806         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 807
 808         // misc
 809         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 810
 811         next_pingtime = time + 5;
 812
 813         detect_maptype();
 814
 815         // set up information replies for clients and server to use
 816         maplist_reply = strzone(getmaplist());
 817         lsmaps_reply = strzone(getlsmaps());
 818         for(i = 0; i < 10; ++i)
 819         {
 820                 s = getrecords(i);
 821                 if (s)
 822                         records_reply[i] = strzone(s);
 823         }
 824         ladder_reply = strzone(getladder());
 825         rankings_reply = strzone(getrankings());
 826
 827         // begin other init
 828         ClientInit_Spawn();
 829         RandomSeed_Spawn();
 830         PingPLReport_Spawn();
 831
 832         CheatInit();
 833
 834         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 835
 836         // fill sv_curl_serverpackages from .serverpackage files
 837         if(autocvar_sv_curl_serverpackages_auto)
 838         {
 839                 s = "";
 840                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 841                 for(i = 0; i < n; ++i)
 842                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 843                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 844                                 s = strcat(s, " ", argv(i));
 845                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 846                 if(fd >= 0)
 847                 {
 848                         j = search_getsize(fd);
 849                         for(i = 0; i < j; ++i)
 850                                 s = strcat(s, " ", search_getfilename(fd, i));
 851                         search_end(fd);
 852                 }
 853                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 854                 if(fd >= 0)
 855                 {
 856                         j = search_getsize(fd);
 857                         for(i = 0; i < j; ++i)
 858                                 s = strcat(s, " ", search_getfilename(fd, i));
 859                         search_end(fd);
 860                 }
 861                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 862         }
 863
 864         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 865         modname = "Xonotic";
 866         // physics/balance/config changes that count as mod
 867         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 868                 modname = cvar_string("g_mod_physics");
 869         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 870                 modname = cvar_string("g_mod_balance");
 871         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 872                 modname = cvar_string("g_mod_config");
 873         // extra mutators that deserve to count as mod
 874         MUTATOR_CALLHOOK(SetModname);
 875
 876         // save it for later
 877         modname = strzone(modname);
 878
 879         WinningConditionHelper(); // set worldstatus
 880
 881         world_initialized = 1;
 882 }
 883
 884 void spawnfunc_light (void)
 885 {
 886         //makestatic (self); // Who the f___ did that?
 887         remove(self);
 888 }
 889
 890 string GetGametype()
 891 {
 892         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 893 }
 894
 895 string getmapname_stored;
 896 string GetMapname()
 897 {
 898         return mapname;
 899 }
 900
 901 float Map_Count, Map_Current;
 902 string Map_Current_Name;
 903
 904 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 905 float GetMaplistPosition()
 906 {
 907         float pos, idx;
 908         string map;
 909
 910         map = GetMapname();
 911         idx = autocvar_g_maplist_index;
 912
 913         if(idx >= 0)
 914                 if(idx < Map_Count)
 915                         if(map == argv(idx))
 916                                 return idx;
 917
 918         for(pos = 0; pos < Map_Count; ++pos)
 919                 if(map == argv(pos))
 920                         return pos;
 921
 922         // resume normal maplist rotation if current map is not in g_maplist
 923         return idx;
 924 }
 925
 926 float MapHasRightSize(string map)
 927 {
 928         float fh;
 929         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 930         if(autocvar_g_maplist_check_waypoints)
 931         {
 932                 dprint("checkwp "); dprint(map);
 933                 if(!fexists(strcat("maps/", map, ".waypoints")))
 934                 {
 935                         dprint(": no waypoints\n");
 936                         return FALSE;
 937                 }
 938                 dprint(": has waypoints\n");
 939         }
 940
 941         // open map size restriction file
 942         dprint("opensize "); dprint(map);
 943         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 944         if(fh >= 0)
 945         {
 946                 float mapmin, mapmax;
 947                 dprint(": ok, ");
 948                 mapmin = stof(fgets(fh));
 949                 mapmax = stof(fgets(fh));
 950                 fclose(fh);
 951                 if(player_count < mapmin)
 952                 {
 953                         dprint("not enough\n");
 954                         return FALSE;
 955                 }
 956                 if(player_count > mapmax)
 957                 {
 958                         dprint("too many\n");
 959                         return FALSE;
 960                 }
 961                 dprint("right size\n");
 962                 return TRUE;
 963         }
 964         dprint(": not found\n");
 965         return TRUE;
 966 }
 967
 968 string Map_Filename(float position)
 969 {
 970         return strcat("maps/", argv(position), ".bsp");
 971 }
 972
 973 string strwords(string s, float w)
 974 {
 975         float endpos;
 976         for(endpos = 0; w && endpos >= 0; --w)
 977                 endpos = strstrofs(s, " ", endpos + 1);
 978         if(endpos < 0)
 979                 return s;
 980         else
 981                 return substring(s, 0, endpos);
 982 }
 983
 984 float strhasword(string s, string w)
 985 {
 986         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 987 }
 988
 989 void Map_MarkAsRecent(string m)
 990 {
 991         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 992 }
 993
 994 float Map_IsRecent(string m)
 995 {
 996         return strhasword(autocvar_g_maplist_mostrecent, m);
 997 }
 998
 999 float Map_Check(float position, float pass)
1000 {
1001         string filename;
1002         string map_next;
1003         map_next = argv(position);
1004         if(pass <= 1)
1005         {
1006                 if(Map_IsRecent(map_next))
1007                         return 0;
1008         }
1009         filename = Map_Filename(position);
1010         if(MapInfo_CheckMap(map_next))
1011         {
1012                 if(pass == 2)
1013                         return 1;
1014                 if(MapHasRightSize(map_next))
1015                         return 1;
1016                 return 0;
1017         }
1018         else
1019                 dprint( "Couldn't select '", filename, "'..\n" );
1020
1021         return 0;
1022 }
1023
1024 void Map_Goto_SetStr(string nextmapname)
1025 {
1026         if(getmapname_stored != "")
1027                 strunzone(getmapname_stored);
1028         if(nextmapname == "")
1029                 getmapname_stored = "";
1030         else
1031                 getmapname_stored = strzone(nextmapname);
1032 }
1033
1034 void Map_Goto_SetFloat(float position)
1035 {
1036         cvar_set("g_maplist_index", ftos(position));
1037         Map_Goto_SetStr(argv(position));
1038 }
1039
1040 void Map_Goto(float reinit)
1041 {
1042         MapInfo_LoadMap(getmapname_stored, reinit);
1043 }
1044
1045 // return codes of map selectors:
1046 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1047 //   -2 = permanent failure
1048 float() MaplistMethod_Iterate = // usual method
1049 {
1050         float pass, i;
1051
1052         for(pass = 1; pass <= 2; ++pass)
1053         {
1054                 for(i = 1; i < Map_Count; ++i)
1055                 {
1056                         float mapindex;
1057                         mapindex = mod(i + Map_Current, Map_Count);
1058                         if(Map_Check(mapindex, pass))
1059                                 return mapindex;
1060                 }
1061         }
1062         return -1;
1063 }
1064
1065 float() MaplistMethod_Repeat = // fallback method
1066 {
1067         if(Map_Check(Map_Current, 2))
1068                 return Map_Current;
1069         return -2;
1070 }
1071
1072 float() MaplistMethod_Random = // random map selection
1073 {
1074         float i, imax;
1075
1076         imax = 42;
1077
1078         for(i = 0; i <= imax; ++i)
1079         {
1080                 float mapindex;
1081                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1082                 if(Map_Check(mapindex, 1))
1083                         return mapindex;
1084         }
1085         return -1;
1086 }
1087
1088 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1089 // the exponent sets a bias on the map selection:
1090 // the higher the exponent, the less likely "shortly repeated" same maps are
1091 {
1092         float i, j, imax, insertpos;
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 string newlist;
1099
1100                 // now reinsert this at another position
1101                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1102                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1103                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1104                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1105
1106                 // insert the current map there
1107                 newlist = "";
1108                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1109                         newlist = strcat(newlist, " ", argv(j));
1110                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1111                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1112                         newlist = strcat(newlist, " ", argv(j));
1113                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1114                 cvar_set("g_maplist", newlist);
1115                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1116
1117                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1118                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1119                 if(Map_Check(Map_Current, 1))
1120                         return Map_Current;
1121         }
1122         return -1;
1123 }
1124
1125 void Maplist_Init()
1126 {
1127         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128         if(Map_Count == 0)
1129         {
1130                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1131                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1132                 if(autocvar_g_maplist_shuffle)
1133                         ShuffleMaplist();
1134                 localcmd("\nmenu_cmd sync\n");
1135                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1136         }
1137         if(Map_Count == 0)
1138                 error("empty maplist, cannot select a new map");
1139         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1140
1141         if(Map_Current_Name)
1142                 strunzone(Map_Current_Name);
1143         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1144         // this may or may not be correct, but who cares, in the worst case a map
1145         // isn't chosen in the first pass that should have been
1146 }
1147
1148 string GetNextMap()
1149 {
1150         float nextMap;
1151
1152         Maplist_Init();
1153         nextMap = -1;
1154
1155         if(nextMap == -1)
1156                 if(autocvar_g_maplist_shuffle > 0)
1157                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1158
1159         if(nextMap == -1)
1160                 if(autocvar_g_maplist_selectrandom)
1161                         nextMap = MaplistMethod_Random();
1162
1163         if(nextMap == -1)
1164                 nextMap = MaplistMethod_Iterate();
1165
1166         if(nextMap == -1)
1167                 nextMap = MaplistMethod_Repeat();
1168
1169         if(nextMap >= 0)
1170         {
1171                 Map_Goto_SetFloat(nextMap);
1172                 return getmapname_stored;
1173         }
1174
1175         return "";
1176 }
1177
1178 float DoNextMapOverride(float reinit)
1179 {
1180         if(autocvar_g_campaign)
1181         {
1182                 CampaignPostIntermission();
1183                 alreadychangedlevel = TRUE;
1184                 return TRUE;
1185         }
1186         if(autocvar_quit_when_empty)
1187         {
1188                 if(player_count <= currentbots)
1189                 {
1190                         localcmd("quit\n");
1191                         alreadychangedlevel = TRUE;
1192                         return TRUE;
1193                 }
1194         }
1195         if(autocvar_quit_and_redirect != "")
1196         {
1197                 redirection_target = strzone(autocvar_quit_and_redirect);
1198                 alreadychangedlevel = TRUE;
1199                 return TRUE;
1200         }
1201         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1202         {
1203                 localcmd("restart\n");
1204                 alreadychangedlevel = TRUE;
1205                 return TRUE;
1206         }
1207         if(autocvar_nextmap != "")
1208                 if(MapInfo_CheckMap(autocvar_nextmap))
1209                 {
1210                         Map_Goto_SetStr(autocvar_nextmap);
1211                         Map_Goto(reinit);
1212                         alreadychangedlevel = TRUE;
1213                         return TRUE;
1214                 }
1215         if(!reinit && autocvar_lastlevel)
1216         {
1217                 cvar_settemp_restore();
1218                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1219                 alreadychangedlevel = TRUE;
1220                 return TRUE;
1221         }
1222         return FALSE;
1223 }
1224
1225 void GotoNextMap(float reinit)
1226 {
1227         //string nextmap;
1228         //float n, nummaps;
1229         //string s;
1230         if (alreadychangedlevel)
1231                 return;
1232         alreadychangedlevel = TRUE;
1233
1234         {
1235                 string nextMap;
1236                 float allowReset;
1237
1238                 for(allowReset = 1; allowReset >= 0; --allowReset)
1239                 {
1240                         nextMap = GetNextMap();
1241                         if(nextMap != "")
1242                                 break;
1243
1244                         if(allowReset)
1245                         {
1246                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1247                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1248                                 if(autocvar_g_maplist_shuffle)
1249                                         ShuffleMaplist();
1250                                 localcmd("\nmenu_cmd sync\n");
1251                         }
1252                         else
1253                         {
1254                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1255                         }
1256                 }
1257                 Map_Goto(reinit);
1258         }
1259 }
1260
1261
1262 /*
1263 ============
1264 IntermissionThink
1265
1266 When the player presses attack or jump, change to the next level
1267 ============
1268 */
1269 .float autoscreenshot;
1270 void() MapVote_Start;
1271 void() MapVote_Think;
1272 float mapvote_initialized;
1273 void IntermissionThink()
1274 {
1275         FixIntermissionClient(self);
1276
1277         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1278         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1279
1280         if( (server_screenshot || client_screenshot)
1281                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1282         {
1283                 self.autoscreenshot = -1;
1284                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1285                 return;
1286         }
1287
1288         if (time < intermission_exittime)
1289                 return;
1290
1291         if(!mapvote_initialized)
1292                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1293                         return;
1294
1295         MapVote_Start();
1296 }
1297
1298 /*
1299 ============
1300 FindIntermission
1301
1302 Returns the entity to view from
1303 ============
1304 */
1305 /*
1306 entity FindIntermission()
1307 {
1308         local   entity spot;
1309         local   float cyc;
1310
1311 // look for info_intermission first
1312         spot = find (world, classname, "info_intermission");
1313         if (spot)
1314         {       // pick a random one
1315                 cyc = random() * 4;
1316                 while (cyc > 1)
1317                 {
1318                         spot = find (spot, classname, "info_intermission");
1319                         if (!spot)
1320                                 spot = find (spot, classname, "info_intermission");
1321                         cyc = cyc - 1;
1322                 }
1323                 return spot;
1324         }
1325
1326 // then look for the start position
1327         spot = find (world, classname, "info_player_start");
1328         if (spot)
1329                 return spot;
1330
1331 // testinfo_player_start is only found in regioned levels
1332         spot = find (world, classname, "testplayerstart");
1333         if (spot)
1334                 return spot;
1335
1336 // then look for the start position
1337         spot = find (world, classname, "info_player_deathmatch");
1338         if (spot)
1339                 return spot;
1340
1341         //objerror ("FindIntermission: no spot");
1342         return world;
1343 }
1344 */
1345
1346 /*
1347 ===============================================================================
1348
1349 RULES
1350
1351 ===============================================================================
1352 */
1353
1354 void DumpStats(float final)
1355 {
1356         float file;
1357         string s;
1358         float to_console;
1359         float to_eventlog;
1360         float to_file;
1361         float i;
1362
1363         to_console = autocvar_sv_logscores_console;
1364         to_eventlog = autocvar_sv_eventlog;
1365         to_file = autocvar_sv_logscores_file;
1366
1367         if(!final)
1368         {
1369                 to_console = TRUE; // always print printstats replies
1370                 to_eventlog = FALSE; // but never print them to the event log
1371         }
1372
1373         if(to_eventlog)
1374                 if(autocvar_sv_eventlog_console)
1375                         to_console = FALSE; // otherwise we get the output twice
1376
1377         if(final)
1378                 s = ":scores:";
1379         else
1380                 s = ":status:";
1381         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1382
1383         if(to_console)
1384                 print(s, "\n");
1385         if(to_eventlog)
1386                 GameLogEcho(s);
1387
1388         file = -1;
1389         if(to_file)
1390         {
1391                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1392                 if(file == -1)
1393                         to_file = FALSE;
1394                 else
1395                         fputs(file, strcat(s, "\n"));
1396         }
1397
1398         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1399         if(to_console)
1400                 print(s, "\n");
1401         if(to_eventlog)
1402                 GameLogEcho(s);
1403         if(to_file)
1404                 fputs(file, strcat(s, "\n"));
1405
1406         FOR_EACH_CLIENT(other)
1407         {
1408                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1409                 {
1410                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1411                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1412                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1413                                 s = strcat(s, ftos(other.team), ":");
1414                         else
1415                                 s = strcat(s, "spectator:");
1416
1417                         if(to_console)
1418                                 print(s, other.netname, "\n");
1419                         if(to_eventlog)
1420                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1421                         if(to_file)
1422                                 fputs(file, strcat(s, other.netname, "\n"));
1423                 }
1424         }
1425
1426         if(teamplay)
1427         {
1428                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1429                 if(to_console)
1430                         print(s, "\n");
1431                 if(to_eventlog)
1432                         GameLogEcho(s);
1433                 if(to_file)
1434                         fputs(file, strcat(s, "\n"));
1435
1436                 for(i = 1; i < 16; ++i)
1437                 {
1438                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1439                         s = strcat(s, ":", ftos(i));
1440                         if(to_console)
1441                                 print(s, "\n");
1442                         if(to_eventlog)
1443                                 GameLogEcho(s);
1444                         if(to_file)
1445                                 fputs(file, strcat(s, "\n"));
1446                 }
1447         }
1448
1449         if(to_console)
1450                 print(":end\n");
1451         if(to_eventlog)
1452                 GameLogEcho(":end");
1453         if(to_file)
1454         {
1455                 fputs(file, ":end\n");
1456                 fclose(file);
1457         }
1458 }
1459
1460 void FixIntermissionClient(entity e)
1461 {
1462         string s;
1463         if(!e.autoscreenshot) // initial call
1464         {
1465                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1466                 e.health = -2342;
1467                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1468                 e.solid = SOLID_NOT;
1469                 e.movetype = MOVETYPE_NONE;
1470                 e.takedamage = DAMAGE_NO;
1471                 if(e.weaponentity)
1472                 {
1473                         e.weaponentity.effects = EF_NODRAW;
1474                         if (e.weaponentity.weaponentity)
1475                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1476                 }
1477                 if(IS_REAL_CLIENT(e))
1478                 {
1479                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1480                         s = autocvar_sv_intermission_cdtrack;
1481                         if(s != "")
1482                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1483                         msg_entity = e;
1484                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1485                 }
1486         }
1487 }
1488
1489 /*
1490 go to the next level for deathmatch
1491 only called if a time or frag limit has expired
1492 */
1493 void NextLevel()
1494 {
1495         gameover = TRUE;
1496
1497         intermission_running = 1;
1498
1499 // enforce a wait time before allowing changelevel
1500         if(player_count > 0)
1501                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1502         else
1503                 intermission_exittime = -1;
1504
1505         /*
1506         WriteByte (MSG_ALL, SVC_CDTRACK);
1507         WriteByte (MSG_ALL, 3);
1508         WriteByte (MSG_ALL, 3);
1509         // done in FixIntermission
1510         */
1511
1512         //pos = FindIntermission ();
1513
1514         VoteReset();
1515
1516         DumpStats(TRUE);
1517
1518         // send statistics
1519         entity e;
1520         PlayerStats_EndMatch(1);
1521         FOR_EACH_CLIENT(e)
1522                 PlayerStats_AddGlobalInfo(e);
1523         PlayerStats_Shutdown();
1524         WeaponStats_Shutdown();
1525
1526         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1527
1528         if(autocvar_sv_eventlog)
1529                 GameLogEcho(":gameover");
1530
1531         GameLogClose();
1532
1533         FOR_EACH_PLAYER(other) {
1534                 FixIntermissionClient(other);
1535                 if(other.winning)
1536                         bprint(other.netname, " ^7wins.\n");
1537         }
1538
1539         if(autocvar_g_campaign)
1540                 CampaignPreIntermission();
1541
1542         MUTATOR_CALLHOOK(MatchEnd);
1543
1544         localcmd("\nsv_hook_gameend\n");
1545 }
1546
1547 /*
1548 ============
1549 CheckRules_Player
1550
1551 Exit deathmatch games upon conditions
1552 ============
1553 */
1554 void CheckRules_Player()
1555 {
1556         if (gameover)   // someone else quit the game already
1557                 return;
1558
1559         if(self.deadflag == DEAD_NO)
1560                 self.play_time += frametime;
1561
1562         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1563         //   (div0: and that in CheckRules_World please)
1564 }
1565
1566 float checkrules_equality;
1567 float checkrules_suddendeathwarning;
1568 float checkrules_suddendeathend;
1569 float checkrules_overtimesadded; //how many overtimes have been already added
1570
1571 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1572 const float WINNING_YES = 1; // winner found
1573 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1574 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1575
1576 float InitiateSuddenDeath()
1577 {
1578         // Check first whether normal overtimes could be added before initiating suddendeath mode
1579         // - for this timelimit_overtime needs to be >0 of course
1580         // - also check the winning condition calculated in the previous frame and only add normal overtime
1581         //   again, if at the point at which timelimit would be extended again, still no winner was found
1582         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1583         {
1584                 return 1; // need to call InitiateOvertime later
1585         }
1586         else
1587         {
1588                 if(!checkrules_suddendeathend)
1589                 {
1590                         if(autocvar_g_campaign)
1591                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1592                         else
1593                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1594                         if(g_race && !g_race_qualifying)
1595                                 race_StartCompleting();
1596                 }
1597                 return 0;
1598         }
1599 }
1600
1601 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1602 {
1603         ++checkrules_overtimesadded;
1604         //add one more overtime by simply extending the timelimit
1605         float tl;
1606         tl = autocvar_timelimit;
1607         tl += autocvar_timelimit_overtime;
1608         cvar_set("timelimit", ftos(tl));
1609
1610         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1611 }
1612
1613 float GetWinningCode(float fraglimitreached, float equality)
1614 {
1615         if(autocvar_g_campaign == 1)
1616                 if(fraglimitreached)
1617                         return WINNING_YES;
1618                 else
1619                         return WINNING_NO;
1620
1621         else
1622                 if(equality)
1623                         if(fraglimitreached)
1624                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1625                         else
1626                                 return WINNING_NEVER;
1627                 else
1628                         if(fraglimitreached)
1629                                 return WINNING_YES;
1630                         else
1631                                 return WINNING_NO;
1632 }
1633
1634 // set the .winning flag for exactly those players with a given field value
1635 void SetWinners(.float field, float value)
1636 {
1637         entity head;
1638         FOR_EACH_PLAYER(head)
1639                 head.winning = (head.field == value);
1640 }
1641
1642 // set the .winning flag for those players with a given field value
1643 void AddWinners(.float field, float value)
1644 {
1645         entity head;
1646         FOR_EACH_PLAYER(head)
1647                 if(head.field == value)
1648                         head.winning = 1;
1649 }
1650
1651 // clear the .winning flags
1652 void ClearWinners(void)
1653 {
1654         entity head;
1655         FOR_EACH_PLAYER(head)
1656                 head.winning = 0;
1657 }
1658
1659 // Onslaught winning condition:
1660 // game terminates if only one team has a working generator (or none)
1661 float WinningCondition_Onslaught()
1662 {
1663         entity head;
1664         float t1, t2, t3, t4;
1665
1666         WinningConditionHelper(); // set worldstatus
1667
1668         if(warmup_stage)
1669                 return WINNING_NO;
1670
1671         // first check if the game has ended
1672         t1 = t2 = t3 = t4 = 0;
1673         head = find(world, classname, "onslaught_generator");
1674         while (head)
1675         {
1676                 if (head.health > 0)
1677                 {
1678                         if (head.team == NUM_TEAM_1) t1 = 1;
1679                         if (head.team == NUM_TEAM_2) t2 = 1;
1680                         if (head.team == NUM_TEAM_3) t3 = 1;
1681                         if (head.team == NUM_TEAM_4) t4 = 1;
1682                 }
1683                 head = find(head, classname, "onslaught_generator");
1684         }
1685         if (t1 + t2 + t3 + t4 < 2)
1686         {
1687                 // game over, only one team remains (or none)
1688                 ClearWinners();
1689                 if (t1) SetWinners(team, NUM_TEAM_1);
1690                 if (t2) SetWinners(team, NUM_TEAM_2);
1691                 if (t3) SetWinners(team, NUM_TEAM_3);
1692                 if (t4) SetWinners(team, NUM_TEAM_4);
1693                 dprint("Have a winner, ending game.\n");
1694                 return WINNING_YES;
1695         }
1696
1697         // Two or more teams remain
1698         return WINNING_NO;
1699 }
1700
1701 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1702 // they win. Otherwise the defending team wins once the timelimit passes.
1703 void assault_new_round();
1704 float WinningCondition_Assault()
1705 {
1706         float status;
1707
1708         WinningConditionHelper(); // set worldstatus
1709
1710         status = WINNING_NO;
1711         // as the timelimit has not yet passed just assume the defending team will win
1712         if(assault_attacker_team == NUM_TEAM_1)
1713         {
1714                 SetWinners(team, NUM_TEAM_2);
1715         }
1716         else
1717         {
1718                 SetWinners(team, NUM_TEAM_1);
1719         }
1720
1721         entity ent;
1722         ent = find(world, classname, "target_assault_roundend");
1723         if(ent)
1724         {
1725                 if(ent.winning) // round end has been triggered by attacking team
1726                 {
1727                         bprint("ASSAULT: round completed...\n");
1728                         SetWinners(team, assault_attacker_team);
1729
1730                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1731
1732                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1733                         {
1734                                 status = WINNING_YES;
1735                         }
1736                         else
1737                         {
1738                                 entity oldself;
1739                                 oldself = self;
1740                                 self = ent;
1741                                 assault_new_round();
1742                                 self = oldself;
1743                         }
1744                 }
1745         }
1746
1747         return status;
1748 }
1749
1750 // LMS winning condition: game terminates if and only if there's at most one
1751 // one player who's living lives. Top two scores being equal cancels the time
1752 // limit.
1753 float WinningCondition_LMS()
1754 {
1755         entity head, head2;
1756         float have_player;
1757         float have_players;
1758         float l;
1759
1760         have_player = FALSE;
1761         have_players = FALSE;
1762         l = LMS_NewPlayerLives();
1763
1764         head = find(world, classname, "player");
1765         if(head)
1766                 have_player = TRUE;
1767         head2 = find(head, classname, "player");
1768         if(head2)
1769                 have_players = TRUE;
1770
1771         if(have_player)
1772         {
1773                 // we have at least one player
1774                 if(have_players)
1775                 {
1776                         // two or more active players - continue with the game
1777                 }
1778                 else
1779                 {
1780                         // exactly one player?
1781
1782                         ClearWinners();
1783                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1784
1785                         if(l)
1786                         {
1787                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1788                                 return WINNING_NO;
1789                         }
1790                         else
1791                         {
1792                                 // a winner!
1793                                 // and assign him his first place
1794                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1795                                 return WINNING_YES;
1796                         }
1797                 }
1798         }
1799         else
1800         {
1801                 // nobody is playing at all...
1802                 if(l)
1803                 {
1804                         // wait for players...
1805                 }
1806                 else
1807                 {
1808                         // SNAFU (maybe a draw game?)
1809                         ClearWinners();
1810                         dprint("No players, ending game.\n");
1811                         return WINNING_YES;
1812                 }
1813         }
1814
1815         // When we get here, we have at least two players who are actually LIVING,
1816         // now check if the top two players have equal score.
1817         WinningConditionHelper();
1818
1819         ClearWinners();
1820         if(WinningConditionHelper_winner)
1821                 WinningConditionHelper_winner.winning = TRUE;
1822         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1823                 return WINNING_NEVER;
1824
1825         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1826         return WINNING_NO;
1827 }
1828
1829 void ShuffleMaplist()
1830 {
1831         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1832 }
1833
1834 float leaderfrags;
1835 float WinningCondition_Scores(float limit, float leadlimit)
1836 {
1837         float limitreached;
1838
1839         // TODO make everything use THIS winning condition (except LMS)
1840         WinningConditionHelper();
1841
1842         if(teamplay)
1843         {
1844                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1845                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1846                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1847                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1848         }
1849
1850         ClearWinners();
1851         if(WinningConditionHelper_winner)
1852                 WinningConditionHelper_winner.winning = 1;
1853         if(WinningConditionHelper_winnerteam >= 0)
1854                 SetWinners(team, WinningConditionHelper_winnerteam);
1855
1856         if(WinningConditionHelper_lowerisbetter)
1857         {
1858                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1859                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1860                 limit = -limit;
1861         }
1862
1863         if(WinningConditionHelper_zeroisworst)
1864                 leadlimit = 0; // not supported in this mode
1865
1866         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1867         // these modes always score in increments of 1, thus this makes sense
1868         {
1869                 if(leaderfrags != WinningConditionHelper_topscore)
1870                 {
1871                         leaderfrags = WinningConditionHelper_topscore;
1872
1873                         if (limit)
1874                         if (leaderfrags == limit - 1)
1875                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1876                         else if (leaderfrags == limit - 2)
1877                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1878                         else if (leaderfrags == limit - 3)
1879                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1880                 }
1881         }
1882
1883         limitreached = FALSE;
1884         if(limit)
1885                 if(WinningConditionHelper_topscore >= limit)
1886                         limitreached = TRUE;
1887         if(leadlimit)
1888         {
1889                 float leadlimitreached;
1890                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1891                 if(autocvar_leadlimit_and_fraglimit)
1892                         limitreached = (limitreached && leadlimitreached);
1893                 else
1894                         limitreached = (limitreached || leadlimitreached);
1895         }
1896
1897         if(limit)
1898                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1899
1900         return GetWinningCode(
1901                 WinningConditionHelper_topscore && limitreached,
1902                 WinningConditionHelper_equality
1903         );
1904 }
1905
1906 float WinningCondition_Race(float fraglimit)
1907 {
1908         float wc;
1909         entity p;
1910         float n, c;
1911
1912         n = 0;
1913         c = 0;
1914         FOR_EACH_PLAYER(p)
1915         {
1916                 ++n;
1917                 if(p.race_completed)
1918                         ++c;
1919         }
1920         if(n && (n == c))
1921                 return WINNING_YES;
1922         wc = WinningCondition_Scores(fraglimit, 0);
1923
1924         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1925         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1926         // do NOT support equality when the laps are all raced!
1927                 return WINNING_STARTSUDDENDEATHOVERTIME;
1928         else
1929                 return WINNING_NEVER;
1930 }
1931
1932 float WinningCondition_QualifyingThenRace(float limit)
1933 {
1934         float wc;
1935         wc = WinningCondition_Scores(limit, 0);
1936
1937         // NEVER initiate overtime
1938         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1939         {
1940                 return WINNING_YES;
1941         }
1942
1943         return wc;
1944 }
1945
1946 float WinningCondition_RanOutOfSpawns()
1947 {
1948         entity head;
1949
1950         if(have_team_spawns <= 0)
1951                 return WINNING_NO;
1952
1953         if(autocvar_g_spawn_useallspawns <= 0)
1954                 return WINNING_NO;
1955
1956         if(!some_spawn_has_been_used)
1957                 return WINNING_NO;
1958
1959         team1_score = team2_score = team3_score = team4_score = 0;
1960
1961         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1962         {
1963                 if(head.team == NUM_TEAM_1)
1964                         team1_score = 1;
1965                 else if(head.team == NUM_TEAM_2)
1966                         team2_score = 1;
1967                 else if(head.team == NUM_TEAM_3)
1968                         team3_score = 1;
1969                 else if(head.team == NUM_TEAM_4)
1970                         team4_score = 1;
1971         }
1972
1973         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1974         {
1975                 if(head.team == NUM_TEAM_1)
1976                         team1_score = 1;
1977                 else if(head.team == NUM_TEAM_2)
1978                         team2_score = 1;
1979                 else if(head.team == NUM_TEAM_3)
1980                         team3_score = 1;
1981                 else if(head.team == NUM_TEAM_4)
1982                         team4_score = 1;
1983         }
1984
1985         ClearWinners();
1986         if(team1_score + team2_score + team3_score + team4_score == 0)
1987         {
1988                 checkrules_equality = TRUE;
1989                 return WINNING_YES;
1990         }
1991         else if(team1_score + team2_score + team3_score + team4_score == 1)
1992         {
1993                 float t, i;
1994                 if(team1_score)
1995                         t = NUM_TEAM_1;
1996                 else if(team2_score)
1997                         t = NUM_TEAM_2;
1998                 else if(team3_score)
1999                         t = NUM_TEAM_3;
2000                 else // if(team4_score)
2001                         t = NUM_TEAM_4;
2002                 CheckAllowedTeams(world);
2003                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2004                 {
2005                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2006                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2007                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2008                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2009                 }
2010
2011                 AddWinners(team, t);
2012                 return WINNING_YES;
2013         }
2014         else
2015                 return WINNING_NO;
2016 }
2017
2018 /*
2019 ============
2020 CheckRules_World
2021
2022 Exit deathmatch games upon conditions
2023 ============
2024 */
2025 void ReadyRestart();
2026 void CheckRules_World()
2027 {
2028         float timelimit;
2029         float fraglimit;
2030         float leadlimit;
2031
2032         VoteThink();
2033         MapVote_Think();
2034
2035         SetDefaultAlpha();
2036
2037         /*
2038         MapVote_Think should now do that part
2039         if (intermission_running)
2040                 if (time >= intermission_exittime + 60)
2041                 {
2042                         if(!DoNextMapOverride())
2043                                 GotoNextMap();
2044                         return;
2045                 }
2046         */
2047
2048         if (gameover)   // someone else quit the game already
2049         {
2050                 if(player_count == 0) // Nobody there? Then let's go to the next map
2051                         MapVote_Start();
2052                         // this will actually check the player count in the next frame
2053                         // again, but this shouldn't hurt
2054                 return;
2055         }
2056
2057         timelimit = autocvar_timelimit * 60;
2058         fraglimit = autocvar_fraglimit;
2059         leadlimit = autocvar_leadlimit;
2060
2061         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2062         {
2063                 if(timelimit > 0)
2064                         timelimit = 0; // timelimit is not made for warmup
2065                 if(fraglimit > 0)
2066                         fraglimit = 0; // no fraglimit for now
2067                 leadlimit = 0; // no leadlimit for now
2068         }
2069
2070         if(timelimit > 0)
2071         {
2072                 timelimit += game_starttime;
2073         }
2074         else if (timelimit < 0)
2075         {
2076                 // endmatch
2077                 NextLevel();
2078                 return;
2079         }
2080
2081         if(g_onslaught)
2082                 timelimit = 0; // ONS has its own overtime rule
2083
2084         float wantovertime;
2085         wantovertime = 0;
2086
2087         if(timelimit > game_starttime)
2088                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2089         else
2090                 game_completion_ratio = 0;
2091
2092         if(checkrules_suddendeathend)
2093         {
2094                 if(!checkrules_suddendeathwarning)
2095                 {
2096                         checkrules_suddendeathwarning = TRUE;
2097                         if(g_race && !g_race_qualifying)
2098                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2099                         else
2100                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2101                 }
2102         }
2103         else
2104         {
2105                 if (timelimit && time >= timelimit)
2106                 {
2107                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2108                         {
2109                                 float totalplayers;
2110                                 float playerswithlaps;
2111                                 float readyplayers;
2112                                 entity head;
2113                                 totalplayers = playerswithlaps = readyplayers = 0;
2114                                 FOR_EACH_PLAYER(head)
2115                                 {
2116                                         ++totalplayers;
2117                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2118                                                 ++playerswithlaps;
2119                                         if(head.ready)
2120                                                 ++readyplayers;
2121                                 }
2122
2123                                 // at least 2 of the players have completed a lap: start the RACE
2124                                 // otherwise, the players should end the qualifying on their own
2125                                 if(readyplayers || playerswithlaps >= 2)
2126                                 {
2127                                         checkrules_suddendeathend = 0;
2128                                         ReadyRestart(); // go to race
2129                                         return;
2130                                 }
2131                                 else
2132                                         wantovertime |= InitiateSuddenDeath();
2133                         }
2134                         else
2135                                 wantovertime |= InitiateSuddenDeath();
2136                 }
2137         }
2138
2139         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2140         {
2141                 NextLevel();
2142                 return;
2143         }
2144
2145         float checkrules_status;
2146         checkrules_status = WinningCondition_RanOutOfSpawns();
2147         if(checkrules_status == WINNING_YES)
2148         {
2149                 bprint("Hey! Someone ran out of spawns!\n");
2150         }
2151         else if(g_race && !g_race_qualifying && timelimit >= 0)
2152         {
2153                 checkrules_status = WinningCondition_Race(fraglimit);
2154                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2155         }
2156         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2157         {
2158                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2159                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2160         }
2161         else if(g_assault)
2162         {
2163                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2164         }
2165         else if(g_lms)
2166         {
2167                 checkrules_status = WinningCondition_LMS();
2168         }
2169         else if (g_onslaught)
2170         {
2171                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2172         }
2173         else
2174         {
2175                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2176                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2177         }
2178
2179         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2180         {
2181                 checkrules_status = WINNING_NEVER;
2182                 checkrules_overtimesadded = -1;
2183                 wantovertime |= InitiateSuddenDeath();
2184         }
2185
2186         if(checkrules_status == WINNING_NEVER)
2187                 // equality cases! Nobody wins if the overtime ends in a draw.
2188                 ClearWinners();
2189
2190         if(wantovertime)
2191         {
2192                 if(checkrules_status == WINNING_NEVER)
2193                         InitiateOvertime();
2194                 else
2195                         checkrules_status = WINNING_YES;
2196         }
2197
2198         if(checkrules_suddendeathend)
2199                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2200                         checkrules_status = WINNING_YES;
2201
2202         if(checkrules_status == WINNING_YES)
2203         {
2204                 //print("WINNING\n");
2205                 NextLevel();
2206         }
2207 }
2208
2209 float mapvote_nextthink;
2210 float mapvote_initialized;
2211 float mapvote_keeptwotime;
2212 float mapvote_timeout;
2213 string mapvote_message;
2214 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2215 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2216 float mapvote_screenshot_dirs_count;
2217
2218 float mapvote_count;
2219 float mapvote_count_real;
2220 string mapvote_maps[MAPVOTE_COUNT];
2221 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2222 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2223 float mapvote_maps_suggested[MAPVOTE_COUNT];
2224 string mapvote_suggestions[MAPVOTE_COUNT];
2225 float mapvote_suggestion_ptr;
2226 float mapvote_voters;
2227 float mapvote_selections[MAPVOTE_COUNT];
2228 float mapvote_run;
2229 float mapvote_detail;
2230 float mapvote_abstain;
2231 .float mapvote;
2232
2233 void MapVote_ClearAllVotes()
2234 {
2235         FOR_EACH_CLIENT(other)
2236                 other.mapvote = 0;
2237 }
2238
2239 string MapVote_Suggest(string m)
2240 {
2241         float i;
2242         if(m == "")
2243                 return "That's not how to use this command.";
2244         if(!autocvar_g_maplist_votable_suggestions)
2245                 return "Suggestions are not accepted on this server.";
2246         if(mapvote_initialized)
2247                 return "Can't suggest - voting is already in progress!";
2248         m = MapInfo_FixName(m);
2249         if not(m)
2250                 return "The map you suggested is not available on this server.";
2251         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2252                 if(Map_IsRecent(m))
2253                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2254
2255         if(!MapInfo_CheckMap(m))
2256                 return "The map you suggested does not support the current game mode.";
2257         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2258                 if(mapvote_suggestions[i] == m)
2259                         return "This map was already suggested.";
2260         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2261         {
2262                 i = floor(random() * mapvote_suggestion_ptr);
2263         }
2264         else
2265         {
2266                 i = mapvote_suggestion_ptr;
2267                 mapvote_suggestion_ptr += 1;
2268         }
2269         if(mapvote_suggestions[i] != "")
2270                 strunzone(mapvote_suggestions[i]);
2271         mapvote_suggestions[i] = strzone(m);
2272         if(autocvar_sv_eventlog)
2273                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2274         return strcat("Suggestion of ", m, " accepted.");
2275 }
2276
2277 void MapVote_AddVotable(string nextMap, float isSuggestion)
2278 {
2279         float j, i, o;
2280         string pakfile, mapfile;
2281
2282         if(nextMap == "")
2283                 return;
2284         for(j = 0; j < mapvote_count; ++j)
2285                 if(mapvote_maps[j] == nextMap)
2286                         return;
2287         // suggestions might be no longer valid/allowed after gametype switch!
2288         if(isSuggestion)
2289                 if(!MapInfo_CheckMap(nextMap))
2290                         return;
2291         mapvote_maps[mapvote_count] = strzone(nextMap);
2292         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2293
2294         pakfile = string_null;
2295         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2296         {
2297                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2298                 pakfile = whichpack(strcat(mapfile, ".tga"));
2299                 if(pakfile == "")
2300                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2301                 if(pakfile == "")
2302                         pakfile = whichpack(strcat(mapfile, ".png"));
2303                 if(pakfile != "")
2304                         break;
2305         }
2306         if(i >= mapvote_screenshot_dirs_count)
2307                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2308         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2309                 pakfile = substring(pakfile, o, -1);
2310
2311         mapvote_maps_screenshot_dir[mapvote_count] = i;
2312         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2313
2314         mapvote_count += 1;
2315 }
2316
2317 void MapVote_Spawn();
2318 void MapVote_Init()
2319 {
2320         float i;
2321         float nmax, smax;
2322
2323         MapVote_ClearAllVotes();
2324
2325         mapvote_count = 0;
2326         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2327         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2328
2329         if(mapvote_abstain)
2330                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2331         else
2332                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2333         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2334
2335         // we need this for AddVotable, as that cycles through the screenshot dirs
2336         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2337         if(mapvote_screenshot_dirs_count == 0)
2338                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2339         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2340         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2341                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2342
2343         if(mapvote_suggestion_ptr)
2344                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2345                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2346
2347         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2348                 MapVote_AddVotable(GetNextMap(), FALSE);
2349
2350         if(mapvote_count == 0)
2351         {
2352                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2353                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2354                 if(autocvar_g_maplist_shuffle)
2355                         ShuffleMaplist();
2356                 localcmd("\nmenu_cmd sync\n");
2357                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2358                         MapVote_AddVotable(GetNextMap(), FALSE);
2359         }
2360
2361         mapvote_count_real = mapvote_count;
2362         if(mapvote_abstain)
2363                 MapVote_AddVotable("don't care", 0);
2364
2365         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2366
2367         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2368         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2369         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2370                 mapvote_keeptwotime = 0;
2371         mapvote_message = "Choose a map and press its key!";
2372
2373         MapVote_Spawn();
2374 }
2375
2376 void MapVote_SendPicture(float id)
2377 {
2378         msg_entity = self;
2379         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2380         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2381         WriteByte(MSG_ONE, id);
2382         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2383 }
2384
2385 float MapVote_GetMapMask()
2386 {
2387         float mask, i, power;
2388         mask = 0;
2389         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2390                 if(mapvote_maps[i] != "")
2391                         mask |= power;
2392         return mask;
2393 }
2394
2395 entity mapvote_ent;
2396 float MapVote_SendEntity(entity to, float sf)
2397 {
2398         float i;
2399
2400         if(sf & 1)
2401                 sf &= ~2; // if we send 1, we don't need to also send 2
2402
2403         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2404         WriteByte(MSG_ENTITY, sf);
2405
2406         if(sf & 1)
2407         {
2408                 // flag 1 == initialization
2409                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2410                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2411                 WriteString(MSG_ENTITY, "");
2412                 WriteByte(MSG_ENTITY, mapvote_count);
2413                 WriteByte(MSG_ENTITY, mapvote_abstain);
2414                 WriteByte(MSG_ENTITY, mapvote_detail);
2415                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2416                 if(mapvote_count <= 8)
2417                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2418                 else
2419                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2420                 for(i = 0; i < mapvote_count; ++i)
2421                         if(mapvote_maps[i] != "")
2422                         {
2423                                 if(mapvote_abstain && i == mapvote_count - 1)
2424                                 {
2425                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2426                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2427                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2428                                 }
2429                                 else
2430                                 {
2431                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2432                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2433                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2434                                 }
2435                         }
2436         }
2437
2438         if(sf & 2)
2439         {
2440                 // flag 2 == update of mask
2441                 if(mapvote_count <= 8)
2442                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2443                 else
2444                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2445         }
2446
2447         if(sf & 4)
2448         {
2449                 if(mapvote_detail)
2450                         for(i = 0; i < mapvote_count; ++i)
2451                                 if(mapvote_maps[i] != "")
2452                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2453
2454                 WriteByte(MSG_ENTITY, to.mapvote);
2455         }
2456
2457         return TRUE;
2458 }
2459
2460 void MapVote_Spawn()
2461 {
2462         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2463 }
2464
2465 void MapVote_TouchMask()
2466 {
2467         mapvote_ent.SendFlags |= 2;
2468 }
2469
2470 void MapVote_TouchVotes(entity voter)
2471 {
2472         mapvote_ent.SendFlags |= 4;
2473 }
2474
2475 float MapVote_Finished(float mappos)
2476 {
2477         string result;
2478         float i;
2479         float didntvote;
2480
2481         if(autocvar_sv_eventlog)
2482         {
2483                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2484                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2485                 didntvote = mapvote_voters;
2486                 for(i = 0; i < mapvote_count; ++i)
2487                         if(mapvote_maps[i] != "")
2488                         {
2489                                 didntvote -= mapvote_selections[i];
2490                                 if(i != mappos)
2491                                 {
2492                                         result = strcat(result, ":", mapvote_maps[i]);
2493                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2494                                 }
2495                         }
2496                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2497
2498                 GameLogEcho(result);
2499                 if(mapvote_maps_suggested[mappos])
2500                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2501         }
2502
2503         FOR_EACH_REALCLIENT(other)
2504                 FixClientCvars(other);
2505
2506         Map_Goto_SetStr(mapvote_maps[mappos]);
2507         Map_Goto(0);
2508         alreadychangedlevel = TRUE;
2509         return TRUE;
2510 }
2511 void MapVote_CheckRules_1()
2512 {
2513         float i;
2514
2515         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2516         {
2517                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2518                 mapvote_selections[i] = 0;
2519         }
2520
2521         mapvote_voters = 0;
2522         FOR_EACH_REALCLIENT(other)
2523         {
2524                 ++mapvote_voters;
2525                 if(other.mapvote)
2526                 {
2527                         i = other.mapvote - 1;
2528                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2529                         mapvote_selections[i] = mapvote_selections[i] + 1;
2530                 }
2531         }
2532 }
2533
2534 float MapVote_CheckRules_2()
2535 {
2536         float i;
2537         float firstPlace, secondPlace;
2538         float firstPlaceVotes, secondPlaceVotes;
2539         float mapvote_voters_real;
2540         string result;
2541
2542         if(mapvote_count_real == 1)
2543                 return MapVote_Finished(0);
2544
2545         mapvote_voters_real = mapvote_voters;
2546         if(mapvote_abstain)
2547                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2548
2549         RandomSelection_Init();
2550         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2551                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2552         firstPlace = RandomSelection_chosen_float;
2553         firstPlaceVotes = RandomSelection_best_priority;
2554         //dprint("First place: ", ftos(firstPlace), "\n");
2555         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2556
2557         RandomSelection_Init();
2558         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2559                 if(i != firstPlace)
2560                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2561         secondPlace = RandomSelection_chosen_float;
2562         secondPlaceVotes = RandomSelection_best_priority;
2563         //dprint("Second place: ", ftos(secondPlace), "\n");
2564         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2565
2566         if(firstPlace == -1)
2567                 error("No first place in map vote... WTF?");
2568
2569         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2570                 return MapVote_Finished(firstPlace);
2571
2572         if(mapvote_keeptwotime)
2573                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2574                 {
2575                         float didntvote;
2576                         MapVote_TouchMask();
2577                         mapvote_message = "Now decide between the TOP TWO!";
2578                         mapvote_keeptwotime = 0;
2579                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2580                         result = strcat(result, ":", ftos(firstPlaceVotes));
2581                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2582                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2583                         didntvote = mapvote_voters;
2584                         for(i = 0; i < mapvote_count; ++i)
2585                                 if(mapvote_maps[i] != "")
2586                                 {
2587                                         didntvote -= mapvote_selections[i];
2588                                         if(i != firstPlace)
2589                                                 if(i != secondPlace)
2590                                                 {
2591                                                         result = strcat(result, ":", mapvote_maps[i]);
2592                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2593                                                         if(i < mapvote_count_real)
2594                                                         {
2595                                                                 strunzone(mapvote_maps[i]);
2596                                                                 mapvote_maps[i] = "";
2597                                                                 strunzone(mapvote_maps_pakfile[i]);
2598                                                                 mapvote_maps_pakfile[i] = "";
2599                                                         }
2600                                                 }
2601                                 }
2602                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2603                         if(autocvar_sv_eventlog)
2604                                 GameLogEcho(result);
2605                 }
2606
2607         return FALSE;
2608 }
2609 void MapVote_Tick()
2610 {
2611         float keeptwo;
2612         float totalvotes;
2613
2614         keeptwo = mapvote_keeptwotime;
2615         MapVote_CheckRules_1(); // count
2616         if(MapVote_CheckRules_2()) // decide
2617                 return;
2618
2619         totalvotes = 0;
2620         FOR_EACH_REALCLIENT(other)
2621         {
2622                 // hide scoreboard again
2623                 if(other.health != 2342)
2624                 {
2625                         other.health = 2342;
2626                         other.impulse = 0;
2627                         if(IS_REAL_CLIENT(other))
2628                         {
2629                                 msg_entity = other;
2630                                 WriteByte(MSG_ONE, SVC_FINALE);
2631                                 WriteString(MSG_ONE, "");
2632                         }
2633                 }
2634
2635                 // clear possibly invalid votes
2636                 if(mapvote_maps[other.mapvote - 1] == "")
2637                         other.mapvote = 0;
2638                 // use impulses as new vote
2639                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2640                         if(mapvote_maps[other.impulse - 1] != "")
2641                         {
2642                                 other.mapvote = other.impulse;
2643                                 MapVote_TouchVotes(other);
2644                         }
2645                 other.impulse = 0;
2646
2647                 if(other.mapvote)
2648                         ++totalvotes;
2649         }
2650
2651         MapVote_CheckRules_1(); // just count
2652 }
2653 void MapVote_Start()
2654 {
2655         if(mapvote_run)
2656                 return;
2657
2658         // wait for stats to be sent first
2659         if(!playerstats_waitforme)
2660                 return;
2661
2662         MapInfo_Enumerate();
2663         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2664                 mapvote_run = TRUE;
2665 }
2666 void MapVote_Think()
2667 {
2668         if(!mapvote_run)
2669                 return;
2670
2671         if(alreadychangedlevel)
2672                 return;
2673
2674         if(time < mapvote_nextthink)
2675                 return;
2676         //dprint("tick\n");
2677
2678         mapvote_nextthink = time + 0.5;
2679
2680         if(!mapvote_initialized)
2681         {
2682                 if(autocvar_rescan_pending == 1)
2683                 {
2684                         cvar_set("rescan_pending", "2");
2685                         localcmd("fs_rescan\nrescan_pending 3\n");
2686                         return;
2687                 }
2688                 else if(autocvar_rescan_pending == 2)
2689                 {
2690                         return;
2691                 }
2692                 else if(autocvar_rescan_pending == 3)
2693                 {
2694                         // now build missing mapinfo files
2695                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2696                                 return;
2697
2698                         // we're done, start the timer
2699                         cvar_set("rescan_pending", "0");
2700                 }
2701
2702                 mapvote_initialized = TRUE;
2703                 if(DoNextMapOverride(0))
2704                         return;
2705                 if(!autocvar_g_maplist_votable || player_count <= 0)
2706                 {
2707                         GotoNextMap(0);
2708                         return;
2709                 }
2710                 MapVote_Init();
2711         }
2712
2713         MapVote_Tick();
2714 }
2715
2716 string GotoMap(string m)
2717 {
2718         if(!MapInfo_CheckMap(m))
2719                 return "The map you chose is not available on this server.";
2720         cvar_set("nextmap", m);
2721         cvar_set("timelimit", "-1");
2722         if(mapvote_initialized || alreadychangedlevel)
2723         {
2724                 if(DoNextMapOverride(0))
2725                         return "Map switch initiated.";
2726                 else
2727                         return "Hm... no. For some reason I like THIS map more.";
2728         }
2729         else
2730                 return "Map switch will happen after scoreboard.";
2731 }
2732
2733
2734 void EndFrame()
2735 {
2736         float altime;
2737         FOR_EACH_REALCLIENT(self)
2738         {
2739                 if(IS_SPEC(self))
2740                 {
2741                         if(self.enemy.typehitsound)
2742                                 self.typehit_time = time;
2743                         else if(self.enemy.hitsound)
2744                                 self.hit_time = time;
2745                 }
2746                 else
2747                 {
2748                         if(self.typehitsound)
2749                                 self.typehit_time = time;
2750                         else if(self.hitsound)
2751                                 self.hit_time = time;
2752                 }
2753         }
2754         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2755         // add 1 frametime because after this, engine SV_Physics
2756         // increases time by a frametime and then networks the frame
2757         // add another frametime because client shows everything with
2758         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2759         // needed!
2760         FOR_EACH_CLIENT(self)
2761         {
2762                 self.hitsound = FALSE;
2763                 self.typehitsound = FALSE;
2764                 antilag_record(self, altime);
2765         }
2766 }
2767
2768
2769 /*
2770  * RedirectionThink:
2771  * returns TRUE if redirecting
2772  */
2773 float redirection_timeout;
2774 float redirection_nextthink;
2775 float RedirectionThink()
2776 {
2777         float clients_found;
2778
2779         if(redirection_target == "")
2780                 return FALSE;
2781
2782         if(!redirection_timeout)
2783         {
2784                 cvar_set("sv_public", "-2");
2785                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2786                 if(redirection_target == "self")
2787                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2788                 else
2789                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2790         }
2791
2792         if(time < redirection_nextthink)
2793                 return TRUE;
2794
2795         redirection_nextthink = time + 1;
2796
2797         clients_found = 0;
2798         FOR_EACH_REALCLIENT(self)
2799         {
2800                 // TODO add timer
2801                 print("Redirecting: sending connect command to ", self.netname, "\n");
2802                 if(redirection_target == "self")
2803                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2804                 else
2805                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2806                 ++clients_found;
2807         }
2808
2809         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2810
2811         if(time > redirection_timeout || clients_found == 0)
2812                 localcmd("\nwait; wait; wait; quit\n");
2813
2814         return TRUE;
2815 }
2816
2817 void TargetMusic_RestoreGame();
2818 void RestoreGame()
2819 {
2820         // Loaded from a save game
2821         // some things then break, so let's work around them...
2822
2823         // Progs DB (capture records)
2824         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2825
2826         // Mapinfo
2827         MapInfo_Shutdown();
2828         MapInfo_Enumerate();
2829         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2830         WeaponStats_Init();
2831
2832         TargetMusic_RestoreGame();
2833 }
2834
2835 void Shutdown()
2836 {
2837         entity e;
2838
2839         gameover = 2;
2840
2841         if(world_initialized > 0)
2842         {
2843                 world_initialized = 0;
2844                 print("Saving persistent data...\n");
2845                 Ban_SaveBans();
2846
2847                 PlayerStats_EndMatch(0);
2848                 FOR_EACH_CLIENT(e)
2849                         PlayerStats_AddGlobalInfo(e);
2850                 PlayerStats_Shutdown();
2851
2852                 if(!cheatcount_total)
2853                 {
2854                         if(autocvar_sv_db_saveasdump)
2855                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2856                         else
2857                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2858                 }
2859                 if(autocvar_developer)
2860                 {
2861                         if(autocvar_sv_db_saveasdump)
2862                                 db_dump(TemporaryDB, "server-temp.db");
2863                         else
2864                                 db_save(TemporaryDB, "server-temp.db");
2865                 }
2866                 CheatShutdown(); // must be after cheatcount check
2867                 db_close(ServerProgsDB);
2868                 db_close(TemporaryDB);
2869                 print("done!\n");
2870                 // tell the bot system the game is ending now
2871                 bot_endgame();
2872
2873                 WeaponStats_Shutdown();
2874                 MapInfo_Shutdown();
2875         }
2876         else if(world_initialized == 0)
2877         {
2878                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2879         }
2880 }