qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ca_teams_override");
 363                 BADCVAR("g_ctf_ignore_frags");
 364                 BADCVAR("g_domination_point_limit");
 365                 BADCVAR("g_freezetag_teams_override");
 366                 BADCVAR("g_friendlyfire");
 367                 BADCVAR("g_fullbrightitems");
 368                 BADCVAR("g_fullbrightplayers");
 369                 BADCVAR("g_keyhunt_point_limit");
 370                 BADCVAR("g_keyhunt_teams_override");
 371                 BADCVAR("g_lms_lives_override");
 372                 BADCVAR("g_maplist");
 373                 BADCVAR("g_maplist_check_waypoints");
 374                 BADCVAR("g_maplist_mostrecent_count");
 375                 BADCVAR("g_maplist_shuffle");
 376                 BADCVAR("g_maplist_votable");
 377                 BADCVAR("g_maplist_votable_abstain");
 378                 BADCVAR("g_maplist_votable_nodetail");
 379                 BADCVAR("g_maplist_votable_suggestions");
 380                 BADCVAR("g_maxplayers");
 381                 BADCVAR("g_mirrordamage");
 382                 BADCVAR("g_nexball_goallimit");
 383                 BADCVAR("g_powerups");
 384                 BADCVAR("g_start_delay");
 385                 BADCVAR("g_warmup");
 386                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 387                 BADCVAR("hostname");
 388                 BADCVAR("log_file");
 389                 BADCVAR("maxplayers");
 390                 BADCVAR("minplayers");
 391                 BADCVAR("net_address");
 392                 BADCVAR("port");
 393                 BADCVAR("rcon_password");
 394                 BADCVAR("rcon_restricted_commands");
 395                 BADCVAR("rcon_restricted_password");
 396                 BADCVAR("skill");
 397                 BADCVAR("sv_adminnick");
 398                 BADCVAR("sv_autoscreenshot");
 399                 BADCVAR("sv_autotaunt");
 400                 BADCVAR("sv_curl_defaulturl");
 401                 BADCVAR("sv_defaultcharacter");
 402                 BADCVAR("sv_defaultplayercolors");
 403                 BADCVAR("sv_defaultplayermodel");
 404                 BADCVAR("sv_defaultplayerskin");
 405                 BADCVAR("sv_maxidle");
 406                 BADCVAR("sv_maxrate");
 407                 BADCVAR("sv_motd");
 408                 BADCVAR("sv_public");
 409                 BADCVAR("sv_ready_restart");
 410                 BADCVAR("sv_status_privacy");
 411                 BADCVAR("sv_taunt");
 412                 BADCVAR("sv_vote_call");
 413                 BADCVAR("sv_vote_commands");
 414                 BADCVAR("sv_vote_majority_factor");
 415                 BADCVAR("sv_vote_master");
 416                 BADCVAR("sv_vote_master_commands");
 417                 BADCVAR("sv_vote_master_password");
 418                 BADCVAR("sv_vote_simple_majority_factor");
 419                 BADCVAR("teamplay_mode");
 420                 BADCVAR("timelimit_override");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADPREFIX("g_warmup_");
 423                 BADPREFIX("sv_ready_restart_");
 424
 425                 // mutators that announce themselves properly to the server browser
 426                 BADCVAR("g_minstagib");
 427                 BADCVAR("g_new_toys");
 428                 BADCVAR("g_nix");
 429                 BADCVAR("g_grappling_hook");
 430                 BADCVAR("g_jetpack");
 431
 432 #undef BADPREFIX
 433 #undef BADCVAR
 434
 435                 if(pureadding)
 436                 {
 437                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 438                         if(strlen(cvar_purechanges) > 16384)
 439                         {
 440                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 441                                 pureadding = 0;
 442                         }
 443                 }
 444                 ++cvar_purechanges_count;
 445                 // WARNING: this variable is used for the server list
 446                 // NEVER dare to skip this code!
 447                 // Hacks to intentionally appearing as "pure server" even though you DO have
 448                 // modified settings may be punished by removal from the server list.
 449                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 450                 // though.
 451         }
 452         buf_del(h);
 453         if(cvar_changes == "")
 454                 cvar_changes = "// this server runs at default server settings\n";
 455         else
 456                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 457         cvar_changes = strzone(cvar_changes);
 458         if(cvar_purechanges == "")
 459                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 460         else
 461                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 462         cvar_purechanges = strzone(cvar_purechanges);
 463 }
 464
 465 void detect_maptype()
 466 {
 467 #if 0
 468         vector o, v;
 469         float i;
 470
 471         for(;;)
 472         {
 473                 o = world.mins;
 474                 o_x += random() * (world.maxs_x - world.mins_x);
 475                 o_y += random() * (world.maxs_y - world.mins_y);
 476                 o_z += random() * (world.maxs_z - world.mins_z);
 477
 478                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 479                 if(trace_fraction == 1)
 480                         continue;
 481
 482                 v = trace_endpos;
 483
 484                 for(i = 0; i < 64; i += 4)
 485                 {
 486                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 487         if(trace_fraction == 1)
 488                 continue;
 489                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 490                 }
 491
 492                 break;
 493         }
 494 #endif
 495 }
 496
 497 entity randomseed;
 498 float RandomSeed_Send(entity to, float sf)
 499 {
 500         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 501         WriteShort(MSG_ENTITY, self.cnt);
 502         return TRUE;
 503 }
 504 void RandomSeed_Think()
 505 {
 506         self.cnt = bound(0, floor(random() * 65536), 65535);
 507         self.nextthink = time + 5;
 508
 509         self.SendFlags |= 1;
 510 }
 511 void RandomSeed_Spawn()
 512 {
 513         randomseed = spawn();
 514         randomseed.think = RandomSeed_Think;
 515         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 516
 517         entity oldself;
 518         oldself = self;
 519         self = randomseed;
 520         self.think(); // sets random seed and nextthink
 521         self = oldself;
 522 }
 523
 524 void spawnfunc___init_dedicated_server(void)
 525 {
 526         // handler for _init/_init map (only for dedicated server initialization)
 527
 528         world_initialized = -1; // don't complain
 529         cvar = cvar_normal;
 530         cvar_string = cvar_string_normal;
 531         cvar_set = cvar_set_normal;
 532
 533         remove = remove_unsafely;
 534
 535         entity e;
 536         e = spawn();
 537         e.think = GotoFirstMap;
 538         e.nextthink = time; // this is usually 1 at this point
 539
 540         e = spawn();
 541         e.classname = "info_player_deathmatch"; // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 547         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 548         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 549         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 550         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 551
 552         MapInfo_Enumerate();
 553         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 554 }
 555
 556 void Map_MarkAsRecent(string m);
 557 float world_already_spawned;
 558 void Nagger_Init();
 559 void ClientInit_Spawn();
 560 void WeaponStats_Init();
 561 void WeaponStats_Shutdown();
 562 void spawnfunc_worldspawn (void)
 563 {
 564         float fd, l, i, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = TRUE;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         check_unacceptable_compiler_bugs();
 578
 579         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 580
 581         compressShortVector_init();
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WepSet_AddStat();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // freeze attacks
 800         addstat(STAT_FROZEN, AS_INT, frozen);
 801         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 802
 803         // g_movementspeed hack
 804         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 805         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 806         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 807         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 808
 809         // secrets
 810         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 811         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 812
 813         // monsters
 814         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 815         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 816
 817         // misc
 818         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         maplist_reply = strzone(getmaplist());
 826         lsmaps_reply = strzone(getlsmaps());
 827         for(i = 0; i < 10; ++i)
 828         {
 829                 s = getrecords(i);
 830                 if (s)
 831                         records_reply[i] = strzone(s);
 832         }
 833         ladder_reply = strzone(getladder());
 834         rankings_reply = strzone(getrankings());
 835
 836         // begin other init
 837         ClientInit_Spawn();
 838         RandomSeed_Spawn();
 839         PingPLReport_Spawn();
 840
 841         CheatInit();
 842
 843         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 844
 845         // fill sv_curl_serverpackages from .serverpackage files
 846         if(autocvar_sv_curl_serverpackages_auto)
 847         {
 848                 s = "";
 849                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 850                 for(i = 0; i < n; ++i)
 851                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 852                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 853                                 s = strcat(s, " ", argv(i));
 854                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 855                 if(fd >= 0)
 856                 {
 857                         j = search_getsize(fd);
 858                         for(i = 0; i < j; ++i)
 859                                 s = strcat(s, " ", search_getfilename(fd, i));
 860                         search_end(fd);
 861                 }
 862                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 863                 if(fd >= 0)
 864                 {
 865                         j = search_getsize(fd);
 866                         for(i = 0; i < j; ++i)
 867                                 s = strcat(s, " ", search_getfilename(fd, i));
 868                         search_end(fd);
 869                 }
 870                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 871         }
 872
 873         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 874         modname = "Xonotic";
 875         // physics/balance/config changes that count as mod
 876         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 877                 modname = cvar_string("g_mod_physics");
 878         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 879                 modname = cvar_string("g_mod_balance");
 880         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 881                 modname = cvar_string("g_mod_config");
 882         // extra mutators that deserve to count as mod
 883         MUTATOR_CALLHOOK(SetModname);
 884
 885         // save it for later
 886         modname = strzone(modname);
 887
 888         WinningConditionHelper(); // set worldstatus
 889
 890         world_initialized = 1;
 891 }
 892
 893 void spawnfunc_light (void)
 894 {
 895         //makestatic (self); // Who the f___ did that?
 896         remove(self);
 897 }
 898
 899 string GetGametype()
 900 {
 901         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 902 }
 903
 904 string getmapname_stored;
 905 string GetMapname()
 906 {
 907         return mapname;
 908 }
 909
 910 float Map_Count, Map_Current;
 911 string Map_Current_Name;
 912
 913 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 914 float GetMaplistPosition()
 915 {
 916         float pos, idx;
 917         string map;
 918
 919         map = GetMapname();
 920         idx = autocvar_g_maplist_index;
 921
 922         if(idx >= 0)
 923                 if(idx < Map_Count)
 924                         if(map == argv(idx))
 925                                 return idx;
 926
 927         for(pos = 0; pos < Map_Count; ++pos)
 928                 if(map == argv(pos))
 929                         return pos;
 930
 931         // resume normal maplist rotation if current map is not in g_maplist
 932         return idx;
 933 }
 934
 935 float MapHasRightSize(string map)
 936 {
 937         float fh;
 938         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 939         if(autocvar_g_maplist_check_waypoints)
 940         {
 941                 dprint("checkwp "); dprint(map);
 942                 if(!fexists(strcat("maps/", map, ".waypoints")))
 943                 {
 944                         dprint(": no waypoints\n");
 945                         return FALSE;
 946                 }
 947                 dprint(": has waypoints\n");
 948         }
 949
 950         // open map size restriction file
 951         dprint("opensize "); dprint(map);
 952         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 953         if(fh >= 0)
 954         {
 955                 float mapmin, mapmax;
 956                 dprint(": ok, ");
 957                 mapmin = stof(fgets(fh));
 958                 mapmax = stof(fgets(fh));
 959                 fclose(fh);
 960                 if(player_count < mapmin)
 961                 {
 962                         dprint("not enough\n");
 963                         return FALSE;
 964                 }
 965                 if(player_count > mapmax)
 966                 {
 967                         dprint("too many\n");
 968                         return FALSE;
 969                 }
 970                 dprint("right size\n");
 971                 return TRUE;
 972         }
 973         dprint(": not found\n");
 974         return TRUE;
 975 }
 976
 977 string Map_Filename(float position)
 978 {
 979         return strcat("maps/", argv(position), ".bsp");
 980 }
 981
 982 string strwords(string s, float w)
 983 {
 984         float endpos;
 985         for(endpos = 0; w && endpos >= 0; --w)
 986                 endpos = strstrofs(s, " ", endpos + 1);
 987         if(endpos < 0)
 988                 return s;
 989         else
 990                 return substring(s, 0, endpos);
 991 }
 992
 993 float strhasword(string s, string w)
 994 {
 995         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 996 }
 997
 998 void Map_MarkAsRecent(string m)
 999 {
1000         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1001 }
1002
1003 float Map_IsRecent(string m)
1004 {
1005         return strhasword(autocvar_g_maplist_mostrecent, m);
1006 }
1007
1008 float Map_Check(float position, float pass)
1009 {
1010         string filename;
1011         string map_next;
1012         map_next = argv(position);
1013         if(pass <= 1)
1014         {
1015                 if(Map_IsRecent(map_next))
1016                         return 0;
1017         }
1018         filename = Map_Filename(position);
1019         if(MapInfo_CheckMap(map_next))
1020         {
1021                 if(pass == 2)
1022                         return 1;
1023                 if(MapHasRightSize(map_next))
1024                         return 1;
1025                 return 0;
1026         }
1027         else
1028                 dprint( "Couldn't select '", filename, "'..\n" );
1029
1030         return 0;
1031 }
1032
1033 void Map_Goto_SetStr(string nextmapname)
1034 {
1035         if(getmapname_stored != "")
1036                 strunzone(getmapname_stored);
1037         if(nextmapname == "")
1038                 getmapname_stored = "";
1039         else
1040                 getmapname_stored = strzone(nextmapname);
1041 }
1042
1043 void Map_Goto_SetFloat(float position)
1044 {
1045         cvar_set("g_maplist_index", ftos(position));
1046         Map_Goto_SetStr(argv(position));
1047 }
1048
1049 void Map_Goto(float reinit)
1050 {
1051         MapInfo_LoadMap(getmapname_stored, reinit);
1052 }
1053
1054 // return codes of map selectors:
1055 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1056 //   -2 = permanent failure
1057 float() MaplistMethod_Iterate = // usual method
1058 {
1059         float pass, i;
1060
1061         dprint("Trying MaplistMethod_Iterate\n");
1062
1063         for(pass = 1; pass <= 2; ++pass)
1064         {
1065                 for(i = 1; i < Map_Count; ++i)
1066                 {
1067                         float mapindex;
1068                         mapindex = mod(i + Map_Current, Map_Count);
1069                         if(Map_Check(mapindex, pass))
1070                                 return mapindex;
1071                 }
1072         }
1073         return -1;
1074 }
1075
1076 float() MaplistMethod_Repeat = // fallback method
1077 {
1078         dprint("Trying MaplistMethod_Repeat\n");
1079
1080         if(Map_Check(Map_Current, 2))
1081                 return Map_Current;
1082         return -2;
1083 }
1084
1085 float() MaplistMethod_Random = // random map selection
1086 {
1087         float i, imax;
1088
1089         dprint("Trying MaplistMethod_Random\n");
1090
1091         imax = 42;
1092
1093         for(i = 0; i <= imax; ++i)
1094         {
1095                 float mapindex;
1096                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1097                 if(Map_Check(mapindex, 1))
1098                         return mapindex;
1099         }
1100         return -1;
1101 }
1102
1103 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1104 // the exponent sets a bias on the map selection:
1105 // the higher the exponent, the less likely "shortly repeated" same maps are
1106 {
1107         float i, j, imax, insertpos;
1108
1109         dprint("Trying MaplistMethod_Shuffle\n");
1110
1111         imax = 42;
1112
1113         for(i = 0; i <= imax; ++i)
1114         {
1115                 string newlist;
1116
1117                 // now reinsert this at another position
1118                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1119                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1120                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1121                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1122
1123                 // insert the current map there
1124                 newlist = "";
1125                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1126                         newlist = strcat(newlist, " ", argv(j));
1127                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1128                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1129                         newlist = strcat(newlist, " ", argv(j));
1130                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1131                 cvar_set("g_maplist", newlist);
1132                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1133
1134                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1135                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1136                 if(Map_Check(Map_Current, 1))
1137                         return Map_Current;
1138         }
1139         return -1;
1140 }
1141
1142 void Maplist_Init()
1143 {
1144         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1145         float i;
1146         for (i = 0; i < Map_Count; ++i)
1147                 if (Map_Check(i, 2))
1148                         break;
1149         if (i == Map_Count)
1150         {
1151                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1152                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1153                 if(autocvar_g_maplist_shuffle)
1154                         ShuffleMaplist();
1155                 localcmd("\nmenu_cmd sync\n");
1156                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1157         }
1158         if(Map_Count == 0)
1159                 error("empty maplist, cannot select a new map");
1160         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1161
1162         if(Map_Current_Name)
1163                 strunzone(Map_Current_Name);
1164         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1165         // this may or may not be correct, but who cares, in the worst case a map
1166         // isn't chosen in the first pass that should have been
1167 }
1168
1169 string GetNextMap()
1170 {
1171         float nextMap;
1172
1173         Maplist_Init();
1174         nextMap = -1;
1175
1176         if(nextMap == -1)
1177                 if(autocvar_g_maplist_shuffle > 0)
1178                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1179
1180         if(nextMap == -1)
1181                 if(autocvar_g_maplist_selectrandom)
1182                         nextMap = MaplistMethod_Random();
1183
1184         if(nextMap == -1)
1185                 nextMap = MaplistMethod_Iterate();
1186
1187         if(nextMap == -1)
1188                 nextMap = MaplistMethod_Repeat();
1189
1190         if(nextMap >= 0)
1191         {
1192                 Map_Goto_SetFloat(nextMap);
1193                 return getmapname_stored;
1194         }
1195
1196         return "";
1197 }
1198
1199 float DoNextMapOverride(float reinit)
1200 {
1201         if(autocvar_g_campaign)
1202         {
1203                 CampaignPostIntermission();
1204                 alreadychangedlevel = TRUE;
1205                 return TRUE;
1206         }
1207         if(autocvar_quit_when_empty)
1208         {
1209                 if(player_count <= currentbots)
1210                 {
1211                         localcmd("quit\n");
1212                         alreadychangedlevel = TRUE;
1213                         return TRUE;
1214                 }
1215         }
1216         if(autocvar_quit_and_redirect != "")
1217         {
1218                 redirection_target = strzone(autocvar_quit_and_redirect);
1219                 alreadychangedlevel = TRUE;
1220                 return TRUE;
1221         }
1222         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1223         {
1224                 localcmd("restart\n");
1225                 alreadychangedlevel = TRUE;
1226                 return TRUE;
1227         }
1228         if(autocvar_nextmap != "")
1229                 if(MapInfo_CheckMap(autocvar_nextmap))
1230                 {
1231                         Map_Goto_SetStr(autocvar_nextmap);
1232                         Map_Goto(reinit);
1233                         alreadychangedlevel = TRUE;
1234                         return TRUE;
1235                 }
1236         if(!reinit && autocvar_lastlevel)
1237         {
1238                 cvar_settemp_restore();
1239                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1240                 alreadychangedlevel = TRUE;
1241                 return TRUE;
1242         }
1243         return FALSE;
1244 }
1245
1246 void GotoNextMap(float reinit)
1247 {
1248         //string nextmap;
1249         //float n, nummaps;
1250         //string s;
1251         if (alreadychangedlevel)
1252                 return;
1253         alreadychangedlevel = TRUE;
1254
1255         string nextMap;
1256
1257         nextMap = GetNextMap();
1258         if(nextMap == "")
1259                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1260         Map_Goto(reinit);
1261 }
1262
1263
1264 /*
1265 ============
1266 IntermissionThink
1267
1268 When the player presses attack or jump, change to the next level
1269 ============
1270 */
1271 .float autoscreenshot;
1272 void() MapVote_Start;
1273 void() MapVote_Think;
1274 float mapvote_initialized;
1275 void IntermissionThink()
1276 {
1277         FixIntermissionClient(self);
1278
1279         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1280         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1281
1282         if( (server_screenshot || client_screenshot)
1283                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1284         {
1285                 self.autoscreenshot = -1;
1286                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1287                 return;
1288         }
1289
1290         if (time < intermission_exittime)
1291                 return;
1292
1293         if(!mapvote_initialized)
1294                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1295                         return;
1296
1297         MapVote_Start();
1298 }
1299
1300 /*
1301 ============
1302 FindIntermission
1303
1304 Returns the entity to view from
1305 ============
1306 */
1307 /*
1308 entity FindIntermission()
1309 {
1310         local   entity spot;
1311         local   float cyc;
1312
1313 // look for info_intermission first
1314         spot = find (world, classname, "info_intermission");
1315         if (spot)
1316         {       // pick a random one
1317                 cyc = random() * 4;
1318                 while (cyc > 1)
1319                 {
1320                         spot = find (spot, classname, "info_intermission");
1321                         if (!spot)
1322                                 spot = find (spot, classname, "info_intermission");
1323                         cyc = cyc - 1;
1324                 }
1325                 return spot;
1326         }
1327
1328 // then look for the start position
1329         spot = find (world, classname, "info_player_start");
1330         if (spot)
1331                 return spot;
1332
1333 // testinfo_player_start is only found in regioned levels
1334         spot = find (world, classname, "testplayerstart");
1335         if (spot)
1336                 return spot;
1337
1338 // then look for the start position
1339         spot = find (world, classname, "info_player_deathmatch");
1340         if (spot)
1341                 return spot;
1342
1343         //objerror ("FindIntermission: no spot");
1344         return world;
1345 }
1346 */
1347
1348 /*
1349 ===============================================================================
1350
1351 RULES
1352
1353 ===============================================================================
1354 */
1355
1356 void DumpStats(float final)
1357 {
1358         float file;
1359         string s;
1360         float to_console;
1361         float to_eventlog;
1362         float to_file;
1363         float i;
1364
1365         to_console = autocvar_sv_logscores_console;
1366         to_eventlog = autocvar_sv_eventlog;
1367         to_file = autocvar_sv_logscores_file;
1368
1369         if(!final)
1370         {
1371                 to_console = TRUE; // always print printstats replies
1372                 to_eventlog = FALSE; // but never print them to the event log
1373         }
1374
1375         if(to_eventlog)
1376                 if(autocvar_sv_eventlog_console)
1377                         to_console = FALSE; // otherwise we get the output twice
1378
1379         if(final)
1380                 s = ":scores:";
1381         else
1382                 s = ":status:";
1383         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1384
1385         if(to_console)
1386                 print(s, "\n");
1387         if(to_eventlog)
1388                 GameLogEcho(s);
1389
1390         file = -1;
1391         if(to_file)
1392         {
1393                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1394                 if(file == -1)
1395                         to_file = FALSE;
1396                 else
1397                         fputs(file, strcat(s, "\n"));
1398         }
1399
1400         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1401         if(to_console)
1402                 print(s, "\n");
1403         if(to_eventlog)
1404                 GameLogEcho(s);
1405         if(to_file)
1406                 fputs(file, strcat(s, "\n"));
1407
1408         FOR_EACH_CLIENT(other)
1409         {
1410                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1411                 {
1412                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1413                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1414                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1415                                 s = strcat(s, ftos(other.team), ":");
1416                         else
1417                                 s = strcat(s, "spectator:");
1418
1419                         if(to_console)
1420                                 print(s, other.netname, "\n");
1421                         if(to_eventlog)
1422                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1423                         if(to_file)
1424                                 fputs(file, strcat(s, other.netname, "\n"));
1425                 }
1426         }
1427
1428         if(teamplay)
1429         {
1430                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1431                 if(to_console)
1432                         print(s, "\n");
1433                 if(to_eventlog)
1434                         GameLogEcho(s);
1435                 if(to_file)
1436                         fputs(file, strcat(s, "\n"));
1437
1438                 for(i = 1; i < 16; ++i)
1439                 {
1440                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1441                         s = strcat(s, ":", ftos(i));
1442                         if(to_console)
1443                                 print(s, "\n");
1444                         if(to_eventlog)
1445                                 GameLogEcho(s);
1446                         if(to_file)
1447                                 fputs(file, strcat(s, "\n"));
1448                 }
1449         }
1450
1451         if(to_console)
1452                 print(":end\n");
1453         if(to_eventlog)
1454                 GameLogEcho(":end");
1455         if(to_file)
1456         {
1457                 fputs(file, ":end\n");
1458                 fclose(file);
1459         }
1460 }
1461
1462 void FixIntermissionClient(entity e)
1463 {
1464         string s;
1465         if(!e.autoscreenshot) // initial call
1466         {
1467                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1468                 e.health = -2342;
1469                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1470                 e.solid = SOLID_NOT;
1471                 e.movetype = MOVETYPE_NONE;
1472                 e.takedamage = DAMAGE_NO;
1473                 if(e.weaponentity)
1474                 {
1475                         e.weaponentity.effects = EF_NODRAW;
1476                         if (e.weaponentity.weaponentity)
1477                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1478                 }
1479                 if(IS_REAL_CLIENT(e))
1480                 {
1481                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1482                         s = autocvar_sv_intermission_cdtrack;
1483                         if(s != "")
1484                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1485                         msg_entity = e;
1486                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1487                 }
1488         }
1489 }
1490
1491 /*
1492 go to the next level for deathmatch
1493 only called if a time or frag limit has expired
1494 */
1495 void NextLevel()
1496 {
1497         gameover = TRUE;
1498
1499         intermission_running = 1;
1500
1501 // enforce a wait time before allowing changelevel
1502         if(player_count > 0)
1503                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1504         else
1505                 intermission_exittime = -1;
1506
1507         /*
1508         WriteByte (MSG_ALL, SVC_CDTRACK);
1509         WriteByte (MSG_ALL, 3);
1510         WriteByte (MSG_ALL, 3);
1511         // done in FixIntermission
1512         */
1513
1514         //pos = FindIntermission ();
1515
1516         VoteReset();
1517
1518         DumpStats(TRUE);
1519
1520         // send statistics
1521         entity e;
1522         PlayerStats_EndMatch(1);
1523         FOR_EACH_CLIENT(e)
1524                 PlayerStats_AddGlobalInfo(e);
1525         PlayerStats_Shutdown();
1526         WeaponStats_Shutdown();
1527
1528         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1529
1530         if(autocvar_sv_eventlog)
1531                 GameLogEcho(":gameover");
1532
1533         GameLogClose();
1534
1535         FOR_EACH_PLAYER(other) {
1536                 FixIntermissionClient(other);
1537                 if(other.winning)
1538                         bprint(other.netname, " ^7wins.\n");
1539         }
1540
1541         if(autocvar_g_campaign)
1542                 CampaignPreIntermission();
1543
1544         MUTATOR_CALLHOOK(MatchEnd);
1545
1546         localcmd("\nsv_hook_gameend\n");
1547 }
1548
1549 /*
1550 ============
1551 CheckRules_Player
1552
1553 Exit deathmatch games upon conditions
1554 ============
1555 */
1556 void CheckRules_Player()
1557 {
1558         if (gameover)   // someone else quit the game already
1559                 return;
1560
1561         if(self.deadflag == DEAD_NO)
1562                 self.play_time += frametime;
1563
1564         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1565         //   (div0: and that in CheckRules_World please)
1566 }
1567
1568 float checkrules_equality;
1569 float checkrules_suddendeathwarning;
1570 float checkrules_suddendeathend;
1571 float checkrules_overtimesadded; //how many overtimes have been already added
1572
1573 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1574 const float WINNING_YES = 1; // winner found
1575 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1576 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1577
1578 float InitiateSuddenDeath()
1579 {
1580         // Check first whether normal overtimes could be added before initiating suddendeath mode
1581         // - for this timelimit_overtime needs to be >0 of course
1582         // - also check the winning condition calculated in the previous frame and only add normal overtime
1583         //   again, if at the point at which timelimit would be extended again, still no winner was found
1584         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1585         {
1586                 return 1; // need to call InitiateOvertime later
1587         }
1588         else
1589         {
1590                 if(!checkrules_suddendeathend)
1591                 {
1592                         if(autocvar_g_campaign)
1593                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1594                         else
1595                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1596                         if(g_race && !g_race_qualifying)
1597                                 race_StartCompleting();
1598                 }
1599                 return 0;
1600         }
1601 }
1602
1603 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1604 {
1605         ++checkrules_overtimesadded;
1606         //add one more overtime by simply extending the timelimit
1607         float tl;
1608         tl = autocvar_timelimit;
1609         tl += autocvar_timelimit_overtime;
1610         cvar_set("timelimit", ftos(tl));
1611
1612         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1613 }
1614
1615 float GetWinningCode(float fraglimitreached, float equality)
1616 {
1617         if(autocvar_g_campaign == 1)
1618                 if(fraglimitreached)
1619                         return WINNING_YES;
1620                 else
1621                         return WINNING_NO;
1622
1623         else
1624                 if(equality)
1625                         if(fraglimitreached)
1626                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1627                         else
1628                                 return WINNING_NEVER;
1629                 else
1630                         if(fraglimitreached)
1631                                 return WINNING_YES;
1632                         else
1633                                 return WINNING_NO;
1634 }
1635
1636 // set the .winning flag for exactly those players with a given field value
1637 void SetWinners(.float field, float value)
1638 {
1639         entity head;
1640         FOR_EACH_PLAYER(head)
1641                 head.winning = (head.field == value);
1642 }
1643
1644 // set the .winning flag for those players with a given field value
1645 void AddWinners(.float field, float value)
1646 {
1647         entity head;
1648         FOR_EACH_PLAYER(head)
1649                 if(head.field == value)
1650                         head.winning = 1;
1651 }
1652
1653 // clear the .winning flags
1654 void ClearWinners(void)
1655 {
1656         entity head;
1657         FOR_EACH_PLAYER(head)
1658                 head.winning = 0;
1659 }
1660
1661 // Onslaught winning condition:
1662 // game terminates if only one team has a working generator (or none)
1663 float WinningCondition_Onslaught()
1664 {
1665         entity head;
1666         float t1, t2, t3, t4;
1667
1668         WinningConditionHelper(); // set worldstatus
1669
1670         if(warmup_stage)
1671                 return WINNING_NO;
1672
1673         // first check if the game has ended
1674         t1 = t2 = t3 = t4 = 0;
1675         head = find(world, classname, "onslaught_generator");
1676         while (head)
1677         {
1678                 if (head.health > 0)
1679                 {
1680                         if (head.team == NUM_TEAM_1) t1 = 1;
1681                         if (head.team == NUM_TEAM_2) t2 = 1;
1682                         if (head.team == NUM_TEAM_3) t3 = 1;
1683                         if (head.team == NUM_TEAM_4) t4 = 1;
1684                 }
1685                 head = find(head, classname, "onslaught_generator");
1686         }
1687         if (t1 + t2 + t3 + t4 < 2)
1688         {
1689                 // game over, only one team remains (or none)
1690                 ClearWinners();
1691                 if (t1) SetWinners(team, NUM_TEAM_1);
1692                 if (t2) SetWinners(team, NUM_TEAM_2);
1693                 if (t3) SetWinners(team, NUM_TEAM_3);
1694                 if (t4) SetWinners(team, NUM_TEAM_4);
1695                 dprint("Have a winner, ending game.\n");
1696                 return WINNING_YES;
1697         }
1698
1699         // Two or more teams remain
1700         return WINNING_NO;
1701 }
1702
1703 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1704 // they win. Otherwise the defending team wins once the timelimit passes.
1705 void assault_new_round();
1706 float WinningCondition_Assault()
1707 {
1708         float status;
1709
1710         WinningConditionHelper(); // set worldstatus
1711
1712         status = WINNING_NO;
1713         // as the timelimit has not yet passed just assume the defending team will win
1714         if(assault_attacker_team == NUM_TEAM_1)
1715         {
1716                 SetWinners(team, NUM_TEAM_2);
1717         }
1718         else
1719         {
1720                 SetWinners(team, NUM_TEAM_1);
1721         }
1722
1723         entity ent;
1724         ent = find(world, classname, "target_assault_roundend");
1725         if(ent)
1726         {
1727                 if(ent.winning) // round end has been triggered by attacking team
1728                 {
1729                         bprint("ASSAULT: round completed...\n");
1730                         SetWinners(team, assault_attacker_team);
1731
1732                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1733
1734                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1735                         {
1736                                 status = WINNING_YES;
1737                         }
1738                         else
1739                         {
1740                                 entity oldself;
1741                                 oldself = self;
1742                                 self = ent;
1743                                 assault_new_round();
1744                                 self = oldself;
1745                         }
1746                 }
1747         }
1748
1749         return status;
1750 }
1751
1752 // LMS winning condition: game terminates if and only if there's at most one
1753 // one player who's living lives. Top two scores being equal cancels the time
1754 // limit.
1755 float WinningCondition_LMS()
1756 {
1757         entity head, head2;
1758         float have_player;
1759         float have_players;
1760         float l;
1761
1762         have_player = FALSE;
1763         have_players = FALSE;
1764         l = LMS_NewPlayerLives();
1765
1766         head = find(world, classname, "player");
1767         if(head)
1768                 have_player = TRUE;
1769         head2 = find(head, classname, "player");
1770         if(head2)
1771                 have_players = TRUE;
1772
1773         if(have_player)
1774         {
1775                 // we have at least one player
1776                 if(have_players)
1777                 {
1778                         // two or more active players - continue with the game
1779                 }
1780                 else
1781                 {
1782                         // exactly one player?
1783
1784                         ClearWinners();
1785                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1786
1787                         if(l)
1788                         {
1789                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1790                                 return WINNING_NO;
1791                         }
1792                         else
1793                         {
1794                                 // a winner!
1795                                 // and assign him his first place
1796                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1797                                 return WINNING_YES;
1798                         }
1799                 }
1800         }
1801         else
1802         {
1803                 // nobody is playing at all...
1804                 if(l)
1805                 {
1806                         // wait for players...
1807                 }
1808                 else
1809                 {
1810                         // SNAFU (maybe a draw game?)
1811                         ClearWinners();
1812                         dprint("No players, ending game.\n");
1813                         return WINNING_YES;
1814                 }
1815         }
1816
1817         // When we get here, we have at least two players who are actually LIVING,
1818         // now check if the top two players have equal score.
1819         WinningConditionHelper();
1820
1821         ClearWinners();
1822         if(WinningConditionHelper_winner)
1823                 WinningConditionHelper_winner.winning = TRUE;
1824         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1825                 return WINNING_NEVER;
1826
1827         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1828         return WINNING_NO;
1829 }
1830
1831 void ShuffleMaplist()
1832 {
1833         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1834 }
1835
1836 float leaderfrags;
1837 float WinningCondition_Scores(float limit, float leadlimit)
1838 {
1839         float limitreached;
1840
1841         // TODO make everything use THIS winning condition (except LMS)
1842         WinningConditionHelper();
1843
1844         if(teamplay)
1845         {
1846                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1847                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1848                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1849                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1850         }
1851
1852         ClearWinners();
1853         if(WinningConditionHelper_winner)
1854                 WinningConditionHelper_winner.winning = 1;
1855         if(WinningConditionHelper_winnerteam >= 0)
1856                 SetWinners(team, WinningConditionHelper_winnerteam);
1857
1858         if(WinningConditionHelper_lowerisbetter)
1859         {
1860                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1861                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1862                 limit = -limit;
1863         }
1864
1865         if(WinningConditionHelper_zeroisworst)
1866                 leadlimit = 0; // not supported in this mode
1867
1868         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1869         // these modes always score in increments of 1, thus this makes sense
1870         {
1871                 if(leaderfrags != WinningConditionHelper_topscore)
1872                 {
1873                         leaderfrags = WinningConditionHelper_topscore;
1874
1875                         if (limit)
1876                         if (leaderfrags == limit - 1)
1877                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1878                         else if (leaderfrags == limit - 2)
1879                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1880                         else if (leaderfrags == limit - 3)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1882                 }
1883         }
1884
1885         limitreached = FALSE;
1886         if(limit)
1887                 if(WinningConditionHelper_topscore >= limit)
1888                         limitreached = TRUE;
1889         if(leadlimit)
1890         {
1891                 float leadlimitreached;
1892                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1893                 if(autocvar_leadlimit_and_fraglimit)
1894                         limitreached = (limitreached && leadlimitreached);
1895                 else
1896                         limitreached = (limitreached || leadlimitreached);
1897         }
1898
1899         if(limit)
1900                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1901
1902         return GetWinningCode(
1903                 WinningConditionHelper_topscore && limitreached,
1904                 WinningConditionHelper_equality
1905         );
1906 }
1907
1908 float WinningCondition_Race(float fraglimit)
1909 {
1910         float wc;
1911         entity p;
1912         float n, c;
1913
1914         n = 0;
1915         c = 0;
1916         FOR_EACH_PLAYER(p)
1917         {
1918                 ++n;
1919                 if(p.race_completed)
1920                         ++c;
1921         }
1922         if(n && (n == c))
1923                 return WINNING_YES;
1924         wc = WinningCondition_Scores(fraglimit, 0);
1925
1926         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1927         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1928         // do NOT support equality when the laps are all raced!
1929                 return WINNING_STARTSUDDENDEATHOVERTIME;
1930         else
1931                 return WINNING_NEVER;
1932 }
1933
1934 float WinningCondition_QualifyingThenRace(float limit)
1935 {
1936         float wc;
1937         wc = WinningCondition_Scores(limit, 0);
1938
1939         // NEVER initiate overtime
1940         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1941         {
1942                 return WINNING_YES;
1943         }
1944
1945         return wc;
1946 }
1947
1948 float WinningCondition_RanOutOfSpawns()
1949 {
1950         entity head;
1951
1952         if(have_team_spawns <= 0)
1953                 return WINNING_NO;
1954
1955         if(autocvar_g_spawn_useallspawns <= 0)
1956                 return WINNING_NO;
1957
1958         if(!some_spawn_has_been_used)
1959                 return WINNING_NO;
1960
1961         team1_score = team2_score = team3_score = team4_score = 0;
1962
1963         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1964         {
1965                 if(head.team == NUM_TEAM_1)
1966                         team1_score = 1;
1967                 else if(head.team == NUM_TEAM_2)
1968                         team2_score = 1;
1969                 else if(head.team == NUM_TEAM_3)
1970                         team3_score = 1;
1971                 else if(head.team == NUM_TEAM_4)
1972                         team4_score = 1;
1973         }
1974
1975         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1976         {
1977                 if(head.team == NUM_TEAM_1)
1978                         team1_score = 1;
1979                 else if(head.team == NUM_TEAM_2)
1980                         team2_score = 1;
1981                 else if(head.team == NUM_TEAM_3)
1982                         team3_score = 1;
1983                 else if(head.team == NUM_TEAM_4)
1984                         team4_score = 1;
1985         }
1986
1987         ClearWinners();
1988         if(team1_score + team2_score + team3_score + team4_score == 0)
1989         {
1990                 checkrules_equality = TRUE;
1991                 return WINNING_YES;
1992         }
1993         else if(team1_score + team2_score + team3_score + team4_score == 1)
1994         {
1995                 float t, i;
1996                 if(team1_score)
1997                         t = NUM_TEAM_1;
1998                 else if(team2_score)
1999                         t = NUM_TEAM_2;
2000                 else if(team3_score)
2001                         t = NUM_TEAM_3;
2002                 else // if(team4_score)
2003                         t = NUM_TEAM_4;
2004                 CheckAllowedTeams(world);
2005                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2006                 {
2007                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2008                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2009                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2010                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2011                 }
2012
2013                 AddWinners(team, t);
2014                 return WINNING_YES;
2015         }
2016         else
2017                 return WINNING_NO;
2018 }
2019
2020 /*
2021 ============
2022 CheckRules_World
2023
2024 Exit deathmatch games upon conditions
2025 ============
2026 */
2027 void ReadyRestart();
2028 void CheckRules_World()
2029 {
2030         float timelimit;
2031         float fraglimit;
2032         float leadlimit;
2033
2034         VoteThink();
2035         MapVote_Think();
2036
2037         SetDefaultAlpha();
2038
2039         /*
2040         MapVote_Think should now do that part
2041         if (intermission_running)
2042                 if (time >= intermission_exittime + 60)
2043                 {
2044                         if(!DoNextMapOverride())
2045                                 GotoNextMap();
2046                         return;
2047                 }
2048         */
2049
2050         if (gameover)   // someone else quit the game already
2051         {
2052                 if(player_count == 0) // Nobody there? Then let's go to the next map
2053                         MapVote_Start();
2054                         // this will actually check the player count in the next frame
2055                         // again, but this shouldn't hurt
2056                 return;
2057         }
2058
2059         timelimit = autocvar_timelimit * 60;
2060         fraglimit = autocvar_fraglimit;
2061         leadlimit = autocvar_leadlimit;
2062
2063         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2064         {
2065                 if(timelimit > 0)
2066                         timelimit = 0; // timelimit is not made for warmup
2067                 if(fraglimit > 0)
2068                         fraglimit = 0; // no fraglimit for now
2069                 leadlimit = 0; // no leadlimit for now
2070         }
2071
2072         if(timelimit > 0)
2073         {
2074                 timelimit += game_starttime;
2075         }
2076         else if (timelimit < 0)
2077         {
2078                 // endmatch
2079                 NextLevel();
2080                 return;
2081         }
2082
2083         if(g_onslaught)
2084                 timelimit = 0; // ONS has its own overtime rule
2085
2086         float wantovertime;
2087         wantovertime = 0;
2088
2089         if(timelimit > game_starttime)
2090                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2091         else
2092                 game_completion_ratio = 0;
2093
2094         if(checkrules_suddendeathend)
2095         {
2096                 if(!checkrules_suddendeathwarning)
2097                 {
2098                         checkrules_suddendeathwarning = TRUE;
2099                         if(g_race && !g_race_qualifying)
2100                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2101                         else
2102                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2103                 }
2104         }
2105         else
2106         {
2107                 if (timelimit && time >= timelimit)
2108                 {
2109                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2110                         {
2111                                 float totalplayers;
2112                                 float playerswithlaps;
2113                                 float readyplayers;
2114                                 entity head;
2115                                 totalplayers = playerswithlaps = readyplayers = 0;
2116                                 FOR_EACH_PLAYER(head)
2117                                 {
2118                                         ++totalplayers;
2119                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2120                                                 ++playerswithlaps;
2121                                         if(head.ready)
2122                                                 ++readyplayers;
2123                                 }
2124
2125                                 // at least 2 of the players have completed a lap: start the RACE
2126                                 // otherwise, the players should end the qualifying on their own
2127                                 if(readyplayers || playerswithlaps >= 2)
2128                                 {
2129                                         checkrules_suddendeathend = 0;
2130                                         ReadyRestart(); // go to race
2131                                         return;
2132                                 }
2133                                 else
2134                                         wantovertime |= InitiateSuddenDeath();
2135                         }
2136                         else
2137                                 wantovertime |= InitiateSuddenDeath();
2138                 }
2139         }
2140
2141         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2142         {
2143                 NextLevel();
2144                 return;
2145         }
2146
2147         float checkrules_status;
2148         checkrules_status = WinningCondition_RanOutOfSpawns();
2149         if(checkrules_status == WINNING_YES)
2150         {
2151                 bprint("Hey! Someone ran out of spawns!\n");
2152         }
2153         else if(g_race && !g_race_qualifying && timelimit >= 0)
2154         {
2155                 checkrules_status = WinningCondition_Race(fraglimit);
2156                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2157         }
2158         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2159         {
2160                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2161                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2162         }
2163         else if(g_assault)
2164         {
2165                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2166         }
2167         else if(g_lms)
2168         {
2169                 checkrules_status = WinningCondition_LMS();
2170         }
2171         else if (g_onslaught)
2172         {
2173                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2174         }
2175         else
2176         {
2177                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2178                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2179         }
2180
2181         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2182         {
2183                 checkrules_status = WINNING_NEVER;
2184                 checkrules_overtimesadded = -1;
2185                 wantovertime |= InitiateSuddenDeath();
2186         }
2187
2188         if(checkrules_status == WINNING_NEVER)
2189                 // equality cases! Nobody wins if the overtime ends in a draw.
2190                 ClearWinners();
2191
2192         if(wantovertime)
2193         {
2194                 if(checkrules_status == WINNING_NEVER)
2195                         InitiateOvertime();
2196                 else
2197                         checkrules_status = WINNING_YES;
2198         }
2199
2200         if(checkrules_suddendeathend)
2201                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2202                         checkrules_status = WINNING_YES;
2203
2204         if(checkrules_status == WINNING_YES)
2205         {
2206                 //print("WINNING\n");
2207                 NextLevel();
2208         }
2209 }
2210
2211 float mapvote_nextthink;
2212 float mapvote_initialized;
2213 float mapvote_keeptwotime;
2214 float mapvote_timeout;
2215 string mapvote_message;
2216 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2217 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2218 float mapvote_screenshot_dirs_count;
2219
2220 float mapvote_count;
2221 float mapvote_count_real;
2222 string mapvote_maps[MAPVOTE_COUNT];
2223 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2224 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2225 float mapvote_maps_suggested[MAPVOTE_COUNT];
2226 string mapvote_suggestions[MAPVOTE_COUNT];
2227 float mapvote_suggestion_ptr;
2228 float mapvote_voters;
2229 float mapvote_selections[MAPVOTE_COUNT];
2230 float mapvote_run;
2231 float mapvote_detail;
2232 float mapvote_abstain;
2233 .float mapvote;
2234
2235 void MapVote_ClearAllVotes()
2236 {
2237         FOR_EACH_CLIENT(other)
2238                 other.mapvote = 0;
2239 }
2240
2241 string MapVote_Suggest(string m)
2242 {
2243         float i;
2244         if(m == "")
2245                 return "That's not how to use this command.";
2246         if(!autocvar_g_maplist_votable_suggestions)
2247                 return "Suggestions are not accepted on this server.";
2248         if(mapvote_initialized)
2249                 return "Can't suggest - voting is already in progress!";
2250         m = MapInfo_FixName(m);
2251         if not(m)
2252                 return "The map you suggested is not available on this server.";
2253         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2254                 if(Map_IsRecent(m))
2255                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2256
2257         if(!MapInfo_CheckMap(m))
2258                 return "The map you suggested does not support the current game mode.";
2259         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2260                 if(mapvote_suggestions[i] == m)
2261                         return "This map was already suggested.";
2262         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2263         {
2264                 i = floor(random() * mapvote_suggestion_ptr);
2265         }
2266         else
2267         {
2268                 i = mapvote_suggestion_ptr;
2269                 mapvote_suggestion_ptr += 1;
2270         }
2271         if(mapvote_suggestions[i] != "")
2272                 strunzone(mapvote_suggestions[i]);
2273         mapvote_suggestions[i] = strzone(m);
2274         if(autocvar_sv_eventlog)
2275                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2276         return strcat("Suggestion of ", m, " accepted.");
2277 }
2278
2279 void MapVote_AddVotable(string nextMap, float isSuggestion)
2280 {
2281         float j, i, o;
2282         string pakfile, mapfile;
2283
2284         if(nextMap == "")
2285                 return;
2286         for(j = 0; j < mapvote_count; ++j)
2287                 if(mapvote_maps[j] == nextMap)
2288                         return;
2289         // suggestions might be no longer valid/allowed after gametype switch!
2290         if(isSuggestion)
2291                 if(!MapInfo_CheckMap(nextMap))
2292                         return;
2293         mapvote_maps[mapvote_count] = strzone(nextMap);
2294         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2295
2296         pakfile = string_null;
2297         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2298         {
2299                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2300                 pakfile = whichpack(strcat(mapfile, ".tga"));
2301                 if(pakfile == "")
2302                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2303                 if(pakfile == "")
2304                         pakfile = whichpack(strcat(mapfile, ".png"));
2305                 if(pakfile != "")
2306                         break;
2307         }
2308         if(i >= mapvote_screenshot_dirs_count)
2309                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2310         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2311                 pakfile = substring(pakfile, o, -1);
2312
2313         mapvote_maps_screenshot_dir[mapvote_count] = i;
2314         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2315
2316         mapvote_count += 1;
2317 }
2318
2319 void MapVote_Spawn();
2320 void MapVote_Init()
2321 {
2322         float i;
2323         float nmax, smax;
2324
2325         MapVote_ClearAllVotes();
2326
2327         mapvote_count = 0;
2328         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2329         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2330
2331         if(mapvote_abstain)
2332                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2333         else
2334                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2335         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2336
2337         // we need this for AddVotable, as that cycles through the screenshot dirs
2338         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2339         if(mapvote_screenshot_dirs_count == 0)
2340                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2341         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2342         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2343                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2344
2345         if(mapvote_suggestion_ptr)
2346                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2347                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2348
2349         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2350                 MapVote_AddVotable(GetNextMap(), FALSE);
2351
2352         if(mapvote_count == 0)
2353         {
2354                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2355                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2356                 if(autocvar_g_maplist_shuffle)
2357                         ShuffleMaplist();
2358                 localcmd("\nmenu_cmd sync\n");
2359                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2360                         MapVote_AddVotable(GetNextMap(), FALSE);
2361         }
2362
2363         mapvote_count_real = mapvote_count;
2364         if(mapvote_abstain)
2365                 MapVote_AddVotable("don't care", 0);
2366
2367         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2368
2369         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2370         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2371         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2372                 mapvote_keeptwotime = 0;
2373         mapvote_message = "Choose a map and press its key!";
2374
2375         MapVote_Spawn();
2376 }
2377
2378 void MapVote_SendPicture(float id)
2379 {
2380         msg_entity = self;
2381         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2382         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2383         WriteByte(MSG_ONE, id);
2384         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2385 }
2386
2387 float MapVote_GetMapMask()
2388 {
2389         float mask, i, power;
2390         mask = 0;
2391         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2392                 if(mapvote_maps[i] != "")
2393                         mask |= power;
2394         return mask;
2395 }
2396
2397 entity mapvote_ent;
2398 float MapVote_SendEntity(entity to, float sf)
2399 {
2400         float i;
2401
2402         if(sf & 1)
2403                 sf &= ~2; // if we send 1, we don't need to also send 2
2404
2405         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2406         WriteByte(MSG_ENTITY, sf);
2407
2408         if(sf & 1)
2409         {
2410                 // flag 1 == initialization
2411                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2412                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2413                 WriteString(MSG_ENTITY, "");
2414                 WriteByte(MSG_ENTITY, mapvote_count);
2415                 WriteByte(MSG_ENTITY, mapvote_abstain);
2416                 WriteByte(MSG_ENTITY, mapvote_detail);
2417                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2418                 if(mapvote_count <= 8)
2419                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2420                 else
2421                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2422                 for(i = 0; i < mapvote_count; ++i)
2423                         if(mapvote_maps[i] != "")
2424                         {
2425                                 if(mapvote_abstain && i == mapvote_count - 1)
2426                                 {
2427                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2428                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2429                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2430                                 }
2431                                 else
2432                                 {
2433                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2434                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2435                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2436                                 }
2437                         }
2438         }
2439
2440         if(sf & 2)
2441         {
2442                 // flag 2 == update of mask
2443                 if(mapvote_count <= 8)
2444                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2445                 else
2446                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2447         }
2448
2449         if(sf & 4)
2450         {
2451                 if(mapvote_detail)
2452                         for(i = 0; i < mapvote_count; ++i)
2453                                 if(mapvote_maps[i] != "")
2454                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2455
2456                 WriteByte(MSG_ENTITY, to.mapvote);
2457         }
2458
2459         return TRUE;
2460 }
2461
2462 void MapVote_Spawn()
2463 {
2464         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2465 }
2466
2467 void MapVote_TouchMask()
2468 {
2469         mapvote_ent.SendFlags |= 2;
2470 }
2471
2472 void MapVote_TouchVotes(entity voter)
2473 {
2474         mapvote_ent.SendFlags |= 4;
2475 }
2476
2477 float MapVote_Finished(float mappos)
2478 {
2479         string result;
2480         float i;
2481         float didntvote;
2482
2483         if(autocvar_sv_eventlog)
2484         {
2485                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2486                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2487                 didntvote = mapvote_voters;
2488                 for(i = 0; i < mapvote_count; ++i)
2489                         if(mapvote_maps[i] != "")
2490                         {
2491                                 didntvote -= mapvote_selections[i];
2492                                 if(i != mappos)
2493                                 {
2494                                         result = strcat(result, ":", mapvote_maps[i]);
2495                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2496                                 }
2497                         }
2498                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2499
2500                 GameLogEcho(result);
2501                 if(mapvote_maps_suggested[mappos])
2502                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2503         }
2504
2505         FOR_EACH_REALCLIENT(other)
2506                 FixClientCvars(other);
2507
2508         Map_Goto_SetStr(mapvote_maps[mappos]);
2509         Map_Goto(0);
2510         alreadychangedlevel = TRUE;
2511         return TRUE;
2512 }
2513 void MapVote_CheckRules_1()
2514 {
2515         float i;
2516
2517         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2518         {
2519                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2520                 mapvote_selections[i] = 0;
2521         }
2522
2523         mapvote_voters = 0;
2524         FOR_EACH_REALCLIENT(other)
2525         {
2526                 ++mapvote_voters;
2527                 if(other.mapvote)
2528                 {
2529                         i = other.mapvote - 1;
2530                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2531                         mapvote_selections[i] = mapvote_selections[i] + 1;
2532                 }
2533         }
2534 }
2535
2536 float MapVote_CheckRules_2()
2537 {
2538         float i;
2539         float firstPlace, secondPlace;
2540         float firstPlaceVotes, secondPlaceVotes;
2541         float mapvote_voters_real;
2542         string result;
2543
2544         if(mapvote_count_real == 1)
2545                 return MapVote_Finished(0);
2546
2547         mapvote_voters_real = mapvote_voters;
2548         if(mapvote_abstain)
2549                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2550
2551         RandomSelection_Init();
2552         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2553                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2554         firstPlace = RandomSelection_chosen_float;
2555         firstPlaceVotes = RandomSelection_best_priority;
2556         //dprint("First place: ", ftos(firstPlace), "\n");
2557         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2558
2559         RandomSelection_Init();
2560         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2561                 if(i != firstPlace)
2562                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2563         secondPlace = RandomSelection_chosen_float;
2564         secondPlaceVotes = RandomSelection_best_priority;
2565         //dprint("Second place: ", ftos(secondPlace), "\n");
2566         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2567
2568         if(firstPlace == -1)
2569                 error("No first place in map vote... WTF?");
2570
2571         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2572                 return MapVote_Finished(firstPlace);
2573
2574         if(mapvote_keeptwotime)
2575                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2576                 {
2577                         float didntvote;
2578                         MapVote_TouchMask();
2579                         mapvote_message = "Now decide between the TOP TWO!";
2580                         mapvote_keeptwotime = 0;
2581                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2582                         result = strcat(result, ":", ftos(firstPlaceVotes));
2583                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2584                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2585                         didntvote = mapvote_voters;
2586                         for(i = 0; i < mapvote_count; ++i)
2587                                 if(mapvote_maps[i] != "")
2588                                 {
2589                                         didntvote -= mapvote_selections[i];
2590                                         if(i != firstPlace)
2591                                                 if(i != secondPlace)
2592                                                 {
2593                                                         result = strcat(result, ":", mapvote_maps[i]);
2594                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2595                                                         if(i < mapvote_count_real)
2596                                                         {
2597                                                                 strunzone(mapvote_maps[i]);
2598                                                                 mapvote_maps[i] = "";
2599                                                                 strunzone(mapvote_maps_pakfile[i]);
2600                                                                 mapvote_maps_pakfile[i] = "";
2601                                                         }
2602                                                 }
2603                                 }
2604                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2605                         if(autocvar_sv_eventlog)
2606                                 GameLogEcho(result);
2607                 }
2608
2609         return FALSE;
2610 }
2611 void MapVote_Tick()
2612 {
2613         float keeptwo;
2614         float totalvotes;
2615
2616         keeptwo = mapvote_keeptwotime;
2617         MapVote_CheckRules_1(); // count
2618         if(MapVote_CheckRules_2()) // decide
2619                 return;
2620
2621         totalvotes = 0;
2622         FOR_EACH_REALCLIENT(other)
2623         {
2624                 // hide scoreboard again
2625                 if(other.health != 2342)
2626                 {
2627                         other.health = 2342;
2628                         other.impulse = 0;
2629                         if(IS_REAL_CLIENT(other))
2630                         {
2631                                 msg_entity = other;
2632                                 WriteByte(MSG_ONE, SVC_FINALE);
2633                                 WriteString(MSG_ONE, "");
2634                         }
2635                 }
2636
2637                 // clear possibly invalid votes
2638                 if(mapvote_maps[other.mapvote - 1] == "")
2639                         other.mapvote = 0;
2640                 // use impulses as new vote
2641                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2642                         if(mapvote_maps[other.impulse - 1] != "")
2643                         {
2644                                 other.mapvote = other.impulse;
2645                                 MapVote_TouchVotes(other);
2646                         }
2647                 other.impulse = 0;
2648
2649                 if(other.mapvote)
2650                         ++totalvotes;
2651         }
2652
2653         MapVote_CheckRules_1(); // just count
2654 }
2655 void MapVote_Start()
2656 {
2657         if(mapvote_run)
2658                 return;
2659
2660         // wait for stats to be sent first
2661         if(!playerstats_waitforme)
2662                 return;
2663
2664         MapInfo_Enumerate();
2665         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2666                 mapvote_run = TRUE;
2667 }
2668 void MapVote_Think()
2669 {
2670         if(!mapvote_run)
2671                 return;
2672
2673         if(alreadychangedlevel)
2674                 return;
2675
2676         if(time < mapvote_nextthink)
2677                 return;
2678         //dprint("tick\n");
2679
2680         mapvote_nextthink = time + 0.5;
2681
2682         if(!mapvote_initialized)
2683         {
2684                 if(autocvar_rescan_pending == 1)
2685                 {
2686                         cvar_set("rescan_pending", "2");
2687                         localcmd("fs_rescan\nrescan_pending 3\n");
2688                         return;
2689                 }
2690                 else if(autocvar_rescan_pending == 2)
2691                 {
2692                         return;
2693                 }
2694                 else if(autocvar_rescan_pending == 3)
2695                 {
2696                         // now build missing mapinfo files
2697                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2698                                 return;
2699
2700                         // we're done, start the timer
2701                         cvar_set("rescan_pending", "0");
2702                 }
2703
2704                 mapvote_initialized = TRUE;
2705                 if(DoNextMapOverride(0))
2706                         return;
2707                 if(!autocvar_g_maplist_votable || player_count <= 0)
2708                 {
2709                         GotoNextMap(0);
2710                         return;
2711                 }
2712                 MapVote_Init();
2713         }
2714
2715         MapVote_Tick();
2716 }
2717
2718 string GotoMap(string m)
2719 {
2720         if(!MapInfo_CheckMap(m))
2721                 return "The map you chose is not available on this server.";
2722         cvar_set("nextmap", m);
2723         cvar_set("timelimit", "-1");
2724         if(mapvote_initialized || alreadychangedlevel)
2725         {
2726                 if(DoNextMapOverride(0))
2727                         return "Map switch initiated.";
2728                 else
2729                         return "Hm... no. For some reason I like THIS map more.";
2730         }
2731         else
2732                 return "Map switch will happen after scoreboard.";
2733 }
2734
2735
2736 void EndFrame()
2737 {
2738         float altime;
2739         FOR_EACH_REALCLIENT(self)
2740         {
2741                 if(IS_SPEC(self))
2742                 {
2743                         if(self.enemy.typehitsound)
2744                                 self.typehit_time = time;
2745                         else if(self.enemy.hitsound)
2746                                 self.hit_time = time;
2747                 }
2748                 else
2749                 {
2750                         if(self.typehitsound)
2751                                 self.typehit_time = time;
2752                         else if(self.hitsound)
2753                                 self.hit_time = time;
2754                 }
2755         }
2756         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2757         // add 1 frametime because after this, engine SV_Physics
2758         // increases time by a frametime and then networks the frame
2759         // add another frametime because client shows everything with
2760         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2761         // needed!
2762         FOR_EACH_CLIENT(self)
2763         {
2764                 self.hitsound = FALSE;
2765                 self.typehitsound = FALSE;
2766                 antilag_record(self, altime);
2767         }
2768 }
2769
2770
2771 /*
2772  * RedirectionThink:
2773  * returns TRUE if redirecting
2774  */
2775 float redirection_timeout;
2776 float redirection_nextthink;
2777 float RedirectionThink()
2778 {
2779         float clients_found;
2780
2781         if(redirection_target == "")
2782                 return FALSE;
2783
2784         if(!redirection_timeout)
2785         {
2786                 cvar_set("sv_public", "-2");
2787                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2788                 if(redirection_target == "self")
2789                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2790                 else
2791                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2792         }
2793
2794         if(time < redirection_nextthink)
2795                 return TRUE;
2796
2797         redirection_nextthink = time + 1;
2798
2799         clients_found = 0;
2800         FOR_EACH_REALCLIENT(self)
2801         {
2802                 // TODO add timer
2803                 print("Redirecting: sending connect command to ", self.netname, "\n");
2804                 if(redirection_target == "self")
2805                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2806                 else
2807                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2808                 ++clients_found;
2809         }
2810
2811         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2812
2813         if(time > redirection_timeout || clients_found == 0)
2814                 localcmd("\nwait; wait; wait; quit\n");
2815
2816         return TRUE;
2817 }
2818
2819 void TargetMusic_RestoreGame();
2820 void RestoreGame()
2821 {
2822         // Loaded from a save game
2823         // some things then break, so let's work around them...
2824
2825         // Progs DB (capture records)
2826         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2827
2828         // Mapinfo
2829         MapInfo_Shutdown();
2830         MapInfo_Enumerate();
2831         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2832         WeaponStats_Init();
2833
2834         TargetMusic_RestoreGame();
2835 }
2836
2837 void Shutdown()
2838 {
2839         entity e;
2840
2841         gameover = 2;
2842
2843         if(world_initialized > 0)
2844         {
2845                 world_initialized = 0;
2846                 print("Saving persistent data...\n");
2847                 Ban_SaveBans();
2848
2849                 PlayerStats_EndMatch(0);
2850                 FOR_EACH_CLIENT(e)
2851                         PlayerStats_AddGlobalInfo(e);
2852                 PlayerStats_Shutdown();
2853
2854                 if(!cheatcount_total)
2855                 {
2856                         if(autocvar_sv_db_saveasdump)
2857                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2858                         else
2859                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2860                 }
2861                 if(autocvar_developer)
2862                 {
2863                         if(autocvar_sv_db_saveasdump)
2864                                 db_dump(TemporaryDB, "server-temp.db");
2865                         else
2866                                 db_save(TemporaryDB, "server-temp.db");
2867                 }
2868                 CheatShutdown(); // must be after cheatcount check
2869                 db_close(ServerProgsDB);
2870                 db_close(TemporaryDB);
2871                 print("done!\n");
2872                 // tell the bot system the game is ending now
2873                 bot_endgame();
2874
2875                 WeaponStats_Shutdown();
2876                 MapInfo_Shutdown();
2877         }
2878         else if(world_initialized == 0)
2879         {
2880                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2881         }
2882 }