qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/buffs.qh"
  23 #include "../common/constants.qh"
  24 #include "../common/deathtypes.qh"
  25 #include "../common/effects.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/all.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications.qh"
  31 #include "../common/playerstats.qh"
  32 #include "../common/stats.qh"
  33 #include "../common/teams.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void ShuffleMaplist();
  97
  98 void SetDefaultAlpha()
  99 {
 100         if(autocvar_g_running_guns)
 101         {
 102                 default_player_alpha = -1;
 103                 default_weapon_alpha = +1;
 104         }
 105         else if(g_cloaked)
 106         {
 107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 108                 default_weapon_alpha = default_player_alpha;
 109         }
 110         else
 111         {
 112                 default_player_alpha = autocvar_g_player_alpha;
 113                 if(default_player_alpha == 0)
 114                         default_player_alpha = 1;
 115                 default_weapon_alpha = default_player_alpha;
 116         }
 117 }
 118
 119 void GotoFirstMap()
 120 {
 121         float n;
 122         if(autocvar__sv_init)
 123         {
 124                 // cvar_set("_sv_init", "0");
 125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 126                 // to this "init" map on a dedicated server will cause no permanent
 127                 // harm
 128                 if(autocvar_g_maplist_shuffle)
 129                         ShuffleMaplist();
 130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 132
 133                 MapInfo_Enumerate();
 134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 135
 136                 if(!DoNextMapOverride(1))
 137                         GotoNextMap(1);
 138
 139                 return;
 140         }
 141
 142         if(time < 5)
 143         {
 144                 self.nextthink = time;
 145         }
 146         else
 147         {
 148                 self.nextthink = time + 1;
 149                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 150         }
 151 }
 152
 153 void cvar_changes_init()
 154 {
 155         float h;
 156         string k, v, d;
 157         float n, i, adding, pureadding;
 158
 159         if(cvar_changes)
 160                 strunzone(cvar_changes);
 161         cvar_changes = string_null;
 162         if(cvar_purechanges)
 163                 strunzone(cvar_purechanges);
 164         cvar_purechanges = string_null;
 165         cvar_purechanges_count = 0;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         adding = true;
 172         pureadding = true;
 173
 174         for(i = 0; i < n; ++i)
 175         {
 176                 k = bufstr_get(h, i);
 177
 178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 180 #define BADCVAR(p) if(k == p) continue
 181
 182                 // general excludes and namespaces for server admin used cvars
 183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 184
 185                 // internal
 186                 BADPREFIX("csqc_");
 187                 BADPREFIX("cvar_check_");
 188                 BADCVAR("gamecfg");
 189                 BADCVAR("g_configversion");
 190                 BADCVAR("g_maplist_index");
 191                 BADCVAR("halflifebsp");
 192                 BADCVAR("sv_mapformat_is_quake2");
 193                 BADCVAR("sv_mapformat_is_quake3");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_invasion_teams");
 277                 BADCVAR("g_keepaway");
 278                 BADCVAR("g_keyhunt");
 279                 BADCVAR("g_keyhunt_teams");
 280                 BADCVAR("g_lms");
 281                 BADCVAR("g_nexball");
 282                 BADCVAR("g_onslaught");
 283                 BADCVAR("g_race");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_tdm");
 286                 BADCVAR("g_tdm_teams");
 287                 BADCVAR("leadlimit");
 288                 BADCVAR("nextmap");
 289                 BADCVAR("teamplay");
 290                 BADCVAR("timelimit");
 291
 292                 // long
 293                 BADCVAR("hostname");
 294                 BADCVAR("g_maplist");
 295                 BADCVAR("g_maplist_mostrecent");
 296                 BADCVAR("sv_motd");
 297
 298                 v = cvar_string(k);
 299                 d = cvar_defstring(k);
 300                 if(v == d)
 301                         continue;
 302
 303                 if(adding)
 304                 {
 305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 306                         if(strlen(cvar_changes) > 16384)
 307                         {
 308                                 cvar_changes = "// too many settings have been changed to show them here\n";
 309                                 adding = 0;
 310                         }
 311                 }
 312
 313                 // now check if the changes are actually gameplay relevant
 314
 315                 // does nothing visible
 316                 BADCVAR("captureleadlimit_override");
 317                 BADCVAR("g_balance_kill_delay");
 318                 BADCVAR("g_ca_point_limit");
 319                 BADCVAR("g_ca_point_leadlimit");
 320                 BADCVAR("g_ctf_captimerecord_always");
 321                 BADCVAR("g_ctf_flag_glowtrails");
 322                 BADCVAR("g_ctf_flag_pickup_verbosename");
 323                 BADCVAR("g_domination_point_leadlimit");
 324                 BADCVAR("g_forced_respawn");
 325                 BADCVAR("g_freezetag_point_limit");
 326                 BADCVAR("g_freezetag_point_leadlimit");
 327                 BADCVAR("g_keyhunt_point_leadlimit");
 328                 BADPREFIX("g_mod_");
 329                 BADCVAR("g_invasion_point_limit");
 330                 BADCVAR("g_nexball_goalleadlimit");
 331                 BADCVAR("g_tdm_point_limit");
 332                 BADCVAR("g_tdm_point_leadlimit");
 333                 BADCVAR("leadlimit_and_fraglimit");
 334                 BADCVAR("leadlimit_override");
 335                 BADCVAR("pausable");
 336                 BADCVAR("sv_allow_fullbright");
 337                 BADCVAR("sv_checkforpacketsduringsleep");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_maxidle_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351                 BADCVAR("gameversion");
 352                 BADPREFIX("gameversion_");
 353                 BADCVAR("sv_minigames");
 354                 BADPREFIX("sv_minigames_");
 355                 BADCVAR("sv_namechangetimer");
 356
 357                 // allowed changes to server admins (please sync this to server.cfg)
 358                 // vi commands:
 359                 //   :/"impure"/,$d
 360                 //   :g!,^\/\/[^ /],d
 361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 362                 //   :%!sort
 363                 // yes, this does contain some redundant stuff, don't really care
 364                 BADCVAR("bot_config_file");
 365                 BADCVAR("bot_number");
 366                 BADCVAR("bot_prefix");
 367                 BADCVAR("bot_suffix");
 368                 BADCVAR("capturelimit_override");
 369                 BADCVAR("fraglimit_override");
 370                 BADCVAR("gametype");
 371                 BADCVAR("g_antilag");
 372                 BADCVAR("g_balance_teams");
 373                 BADCVAR("g_balance_teams_prevent_imbalance");
 374                 BADCVAR("g_balance_teams_scorefactor");
 375                 BADCVAR("g_ban_sync_trusted_servers");
 376                 BADCVAR("g_ban_sync_uri");
 377                 BADCVAR("g_ca_teams_override");
 378                 BADCVAR("g_ctf_ignore_frags");
 379                 BADCVAR("g_domination_point_limit");
 380                 BADCVAR("g_domination_teams_override");
 381                 BADCVAR("g_freezetag_teams_override");
 382                 BADCVAR("g_friendlyfire");
 383                 BADCVAR("g_fullbrightitems");
 384                 BADCVAR("g_fullbrightplayers");
 385                 BADCVAR("g_keyhunt_point_limit");
 386                 BADCVAR("g_keyhunt_teams_override");
 387                 BADCVAR("g_lms_lives_override");
 388                 BADCVAR("g_maplist");
 389                 BADCVAR("g_maplist_check_waypoints");
 390                 BADCVAR("g_maplist_mostrecent_count");
 391                 BADCVAR("g_maplist_shuffle");
 392                 BADCVAR("g_maplist_votable");
 393                 BADCVAR("g_maplist_votable_abstain");
 394                 BADCVAR("g_maplist_votable_nodetail");
 395                 BADCVAR("g_maplist_votable_suggestions");
 396                 BADCVAR("g_maxplayers");
 397                 BADCVAR("g_mirrordamage");
 398                 BADCVAR("g_nexball_goallimit");
 399                 BADCVAR("g_powerups");
 400                 BADCVAR("g_start_delay");
 401                 BADCVAR("g_tdm_teams_override");
 402                 BADCVAR("g_warmup");
 403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 404                 BADCVAR("hostname");
 405                 BADCVAR("log_file");
 406                 BADCVAR("maxplayers");
 407                 BADCVAR("minplayers");
 408                 BADCVAR("net_address");
 409                 BADCVAR("port");
 410                 BADCVAR("rcon_password");
 411                 BADCVAR("rcon_restricted_commands");
 412                 BADCVAR("rcon_restricted_password");
 413                 BADCVAR("skill");
 414                 BADCVAR("sv_adminnick");
 415                 BADCVAR("sv_autoscreenshot");
 416                 BADCVAR("sv_autotaunt");
 417                 BADCVAR("sv_curl_defaulturl");
 418                 BADCVAR("sv_defaultcharacter");
 419                 BADCVAR("sv_defaultplayercolors");
 420                 BADCVAR("sv_defaultplayermodel");
 421                 BADCVAR("sv_defaultplayerskin");
 422                 BADCVAR("sv_maxidle");
 423                 BADCVAR("sv_maxrate");
 424                 BADCVAR("sv_motd");
 425                 BADCVAR("sv_public");
 426                 BADCVAR("sv_ready_restart");
 427                 BADCVAR("sv_status_privacy");
 428                 BADCVAR("sv_taunt");
 429                 BADCVAR("sv_vote_call");
 430                 BADCVAR("sv_vote_commands");
 431                 BADCVAR("sv_vote_majority_factor");
 432                 BADCVAR("sv_vote_master");
 433                 BADCVAR("sv_vote_master_commands");
 434                 BADCVAR("sv_vote_master_password");
 435                 BADCVAR("sv_vote_simple_majority_factor");
 436                 BADCVAR("teamplay_mode");
 437                 BADCVAR("timelimit_override");
 438                 BADCVAR("g_spawnshieldtime");
 439                 BADPREFIX("g_warmup_");
 440                 BADPREFIX("sv_ready_restart_");
 441
 442                 // mutators that announce themselves properly to the server browser
 443                 BADCVAR("g_instagib");
 444                 BADCVAR("g_new_toys");
 445                 BADCVAR("g_nix");
 446                 BADCVAR("g_grappling_hook");
 447                 BADCVAR("g_jetpack");
 448
 449 #undef BADPREFIX
 450 #undef BADCVAR
 451
 452                 if(pureadding)
 453                 {
 454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 455                         if(strlen(cvar_purechanges) > 16384)
 456                         {
 457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 458                                 pureadding = 0;
 459                         }
 460                 }
 461                 ++cvar_purechanges_count;
 462                 // WARNING: this variable is used for the server list
 463                 // NEVER dare to skip this code!
 464                 // Hacks to intentionally appearing as "pure server" even though you DO have
 465                 // modified settings may be punished by removal from the server list.
 466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 467                 // though.
 468         }
 469         buf_del(h);
 470         if(cvar_changes == "")
 471                 cvar_changes = "// this server runs at default server settings\n";
 472         else
 473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 474         cvar_changes = strzone(cvar_changes);
 475         if(cvar_purechanges == "")
 476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 477         else
 478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 479         cvar_purechanges = strzone(cvar_purechanges);
 480 }
 481
 482 void detect_maptype()
 483 {
 484 #if 0
 485         vector o, v;
 486         float i;
 487
 488         for (;;)
 489         {
 490                 o = world.mins;
 491                 o.x += random() * (world.maxs.x - world.mins.x);
 492                 o.y += random() * (world.maxs.y - world.mins.y);
 493                 o.z += random() * (world.maxs.z - world.mins.z);
 494
 495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 496                 if(trace_fraction == 1)
 497                         continue;
 498
 499                 v = trace_endpos;
 500
 501                 for(i = 0; i < 64; i += 4)
 502                 {
 503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 504         if(trace_fraction == 1)
 505                 continue;
 506                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 507                 }
 508
 509                 break;
 510         }
 511 #endif
 512 }
 513
 514 entity randomseed;
 515 float RandomSeed_Send(entity to, int sf)
 516 {
 517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 518         WriteShort(MSG_ENTITY, self.cnt);
 519         return true;
 520 }
 521 void RandomSeed_Think()
 522 {
 523         self.cnt = bound(0, floor(random() * 65536), 65535);
 524         self.nextthink = time + 5;
 525
 526         self.SendFlags |= 1;
 527 }
 528 void RandomSeed_Spawn()
 529 {
 530         randomseed = spawn();
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 533
 534         entity oldself;
 535         oldself = self;
 536         self = randomseed;
 537         self.think(); // sets random seed and nextthink
 538         self = oldself;
 539 }
 540
 541 void spawnfunc___init_dedicated_server(void)
 542 {
 543         // handler for _init/_init map (only for dedicated server initialization)
 544
 545         world_initialized = -1; // don't complain
 546         cvar = cvar_normal;
 547         cvar_string = cvar_string_normal;
 548         cvar_set = cvar_set_normal;
 549
 550         remove = remove_unsafely;
 551
 552         entity e;
 553         e = spawn();
 554         e.think = GotoFirstMap;
 555         e.nextthink = time; // this is usually 1 at this point
 556
 557         e = spawn();
 558         e.classname = "info_player_deathmatch"; // safeguard against player joining
 559
 560         self.classname = "worldspawn"; // safeguard against various stuff ;)
 561
 562         // needs to be done so early because of the constants they create
 563         static_init();
 564         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 565         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 566         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 567         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 568
 569         MapInfo_Enumerate();
 570         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 571 }
 572
 573 void Map_MarkAsRecent(string m);
 574 float world_already_spawned;
 575 void Nagger_Init();
 576 void ClientInit_Spawn();
 577 void WeaponStats_Init();
 578 void WeaponStats_Shutdown();
 579 void Physics_AddStats();
 580 void spawnfunc_worldspawn (void)
 581 {
 582         float fd, l, j, n;
 583         string s;
 584
 585         cvar = cvar_normal;
 586         cvar_string = cvar_string_normal;
 587         cvar_set = cvar_set_normal;
 588
 589         if(world_already_spawned)
 590                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 591         world_already_spawned = true;
 592
 593         remove = remove_safely; // during spawning, watch what you remove!
 594
 595         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 596
 597         compressShortVector_init();
 598
 599         entity head;
 600         head = nextent(world);
 601         maxclients = 0;
 602         while(head)
 603         {
 604                 ++maxclients;
 605                 head = nextent(head);
 606         }
 607
 608         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 609
 610         // needs to be done so early because of the constants they create
 611         static_init();
 612         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 613         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 614         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 615         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 616
 617         initialize_minigames();
 618
 619         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 620
 621         TemporaryDB = db_create();
 622
 623         // 0 normal
 624         lightstyle(0, "m");
 625
 626         // 1 FLICKER (first variety)
 627         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 628
 629         // 2 SLOW STRONG PULSE
 630         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 631
 632         // 3 CANDLE (first variety)
 633         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 634
 635         // 4 FAST STROBE
 636         lightstyle(4, "mamamamamama");
 637
 638         // 5 GENTLE PULSE 1
 639         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 640
 641         // 6 FLICKER (second variety)
 642         lightstyle(6, "nmonqnmomnmomomno");
 643
 644         // 7 CANDLE (second variety)
 645         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 646
 647         // 8 CANDLE (third variety)
 648         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 649
 650         // 9 SLOW STROBE (fourth variety)
 651         lightstyle(9, "aaaaaaaazzzzzzzz");
 652
 653         // 10 FLUORESCENT FLICKER
 654         lightstyle(10, "mmamammmmammamamaaamammma");
 655
 656         // 11 SLOW PULSE NOT FADE TO BLACK
 657         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 658
 659         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 660
 661         // 63 testing
 662         lightstyle(63, "a");
 663
 664         if(autocvar_g_campaign)
 665                 CampaignPreInit();
 666
 667         Map_MarkAsRecent(mapname);
 668
 669         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 670
 671         precache_model ("null"); // we need this one before InitGameplayMode
 672         InitGameplayMode();
 673         readlevelcvars();
 674         GrappleHookInit();
 675
 676         player_count = 0;
 677         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 678         if(bot_waypoints_for_items == 1)
 679                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 680                         bot_waypoints_for_items = 0;
 681
 682         precache();
 683
 684         WaypointSprite_Init();
 685
 686         GameLogInit(); // prepare everything
 687         // NOTE for matchid:
 688         // changing the logic generating it is okay. But:
 689         // it HAS to stay <= 64 chars
 690         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 691         if(autocvar_sv_eventlog)
 692         {
 693                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 694                 matchid = strzone(s);
 695
 696                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 697                 s = ":gameinfo:mutators:LIST";
 698
 699                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 700                 s = ret_string;
 701
 702                 // simple, probably not good in the mutator system
 703                 if(autocvar_g_grappling_hook)
 704                         s = strcat(s, ":grappling_hook");
 705
 706                 // initialiation stuff, not good in the mutator system
 707                 if(!autocvar_g_use_ammunition)
 708                         s = strcat(s, ":no_use_ammunition");
 709
 710                 // initialiation stuff, not good in the mutator system
 711                 if(autocvar_g_pickup_items == 0)
 712                         s = strcat(s, ":no_pickup_items");
 713                 if(autocvar_g_pickup_items > 0)
 714                         s = strcat(s, ":pickup_items");
 715
 716                 // initialiation stuff, not good in the mutator system
 717                 if(autocvar_g_weaponarena != "0")
 718                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_norecoil)
 722                         s = strcat(s, ":norecoil");
 723
 724                 // TODO to mutator system
 725                 if(autocvar_g_powerups == 0)
 726                         s = strcat(s, ":no_powerups");
 727                 if(autocvar_g_powerups > 0)
 728                         s = strcat(s, ":powerups");
 729
 730                 GameLogEcho(s);
 731                 GameLogEcho(":gameinfo:end");
 732         }
 733         else
 734                 matchid = strzone(ftos(random()));
 735
 736         cvar_set("nextmap", "");
 737
 738         SetDefaultAlpha();
 739
 740         if(autocvar_g_campaign)
 741                 CampaignPostInit();
 742
 743         Ban_LoadBans();
 744
 745         MapInfo_Enumerate();
 746         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 747
 748         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 749         {
 750                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 751                 if(fd != -1)
 752                 {
 753                         while((s = fgets(fd)))
 754                         {
 755                                 l = tokenize_console(s);
 756                                 if(l < 2)
 757                                         continue;
 758                                 if(argv(0) == "cd")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  cdtrack ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) == "fog")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 766                                         print("  \"fog\" \"", s, "\"\n");
 767                                 }
 768                                 else if(argv(0) == "set")
 769                                 {
 770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 772                                 }
 773                                 else if(argv(0) != "//")
 774                                 {
 775                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 776                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 777                                 }
 778                         }
 779                         fclose(fd);
 780                 }
 781         }
 782
 783         WeaponStats_Init();
 784
 785         WepSet_AddStat();
 786         WepSet_AddStat_InMap();
 787         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 788         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 789         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 790         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 791         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 792         Nagger_Init();
 793
 794         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 795         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 796         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 797         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 798         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 799         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 800         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 801         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 802         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 803         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 804         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 805         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 806         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 807         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 808         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 809
 810         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 811         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 812
 813         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 814
 815         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 816
 817         // freeze attacks
 818         addstat(STAT_FROZEN, AS_INT, frozen);
 819         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 820
 821         // physics
 822         Physics_AddStats();
 823
 824         // new properties
 825         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 826         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 827         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 828         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 829         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 830         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 831         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 832         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 833         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 834         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 835         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 836         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 837         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 838         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 839         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 840         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 841         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 842         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 843         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 844
 845         // secrets
 846         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 847         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 848
 849         // monsters
 850         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 851         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 852
 853         // misc
 854         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 855
 856         next_pingtime = time + 5;
 857
 858         detect_maptype();
 859
 860         // set up information replies for clients and server to use
 861         maplist_reply = strzone(getmaplist());
 862         lsmaps_reply = strzone(getlsmaps());
 863         monsterlist_reply = strzone(getmonsterlist());
 864         for(int i = 0; i < 10; ++i)
 865         {
 866                 s = getrecords(i);
 867                 if (s)
 868                         records_reply[i] = strzone(s);
 869         }
 870         ladder_reply = strzone(getladder());
 871         rankings_reply = strzone(getrankings());
 872
 873         // begin other init
 874         ClientInit_Spawn();
 875         RandomSeed_Spawn();
 876         PingPLReport_Spawn();
 877
 878         CheatInit();
 879
 880         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 881
 882         // fill sv_curl_serverpackages from .serverpackage files
 883         if(autocvar_sv_curl_serverpackages_auto)
 884         {
 885                 s = "";
 886                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 887                 for(int i = 0; i < n; ++i)
 888                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 889                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 890                                 s = strcat(s, " ", argv(i));
 891                 fd = search_begin("*-serverpackage.txt", true, false);
 892                 if(fd >= 0)
 893                 {
 894                         j = search_getsize(fd);
 895                         for(int i = 0; i < j; ++i)
 896                                 s = strcat(s, " ", search_getfilename(fd, i));
 897                         search_end(fd);
 898                 }
 899                 fd = search_begin("*.serverpackage", true, false);
 900                 if(fd >= 0)
 901                 {
 902                         j = search_getsize(fd);
 903                         for(int i = 0; i < j; ++i)
 904                                 s = strcat(s, " ", search_getfilename(fd, i));
 905                         search_end(fd);
 906                 }
 907                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 908         }
 909
 910         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 911         modname = "Xonotic";
 912         // physics/balance/config changes that count as mod
 913         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 914                 modname = cvar_string("g_mod_physics");
 915         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 916                 modname = cvar_string("g_mod_balance");
 917         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 918                 modname = cvar_string("g_mod_config");
 919         // extra mutators that deserve to count as mod
 920         MUTATOR_CALLHOOK(SetModname);
 921
 922         // save it for later
 923         modname = strzone(modname);
 924
 925         WinningConditionHelper(); // set worldstatus
 926
 927         world_initialized = 1;
 928 }
 929
 930 void spawnfunc_light (void)
 931 {
 932         //makestatic (self); // Who the f___ did that?
 933         remove(self);
 934 }
 935
 936 string GetGametype()
 937 {
 938         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 939 }
 940
 941 string GetMapname()
 942 {
 943         return mapname;
 944 }
 945
 946 float Map_Count, Map_Current;
 947 string Map_Current_Name;
 948
 949 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 950 float GetMaplistPosition()
 951 {
 952         float pos, idx;
 953         string map;
 954
 955         map = GetMapname();
 956         idx = autocvar_g_maplist_index;
 957
 958         if(idx >= 0)
 959                 if(idx < Map_Count)
 960                         if(map == argv(idx))
 961                                 return idx;
 962
 963         for(pos = 0; pos < Map_Count; ++pos)
 964                 if(map == argv(pos))
 965                         return pos;
 966
 967         // resume normal maplist rotation if current map is not in g_maplist
 968         return idx;
 969 }
 970
 971 float MapHasRightSize(string map)
 972 {
 973         float fh;
 974         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 975         if(autocvar_g_maplist_check_waypoints)
 976         {
 977                 dprint("checkwp "); dprint(map);
 978                 if(!fexists(strcat("maps/", map, ".waypoints")))
 979                 {
 980                         dprint(": no waypoints\n");
 981                         return false;
 982                 }
 983                 dprint(": has waypoints\n");
 984         }
 985
 986         // open map size restriction file
 987         dprint("opensize "); dprint(map);
 988         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 989         if(fh >= 0)
 990         {
 991                 float mapmin, mapmax;
 992                 dprint(": ok, ");
 993                 mapmin = stof(fgets(fh));
 994                 mapmax = stof(fgets(fh));
 995                 fclose(fh);
 996                 if(player_count < mapmin)
 997                 {
 998                         dprint("not enough\n");
 999                         return false;
1000                 }
1001                 if(player_count > mapmax)
1002                 {
1003                         dprint("too many\n");
1004                         return false;
1005                 }
1006                 dprint("right size\n");
1007                 return true;
1008         }
1009         dprint(": not found\n");
1010         return true;
1011 }
1012
1013 string Map_Filename(float position)
1014 {
1015         return strcat("maps/", argv(position), ".bsp");
1016 }
1017
1018 string strwords(string s, float w)
1019 {
1020         float endpos;
1021         for(endpos = 0; w && endpos >= 0; --w)
1022                 endpos = strstrofs(s, " ", endpos + 1);
1023         if(endpos < 0)
1024                 return s;
1025         else
1026                 return substring(s, 0, endpos);
1027 }
1028
1029 float strhasword(string s, string w)
1030 {
1031         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1032 }
1033
1034 void Map_MarkAsRecent(string m)
1035 {
1036         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1037 }
1038
1039 float Map_IsRecent(string m)
1040 {
1041         return strhasword(autocvar_g_maplist_mostrecent, m);
1042 }
1043
1044 float Map_Check(float position, float pass)
1045 {
1046         string filename;
1047         string map_next;
1048         map_next = argv(position);
1049         if(pass <= 1)
1050         {
1051                 if(Map_IsRecent(map_next))
1052                         return 0;
1053         }
1054         filename = Map_Filename(position);
1055         if(MapInfo_CheckMap(map_next))
1056         {
1057                 if(pass == 2)
1058                         return 1;
1059                 if(MapHasRightSize(map_next))
1060                         return 1;
1061                 return 0;
1062         }
1063         else
1064                 dprint( "Couldn't select '", filename, "'..\n" );
1065
1066         return 0;
1067 }
1068
1069 void Map_Goto_SetStr(string nextmapname)
1070 {
1071         if(getmapname_stored != "")
1072                 strunzone(getmapname_stored);
1073         if(nextmapname == "")
1074                 getmapname_stored = "";
1075         else
1076                 getmapname_stored = strzone(nextmapname);
1077 }
1078
1079 void Map_Goto_SetFloat(float position)
1080 {
1081         cvar_set("g_maplist_index", ftos(position));
1082         Map_Goto_SetStr(argv(position));
1083 }
1084
1085 void Map_Goto(float reinit)
1086 {
1087         MapInfo_LoadMap(getmapname_stored, reinit);
1088 }
1089
1090 // return codes of map selectors:
1091 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1092 //   -2 = permanent failure
1093 float() MaplistMethod_Iterate = // usual method
1094 {
1095         float pass, i;
1096
1097         dprint("Trying MaplistMethod_Iterate\n");
1098
1099         for(pass = 1; pass <= 2; ++pass)
1100         {
1101                 for(i = 1; i < Map_Count; ++i)
1102                 {
1103                         float mapindex;
1104                         mapindex = (i + Map_Current) % Map_Count;
1105                         if(Map_Check(mapindex, pass))
1106                                 return mapindex;
1107                 }
1108         }
1109         return -1;
1110 }
1111
1112 float() MaplistMethod_Repeat = // fallback method
1113 {
1114         dprint("Trying MaplistMethod_Repeat\n");
1115
1116         if(Map_Check(Map_Current, 2))
1117                 return Map_Current;
1118         return -2;
1119 }
1120
1121 float() MaplistMethod_Random = // random map selection
1122 {
1123         float i, imax;
1124
1125         dprint("Trying MaplistMethod_Random\n");
1126
1127         imax = 42;
1128
1129         for(i = 0; i <= imax; ++i)
1130         {
1131                 float mapindex;
1132                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1133                 if(Map_Check(mapindex, 1))
1134                         return mapindex;
1135         }
1136         return -1;
1137 }
1138
1139 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1140 // the exponent sets a bias on the map selection:
1141 // the higher the exponent, the less likely "shortly repeated" same maps are
1142 {
1143         float i, j, imax, insertpos;
1144
1145         dprint("Trying MaplistMethod_Shuffle\n");
1146
1147         imax = 42;
1148
1149         for(i = 0; i <= imax; ++i)
1150         {
1151                 string newlist;
1152
1153                 // now reinsert this at another position
1154                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1155                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1156                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1157                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1158
1159                 // insert the current map there
1160                 newlist = "";
1161                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1162                         newlist = strcat(newlist, " ", argv(j));
1163                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1164                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1165                         newlist = strcat(newlist, " ", argv(j));
1166                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1167                 cvar_set("g_maplist", newlist);
1168                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1169
1170                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1171                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1172                 if(Map_Check(Map_Current, 1))
1173                         return Map_Current;
1174         }
1175         return -1;
1176 }
1177
1178 void Maplist_Init()
1179 {
1180         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1181         float i;
1182         for (i = 0; i < Map_Count; ++i)
1183                 if (Map_Check(i, 2))
1184                         break;
1185         if (i == Map_Count)
1186         {
1187                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1188                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1189                 if(autocvar_g_maplist_shuffle)
1190                         ShuffleMaplist();
1191                 localcmd("\nmenu_cmd sync\n");
1192                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193         }
1194         if(Map_Count == 0)
1195                 error("empty maplist, cannot select a new map");
1196         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1197
1198         if(Map_Current_Name)
1199                 strunzone(Map_Current_Name);
1200         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1201         // this may or may not be correct, but who cares, in the worst case a map
1202         // isn't chosen in the first pass that should have been
1203 }
1204
1205 string GetNextMap()
1206 {
1207         float nextMap;
1208
1209         Maplist_Init();
1210         nextMap = -1;
1211
1212         if(nextMap == -1)
1213                 if(autocvar_g_maplist_shuffle > 0)
1214                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1215
1216         if(nextMap == -1)
1217                 if(autocvar_g_maplist_selectrandom)
1218                         nextMap = MaplistMethod_Random();
1219
1220         if(nextMap == -1)
1221                 nextMap = MaplistMethod_Iterate();
1222
1223         if(nextMap == -1)
1224                 nextMap = MaplistMethod_Repeat();
1225
1226         if(nextMap >= 0)
1227         {
1228                 Map_Goto_SetFloat(nextMap);
1229                 return getmapname_stored;
1230         }
1231
1232         return "";
1233 }
1234
1235 float DoNextMapOverride(float reinit)
1236 {
1237         if(autocvar_g_campaign)
1238         {
1239                 CampaignPostIntermission();
1240                 alreadychangedlevel = true;
1241                 return true;
1242         }
1243         if(autocvar_quit_when_empty)
1244         {
1245                 if(player_count <= currentbots)
1246                 {
1247                         localcmd("quit\n");
1248                         alreadychangedlevel = true;
1249                         return true;
1250                 }
1251         }
1252         if(autocvar_quit_and_redirect != "")
1253         {
1254                 redirection_target = strzone(autocvar_quit_and_redirect);
1255                 alreadychangedlevel = true;
1256                 return true;
1257         }
1258         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1259         {
1260                 localcmd("restart\n");
1261                 alreadychangedlevel = true;
1262                 return true;
1263         }
1264         if(autocvar_nextmap != "")
1265         {
1266                 string m;
1267                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1268                 cvar_set("nextmap",m);
1269
1270                 if(!m || gametypevote)
1271                         return false;
1272                 if(autocvar_sv_vote_gametype)
1273                 {
1274                         Map_Goto_SetStr(m);
1275                         return false;
1276                 }
1277
1278                 if(MapInfo_CheckMap(m))
1279                 {
1280                         Map_Goto_SetStr(m);
1281                         Map_Goto(reinit);
1282                         alreadychangedlevel = true;
1283                         return true;
1284                 }
1285         }
1286         if(!reinit && autocvar_lastlevel)
1287         {
1288                 cvar_settemp_restore();
1289                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1290                 alreadychangedlevel = true;
1291                 return true;
1292         }
1293         return false;
1294 }
1295
1296 void GotoNextMap(float reinit)
1297 {
1298         //string nextmap;
1299         //float n, nummaps;
1300         //string s;
1301         if (alreadychangedlevel)
1302                 return;
1303         alreadychangedlevel = true;
1304
1305         string nextMap;
1306
1307         nextMap = GetNextMap();
1308         if(nextMap == "")
1309                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1310         Map_Goto(reinit);
1311 }
1312
1313
1314 /*
1315 ============
1316 IntermissionThink
1317
1318 When the player presses attack or jump, change to the next level
1319 ============
1320 */
1321 .float autoscreenshot;
1322 void IntermissionThink()
1323 {
1324         FixIntermissionClient(self);
1325
1326         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1327         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1328
1329         if( (server_screenshot || client_screenshot)
1330                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1331         {
1332                 self.autoscreenshot = -1;
1333                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1334                 return;
1335         }
1336
1337         if (time < intermission_exittime)
1338                 return;
1339
1340         if(!mapvote_initialized)
1341                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1342                         return;
1343
1344         MapVote_Start();
1345 }
1346
1347 /*
1348 ============
1349 FindIntermission
1350
1351 Returns the entity to view from
1352 ============
1353 */
1354 /*
1355 entity FindIntermission()
1356 {
1357         local   entity spot;
1358         local   float cyc;
1359
1360 // look for info_intermission first
1361         spot = find (world, classname, "info_intermission");
1362         if (spot)
1363         {       // pick a random one
1364                 cyc = random() * 4;
1365                 while (cyc > 1)
1366                 {
1367                         spot = find (spot, classname, "info_intermission");
1368                         if (!spot)
1369                                 spot = find (spot, classname, "info_intermission");
1370                         cyc = cyc - 1;
1371                 }
1372                 return spot;
1373         }
1374
1375 // then look for the start position
1376         spot = find (world, classname, "info_player_start");
1377         if (spot)
1378                 return spot;
1379
1380 // testinfo_player_start is only found in regioned levels
1381         spot = find (world, classname, "testplayerstart");
1382         if (spot)
1383                 return spot;
1384
1385 // then look for the start position
1386         spot = find (world, classname, "info_player_deathmatch");
1387         if (spot)
1388                 return spot;
1389
1390         //objerror ("FindIntermission: no spot");
1391         return world;
1392 }
1393 */
1394
1395 /*
1396 ===============================================================================
1397
1398 RULES
1399
1400 ===============================================================================
1401 */
1402
1403 void DumpStats(float final)
1404 {
1405         float file;
1406         string s;
1407         float to_console;
1408         float to_eventlog;
1409         float to_file;
1410         float i;
1411
1412         to_console = autocvar_sv_logscores_console;
1413         to_eventlog = autocvar_sv_eventlog;
1414         to_file = autocvar_sv_logscores_file;
1415
1416         if(!final)
1417         {
1418                 to_console = true; // always print printstats replies
1419                 to_eventlog = false; // but never print them to the event log
1420         }
1421
1422         if(to_eventlog)
1423                 if(autocvar_sv_eventlog_console)
1424                         to_console = false; // otherwise we get the output twice
1425
1426         if(final)
1427                 s = ":scores:";
1428         else
1429                 s = ":status:";
1430         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1431
1432         if(to_console)
1433                 print(s, "\n");
1434         if(to_eventlog)
1435                 GameLogEcho(s);
1436
1437         file = -1;
1438         if(to_file)
1439         {
1440                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1441                 if(file == -1)
1442                         to_file = false;
1443                 else
1444                         fputs(file, strcat(s, "\n"));
1445         }
1446
1447         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1448         if(to_console)
1449                 print(s, "\n");
1450         if(to_eventlog)
1451                 GameLogEcho(s);
1452         if(to_file)
1453                 fputs(file, strcat(s, "\n"));
1454
1455         FOR_EACH_CLIENT(other)
1456         {
1457                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1458                 {
1459                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1460                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1461                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1462                                 s = strcat(s, ftos(other.team), ":");
1463                         else
1464                                 s = strcat(s, "spectator:");
1465
1466                         if(to_console)
1467                                 print(s, other.netname, "\n");
1468                         if(to_eventlog)
1469                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1470                         if(to_file)
1471                                 fputs(file, strcat(s, other.netname, "\n"));
1472                 }
1473         }
1474
1475         if(teamplay)
1476         {
1477                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1478                 if(to_console)
1479                         print(s, "\n");
1480                 if(to_eventlog)
1481                         GameLogEcho(s);
1482                 if(to_file)
1483                         fputs(file, strcat(s, "\n"));
1484
1485                 for(i = 1; i < 16; ++i)
1486                 {
1487                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1488                         s = strcat(s, ":", ftos(i));
1489                         if(to_console)
1490                                 print(s, "\n");
1491                         if(to_eventlog)
1492                                 GameLogEcho(s);
1493                         if(to_file)
1494                                 fputs(file, strcat(s, "\n"));
1495                 }
1496         }
1497
1498         if(to_console)
1499                 print(":end\n");
1500         if(to_eventlog)
1501                 GameLogEcho(":end");
1502         if(to_file)
1503         {
1504                 fputs(file, ":end\n");
1505                 fclose(file);
1506         }
1507 }
1508
1509 void FixIntermissionClient(entity e)
1510 {
1511         string s;
1512         if(!e.autoscreenshot) // initial call
1513         {
1514                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1515                 e.health = -2342;
1516                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1517                 e.solid = SOLID_NOT;
1518                 e.movetype = MOVETYPE_NONE;
1519                 e.takedamage = DAMAGE_NO;
1520                 if(e.weaponentity)
1521                 {
1522                         e.weaponentity.effects = EF_NODRAW;
1523                         if (e.weaponentity.weaponentity)
1524                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1525                 }
1526                 if(IS_REAL_CLIENT(e))
1527                 {
1528                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1529                         s = autocvar_sv_intermission_cdtrack;
1530                         if(s != "")
1531                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1532                         msg_entity = e;
1533                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1534                 }
1535         }
1536 }
1537
1538 /*
1539 go to the next level for deathmatch
1540 only called if a time or frag limit has expired
1541 */
1542 void NextLevel()
1543 {
1544         gameover = true;
1545
1546         intermission_running = 1;
1547
1548 // enforce a wait time before allowing changelevel
1549         if(player_count > 0)
1550                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1551         else
1552                 intermission_exittime = -1;
1553
1554         /*
1555         WriteByte (MSG_ALL, SVC_CDTRACK);
1556         WriteByte (MSG_ALL, 3);
1557         WriteByte (MSG_ALL, 3);
1558         // done in FixIntermission
1559         */
1560
1561         //pos = FindIntermission ();
1562
1563         VoteReset();
1564
1565         DumpStats(true);
1566
1567         // send statistics
1568         PlayerStats_GameReport(true);
1569         WeaponStats_Shutdown();
1570
1571         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1572
1573         if(autocvar_sv_eventlog)
1574                 GameLogEcho(":gameover");
1575
1576         GameLogClose();
1577
1578         FOR_EACH_PLAYER(other) {
1579                 FixIntermissionClient(other);
1580                 if(other.winning)
1581                         bprint(other.netname, " ^7wins.\n");
1582         }
1583
1584         if(autocvar_g_campaign)
1585                 CampaignPreIntermission();
1586
1587         MUTATOR_CALLHOOK(MatchEnd);
1588
1589         localcmd("\nsv_hook_gameend\n");
1590 }
1591
1592 /*
1593 ============
1594 CheckRules_Player
1595
1596 Exit deathmatch games upon conditions
1597 ============
1598 */
1599 void CheckRules_Player()
1600 {
1601         if (gameover)   // someone else quit the game already
1602                 return;
1603
1604         if(self.deadflag == DEAD_NO)
1605                 self.play_time += frametime;
1606
1607         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1608         //   (div0: and that in CheckRules_World please)
1609 }
1610
1611
1612 float InitiateSuddenDeath()
1613 {
1614         // Check first whether normal overtimes could be added before initiating suddendeath mode
1615         // - for this timelimit_overtime needs to be >0 of course
1616         // - also check the winning condition calculated in the previous frame and only add normal overtime
1617         //   again, if at the point at which timelimit would be extended again, still no winner was found
1618         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1619         {
1620                 return 1; // need to call InitiateOvertime later
1621         }
1622         else
1623         {
1624                 if(!checkrules_suddendeathend)
1625                 {
1626                         if(autocvar_g_campaign)
1627                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1628                         else
1629                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1630                         if(g_race && !g_race_qualifying)
1631                                 race_StartCompleting();
1632                 }
1633                 return 0;
1634         }
1635 }
1636
1637 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1638 {
1639         ++checkrules_overtimesadded;
1640         //add one more overtime by simply extending the timelimit
1641         float tl;
1642         tl = autocvar_timelimit;
1643         tl += autocvar_timelimit_overtime;
1644         cvar_set("timelimit", ftos(tl));
1645
1646         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1647 }
1648
1649 float GetWinningCode(float fraglimitreached, float equality)
1650 {
1651         if(autocvar_g_campaign == 1)
1652                 if(fraglimitreached)
1653                         return WINNING_YES;
1654                 else
1655                         return WINNING_NO;
1656
1657         else
1658                 if(equality)
1659                         if(fraglimitreached)
1660                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1661                         else
1662                                 return WINNING_NEVER;
1663                 else
1664                         if(fraglimitreached)
1665                                 return WINNING_YES;
1666                         else
1667                                 return WINNING_NO;
1668 }
1669
1670 // set the .winning flag for exactly those players with a given field value
1671 void SetWinners(.float field, float value)
1672 {
1673         entity head;
1674         FOR_EACH_PLAYER(head)
1675                 head.winning = (head.(field) == value);
1676 }
1677
1678 // set the .winning flag for those players with a given field value
1679 void AddWinners(.float field, float value)
1680 {
1681         entity head;
1682         FOR_EACH_PLAYER(head)
1683                 if (head.(field) == value)
1684                         head.winning = 1;
1685 }
1686
1687 // clear the .winning flags
1688 void ClearWinners(void)
1689 {
1690         entity head;
1691         FOR_EACH_PLAYER(head)
1692                 head.winning = 0;
1693 }
1694
1695 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1696 // they win. Otherwise the defending team wins once the timelimit passes.
1697 void assault_new_round();
1698 float WinningCondition_Assault()
1699 {
1700         float status;
1701
1702         WinningConditionHelper(); // set worldstatus
1703
1704         status = WINNING_NO;
1705         // as the timelimit has not yet passed just assume the defending team will win
1706         if(assault_attacker_team == NUM_TEAM_1)
1707         {
1708                 SetWinners(team, NUM_TEAM_2);
1709         }
1710         else
1711         {
1712                 SetWinners(team, NUM_TEAM_1);
1713         }
1714
1715         entity ent;
1716         ent = find(world, classname, "target_assault_roundend");
1717         if(ent)
1718         {
1719                 if(ent.winning) // round end has been triggered by attacking team
1720                 {
1721                         bprint("ASSAULT: round completed...\n");
1722                         SetWinners(team, assault_attacker_team);
1723
1724                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1725
1726                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1727                         {
1728                                 status = WINNING_YES;
1729                         }
1730                         else
1731                         {
1732                                 entity oldself;
1733                                 oldself = self;
1734                                 self = ent;
1735                                 assault_new_round();
1736                                 self = oldself;
1737                         }
1738                 }
1739         }
1740
1741         return status;
1742 }
1743
1744 // LMS winning condition: game terminates if and only if there's at most one
1745 // one player who's living lives. Top two scores being equal cancels the time
1746 // limit.
1747 float WinningCondition_LMS()
1748 {
1749         entity head, head2;
1750         float have_player;
1751         float have_players;
1752         float l;
1753
1754         have_player = false;
1755         have_players = false;
1756         l = LMS_NewPlayerLives();
1757
1758         head = find(world, classname, "player");
1759         if(head)
1760                 have_player = true;
1761         head2 = find(head, classname, "player");
1762         if(head2)
1763                 have_players = true;
1764
1765         if(have_player)
1766         {
1767                 // we have at least one player
1768                 if(have_players)
1769                 {
1770                         // two or more active players - continue with the game
1771                 }
1772                 else
1773                 {
1774                         // exactly one player?
1775
1776                         ClearWinners();
1777                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1778
1779                         if(l)
1780                         {
1781                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1782                                 return WINNING_NO;
1783                         }
1784                         else
1785                         {
1786                                 // a winner!
1787                                 // and assign him his first place
1788                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1789                                 return WINNING_YES;
1790                         }
1791                 }
1792         }
1793         else
1794         {
1795                 // nobody is playing at all...
1796                 if(l)
1797                 {
1798                         // wait for players...
1799                 }
1800                 else
1801                 {
1802                         // SNAFU (maybe a draw game?)
1803                         ClearWinners();
1804                         dprint("No players, ending game.\n");
1805                         return WINNING_YES;
1806                 }
1807         }
1808
1809         // When we get here, we have at least two players who are actually LIVING,
1810         // now check if the top two players have equal score.
1811         WinningConditionHelper();
1812
1813         ClearWinners();
1814         if(WinningConditionHelper_winner)
1815                 WinningConditionHelper_winner.winning = true;
1816         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1817                 return WINNING_NEVER;
1818
1819         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1820         return WINNING_NO;
1821 }
1822
1823 void ShuffleMaplist()
1824 {
1825         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1826 }
1827
1828 float leaderfrags;
1829 float WinningCondition_Scores(float limit, float leadlimit)
1830 {
1831         float limitreached;
1832
1833         // TODO make everything use THIS winning condition (except LMS)
1834         WinningConditionHelper();
1835
1836         if(teamplay)
1837         {
1838                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1839                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1840                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1841                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1842         }
1843
1844         ClearWinners();
1845         if(WinningConditionHelper_winner)
1846                 WinningConditionHelper_winner.winning = 1;
1847         if(WinningConditionHelper_winnerteam >= 0)
1848                 SetWinners(team, WinningConditionHelper_winnerteam);
1849
1850         if(WinningConditionHelper_lowerisbetter)
1851         {
1852                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1853                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1854                 limit = -limit;
1855         }
1856
1857         if(WinningConditionHelper_zeroisworst)
1858                 leadlimit = 0; // not supported in this mode
1859
1860         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1861         // these modes always score in increments of 1, thus this makes sense
1862         {
1863                 if(leaderfrags != WinningConditionHelper_topscore)
1864                 {
1865                         leaderfrags = WinningConditionHelper_topscore;
1866
1867                         if (limit)
1868                         if (leaderfrags == limit - 1)
1869                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1870                         else if (leaderfrags == limit - 2)
1871                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1872                         else if (leaderfrags == limit - 3)
1873                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1874                 }
1875         }
1876
1877         limitreached = false;
1878         if(limit)
1879                 if(WinningConditionHelper_topscore >= limit)
1880                         limitreached = true;
1881         if(leadlimit)
1882         {
1883                 float leadlimitreached;
1884                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1885                 if(autocvar_leadlimit_and_fraglimit)
1886                         limitreached = (limitreached && leadlimitreached);
1887                 else
1888                         limitreached = (limitreached || leadlimitreached);
1889         }
1890
1891         if(limit)
1892                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1893
1894         return GetWinningCode(
1895                 WinningConditionHelper_topscore && limitreached,
1896                 WinningConditionHelper_equality
1897         );
1898 }
1899
1900 float WinningCondition_Race(float fraglimit)
1901 {
1902         float wc;
1903         entity p;
1904         float n, c;
1905
1906         n = 0;
1907         c = 0;
1908         FOR_EACH_PLAYER(p)
1909         {
1910                 ++n;
1911                 if(p.race_completed)
1912                         ++c;
1913         }
1914         if(n && (n == c))
1915                 return WINNING_YES;
1916         wc = WinningCondition_Scores(fraglimit, 0);
1917
1918         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1919         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1920         // do NOT support equality when the laps are all raced!
1921                 return WINNING_STARTSUDDENDEATHOVERTIME;
1922         else
1923                 return WINNING_NEVER;
1924 }
1925
1926 float WinningCondition_QualifyingThenRace(float limit)
1927 {
1928         float wc;
1929         wc = WinningCondition_Scores(limit, 0);
1930
1931         // NEVER initiate overtime
1932         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1933         {
1934                 return WINNING_YES;
1935         }
1936
1937         return wc;
1938 }
1939
1940 float WinningCondition_RanOutOfSpawns()
1941 {
1942         entity head;
1943
1944         if(have_team_spawns <= 0)
1945                 return WINNING_NO;
1946
1947         if(!autocvar_g_spawn_useallspawns)
1948                 return WINNING_NO;
1949
1950         if(!some_spawn_has_been_used)
1951                 return WINNING_NO;
1952
1953         team1_score = team2_score = team3_score = team4_score = 0;
1954
1955         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1956         {
1957                 if(head.team == NUM_TEAM_1)
1958                         team1_score = 1;
1959                 else if(head.team == NUM_TEAM_2)
1960                         team2_score = 1;
1961                 else if(head.team == NUM_TEAM_3)
1962                         team3_score = 1;
1963                 else if(head.team == NUM_TEAM_4)
1964                         team4_score = 1;
1965         }
1966
1967         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1968         {
1969                 if(head.team == NUM_TEAM_1)
1970                         team1_score = 1;
1971                 else if(head.team == NUM_TEAM_2)
1972                         team2_score = 1;
1973                 else if(head.team == NUM_TEAM_3)
1974                         team3_score = 1;
1975                 else if(head.team == NUM_TEAM_4)
1976                         team4_score = 1;
1977         }
1978
1979         ClearWinners();
1980         if(team1_score + team2_score + team3_score + team4_score == 0)
1981         {
1982                 checkrules_equality = true;
1983                 return WINNING_YES;
1984         }
1985         else if(team1_score + team2_score + team3_score + team4_score == 1)
1986         {
1987                 float t, i;
1988                 if(team1_score)
1989                         t = NUM_TEAM_1;
1990                 else if(team2_score)
1991                         t = NUM_TEAM_2;
1992                 else if(team3_score)
1993                         t = NUM_TEAM_3;
1994                 else // if(team4_score)
1995                         t = NUM_TEAM_4;
1996                 CheckAllowedTeams(world);
1997                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1998                 {
1999                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2000                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2001                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2002                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2003                 }
2004
2005                 AddWinners(team, t);
2006                 return WINNING_YES;
2007         }
2008         else
2009                 return WINNING_NO;
2010 }
2011
2012 /*
2013 ============
2014 CheckRules_World
2015
2016 Exit deathmatch games upon conditions
2017 ============
2018 */
2019 void CheckRules_World()
2020 {
2021         float timelimit;
2022         float fraglimit;
2023         float leadlimit;
2024
2025         VoteThink();
2026         MapVote_Think();
2027
2028         SetDefaultAlpha();
2029
2030         if (gameover)   // someone else quit the game already
2031         {
2032                 if(player_count == 0) // Nobody there? Then let's go to the next map
2033                         MapVote_Start();
2034                         // this will actually check the player count in the next frame
2035                         // again, but this shouldn't hurt
2036                 return;
2037         }
2038
2039         timelimit = autocvar_timelimit * 60;
2040         fraglimit = autocvar_fraglimit;
2041         leadlimit = autocvar_leadlimit;
2042
2043         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2044         {
2045                 if(timelimit > 0)
2046                         timelimit = 0; // timelimit is not made for warmup
2047                 if(fraglimit > 0)
2048                         fraglimit = 0; // no fraglimit for now
2049                 leadlimit = 0; // no leadlimit for now
2050         }
2051
2052         if(timelimit > 0)
2053         {
2054                 timelimit += game_starttime;
2055         }
2056         else if (timelimit < 0)
2057         {
2058                 // endmatch
2059                 NextLevel();
2060                 return;
2061         }
2062
2063         float wantovertime;
2064         wantovertime = 0;
2065
2066         if(timelimit > game_starttime)
2067                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2068         else
2069                 game_completion_ratio = 0;
2070
2071         if(checkrules_suddendeathend)
2072         {
2073                 if(!checkrules_suddendeathwarning)
2074                 {
2075                         checkrules_suddendeathwarning = true;
2076                         if(g_race && !g_race_qualifying)
2077                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2078                         else
2079                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2080                 }
2081         }
2082         else
2083         {
2084                 if (timelimit && time >= timelimit)
2085                 {
2086                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2087                         {
2088                                 float totalplayers;
2089                                 float playerswithlaps;
2090                                 float readyplayers;
2091                                 entity head;
2092                                 totalplayers = playerswithlaps = readyplayers = 0;
2093                                 FOR_EACH_PLAYER(head)
2094                                 {
2095                                         ++totalplayers;
2096                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2097                                                 ++playerswithlaps;
2098                                         if(head.ready)
2099                                                 ++readyplayers;
2100                                 }
2101
2102                                 // at least 2 of the players have completed a lap: start the RACE
2103                                 // otherwise, the players should end the qualifying on their own
2104                                 if(readyplayers || playerswithlaps >= 2)
2105                                 {
2106                                         checkrules_suddendeathend = 0;
2107                                         ReadyRestart(); // go to race
2108                                         return;
2109                                 }
2110                                 else
2111                                         wantovertime |= InitiateSuddenDeath();
2112                         }
2113                         else
2114                                 wantovertime |= InitiateSuddenDeath();
2115                 }
2116         }
2117
2118         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2119         {
2120                 NextLevel();
2121                 return;
2122         }
2123
2124         float checkrules_status;
2125         checkrules_status = WinningCondition_RanOutOfSpawns();
2126         if(checkrules_status == WINNING_YES)
2127         {
2128                 bprint("Hey! Someone ran out of spawns!\n");
2129         }
2130         else if(g_race && !g_race_qualifying && timelimit >= 0)
2131         {
2132                 checkrules_status = WinningCondition_Race(fraglimit);
2133                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2134         }
2135         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2136         {
2137                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2138                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2139         }
2140         else if(g_assault)
2141         {
2142                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2143         }
2144         else if(g_lms)
2145         {
2146                 checkrules_status = WinningCondition_LMS();
2147         }
2148         else
2149         {
2150                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2151                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2152         }
2153
2154         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2155         {
2156                 checkrules_status = WINNING_NEVER;
2157                 checkrules_overtimesadded = -1;
2158                 wantovertime |= InitiateSuddenDeath();
2159         }
2160
2161         if(checkrules_status == WINNING_NEVER)
2162                 // equality cases! Nobody wins if the overtime ends in a draw.
2163                 ClearWinners();
2164
2165         if(wantovertime)
2166         {
2167                 if(checkrules_status == WINNING_NEVER)
2168                         InitiateOvertime();
2169                 else
2170                         checkrules_status = WINNING_YES;
2171         }
2172
2173         if(checkrules_suddendeathend)
2174                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2175                         checkrules_status = WINNING_YES;
2176
2177         if(checkrules_status == WINNING_YES)
2178         {
2179                 //print("WINNING\n");
2180                 NextLevel();
2181         }
2182 }
2183
2184 string GotoMap(string m)
2185 {
2186         m = GameTypeVote_MapInfo_FixName(m);
2187         if (!m)
2188                 return "The map you suggested is not available on this server.";
2189         if (!autocvar_sv_vote_gametype)
2190         if(!MapInfo_CheckMap(m))
2191                 return "The map you suggested does not support the current game mode.";
2192         cvar_set("nextmap", m);
2193         cvar_set("timelimit", "-1");
2194         if(mapvote_initialized || alreadychangedlevel)
2195         {
2196                 if(DoNextMapOverride(0))
2197                         return "Map switch initiated.";
2198                 else
2199                         return "Hm... no. For some reason I like THIS map more.";
2200         }
2201         else
2202                 return "Map switch will happen after scoreboard.";
2203 }
2204
2205
2206 void EndFrame()
2207 {
2208         anticheat_endframe();
2209
2210         float altime;
2211         FOR_EACH_REALCLIENT(self)
2212         {
2213                 entity e = IS_SPEC(self) ? self.enemy : self;
2214                 if(e.typehitsound)
2215                         self.typehit_time = time;
2216                 else if(e.damage_dealt)
2217                 {
2218                         self.hit_time = time;
2219                         self.damage_dealt_total += ceil(e.damage_dealt);
2220                 }
2221         }
2222         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2223         // add 1 frametime because after this, engine SV_Physics
2224         // increases time by a frametime and then networks the frame
2225         // add another frametime because client shows everything with
2226         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2227         // needed!
2228         FOR_EACH_CLIENT(self)
2229         {
2230                 self.typehitsound = false;
2231                 self.damage_dealt = 0;
2232                 antilag_record(self, altime);
2233         }
2234         FOR_EACH_MONSTER(self)
2235                 antilag_record(self, altime);
2236 }
2237
2238
2239 /*
2240  * RedirectionThink:
2241  * returns true if redirecting
2242  */
2243 float redirection_timeout;
2244 float redirection_nextthink;
2245 float RedirectionThink()
2246 {
2247         float clients_found;
2248
2249         if(redirection_target == "")
2250                 return false;
2251
2252         if(!redirection_timeout)
2253         {
2254                 cvar_set("sv_public", "-2");
2255                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2256                 if(redirection_target == "self")
2257                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2258                 else
2259                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2260         }
2261
2262         if(time < redirection_nextthink)
2263                 return true;
2264
2265         redirection_nextthink = time + 1;
2266
2267         clients_found = 0;
2268         FOR_EACH_REALCLIENT(self)
2269         {
2270                 // TODO add timer
2271                 print("Redirecting: sending connect command to ", self.netname, "\n");
2272                 if(redirection_target == "self")
2273                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2274                 else
2275                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2276                 ++clients_found;
2277         }
2278
2279         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2280
2281         if(time > redirection_timeout || clients_found == 0)
2282                 localcmd("\nwait; wait; wait; quit\n");
2283
2284         return true;
2285 }
2286
2287 void TargetMusic_RestoreGame();
2288 void RestoreGame()
2289 {
2290         // Loaded from a save game
2291         // some things then break, so let's work around them...
2292
2293         // Progs DB (capture records)
2294         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2295
2296         // Mapinfo
2297         MapInfo_Shutdown();
2298         MapInfo_Enumerate();
2299         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2300         WeaponStats_Init();
2301
2302         TargetMusic_RestoreGame();
2303 }
2304
2305 void Shutdown()
2306 {
2307         gameover = 2;
2308
2309         if(world_initialized > 0)
2310         {
2311                 world_initialized = 0;
2312                 print("Saving persistent data...\n");
2313                 Ban_SaveBans();
2314
2315                 // playerstats with unfinished match
2316                 PlayerStats_GameReport(false);
2317
2318                 if(!cheatcount_total)
2319                 {
2320                         if(autocvar_sv_db_saveasdump)
2321                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2322                         else
2323                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2324                 }
2325                 if(autocvar_developer)
2326                 {
2327                         if(autocvar_sv_db_saveasdump)
2328                                 db_dump(TemporaryDB, "server-temp.db");
2329                         else
2330                                 db_save(TemporaryDB, "server-temp.db");
2331                 }
2332                 CheatShutdown(); // must be after cheatcount check
2333                 db_close(ServerProgsDB);
2334                 db_close(TemporaryDB);
2335                 print("done!\n");
2336                 // tell the bot system the game is ending now
2337                 bot_endgame();
2338
2339                 WeaponStats_Shutdown();
2340                 MapInfo_Shutdown();
2341         }
2342         else if(world_initialized == 0)
2343         {
2344                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2345         }
2346 }