qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431
 432                 if(autocvar_g_minstagib)
 433                 {
 434                         BADCVAR("g_grappling_hook");
 435                         BADCVAR("g_jetpack");
 436                 }
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for(;;)
 477         {
 478                 o = world.mins;
 479                 o_x += random() * (world.maxs_x - world.mins_x);
 480                 o_y += random() * (world.maxs_y - world.mins_y);
 481                 o_z += random() * (world.maxs_z - world.mins_z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 float RandomSeed_Send(entity to, float sf)
 504 {
 505         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return TRUE;
 508 }
 509 void RandomSeed_Think()
 510 {
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {
 518         randomseed = spawn();
 519         randomseed.think = RandomSeed_Think;
 520         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 521
 522         entity oldself;
 523         oldself = self;
 524         self = randomseed;
 525         self.think(); // sets random seed and nextthink
 526         self = oldself;
 527 }
 528
 529 void spawnfunc___init_dedicated_server(void)
 530 {
 531         // handler for _init/_init map (only for dedicated server initialization)
 532
 533         world_initialized = -1; // don't complain
 534         cvar = cvar_normal;
 535         cvar_string = cvar_string_normal;
 536         cvar_set = cvar_set_normal;
 537
 538         remove = remove_unsafely;
 539
 540         entity e;
 541         e = spawn();
 542         e.think = GotoFirstMap;
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = spawn();
 546         e.classname = "info_player_deathmatch"; // safeguard against player joining
 547
 548         self.classname = "worldspawn"; // safeguard against various stuff ;)
 549
 550         // needs to be done so early because of the constants they create
 551         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 552         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 553         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 554         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 555
 556         MapInfo_Enumerate();
 557         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 558 }
 559
 560 void Map_MarkAsRecent(string m);
 561 float world_already_spawned;
 562 void Nagger_Init();
 563 void ClientInit_Spawn();
 564 void WeaponStats_Init();
 565 void WeaponStats_Shutdown();
 566 void spawnfunc_worldspawn (void)
 567 {
 568         float fd, l, i, j, n;
 569         string s, col;
 570
 571         cvar = cvar_normal;
 572         cvar_string = cvar_string_normal;
 573         cvar_set = cvar_set_normal;
 574
 575         if(world_already_spawned)
 576                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 577         world_already_spawned = TRUE;
 578
 579         remove = remove_safely; // during spawning, watch what you remove!
 580
 581         check_unacceptable_compiler_bugs();
 582
 583         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 584
 585         compressShortVector_init();
 586
 587         entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 597
 598         // needs to be done so early because of the constants they create
 599         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 600         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 601         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 602         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 788         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 789         Nagger_Init();
 790
 791         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 792         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 793         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 794         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 795         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 796         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 797         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 798         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 799         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 800         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 801         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 802         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 803         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 804
 805         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 806         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 807
 808         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         // misc
 821         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 822
 823         next_pingtime = time + 5;
 824
 825         detect_maptype();
 826
 827         // set up information replies for clients and server to use
 828         lsmaps_reply = "^7Maps available: ";
 829         lsnewmaps_reply = "^7Maps without a record set: ";
 830         for(i = 0, j = 0; i < MapInfo_count; ++i)
 831         {
 832                 if(MapInfo_Get_ByID(i))
 833                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 834                         {
 835                                 if(mod(i, 2))
 836                                         col = "^2";
 837                                 else
 838                                         col = "^3";
 839
 840                                 ++j;
 841
 842                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 843
 844                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 845                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 846                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 847                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 848                         }
 849         }
 850
 851         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 852         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 853
 854         maplist_reply = "^7Maps in list: ";
 855         n = tokenize_console(autocvar_g_maplist);
 856         for(i = 0, j = 0; i < n; ++i)
 857         {
 858                 if(MapInfo_CheckMap(argv(i)))
 859                 {
 860                         if(mod(j, 2))
 861                                 col = "^2";
 862                         else
 863                                 col = "^3";
 864                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 865                         ++j;
 866                 }
 867         }
 868         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 869         MapInfo_ClearTemps();
 870
 871         for(i = 0; i < 10; ++i)
 872         {
 873                 s = getrecords(i);
 874                 if (s)
 875                         records_reply[i] = strzone(s);
 876         }
 877
 878         ladder_reply = strzone(getladder());
 879
 880         rankings_reply = strzone(getrankings());
 881
 882         // begin other init
 883         ClientInit_Spawn();
 884         RandomSeed_Spawn();
 885         PingPLReport_Spawn();
 886
 887         CheatInit();
 888
 889         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 890
 891         // fill sv_curl_serverpackages from .serverpackage files
 892         if(autocvar_sv_curl_serverpackages_auto)
 893         {
 894                 s = "";
 895                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 896                 for(i = 0; i < n; ++i)
 897                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 898                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 899                                 s = strcat(s, " ", argv(i));
 900                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 901                 if(fd >= 0)
 902                 {
 903                         j = search_getsize(fd);
 904                         for(i = 0; i < j; ++i)
 905                                 s = strcat(s, " ", search_getfilename(fd, i));
 906                         search_end(fd);
 907                 }
 908                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 909                 if(fd >= 0)
 910                 {
 911                         j = search_getsize(fd);
 912                         for(i = 0; i < j; ++i)
 913                                 s = strcat(s, " ", search_getfilename(fd, i));
 914                         search_end(fd);
 915                 }
 916                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 917         }
 918
 919         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 920         modname = "Xonotic";
 921         // physics/balance/config changes that count as mod
 922         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 923                 modname = cvar_string("g_mod_physics");
 924         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 925                 modname = cvar_string("g_mod_balance");
 926         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 927                 modname = cvar_string("g_mod_config");
 928         // weird mutators that deserve to count as mod
 929         if(autocvar_g_minstagib)
 930                 modname = "MinstaGib";
 931         // extra mutators that deserve to count as mod
 932         MUTATOR_CALLHOOK(SetModname);
 933
 934         // save it for later
 935         modname = strzone(modname);
 936
 937         WinningConditionHelper(); // set worldstatus
 938
 939         world_initialized = 1;
 940 }
 941
 942 void spawnfunc_light (void)
 943 {
 944         //makestatic (self); // Who the f___ did that?
 945         remove(self);
 946 }
 947
 948 string GetGametype()
 949 {
 950         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         dprint(": no waypoints\n");
 994                         return FALSE;
 995                 }
 996                 dprint(": has waypoints\n");
 997         }
 998
 999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return FALSE;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return FALSE;
1018                 }
1019                 dprint("right size\n");
1020                 return TRUE;
1021         }
1022         dprint(": not found\n");
1023         return TRUE;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void Map_Goto(float reinit)
1099 {
1100         MapInfo_LoadMap(getmapname_stored, reinit);
1101 }
1102
1103 // return codes of map selectors:
1104 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1105 //   -2 = permanent failure
1106 float() MaplistMethod_Iterate = // usual method
1107 {
1108         float pass, i;
1109
1110         for(pass = 1; pass <= 2; ++pass)
1111         {
1112                 for(i = 1; i < Map_Count; ++i)
1113                 {
1114                         float mapindex;
1115                         mapindex = mod(i + Map_Current, Map_Count);
1116                         if(Map_Check(mapindex, pass))
1117                                 return mapindex;
1118                 }
1119         }
1120         return -1;
1121 }
1122
1123 float() MaplistMethod_Repeat = // fallback method
1124 {
1125         if(Map_Check(Map_Current, 2))
1126                 return Map_Current;
1127         return -2;
1128 }
1129
1130 float() MaplistMethod_Random = // random map selection
1131 {
1132         float i, imax;
1133
1134         imax = 42;
1135
1136         for(i = 0; i <= imax; ++i)
1137         {
1138                 float mapindex;
1139                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1140                 if(Map_Check(mapindex, 1))
1141                         return mapindex;
1142         }
1143         return -1;
1144 }
1145
1146 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1147 // the exponent sets a bias on the map selection:
1148 // the higher the exponent, the less likely "shortly repeated" same maps are
1149 {
1150         float i, j, imax, insertpos;
1151
1152         imax = 42;
1153
1154         for(i = 0; i <= imax; ++i)
1155         {
1156                 string newlist;
1157
1158                 // now reinsert this at another position
1159                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1160                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1161                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1162                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1163
1164                 // insert the current map there
1165                 newlist = "";
1166                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1167                         newlist = strcat(newlist, " ", argv(j));
1168                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1169                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1170                         newlist = strcat(newlist, " ", argv(j));
1171                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1172                 cvar_set("g_maplist", newlist);
1173                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1174
1175                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1176                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1177                 if(Map_Check(Map_Current, 1))
1178                         return Map_Current;
1179         }
1180         return -1;
1181 }
1182
1183 void Maplist_Init()
1184 {
1185         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1186         if(Map_Count == 0)
1187         {
1188                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1189                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1190                 if(autocvar_g_maplist_shuffle)
1191                         ShuffleMaplist();
1192                 localcmd("\nmenu_cmd sync\n");
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         }
1195         if(Map_Count == 0)
1196                 error("empty maplist, cannot select a new map");
1197         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1198
1199         if(Map_Current_Name)
1200                 strunzone(Map_Current_Name);
1201         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1202         // this may or may not be correct, but who cares, in the worst case a map
1203         // isn't chosen in the first pass that should have been
1204 }
1205
1206 string GetNextMap()
1207 {
1208         float nextMap;
1209
1210         Maplist_Init();
1211         nextMap = -1;
1212
1213         if(nextMap == -1)
1214                 if(autocvar_g_maplist_shuffle > 0)
1215                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1216
1217         if(nextMap == -1)
1218                 if(autocvar_g_maplist_selectrandom)
1219                         nextMap = MaplistMethod_Random();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Iterate();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Repeat();
1226
1227         if(nextMap >= 0)
1228         {
1229                 Map_Goto_SetFloat(nextMap);
1230                 return getmapname_stored;
1231         }
1232
1233         return "";
1234 }
1235
1236 float DoNextMapOverride(float reinit)
1237 {
1238         if(autocvar_g_campaign)
1239         {
1240                 CampaignPostIntermission();
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         if(autocvar_quit_when_empty)
1245         {
1246                 if(player_count <= currentbots)
1247                 {
1248                         localcmd("quit\n");
1249                         alreadychangedlevel = TRUE;
1250                         return TRUE;
1251                 }
1252         }
1253         if(autocvar_quit_and_redirect != "")
1254         {
1255                 redirection_target = strzone(autocvar_quit_and_redirect);
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1260         {
1261                 localcmd("restart\n");
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if(autocvar_nextmap != "")
1266                 if(MapInfo_CheckMap(autocvar_nextmap))
1267                 {
1268                         Map_Goto_SetStr(autocvar_nextmap);
1269                         Map_Goto(reinit);
1270                         alreadychangedlevel = TRUE;
1271                         return TRUE;
1272                 }
1273         if(!reinit && autocvar_lastlevel)
1274         {
1275                 cvar_settemp_restore();
1276                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         return FALSE;
1281 }
1282
1283 void GotoNextMap(float reinit)
1284 {
1285         //string nextmap;
1286         //float n, nummaps;
1287         //string s;
1288         if (alreadychangedlevel)
1289                 return;
1290         alreadychangedlevel = TRUE;
1291
1292         {
1293                 string nextMap;
1294                 float allowReset;
1295
1296                 for(allowReset = 1; allowReset >= 0; --allowReset)
1297                 {
1298                         nextMap = GetNextMap();
1299                         if(nextMap != "")
1300                                 break;
1301
1302                         if(allowReset)
1303                         {
1304                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1305                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1306                                 if(autocvar_g_maplist_shuffle)
1307                                         ShuffleMaplist();
1308                                 localcmd("\nmenu_cmd sync\n");
1309                         }
1310                         else
1311                         {
1312                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1313                         }
1314                 }
1315                 Map_Goto(reinit);
1316         }
1317 }
1318
1319
1320 /*
1321 ============
1322 IntermissionThink
1323
1324 When the player presses attack or jump, change to the next level
1325 ============
1326 */
1327 .float autoscreenshot;
1328 void() MapVote_Start;
1329 void() MapVote_Think;
1330 float mapvote_initialized;
1331 void IntermissionThink()
1332 {
1333         FixIntermissionClient(self);
1334
1335         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1336         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1337
1338         if( (server_screenshot || client_screenshot)
1339                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1340         {
1341                 self.autoscreenshot = -1;
1342                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1343                 return;
1344         }
1345
1346         if (time < intermission_exittime)
1347                 return;
1348
1349         if(!mapvote_initialized)
1350                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1351                         return;
1352
1353         MapVote_Start();
1354 }
1355
1356 /*
1357 ============
1358 FindIntermission
1359
1360 Returns the entity to view from
1361 ============
1362 */
1363 /*
1364 entity FindIntermission()
1365 {
1366         local   entity spot;
1367         local   float cyc;
1368
1369 // look for info_intermission first
1370         spot = find (world, classname, "info_intermission");
1371         if (spot)
1372         {       // pick a random one
1373                 cyc = random() * 4;
1374                 while (cyc > 1)
1375                 {
1376                         spot = find (spot, classname, "info_intermission");
1377                         if (!spot)
1378                                 spot = find (spot, classname, "info_intermission");
1379                         cyc = cyc - 1;
1380                 }
1381                 return spot;
1382         }
1383
1384 // then look for the start position
1385         spot = find (world, classname, "info_player_start");
1386         if (spot)
1387                 return spot;
1388
1389 // testinfo_player_start is only found in regioned levels
1390         spot = find (world, classname, "testplayerstart");
1391         if (spot)
1392                 return spot;
1393
1394 // then look for the start position
1395         spot = find (world, classname, "info_player_deathmatch");
1396         if (spot)
1397                 return spot;
1398
1399         //objerror ("FindIntermission: no spot");
1400         return world;
1401 }
1402 */
1403
1404 /*
1405 ===============================================================================
1406
1407 RULES
1408
1409 ===============================================================================
1410 */
1411
1412 void DumpStats(float final)
1413 {
1414         float file;
1415         string s;
1416         float to_console;
1417         float to_eventlog;
1418         float to_file;
1419         float i;
1420
1421         to_console = autocvar_sv_logscores_console;
1422         to_eventlog = autocvar_sv_eventlog;
1423         to_file = autocvar_sv_logscores_file;
1424
1425         if(!final)
1426         {
1427                 to_console = TRUE; // always print printstats replies
1428                 to_eventlog = FALSE; // but never print them to the event log
1429         }
1430
1431         if(to_eventlog)
1432                 if(autocvar_sv_eventlog_console)
1433                         to_console = FALSE; // otherwise we get the output twice
1434
1435         if(final)
1436                 s = ":scores:";
1437         else
1438                 s = ":status:";
1439         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1440
1441         if(to_console)
1442                 print(s, "\n");
1443         if(to_eventlog)
1444                 GameLogEcho(s);
1445
1446         file = -1;
1447         if(to_file)
1448         {
1449                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1450                 if(file == -1)
1451                         to_file = FALSE;
1452                 else
1453                         fputs(file, strcat(s, "\n"));
1454         }
1455
1456         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1457         if(to_console)
1458                 print(s, "\n");
1459         if(to_eventlog)
1460                 GameLogEcho(s);
1461         if(to_file)
1462                 fputs(file, strcat(s, "\n"));
1463
1464         FOR_EACH_CLIENT(other)
1465         {
1466                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1467                 {
1468                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1469                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1470                         if(other.classname == "player" || g_arena || other.caplayer == 1 || g_lms)
1471                                 s = strcat(s, ftos(other.team), ":");
1472                         else
1473                                 s = strcat(s, "spectator:");
1474
1475                         if(to_console)
1476                                 print(s, other.netname, "\n");
1477                         if(to_eventlog)
1478                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1479                         if(to_file)
1480                                 fputs(file, strcat(s, other.netname, "\n"));
1481                 }
1482         }
1483
1484         if(teamplay)
1485         {
1486                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1487                 if(to_console)
1488                         print(s, "\n");
1489                 if(to_eventlog)
1490                         GameLogEcho(s);
1491                 if(to_file)
1492                         fputs(file, strcat(s, "\n"));
1493
1494                 for(i = 1; i < 16; ++i)
1495                 {
1496                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1497                         s = strcat(s, ":", ftos(i));
1498                         if(to_console)
1499                                 print(s, "\n");
1500                         if(to_eventlog)
1501                                 GameLogEcho(s);
1502                         if(to_file)
1503                                 fputs(file, strcat(s, "\n"));
1504                 }
1505         }
1506
1507         if(to_console)
1508                 print(":end\n");
1509         if(to_eventlog)
1510                 GameLogEcho(":end");
1511         if(to_file)
1512         {
1513                 fputs(file, ":end\n");
1514                 fclose(file);
1515         }
1516 }
1517
1518 void FixIntermissionClient(entity e)
1519 {
1520         string s;
1521         if(!e.autoscreenshot) // initial call
1522         {
1523                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1524                 e.health = -2342;
1525                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1526                 e.solid = SOLID_NOT;
1527                 e.movetype = MOVETYPE_NONE;
1528                 e.takedamage = DAMAGE_NO;
1529                 if(e.weaponentity)
1530                 {
1531                         e.weaponentity.effects = EF_NODRAW;
1532                         if (e.weaponentity.weaponentity)
1533                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1534                 }
1535                 if(clienttype(e) == CLIENTTYPE_REAL)
1536                 {
1537                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1538                         s = autocvar_sv_intermission_cdtrack;
1539                         if(s != "")
1540                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1541                         msg_entity = e;
1542                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1543                 }
1544         }
1545 }
1546
1547 void minstagib_stop_countdown(entity e);
1548 /*
1549 go to the next level for deathmatch
1550 only called if a time or frag limit has expired
1551 */
1552 void NextLevel()
1553 {
1554         gameover = TRUE;
1555
1556         intermission_running = 1;
1557
1558 // enforce a wait time before allowing changelevel
1559         if(player_count > 0)
1560                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1561         else
1562                 intermission_exittime = -1;
1563
1564         /*
1565         WriteByte (MSG_ALL, SVC_CDTRACK);
1566         WriteByte (MSG_ALL, 3);
1567         WriteByte (MSG_ALL, 3);
1568         // done in FixIntermission
1569         */
1570
1571         //pos = FindIntermission ();
1572
1573         VoteReset();
1574
1575         DumpStats(TRUE);
1576
1577         // send statistics
1578         entity e;
1579         PlayerStats_EndMatch(1);
1580         FOR_EACH_CLIENT(e)
1581                 PlayerStats_AddGlobalInfo(e);
1582         PlayerStats_Shutdown();
1583         WeaponStats_Shutdown();
1584
1585         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1586
1587         if(autocvar_sv_eventlog)
1588                 GameLogEcho(":gameover");
1589
1590         GameLogClose();
1591
1592         FOR_EACH_PLAYER(other) {
1593                 minstagib_stop_countdown(other);
1594                 FixIntermissionClient(other);
1595                 if(other.winning)
1596                         bprint(other.netname, " ^7wins.\n");
1597         }
1598
1599         if(autocvar_g_campaign)
1600                 CampaignPreIntermission();
1601
1602         MUTATOR_CALLHOOK(MatchEnd);
1603
1604         localcmd("\nsv_hook_gameend\n");
1605 }
1606
1607 /*
1608 ============
1609 CheckRules_Player
1610
1611 Exit deathmatch games upon conditions
1612 ============
1613 */
1614 void CheckRules_Player()
1615 {
1616         if (gameover)   // someone else quit the game already
1617                 return;
1618
1619         if(self.deadflag == DEAD_NO)
1620                 self.play_time += frametime;
1621
1622         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1623         //   (div0: and that in CheckRules_World please)
1624 }
1625
1626 float checkrules_equality;
1627 float checkrules_suddendeathwarning;
1628 float checkrules_suddendeathend;
1629 float checkrules_overtimesadded; //how many overtimes have been already added
1630
1631 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1632 float WINNING_YES = 1; // winner found
1633 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1634 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1635
1636 float InitiateSuddenDeath()
1637 {
1638         // Check first whether normal overtimes could be added before initiating suddendeath mode
1639         // - for this timelimit_overtime needs to be >0 of course
1640         // - also check the winning condition calculated in the previous frame and only add normal overtime
1641         //   again, if at the point at which timelimit would be extended again, still no winner was found
1642         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1643         {
1644                 return 1; // need to call InitiateOvertime later
1645         }
1646         else
1647         {
1648                 if(!checkrules_suddendeathend)
1649                 {
1650                         if(autocvar_g_campaign)
1651                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1652                         else
1653                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1654                         if(g_race && !g_race_qualifying)
1655                                 race_StartCompleting();
1656                 }
1657                 return 0;
1658         }
1659 }
1660
1661 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1662 {
1663         ++checkrules_overtimesadded;
1664         //add one more overtime by simply extending the timelimit
1665         float tl;
1666         tl = autocvar_timelimit;
1667         tl += autocvar_timelimit_overtime;
1668         cvar_set("timelimit", ftos(tl));
1669
1670         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1671 }
1672
1673 float GetWinningCode(float fraglimitreached, float equality)
1674 {
1675         if(autocvar_g_campaign == 1)
1676                 if(fraglimitreached)
1677                         return WINNING_YES;
1678                 else
1679                         return WINNING_NO;
1680
1681         else
1682                 if(equality)
1683                         if(fraglimitreached)
1684                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1685                         else
1686                                 return WINNING_NEVER;
1687                 else
1688                         if(fraglimitreached)
1689                                 return WINNING_YES;
1690                         else
1691                                 return WINNING_NO;
1692 }
1693
1694 // set the .winning flag for exactly those players with a given field value
1695 void SetWinners(.float field, float value)
1696 {
1697         entity head;
1698         FOR_EACH_PLAYER(head)
1699                 head.winning = (head.field == value);
1700 }
1701
1702 // set the .winning flag for those players with a given field value
1703 void AddWinners(.float field, float value)
1704 {
1705         entity head;
1706         FOR_EACH_PLAYER(head)
1707                 if(head.field == value)
1708                         head.winning = 1;
1709 }
1710
1711 // clear the .winning flags
1712 void ClearWinners(void)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = 0;
1717 }
1718
1719 // Onslaught winning condition:
1720 // game terminates if only one team has a working generator (or none)
1721 float WinningCondition_Onslaught()
1722 {
1723         entity head;
1724         float t1, t2, t3, t4;
1725
1726         WinningConditionHelper(); // set worldstatus
1727
1728         if(inWarmupStage)
1729                 return WINNING_NO;
1730
1731         // first check if the game has ended
1732         t1 = t2 = t3 = t4 = 0;
1733         head = find(world, classname, "onslaught_generator");
1734         while (head)
1735         {
1736                 if (head.health > 0)
1737                 {
1738                         if (head.team == NUM_TEAM_1) t1 = 1;
1739                         if (head.team == NUM_TEAM_2) t2 = 1;
1740                         if (head.team == NUM_TEAM_3) t3 = 1;
1741                         if (head.team == NUM_TEAM_4) t4 = 1;
1742                 }
1743                 head = find(head, classname, "onslaught_generator");
1744         }
1745         if (t1 + t2 + t3 + t4 < 2)
1746         {
1747                 // game over, only one team remains (or none)
1748                 ClearWinners();
1749                 if (t1) SetWinners(team, NUM_TEAM_1);
1750                 if (t2) SetWinners(team, NUM_TEAM_2);
1751                 if (t3) SetWinners(team, NUM_TEAM_3);
1752                 if (t4) SetWinners(team, NUM_TEAM_4);
1753                 dprint("Have a winner, ending game.\n");
1754                 return WINNING_YES;
1755         }
1756
1757         // Two or more teams remain
1758         return WINNING_NO;
1759 }
1760
1761 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1762 // they win. Otherwise the defending team wins once the timelimit passes.
1763 void assault_new_round();
1764 float WinningCondition_Assault()
1765 {
1766         float status;
1767
1768         WinningConditionHelper(); // set worldstatus
1769
1770         status = WINNING_NO;
1771         // as the timelimit has not yet passed just assume the defending team will win
1772         if(assault_attacker_team == NUM_TEAM_1)
1773         {
1774                 SetWinners(team, NUM_TEAM_2);
1775         }
1776         else
1777         {
1778                 SetWinners(team, NUM_TEAM_1);
1779         }
1780
1781         entity ent;
1782         ent = find(world, classname, "target_assault_roundend");
1783         if(ent)
1784         {
1785                 if(ent.winning) // round end has been triggered by attacking team
1786                 {
1787                         bprint("ASSAULT: round completed...\n");
1788                         SetWinners(team, assault_attacker_team);
1789
1790                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1791
1792                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1793                         {
1794                                 status = WINNING_YES;
1795                         }
1796                         else
1797                         {
1798                                 entity oldself;
1799                                 oldself = self;
1800                                 self = ent;
1801                                 assault_new_round();
1802                                 self = oldself;
1803                         }
1804                 }
1805         }
1806
1807         return status;
1808 }
1809
1810 // LMS winning condition: game terminates if and only if there's at most one
1811 // one player who's living lives. Top two scores being equal cancels the time
1812 // limit.
1813 float WinningCondition_LMS()
1814 {
1815         entity head, head2;
1816         float have_player;
1817         float have_players;
1818         float l;
1819
1820         have_player = FALSE;
1821         have_players = FALSE;
1822         l = LMS_NewPlayerLives();
1823
1824         head = find(world, classname, "player");
1825         if(head)
1826                 have_player = TRUE;
1827         head2 = find(head, classname, "player");
1828         if(head2)
1829                 have_players = TRUE;
1830
1831         if(have_player)
1832         {
1833                 // we have at least one player
1834                 if(have_players)
1835                 {
1836                         // two or more active players - continue with the game
1837                 }
1838                 else
1839                 {
1840                         // exactly one player?
1841
1842                         ClearWinners();
1843                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1844
1845                         if(l)
1846                         {
1847                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1848                                 return WINNING_NO;
1849                         }
1850                         else
1851                         {
1852                                 // a winner!
1853                                 // and assign him his first place
1854                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1855                                 return WINNING_YES;
1856                         }
1857                 }
1858         }
1859         else
1860         {
1861                 // nobody is playing at all...
1862                 if(l)
1863                 {
1864                         // wait for players...
1865                 }
1866                 else
1867                 {
1868                         // SNAFU (maybe a draw game?)
1869                         ClearWinners();
1870                         dprint("No players, ending game.\n");
1871                         return WINNING_YES;
1872                 }
1873         }
1874
1875         // When we get here, we have at least two players who are actually LIVING,
1876         // now check if the top two players have equal score.
1877         WinningConditionHelper();
1878
1879         ClearWinners();
1880         if(WinningConditionHelper_winner)
1881                 WinningConditionHelper_winner.winning = TRUE;
1882         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1883                 return WINNING_NEVER;
1884
1885         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1886         return WINNING_NO;
1887 }
1888
1889 void ShuffleMaplist()
1890 {
1891         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1892 }
1893
1894 float leaderfrags;
1895 float WinningCondition_Scores(float limit, float leadlimit)
1896 {
1897         float limitreached;
1898
1899         // TODO make everything use THIS winning condition (except LMS)
1900         WinningConditionHelper();
1901
1902         if(teamplay)
1903         {
1904                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1905                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1906                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1907                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1908         }
1909
1910         ClearWinners();
1911         if(WinningConditionHelper_winner)
1912                 WinningConditionHelper_winner.winning = 1;
1913         if(WinningConditionHelper_winnerteam >= 0)
1914                 SetWinners(team, WinningConditionHelper_winnerteam);
1915
1916         if(WinningConditionHelper_lowerisbetter)
1917         {
1918                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1919                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1920                 limit = -limit;
1921         }
1922
1923         if(WinningConditionHelper_zeroisworst)
1924                 leadlimit = 0; // not supported in this mode
1925
1926         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1927         // these modes always score in increments of 1, thus this makes sense
1928         {
1929                 if(leaderfrags != WinningConditionHelper_topscore)
1930                 {
1931                         leaderfrags = WinningConditionHelper_topscore;
1932
1933                         if (limit)
1934                         if (leaderfrags == limit - 1)
1935                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1936                         else if (leaderfrags == limit - 2)
1937                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1938                         else if (leaderfrags == limit - 3)
1939                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1940                 }
1941         }
1942
1943         limitreached = FALSE;
1944         if(limit)
1945                 if(WinningConditionHelper_topscore >= limit)
1946                         limitreached = TRUE;
1947         if(leadlimit)
1948         {
1949                 float leadlimitreached;
1950                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1951                 if(autocvar_leadlimit_and_fraglimit)
1952                         limitreached = (limitreached && leadlimitreached);
1953                 else
1954                         limitreached = (limitreached || leadlimitreached);
1955         }
1956
1957         if(limit)
1958                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1959
1960         return GetWinningCode(
1961                 WinningConditionHelper_topscore && limitreached,
1962                 WinningConditionHelper_equality
1963         );
1964 }
1965
1966 float WinningCondition_Race(float fraglimit)
1967 {
1968         float wc;
1969         entity p;
1970         float n, c;
1971
1972         n = 0;
1973         c = 0;
1974         FOR_EACH_PLAYER(p)
1975         {
1976                 ++n;
1977                 if(p.race_completed)
1978                         ++c;
1979         }
1980         if(n && (n == c))
1981                 return WINNING_YES;
1982         wc = WinningCondition_Scores(fraglimit, 0);
1983
1984         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1985         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1986         // do NOT support equality when the laps are all raced!
1987                 return WINNING_STARTSUDDENDEATHOVERTIME;
1988         else
1989                 return WINNING_NEVER;
1990 }
1991
1992 float WinningCondition_QualifyingThenRace(float limit)
1993 {
1994         float wc;
1995         wc = WinningCondition_Scores(limit, 0);
1996
1997         // NEVER initiate overtime
1998         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1999         {
2000                 return WINNING_YES;
2001         }
2002
2003         return wc;
2004 }
2005
2006 float WinningCondition_RanOutOfSpawns()
2007 {
2008         entity head;
2009
2010         if(have_team_spawns <= 0)
2011                 return WINNING_NO;
2012
2013         if(autocvar_g_spawn_useallspawns <= 0)
2014                 return WINNING_NO;
2015
2016         if(!some_spawn_has_been_used)
2017                 return WINNING_NO;
2018
2019         team1_score = team2_score = team3_score = team4_score = 0;
2020
2021         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2022         {
2023                 if(head.team == NUM_TEAM_1)
2024                         team1_score = 1;
2025                 else if(head.team == NUM_TEAM_2)
2026                         team2_score = 1;
2027                 else if(head.team == NUM_TEAM_3)
2028                         team3_score = 1;
2029                 else if(head.team == NUM_TEAM_4)
2030                         team4_score = 1;
2031         }
2032
2033         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2034         {
2035                 if(head.team == NUM_TEAM_1)
2036                         team1_score = 1;
2037                 else if(head.team == NUM_TEAM_2)
2038                         team2_score = 1;
2039                 else if(head.team == NUM_TEAM_3)
2040                         team3_score = 1;
2041                 else if(head.team == NUM_TEAM_4)
2042                         team4_score = 1;
2043         }
2044
2045         ClearWinners();
2046         if(team1_score + team2_score + team3_score + team4_score == 0)
2047         {
2048                 checkrules_equality = TRUE;
2049                 return WINNING_YES;
2050         }
2051         else if(team1_score + team2_score + team3_score + team4_score == 1)
2052         {
2053                 float t, i;
2054                 if(team1_score)
2055                         t = NUM_TEAM_1;
2056                 else if(team2_score)
2057                         t = NUM_TEAM_2;
2058                 else if(team3_score)
2059                         t = NUM_TEAM_3;
2060                 else // if(team4_score)
2061                         t = NUM_TEAM_4;
2062                 CheckAllowedTeams(world);
2063                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2064                 {
2065                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2066                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2067                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2068                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2069                 }
2070
2071                 AddWinners(team, t);
2072                 return WINNING_YES;
2073         }
2074         else
2075                 return WINNING_NO;
2076 }
2077
2078 /*
2079 ============
2080 CheckRules_World
2081
2082 Exit deathmatch games upon conditions
2083 ============
2084 */
2085 void ReadyRestart();
2086 void CheckRules_World()
2087 {
2088         float timelimit;
2089         float fraglimit;
2090         float leadlimit;
2091
2092         VoteThink();
2093         MapVote_Think();
2094
2095         SetDefaultAlpha();
2096
2097         /*
2098         MapVote_Think should now do that part
2099         if (intermission_running)
2100                 if (time >= intermission_exittime + 60)
2101                 {
2102                         if(!DoNextMapOverride())
2103                                 GotoNextMap();
2104                         return;
2105                 }
2106         */
2107
2108         if (gameover)   // someone else quit the game already
2109         {
2110                 if(player_count == 0) // Nobody there? Then let's go to the next map
2111                         MapVote_Start();
2112                         // this will actually check the player count in the next frame
2113                         // again, but this shouldn't hurt
2114                 return;
2115         }
2116
2117         timelimit = autocvar_timelimit * 60;
2118         fraglimit = autocvar_fraglimit;
2119         leadlimit = autocvar_leadlimit;
2120
2121         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2122         {
2123                 if(timelimit > 0)
2124                         timelimit = 0; // timelimit is not made for warmup
2125                 if(fraglimit > 0)
2126                         fraglimit = 0; // no fraglimit for now
2127                 leadlimit = 0; // no leadlimit for now
2128         }
2129
2130         if(timelimit > 0)
2131         {
2132                 timelimit += game_starttime;
2133         }
2134         else if (timelimit < 0)
2135         {
2136                 // endmatch
2137                 NextLevel();
2138                 return;
2139         }
2140
2141         if(g_onslaught)
2142                 timelimit = 0; // ONS has its own overtime rule
2143
2144         float wantovertime;
2145         wantovertime = 0;
2146
2147         if(timelimit > game_starttime)
2148                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2149         else
2150                 game_completion_ratio = 0;
2151
2152         if(checkrules_suddendeathend)
2153         {
2154                 if(!checkrules_suddendeathwarning)
2155                 {
2156                         checkrules_suddendeathwarning = TRUE;
2157                         if(g_race && !g_race_qualifying)
2158                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2159                         else
2160                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2161                 }
2162         }
2163         else
2164         {
2165                 if (timelimit && time >= timelimit)
2166                 {
2167                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2168                         {
2169                                 float totalplayers;
2170                                 float playerswithlaps;
2171                                 float readyplayers;
2172                                 entity head;
2173                                 totalplayers = playerswithlaps = readyplayers = 0;
2174                                 FOR_EACH_PLAYER(head)
2175                                 {
2176                                         ++totalplayers;
2177                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2178                                                 ++playerswithlaps;
2179                                         if(head.ready)
2180                                                 ++readyplayers;
2181                                 }
2182
2183                                 // at least 2 of the players have completed a lap: start the RACE
2184                                 // otherwise, the players should end the qualifying on their own
2185                                 if(readyplayers || playerswithlaps >= 2)
2186                                 {
2187                                         checkrules_suddendeathend = 0;
2188                                         ReadyRestart(); // go to race
2189                                         return;
2190                                 }
2191                                 else
2192                                         wantovertime |= InitiateSuddenDeath();
2193                         }
2194                         else
2195                                 wantovertime |= InitiateSuddenDeath();
2196                 }
2197         }
2198
2199         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2200         {
2201                 NextLevel();
2202                 return;
2203         }
2204
2205         float checkrules_status;
2206         checkrules_status = WinningCondition_RanOutOfSpawns();
2207         if(checkrules_status == WINNING_YES)
2208         {
2209                 bprint("Hey! Someone ran out of spawns!\n");
2210         }
2211         else if(g_race && !g_race_qualifying && timelimit >= 0)
2212         {
2213                 checkrules_status = WinningCondition_Race(fraglimit);
2214                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2215         }
2216         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2217         {
2218                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2219                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2220         }
2221         else if(g_assault)
2222         {
2223                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2224         }
2225         else if(g_lms)
2226         {
2227                 checkrules_status = WinningCondition_LMS();
2228         }
2229         else if (g_onslaught)
2230         {
2231                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2232         }
2233         else
2234         {
2235                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2236                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2237         }
2238
2239         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2240         {
2241                 checkrules_status = WINNING_NEVER;
2242                 checkrules_overtimesadded = -1;
2243                 wantovertime |= InitiateSuddenDeath();
2244         }
2245
2246         if(checkrules_status == WINNING_NEVER)
2247                 // equality cases! Nobody wins if the overtime ends in a draw.
2248                 ClearWinners();
2249
2250         if(wantovertime)
2251         {
2252                 if(checkrules_status == WINNING_NEVER)
2253                         InitiateOvertime();
2254                 else
2255                         checkrules_status = WINNING_YES;
2256         }
2257
2258         if(checkrules_suddendeathend)
2259                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2260                         checkrules_status = WINNING_YES;
2261
2262         if(checkrules_status == WINNING_YES)
2263         {
2264                 //print("WINNING\n");
2265                 NextLevel();
2266         }
2267 }
2268
2269 float mapvote_nextthink;
2270 float mapvote_initialized;
2271 float mapvote_keeptwotime;
2272 float mapvote_timeout;
2273 string mapvote_message;
2274 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2275 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2276 float mapvote_screenshot_dirs_count;
2277
2278 float mapvote_count;
2279 float mapvote_count_real;
2280 string mapvote_maps[MAPVOTE_COUNT];
2281 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2282 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2283 float mapvote_maps_suggested[MAPVOTE_COUNT];
2284 string mapvote_suggestions[MAPVOTE_COUNT];
2285 float mapvote_suggestion_ptr;
2286 float mapvote_voters;
2287 float mapvote_selections[MAPVOTE_COUNT];
2288 float mapvote_run;
2289 float mapvote_detail;
2290 float mapvote_abstain;
2291 .float mapvote;
2292
2293 void MapVote_ClearAllVotes()
2294 {
2295         FOR_EACH_CLIENT(other)
2296                 other.mapvote = 0;
2297 }
2298
2299 string MapVote_Suggest(string m)
2300 {
2301         float i;
2302         if(m == "")
2303                 return "That's not how to use this command.";
2304         if(!autocvar_g_maplist_votable_suggestions)
2305                 return "Suggestions are not accepted on this server.";
2306         if(mapvote_initialized)
2307                 return "Can't suggest - voting is already in progress!";
2308         m = MapInfo_FixName(m);
2309         if not(m)
2310                 return "The map you suggested is not available on this server.";
2311         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2312                 if(Map_IsRecent(m))
2313                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2314
2315         if(!MapInfo_CheckMap(m))
2316                 return "The map you suggested does not support the current game mode.";
2317         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2318                 if(mapvote_suggestions[i] == m)
2319                         return "This map was already suggested.";
2320         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2321         {
2322                 i = floor(random() * mapvote_suggestion_ptr);
2323         }
2324         else
2325         {
2326                 i = mapvote_suggestion_ptr;
2327                 mapvote_suggestion_ptr += 1;
2328         }
2329         if(mapvote_suggestions[i] != "")
2330                 strunzone(mapvote_suggestions[i]);
2331         mapvote_suggestions[i] = strzone(m);
2332         if(autocvar_sv_eventlog)
2333                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2334         return strcat("Suggestion of ", m, " accepted.");
2335 }
2336
2337 void MapVote_AddVotable(string nextMap, float isSuggestion)
2338 {
2339         float j, i, o;
2340         string pakfile, mapfile;
2341
2342         if(nextMap == "")
2343                 return;
2344         for(j = 0; j < mapvote_count; ++j)
2345                 if(mapvote_maps[j] == nextMap)
2346                         return;
2347         // suggestions might be no longer valid/allowed after gametype switch!
2348         if(isSuggestion)
2349                 if(!MapInfo_CheckMap(nextMap))
2350                         return;
2351         mapvote_maps[mapvote_count] = strzone(nextMap);
2352         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2353
2354         pakfile = string_null;
2355         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2356         {
2357                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2358                 pakfile = whichpack(strcat(mapfile, ".tga"));
2359                 if(pakfile == "")
2360                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2361                 if(pakfile == "")
2362                         pakfile = whichpack(strcat(mapfile, ".png"));
2363                 if(pakfile != "")
2364                         break;
2365         }
2366         if(i >= mapvote_screenshot_dirs_count)
2367                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2368         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2369                 pakfile = substring(pakfile, o, -1);
2370
2371         mapvote_maps_screenshot_dir[mapvote_count] = i;
2372         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2373
2374         mapvote_count += 1;
2375 }
2376
2377 void MapVote_Spawn();
2378 void MapVote_Init()
2379 {
2380         float i;
2381         float nmax, smax;
2382
2383         MapVote_ClearAllVotes();
2384
2385         mapvote_count = 0;
2386         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2387         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2388
2389         if(mapvote_abstain)
2390                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2391         else
2392                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2393         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2394
2395         // we need this for AddVotable, as that cycles through the screenshot dirs
2396         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2397         if(mapvote_screenshot_dirs_count == 0)
2398                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2399         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2400         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2401                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2402
2403         if(mapvote_suggestion_ptr)
2404                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2405                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2406
2407         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2408                 MapVote_AddVotable(GetNextMap(), FALSE);
2409
2410         if(mapvote_count == 0)
2411         {
2412                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2413                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2414                 if(autocvar_g_maplist_shuffle)
2415                         ShuffleMaplist();
2416                 localcmd("\nmenu_cmd sync\n");
2417                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2418                         MapVote_AddVotable(GetNextMap(), FALSE);
2419         }
2420
2421         mapvote_count_real = mapvote_count;
2422         if(mapvote_abstain)
2423                 MapVote_AddVotable("don't care", 0);
2424
2425         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2426
2427         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2428         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2429         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2430                 mapvote_keeptwotime = 0;
2431         mapvote_message = "Choose a map and press its key!";
2432
2433         MapVote_Spawn();
2434 }
2435
2436 void MapVote_SendPicture(float id)
2437 {
2438         msg_entity = self;
2439         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2440         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2441         WriteByte(MSG_ONE, id);
2442         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2443 }
2444
2445 float MapVote_GetMapMask()
2446 {
2447         float mask, i, power;
2448         mask = 0;
2449         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2450                 if(mapvote_maps[i] != "")
2451                         mask |= power;
2452         return mask;
2453 }
2454
2455 entity mapvote_ent;
2456 float MapVote_SendEntity(entity to, float sf)
2457 {
2458         float i;
2459
2460         if(sf & 1)
2461                 sf &~= 2; // if we send 1, we don't need to also send 2
2462
2463         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2464         WriteByte(MSG_ENTITY, sf);
2465
2466         if(sf & 1)
2467         {
2468                 // flag 1 == initialization
2469                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2470                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2471                 WriteString(MSG_ENTITY, "");
2472                 WriteByte(MSG_ENTITY, mapvote_count);
2473                 WriteByte(MSG_ENTITY, mapvote_abstain);
2474                 WriteByte(MSG_ENTITY, mapvote_detail);
2475                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2476                 if(mapvote_count <= 8)
2477                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2478                 else
2479                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2480                 for(i = 0; i < mapvote_count; ++i)
2481                         if(mapvote_maps[i] != "")
2482                         {
2483                                 if(mapvote_abstain && i == mapvote_count - 1)
2484                                 {
2485                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2486                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2487                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2488                                 }
2489                                 else
2490                                 {
2491                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2492                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2493                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2494                                 }
2495                         }
2496         }
2497
2498         if(sf & 2)
2499         {
2500                 // flag 2 == update of mask
2501                 if(mapvote_count <= 8)
2502                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2503                 else
2504                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2505         }
2506
2507         if(sf & 4)
2508         {
2509                 if(mapvote_detail)
2510                         for(i = 0; i < mapvote_count; ++i)
2511                                 if(mapvote_maps[i] != "")
2512                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2513
2514                 WriteByte(MSG_ENTITY, to.mapvote);
2515         }
2516
2517         return TRUE;
2518 }
2519
2520 void MapVote_Spawn()
2521 {
2522         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2523 }
2524
2525 void MapVote_TouchMask()
2526 {
2527         mapvote_ent.SendFlags |= 2;
2528 }
2529
2530 void MapVote_TouchVotes(entity voter)
2531 {
2532         mapvote_ent.SendFlags |= 4;
2533 }
2534
2535 float MapVote_Finished(float mappos)
2536 {
2537         string result;
2538         float i;
2539         float didntvote;
2540
2541         if(autocvar_sv_eventlog)
2542         {
2543                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2544                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2545                 didntvote = mapvote_voters;
2546                 for(i = 0; i < mapvote_count; ++i)
2547                         if(mapvote_maps[i] != "")
2548                         {
2549                                 didntvote -= mapvote_selections[i];
2550                                 if(i != mappos)
2551                                 {
2552                                         result = strcat(result, ":", mapvote_maps[i]);
2553                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2554                                 }
2555                         }
2556                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2557
2558                 GameLogEcho(result);
2559                 if(mapvote_maps_suggested[mappos])
2560                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2561         }
2562
2563         FOR_EACH_REALCLIENT(other)
2564                 FixClientCvars(other);
2565
2566         Map_Goto_SetStr(mapvote_maps[mappos]);
2567         Map_Goto(0);
2568         alreadychangedlevel = TRUE;
2569         return TRUE;
2570 }
2571 void MapVote_CheckRules_1()
2572 {
2573         float i;
2574
2575         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2576         {
2577                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2578                 mapvote_selections[i] = 0;
2579         }
2580
2581         mapvote_voters = 0;
2582         FOR_EACH_REALCLIENT(other)
2583         {
2584                 ++mapvote_voters;
2585                 if(other.mapvote)
2586                 {
2587                         i = other.mapvote - 1;
2588                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2589                         mapvote_selections[i] = mapvote_selections[i] + 1;
2590                 }
2591         }
2592 }
2593
2594 float MapVote_CheckRules_2()
2595 {
2596         float i;
2597         float firstPlace, secondPlace;
2598         float firstPlaceVotes, secondPlaceVotes;
2599         float mapvote_voters_real;
2600         string result;
2601
2602         if(mapvote_count_real == 1)
2603                 return MapVote_Finished(0);
2604
2605         mapvote_voters_real = mapvote_voters;
2606         if(mapvote_abstain)
2607                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2608
2609         RandomSelection_Init();
2610         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2611                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2612         firstPlace = RandomSelection_chosen_float;
2613         firstPlaceVotes = RandomSelection_best_priority;
2614         //dprint("First place: ", ftos(firstPlace), "\n");
2615         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2616
2617         RandomSelection_Init();
2618         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2619                 if(i != firstPlace)
2620                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2621         secondPlace = RandomSelection_chosen_float;
2622         secondPlaceVotes = RandomSelection_best_priority;
2623         //dprint("Second place: ", ftos(secondPlace), "\n");
2624         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2625
2626         if(firstPlace == -1)
2627                 error("No first place in map vote... WTF?");
2628
2629         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2630                 return MapVote_Finished(firstPlace);
2631
2632         if(mapvote_keeptwotime)
2633                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2634                 {
2635                         float didntvote;
2636                         MapVote_TouchMask();
2637                         mapvote_message = "Now decide between the TOP TWO!";
2638                         mapvote_keeptwotime = 0;
2639                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2640                         result = strcat(result, ":", ftos(firstPlaceVotes));
2641                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2642                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2643                         didntvote = mapvote_voters;
2644                         for(i = 0; i < mapvote_count; ++i)
2645                                 if(mapvote_maps[i] != "")
2646                                 {
2647                                         didntvote -= mapvote_selections[i];
2648                                         if(i != firstPlace)
2649                                                 if(i != secondPlace)
2650                                                 {
2651                                                         result = strcat(result, ":", mapvote_maps[i]);
2652                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2653                                                         if(i < mapvote_count_real)
2654                                                         {
2655                                                                 strunzone(mapvote_maps[i]);
2656                                                                 mapvote_maps[i] = "";
2657                                                                 strunzone(mapvote_maps_pakfile[i]);
2658                                                                 mapvote_maps_pakfile[i] = "";
2659                                                         }
2660                                                 }
2661                                 }
2662                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2663                         if(autocvar_sv_eventlog)
2664                                 GameLogEcho(result);
2665                 }
2666
2667         return FALSE;
2668 }
2669 void MapVote_Tick()
2670 {
2671         float keeptwo;
2672         float totalvotes;
2673
2674         keeptwo = mapvote_keeptwotime;
2675         MapVote_CheckRules_1(); // count
2676         if(MapVote_CheckRules_2()) // decide
2677                 return;
2678
2679         totalvotes = 0;
2680         FOR_EACH_REALCLIENT(other)
2681         {
2682                 // hide scoreboard again
2683                 if(other.health != 2342)
2684                 {
2685                         other.health = 2342;
2686                         other.impulse = 0;
2687                         if(clienttype(other) == CLIENTTYPE_REAL)
2688                         {
2689                                 msg_entity = other;
2690                                 WriteByte(MSG_ONE, SVC_FINALE);
2691                                 WriteString(MSG_ONE, "");
2692                         }
2693                 }
2694
2695                 // clear possibly invalid votes
2696                 if(mapvote_maps[other.mapvote - 1] == "")
2697                         other.mapvote = 0;
2698                 // use impulses as new vote
2699                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2700                         if(mapvote_maps[other.impulse - 1] != "")
2701                         {
2702                                 other.mapvote = other.impulse;
2703                                 MapVote_TouchVotes(other);
2704                         }
2705                 other.impulse = 0;
2706
2707                 if(other.mapvote)
2708                         ++totalvotes;
2709         }
2710
2711         MapVote_CheckRules_1(); // just count
2712 }
2713 void MapVote_Start()
2714 {
2715         if(mapvote_run)
2716                 return;
2717
2718         // wait for stats to be sent first
2719         if(!playerstats_waitforme)
2720                 return;
2721
2722         MapInfo_Enumerate();
2723         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2724                 mapvote_run = TRUE;
2725 }
2726 void MapVote_Think()
2727 {
2728         if(!mapvote_run)
2729                 return;
2730
2731         if(alreadychangedlevel)
2732                 return;
2733
2734         if(time < mapvote_nextthink)
2735                 return;
2736         //dprint("tick\n");
2737
2738         mapvote_nextthink = time + 0.5;
2739
2740         if(!mapvote_initialized)
2741         {
2742                 if(autocvar_rescan_pending == 1)
2743                 {
2744                         cvar_set("rescan_pending", "2");
2745                         localcmd("fs_rescan\nrescan_pending 3\n");
2746                         return;
2747                 }
2748                 else if(autocvar_rescan_pending == 2)
2749                 {
2750                         return;
2751                 }
2752                 else if(autocvar_rescan_pending == 3)
2753                 {
2754                         // now build missing mapinfo files
2755                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2756                                 return;
2757
2758                         // we're done, start the timer
2759                         cvar_set("rescan_pending", "0");
2760                 }
2761
2762                 mapvote_initialized = TRUE;
2763                 if(DoNextMapOverride(0))
2764                         return;
2765                 if(!autocvar_g_maplist_votable || player_count <= 0)
2766                 {
2767                         GotoNextMap(0);
2768                         return;
2769                 }
2770                 MapVote_Init();
2771         }
2772
2773         MapVote_Tick();
2774 }
2775
2776 string GotoMap(string m)
2777 {
2778         if(!MapInfo_CheckMap(m))
2779                 return "The map you chose is not available on this server.";
2780         cvar_set("nextmap", m);
2781         cvar_set("timelimit", "-1");
2782         if(mapvote_initialized || alreadychangedlevel)
2783         {
2784                 if(DoNextMapOverride(0))
2785                         return "Map switch initiated.";
2786                 else
2787                         return "Hm... no. For some reason I like THIS map more.";
2788         }
2789         else
2790                 return "Map switch will happen after scoreboard.";
2791 }
2792
2793
2794 void EndFrame()
2795 {
2796         float altime;
2797         FOR_EACH_REALCLIENT(self)
2798         {
2799                 if(self.classname == "spectator")
2800                 {
2801                         if(self.enemy.typehitsound)
2802                                 self.typehit_time = time;
2803                         else if(self.enemy.hitsound)
2804                                 self.hit_time = time;
2805                 }
2806                 else
2807                 {
2808                         if(self.typehitsound)
2809                                 self.typehit_time = time;
2810                         else if(self.hitsound)
2811                                 self.hit_time = time;
2812                 }
2813         }
2814         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2815         // add 1 frametime because after this, engine SV_Physics
2816         // increases time by a frametime and then networks the frame
2817         // add another frametime because client shows everything with
2818         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2819         // needed!
2820         FOR_EACH_CLIENT(self)
2821         {
2822                 self.hitsound = FALSE;
2823                 self.typehitsound = FALSE;
2824                 antilag_record(self, altime);
2825         }
2826 }
2827
2828
2829 /*
2830  * RedirectionThink:
2831  * returns TRUE if redirecting
2832  */
2833 float redirection_timeout;
2834 float redirection_nextthink;
2835 float RedirectionThink()
2836 {
2837         float clients_found;
2838
2839         if(redirection_target == "")
2840                 return FALSE;
2841
2842         if(!redirection_timeout)
2843         {
2844                 cvar_set("sv_public", "-2");
2845                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2846                 if(redirection_target == "self")
2847                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2848                 else
2849                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2850         }
2851
2852         if(time < redirection_nextthink)
2853                 return TRUE;
2854
2855         redirection_nextthink = time + 1;
2856
2857         clients_found = 0;
2858         FOR_EACH_REALCLIENT(self)
2859         {
2860                 // TODO add timer
2861                 print("Redirecting: sending connect command to ", self.netname, "\n");
2862                 if(redirection_target == "self")
2863                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2864                 else
2865                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2866                 ++clients_found;
2867         }
2868
2869         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2870
2871         if(time > redirection_timeout || clients_found == 0)
2872                 localcmd("\nwait; wait; wait; quit\n");
2873
2874         return TRUE;
2875 }
2876
2877 void TargetMusic_RestoreGame();
2878 void RestoreGame()
2879 {
2880         // Loaded from a save game
2881         // some things then break, so let's work around them...
2882
2883         // Progs DB (capture records)
2884         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2885
2886         // Mapinfo
2887         MapInfo_Shutdown();
2888         MapInfo_Enumerate();
2889         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2890         WeaponStats_Init();
2891
2892         TargetMusic_RestoreGame();
2893 }
2894
2895 void Shutdown()
2896 {
2897         entity e;
2898
2899         gameover = 2;
2900
2901         if(world_initialized > 0)
2902         {
2903                 world_initialized = 0;
2904                 print("Saving persistent data...\n");
2905                 Ban_SaveBans();
2906
2907                 PlayerStats_EndMatch(0);
2908                 FOR_EACH_CLIENT(e)
2909                         PlayerStats_AddGlobalInfo(e);
2910                 PlayerStats_Shutdown();
2911
2912                 if(!cheatcount_total)
2913                 {
2914                         if(autocvar_sv_db_saveasdump)
2915                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2916                         else
2917                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2918                 }
2919                 if(autocvar_developer)
2920                 {
2921                         if(autocvar_sv_db_saveasdump)
2922                                 db_dump(TemporaryDB, "server-temp.db");
2923                         else
2924                                 db_save(TemporaryDB, "server-temp.db");
2925                 }
2926                 CheatShutdown(); // must be after cheatcount check
2927                 db_close(ServerProgsDB);
2928                 db_close(TemporaryDB);
2929                 print("done!\n");
2930                 // tell the bot system the game is ending now
2931                 bot_endgame();
2932
2933                 WeaponStats_Shutdown();
2934                 MapInfo_Shutdown();
2935         }
2936         else if(world_initialized == 0)
2937         {
2938                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2939         }
2940 }