qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications.qh"
  28 #include "../common/physics.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  74                 WriteByte(MSG_BROADCAST, self.cnt);
  75                 WriteShort(MSG_BROADCAST, 0);
  76                 WriteByte(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78         }
  79         self.cnt = (self.cnt + 1) % maxclients;
  80 }
  81 void PingPLReport_Spawn()
  82 {
  83         pingplreport = new(pingplreport);
  84         make_pure(pingplreport);
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap()
 108 {SELFPARAM();
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 self.nextthink = time;
 133         }
 134         else
 135         {
 136                 self.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_respawn_ghosts");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251
 252                 // mapinfo
 253                 BADCVAR("fraglimit");
 254                 BADCVAR("g_assault");
 255                 BADCVAR("g_ca");
 256                 BADCVAR("g_ca_teams");
 257                 BADCVAR("g_ctf");
 258                 BADCVAR("g_cts");
 259                 BADCVAR("g_dm");
 260                 BADCVAR("g_domination");
 261                 BADCVAR("g_domination_default_teams");
 262                 BADCVAR("g_freezetag");
 263                 BADCVAR("g_freezetag_teams");
 264                 BADCVAR("g_invasion_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_limit");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_freezetag_point_limit");
 314                 BADCVAR("g_freezetag_point_leadlimit");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_invasion_point_limit");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_tdm_point_limit");
 320                 BADCVAR("g_tdm_point_leadlimit");
 321                 BADCVAR("leadlimit_and_fraglimit");
 322                 BADCVAR("leadlimit_override");
 323                 BADCVAR("pausable");
 324                 BADCVAR("sv_allow_fullbright");
 325                 BADCVAR("sv_checkforpacketsduringsleep");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_minigames");
 342                 BADPREFIX("sv_minigames_");
 343                 BADCVAR("sv_namechangetimer");
 344
 345                 // allowed changes to server admins (please sync this to server.cfg)
 346                 // vi commands:
 347                 //   :/"impure"/,$d
 348                 //   :g!,^\/\/[^ /],d
 349                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 350                 //   :%!sort
 351                 // yes, this does contain some redundant stuff, don't really care
 352                 BADCVAR("bot_config_file");
 353                 BADCVAR("bot_number");
 354                 BADCVAR("bot_prefix");
 355                 BADCVAR("bot_suffix");
 356                 BADCVAR("capturelimit_override");
 357                 BADCVAR("fraglimit_override");
 358                 BADCVAR("gametype");
 359                 BADCVAR("g_antilag");
 360                 BADCVAR("g_balance_teams");
 361                 BADCVAR("g_balance_teams_prevent_imbalance");
 362                 BADCVAR("g_balance_teams_scorefactor");
 363                 BADCVAR("g_ban_sync_trusted_servers");
 364                 BADCVAR("g_ban_sync_uri");
 365                 BADCVAR("g_ca_teams_override");
 366                 BADCVAR("g_ctf_ignore_frags");
 367                 BADCVAR("g_domination_point_limit");
 368                 BADCVAR("g_domination_teams_override");
 369                 BADCVAR("g_freezetag_teams_override");
 370                 BADCVAR("g_friendlyfire");
 371                 BADCVAR("g_fullbrightitems");
 372                 BADCVAR("g_fullbrightplayers");
 373                 BADCVAR("g_keyhunt_point_limit");
 374                 BADCVAR("g_keyhunt_teams_override");
 375                 BADCVAR("g_lms_lives_override");
 376                 BADCVAR("g_maplist");
 377                 BADCVAR("g_maplist_check_waypoints");
 378                 BADCVAR("g_maplist_mostrecent_count");
 379                 BADCVAR("g_maplist_shuffle");
 380                 BADCVAR("g_maplist_votable");
 381                 BADCVAR("g_maplist_votable_abstain");
 382                 BADCVAR("g_maplist_votable_nodetail");
 383                 BADCVAR("g_maplist_votable_suggestions");
 384                 BADCVAR("g_maxplayers");
 385                 BADCVAR("g_mirrordamage");
 386                 BADCVAR("g_nexball_goallimit");
 387                 BADCVAR("g_powerups");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_tdm_teams_override");
 390                 BADCVAR("g_warmup");
 391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_adminnick");
 403                 BADCVAR("sv_autoscreenshot");
 404                 BADCVAR("sv_autotaunt");
 405                 BADCVAR("sv_curl_defaulturl");
 406                 BADCVAR("sv_defaultcharacter");
 407                 BADCVAR("sv_defaultplayercolors");
 408                 BADCVAR("sv_defaultplayermodel");
 409                 BADCVAR("sv_defaultplayerskin");
 410                 BADCVAR("sv_maxidle");
 411                 BADCVAR("sv_maxrate");
 412                 BADCVAR("sv_motd");
 413                 BADCVAR("sv_public");
 414                 BADCVAR("sv_ready_restart");
 415                 BADCVAR("sv_status_privacy");
 416                 BADCVAR("sv_taunt");
 417                 BADCVAR("sv_vote_call");
 418                 BADCVAR("sv_vote_commands");
 419                 BADCVAR("sv_vote_majority_factor");
 420                 BADCVAR("sv_vote_master");
 421                 BADCVAR("sv_vote_master_commands");
 422                 BADCVAR("sv_vote_master_password");
 423                 BADCVAR("sv_vote_simple_majority_factor");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_instagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434                 BADCVAR("g_grappling_hook");
 435                 BADCVAR("g_jetpack");
 436
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for (;;)
 477         {
 478                 o = world.mins;
 479                 o.x += random() * (world.maxs.x - world.mins.x);
 480                 o.y += random() * (world.maxs.y - world.mins.y);
 481                 o.z += random() * (world.maxs.z - world.mins.z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 bool RandomSeed_Send(entity this, entity to, int sf)
 504 {
 505         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return true;
 508 }
 509 void RandomSeed_Think()
 510 {SELFPARAM();
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {SELFPARAM();
 518         randomseed = new(randomseed);
 519         make_pure(randomseed);
 520         randomseed.think = RandomSeed_Think;
 521         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 522
 523         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 524 }
 525
 526 spawnfunc(__init_dedicated_server)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e = spawn();
 538         e.think = GotoFirstMap;
 539         e.nextthink = time; // this is usually 1 at this point
 540
 541         e = new(info_player_deathmatch);  // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         static_init();
 547         static_init_late();
 548         static_init_precache();
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void __init_dedicated_server_shutdown() {
 555         MapInfo_Shutdown();
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 spawnfunc(worldspawn)
 565 {
 566         float fd, l, j, n;
 567         string s;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = true;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 580
 581         compressShortVector_init();
 582
 583         maxclients = 0;
 584         for (entity head = nextent(world); head; head = nextent(head))
 585         {
 586                 ++maxclients;
 587         }
 588
 589         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 590
 591         // needs to be done so early because of the constants they create
 592         static_init();
 593
 594         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 595
 596         TemporaryDB = db_create();
 597
 598         // 0 normal
 599         lightstyle(0, "m");
 600
 601         // 1 FLICKER (first variety)
 602         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 603
 604         // 2 SLOW STRONG PULSE
 605         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 606
 607         // 3 CANDLE (first variety)
 608         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 609
 610         // 4 FAST STROBE
 611         lightstyle(4, "mamamamamama");
 612
 613         // 5 GENTLE PULSE 1
 614         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 615
 616         // 6 FLICKER (second variety)
 617         lightstyle(6, "nmonqnmomnmomomno");
 618
 619         // 7 CANDLE (second variety)
 620         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 621
 622         // 8 CANDLE (third variety)
 623         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 624
 625         // 9 SLOW STROBE (fourth variety)
 626         lightstyle(9, "aaaaaaaazzzzzzzz");
 627
 628         // 10 FLUORESCENT FLICKER
 629         lightstyle(10, "mmamammmmammamamaaamammma");
 630
 631         // 11 SLOW PULSE NOT FADE TO BLACK
 632         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 633
 634         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 635
 636         // 63 testing
 637         lightstyle(63, "a");
 638
 639         if(autocvar_g_campaign)
 640                 CampaignPreInit();
 641
 642         Map_MarkAsRecent(mapname);
 643
 644         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 645
 646         InitGameplayMode();
 647         static_init_late();
 648         static_init_precache();
 649         readlevelcvars();
 650         GrappleHookInit();
 651
 652         player_count = 0;
 653         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 654         if(bot_waypoints_for_items == 1)
 655                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 656                         bot_waypoints_for_items = 0;
 657
 658         precache();
 659
 660         WaypointSprite_Init();
 661
 662         GameLogInit(); // prepare everything
 663         // NOTE for matchid:
 664         // changing the logic generating it is okay. But:
 665         // it HAS to stay <= 64 chars
 666         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 667         if(autocvar_sv_eventlog)
 668         {
 669                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 670                 matchid = strzone(s);
 671
 672                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 673                 s = ":gameinfo:mutators:LIST";
 674
 675                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 676                 s = ret_string;
 677
 678                 // initialiation stuff, not good in the mutator system
 679                 if(!autocvar_g_use_ammunition)
 680                         s = strcat(s, ":no_use_ammunition");
 681
 682                 // initialiation stuff, not good in the mutator system
 683                 if(autocvar_g_pickup_items == 0)
 684                         s = strcat(s, ":no_pickup_items");
 685                 if(autocvar_g_pickup_items > 0)
 686                         s = strcat(s, ":pickup_items");
 687
 688                 // initialiation stuff, not good in the mutator system
 689                 if(autocvar_g_weaponarena != "0")
 690                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 691
 692                 // TODO to mutator system
 693                 if(autocvar_g_norecoil)
 694                         s = strcat(s, ":norecoil");
 695
 696                 // TODO to mutator system
 697                 if(autocvar_g_powerups == 0)
 698                         s = strcat(s, ":no_powerups");
 699                 if(autocvar_g_powerups > 0)
 700                         s = strcat(s, ":powerups");
 701
 702                 GameLogEcho(s);
 703                 GameLogEcho(":gameinfo:end");
 704         }
 705         else
 706                 matchid = strzone(ftos(random()));
 707
 708         cvar_set("nextmap", "");
 709
 710         SetDefaultAlpha();
 711
 712         if(autocvar_g_campaign)
 713                 CampaignPostInit();
 714
 715         Ban_LoadBans();
 716
 717         MapInfo_Enumerate();
 718         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 719
 720         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 721         {
 722                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 723                 if(fd != -1)
 724                 {
 725                         while((s = fgets(fd)))
 726                         {
 727                                 l = tokenize_console(s);
 728                                 if(l < 2)
 729                                         continue;
 730                                 if(argv(0) == "cd")
 731                                 {
 732                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 733                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 734                                 }
 735                                 else if(argv(0) == "fog")
 736                                 {
 737                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 738                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 739                                 }
 740                                 else if(argv(0) == "set")
 741                                 {
 742                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 743                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 744                                 }
 745                                 else if(argv(0) != "//")
 746                                 {
 747                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 748                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 749                                 }
 750                         }
 751                         fclose(fd);
 752                 }
 753         }
 754
 755         WeaponStats_Init();
 756
 757         Nagger_Init();
 758
 759         next_pingtime = time + 5;
 760
 761         detect_maptype();
 762
 763         // set up information replies for clients and server to use
 764         maplist_reply = strzone(getmaplist());
 765         lsmaps_reply = strzone(getlsmaps());
 766         monsterlist_reply = strzone(getmonsterlist());
 767         for(int i = 0; i < 10; ++i)
 768         {
 769                 s = getrecords(i);
 770                 if (s)
 771                         records_reply[i] = strzone(s);
 772         }
 773         ladder_reply = strzone(getladder());
 774         rankings_reply = strzone(getrankings());
 775
 776         // begin other init
 777         ClientInit_Spawn();
 778         RandomSeed_Spawn();
 779         PingPLReport_Spawn();
 780
 781         CheatInit();
 782
 783         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 784
 785         // fill sv_curl_serverpackages from .serverpackage files
 786         if(autocvar_sv_curl_serverpackages_auto)
 787         {
 788                 s = "";
 789                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 790                 for(int i = 0; i < n; ++i)
 791                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 792                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 793                                 s = strcat(s, " ", argv(i));
 794                 fd = search_begin("*-serverpackage.txt", true, false);
 795                 if(fd >= 0)
 796                 {
 797                         j = search_getsize(fd);
 798                         for(int i = 0; i < j; ++i)
 799                                 s = strcat(s, " ", search_getfilename(fd, i));
 800                         search_end(fd);
 801                 }
 802                 fd = search_begin("*.serverpackage", true, false);
 803                 if(fd >= 0)
 804                 {
 805                         j = search_getsize(fd);
 806                         for(int i = 0; i < j; ++i)
 807                                 s = strcat(s, " ", search_getfilename(fd, i));
 808                         search_end(fd);
 809                 }
 810                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 811         }
 812
 813         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 814         modname = "Xonotic";
 815         // physics/balance/config changes that count as mod
 816         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 817                 modname = cvar_string("g_mod_physics");
 818         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 819                 modname = cvar_string("g_mod_balance");
 820         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 821                 modname = cvar_string("g_mod_config");
 822         // extra mutators that deserve to count as mod
 823         MUTATOR_CALLHOOK(SetModname);
 824
 825         // save it for later
 826         modname = strzone(modname);
 827
 828         WinningConditionHelper(); // set worldstatus
 829
 830         world_initialized = 1;
 831 }
 832
 833 spawnfunc(light)
 834 {
 835         //makestatic (self); // Who the f___ did that?
 836         remove(self);
 837 }
 838
 839 string GetGametype()
 840 {
 841         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 842 }
 843
 844 string GetMapname()
 845 {
 846         return mapname;
 847 }
 848
 849 float Map_Count, Map_Current;
 850 string Map_Current_Name;
 851
 852 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 853 float GetMaplistPosition()
 854 {
 855         float pos, idx;
 856         string map;
 857
 858         map = GetMapname();
 859         idx = autocvar_g_maplist_index;
 860
 861         if(idx >= 0)
 862                 if(idx < Map_Count)
 863                         if(map == argv(idx))
 864                                 return idx;
 865
 866         for(pos = 0; pos < Map_Count; ++pos)
 867                 if(map == argv(pos))
 868                         return pos;
 869
 870         // resume normal maplist rotation if current map is not in g_maplist
 871         return idx;
 872 }
 873
 874 float MapHasRightSize(string map)
 875 {
 876         float fh;
 877         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 878         if(autocvar_g_maplist_check_waypoints)
 879         {
 880                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 881                 if(!fexists(strcat("maps/", map, ".waypoints")))
 882                 {
 883                         LOG_TRACE(": no waypoints\n");
 884                         return false;
 885                 }
 886                 LOG_TRACE(": has waypoints\n");
 887         }
 888
 889         // open map size restriction file
 890         LOG_TRACE("opensize "); LOG_TRACE(map);
 891         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 892         if(fh >= 0)
 893         {
 894                 float mapmin, mapmax;
 895                 LOG_TRACE(": ok, ");
 896                 mapmin = stof(fgets(fh));
 897                 mapmax = stof(fgets(fh));
 898                 fclose(fh);
 899                 if(player_count < mapmin)
 900                 {
 901                         LOG_TRACE("not enough\n");
 902                         return false;
 903                 }
 904                 if(player_count > mapmax)
 905                 {
 906                         LOG_TRACE("too many\n");
 907                         return false;
 908                 }
 909                 LOG_TRACE("right size\n");
 910                 return true;
 911         }
 912         LOG_TRACE(": not found\n");
 913         return true;
 914 }
 915
 916 string Map_Filename(float position)
 917 {
 918         return strcat("maps/", argv(position), ".bsp");
 919 }
 920
 921 void Map_MarkAsRecent(string m)
 922 {
 923         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 924 }
 925
 926 float Map_IsRecent(string m)
 927 {
 928         return strhasword(autocvar_g_maplist_mostrecent, m);
 929 }
 930
 931 float Map_Check(float position, float pass)
 932 {
 933         string filename;
 934         string map_next;
 935         map_next = argv(position);
 936         if(pass <= 1)
 937         {
 938                 if(Map_IsRecent(map_next))
 939                         return 0;
 940         }
 941         filename = Map_Filename(position);
 942         if(MapInfo_CheckMap(map_next))
 943         {
 944                 if(pass == 2)
 945                         return 1;
 946                 if(MapHasRightSize(map_next))
 947                         return 1;
 948                 return 0;
 949         }
 950         else
 951                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
 952
 953         return 0;
 954 }
 955
 956 void Map_Goto_SetStr(string nextmapname)
 957 {
 958         if(getmapname_stored != "")
 959                 strunzone(getmapname_stored);
 960         if(nextmapname == "")
 961                 getmapname_stored = "";
 962         else
 963                 getmapname_stored = strzone(nextmapname);
 964 }
 965
 966 void Map_Goto_SetFloat(float position)
 967 {
 968         cvar_set("g_maplist_index", ftos(position));
 969         Map_Goto_SetStr(argv(position));
 970 }
 971
 972 void Map_Goto(float reinit)
 973 {
 974         MapInfo_LoadMap(getmapname_stored, reinit);
 975 }
 976
 977 // return codes of map selectors:
 978 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 979 //   -2 = permanent failure
 980 float() MaplistMethod_Iterate = // usual method
 981 {
 982         float pass, i;
 983
 984         LOG_TRACE("Trying MaplistMethod_Iterate\n");
 985
 986         for(pass = 1; pass <= 2; ++pass)
 987         {
 988                 for(i = 1; i < Map_Count; ++i)
 989                 {
 990                         float mapindex;
 991                         mapindex = (i + Map_Current) % Map_Count;
 992                         if(Map_Check(mapindex, pass))
 993                                 return mapindex;
 994                 }
 995         }
 996         return -1;
 997 }
 998
 999 float() MaplistMethod_Repeat = // fallback method
1000 {
1001         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1002
1003         if(Map_Check(Map_Current, 2))
1004                 return Map_Current;
1005         return -2;
1006 }
1007
1008 float() MaplistMethod_Random = // random map selection
1009 {
1010         float i, imax;
1011
1012         LOG_TRACE("Trying MaplistMethod_Random\n");
1013
1014         imax = 42;
1015
1016         for(i = 0; i <= imax; ++i)
1017         {
1018                 float mapindex;
1019                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1020                 if(Map_Check(mapindex, 1))
1021                         return mapindex;
1022         }
1023         return -1;
1024 }
1025
1026 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1027 // the exponent sets a bias on the map selection:
1028 // the higher the exponent, the less likely "shortly repeated" same maps are
1029 {
1030         float i, j, imax, insertpos;
1031
1032         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1033
1034         imax = 42;
1035
1036         for(i = 0; i <= imax; ++i)
1037         {
1038                 string newlist;
1039
1040                 // now reinsert this at another position
1041                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1042                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1043                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1044                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1045
1046                 // insert the current map there
1047                 newlist = "";
1048                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1049                         newlist = strcat(newlist, " ", argv(j));
1050                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1051                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1052                         newlist = strcat(newlist, " ", argv(j));
1053                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1054                 cvar_set("g_maplist", newlist);
1055                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1056
1057                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1058                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1059                 if(Map_Check(Map_Current, 1))
1060                         return Map_Current;
1061         }
1062         return -1;
1063 }
1064
1065 void Maplist_Init()
1066 {
1067         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1068         float i;
1069         for (i = 0; i < Map_Count; ++i)
1070                 if (Map_Check(i, 2))
1071                         break;
1072         if (i == Map_Count)
1073         {
1074                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1075                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1076                 if(autocvar_g_maplist_shuffle)
1077                         ShuffleMaplist();
1078                 localcmd("\nmenu_cmd sync\n");
1079                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1080         }
1081         if(Map_Count == 0)
1082                 error("empty maplist, cannot select a new map");
1083         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1084
1085         if(Map_Current_Name)
1086                 strunzone(Map_Current_Name);
1087         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1088         // this may or may not be correct, but who cares, in the worst case a map
1089         // isn't chosen in the first pass that should have been
1090 }
1091
1092 string GetNextMap()
1093 {
1094         float nextMap;
1095
1096         Maplist_Init();
1097         nextMap = -1;
1098
1099         if(nextMap == -1)
1100                 if(autocvar_g_maplist_shuffle > 0)
1101                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1102
1103         if(nextMap == -1)
1104                 if(autocvar_g_maplist_selectrandom)
1105                         nextMap = MaplistMethod_Random();
1106
1107         if(nextMap == -1)
1108                 nextMap = MaplistMethod_Iterate();
1109
1110         if(nextMap == -1)
1111                 nextMap = MaplistMethod_Repeat();
1112
1113         if(nextMap >= 0)
1114         {
1115                 Map_Goto_SetFloat(nextMap);
1116                 return getmapname_stored;
1117         }
1118
1119         return "";
1120 }
1121
1122 float DoNextMapOverride(float reinit)
1123 {
1124         if(autocvar_g_campaign)
1125         {
1126                 CampaignPostIntermission();
1127                 alreadychangedlevel = true;
1128                 return true;
1129         }
1130         if(autocvar_quit_when_empty)
1131         {
1132                 if(player_count <= currentbots)
1133                 {
1134                         localcmd("quit\n");
1135                         alreadychangedlevel = true;
1136                         return true;
1137                 }
1138         }
1139         if(autocvar_quit_and_redirect != "")
1140         {
1141                 redirection_target = strzone(autocvar_quit_and_redirect);
1142                 alreadychangedlevel = true;
1143                 return true;
1144         }
1145         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1146         {
1147                 localcmd("restart\n");
1148                 alreadychangedlevel = true;
1149                 return true;
1150         }
1151         if(autocvar_nextmap != "")
1152         {
1153                 string m;
1154                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1155                 cvar_set("nextmap",m);
1156
1157                 if(!m || gametypevote)
1158                         return false;
1159                 if(autocvar_sv_vote_gametype)
1160                 {
1161                         Map_Goto_SetStr(m);
1162                         return false;
1163                 }
1164
1165                 if(MapInfo_CheckMap(m))
1166                 {
1167                         Map_Goto_SetStr(m);
1168                         Map_Goto(reinit);
1169                         alreadychangedlevel = true;
1170                         return true;
1171                 }
1172         }
1173         if(!reinit && autocvar_lastlevel)
1174         {
1175                 cvar_settemp_restore();
1176                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1177                 alreadychangedlevel = true;
1178                 return true;
1179         }
1180         return false;
1181 }
1182
1183 void GotoNextMap(float reinit)
1184 {
1185         //string nextmap;
1186         //float n, nummaps;
1187         //string s;
1188         if (alreadychangedlevel)
1189                 return;
1190         alreadychangedlevel = true;
1191
1192         string nextMap;
1193
1194         nextMap = GetNextMap();
1195         if(nextMap == "")
1196                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1197         Map_Goto(reinit);
1198 }
1199
1200
1201 /*
1202 ============
1203 IntermissionThink
1204
1205 When the player presses attack or jump, change to the next level
1206 ============
1207 */
1208 .float autoscreenshot;
1209 void IntermissionThink()
1210 {SELFPARAM();
1211         FixIntermissionClient(self);
1212
1213         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1214         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1215
1216         if( (server_screenshot || client_screenshot)
1217                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1218         {
1219                 self.autoscreenshot = -1;
1220                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1221                 return;
1222         }
1223
1224         if (time < intermission_exittime)
1225                 return;
1226
1227         if(!mapvote_initialized)
1228                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1229                         return;
1230
1231         MapVote_Start();
1232 }
1233
1234 /*
1235 ============
1236 FindIntermission
1237
1238 Returns the entity to view from
1239 ============
1240 */
1241 /*
1242 entity FindIntermission()
1243 {
1244         local   entity spot;
1245         local   float cyc;
1246
1247 // look for info_intermission first
1248         spot = find (world, classname, "info_intermission");
1249         if (spot)
1250         {       // pick a random one
1251                 cyc = random() * 4;
1252                 while (cyc > 1)
1253                 {
1254                         spot = find (spot, classname, "info_intermission");
1255                         if (!spot)
1256                                 spot = find (spot, classname, "info_intermission");
1257                         cyc = cyc - 1;
1258                 }
1259                 return spot;
1260         }
1261
1262 // then look for the start position
1263         spot = find (world, classname, "info_player_start");
1264         if (spot)
1265                 return spot;
1266
1267 // testinfo_player_start is only found in regioned levels
1268         spot = find (world, classname, "testplayerstart");
1269         if (spot)
1270                 return spot;
1271
1272 // then look for the start position
1273         spot = find (world, classname, "info_player_deathmatch");
1274         if (spot)
1275                 return spot;
1276
1277         //objerror ("FindIntermission: no spot");
1278         return world;
1279 }
1280 */
1281
1282 /*
1283 ===============================================================================
1284
1285 RULES
1286
1287 ===============================================================================
1288 */
1289
1290 void DumpStats(float final)
1291 {
1292         float file;
1293         string s;
1294         float to_console;
1295         float to_eventlog;
1296         float to_file;
1297         float i;
1298
1299         to_console = autocvar_sv_logscores_console;
1300         to_eventlog = autocvar_sv_eventlog;
1301         to_file = autocvar_sv_logscores_file;
1302
1303         if(!final)
1304         {
1305                 to_console = true; // always print printstats replies
1306                 to_eventlog = false; // but never print them to the event log
1307         }
1308
1309         if(to_eventlog)
1310                 if(autocvar_sv_eventlog_console)
1311                         to_console = false; // otherwise we get the output twice
1312
1313         if(final)
1314                 s = ":scores:";
1315         else
1316                 s = ":status:";
1317         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1318
1319         if(to_console)
1320                 LOG_INFO(s, "\n");
1321         if(to_eventlog)
1322                 GameLogEcho(s);
1323
1324         file = -1;
1325         if(to_file)
1326         {
1327                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1328                 if(file == -1)
1329                         to_file = false;
1330                 else
1331                         fputs(file, strcat(s, "\n"));
1332         }
1333
1334         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1335         if(to_console)
1336                 LOG_INFO(s, "\n");
1337         if(to_eventlog)
1338                 GameLogEcho(s);
1339         if(to_file)
1340                 fputs(file, strcat(s, "\n"));
1341
1342         FOR_EACH_CLIENT(other)
1343         {
1344                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1345                 {
1346                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1347                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1348                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1349                                 s = strcat(s, ftos(other.team), ":");
1350                         else
1351                                 s = strcat(s, "spectator:");
1352
1353                         if(to_console)
1354                                 LOG_INFO(s, other.netname, "\n");
1355                         if(to_eventlog)
1356                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1357                         if(to_file)
1358                                 fputs(file, strcat(s, other.netname, "\n"));
1359                 }
1360         }
1361
1362         if(teamplay)
1363         {
1364                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1365                 if(to_console)
1366                         LOG_INFO(s, "\n");
1367                 if(to_eventlog)
1368                         GameLogEcho(s);
1369                 if(to_file)
1370                         fputs(file, strcat(s, "\n"));
1371
1372                 for(i = 1; i < 16; ++i)
1373                 {
1374                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1375                         s = strcat(s, ":", ftos(i));
1376                         if(to_console)
1377                                 LOG_INFO(s, "\n");
1378                         if(to_eventlog)
1379                                 GameLogEcho(s);
1380                         if(to_file)
1381                                 fputs(file, strcat(s, "\n"));
1382                 }
1383         }
1384
1385         if(to_console)
1386                 LOG_INFO(":end\n");
1387         if(to_eventlog)
1388                 GameLogEcho(":end");
1389         if(to_file)
1390         {
1391                 fputs(file, ":end\n");
1392                 fclose(file);
1393         }
1394 }
1395
1396 void FixIntermissionClient(entity e)
1397 {
1398         if(!e.autoscreenshot) // initial call
1399         {
1400                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1401                 e.health = -2342;
1402                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1403                 e.solid = SOLID_NOT;
1404                 e.movetype = MOVETYPE_NONE;
1405                 e.takedamage = DAMAGE_NO;
1406                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1407                 {
1408                     .entity weaponentity = weaponentities[slot];
1409                         if(e.(weaponentity))
1410                         {
1411                                 e.(weaponentity).effects = EF_NODRAW;
1412                                 if (e.(weaponentity).weaponchild)
1413                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1414                         }
1415                 }
1416                 if(IS_REAL_CLIENT(e))
1417                 {
1418                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1419                         RandomSelection_Init();
1420                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1421                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1422                         ));
1423                         if (RandomSelection_chosen_string != "")
1424                         {
1425                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1426                         }
1427                         msg_entity = e;
1428                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1429                 }
1430         }
1431 }
1432
1433 /*
1434 go to the next level for deathmatch
1435 only called if a time or frag limit has expired
1436 */
1437 void NextLevel()
1438 {
1439         gameover = true;
1440
1441         intermission_running = 1;
1442
1443 // enforce a wait time before allowing changelevel
1444         if(player_count > 0)
1445                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1446         else
1447                 intermission_exittime = -1;
1448
1449         /*
1450         WriteByte (MSG_ALL, SVC_CDTRACK);
1451         WriteByte (MSG_ALL, 3);
1452         WriteByte (MSG_ALL, 3);
1453         // done in FixIntermission
1454         */
1455
1456         //pos = FindIntermission ();
1457
1458         VoteReset();
1459
1460         DumpStats(true);
1461
1462         // send statistics
1463         PlayerStats_GameReport(true);
1464         WeaponStats_Shutdown();
1465
1466         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1467
1468         if(autocvar_sv_eventlog)
1469                 GameLogEcho(":gameover");
1470
1471         GameLogClose();
1472
1473         FOR_EACH_PLAYER(other) {
1474                 FixIntermissionClient(other);
1475                 if(other.winning)
1476                         bprint(other.netname, " ^7wins.\n");
1477         }
1478
1479         entity oldself = self;
1480         target_music_kill();
1481         self = oldself;
1482
1483         if(autocvar_g_campaign)
1484                 CampaignPreIntermission();
1485
1486         MUTATOR_CALLHOOK(MatchEnd);
1487
1488         localcmd("\nsv_hook_gameend\n");
1489 }
1490
1491 /*
1492 ============
1493 CheckRules_Player
1494
1495 Exit deathmatch games upon conditions
1496 ============
1497 */
1498 void CheckRules_Player()
1499 {SELFPARAM();
1500         if (gameover)   // someone else quit the game already
1501                 return;
1502
1503         if(self.deadflag == DEAD_NO)
1504                 self.play_time += frametime;
1505
1506         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1507         //   (div0: and that in CheckRules_World please)
1508 }
1509
1510
1511 float InitiateSuddenDeath()
1512 {
1513         // Check first whether normal overtimes could be added before initiating suddendeath mode
1514         // - for this timelimit_overtime needs to be >0 of course
1515         // - also check the winning condition calculated in the previous frame and only add normal overtime
1516         //   again, if at the point at which timelimit would be extended again, still no winner was found
1517         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1518         {
1519                 return 1; // need to call InitiateOvertime later
1520         }
1521         else
1522         {
1523                 if(!checkrules_suddendeathend)
1524                 {
1525                         if(autocvar_g_campaign)
1526                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1527                         else
1528                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1529                         if(g_race && !g_race_qualifying)
1530                                 race_StartCompleting();
1531                 }
1532                 return 0;
1533         }
1534 }
1535
1536 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1537 {
1538         ++checkrules_overtimesadded;
1539         //add one more overtime by simply extending the timelimit
1540         float tl;
1541         tl = autocvar_timelimit;
1542         tl += autocvar_timelimit_overtime;
1543         cvar_set("timelimit", ftos(tl));
1544
1545         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1546 }
1547
1548 float GetWinningCode(float fraglimitreached, float equality)
1549 {
1550         if(autocvar_g_campaign == 1)
1551                 if(fraglimitreached)
1552                         return WINNING_YES;
1553                 else
1554                         return WINNING_NO;
1555
1556         else
1557                 if(equality)
1558                         if(fraglimitreached)
1559                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1560                         else
1561                                 return WINNING_NEVER;
1562                 else
1563                         if(fraglimitreached)
1564                                 return WINNING_YES;
1565                         else
1566                                 return WINNING_NO;
1567 }
1568
1569 // set the .winning flag for exactly those players with a given field value
1570 void SetWinners(.float field, float value)
1571 {
1572         entity head;
1573         FOR_EACH_PLAYER(head)
1574                 head.winning = (head.(field) == value);
1575 }
1576
1577 // set the .winning flag for those players with a given field value
1578 void AddWinners(.float field, float value)
1579 {
1580         entity head;
1581         FOR_EACH_PLAYER(head)
1582                 if (head.(field) == value)
1583                         head.winning = 1;
1584 }
1585
1586 // clear the .winning flags
1587 void ClearWinners()
1588 {
1589         entity head;
1590         FOR_EACH_PLAYER(head)
1591                 head.winning = 0;
1592 }
1593
1594 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1595 // they win. Otherwise the defending team wins once the timelimit passes.
1596 void assault_new_round();
1597 float WinningCondition_Assault()
1598 {SELFPARAM();
1599         float status;
1600
1601         WinningConditionHelper(); // set worldstatus
1602
1603         status = WINNING_NO;
1604         // as the timelimit has not yet passed just assume the defending team will win
1605         if(assault_attacker_team == NUM_TEAM_1)
1606         {
1607                 SetWinners(team, NUM_TEAM_2);
1608         }
1609         else
1610         {
1611                 SetWinners(team, NUM_TEAM_1);
1612         }
1613
1614         entity ent;
1615         ent = find(world, classname, "target_assault_roundend");
1616         if(ent)
1617         {
1618                 if(ent.winning) // round end has been triggered by attacking team
1619                 {
1620                         bprint("ASSAULT: round completed...\n");
1621                         SetWinners(team, assault_attacker_team);
1622
1623                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1624
1625                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1626                         {
1627                                 status = WINNING_YES;
1628                         }
1629                         else
1630                         {
1631                                 WITH(entity, self, ent, assault_new_round());
1632                         }
1633                 }
1634         }
1635
1636         return status;
1637 }
1638
1639 void ShuffleMaplist()
1640 {
1641         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1642 }
1643
1644 float leaderfrags;
1645 float WinningCondition_Scores(float limit, float leadlimit)
1646 {
1647         float limitreached;
1648
1649         // TODO make everything use THIS winning condition (except LMS)
1650         WinningConditionHelper();
1651
1652         if(teamplay)
1653         {
1654                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1655                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1656                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1657                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1658         }
1659
1660         ClearWinners();
1661         if(WinningConditionHelper_winner)
1662                 WinningConditionHelper_winner.winning = 1;
1663         if(WinningConditionHelper_winnerteam >= 0)
1664                 SetWinners(team, WinningConditionHelper_winnerteam);
1665
1666         if(WinningConditionHelper_lowerisbetter)
1667         {
1668                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1669                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1670                 limit = -limit;
1671         }
1672
1673         if(WinningConditionHelper_zeroisworst)
1674                 leadlimit = 0; // not supported in this mode
1675
1676         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1677         // these modes always score in increments of 1, thus this makes sense
1678         {
1679                 if(leaderfrags != WinningConditionHelper_topscore)
1680                 {
1681                         leaderfrags = WinningConditionHelper_topscore;
1682
1683                         if (limit)
1684                         if (leaderfrags == limit - 1)
1685                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1686                         else if (leaderfrags == limit - 2)
1687                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1688                         else if (leaderfrags == limit - 3)
1689                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1690                 }
1691         }
1692
1693         limitreached = false;
1694         if(limit)
1695                 if(WinningConditionHelper_topscore >= limit)
1696                         limitreached = true;
1697         if(leadlimit)
1698         {
1699                 float leadlimitreached;
1700                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1701                 if(autocvar_leadlimit_and_fraglimit)
1702                         limitreached = (limitreached && leadlimitreached);
1703                 else
1704                         limitreached = (limitreached || leadlimitreached);
1705         }
1706
1707         if(limit)
1708                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1709
1710         return GetWinningCode(
1711                 WinningConditionHelper_topscore && limitreached,
1712                 WinningConditionHelper_equality
1713         );
1714 }
1715
1716 float WinningCondition_RanOutOfSpawns()
1717 {
1718         entity head;
1719
1720         if(have_team_spawns <= 0)
1721                 return WINNING_NO;
1722
1723         if(!autocvar_g_spawn_useallspawns)
1724                 return WINNING_NO;
1725
1726         if(!some_spawn_has_been_used)
1727                 return WINNING_NO;
1728
1729         team1_score = team2_score = team3_score = team4_score = 0;
1730
1731         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1732         {
1733                 if(head.team == NUM_TEAM_1)
1734                         team1_score = 1;
1735                 else if(head.team == NUM_TEAM_2)
1736                         team2_score = 1;
1737                 else if(head.team == NUM_TEAM_3)
1738                         team3_score = 1;
1739                 else if(head.team == NUM_TEAM_4)
1740                         team4_score = 1;
1741         }
1742
1743         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1744         {
1745                 if(head.team == NUM_TEAM_1)
1746                         team1_score = 1;
1747                 else if(head.team == NUM_TEAM_2)
1748                         team2_score = 1;
1749                 else if(head.team == NUM_TEAM_3)
1750                         team3_score = 1;
1751                 else if(head.team == NUM_TEAM_4)
1752                         team4_score = 1;
1753         }
1754
1755         ClearWinners();
1756         if(team1_score + team2_score + team3_score + team4_score == 0)
1757         {
1758                 checkrules_equality = true;
1759                 return WINNING_YES;
1760         }
1761         else if(team1_score + team2_score + team3_score + team4_score == 1)
1762         {
1763                 float t, i;
1764                 if(team1_score)
1765                         t = NUM_TEAM_1;
1766                 else if(team2_score)
1767                         t = NUM_TEAM_2;
1768                 else if(team3_score)
1769                         t = NUM_TEAM_3;
1770                 else // if(team4_score)
1771                         t = NUM_TEAM_4;
1772                 CheckAllowedTeams(world);
1773                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1774                 {
1775                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1776                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1777                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1778                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1779                 }
1780
1781                 AddWinners(team, t);
1782                 return WINNING_YES;
1783         }
1784         else
1785                 return WINNING_NO;
1786 }
1787
1788 /*
1789 ============
1790 CheckRules_World
1791
1792 Exit deathmatch games upon conditions
1793 ============
1794 */
1795 void CheckRules_World()
1796 {
1797         float timelimit;
1798         float fraglimit;
1799         float leadlimit;
1800
1801         VoteThink();
1802         MapVote_Think();
1803
1804         SetDefaultAlpha();
1805
1806         if (gameover)   // someone else quit the game already
1807         {
1808                 if(player_count == 0) // Nobody there? Then let's go to the next map
1809                         MapVote_Start();
1810                         // this will actually check the player count in the next frame
1811                         // again, but this shouldn't hurt
1812                 return;
1813         }
1814
1815         timelimit = autocvar_timelimit * 60;
1816         fraglimit = autocvar_fraglimit;
1817         leadlimit = autocvar_leadlimit;
1818
1819         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1820         {
1821                 if(timelimit > 0)
1822                         timelimit = 0; // timelimit is not made for warmup
1823                 if(fraglimit > 0)
1824                         fraglimit = 0; // no fraglimit for now
1825                 leadlimit = 0; // no leadlimit for now
1826         }
1827
1828         if(timelimit > 0)
1829         {
1830                 timelimit += game_starttime;
1831         }
1832         else if (timelimit < 0)
1833         {
1834                 // endmatch
1835                 NextLevel();
1836                 return;
1837         }
1838
1839         float wantovertime;
1840         wantovertime = 0;
1841
1842         if(timelimit > game_starttime)
1843                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1844         else
1845                 game_completion_ratio = 0;
1846
1847         if(checkrules_suddendeathend)
1848         {
1849                 if(!checkrules_suddendeathwarning)
1850                 {
1851                         checkrules_suddendeathwarning = true;
1852                         if(g_race && !g_race_qualifying)
1853                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1854                         else
1855                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1856                 }
1857         }
1858         else
1859         {
1860                 if (timelimit && time >= timelimit)
1861                 {
1862                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1863                         {
1864                                 float totalplayers;
1865                                 float playerswithlaps;
1866                                 float readyplayers;
1867                                 entity head;
1868                                 totalplayers = playerswithlaps = readyplayers = 0;
1869                                 FOR_EACH_PLAYER(head)
1870                                 {
1871                                         ++totalplayers;
1872                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1873                                                 ++playerswithlaps;
1874                                         if(head.ready)
1875                                                 ++readyplayers;
1876                                 }
1877
1878                                 // at least 2 of the players have completed a lap: start the RACE
1879                                 // otherwise, the players should end the qualifying on their own
1880                                 if(readyplayers || playerswithlaps >= 2)
1881                                 {
1882                                         checkrules_suddendeathend = 0;
1883                                         ReadyRestart(); // go to race
1884                                         return;
1885                                 }
1886                                 else
1887                                         wantovertime |= InitiateSuddenDeath();
1888                         }
1889                         else
1890                                 wantovertime |= InitiateSuddenDeath();
1891                 }
1892         }
1893
1894         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1895         {
1896                 NextLevel();
1897                 return;
1898         }
1899
1900         int checkrules_status = WinningCondition_RanOutOfSpawns();
1901         if(checkrules_status == WINNING_YES)
1902                 bprint("Hey! Someone ran out of spawns!\n");
1903         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1904                 checkrules_status = ret_float;
1905         else
1906                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1907
1908         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1909         {
1910                 checkrules_status = WINNING_NEVER;
1911                 checkrules_overtimesadded = -1;
1912                 wantovertime |= InitiateSuddenDeath();
1913         }
1914
1915         if(checkrules_status == WINNING_NEVER)
1916                 // equality cases! Nobody wins if the overtime ends in a draw.
1917                 ClearWinners();
1918
1919         if(wantovertime)
1920         {
1921                 if(checkrules_status == WINNING_NEVER)
1922                         InitiateOvertime();
1923                 else
1924                         checkrules_status = WINNING_YES;
1925         }
1926
1927         if(checkrules_suddendeathend)
1928                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1929                         checkrules_status = WINNING_YES;
1930
1931         if(checkrules_status == WINNING_YES)
1932         {
1933                 //print("WINNING\n");
1934                 NextLevel();
1935         }
1936 }
1937
1938 string GotoMap(string m)
1939 {
1940         m = GameTypeVote_MapInfo_FixName(m);
1941         if (!m)
1942                 return "The map you suggested is not available on this server.";
1943         if (!autocvar_sv_vote_gametype)
1944         if(!MapInfo_CheckMap(m))
1945                 return "The map you suggested does not support the current game mode.";
1946         cvar_set("nextmap", m);
1947         cvar_set("timelimit", "-1");
1948         if(mapvote_initialized || alreadychangedlevel)
1949         {
1950                 if(DoNextMapOverride(0))
1951                         return "Map switch initiated.";
1952                 else
1953                         return "Hm... no. For some reason I like THIS map more.";
1954         }
1955         else
1956                 return "Map switch will happen after scoreboard.";
1957 }
1958
1959
1960 void EndFrame()
1961 {SELFPARAM();
1962         anticheat_endframe();
1963
1964         float altime;
1965         entity e_;
1966         FOR_EACH_REALCLIENT(e_)
1967         {
1968                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
1969                 if(e.typehitsound)
1970                         e_.typehit_time = time;
1971                 else if(e.damage_dealt)
1972                 {
1973                         e_.hit_time = time;
1974                         e_.damage_dealt_total += ceil(e.damage_dealt);
1975                 }
1976         }
1977         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
1978         // add 1 frametime because after this, engine SV_Physics
1979         // increases time by a frametime and then networks the frame
1980         // add another frametime because client shows everything with
1981         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
1982         // needed!
1983         FOR_EACH_CLIENT(e_)
1984         {
1985                 e_.typehitsound = false;
1986                 e_.damage_dealt = 0;
1987                 setself(e_);
1988                 antilag_record(e_, altime);
1989         }
1990         FOR_EACH_MONSTER(e_)
1991         {
1992                 setself(e_);
1993                 antilag_record(e_, altime);
1994         }
1995         FOREACH_CLIENT(PS(it), {
1996                 PlayerState s = PS(it);
1997                 s.ps_push(s, it);
1998         });
1999 }
2000
2001
2002 /*
2003  * RedirectionThink:
2004  * returns true if redirecting
2005  */
2006 float redirection_timeout;
2007 float redirection_nextthink;
2008 float RedirectionThink()
2009 {SELFPARAM();
2010         float clients_found;
2011
2012         if(redirection_target == "")
2013                 return false;
2014
2015         if(!redirection_timeout)
2016         {
2017                 cvar_set("sv_public", "-2");
2018                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2019                 if(redirection_target == "self")
2020                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2021                 else
2022                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2023         }
2024
2025         if(time < redirection_nextthink)
2026                 return true;
2027
2028         redirection_nextthink = time + 1;
2029
2030         clients_found = 0;
2031         entity e;
2032         FOR_EACH_REALCLIENT(e)
2033         {
2034                 setself(e);
2035                 // TODO add timer
2036                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2037                 if(redirection_target == "self")
2038                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2039                 else
2040                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2041                 ++clients_found;
2042         }
2043
2044         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2045
2046         if(time > redirection_timeout || clients_found == 0)
2047                 localcmd("\nwait; wait; wait; quit\n");
2048
2049         return true;
2050 }
2051
2052 void TargetMusic_RestoreGame();
2053 void RestoreGame()
2054 {
2055         // Loaded from a save game
2056         // some things then break, so let's work around them...
2057
2058         // Progs DB (capture records)
2059         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2060
2061         // Mapinfo
2062         MapInfo_Shutdown();
2063         MapInfo_Enumerate();
2064         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2065         WeaponStats_Init();
2066
2067         TargetMusic_RestoreGame();
2068 }
2069
2070 void Shutdown()
2071 {
2072         gameover = 2;
2073
2074         if(world_initialized > 0)
2075         {
2076                 world_initialized = 0;
2077                 LOG_TRACE("Saving persistent data...\n");
2078                 Ban_SaveBans();
2079
2080                 // playerstats with unfinished match
2081                 PlayerStats_GameReport(false);
2082
2083                 if(!cheatcount_total)
2084                 {
2085                         if(autocvar_sv_db_saveasdump)
2086                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2087                         else
2088                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2089                 }
2090                 if(autocvar_developer)
2091                 {
2092                         if(autocvar_sv_db_saveasdump)
2093                                 db_dump(TemporaryDB, "server-temp.db");
2094                         else
2095                                 db_save(TemporaryDB, "server-temp.db");
2096                 }
2097                 CheatShutdown(); // must be after cheatcount check
2098                 db_close(ServerProgsDB);
2099                 db_close(TemporaryDB);
2100                 LOG_TRACE("Saving persistent data... done!\n");
2101                 // tell the bot system the game is ending now
2102                 bot_endgame();
2103
2104                 WeaponStats_Shutdown();
2105                 MapInfo_Shutdown();
2106         }
2107         else if(world_initialized == 0)
2108         {
2109                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2110         }
2111         else
2112         {
2113                 __init_dedicated_server_shutdown();
2114         }
2115 }