qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_arena_point_leadlimit");
 307                 BADCVAR("g_balance_kill_delay");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_keyhunt_point_leadlimit");
 315                 BADPREFIX("g_mod_");
 316                 BADCVAR("g_nexball_goalleadlimit");
 317                 BADCVAR("leadlimit_and_fraglimit");
 318                 BADCVAR("leadlimit_override");
 319                 BADCVAR("pausable");
 320                 BADCVAR("sv_allow_fullbright");
 321                 BADCVAR("sv_checkforpacketsduringsleep");
 322                 BADCVAR("sv_fraginfo");
 323                 BADCVAR("sv_timeout");
 324                 BADPREFIX("sv_timeout_");
 325                 BADCVAR("welcome_message_time");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ctf_ignore_frags");
 363                 BADCVAR("g_domination_point_limit");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("sys_ticrate");
 418                 BADCVAR("teamplay_mode");
 419                 BADCVAR("timelimit_override");
 420                 BADCVAR("g_spawnshieldtime");
 421                 BADPREFIX("g_warmup_");
 422                 BADPREFIX("sv_ready_restart_");
 423
 424                 // mutators that announce themselves properly to the server browser
 425                 BADCVAR("g_minstagib");
 426                 BADCVAR("g_new_toys");
 427                 BADCVAR("g_nix");
 428                 BADCVAR("g_grappling_hook");
 429                 BADCVAR("g_jetpack");
 430
 431 #undef BADPREFIX
 432 #undef BADCVAR
 433
 434                 if(pureadding)
 435                 {
 436                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 437                         if(strlen(cvar_purechanges) > 16384)
 438                         {
 439                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 440                                 pureadding = 0;
 441                         }
 442                 }
 443                 ++cvar_purechanges_count;
 444                 // WARNING: this variable is used for the server list
 445                 // NEVER dare to skip this code!
 446                 // Hacks to intentionally appearing as "pure server" even though you DO have
 447                 // modified settings may be punished by removal from the server list.
 448                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 449                 // though.
 450         }
 451         buf_del(h);
 452         if(cvar_changes == "")
 453                 cvar_changes = "// this server runs at default server settings\n";
 454         else
 455                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 456         cvar_changes = strzone(cvar_changes);
 457         if(cvar_purechanges == "")
 458                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 459         else
 460                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 461         cvar_purechanges = strzone(cvar_purechanges);
 462 }
 463
 464 void detect_maptype()
 465 {
 466 #if 0
 467         vector o, v;
 468         float i;
 469
 470         for(;;)
 471         {
 472                 o = world.mins;
 473                 o_x += random() * (world.maxs_x - world.mins_x);
 474                 o_y += random() * (world.maxs_y - world.mins_y);
 475                 o_z += random() * (world.maxs_z - world.mins_z);
 476
 477                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 478                 if(trace_fraction == 1)
 479                         continue;
 480
 481                 v = trace_endpos;
 482
 483                 for(i = 0; i < 64; i += 4)
 484                 {
 485                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 486         if(trace_fraction == 1)
 487                 continue;
 488                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 489                 }
 490
 491                 break;
 492         }
 493 #endif
 494 }
 495
 496 entity randomseed;
 497 float RandomSeed_Send(entity to, float sf)
 498 {
 499         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 500         WriteShort(MSG_ENTITY, self.cnt);
 501         return TRUE;
 502 }
 503 void RandomSeed_Think()
 504 {
 505         self.cnt = bound(0, floor(random() * 65536), 65535);
 506         self.nextthink = time + 5;
 507
 508         self.SendFlags |= 1;
 509 }
 510 void RandomSeed_Spawn()
 511 {
 512         randomseed = spawn();
 513         randomseed.think = RandomSeed_Think;
 514         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 515
 516         entity oldself;
 517         oldself = self;
 518         self = randomseed;
 519         self.think(); // sets random seed and nextthink
 520         self = oldself;
 521 }
 522
 523 void spawnfunc___init_dedicated_server(void)
 524 {
 525         // handler for _init/_init map (only for dedicated server initialization)
 526
 527         world_initialized = -1; // don't complain
 528         cvar = cvar_normal;
 529         cvar_string = cvar_string_normal;
 530         cvar_set = cvar_set_normal;
 531
 532         remove = remove_unsafely;
 533
 534         entity e;
 535         e = spawn();
 536         e.think = GotoFirstMap;
 537         e.nextthink = time; // this is usually 1 at this point
 538
 539         e = spawn();
 540         e.classname = "info_player_deathmatch"; // safeguard against player joining
 541
 542         self.classname = "worldspawn"; // safeguard against various stuff ;)
 543
 544         // needs to be done so early because of the constants they create
 545         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s, col;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         allowed_to_spawn = TRUE;
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 597         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 598         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_midair)
 710                         s = strcat(s, ":midair");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_powerups == 0)
 714                         s = strcat(s, ":no_powerups");
 715                 if(autocvar_g_powerups > 0)
 716                         s = strcat(s, ":powerups");
 717
 718                 GameLogEcho(s);
 719                 GameLogEcho(":gameinfo:end");
 720         }
 721         else
 722                 matchid = strzone(ftos(random()));
 723
 724         cvar_set("nextmap", "");
 725
 726         SetDefaultAlpha();
 727
 728         if(autocvar_g_campaign)
 729                 CampaignPostInit();
 730
 731         fteqcc_testbugs();
 732
 733         Ban_LoadBans();
 734
 735         MapInfo_Enumerate();
 736         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 737
 738         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 739         {
 740                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 741                 if(fd != -1)
 742                 {
 743                         while((s = fgets(fd)))
 744                         {
 745                                 l = tokenize_console(s);
 746                                 if(l < 2)
 747                                         continue;
 748                                 if(argv(0) == "cd")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 751                                         print("  cdtrack ", argv(2), "\n");
 752                                 }
 753                                 else if(argv(0) == "fog")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 756                                         print("  \"fog\" \"", s, "\"\n");
 757                                 }
 758                                 else if(argv(0) == "set")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) != "//")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 767                                 }
 768                         }
 769                         fclose(fd);
 770                 }
 771         }
 772
 773         WeaponStats_Init();
 774
 775         WEPSET_ADDSTAT();
 776         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 777         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 778         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 779         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 780         Nagger_Init();
 781
 782         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 783         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 784         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 785         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 786         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 787         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 788         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 789         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 790         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 791         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 792         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 793         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 794         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 795
 796         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 797         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 798
 799         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 800
 801         if(g_ca || g_freezetag)
 802         {
 803                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 804                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 805                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 806                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 807         }
 808         if(g_freezetag)
 809         {
 810                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 811                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 812         }
 813
 814         // g_movementspeed hack
 815         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 816         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 817         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 818         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 819
 820         // secrets
 821         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 822         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 823
 824         // misc
 825         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 826
 827         next_pingtime = time + 5;
 828
 829         detect_maptype();
 830
 831         // set up information replies for clients and server to use
 832         lsmaps_reply = "^7Maps available: ";
 833         lsnewmaps_reply = "^7Maps without a record set: ";
 834         for(i = 0, j = 0; i < MapInfo_count; ++i)
 835         {
 836                 if(MapInfo_Get_ByID(i))
 837                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 838                         {
 839                                 if(mod(i, 2))
 840                                         col = "^2";
 841                                 else
 842                                         col = "^3";
 843
 844                                 ++j;
 845
 846                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 847
 848                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 849                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 850                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 851                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 852                         }
 853         }
 854
 855         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 856         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 857
 858         maplist_reply = "^7Maps in list: ";
 859         n = tokenize_console(autocvar_g_maplist);
 860         for(i = 0, j = 0; i < n; ++i)
 861         {
 862                 if(MapInfo_CheckMap(argv(i)))
 863                 {
 864                         if(mod(j, 2))
 865                                 col = "^2";
 866                         else
 867                                 col = "^3";
 868                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 869                         ++j;
 870                 }
 871         }
 872         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 873         MapInfo_ClearTemps();
 874
 875         for(i = 0; i < 10; ++i)
 876         {
 877                 s = getrecords(i);
 878                 if (s)
 879                         records_reply[i] = strzone(s);
 880         }
 881
 882         ladder_reply = strzone(getladder());
 883
 884         rankings_reply = strzone(getrankings());
 885
 886         // begin other init
 887         ClientInit_Spawn();
 888         RandomSeed_Spawn();
 889         PingPLReport_Spawn();
 890
 891         CheatInit();
 892
 893         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 894
 895         // fill sv_curl_serverpackages from .serverpackage files
 896         if(autocvar_sv_curl_serverpackages_auto)
 897         {
 898                 s = "";
 899                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 900                 for(i = 0; i < n; ++i)
 901                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 902                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 903                                 s = strcat(s, " ", argv(i));
 904                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 905                 if(fd >= 0)
 906                 {
 907                         j = search_getsize(fd);
 908                         for(i = 0; i < j; ++i)
 909                                 s = strcat(s, " ", search_getfilename(fd, i));
 910                         search_end(fd);
 911                 }
 912                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 913                 if(fd >= 0)
 914                 {
 915                         j = search_getsize(fd);
 916                         for(i = 0; i < j; ++i)
 917                                 s = strcat(s, " ", search_getfilename(fd, i));
 918                         search_end(fd);
 919                 }
 920                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 921         }
 922
 923         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 924         modname = "Xonotic";
 925         // physics/balance/config changes that count as mod
 926         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 927                 modname = cvar_string("g_mod_physics");
 928         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 929                 modname = cvar_string("g_mod_balance");
 930         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 931                 modname = cvar_string("g_mod_config");
 932         // extra mutators that deserve to count as mod
 933         MUTATOR_CALLHOOK(SetModname);
 934
 935         // save it for later
 936         modname = strzone(modname);
 937
 938         WinningConditionHelper(); // set worldstatus
 939
 940         world_initialized = 1;
 941 }
 942
 943 void spawnfunc_light (void)
 944 {
 945         //makestatic (self); // Who the f___ did that?
 946         remove(self);
 947 }
 948
 949 string GetGametype()
 950 {
 951         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 952 }
 953
 954 string getmapname_stored;
 955 string GetMapname()
 956 {
 957         return mapname;
 958 }
 959
 960 float Map_Count, Map_Current;
 961 string Map_Current_Name;
 962
 963 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 964 float GetMaplistPosition()
 965 {
 966         float pos, idx;
 967         string map;
 968
 969         map = GetMapname();
 970         idx = autocvar_g_maplist_index;
 971
 972         if(idx >= 0)
 973                 if(idx < Map_Count)
 974                         if(map == argv(idx))
 975                                 return idx;
 976
 977         for(pos = 0; pos < Map_Count; ++pos)
 978                 if(map == argv(pos))
 979                         return pos;
 980
 981         // resume normal maplist rotation if current map is not in g_maplist
 982         return idx;
 983 }
 984
 985 float MapHasRightSize(string map)
 986 {
 987         float fh;
 988         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 989         if(autocvar_g_maplist_check_waypoints)
 990         {
 991                 dprint("checkwp "); dprint(map);
 992                 if(!fexists(strcat("maps/", map, ".waypoints")))
 993                 {
 994                         dprint(": no waypoints\n");
 995                         return FALSE;
 996                 }
 997                 dprint(": has waypoints\n");
 998         }
 999
1000         // open map size restriction file
1001         dprint("opensize "); dprint(map);
1002         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1003         if(fh >= 0)
1004         {
1005                 float mapmin, mapmax;
1006                 dprint(": ok, ");
1007                 mapmin = stof(fgets(fh));
1008                 mapmax = stof(fgets(fh));
1009                 fclose(fh);
1010                 if(player_count < mapmin)
1011                 {
1012                         dprint("not enough\n");
1013                         return FALSE;
1014                 }
1015                 if(player_count > mapmax)
1016                 {
1017                         dprint("too many\n");
1018                         return FALSE;
1019                 }
1020                 dprint("right size\n");
1021                 return TRUE;
1022         }
1023         dprint(": not found\n");
1024         return TRUE;
1025 }
1026
1027 string Map_Filename(float position)
1028 {
1029         return strcat("maps/", argv(position), ".bsp");
1030 }
1031
1032 string strwords(string s, float w)
1033 {
1034         float endpos;
1035         for(endpos = 0; w && endpos >= 0; --w)
1036                 endpos = strstrofs(s, " ", endpos + 1);
1037         if(endpos < 0)
1038                 return s;
1039         else
1040                 return substring(s, 0, endpos);
1041 }
1042
1043 float strhasword(string s, string w)
1044 {
1045         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1046 }
1047
1048 void Map_MarkAsRecent(string m)
1049 {
1050         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1051 }
1052
1053 float Map_IsRecent(string m)
1054 {
1055         return strhasword(autocvar_g_maplist_mostrecent, m);
1056 }
1057
1058 float Map_Check(float position, float pass)
1059 {
1060         string filename;
1061         string map_next;
1062         map_next = argv(position);
1063         if(pass <= 1)
1064         {
1065                 if(Map_IsRecent(map_next))
1066                         return 0;
1067         }
1068         filename = Map_Filename(position);
1069         if(MapInfo_CheckMap(map_next))
1070         {
1071                 if(pass == 2)
1072                         return 1;
1073                 if(MapHasRightSize(map_next))
1074                         return 1;
1075                 return 0;
1076         }
1077         else
1078                 dprint( "Couldn't select '", filename, "'..\n" );
1079
1080         return 0;
1081 }
1082
1083 void Map_Goto_SetStr(string nextmapname)
1084 {
1085         if(getmapname_stored != "")
1086                 strunzone(getmapname_stored);
1087         if(nextmapname == "")
1088                 getmapname_stored = "";
1089         else
1090                 getmapname_stored = strzone(nextmapname);
1091 }
1092
1093 void Map_Goto_SetFloat(float position)
1094 {
1095         cvar_set("g_maplist_index", ftos(position));
1096         Map_Goto_SetStr(argv(position));
1097 }
1098
1099 void Map_Goto(float reinit)
1100 {
1101         MapInfo_LoadMap(getmapname_stored, reinit);
1102 }
1103
1104 // return codes of map selectors:
1105 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1106 //   -2 = permanent failure
1107 float() MaplistMethod_Iterate = // usual method
1108 {
1109         float pass, i;
1110
1111         for(pass = 1; pass <= 2; ++pass)
1112         {
1113                 for(i = 1; i < Map_Count; ++i)
1114                 {
1115                         float mapindex;
1116                         mapindex = mod(i + Map_Current, Map_Count);
1117                         if(Map_Check(mapindex, pass))
1118                                 return mapindex;
1119                 }
1120         }
1121         return -1;
1122 }
1123
1124 float() MaplistMethod_Repeat = // fallback method
1125 {
1126         if(Map_Check(Map_Current, 2))
1127                 return Map_Current;
1128         return -2;
1129 }
1130
1131 float() MaplistMethod_Random = // random map selection
1132 {
1133         float i, imax;
1134
1135         imax = 42;
1136
1137         for(i = 0; i <= imax; ++i)
1138         {
1139                 float mapindex;
1140                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1141                 if(Map_Check(mapindex, 1))
1142                         return mapindex;
1143         }
1144         return -1;
1145 }
1146
1147 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1148 // the exponent sets a bias on the map selection:
1149 // the higher the exponent, the less likely "shortly repeated" same maps are
1150 {
1151         float i, j, imax, insertpos;
1152
1153         imax = 42;
1154
1155         for(i = 0; i <= imax; ++i)
1156         {
1157                 string newlist;
1158
1159                 // now reinsert this at another position
1160                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1161                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1162                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1163                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1164
1165                 // insert the current map there
1166                 newlist = "";
1167                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1168                         newlist = strcat(newlist, " ", argv(j));
1169                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1170                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1171                         newlist = strcat(newlist, " ", argv(j));
1172                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1173                 cvar_set("g_maplist", newlist);
1174                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1175
1176                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1177                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1178                 if(Map_Check(Map_Current, 1))
1179                         return Map_Current;
1180         }
1181         return -1;
1182 }
1183
1184 void Maplist_Init()
1185 {
1186         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187         if(Map_Count == 0)
1188         {
1189                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1190                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1191                 if(autocvar_g_maplist_shuffle)
1192                         ShuffleMaplist();
1193                 localcmd("\nmenu_cmd sync\n");
1194                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         }
1196         if(Map_Count == 0)
1197                 error("empty maplist, cannot select a new map");
1198         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1199
1200         if(Map_Current_Name)
1201                 strunzone(Map_Current_Name);
1202         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1203         // this may or may not be correct, but who cares, in the worst case a map
1204         // isn't chosen in the first pass that should have been
1205 }
1206
1207 string GetNextMap()
1208 {
1209         float nextMap;
1210
1211         Maplist_Init();
1212         nextMap = -1;
1213
1214         if(nextMap == -1)
1215                 if(autocvar_g_maplist_shuffle > 0)
1216                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1217
1218         if(nextMap == -1)
1219                 if(autocvar_g_maplist_selectrandom)
1220                         nextMap = MaplistMethod_Random();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Iterate();
1224
1225         if(nextMap == -1)
1226                 nextMap = MaplistMethod_Repeat();
1227
1228         if(nextMap >= 0)
1229         {
1230                 Map_Goto_SetFloat(nextMap);
1231                 return getmapname_stored;
1232         }
1233
1234         return "";
1235 }
1236
1237 float DoNextMapOverride(float reinit)
1238 {
1239         if(autocvar_g_campaign)
1240         {
1241                 CampaignPostIntermission();
1242                 alreadychangedlevel = TRUE;
1243                 return TRUE;
1244         }
1245         if(autocvar_quit_when_empty)
1246         {
1247                 if(player_count <= currentbots)
1248                 {
1249                         localcmd("quit\n");
1250                         alreadychangedlevel = TRUE;
1251                         return TRUE;
1252                 }
1253         }
1254         if(autocvar_quit_and_redirect != "")
1255         {
1256                 redirection_target = strzone(autocvar_quit_and_redirect);
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1261         {
1262                 localcmd("restart\n");
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if(autocvar_nextmap != "")
1267                 if(MapInfo_CheckMap(autocvar_nextmap))
1268                 {
1269                         Map_Goto_SetStr(autocvar_nextmap);
1270                         Map_Goto(reinit);
1271                         alreadychangedlevel = TRUE;
1272                         return TRUE;
1273                 }
1274         if(!reinit && autocvar_lastlevel)
1275         {
1276                 cvar_settemp_restore();
1277                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1278                 alreadychangedlevel = TRUE;
1279                 return TRUE;
1280         }
1281         return FALSE;
1282 }
1283
1284 void GotoNextMap(float reinit)
1285 {
1286         //string nextmap;
1287         //float n, nummaps;
1288         //string s;
1289         if (alreadychangedlevel)
1290                 return;
1291         alreadychangedlevel = TRUE;
1292
1293         {
1294                 string nextMap;
1295                 float allowReset;
1296
1297                 for(allowReset = 1; allowReset >= 0; --allowReset)
1298                 {
1299                         nextMap = GetNextMap();
1300                         if(nextMap != "")
1301                                 break;
1302
1303                         if(allowReset)
1304                         {
1305                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1306                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1307                                 if(autocvar_g_maplist_shuffle)
1308                                         ShuffleMaplist();
1309                                 localcmd("\nmenu_cmd sync\n");
1310                         }
1311                         else
1312                         {
1313                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1314                         }
1315                 }
1316                 Map_Goto(reinit);
1317         }
1318 }
1319
1320
1321 /*
1322 ============
1323 IntermissionThink
1324
1325 When the player presses attack or jump, change to the next level
1326 ============
1327 */
1328 .float autoscreenshot;
1329 void() MapVote_Start;
1330 void() MapVote_Think;
1331 float mapvote_initialized;
1332 void IntermissionThink()
1333 {
1334         FixIntermissionClient(self);
1335
1336         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1337         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1338
1339         if( (server_screenshot || client_screenshot)
1340                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1341         {
1342                 self.autoscreenshot = -1;
1343                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1344                 return;
1345         }
1346
1347         if (time < intermission_exittime)
1348                 return;
1349
1350         if(!mapvote_initialized)
1351                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1352                         return;
1353
1354         MapVote_Start();
1355 }
1356
1357 /*
1358 ============
1359 FindIntermission
1360
1361 Returns the entity to view from
1362 ============
1363 */
1364 /*
1365 entity FindIntermission()
1366 {
1367         local   entity spot;
1368         local   float cyc;
1369
1370 // look for info_intermission first
1371         spot = find (world, classname, "info_intermission");
1372         if (spot)
1373         {       // pick a random one
1374                 cyc = random() * 4;
1375                 while (cyc > 1)
1376                 {
1377                         spot = find (spot, classname, "info_intermission");
1378                         if (!spot)
1379                                 spot = find (spot, classname, "info_intermission");
1380                         cyc = cyc - 1;
1381                 }
1382                 return spot;
1383         }
1384
1385 // then look for the start position
1386         spot = find (world, classname, "info_player_start");
1387         if (spot)
1388                 return spot;
1389
1390 // testinfo_player_start is only found in regioned levels
1391         spot = find (world, classname, "testplayerstart");
1392         if (spot)
1393                 return spot;
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_deathmatch");
1397         if (spot)
1398                 return spot;
1399
1400         //objerror ("FindIntermission: no spot");
1401         return world;
1402 }
1403 */
1404
1405 /*
1406 ===============================================================================
1407
1408 RULES
1409
1410 ===============================================================================
1411 */
1412
1413 void DumpStats(float final)
1414 {
1415         float file;
1416         string s;
1417         float to_console;
1418         float to_eventlog;
1419         float to_file;
1420         float i;
1421
1422         to_console = autocvar_sv_logscores_console;
1423         to_eventlog = autocvar_sv_eventlog;
1424         to_file = autocvar_sv_logscores_file;
1425
1426         if(!final)
1427         {
1428                 to_console = TRUE; // always print printstats replies
1429                 to_eventlog = FALSE; // but never print them to the event log
1430         }
1431
1432         if(to_eventlog)
1433                 if(autocvar_sv_eventlog_console)
1434                         to_console = FALSE; // otherwise we get the output twice
1435
1436         if(final)
1437                 s = ":scores:";
1438         else
1439                 s = ":status:";
1440         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1441
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446
1447         file = -1;
1448         if(to_file)
1449         {
1450                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1451                 if(file == -1)
1452                         to_file = FALSE;
1453                 else
1454                         fputs(file, strcat(s, "\n"));
1455         }
1456
1457         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1458         if(to_console)
1459                 print(s, "\n");
1460         if(to_eventlog)
1461                 GameLogEcho(s);
1462         if(to_file)
1463                 fputs(file, strcat(s, "\n"));
1464
1465         FOR_EACH_CLIENT(other)
1466         {
1467                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1468                 {
1469                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1470                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1471                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1472                                 s = strcat(s, ftos(other.team), ":");
1473                         else
1474                                 s = strcat(s, "spectator:");
1475
1476                         if(to_console)
1477                                 print(s, other.netname, "\n");
1478                         if(to_eventlog)
1479                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1480                         if(to_file)
1481                                 fputs(file, strcat(s, other.netname, "\n"));
1482                 }
1483         }
1484
1485         if(teamplay)
1486         {
1487                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1488                 if(to_console)
1489                         print(s, "\n");
1490                 if(to_eventlog)
1491                         GameLogEcho(s);
1492                 if(to_file)
1493                         fputs(file, strcat(s, "\n"));
1494
1495                 for(i = 1; i < 16; ++i)
1496                 {
1497                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1498                         s = strcat(s, ":", ftos(i));
1499                         if(to_console)
1500                                 print(s, "\n");
1501                         if(to_eventlog)
1502                                 GameLogEcho(s);
1503                         if(to_file)
1504                                 fputs(file, strcat(s, "\n"));
1505                 }
1506         }
1507
1508         if(to_console)
1509                 print(":end\n");
1510         if(to_eventlog)
1511                 GameLogEcho(":end");
1512         if(to_file)
1513         {
1514                 fputs(file, ":end\n");
1515                 fclose(file);
1516         }
1517 }
1518
1519 void FixIntermissionClient(entity e)
1520 {
1521         string s;
1522         if(!e.autoscreenshot) // initial call
1523         {
1524                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1525                 e.health = -2342;
1526                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1527                 e.solid = SOLID_NOT;
1528                 e.movetype = MOVETYPE_NONE;
1529                 e.takedamage = DAMAGE_NO;
1530                 if(e.weaponentity)
1531                 {
1532                         e.weaponentity.effects = EF_NODRAW;
1533                         if (e.weaponentity.weaponentity)
1534                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1535                 }
1536                 if(clienttype(e) == CLIENTTYPE_REAL)
1537                 {
1538                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1539                         s = autocvar_sv_intermission_cdtrack;
1540                         if(s != "")
1541                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1542                         msg_entity = e;
1543                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1544                 }
1545         }
1546 }
1547
1548 void minstagib_stop_countdown(entity e);
1549 /*
1550 go to the next level for deathmatch
1551 only called if a time or frag limit has expired
1552 */
1553 void NextLevel()
1554 {
1555         gameover = TRUE;
1556
1557         intermission_running = 1;
1558
1559 // enforce a wait time before allowing changelevel
1560         if(player_count > 0)
1561                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1562         else
1563                 intermission_exittime = -1;
1564
1565         /*
1566         WriteByte (MSG_ALL, SVC_CDTRACK);
1567         WriteByte (MSG_ALL, 3);
1568         WriteByte (MSG_ALL, 3);
1569         // done in FixIntermission
1570         */
1571
1572         //pos = FindIntermission ();
1573
1574         VoteReset();
1575
1576         DumpStats(TRUE);
1577
1578         // send statistics
1579         entity e;
1580         PlayerStats_EndMatch(1);
1581         FOR_EACH_CLIENT(e)
1582                 PlayerStats_AddGlobalInfo(e);
1583         PlayerStats_Shutdown();
1584         WeaponStats_Shutdown();
1585
1586         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1587
1588         if(autocvar_sv_eventlog)
1589                 GameLogEcho(":gameover");
1590
1591         GameLogClose();
1592
1593         FOR_EACH_PLAYER(other) {
1594                 minstagib_stop_countdown(other);
1595                 FixIntermissionClient(other);
1596                 if(other.winning)
1597                         bprint(other.netname, " ^7wins.\n");
1598         }
1599
1600         if(autocvar_g_campaign)
1601                 CampaignPreIntermission();
1602
1603         MUTATOR_CALLHOOK(MatchEnd);
1604
1605         localcmd("\nsv_hook_gameend\n");
1606 }
1607
1608 /*
1609 ============
1610 CheckRules_Player
1611
1612 Exit deathmatch games upon conditions
1613 ============
1614 */
1615 void CheckRules_Player()
1616 {
1617         if (gameover)   // someone else quit the game already
1618                 return;
1619
1620         if(self.deadflag == DEAD_NO)
1621                 self.play_time += frametime;
1622
1623         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1624         //   (div0: and that in CheckRules_World please)
1625 }
1626
1627 float checkrules_equality;
1628 float checkrules_suddendeathwarning;
1629 float checkrules_suddendeathend;
1630 float checkrules_overtimesadded; //how many overtimes have been already added
1631
1632 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1633 float WINNING_YES = 1; // winner found
1634 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1635 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1636
1637 float InitiateSuddenDeath()
1638 {
1639         // Check first whether normal overtimes could be added before initiating suddendeath mode
1640         // - for this timelimit_overtime needs to be >0 of course
1641         // - also check the winning condition calculated in the previous frame and only add normal overtime
1642         //   again, if at the point at which timelimit would be extended again, still no winner was found
1643         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1644         {
1645                 return 1; // need to call InitiateOvertime later
1646         }
1647         else
1648         {
1649                 if(!checkrules_suddendeathend)
1650                 {
1651                         if(autocvar_g_campaign)
1652                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1653                         else
1654                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1655                         if(g_race && !g_race_qualifying)
1656                                 race_StartCompleting();
1657                 }
1658                 return 0;
1659         }
1660 }
1661
1662 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1663 {
1664         ++checkrules_overtimesadded;
1665         //add one more overtime by simply extending the timelimit
1666         float tl;
1667         tl = autocvar_timelimit;
1668         tl += autocvar_timelimit_overtime;
1669         cvar_set("timelimit", ftos(tl));
1670
1671         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime);
1672 }
1673
1674 float GetWinningCode(float fraglimitreached, float equality)
1675 {
1676         if(autocvar_g_campaign == 1)
1677                 if(fraglimitreached)
1678                         return WINNING_YES;
1679                 else
1680                         return WINNING_NO;
1681
1682         else
1683                 if(equality)
1684                         if(fraglimitreached)
1685                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1686                         else
1687                                 return WINNING_NEVER;
1688                 else
1689                         if(fraglimitreached)
1690                                 return WINNING_YES;
1691                         else
1692                                 return WINNING_NO;
1693 }
1694
1695 // set the .winning flag for exactly those players with a given field value
1696 void SetWinners(.float field, float value)
1697 {
1698         entity head;
1699         FOR_EACH_PLAYER(head)
1700                 head.winning = (head.field == value);
1701 }
1702
1703 // set the .winning flag for those players with a given field value
1704 void AddWinners(.float field, float value)
1705 {
1706         entity head;
1707         FOR_EACH_PLAYER(head)
1708                 if(head.field == value)
1709                         head.winning = 1;
1710 }
1711
1712 // clear the .winning flags
1713 void ClearWinners(void)
1714 {
1715         entity head;
1716         FOR_EACH_PLAYER(head)
1717                 head.winning = 0;
1718 }
1719
1720 // Onslaught winning condition:
1721 // game terminates if only one team has a working generator (or none)
1722 float WinningCondition_Onslaught()
1723 {
1724         entity head;
1725         float t1, t2, t3, t4;
1726
1727         WinningConditionHelper(); // set worldstatus
1728
1729         if(inWarmupStage)
1730                 return WINNING_NO;
1731
1732         // first check if the game has ended
1733         t1 = t2 = t3 = t4 = 0;
1734         head = find(world, classname, "onslaught_generator");
1735         while (head)
1736         {
1737                 if (head.health > 0)
1738                 {
1739                         if (head.team == NUM_TEAM_1) t1 = 1;
1740                         if (head.team == NUM_TEAM_2) t2 = 1;
1741                         if (head.team == NUM_TEAM_3) t3 = 1;
1742                         if (head.team == NUM_TEAM_4) t4 = 1;
1743                 }
1744                 head = find(head, classname, "onslaught_generator");
1745         }
1746         if (t1 + t2 + t3 + t4 < 2)
1747         {
1748                 // game over, only one team remains (or none)
1749                 ClearWinners();
1750                 if (t1) SetWinners(team, NUM_TEAM_1);
1751                 if (t2) SetWinners(team, NUM_TEAM_2);
1752                 if (t3) SetWinners(team, NUM_TEAM_3);
1753                 if (t4) SetWinners(team, NUM_TEAM_4);
1754                 dprint("Have a winner, ending game.\n");
1755                 return WINNING_YES;
1756         }
1757
1758         // Two or more teams remain
1759         return WINNING_NO;
1760 }
1761
1762 float LMS_NewPlayerLives()
1763 {
1764         float fl;
1765         fl = autocvar_fraglimit;
1766         if(fl == 0)
1767                 fl = 999;
1768
1769         // first player has left the game for dying too much? Nobody else can get in.
1770         if(lms_lowest_lives < 1)
1771                 return 0;
1772
1773         if(!autocvar_g_lms_join_anytime)
1774                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1775                         return 0;
1776
1777         return bound(1, lms_lowest_lives, fl);
1778 }
1779
1780 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1781 // they win. Otherwise the defending team wins once the timelimit passes.
1782 void assault_new_round();
1783 float WinningCondition_Assault()
1784 {
1785         float status;
1786
1787         WinningConditionHelper(); // set worldstatus
1788
1789         status = WINNING_NO;
1790         // as the timelimit has not yet passed just assume the defending team will win
1791         if(assault_attacker_team == NUM_TEAM_1)
1792         {
1793                 SetWinners(team, NUM_TEAM_2);
1794         }
1795         else
1796         {
1797                 SetWinners(team, NUM_TEAM_1);
1798         }
1799
1800         entity ent;
1801         ent = find(world, classname, "target_assault_roundend");
1802         if(ent)
1803         {
1804                 if(ent.winning) // round end has been triggered by attacking team
1805                 {
1806                         bprint("ASSAULT: round completed...\n");
1807                         SetWinners(team, assault_attacker_team);
1808
1809                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1810
1811                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1812                         {
1813                                 status = WINNING_YES;
1814                         }
1815                         else
1816                         {
1817                                 entity oldself;
1818                                 oldself = self;
1819                                 self = ent;
1820                                 assault_new_round();
1821                                 self = oldself;
1822                         }
1823                 }
1824         }
1825
1826         return status;
1827 }
1828
1829 // LMS winning condition: game terminates if and only if there's at most one
1830 // one player who's living lives. Top two scores being equal cancels the time
1831 // limit.
1832 float WinningCondition_LMS()
1833 {
1834         entity head, head2;
1835         float have_player;
1836         float have_players;
1837         float l;
1838
1839         have_player = FALSE;
1840         have_players = FALSE;
1841         l = LMS_NewPlayerLives();
1842
1843         head = find(world, classname, "player");
1844         if(head)
1845                 have_player = TRUE;
1846         head2 = find(head, classname, "player");
1847         if(head2)
1848                 have_players = TRUE;
1849
1850         if(have_player)
1851         {
1852                 // we have at least one player
1853                 if(have_players)
1854                 {
1855                         // two or more active players - continue with the game
1856                 }
1857                 else
1858                 {
1859                         // exactly one player?
1860
1861                         ClearWinners();
1862                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1863
1864                         if(l)
1865                         {
1866                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1867                                 return WINNING_NO;
1868                         }
1869                         else
1870                         {
1871                                 // a winner!
1872                                 // and assign him his first place
1873                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1874                                 return WINNING_YES;
1875                         }
1876                 }
1877         }
1878         else
1879         {
1880                 // nobody is playing at all...
1881                 if(l)
1882                 {
1883                         // wait for players...
1884                 }
1885                 else
1886                 {
1887                         // SNAFU (maybe a draw game?)
1888                         ClearWinners();
1889                         dprint("No players, ending game.\n");
1890                         return WINNING_YES;
1891                 }
1892         }
1893
1894         // When we get here, we have at least two players who are actually LIVING,
1895         // now check if the top two players have equal score.
1896         WinningConditionHelper();
1897
1898         ClearWinners();
1899         if(WinningConditionHelper_winner)
1900                 WinningConditionHelper_winner.winning = TRUE;
1901         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1902                 return WINNING_NEVER;
1903
1904         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1905         return WINNING_NO;
1906 }
1907
1908 void ShuffleMaplist()
1909 {
1910         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1911 }
1912
1913 float leaderfrags;
1914 float WinningCondition_Scores(float limit, float leadlimit)
1915 {
1916         float limitreached;
1917
1918         // TODO make everything use THIS winning condition (except LMS)
1919         WinningConditionHelper();
1920
1921         if(teamplay)
1922         {
1923                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1924                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1925                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1926                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1927         }
1928
1929         ClearWinners();
1930         if(WinningConditionHelper_winner)
1931                 WinningConditionHelper_winner.winning = 1;
1932         if(WinningConditionHelper_winnerteam >= 0)
1933                 SetWinners(team, WinningConditionHelper_winnerteam);
1934
1935         if(WinningConditionHelper_lowerisbetter)
1936         {
1937                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1938                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1939                 limit = -limit;
1940         }
1941
1942         if(WinningConditionHelper_zeroisworst)
1943                 leadlimit = 0; // not supported in this mode
1944
1945         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1946         // these modes always score in increments of 1, thus this makes sense
1947         {
1948                 if(leaderfrags != WinningConditionHelper_topscore)
1949                 {
1950                         leaderfrags = WinningConditionHelper_topscore;
1951
1952                         if (limit)
1953                         if (leaderfrags == limit - 1)
1954                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1955                         else if (leaderfrags == limit - 2)
1956                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1957                         else if (leaderfrags == limit - 3)
1958                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1959                 }
1960         }
1961
1962         limitreached = FALSE;
1963         if(limit)
1964                 if(WinningConditionHelper_topscore >= limit)
1965                         limitreached = TRUE;
1966         if(leadlimit)
1967         {
1968                 float leadlimitreached;
1969                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1970                 if(autocvar_leadlimit_and_fraglimit)
1971                         limitreached = (limitreached && leadlimitreached);
1972                 else
1973                         limitreached = (limitreached || leadlimitreached);
1974         }
1975
1976         if(limit)
1977                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1978
1979         return GetWinningCode(
1980                 WinningConditionHelper_topscore && limitreached,
1981                 WinningConditionHelper_equality
1982         );
1983 }
1984
1985 float WinningCondition_Race(float fraglimit)
1986 {
1987         float wc;
1988         entity p;
1989         float n, c;
1990
1991         n = 0;
1992         c = 0;
1993         FOR_EACH_PLAYER(p)
1994         {
1995                 ++n;
1996                 if(p.race_completed)
1997                         ++c;
1998         }
1999         if(n && (n == c))
2000                 return WINNING_YES;
2001         wc = WinningCondition_Scores(fraglimit, 0);
2002
2003         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2004         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2005         // do NOT support equality when the laps are all raced!
2006                 return WINNING_STARTSUDDENDEATHOVERTIME;
2007         else
2008                 return WINNING_NEVER;
2009 }
2010
2011 float WinningCondition_QualifyingThenRace(float limit)
2012 {
2013         float wc;
2014         wc = WinningCondition_Scores(limit, 0);
2015
2016         // NEVER initiate overtime
2017         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2018         {
2019                 return WINNING_YES;
2020         }
2021
2022         return wc;
2023 }
2024
2025 float WinningCondition_RanOutOfSpawns()
2026 {
2027         entity head;
2028
2029         if(have_team_spawns <= 0)
2030                 return WINNING_NO;
2031
2032         if(autocvar_g_spawn_useallspawns <= 0)
2033                 return WINNING_NO;
2034
2035         if(!some_spawn_has_been_used)
2036                 return WINNING_NO;
2037
2038         team1_score = team2_score = team3_score = team4_score = 0;
2039
2040         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2041         {
2042                 if(head.team == NUM_TEAM_1)
2043                         team1_score = 1;
2044                 else if(head.team == NUM_TEAM_2)
2045                         team2_score = 1;
2046                 else if(head.team == NUM_TEAM_3)
2047                         team3_score = 1;
2048                 else if(head.team == NUM_TEAM_4)
2049                         team4_score = 1;
2050         }
2051
2052         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2053         {
2054                 if(head.team == NUM_TEAM_1)
2055                         team1_score = 1;
2056                 else if(head.team == NUM_TEAM_2)
2057                         team2_score = 1;
2058                 else if(head.team == NUM_TEAM_3)
2059                         team3_score = 1;
2060                 else if(head.team == NUM_TEAM_4)
2061                         team4_score = 1;
2062         }
2063
2064         ClearWinners();
2065         if(team1_score + team2_score + team3_score + team4_score == 0)
2066         {
2067                 checkrules_equality = TRUE;
2068                 return WINNING_YES;
2069         }
2070         else if(team1_score + team2_score + team3_score + team4_score == 1)
2071         {
2072                 float t, i;
2073                 if(team1_score)
2074                         t = NUM_TEAM_1;
2075                 else if(team2_score)
2076                         t = NUM_TEAM_2;
2077                 else if(team3_score)
2078                         t = NUM_TEAM_3;
2079                 else // if(team4_score)
2080                         t = NUM_TEAM_4;
2081                 CheckAllowedTeams(world);
2082                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2083                 {
2084                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2085                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2086                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2087                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2088                 }
2089
2090                 AddWinners(team, t);
2091                 return WINNING_YES;
2092         }
2093         else
2094                 return WINNING_NO;
2095 }
2096
2097 /*
2098 ============
2099 CheckRules_World
2100
2101 Exit deathmatch games upon conditions
2102 ============
2103 */
2104 void ReadyRestart();
2105 void CheckRules_World()
2106 {
2107         float timelimit;
2108         float fraglimit;
2109         float leadlimit;
2110
2111         VoteThink();
2112         MapVote_Think();
2113
2114         SetDefaultAlpha();
2115
2116         /*
2117         MapVote_Think should now do that part
2118         if (intermission_running)
2119                 if (time >= intermission_exittime + 60)
2120                 {
2121                         if(!DoNextMapOverride())
2122                                 GotoNextMap();
2123                         return;
2124                 }
2125         */
2126
2127         if (gameover)   // someone else quit the game already
2128         {
2129                 if(player_count == 0) // Nobody there? Then let's go to the next map
2130                         MapVote_Start();
2131                         // this will actually check the player count in the next frame
2132                         // again, but this shouldn't hurt
2133                 return;
2134         }
2135
2136         timelimit = autocvar_timelimit * 60;
2137         fraglimit = autocvar_fraglimit;
2138         leadlimit = autocvar_leadlimit;
2139
2140         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2141         {
2142                 if(timelimit > 0)
2143                         timelimit = 0; // timelimit is not made for warmup
2144                 if(fraglimit > 0)
2145                         fraglimit = 0; // no fraglimit for now
2146                 leadlimit = 0; // no leadlimit for now
2147         }
2148
2149         if(timelimit > 0)
2150         {
2151                 timelimit += game_starttime;
2152         }
2153         else if (timelimit < 0)
2154         {
2155                 // endmatch
2156                 NextLevel();
2157                 return;
2158         }
2159
2160         if(g_onslaught)
2161                 timelimit = 0; // ONS has its own overtime rule
2162
2163         float wantovertime;
2164         wantovertime = 0;
2165
2166         if(timelimit > game_starttime)
2167                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2168         else
2169                 game_completion_ratio = 0;
2170
2171         if(checkrules_suddendeathend)
2172         {
2173                 if(!checkrules_suddendeathwarning)
2174                 {
2175                         checkrules_suddendeathwarning = TRUE;
2176                         if(g_race && !g_race_qualifying)
2177                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2178                         else
2179                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2180                 }
2181         }
2182         else
2183         {
2184                 if (timelimit && time >= timelimit)
2185                 {
2186                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2187                         {
2188                                 float totalplayers;
2189                                 float playerswithlaps;
2190                                 float readyplayers;
2191                                 entity head;
2192                                 totalplayers = playerswithlaps = readyplayers = 0;
2193                                 FOR_EACH_PLAYER(head)
2194                                 {
2195                                         ++totalplayers;
2196                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2197                                                 ++playerswithlaps;
2198                                         if(head.ready)
2199                                                 ++readyplayers;
2200                                 }
2201
2202                                 // at least 2 of the players have completed a lap: start the RACE
2203                                 // otherwise, the players should end the qualifying on their own
2204                                 if(readyplayers || playerswithlaps >= 2)
2205                                 {
2206                                         checkrules_suddendeathend = 0;
2207                                         ReadyRestart(); // go to race
2208                                         return;
2209                                 }
2210                                 else
2211                                         wantovertime |= InitiateSuddenDeath();
2212                         }
2213                         else
2214                                 wantovertime |= InitiateSuddenDeath();
2215                 }
2216         }
2217
2218         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2219         {
2220                 NextLevel();
2221                 return;
2222         }
2223
2224         float checkrules_status;
2225         checkrules_status = WinningCondition_RanOutOfSpawns();
2226         if(checkrules_status == WINNING_YES)
2227         {
2228                 bprint("Hey! Someone ran out of spawns!\n");
2229         }
2230         else if(g_race && !g_race_qualifying && timelimit >= 0)
2231         {
2232                 checkrules_status = WinningCondition_Race(fraglimit);
2233                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2234         }
2235         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2236         {
2237                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2238                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2239         }
2240         else if(g_assault)
2241         {
2242                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2243         }
2244         else if(g_lms)
2245         {
2246                 checkrules_status = WinningCondition_LMS();
2247         }
2248         else if (g_onslaught)
2249         {
2250                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2251         }
2252         else
2253         {
2254                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2255                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2256         }
2257
2258         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2259         {
2260                 checkrules_status = WINNING_NEVER;
2261                 checkrules_overtimesadded = -1;
2262                 wantovertime |= InitiateSuddenDeath();
2263         }
2264
2265         if(checkrules_status == WINNING_NEVER)
2266                 // equality cases! Nobody wins if the overtime ends in a draw.
2267                 ClearWinners();
2268
2269         if(wantovertime)
2270         {
2271                 if(checkrules_status == WINNING_NEVER)
2272                         InitiateOvertime();
2273                 else
2274                         checkrules_status = WINNING_YES;
2275         }
2276
2277         if(checkrules_suddendeathend)
2278                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2279                         checkrules_status = WINNING_YES;
2280
2281         if(checkrules_status == WINNING_YES)
2282         {
2283                 //print("WINNING\n");
2284                 NextLevel();
2285         }
2286 }
2287
2288 float mapvote_nextthink;
2289 float mapvote_initialized;
2290 float mapvote_keeptwotime;
2291 float mapvote_timeout;
2292 string mapvote_message;
2293 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2294 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2295 float mapvote_screenshot_dirs_count;
2296
2297 float mapvote_count;
2298 float mapvote_count_real;
2299 string mapvote_maps[MAPVOTE_COUNT];
2300 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2301 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2302 float mapvote_maps_suggested[MAPVOTE_COUNT];
2303 string mapvote_suggestions[MAPVOTE_COUNT];
2304 float mapvote_suggestion_ptr;
2305 float mapvote_voters;
2306 float mapvote_selections[MAPVOTE_COUNT];
2307 float mapvote_run;
2308 float mapvote_detail;
2309 float mapvote_abstain;
2310 .float mapvote;
2311
2312 void MapVote_ClearAllVotes()
2313 {
2314         FOR_EACH_CLIENT(other)
2315                 other.mapvote = 0;
2316 }
2317
2318 string MapVote_Suggest(string m)
2319 {
2320         float i;
2321         if(m == "")
2322                 return "That's not how to use this command.";
2323         if(!autocvar_g_maplist_votable_suggestions)
2324                 return "Suggestions are not accepted on this server.";
2325         if(mapvote_initialized)
2326                 return "Can't suggest - voting is already in progress!";
2327         m = MapInfo_FixName(m);
2328         if not(m)
2329                 return "The map you suggested is not available on this server.";
2330         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2331                 if(Map_IsRecent(m))
2332                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2333
2334         if(!MapInfo_CheckMap(m))
2335                 return "The map you suggested does not support the current game mode.";
2336         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2337                 if(mapvote_suggestions[i] == m)
2338                         return "This map was already suggested.";
2339         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2340         {
2341                 i = floor(random() * mapvote_suggestion_ptr);
2342         }
2343         else
2344         {
2345                 i = mapvote_suggestion_ptr;
2346                 mapvote_suggestion_ptr += 1;
2347         }
2348         if(mapvote_suggestions[i] != "")
2349                 strunzone(mapvote_suggestions[i]);
2350         mapvote_suggestions[i] = strzone(m);
2351         if(autocvar_sv_eventlog)
2352                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2353         return strcat("Suggestion of ", m, " accepted.");
2354 }
2355
2356 void MapVote_AddVotable(string nextMap, float isSuggestion)
2357 {
2358         float j, i, o;
2359         string pakfile, mapfile;
2360
2361         if(nextMap == "")
2362                 return;
2363         for(j = 0; j < mapvote_count; ++j)
2364                 if(mapvote_maps[j] == nextMap)
2365                         return;
2366         // suggestions might be no longer valid/allowed after gametype switch!
2367         if(isSuggestion)
2368                 if(!MapInfo_CheckMap(nextMap))
2369                         return;
2370         mapvote_maps[mapvote_count] = strzone(nextMap);
2371         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2372
2373         pakfile = string_null;
2374         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2375         {
2376                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2377                 pakfile = whichpack(strcat(mapfile, ".tga"));
2378                 if(pakfile == "")
2379                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2380                 if(pakfile == "")
2381                         pakfile = whichpack(strcat(mapfile, ".png"));
2382                 if(pakfile != "")
2383                         break;
2384         }
2385         if(i >= mapvote_screenshot_dirs_count)
2386                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2387         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2388                 pakfile = substring(pakfile, o, -1);
2389
2390         mapvote_maps_screenshot_dir[mapvote_count] = i;
2391         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2392
2393         mapvote_count += 1;
2394 }
2395
2396 void MapVote_Spawn();
2397 void MapVote_Init()
2398 {
2399         float i;
2400         float nmax, smax;
2401
2402         MapVote_ClearAllVotes();
2403
2404         mapvote_count = 0;
2405         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2406         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2407
2408         if(mapvote_abstain)
2409                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2410         else
2411                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2412         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2413
2414         // we need this for AddVotable, as that cycles through the screenshot dirs
2415         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2416         if(mapvote_screenshot_dirs_count == 0)
2417                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2418         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2419         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2420                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2421
2422         if(mapvote_suggestion_ptr)
2423                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2424                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2425
2426         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2427                 MapVote_AddVotable(GetNextMap(), FALSE);
2428
2429         if(mapvote_count == 0)
2430         {
2431                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2432                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2433                 if(autocvar_g_maplist_shuffle)
2434                         ShuffleMaplist();
2435                 localcmd("\nmenu_cmd sync\n");
2436                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2437                         MapVote_AddVotable(GetNextMap(), FALSE);
2438         }
2439
2440         mapvote_count_real = mapvote_count;
2441         if(mapvote_abstain)
2442                 MapVote_AddVotable("don't care", 0);
2443
2444         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2445
2446         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2447         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2448         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2449                 mapvote_keeptwotime = 0;
2450         mapvote_message = "Choose a map and press its key!";
2451
2452         MapVote_Spawn();
2453 }
2454
2455 void MapVote_SendPicture(float id)
2456 {
2457         msg_entity = self;
2458         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2459         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2460         WriteByte(MSG_ONE, id);
2461         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2462 }
2463
2464 float MapVote_GetMapMask()
2465 {
2466         float mask, i, power;
2467         mask = 0;
2468         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2469                 if(mapvote_maps[i] != "")
2470                         mask |= power;
2471         return mask;
2472 }
2473
2474 entity mapvote_ent;
2475 float MapVote_SendEntity(entity to, float sf)
2476 {
2477         float i;
2478
2479         if(sf & 1)
2480                 sf &~= 2; // if we send 1, we don't need to also send 2
2481
2482         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2483         WriteByte(MSG_ENTITY, sf);
2484
2485         if(sf & 1)
2486         {
2487                 // flag 1 == initialization
2488                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2489                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2490                 WriteString(MSG_ENTITY, "");
2491                 WriteByte(MSG_ENTITY, mapvote_count);
2492                 WriteByte(MSG_ENTITY, mapvote_abstain);
2493                 WriteByte(MSG_ENTITY, mapvote_detail);
2494                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2495                 if(mapvote_count <= 8)
2496                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2497                 else
2498                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2499                 for(i = 0; i < mapvote_count; ++i)
2500                         if(mapvote_maps[i] != "")
2501                         {
2502                                 if(mapvote_abstain && i == mapvote_count - 1)
2503                                 {
2504                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2505                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2506                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2507                                 }
2508                                 else
2509                                 {
2510                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2511                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2512                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2513                                 }
2514                         }
2515         }
2516
2517         if(sf & 2)
2518         {
2519                 // flag 2 == update of mask
2520                 if(mapvote_count <= 8)
2521                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2522                 else
2523                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2524         }
2525
2526         if(sf & 4)
2527         {
2528                 if(mapvote_detail)
2529                         for(i = 0; i < mapvote_count; ++i)
2530                                 if(mapvote_maps[i] != "")
2531                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2532
2533                 WriteByte(MSG_ENTITY, to.mapvote);
2534         }
2535
2536         return TRUE;
2537 }
2538
2539 void MapVote_Spawn()
2540 {
2541         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2542 }
2543
2544 void MapVote_TouchMask()
2545 {
2546         mapvote_ent.SendFlags |= 2;
2547 }
2548
2549 void MapVote_TouchVotes(entity voter)
2550 {
2551         mapvote_ent.SendFlags |= 4;
2552 }
2553
2554 float MapVote_Finished(float mappos)
2555 {
2556         string result;
2557         float i;
2558         float didntvote;
2559
2560         if(autocvar_sv_eventlog)
2561         {
2562                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2563                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2564                 didntvote = mapvote_voters;
2565                 for(i = 0; i < mapvote_count; ++i)
2566                         if(mapvote_maps[i] != "")
2567                         {
2568                                 didntvote -= mapvote_selections[i];
2569                                 if(i != mappos)
2570                                 {
2571                                         result = strcat(result, ":", mapvote_maps[i]);
2572                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2573                                 }
2574                         }
2575                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2576
2577                 GameLogEcho(result);
2578                 if(mapvote_maps_suggested[mappos])
2579                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2580         }
2581
2582         FOR_EACH_REALCLIENT(other)
2583                 FixClientCvars(other);
2584
2585         Map_Goto_SetStr(mapvote_maps[mappos]);
2586         Map_Goto(0);
2587         alreadychangedlevel = TRUE;
2588         return TRUE;
2589 }
2590 void MapVote_CheckRules_1()
2591 {
2592         float i;
2593
2594         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2595         {
2596                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2597                 mapvote_selections[i] = 0;
2598         }
2599
2600         mapvote_voters = 0;
2601         FOR_EACH_REALCLIENT(other)
2602         {
2603                 ++mapvote_voters;
2604                 if(other.mapvote)
2605                 {
2606                         i = other.mapvote - 1;
2607                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2608                         mapvote_selections[i] = mapvote_selections[i] + 1;
2609                 }
2610         }
2611 }
2612
2613 float MapVote_CheckRules_2()
2614 {
2615         float i;
2616         float firstPlace, secondPlace;
2617         float firstPlaceVotes, secondPlaceVotes;
2618         float mapvote_voters_real;
2619         string result;
2620
2621         if(mapvote_count_real == 1)
2622                 return MapVote_Finished(0);
2623
2624         mapvote_voters_real = mapvote_voters;
2625         if(mapvote_abstain)
2626                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2627
2628         RandomSelection_Init();
2629         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2630                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2631         firstPlace = RandomSelection_chosen_float;
2632         firstPlaceVotes = RandomSelection_best_priority;
2633         //dprint("First place: ", ftos(firstPlace), "\n");
2634         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2635
2636         RandomSelection_Init();
2637         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2638                 if(i != firstPlace)
2639                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2640         secondPlace = RandomSelection_chosen_float;
2641         secondPlaceVotes = RandomSelection_best_priority;
2642         //dprint("Second place: ", ftos(secondPlace), "\n");
2643         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2644
2645         if(firstPlace == -1)
2646                 error("No first place in map vote... WTF?");
2647
2648         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2649                 return MapVote_Finished(firstPlace);
2650
2651         if(mapvote_keeptwotime)
2652                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2653                 {
2654                         float didntvote;
2655                         MapVote_TouchMask();
2656                         mapvote_message = "Now decide between the TOP TWO!";
2657                         mapvote_keeptwotime = 0;
2658                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2659                         result = strcat(result, ":", ftos(firstPlaceVotes));
2660                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2661                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2662                         didntvote = mapvote_voters;
2663                         for(i = 0; i < mapvote_count; ++i)
2664                                 if(mapvote_maps[i] != "")
2665                                 {
2666                                         didntvote -= mapvote_selections[i];
2667                                         if(i != firstPlace)
2668                                                 if(i != secondPlace)
2669                                                 {
2670                                                         result = strcat(result, ":", mapvote_maps[i]);
2671                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2672                                                         if(i < mapvote_count_real)
2673                                                         {
2674                                                                 strunzone(mapvote_maps[i]);
2675                                                                 mapvote_maps[i] = "";
2676                                                                 strunzone(mapvote_maps_pakfile[i]);
2677                                                                 mapvote_maps_pakfile[i] = "";
2678                                                         }
2679                                                 }
2680                                 }
2681                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2682                         if(autocvar_sv_eventlog)
2683                                 GameLogEcho(result);
2684                 }
2685
2686         return FALSE;
2687 }
2688 void MapVote_Tick()
2689 {
2690         float keeptwo;
2691         float totalvotes;
2692
2693         keeptwo = mapvote_keeptwotime;
2694         MapVote_CheckRules_1(); // count
2695         if(MapVote_CheckRules_2()) // decide
2696                 return;
2697
2698         totalvotes = 0;
2699         FOR_EACH_REALCLIENT(other)
2700         {
2701                 // hide scoreboard again
2702                 if(other.health != 2342)
2703                 {
2704                         other.health = 2342;
2705                         other.impulse = 0;
2706                         if(clienttype(other) == CLIENTTYPE_REAL)
2707                         {
2708                                 msg_entity = other;
2709                                 WriteByte(MSG_ONE, SVC_FINALE);
2710                                 WriteString(MSG_ONE, "");
2711                         }
2712                 }
2713
2714                 // clear possibly invalid votes
2715                 if(mapvote_maps[other.mapvote - 1] == "")
2716                         other.mapvote = 0;
2717                 // use impulses as new vote
2718                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2719                         if(mapvote_maps[other.impulse - 1] != "")
2720                         {
2721                                 other.mapvote = other.impulse;
2722                                 MapVote_TouchVotes(other);
2723                         }
2724                 other.impulse = 0;
2725
2726                 if(other.mapvote)
2727                         ++totalvotes;
2728         }
2729
2730         MapVote_CheckRules_1(); // just count
2731 }
2732 void MapVote_Start()
2733 {
2734         if(mapvote_run)
2735                 return;
2736
2737         // wait for stats to be sent first
2738         if(!playerstats_waitforme)
2739                 return;
2740
2741         MapInfo_Enumerate();
2742         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2743                 mapvote_run = TRUE;
2744 }
2745 void MapVote_Think()
2746 {
2747         if(!mapvote_run)
2748                 return;
2749
2750         if(alreadychangedlevel)
2751                 return;
2752
2753         if(time < mapvote_nextthink)
2754                 return;
2755         //dprint("tick\n");
2756
2757         mapvote_nextthink = time + 0.5;
2758
2759         if(!mapvote_initialized)
2760         {
2761                 if(autocvar_rescan_pending == 1)
2762                 {
2763                         cvar_set("rescan_pending", "2");
2764                         localcmd("fs_rescan\nrescan_pending 3\n");
2765                         return;
2766                 }
2767                 else if(autocvar_rescan_pending == 2)
2768                 {
2769                         return;
2770                 }
2771                 else if(autocvar_rescan_pending == 3)
2772                 {
2773                         // now build missing mapinfo files
2774                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2775                                 return;
2776
2777                         // we're done, start the timer
2778                         cvar_set("rescan_pending", "0");
2779                 }
2780
2781                 mapvote_initialized = TRUE;
2782                 if(DoNextMapOverride(0))
2783                         return;
2784                 if(!autocvar_g_maplist_votable || player_count <= 0)
2785                 {
2786                         GotoNextMap(0);
2787                         return;
2788                 }
2789                 MapVote_Init();
2790         }
2791
2792         MapVote_Tick();
2793 }
2794
2795 string GotoMap(string m)
2796 {
2797         if(!MapInfo_CheckMap(m))
2798                 return "The map you chose is not available on this server.";
2799         cvar_set("nextmap", m);
2800         cvar_set("timelimit", "-1");
2801         if(mapvote_initialized || alreadychangedlevel)
2802         {
2803                 if(DoNextMapOverride(0))
2804                         return "Map switch initiated.";
2805                 else
2806                         return "Hm... no. For some reason I like THIS map more.";
2807         }
2808         else
2809                 return "Map switch will happen after scoreboard.";
2810 }
2811
2812
2813 void EndFrame()
2814 {
2815         float altime;
2816         FOR_EACH_REALCLIENT(self)
2817         {
2818                 if(self.classname == "spectator")
2819                 {
2820                         if(self.enemy.typehitsound)
2821                                 self.typehit_time = time;
2822                         else if(self.enemy.hitsound)
2823                                 self.hit_time = time;
2824                 }
2825                 else
2826                 {
2827                         if(self.typehitsound)
2828                                 self.typehit_time = time;
2829                         else if(self.hitsound)
2830                                 self.hit_time = time;
2831                 }
2832         }
2833         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2834         // add 1 frametime because after this, engine SV_Physics
2835         // increases time by a frametime and then networks the frame
2836         // add another frametime because client shows everything with
2837         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2838         // needed!
2839         FOR_EACH_CLIENT(self)
2840         {
2841                 self.hitsound = FALSE;
2842                 self.typehitsound = FALSE;
2843                 antilag_record(self, altime);
2844         }
2845 }
2846
2847
2848 /*
2849  * RedirectionThink:
2850  * returns TRUE if redirecting
2851  */
2852 float redirection_timeout;
2853 float redirection_nextthink;
2854 float RedirectionThink()
2855 {
2856         float clients_found;
2857
2858         if(redirection_target == "")
2859                 return FALSE;
2860
2861         if(!redirection_timeout)
2862         {
2863                 cvar_set("sv_public", "-2");
2864                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2865                 if(redirection_target == "self")
2866                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2867                 else
2868                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2869         }
2870
2871         if(time < redirection_nextthink)
2872                 return TRUE;
2873
2874         redirection_nextthink = time + 1;
2875
2876         clients_found = 0;
2877         FOR_EACH_REALCLIENT(self)
2878         {
2879                 // TODO add timer
2880                 print("Redirecting: sending connect command to ", self.netname, "\n");
2881                 if(redirection_target == "self")
2882                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2883                 else
2884                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2885                 ++clients_found;
2886         }
2887
2888         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2889
2890         if(time > redirection_timeout || clients_found == 0)
2891                 localcmd("\nwait; wait; wait; quit\n");
2892
2893         return TRUE;
2894 }
2895
2896 void TargetMusic_RestoreGame();
2897 void RestoreGame()
2898 {
2899         // Loaded from a save game
2900         // some things then break, so let's work around them...
2901
2902         // Progs DB (capture records)
2903         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2904
2905         // Mapinfo
2906         MapInfo_Shutdown();
2907         MapInfo_Enumerate();
2908         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2909         WeaponStats_Init();
2910
2911         TargetMusic_RestoreGame();
2912 }
2913
2914 void Shutdown()
2915 {
2916         entity e;
2917
2918         gameover = 2;
2919
2920         if(world_initialized > 0)
2921         {
2922                 world_initialized = 0;
2923                 print("Saving persistent data...\n");
2924                 Ban_SaveBans();
2925
2926                 PlayerStats_EndMatch(0);
2927                 FOR_EACH_CLIENT(e)
2928                         PlayerStats_AddGlobalInfo(e);
2929                 PlayerStats_Shutdown();
2930
2931                 if(!cheatcount_total)
2932                 {
2933                         if(autocvar_sv_db_saveasdump)
2934                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2935                         else
2936                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2937                 }
2938                 if(autocvar_developer)
2939                 {
2940                         if(autocvar_sv_db_saveasdump)
2941                                 db_dump(TemporaryDB, "server-temp.db");
2942                         else
2943                                 db_save(TemporaryDB, "server-temp.db");
2944                 }
2945                 CheatShutdown(); // must be after cheatcount check
2946                 db_close(ServerProgsDB);
2947                 db_close(TemporaryDB);
2948                 print("done!\n");
2949                 // tell the bot system the game is ending now
2950                 bot_endgame();
2951
2952                 WeaponStats_Shutdown();
2953                 MapInfo_Shutdown();
2954         }
2955         else if(world_initialized == 0)
2956         {
2957                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2958         }
2959 }