qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_instagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WepSet_AddStat();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 776         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 777         Nagger_Init();
 778
 779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 794         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         // freeze attacks
 799         addstat(STAT_FROZEN, AS_INT, frozen);
 800         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 801
 802         // g_movementspeed hack
 803         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 804         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 805         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 806         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 807
 808         // secrets
 809         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 810         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 811
 812         // monsters
 813         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 814         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 815
 816         // misc
 817         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 818
 819         next_pingtime = time + 5;
 820
 821         detect_maptype();
 822
 823         // set up information replies for clients and server to use
 824         maplist_reply = strzone(getmaplist());
 825         lsmaps_reply = strzone(getlsmaps());
 826         monsterlist_reply = strzone(getmonsterlist());
 827         for(i = 0; i < 10; ++i)
 828         {
 829                 s = getrecords(i);
 830                 if (s)
 831                         records_reply[i] = strzone(s);
 832         }
 833         ladder_reply = strzone(getladder());
 834         rankings_reply = strzone(getrankings());
 835
 836         // begin other init
 837         ClientInit_Spawn();
 838         RandomSeed_Spawn();
 839         PingPLReport_Spawn();
 840
 841         CheatInit();
 842
 843         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 844
 845         // fill sv_curl_serverpackages from .serverpackage files
 846         if(autocvar_sv_curl_serverpackages_auto)
 847         {
 848                 s = "";
 849                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 850                 for(i = 0; i < n; ++i)
 851                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 852                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 853                                 s = strcat(s, " ", argv(i));
 854                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 855                 if(fd >= 0)
 856                 {
 857                         j = search_getsize(fd);
 858                         for(i = 0; i < j; ++i)
 859                                 s = strcat(s, " ", search_getfilename(fd, i));
 860                         search_end(fd);
 861                 }
 862                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 863                 if(fd >= 0)
 864                 {
 865                         j = search_getsize(fd);
 866                         for(i = 0; i < j; ++i)
 867                                 s = strcat(s, " ", search_getfilename(fd, i));
 868                         search_end(fd);
 869                 }
 870                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 871         }
 872
 873         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 874         modname = "Xonotic";
 875         // physics/balance/config changes that count as mod
 876         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 877                 modname = cvar_string("g_mod_physics");
 878         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 879                 modname = cvar_string("g_mod_balance");
 880         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 881                 modname = cvar_string("g_mod_config");
 882         // extra mutators that deserve to count as mod
 883         MUTATOR_CALLHOOK(SetModname);
 884
 885         // save it for later
 886         modname = strzone(modname);
 887
 888         WinningConditionHelper(); // set worldstatus
 889
 890         world_initialized = 1;
 891 }
 892
 893 void spawnfunc_light (void)
 894 {
 895         //makestatic (self); // Who the f___ did that?
 896         remove(self);
 897 }
 898
 899 string GetGametype()
 900 {
 901         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 902 }
 903
 904 string GetMapname()
 905 {
 906         return mapname;
 907 }
 908
 909 float Map_Count, Map_Current;
 910 string Map_Current_Name;
 911
 912 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 913 float GetMaplistPosition()
 914 {
 915         float pos, idx;
 916         string map;
 917
 918         map = GetMapname();
 919         idx = autocvar_g_maplist_index;
 920
 921         if(idx >= 0)
 922                 if(idx < Map_Count)
 923                         if(map == argv(idx))
 924                                 return idx;
 925
 926         for(pos = 0; pos < Map_Count; ++pos)
 927                 if(map == argv(pos))
 928                         return pos;
 929
 930         // resume normal maplist rotation if current map is not in g_maplist
 931         return idx;
 932 }
 933
 934 float MapHasRightSize(string map)
 935 {
 936         float fh;
 937         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 938         if(autocvar_g_maplist_check_waypoints)
 939         {
 940                 dprint("checkwp "); dprint(map);
 941                 if(!fexists(strcat("maps/", map, ".waypoints")))
 942                 {
 943                         dprint(": no waypoints\n");
 944                         return FALSE;
 945                 }
 946                 dprint(": has waypoints\n");
 947         }
 948
 949         // open map size restriction file
 950         dprint("opensize "); dprint(map);
 951         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 952         if(fh >= 0)
 953         {
 954                 float mapmin, mapmax;
 955                 dprint(": ok, ");
 956                 mapmin = stof(fgets(fh));
 957                 mapmax = stof(fgets(fh));
 958                 fclose(fh);
 959                 if(player_count < mapmin)
 960                 {
 961                         dprint("not enough\n");
 962                         return FALSE;
 963                 }
 964                 if(player_count > mapmax)
 965                 {
 966                         dprint("too many\n");
 967                         return FALSE;
 968                 }
 969                 dprint("right size\n");
 970                 return TRUE;
 971         }
 972         dprint(": not found\n");
 973         return TRUE;
 974 }
 975
 976 string Map_Filename(float position)
 977 {
 978         return strcat("maps/", argv(position), ".bsp");
 979 }
 980
 981 string strwords(string s, float w)
 982 {
 983         float endpos;
 984         for(endpos = 0; w && endpos >= 0; --w)
 985                 endpos = strstrofs(s, " ", endpos + 1);
 986         if(endpos < 0)
 987                 return s;
 988         else
 989                 return substring(s, 0, endpos);
 990 }
 991
 992 float strhasword(string s, string w)
 993 {
 994         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 995 }
 996
 997 void Map_MarkAsRecent(string m)
 998 {
 999         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1000 }
1001
1002 float Map_IsRecent(string m)
1003 {
1004         return strhasword(autocvar_g_maplist_mostrecent, m);
1005 }
1006
1007 float Map_Check(float position, float pass)
1008 {
1009         string filename;
1010         string map_next;
1011         map_next = argv(position);
1012         if(pass <= 1)
1013         {
1014                 if(Map_IsRecent(map_next))
1015                         return 0;
1016         }
1017         filename = Map_Filename(position);
1018         if(MapInfo_CheckMap(map_next))
1019         {
1020                 if(pass == 2)
1021                         return 1;
1022                 if(MapHasRightSize(map_next))
1023                         return 1;
1024                 return 0;
1025         }
1026         else
1027                 dprint( "Couldn't select '", filename, "'..\n" );
1028
1029         return 0;
1030 }
1031
1032 void Map_Goto_SetStr(string nextmapname)
1033 {
1034         if(getmapname_stored != "")
1035                 strunzone(getmapname_stored);
1036         if(nextmapname == "")
1037                 getmapname_stored = "";
1038         else
1039                 getmapname_stored = strzone(nextmapname);
1040 }
1041
1042 void Map_Goto_SetFloat(float position)
1043 {
1044         cvar_set("g_maplist_index", ftos(position));
1045         Map_Goto_SetStr(argv(position));
1046 }
1047
1048 void Map_Goto(float reinit)
1049 {
1050         MapInfo_LoadMap(getmapname_stored, reinit);
1051 }
1052
1053 // return codes of map selectors:
1054 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1055 //   -2 = permanent failure
1056 float() MaplistMethod_Iterate = // usual method
1057 {
1058         float pass, i;
1059
1060         dprint("Trying MaplistMethod_Iterate\n");
1061
1062         for(pass = 1; pass <= 2; ++pass)
1063         {
1064                 for(i = 1; i < Map_Count; ++i)
1065                 {
1066                         float mapindex;
1067                         mapindex = mod(i + Map_Current, Map_Count);
1068                         if(Map_Check(mapindex, pass))
1069                                 return mapindex;
1070                 }
1071         }
1072         return -1;
1073 }
1074
1075 float() MaplistMethod_Repeat = // fallback method
1076 {
1077         dprint("Trying MaplistMethod_Repeat\n");
1078
1079         if(Map_Check(Map_Current, 2))
1080                 return Map_Current;
1081         return -2;
1082 }
1083
1084 float() MaplistMethod_Random = // random map selection
1085 {
1086         float i, imax;
1087
1088         dprint("Trying MaplistMethod_Random\n");
1089
1090         imax = 42;
1091
1092         for(i = 0; i <= imax; ++i)
1093         {
1094                 float mapindex;
1095                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1096                 if(Map_Check(mapindex, 1))
1097                         return mapindex;
1098         }
1099         return -1;
1100 }
1101
1102 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1103 // the exponent sets a bias on the map selection:
1104 // the higher the exponent, the less likely "shortly repeated" same maps are
1105 {
1106         float i, j, imax, insertpos;
1107
1108         dprint("Trying MaplistMethod_Shuffle\n");
1109
1110         imax = 42;
1111
1112         for(i = 0; i <= imax; ++i)
1113         {
1114                 string newlist;
1115
1116                 // now reinsert this at another position
1117                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1118                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1119                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1120                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1121
1122                 // insert the current map there
1123                 newlist = "";
1124                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1125                         newlist = strcat(newlist, " ", argv(j));
1126                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1127                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1128                         newlist = strcat(newlist, " ", argv(j));
1129                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1130                 cvar_set("g_maplist", newlist);
1131                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1132
1133                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1134                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1135                 if(Map_Check(Map_Current, 1))
1136                         return Map_Current;
1137         }
1138         return -1;
1139 }
1140
1141 void Maplist_Init()
1142 {
1143         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1144         float i;
1145         for (i = 0; i < Map_Count; ++i)
1146                 if (Map_Check(i, 2))
1147                         break;
1148         if (i == Map_Count)
1149         {
1150                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1151                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1152                 if(autocvar_g_maplist_shuffle)
1153                         ShuffleMaplist();
1154                 localcmd("\nmenu_cmd sync\n");
1155                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1156         }
1157         if(Map_Count == 0)
1158                 error("empty maplist, cannot select a new map");
1159         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1160
1161         if(Map_Current_Name)
1162                 strunzone(Map_Current_Name);
1163         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1164         // this may or may not be correct, but who cares, in the worst case a map
1165         // isn't chosen in the first pass that should have been
1166 }
1167
1168 string GetNextMap()
1169 {
1170         float nextMap;
1171
1172         Maplist_Init();
1173         nextMap = -1;
1174
1175         if(nextMap == -1)
1176                 if(autocvar_g_maplist_shuffle > 0)
1177                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1178
1179         if(nextMap == -1)
1180                 if(autocvar_g_maplist_selectrandom)
1181                         nextMap = MaplistMethod_Random();
1182
1183         if(nextMap == -1)
1184                 nextMap = MaplistMethod_Iterate();
1185
1186         if(nextMap == -1)
1187                 nextMap = MaplistMethod_Repeat();
1188
1189         if(nextMap >= 0)
1190         {
1191                 Map_Goto_SetFloat(nextMap);
1192                 return getmapname_stored;
1193         }
1194
1195         return "";
1196 }
1197
1198 float DoNextMapOverride(float reinit)
1199 {
1200         if(autocvar_g_campaign)
1201         {
1202                 CampaignPostIntermission();
1203                 alreadychangedlevel = TRUE;
1204                 return TRUE;
1205         }
1206         if(autocvar_quit_when_empty)
1207         {
1208                 if(player_count <= currentbots)
1209                 {
1210                         localcmd("quit\n");
1211                         alreadychangedlevel = TRUE;
1212                         return TRUE;
1213                 }
1214         }
1215         if(autocvar_quit_and_redirect != "")
1216         {
1217                 redirection_target = strzone(autocvar_quit_and_redirect);
1218                 alreadychangedlevel = TRUE;
1219                 return TRUE;
1220         }
1221         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1222         {
1223                 localcmd("restart\n");
1224                 alreadychangedlevel = TRUE;
1225                 return TRUE;
1226         }
1227         if(autocvar_nextmap != "")
1228         {
1229                 string m;
1230                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1231                 cvar_set("nextmap",m);
1232
1233                 if(!m || gametypevote)
1234                         return FALSE;
1235                 if(autocvar_sv_vote_gametype)
1236                 {
1237                         Map_Goto_SetStr(m);
1238                         return FALSE;
1239                 }
1240
1241                 if(MapInfo_CheckMap(m))
1242                 {
1243                         Map_Goto_SetStr(m);
1244                         Map_Goto(reinit);
1245                         alreadychangedlevel = TRUE;
1246                         return TRUE;
1247                 }
1248         }
1249         if(!reinit && autocvar_lastlevel)
1250         {
1251                 cvar_settemp_restore();
1252                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1253                 alreadychangedlevel = TRUE;
1254                 return TRUE;
1255         }
1256         return FALSE;
1257 }
1258
1259 void GotoNextMap(float reinit)
1260 {
1261         //string nextmap;
1262         //float n, nummaps;
1263         //string s;
1264         if (alreadychangedlevel)
1265                 return;
1266         alreadychangedlevel = TRUE;
1267
1268         string nextMap;
1269
1270         nextMap = GetNextMap();
1271         if(nextMap == "")
1272                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1273         Map_Goto(reinit);
1274 }
1275
1276
1277 /*
1278 ============
1279 IntermissionThink
1280
1281 When the player presses attack or jump, change to the next level
1282 ============
1283 */
1284 .float autoscreenshot;
1285 void IntermissionThink()
1286 {
1287         FixIntermissionClient(self);
1288
1289         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1290         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1291
1292         if( (server_screenshot || client_screenshot)
1293                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1294         {
1295                 self.autoscreenshot = -1;
1296                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1297                 return;
1298         }
1299
1300         if (time < intermission_exittime)
1301                 return;
1302
1303         if(!mapvote_initialized)
1304                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1305                         return;
1306
1307         MapVote_Start();
1308 }
1309
1310 /*
1311 ============
1312 FindIntermission
1313
1314 Returns the entity to view from
1315 ============
1316 */
1317 /*
1318 entity FindIntermission()
1319 {
1320         local   entity spot;
1321         local   float cyc;
1322
1323 // look for info_intermission first
1324         spot = find (world, classname, "info_intermission");
1325         if (spot)
1326         {       // pick a random one
1327                 cyc = random() * 4;
1328                 while (cyc > 1)
1329                 {
1330                         spot = find (spot, classname, "info_intermission");
1331                         if (!spot)
1332                                 spot = find (spot, classname, "info_intermission");
1333                         cyc = cyc - 1;
1334                 }
1335                 return spot;
1336         }
1337
1338 // then look for the start position
1339         spot = find (world, classname, "info_player_start");
1340         if (spot)
1341                 return spot;
1342
1343 // testinfo_player_start is only found in regioned levels
1344         spot = find (world, classname, "testplayerstart");
1345         if (spot)
1346                 return spot;
1347
1348 // then look for the start position
1349         spot = find (world, classname, "info_player_deathmatch");
1350         if (spot)
1351                 return spot;
1352
1353         //objerror ("FindIntermission: no spot");
1354         return world;
1355 }
1356 */
1357
1358 /*
1359 ===============================================================================
1360
1361 RULES
1362
1363 ===============================================================================
1364 */
1365
1366 void DumpStats(float final)
1367 {
1368         float file;
1369         string s;
1370         float to_console;
1371         float to_eventlog;
1372         float to_file;
1373         float i;
1374
1375         to_console = autocvar_sv_logscores_console;
1376         to_eventlog = autocvar_sv_eventlog;
1377         to_file = autocvar_sv_logscores_file;
1378
1379         if(!final)
1380         {
1381                 to_console = TRUE; // always print printstats replies
1382                 to_eventlog = FALSE; // but never print them to the event log
1383         }
1384
1385         if(to_eventlog)
1386                 if(autocvar_sv_eventlog_console)
1387                         to_console = FALSE; // otherwise we get the output twice
1388
1389         if(final)
1390                 s = ":scores:";
1391         else
1392                 s = ":status:";
1393         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1394
1395         if(to_console)
1396                 print(s, "\n");
1397         if(to_eventlog)
1398                 GameLogEcho(s);
1399
1400         file = -1;
1401         if(to_file)
1402         {
1403                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1404                 if(file == -1)
1405                         to_file = FALSE;
1406                 else
1407                         fputs(file, strcat(s, "\n"));
1408         }
1409
1410         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1411         if(to_console)
1412                 print(s, "\n");
1413         if(to_eventlog)
1414                 GameLogEcho(s);
1415         if(to_file)
1416                 fputs(file, strcat(s, "\n"));
1417
1418         FOR_EACH_CLIENT(other)
1419         {
1420                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1421                 {
1422                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1423                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1424                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1425                                 s = strcat(s, ftos(other.team), ":");
1426                         else
1427                                 s = strcat(s, "spectator:");
1428
1429                         if(to_console)
1430                                 print(s, other.netname, "\n");
1431                         if(to_eventlog)
1432                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1433                         if(to_file)
1434                                 fputs(file, strcat(s, other.netname, "\n"));
1435                 }
1436         }
1437
1438         if(teamplay)
1439         {
1440                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1441                 if(to_console)
1442                         print(s, "\n");
1443                 if(to_eventlog)
1444                         GameLogEcho(s);
1445                 if(to_file)
1446                         fputs(file, strcat(s, "\n"));
1447
1448                 for(i = 1; i < 16; ++i)
1449                 {
1450                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1451                         s = strcat(s, ":", ftos(i));
1452                         if(to_console)
1453                                 print(s, "\n");
1454                         if(to_eventlog)
1455                                 GameLogEcho(s);
1456                         if(to_file)
1457                                 fputs(file, strcat(s, "\n"));
1458                 }
1459         }
1460
1461         if(to_console)
1462                 print(":end\n");
1463         if(to_eventlog)
1464                 GameLogEcho(":end");
1465         if(to_file)
1466         {
1467                 fputs(file, ":end\n");
1468                 fclose(file);
1469         }
1470 }
1471
1472 void FixIntermissionClient(entity e)
1473 {
1474         string s;
1475         if(!e.autoscreenshot) // initial call
1476         {
1477                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1478                 e.health = -2342;
1479                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1480                 e.solid = SOLID_NOT;
1481                 e.movetype = MOVETYPE_NONE;
1482                 e.takedamage = DAMAGE_NO;
1483                 if(e.weaponentity)
1484                 {
1485                         e.weaponentity.effects = EF_NODRAW;
1486                         if (e.weaponentity.weaponentity)
1487                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1488                 }
1489                 if(IS_REAL_CLIENT(e))
1490                 {
1491                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1492                         s = autocvar_sv_intermission_cdtrack;
1493                         if(s != "")
1494                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1495                         msg_entity = e;
1496                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1497                 }
1498         }
1499 }
1500
1501 /*
1502 go to the next level for deathmatch
1503 only called if a time or frag limit has expired
1504 */
1505 void NextLevel()
1506 {
1507         gameover = TRUE;
1508
1509         intermission_running = 1;
1510
1511 // enforce a wait time before allowing changelevel
1512         if(player_count > 0)
1513                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1514         else
1515                 intermission_exittime = -1;
1516
1517         /*
1518         WriteByte (MSG_ALL, SVC_CDTRACK);
1519         WriteByte (MSG_ALL, 3);
1520         WriteByte (MSG_ALL, 3);
1521         // done in FixIntermission
1522         */
1523
1524         //pos = FindIntermission ();
1525
1526         VoteReset();
1527
1528         DumpStats(TRUE);
1529
1530         // send statistics
1531         entity e;
1532         PlayerStats_EndMatch(1);
1533         FOR_EACH_CLIENT(e)
1534                 PlayerStats_AddGlobalInfo(e);
1535         PlayerStats_Shutdown();
1536         WeaponStats_Shutdown();
1537
1538         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1539
1540         if(autocvar_sv_eventlog)
1541                 GameLogEcho(":gameover");
1542
1543         GameLogClose();
1544
1545         FOR_EACH_PLAYER(other) {
1546                 FixIntermissionClient(other);
1547                 if(other.winning)
1548                         bprint(other.netname, " ^7wins.\n");
1549         }
1550
1551         if(autocvar_g_campaign)
1552                 CampaignPreIntermission();
1553
1554         MUTATOR_CALLHOOK(MatchEnd);
1555
1556         localcmd("\nsv_hook_gameend\n");
1557 }
1558
1559 /*
1560 ============
1561 CheckRules_Player
1562
1563 Exit deathmatch games upon conditions
1564 ============
1565 */
1566 void CheckRules_Player()
1567 {
1568         if (gameover)   // someone else quit the game already
1569                 return;
1570
1571         if(self.deadflag == DEAD_NO)
1572                 self.play_time += frametime;
1573
1574         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1575         //   (div0: and that in CheckRules_World please)
1576 }
1577
1578 float checkrules_equality;
1579 float checkrules_suddendeathwarning;
1580 float checkrules_suddendeathend;
1581 float checkrules_overtimesadded; //how many overtimes have been already added
1582
1583 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1584 const float WINNING_YES = 1; // winner found
1585 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1586 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1587
1588 float InitiateSuddenDeath()
1589 {
1590         // Check first whether normal overtimes could be added before initiating suddendeath mode
1591         // - for this timelimit_overtime needs to be >0 of course
1592         // - also check the winning condition calculated in the previous frame and only add normal overtime
1593         //   again, if at the point at which timelimit would be extended again, still no winner was found
1594         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1595         {
1596                 return 1; // need to call InitiateOvertime later
1597         }
1598         else
1599         {
1600                 if(!checkrules_suddendeathend)
1601                 {
1602                         if(autocvar_g_campaign)
1603                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1604                         else
1605                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1606                         if(g_race && !g_race_qualifying)
1607                                 race_StartCompleting();
1608                 }
1609                 return 0;
1610         }
1611 }
1612
1613 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1614 {
1615         ++checkrules_overtimesadded;
1616         //add one more overtime by simply extending the timelimit
1617         float tl;
1618         tl = autocvar_timelimit;
1619         tl += autocvar_timelimit_overtime;
1620         cvar_set("timelimit", ftos(tl));
1621
1622         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1623 }
1624
1625 float GetWinningCode(float fraglimitreached, float equality)
1626 {
1627         if(autocvar_g_campaign == 1)
1628                 if(fraglimitreached)
1629                         return WINNING_YES;
1630                 else
1631                         return WINNING_NO;
1632
1633         else
1634                 if(equality)
1635                         if(fraglimitreached)
1636                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1637                         else
1638                                 return WINNING_NEVER;
1639                 else
1640                         if(fraglimitreached)
1641                                 return WINNING_YES;
1642                         else
1643                                 return WINNING_NO;
1644 }
1645
1646 // set the .winning flag for exactly those players with a given field value
1647 void SetWinners(.float field, float value)
1648 {
1649         entity head;
1650         FOR_EACH_PLAYER(head)
1651                 head.winning = (head.field == value);
1652 }
1653
1654 // set the .winning flag for those players with a given field value
1655 void AddWinners(.float field, float value)
1656 {
1657         entity head;
1658         FOR_EACH_PLAYER(head)
1659                 if(head.field == value)
1660                         head.winning = 1;
1661 }
1662
1663 // clear the .winning flags
1664 void ClearWinners(void)
1665 {
1666         entity head;
1667         FOR_EACH_PLAYER(head)
1668                 head.winning = 0;
1669 }
1670
1671 // Onslaught winning condition:
1672 // game terminates if only one team has a working generator (or none)
1673 float WinningCondition_Onslaught()
1674 {
1675         entity head;
1676         float t1, t2, t3, t4;
1677
1678         WinningConditionHelper(); // set worldstatus
1679
1680         if(warmup_stage)
1681                 return WINNING_NO;
1682
1683         // first check if the game has ended
1684         t1 = t2 = t3 = t4 = 0;
1685         head = find(world, classname, "onslaught_generator");
1686         while (head)
1687         {
1688                 if (head.health > 0)
1689                 {
1690                         if (head.team == NUM_TEAM_1) t1 = 1;
1691                         if (head.team == NUM_TEAM_2) t2 = 1;
1692                         if (head.team == NUM_TEAM_3) t3 = 1;
1693                         if (head.team == NUM_TEAM_4) t4 = 1;
1694                 }
1695                 head = find(head, classname, "onslaught_generator");
1696         }
1697         if (t1 + t2 + t3 + t4 < 2)
1698         {
1699                 // game over, only one team remains (or none)
1700                 ClearWinners();
1701                 if (t1) SetWinners(team, NUM_TEAM_1);
1702                 if (t2) SetWinners(team, NUM_TEAM_2);
1703                 if (t3) SetWinners(team, NUM_TEAM_3);
1704                 if (t4) SetWinners(team, NUM_TEAM_4);
1705                 dprint("Have a winner, ending game.\n");
1706                 return WINNING_YES;
1707         }
1708
1709         // Two or more teams remain
1710         return WINNING_NO;
1711 }
1712
1713 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1714 // they win. Otherwise the defending team wins once the timelimit passes.
1715 void assault_new_round();
1716 float WinningCondition_Assault()
1717 {
1718         float status;
1719
1720         WinningConditionHelper(); // set worldstatus
1721
1722         status = WINNING_NO;
1723         // as the timelimit has not yet passed just assume the defending team will win
1724         if(assault_attacker_team == NUM_TEAM_1)
1725         {
1726                 SetWinners(team, NUM_TEAM_2);
1727         }
1728         else
1729         {
1730                 SetWinners(team, NUM_TEAM_1);
1731         }
1732
1733         entity ent;
1734         ent = find(world, classname, "target_assault_roundend");
1735         if(ent)
1736         {
1737                 if(ent.winning) // round end has been triggered by attacking team
1738                 {
1739                         bprint("ASSAULT: round completed...\n");
1740                         SetWinners(team, assault_attacker_team);
1741
1742                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1743
1744                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1745                         {
1746                                 status = WINNING_YES;
1747                         }
1748                         else
1749                         {
1750                                 entity oldself;
1751                                 oldself = self;
1752                                 self = ent;
1753                                 assault_new_round();
1754                                 self = oldself;
1755                         }
1756                 }
1757         }
1758
1759         return status;
1760 }
1761
1762 // LMS winning condition: game terminates if and only if there's at most one
1763 // one player who's living lives. Top two scores being equal cancels the time
1764 // limit.
1765 float WinningCondition_LMS()
1766 {
1767         entity head, head2;
1768         float have_player;
1769         float have_players;
1770         float l;
1771
1772         have_player = FALSE;
1773         have_players = FALSE;
1774         l = LMS_NewPlayerLives();
1775
1776         head = find(world, classname, "player");
1777         if(head)
1778                 have_player = TRUE;
1779         head2 = find(head, classname, "player");
1780         if(head2)
1781                 have_players = TRUE;
1782
1783         if(have_player)
1784         {
1785                 // we have at least one player
1786                 if(have_players)
1787                 {
1788                         // two or more active players - continue with the game
1789                 }
1790                 else
1791                 {
1792                         // exactly one player?
1793
1794                         ClearWinners();
1795                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1796
1797                         if(l)
1798                         {
1799                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1800                                 return WINNING_NO;
1801                         }
1802                         else
1803                         {
1804                                 // a winner!
1805                                 // and assign him his first place
1806                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1807                                 return WINNING_YES;
1808                         }
1809                 }
1810         }
1811         else
1812         {
1813                 // nobody is playing at all...
1814                 if(l)
1815                 {
1816                         // wait for players...
1817                 }
1818                 else
1819                 {
1820                         // SNAFU (maybe a draw game?)
1821                         ClearWinners();
1822                         dprint("No players, ending game.\n");
1823                         return WINNING_YES;
1824                 }
1825         }
1826
1827         // When we get here, we have at least two players who are actually LIVING,
1828         // now check if the top two players have equal score.
1829         WinningConditionHelper();
1830
1831         ClearWinners();
1832         if(WinningConditionHelper_winner)
1833                 WinningConditionHelper_winner.winning = TRUE;
1834         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1835                 return WINNING_NEVER;
1836
1837         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1838         return WINNING_NO;
1839 }
1840
1841 void ShuffleMaplist()
1842 {
1843         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1844 }
1845
1846 float leaderfrags;
1847 float WinningCondition_Scores(float limit, float leadlimit)
1848 {
1849         float limitreached;
1850
1851         // TODO make everything use THIS winning condition (except LMS)
1852         WinningConditionHelper();
1853
1854         if(teamplay)
1855         {
1856                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1857                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1858                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1859                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1860         }
1861
1862         ClearWinners();
1863         if(WinningConditionHelper_winner)
1864                 WinningConditionHelper_winner.winning = 1;
1865         if(WinningConditionHelper_winnerteam >= 0)
1866                 SetWinners(team, WinningConditionHelper_winnerteam);
1867
1868         if(WinningConditionHelper_lowerisbetter)
1869         {
1870                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1871                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1872                 limit = -limit;
1873         }
1874
1875         if(WinningConditionHelper_zeroisworst)
1876                 leadlimit = 0; // not supported in this mode
1877
1878         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1879         // these modes always score in increments of 1, thus this makes sense
1880         {
1881                 if(leaderfrags != WinningConditionHelper_topscore)
1882                 {
1883                         leaderfrags = WinningConditionHelper_topscore;
1884
1885                         if (limit)
1886                         if (leaderfrags == limit - 1)
1887                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1888                         else if (leaderfrags == limit - 2)
1889                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1890                         else if (leaderfrags == limit - 3)
1891                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1892                 }
1893         }
1894
1895         limitreached = FALSE;
1896         if(limit)
1897                 if(WinningConditionHelper_topscore >= limit)
1898                         limitreached = TRUE;
1899         if(leadlimit)
1900         {
1901                 float leadlimitreached;
1902                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1903                 if(autocvar_leadlimit_and_fraglimit)
1904                         limitreached = (limitreached && leadlimitreached);
1905                 else
1906                         limitreached = (limitreached || leadlimitreached);
1907         }
1908
1909         if(limit)
1910                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1911
1912         return GetWinningCode(
1913                 WinningConditionHelper_topscore && limitreached,
1914                 WinningConditionHelper_equality
1915         );
1916 }
1917
1918 float WinningCondition_Race(float fraglimit)
1919 {
1920         float wc;
1921         entity p;
1922         float n, c;
1923
1924         n = 0;
1925         c = 0;
1926         FOR_EACH_PLAYER(p)
1927         {
1928                 ++n;
1929                 if(p.race_completed)
1930                         ++c;
1931         }
1932         if(n && (n == c))
1933                 return WINNING_YES;
1934         wc = WinningCondition_Scores(fraglimit, 0);
1935
1936         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1937         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1938         // do NOT support equality when the laps are all raced!
1939                 return WINNING_STARTSUDDENDEATHOVERTIME;
1940         else
1941                 return WINNING_NEVER;
1942 }
1943
1944 float WinningCondition_QualifyingThenRace(float limit)
1945 {
1946         float wc;
1947         wc = WinningCondition_Scores(limit, 0);
1948
1949         // NEVER initiate overtime
1950         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1951         {
1952                 return WINNING_YES;
1953         }
1954
1955         return wc;
1956 }
1957
1958 float WinningCondition_RanOutOfSpawns()
1959 {
1960         entity head;
1961
1962         if(have_team_spawns <= 0)
1963                 return WINNING_NO;
1964
1965         if(autocvar_g_spawn_useallspawns <= 0)
1966                 return WINNING_NO;
1967
1968         if(!some_spawn_has_been_used)
1969                 return WINNING_NO;
1970
1971         team1_score = team2_score = team3_score = team4_score = 0;
1972
1973         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1974         {
1975                 if(head.team == NUM_TEAM_1)
1976                         team1_score = 1;
1977                 else if(head.team == NUM_TEAM_2)
1978                         team2_score = 1;
1979                 else if(head.team == NUM_TEAM_3)
1980                         team3_score = 1;
1981                 else if(head.team == NUM_TEAM_4)
1982                         team4_score = 1;
1983         }
1984
1985         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1986         {
1987                 if(head.team == NUM_TEAM_1)
1988                         team1_score = 1;
1989                 else if(head.team == NUM_TEAM_2)
1990                         team2_score = 1;
1991                 else if(head.team == NUM_TEAM_3)
1992                         team3_score = 1;
1993                 else if(head.team == NUM_TEAM_4)
1994                         team4_score = 1;
1995         }
1996
1997         ClearWinners();
1998         if(team1_score + team2_score + team3_score + team4_score == 0)
1999         {
2000                 checkrules_equality = TRUE;
2001                 return WINNING_YES;
2002         }
2003         else if(team1_score + team2_score + team3_score + team4_score == 1)
2004         {
2005                 float t, i;
2006                 if(team1_score)
2007                         t = NUM_TEAM_1;
2008                 else if(team2_score)
2009                         t = NUM_TEAM_2;
2010                 else if(team3_score)
2011                         t = NUM_TEAM_3;
2012                 else // if(team4_score)
2013                         t = NUM_TEAM_4;
2014                 CheckAllowedTeams(world);
2015                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2016                 {
2017                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2018                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2019                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2020                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2021                 }
2022
2023                 AddWinners(team, t);
2024                 return WINNING_YES;
2025         }
2026         else
2027                 return WINNING_NO;
2028 }
2029
2030 /*
2031 ============
2032 CheckRules_World
2033
2034 Exit deathmatch games upon conditions
2035 ============
2036 */
2037 void ReadyRestart();
2038 void CheckRules_World()
2039 {
2040         float timelimit;
2041         float fraglimit;
2042         float leadlimit;
2043
2044         VoteThink();
2045         MapVote_Think();
2046
2047         SetDefaultAlpha();
2048
2049         if (gameover)   // someone else quit the game already
2050         {
2051                 if(player_count == 0) // Nobody there? Then let's go to the next map
2052                         MapVote_Start();
2053                         // this will actually check the player count in the next frame
2054                         // again, but this shouldn't hurt
2055                 return;
2056         }
2057
2058         timelimit = autocvar_timelimit * 60;
2059         fraglimit = autocvar_fraglimit;
2060         leadlimit = autocvar_leadlimit;
2061
2062         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2063         {
2064                 if(timelimit > 0)
2065                         timelimit = 0; // timelimit is not made for warmup
2066                 if(fraglimit > 0)
2067                         fraglimit = 0; // no fraglimit for now
2068                 leadlimit = 0; // no leadlimit for now
2069         }
2070
2071         if(timelimit > 0)
2072         {
2073                 timelimit += game_starttime;
2074         }
2075         else if (timelimit < 0)
2076         {
2077                 // endmatch
2078                 NextLevel();
2079                 return;
2080         }
2081
2082         if(g_onslaught)
2083                 timelimit = 0; // ONS has its own overtime rule
2084
2085         float wantovertime;
2086         wantovertime = 0;
2087
2088         if(timelimit > game_starttime)
2089                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2090         else
2091                 game_completion_ratio = 0;
2092
2093         if(checkrules_suddendeathend)
2094         {
2095                 if(!checkrules_suddendeathwarning)
2096                 {
2097                         checkrules_suddendeathwarning = TRUE;
2098                         if(g_race && !g_race_qualifying)
2099                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2100                         else
2101                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2102                 }
2103         }
2104         else
2105         {
2106                 if (timelimit && time >= timelimit)
2107                 {
2108                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2109                         {
2110                                 float totalplayers;
2111                                 float playerswithlaps;
2112                                 float readyplayers;
2113                                 entity head;
2114                                 totalplayers = playerswithlaps = readyplayers = 0;
2115                                 FOR_EACH_PLAYER(head)
2116                                 {
2117                                         ++totalplayers;
2118                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2119                                                 ++playerswithlaps;
2120                                         if(head.ready)
2121                                                 ++readyplayers;
2122                                 }
2123
2124                                 // at least 2 of the players have completed a lap: start the RACE
2125                                 // otherwise, the players should end the qualifying on their own
2126                                 if(readyplayers || playerswithlaps >= 2)
2127                                 {
2128                                         checkrules_suddendeathend = 0;
2129                                         ReadyRestart(); // go to race
2130                                         return;
2131                                 }
2132                                 else
2133                                         wantovertime |= InitiateSuddenDeath();
2134                         }
2135                         else
2136                                 wantovertime |= InitiateSuddenDeath();
2137                 }
2138         }
2139
2140         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2141         {
2142                 NextLevel();
2143                 return;
2144         }
2145
2146         float checkrules_status;
2147         checkrules_status = WinningCondition_RanOutOfSpawns();
2148         if(checkrules_status == WINNING_YES)
2149         {
2150                 bprint("Hey! Someone ran out of spawns!\n");
2151         }
2152         else if(g_race && !g_race_qualifying && timelimit >= 0)
2153         {
2154                 checkrules_status = WinningCondition_Race(fraglimit);
2155                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2156         }
2157         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2158         {
2159                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2160                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2161         }
2162         else if(g_assault)
2163         {
2164                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2165         }
2166         else if(g_lms)
2167         {
2168                 checkrules_status = WinningCondition_LMS();
2169         }
2170         else if (g_onslaught)
2171         {
2172                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2173         }
2174         else
2175         {
2176                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2177                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2178         }
2179
2180         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2181         {
2182                 checkrules_status = WINNING_NEVER;
2183                 checkrules_overtimesadded = -1;
2184                 wantovertime |= InitiateSuddenDeath();
2185         }
2186
2187         if(checkrules_status == WINNING_NEVER)
2188                 // equality cases! Nobody wins if the overtime ends in a draw.
2189                 ClearWinners();
2190
2191         if(wantovertime)
2192         {
2193                 if(checkrules_status == WINNING_NEVER)
2194                         InitiateOvertime();
2195                 else
2196                         checkrules_status = WINNING_YES;
2197         }
2198
2199         if(checkrules_suddendeathend)
2200                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2201                         checkrules_status = WINNING_YES;
2202
2203         if(checkrules_status == WINNING_YES)
2204         {
2205                 //print("WINNING\n");
2206                 NextLevel();
2207         }
2208 }
2209
2210 string GotoMap(string m)
2211 {
2212         m = GameTypeVote_MapInfo_FixName(m);
2213         if (!m)
2214                 return "The map you suggested is not available on this server.";
2215         if (!autocvar_sv_vote_gametype)
2216         if(!MapInfo_CheckMap(m))
2217                 return "The map you suggested does not support the current game mode.";
2218         cvar_set("nextmap", m);
2219         cvar_set("timelimit", "-1");
2220         if(mapvote_initialized || alreadychangedlevel)
2221         {
2222                 if(DoNextMapOverride(0))
2223                         return "Map switch initiated.";
2224                 else
2225                         return "Hm... no. For some reason I like THIS map more.";
2226         }
2227         else
2228                 return "Map switch will happen after scoreboard.";
2229 }
2230
2231
2232 void EndFrame()
2233 {
2234         anticheat_endframe();
2235
2236         float altime;
2237         FOR_EACH_REALCLIENT(self)
2238         {
2239                 if(IS_SPEC(self))
2240                 {
2241                         if(self.enemy.typehitsound)
2242                                 self.typehit_time = time;
2243                         else if(self.enemy.hitsound)
2244                                 self.hit_time = time;
2245                 }
2246                 else
2247                 {
2248                         if(self.typehitsound)
2249                                 self.typehit_time = time;
2250                         else if(self.hitsound)
2251                                 self.hit_time = time;
2252                 }
2253         }
2254         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2255         // add 1 frametime because after this, engine SV_Physics
2256         // increases time by a frametime and then networks the frame
2257         // add another frametime because client shows everything with
2258         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2259         // needed!
2260         FOR_EACH_CLIENT(self)
2261         {
2262                 self.hitsound = FALSE;
2263                 self.typehitsound = FALSE;
2264                 antilag_record(self, altime);
2265         }
2266 }
2267
2268
2269 /*
2270  * RedirectionThink:
2271  * returns TRUE if redirecting
2272  */
2273 float redirection_timeout;
2274 float redirection_nextthink;
2275 float RedirectionThink()
2276 {
2277         float clients_found;
2278
2279         if(redirection_target == "")
2280                 return FALSE;
2281
2282         if(!redirection_timeout)
2283         {
2284                 cvar_set("sv_public", "-2");
2285                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2286                 if(redirection_target == "self")
2287                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2288                 else
2289                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2290         }
2291
2292         if(time < redirection_nextthink)
2293                 return TRUE;
2294
2295         redirection_nextthink = time + 1;
2296
2297         clients_found = 0;
2298         FOR_EACH_REALCLIENT(self)
2299         {
2300                 // TODO add timer
2301                 print("Redirecting: sending connect command to ", self.netname, "\n");
2302                 if(redirection_target == "self")
2303                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2304                 else
2305                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2306                 ++clients_found;
2307         }
2308
2309         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2310
2311         if(time > redirection_timeout || clients_found == 0)
2312                 localcmd("\nwait; wait; wait; quit\n");
2313
2314         return TRUE;
2315 }
2316
2317 void TargetMusic_RestoreGame();
2318 void RestoreGame()
2319 {
2320         // Loaded from a save game
2321         // some things then break, so let's work around them...
2322
2323         // Progs DB (capture records)
2324         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2325
2326         // Mapinfo
2327         MapInfo_Shutdown();
2328         MapInfo_Enumerate();
2329         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2330         WeaponStats_Init();
2331
2332         TargetMusic_RestoreGame();
2333 }
2334
2335 void Shutdown()
2336 {
2337         entity e;
2338
2339         gameover = 2;
2340
2341         if(world_initialized > 0)
2342         {
2343                 world_initialized = 0;
2344                 print("Saving persistent data...\n");
2345                 Ban_SaveBans();
2346
2347                 PlayerStats_EndMatch(0);
2348                 FOR_EACH_CLIENT(e)
2349                         PlayerStats_AddGlobalInfo(e);
2350                 PlayerStats_Shutdown();
2351
2352                 if(!cheatcount_total)
2353                 {
2354                         if(autocvar_sv_db_saveasdump)
2355                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2356                         else
2357                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2358                 }
2359                 if(autocvar_developer)
2360                 {
2361                         if(autocvar_sv_db_saveasdump)
2362                                 db_dump(TemporaryDB, "server-temp.db");
2363                         else
2364                                 db_save(TemporaryDB, "server-temp.db");
2365                 }
2366                 CheatShutdown(); // must be after cheatcount check
2367                 db_close(ServerProgsDB);
2368                 db_close(TemporaryDB);
2369                 print("done!\n");
2370                 // tell the bot system the game is ending now
2371                 bot_endgame();
2372
2373                 WeaponStats_Shutdown();
2374                 MapInfo_Shutdown();
2375         }
2376         else if(world_initialized == 0)
2377         {
2378                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2379         }
2380 }