qcsrc/server/ipban.qc

   1 #include "ipban.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "autocvars.qh"
   6 #include "command/banning.qh"
   7 #include "defs.qh"
   8 #include "../common/constants.qh"
   9 #include "../common/util.qh"
  10
  11 /*
  12  * Protocol of online ban list:
  13  *
  14  * - Reporting a ban:
  15  *     GET g_ban_sync_uri?action=ban&hostname=...&ip=xxx.xxx.xxx&duration=nnnn&reason=...................
  16  *     (IP 1, 2, 3, or 4 octets, 3 octets for example is a /24 mask)
  17  * - Removing a ban:
  18  *     GET g_ban_sync_uri?action=unban&hostname=...&ip=xxx.xxx.xxx
  19  * - Querying the ban list
  20  *     GET g_ban_sync_uri?action=list&hostname=...&servers=xxx.xxx.xxx.xxx;xxx.xxx.xxx.xxx;...
  21  *
  22  *     shows the bans from the listed servers, and possibly others.
  23  *     Format of a ban is ASCII plain text, four lines per ban, delimited by
  24  *     newline ONLY (no carriage return):
  25  *
  26  *     IP address (also 1, 2, 3, or 4 octets, delimited by dot)
  27  *     time left in seconds
  28  *     reason of the ban
  29  *     server IP that registered the ban
  30  */
  31
  32 #define MAX_IPBAN_URIS (URI_GET_IPBAN_END - URI_GET_IPBAN + 1)
  33
  34 float Ban_Insert(string ip, float bantime, string reason, float dosync);
  35
  36 void OnlineBanList_SendBan(string ip, float bantime, string reason)
  37 {
  38         string uri;
  39         float i, n;
  40
  41         uri = strcat(     "action=ban&hostname=", uri_escape(autocvar_hostname));
  42         uri = strcat(uri, "&ip=", uri_escape(ip));
  43         uri = strcat(uri, "&duration=", ftos(bantime));
  44         uri = strcat(uri, "&reason=", uri_escape(reason));
  45
  46         n = tokenize_console(autocvar_g_ban_sync_uri);
  47         if(n >= MAX_IPBAN_URIS)
  48                 n = MAX_IPBAN_URIS;
  49         for(i = 0; i < n; ++i)
  50         {
  51                 if(strstrofs(argv(i), "?", 0) >= 0)
  52                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  53                 else
  54                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  55         }
  56 }
  57
  58 void OnlineBanList_SendUnban(string ip)
  59 {
  60         string uri;
  61         float i, n;
  62
  63         uri = strcat(     "action=unban&hostname=", uri_escape(autocvar_hostname));
  64         uri = strcat(uri, "&ip=", uri_escape(ip));
  65
  66         n = tokenize_console(autocvar_g_ban_sync_uri);
  67         if(n >= MAX_IPBAN_URIS)
  68                 n = MAX_IPBAN_URIS;
  69         for(i = 0; i < n; ++i)
  70         {
  71                 if(strstrofs(argv(i), "?", 0) >= 0)
  72                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  73                 else
  74                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  75         }
  76 }
  77
  78 string OnlineBanList_Servers;
  79 float OnlineBanList_Timeout;
  80 float OnlineBanList_RequestWaiting[MAX_IPBAN_URIS];
  81
  82 void OnlineBanList_URI_Get_Callback(float id, float status, string data)
  83 {
  84         float n, i, j, l;
  85         string ip;
  86         float timeleft;
  87         string reason;
  88         string serverip;
  89         float syncinterval;
  90         string uri;
  91
  92         id -= URI_GET_IPBAN;
  93
  94         if(id >= MAX_IPBAN_URIS)
  95         {
  96                 LOG_INFO("Received ban list for invalid ID");
  97                 return;
  98         }
  99
 100         tokenize_console(autocvar_g_ban_sync_uri);
 101         uri = argv(id);
 102
 103         string prelude = strcat("Received ban list from ", uri, ": ");
 104
 105         if(OnlineBanList_RequestWaiting[id] == 0)
 106         {
 107                 LOG_INFO(prelude, "rejected (unexpected)");
 108                 return;
 109         }
 110
 111         OnlineBanList_RequestWaiting[id] = 0;
 112
 113         if(time > OnlineBanList_Timeout)
 114         {
 115                 LOG_INFO(prelude, "rejected (too late)");
 116                 return;
 117         }
 118
 119         syncinterval = autocvar_g_ban_sync_interval;
 120         if(syncinterval == 0)
 121         {
 122                 LOG_INFO(prelude, "rejected (syncing disabled)");
 123                 return;
 124         }
 125         if(syncinterval > 0)
 126                 syncinterval *= 60;
 127
 128         if(status != 0)
 129         {
 130                 LOG_INFO(prelude, "error: status is ", ftos(status));
 131                 return;
 132         }
 133
 134         if(substring(data, 0, 1) == "<")
 135         {
 136                 LOG_INFO(prelude, "error: received HTML instead of a ban list");
 137                 return;
 138         }
 139
 140         if(strstrofs(data, "\r", 0) != -1)
 141         {
 142                 LOG_INFO(prelude, "error: received carriage returns");
 143                 return;
 144         }
 145
 146         if(data == "")
 147                 n = 0;
 148         else
 149                 n = tokenizebyseparator(data, "\n");
 150
 151         if((n % 4) != 0)
 152         {
 153                 LOG_INFO(prelude, "error: received invalid item count: ", ftos(n));
 154                 return;
 155         }
 156
 157         LOG_INFO(prelude, "OK, ", ftos(n / 4), " items");
 158
 159         for(i = 0; i < n; i += 4)
 160         {
 161                 ip = argv(i);
 162                 timeleft = stof(argv(i + 1));
 163                 reason = argv(i + 2);
 164                 serverip = argv(i + 3);
 165
 166                 LOG_TRACE("received ban list item ", ftos(i / 4), ": ip=", ip);
 167                 LOG_TRACE(" timeleft=", ftos(timeleft), " reason=", reason);
 168                 LOG_TRACE(" serverip=", serverip);
 169
 170                 timeleft -= 1.5 * autocvar_g_ban_sync_timeout;
 171                 if(timeleft < 0)
 172                         continue;
 173
 174                 l = strlen(ip);
 175                 if(l != 44) // length 44 is a cryptographic ID
 176                 {
 177                         for(j = 0; j < l; ++j)
 178                                 if(strstrofs("0123456789.", substring(ip, j, 1), 0) == -1)
 179                                 {
 180                                         LOG_INFO("Invalid character ", substring(ip, j, 1), " in IP address ", ip, ". Skipping this ban.");
 181                                         goto skip;
 182                                 }
 183                 }
 184
 185                 if(autocvar_g_ban_sync_trusted_servers_verify)
 186                         if((strstrofs(strcat(";", OnlineBanList_Servers, ";"), strcat(";", serverip, ";"), 0) == -1))
 187                                 continue;
 188
 189                 if(syncinterval > 0)
 190                         timeleft = min(syncinterval + (OnlineBanList_Timeout - time) + 5, timeleft);
 191                         // the ban will be prolonged on the next sync
 192                         // or expire 5 seconds after the next timeout
 193                 Ban_Insert(ip, timeleft, strcat("ban synced from ", serverip, " at ", uri), 0);
 194                 LOG_INFO("Ban list syncing: accepted ban of ", ip, " by ", serverip, " at ", uri, ": ", reason);
 195
 196 LABEL(skip)
 197         }
 198 }
 199
 200 void OnlineBanList_Think(entity this)
 201 {
 202         float argc;
 203         string uri;
 204         float i, n;
 205
 206         if(autocvar_g_ban_sync_uri == "")
 207                 goto killme;
 208         if(autocvar_g_ban_sync_interval == 0) // < 0 is okay, it means "sync on level start only"
 209                 goto killme;
 210         argc = tokenize_console(autocvar_g_ban_sync_trusted_servers);
 211         if(argc == 0)
 212                 goto killme;
 213
 214         string s = argv(0); for(i = 1; i < argc; ++i) s = strcat(s, ";", argv(i));
 215         strcpy(OnlineBanList_Servers, s);
 216
 217         uri = strcat(     "action=list&hostname=", uri_escape(autocvar_hostname));
 218         uri = strcat(uri, "&servers=", uri_escape(OnlineBanList_Servers));
 219
 220         OnlineBanList_Timeout = time + autocvar_g_ban_sync_timeout;
 221
 222         n = tokenize_console(autocvar_g_ban_sync_uri);
 223         if(n >= MAX_IPBAN_URIS)
 224                 n = MAX_IPBAN_URIS;
 225         for(i = 0; i < n; ++i)
 226         {
 227                 if(OnlineBanList_RequestWaiting[i])
 228                         continue;
 229                 OnlineBanList_RequestWaiting[i] = 1;
 230                 if(strstrofs(argv(i), "?", 0) >= 0)
 231                         uri_get(strcat(argv(i), "&", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 232                 else
 233                         uri_get(strcat(argv(i), "?", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 234         }
 235
 236         if(autocvar_g_ban_sync_interval > 0)
 237                 this.nextthink = time + max(60, autocvar_g_ban_sync_interval * 60);
 238         else
 239                 goto killme;
 240         return;
 241
 242 LABEL(killme)
 243         delete(this);
 244 }
 245
 246 const float BAN_MAX = 256;
 247 float ban_loaded;
 248 string ban_ip[BAN_MAX];
 249 float ban_expire[BAN_MAX];
 250 float ban_count;
 251
 252 string ban_ip1;
 253 string ban_ip2;
 254 string ban_ip3;
 255 string ban_ip4;
 256 string ban_idfp;
 257
 258 void Ban_SaveBans()
 259 {
 260         string out;
 261         float i;
 262
 263         if(!ban_loaded)
 264                 return;
 265
 266         // version of list
 267         out = "1";
 268         for(i = 0; i < ban_count; ++i)
 269         {
 270                 if(time > ban_expire[i])
 271                         continue;
 272                 out = strcat(out, " ", ban_ip[i]);
 273                 out = strcat(out, " ", ftos(ban_expire[i] - time));
 274         }
 275         if(strlen(out) <= 1) // no real entries
 276                 cvar_set("g_banned_list", "");
 277         else
 278                 cvar_set("g_banned_list", out);
 279 }
 280
 281 float Ban_Delete(float i)
 282 {
 283         if(i < 0)
 284                 return false;
 285         if(i >= ban_count)
 286                 return false;
 287         if(ban_expire[i] == 0)
 288                 return false;
 289         if(ban_expire[i] > 0)
 290         {
 291                 OnlineBanList_SendUnban(ban_ip[i]);
 292                 strunzone(ban_ip[i]);
 293         }
 294         ban_expire[i] = 0;
 295         ban_ip[i] = "";
 296         Ban_SaveBans();
 297         return true;
 298 }
 299
 300 void Ban_LoadBans()
 301 {
 302         float i, n;
 303         for(i = 0; i < ban_count; ++i)
 304                 Ban_Delete(i);
 305         ban_count = 0;
 306         ban_loaded = true;
 307         n = tokenize_console(autocvar_g_banned_list);
 308         if(stof(argv(0)) == 1)
 309         {
 310                 ban_count = (n - 1) / 2;
 311                 for(i = 0; i < ban_count; ++i)
 312                 {
 313                         ban_ip[i] = strzone(argv(2*i+1));
 314                         ban_expire[i] = time + stof(argv(2*i+2));
 315                 }
 316         }
 317
 318         entity e = new(bansyncer);
 319         setthink(e, OnlineBanList_Think);
 320         e.nextthink = time + 1;
 321 }
 322
 323 void Ban_View()
 324 {
 325         float i, n;
 326         string msg;
 327
 328         LOG_INFO("^2Listing all existing active bans:");
 329
 330         n = 0;
 331         for(i = 0; i < ban_count; ++i)
 332         {
 333                 if(time > ban_expire[i])
 334                         continue;
 335
 336                 ++n; // total number of existing bans
 337
 338                 msg = strcat("#", ftos(i), ": ");
 339                 msg = strcat(msg, ban_ip[i], " is still banned for ");
 340                 msg = strcat(msg, ftos(ban_expire[i] - time), " seconds");
 341
 342                 LOG_INFO("  ", msg);
 343         }
 344
 345         LOG_INFO("^2Done listing all active (", ftos(n), ") bans.");
 346 }
 347
 348 float Ban_GetClientIP(entity client)
 349 {
 350         // we can't use tokenizing here, as this is called during ban list parsing
 351         float i1, i2, i3, i4;
 352         string s;
 353
 354         if(client.crypto_idfp_signed)
 355                 ban_idfp = client.crypto_idfp;
 356         else
 357                 ban_idfp = string_null;
 358
 359         s = client.netaddress;
 360
 361         i1 = strstrofs(s, ".", 0);
 362         if(i1 < 0)
 363                 goto ipv6;
 364         i2 = strstrofs(s, ".", i1 + 1);
 365         if(i2 < 0)
 366                 return false;
 367         i3 = strstrofs(s, ".", i2 + 1);
 368         if(i3 < 0)
 369                 return false;
 370         i4 = strstrofs(s, ".", i3 + 1);
 371         if(i4 >= 0)
 372                 s = substring(s, 0, i4);
 373
 374         ban_ip1 = substring(s, 0, i1); // 8
 375         ban_ip2 = substring(s, 0, i2); // 16
 376         ban_ip3 = substring(s, 0, i3); // 24
 377         ban_ip4 = strcat1(s); // 32
 378         return true;
 379
 380 LABEL(ipv6)
 381         i1 = strstrofs(s, ":", 0);
 382         if(i1 < 0)
 383                 return false;
 384         i1 = strstrofs(s, ":", i1 + 1);
 385         if(i1 < 0)
 386                 return false;
 387         i2 = strstrofs(s, ":", i1 + 1);
 388         if(i2 < 0)
 389                 return false;
 390         i3 = strstrofs(s, ":", i2 + 1);
 391         if(i3 < 0)
 392                 return false;
 393
 394         ban_ip1 = strcat(substring(s, 0, i1), "::/32"); // 32
 395         ban_ip2 = strcat(substring(s, 0, i2), "::/48"); // 48
 396         ban_ip4 = strcat(substring(s, 0, i3), "::/64"); // 64
 397
 398         if(i3 - i2 > 3) // means there is more than 2 digits and a : in the range
 399                 ban_ip3 = strcat(substring(s, 0, i2), ":", substring(s, i2 + 1, i3 - i2 - 3), "00::/56");
 400         else
 401                 ban_ip3 = strcat(substring(s, 0, i2), ":0::/56");
 402
 403         return true;
 404 }
 405
 406 float Ban_IsClientBanned(entity client, float idx)
 407 {
 408         float i, b, e, ipbanned;
 409         if(!ban_loaded)
 410                 Ban_LoadBans();
 411         if(!Ban_GetClientIP(client))
 412                 return false;
 413         if(idx < 0)
 414         {
 415                 b = 0;
 416                 e = ban_count;
 417         }
 418         else
 419         {
 420                 b = idx;
 421                 e = idx + 1;
 422         }
 423         ipbanned = false;
 424         for(i = b; i < e; ++i)
 425         {
 426                 string s;
 427                 if(time > ban_expire[i])
 428                         continue;
 429                 s = ban_ip[i];
 430                 if(ban_ip1 == s) ipbanned = true;
 431                 if(ban_ip2 == s) ipbanned = true;
 432                 if(ban_ip3 == s) ipbanned = true;
 433                 if(ban_ip4 == s) ipbanned = true;
 434                 if(ban_idfp == s) return true;
 435         }
 436         if(ipbanned)
 437         {
 438                 if(!autocvar_g_banned_list_idmode)
 439                         return true;
 440                 if (!ban_idfp)
 441                         return true;
 442         }
 443         return false;
 444 }
 445
 446 bool Ban_MaybeEnforceBan(entity client)
 447 {
 448         if (Ban_IsClientBanned(client, -1))
 449         {
 450                 string s = sprintf("^1NOTE:^7 banned client %s just tried to enter\n", client.netaddress);
 451                 dropclient(client);
 452                 bprint(s);
 453                 return true;
 454         }
 455         return false;
 456 }
 457
 458 .bool ban_checked;
 459 bool Ban_MaybeEnforceBanOnce(entity client)
 460 {
 461         if (client.ban_checked) return false;
 462         client.ban_checked = true;
 463         return Ban_MaybeEnforceBan(client);
 464 }
 465
 466 string Ban_Enforce(float j, string reason)
 467 {
 468         string s;
 469
 470         // Enforce our new ban
 471         s = "";
 472         FOREACH_CLIENTSLOT(IS_REAL_CLIENT(it),
 473         {
 474                 if(Ban_IsClientBanned(it, j))
 475                 {
 476                         if(reason != "")
 477                         {
 478                                 if(s == "")
 479                                         reason = strcat(reason, ": affects ");
 480                                 else
 481                                         reason = strcat(reason, ", ");
 482                                 reason = strcat(reason, it.netname);
 483                         }
 484                         s = strcat(s, "^1NOTE:^7 banned client ", it.netaddress, "^7 has to go\n");
 485                         dropclient(it);
 486                 }
 487         });
 488         bprint(s);
 489
 490         return reason;
 491 }
 492
 493 float Ban_Insert(string ip, float bantime, string reason, float dosync)
 494 {
 495         float i;
 496         float j;
 497         float bestscore;
 498
 499         // already banned?
 500         for(i = 0; i < ban_count; ++i)
 501                 if(ban_ip[i] == ip)
 502                 {
 503                         // prolong the ban
 504                         if(time + bantime > ban_expire[i])
 505                         {
 506                                 ban_expire[i] = time + bantime;
 507                                 LOG_TRACE(ip, "'s ban has been prolonged to ", ftos(bantime), " seconds from now");
 508                         }
 509                         else
 510                                 LOG_TRACE(ip, "'s ban is still active until ", ftos(ban_expire[i] - time), " seconds from now");
 511
 512                         // and enforce
 513                         reason = Ban_Enforce(i, reason);
 514
 515                         // and abort
 516                         if(dosync)
 517                                 if(reason != "")
 518                                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 519                                                 OnlineBanList_SendBan(ip, bantime, reason);
 520
 521                         return false;
 522                 }
 523
 524         // do we have a free slot?
 525         for(i = 0; i < ban_count; ++i)
 526                 if(time > ban_expire[i])
 527                         break;
 528         // no free slot? Then look for the one who would get unbanned next
 529         if(i >= BAN_MAX)
 530         {
 531                 i = 0;
 532                 bestscore = ban_expire[i];
 533                 for(j = 1; j < ban_count; ++j)
 534                 {
 535                         if(ban_expire[j] < bestscore)
 536                         {
 537                                 i = j;
 538                                 bestscore = ban_expire[i];
 539                         }
 540                 }
 541         }
 542         // if we replace someone, will we be banned longer than him (so long-term
 543         // bans never get overridden by short-term bans)
 544         if(i < ban_count)
 545         if(ban_expire[i] > time + bantime)
 546         {
 547                 LOG_INFO(ip, " could not get banned due to no free ban slot");
 548                 return false;
 549         }
 550         // okay, insert our new victim as i
 551         Ban_Delete(i);
 552         LOG_TRACE(ip, " has been banned for ", ftos(bantime), " seconds");
 553         ban_expire[i] = time + bantime;
 554         ban_ip[i] = strzone(ip);
 555         ban_count = max(ban_count, i + 1);
 556
 557         Ban_SaveBans();
 558
 559         reason = Ban_Enforce(i, reason);
 560
 561         // and abort
 562         if(dosync)
 563                 if(reason != "")
 564                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 565                                 OnlineBanList_SendBan(ip, bantime, reason);
 566
 567         return true;
 568 }
 569
 570 void Ban_KickBanClient(entity client, float bantime, float masksize, string reason)
 571 {
 572         string ip, id;
 573         if(!Ban_GetClientIP(client))
 574         {
 575                 sprint(client, strcat("Kickbanned: ", reason, "\n"));
 576                 dropclient(client);
 577                 return;
 578         }
 579
 580         // who to ban?
 581         switch(masksize)
 582         {
 583                 case 1:
 584                         ip = strcat1(ban_ip1);
 585                         break;
 586                 case 2:
 587                         ip = strcat1(ban_ip2);
 588                         break;
 589                 case 3:
 590                         ip = strcat1(ban_ip3);
 591                         break;
 592                 case 4:
 593                 default:
 594                         ip = strcat1(ban_ip4);
 595                         break;
 596         }
 597         if(ban_idfp)
 598                 id = strcat1(ban_idfp);
 599         else
 600                 id = string_null;
 601
 602         Ban_Insert(ip, bantime, reason, 1);
 603         if(id)
 604                 Ban_Insert(id, bantime, reason, 1);
 605         /*
 606          * not needed, as we enforce the ban in Ban_Insert anyway
 607         // and kick him
 608         sprint(client, strcat("Kickbanned: ", reason, "\n"));
 609         dropclient(client);
 610          */
 611 }