qcsrc/server/ipban.qc

   1 /*
   2  * Protocol of online ban list:
   3  *
   4  * - Reporting a ban:
   5  *     GET g_ban_sync_uri?action=ban&hostname=...&ip=xxx.xxx.xxx&duration=nnnn&reason=...................
   6  *     (IP 1, 2, 3, or 4 octets, 3 octets for example is a /24 mask)
   7  * - Removing a ban:
   8  *     GET g_ban_sync_uri?action=unban&hostname=...&ip=xxx.xxx.xxx
   9  * - Querying the ban list
  10  *     GET g_ban_sync_uri?action=list&hostname=...&servers=xxx.xxx.xxx.xxx;xxx.xxx.xxx.xxx;...
  11  *
  12  *     shows the bans from the listed servers, and possibly others.
  13  *     Format of a ban is ASCII plain text, four lines per ban, delimited by
  14  *     newline ONLY (no carriage return):
  15  *
  16  *     IP address (also 1, 2, 3, or 4 octets, delimited by dot)
  17  *     time left in seconds
  18  *     reason of the ban
  19  *     server IP that registered the ban
  20  */
  21
  22 float Ban_Insert(string ip, float bantime, string reason, float dosync);
  23
  24 void OnlineBanList_SendBan(string ip, float bantime, string reason)
  25 {
  26         string uri;
  27         float i, n;
  28
  29         uri = strcat(     "action=ban&hostname=", uri_escape(cvar_string("hostname")));
  30         uri = strcat(uri, "&ip=", uri_escape(ip));
  31         uri = strcat(uri, "&duration=", ftos(bantime));
  32         uri = strcat(uri, "&reason=", uri_escape(reason));
  33
  34         n = tokenize_console(cvar_string("g_ban_sync_uri"));
  35         if(n >= MAX_IPBAN_URIS)
  36                 n = MAX_IPBAN_URIS;
  37         for(i = 0; i < n; ++i)
  38         {
  39                 if(strstrofs(argv(i), "?", 0) >= 0)
  40                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  41                 else
  42                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  43         }
  44 }
  45
  46 void OnlineBanList_SendUnban(string ip)
  47 {
  48         string uri;
  49         float i, n;
  50
  51         uri = strcat(     "action=unban&hostname=", uri_escape(cvar_string("hostname")));
  52         uri = strcat(uri, "&ip=", uri_escape(ip));
  53
  54         n = tokenize_console(cvar_string("g_ban_sync_uri"));
  55         if(n >= MAX_IPBAN_URIS)
  56                 n = MAX_IPBAN_URIS;
  57         for(i = 0; i < n; ++i)
  58         {
  59                 if(strstrofs(argv(i), "?", 0) >= 0)
  60                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  61                 else
  62                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  63         }
  64 }
  65
  66 string OnlineBanList_Servers;
  67 float OnlineBanList_Timeout;
  68 float OnlineBanList_RequestWaiting[MAX_IPBAN_URIS];
  69
  70 void OnlineBanList_URI_Get_Callback(float id, float status, string data)
  71 {
  72         float n, i, j, l;
  73         string ip;
  74         float timeleft;
  75         string reason;
  76         string serverip;
  77         float syncinterval;
  78         string uri;
  79
  80         id -= URI_GET_IPBAN;
  81
  82         if(id >= MAX_IPBAN_URIS)
  83         {
  84                 print("Received ban list for invalid ID\n");
  85                 return;
  86         }
  87
  88         tokenize_console(cvar_string("g_ban_sync_uri"));
  89         uri = argv(id);
  90
  91         print("Received ban list from ", uri, ": ");
  92
  93         if(OnlineBanList_RequestWaiting[id] == 0)
  94         {
  95                 print("rejected (unexpected)\n");
  96                 return;
  97         }
  98
  99         OnlineBanList_RequestWaiting[id] = 0;
 100
 101         if(time > OnlineBanList_Timeout)
 102         {
 103                 print("rejected (too late)\n");
 104                 return;
 105         }
 106
 107         syncinterval = cvar("g_ban_sync_interval");
 108         if(syncinterval == 0)
 109         {
 110                 print("rejected (syncing disabled)\n");
 111                 return;
 112         }
 113         if(syncinterval > 0)
 114                 syncinterval *= 60;
 115
 116         if(status != 0)
 117         {
 118                 print("error: status is ", ftos(status), "\n");
 119                 return;
 120         }
 121
 122         if(substring(data, 0, 1) == "<")
 123         {
 124                 print("error: received HTML instead of a ban list\n");
 125                 return;
 126         }
 127
 128         if(strstrofs(data, "\r", 0) != -1)
 129         {
 130                 print("error: received carriage returns\n");
 131                 return;
 132         }
 133
 134         if(data == "")
 135                 n = 0;
 136         else
 137                 n = tokenizebyseparator(data, "\n");
 138
 139         if(mod(n, 4) != 0)
 140         {
 141                 print("error: received invalid item count: ", ftos(n), "\n");
 142                 return;
 143         }
 144
 145         print("OK, ", ftos(n / 4), " items\n");
 146
 147         for(i = 0; i < n; i += 4)
 148         {
 149                 ip = argv(i);
 150                 timeleft = stof(argv(i + 1));
 151                 reason = argv(i + 2);
 152                 serverip = argv(i + 3);
 153
 154                 dprint("received ban list item ", ftos(i / 4), ": ip=", ip);
 155                 dprint(" timeleft=", ftos(timeleft), " reason=", reason);
 156                 dprint(" serverip=", serverip, "\n");
 157
 158                 timeleft -= 1.5 * cvar("g_ban_sync_timeout");
 159                 if(timeleft < 0)
 160                         continue;
 161
 162                 l = strlen(ip);
 163                 for(j = 0; j < l; ++j)
 164                         if(strstrofs("0123456789.", substring(ip, j, 1), 0) == -1)
 165                         {
 166                                 print("Invalid character ", substring(ip, j, 1), " in IP address ", ip, ". Skipping this ban.\n");
 167                                 goto skip;
 168                         }
 169
 170                 if(cvar("g_ban_sync_trusted_servers_verify"))
 171                         if((strstrofs(strcat(";", OnlineBanList_Servers, ";"), strcat(";", serverip, ";"), 0) == -1))
 172                                 continue;
 173
 174                 if(syncinterval > 0)
 175                         timeleft = min(syncinterval + (OnlineBanList_Timeout - time) + 5, timeleft);
 176                         // the ban will be prolonged on the next sync
 177                         // or expire 5 seconds after the next timeout
 178                 Ban_Insert(ip, timeleft, strcat("ban synced from ", serverip, " at ", uri), 0);
 179                 print("Ban list syncing: accepted ban of ", ip, " by ", serverip, " at ", uri, ": ");
 180                 print(reason, "\n");
 181
 182 :skip
 183         }
 184 }
 185
 186 void OnlineBanList_Think()
 187 {
 188         float argc;
 189         string uri;
 190         float i, n;
 191
 192         if(cvar_string("g_ban_sync_uri") == "")
 193                 goto killme;
 194         if(cvar("g_ban_sync_interval") == 0) // < 0 is okay, it means "sync on level start only"
 195                 goto killme;
 196         argc = tokenize_console(cvar_string("g_ban_sync_trusted_servers"));
 197         if(argc == 0)
 198                 goto killme;
 199
 200         if(OnlineBanList_Servers)
 201                 strunzone(OnlineBanList_Servers);
 202         OnlineBanList_Servers = argv(0);
 203         for(i = 1; i < argc; ++i)
 204                 OnlineBanList_Servers = strcat(OnlineBanList_Servers, ";", argv(i));
 205         OnlineBanList_Servers = strzone(OnlineBanList_Servers);
 206
 207         uri = strcat(     "action=list&hostname=", uri_escape(cvar_string("hostname")));
 208         uri = strcat(uri, "&servers=", uri_escape(OnlineBanList_Servers));
 209
 210         OnlineBanList_Timeout = time + cvar("g_ban_sync_timeout");
 211
 212         n = tokenize_console(cvar_string("g_ban_sync_uri"));
 213         if(n >= MAX_IPBAN_URIS)
 214                 n = MAX_IPBAN_URIS;
 215         for(i = 0; i < n; ++i)
 216         {
 217                 if(OnlineBanList_RequestWaiting[i])
 218                         continue;
 219                 OnlineBanList_RequestWaiting[i] = 1;
 220                 if(strstrofs(argv(i), "?", 0) >= 0)
 221                         uri_get(strcat(argv(i), "&", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 222                 else
 223                         uri_get(strcat(argv(i), "?", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 224         }
 225
 226         if(cvar("g_ban_sync_interval") > 0)
 227                 self.nextthink = time + max(60, cvar("g_ban_sync_interval") * 60);
 228         else
 229                 goto killme;
 230         return;
 231
 232 :killme
 233         remove(self);
 234 }
 235
 236 #define BAN_MAX 256
 237 float ban_loaded;
 238 string ban_ip[BAN_MAX];
 239 float ban_expire[BAN_MAX];
 240 float ban_count;
 241
 242 string ban_ip1;
 243 string ban_ip2;
 244 string ban_ip3;
 245 string ban_ip4;
 246 #ifdef UID
 247 string ban_uid;
 248 #endif
 249
 250 void Ban_SaveBans()
 251 {
 252         string out;
 253         float i;
 254
 255         if(!ban_loaded)
 256                 return;
 257
 258         // version of list
 259         out = "1";
 260         for(i = 0; i < ban_count; ++i)
 261         {
 262                 if(time > ban_expire[i])
 263                         continue;
 264                 out = strcat(out, " ", ban_ip[i]);
 265                 out = strcat(out, " ", ftos(ban_expire[i] - time));
 266         }
 267         if(strlen(out) <= 1) // no real entries
 268                 cvar_set("g_banned_list", "");
 269         else
 270                 cvar_set("g_banned_list", out);
 271 }
 272
 273 float Ban_Delete(float i)
 274 {
 275         if(i < 0)
 276                 return FALSE;
 277         if(i >= ban_count)
 278                 return FALSE;
 279         if(ban_expire[i] == 0)
 280                 return FALSE;
 281         if(ban_expire[i] > 0)
 282         {
 283                 OnlineBanList_SendUnban(ban_ip[i]);
 284                 strunzone(ban_ip[i]);
 285         }
 286         ban_expire[i] = 0;
 287         ban_ip[i] = "";
 288         Ban_SaveBans();
 289         return TRUE;
 290 }
 291
 292 void Ban_LoadBans()
 293 {
 294         float i, n;
 295         for(i = 0; i < ban_count; ++i)
 296                 Ban_Delete(i);
 297         ban_count = 0;
 298         ban_loaded = TRUE;
 299         n = tokenize_console(cvar_string("g_banned_list"));
 300         if(stof(argv(0)) == 1)
 301         {
 302                 ban_count = (n - 1) / 2;
 303                 for(i = 0; i < ban_count; ++i)
 304                 {
 305                         ban_ip[i] = strzone(argv(2*i+1));
 306                         ban_expire[i] = time + stof(argv(2*i+2));
 307                 }
 308         }
 309
 310         entity e;
 311         e = spawn();
 312         e.classname = "bansyncer";
 313         e.think = OnlineBanList_Think;
 314         e.nextthink = time + 1;
 315 }
 316
 317 void Ban_View()
 318 {
 319         float i;
 320         string msg;
 321         for(i = 0; i < ban_count; ++i)
 322         {
 323                 if(time > ban_expire[i])
 324                         continue;
 325                 msg = strcat("#", ftos(i), ": ");
 326                 msg = strcat(msg, ban_ip[i], " is still banned for ");
 327                 msg = strcat(msg, ftos(ban_expire[i] - time), " seconds");
 328                 print(msg, "\n");
 329         }
 330 }
 331
 332 float Ban_GetClientIP(entity client)
 333 {
 334         // we can't use tokenizing here, as this is called during ban list parsing
 335         float i1, i2, i3, i4;
 336         string s;
 337
 338         s = client.netaddress;
 339
 340         i1 = strstrofs(s, ".", 0);
 341         if(i1 < 0)
 342                 i1 = strstrofs(s, ":", 0);
 343         if(i1 < 0)
 344                 return FALSE;
 345         i2 = strstrofs(s, ".", i1 + 1);
 346         if(i2 < 0)
 347                 i2 = strstrofs(s, ":", i1 + 1);
 348         if(i2 < 0)
 349                 return FALSE;
 350         i3 = strstrofs(s, ".", i2 + 1);
 351         if(i3 < 0)
 352                 i3 = strstrofs(s, ":", i2 + 1);
 353         if(i3 < 0)
 354                 return FALSE;
 355         i4 = strstrofs(s, ".", i3 + 1);
 356         if(i4 < 0)
 357                 i4 = strstrofs(s, ":", i3 + 1);
 358         if(i4 >= 0)
 359                 s = substring(s, 0, i4);
 360
 361         ban_ip1 = substring(s, 0, i1);
 362         ban_ip2 = substring(s, 0, i2);
 363         ban_ip3 = substring(s, 0, i3);
 364         ban_ip4 = strcat1(s);
 365 #ifdef UID
 366         ban_uid = client.uid;
 367 #endif
 368
 369         return TRUE;
 370 }
 371
 372 float Ban_IsClientBanned(entity client, float idx)
 373 {
 374         float i, b, e;
 375         if(!ban_loaded)
 376                 Ban_LoadBans();
 377         if(!Ban_GetClientIP(client))
 378                 return FALSE;
 379         if(idx < 0)
 380         {
 381                 b = 0;
 382                 e = ban_count;
 383         }
 384         else
 385         {
 386                 b = idx;
 387                 e = idx + 1;
 388         }
 389         for(i = b; i < e; ++i)
 390         {
 391                 string s;
 392                 if(time > ban_expire[i])
 393                         continue;
 394                 s = ban_ip[i];
 395                 if(ban_ip1 == s) return TRUE;
 396                 if(ban_ip2 == s) return TRUE;
 397                 if(ban_ip3 == s) return TRUE;
 398                 if(ban_ip4 == s) return TRUE;
 399 #ifdef UID
 400                 if(ban_uid == s) return TRUE;
 401 #endif
 402         }
 403         return FALSE;
 404 }
 405
 406 float Ban_MaybeEnforceBan(entity client)
 407 {
 408         if(Ban_IsClientBanned(client, -1))
 409         {
 410                 string s;
 411                 s = strcat("^1NOTE:^7 banned client ", client.netaddress, " just tried to enter\n");
 412                 dropclient(client);
 413                 bprint(s);
 414                 return TRUE;
 415         }
 416         return FALSE;
 417 }
 418
 419 string Ban_Enforce(float i, string reason)
 420 {
 421         string s;
 422         entity e;
 423
 424         // Enforce our new ban
 425         s = "";
 426         FOR_EACH_REALCLIENT(e)
 427                 if(Ban_IsClientBanned(e, i))
 428                 {
 429                         if(reason != "")
 430                         {
 431                                 if(s == "")
 432                                         reason = strcat(reason, ": affects ");
 433                                 else
 434                                         reason = strcat(reason, ", ");
 435                                 reason = strcat(reason, e.netname);
 436                         }
 437                         s = strcat(s, "^1NOTE:^7 banned client ", e.netname, "^7 has to go\n");
 438                         dropclient(e);
 439                 }
 440         bprint(s);
 441
 442         return reason;
 443 }
 444
 445 float Ban_Insert(string ip, float bantime, string reason, float dosync)
 446 {
 447         float i;
 448         float j;
 449         float bestscore;
 450
 451         // already banned?
 452         for(i = 0; i < ban_count; ++i)
 453                 if(ban_ip[i] == ip)
 454                 {
 455                         // prolong the ban
 456                         if(time + bantime > ban_expire[i])
 457                         {
 458                                 ban_expire[i] = time + bantime;
 459                                 dprint(ip, "'s ban has been prolonged to ", ftos(bantime), " seconds from now\n");
 460                         }
 461                         else
 462                                 dprint(ip, "'s ban is still active until ", ftos(ban_expire[i] - time), " seconds from now\n");
 463
 464                         // and enforce
 465                         reason = Ban_Enforce(i, reason);
 466
 467                         // and abort
 468                         if(dosync)
 469                                 if(reason != "")
 470                                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 471                                                 OnlineBanList_SendBan(ip, bantime, reason);
 472
 473                         return FALSE;
 474                 }
 475
 476         // do we have a free slot?
 477         for(i = 0; i < ban_count; ++i)
 478                 if(time > ban_expire[i])
 479                         break;
 480         // no free slot? Then look for the one who would get unbanned next
 481         if(i >= BAN_MAX)
 482         {
 483                 i = 0;
 484                 bestscore = ban_expire[i];
 485                 for(j = 1; j < ban_count; ++j)
 486                 {
 487                         if(ban_expire[j] < bestscore)
 488                         {
 489                                 i = j;
 490                                 bestscore = ban_expire[i];
 491                         }
 492                 }
 493         }
 494         // if we replace someone, will we be banned longer than him (so long-term
 495         // bans never get overridden by short-term bans)
 496         if(i < ban_count)
 497         if(ban_expire[i] > time + bantime)
 498         {
 499                 print(ip, " could not get banned due to no free ban slot\n");
 500                 return FALSE;
 501         }
 502         // okay, insert our new victim as i
 503         Ban_Delete(i);
 504         dprint(ip, " has been banned for ", ftos(bantime), " seconds\n");
 505         ban_expire[i] = time + bantime;
 506         ban_ip[i] = strzone(ip);
 507         ban_count = max(ban_count, i + 1);
 508
 509         Ban_SaveBans();
 510
 511         reason = Ban_Enforce(i, reason);
 512
 513         // and abort
 514         if(dosync)
 515                 if(reason != "")
 516                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 517                                 OnlineBanList_SendBan(ip, bantime, reason);
 518
 519         return TRUE;
 520 }
 521
 522 void Ban_KickBanClient(entity client, float bantime, float masksize, string reason)
 523 {
 524         if(!Ban_GetClientIP(client))
 525         {
 526                 sprint(client, strcat("Kickbanned: ", reason, "\n"));
 527                 dropclient(client);
 528                 return;
 529         }
 530         // now ban him
 531         switch(masksize)
 532         {
 533                 case 1:
 534                         Ban_Insert(ban_ip1, bantime, reason, 1);
 535                         break;
 536                 case 2:
 537                         Ban_Insert(ban_ip2, bantime, reason, 1);
 538                         break;
 539                 case 3:
 540                         Ban_Insert(ban_ip3, bantime, reason, 1);
 541                         break;
 542                 case 4:
 543                 default:
 544                         Ban_Insert(ban_ip4, bantime, reason, 1);
 545                         break;
 546 #ifdef UID
 547                 case 0:
 548                         Ban_Insert(ban_uid, bantime, reason, 1);
 549                         break;
 550 #endif
 551         }
 552         /*
 553          * not needed, as we enforce the ban in Ban_Insert anyway
 554         // and kick him
 555         sprint(client, strcat("Kickbanned: ", reason, "\n"));
 556         dropclient(client);
 557          */
 558 }
 559
 560 float GameCommand_Ban(string command)
 561 {
 562         float argc;
 563         float bantime;
 564         entity client;
 565         float entno;
 566         float masksize;
 567         string reason;
 568         float reasonarg;
 569
 570         argc = tokenize_console(command);
 571         if(argv(0) == "help")
 572         {
 573                 print("  kickban # n m p reason - kickban player n for m seconds, using mask size p (1 to 4)\n");
 574                 print("  ban ip m reason - ban an IP or range (incomplete IP, like 1.2.3) for m seconds\n");
 575                 print("  bans - list all existing bans\n");
 576                 print("  unban n - delete the entry #n from the bans list\n");
 577                 return TRUE;
 578         }
 579         if(argv(0) == "kickban")
 580         {
 581 #define INITARG(c) reasonarg = c
 582 #define GETARG(v,d) if((argc > reasonarg) && ((v = stof(argv(reasonarg))) != 0)) ++reasonarg; else v = d
 583 #define RESTARG(v) if(argc > reasonarg) v = substring(command, argv_start_index(reasonarg), strlen(command) - argv_start_index(reasonarg)); else v = ""
 584                 if(argc >= 3)
 585                 {
 586                         entno = stof(argv(2));
 587                         if(entno > maxclients || entno < 1)
 588                                 return TRUE;
 589                         client = edict_num(entno);
 590
 591                         INITARG(3);
 592                         GETARG(bantime, cvar("g_ban_default_bantime"));
 593                         GETARG(masksize, cvar("g_ban_default_masksize"));
 594                         RESTARG(reason);
 595
 596                         Ban_KickBanClient(client, bantime, masksize, reason);
 597                         return TRUE;
 598                 }
 599         }
 600         else if(argv(0) == "ban")
 601         {
 602                 if(argc >= 2)
 603                 {
 604                         string ip;
 605                         ip = argv(1);
 606
 607                         INITARG(2);
 608                         GETARG(bantime, cvar("g_ban_default_bantime"));
 609                         RESTARG(reason);
 610
 611                         Ban_Insert(ip, bantime, reason, 1);
 612                         return TRUE;
 613                 }
 614 #undef INITARG
 615 #undef GETARG
 616 #undef RESTARG
 617         }
 618         else if(argv(0) == "bans")
 619         {
 620                 Ban_View();
 621                 return TRUE;
 622         }
 623         else if(argv(0) == "unban")
 624         {
 625                 if(argc >= 2)
 626                 {
 627                         float who;
 628                         who = stof(argv(1));
 629                         Ban_Delete(who);
 630                         return TRUE;
 631                 }
 632         }
 633         return FALSE;
 634 }