qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
 394
 395 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 396
 397 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 398
 399 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 400
 401 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 402
 403 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 404
 405 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 406
 407 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 408
 409 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 410
 411 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 412
 413 REPLICATE(cvar_cl_physics, string, "cl_physics");
 414
 415 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 416
 417 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 418
 419 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 420
 421 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 422
 423 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 424
 425 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 426
 427 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 428
 429 /**
 430  * @param f -1: cleanup, 0: request, 1: receive
 431  */
 432 void GetCvars(entity this, entity store, int f)
 433 {
 434         string s = string_null;
 435
 436         if (f == 0)
 437                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 438
 439         if (f > 0)
 440                 s = strcat1(argv(f));
 441
 442         get_cvars_f = f;
 443         get_cvars_s = s;
 444         MUTATOR_CALLHOOK(GetCvars);
 445
 446         Notification_GetCvars(this);
 447
 448         ReplicateVars(this, store, s, f);
 449
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 454         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 455         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 456         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 457         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 458         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 459         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 460         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 461
 462         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 463
 464         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 465         if (f > 0)
 466         {
 467                 if (s == "cl_weaponpriority")
 468                 {
 469                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 470                         {
 471                                 .entity weaponentity = weaponentities[slot];
 472                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 473                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 474                         }
 475                 }
 476                 if (s == "cl_allow_uidtracking")
 477                         PlayerStats_GameReport_AddPlayer(this);
 478         }
 479 }
 480
 481 // decolorizes and team colors the player name when needed
 482 string playername(entity p, bool team_colorize)
 483 {
 484     string t;
 485     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 486     {
 487         t = Team_ColorCode(p.team);
 488         return strcat(t, strdecolorize(p.netname));
 489     }
 490     else
 491         return p.netname;
 492 }
 493
 494 float want_weapon(entity weaponinfo, float allguns)
 495 {
 496         int d = 0;
 497         bool allow_mutatorblocked = false;
 498
 499         if(!weaponinfo.m_id)
 500                 return 0;
 501
 502         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 503         d = M_ARGV(1, float);
 504         allguns = M_ARGV(2, bool);
 505         allow_mutatorblocked = M_ARGV(3, bool);
 506
 507         if(allguns)
 508                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
 509         else if(!mutator_returnvalue)
 510                 d = !(!weaponinfo.weaponstart);
 511
 512         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 513                 d = 0;
 514
 515         float t = weaponinfo.weaponstartoverride;
 516
 517         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 518
 519         // bit order in t:
 520         // 1: want or not
 521         // 2: is default?
 522         // 4: is set by default?
 523         if(t < 0)
 524                 t = 4 | (3 * d);
 525         else
 526                 t |= (2 * d);
 527
 528         return t;
 529 }
 530
 531 /// Weapons the player normally starts with outside weapon arena.
 532 WepSet weapons_start()
 533 {
 534         WepSet ret = '0 0 0';
 535         FOREACH(Weapons, it != WEP_Null, {
 536                 int w = want_weapon(it, false);
 537                 if (w & 1)
 538                         ret |= it.m_wepset;
 539         });
 540         return ret;
 541 }
 542
 543 WepSet weapons_all()
 544 {
 545         WepSet ret = '0 0 0';
 546         FOREACH(Weapons, it != WEP_Null, {
 547                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
 548                         ret |= it.m_wepset;
 549         });
 550         return ret;
 551 }
 552
 553 WepSet weapons_devall()
 554 {
 555         WepSet ret = '0 0 0';
 556         FOREACH(Weapons, it != WEP_Null,
 557         {
 558                 ret |= it.m_wepset;
 559         });
 560         return ret;
 561 }
 562
 563 WepSet weapons_most()
 564 {
 565         WepSet ret = '0 0 0';
 566         FOREACH(Weapons, it != WEP_Null, {
 567                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
 568                         ret |= it.m_wepset;
 569         });
 570         return ret;
 571 }
 572
 573 void weaponarena_available_all_update(entity this)
 574 {
 575         if (weaponsInMapAll)
 576         {
 577                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 578         }
 579         else
 580         {
 581                 // if no weapons are available on the map, just fall back to all weapons arena
 582                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 583         }
 584 }
 585
 586 void weaponarena_available_devall_update(entity this)
 587 {
 588         if (weaponsInMapAll)
 589         {
 590                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 591         }
 592         else
 593         {
 594                 // if no weapons are available on the map, just fall back to devall weapons arena
 595                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 596         }
 597 }
 598
 599 void weaponarena_available_most_update(entity this)
 600 {
 601         if (weaponsInMapAll)
 602         {
 603                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 604         }
 605         else
 606         {
 607                 // if no weapons are available on the map, just fall back to most weapons arena
 608                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 609         }
 610 }
 611
 612 void readplayerstartcvars()
 613 {
 614         float i, t;
 615
 616         // initialize starting values for players
 617         start_weapons = '0 0 0';
 618         start_weapons_default = '0 0 0';
 619         start_weapons_defaultmask = '0 0 0';
 620         start_items = 0;
 621         start_ammo_shells = 0;
 622         start_ammo_nails = 0;
 623         start_ammo_rockets = 0;
 624         start_ammo_cells = 0;
 625         start_ammo_plasma = 0;
 626         if (random_start_ammo == NULL)
 627         {
 628                 random_start_ammo = spawn();
 629         }
 630         start_health = cvar("g_balance_health_start");
 631         start_armorvalue = cvar("g_balance_armor_start");
 632
 633         g_weaponarena = 0;
 634         g_weaponarena_weapons = '0 0 0';
 635
 636         string s = cvar_string("g_weaponarena");
 637
 638         MUTATOR_CALLHOOK(SetWeaponArena, s);
 639         s = M_ARGV(0, string);
 640
 641         if (s == "0" || s == "")
 642         {
 643                 // no arena
 644         }
 645         else if (s == "off")
 646         {
 647                 // forcibly turn off weaponarena
 648         }
 649         else if (s == "all" || s == "1")
 650         {
 651                 g_weaponarena = 1;
 652                 g_weaponarena_list = "All Weapons";
 653                 g_weaponarena_weapons = weapons_all();
 654         }
 655         else if (s == "devall")
 656         {
 657                 g_weaponarena = 1;
 658                 g_weaponarena_list = "Dev All Weapons";
 659                 g_weaponarena_weapons = weapons_devall();
 660         }
 661         else if (s == "most")
 662         {
 663                 g_weaponarena = 1;
 664                 g_weaponarena_list = "Most Weapons";
 665                 g_weaponarena_weapons = weapons_most();
 666         }
 667         else if (s == "all_available")
 668         {
 669                 g_weaponarena = 1;
 670                 g_weaponarena_list = "All Available Weapons";
 671
 672                 // this needs to run after weaponsInMapAll is initialized
 673                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 674         }
 675         else if (s == "devall_available")
 676         {
 677                 g_weaponarena = 1;
 678                 g_weaponarena_list = "Dev All Available Weapons";
 679
 680                 // this needs to run after weaponsInMapAll is initialized
 681                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 682         }
 683         else if (s == "most_available")
 684         {
 685                 g_weaponarena = 1;
 686                 g_weaponarena_list = "Most Available Weapons";
 687
 688                 // this needs to run after weaponsInMapAll is initialized
 689                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 690         }
 691         else if (s == "none")
 692         {
 693                 g_weaponarena = 1;
 694                 g_weaponarena_list = "No Weapons";
 695         }
 696         else
 697         {
 698                 g_weaponarena = 1;
 699                 t = tokenize_console(s);
 700                 g_weaponarena_list = "";
 701                 for (i = 0; i < t; ++i)
 702                 {
 703                         s = argv(i);
 704                         Weapon wep = Weapons_fromstr(s);
 705                         if(wep != WEP_Null)
 706                         {
 707                                 g_weaponarena_weapons |= (wep.m_wepset);
 708                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 709                         }
 710                 }
 711                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 712         }
 713
 714         if (g_weaponarena)
 715         {
 716                 g_weapon_stay = 0; // incompatible
 717                 start_weapons = g_weaponarena_weapons;
 718                 start_items |= IT_UNLIMITED_AMMO;
 719         }
 720         else
 721         {
 722                 FOREACH(Weapons, it != WEP_Null, {
 723                         int w = want_weapon(it, false);
 724                         WepSet s = it.m_wepset;
 725                         if(w & 1)
 726                                 start_weapons |= s;
 727                         if(w & 2)
 728                                 start_weapons_default |= s;
 729                         if(w & 4)
 730                                 start_weapons_defaultmask |= s;
 731                 });
 732         }
 733
 734         if(cvar("g_balance_superweapons_time") < 0)
 735                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 736
 737         if(!cvar("g_use_ammunition"))
 738                 start_items |= IT_UNLIMITED_AMMO;
 739
 740         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 741         {
 742                 start_ammo_shells = 999;
 743                 start_ammo_nails = 999;
 744                 start_ammo_rockets = 999;
 745                 start_ammo_cells = 999;
 746                 start_ammo_plasma = 999;
 747                 start_ammo_fuel = 999;
 748         }
 749         else
 750         {
 751                 start_ammo_shells = cvar("g_start_ammo_shells");
 752                 start_ammo_nails = cvar("g_start_ammo_nails");
 753                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 754                 start_ammo_cells = cvar("g_start_ammo_cells");
 755                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 756                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 757                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 758                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
 759                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
 760                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
 761                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
 762                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
 763         }
 764
 765         warmup_start_ammo_shells = start_ammo_shells;
 766         warmup_start_ammo_nails = start_ammo_nails;
 767         warmup_start_ammo_rockets = start_ammo_rockets;
 768         warmup_start_ammo_cells = start_ammo_cells;
 769         warmup_start_ammo_plasma = start_ammo_plasma;
 770         warmup_start_ammo_fuel = start_ammo_fuel;
 771         warmup_start_health = start_health;
 772         warmup_start_armorvalue = start_armorvalue;
 773         warmup_start_weapons = start_weapons;
 774         warmup_start_weapons_default = start_weapons_default;
 775         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 776
 777         if (!g_weaponarena)
 778         {
 779                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 780                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 781                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 782                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 783                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 784                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 785                 warmup_start_health = cvar("g_warmup_start_health");
 786                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
 787                 warmup_start_weapons = '0 0 0';
 788                 warmup_start_weapons_default = '0 0 0';
 789                 warmup_start_weapons_defaultmask = '0 0 0';
 790                 FOREACH(Weapons, it != WEP_Null, {
 791                         int w = want_weapon(it, g_warmup_allguns);
 792                         WepSet s = it.m_wepset;
 793                         if(w & 1)
 794                                 warmup_start_weapons |= s;
 795                         if(w & 2)
 796                                 warmup_start_weapons_default |= s;
 797                         if(w & 4)
 798                                 warmup_start_weapons_defaultmask |= s;
 799                 });
 800         }
 801
 802         if (g_jetpack)
 803                 start_items |= ITEM_Jetpack.m_itemid;
 804
 805         MUTATOR_CALLHOOK(SetStartItems);
 806
 807         if (start_items & ITEM_Jetpack.m_itemid)
 808         {
 809                 start_items |= ITEM_JetpackRegen.m_itemid;
 810                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 811                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 812         }
 813
 814         start_ammo_shells = max(0, start_ammo_shells);
 815         start_ammo_nails = max(0, start_ammo_nails);
 816         start_ammo_rockets = max(0, start_ammo_rockets);
 817         start_ammo_cells = max(0, start_ammo_cells);
 818         start_ammo_plasma = max(0, start_ammo_plasma);
 819         start_ammo_fuel = max(0, start_ammo_fuel);
 820         SetResource(random_start_ammo, RES_SHELLS,
 821                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
 822         SetResource(random_start_ammo, RES_BULLETS,
 823                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
 824         SetResource(random_start_ammo, RES_ROCKETS,
 825                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
 826         SetResource(random_start_ammo, RES_CELLS,
 827                 max(0, GetResource(random_start_ammo, RES_CELLS)));
 828         SetResource(random_start_ammo, RES_PLASMA,
 829                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
 830
 831         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 832         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 833         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 834         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 835         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 836         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 837 }
 838
 839 void precache_playermodel(string m)
 840 {
 841         float globhandle, i, n;
 842         string f;
 843
 844         if(substring(m, -9, 5) == "_lod1")
 845                 return;
 846         if(substring(m, -9, 5) == "_lod2")
 847                 return;
 848         precache_model(m);
 849         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 850         if(fexists(f))
 851                 precache_model(f);
 852         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 853         if(fexists(f))
 854                 precache_model(f);
 855
 856         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 857         if (globhandle < 0)
 858                 return;
 859         n = search_getsize(globhandle);
 860         for (i = 0; i < n; ++i)
 861         {
 862                 //print(search_getfilename(globhandle, i), "\n");
 863                 f = search_getfilename(globhandle, i);
 864                 PrecachePlayerSounds(f);
 865         }
 866         search_end(globhandle);
 867 }
 868 void precache_all_playermodels(string pattern)
 869 {
 870         int globhandle = search_begin(pattern, true, false);
 871         if (globhandle < 0) return;
 872         int n = search_getsize(globhandle);
 873         for (int i = 0; i < n; ++i)
 874         {
 875                 string s = search_getfilename(globhandle, i);
 876                 precache_playermodel(s);
 877         }
 878         search_end(globhandle);
 879 }
 880
 881 void precache_playermodels(string s)
 882 {
 883         FOREACH_WORD(s, true, { precache_playermodel(it); });
 884 }
 885
 886 void precache()
 887 {
 888     // gamemode related things
 889
 890     // Precache all player models if desired
 891     if (autocvar_sv_precacheplayermodels)
 892     {
 893         PrecachePlayerSounds("sound/player/default.sounds");
 894         precache_all_playermodels("models/player/*.zym");
 895         precache_all_playermodels("models/player/*.dpm");
 896         precache_all_playermodels("models/player/*.md3");
 897         precache_all_playermodels("models/player/*.psk");
 898         precache_all_playermodels("models/player/*.iqm");
 899     }
 900
 901     if (autocvar_sv_defaultcharacter)
 902     {
 903                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 904                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 905                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 906                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 907                 precache_playermodels(autocvar_sv_defaultplayermodel);
 908     }
 909
 910 #if 0
 911     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 912
 913     if (!this.noise && this.music) // quake 3 uses the music field
 914         this.noise = this.music;
 915
 916     // plays music for the level if there is any
 917     if (this.noise)
 918     {
 919         precache_sound (this.noise);
 920         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 921     }
 922 #endif
 923 }
 924
 925
 926 void make_safe_for_remove(entity e)
 927 {
 928     if (e.initialize_entity)
 929     {
 930         entity ent, prev = NULL;
 931         for (ent = initialize_entity_first; ent; )
 932         {
 933             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 934             {
 935                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 936                 // skip it in linked list
 937                 if (prev)
 938                 {
 939                     prev.initialize_entity_next = ent.initialize_entity_next;
 940                     ent = prev.initialize_entity_next;
 941                 }
 942                 else
 943                 {
 944                     initialize_entity_first = ent.initialize_entity_next;
 945                     ent = initialize_entity_first;
 946                 }
 947             }
 948             else
 949             {
 950                 prev = ent;
 951                 ent = ent.initialize_entity_next;
 952             }
 953         }
 954     }
 955 }
 956
 957 .float remove_except_protected_forbidden;
 958 void remove_except_protected(entity e)
 959 {
 960         if(e.remove_except_protected_forbidden)
 961                 error("not allowed to remove this at this point");
 962         builtin_remove(e);
 963 }
 964
 965 void remove_unsafely(entity e)
 966 {
 967     if(e.classname == "spike")
 968         error("Removing spikes is forbidden (crylink bug), please report");
 969     builtin_remove(e);
 970 }
 971
 972 void remove_safely(entity e)
 973 {
 974     make_safe_for_remove(e);
 975     builtin_remove(e);
 976 }
 977
 978 void InitializeEntity(entity e, void(entity this) func, int order)
 979 {
 980     entity prev, cur;
 981
 982     if (!e || e.initialize_entity)
 983     {
 984         // make a proxy initializer entity
 985         entity e_old = e;
 986         e = new(initialize_entity);
 987         e.enemy = e_old;
 988     }
 989
 990     e.initialize_entity = func;
 991     e.initialize_entity_order = order;
 992
 993     cur = initialize_entity_first;
 994     prev = NULL;
 995     for (;;)
 996     {
 997         if (!cur || cur.initialize_entity_order > order)
 998         {
 999             // insert between prev and cur
1000             if (prev)
1001                 prev.initialize_entity_next = e;
1002             else
1003                 initialize_entity_first = e;
1004             e.initialize_entity_next = cur;
1005             return;
1006         }
1007         prev = cur;
1008         cur = cur.initialize_entity_next;
1009     }
1010 }
1011 void InitializeEntitiesRun()
1012 {
1013     entity startoflist = initialize_entity_first;
1014     initialize_entity_first = NULL;
1015     delete_fn = remove_except_protected;
1016     for (entity e = startoflist; e; e = e.initialize_entity_next)
1017     {
1018                 e.remove_except_protected_forbidden = 1;
1019     }
1020     for (entity e = startoflist; e; )
1021     {
1022                 e.remove_except_protected_forbidden = 0;
1023         e.initialize_entity_order = 0;
1024         entity next = e.initialize_entity_next;
1025         e.initialize_entity_next = NULL;
1026         var void(entity this) func = e.initialize_entity;
1027         e.initialize_entity = func_null;
1028         if (e.classname == "initialize_entity")
1029         {
1030             entity wrappee = e.enemy;
1031             builtin_remove(e);
1032             e = wrappee;
1033         }
1034         //dprint("Delayed initialization: ", e.classname, "\n");
1035         if (func)
1036         {
1037                 func(e);
1038         }
1039         else
1040         {
1041             eprint(e);
1042             backtrace(strcat("Null function in: ", e.classname, "\n"));
1043         }
1044         e = next;
1045     }
1046     delete_fn = remove_unsafely;
1047 }
1048
1049 .float(entity) isEliminated;
1050 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1051 {
1052         Stream out = MSG_ENTITY;
1053         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1054         serialize(byte, out, sendflags);
1055         if (sendflags & 1) {
1056                 for (int i = 1; i <= maxclients; i += 8) {
1057                         int f = 0;
1058                         entity e = edict_num(i);
1059                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1060                                 if (eliminatedPlayers.isEliminated(e)) {
1061                                         f |= BIT(b);
1062                                 }
1063                         }
1064                         serialize(byte, out, f);
1065                 }
1066         }
1067         return true;
1068 }
1069
1070 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1071 {
1072         if(eliminatedPlayers)
1073         {
1074                 backtrace("Can't spawn eliminatedPlayers again!");
1075                 return;
1076         }
1077         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1078         eliminatedPlayers.isEliminated = isEliminated_func;
1079 }
1080
1081
1082
1083
1084 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1085 {
1086         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1087                 this.projectiledeathtype |= HITTYPE_SPLASH;
1088         adaptor_think2use(this);
1089 }
1090
1091 // deferred dropping
1092 void DropToFloor_Handler(entity this)
1093 {
1094     WITHSELF(this, builtin_droptofloor());
1095     this.dropped_origin = this.origin;
1096 }
1097
1098 void droptofloor(entity this)
1099 {
1100     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1101 }
1102
1103
1104
1105 float trace_hits_box_a0, trace_hits_box_a1;
1106
1107 float trace_hits_box_1d(float end, float thmi, float thma)
1108 {
1109     if (end == 0)
1110     {
1111         // just check if x is in range
1112         if (0 < thmi)
1113             return false;
1114         if (0 > thma)
1115             return false;
1116     }
1117     else
1118     {
1119         // do the trace with respect to x
1120         // 0 -> end has to stay in thmi -> thma
1121         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1122         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1123         if (trace_hits_box_a0 > trace_hits_box_a1)
1124             return false;
1125     }
1126     return true;
1127 }
1128
1129 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1130 {
1131     end -= start;
1132     thmi -= start;
1133     thma -= start;
1134     // now it is a trace from 0 to end
1135
1136     trace_hits_box_a0 = 0;
1137     trace_hits_box_a1 = 1;
1138
1139     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1140         return false;
1141     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1142         return false;
1143     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1144         return false;
1145
1146     return true;
1147 }
1148
1149 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1150 {
1151     return trace_hits_box(start, end, thmi - ma, thma - mi);
1152 }
1153
1154 bool SUB_NoImpactCheck(entity this, entity toucher)
1155 {
1156         // zero hitcontents = this is not the real impact, but either the
1157         // mirror-impact of something hitting the projectile instead of the
1158         // projectile hitting the something, or a touchareagrid one. Neither of
1159         // these stop the projectile from moving, so...
1160         if(trace_dphitcontents == 0)
1161         {
1162                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1163                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1164         }
1165     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1166         return true;
1167     if (toucher == NULL && this.size != '0 0 0')
1168     {
1169         vector tic;
1170         tic = this.velocity * sys_frametime;
1171         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1172         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1173         if (trace_fraction >= 1)
1174         {
1175             LOG_TRACE("Odd... did not hit...?");
1176         }
1177         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1178         {
1179             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1180             return true;
1181         }
1182     }
1183
1184     return false;
1185 }
1186
1187 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1188
1189 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1190 {
1191         if(SUB_OwnerCheck(this, toucher))
1192                 return true;
1193         if(SUB_NoImpactCheck(this, toucher))
1194         {
1195                 if(this.classname == "nade")
1196                         return false; // no checks here
1197                 else if(this.classname == "grapplinghook")
1198                         RemoveHook(this);
1199                 else
1200                         delete(this);
1201                 return true;
1202         }
1203         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1204                 UpdateCSQCProjectile(this);
1205         return false;
1206 }
1207
1208 /** engine callback */
1209 void URI_Get_Callback(float id, float status, string data)
1210 {
1211         if(url_URI_Get_Callback(id, status, data))
1212         {
1213                 // handled
1214         }
1215         else if (id == URI_GET_DISCARD)
1216         {
1217                 // discard
1218         }
1219         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1220         {
1221                 // sv_cmd curl
1222                 Curl_URI_Get_Callback(id, status, data);
1223         }
1224         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1225         {
1226                 // online ban list
1227                 OnlineBanList_URI_Get_Callback(id, status, data);
1228         }
1229         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1230         {
1231                 // handled by a mutator
1232         }
1233         else
1234         {
1235                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1236         }
1237 }
1238
1239 string uid2name(string myuid) {
1240         string s;
1241         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1242
1243         // FIXME remove this later after 0.6 release
1244         // convert old style broken records to correct style
1245         if(s == "")
1246         {
1247                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1248                 if(s != "")
1249                 {
1250                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1251                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1252                 }
1253         }
1254
1255         if(s == "")
1256                 s = "^1Unregistered Player";
1257         return s;
1258 }
1259
1260 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1261 {
1262     float m, i;
1263     vector start, org, delta, end, enddown, mstart;
1264
1265     m = e.dphitcontentsmask;
1266     e.dphitcontentsmask = goodcontents | badcontents;
1267
1268     org = boundmin;
1269     delta = boundmax - boundmin;
1270
1271     start = end = org;
1272
1273     for (i = 0; i < attempts; ++i)
1274     {
1275         start.x = org.x + random() * delta.x;
1276         start.y = org.y + random() * delta.y;
1277         start.z = org.z + random() * delta.z;
1278
1279         // rule 1: start inside world bounds, and outside
1280         // solid, and don't start from somewhere where you can
1281         // fall down to evil
1282         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1283         if (trace_fraction >= 1)
1284             continue;
1285         if (trace_startsolid)
1286             continue;
1287         if (trace_dphitcontents & badcontents)
1288             continue;
1289         if (trace_dphitq3surfaceflags & badsurfaceflags)
1290             continue;
1291
1292         // rule 2: if we are too high, lower the point
1293         if (trace_fraction * delta.z > maxaboveground)
1294             start = trace_endpos + '0 0 1' * maxaboveground;
1295         enddown = trace_endpos;
1296
1297         // rule 3: make sure we aren't outside the map. This only works
1298         // for somewhat well formed maps. A good rule of thumb is that
1299         // the map should have a convex outside hull.
1300         // these can be traceLINES as we already verified the starting box
1301         mstart = start + 0.5 * (e.mins + e.maxs);
1302         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1303         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1304             continue;
1305         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1306         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1307             continue;
1308         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1309         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1310             continue;
1311         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1312         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1313             continue;
1314         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1315         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1316             continue;
1317
1318         // rule 4: we must "see" some spawnpoint or item
1319     entity sp = NULL;
1320     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1321     {
1322         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1323         {
1324                 sp = it;
1325                 break;
1326         }
1327     });
1328         if(!sp)
1329         {
1330                 int items_checked = 0;
1331                 IL_EACH(g_items, checkpvs(mstart, it),
1332                 {
1333                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1334                         {
1335                                 sp = it;
1336                                 break;
1337                         }
1338
1339                         ++items_checked;
1340                         if(items_checked >= attempts)
1341                                 break; // sanity
1342                 });
1343
1344                 if(!sp)
1345                         continue;
1346         }
1347
1348         // find a random vector to "look at"
1349         end.x = org.x + random() * delta.x;
1350         end.y = org.y + random() * delta.y;
1351         end.z = org.z + random() * delta.z;
1352         end = start + normalize(end - start) * vlen(delta);
1353
1354         // rule 4: start TO end must not be too short
1355         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1356         if (trace_startsolid)
1357             continue;
1358         if (trace_fraction < minviewdistance / vlen(delta))
1359             continue;
1360
1361         // rule 5: don't want to look at sky
1362         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1363             continue;
1364
1365         // rule 6: we must not end up in trigger_hurt
1366         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1367             continue;
1368
1369         break;
1370     }
1371
1372     e.dphitcontentsmask = m;
1373
1374     if (i < attempts)
1375     {
1376         setorigin(e, start);
1377         e.angles = vectoangles(end - start);
1378         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1379         return true;
1380     }
1381     else
1382         return false;
1383 }
1384
1385 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1386 {
1387         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1388 }
1389
1390 void write_recordmarker(entity pl, float tstart, float dt)
1391 {
1392     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1393
1394     // also write a marker into demo files for demotc-race-record-extractor to find
1395     stuffcmd(pl,
1396              strcat(
1397                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1398                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1399 }
1400
1401 void attach_sameorigin(entity e, entity to, string tag)
1402 {
1403     vector org, t_forward, t_left, t_up, e_forward, e_up;
1404     float tagscale;
1405
1406     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1407     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1408     t_forward = v_forward * tagscale;
1409     t_left = v_right * -tagscale;
1410     t_up = v_up * tagscale;
1411
1412     e.origin_x = org * t_forward;
1413     e.origin_y = org * t_left;
1414     e.origin_z = org * t_up;
1415
1416     // current forward and up directions
1417     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1418                 e.angles = AnglesTransform_FromVAngles(e.angles);
1419         else
1420                 e.angles = AnglesTransform_FromAngles(e.angles);
1421     fixedmakevectors(e.angles);
1422
1423     // untransform forward, up!
1424     e_forward.x = v_forward * t_forward;
1425     e_forward.y = v_forward * t_left;
1426     e_forward.z = v_forward * t_up;
1427     e_up.x = v_up * t_forward;
1428     e_up.y = v_up * t_left;
1429     e_up.z = v_up * t_up;
1430
1431     e.angles = fixedvectoangles2(e_forward, e_up);
1432     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1433                 e.angles = AnglesTransform_ToVAngles(e.angles);
1434         else
1435                 e.angles = AnglesTransform_ToAngles(e.angles);
1436
1437     setattachment(e, to, tag);
1438     setorigin(e, e.origin);
1439 }
1440
1441 void detach_sameorigin(entity e)
1442 {
1443     vector org;
1444     org = gettaginfo(e, 0);
1445     e.angles = fixedvectoangles2(v_forward, v_up);
1446     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1447                 e.angles = AnglesTransform_ToVAngles(e.angles);
1448         else
1449                 e.angles = AnglesTransform_ToAngles(e.angles);
1450     setorigin(e, org);
1451     setattachment(e, NULL, "");
1452     setorigin(e, e.origin);
1453 }
1454
1455 void follow_sameorigin(entity e, entity to)
1456 {
1457     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1458     e.aiment = to; // make the hole follow bmodel
1459     e.punchangle = to.angles; // the original angles of bmodel
1460     e.view_ofs = e.origin - to.origin; // relative origin
1461     e.v_angle = e.angles - to.angles; // relative angles
1462 }
1463
1464 void unfollow_sameorigin(entity e)
1465 {
1466     set_movetype(e, MOVETYPE_NONE);
1467 }
1468
1469 entity gettaginfo_relative_ent;
1470 vector gettaginfo_relative(entity e, float tag)
1471 {
1472     if (!gettaginfo_relative_ent)
1473     {
1474         gettaginfo_relative_ent = spawn();
1475         gettaginfo_relative_ent.effects = EF_NODRAW;
1476     }
1477     gettaginfo_relative_ent.model = e.model;
1478     gettaginfo_relative_ent.modelindex = e.modelindex;
1479     gettaginfo_relative_ent.frame = e.frame;
1480     return gettaginfo(gettaginfo_relative_ent, tag);
1481 }
1482
1483 .string aiment_classname;
1484 .float aiment_deadflag;
1485 void SetMovetypeFollow(entity ent, entity e)
1486 {
1487         // FIXME this may not be warpzone aware
1488         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1489         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1490         ent.aiment = e; // make the hole follow bmodel
1491         ent.punchangle = e.angles; // the original angles of bmodel
1492         ent.view_ofs = ent.origin - e.origin; // relative origin
1493         ent.v_angle = ent.angles - e.angles; // relative angles
1494         ent.aiment_classname = strzone(e.classname);
1495         ent.aiment_deadflag = e.deadflag;
1496 }
1497 void UnsetMovetypeFollow(entity ent)
1498 {
1499         set_movetype(ent, MOVETYPE_FLY);
1500         PROJECTILE_MAKETRIGGER(ent);
1501         ent.aiment = NULL;
1502 }
1503 float LostMovetypeFollow(entity ent)
1504 {
1505 /*
1506         if(ent.move_movetype != MOVETYPE_FOLLOW)
1507                 if(ent.aiment)
1508                         error("???");
1509 */
1510         if(ent.aiment)
1511         {
1512                 if(ent.aiment.classname != ent.aiment_classname)
1513                         return 1;
1514                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1515                         return 1;
1516         }
1517         return 0;
1518 }
1519
1520 .bool pushable;
1521 bool isPushable(entity e)
1522 {
1523         if(e.pushable)
1524                 return true;
1525         if(IS_VEHICLE(e))
1526                 return false;
1527         if(e.iscreature)
1528                 return true;
1529         if (Item_IsLoot(e))
1530         {
1531                 return true;
1532         }
1533         switch(e.classname)
1534         {
1535                 case "body":
1536                         return true;
1537                 case "bullet": // antilagged bullets can't hit this either
1538                         return false;
1539         }
1540         if (e.projectiledeathtype)
1541                 return true;
1542         return false;
1543 }