Merge remote branch 'origin/terencehill/incompatible_mutators'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void crosshair_trace_plusvisibletriggers(entity pl)
12 {
13         entity first;
14         entity e;
15         first = findchainfloat(solid, SOLID_TRIGGER);
16
17         for (e = first; e; e = e.chain)
18                 if (e.model != "")
19                         e.solid = SOLID_BSP;
20
21         crosshair_trace(pl);
22
23         for (e = first; e; e = e.chain)
24                 e.solid = SOLID_TRIGGER;
25 }
26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
27 void WarpZone_crosshair_trace(entity pl)
28 {
29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
30 }
31
32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
33 void() spawnpoint_use;
34 string GetMapname();
35 string ColoredTeamName(float t);
36
37 string admin_name(void)
38 {
39         if(autocvar_sv_adminnick != "")
40                 return autocvar_sv_adminnick;
41         else
42                 return "SERVER ADMIN";
43 }
44
45 float DistributeEvenly_amount;
46 float DistributeEvenly_totalweight;
47 void DistributeEvenly_Init(float amount, float totalweight)
48 {
49     if (DistributeEvenly_amount)
50     {
51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
53     }
54     if (totalweight == 0)
55         DistributeEvenly_amount = 0;
56     else
57         DistributeEvenly_amount = amount;
58     DistributeEvenly_totalweight = totalweight;
59 }
60 float DistributeEvenly_Get(float weight)
61 {
62     float f;
63     if (weight <= 0)
64         return 0;
65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
66     DistributeEvenly_totalweight -= weight;
67     DistributeEvenly_amount -= f;
68     return f;
69 }
70
71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
72
73
74 string STR_PLAYER = "player";
75 string STR_SPECTATOR = "spectator";
76 string STR_OBSERVER = "observer";
77
78 #if 0
79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
83 #else
84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
89 #endif
90
91 // copies a string to a tempstring (so one can strunzone it)
92 string strcat1(string s) = #115; // FRIK_FILE
93
94 float logfile_open;
95 float logfile;
96
97 void bcenterprint(string s)
98 {
99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
100     entity head;
101     FOR_EACH_PLAYER(head)
102     if (clienttype(head) == CLIENTTYPE_REAL)
103         centerprint(head, s);
104 }
105
106 void GameLogEcho(string s)
107 {
108     string fn;
109     float matches;
110
111     if (autocvar_sv_eventlog_files)
112     {
113         if (!logfile_open)
114         {
115             logfile_open = TRUE;
116             matches = autocvar_sv_eventlog_files_counter + 1;
117             cvar_set("sv_eventlog_files_counter", ftos(matches));
118             fn = ftos(matches);
119             if (strlen(fn) < 8)
120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
122             logfile = fopen(fn, FILE_APPEND);
123             fputs(logfile, ":logversion:3\n");
124         }
125         if (logfile >= 0)
126         {
127             if (autocvar_sv_eventlog_files_timestamps)
128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
129             else
130                 fputs(logfile, strcat(s, "\n"));
131         }
132     }
133     if (autocvar_sv_eventlog_console)
134     {
135         print(s, "\n");
136     }
137 }
138
139 void GameLogInit()
140 {
141     logfile_open = 0;
142     // will be opened later
143 }
144
145 void GameLogClose()
146 {
147     if (logfile_open && logfile >= 0)
148     {
149         fclose(logfile);
150         logfile = -1;
151     }
152 }
153
154 float spawnpoint_nag;
155 void relocate_spawnpoint()
156 {
157     // nudge off the floor
158     setorigin(self, self.origin + '0 0 1');
159
160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
161     if (trace_startsolid)
162     {
163         vector o;
164         o = self.origin;
165         self.mins = PL_MIN;
166         self.maxs = PL_MAX;
167         if (!move_out_of_solid(self))
168             objerror("could not get out of solid at all!");
169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
171         print(" ", ftos(self.origin_y - o_y));
172         print(" ", ftos(self.origin_z - o_z), "'\n");
173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
174         {
175             if (!spawnpoint_nag)
176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
177             spawnpoint_nag = 1;
178         }
179         else
180         {
181             setorigin(self, o);
182             self.mins = self.maxs = '0 0 0';
183             objerror("player spawn point in solid, mapper sucks!\n");
184             return;
185         }
186     }
187
188     self.use = spawnpoint_use;
189     self.team_saved = self.team;
190     if (!self.cnt)
191         self.cnt = 1;
192
193     if (have_team_spawns != 0)
194         if (self.team)
195             have_team_spawns = 1;
196     have_team_spawns_forteam[self.team] = 1;
197
198     if (autocvar_r_showbboxes)
199     {
200         // show where spawnpoints point at too
201         makevectors(self.angles);
202         entity e;
203         e = spawn();
204         e.classname = "info_player_foo";
205         setorigin(e, self.origin + v_forward * 24);
206         setsize(e, '-8 -8 -8', '8 8 8');
207         e.solid = SOLID_TRIGGER;
208     }
209 }
210
211 #define strstr strstrofs
212 /*
213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
216 // BE CONSTANT OR strzoneD!
217 float strstr(string haystack, string needle, float offset)
218 {
219         float len, endpos;
220         string found;
221         len = strlen(needle);
222         endpos = strlen(haystack) - len;
223         while(offset <= endpos)
224         {
225                 found = substring(haystack, offset, len);
226                 if(found == needle)
227                         return offset;
228                 offset = offset + 1;
229         }
230         return -1;
231 }
232 */
233
234 float NUM_NEAREST_ENTITIES = 4;
235 entity nearest_entity[NUM_NEAREST_ENTITIES];
236 float nearest_length[NUM_NEAREST_ENTITIES];
237 entity findnearest(vector point, .string field, string value, vector axismod)
238 {
239     entity localhead;
240     float i;
241     float j;
242     float len;
243     vector dist;
244
245     float num_nearest;
246     num_nearest = 0;
247
248     localhead = find(world, field, value);
249     while (localhead)
250     {
251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
252             dist = localhead.oldorigin;
253         else
254             dist = localhead.origin;
255         dist = dist - point;
256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
257         len = vlen(dist);
258
259         for (i = 0; i < num_nearest; ++i)
260         {
261             if (len < nearest_length[i])
262                 break;
263         }
264
265         // now i tells us where to insert at
266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
267         if (i < NUM_NEAREST_ENTITIES)
268         {
269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
270             {
271                 nearest_length[j + 1] = nearest_length[j];
272                 nearest_entity[j + 1] = nearest_entity[j];
273             }
274             nearest_length[i] = len;
275             nearest_entity[i] = localhead;
276             if (num_nearest < NUM_NEAREST_ENTITIES)
277                 num_nearest = num_nearest + 1;
278         }
279
280         localhead = find(localhead, field, value);
281     }
282
283     // now use the first one from our list that we can see
284     for (i = 0; i < num_nearest; ++i)
285     {
286         traceline(point, nearest_entity[i].origin, TRUE, world);
287         if (trace_fraction == 1)
288         {
289             if (i != 0)
290             {
291                 dprint("Nearest point (");
292                 dprint(nearest_entity[0].netname);
293                 dprint(") is not visible, using a visible one.\n");
294             }
295             return nearest_entity[i];
296         }
297     }
298
299     if (num_nearest == 0)
300         return world;
301
302     dprint("Not seeing any location point, using nearest as fallback.\n");
303     /* DEBUGGING CODE:
304     dprint("Candidates were: ");
305     for(j = 0; j < num_nearest; ++j)
306     {
307         if(j != 0)
308                 dprint(", ");
309         dprint(nearest_entity[j].netname);
310     }
311     dprint("\n");
312     */
313
314     return nearest_entity[0];
315 }
316
317 void spawnfunc_target_location()
318 {
319     self.classname = "target_location";
320     // location name in netname
321     // eventually support: count, teamgame selectors, line of sight?
322 }
323
324 void spawnfunc_info_location()
325 {
326     self.classname = "target_location";
327     self.message = self.netname;
328 }
329
330 string NearestLocation(vector p)
331 {
332     entity loc;
333     string ret;
334     ret = "somewhere";
335     loc = findnearest(p, classname, "target_location", '1 1 1');
336     if (loc)
337     {
338         ret = loc.message;
339     }
340     else
341     {
342         loc = findnearest(p, target, "###item###", '1 1 4');
343         if (loc)
344             ret = loc.netname;
345     }
346     return ret;
347 }
348
349 string formatmessage(string msg)
350 {
351         float p, p1, p2;
352         float n;
353         vector cursor;
354         entity cursor_ent;
355         string escape;
356         string replacement;
357         p = 0;
358         n = 7;
359
360         WarpZone_crosshair_trace(self);
361         cursor = trace_endpos;
362         cursor_ent = trace_ent;
363
364         while (1) {
365                 if (n < 1)
366                         break; // too many replacements
367
368                 n = n - 1;
369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
371
372                 if (p1 < 0)
373                         p1 = p2;
374
375                 if (p2 < 0)
376                         p2 = p1;
377
378                 p = min(p1, p2);
379
380                 if (p < 0)
381                         break;
382
383                 replacement = substring(msg, p, 2);
384                 escape = substring(msg, p + 1, 1);
385
386                 if (escape == "%")
387                         replacement = "%";
388                 else if (escape == "\\")
389                         replacement = "\\";
390                 else if (escape == "n")
391                         replacement = "\n";
392                 else if (escape == "a")
393                         replacement = ftos(floor(self.armorvalue));
394                 else if (escape == "h")
395                         replacement = ftos(floor(self.health));
396                 else if (escape == "l")
397                         replacement = NearestLocation(self.origin);
398                 else if (escape == "y")
399                         replacement = NearestLocation(cursor);
400                 else if (escape == "d")
401                         replacement = NearestLocation(self.death_origin);
402                 else if (escape == "w") {
403                         float wep;
404                         wep = self.weapon;
405                         if (!wep)
406                                 wep = self.switchweapon;
407                         if (!wep)
408                                 wep = self.cnt;
409                         replacement = W_Name(wep);
410                 } else if (escape == "W") {
411                         if (self.items & IT_SHELLS) replacement = "shells";
412                         else if (self.items & IT_NAILS) replacement = "bullets";
413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
414                         else if (self.items & IT_CELLS) replacement = "cells";
415                         else replacement = "batteries"; // ;)
416                 } else if (escape == "x") {
417                         replacement = cursor_ent.netname;
418                         if (!replacement || !cursor_ent)
419                                 replacement = "nothing";
420                 } else if (escape == "s")
421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
422                 else if (escape == "S")
423                         replacement = ftos(vlen(self.velocity));
424
425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
426                 p = p + strlen(replacement);
427         }
428         return msg;
429 }
430
431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
432         return (value == 0) ? FALSE : TRUE;
433 }
434
435 /*
436 =============
437 GetCvars
438 =============
439 Called with:
440   0:  sends the request
441   >0: receives a cvar from name=argv(f) value=argv(f+1)
442 */
443 void GetCvars_handleString(string thisname, float f, .string field, string name)
444 {
445         if (f < 0)
446         {
447                 if (self.field)
448                         strunzone(self.field);
449                 self.field = string_null;
450         }
451         else if (f > 0)
452         {
453                 if (thisname == name)
454                 {
455                         if (self.field)
456                                 strunzone(self.field);
457                         self.field = strzone(argv(f + 1));
458                 }
459         }
460         else
461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
462 }
463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
464 {
465         GetCvars_handleString(thisname, f, field, name);
466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
467                 if (thisname == name)
468                 {
469                         string s;
470                         s = func(strcat1(self.field));
471                         if (s != self.field)
472                         {
473                                 strunzone(self.field);
474                                 self.field = strzone(s);
475                         }
476                 }
477 }
478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
479 {
480         if (f < 0)
481         {
482         }
483         else if (f > 0)
484         {
485                 if (thisname == name)
486                         self.field = stof(argv(f + 1));
487         }
488         else
489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
490 }
491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
492 {
493         if (f < 0)
494         {
495         }
496         else if (f > 0)
497         {
498                 if (thisname == name)
499                 {
500                         if(!self.field)
501                         {
502                                 self.field = stof(argv(f + 1));
503                                 if(!self.field)
504                                         self.field = -1;
505                         }
506                 }
507         }
508         else
509         {
510                 if(!self.field)
511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
512         }
513 }
514 float w_getbestweapon(entity e);
515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
516 {
517         string o;
518         o = W_FixWeaponOrder_ForceComplete(wo);
519         if(self.weaponorder_byimpulse)
520         {
521                 strunzone(self.weaponorder_byimpulse);
522                 self.weaponorder_byimpulse = string_null;
523         }
524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
525         return o;
526 }
527 void GetCvars(float f)
528 {
529         string s;
530
531         if (f > 0)
532                 s = strcat1(argv(f));
533
534         get_cvars_f = f;
535         get_cvars_s = s;
536         MUTATOR_CALLHOOK(GetCvars);
537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
560
561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
563
564 #ifdef ALLOW_FORCEMODELS
565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
567 #endif
568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
573
574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
575         if (f > 0)
576         {
577                 if (s == "cl_weaponpriority")
578                         self.switchweapon = w_getbestweapon(self);
579                 if (s == "cl_allow_uidtracking")
580                         PlayerStats_AddPlayer(self);
581         }
582 }
583
584 void backtrace(string msg)
585 {
586     float dev, war;
587     dev = autocvar_developer;
588     war = autocvar_prvm_backtraceforwarnings;
589     cvar_set("developer", "1");
590     cvar_set("prvm_backtraceforwarnings", "1");
591     print("\n");
592     print("--- CUT HERE ---\nWARNING: ");
593     print(msg);
594     print("\n");
595     remove(world); // isn't there any better way to cause a backtrace?
596     print("\n--- CUT UNTIL HERE ---\n");
597     cvar_set("developer", ftos(dev));
598     cvar_set("prvm_backtraceforwarnings", ftos(war));
599 }
600
601 string Team_ColorCode(float teamid)
602 {
603     if (teamid == COLOR_TEAM1)
604         return "^1";
605     else if (teamid == COLOR_TEAM2)
606         return "^4";
607     else if (teamid == COLOR_TEAM3)
608         return "^3";
609     else if (teamid == COLOR_TEAM4)
610         return "^6";
611     else
612         return "^7";
613 }
614
615 string Team_ColorName(float t)
616 {
617     // fixme: Search for team entities and get their .netname's!
618     if (t == COLOR_TEAM1)
619         return "Red";
620     if (t == COLOR_TEAM2)
621         return "Blue";
622     if (t == COLOR_TEAM3)
623         return "Yellow";
624     if (t == COLOR_TEAM4)
625         return "Pink";
626     return "Neutral";
627 }
628
629 string Team_ColorNameLowerCase(float t)
630 {
631     // fixme: Search for team entities and get their .netname's!
632     if (t == COLOR_TEAM1)
633         return "red";
634     if (t == COLOR_TEAM2)
635         return "blue";
636     if (t == COLOR_TEAM3)
637         return "yellow";
638     if (t == COLOR_TEAM4)
639         return "pink";
640     return "neutral";
641 }
642
643 float ColourToNumber(string team_colour)
644 {
645         if (team_colour == "red")
646                 return COLOR_TEAM1;
647
648         if (team_colour == "blue")
649                 return COLOR_TEAM2;
650
651         if (team_colour == "yellow")
652                 return COLOR_TEAM3;
653
654         if (team_colour == "pink")
655                 return COLOR_TEAM4;
656
657         if (team_colour == "auto")
658                 return 0;
659
660         return -1;
661 }
662
663 float NumberToTeamNumber(float number)
664 {
665         if (number == 1)
666                 return COLOR_TEAM1;
667
668         if (number == 2)
669                 return COLOR_TEAM2;
670
671         if (number == 3)
672                 return COLOR_TEAM3;
673
674         if (number == 4)
675                 return COLOR_TEAM4;
676
677         return -1;
678 }
679
680 // decolorizes and team colors the player name when needed
681 string playername(entity p)
682 {
683     string t;
684     if (teamplay && !intermission_running && p.classname == "player")
685     {
686         t = Team_ColorCode(p.team);
687         return strcat(t, strdecolorize(p.netname));
688     }
689     else
690         return p.netname;
691 }
692
693 vector randompos(vector m1, vector m2)
694 {
695     vector v;
696     m2 = m2 - m1;
697     v_x = m2_x * random() + m1_x;
698     v_y = m2_y * random() + m1_y;
699     v_z = m2_z * random() + m1_z;
700     return  v;
701 }
702
703 //#NO AUTOCVARS START
704
705 float g_pickup_shells;
706 float g_pickup_shells_max;
707 float g_pickup_nails;
708 float g_pickup_nails_max;
709 float g_pickup_rockets;
710 float g_pickup_rockets_max;
711 float g_pickup_cells;
712 float g_pickup_cells_max;
713 float g_pickup_fuel;
714 float g_pickup_fuel_jetpack;
715 float g_pickup_fuel_max;
716 float g_pickup_armorsmall;
717 float g_pickup_armorsmall_max;
718 float g_pickup_armorsmall_anyway;
719 float g_pickup_armormedium;
720 float g_pickup_armormedium_max;
721 float g_pickup_armormedium_anyway;
722 float g_pickup_armorbig;
723 float g_pickup_armorbig_max;
724 float g_pickup_armorbig_anyway;
725 float g_pickup_armorlarge;
726 float g_pickup_armorlarge_max;
727 float g_pickup_armorlarge_anyway;
728 float g_pickup_healthsmall;
729 float g_pickup_healthsmall_max;
730 float g_pickup_healthsmall_anyway;
731 float g_pickup_healthmedium;
732 float g_pickup_healthmedium_max;
733 float g_pickup_healthmedium_anyway;
734 float g_pickup_healthlarge;
735 float g_pickup_healthlarge_max;
736 float g_pickup_healthlarge_anyway;
737 float g_pickup_healthmega;
738 float g_pickup_healthmega_max;
739 float g_pickup_healthmega_anyway;
740 float g_pickup_ammo_anyway;
741 float g_pickup_weapons_anyway;
742 float g_weaponarena;
743 float g_weaponarena_random;
744 float g_weaponarena_random_with_laser;
745 string g_weaponarena_list;
746 float g_weaponspeedfactor;
747 float g_weaponratefactor;
748 float g_weapondamagefactor;
749 float g_weaponforcefactor;
750 float g_weaponspreadfactor;
751
752 float start_weapons;
753 float start_items;
754 float start_ammo_shells;
755 float start_ammo_nails;
756 float start_ammo_rockets;
757 float start_ammo_cells;
758 float start_ammo_fuel;
759 float start_health;
760 float start_armorvalue;
761 float warmup_start_weapons;
762 float warmup_start_ammo_shells;
763 float warmup_start_ammo_nails;
764 float warmup_start_ammo_rockets;
765 float warmup_start_ammo_cells;
766 float warmup_start_ammo_fuel;
767 float warmup_start_health;
768 float warmup_start_armorvalue;
769 float g_weapon_stay;
770 float g_ghost_items;
771
772 entity get_weaponinfo(float w);
773
774 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
775 {
776         var float i = weaponinfo.weapon;
777
778         if (!i)
779                 return 0;
780
781         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
782
783         if (t < 0) // "default" weapon selection
784         {
785                 if (g_lms || g_ca || allguns)
786                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
787                 else if(t < -1)
788                         t = 0;
789                 else if (g_cts)
790                         t = (i == WEP_SHOTGUN);
791                 else if (g_nexball)
792                         t = 0; // weapon is set a few lines later
793                 else
794                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
795                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
796                         t |= (i == WEP_HOOK);
797         }
798
799         // we cannot disable porto in Nexball, we must force it
800         if(g_nexball && i == WEP_PORTO)
801                 t = 1;
802
803         return t;
804 }
805
806 void readplayerstartcvars()
807 {
808         entity e;
809         float i, j, t;
810         string s;
811
812         // initialize starting values for players
813         start_weapons = 0;
814         start_items = 0;
815         start_ammo_shells = 0;
816         start_ammo_nails = 0;
817         start_ammo_rockets = 0;
818         start_ammo_cells = 0;
819         start_health = cvar("g_balance_health_start");
820         start_armorvalue = cvar("g_balance_armor_start");
821
822         g_weaponarena = 0;
823         s = cvar_string("g_weaponarena");
824         if (s == "0" || s == "")
825         {
826                 if(g_lms || g_ca)
827                         s = "most";
828         }
829
830         if (s == "0" || s == "")
831         {
832                 // no arena
833         }
834         else if (s == "off")
835         {
836                 // forcibly turn off weaponarena
837         }
838         else if (s == "all")
839         {
840                 g_weaponarena_list = "All Weapons";
841                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
842                 {
843                         e = get_weaponinfo(j);
844                         g_weaponarena |= e.weapons;
845                         weapon_action(e.weapon, WR_PRECACHE);
846                 }
847         }
848         else if (s == "most")
849         {
850                 g_weaponarena_list = "Most Weapons";
851                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
852                 {
853                         e = get_weaponinfo(j);
854                         if (e.spawnflags & WEP_FLAG_NORMAL)
855                         {
856                                 g_weaponarena |= e.weapons;
857                                 weapon_action(e.weapon, WR_PRECACHE);
858                         }
859                 }
860         }
861         else if (s == "none")
862         {
863                 g_weaponarena_list = "No Weapons";
864                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
865         }
866         else
867         {
868                 t = tokenize_console(s);
869                 g_weaponarena_list = "";
870                 for (i = 0; i < t; ++i)
871                 {
872                         s = argv(i);
873                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
874                         {
875                                 e = get_weaponinfo(j);
876                                 if (e.netname == s)
877                                 {
878                                         g_weaponarena |= e.weapons;
879                                         weapon_action(e.weapon, WR_PRECACHE);
880                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
881                                         break;
882                                 }
883                         }
884                         if (j > WEP_LAST)
885                         {
886                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
887                         }
888                 }
889                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
890         }
891
892         if(g_weaponarena)
893                 g_weaponarena_random = cvar("g_weaponarena_random");
894         else
895                 g_weaponarena_random = 0;
896         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
897
898         if (g_weaponarena)
899         {
900                 g_minstagib = 0; // incompatible
901                 g_pinata = 0; // incompatible
902                 g_weapon_stay = 0; // incompatible
903                 start_weapons = g_weaponarena;
904                 if(!(g_lms || g_ca))
905                         start_items |= IT_UNLIMITED_AMMO;
906         }
907         else if (g_minstagib)
908         {
909                 g_pinata = 0; // incompatible
910                 g_weapon_stay = 0; // incompatible
911                 g_bloodloss = 0; // incompatible
912                 start_health = 100;
913                 start_armorvalue = 0;
914                 start_weapons = WEPBIT_MINSTANEX;
915                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
916                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
917                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
918
919                 if (g_minstagib_invis_alpha <= 0)
920                         g_minstagib_invis_alpha = -1;
921         }
922         else
923         {
924                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
925                 {
926                         e = get_weaponinfo(i);
927                         if(want_weapon("g_start_weapon_", e, FALSE))
928                                 start_weapons |= e.weapons;
929                 }
930         }
931
932         if(!cvar("g_use_ammunition"))
933                 start_items |= IT_UNLIMITED_AMMO;
934
935         if(cvar("g_nexball"))
936                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
937
938         if(g_minstagib)
939         {
940                 start_ammo_cells = cvar("g_minstagib_ammo_start");
941                 start_ammo_fuel = cvar("g_start_ammo_fuel");
942         }
943         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
944         {
945                 start_ammo_rockets = 999;
946                 start_ammo_shells = 999;
947                 start_ammo_cells = 999;
948                 start_ammo_nails = 999;
949                 start_ammo_fuel = 999;
950         }
951         else
952         {
953                 if(g_lms || g_ca)
954                 {
955                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
956                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
957                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
958                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
959                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
960                 }
961                 else
962                 {
963                         start_ammo_shells = cvar("g_start_ammo_shells");
964                         start_ammo_nails = cvar("g_start_ammo_nails");
965                         start_ammo_rockets = cvar("g_start_ammo_rockets");
966                         start_ammo_cells = cvar("g_start_ammo_cells");
967                         start_ammo_fuel = cvar("g_start_ammo_fuel");
968                 }
969         }
970
971         if (g_lms || g_ca)
972         {
973                 start_health = cvar("g_lms_start_health");
974                 start_armorvalue = cvar("g_lms_start_armor");
975         }
976
977         if (inWarmupStage)
978         {
979                 warmup_start_ammo_shells = start_ammo_shells;
980                 warmup_start_ammo_nails = start_ammo_nails;
981                 warmup_start_ammo_rockets = start_ammo_rockets;
982                 warmup_start_ammo_cells = start_ammo_cells;
983                 warmup_start_ammo_fuel = start_ammo_fuel;
984                 warmup_start_health = start_health;
985                 warmup_start_armorvalue = start_armorvalue;
986                 warmup_start_weapons = start_weapons;
987
988                 if (!g_weaponarena && !g_minstagib && !g_ca)
989                 {
990                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
991                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
992                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
993                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
994                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
995                         warmup_start_health = cvar("g_warmup_start_health");
996                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
997                         warmup_start_weapons = 0;
998                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
999                         {
1000                                 e = get_weaponinfo(i);
1001                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1002                                         warmup_start_weapons |= e.weapons;
1003                         }
1004                 }
1005         }
1006
1007         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1008         {
1009                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1010                 start_items |= IT_FUEL_REGEN;
1011                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1012                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1013         }
1014
1015         if (g_jetpack)
1016                 start_items |= IT_JETPACK;
1017
1018         MUTATOR_CALLHOOK(SetStartItems);
1019
1020         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1021         {
1022                 e = get_weaponinfo(i);
1023                 if(e.weapons & (start_weapons | warmup_start_weapons))
1024                         weapon_action(e.weapon, WR_PRECACHE);
1025         }
1026
1027         start_ammo_shells = max(0, start_ammo_shells);
1028         start_ammo_nails = max(0, start_ammo_nails);
1029         start_ammo_cells = max(0, start_ammo_cells);
1030         start_ammo_rockets = max(0, start_ammo_rockets);
1031         start_ammo_fuel = max(0, start_ammo_fuel);
1032
1033         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1034         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1035         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1036         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1037         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1038 }
1039
1040 float g_bugrigs;
1041 float g_bugrigs_planar_movement;
1042 float g_bugrigs_planar_movement_car_jumping;
1043 float g_bugrigs_reverse_spinning;
1044 float g_bugrigs_reverse_speeding;
1045 float g_bugrigs_reverse_stopping;
1046 float g_bugrigs_air_steering;
1047 float g_bugrigs_angle_smoothing;
1048 float g_bugrigs_friction_floor;
1049 float g_bugrigs_friction_brake;
1050 float g_bugrigs_friction_air;
1051 float g_bugrigs_accel;
1052 float g_bugrigs_speed_ref;
1053 float g_bugrigs_speed_pow;
1054 float g_bugrigs_steer;
1055
1056 float g_touchexplode;
1057 float g_touchexplode_radius;
1058 float g_touchexplode_damage;
1059 float g_touchexplode_edgedamage;
1060 float g_touchexplode_force;
1061
1062 float sv_autotaunt;
1063 float sv_taunt;
1064
1065 float sv_pitch_min;
1066 float sv_pitch_max;
1067 float sv_pitch_fixyaw;
1068
1069 string GetGametype(); // g_world.qc
1070 void readlevelcvars(void)
1071 {
1072         // first load all the mutators
1073         if(cvar("g_invincible_projectiles"))
1074                 MUTATOR_ADD(mutator_invincibleprojectiles);
1075         if(cvar("g_nix"))
1076                 MUTATOR_ADD(mutator_nix);
1077         if(cvar("g_dodging"))
1078                 MUTATOR_ADD(mutator_dodging);
1079         if(cvar("g_rocket_flying"))
1080                 MUTATOR_ADD(mutator_rocketflying);
1081         if(cvar("g_vampire"))
1082                 MUTATOR_ADD(mutator_vampire);
1083         if(cvar("g_spawn_near_teammate"))
1084                 MUTATOR_ADD(mutator_spawn_near_teammate);
1085
1086         // is this a mutator? is this a mode?
1087         if(cvar("g_sandbox"))
1088                 MUTATOR_ADD(sandbox);
1089
1090         if(cvar("sv_allow_fullbright"))
1091                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1092
1093     g_bugrigs = cvar("g_bugrigs");
1094     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1095     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1096     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1097     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1098     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1099     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1100     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1101     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1102     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1103     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1104     g_bugrigs_accel = cvar("g_bugrigs_accel");
1105     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1106     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1107     g_bugrigs_steer = cvar("g_bugrigs_steer");
1108
1109     g_touchexplode = cvar("g_touchexplode");
1110     g_touchexplode_radius = cvar("g_touchexplode_radius");
1111     g_touchexplode_damage = cvar("g_touchexplode_damage");
1112     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1113     g_touchexplode_force = cvar("g_touchexplode_force");
1114
1115 #ifdef ALLOW_FORCEMODELS
1116         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1117 #endif
1118
1119         sv_clones = cvar("sv_clones");
1120         sv_gentle = cvar("sv_gentle");
1121         sv_foginterval = cvar("sv_foginterval");
1122         g_cloaked = cvar("g_cloaked");
1123     if(g_cts)
1124         g_cloaked = 1; // always enable cloak in CTS
1125         g_jump_grunt = cvar("g_jump_grunt");
1126         g_footsteps = cvar("g_footsteps");
1127         g_grappling_hook = cvar("g_grappling_hook");
1128         g_jetpack = cvar("g_jetpack");
1129         g_midair = cvar("g_midair");
1130         g_minstagib = cvar("g_minstagib");
1131         g_norecoil = cvar("g_norecoil");
1132         g_bloodloss = cvar("g_bloodloss");
1133         sv_maxidle = cvar("sv_maxidle");
1134         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1135         g_ctf_reverse = cvar("g_ctf_reverse");
1136         sv_autotaunt = cvar("sv_autotaunt");
1137         sv_taunt = cvar("sv_taunt");
1138
1139         inWarmupStage = cvar("g_warmup");
1140         g_warmup_limit = cvar("g_warmup_limit");
1141         g_warmup_allguns = cvar("g_warmup_allguns");
1142         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1143
1144         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1145                 inWarmupStage = 0; // these modes cannot work together, sorry
1146
1147         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1148         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1149         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1150         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1151         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1152         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1153         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1154         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1155         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1156         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1157         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1158         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1159         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1160         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1161
1162         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1163         g_weaponratefactor = cvar("g_weaponratefactor");
1164         g_weapondamagefactor = cvar("g_weapondamagefactor");
1165         g_weaponforcefactor = cvar("g_weaponforcefactor");
1166         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1167
1168         g_pickup_shells = cvar("g_pickup_shells");
1169         g_pickup_shells_max = cvar("g_pickup_shells_max");
1170         g_pickup_nails = cvar("g_pickup_nails");
1171         g_pickup_nails_max = cvar("g_pickup_nails_max");
1172         g_pickup_rockets = cvar("g_pickup_rockets");
1173         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1174         g_pickup_cells = cvar("g_pickup_cells");
1175         g_pickup_cells_max = cvar("g_pickup_cells_max");
1176         g_pickup_fuel = cvar("g_pickup_fuel");
1177         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1178         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1179         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1180         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1181         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1182         g_pickup_armormedium = cvar("g_pickup_armormedium");
1183         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1184         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1185         g_pickup_armorbig = cvar("g_pickup_armorbig");
1186         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1187         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1188         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1189         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1190         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1191         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1192         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1193         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1194         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1195         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1196         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1197         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1198         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1199         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1200         g_pickup_healthmega = cvar("g_pickup_healthmega");
1201         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1202         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1203
1204         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1205         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1206
1207         g_pinata = cvar("g_pinata");
1208
1209     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1210     if(!g_weapon_stay)
1211         g_weapon_stay = cvar("g_weapon_stay");
1212
1213         g_ghost_items = cvar("g_ghost_items");
1214
1215         if(g_ghost_items >= 1)
1216                 g_ghost_items = 0.25; // default alpha value
1217
1218         if not(inWarmupStage && !g_ca)
1219                 game_starttime = cvar("g_start_delay");
1220
1221         sv_pitch_min = cvar("sv_pitch_min");
1222         sv_pitch_max = cvar("sv_pitch_max");
1223         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1224
1225         readplayerstartcvars();
1226 }
1227
1228 //#NO AUTOCVARS END
1229
1230 // Sound functions
1231 string precache_sound (string s) = #19;
1232 float precache_sound_index (string s) = #19;
1233
1234 #define SND_VOLUME      1
1235 #define SND_ATTENUATION 2
1236 #define SND_LARGEENTITY 8
1237 #define SND_LARGESOUND  16
1238
1239 float sound_allowed(float dest, entity e)
1240 {
1241     // sounds from world may always pass
1242     for (;;)
1243     {
1244         if (e.classname == "body")
1245             e = e.enemy;
1246         else if (e.realowner && e.realowner != e)
1247             e = e.realowner;
1248         else if (e.owner && e.owner != e)
1249             e = e.owner;
1250         else
1251             break;
1252     }
1253     // sounds to self may always pass
1254     if (dest == MSG_ONE)
1255         if (e == msg_entity)
1256             return TRUE;
1257     // sounds by players can be removed
1258     if (autocvar_bot_sound_monopoly)
1259         if (clienttype(e) == CLIENTTYPE_REAL)
1260             return FALSE;
1261     // anything else may pass
1262     return TRUE;
1263 }
1264
1265 #ifdef COMPAT_XON010_CHANNELS
1266 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1267 void sound(entity e, float chan, string samp, float vol, float atten)
1268 {
1269     if (!sound_allowed(MSG_BROADCAST, e))
1270         return;
1271     builtin_sound(e, chan, samp, vol, atten);
1272 }
1273 #else
1274 #undef sound
1275 void sound(entity e, float chan, string samp, float vol, float atten)
1276 {
1277     if (!sound_allowed(MSG_BROADCAST, e))
1278         return;
1279     sound7(e, chan, samp, vol, atten, 0, 0);
1280 }
1281 #endif
1282
1283 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1284 {
1285     float entno, idx;
1286
1287     if (!sound_allowed(dest, e))
1288         return;
1289
1290     entno = num_for_edict(e);
1291     idx = precache_sound_index(samp);
1292
1293     float sflags;
1294     sflags = 0;
1295
1296     atten = floor(atten * 64);
1297     vol = floor(vol * 255);
1298
1299     if (vol != 255)
1300         sflags |= SND_VOLUME;
1301     if (atten != 64)
1302         sflags |= SND_ATTENUATION;
1303     if (entno >= 8192 || chan < 0 || chan > 7)
1304         sflags |= SND_LARGEENTITY;
1305     if (idx >= 256)
1306         sflags |= SND_LARGESOUND;
1307
1308     WriteByte(dest, SVC_SOUND);
1309     WriteByte(dest, sflags);
1310     if (sflags & SND_VOLUME)
1311         WriteByte(dest, vol);
1312     if (sflags & SND_ATTENUATION)
1313         WriteByte(dest, atten);
1314     if (sflags & SND_LARGEENTITY)
1315     {
1316         WriteShort(dest, entno);
1317         WriteByte(dest, chan);
1318     }
1319     else
1320     {
1321         WriteShort(dest, entno * 8 + chan);
1322     }
1323     if (sflags & SND_LARGESOUND)
1324         WriteShort(dest, idx);
1325     else
1326         WriteByte(dest, idx);
1327
1328     WriteCoord(dest, o_x);
1329     WriteCoord(dest, o_y);
1330     WriteCoord(dest, o_z);
1331 }
1332 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1333 {
1334     vector o;
1335
1336     if (!sound_allowed(dest, e))
1337         return;
1338
1339     o = e.origin + 0.5 * (e.mins + e.maxs);
1340     soundtoat(dest, e, o, chan, samp, vol, atten);
1341 }
1342 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1343 {
1344     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1345 }
1346 void stopsoundto(float dest, entity e, float chan)
1347 {
1348     float entno;
1349
1350     if (!sound_allowed(dest, e))
1351         return;
1352
1353     entno = num_for_edict(e);
1354
1355     if (entno >= 8192 || chan < 0 || chan > 7)
1356     {
1357         float idx, sflags;
1358         idx = precache_sound_index("misc/null.wav");
1359         sflags = SND_LARGEENTITY;
1360         if (idx >= 256)
1361             sflags |= SND_LARGESOUND;
1362         WriteByte(dest, SVC_SOUND);
1363         WriteByte(dest, sflags);
1364         WriteShort(dest, entno);
1365         WriteByte(dest, chan);
1366         if (sflags & SND_LARGESOUND)
1367             WriteShort(dest, idx);
1368         else
1369             WriteByte(dest, idx);
1370         WriteCoord(dest, e.origin_x);
1371         WriteCoord(dest, e.origin_y);
1372         WriteCoord(dest, e.origin_z);
1373     }
1374     else
1375     {
1376         WriteByte(dest, SVC_STOPSOUND);
1377         WriteShort(dest, entno * 8 + chan);
1378     }
1379 }
1380 void stopsound(entity e, float chan)
1381 {
1382     if (!sound_allowed(MSG_BROADCAST, e))
1383         return;
1384
1385     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1386     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1387 }
1388
1389 void play2(entity e, string filename)
1390 {
1391     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1392     msg_entity = e;
1393     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1394 }
1395
1396 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1397 .float spamtime;
1398 float spamsound(entity e, float chan, string samp, float vol, float atten)
1399 {
1400     if (!sound_allowed(MSG_BROADCAST, e))
1401         return FALSE;
1402
1403     if (time > e.spamtime)
1404     {
1405         e.spamtime = time;
1406         sound(e, chan, samp, vol, atten);
1407         return TRUE;
1408     }
1409     return FALSE;
1410 }
1411
1412 void play2team(float t, string filename)
1413 {
1414     entity head;
1415
1416     if (autocvar_bot_sound_monopoly)
1417         return;
1418
1419     FOR_EACH_REALPLAYER(head)
1420     {
1421         if (head.team == t)
1422             play2(head, filename);
1423     }
1424 }
1425
1426 void play2all(string samp)
1427 {
1428     if (autocvar_bot_sound_monopoly)
1429         return;
1430
1431     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1432 }
1433
1434 void PrecachePlayerSounds(string f);
1435 void precache_playermodel(string m)
1436 {
1437         float globhandle, i, n;
1438         string f;
1439
1440         if(substring(m, -9,5) == "_lod1")
1441                 return;
1442         if(substring(m, -9,5) == "_lod2")
1443                 return;
1444         precache_model(m);
1445         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1446         if(fexists(f))
1447                 precache_model(f);
1448         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1449         if(fexists(f))
1450                 precache_model(f);
1451
1452         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1453         if (globhandle < 0)
1454                 return;
1455         n = search_getsize(globhandle);
1456         for (i = 0; i < n; ++i)
1457         {
1458                 //print(search_getfilename(globhandle, i), "\n");
1459                 f = search_getfilename(globhandle, i);
1460                 PrecachePlayerSounds(f);
1461         }
1462         search_end(globhandle);
1463 }
1464 void precache_all_playermodels(string pattern)
1465 {
1466         float globhandle, i, n;
1467         string f;
1468
1469         globhandle = search_begin(pattern, TRUE, FALSE);
1470         if (globhandle < 0)
1471                 return;
1472         n = search_getsize(globhandle);
1473         for (i = 0; i < n; ++i)
1474         {
1475                 //print(search_getfilename(globhandle, i), "\n");
1476                 f = search_getfilename(globhandle, i);
1477                 precache_playermodel(f);
1478         }
1479         search_end(globhandle);
1480 }
1481
1482 void precache()
1483 {
1484     // gamemode related things
1485     precache_model ("models/misc/chatbubble.spr");
1486     if (g_runematch)
1487     {
1488         precache_model ("models/runematch/curse.mdl");
1489         precache_model ("models/runematch/rune.mdl");
1490     }
1491
1492 #ifdef TTURRETS_ENABLED
1493     if (autocvar_g_turrets)
1494         turrets_precash();
1495 #endif
1496
1497     // Precache all player models if desired
1498     if (autocvar_sv_precacheplayermodels)
1499     {
1500         PrecachePlayerSounds("sound/player/default.sounds");
1501         precache_all_playermodels("models/player/*.zym");
1502         precache_all_playermodels("models/player/*.dpm");
1503         precache_all_playermodels("models/player/*.md3");
1504         precache_all_playermodels("models/player/*.psk");
1505         precache_all_playermodels("models/player/*.iqm");
1506     }
1507
1508     if (autocvar_sv_defaultcharacter)
1509     {
1510         string s;
1511         s = autocvar_sv_defaultplayermodel_red;
1512         if (s != "")
1513             precache_playermodel(s);
1514         s = autocvar_sv_defaultplayermodel_blue;
1515         if (s != "")
1516             precache_playermodel(s);
1517         s = autocvar_sv_defaultplayermodel_yellow;
1518         if (s != "")
1519             precache_playermodel(s);
1520         s = autocvar_sv_defaultplayermodel_pink;
1521         if (s != "")
1522             precache_playermodel(s);
1523         s = autocvar_sv_defaultplayermodel;
1524         if (s != "")
1525             precache_playermodel(s);
1526     }
1527
1528     if (g_footsteps)
1529     {
1530         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1531         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1532     }
1533
1534     // gore and miscellaneous sounds
1535     //precache_sound ("misc/h2ohit.wav");
1536     precache_model ("models/hook.md3");
1537     precache_sound ("misc/armorimpact.wav");
1538     precache_sound ("misc/bodyimpact1.wav");
1539     precache_sound ("misc/bodyimpact2.wav");
1540     precache_sound ("misc/gib.wav");
1541     precache_sound ("misc/gib_splat01.wav");
1542     precache_sound ("misc/gib_splat02.wav");
1543     precache_sound ("misc/gib_splat03.wav");
1544     precache_sound ("misc/gib_splat04.wav");
1545     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1546     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1547     precache_sound ("misc/null.wav");
1548     precache_sound ("misc/spawn.wav");
1549     precache_sound ("misc/talk.wav");
1550     precache_sound ("misc/teleport.wav");
1551     precache_sound ("misc/poweroff.wav");
1552     precache_sound ("player/lava.wav");
1553     precache_sound ("player/slime.wav");
1554
1555     if (g_jetpack)
1556         precache_sound ("misc/jetpack_fly.wav");
1557
1558     precache_model ("models/sprites/0.spr32");
1559     precache_model ("models/sprites/1.spr32");
1560     precache_model ("models/sprites/2.spr32");
1561     precache_model ("models/sprites/3.spr32");
1562     precache_model ("models/sprites/4.spr32");
1563     precache_model ("models/sprites/5.spr32");
1564     precache_model ("models/sprites/6.spr32");
1565     precache_model ("models/sprites/7.spr32");
1566     precache_model ("models/sprites/8.spr32");
1567     precache_model ("models/sprites/9.spr32");
1568     precache_model ("models/sprites/10.spr32");
1569
1570     // common weapon precaches
1571         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1572     precache_sound ("weapons/weapon_switch.wav");
1573     precache_sound ("weapons/weaponpickup.wav");
1574     precache_sound ("weapons/unavailable.wav");
1575     precache_sound ("weapons/dryfire.wav");
1576     if (g_grappling_hook)
1577     {
1578         precache_sound ("weapons/hook_fire.wav"); // hook
1579         precache_sound ("weapons/hook_impact.wav"); // hook
1580     }
1581
1582     if(autocvar_sv_precacheweapons)
1583     {
1584         //precache weapon models/sounds
1585         float wep;
1586         wep = WEP_FIRST;
1587         while (wep <= WEP_LAST)
1588         {
1589             weapon_action(wep, WR_PRECACHE);
1590             wep = wep + 1;
1591         }
1592     }
1593
1594     precache_model("models/elaser.mdl");
1595     precache_model("models/laser.mdl");
1596     precache_model("models/ebomb.mdl");
1597
1598 #if 0
1599     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1600
1601     if (!self.noise && self.music) // quake 3 uses the music field
1602         self.noise = self.music;
1603
1604     // plays music for the level if there is any
1605     if (self.noise)
1606     {
1607         precache_sound (self.noise);
1608         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1609     }
1610 #endif
1611 }
1612
1613 // sorry, but using \ in macros breaks line numbers
1614 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1615 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1616 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1617
1618
1619 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1620 {
1621         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1622         {
1623                 msg_entity = e;
1624                 WRITESPECTATABLE_MSG_ONE({
1625                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1626                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1627                         WriteByte(MSG_ONE, id);
1628                         WriteString(MSG_ONE, s);
1629                         if (id != 0 && s != "")
1630                         {
1631                                 WriteByte(MSG_ONE, duration);
1632                                 WriteByte(MSG_ONE, countdown_num);
1633                         }
1634                 });
1635         }
1636 }
1637 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1638 {
1639         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1640 }
1641 // WARNING: this kills the trace globals
1642 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1643 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1644
1645 #define INITPRIO_FIRST              0
1646 #define INITPRIO_GAMETYPE           0
1647 #define INITPRIO_GAMETYPE_FALLBACK  1
1648 #define INITPRIO_FINDTARGET        10
1649 #define INITPRIO_DROPTOFLOOR       20
1650 #define INITPRIO_SETLOCATION       90
1651 #define INITPRIO_LINKDOORS         91
1652 #define INITPRIO_LAST              99
1653
1654 .void(void) initialize_entity;
1655 .float initialize_entity_order;
1656 .entity initialize_entity_next;
1657 entity initialize_entity_first;
1658
1659 void make_safe_for_remove(entity e)
1660 {
1661     if (e.initialize_entity)
1662     {
1663         entity ent, prev;
1664         for (ent = initialize_entity_first; ent; )
1665         {
1666             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1667             {
1668                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1669                 // skip it in linked list
1670                 if (prev)
1671                 {
1672                     prev.initialize_entity_next = ent.initialize_entity_next;
1673                     ent = prev.initialize_entity_next;
1674                 }
1675                 else
1676                 {
1677                     initialize_entity_first = ent.initialize_entity_next;
1678                     ent = initialize_entity_first;
1679                 }
1680             }
1681             else
1682             {
1683                 prev = ent;
1684                 ent = ent.initialize_entity_next;
1685             }
1686         }
1687     }
1688 }
1689
1690 void objerror(string s)
1691 {
1692     make_safe_for_remove(self);
1693     builtin_objerror(s);
1694 }
1695
1696 .float remove_except_protected_forbidden;
1697 void remove_except_protected(entity e)
1698 {
1699         if(e.remove_except_protected_forbidden)
1700                 error("not allowed to remove this at this point");
1701         builtin_remove(e);
1702 }
1703
1704 void remove_unsafely(entity e)
1705 {
1706     if(e.classname == "spike")
1707         error("Removing spikes is forbidden (crylink bug), please report");
1708     builtin_remove(e);
1709 }
1710
1711 void remove_safely(entity e)
1712 {
1713     make_safe_for_remove(e);
1714     builtin_remove(e);
1715 }
1716
1717 void InitializeEntity(entity e, void(void) func, float order)
1718 {
1719     entity prev, cur;
1720
1721     if (!e || e.initialize_entity)
1722     {
1723         // make a proxy initializer entity
1724         entity e_old;
1725         e_old = e;
1726         e = spawn();
1727         e.classname = "initialize_entity";
1728         e.enemy = e_old;
1729     }
1730
1731     e.initialize_entity = func;
1732     e.initialize_entity_order = order;
1733
1734     cur = initialize_entity_first;
1735     for (;;)
1736     {
1737         if (!cur || cur.initialize_entity_order > order)
1738         {
1739             // insert between prev and cur
1740             if (prev)
1741                 prev.initialize_entity_next = e;
1742             else
1743                 initialize_entity_first = e;
1744             e.initialize_entity_next = cur;
1745             return;
1746         }
1747         prev = cur;
1748         cur = cur.initialize_entity_next;
1749     }
1750 }
1751 void InitializeEntitiesRun()
1752 {
1753     entity startoflist;
1754     startoflist = initialize_entity_first;
1755     initialize_entity_first = world;
1756     remove = remove_except_protected;
1757     for (self = startoflist; self; self = self.initialize_entity_next)
1758     {
1759         self.remove_except_protected_forbidden = 1;
1760     }
1761     for (self = startoflist; self; )
1762     {
1763         entity e;
1764         var void(void) func;
1765         e = self.initialize_entity_next;
1766         func = self.initialize_entity;
1767         self.initialize_entity_order = 0;
1768         self.initialize_entity = func_null;
1769         self.initialize_entity_next = world;
1770         self.remove_except_protected_forbidden = 0;
1771         if (self.classname == "initialize_entity")
1772         {
1773             entity e_old;
1774             e_old = self.enemy;
1775             builtin_remove(self);
1776             self = e_old;
1777         }
1778         //dprint("Delayed initialization: ", self.classname, "\n");
1779         if(func != func_null)
1780             func();
1781         else
1782         {
1783             eprint(self);
1784             backtrace(strcat("Null function in: ", self.classname, "\n"));
1785         }
1786         self = e;
1787     }
1788     remove = remove_unsafely;
1789 }
1790
1791 .float uncustomizeentityforclient_set;
1792 .void(void) uncustomizeentityforclient;
1793 void(void) SUB_Nullpointer = #0;
1794 void UncustomizeEntitiesRun()
1795 {
1796     entity oldself;
1797     oldself = self;
1798     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1799         self.uncustomizeentityforclient();
1800     self = oldself;
1801 }
1802 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1803 {
1804     e.customizeentityforclient = customizer;
1805     e.uncustomizeentityforclient = uncustomizer;
1806     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1807 }
1808
1809 .float nottargeted;
1810 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1811
1812 void() SUB_Remove;
1813 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1814 {
1815     vector mi, ma;
1816
1817     if (e.classname == "")
1818         e.classname = "net_linked";
1819
1820     if (e.model == "" || self.modelindex == 0)
1821     {
1822         mi = e.mins;
1823         ma = e.maxs;
1824         setmodel(e, "null");
1825         setsize(e, mi, ma);
1826     }
1827
1828     e.SendEntity = sendfunc;
1829     e.SendFlags = 0xFFFFFF;
1830
1831     if (!docull)
1832         e.effects |= EF_NODEPTHTEST;
1833
1834     if (dt)
1835     {
1836         e.nextthink = time + dt;
1837         e.think = SUB_Remove;
1838     }
1839 }
1840
1841 void adaptor_think2touch()
1842 {
1843     entity o;
1844     o = other;
1845     other = world;
1846     self.touch();
1847     other = o;
1848 }
1849
1850 void adaptor_think2use()
1851 {
1852     entity o, a;
1853     o = other;
1854     a = activator;
1855     activator = world;
1856     other = world;
1857     self.use();
1858     other = o;
1859     activator = a;
1860 }
1861
1862 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1863 {
1864         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1865                 self.projectiledeathtype |= HITTYPE_SPLASH;
1866         adaptor_think2use();
1867 }
1868
1869 // deferred dropping
1870 void DropToFloor_Handler()
1871 {
1872     builtin_droptofloor();
1873     self.dropped_origin = self.origin;
1874 }
1875
1876 void droptofloor()
1877 {
1878     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1879 }
1880
1881
1882
1883 float trace_hits_box_a0, trace_hits_box_a1;
1884
1885 float trace_hits_box_1d(float end, float thmi, float thma)
1886 {
1887     if (end == 0)
1888     {
1889         // just check if x is in range
1890         if (0 < thmi)
1891             return FALSE;
1892         if (0 > thma)
1893             return FALSE;
1894     }
1895     else
1896     {
1897         // do the trace with respect to x
1898         // 0 -> end has to stay in thmi -> thma
1899         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1900         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1901         if (trace_hits_box_a0 > trace_hits_box_a1)
1902             return FALSE;
1903     }
1904     return TRUE;
1905 }
1906
1907 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1908 {
1909     end -= start;
1910     thmi -= start;
1911     thma -= start;
1912     // now it is a trace from 0 to end
1913
1914     trace_hits_box_a0 = 0;
1915     trace_hits_box_a1 = 1;
1916
1917     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1918         return FALSE;
1919     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1920         return FALSE;
1921     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1922         return FALSE;
1923
1924     return TRUE;
1925 }
1926
1927 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1928 {
1929     return trace_hits_box(start, end, thmi - ma, thma - mi);
1930 }
1931
1932 float SUB_NoImpactCheck()
1933 {
1934         // zero hitcontents = this is not the real impact, but either the
1935         // mirror-impact of something hitting the projectile instead of the
1936         // projectile hitting the something, or a touchareagrid one. Neither of
1937         // these stop the projectile from moving, so...
1938         if(trace_dphitcontents == 0)
1939         {
1940                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1941                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1942                 checkclient();
1943         }
1944     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1945         return 1;
1946     if (other == world && self.size != '0 0 0')
1947     {
1948         vector tic;
1949         tic = self.velocity * sys_frametime;
1950         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1951         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1952         if (trace_fraction >= 1)
1953         {
1954             dprint("Odd... did not hit...?\n");
1955         }
1956         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1957         {
1958             dprint("Detected and prevented the sky-grapple bug.\n");
1959             return 1;
1960         }
1961     }
1962
1963     return 0;
1964 }
1965
1966 #define SUB_OwnerCheck() (other && (other == self.owner))
1967
1968 void RemoveGrapplingHook(entity pl);
1969 void W_Crylink_Dequeue(entity e);
1970 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1971 {
1972         if(SUB_OwnerCheck())
1973                 return TRUE;
1974         if(SUB_NoImpactCheck())
1975         {
1976                 if(self.classname == "grapplinghook")
1977                         RemoveGrapplingHook(self.realowner);
1978                 else if(self.classname == "spike")
1979                 {
1980                         W_Crylink_Dequeue(self);
1981                         remove(self);
1982                 }
1983                 else
1984                         remove(self);
1985                 return TRUE;
1986         }
1987         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1988                 UpdateCSQCProjectile(self);
1989         return FALSE;
1990 }
1991 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1992
1993 void URI_Get_Callback(float id, float status, string data)
1994 {
1995         if(url_URI_Get_Callback(id, status, data))
1996         {
1997                 // handled
1998         }
1999         else if (id == URI_GET_DISCARD)
2000         {
2001                 // discard
2002         }
2003         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2004         {
2005                 // sv_cmd curl
2006                 Curl_URI_Get_Callback(id, status, data);
2007         }
2008         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2009         {
2010                 // online ban list
2011                 OnlineBanList_URI_Get_Callback(id, status, data);
2012         }
2013         else
2014         {
2015                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2016         }
2017 }
2018
2019 string uid2name(string myuid) {
2020         string s;
2021         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2022
2023         // FIXME remove this later after 0.6 release
2024         // convert old style broken records to correct style
2025         if(s == "")
2026         {
2027                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2028                 if(s != "")
2029                 {
2030                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2031                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2032                 }
2033         }
2034         
2035         if(s == "")
2036                 s = "^1Unregistered Player";
2037         return s;
2038 }
2039
2040 float race_readTime(string map, float pos)
2041 {
2042         string rr;
2043         if(g_cts)
2044                 rr = CTS_RECORD;
2045         else
2046                 rr = RACE_RECORD;
2047
2048         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2049 }
2050
2051 string race_readUID(string map, float pos)
2052 {
2053         string rr;
2054         if(g_cts)
2055                 rr = CTS_RECORD;
2056         else
2057                 rr = RACE_RECORD;
2058
2059         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2060 }
2061
2062 float race_readPos(string map, float t) {
2063         float i;
2064         for (i = 1; i <= RANKINGS_CNT; ++i)
2065                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2066                         return i;
2067
2068         return 0; // pos is zero if unranked
2069 }
2070
2071 void race_writeTime(string map, float t, string myuid)
2072 {
2073         string rr;
2074         if(g_cts)
2075                 rr = CTS_RECORD;
2076         else
2077                 rr = RACE_RECORD;
2078
2079         float newpos;
2080         newpos = race_readPos(map, t);
2081
2082         float i, prevpos;
2083         for(i = 1; i <= RANKINGS_CNT; ++i)
2084         {
2085                 if(race_readUID(map, i) == myuid)
2086                         prevpos = i;
2087         }
2088         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2089                 for (i = prevpos; i > newpos; --i) {
2090                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2091                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2092                 }
2093         } else { // player has no ranked record yet
2094                 for (i = RANKINGS_CNT; i > newpos; --i) {
2095                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2096                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2097                 }
2098         }
2099
2100         // store new time itself
2101         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2102         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2103 }
2104
2105 string race_readName(string map, float pos)
2106 {
2107         string rr;
2108         if(g_cts)
2109                 rr = CTS_RECORD;
2110         else
2111                 rr = RACE_RECORD;
2112
2113         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2114 }
2115
2116 string race_placeName(float pos) {
2117         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2118         {
2119                 if(mod(pos, 10) == 1)
2120                         return strcat(ftos(pos), "st");
2121                 else if(mod(pos, 10) == 2)
2122                         return strcat(ftos(pos), "nd");
2123                 else if(mod(pos, 10) == 3)
2124                         return strcat(ftos(pos), "rd");
2125                 else
2126                         return strcat(ftos(pos), "th");
2127         }
2128         else
2129                 return strcat(ftos(pos), "th");
2130 }
2131
2132 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2133 {
2134     float m, i;
2135     vector start, org, delta, end, enddown, mstart;
2136     entity sp;
2137
2138     m = e.dphitcontentsmask;
2139     e.dphitcontentsmask = goodcontents | badcontents;
2140
2141     org = world.mins;
2142     delta = world.maxs - world.mins;
2143
2144     for (i = 0; i < attempts; ++i)
2145     {
2146         start_x = org_x + random() * delta_x;
2147         start_y = org_y + random() * delta_y;
2148         start_z = org_z + random() * delta_z;
2149
2150         // rule 1: start inside world bounds, and outside
2151         // solid, and don't start from somewhere where you can
2152         // fall down to evil
2153         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2154         if (trace_fraction >= 1)
2155             continue;
2156         if (trace_startsolid)
2157             continue;
2158         if (trace_dphitcontents & badcontents)
2159             continue;
2160         if (trace_dphitq3surfaceflags & badsurfaceflags)
2161             continue;
2162
2163         // rule 2: if we are too high, lower the point
2164         if (trace_fraction * delta_z > maxaboveground)
2165             start = trace_endpos + '0 0 1' * maxaboveground;
2166         enddown = trace_endpos;
2167
2168         // rule 3: make sure we aren't outside the map. This only works
2169         // for somewhat well formed maps. A good rule of thumb is that
2170         // the map should have a convex outside hull.
2171         // these can be traceLINES as we already verified the starting box
2172         mstart = start + 0.5 * (e.mins + e.maxs);
2173         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2174         if (trace_fraction >= 1)
2175             continue;
2176         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2177         if (trace_fraction >= 1)
2178             continue;
2179         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2180         if (trace_fraction >= 1)
2181             continue;
2182         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2183         if (trace_fraction >= 1)
2184             continue;
2185         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2186         if (trace_fraction >= 1)
2187             continue;
2188
2189         // rule 4: we must "see" some spawnpoint
2190         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2191                 if(checkpvs(mstart, sp))
2192                         break;
2193         if(!sp)
2194         {
2195                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2196                         if(checkpvs(mstart, sp))
2197                                 break;
2198                 if(!sp)
2199                         continue;
2200         }
2201
2202         // find a random vector to "look at"
2203         end_x = org_x + random() * delta_x;
2204         end_y = org_y + random() * delta_y;
2205         end_z = org_z + random() * delta_z;
2206         end = start + normalize(end - start) * vlen(delta);
2207
2208         // rule 4: start TO end must not be too short
2209         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2210         if (trace_startsolid)
2211             continue;
2212         if (trace_fraction < minviewdistance / vlen(delta))
2213             continue;
2214
2215         // rule 5: don't want to look at sky
2216         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2217             continue;
2218
2219         // rule 6: we must not end up in trigger_hurt
2220         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2221             continue;
2222
2223         break;
2224     }
2225
2226     e.dphitcontentsmask = m;
2227
2228     if (i < attempts)
2229     {
2230         setorigin(e, start);
2231         e.angles = vectoangles(end - start);
2232         dprint("Needed ", ftos(i + 1), " attempts\n");
2233         return TRUE;
2234     }
2235     else
2236         return FALSE;
2237 }
2238
2239 float zcurveparticles_effectno;
2240 vector zcurveparticles_start;
2241 float zcurveparticles_spd;
2242
2243 void endzcurveparticles()
2244 {
2245         if(zcurveparticles_effectno)
2246         {
2247                 // terminator
2248                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2249         }
2250         zcurveparticles_effectno = 0;
2251 }
2252
2253 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2254 {
2255         spd = bound(0, floor(spd / 16), 32767);
2256         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2257         {
2258                 endzcurveparticles();
2259                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2260                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2261                 WriteShort(MSG_BROADCAST, effectno);
2262                 WriteCoord(MSG_BROADCAST, start_x);
2263                 WriteCoord(MSG_BROADCAST, start_y);
2264                 WriteCoord(MSG_BROADCAST, start_z);
2265                 zcurveparticles_effectno = effectno;
2266                 zcurveparticles_start = start;
2267         }
2268         else
2269                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2270         WriteCoord(MSG_BROADCAST, end_x);
2271         WriteCoord(MSG_BROADCAST, end_y);
2272         WriteCoord(MSG_BROADCAST, end_z);
2273         WriteCoord(MSG_BROADCAST, end_dz);
2274         zcurveparticles_spd = spd;
2275 }
2276
2277 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2278 {
2279         float end_dz;
2280         vector vecxy, velxy;
2281
2282         vecxy = end - start;
2283         vecxy_z = 0;
2284         velxy = vel;
2285         velxy_z = 0;
2286
2287         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2288         {
2289                 endzcurveparticles();
2290                 trailparticles(world, effectno, start, end);
2291                 return;
2292         }
2293
2294         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2295         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2296 }
2297
2298 void write_recordmarker(entity pl, float tstart, float dt)
2299 {
2300     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2301
2302     // also write a marker into demo files for demotc-race-record-extractor to find
2303     stuffcmd(pl,
2304              strcat(
2305                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2306                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2307 }
2308
2309 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2310 {
2311         switch(algn)
2312         {
2313                 default:
2314                 case 3: // right
2315                         break;
2316
2317                 case 4: // left
2318                         vecs_y = -vecs_y;
2319                         break;
2320
2321                 case 1:
2322                         if(allowcenter) // 2: allow center handedness
2323                         {
2324                                 // center
2325                                 vecs_y = 0;
2326                                 vecs_z -= 2;
2327                         }
2328                         else
2329                         {
2330                                 // right
2331                         }
2332                         break;
2333
2334                 case 2:
2335                         if(allowcenter) // 2: allow center handedness
2336                         {
2337                                 // center
2338                                 vecs_y = 0;
2339                                 vecs_z -= 2;
2340                         }
2341                         else
2342                         {
2343                                 // left
2344                                 vecs_y = -vecs_y;
2345                         }
2346                         break;
2347         }
2348         return vecs;
2349 }
2350
2351 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2352 {
2353         string s;
2354         vector v;
2355
2356         if (autocvar_g_shootfromeye)
2357         {
2358                 if (visual)
2359                 {
2360                         vecs_y = 0;
2361                         vecs_z -= 2;
2362                 }
2363                 else
2364                 {
2365                         vecs_y = 0;
2366                         vecs_z = 0;
2367                 }
2368         }
2369         else if (autocvar_g_shootfromcenter)
2370         {
2371                 vecs_y = 0;
2372                 vecs_z -= 2;
2373         }
2374         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2375         {
2376                 v = stov(s);
2377                 if (y_is_right)
2378                         v_y = -v_y;
2379                 if (v_x != 0)
2380                         vecs_x = v_x;
2381                 vecs_y = v_y;
2382                 vecs_z = v_z;
2383         }
2384         else if (autocvar_g_shootfromclient)
2385         {
2386                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2387         }
2388         return vecs;
2389 }
2390
2391 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2392 {
2393         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2394 }
2395
2396
2397 void attach_sameorigin(entity e, entity to, string tag)
2398 {
2399     vector org, t_forward, t_left, t_up, e_forward, e_up;
2400     vector org0, ang0;
2401     float tagscale;
2402
2403     ang0 = e.angles;
2404     org0 = e.origin;
2405
2406     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2407     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2408     t_forward = v_forward * tagscale;
2409     t_left = v_right * -tagscale;
2410     t_up = v_up * tagscale;
2411
2412     e.origin_x = org * t_forward;
2413     e.origin_y = org * t_left;
2414     e.origin_z = org * t_up;
2415
2416     // current forward and up directions
2417     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2418                 e.angles = AnglesTransform_FromVAngles(e.angles);
2419         else
2420                 e.angles = AnglesTransform_FromAngles(e.angles);
2421     fixedmakevectors(e.angles);
2422
2423     // untransform forward, up!
2424     e_forward_x = v_forward * t_forward;
2425     e_forward_y = v_forward * t_left;
2426     e_forward_z = v_forward * t_up;
2427     e_up_x = v_up * t_forward;
2428     e_up_y = v_up * t_left;
2429     e_up_z = v_up * t_up;
2430
2431     e.angles = fixedvectoangles2(e_forward, e_up);
2432     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2433                 e.angles = AnglesTransform_ToVAngles(e.angles);
2434         else
2435                 e.angles = AnglesTransform_ToAngles(e.angles);
2436
2437     setattachment(e, to, tag);
2438     setorigin(e, e.origin);
2439 }
2440
2441 void detach_sameorigin(entity e)
2442 {
2443     vector org;
2444     org = gettaginfo(e, 0);
2445     e.angles = fixedvectoangles2(v_forward, v_up);
2446     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2447                 e.angles = AnglesTransform_ToVAngles(e.angles);
2448         else
2449                 e.angles = AnglesTransform_ToAngles(e.angles);
2450     setorigin(e, org);
2451     setattachment(e, world, "");
2452     setorigin(e, e.origin);
2453 }
2454
2455 void follow_sameorigin(entity e, entity to)
2456 {
2457     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2458     e.aiment = to; // make the hole follow bmodel
2459     e.punchangle = to.angles; // the original angles of bmodel
2460     e.view_ofs = e.origin - to.origin; // relative origin
2461     e.v_angle = e.angles - to.angles; // relative angles
2462 }
2463
2464 void unfollow_sameorigin(entity e)
2465 {
2466     e.movetype = MOVETYPE_NONE;
2467 }
2468
2469 entity gettaginfo_relative_ent;
2470 vector gettaginfo_relative(entity e, float tag)
2471 {
2472     if (!gettaginfo_relative_ent)
2473     {
2474         gettaginfo_relative_ent = spawn();
2475         gettaginfo_relative_ent.effects = EF_NODRAW;
2476     }
2477     gettaginfo_relative_ent.model = e.model;
2478     gettaginfo_relative_ent.modelindex = e.modelindex;
2479     gettaginfo_relative_ent.frame = e.frame;
2480     return gettaginfo(gettaginfo_relative_ent, tag);
2481 }
2482
2483 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2484 {
2485     float p;
2486     p = pow(2, chan);
2487     if (pl.soundentity.cnt & p)
2488         return;
2489     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2490     pl.soundentity.cnt |= p;
2491 }
2492
2493 void SoundEntity_StopSound(entity pl, float chan)
2494 {
2495     float p;
2496     p = pow(2, chan);
2497     if (pl.soundentity.cnt & p)
2498     {
2499         stopsoundto(MSG_ALL, pl.soundentity, chan);
2500         pl.soundentity.cnt &~= p;
2501     }
2502 }
2503
2504 void SoundEntity_Attach(entity pl)
2505 {
2506     pl.soundentity = spawn();
2507     pl.soundentity.classname = "soundentity";
2508     pl.soundentity.owner = pl;
2509     setattachment(pl.soundentity, pl, "");
2510     setmodel(pl.soundentity, "null");
2511 }
2512
2513 void SoundEntity_Detach(entity pl)
2514 {
2515     float i;
2516     for (i = 0; i <= 7; ++i)
2517         SoundEntity_StopSound(pl, i);
2518 }
2519
2520 .float scale2;
2521
2522 float modeleffect_SendEntity(entity to, float sf)
2523 {
2524         float f;
2525         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2526
2527         f = 0;
2528         if(self.velocity != '0 0 0')
2529                 f |= 1;
2530         if(self.angles != '0 0 0')
2531                 f |= 2;
2532         if(self.avelocity != '0 0 0')
2533                 f |= 4;
2534
2535         WriteByte(MSG_ENTITY, f);
2536         WriteShort(MSG_ENTITY, self.modelindex);
2537         WriteByte(MSG_ENTITY, self.skin);
2538         WriteByte(MSG_ENTITY, self.frame);
2539         WriteCoord(MSG_ENTITY, self.origin_x);
2540         WriteCoord(MSG_ENTITY, self.origin_y);
2541         WriteCoord(MSG_ENTITY, self.origin_z);
2542         if(f & 1)
2543         {
2544                 WriteCoord(MSG_ENTITY, self.velocity_x);
2545                 WriteCoord(MSG_ENTITY, self.velocity_y);
2546                 WriteCoord(MSG_ENTITY, self.velocity_z);
2547         }
2548         if(f & 2)
2549         {
2550                 WriteCoord(MSG_ENTITY, self.angles_x);
2551                 WriteCoord(MSG_ENTITY, self.angles_y);
2552                 WriteCoord(MSG_ENTITY, self.angles_z);
2553         }
2554         if(f & 4)
2555         {
2556                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2557                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2558                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2559         }
2560         WriteShort(MSG_ENTITY, self.scale * 256.0);
2561         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2562         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2563         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2564         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2565
2566         return TRUE;
2567 }
2568
2569 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2570 {
2571         entity e;
2572         float sz;
2573         e = spawn();
2574         e.classname = "modeleffect";
2575         setmodel(e, m);
2576         e.frame = f;
2577         setorigin(e, o);
2578         e.velocity = v;
2579         e.angles = ang;
2580         e.avelocity = angv;
2581         e.alpha = a;
2582         e.teleport_time = t1;
2583         e.fade_time = t2;
2584         e.skin = s;
2585         if(s0 >= 0)
2586                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2587         else
2588                 e.scale = -s0;
2589         if(s2 >= 0)
2590                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2591         else
2592                 e.scale2 = -s2;
2593         sz = max(e.scale, e.scale2);
2594         setsize(e, e.mins * sz, e.maxs * sz);
2595         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2596 }
2597
2598 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2599 {
2600         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2601 }
2602
2603 float randombit(float bits)
2604 {
2605         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2606                 return bits;
2607
2608         float n, f, b, r;
2609
2610         r = random();
2611         b = 0;
2612         n = 0;
2613
2614         for(f = 1; f <= bits; f *= 2)
2615         {
2616                 if(bits & f)
2617                 {
2618                         ++n;
2619                         r *= n;
2620                         if(r <= 1)
2621                                 b = f;
2622                         else
2623                                 r = (r - 1) / (n - 1);
2624                 }
2625         }
2626
2627         return b;
2628 }
2629
2630 float randombits(float bits, float k, float error_return)
2631 {
2632         float r;
2633         r = 0;
2634         while(k > 0 && bits != r)
2635         {
2636                 r += randombit(bits - r);
2637                 --k;
2638         }
2639         if(error_return)
2640                 if(k > 0)
2641                         return -1; // all
2642         return r;
2643 }
2644
2645 void randombit_test(float bits, float iter)
2646 {
2647         while(iter > 0)
2648         {
2649                 print(ftos(randombit(bits)), "\n");
2650                 --iter;
2651         }
2652 }
2653
2654 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2655 {
2656         if(halflifedist > 0)
2657                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2658         else if(halflifedist < 0)
2659                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2660         else
2661                 return 1;
2662 }
2663
2664
2665
2666
2667 #ifdef RELEASE
2668 #define cvar_string_normal builtin_cvar_string
2669 #define cvar_normal builtin_cvar
2670 #else
2671 string cvar_string_normal(string n)
2672 {
2673         if not(cvar_type(n) & 1)
2674                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2675         return builtin_cvar_string(n);
2676 }
2677
2678 float cvar_normal(string n)
2679 {
2680         return stof(cvar_string_normal(n));
2681 }
2682 #endif
2683 #define cvar_set_normal builtin_cvar_set
2684
2685 void defer_think()
2686 {
2687     entity oself;
2688
2689     oself           = self;
2690     self            = self.owner;
2691     oself.think     = SUB_Remove;
2692     oself.nextthink = time;
2693
2694     oself.use();
2695 }
2696
2697 /*
2698     Execute func() after time + fdelay.
2699     self when func is executed = self when defer is called
2700 */
2701 void defer(float fdelay, void() func)
2702 {
2703     entity e;
2704
2705     e           = spawn();
2706     e.owner     = self;
2707     e.use       = func;
2708     e.think     = defer_think;
2709     e.nextthink = time + fdelay;
2710 }
2711
2712 .string aiment_classname;
2713 .float aiment_deadflag;
2714 void SetMovetypeFollow(entity ent, entity e)
2715 {
2716         // FIXME this may not be warpzone aware
2717         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2718         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2719         ent.aiment = e; // make the hole follow bmodel
2720         ent.punchangle = e.angles; // the original angles of bmodel
2721         ent.view_ofs = ent.origin - e.origin; // relative origin
2722         ent.v_angle = ent.angles - e.angles; // relative angles
2723         ent.aiment_classname = strzone(e.classname);
2724         ent.aiment_deadflag = e.deadflag;
2725 }
2726 void UnsetMovetypeFollow(entity ent)
2727 {
2728         ent.movetype = MOVETYPE_FLY;
2729         PROJECTILE_MAKETRIGGER(ent);
2730         ent.aiment = world;
2731 }
2732 float LostMovetypeFollow(entity ent)
2733 {
2734 /*
2735         if(ent.movetype != MOVETYPE_FOLLOW)
2736                 if(ent.aiment)
2737                         error("???");
2738 */
2739         if(ent.aiment)
2740         {
2741                 if(ent.aiment.classname != ent.aiment_classname)
2742                         return 1;
2743                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2744                         return 1;
2745         }
2746         return 0;
2747 }
2748
2749 float isPushable(entity e)
2750 {
2751         if(e.iscreature)
2752                 return TRUE;
2753         switch(e.classname)
2754         {
2755                 case "body":
2756                 case "droppedweapon":
2757                 case "keepawayball":
2758                 case "nexball_basketball":
2759                 case "nexball_football":
2760                         return TRUE;
2761                 case "bullet": // antilagged bullets can't hit this either
2762                         return FALSE;
2763         }
2764         if (e.projectiledeathtype)
2765                 return TRUE;
2766         return FALSE;
2767 }