1a885f78f0bf3f508b85de78f6fd2a131506dd90
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 #include "miscfunctions.qh"
2
3 #include "antilag.qh"
4 #include "command/common.qh"
5 #include "constants.qh"
6 #include "g_hook.qh"
7 #include "ipban.qh"
8 #include <server/mutators/_mod.qh>
9 #include "../common/t_items.qh"
10 #include "resources.qh"
11 #include "items.qh"
12 #include "player.qh"
13 #include "weapons/accuracy.qh"
14 #include "weapons/csqcprojectile.qh"
15 #include "weapons/selection.qh"
16 #include "../common/command/_mod.qh"
17 #include "../common/constants.qh"
18 #include <common/net_linked.qh>
19 #include "../common/deathtypes/all.qh"
20 #include "../common/mapinfo.qh"
21 #include "../common/notifications/all.qh"
22 #include "../common/playerstats.qh"
23 #include "../common/teams.qh"
24 #include "../common/mapobjects/subs.qh"
25 #include "../common/util.qh"
26 #include "../common/turrets/sv_turrets.qh"
27 #include <common/weapons/_all.qh>
28 #include "../common/vehicles/sv_vehicles.qh"
29 #include "../common/vehicles/vehicle.qh"
30 #include "../common/items/_mod.qh"
31 #include "../common/state.qh"
32 #include "../common/effects/qc/globalsound.qh"
33 #include "../common/wepent.qh"
34 #include "../lib/csqcmodel/sv_model.qh"
35 #include "../lib/warpzone/anglestransform.qh"
36 #include "../lib/warpzone/server.qh"
37
38 void crosshair_trace(entity pl)
39 {
40         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
41 }
42 .bool ctrace_solidchanged;
43 void crosshair_trace_plusvisibletriggers(entity pl)
44 {
45         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
46         {
47                 if(it.model != "")
48                 {
49                         it.solid = SOLID_BSP;
50                         it.ctrace_solidchanged = true;
51                         IL_PUSH(g_ctrace_changed, it);
52                 }
53         });
54
55         crosshair_trace(pl);
56
57         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
58         {
59                 it.solid = SOLID_TRIGGER;
60                 it.ctrace_solidchanged = false;
61         });
62
63         IL_CLEAR(g_ctrace_changed);
64 }
65 void WarpZone_crosshair_trace(entity pl)
66 {
67         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
68 }
69
70
71 void GameLogEcho(string s)
72 {
73     string fn;
74     int matches;
75
76     if (autocvar_sv_eventlog_files)
77     {
78         if (!logfile_open)
79         {
80             logfile_open = true;
81             matches = autocvar_sv_eventlog_files_counter + 1;
82             cvar_set("sv_eventlog_files_counter", itos(matches));
83             fn = ftos(matches);
84             if (strlen(fn) < 8)
85                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
86             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
87             logfile = fopen(fn, FILE_APPEND);
88             fputs(logfile, ":logversion:3\n");
89         }
90         if (logfile >= 0)
91         {
92             if (autocvar_sv_eventlog_files_timestamps)
93                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
94             else
95                 fputs(logfile, strcat(s, "\n"));
96         }
97     }
98     if (autocvar_sv_eventlog_console)
99     {
100         dedicated_print(strcat(s, "\n"));
101     }
102 }
103
104 void GameLogInit()
105 {
106     logfile_open = 0;
107     // will be opened later
108 }
109
110 void GameLogClose()
111 {
112     if (logfile_open && logfile >= 0)
113     {
114         fclose(logfile);
115         logfile = -1;
116     }
117 }
118
119 entity findnearest(vector point, bool checkitems, vector axismod)
120 {
121     vector dist;
122     int num_nearest = 0;
123
124     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
125     {
126         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
127             dist = it.oldorigin;
128         else
129             dist = it.origin;
130         dist = dist - point;
131         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
132         float len = vlen2(dist);
133
134         int l;
135         for (l = 0; l < num_nearest; ++l)
136         {
137             if (len < nearest_length[l])
138                 break;
139         }
140
141         // now i tells us where to insert at
142         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
143         if (l < NUM_NEAREST_ENTITIES)
144         {
145             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
146             {
147                 nearest_length[j + 1] = nearest_length[j];
148                 nearest_entity[j + 1] = nearest_entity[j];
149             }
150             nearest_length[l] = len;
151             nearest_entity[l] = it;
152             if (num_nearest < NUM_NEAREST_ENTITIES)
153                 num_nearest = num_nearest + 1;
154         }
155     });
156
157     // now use the first one from our list that we can see
158     for (int j = 0; j < num_nearest; ++j)
159     {
160         traceline(point, nearest_entity[j].origin, true, NULL);
161         if (trace_fraction == 1)
162         {
163             if (j != 0)
164                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
165             return nearest_entity[j];
166         }
167     }
168
169     if (num_nearest == 0)
170         return NULL;
171
172     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
173     /* DEBUGGING CODE:
174     dprint("Candidates were: ");
175     for(j = 0; j < num_nearest; ++j)
176     {
177         if(j != 0)
178                 dprint(", ");
179         dprint(nearest_entity[j].netname);
180     }
181     dprint("\n");
182     */
183
184     return nearest_entity[0];
185 }
186
187 string NearestLocation(vector p)
188 {
189     string ret = "somewhere";
190     entity loc = findnearest(p, false, '1 1 1');
191     if (loc)
192         ret = loc.message;
193     else
194     {
195         loc = findnearest(p, true, '1 1 4');
196         if (loc)
197             ret = loc.netname;
198     }
199     return ret;
200 }
201
202 string AmmoNameFromWeaponentity(Weapon wep)
203 {
204         string ammoitems = "batteries";
205         switch (wep.ammo_type)
206         {
207                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
208                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
209                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
210                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
211                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
212                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
213         }
214         return ammoitems;
215 }
216
217 string formatmessage(entity this, string msg)
218 {
219         float p, p1, p2;
220         float n;
221         vector cursor;
222         entity cursor_ent;
223         string escape;
224         string replacement;
225         p = 0;
226         n = 7;
227
228         WarpZone_crosshair_trace(this);
229         cursor = trace_endpos;
230         cursor_ent = trace_ent;
231
232         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
233         msg = M_ARGV(1, string);
234
235         while (1) {
236                 if (n < 1)
237                         break; // too many replacements
238
239                 n = n - 1;
240                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
241                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
242
243                 if (p1 < 0)
244                         p1 = p2;
245
246                 if (p2 < 0)
247                         p2 = p1;
248
249                 p = min(p1, p2);
250
251                 if (p < 0)
252                         break;
253
254                 replacement = substring(msg, p, 2);
255                 escape = substring(msg, p + 1, 1);
256
257                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
258
259                 switch(escape)
260                 {
261                         case "%": replacement = "%"; break;
262                         case "\\":replacement = "\\"; break;
263                         case "n": replacement = "\n"; break;
264                         case "a": replacement = ftos(floor(this.armorvalue)); break;
265                         case "h": replacement = ftos(floor(this.health)); break;
266                         case "l": replacement = NearestLocation(this.origin); break;
267                         case "y": replacement = NearestLocation(cursor); break;
268                         case "d": replacement = NearestLocation(this.death_origin); break;
269                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
270                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
271                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
272                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
273                         case "S": replacement = ftos(vlen(this.velocity)); break;
274                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
275                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
276                         default:
277                         {
278                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
279                                 replacement = M_ARGV(2, string);
280                                 break;
281                         }
282                 }
283
284                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
285                 p = p + strlen(replacement);
286         }
287         return msg;
288 }
289
290 /*
291 =============
292 GetCvars
293 =============
294 Called with:
295   0:  sends the request
296   >0: receives a cvar from name=argv(f) value=argv(f+1)
297 */
298 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
299 {
300         if (f < 0)
301         {
302                 strfree(store.(field));
303         }
304         else if (f > 0)
305         {
306                 if (thisname == name)
307                 {
308                         strcpy(store.(field), argv(f + 1));
309                 }
310         }
311         else
312                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
313 }
314 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
315 {
316         GetCvars_handleString(this, store, thisname, f, field, name);
317         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
318                 if (thisname == name)
319                 {
320                         string s = func(this, strcat1(store.(field)));
321                         if (s != store.(field))
322                         {
323                                 strcpy(store.(field), s);
324                         }
325                 }
326 }
327 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
328 {
329         if (f < 0)
330         {
331         }
332         else if (f > 0)
333         {
334                 if (thisname == name)
335                         store.(field) = stof(argv(f + 1));
336         }
337         else
338                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
339 }
340 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
341 {
342         if (f < 0)
343         {
344         }
345         else if (f > 0)
346         {
347                 if (thisname == name)
348                 {
349                         if (!store.(field))
350                         {
351                                 store.(field) = stof(argv(f + 1));
352                                 if (!store.(field))
353                                         store.(field) = -1;
354                         }
355                 }
356         }
357         else
358         {
359                 if (!store.(field))
360                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
361         }
362 }
363 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
364 {
365         string o = W_FixWeaponOrder_ForceComplete(wo);
366         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
367         return o;
368 }
369
370 REPLICATE(autoswitch, bool, "cl_autoswitch");
371
372 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
373
374 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
375
376 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
377
378 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
379
380 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
381
382 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
383
384 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
385
386 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
387
388 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
389
390 REPLICATE(cvar_cl_physics, string, "cl_physics");
391
392 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
393
394 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
395
396 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
397
398 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
399
400 /**
401  * @param f -1: cleanup, 0: request, 1: receive
402  */
403 void GetCvars(entity this, entity store, int f)
404 {
405         string s = string_null;
406
407         if (f > 0)
408                 s = strcat1(argv(f));
409
410         get_cvars_f = f;
411         get_cvars_s = s;
412         MUTATOR_CALLHOOK(GetCvars);
413
414         Notification_GetCvars(this);
415
416         ReplicateVars(this, store, s, f);
417
418         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
419         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
420         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
421         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
422         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
425         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
429
430         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
431
432         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
433         if (f > 0)
434         {
435                 if (s == "cl_weaponpriority")
436                 {
437                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
438                         {
439                                 .entity weaponentity = weaponentities[slot];
440                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
441                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
442                         }
443                 }
444                 if (s == "cl_allow_uidtracking")
445                         PlayerStats_GameReport_AddPlayer(this);
446         }
447 }
448
449 // decolorizes and team colors the player name when needed
450 string playername(entity p, bool team_colorize)
451 {
452     string t;
453     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
454     {
455         t = Team_ColorCode(p.team);
456         return strcat(t, strdecolorize(p.netname));
457     }
458     else
459         return p.netname;
460 }
461
462 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
463 {
464         int i = weaponinfo.m_id;
465         int d = 0;
466         bool allow_mutatorblocked = false;
467
468         if(!i)
469                 return 0;
470
471         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
472         d = M_ARGV(1, float);
473         allguns = M_ARGV(2, bool);
474         allow_mutatorblocked = M_ARGV(3, bool);
475
476         if(allguns)
477         {
478                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
479                         d = true;
480                 else
481                         d = false;
482         }
483         else if(!mutator_returnvalue)
484                 d = !(!weaponinfo.weaponstart);
485
486         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
487                 d = 0;
488
489         float t = weaponinfo.weaponstartoverride;
490
491         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
492
493         // bit order in t:
494         // 1: want or not
495         // 2: is default?
496         // 4: is set by default?
497         if(t < 0)
498                 t = 4 | (3 * d);
499         else
500                 t |= (2 * d);
501
502         return t;
503 }
504
505 void readplayerstartcvars()
506 {
507         float i, t;
508         string s;
509
510         // initialize starting values for players
511         start_weapons = '0 0 0';
512         start_weapons_default = '0 0 0';
513         start_weapons_defaultmask = '0 0 0';
514         start_items = 0;
515         start_ammo_shells = 0;
516         start_ammo_nails = 0;
517         start_ammo_rockets = 0;
518         start_ammo_cells = 0;
519         start_ammo_plasma = 0;
520         if (random_start_ammo == NULL)
521         {
522                 random_start_ammo = spawn();
523         }
524         start_health = cvar("g_balance_health_start");
525         start_armorvalue = cvar("g_balance_armor_start");
526
527         g_weaponarena = 0;
528         g_weaponarena_weapons = '0 0 0';
529
530         s = cvar_string("g_weaponarena");
531
532         MUTATOR_CALLHOOK(SetWeaponArena, s);
533         s = M_ARGV(0, string);
534
535         if (s == "0" || s == "")
536         {
537                 // no arena
538         }
539         else if (s == "off")
540         {
541                 // forcibly turn off weaponarena
542         }
543         else if (s == "all" || s == "1")
544         {
545                 g_weaponarena = 1;
546                 g_weaponarena_list = "All Weapons";
547                 FOREACH(Weapons, it != WEP_Null, {
548                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
549                                 g_weaponarena_weapons |= (it.m_wepset);
550                 });
551         }
552         else if (s == "devall")
553         {
554                 g_weaponarena = 1;
555                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
556                 FOREACH(Weapons, it != WEP_Null,
557                 {
558                         g_weaponarena_weapons |= (it.m_wepset);
559                 });
560         }
561         else if (s == "most")
562         {
563                 g_weaponarena = 1;
564                 g_weaponarena_list = "Most Weapons";
565                 FOREACH(Weapons, it != WEP_Null, {
566                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
567                                 if(it.spawnflags & WEP_FLAG_NORMAL)
568                                         g_weaponarena_weapons |= (it.m_wepset);
569                 });
570         }
571         else if (s == "none")
572         {
573                 g_weaponarena = 1;
574                 g_weaponarena_list = "No Weapons";
575         }
576         else
577         {
578                 g_weaponarena = 1;
579                 t = tokenize_console(s);
580                 g_weaponarena_list = "";
581                 for (i = 0; i < t; ++i)
582                 {
583                         s = argv(i);
584                         FOREACH(Weapons, it != WEP_Null, {
585                                 if(it.netname == s)
586                                 {
587                                         g_weaponarena_weapons |= (it.m_wepset);
588                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
589                                         break;
590                                 }
591                         });
592                 }
593                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
594         }
595
596         if (g_weaponarena)
597         {
598                 g_weapon_stay = 0; // incompatible
599                 start_weapons = g_weaponarena_weapons;
600                 start_items |= IT_UNLIMITED_AMMO;
601         }
602         else
603         {
604                 FOREACH(Weapons, it != WEP_Null, {
605                         int w = want_weapon(it, false);
606                         WepSet s = it.m_wepset;
607                         if(w & 1)
608                                 start_weapons |= s;
609                         if(w & 2)
610                                 start_weapons_default |= s;
611                         if(w & 4)
612                                 start_weapons_defaultmask |= s;
613                 });
614         }
615
616         if(!cvar("g_use_ammunition"))
617                 start_items |= IT_UNLIMITED_AMMO;
618
619         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
620         {
621                 start_ammo_shells = 999;
622                 start_ammo_nails = 999;
623                 start_ammo_rockets = 999;
624                 start_ammo_cells = 999;
625                 start_ammo_plasma = 999;
626                 start_ammo_fuel = 999;
627         }
628         else
629         {
630                 start_ammo_shells = cvar("g_start_ammo_shells");
631                 start_ammo_nails = cvar("g_start_ammo_nails");
632                 start_ammo_rockets = cvar("g_start_ammo_rockets");
633                 start_ammo_cells = cvar("g_start_ammo_cells");
634                 start_ammo_plasma = cvar("g_start_ammo_plasma");
635                 start_ammo_fuel = cvar("g_start_ammo_fuel");
636                 random_start_weapons_count = cvar("g_random_start_weapons_count");
637                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
638                         "g_random_start_shells"));
639                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
640                         "g_random_start_bullets"));
641                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
642                         cvar("g_random_start_rockets"));
643                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
644                         "g_random_start_cells"));
645                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
646                         "g_random_start_plasma"));
647         }
648
649         if (warmup_stage)
650         {
651                 warmup_start_ammo_shells = start_ammo_shells;
652                 warmup_start_ammo_nails = start_ammo_nails;
653                 warmup_start_ammo_rockets = start_ammo_rockets;
654                 warmup_start_ammo_cells = start_ammo_cells;
655                 warmup_start_ammo_plasma = start_ammo_plasma;
656                 warmup_start_ammo_fuel = start_ammo_fuel;
657                 warmup_start_health = start_health;
658                 warmup_start_armorvalue = start_armorvalue;
659                 warmup_start_weapons = start_weapons;
660                 warmup_start_weapons_default = start_weapons_default;
661                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
662
663                 if (!g_weaponarena && !g_ca && !g_freezetag)
664                 {
665                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
666                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
667                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
668                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
669                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
670                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
671                         warmup_start_health = cvar("g_warmup_start_health");
672                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
673                         warmup_start_weapons = '0 0 0';
674                         warmup_start_weapons_default = '0 0 0';
675                         warmup_start_weapons_defaultmask = '0 0 0';
676                         FOREACH(Weapons, it != WEP_Null, {
677                                 int w = want_weapon(it, g_warmup_allguns);
678                                 WepSet s = (it.m_wepset);
679                                 if(w & 1)
680                                         warmup_start_weapons |= s;
681                                 if(w & 2)
682                                         warmup_start_weapons_default |= s;
683                                 if(w & 4)
684                                         warmup_start_weapons_defaultmask |= s;
685                         });
686                 }
687         }
688
689         if (g_jetpack)
690                 start_items |= ITEM_Jetpack.m_itemid;
691
692         MUTATOR_CALLHOOK(SetStartItems);
693
694         if (start_items & ITEM_Jetpack.m_itemid)
695         {
696                 start_items |= ITEM_JetpackRegen.m_itemid;
697                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
698                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
699         }
700
701         WepSet precache_weapons = start_weapons;
702         if (g_warmup_allguns != 1)
703                 precache_weapons |= warmup_start_weapons;
704         FOREACH(Weapons, it != WEP_Null, {
705                 if(precache_weapons & (it.m_wepset))
706                         it.wr_init(it);
707         });
708
709         start_ammo_shells = max(0, start_ammo_shells);
710         start_ammo_nails = max(0, start_ammo_nails);
711         start_ammo_rockets = max(0, start_ammo_rockets);
712         start_ammo_cells = max(0, start_ammo_cells);
713         start_ammo_plasma = max(0, start_ammo_plasma);
714         start_ammo_fuel = max(0, start_ammo_fuel);
715         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
716                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
717         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
718                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
719         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
720                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
721         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
722                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
723         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
724                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
725
726         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
727         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
728         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
729         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
730         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
731         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
732 }
733
734 void precache_playermodel(string m)
735 {
736         float globhandle, i, n;
737         string f;
738
739         if(substring(m, -9,5) == "_lod1")
740                 return;
741         if(substring(m, -9,5) == "_lod2")
742                 return;
743         precache_model(m);
744         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
745         if(fexists(f))
746                 precache_model(f);
747         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
748         if(fexists(f))
749                 precache_model(f);
750
751         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
752         if (globhandle < 0)
753                 return;
754         n = search_getsize(globhandle);
755         for (i = 0; i < n; ++i)
756         {
757                 //print(search_getfilename(globhandle, i), "\n");
758                 f = search_getfilename(globhandle, i);
759                 PrecachePlayerSounds(f);
760         }
761         search_end(globhandle);
762 }
763 void precache_all_playermodels(string pattern)
764 {
765         int globhandle = search_begin(pattern, true, false);
766         if (globhandle < 0) return;
767         int n = search_getsize(globhandle);
768         for (int i = 0; i < n; ++i)
769         {
770                 string s = search_getfilename(globhandle, i);
771                 precache_playermodel(s);
772         }
773         search_end(globhandle);
774 }
775
776 void precache_playermodels(string s)
777 {
778         FOREACH_WORD(s, true, { precache_playermodel(it); });
779 }
780
781 void precache()
782 {
783     // gamemode related things
784
785     // Precache all player models if desired
786     if (autocvar_sv_precacheplayermodels)
787     {
788         PrecachePlayerSounds("sound/player/default.sounds");
789         precache_all_playermodels("models/player/*.zym");
790         precache_all_playermodels("models/player/*.dpm");
791         precache_all_playermodels("models/player/*.md3");
792         precache_all_playermodels("models/player/*.psk");
793         precache_all_playermodels("models/player/*.iqm");
794     }
795
796     if (autocvar_sv_defaultcharacter)
797     {
798                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
799                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
800                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
801                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
802                 precache_playermodels(autocvar_sv_defaultplayermodel);
803     }
804
805 #if 0
806     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
807
808     if (!this.noise && this.music) // quake 3 uses the music field
809         this.noise = this.music;
810
811     // plays music for the level if there is any
812     if (this.noise)
813     {
814         precache_sound (this.noise);
815         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
816     }
817 #endif
818 }
819
820
821 void make_safe_for_remove(entity e)
822 {
823     if (e.initialize_entity)
824     {
825         entity ent, prev = NULL;
826         for (ent = initialize_entity_first; ent; )
827         {
828             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
829             {
830                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
831                 // skip it in linked list
832                 if (prev)
833                 {
834                     prev.initialize_entity_next = ent.initialize_entity_next;
835                     ent = prev.initialize_entity_next;
836                 }
837                 else
838                 {
839                     initialize_entity_first = ent.initialize_entity_next;
840                     ent = initialize_entity_first;
841                 }
842             }
843             else
844             {
845                 prev = ent;
846                 ent = ent.initialize_entity_next;
847             }
848         }
849     }
850 }
851
852 .float remove_except_protected_forbidden;
853 void remove_except_protected(entity e)
854 {
855         if(e.remove_except_protected_forbidden)
856                 error("not allowed to remove this at this point");
857         builtin_remove(e);
858 }
859
860 void remove_unsafely(entity e)
861 {
862     if(e.classname == "spike")
863         error("Removing spikes is forbidden (crylink bug), please report");
864     builtin_remove(e);
865 }
866
867 void remove_safely(entity e)
868 {
869     make_safe_for_remove(e);
870     builtin_remove(e);
871 }
872
873 void InitializeEntity(entity e, void(entity this) func, float order)
874 {
875     entity prev, cur;
876
877     if (!e || e.initialize_entity)
878     {
879         // make a proxy initializer entity
880         entity e_old = e;
881         e = new(initialize_entity);
882         e.enemy = e_old;
883     }
884
885     e.initialize_entity = func;
886     e.initialize_entity_order = order;
887
888     cur = initialize_entity_first;
889     prev = NULL;
890     for (;;)
891     {
892         if (!cur || cur.initialize_entity_order > order)
893         {
894             // insert between prev and cur
895             if (prev)
896                 prev.initialize_entity_next = e;
897             else
898                 initialize_entity_first = e;
899             e.initialize_entity_next = cur;
900             return;
901         }
902         prev = cur;
903         cur = cur.initialize_entity_next;
904     }
905 }
906 void InitializeEntitiesRun()
907 {
908     entity startoflist = initialize_entity_first;
909     initialize_entity_first = NULL;
910     delete_fn = remove_except_protected;
911     for (entity e = startoflist; e; e = e.initialize_entity_next)
912     {
913                 e.remove_except_protected_forbidden = 1;
914     }
915     for (entity e = startoflist; e; )
916     {
917                 e.remove_except_protected_forbidden = 0;
918         e.initialize_entity_order = 0;
919         entity next = e.initialize_entity_next;
920         e.initialize_entity_next = NULL;
921         var void(entity this) func = e.initialize_entity;
922         e.initialize_entity = func_null;
923         if (e.classname == "initialize_entity")
924         {
925             entity wrappee = e.enemy;
926             builtin_remove(e);
927             e = wrappee;
928         }
929         //dprint("Delayed initialization: ", e.classname, "\n");
930         if (func)
931         {
932                 func(e);
933         }
934         else
935         {
936             eprint(e);
937             backtrace(strcat("Null function in: ", e.classname, "\n"));
938         }
939         e = next;
940     }
941     delete_fn = remove_unsafely;
942 }
943
944 .float(entity) isEliminated;
945 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
946 {
947         Stream out = MSG_ENTITY;
948         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
949         serialize(byte, out, sendflags);
950         if (sendflags & 1) {
951                 for (int i = 1; i <= maxclients; i += 8) {
952                         int f = 0;
953                         entity e = edict_num(i);
954                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
955                                 if (eliminatedPlayers.isEliminated(e)) {
956                                         f |= BIT(b);
957                                 }
958                         }
959                         serialize(byte, out, f);
960                 }
961         }
962         return true;
963 }
964
965 void EliminatedPlayers_Init(float(entity) isEliminated_func)
966 {
967         if(eliminatedPlayers)
968         {
969                 backtrace("Can't spawn eliminatedPlayers again!");
970                 return;
971         }
972         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
973         eliminatedPlayers.isEliminated = isEliminated_func;
974 }
975
976
977
978
979 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
980 {
981         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
982                 this.projectiledeathtype |= HITTYPE_SPLASH;
983         adaptor_think2use(this);
984 }
985
986 // deferred dropping
987 void DropToFloor_Handler(entity this)
988 {
989     WITHSELF(this, builtin_droptofloor());
990     this.dropped_origin = this.origin;
991 }
992
993 void droptofloor(entity this)
994 {
995     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
996 }
997
998
999
1000 float trace_hits_box_a0, trace_hits_box_a1;
1001
1002 float trace_hits_box_1d(float end, float thmi, float thma)
1003 {
1004     if (end == 0)
1005     {
1006         // just check if x is in range
1007         if (0 < thmi)
1008             return false;
1009         if (0 > thma)
1010             return false;
1011     }
1012     else
1013     {
1014         // do the trace with respect to x
1015         // 0 -> end has to stay in thmi -> thma
1016         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1017         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1018         if (trace_hits_box_a0 > trace_hits_box_a1)
1019             return false;
1020     }
1021     return true;
1022 }
1023
1024 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1025 {
1026     end -= start;
1027     thmi -= start;
1028     thma -= start;
1029     // now it is a trace from 0 to end
1030
1031     trace_hits_box_a0 = 0;
1032     trace_hits_box_a1 = 1;
1033
1034     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1035         return false;
1036     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1037         return false;
1038     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1039         return false;
1040
1041     return true;
1042 }
1043
1044 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1045 {
1046     return trace_hits_box(start, end, thmi - ma, thma - mi);
1047 }
1048
1049 bool SUB_NoImpactCheck(entity this, entity toucher)
1050 {
1051         // zero hitcontents = this is not the real impact, but either the
1052         // mirror-impact of something hitting the projectile instead of the
1053         // projectile hitting the something, or a touchareagrid one. Neither of
1054         // these stop the projectile from moving, so...
1055         if(trace_dphitcontents == 0)
1056         {
1057                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1058                 checkclient(this);
1059         }
1060     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1061         return true;
1062     if (toucher == NULL && this.size != '0 0 0')
1063     {
1064         vector tic;
1065         tic = this.velocity * sys_frametime;
1066         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1067         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1068         if (trace_fraction >= 1)
1069         {
1070             LOG_TRACE("Odd... did not hit...?");
1071         }
1072         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1073         {
1074             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1075             return true;
1076         }
1077     }
1078
1079     return false;
1080 }
1081
1082 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1083
1084 void W_Crylink_Dequeue(entity e);
1085 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1086 {
1087         if(SUB_OwnerCheck(this, toucher))
1088                 return true;
1089         if(SUB_NoImpactCheck(this, toucher))
1090         {
1091                 if(this.classname == "nade")
1092                         return false; // no checks here
1093                 else if(this.classname == "grapplinghook")
1094                         RemoveHook(this);
1095                 else if(this.classname == "spike")
1096                 {
1097                         W_Crylink_Dequeue(this);
1098                         delete(this);
1099                 }
1100                 else
1101                         delete(this);
1102                 return true;
1103         }
1104         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1105                 UpdateCSQCProjectile(this);
1106         return false;
1107 }
1108
1109 /** engine callback */
1110 void URI_Get_Callback(float id, float status, string data)
1111 {
1112         if(url_URI_Get_Callback(id, status, data))
1113         {
1114                 // handled
1115         }
1116         else if (id == URI_GET_DISCARD)
1117         {
1118                 // discard
1119         }
1120         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1121         {
1122                 // sv_cmd curl
1123                 Curl_URI_Get_Callback(id, status, data);
1124         }
1125         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1126         {
1127                 // online ban list
1128                 OnlineBanList_URI_Get_Callback(id, status, data);
1129         }
1130         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1131         {
1132                 // handled by a mutator
1133         }
1134         else
1135         {
1136                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1137         }
1138 }
1139
1140 string uid2name(string myuid) {
1141         string s;
1142         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1143
1144         // FIXME remove this later after 0.6 release
1145         // convert old style broken records to correct style
1146         if(s == "")
1147         {
1148                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1149                 if(s != "")
1150                 {
1151                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1152                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1153                 }
1154         }
1155
1156         if(s == "")
1157                 s = "^1Unregistered Player";
1158         return s;
1159 }
1160
1161 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1162 {
1163     float m, i;
1164     vector start, org, delta, end, enddown, mstart;
1165
1166     m = e.dphitcontentsmask;
1167     e.dphitcontentsmask = goodcontents | badcontents;
1168
1169     org = boundmin;
1170     delta = boundmax - boundmin;
1171
1172     start = end = org;
1173
1174     for (i = 0; i < attempts; ++i)
1175     {
1176         start.x = org.x + random() * delta.x;
1177         start.y = org.y + random() * delta.y;
1178         start.z = org.z + random() * delta.z;
1179
1180         // rule 1: start inside world bounds, and outside
1181         // solid, and don't start from somewhere where you can
1182         // fall down to evil
1183         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1184         if (trace_fraction >= 1)
1185             continue;
1186         if (trace_startsolid)
1187             continue;
1188         if (trace_dphitcontents & badcontents)
1189             continue;
1190         if (trace_dphitq3surfaceflags & badsurfaceflags)
1191             continue;
1192
1193         // rule 2: if we are too high, lower the point
1194         if (trace_fraction * delta.z > maxaboveground)
1195             start = trace_endpos + '0 0 1' * maxaboveground;
1196         enddown = trace_endpos;
1197
1198         // rule 3: make sure we aren't outside the map. This only works
1199         // for somewhat well formed maps. A good rule of thumb is that
1200         // the map should have a convex outside hull.
1201         // these can be traceLINES as we already verified the starting box
1202         mstart = start + 0.5 * (e.mins + e.maxs);
1203         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1204         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1205             continue;
1206         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1207         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1208             continue;
1209         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1210         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1211             continue;
1212         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1213         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1214             continue;
1215         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1216         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1217             continue;
1218
1219         // rule 4: we must "see" some spawnpoint or item
1220     entity sp = NULL;
1221     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1222     {
1223         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1224         {
1225                 sp = it;
1226                 break;
1227         }
1228     });
1229         if(!sp)
1230         {
1231                 int items_checked = 0;
1232                 IL_EACH(g_items, checkpvs(mstart, it),
1233                 {
1234                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1235                         {
1236                                 sp = it;
1237                                 break;
1238                         }
1239
1240                         ++items_checked;
1241                         if(items_checked >= attempts)
1242                                 break; // sanity
1243                 });
1244
1245                 if(!sp)
1246                         continue;
1247         }
1248
1249         // find a random vector to "look at"
1250         end.x = org.x + random() * delta.x;
1251         end.y = org.y + random() * delta.y;
1252         end.z = org.z + random() * delta.z;
1253         end = start + normalize(end - start) * vlen(delta);
1254
1255         // rule 4: start TO end must not be too short
1256         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1257         if (trace_startsolid)
1258             continue;
1259         if (trace_fraction < minviewdistance / vlen(delta))
1260             continue;
1261
1262         // rule 5: don't want to look at sky
1263         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1264             continue;
1265
1266         // rule 6: we must not end up in trigger_hurt
1267         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1268             continue;
1269
1270         break;
1271     }
1272
1273     e.dphitcontentsmask = m;
1274
1275     if (i < attempts)
1276     {
1277         setorigin(e, start);
1278         e.angles = vectoangles(end - start);
1279         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1280         return true;
1281     }
1282     else
1283         return false;
1284 }
1285
1286 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1287 {
1288         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1289 }
1290
1291 void write_recordmarker(entity pl, float tstart, float dt)
1292 {
1293     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1294
1295     // also write a marker into demo files for demotc-race-record-extractor to find
1296     stuffcmd(pl,
1297              strcat(
1298                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1299                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1300 }
1301
1302 void attach_sameorigin(entity e, entity to, string tag)
1303 {
1304     vector org, t_forward, t_left, t_up, e_forward, e_up;
1305     float tagscale;
1306
1307     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1308     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1309     t_forward = v_forward * tagscale;
1310     t_left = v_right * -tagscale;
1311     t_up = v_up * tagscale;
1312
1313     e.origin_x = org * t_forward;
1314     e.origin_y = org * t_left;
1315     e.origin_z = org * t_up;
1316
1317     // current forward and up directions
1318     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1319                 e.angles = AnglesTransform_FromVAngles(e.angles);
1320         else
1321                 e.angles = AnglesTransform_FromAngles(e.angles);
1322     fixedmakevectors(e.angles);
1323
1324     // untransform forward, up!
1325     e_forward.x = v_forward * t_forward;
1326     e_forward.y = v_forward * t_left;
1327     e_forward.z = v_forward * t_up;
1328     e_up.x = v_up * t_forward;
1329     e_up.y = v_up * t_left;
1330     e_up.z = v_up * t_up;
1331
1332     e.angles = fixedvectoangles2(e_forward, e_up);
1333     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1334                 e.angles = AnglesTransform_ToVAngles(e.angles);
1335         else
1336                 e.angles = AnglesTransform_ToAngles(e.angles);
1337
1338     setattachment(e, to, tag);
1339     setorigin(e, e.origin);
1340 }
1341
1342 void detach_sameorigin(entity e)
1343 {
1344     vector org;
1345     org = gettaginfo(e, 0);
1346     e.angles = fixedvectoangles2(v_forward, v_up);
1347     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1348                 e.angles = AnglesTransform_ToVAngles(e.angles);
1349         else
1350                 e.angles = AnglesTransform_ToAngles(e.angles);
1351     setorigin(e, org);
1352     setattachment(e, NULL, "");
1353     setorigin(e, e.origin);
1354 }
1355
1356 void follow_sameorigin(entity e, entity to)
1357 {
1358     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1359     e.aiment = to; // make the hole follow bmodel
1360     e.punchangle = to.angles; // the original angles of bmodel
1361     e.view_ofs = e.origin - to.origin; // relative origin
1362     e.v_angle = e.angles - to.angles; // relative angles
1363 }
1364
1365 void unfollow_sameorigin(entity e)
1366 {
1367     set_movetype(e, MOVETYPE_NONE);
1368 }
1369
1370 entity gettaginfo_relative_ent;
1371 vector gettaginfo_relative(entity e, float tag)
1372 {
1373     if (!gettaginfo_relative_ent)
1374     {
1375         gettaginfo_relative_ent = spawn();
1376         gettaginfo_relative_ent.effects = EF_NODRAW;
1377     }
1378     gettaginfo_relative_ent.model = e.model;
1379     gettaginfo_relative_ent.modelindex = e.modelindex;
1380     gettaginfo_relative_ent.frame = e.frame;
1381     return gettaginfo(gettaginfo_relative_ent, tag);
1382 }
1383
1384 .string aiment_classname;
1385 .float aiment_deadflag;
1386 void SetMovetypeFollow(entity ent, entity e)
1387 {
1388         // FIXME this may not be warpzone aware
1389         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1390         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1391         ent.aiment = e; // make the hole follow bmodel
1392         ent.punchangle = e.angles; // the original angles of bmodel
1393         ent.view_ofs = ent.origin - e.origin; // relative origin
1394         ent.v_angle = ent.angles - e.angles; // relative angles
1395         ent.aiment_classname = strzone(e.classname);
1396         ent.aiment_deadflag = e.deadflag;
1397 }
1398 void UnsetMovetypeFollow(entity ent)
1399 {
1400         set_movetype(ent, MOVETYPE_FLY);
1401         PROJECTILE_MAKETRIGGER(ent);
1402         ent.aiment = NULL;
1403 }
1404 float LostMovetypeFollow(entity ent)
1405 {
1406 /*
1407         if(ent.move_movetype != MOVETYPE_FOLLOW)
1408                 if(ent.aiment)
1409                         error("???");
1410 */
1411         if(ent.aiment)
1412         {
1413                 if(ent.aiment.classname != ent.aiment_classname)
1414                         return 1;
1415                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1416                         return 1;
1417         }
1418         return 0;
1419 }
1420
1421 .bool pushable;
1422 bool isPushable(entity e)
1423 {
1424         if(e.pushable)
1425                 return true;
1426         if(IS_VEHICLE(e))
1427                 return false;
1428         if(e.iscreature)
1429                 return true;
1430         if (Item_IsLoot(e))
1431         {
1432                 return true;
1433         }
1434         switch(e.classname)
1435         {
1436                 case "body":
1437                         return true;
1438                 case "bullet": // antilagged bullets can't hit this either
1439                         return false;
1440         }
1441         if (e.projectiledeathtype)
1442                 return true;
1443         return false;
1444 }