qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f > 0)
 433                 s = strcat1(argv(f));
 434
 435         get_cvars_f = f;
 436         get_cvars_s = s;
 437         MUTATOR_CALLHOOK(GetCvars);
 438
 439         Notification_GetCvars(this);
 440
 441         ReplicateVars(this, store, s, f);
 442
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 454
 455         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 456
 457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 458         if (f > 0)
 459         {
 460                 if (s == "cl_weaponpriority")
 461                 {
 462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 463                         {
 464                                 .entity weaponentity = weaponentities[slot];
 465                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 466                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 467                         }
 468                 }
 469                 if (s == "cl_allow_uidtracking")
 470                         PlayerStats_GameReport_AddPlayer(this);
 471         }
 472 }
 473
 474 // decolorizes and team colors the player name when needed
 475 string playername(entity p, bool team_colorize)
 476 {
 477     string t;
 478     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 479     {
 480         t = Team_ColorCode(p.team);
 481         return strcat(t, strdecolorize(p.netname));
 482     }
 483     else
 484         return p.netname;
 485 }
 486
 487 float want_weapon(entity weaponinfo, float allguns)
 488 {
 489         int d = 0;
 490         bool allow_mutatorblocked = false;
 491
 492         if(!weaponinfo.m_id)
 493                 return 0;
 494
 495         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 496         d = M_ARGV(1, float);
 497         allguns = M_ARGV(2, bool);
 498         allow_mutatorblocked = M_ARGV(3, bool);
 499
 500         if(allguns)
 501                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & WEP_FLAG_HIDDEN));
 502         else if(!mutator_returnvalue)
 503                 d = !(!weaponinfo.weaponstart);
 504
 505         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 506                 d = 0;
 507
 508         float t = weaponinfo.weaponstartoverride;
 509
 510         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 511
 512         // bit order in t:
 513         // 1: want or not
 514         // 2: is default?
 515         // 4: is set by default?
 516         if(t < 0)
 517                 t = 4 | (3 * d);
 518         else
 519                 t |= (2 * d);
 520
 521         return t;
 522 }
 523
 524 /// Weapons the player normally starts with outside weapon arena.
 525 WepSet weapons_start()
 526 {
 527         WepSet ret = '0 0 0';
 528         FOREACH(Weapons, it != WEP_Null, {
 529                 int w = want_weapon(it, false);
 530                 if(w & 1)
 531                         ret |= it.m_wepset;
 532         });
 533         return ret;
 534 }
 535
 536 WepSet weapons_all()
 537 {
 538         WepSet ret = '0 0 0';
 539         FOREACH(Weapons, it != WEP_Null, {
 540                 if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 541                         ret |= it.m_wepset;
 542         });
 543         return ret;
 544 }
 545
 546 WepSet weapons_devall()
 547 {
 548         WepSet ret = '0 0 0';
 549         FOREACH(Weapons, it != WEP_Null,
 550         {
 551                 ret |= it.m_wepset;
 552         });
 553         return ret;
 554 }
 555
 556 WepSet weapons_most()
 557 {
 558         WepSet ret = '0 0 0';
 559         FOREACH(Weapons, it != WEP_Null, {
 560                 if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && (it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & WEP_FLAG_HIDDEN))
 561                         ret |= it.m_wepset;
 562         });
 563         return ret;
 564 }
 565
 566 void weaponarena_available_all_update(entity this)
 567 {
 568         if (weaponsInMapAll)
 569         {
 570                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 571         }
 572         else
 573         {
 574                 // if no weapons are available on the map, just fall back to all weapons arena
 575                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 576         }
 577 }
 578
 579 void weaponarena_available_devall_update(entity this)
 580 {
 581         if (weaponsInMapAll)
 582         {
 583                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 584         }
 585         else
 586         {
 587                 // if no weapons are available on the map, just fall back to devall weapons arena
 588                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 589         }
 590 }
 591
 592 void weaponarena_available_most_update(entity this)
 593 {
 594         if (weaponsInMapAll)
 595         {
 596                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 597         }
 598         else
 599         {
 600                 // if no weapons are available on the map, just fall back to most weapons arena
 601                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 602         }
 603 }
 604
 605 void readplayerstartcvars()
 606 {
 607         float i, t;
 608
 609         // initialize starting values for players
 610         start_weapons = '0 0 0';
 611         start_weapons_default = '0 0 0';
 612         start_weapons_defaultmask = '0 0 0';
 613         start_items = 0;
 614         start_ammo_shells = 0;
 615         start_ammo_nails = 0;
 616         start_ammo_rockets = 0;
 617         start_ammo_cells = 0;
 618         start_ammo_plasma = 0;
 619         if (random_start_ammo == NULL)
 620         {
 621                 random_start_ammo = spawn();
 622         }
 623         start_health = cvar("g_balance_health_start");
 624         start_armorvalue = cvar("g_balance_armor_start");
 625
 626         g_weaponarena = 0;
 627         g_weaponarena_weapons = '0 0 0';
 628
 629         string s = cvar_string("g_weaponarena");
 630
 631         MUTATOR_CALLHOOK(SetWeaponArena, s);
 632         s = M_ARGV(0, string);
 633
 634         if (s == "0" || s == "")
 635         {
 636                 // no arena
 637         }
 638         else if (s == "off")
 639         {
 640                 // forcibly turn off weaponarena
 641         }
 642         else if (s == "all" || s == "1")
 643         {
 644                 g_weaponarena = 1;
 645                 g_weaponarena_list = "All Weapons";
 646                 g_weaponarena_weapons = weapons_all();
 647         }
 648         else if (s == "devall")
 649         {
 650                 g_weaponarena = 1;
 651                 g_weaponarena_list = "Dev All Weapons";
 652                 g_weaponarena_weapons = weapons_devall();
 653         }
 654         else if (s == "most")
 655         {
 656                 g_weaponarena = 1;
 657                 g_weaponarena_list = "Most Weapons";
 658                 g_weaponarena_weapons = weapons_most();
 659         }
 660         else if (s == "all_available")
 661         {
 662                 g_weaponarena = 1;
 663                 g_weaponarena_list = "All Available Weapons";
 664
 665                 // this needs to run after weaponsInMapAll is initialized
 666                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 667         }
 668         else if (s == "devall_available")
 669         {
 670                 g_weaponarena = 1;
 671                 g_weaponarena_list = "Dev All Available Weapons";
 672
 673                 // this needs to run after weaponsInMapAll is initialized
 674                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 675         }
 676         else if (s == "most_available")
 677         {
 678                 g_weaponarena = 1;
 679                 g_weaponarena_list = "Most Available Weapons";
 680
 681                 // this needs to run after weaponsInMapAll is initialized
 682                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 683         }
 684         else if (s == "none")
 685         {
 686                 g_weaponarena = 1;
 687                 g_weaponarena_list = "No Weapons";
 688         }
 689         else
 690         {
 691                 g_weaponarena = 1;
 692                 t = tokenize_console(s);
 693                 g_weaponarena_list = "";
 694                 for (i = 0; i < t; ++i)
 695                 {
 696                         s = argv(i);
 697                         Weapon wep = Weapons_fromstr(s);
 698                         if(wep != WEP_Null)
 699                         {
 700                                 g_weaponarena_weapons |= (wep.m_wepset);
 701                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 702                         }
 703                 }
 704                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 705         }
 706
 707         if (g_weaponarena)
 708         {
 709                 g_weapon_stay = 0; // incompatible
 710                 start_weapons = g_weaponarena_weapons;
 711                 start_items |= IT_UNLIMITED_AMMO;
 712         }
 713         else
 714         {
 715                 FOREACH(Weapons, it != WEP_Null, {
 716                         int w = want_weapon(it, false);
 717                         WepSet s = it.m_wepset;
 718                         if(w & 1)
 719                                 start_weapons |= s;
 720                         if(w & 2)
 721                                 start_weapons_default |= s;
 722                         if(w & 4)
 723                                 start_weapons_defaultmask |= s;
 724                 });
 725         }
 726
 727         if(cvar("g_balance_superweapons_time") < 0)
 728                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 729
 730         if(!cvar("g_use_ammunition"))
 731                 start_items |= IT_UNLIMITED_AMMO;
 732
 733         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 734         {
 735                 start_ammo_shells = 999;
 736                 start_ammo_nails = 999;
 737                 start_ammo_rockets = 999;
 738                 start_ammo_cells = 999;
 739                 start_ammo_plasma = 999;
 740                 start_ammo_fuel = 999;
 741         }
 742         else
 743         {
 744                 start_ammo_shells = cvar("g_start_ammo_shells");
 745                 start_ammo_nails = cvar("g_start_ammo_nails");
 746                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 747                 start_ammo_cells = cvar("g_start_ammo_cells");
 748                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 749                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 750                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 751                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
 752                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
 753                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
 754                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
 755                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
 756         }
 757
 758         warmup_start_ammo_shells = start_ammo_shells;
 759         warmup_start_ammo_nails = start_ammo_nails;
 760         warmup_start_ammo_rockets = start_ammo_rockets;
 761         warmup_start_ammo_cells = start_ammo_cells;
 762         warmup_start_ammo_plasma = start_ammo_plasma;
 763         warmup_start_ammo_fuel = start_ammo_fuel;
 764         warmup_start_health = start_health;
 765         warmup_start_armorvalue = start_armorvalue;
 766         warmup_start_weapons = start_weapons;
 767         warmup_start_weapons_default = start_weapons_default;
 768         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 769
 770         if (!g_weaponarena)
 771         {
 772                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 773                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 774                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 775                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 776                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 777                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 778                 warmup_start_health = cvar("g_warmup_start_health");
 779                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
 780                 warmup_start_weapons = '0 0 0';
 781                 warmup_start_weapons_default = '0 0 0';
 782                 warmup_start_weapons_defaultmask = '0 0 0';
 783                 FOREACH(Weapons, it != WEP_Null, {
 784                         int w = want_weapon(it, g_warmup_allguns);
 785                         WepSet s = it.m_wepset;
 786                         if(w & 1)
 787                                 warmup_start_weapons |= s;
 788                         if(w & 2)
 789                                 warmup_start_weapons_default |= s;
 790                         if(w & 4)
 791                                 warmup_start_weapons_defaultmask |= s;
 792                 });
 793         }
 794
 795         if (g_jetpack)
 796                 start_items |= ITEM_Jetpack.m_itemid;
 797
 798         MUTATOR_CALLHOOK(SetStartItems);
 799
 800         if (start_items & ITEM_Jetpack.m_itemid)
 801         {
 802                 start_items |= ITEM_JetpackRegen.m_itemid;
 803                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 804                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 805         }
 806
 807         start_ammo_shells = max(0, start_ammo_shells);
 808         start_ammo_nails = max(0, start_ammo_nails);
 809         start_ammo_rockets = max(0, start_ammo_rockets);
 810         start_ammo_cells = max(0, start_ammo_cells);
 811         start_ammo_plasma = max(0, start_ammo_plasma);
 812         start_ammo_fuel = max(0, start_ammo_fuel);
 813         SetResource(random_start_ammo, RES_SHELLS,
 814                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
 815         SetResource(random_start_ammo, RES_BULLETS,
 816                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
 817         SetResource(random_start_ammo, RES_ROCKETS,
 818                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
 819         SetResource(random_start_ammo, RES_CELLS,
 820                 max(0, GetResource(random_start_ammo, RES_CELLS)));
 821         SetResource(random_start_ammo, RES_PLASMA,
 822                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
 823
 824         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 825         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 826         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 827         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 828         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 829         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 830 }
 831
 832 void precache_playermodel(string m)
 833 {
 834         float globhandle, i, n;
 835         string f;
 836
 837         if(substring(m, -9, 5) == "_lod1")
 838                 return;
 839         if(substring(m, -9, 5) == "_lod2")
 840                 return;
 841         precache_model(m);
 842         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 843         if(fexists(f))
 844                 precache_model(f);
 845         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 846         if(fexists(f))
 847                 precache_model(f);
 848
 849         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 850         if (globhandle < 0)
 851                 return;
 852         n = search_getsize(globhandle);
 853         for (i = 0; i < n; ++i)
 854         {
 855                 //print(search_getfilename(globhandle, i), "\n");
 856                 f = search_getfilename(globhandle, i);
 857                 PrecachePlayerSounds(f);
 858         }
 859         search_end(globhandle);
 860 }
 861 void precache_all_playermodels(string pattern)
 862 {
 863         int globhandle = search_begin(pattern, true, false);
 864         if (globhandle < 0) return;
 865         int n = search_getsize(globhandle);
 866         for (int i = 0; i < n; ++i)
 867         {
 868                 string s = search_getfilename(globhandle, i);
 869                 precache_playermodel(s);
 870         }
 871         search_end(globhandle);
 872 }
 873
 874 void precache_playermodels(string s)
 875 {
 876         FOREACH_WORD(s, true, { precache_playermodel(it); });
 877 }
 878
 879 void precache()
 880 {
 881     // gamemode related things
 882
 883     // Precache all player models if desired
 884     if (autocvar_sv_precacheplayermodels)
 885     {
 886         PrecachePlayerSounds("sound/player/default.sounds");
 887         precache_all_playermodels("models/player/*.zym");
 888         precache_all_playermodels("models/player/*.dpm");
 889         precache_all_playermodels("models/player/*.md3");
 890         precache_all_playermodels("models/player/*.psk");
 891         precache_all_playermodels("models/player/*.iqm");
 892     }
 893
 894     if (autocvar_sv_defaultcharacter)
 895     {
 896                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 897                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 898                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 899                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 900                 precache_playermodels(autocvar_sv_defaultplayermodel);
 901     }
 902
 903 #if 0
 904     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 905
 906     if (!this.noise && this.music) // quake 3 uses the music field
 907         this.noise = this.music;
 908
 909     // plays music for the level if there is any
 910     if (this.noise)
 911     {
 912         precache_sound (this.noise);
 913         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 914     }
 915 #endif
 916 }
 917
 918
 919 void make_safe_for_remove(entity e)
 920 {
 921     if (e.initialize_entity)
 922     {
 923         entity ent, prev = NULL;
 924         for (ent = initialize_entity_first; ent; )
 925         {
 926             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 927             {
 928                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 929                 // skip it in linked list
 930                 if (prev)
 931                 {
 932                     prev.initialize_entity_next = ent.initialize_entity_next;
 933                     ent = prev.initialize_entity_next;
 934                 }
 935                 else
 936                 {
 937                     initialize_entity_first = ent.initialize_entity_next;
 938                     ent = initialize_entity_first;
 939                 }
 940             }
 941             else
 942             {
 943                 prev = ent;
 944                 ent = ent.initialize_entity_next;
 945             }
 946         }
 947     }
 948 }
 949
 950 .float remove_except_protected_forbidden;
 951 void remove_except_protected(entity e)
 952 {
 953         if(e.remove_except_protected_forbidden)
 954                 error("not allowed to remove this at this point");
 955         builtin_remove(e);
 956 }
 957
 958 void remove_unsafely(entity e)
 959 {
 960     if(e.classname == "spike")
 961         error("Removing spikes is forbidden (crylink bug), please report");
 962     builtin_remove(e);
 963 }
 964
 965 void remove_safely(entity e)
 966 {
 967     make_safe_for_remove(e);
 968     builtin_remove(e);
 969 }
 970
 971 void InitializeEntity(entity e, void(entity this) func, int order)
 972 {
 973     entity prev, cur;
 974
 975     if (!e || e.initialize_entity)
 976     {
 977         // make a proxy initializer entity
 978         entity e_old = e;
 979         e = new(initialize_entity);
 980         e.enemy = e_old;
 981     }
 982
 983     e.initialize_entity = func;
 984     e.initialize_entity_order = order;
 985
 986     cur = initialize_entity_first;
 987     prev = NULL;
 988     for (;;)
 989     {
 990         if (!cur || cur.initialize_entity_order > order)
 991         {
 992             // insert between prev and cur
 993             if (prev)
 994                 prev.initialize_entity_next = e;
 995             else
 996                 initialize_entity_first = e;
 997             e.initialize_entity_next = cur;
 998             return;
 999         }
1000         prev = cur;
1001         cur = cur.initialize_entity_next;
1002     }
1003 }
1004 void InitializeEntitiesRun()
1005 {
1006     entity startoflist = initialize_entity_first;
1007     initialize_entity_first = NULL;
1008     delete_fn = remove_except_protected;
1009     for (entity e = startoflist; e; e = e.initialize_entity_next)
1010     {
1011                 e.remove_except_protected_forbidden = 1;
1012     }
1013     for (entity e = startoflist; e; )
1014     {
1015                 e.remove_except_protected_forbidden = 0;
1016         e.initialize_entity_order = 0;
1017         entity next = e.initialize_entity_next;
1018         e.initialize_entity_next = NULL;
1019         var void(entity this) func = e.initialize_entity;
1020         e.initialize_entity = func_null;
1021         if (e.classname == "initialize_entity")
1022         {
1023             entity wrappee = e.enemy;
1024             builtin_remove(e);
1025             e = wrappee;
1026         }
1027         //dprint("Delayed initialization: ", e.classname, "\n");
1028         if (func)
1029         {
1030                 func(e);
1031         }
1032         else
1033         {
1034             eprint(e);
1035             backtrace(strcat("Null function in: ", e.classname, "\n"));
1036         }
1037         e = next;
1038     }
1039     delete_fn = remove_unsafely;
1040 }
1041
1042 .float(entity) isEliminated;
1043 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1044 {
1045         Stream out = MSG_ENTITY;
1046         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1047         serialize(byte, out, sendflags);
1048         if (sendflags & 1) {
1049                 for (int i = 1; i <= maxclients; i += 8) {
1050                         int f = 0;
1051                         entity e = edict_num(i);
1052                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1053                                 if (eliminatedPlayers.isEliminated(e)) {
1054                                         f |= BIT(b);
1055                                 }
1056                         }
1057                         serialize(byte, out, f);
1058                 }
1059         }
1060         return true;
1061 }
1062
1063 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1064 {
1065         if(eliminatedPlayers)
1066         {
1067                 backtrace("Can't spawn eliminatedPlayers again!");
1068                 return;
1069         }
1070         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1071         eliminatedPlayers.isEliminated = isEliminated_func;
1072 }
1073
1074
1075
1076
1077 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1078 {
1079         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1080                 this.projectiledeathtype |= HITTYPE_SPLASH;
1081         adaptor_think2use(this);
1082 }
1083
1084 // deferred dropping
1085 void DropToFloor_Handler(entity this)
1086 {
1087     WITHSELF(this, builtin_droptofloor());
1088     this.dropped_origin = this.origin;
1089 }
1090
1091 void droptofloor(entity this)
1092 {
1093     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1094 }
1095
1096
1097
1098 float trace_hits_box_a0, trace_hits_box_a1;
1099
1100 float trace_hits_box_1d(float end, float thmi, float thma)
1101 {
1102     if (end == 0)
1103     {
1104         // just check if x is in range
1105         if (0 < thmi)
1106             return false;
1107         if (0 > thma)
1108             return false;
1109     }
1110     else
1111     {
1112         // do the trace with respect to x
1113         // 0 -> end has to stay in thmi -> thma
1114         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1115         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1116         if (trace_hits_box_a0 > trace_hits_box_a1)
1117             return false;
1118     }
1119     return true;
1120 }
1121
1122 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1123 {
1124     end -= start;
1125     thmi -= start;
1126     thma -= start;
1127     // now it is a trace from 0 to end
1128
1129     trace_hits_box_a0 = 0;
1130     trace_hits_box_a1 = 1;
1131
1132     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1133         return false;
1134     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1135         return false;
1136     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1137         return false;
1138
1139     return true;
1140 }
1141
1142 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1143 {
1144     return trace_hits_box(start, end, thmi - ma, thma - mi);
1145 }
1146
1147 bool SUB_NoImpactCheck(entity this, entity toucher)
1148 {
1149         // zero hitcontents = this is not the real impact, but either the
1150         // mirror-impact of something hitting the projectile instead of the
1151         // projectile hitting the something, or a touchareagrid one. Neither of
1152         // these stop the projectile from moving, so...
1153         if(trace_dphitcontents == 0)
1154         {
1155                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1156                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1157         }
1158     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1159         return true;
1160     if (toucher == NULL && this.size != '0 0 0')
1161     {
1162         vector tic;
1163         tic = this.velocity * sys_frametime;
1164         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1165         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1166         if (trace_fraction >= 1)
1167         {
1168             LOG_TRACE("Odd... did not hit...?");
1169         }
1170         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1171         {
1172             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1173             return true;
1174         }
1175     }
1176
1177     return false;
1178 }
1179
1180 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1181
1182 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1183 {
1184         if(SUB_OwnerCheck(this, toucher))
1185                 return true;
1186         if(SUB_NoImpactCheck(this, toucher))
1187         {
1188                 if(this.classname == "nade")
1189                         return false; // no checks here
1190                 else if(this.classname == "grapplinghook")
1191                         RemoveHook(this);
1192                 else if(this.classname == "spike")
1193                 {
1194                         W_Crylink_Dequeue(this);
1195                         delete(this);
1196                 }
1197                 else
1198                         delete(this);
1199                 return true;
1200         }
1201         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1202                 UpdateCSQCProjectile(this);
1203         return false;
1204 }
1205
1206 /** engine callback */
1207 void URI_Get_Callback(float id, float status, string data)
1208 {
1209         if(url_URI_Get_Callback(id, status, data))
1210         {
1211                 // handled
1212         }
1213         else if (id == URI_GET_DISCARD)
1214         {
1215                 // discard
1216         }
1217         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1218         {
1219                 // sv_cmd curl
1220                 Curl_URI_Get_Callback(id, status, data);
1221         }
1222         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1223         {
1224                 // online ban list
1225                 OnlineBanList_URI_Get_Callback(id, status, data);
1226         }
1227         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1228         {
1229                 // handled by a mutator
1230         }
1231         else
1232         {
1233                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1234         }
1235 }
1236
1237 string uid2name(string myuid) {
1238         string s;
1239         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1240
1241         // FIXME remove this later after 0.6 release
1242         // convert old style broken records to correct style
1243         if(s == "")
1244         {
1245                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1246                 if(s != "")
1247                 {
1248                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1249                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1250                 }
1251         }
1252
1253         if(s == "")
1254                 s = "^1Unregistered Player";
1255         return s;
1256 }
1257
1258 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1259 {
1260     float m, i;
1261     vector start, org, delta, end, enddown, mstart;
1262
1263     m = e.dphitcontentsmask;
1264     e.dphitcontentsmask = goodcontents | badcontents;
1265
1266     org = boundmin;
1267     delta = boundmax - boundmin;
1268
1269     start = end = org;
1270
1271     for (i = 0; i < attempts; ++i)
1272     {
1273         start.x = org.x + random() * delta.x;
1274         start.y = org.y + random() * delta.y;
1275         start.z = org.z + random() * delta.z;
1276
1277         // rule 1: start inside world bounds, and outside
1278         // solid, and don't start from somewhere where you can
1279         // fall down to evil
1280         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1281         if (trace_fraction >= 1)
1282             continue;
1283         if (trace_startsolid)
1284             continue;
1285         if (trace_dphitcontents & badcontents)
1286             continue;
1287         if (trace_dphitq3surfaceflags & badsurfaceflags)
1288             continue;
1289
1290         // rule 2: if we are too high, lower the point
1291         if (trace_fraction * delta.z > maxaboveground)
1292             start = trace_endpos + '0 0 1' * maxaboveground;
1293         enddown = trace_endpos;
1294
1295         // rule 3: make sure we aren't outside the map. This only works
1296         // for somewhat well formed maps. A good rule of thumb is that
1297         // the map should have a convex outside hull.
1298         // these can be traceLINES as we already verified the starting box
1299         mstart = start + 0.5 * (e.mins + e.maxs);
1300         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1301         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1302             continue;
1303         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1304         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1305             continue;
1306         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1307         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1308             continue;
1309         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1310         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1311             continue;
1312         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1313         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1314             continue;
1315
1316         // rule 4: we must "see" some spawnpoint or item
1317     entity sp = NULL;
1318     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1319     {
1320         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1321         {
1322                 sp = it;
1323                 break;
1324         }
1325     });
1326         if(!sp)
1327         {
1328                 int items_checked = 0;
1329                 IL_EACH(g_items, checkpvs(mstart, it),
1330                 {
1331                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1332                         {
1333                                 sp = it;
1334                                 break;
1335                         }
1336
1337                         ++items_checked;
1338                         if(items_checked >= attempts)
1339                                 break; // sanity
1340                 });
1341
1342                 if(!sp)
1343                         continue;
1344         }
1345
1346         // find a random vector to "look at"
1347         end.x = org.x + random() * delta.x;
1348         end.y = org.y + random() * delta.y;
1349         end.z = org.z + random() * delta.z;
1350         end = start + normalize(end - start) * vlen(delta);
1351
1352         // rule 4: start TO end must not be too short
1353         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1354         if (trace_startsolid)
1355             continue;
1356         if (trace_fraction < minviewdistance / vlen(delta))
1357             continue;
1358
1359         // rule 5: don't want to look at sky
1360         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1361             continue;
1362
1363         // rule 6: we must not end up in trigger_hurt
1364         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1365             continue;
1366
1367         break;
1368     }
1369
1370     e.dphitcontentsmask = m;
1371
1372     if (i < attempts)
1373     {
1374         setorigin(e, start);
1375         e.angles = vectoangles(end - start);
1376         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1377         return true;
1378     }
1379     else
1380         return false;
1381 }
1382
1383 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1384 {
1385         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1386 }
1387
1388 void write_recordmarker(entity pl, float tstart, float dt)
1389 {
1390     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1391
1392     // also write a marker into demo files for demotc-race-record-extractor to find
1393     stuffcmd(pl,
1394              strcat(
1395                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1396                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1397 }
1398
1399 void attach_sameorigin(entity e, entity to, string tag)
1400 {
1401     vector org, t_forward, t_left, t_up, e_forward, e_up;
1402     float tagscale;
1403
1404     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1405     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1406     t_forward = v_forward * tagscale;
1407     t_left = v_right * -tagscale;
1408     t_up = v_up * tagscale;
1409
1410     e.origin_x = org * t_forward;
1411     e.origin_y = org * t_left;
1412     e.origin_z = org * t_up;
1413
1414     // current forward and up directions
1415     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1416                 e.angles = AnglesTransform_FromVAngles(e.angles);
1417         else
1418                 e.angles = AnglesTransform_FromAngles(e.angles);
1419     fixedmakevectors(e.angles);
1420
1421     // untransform forward, up!
1422     e_forward.x = v_forward * t_forward;
1423     e_forward.y = v_forward * t_left;
1424     e_forward.z = v_forward * t_up;
1425     e_up.x = v_up * t_forward;
1426     e_up.y = v_up * t_left;
1427     e_up.z = v_up * t_up;
1428
1429     e.angles = fixedvectoangles2(e_forward, e_up);
1430     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1431                 e.angles = AnglesTransform_ToVAngles(e.angles);
1432         else
1433                 e.angles = AnglesTransform_ToAngles(e.angles);
1434
1435     setattachment(e, to, tag);
1436     setorigin(e, e.origin);
1437 }
1438
1439 void detach_sameorigin(entity e)
1440 {
1441     vector org;
1442     org = gettaginfo(e, 0);
1443     e.angles = fixedvectoangles2(v_forward, v_up);
1444     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1445                 e.angles = AnglesTransform_ToVAngles(e.angles);
1446         else
1447                 e.angles = AnglesTransform_ToAngles(e.angles);
1448     setorigin(e, org);
1449     setattachment(e, NULL, "");
1450     setorigin(e, e.origin);
1451 }
1452
1453 void follow_sameorigin(entity e, entity to)
1454 {
1455     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1456     e.aiment = to; // make the hole follow bmodel
1457     e.punchangle = to.angles; // the original angles of bmodel
1458     e.view_ofs = e.origin - to.origin; // relative origin
1459     e.v_angle = e.angles - to.angles; // relative angles
1460 }
1461
1462 void unfollow_sameorigin(entity e)
1463 {
1464     set_movetype(e, MOVETYPE_NONE);
1465 }
1466
1467 entity gettaginfo_relative_ent;
1468 vector gettaginfo_relative(entity e, float tag)
1469 {
1470     if (!gettaginfo_relative_ent)
1471     {
1472         gettaginfo_relative_ent = spawn();
1473         gettaginfo_relative_ent.effects = EF_NODRAW;
1474     }
1475     gettaginfo_relative_ent.model = e.model;
1476     gettaginfo_relative_ent.modelindex = e.modelindex;
1477     gettaginfo_relative_ent.frame = e.frame;
1478     return gettaginfo(gettaginfo_relative_ent, tag);
1479 }
1480
1481 .string aiment_classname;
1482 .float aiment_deadflag;
1483 void SetMovetypeFollow(entity ent, entity e)
1484 {
1485         // FIXME this may not be warpzone aware
1486         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1487         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1488         ent.aiment = e; // make the hole follow bmodel
1489         ent.punchangle = e.angles; // the original angles of bmodel
1490         ent.view_ofs = ent.origin - e.origin; // relative origin
1491         ent.v_angle = ent.angles - e.angles; // relative angles
1492         ent.aiment_classname = strzone(e.classname);
1493         ent.aiment_deadflag = e.deadflag;
1494 }
1495 void UnsetMovetypeFollow(entity ent)
1496 {
1497         set_movetype(ent, MOVETYPE_FLY);
1498         PROJECTILE_MAKETRIGGER(ent);
1499         ent.aiment = NULL;
1500 }
1501 float LostMovetypeFollow(entity ent)
1502 {
1503 /*
1504         if(ent.move_movetype != MOVETYPE_FOLLOW)
1505                 if(ent.aiment)
1506                         error("???");
1507 */
1508         if(ent.aiment)
1509         {
1510                 if(ent.aiment.classname != ent.aiment_classname)
1511                         return 1;
1512                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1513                         return 1;
1514         }
1515         return 0;
1516 }
1517
1518 .bool pushable;
1519 bool isPushable(entity e)
1520 {
1521         if(e.pushable)
1522                 return true;
1523         if(IS_VEHICLE(e))
1524                 return false;
1525         if(e.iscreature)
1526                 return true;
1527         if (Item_IsLoot(e))
1528         {
1529                 return true;
1530         }
1531         switch(e.classname)
1532         {
1533                 case "body":
1534                         return true;
1535                 case "bullet": // antilagged bullets can't hit this either
1536                         return false;
1537         }
1538         if (e.projectiledeathtype)
1539                 return true;
1540         return false;
1541 }