qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 float spawnpoint_nag;
 161 void relocate_spawnpoint()
 162 {
 163     // nudge off the floor
 164     setorigin(self, self.origin + '0 0 1');
 165
 166     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 167     if (trace_startsolid)
 168     {
 169         vector o;
 170         o = self.origin;
 171         self.mins = PL_MIN;
 172         self.maxs = PL_MAX;
 173         if (!move_out_of_solid(self))
 174             objerror("could not get out of solid at all!");
 175         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 176         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 177         print(" ", ftos(self.origin_y - o_y));
 178         print(" ", ftos(self.origin_z - o_z), "'\n");
 179         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 180         {
 181             if (!spawnpoint_nag)
 182                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 183             spawnpoint_nag = 1;
 184         }
 185         else
 186         {
 187             setorigin(self, o);
 188             self.mins = self.maxs = '0 0 0';
 189             objerror("player spawn point in solid, mapper sucks!\n");
 190             return;
 191         }
 192     }
 193
 194     self.use = spawnpoint_use;
 195     self.team_saved = self.team;
 196     if (!self.cnt)
 197         self.cnt = 1;
 198
 199     if (have_team_spawns != 0)
 200         if (self.team)
 201             have_team_spawns = 1;
 202     have_team_spawns_forteam[self.team] = 1;
 203
 204     if (autocvar_r_showbboxes)
 205     {
 206         // show where spawnpoints point at too
 207         makevectors(self.angles);
 208         entity e;
 209         e = spawn();
 210         e.classname = "info_player_foo";
 211         setorigin(e, self.origin + v_forward * 24);
 212         setsize(e, '-8 -8 -8', '8 8 8');
 213         e.solid = SOLID_TRIGGER;
 214     }
 215 }
 216
 217 #define strstr strstrofs
 218 /*
 219 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 220 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 221 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 222 // BE CONSTANT OR strzoneD!
 223 float strstr(string haystack, string needle, float offset)
 224 {
 225         float len, endpos;
 226         string found;
 227         len = strlen(needle);
 228         endpos = strlen(haystack) - len;
 229         while(offset <= endpos)
 230         {
 231                 found = substring(haystack, offset, len);
 232                 if(found == needle)
 233                         return offset;
 234                 offset = offset + 1;
 235         }
 236         return -1;
 237 }
 238 */
 239
 240 float NUM_NEAREST_ENTITIES = 4;
 241 entity nearest_entity[NUM_NEAREST_ENTITIES];
 242 float nearest_length[NUM_NEAREST_ENTITIES];
 243 entity findnearest(vector point, .string field, string value, vector axismod)
 244 {
 245     entity localhead;
 246     float i;
 247     float j;
 248     float len;
 249     vector dist;
 250
 251     float num_nearest;
 252     num_nearest = 0;
 253
 254     localhead = find(world, field, value);
 255     while (localhead)
 256     {
 257         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 258             dist = localhead.oldorigin;
 259         else
 260             dist = localhead.origin;
 261         dist = dist - point;
 262         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 263         len = vlen(dist);
 264
 265         for (i = 0; i < num_nearest; ++i)
 266         {
 267             if (len < nearest_length[i])
 268                 break;
 269         }
 270
 271         // now i tells us where to insert at
 272         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 273         if (i < NUM_NEAREST_ENTITIES)
 274         {
 275             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 276             {
 277                 nearest_length[j + 1] = nearest_length[j];
 278                 nearest_entity[j + 1] = nearest_entity[j];
 279             }
 280             nearest_length[i] = len;
 281             nearest_entity[i] = localhead;
 282             if (num_nearest < NUM_NEAREST_ENTITIES)
 283                 num_nearest = num_nearest + 1;
 284         }
 285
 286         localhead = find(localhead, field, value);
 287     }
 288
 289     // now use the first one from our list that we can see
 290     for (i = 0; i < num_nearest; ++i)
 291     {
 292         traceline(point, nearest_entity[i].origin, TRUE, world);
 293         if (trace_fraction == 1)
 294         {
 295             if (i != 0)
 296             {
 297                 dprint("Nearest point (");
 298                 dprint(nearest_entity[0].netname);
 299                 dprint(") is not visible, using a visible one.\n");
 300             }
 301             return nearest_entity[i];
 302         }
 303     }
 304
 305     if (num_nearest == 0)
 306         return world;
 307
 308     dprint("Not seeing any location point, using nearest as fallback.\n");
 309     /* DEBUGGING CODE:
 310     dprint("Candidates were: ");
 311     for(j = 0; j < num_nearest; ++j)
 312     {
 313         if(j != 0)
 314                 dprint(", ");
 315         dprint(nearest_entity[j].netname);
 316     }
 317     dprint("\n");
 318     */
 319
 320     return nearest_entity[0];
 321 }
 322
 323 void spawnfunc_target_location()
 324 {
 325     self.classname = "target_location";
 326     // location name in netname
 327     // eventually support: count, teamgame selectors, line of sight?
 328 }
 329
 330 void spawnfunc_info_location()
 331 {
 332     self.classname = "target_location";
 333     self.message = self.netname;
 334 }
 335
 336 string NearestLocation(vector p)
 337 {
 338     entity loc;
 339     string ret;
 340     ret = "somewhere";
 341     loc = findnearest(p, classname, "target_location", '1 1 1');
 342     if (loc)
 343     {
 344         ret = loc.message;
 345     }
 346     else
 347     {
 348         loc = findnearest(p, target, "###item###", '1 1 4');
 349         if (loc)
 350             ret = loc.netname;
 351     }
 352     return ret;
 353 }
 354
 355 string formatmessage(string msg)
 356 {
 357         float p, p1, p2;
 358         float n;
 359         vector cursor;
 360         entity cursor_ent;
 361         string escape;
 362         string replacement;
 363         p = 0;
 364         n = 7;
 365
 366         WarpZone_crosshair_trace(self);
 367         cursor = trace_endpos;
 368         cursor_ent = trace_ent;
 369
 370         while (1) {
 371                 if (n < 1)
 372                         break; // too many replacements
 373
 374                 n = n - 1;
 375                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 376                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 377
 378                 if (p1 < 0)
 379                         p1 = p2;
 380
 381                 if (p2 < 0)
 382                         p2 = p1;
 383
 384                 p = min(p1, p2);
 385
 386                 if (p < 0)
 387                         break;
 388
 389                 replacement = substring(msg, p, 2);
 390                 escape = substring(msg, p + 1, 1);
 391
 392                 if (escape == "%")
 393                         replacement = "%";
 394                 else if (escape == "\\")
 395                         replacement = "\\";
 396                 else if (escape == "n")
 397                         replacement = "\n";
 398                 else if (escape == "a")
 399                         replacement = ftos(floor(self.armorvalue));
 400                 else if (escape == "h")
 401                         replacement = ftos(floor(self.health));
 402                 else if (escape == "l")
 403                         replacement = NearestLocation(self.origin);
 404                 else if (escape == "y")
 405                         replacement = NearestLocation(cursor);
 406                 else if (escape == "d")
 407                         replacement = NearestLocation(self.death_origin);
 408                 else if (escape == "w") {
 409                         float wep;
 410                         wep = self.weapon;
 411                         if (!wep)
 412                                 wep = self.switchweapon;
 413                         if (!wep)
 414                                 wep = self.cnt;
 415                         replacement = W_Name(wep);
 416                 } else if (escape == "W") {
 417                         if (self.items & IT_SHELLS) replacement = "shells";
 418                         else if (self.items & IT_NAILS) replacement = "bullets";
 419                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 420                         else if (self.items & IT_CELLS) replacement = "cells";
 421                         else replacement = "batteries"; // ;)
 422                 } else if (escape == "x") {
 423                         replacement = cursor_ent.netname;
 424                         if (replacement == "" || !cursor_ent)
 425                                 replacement = "nothing";
 426                 } else if (escape == "s")
 427                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 428                 else if (escape == "S")
 429                         replacement = ftos(vlen(self.velocity));
 430
 431                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 432                 p = p + strlen(replacement);
 433         }
 434         return msg;
 435 }
 436
 437 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 438         return (value == 0) ? FALSE : TRUE;
 439 }
 440
 441 /*
 442 =============
 443 GetCvars
 444 =============
 445 Called with:
 446   0:  sends the request
 447   >0: receives a cvar from name=argv(f) value=argv(f+1)
 448 */
 449 void GetCvars_handleString(string thisname, float f, .string field, string name)
 450 {
 451         if (f < 0)
 452         {
 453                 if (self.field)
 454                         strunzone(self.field);
 455                 self.field = string_null;
 456         }
 457         else if (f > 0)
 458         {
 459                 if (thisname == name)
 460                 {
 461                         if (self.field)
 462                                 strunzone(self.field);
 463                         self.field = strzone(argv(f + 1));
 464                 }
 465         }
 466         else
 467                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 468 }
 469 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 470 {
 471         GetCvars_handleString(thisname, f, field, name);
 472         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 473                 if (thisname == name)
 474                 {
 475                         string s;
 476                         s = func(strcat1(self.field));
 477                         if (s != self.field)
 478                         {
 479                                 strunzone(self.field);
 480                                 self.field = strzone(s);
 481                         }
 482                 }
 483 }
 484 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 485 {
 486         if (f < 0)
 487         {
 488         }
 489         else if (f > 0)
 490         {
 491                 if (thisname == name)
 492                         self.field = stof(argv(f + 1));
 493         }
 494         else
 495                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 496 }
 497 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 498 {
 499         if (f < 0)
 500         {
 501         }
 502         else if (f > 0)
 503         {
 504                 if (thisname == name)
 505                 {
 506                         if(!self.field)
 507                         {
 508                                 self.field = stof(argv(f + 1));
 509                                 if(!self.field)
 510                                         self.field = -1;
 511                         }
 512                 }
 513         }
 514         else
 515         {
 516                 if(!self.field)
 517                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 518         }
 519 }
 520 float w_getbestweapon(entity e);
 521 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 522 {
 523         string o;
 524         o = W_FixWeaponOrder_ForceComplete(wo);
 525         if(self.weaponorder_byimpulse)
 526         {
 527                 strunzone(self.weaponorder_byimpulse);
 528                 self.weaponorder_byimpulse = string_null;
 529         }
 530         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 531         return o;
 532 }
 533 void GetCvars(float f)
 534 {
 535         string s = string_null;
 536
 537         if (f > 0)
 538                 s = strcat1(argv(f));
 539
 540         get_cvars_f = f;
 541         get_cvars_s = s;
 542
 543         MUTATOR_CALLHOOK(GetCvars);
 544
 545         Notification_GetCvars();
 546
 547         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 548         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 549         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 550         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 551         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 564         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 565         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 566         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 567         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 568         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 569         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 570
 571         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 572         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 573
 574         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 575         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 576         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 577         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 578         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 579
 580         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 581         if (f > 0)
 582         {
 583                 if (s == "cl_weaponpriority")
 584                         self.switchweapon = w_getbestweapon(self);
 585                 if (s == "cl_allow_uidtracking")
 586                         PlayerStats_AddPlayer(self);
 587         }
 588 }
 589
 590 // decolorizes and team colors the player name when needed
 591 string playername(entity p)
 592 {
 593     string t;
 594     if (teamplay && !intermission_running && p.classname == "player")
 595     {
 596         t = Team_ColorCode(p.team);
 597         return strcat(t, strdecolorize(p.netname));
 598     }
 599     else
 600         return p.netname;
 601 }
 602
 603 vector randompos(vector m1, vector m2)
 604 {
 605     vector v;
 606     m2 = m2 - m1;
 607     v_x = m2_x * random() + m1_x;
 608     v_y = m2_y * random() + m1_y;
 609     v_z = m2_z * random() + m1_z;
 610     return  v;
 611 }
 612
 613 //#NO AUTOCVARS START
 614
 615 float g_pickup_shells;
 616 float g_pickup_shells_max;
 617 float g_pickup_nails;
 618 float g_pickup_nails_max;
 619 float g_pickup_rockets;
 620 float g_pickup_rockets_max;
 621 float g_pickup_cells;
 622 float g_pickup_cells_max;
 623 float g_pickup_fuel;
 624 float g_pickup_fuel_jetpack;
 625 float g_pickup_fuel_max;
 626 float g_pickup_armorsmall;
 627 float g_pickup_armorsmall_max;
 628 float g_pickup_armorsmall_anyway;
 629 float g_pickup_armormedium;
 630 float g_pickup_armormedium_max;
 631 float g_pickup_armormedium_anyway;
 632 float g_pickup_armorbig;
 633 float g_pickup_armorbig_max;
 634 float g_pickup_armorbig_anyway;
 635 float g_pickup_armorlarge;
 636 float g_pickup_armorlarge_max;
 637 float g_pickup_armorlarge_anyway;
 638 float g_pickup_healthsmall;
 639 float g_pickup_healthsmall_max;
 640 float g_pickup_healthsmall_anyway;
 641 float g_pickup_healthmedium;
 642 float g_pickup_healthmedium_max;
 643 float g_pickup_healthmedium_anyway;
 644 float g_pickup_healthlarge;
 645 float g_pickup_healthlarge_max;
 646 float g_pickup_healthlarge_anyway;
 647 float g_pickup_healthmega;
 648 float g_pickup_healthmega_max;
 649 float g_pickup_healthmega_anyway;
 650 float g_pickup_ammo_anyway;
 651 float g_pickup_weapons_anyway;
 652 float g_weaponarena;
 653 WEPSET_DECLARE_A(g_weaponarena_weapons);
 654 float g_weaponarena_random;
 655 float g_weaponarena_random_with_laser;
 656 string g_weaponarena_list;
 657 float g_weaponspeedfactor;
 658 float g_weaponratefactor;
 659 float g_weapondamagefactor;
 660 float g_weaponforcefactor;
 661 float g_weaponspreadfactor;
 662
 663 WEPSET_DECLARE_A(start_weapons);
 664 WEPSET_DECLARE_A(start_weapons_default);
 665 WEPSET_DECLARE_A(start_weapons_defaultmask);
 666 float start_items;
 667 float start_ammo_shells;
 668 float start_ammo_nails;
 669 float start_ammo_rockets;
 670 float start_ammo_cells;
 671 float start_ammo_fuel;
 672 float start_health;
 673 float start_armorvalue;
 674 WEPSET_DECLARE_A(warmup_start_weapons);
 675 WEPSET_DECLARE_A(warmup_start_weapons_default);
 676 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 677 float warmup_start_ammo_shells;
 678 float warmup_start_ammo_nails;
 679 float warmup_start_ammo_rockets;
 680 float warmup_start_ammo_cells;
 681 float warmup_start_ammo_fuel;
 682 float warmup_start_health;
 683 float warmup_start_armorvalue;
 684 float g_weapon_stay;
 685
 686 entity get_weaponinfo(float w);
 687
 688 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 689 {
 690         var float i = weaponinfo.weapon;
 691         var float d = 0;
 692
 693         if (!i)
 694                 return 0;
 695
 696         if (g_lms || g_ca || allguns)
 697         {
 698                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 699                         d = TRUE;
 700                 else
 701                         d = FALSE;
 702         }
 703         else if (g_cts)
 704                 d = (i == WEP_SHOTGUN);
 705         else if (g_nexball)
 706                 d = 0; // weapon is set a few lines later
 707         else
 708                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 709
 710         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 711                 d |= (i == WEP_HOOK);
 712         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 713                 d = 0;
 714
 715         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 716
 717         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 718
 719         // bit order in t:
 720         // 1: want or not
 721         // 2: is default?
 722         // 4: is set by default?
 723         if(t < 0)
 724                 t = 4 | (3 * d);
 725         else
 726                 t |= (2 * d);
 727
 728         return t;
 729 }
 730
 731 void readplayerstartcvars()
 732 {
 733         entity e;
 734         float i, j, t;
 735         string s;
 736
 737         // initialize starting values for players
 738         WEPSET_CLEAR_A(start_weapons);
 739         WEPSET_CLEAR_A(start_weapons_default);
 740         WEPSET_CLEAR_A(start_weapons_defaultmask);
 741         start_items = 0;
 742         start_ammo_shells = 0;
 743         start_ammo_nails = 0;
 744         start_ammo_rockets = 0;
 745         start_ammo_cells = 0;
 746         start_health = cvar("g_balance_health_start");
 747         start_armorvalue = cvar("g_balance_armor_start");
 748
 749         g_weaponarena = 0;
 750         WEPSET_CLEAR_A(g_weaponarena_weapons);
 751
 752         s = cvar_string("g_weaponarena");
 753         if (s == "0" || s == "")
 754         {
 755                 if(g_ca)
 756                         s = "most";
 757         }
 758
 759         if (s == "0" || s == "")
 760         {
 761                 // no arena
 762         }
 763         else if (s == "off")
 764         {
 765                 // forcibly turn off weaponarena
 766         }
 767         else if (s == "all")
 768         {
 769                 g_weaponarena = 1;
 770                 g_weaponarena_list = "All Weapons";
 771                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 772                 {
 773                         e = get_weaponinfo(j);
 774                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 775                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 776                 }
 777         }
 778         else if (s == "most")
 779         {
 780                 g_weaponarena = 1;
 781                 g_weaponarena_list = "Most Weapons";
 782                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 783                 {
 784                         e = get_weaponinfo(j);
 785                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 786                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 787                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 788                 }
 789         }
 790         else if (s == "none")
 791         {
 792                 g_weaponarena = 1;
 793                 g_weaponarena_list = "No Weapons";
 794         }
 795         else
 796         {
 797                 g_weaponarena = 1;
 798                 t = tokenize_console(s);
 799                 g_weaponarena_list = "";
 800                 for (i = 0; i < t; ++i)
 801                 {
 802                         s = argv(i);
 803                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 804                         {
 805                                 e = get_weaponinfo(j);
 806                                 if (e.netname == s)
 807                                 {
 808                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 809                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 810                                         break;
 811                                 }
 812                         }
 813                         if (j > WEP_LAST)
 814                         {
 815                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 816                         }
 817                 }
 818                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 819         }
 820
 821         if(g_weaponarena)
 822                 g_weaponarena_random = cvar("g_weaponarena_random");
 823         else
 824                 g_weaponarena_random = 0;
 825         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 826
 827         if (g_weaponarena)
 828         {
 829                 g_minstagib = 0; // incompatible
 830                 g_pinata = 0; // incompatible
 831                 g_weapon_stay = 0; // incompatible
 832                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 833                 if(!g_ca)
 834                         start_items |= IT_UNLIMITED_AMMO;
 835         }
 836         else if (g_minstagib)
 837         {
 838                 g_pinata = 0; // incompatible
 839                 g_weapon_stay = 0; // incompatible
 840                 g_bloodloss = 0; // incompatible
 841                 start_health = 100;
 842                 start_armorvalue = 0;
 843                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 844                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 845                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 846
 847                 if (g_minstagib_invis_alpha <= 0)
 848                         g_minstagib_invis_alpha = -1;
 849         }
 850         else
 851         {
 852                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 853                 {
 854                         e = get_weaponinfo(i);
 855                         float w = want_weapon("g_start_weapon_", e, FALSE);
 856                         if(w & 1)
 857                                 WEPSET_OR_AW(start_weapons, i);
 858                         if(w & 2)
 859                                 WEPSET_OR_AW(start_weapons_default, i);
 860                         if(w & 4)
 861                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 862                 }
 863         }
 864
 865         if(!cvar("g_use_ammunition"))
 866                 start_items |= IT_UNLIMITED_AMMO;
 867
 868         if(cvar("g_nexball"))
 869                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 870
 871         if(g_minstagib)
 872         {
 873                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 874                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 875         }
 876         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 877         {
 878                 start_ammo_rockets = 999;
 879                 start_ammo_shells = 999;
 880                 start_ammo_cells = 999;
 881                 start_ammo_nails = 999;
 882                 start_ammo_fuel = 999;
 883         }
 884         else
 885         {
 886                 if(g_ca)
 887                 {
 888                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 889                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 890                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 891                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 892                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 893                 }
 894                 else
 895                 {
 896                         start_ammo_shells = cvar("g_start_ammo_shells");
 897                         start_ammo_nails = cvar("g_start_ammo_nails");
 898                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 899                         start_ammo_cells = cvar("g_start_ammo_cells");
 900                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 901                 }
 902         }
 903
 904         if (g_ca)
 905         {
 906                 start_health = cvar("g_lms_start_health");
 907                 start_armorvalue = cvar("g_lms_start_armor");
 908         }
 909
 910         if (inWarmupStage)
 911         {
 912                 warmup_start_ammo_shells = start_ammo_shells;
 913                 warmup_start_ammo_nails = start_ammo_nails;
 914                 warmup_start_ammo_rockets = start_ammo_rockets;
 915                 warmup_start_ammo_cells = start_ammo_cells;
 916                 warmup_start_ammo_fuel = start_ammo_fuel;
 917                 warmup_start_health = start_health;
 918                 warmup_start_armorvalue = start_armorvalue;
 919                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 920                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 921                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 922
 923                 if (!g_weaponarena && !g_minstagib && !g_ca)
 924                 {
 925                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 926                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 927                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 928                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 929                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 930                         warmup_start_health = cvar("g_warmup_start_health");
 931                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 932                         WEPSET_CLEAR_A(warmup_start_weapons);
 933                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 934                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 935                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 936                         {
 937                                 e = get_weaponinfo(i);
 938                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 939                                 if(w & 1)
 940                                         WEPSET_OR_AW(warmup_start_weapons, i);
 941                                 if(w & 2)
 942                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 943                                 if(w & 4)
 944                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 945                         }
 946                 }
 947         }
 948
 949         if (g_jetpack)
 950                 start_items |= IT_JETPACK;
 951
 952         MUTATOR_CALLHOOK(SetStartItems);
 953
 954         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 955         {
 956                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 957                 start_items |= IT_FUEL_REGEN;
 958                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 959                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 960         }
 961
 962         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 963         {
 964                 e = get_weaponinfo(i);
 965                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 966                         weapon_action(i, WR_PRECACHE);
 967         }
 968
 969         start_ammo_shells = max(0, start_ammo_shells);
 970         start_ammo_nails = max(0, start_ammo_nails);
 971         start_ammo_cells = max(0, start_ammo_cells);
 972         start_ammo_rockets = max(0, start_ammo_rockets);
 973         start_ammo_fuel = max(0, start_ammo_fuel);
 974
 975         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 976         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 977         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 978         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 979         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 980 }
 981
 982 float g_bugrigs;
 983 float g_bugrigs_planar_movement;
 984 float g_bugrigs_planar_movement_car_jumping;
 985 float g_bugrigs_reverse_spinning;
 986 float g_bugrigs_reverse_speeding;
 987 float g_bugrigs_reverse_stopping;
 988 float g_bugrigs_air_steering;
 989 float g_bugrigs_angle_smoothing;
 990 float g_bugrigs_friction_floor;
 991 float g_bugrigs_friction_brake;
 992 float g_bugrigs_friction_air;
 993 float g_bugrigs_accel;
 994 float g_bugrigs_speed_ref;
 995 float g_bugrigs_speed_pow;
 996 float g_bugrigs_steer;
 997
 998 float sv_autotaunt;
 999 float sv_taunt;
1000
1001 string GetGametype(); // g_world.qc
1002 void readlevelcvars(void)
1003 {
1004         g_minstagib = cvar("g_minstagib");
1005
1006         monster_skill = cvar("g_monsters_skill");
1007
1008         // load ALL the mutators
1009         if(cvar("g_dodging"))
1010                 MUTATOR_ADD(mutator_dodging);
1011         if(cvar("g_spawn_near_teammate"))
1012                 MUTATOR_ADD(mutator_spawn_near_teammate);
1013         if(cvar("g_physical_items"))
1014                 MUTATOR_ADD(mutator_physical_items);
1015         if(cvar("g_touchexplode"))
1016                 MUTATOR_ADD(mutator_touchexplode);
1017         if(!g_minstagib)
1018         {
1019                 if(cvar("g_invincible_projectiles"))
1020                         MUTATOR_ADD(mutator_invincibleprojectiles);
1021                 if(cvar("g_new_toys"))
1022                         MUTATOR_ADD(mutator_new_toys);
1023                 if(cvar("g_nix"))
1024                         MUTATOR_ADD(mutator_nix);
1025                 if(cvar("g_rocket_flying"))
1026                         MUTATOR_ADD(mutator_rocketflying);
1027                 if(cvar("g_vampire"))
1028                         MUTATOR_ADD(mutator_vampire);
1029                 if(cvar("g_superspectate"))
1030                         MUTATOR_ADD(mutator_superspec);
1031         }
1032
1033         // is this a mutator? is this a mode?
1034         if(cvar("g_sandbox"))
1035                 MUTATOR_ADD(sandbox);
1036
1037         if(cvar("sv_allow_fullbright"))
1038                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1039
1040     g_bugrigs = cvar("g_bugrigs");
1041     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1042     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1043     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1044     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1045     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1046     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1047     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1048     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1049     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1050     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1051     g_bugrigs_accel = cvar("g_bugrigs_accel");
1052     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1053     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1054     g_bugrigs_steer = cvar("g_bugrigs_steer");
1055
1056         sv_clones = cvar("sv_clones");
1057         sv_foginterval = cvar("sv_foginterval");
1058         g_cloaked = cvar("g_cloaked");
1059     if(g_cts)
1060         g_cloaked = 1; // always enable cloak in CTS
1061         g_jump_grunt = cvar("g_jump_grunt");
1062         g_footsteps = cvar("g_footsteps");
1063         g_grappling_hook = cvar("g_grappling_hook");
1064         g_jetpack = cvar("g_jetpack");
1065         g_midair = cvar("g_midair");
1066         g_norecoil = cvar("g_norecoil");
1067         g_bloodloss = cvar("g_bloodloss");
1068         sv_maxidle = cvar("sv_maxidle");
1069         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1070         sv_autotaunt = cvar("sv_autotaunt");
1071         sv_taunt = cvar("sv_taunt");
1072
1073         inWarmupStage = cvar("g_warmup");
1074         g_warmup_limit = cvar("g_warmup_limit");
1075         g_warmup_allguns = cvar("g_warmup_allguns");
1076         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1077
1078         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1079                 inWarmupStage = 0; // these modes cannot work together, sorry
1080
1081         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1082         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1083         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1084         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1085         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1086         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1087         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1088         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1089         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1090         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1091         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1092         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1093         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1094         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1095
1096         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1097         g_weaponratefactor = cvar("g_weaponratefactor");
1098         g_weapondamagefactor = cvar("g_weapondamagefactor");
1099         g_weaponforcefactor = cvar("g_weaponforcefactor");
1100         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1101
1102         g_pickup_shells = cvar("g_pickup_shells");
1103         g_pickup_shells_max = cvar("g_pickup_shells_max");
1104         g_pickup_nails = cvar("g_pickup_nails");
1105         g_pickup_nails_max = cvar("g_pickup_nails_max");
1106         g_pickup_rockets = cvar("g_pickup_rockets");
1107         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1108         g_pickup_cells = cvar("g_pickup_cells");
1109         g_pickup_cells_max = cvar("g_pickup_cells_max");
1110         g_pickup_fuel = cvar("g_pickup_fuel");
1111         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1112         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1113         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1114         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1115         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1116         g_pickup_armormedium = cvar("g_pickup_armormedium");
1117         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1118         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1119         g_pickup_armorbig = cvar("g_pickup_armorbig");
1120         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1121         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1122         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1123         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1124         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1125         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1126         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1127         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1128         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1129         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1130         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1131         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1132         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1133         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1134         g_pickup_healthmega = cvar("g_pickup_healthmega");
1135         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1136         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1137
1138         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1139         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1140
1141         g_pinata = cvar("g_pinata");
1142
1143     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1144     if(!g_weapon_stay)
1145         g_weapon_stay = cvar("g_weapon_stay");
1146
1147         if not(inWarmupStage)
1148                 game_starttime = time + cvar("g_start_delay");
1149
1150         readplayerstartcvars();
1151 }
1152
1153 //#NO AUTOCVARS END
1154
1155 // Sound functions
1156 string precache_sound (string s) = #19;
1157 float precache_sound_index (string s) = #19;
1158
1159 #define SND_VOLUME      1
1160 #define SND_ATTENUATION 2
1161 #define SND_LARGEENTITY 8
1162 #define SND_LARGESOUND  16
1163
1164 float sound_allowed(float dest, entity e)
1165 {
1166     // sounds from world may always pass
1167     for (;;)
1168     {
1169         if (e.classname == "body")
1170             e = e.enemy;
1171         else if (e.realowner && e.realowner != e)
1172             e = e.realowner;
1173         else if (e.owner && e.owner != e)
1174             e = e.owner;
1175         else
1176             break;
1177     }
1178     // sounds to self may always pass
1179     if (dest == MSG_ONE)
1180         if (e == msg_entity)
1181             return TRUE;
1182     // sounds by players can be removed
1183     if (autocvar_bot_sound_monopoly)
1184         if (clienttype(e) == CLIENTTYPE_REAL)
1185             return FALSE;
1186     // anything else may pass
1187     return TRUE;
1188 }
1189
1190 #ifdef COMPAT_XON010_CHANNELS
1191 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1192 void sound(entity e, float chan, string samp, float vol, float atten)
1193 {
1194     if (!sound_allowed(MSG_BROADCAST, e))
1195         return;
1196     builtin_sound(e, chan, samp, vol, atten);
1197 }
1198 #else
1199 #undef sound
1200 void sound(entity e, float chan, string samp, float vol, float atten)
1201 {
1202     if (!sound_allowed(MSG_BROADCAST, e))
1203         return;
1204     sound7(e, chan, samp, vol, atten, 0, 0);
1205 }
1206 #endif
1207
1208 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1209 {
1210     float entno, idx;
1211
1212     if (!sound_allowed(dest, e))
1213         return;
1214
1215     entno = num_for_edict(e);
1216     idx = precache_sound_index(samp);
1217
1218     float sflags;
1219     sflags = 0;
1220
1221     atten = floor(atten * 64);
1222     vol = floor(vol * 255);
1223
1224     if (vol != 255)
1225         sflags |= SND_VOLUME;
1226     if (atten != 64)
1227         sflags |= SND_ATTENUATION;
1228     if (entno >= 8192 || chan < 0 || chan > 7)
1229         sflags |= SND_LARGEENTITY;
1230     if (idx >= 256)
1231         sflags |= SND_LARGESOUND;
1232
1233     WriteByte(dest, SVC_SOUND);
1234     WriteByte(dest, sflags);
1235     if (sflags & SND_VOLUME)
1236         WriteByte(dest, vol);
1237     if (sflags & SND_ATTENUATION)
1238         WriteByte(dest, atten);
1239     if (sflags & SND_LARGEENTITY)
1240     {
1241         WriteShort(dest, entno);
1242         WriteByte(dest, chan);
1243     }
1244     else
1245     {
1246         WriteShort(dest, entno * 8 + chan);
1247     }
1248     if (sflags & SND_LARGESOUND)
1249         WriteShort(dest, idx);
1250     else
1251         WriteByte(dest, idx);
1252
1253     WriteCoord(dest, o_x);
1254     WriteCoord(dest, o_y);
1255     WriteCoord(dest, o_z);
1256 }
1257 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1258 {
1259     vector o;
1260
1261     if (!sound_allowed(dest, e))
1262         return;
1263
1264     o = e.origin + 0.5 * (e.mins + e.maxs);
1265     soundtoat(dest, e, o, chan, samp, vol, atten);
1266 }
1267 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1268 {
1269     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1270 }
1271 void stopsoundto(float dest, entity e, float chan)
1272 {
1273     float entno;
1274
1275     if (!sound_allowed(dest, e))
1276         return;
1277
1278     entno = num_for_edict(e);
1279
1280     if (entno >= 8192 || chan < 0 || chan > 7)
1281     {
1282         float idx, sflags;
1283         idx = precache_sound_index("misc/null.wav");
1284         sflags = SND_LARGEENTITY;
1285         if (idx >= 256)
1286             sflags |= SND_LARGESOUND;
1287         WriteByte(dest, SVC_SOUND);
1288         WriteByte(dest, sflags);
1289         WriteShort(dest, entno);
1290         WriteByte(dest, chan);
1291         if (sflags & SND_LARGESOUND)
1292             WriteShort(dest, idx);
1293         else
1294             WriteByte(dest, idx);
1295         WriteCoord(dest, e.origin_x);
1296         WriteCoord(dest, e.origin_y);
1297         WriteCoord(dest, e.origin_z);
1298     }
1299     else
1300     {
1301         WriteByte(dest, SVC_STOPSOUND);
1302         WriteShort(dest, entno * 8 + chan);
1303     }
1304 }
1305 void stopsound(entity e, float chan)
1306 {
1307     if (!sound_allowed(MSG_BROADCAST, e))
1308         return;
1309
1310     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1311     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1312 }
1313
1314 void play2(entity e, string filename)
1315 {
1316     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1317     msg_entity = e;
1318     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1319 }
1320
1321 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1322 .float spamtime;
1323 float spamsound(entity e, float chan, string samp, float vol, float atten)
1324 {
1325     if (!sound_allowed(MSG_BROADCAST, e))
1326         return FALSE;
1327
1328     if (time > e.spamtime)
1329     {
1330         e.spamtime = time;
1331         sound(e, chan, samp, vol, atten);
1332         return TRUE;
1333     }
1334     return FALSE;
1335 }
1336
1337 void play2team(float t, string filename)
1338 {
1339     entity head;
1340
1341     if (autocvar_bot_sound_monopoly)
1342         return;
1343
1344     FOR_EACH_REALPLAYER(head)
1345     {
1346         if (head.team == t)
1347             play2(head, filename);
1348     }
1349 }
1350
1351 void play2all(string samp)
1352 {
1353     if (autocvar_bot_sound_monopoly)
1354         return;
1355
1356     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1357 }
1358
1359 void PrecachePlayerSounds(string f);
1360 void precache_playermodel(string m)
1361 {
1362         float globhandle, i, n;
1363         string f;
1364
1365         if(substring(m, -9,5) == "_lod1")
1366                 return;
1367         if(substring(m, -9,5) == "_lod2")
1368                 return;
1369         precache_model(m);
1370         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1371         if(fexists(f))
1372                 precache_model(f);
1373         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1374         if(fexists(f))
1375                 precache_model(f);
1376
1377         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1378         if (globhandle < 0)
1379                 return;
1380         n = search_getsize(globhandle);
1381         for (i = 0; i < n; ++i)
1382         {
1383                 //print(search_getfilename(globhandle, i), "\n");
1384                 f = search_getfilename(globhandle, i);
1385                 PrecachePlayerSounds(f);
1386         }
1387         search_end(globhandle);
1388 }
1389 void precache_all_playermodels(string pattern)
1390 {
1391         float globhandle, i, n;
1392         string f;
1393
1394         globhandle = search_begin(pattern, TRUE, FALSE);
1395         if (globhandle < 0)
1396                 return;
1397         n = search_getsize(globhandle);
1398         for (i = 0; i < n; ++i)
1399         {
1400                 //print(search_getfilename(globhandle, i), "\n");
1401                 f = search_getfilename(globhandle, i);
1402                 precache_playermodel(f);
1403         }
1404         search_end(globhandle);
1405 }
1406
1407 void precache()
1408 {
1409     // gamemode related things
1410     precache_model ("models/misc/chatbubble.spr");
1411
1412 #ifdef TTURRETS_ENABLED
1413     if (autocvar_g_turrets)
1414         turrets_precash();
1415 #endif
1416
1417     // Precache all player models if desired
1418     if (autocvar_sv_precacheplayermodels)
1419     {
1420         PrecachePlayerSounds("sound/player/default.sounds");
1421         precache_all_playermodels("models/player/*.zym");
1422         precache_all_playermodels("models/player/*.dpm");
1423         precache_all_playermodels("models/player/*.md3");
1424         precache_all_playermodels("models/player/*.psk");
1425         precache_all_playermodels("models/player/*.iqm");
1426     }
1427
1428     if (autocvar_sv_defaultcharacter)
1429     {
1430         string s;
1431         s = autocvar_sv_defaultplayermodel_red;
1432         if (s != "")
1433             precache_playermodel(s);
1434         s = autocvar_sv_defaultplayermodel_blue;
1435         if (s != "")
1436             precache_playermodel(s);
1437         s = autocvar_sv_defaultplayermodel_yellow;
1438         if (s != "")
1439             precache_playermodel(s);
1440         s = autocvar_sv_defaultplayermodel_pink;
1441         if (s != "")
1442             precache_playermodel(s);
1443         s = autocvar_sv_defaultplayermodel;
1444         if (s != "")
1445             precache_playermodel(s);
1446     }
1447
1448     if (g_footsteps)
1449     {
1450         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1451         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1452     }
1453
1454     // gore and miscellaneous sounds
1455     //precache_sound ("misc/h2ohit.wav");
1456     precache_model ("models/hook.md3");
1457     precache_sound ("misc/armorimpact.wav");
1458     precache_sound ("misc/bodyimpact1.wav");
1459     precache_sound ("misc/bodyimpact2.wav");
1460     precache_sound ("misc/gib.wav");
1461     precache_sound ("misc/gib_splat01.wav");
1462     precache_sound ("misc/gib_splat02.wav");
1463     precache_sound ("misc/gib_splat03.wav");
1464     precache_sound ("misc/gib_splat04.wav");
1465     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1466     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1467     precache_sound ("misc/null.wav");
1468     precache_sound ("misc/spawn.wav");
1469     precache_sound ("misc/talk.wav");
1470     precache_sound ("misc/teleport.wav");
1471     precache_sound ("misc/poweroff.wav");
1472     precache_sound ("player/lava.wav");
1473     precache_sound ("player/slime.wav");
1474
1475     precache_model ("models/sprites/0.spr32");
1476     precache_model ("models/sprites/1.spr32");
1477     precache_model ("models/sprites/2.spr32");
1478     precache_model ("models/sprites/3.spr32");
1479     precache_model ("models/sprites/4.spr32");
1480     precache_model ("models/sprites/5.spr32");
1481     precache_model ("models/sprites/6.spr32");
1482     precache_model ("models/sprites/7.spr32");
1483     precache_model ("models/sprites/8.spr32");
1484     precache_model ("models/sprites/9.spr32");
1485     precache_model ("models/sprites/10.spr32");
1486
1487     // common weapon precaches
1488         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1489     precache_sound ("weapons/weapon_switch.wav");
1490     precache_sound ("weapons/weaponpickup.wav");
1491     precache_sound ("weapons/unavailable.wav");
1492     precache_sound ("weapons/dryfire.wav");
1493     if (g_grappling_hook)
1494     {
1495         precache_sound ("weapons/hook_fire.wav"); // hook
1496         precache_sound ("weapons/hook_impact.wav"); // hook
1497     }
1498
1499     if(autocvar_sv_precacheweapons)
1500     {
1501         //precache weapon models/sounds
1502         float wep;
1503         wep = WEP_FIRST;
1504         while (wep <= WEP_LAST)
1505         {
1506             weapon_action(wep, WR_PRECACHE);
1507             wep = wep + 1;
1508         }
1509     }
1510
1511     precache_model("models/elaser.mdl");
1512     precache_model("models/laser.mdl");
1513     precache_model("models/ebomb.mdl");
1514
1515 #if 0
1516     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1517
1518     if (!self.noise && self.music) // quake 3 uses the music field
1519         self.noise = self.music;
1520
1521     // plays music for the level if there is any
1522     if (self.noise)
1523     {
1524         precache_sound (self.noise);
1525         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1526     }
1527 #endif
1528 }
1529
1530 // WARNING: this kills the trace globals
1531 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1532 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1533
1534 #define INITPRIO_FIRST              0
1535 #define INITPRIO_GAMETYPE           0
1536 #define INITPRIO_GAMETYPE_FALLBACK  1
1537 #define INITPRIO_FINDTARGET        10
1538 #define INITPRIO_DROPTOFLOOR       20
1539 #define INITPRIO_SETLOCATION       90
1540 #define INITPRIO_LINKDOORS         91
1541 #define INITPRIO_LAST              99
1542
1543 .void(void) initialize_entity;
1544 .float initialize_entity_order;
1545 .entity initialize_entity_next;
1546 entity initialize_entity_first;
1547
1548 void make_safe_for_remove(entity e)
1549 {
1550     if (e.initialize_entity)
1551     {
1552         entity ent, prev = world;
1553         for (ent = initialize_entity_first; ent; )
1554         {
1555             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1556             {
1557                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1558                 // skip it in linked list
1559                 if (prev)
1560                 {
1561                     prev.initialize_entity_next = ent.initialize_entity_next;
1562                     ent = prev.initialize_entity_next;
1563                 }
1564                 else
1565                 {
1566                     initialize_entity_first = ent.initialize_entity_next;
1567                     ent = initialize_entity_first;
1568                 }
1569             }
1570             else
1571             {
1572                 prev = ent;
1573                 ent = ent.initialize_entity_next;
1574             }
1575         }
1576     }
1577 }
1578
1579 void objerror(string s)
1580 {
1581     make_safe_for_remove(self);
1582     builtin_objerror(s);
1583 }
1584
1585 .float remove_except_protected_forbidden;
1586 void remove_except_protected(entity e)
1587 {
1588         if(e.remove_except_protected_forbidden)
1589                 error("not allowed to remove this at this point");
1590         builtin_remove(e);
1591 }
1592
1593 void remove_unsafely(entity e)
1594 {
1595     if(e.classname == "spike")
1596         error("Removing spikes is forbidden (crylink bug), please report");
1597     builtin_remove(e);
1598 }
1599
1600 void remove_safely(entity e)
1601 {
1602     make_safe_for_remove(e);
1603     builtin_remove(e);
1604 }
1605
1606 void InitializeEntity(entity e, void(void) func, float order)
1607 {
1608     entity prev, cur;
1609
1610     if (!e || e.initialize_entity)
1611     {
1612         // make a proxy initializer entity
1613         entity e_old;
1614         e_old = e;
1615         e = spawn();
1616         e.classname = "initialize_entity";
1617         e.enemy = e_old;
1618     }
1619
1620     e.initialize_entity = func;
1621     e.initialize_entity_order = order;
1622
1623     cur = initialize_entity_first;
1624     prev = world;
1625     for (;;)
1626     {
1627         if (!cur || cur.initialize_entity_order > order)
1628         {
1629             // insert between prev and cur
1630             if (prev)
1631                 prev.initialize_entity_next = e;
1632             else
1633                 initialize_entity_first = e;
1634             e.initialize_entity_next = cur;
1635             return;
1636         }
1637         prev = cur;
1638         cur = cur.initialize_entity_next;
1639     }
1640 }
1641 void InitializeEntitiesRun()
1642 {
1643     entity startoflist;
1644     startoflist = initialize_entity_first;
1645     initialize_entity_first = world;
1646     remove = remove_except_protected;
1647     for (self = startoflist; self; self = self.initialize_entity_next)
1648     {
1649         self.remove_except_protected_forbidden = 1;
1650     }
1651     for (self = startoflist; self; )
1652     {
1653         entity e;
1654         var void(void) func;
1655         e = self.initialize_entity_next;
1656         func = self.initialize_entity;
1657         self.initialize_entity_order = 0;
1658         self.initialize_entity = func_null;
1659         self.initialize_entity_next = world;
1660         self.remove_except_protected_forbidden = 0;
1661         if (self.classname == "initialize_entity")
1662         {
1663             entity e_old;
1664             e_old = self.enemy;
1665             builtin_remove(self);
1666             self = e_old;
1667         }
1668         //dprint("Delayed initialization: ", self.classname, "\n");
1669         if(func)
1670             func();
1671         else
1672         {
1673             eprint(self);
1674             backtrace(strcat("Null function in: ", self.classname, "\n"));
1675         }
1676         self = e;
1677     }
1678     remove = remove_unsafely;
1679 }
1680
1681 .float uncustomizeentityforclient_set;
1682 .void(void) uncustomizeentityforclient;
1683 void UncustomizeEntitiesRun()
1684 {
1685     entity oldself;
1686     oldself = self;
1687     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1688         self.uncustomizeentityforclient();
1689     self = oldself;
1690 }
1691 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1692 {
1693     e.customizeentityforclient = customizer;
1694     e.uncustomizeentityforclient = uncustomizer;
1695     e.uncustomizeentityforclient_set = !!uncustomizer;
1696 }
1697
1698 .float nottargeted;
1699 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1700
1701 void() SUB_Remove;
1702 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1703 {
1704     vector mi, ma;
1705
1706     if (e.classname == "")
1707         e.classname = "net_linked";
1708
1709     if (e.model == "" || self.modelindex == 0)
1710     {
1711         mi = e.mins;
1712         ma = e.maxs;
1713         setmodel(e, "null");
1714         setsize(e, mi, ma);
1715     }
1716
1717     e.SendEntity = sendfunc;
1718     e.SendFlags = 0xFFFFFF;
1719
1720     if (!docull)
1721         e.effects |= EF_NODEPTHTEST;
1722
1723     if (dt)
1724     {
1725         e.nextthink = time + dt;
1726         e.think = SUB_Remove;
1727     }
1728 }
1729
1730 void adaptor_think2touch()
1731 {
1732     entity o;
1733     o = other;
1734     other = world;
1735     self.touch();
1736     other = o;
1737 }
1738
1739 void adaptor_think2use()
1740 {
1741     entity o, a;
1742     o = other;
1743     a = activator;
1744     activator = world;
1745     other = world;
1746     self.use();
1747     other = o;
1748     activator = a;
1749 }
1750
1751 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1752 {
1753         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1754                 self.projectiledeathtype |= HITTYPE_SPLASH;
1755         adaptor_think2use();
1756 }
1757
1758 // deferred dropping
1759 void DropToFloor_Handler()
1760 {
1761     builtin_droptofloor();
1762     self.dropped_origin = self.origin;
1763 }
1764
1765 void droptofloor()
1766 {
1767     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1768 }
1769
1770
1771
1772 float trace_hits_box_a0, trace_hits_box_a1;
1773
1774 float trace_hits_box_1d(float end, float thmi, float thma)
1775 {
1776     if (end == 0)
1777     {
1778         // just check if x is in range
1779         if (0 < thmi)
1780             return FALSE;
1781         if (0 > thma)
1782             return FALSE;
1783     }
1784     else
1785     {
1786         // do the trace with respect to x
1787         // 0 -> end has to stay in thmi -> thma
1788         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1789         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1790         if (trace_hits_box_a0 > trace_hits_box_a1)
1791             return FALSE;
1792     }
1793     return TRUE;
1794 }
1795
1796 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1797 {
1798     end -= start;
1799     thmi -= start;
1800     thma -= start;
1801     // now it is a trace from 0 to end
1802
1803     trace_hits_box_a0 = 0;
1804     trace_hits_box_a1 = 1;
1805
1806     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1807         return FALSE;
1808     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1809         return FALSE;
1810     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1811         return FALSE;
1812
1813     return TRUE;
1814 }
1815
1816 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1817 {
1818     return trace_hits_box(start, end, thmi - ma, thma - mi);
1819 }
1820
1821 float SUB_NoImpactCheck()
1822 {
1823         // zero hitcontents = this is not the real impact, but either the
1824         // mirror-impact of something hitting the projectile instead of the
1825         // projectile hitting the something, or a touchareagrid one. Neither of
1826         // these stop the projectile from moving, so...
1827         if(trace_dphitcontents == 0)
1828         {
1829                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1830                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1831                 checkclient();
1832         }
1833     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1834         return 1;
1835     if (other == world && self.size != '0 0 0')
1836     {
1837         vector tic;
1838         tic = self.velocity * sys_frametime;
1839         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1840         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1841         if (trace_fraction >= 1)
1842         {
1843             dprint("Odd... did not hit...?\n");
1844         }
1845         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1846         {
1847             dprint("Detected and prevented the sky-grapple bug.\n");
1848             return 1;
1849         }
1850     }
1851
1852     return 0;
1853 }
1854
1855 #define SUB_OwnerCheck() (other && (other == self.owner))
1856
1857 void RemoveGrapplingHook(entity pl);
1858 void W_Crylink_Dequeue(entity e);
1859 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1860 {
1861         if(SUB_OwnerCheck())
1862                 return TRUE;
1863         if(SUB_NoImpactCheck())
1864         {
1865                 if(self.classname == "grapplinghook")
1866                         RemoveGrapplingHook(self.realowner);
1867                 else if(self.classname == "spike")
1868                 {
1869                         W_Crylink_Dequeue(self);
1870                         remove(self);
1871                 }
1872                 else
1873                         remove(self);
1874                 return TRUE;
1875         }
1876         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1877                 UpdateCSQCProjectile(self);
1878         return FALSE;
1879 }
1880 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1881
1882 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1883 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1884
1885 void URI_Get_Callback(float id, float status, string data)
1886 {
1887         if(url_URI_Get_Callback(id, status, data))
1888         {
1889                 // handled
1890         }
1891         else if (id == URI_GET_DISCARD)
1892         {
1893                 // discard
1894         }
1895         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1896         {
1897                 // sv_cmd curl
1898                 Curl_URI_Get_Callback(id, status, data);
1899         }
1900         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1901         {
1902                 // online ban list
1903                 OnlineBanList_URI_Get_Callback(id, status, data);
1904         }
1905         else
1906         {
1907                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1908         }
1909 }
1910
1911 string uid2name(string myuid) {
1912         string s;
1913         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1914
1915         // FIXME remove this later after 0.6 release
1916         // convert old style broken records to correct style
1917         if(s == "")
1918         {
1919                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1920                 if(s != "")
1921                 {
1922                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1923                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1924                 }
1925         }
1926
1927         if(s == "")
1928                 s = "^1Unregistered Player";
1929         return s;
1930 }
1931
1932 float race_readTime(string map, float pos)
1933 {
1934         string rr;
1935         if(g_cts)
1936                 rr = CTS_RECORD;
1937         else
1938                 rr = RACE_RECORD;
1939
1940         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1941 }
1942
1943 string race_readUID(string map, float pos)
1944 {
1945         string rr;
1946         if(g_cts)
1947                 rr = CTS_RECORD;
1948         else
1949                 rr = RACE_RECORD;
1950
1951         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1952 }
1953
1954 float race_readPos(string map, float t) {
1955         float i;
1956         for (i = 1; i <= RANKINGS_CNT; ++i)
1957                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1958                         return i;
1959
1960         return 0; // pos is zero if unranked
1961 }
1962
1963 void race_writeTime(string map, float t, string myuid)
1964 {
1965         string rr;
1966         if(g_cts)
1967                 rr = CTS_RECORD;
1968         else
1969                 rr = RACE_RECORD;
1970
1971         float newpos;
1972         newpos = race_readPos(map, t);
1973
1974         float i, prevpos = 0;
1975         for(i = 1; i <= RANKINGS_CNT; ++i)
1976         {
1977                 if(race_readUID(map, i) == myuid)
1978                         prevpos = i;
1979         }
1980         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1981                 for (i = prevpos; i > newpos; --i) {
1982                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1983                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1984                 }
1985         } else { // player has no ranked record yet
1986                 for (i = RANKINGS_CNT; i > newpos; --i) {
1987                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1988                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1989                 }
1990         }
1991
1992         // store new time itself
1993         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1994         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1995 }
1996
1997 string race_readName(string map, float pos)
1998 {
1999         string rr;
2000         if(g_cts)
2001                 rr = CTS_RECORD;
2002         else
2003                 rr = RACE_RECORD;
2004
2005         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2006 }
2007
2008 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2009 {
2010     float m, i;
2011     vector start, org, delta, end, enddown, mstart;
2012     entity sp;
2013
2014     m = e.dphitcontentsmask;
2015     e.dphitcontentsmask = goodcontents | badcontents;
2016
2017     org = world.mins;
2018     delta = world.maxs - world.mins;
2019
2020     start = end = org;
2021
2022     for (i = 0; i < attempts; ++i)
2023     {
2024         start_x = org_x + random() * delta_x;
2025         start_y = org_y + random() * delta_y;
2026         start_z = org_z + random() * delta_z;
2027
2028         // rule 1: start inside world bounds, and outside
2029         // solid, and don't start from somewhere where you can
2030         // fall down to evil
2031         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2032         if (trace_fraction >= 1)
2033             continue;
2034         if (trace_startsolid)
2035             continue;
2036         if (trace_dphitcontents & badcontents)
2037             continue;
2038         if (trace_dphitq3surfaceflags & badsurfaceflags)
2039             continue;
2040
2041         // rule 2: if we are too high, lower the point
2042         if (trace_fraction * delta_z > maxaboveground)
2043             start = trace_endpos + '0 0 1' * maxaboveground;
2044         enddown = trace_endpos;
2045
2046         // rule 3: make sure we aren't outside the map. This only works
2047         // for somewhat well formed maps. A good rule of thumb is that
2048         // the map should have a convex outside hull.
2049         // these can be traceLINES as we already verified the starting box
2050         mstart = start + 0.5 * (e.mins + e.maxs);
2051         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2052         if (trace_fraction >= 1)
2053             continue;
2054         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2055         if (trace_fraction >= 1)
2056             continue;
2057         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2058         if (trace_fraction >= 1)
2059             continue;
2060         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2061         if (trace_fraction >= 1)
2062             continue;
2063         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2064         if (trace_fraction >= 1)
2065             continue;
2066
2067         // rule 4: we must "see" some spawnpoint
2068         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2069                 if(checkpvs(mstart, sp))
2070                         break;
2071         if(!sp)
2072         {
2073                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2074                         if(checkpvs(mstart, sp))
2075                                 break;
2076                 if(!sp)
2077                         continue;
2078         }
2079
2080         // find a random vector to "look at"
2081         end_x = org_x + random() * delta_x;
2082         end_y = org_y + random() * delta_y;
2083         end_z = org_z + random() * delta_z;
2084         end = start + normalize(end - start) * vlen(delta);
2085
2086         // rule 4: start TO end must not be too short
2087         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2088         if (trace_startsolid)
2089             continue;
2090         if (trace_fraction < minviewdistance / vlen(delta))
2091             continue;
2092
2093         // rule 5: don't want to look at sky
2094         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2095             continue;
2096
2097         // rule 6: we must not end up in trigger_hurt
2098         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2099             continue;
2100
2101         break;
2102     }
2103
2104     e.dphitcontentsmask = m;
2105
2106     if (i < attempts)
2107     {
2108         setorigin(e, start);
2109         e.angles = vectoangles(end - start);
2110         dprint("Needed ", ftos(i + 1), " attempts\n");
2111         return TRUE;
2112     }
2113     else
2114         return FALSE;
2115 }
2116
2117 float zcurveparticles_effectno;
2118 vector zcurveparticles_start;
2119 float zcurveparticles_spd;
2120
2121 void endzcurveparticles()
2122 {
2123         if(zcurveparticles_effectno)
2124         {
2125                 // terminator
2126                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2127         }
2128         zcurveparticles_effectno = 0;
2129 }
2130
2131 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2132 {
2133         spd = bound(0, floor(spd / 16), 32767);
2134         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2135         {
2136                 endzcurveparticles();
2137                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2138                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2139                 WriteShort(MSG_BROADCAST, effectno);
2140                 WriteCoord(MSG_BROADCAST, start_x);
2141                 WriteCoord(MSG_BROADCAST, start_y);
2142                 WriteCoord(MSG_BROADCAST, start_z);
2143                 zcurveparticles_effectno = effectno;
2144                 zcurveparticles_start = start;
2145         }
2146         else
2147                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2148         WriteCoord(MSG_BROADCAST, end_x);
2149         WriteCoord(MSG_BROADCAST, end_y);
2150         WriteCoord(MSG_BROADCAST, end_z);
2151         WriteCoord(MSG_BROADCAST, end_dz);
2152         zcurveparticles_spd = spd;
2153 }
2154
2155 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2156 {
2157         float end_dz;
2158         vector vecxy, velxy;
2159
2160         vecxy = end - start;
2161         vecxy_z = 0;
2162         velxy = vel;
2163         velxy_z = 0;
2164
2165         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2166         {
2167                 endzcurveparticles();
2168                 trailparticles(world, effectno, start, end);
2169                 return;
2170         }
2171
2172         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2173         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2174 }
2175
2176 void write_recordmarker(entity pl, float tstart, float dt)
2177 {
2178     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2179
2180     // also write a marker into demo files for demotc-race-record-extractor to find
2181     stuffcmd(pl,
2182              strcat(
2183                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2184                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2185 }
2186
2187 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2188 {
2189         switch(algn)
2190         {
2191                 default:
2192                 case 3: // right
2193                         break;
2194
2195                 case 4: // left
2196                         vecs_y = -vecs_y;
2197                         break;
2198
2199                 case 1:
2200                         if(allowcenter) // 2: allow center handedness
2201                         {
2202                                 // center
2203                                 vecs_y = 0;
2204                                 vecs_z -= 2;
2205                         }
2206                         else
2207                         {
2208                                 // right
2209                         }
2210                         break;
2211
2212                 case 2:
2213                         if(allowcenter) // 2: allow center handedness
2214                         {
2215                                 // center
2216                                 vecs_y = 0;
2217                                 vecs_z -= 2;
2218                         }
2219                         else
2220                         {
2221                                 // left
2222                                 vecs_y = -vecs_y;
2223                         }
2224                         break;
2225         }
2226         return vecs;
2227 }
2228
2229 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2230 {
2231         string s;
2232         vector v;
2233
2234         if (autocvar_g_shootfromeye)
2235         {
2236                 if (visual)
2237                 {
2238                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2239                         else { vecs_y = 0; vecs_z -= 2; }
2240                 }
2241                 else
2242                 {
2243                         vecs_y = 0;
2244                         vecs_z = 0;
2245                 }
2246         }
2247         else if (autocvar_g_shootfromcenter)
2248         {
2249                 vecs_y = 0;
2250                 vecs_z -= 2;
2251         }
2252         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2253         {
2254                 v = stov(s);
2255                 if (y_is_right)
2256                         v_y = -v_y;
2257                 if (v_x != 0)
2258                         vecs_x = v_x;
2259                 vecs_y = v_y;
2260                 vecs_z = v_z;
2261         }
2262         else if (autocvar_g_shootfromclient)
2263         {
2264                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2265         }
2266         return vecs;
2267 }
2268
2269 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2270 {
2271         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2272 }
2273
2274
2275 void attach_sameorigin(entity e, entity to, string tag)
2276 {
2277     vector org, t_forward, t_left, t_up, e_forward, e_up;
2278     float tagscale;
2279
2280     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2281     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2282     t_forward = v_forward * tagscale;
2283     t_left = v_right * -tagscale;
2284     t_up = v_up * tagscale;
2285
2286     e.origin_x = org * t_forward;
2287     e.origin_y = org * t_left;
2288     e.origin_z = org * t_up;
2289
2290     // current forward and up directions
2291     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2292                 e.angles = AnglesTransform_FromVAngles(e.angles);
2293         else
2294                 e.angles = AnglesTransform_FromAngles(e.angles);
2295     fixedmakevectors(e.angles);
2296
2297     // untransform forward, up!
2298     e_forward_x = v_forward * t_forward;
2299     e_forward_y = v_forward * t_left;
2300     e_forward_z = v_forward * t_up;
2301     e_up_x = v_up * t_forward;
2302     e_up_y = v_up * t_left;
2303     e_up_z = v_up * t_up;
2304
2305     e.angles = fixedvectoangles2(e_forward, e_up);
2306     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2307                 e.angles = AnglesTransform_ToVAngles(e.angles);
2308         else
2309                 e.angles = AnglesTransform_ToAngles(e.angles);
2310
2311     setattachment(e, to, tag);
2312     setorigin(e, e.origin);
2313 }
2314
2315 void detach_sameorigin(entity e)
2316 {
2317     vector org;
2318     org = gettaginfo(e, 0);
2319     e.angles = fixedvectoangles2(v_forward, v_up);
2320     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2321                 e.angles = AnglesTransform_ToVAngles(e.angles);
2322         else
2323                 e.angles = AnglesTransform_ToAngles(e.angles);
2324     setorigin(e, org);
2325     setattachment(e, world, "");
2326     setorigin(e, e.origin);
2327 }
2328
2329 void follow_sameorigin(entity e, entity to)
2330 {
2331     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2332     e.aiment = to; // make the hole follow bmodel
2333     e.punchangle = to.angles; // the original angles of bmodel
2334     e.view_ofs = e.origin - to.origin; // relative origin
2335     e.v_angle = e.angles - to.angles; // relative angles
2336 }
2337
2338 void unfollow_sameorigin(entity e)
2339 {
2340     e.movetype = MOVETYPE_NONE;
2341 }
2342
2343 entity gettaginfo_relative_ent;
2344 vector gettaginfo_relative(entity e, float tag)
2345 {
2346     if (!gettaginfo_relative_ent)
2347     {
2348         gettaginfo_relative_ent = spawn();
2349         gettaginfo_relative_ent.effects = EF_NODRAW;
2350     }
2351     gettaginfo_relative_ent.model = e.model;
2352     gettaginfo_relative_ent.modelindex = e.modelindex;
2353     gettaginfo_relative_ent.frame = e.frame;
2354     return gettaginfo(gettaginfo_relative_ent, tag);
2355 }
2356
2357 .float scale2;
2358
2359 float modeleffect_SendEntity(entity to, float sf)
2360 {
2361         float f;
2362         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2363
2364         f = 0;
2365         if(self.velocity != '0 0 0')
2366                 f |= 1;
2367         if(self.angles != '0 0 0')
2368                 f |= 2;
2369         if(self.avelocity != '0 0 0')
2370                 f |= 4;
2371
2372         WriteByte(MSG_ENTITY, f);
2373         WriteShort(MSG_ENTITY, self.modelindex);
2374         WriteByte(MSG_ENTITY, self.skin);
2375         WriteByte(MSG_ENTITY, self.frame);
2376         WriteCoord(MSG_ENTITY, self.origin_x);
2377         WriteCoord(MSG_ENTITY, self.origin_y);
2378         WriteCoord(MSG_ENTITY, self.origin_z);
2379         if(f & 1)
2380         {
2381                 WriteCoord(MSG_ENTITY, self.velocity_x);
2382                 WriteCoord(MSG_ENTITY, self.velocity_y);
2383                 WriteCoord(MSG_ENTITY, self.velocity_z);
2384         }
2385         if(f & 2)
2386         {
2387                 WriteCoord(MSG_ENTITY, self.angles_x);
2388                 WriteCoord(MSG_ENTITY, self.angles_y);
2389                 WriteCoord(MSG_ENTITY, self.angles_z);
2390         }
2391         if(f & 4)
2392         {
2393                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2394                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2395                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2396         }
2397         WriteShort(MSG_ENTITY, self.scale * 256.0);
2398         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2399         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2400         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2401         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2402
2403         return TRUE;
2404 }
2405
2406 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2407 {
2408         entity e;
2409         float sz;
2410         e = spawn();
2411         e.classname = "modeleffect";
2412         setmodel(e, m);
2413         e.frame = f;
2414         setorigin(e, o);
2415         e.velocity = v;
2416         e.angles = ang;
2417         e.avelocity = angv;
2418         e.alpha = a;
2419         e.teleport_time = t1;
2420         e.fade_time = t2;
2421         e.skin = s;
2422         if(s0 >= 0)
2423                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2424         else
2425                 e.scale = -s0;
2426         if(s2 >= 0)
2427                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2428         else
2429                 e.scale2 = -s2;
2430         sz = max(e.scale, e.scale2);
2431         setsize(e, e.mins * sz, e.maxs * sz);
2432         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2433 }
2434
2435 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2436 {
2437         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2438 }
2439
2440 float randombit(float bits)
2441 {
2442         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2443                 return bits;
2444
2445         float n, f, b, r;
2446
2447         r = random();
2448         b = 0;
2449         n = 0;
2450
2451         for(f = 1; f <= bits; f *= 2)
2452         {
2453                 if(bits & f)
2454                 {
2455                         ++n;
2456                         r *= n;
2457                         if(r <= 1)
2458                                 b = f;
2459                         else
2460                                 r = (r - 1) / (n - 1);
2461                 }
2462         }
2463
2464         return b;
2465 }
2466
2467 float randombits(float bits, float k, float error_return)
2468 {
2469         float r;
2470         r = 0;
2471         while(k > 0 && bits != r)
2472         {
2473                 r += randombit(bits - r);
2474                 --k;
2475         }
2476         if(error_return)
2477                 if(k > 0)
2478                         return -1; // all
2479         return r;
2480 }
2481
2482 void randombit_test(float bits, float iter)
2483 {
2484         while(iter > 0)
2485         {
2486                 print(ftos(randombit(bits)), "\n");
2487                 --iter;
2488         }
2489 }
2490
2491 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2492 {
2493         if(halflifedist > 0)
2494                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2495         else if(halflifedist < 0)
2496                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2497         else
2498                 return 1;
2499 }
2500
2501
2502
2503
2504 #ifdef RELEASE
2505 #define cvar_string_normal builtin_cvar_string
2506 #define cvar_normal builtin_cvar
2507 #else
2508 string cvar_string_normal(string n)
2509 {
2510         if not(cvar_type(n) & 1)
2511                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2512         return builtin_cvar_string(n);
2513 }
2514
2515 float cvar_normal(string n)
2516 {
2517         return stof(cvar_string_normal(n));
2518 }
2519 #endif
2520 #define cvar_set_normal builtin_cvar_set
2521
2522 void defer_think()
2523 {
2524     entity oself;
2525
2526     oself           = self;
2527     self            = self.owner;
2528     oself.think     = SUB_Remove;
2529     oself.nextthink = time;
2530
2531     oself.use();
2532 }
2533
2534 /*
2535     Execute func() after time + fdelay.
2536     self when func is executed = self when defer is called
2537 */
2538 void defer(float fdelay, void() func)
2539 {
2540     entity e;
2541
2542     e           = spawn();
2543     e.owner     = self;
2544     e.use       = func;
2545     e.think     = defer_think;
2546     e.nextthink = time + fdelay;
2547 }
2548
2549 .string aiment_classname;
2550 .float aiment_deadflag;
2551 void SetMovetypeFollow(entity ent, entity e)
2552 {
2553         // FIXME this may not be warpzone aware
2554         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2555         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2556         ent.aiment = e; // make the hole follow bmodel
2557         ent.punchangle = e.angles; // the original angles of bmodel
2558         ent.view_ofs = ent.origin - e.origin; // relative origin
2559         ent.v_angle = ent.angles - e.angles; // relative angles
2560         ent.aiment_classname = strzone(e.classname);
2561         ent.aiment_deadflag = e.deadflag;
2562 }
2563 void UnsetMovetypeFollow(entity ent)
2564 {
2565         ent.movetype = MOVETYPE_FLY;
2566         PROJECTILE_MAKETRIGGER(ent);
2567         ent.aiment = world;
2568 }
2569 float LostMovetypeFollow(entity ent)
2570 {
2571 /*
2572         if(ent.movetype != MOVETYPE_FOLLOW)
2573                 if(ent.aiment)
2574                         error("???");
2575 */
2576         if(ent.aiment)
2577         {
2578                 if(ent.aiment.classname != ent.aiment_classname)
2579                         return 1;
2580                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2581                         return 1;
2582         }
2583         return 0;
2584 }
2585
2586 float isPushable(entity e)
2587 {
2588         if(e.iscreature)
2589                 return TRUE;
2590         if(e.pushable)
2591                 return TRUE;
2592         switch(e.classname)
2593         {
2594                 case "body":
2595                 case "droppedweapon":
2596                 case "keepawayball":
2597                 case "nexball_basketball":
2598                 case "nexball_football":
2599                         return TRUE;
2600                 case "bullet": // antilagged bullets can't hit this either
2601                         return FALSE;
2602         }
2603         if (e.projectiledeathtype)
2604                 return TRUE;
2605         return FALSE;
2606 }