qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "mapvoting.qh"
  11 #include "resources.qh"
  12 #include "items.qh"
  13 #include "player.qh"
  14 #include "weapons/accuracy.qh"
  15 #include "weapons/csqcprojectile.qh"
  16 #include "weapons/selection.qh"
  17 #include "../common/command/_mod.qh"
  18 #include "../common/constants.qh"
  19 #include <common/net_linked.qh>
  20 #include <common/weapons/weapon/crylink.qh>
  21 #include "../common/deathtypes/all.qh"
  22 #include "../common/mapinfo.qh"
  23 #include "../common/notifications/all.qh"
  24 #include "../common/playerstats.qh"
  25 #include "../common/teams.qh"
  26 #include "../common/mapobjects/subs.qh"
  27 #include "../common/util.qh"
  28 #include "../common/turrets/sv_turrets.qh"
  29 #include <common/weapons/_all.qh>
  30 #include "../common/vehicles/sv_vehicles.qh"
  31 #include "../common/vehicles/vehicle.qh"
  32 #include "../common/items/_mod.qh"
  33 #include "../common/state.qh"
  34 #include "../common/effects/qc/globalsound.qh"
  35 #include "../common/wepent.qh"
  36 #include <common/weapons/weapon.qh>
  37 #include "../lib/csqcmodel/sv_model.qh"
  38 #include "../lib/warpzone/anglestransform.qh"
  39 #include "../lib/warpzone/server.qh"
  40
  41 void crosshair_trace(entity pl)
  42 {
  43         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  44 }
  45
  46 void crosshair_trace_plusvisibletriggers(entity pl)
  47 {
  48         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  49 }
  50
  51 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  52 {
  53         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  54 }
  55
  56 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  57 {
  58         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  59         {
  60                 if(it.model != "")
  61                 {
  62                         it.solid = SOLID_BSP;
  63                         IL_PUSH(g_ctrace_changed, it);
  64                 }
  65         });
  66
  67         if (is_wz)
  68                 WarpZone_crosshair_trace(pl);
  69         else
  70                 crosshair_trace(pl);
  71
  72         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  73
  74         IL_CLEAR(g_ctrace_changed);
  75 }
  76
  77 void WarpZone_crosshair_trace(entity pl)
  78 {
  79         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  80 }
  81
  82 void dedicated_print(string input)
  83 {
  84         if (server_is_dedicated) print(input);
  85 }
  86
  87 string GameLog_ProcessIP(string s)
  88 {
  89         if(!autocvar_sv_eventlog_ipv6_delimiter)
  90                 return s;
  91         return strreplace(":", "_", s);
  92 }
  93
  94 void GameLogEcho(string s)
  95 {
  96     string fn;
  97     int matches;
  98
  99     if (autocvar_sv_eventlog_files)
 100     {
 101         if (!logfile_open)
 102         {
 103             logfile_open = true;
 104             matches = autocvar_sv_eventlog_files_counter + 1;
 105             cvar_set("sv_eventlog_files_counter", itos(matches));
 106             fn = ftos(matches);
 107             if (strlen(fn) < 8)
 108                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 109             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 110             logfile = fopen(fn, FILE_APPEND);
 111             fputs(logfile, ":logversion:3\n");
 112         }
 113         if (logfile >= 0)
 114         {
 115             if (autocvar_sv_eventlog_files_timestamps)
 116                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 117             else
 118                 fputs(logfile, strcat(s, "\n"));
 119         }
 120     }
 121     if (autocvar_sv_eventlog_console)
 122     {
 123         dedicated_print(strcat(s, "\n"));
 124     }
 125 }
 126
 127 void GameLogInit()
 128 {
 129     logfile_open = 0;
 130     // will be opened later
 131 }
 132
 133 void GameLogClose()
 134 {
 135     if (logfile_open && logfile >= 0)
 136     {
 137         fclose(logfile);
 138         logfile = -1;
 139     }
 140 }
 141
 142 entity findnearest(vector point, bool checkitems, vector axismod)
 143 {
 144     vector dist;
 145     int num_nearest = 0;
 146
 147     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 148     {
 149         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 150             dist = it.oldorigin;
 151         else
 152             dist = it.origin;
 153         dist = dist - point;
 154         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 155         float len = vlen2(dist);
 156
 157         int l;
 158         for (l = 0; l < num_nearest; ++l)
 159         {
 160             if (len < nearest_length[l])
 161                 break;
 162         }
 163
 164         // now i tells us where to insert at
 165         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 166         if (l < NUM_NEAREST_ENTITIES)
 167         {
 168             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 169             {
 170                 nearest_length[j + 1] = nearest_length[j];
 171                 nearest_entity[j + 1] = nearest_entity[j];
 172             }
 173             nearest_length[l] = len;
 174             nearest_entity[l] = it;
 175             if (num_nearest < NUM_NEAREST_ENTITIES)
 176                 num_nearest = num_nearest + 1;
 177         }
 178     });
 179
 180     // now use the first one from our list that we can see
 181     for (int j = 0; j < num_nearest; ++j)
 182     {
 183         traceline(point, nearest_entity[j].origin, true, NULL);
 184         if (trace_fraction == 1)
 185         {
 186             if (j != 0)
 187                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 188             return nearest_entity[j];
 189         }
 190     }
 191
 192     if (num_nearest == 0)
 193         return NULL;
 194
 195     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 196     /* DEBUGGING CODE:
 197     dprint("Candidates were: ");
 198     for(j = 0; j < num_nearest; ++j)
 199     {
 200         if(j != 0)
 201                 dprint(", ");
 202         dprint(nearest_entity[j].netname);
 203     }
 204     dprint("\n");
 205     */
 206
 207     return nearest_entity[0];
 208 }
 209
 210 string NearestLocation(vector p)
 211 {
 212     string ret = "somewhere";
 213     entity loc = findnearest(p, false, '1 1 1');
 214     if (loc)
 215         ret = loc.message;
 216     else
 217     {
 218         loc = findnearest(p, true, '1 1 4');
 219         if (loc)
 220             ret = loc.netname;
 221     }
 222     return ret;
 223 }
 224
 225 string PlayerHealth(entity this)
 226 {
 227         float myhealth = floor(GetResource(this, RES_HEALTH));
 228         if(myhealth == -666)
 229                 return "spectating";
 230         else if(myhealth == -2342 || (myhealth == 2342 && mapvote_initialized))
 231                 return "observing";
 232         else if(myhealth <= 0 || IS_DEAD(this))
 233                 return "dead";
 234         return ftos(myhealth);
 235 }
 236
 237 string WeaponNameFromWeaponentity(entity this, .entity weaponentity)
 238 {
 239         entity wepent = this.(weaponentity);
 240         if(!wepent)
 241                 return "none";
 242         else if(wepent.m_weapon != WEP_Null)
 243                 return wepent.m_weapon.m_name;
 244         else if(wepent.m_switchweapon != WEP_Null)
 245                 return wepent.m_switchweapon.m_name;
 246         return "none"; //Weapons_from(wepent.cnt).m_name;
 247 }
 248
 249 string formatmessage(entity this, string msg)
 250 {
 251         float p, p1, p2;
 252         float n;
 253         vector cursor = '0 0 0';
 254         entity cursor_ent = NULL;
 255         string escape;
 256         string replacement;
 257         p = 0;
 258         n = 7;
 259         bool traced = false;
 260
 261         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 262         msg = M_ARGV(1, string);
 263
 264         while (1) {
 265                 if (n < 1)
 266                         break; // too many replacements
 267
 268                 n = n - 1;
 269                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 270                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 271
 272                 if (p1 < 0)
 273                         p1 = p2;
 274
 275                 if (p2 < 0)
 276                         p2 = p1;
 277
 278                 p = min(p1, p2);
 279
 280                 if (p < 0)
 281                         break;
 282
 283                 if(!traced)
 284                 {
 285                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 286                         cursor = trace_endpos;
 287                         cursor_ent = trace_ent;
 288                         traced = true;
 289                 }
 290
 291                 replacement = substring(msg, p, 2);
 292                 escape = substring(msg, p + 1, 1);
 293
 294                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 295
 296                 switch(escape)
 297                 {
 298                         case "%": replacement = "%"; break;
 299                         case "\\":replacement = "\\"; break;
 300                         case "n": replacement = "\n"; break;
 301                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 302                         case "h": replacement = PlayerHealth(this); break;
 303                         case "l": replacement = NearestLocation(this.origin); break;
 304                         case "y": replacement = NearestLocation(cursor); break;
 305                         case "d": replacement = NearestLocation(this.death_origin); break;
 306                         case "w": replacement = WeaponNameFromWeaponentity(this, weaponentity); break;
 307                         case "W": replacement = GetAmmoName(this.(weaponentity).m_weapon.ammo_type); break;
 308                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 309                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 310                         case "S": replacement = ftos(vlen(this.velocity)); break;
 311                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 312                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 313                         default:
 314                         {
 315                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 316                                 replacement = M_ARGV(2, string);
 317                                 break;
 318                         }
 319                 }
 320
 321                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 322                 p = p + strlen(replacement);
 323         }
 324         return msg;
 325 }
 326
 327 /*
 328 =============
 329 GetCvars
 330 =============
 331 Called with:
 332   0:  sends the request
 333   >0: receives a cvar from name=argv(f) value=argv(f+1)
 334 */
 335 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 336 {
 337         if (f < 0)
 338         {
 339                 strfree(store.(field));
 340         }
 341         else if (f > 0)
 342         {
 343                 if (thisname == name)
 344                 {
 345                         strcpy(store.(field), argv(f + 1));
 346                 }
 347         }
 348         else
 349                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 350 }
 351 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 352 {
 353         GetCvars_handleString(this, store, thisname, f, field, name);
 354         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 355                 if (thisname == name)
 356                 {
 357                         string s = func(this, strcat1(store.(field)));
 358                         if (s != store.(field))
 359                         {
 360                                 strcpy(store.(field), s);
 361                         }
 362                 }
 363 }
 364 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 365 {
 366         if (f < 0)
 367         {
 368         }
 369         else if (f > 0)
 370         {
 371                 if (thisname == name)
 372                         store.(field) = stof(argv(f + 1));
 373         }
 374         else
 375                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 376 }
 377 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 378 {
 379         if (f < 0)
 380         {
 381         }
 382         else if (f > 0)
 383         {
 384                 if (thisname == name)
 385                 {
 386                         if (!store.(field))
 387                         {
 388                                 store.(field) = stof(argv(f + 1));
 389                                 if (!store.(field))
 390                                         store.(field) = -1;
 391                         }
 392                 }
 393         }
 394         else
 395         {
 396                 if (!store.(field))
 397                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 398         }
 399 }
 400 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 401 {
 402         string o = W_FixWeaponOrder_ForceComplete(wo);
 403         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 404         return o;
 405 }
 406
 407 REPLICATE(autoswitch, bool, "cl_autoswitch");
 408
 409 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 410
 411 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
 412
 413 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 414
 415 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 416
 417 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 418
 419 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 420
 421 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 422
 423 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 424
 425 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 426
 427 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 428
 429 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 430
 431 REPLICATE(cvar_cl_physics, string, "cl_physics");
 432
 433 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 434
 435 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 436
 437 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 438
 439 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 440
 441 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 442
 443 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 444
 445 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 446
 447 /**
 448  * @param f -1: cleanup, 0: request, 1: receive
 449  */
 450 void GetCvars(entity this, entity store, int f)
 451 {
 452         string s = string_null;
 453
 454         if (f == 0)
 455                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 456
 457         if (f > 0)
 458                 s = strcat1(argv(f));
 459
 460         get_cvars_f = f;
 461         get_cvars_s = s;
 462         MUTATOR_CALLHOOK(GetCvars);
 463
 464         Notification_GetCvars(this);
 465
 466         ReplicateVars(this, store, s, f);
 467
 468         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 469         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 470         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 471         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 472         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 473         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 474         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 475         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 476         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 477         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 478         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 479
 480         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 481
 482         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 483         if (f > 0)
 484         {
 485                 if (s == "cl_weaponpriority")
 486                 {
 487                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 488                         {
 489                                 .entity weaponentity = weaponentities[slot];
 490                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 491                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 492                         }
 493                 }
 494                 if (s == "cl_allow_uidtracking")
 495                         PlayerStats_GameReport_AddPlayer(this);
 496                 //if (s == "cl_gunalign")
 497                         //W_ResetGunAlign(this, store.cvar_cl_gunalign);
 498         }
 499 }
 500
 501 // decolorizes and team colors the player name when needed
 502 string playername(entity p, bool team_colorize)
 503 {
 504     string t;
 505     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 506     {
 507         t = Team_ColorCode(p.team);
 508         return strcat(t, strdecolorize(p.netname));
 509     }
 510     else
 511         return p.netname;
 512 }
 513
 514 float want_weapon(entity weaponinfo, float allguns)
 515 {
 516         int d = 0;
 517         bool allow_mutatorblocked = false;
 518
 519         if(!weaponinfo.m_id)
 520                 return 0;
 521
 522         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 523         d = M_ARGV(1, float);
 524         allguns = M_ARGV(2, bool);
 525         allow_mutatorblocked = M_ARGV(3, bool);
 526
 527         if(allguns)
 528                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
 529         else if(!mutator_returnvalue)
 530                 d = !(!weaponinfo.weaponstart);
 531
 532         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 533                 d = 0;
 534
 535         float t = weaponinfo.weaponstartoverride;
 536
 537         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 538
 539         // bit order in t:
 540         // 1: want or not
 541         // 2: is default?
 542         // 4: is set by default?
 543         if(t < 0)
 544                 t = 4 | (3 * d);
 545         else
 546                 t |= (2 * d);
 547
 548         return t;
 549 }
 550
 551 /// Weapons the player normally starts with outside weapon arena.
 552 WepSet weapons_start()
 553 {
 554         WepSet ret = '0 0 0';
 555         FOREACH(Weapons, it != WEP_Null, {
 556                 int w = want_weapon(it, false);
 557                 if (w & 1)
 558                         ret |= it.m_wepset;
 559         });
 560         return ret;
 561 }
 562
 563 WepSet weapons_all()
 564 {
 565         WepSet ret = '0 0 0';
 566         FOREACH(Weapons, it != WEP_Null, {
 567                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
 568                         ret |= it.m_wepset;
 569         });
 570         return ret;
 571 }
 572
 573 WepSet weapons_devall()
 574 {
 575         WepSet ret = '0 0 0';
 576         FOREACH(Weapons, it != WEP_Null,
 577         {
 578                 ret |= it.m_wepset;
 579         });
 580         return ret;
 581 }
 582
 583 WepSet weapons_most()
 584 {
 585         WepSet ret = '0 0 0';
 586         FOREACH(Weapons, it != WEP_Null, {
 587                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
 588                         ret |= it.m_wepset;
 589         });
 590         return ret;
 591 }
 592
 593 void weaponarena_available_all_update(entity this)
 594 {
 595         if (weaponsInMapAll)
 596         {
 597                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 598         }
 599         else
 600         {
 601                 // if no weapons are available on the map, just fall back to all weapons arena
 602                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 603         }
 604 }
 605
 606 void weaponarena_available_devall_update(entity this)
 607 {
 608         if (weaponsInMapAll)
 609         {
 610                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 611         }
 612         else
 613         {
 614                 // if no weapons are available on the map, just fall back to devall weapons arena
 615                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 616         }
 617 }
 618
 619 void weaponarena_available_most_update(entity this)
 620 {
 621         if (weaponsInMapAll)
 622         {
 623                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 624         }
 625         else
 626         {
 627                 // if no weapons are available on the map, just fall back to most weapons arena
 628                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 629         }
 630 }
 631
 632 void readplayerstartcvars()
 633 {
 634         // initialize starting values for players
 635         start_weapons = '0 0 0';
 636         start_weapons_default = '0 0 0';
 637         start_weapons_defaultmask = '0 0 0';
 638         start_items = 0;
 639         start_ammo_shells = 0;
 640         start_ammo_nails = 0;
 641         start_ammo_rockets = 0;
 642         start_ammo_cells = 0;
 643         start_ammo_plasma = 0;
 644         if (random_start_ammo == NULL)
 645         {
 646                 random_start_ammo = spawn();
 647         }
 648         start_health = cvar("g_balance_health_start");
 649         start_armorvalue = cvar("g_balance_armor_start");
 650
 651         g_weaponarena = 0;
 652         g_weaponarena_weapons = '0 0 0';
 653
 654         string s = cvar_string("g_weaponarena");
 655
 656         MUTATOR_CALLHOOK(SetWeaponArena, s);
 657         s = M_ARGV(0, string);
 658
 659         if (s == "0" || s == "")
 660         {
 661                 // no arena
 662         }
 663         else if (s == "off")
 664         {
 665                 // forcibly turn off weaponarena
 666         }
 667         else if (s == "all" || s == "1")
 668         {
 669                 g_weaponarena = 1;
 670                 g_weaponarena_list = "All Weapons";
 671                 g_weaponarena_weapons = weapons_all();
 672         }
 673         else if (s == "devall")
 674         {
 675                 g_weaponarena = 1;
 676                 g_weaponarena_list = "Dev All Weapons";
 677                 g_weaponarena_weapons = weapons_devall();
 678         }
 679         else if (s == "most")
 680         {
 681                 g_weaponarena = 1;
 682                 g_weaponarena_list = "Most Weapons";
 683                 g_weaponarena_weapons = weapons_most();
 684         }
 685         else if (s == "all_available")
 686         {
 687                 g_weaponarena = 1;
 688                 g_weaponarena_list = "All Available Weapons";
 689
 690                 // this needs to run after weaponsInMapAll is initialized
 691                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 692         }
 693         else if (s == "devall_available")
 694         {
 695                 g_weaponarena = 1;
 696                 g_weaponarena_list = "Dev All Available Weapons";
 697
 698                 // this needs to run after weaponsInMapAll is initialized
 699                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 700         }
 701         else if (s == "most_available")
 702         {
 703                 g_weaponarena = 1;
 704                 g_weaponarena_list = "Most Available Weapons";
 705
 706                 // this needs to run after weaponsInMapAll is initialized
 707                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 708         }
 709         else if (s == "none")
 710         {
 711                 g_weaponarena = 1;
 712                 g_weaponarena_list = "No Weapons";
 713         }
 714         else
 715         {
 716                 g_weaponarena = 1;
 717                 float t = tokenize_console(s);
 718                 g_weaponarena_list = "";
 719                 for (int j = 0; j < t; ++j)
 720                 {
 721                         s = argv(j);
 722                         Weapon wep = Weapons_fromstr(s);
 723                         if(wep != WEP_Null)
 724                         {
 725                                 g_weaponarena_weapons |= (wep.m_wepset);
 726                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 727                         }
 728                 }
 729                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 730         }
 731
 732         if (g_weaponarena)
 733         {
 734                 g_weapon_stay = 0; // incompatible
 735                 start_weapons = g_weaponarena_weapons;
 736                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
 737         }
 738         else
 739         {
 740                 FOREACH(Weapons, it != WEP_Null, {
 741                         int w = want_weapon(it, false);
 742                         WepSet s = it.m_wepset;
 743                         if(w & 1)
 744                                 start_weapons |= s;
 745                         if(w & 2)
 746                                 start_weapons_default |= s;
 747                         if(w & 4)
 748                                 start_weapons_defaultmask |= s;
 749                 });
 750         }
 751
 752         if(cvar("g_balance_superweapons_time") < 0)
 753                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 754
 755         if(!cvar("g_use_ammunition"))
 756                 start_items |= IT_UNLIMITED_AMMO;
 757
 758         if(start_items & IT_UNLIMITED_AMMO)
 759         {
 760                 start_ammo_shells = 999;
 761                 start_ammo_nails = 999;
 762                 start_ammo_rockets = 999;
 763                 start_ammo_cells = 999;
 764                 start_ammo_plasma = 999;
 765                 start_ammo_fuel = 999;
 766         }
 767         else
 768         {
 769                 start_ammo_shells = cvar("g_start_ammo_shells");
 770                 start_ammo_nails = cvar("g_start_ammo_nails");
 771                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 772                 start_ammo_cells = cvar("g_start_ammo_cells");
 773                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 774                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 775                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 776                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
 777                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
 778                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
 779                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
 780                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
 781         }
 782
 783         warmup_start_ammo_shells = start_ammo_shells;
 784         warmup_start_ammo_nails = start_ammo_nails;
 785         warmup_start_ammo_rockets = start_ammo_rockets;
 786         warmup_start_ammo_cells = start_ammo_cells;
 787         warmup_start_ammo_plasma = start_ammo_plasma;
 788         warmup_start_ammo_fuel = start_ammo_fuel;
 789         warmup_start_health = start_health;
 790         warmup_start_armorvalue = start_armorvalue;
 791         warmup_start_weapons = start_weapons;
 792         warmup_start_weapons_default = start_weapons_default;
 793         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 794
 795         if (!g_weaponarena)
 796         {
 797                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 798                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 799                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 800                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 801                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 802                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 803                 warmup_start_health = cvar("g_warmup_start_health");
 804                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
 805                 warmup_start_weapons = '0 0 0';
 806                 warmup_start_weapons_default = '0 0 0';
 807                 warmup_start_weapons_defaultmask = '0 0 0';
 808                 FOREACH(Weapons, it != WEP_Null, {
 809                         int w = want_weapon(it, g_warmup_allguns);
 810                         WepSet s = it.m_wepset;
 811                         if(w & 1)
 812                                 warmup_start_weapons |= s;
 813                         if(w & 2)
 814                                 warmup_start_weapons_default |= s;
 815                         if(w & 4)
 816                                 warmup_start_weapons_defaultmask |= s;
 817                 });
 818         }
 819
 820         if (g_jetpack)
 821                 start_items |= ITEM_Jetpack.m_itemid;
 822
 823         MUTATOR_CALLHOOK(SetStartItems);
 824
 825         if (start_items & ITEM_Jetpack.m_itemid)
 826         {
 827                 start_items |= ITEM_JetpackRegen.m_itemid;
 828                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 829                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 830         }
 831
 832         start_ammo_shells = max(0, start_ammo_shells);
 833         start_ammo_nails = max(0, start_ammo_nails);
 834         start_ammo_rockets = max(0, start_ammo_rockets);
 835         start_ammo_cells = max(0, start_ammo_cells);
 836         start_ammo_plasma = max(0, start_ammo_plasma);
 837         start_ammo_fuel = max(0, start_ammo_fuel);
 838         SetResource(random_start_ammo, RES_SHELLS,
 839                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
 840         SetResource(random_start_ammo, RES_BULLETS,
 841                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
 842         SetResource(random_start_ammo, RES_ROCKETS,
 843                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
 844         SetResource(random_start_ammo, RES_CELLS,
 845                 max(0, GetResource(random_start_ammo, RES_CELLS)));
 846         SetResource(random_start_ammo, RES_PLASMA,
 847                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
 848
 849         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 850         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 851         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 852         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 853         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 854         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 855 }
 856
 857 void precache_playermodel(string m)
 858 {
 859         float globhandle, i, n;
 860         string f;
 861
 862         if(substring(m, -9, 5) == "_lod1")
 863                 return;
 864         if(substring(m, -9, 5) == "_lod2")
 865                 return;
 866         precache_model(m);
 867         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 868         if(fexists(f))
 869                 precache_model(f);
 870         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 871         if(fexists(f))
 872                 precache_model(f);
 873
 874         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 875         if (globhandle < 0)
 876                 return;
 877         n = search_getsize(globhandle);
 878         for (i = 0; i < n; ++i)
 879         {
 880                 //print(search_getfilename(globhandle, i), "\n");
 881                 f = search_getfilename(globhandle, i);
 882                 PrecachePlayerSounds(f);
 883         }
 884         search_end(globhandle);
 885 }
 886 void precache_all_playermodels(string pattern)
 887 {
 888         int globhandle = search_begin(pattern, true, false);
 889         if (globhandle < 0) return;
 890         int n = search_getsize(globhandle);
 891         for (int i = 0; i < n; ++i)
 892         {
 893                 string s = search_getfilename(globhandle, i);
 894                 precache_playermodel(s);
 895         }
 896         search_end(globhandle);
 897 }
 898
 899 void precache_playermodels(string s)
 900 {
 901         FOREACH_WORD(s, true, { precache_playermodel(it); });
 902 }
 903
 904 PRECACHE(PlayerModels)
 905 {
 906     // Precache all player models if desired
 907     if (autocvar_sv_precacheplayermodels)
 908     {
 909         PrecachePlayerSounds("sound/player/default.sounds");
 910         precache_all_playermodels("models/player/*.zym");
 911         precache_all_playermodels("models/player/*.dpm");
 912         precache_all_playermodels("models/player/*.md3");
 913         precache_all_playermodels("models/player/*.psk");
 914         precache_all_playermodels("models/player/*.iqm");
 915     }
 916
 917     if (autocvar_sv_defaultcharacter)
 918     {
 919                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 920                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 921                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 922                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 923                 precache_playermodels(autocvar_sv_defaultplayermodel);
 924     }
 925 }
 926
 927
 928 void make_safe_for_remove(entity e)
 929 {
 930     if (e.initialize_entity)
 931     {
 932         entity ent, prev = NULL;
 933         for (ent = initialize_entity_first; ent; )
 934         {
 935             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 936             {
 937                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 938                 // skip it in linked list
 939                 if (prev)
 940                 {
 941                     prev.initialize_entity_next = ent.initialize_entity_next;
 942                     ent = prev.initialize_entity_next;
 943                 }
 944                 else
 945                 {
 946                     initialize_entity_first = ent.initialize_entity_next;
 947                     ent = initialize_entity_first;
 948                 }
 949             }
 950             else
 951             {
 952                 prev = ent;
 953                 ent = ent.initialize_entity_next;
 954             }
 955         }
 956     }
 957 }
 958
 959 .float remove_except_protected_forbidden;
 960 void remove_except_protected(entity e)
 961 {
 962         if(e.remove_except_protected_forbidden)
 963                 error("not allowed to remove this at this point");
 964         builtin_remove(e);
 965 }
 966
 967 void remove_unsafely(entity e)
 968 {
 969     if(e.classname == "spike")
 970         error("Removing spikes is forbidden (crylink bug), please report");
 971     builtin_remove(e);
 972 }
 973
 974 void remove_safely(entity e)
 975 {
 976     make_safe_for_remove(e);
 977     builtin_remove(e);
 978 }
 979
 980 void InitializeEntity(entity e, void(entity this) func, int order)
 981 {
 982     entity prev, cur;
 983
 984     if (!e || e.initialize_entity)
 985     {
 986         // make a proxy initializer entity
 987         entity e_old = e;
 988         e = new(initialize_entity);
 989         e.enemy = e_old;
 990     }
 991
 992     e.initialize_entity = func;
 993     e.initialize_entity_order = order;
 994
 995     cur = initialize_entity_first;
 996     prev = NULL;
 997     for (;;)
 998     {
 999         if (!cur || cur.initialize_entity_order > order)
1000         {
1001             // insert between prev and cur
1002             if (prev)
1003                 prev.initialize_entity_next = e;
1004             else
1005                 initialize_entity_first = e;
1006             e.initialize_entity_next = cur;
1007             return;
1008         }
1009         prev = cur;
1010         cur = cur.initialize_entity_next;
1011     }
1012 }
1013 void InitializeEntitiesRun()
1014 {
1015     entity startoflist = initialize_entity_first;
1016     initialize_entity_first = NULL;
1017     delete_fn = remove_except_protected;
1018     for (entity e = startoflist; e; e = e.initialize_entity_next)
1019     {
1020                 e.remove_except_protected_forbidden = 1;
1021     }
1022     for (entity e = startoflist; e; )
1023     {
1024                 e.remove_except_protected_forbidden = 0;
1025         e.initialize_entity_order = 0;
1026         entity next = e.initialize_entity_next;
1027         e.initialize_entity_next = NULL;
1028         var void(entity this) func = e.initialize_entity;
1029         e.initialize_entity = func_null;
1030         if (e.classname == "initialize_entity")
1031         {
1032             entity wrappee = e.enemy;
1033             builtin_remove(e);
1034             e = wrappee;
1035         }
1036         //dprint("Delayed initialization: ", e.classname, "\n");
1037         if (func)
1038         {
1039                 func(e);
1040         }
1041         else
1042         {
1043             eprint(e);
1044             backtrace(strcat("Null function in: ", e.classname, "\n"));
1045         }
1046         e = next;
1047     }
1048     delete_fn = remove_unsafely;
1049 }
1050
1051 .float(entity) isEliminated;
1052 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1053 {
1054         Stream out = MSG_ENTITY;
1055         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1056         serialize(byte, out, sendflags);
1057         if (sendflags & 1) {
1058                 for (int i = 1; i <= maxclients; i += 8) {
1059                         int f = 0;
1060                         entity e = edict_num(i);
1061                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1062                                 if (eliminatedPlayers.isEliminated(e)) {
1063                                         f |= BIT(b);
1064                                 }
1065                         }
1066                         serialize(byte, out, f);
1067                 }
1068         }
1069         return true;
1070 }
1071
1072 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1073 {
1074         if(eliminatedPlayers)
1075         {
1076                 backtrace("Can't spawn eliminatedPlayers again!");
1077                 return;
1078         }
1079         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1080         eliminatedPlayers.isEliminated = isEliminated_func;
1081 }
1082
1083
1084
1085
1086 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1087 {
1088         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1089                 this.projectiledeathtype |= HITTYPE_SPLASH;
1090         adaptor_think2use(this);
1091 }
1092
1093 // deferred dropping
1094 void DropToFloor_Handler(entity this)
1095 {
1096     WITHSELF(this, builtin_droptofloor());
1097     this.dropped_origin = this.origin;
1098 }
1099
1100 void droptofloor(entity this)
1101 {
1102     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1103 }
1104
1105
1106
1107 float trace_hits_box_a0, trace_hits_box_a1;
1108
1109 float trace_hits_box_1d(float end, float thmi, float thma)
1110 {
1111     if (end == 0)
1112     {
1113         // just check if x is in range
1114         if (0 < thmi)
1115             return false;
1116         if (0 > thma)
1117             return false;
1118     }
1119     else
1120     {
1121         // do the trace with respect to x
1122         // 0 -> end has to stay in thmi -> thma
1123         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1124         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1125         if (trace_hits_box_a0 > trace_hits_box_a1)
1126             return false;
1127     }
1128     return true;
1129 }
1130
1131 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1132 {
1133     end -= start;
1134     thmi -= start;
1135     thma -= start;
1136     // now it is a trace from 0 to end
1137
1138     trace_hits_box_a0 = 0;
1139     trace_hits_box_a1 = 1;
1140
1141     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1142         return false;
1143     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1144         return false;
1145     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1146         return false;
1147
1148     return true;
1149 }
1150
1151 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1152 {
1153     return trace_hits_box(start, end, thmi - ma, thma - mi);
1154 }
1155
1156 bool SUB_NoImpactCheck(entity this, entity toucher)
1157 {
1158         // zero hitcontents = this is not the real impact, but either the
1159         // mirror-impact of something hitting the projectile instead of the
1160         // projectile hitting the something, or a touchareagrid one. Neither of
1161         // these stop the projectile from moving, so...
1162         if(trace_dphitcontents == 0)
1163         {
1164                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1165                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1166         }
1167     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1168         return true;
1169     if (toucher == NULL && this.size != '0 0 0')
1170     {
1171         vector tic;
1172         tic = this.velocity * sys_frametime;
1173         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1174         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1175         if (trace_fraction >= 1)
1176         {
1177             LOG_TRACE("Odd... did not hit...?");
1178         }
1179         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1180         {
1181             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1182             return true;
1183         }
1184     }
1185
1186     return false;
1187 }
1188
1189 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1190 {
1191         // owner check
1192         if(toucher && toucher == this.owner)
1193                 return true;
1194         if(SUB_NoImpactCheck(this, toucher))
1195         {
1196                 if(this.classname == "nade")
1197                         return false; // no checks here
1198                 else if(this.classname == "grapplinghook")
1199                         RemoveHook(this);
1200                 else
1201                         delete(this);
1202                 return true;
1203         }
1204         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1205                 UpdateCSQCProjectile(this);
1206         return false;
1207 }
1208
1209 /** engine callback */
1210 void URI_Get_Callback(float id, float status, string data)
1211 {
1212         if(url_URI_Get_Callback(id, status, data))
1213         {
1214                 // handled
1215         }
1216         else if (id == URI_GET_DISCARD)
1217         {
1218                 // discard
1219         }
1220         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1221         {
1222                 // sv_cmd curl
1223                 Curl_URI_Get_Callback(id, status, data);
1224         }
1225         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1226         {
1227                 // online ban list
1228                 OnlineBanList_URI_Get_Callback(id, status, data);
1229         }
1230         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1231         {
1232                 // handled by a mutator
1233         }
1234         else
1235         {
1236                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1237         }
1238 }
1239
1240 string uid2name(string myuid)
1241 {
1242         string s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1243
1244         // FIXME remove this later after 0.6 release
1245         // convert old style broken records to correct style
1246         if(s == "")
1247         {
1248                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1249                 if(s != "")
1250                 {
1251                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1252                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1253                 }
1254         }
1255
1256         if(s == "")
1257                 s = "^1Unregistered Player";
1258         return s;
1259 }
1260
1261 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1262 {
1263     float m = e.dphitcontentsmask;
1264     e.dphitcontentsmask = goodcontents | badcontents;
1265
1266     vector org = boundmin;
1267     vector delta = boundmax - boundmin;
1268
1269     vector start, end;
1270     start = end = org;
1271     int j; // used after the loop
1272     for(j = 0; j < attempts; ++j)
1273     {
1274         start.x = org.x + random() * delta.x;
1275         start.y = org.y + random() * delta.y;
1276         start.z = org.z + random() * delta.z;
1277
1278         // rule 1: start inside world bounds, and outside
1279         // solid, and don't start from somewhere where you can
1280         // fall down to evil
1281         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1282         if (trace_fraction >= 1)
1283             continue;
1284         if (trace_startsolid)
1285             continue;
1286         if (trace_dphitcontents & badcontents)
1287             continue;
1288         if (trace_dphitq3surfaceflags & badsurfaceflags)
1289             continue;
1290
1291         // rule 2: if we are too high, lower the point
1292         if (trace_fraction * delta.z > maxaboveground)
1293             start = trace_endpos + '0 0 1' * maxaboveground;
1294         vector enddown = trace_endpos;
1295
1296         // rule 3: make sure we aren't outside the map. This only works
1297         // for somewhat well formed maps. A good rule of thumb is that
1298         // the map should have a convex outside hull.
1299         // these can be traceLINES as we already verified the starting box
1300         vector mstart = start + 0.5 * (e.mins + e.maxs);
1301         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1302         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1303             continue;
1304         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1305         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1306             continue;
1307         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1308         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1309             continue;
1310         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1311         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1312             continue;
1313         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1314         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1315             continue;
1316
1317                 // rule 4: we must "see" some spawnpoint or item
1318             entity sp = NULL;
1319             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1320             {
1321                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1322                 {
1323                         sp = it;
1324                         break;
1325                 }
1326             });
1327                 if(!sp)
1328                 {
1329                         int items_checked = 0;
1330                         IL_EACH(g_items, checkpvs(mstart, it),
1331                         {
1332                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1333                                 {
1334                                         sp = it;
1335                                         break;
1336                                 }
1337
1338                                 ++items_checked;
1339                                 if(items_checked >= attempts)
1340                                         break; // sanity
1341                         });
1342
1343                         if(!sp)
1344                                 continue;
1345                 }
1346
1347         // find a random vector to "look at"
1348         end.x = org.x + random() * delta.x;
1349         end.y = org.y + random() * delta.y;
1350         end.z = org.z + random() * delta.z;
1351         end = start + normalize(end - start) * vlen(delta);
1352
1353         // rule 4: start TO end must not be too short
1354         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1355         if(trace_startsolid)
1356             continue;
1357         if(trace_fraction < minviewdistance / vlen(delta))
1358             continue;
1359
1360         // rule 5: don't want to look at sky
1361         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1362             continue;
1363
1364         // rule 6: we must not end up in trigger_hurt
1365         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1366             continue;
1367
1368         break;
1369     }
1370
1371     e.dphitcontentsmask = m;
1372
1373     if(j < attempts)
1374     {
1375         setorigin(e, start);
1376         e.angles = vectoangles(end - start);
1377         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1378         return true;
1379     }
1380     return false;
1381 }
1382
1383 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1384 {
1385         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1386 }
1387
1388 void write_recordmarker(entity pl, float tstart, float dt)
1389 {
1390     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1391
1392     // also write a marker into demo files for demotc-race-record-extractor to find
1393     stuffcmd(pl,
1394              strcat(
1395                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1396                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1397 }
1398
1399 void attach_sameorigin(entity e, entity to, string tag)
1400 {
1401     vector org, t_forward, t_left, t_up, e_forward, e_up;
1402     float tagscale;
1403
1404     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1405     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1406     t_forward = v_forward * tagscale;
1407     t_left = v_right * -tagscale;
1408     t_up = v_up * tagscale;
1409
1410     e.origin_x = org * t_forward;
1411     e.origin_y = org * t_left;
1412     e.origin_z = org * t_up;
1413
1414     // current forward and up directions
1415     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1416                 e.angles = AnglesTransform_FromVAngles(e.angles);
1417         else
1418                 e.angles = AnglesTransform_FromAngles(e.angles);
1419     fixedmakevectors(e.angles);
1420
1421     // untransform forward, up!
1422     e_forward.x = v_forward * t_forward;
1423     e_forward.y = v_forward * t_left;
1424     e_forward.z = v_forward * t_up;
1425     e_up.x = v_up * t_forward;
1426     e_up.y = v_up * t_left;
1427     e_up.z = v_up * t_up;
1428
1429     e.angles = fixedvectoangles2(e_forward, e_up);
1430     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1431                 e.angles = AnglesTransform_ToVAngles(e.angles);
1432         else
1433                 e.angles = AnglesTransform_ToAngles(e.angles);
1434
1435     setattachment(e, to, tag);
1436     setorigin(e, e.origin);
1437 }
1438
1439 void detach_sameorigin(entity e)
1440 {
1441     vector org;
1442     org = gettaginfo(e, 0);
1443     e.angles = fixedvectoangles2(v_forward, v_up);
1444     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1445                 e.angles = AnglesTransform_ToVAngles(e.angles);
1446         else
1447                 e.angles = AnglesTransform_ToAngles(e.angles);
1448     setorigin(e, org);
1449     setattachment(e, NULL, "");
1450     setorigin(e, e.origin);
1451 }
1452
1453 void follow_sameorigin(entity e, entity to)
1454 {
1455     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1456     e.aiment = to; // make the hole follow bmodel
1457     e.punchangle = to.angles; // the original angles of bmodel
1458     e.view_ofs = e.origin - to.origin; // relative origin
1459     e.v_angle = e.angles - to.angles; // relative angles
1460 }
1461
1462 #if 0
1463 // TODO: unused, likely for a reason, possibly needs extensions (allow setting the new movetype as a parameter?)
1464 void unfollow_sameorigin(entity e)
1465 {
1466     set_movetype(e, MOVETYPE_NONE);
1467 }
1468 #endif
1469
1470 .string aiment_classname;
1471 .float aiment_deadflag;
1472 void SetMovetypeFollow(entity ent, entity e)
1473 {
1474         // FIXME this may not be warpzone aware
1475         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1476         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1477         ent.aiment = e; // make the hole follow bmodel
1478         ent.punchangle = e.angles; // the original angles of bmodel
1479         ent.view_ofs = ent.origin - e.origin; // relative origin
1480         ent.v_angle = ent.angles - e.angles; // relative angles
1481         ent.aiment_classname = strzone(e.classname);
1482         ent.aiment_deadflag = e.deadflag;
1483 }
1484 void UnsetMovetypeFollow(entity ent)
1485 {
1486         set_movetype(ent, MOVETYPE_FLY);
1487         PROJECTILE_MAKETRIGGER(ent);
1488         ent.aiment = NULL;
1489 }
1490 float LostMovetypeFollow(entity ent)
1491 {
1492 /*
1493         if(ent.move_movetype != MOVETYPE_FOLLOW)
1494                 if(ent.aiment)
1495                         error("???");
1496 */
1497         if(ent.aiment)
1498         {
1499                 if(ent.aiment.classname != ent.aiment_classname)
1500                         return 1;
1501                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1502                         return 1;
1503         }
1504         return 0;
1505 }
1506
1507 .bool pushable;
1508 bool isPushable(entity e)
1509 {
1510         if(e.pushable)
1511                 return true;
1512         if(IS_VEHICLE(e))
1513                 return false;
1514         if(e.iscreature)
1515                 return true;
1516         if (Item_IsLoot(e))
1517         {
1518                 return true;
1519         }
1520         switch(e.classname)
1521         {
1522                 case "body":
1523                         return true;
1524                 case "bullet": // antilagged bullets can't hit this either
1525                         return false;
1526         }
1527         if (e.projectiledeathtype)
1528                 return true;
1529         return false;
1530 }