qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 float spawnpoint_nag;
 159 void relocate_spawnpoint()
 160 {
 161     // nudge off the floor
 162     setorigin(self, self.origin + '0 0 1');
 163
 164     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 165     if (trace_startsolid)
 166     {
 167         vector o;
 168         o = self.origin;
 169         self.mins = PL_MIN;
 170         self.maxs = PL_MAX;
 171         if (!move_out_of_solid(self))
 172             objerror("could not get out of solid at all!");
 173         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 174         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 175         print(" ", ftos(self.origin_y - o_y));
 176         print(" ", ftos(self.origin_z - o_z), "'\n");
 177         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 178         {
 179             if (!spawnpoint_nag)
 180                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 181             spawnpoint_nag = 1;
 182         }
 183         else
 184         {
 185             setorigin(self, o);
 186             self.mins = self.maxs = '0 0 0';
 187             objerror("player spawn point in solid, mapper sucks!\n");
 188             return;
 189         }
 190     }
 191
 192     self.use = spawnpoint_use;
 193     self.team_saved = self.team;
 194     if (!self.cnt)
 195         self.cnt = 1;
 196
 197     if (have_team_spawns != 0)
 198         if (self.team)
 199             have_team_spawns = 1;
 200     have_team_spawns_forteam[self.team] = 1;
 201
 202     if (autocvar_r_showbboxes)
 203     {
 204         // show where spawnpoints point at too
 205         makevectors(self.angles);
 206         entity e;
 207         e = spawn();
 208         e.classname = "info_player_foo";
 209         setorigin(e, self.origin + v_forward * 24);
 210         setsize(e, '-8 -8 -8', '8 8 8');
 211         e.solid = SOLID_TRIGGER;
 212     }
 213 }
 214
 215 #define strstr strstrofs
 216 /*
 217 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 218 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 219 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 220 // BE CONSTANT OR strzoneD!
 221 float strstr(string haystack, string needle, float offset)
 222 {
 223         float len, endpos;
 224         string found;
 225         len = strlen(needle);
 226         endpos = strlen(haystack) - len;
 227         while(offset <= endpos)
 228         {
 229                 found = substring(haystack, offset, len);
 230                 if(found == needle)
 231                         return offset;
 232                 offset = offset + 1;
 233         }
 234         return -1;
 235 }
 236 */
 237
 238 float NUM_NEAREST_ENTITIES = 4;
 239 entity nearest_entity[NUM_NEAREST_ENTITIES];
 240 float nearest_length[NUM_NEAREST_ENTITIES];
 241 entity findnearest(vector point, .string field, string value, vector axismod)
 242 {
 243     entity localhead;
 244     float i;
 245     float j;
 246     float len;
 247     vector dist;
 248
 249     float num_nearest;
 250     num_nearest = 0;
 251
 252     localhead = find(world, field, value);
 253     while (localhead)
 254     {
 255         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 256             dist = localhead.oldorigin;
 257         else
 258             dist = localhead.origin;
 259         dist = dist - point;
 260         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 261         len = vlen(dist);
 262
 263         for (i = 0; i < num_nearest; ++i)
 264         {
 265             if (len < nearest_length[i])
 266                 break;
 267         }
 268
 269         // now i tells us where to insert at
 270         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 271         if (i < NUM_NEAREST_ENTITIES)
 272         {
 273             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 274             {
 275                 nearest_length[j + 1] = nearest_length[j];
 276                 nearest_entity[j + 1] = nearest_entity[j];
 277             }
 278             nearest_length[i] = len;
 279             nearest_entity[i] = localhead;
 280             if (num_nearest < NUM_NEAREST_ENTITIES)
 281                 num_nearest = num_nearest + 1;
 282         }
 283
 284         localhead = find(localhead, field, value);
 285     }
 286
 287     // now use the first one from our list that we can see
 288     for (i = 0; i < num_nearest; ++i)
 289     {
 290         traceline(point, nearest_entity[i].origin, TRUE, world);
 291         if (trace_fraction == 1)
 292         {
 293             if (i != 0)
 294             {
 295                 dprint("Nearest point (");
 296                 dprint(nearest_entity[0].netname);
 297                 dprint(") is not visible, using a visible one.\n");
 298             }
 299             return nearest_entity[i];
 300         }
 301     }
 302
 303     if (num_nearest == 0)
 304         return world;
 305
 306     dprint("Not seeing any location point, using nearest as fallback.\n");
 307     /* DEBUGGING CODE:
 308     dprint("Candidates were: ");
 309     for(j = 0; j < num_nearest; ++j)
 310     {
 311         if(j != 0)
 312                 dprint(", ");
 313         dprint(nearest_entity[j].netname);
 314     }
 315     dprint("\n");
 316     */
 317
 318     return nearest_entity[0];
 319 }
 320
 321 void spawnfunc_target_location()
 322 {
 323     self.classname = "target_location";
 324     // location name in netname
 325     // eventually support: count, teamgame selectors, line of sight?
 326 }
 327
 328 void spawnfunc_info_location()
 329 {
 330     self.classname = "target_location";
 331     self.message = self.netname;
 332 }
 333
 334 string NearestLocation(vector p)
 335 {
 336     entity loc;
 337     string ret;
 338     ret = "somewhere";
 339     loc = findnearest(p, classname, "target_location", '1 1 1');
 340     if (loc)
 341     {
 342         ret = loc.message;
 343     }
 344     else
 345     {
 346         loc = findnearest(p, target, "###item###", '1 1 4');
 347         if (loc)
 348             ret = loc.netname;
 349     }
 350     return ret;
 351 }
 352
 353 string formatmessage(string msg)
 354 {
 355         float p, p1, p2;
 356         float n;
 357         vector cursor;
 358         entity cursor_ent;
 359         string escape;
 360         string replacement;
 361         p = 0;
 362         n = 7;
 363
 364         WarpZone_crosshair_trace(self);
 365         cursor = trace_endpos;
 366         cursor_ent = trace_ent;
 367
 368         while (1) {
 369                 if (n < 1)
 370                         break; // too many replacements
 371
 372                 n = n - 1;
 373                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 374                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 375
 376                 if (p1 < 0)
 377                         p1 = p2;
 378
 379                 if (p2 < 0)
 380                         p2 = p1;
 381
 382                 p = min(p1, p2);
 383
 384                 if (p < 0)
 385                         break;
 386
 387                 replacement = substring(msg, p, 2);
 388                 escape = substring(msg, p + 1, 1);
 389
 390                 if (escape == "%")
 391                         replacement = "%";
 392                 else if (escape == "\\")
 393                         replacement = "\\";
 394                 else if (escape == "n")
 395                         replacement = "\n";
 396                 else if (escape == "a")
 397                         replacement = ftos(floor(self.armorvalue));
 398                 else if (escape == "h")
 399                         replacement = ftos(floor(self.health));
 400                 else if (escape == "l")
 401                         replacement = NearestLocation(self.origin);
 402                 else if (escape == "y")
 403                         replacement = NearestLocation(cursor);
 404                 else if (escape == "d")
 405                         replacement = NearestLocation(self.death_origin);
 406                 else if (escape == "w") {
 407                         float wep;
 408                         wep = self.weapon;
 409                         if (!wep)
 410                                 wep = self.switchweapon;
 411                         if (!wep)
 412                                 wep = self.cnt;
 413                         replacement = W_Name(wep);
 414                 } else if (escape == "W") {
 415                         if (self.items & IT_SHELLS) replacement = "shells";
 416                         else if (self.items & IT_NAILS) replacement = "bullets";
 417                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 418                         else if (self.items & IT_CELLS) replacement = "cells";
 419                         else replacement = "batteries"; // ;)
 420                 } else if (escape == "x") {
 421                         replacement = cursor_ent.netname;
 422                         if (replacement == "" || !cursor_ent)
 423                                 replacement = "nothing";
 424                 } else if (escape == "s")
 425                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 426                 else if (escape == "S")
 427                         replacement = ftos(vlen(self.velocity));
 428
 429                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 430                 p = p + strlen(replacement);
 431         }
 432         return msg;
 433 }
 434
 435 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 436         return (value == 0) ? FALSE : TRUE;
 437 }
 438
 439 /*
 440 =============
 441 GetCvars
 442 =============
 443 Called with:
 444   0:  sends the request
 445   >0: receives a cvar from name=argv(f) value=argv(f+1)
 446 */
 447 void GetCvars_handleString(string thisname, float f, .string field, string name)
 448 {
 449         if (f < 0)
 450         {
 451                 if (self.field)
 452                         strunzone(self.field);
 453                 self.field = string_null;
 454         }
 455         else if (f > 0)
 456         {
 457                 if (thisname == name)
 458                 {
 459                         if (self.field)
 460                                 strunzone(self.field);
 461                         self.field = strzone(argv(f + 1));
 462                 }
 463         }
 464         else
 465                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 466 }
 467 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 468 {
 469         GetCvars_handleString(thisname, f, field, name);
 470         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 471                 if (thisname == name)
 472                 {
 473                         string s;
 474                         s = func(strcat1(self.field));
 475                         if (s != self.field)
 476                         {
 477                                 strunzone(self.field);
 478                                 self.field = strzone(s);
 479                         }
 480                 }
 481 }
 482 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 483 {
 484         if (f < 0)
 485         {
 486         }
 487         else if (f > 0)
 488         {
 489                 if (thisname == name)
 490                         self.field = stof(argv(f + 1));
 491         }
 492         else
 493                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 494 }
 495 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 496 {
 497         if (f < 0)
 498         {
 499         }
 500         else if (f > 0)
 501         {
 502                 if (thisname == name)
 503                 {
 504                         if(!self.field)
 505                         {
 506                                 self.field = stof(argv(f + 1));
 507                                 if(!self.field)
 508                                         self.field = -1;
 509                         }
 510                 }
 511         }
 512         else
 513         {
 514                 if(!self.field)
 515                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 516         }
 517 }
 518 float w_getbestweapon(entity e);
 519 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 520 {
 521         string o;
 522         o = W_FixWeaponOrder_ForceComplete(wo);
 523         if(self.weaponorder_byimpulse)
 524         {
 525                 strunzone(self.weaponorder_byimpulse);
 526                 self.weaponorder_byimpulse = string_null;
 527         }
 528         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 529         return o;
 530 }
 531 void GetCvars(float f)
 532 {
 533         string s = string_null;
 534
 535         if (f > 0)
 536                 s = strcat1(argv(f));
 537
 538         get_cvars_f = f;
 539         get_cvars_s = s;
 540
 541         MUTATOR_CALLHOOK(GetCvars);
 542
 543         Notification_GetCvars();
 544
 545         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 546         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 547         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 548         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 549         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 562         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 563         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 564         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 565         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 566         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 567         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 568
 569         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 570         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 571
 572         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 573         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 574         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 575         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 576         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 577
 578         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 579         if (f > 0)
 580         {
 581                 if (s == "cl_weaponpriority")
 582                         self.switchweapon = w_getbestweapon(self);
 583                 if (s == "cl_allow_uidtracking")
 584                         PlayerStats_AddPlayer(self);
 585         }
 586 }
 587
 588 // decolorizes and team colors the player name when needed
 589 string playername(entity p)
 590 {
 591     string t;
 592     if (teamplay && !intermission_running && p.classname == "player")
 593     {
 594         t = Team_ColorCode(p.team);
 595         return strcat(t, strdecolorize(p.netname));
 596     }
 597     else
 598         return p.netname;
 599 }
 600
 601 vector randompos(vector m1, vector m2)
 602 {
 603     vector v;
 604     m2 = m2 - m1;
 605     v_x = m2_x * random() + m1_x;
 606     v_y = m2_y * random() + m1_y;
 607     v_z = m2_z * random() + m1_z;
 608     return  v;
 609 }
 610
 611 //#NO AUTOCVARS START
 612
 613 float g_pickup_shells;
 614 float g_pickup_shells_max;
 615 float g_pickup_nails;
 616 float g_pickup_nails_max;
 617 float g_pickup_rockets;
 618 float g_pickup_rockets_max;
 619 float g_pickup_cells;
 620 float g_pickup_cells_max;
 621 float g_pickup_fuel;
 622 float g_pickup_fuel_jetpack;
 623 float g_pickup_fuel_max;
 624 float g_pickup_armorsmall;
 625 float g_pickup_armorsmall_max;
 626 float g_pickup_armorsmall_anyway;
 627 float g_pickup_armormedium;
 628 float g_pickup_armormedium_max;
 629 float g_pickup_armormedium_anyway;
 630 float g_pickup_armorbig;
 631 float g_pickup_armorbig_max;
 632 float g_pickup_armorbig_anyway;
 633 float g_pickup_armorlarge;
 634 float g_pickup_armorlarge_max;
 635 float g_pickup_armorlarge_anyway;
 636 float g_pickup_healthsmall;
 637 float g_pickup_healthsmall_max;
 638 float g_pickup_healthsmall_anyway;
 639 float g_pickup_healthmedium;
 640 float g_pickup_healthmedium_max;
 641 float g_pickup_healthmedium_anyway;
 642 float g_pickup_healthlarge;
 643 float g_pickup_healthlarge_max;
 644 float g_pickup_healthlarge_anyway;
 645 float g_pickup_healthmega;
 646 float g_pickup_healthmega_max;
 647 float g_pickup_healthmega_anyway;
 648 float g_pickup_ammo_anyway;
 649 float g_pickup_weapons_anyway;
 650 float g_weaponarena;
 651 WEPSET_DECLARE_A(g_weaponarena_weapons);
 652 float g_weaponarena_random;
 653 float g_weaponarena_random_with_laser;
 654 string g_weaponarena_list;
 655 float g_weaponspeedfactor;
 656 float g_weaponratefactor;
 657 float g_weapondamagefactor;
 658 float g_weaponforcefactor;
 659 float g_weaponspreadfactor;
 660
 661 WEPSET_DECLARE_A(start_weapons);
 662 WEPSET_DECLARE_A(start_weapons_default);
 663 WEPSET_DECLARE_A(start_weapons_defaultmask);
 664 float start_items;
 665 float start_ammo_shells;
 666 float start_ammo_nails;
 667 float start_ammo_rockets;
 668 float start_ammo_cells;
 669 float start_ammo_fuel;
 670 float start_health;
 671 float start_armorvalue;
 672 WEPSET_DECLARE_A(warmup_start_weapons);
 673 WEPSET_DECLARE_A(warmup_start_weapons_default);
 674 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 675 float warmup_start_ammo_shells;
 676 float warmup_start_ammo_nails;
 677 float warmup_start_ammo_rockets;
 678 float warmup_start_ammo_cells;
 679 float warmup_start_ammo_fuel;
 680 float warmup_start_health;
 681 float warmup_start_armorvalue;
 682 float g_weapon_stay;
 683
 684 entity get_weaponinfo(float w);
 685
 686 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 687 {
 688         var float i = weaponinfo.weapon;
 689         var float d = 0;
 690
 691         if (!i)
 692                 return 0;
 693
 694         if (g_lms || g_ca || allguns)
 695         {
 696                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 697                         d = TRUE;
 698                 else
 699                         d = FALSE;
 700         }
 701         else if (g_cts)
 702                 d = (i == WEP_SHOTGUN);
 703         else if (g_nexball)
 704                 d = 0; // weapon is set a few lines later
 705         else
 706                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 707
 708         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 709                 d |= (i == WEP_HOOK);
 710         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 711                 d = 0;
 712
 713         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 714
 715         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 716
 717         // bit order in t:
 718         // 1: want or not
 719         // 2: is default?
 720         // 4: is set by default?
 721         if(t < 0)
 722                 t = 4 | (3 * d);
 723         else
 724                 t |= (2 * d);
 725
 726         return t;
 727 }
 728
 729 void readplayerstartcvars()
 730 {
 731         entity e;
 732         float i, j, t;
 733         string s;
 734
 735         // initialize starting values for players
 736         WEPSET_CLEAR_A(start_weapons);
 737         WEPSET_CLEAR_A(start_weapons_default);
 738         WEPSET_CLEAR_A(start_weapons_defaultmask);
 739         start_items = 0;
 740         start_ammo_shells = 0;
 741         start_ammo_nails = 0;
 742         start_ammo_rockets = 0;
 743         start_ammo_cells = 0;
 744         start_health = cvar("g_balance_health_start");
 745         start_armorvalue = cvar("g_balance_armor_start");
 746
 747         g_weaponarena = 0;
 748         WEPSET_CLEAR_A(g_weaponarena_weapons);
 749
 750         s = cvar_string("g_weaponarena");
 751         if (s == "0" || s == "")
 752         {
 753                 if(g_lms || g_ca)
 754                         s = "most";
 755         }
 756
 757         if (s == "0" || s == "")
 758         {
 759                 // no arena
 760         }
 761         else if (s == "off")
 762         {
 763                 // forcibly turn off weaponarena
 764         }
 765         else if (s == "all")
 766         {
 767                 g_weaponarena = 1;
 768                 g_weaponarena_list = "All Weapons";
 769                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 773                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 774                 }
 775         }
 776         else if (s == "most")
 777         {
 778                 g_weaponarena = 1;
 779                 g_weaponarena_list = "Most Weapons";
 780                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 781                 {
 782                         e = get_weaponinfo(j);
 783                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 784                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 785                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 786                 }
 787         }
 788         else if (s == "none")
 789         {
 790                 g_weaponarena = 1;
 791                 g_weaponarena_list = "No Weapons";
 792         }
 793         else
 794         {
 795                 g_weaponarena = 1;
 796                 t = tokenize_console(s);
 797                 g_weaponarena_list = "";
 798                 for (i = 0; i < t; ++i)
 799                 {
 800                         s = argv(i);
 801                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 802                         {
 803                                 e = get_weaponinfo(j);
 804                                 if (e.netname == s)
 805                                 {
 806                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 807                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 808                                         break;
 809                                 }
 810                         }
 811                         if (j > WEP_LAST)
 812                         {
 813                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 814                         }
 815                 }
 816                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 817         }
 818
 819         if(g_weaponarena)
 820                 g_weaponarena_random = cvar("g_weaponarena_random");
 821         else
 822                 g_weaponarena_random = 0;
 823         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 824
 825         if (g_weaponarena)
 826         {
 827                 g_minstagib = 0; // incompatible
 828                 g_pinata = 0; // incompatible
 829                 g_weapon_stay = 0; // incompatible
 830                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 831                 if(!(g_lms || g_ca))
 832                         start_items |= IT_UNLIMITED_AMMO;
 833         }
 834         else if (g_minstagib)
 835         {
 836                 g_pinata = 0; // incompatible
 837                 g_weapon_stay = 0; // incompatible
 838                 g_bloodloss = 0; // incompatible
 839                 start_health = 100;
 840                 start_armorvalue = 0;
 841                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 842                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 843                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 844
 845                 if (g_minstagib_invis_alpha <= 0)
 846                         g_minstagib_invis_alpha = -1;
 847         }
 848         else
 849         {
 850                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 851                 {
 852                         e = get_weaponinfo(i);
 853                         float w = want_weapon("g_start_weapon_", e, FALSE);
 854                         if(w & 1)
 855                                 WEPSET_OR_AW(start_weapons, i);
 856                         if(w & 2)
 857                                 WEPSET_OR_AW(start_weapons_default, i);
 858                         if(w & 4)
 859                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 860                 }
 861         }
 862
 863         if(!cvar("g_use_ammunition"))
 864                 start_items |= IT_UNLIMITED_AMMO;
 865
 866         if(cvar("g_nexball"))
 867                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 868
 869         if(g_minstagib)
 870         {
 871                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 872                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 873         }
 874         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 875         {
 876                 start_ammo_rockets = 999;
 877                 start_ammo_shells = 999;
 878                 start_ammo_cells = 999;
 879                 start_ammo_nails = 999;
 880                 start_ammo_fuel = 999;
 881         }
 882         else
 883         {
 884                 if(g_lms || g_ca)
 885                 {
 886                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 887                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 888                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 889                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 890                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 891                 }
 892                 else
 893                 {
 894                         start_ammo_shells = cvar("g_start_ammo_shells");
 895                         start_ammo_nails = cvar("g_start_ammo_nails");
 896                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 897                         start_ammo_cells = cvar("g_start_ammo_cells");
 898                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 899                 }
 900         }
 901
 902         if (g_lms || g_ca)
 903         {
 904                 start_health = cvar("g_lms_start_health");
 905                 start_armorvalue = cvar("g_lms_start_armor");
 906         }
 907
 908         if (inWarmupStage)
 909         {
 910                 warmup_start_ammo_shells = start_ammo_shells;
 911                 warmup_start_ammo_nails = start_ammo_nails;
 912                 warmup_start_ammo_rockets = start_ammo_rockets;
 913                 warmup_start_ammo_cells = start_ammo_cells;
 914                 warmup_start_ammo_fuel = start_ammo_fuel;
 915                 warmup_start_health = start_health;
 916                 warmup_start_armorvalue = start_armorvalue;
 917                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 918                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 919                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 920
 921                 if (!g_weaponarena && !g_minstagib && !g_ca)
 922                 {
 923                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 924                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 925                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 926                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 927                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 928                         warmup_start_health = cvar("g_warmup_start_health");
 929                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 930                         WEPSET_CLEAR_A(warmup_start_weapons);
 931                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 932                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 933                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 934                         {
 935                                 e = get_weaponinfo(i);
 936                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 937                                 if(w & 1)
 938                                         WEPSET_OR_AW(warmup_start_weapons, i);
 939                                 if(w & 2)
 940                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 941                                 if(w & 4)
 942                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 943                         }
 944                 }
 945         }
 946
 947         if (g_jetpack)
 948                 start_items |= IT_JETPACK;
 949
 950         MUTATOR_CALLHOOK(SetStartItems);
 951
 952         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 953         {
 954                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 955                 start_items |= IT_FUEL_REGEN;
 956                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 957                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 958         }
 959
 960         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 961         {
 962                 e = get_weaponinfo(i);
 963                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 964                         weapon_action(i, WR_PRECACHE);
 965         }
 966
 967         start_ammo_shells = max(0, start_ammo_shells);
 968         start_ammo_nails = max(0, start_ammo_nails);
 969         start_ammo_cells = max(0, start_ammo_cells);
 970         start_ammo_rockets = max(0, start_ammo_rockets);
 971         start_ammo_fuel = max(0, start_ammo_fuel);
 972
 973         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 974         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 975         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 976         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 977         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 978 }
 979
 980 float g_bugrigs;
 981 float g_bugrigs_planar_movement;
 982 float g_bugrigs_planar_movement_car_jumping;
 983 float g_bugrigs_reverse_spinning;
 984 float g_bugrigs_reverse_speeding;
 985 float g_bugrigs_reverse_stopping;
 986 float g_bugrigs_air_steering;
 987 float g_bugrigs_angle_smoothing;
 988 float g_bugrigs_friction_floor;
 989 float g_bugrigs_friction_brake;
 990 float g_bugrigs_friction_air;
 991 float g_bugrigs_accel;
 992 float g_bugrigs_speed_ref;
 993 float g_bugrigs_speed_pow;
 994 float g_bugrigs_steer;
 995
 996 float sv_autotaunt;
 997 float sv_taunt;
 998
 999 string GetGametype(); // g_world.qc
1000 void readlevelcvars(void)
1001 {
1002         g_minstagib = cvar("g_minstagib");
1003
1004         // load ALL the mutators
1005         if(cvar("g_dodging"))
1006                 MUTATOR_ADD(mutator_dodging);
1007         if(cvar("g_spawn_near_teammate"))
1008                 MUTATOR_ADD(mutator_spawn_near_teammate);
1009         if(cvar("g_physical_items"))
1010                 MUTATOR_ADD(mutator_physical_items);
1011         if(cvar("g_touchexplode"))
1012                 MUTATOR_ADD(mutator_touchexplode);
1013         if(!g_minstagib)
1014         {
1015                 if(cvar("g_invincible_projectiles"))
1016                         MUTATOR_ADD(mutator_invincibleprojectiles);
1017                 if(cvar("g_new_toys"))
1018                         MUTATOR_ADD(mutator_new_toys);
1019                 if(cvar("g_nix"))
1020                         MUTATOR_ADD(mutator_nix);
1021                 if(cvar("g_rocket_flying"))
1022                         MUTATOR_ADD(mutator_rocketflying);
1023                 if(cvar("g_vampire"))
1024                         MUTATOR_ADD(mutator_vampire);
1025                 if(cvar("g_superspectate"))
1026                         MUTATOR_ADD(mutator_superspec);
1027         }
1028
1029         // is this a mutator? is this a mode?
1030         if(cvar("g_sandbox"))
1031                 MUTATOR_ADD(sandbox);
1032
1033         if(cvar("sv_allow_fullbright"))
1034                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1035
1036     g_bugrigs = cvar("g_bugrigs");
1037     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1038     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1039     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1040     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1041     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1042     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1043     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1044     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1045     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1046     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1047     g_bugrigs_accel = cvar("g_bugrigs_accel");
1048     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1049     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1050     g_bugrigs_steer = cvar("g_bugrigs_steer");
1051
1052         sv_clones = cvar("sv_clones");
1053         sv_foginterval = cvar("sv_foginterval");
1054         g_cloaked = cvar("g_cloaked");
1055     if(g_cts)
1056         g_cloaked = 1; // always enable cloak in CTS
1057         g_jump_grunt = cvar("g_jump_grunt");
1058         g_footsteps = cvar("g_footsteps");
1059         g_grappling_hook = cvar("g_grappling_hook");
1060         g_jetpack = cvar("g_jetpack");
1061         g_midair = cvar("g_midair");
1062         g_norecoil = cvar("g_norecoil");
1063         g_bloodloss = cvar("g_bloodloss");
1064         sv_maxidle = cvar("sv_maxidle");
1065         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1066         sv_autotaunt = cvar("sv_autotaunt");
1067         sv_taunt = cvar("sv_taunt");
1068
1069         inWarmupStage = cvar("g_warmup");
1070         g_warmup_limit = cvar("g_warmup_limit");
1071         g_warmup_allguns = cvar("g_warmup_allguns");
1072         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1073
1074         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1075                 inWarmupStage = 0; // these modes cannot work together, sorry
1076
1077         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1078         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1079         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1080         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1081         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1082         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1083         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1084         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1085         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1086         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1087         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1088         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1089         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1090         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1091
1092         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1093         g_weaponratefactor = cvar("g_weaponratefactor");
1094         g_weapondamagefactor = cvar("g_weapondamagefactor");
1095         g_weaponforcefactor = cvar("g_weaponforcefactor");
1096         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1097
1098         g_pickup_shells = cvar("g_pickup_shells");
1099         g_pickup_shells_max = cvar("g_pickup_shells_max");
1100         g_pickup_nails = cvar("g_pickup_nails");
1101         g_pickup_nails_max = cvar("g_pickup_nails_max");
1102         g_pickup_rockets = cvar("g_pickup_rockets");
1103         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1104         g_pickup_cells = cvar("g_pickup_cells");
1105         g_pickup_cells_max = cvar("g_pickup_cells_max");
1106         g_pickup_fuel = cvar("g_pickup_fuel");
1107         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1108         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1109         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1110         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1111         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1112         g_pickup_armormedium = cvar("g_pickup_armormedium");
1113         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1114         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1115         g_pickup_armorbig = cvar("g_pickup_armorbig");
1116         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1117         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1118         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1119         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1120         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1121         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1122         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1123         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1124         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1125         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1126         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1127         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1128         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1129         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1130         g_pickup_healthmega = cvar("g_pickup_healthmega");
1131         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1132         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1133
1134         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1135         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1136
1137         g_pinata = cvar("g_pinata");
1138
1139     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1140     if(!g_weapon_stay)
1141         g_weapon_stay = cvar("g_weapon_stay");
1142
1143         if not(inWarmupStage && !g_ca)
1144                 game_starttime = cvar("g_start_delay");
1145
1146         readplayerstartcvars();
1147 }
1148
1149 //#NO AUTOCVARS END
1150
1151 // Sound functions
1152 string precache_sound (string s) = #19;
1153 float precache_sound_index (string s) = #19;
1154
1155 #define SND_VOLUME      1
1156 #define SND_ATTENUATION 2
1157 #define SND_LARGEENTITY 8
1158 #define SND_LARGESOUND  16
1159
1160 float sound_allowed(float dest, entity e)
1161 {
1162     // sounds from world may always pass
1163     for (;;)
1164     {
1165         if (e.classname == "body")
1166             e = e.enemy;
1167         else if (e.realowner && e.realowner != e)
1168             e = e.realowner;
1169         else if (e.owner && e.owner != e)
1170             e = e.owner;
1171         else
1172             break;
1173     }
1174     // sounds to self may always pass
1175     if (dest == MSG_ONE)
1176         if (e == msg_entity)
1177             return TRUE;
1178     // sounds by players can be removed
1179     if (autocvar_bot_sound_monopoly)
1180         if (clienttype(e) == CLIENTTYPE_REAL)
1181             return FALSE;
1182     // anything else may pass
1183     return TRUE;
1184 }
1185
1186 #ifdef COMPAT_XON010_CHANNELS
1187 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1188 void sound(entity e, float chan, string samp, float vol, float atten)
1189 {
1190     if (!sound_allowed(MSG_BROADCAST, e))
1191         return;
1192     builtin_sound(e, chan, samp, vol, atten);
1193 }
1194 #else
1195 #undef sound
1196 void sound(entity e, float chan, string samp, float vol, float atten)
1197 {
1198     if (!sound_allowed(MSG_BROADCAST, e))
1199         return;
1200     sound7(e, chan, samp, vol, atten, 0, 0);
1201 }
1202 #endif
1203
1204 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1205 {
1206     float entno, idx;
1207
1208     if (!sound_allowed(dest, e))
1209         return;
1210
1211     entno = num_for_edict(e);
1212     idx = precache_sound_index(samp);
1213
1214     float sflags;
1215     sflags = 0;
1216
1217     atten = floor(atten * 64);
1218     vol = floor(vol * 255);
1219
1220     if (vol != 255)
1221         sflags |= SND_VOLUME;
1222     if (atten != 64)
1223         sflags |= SND_ATTENUATION;
1224     if (entno >= 8192 || chan < 0 || chan > 7)
1225         sflags |= SND_LARGEENTITY;
1226     if (idx >= 256)
1227         sflags |= SND_LARGESOUND;
1228
1229     WriteByte(dest, SVC_SOUND);
1230     WriteByte(dest, sflags);
1231     if (sflags & SND_VOLUME)
1232         WriteByte(dest, vol);
1233     if (sflags & SND_ATTENUATION)
1234         WriteByte(dest, atten);
1235     if (sflags & SND_LARGEENTITY)
1236     {
1237         WriteShort(dest, entno);
1238         WriteByte(dest, chan);
1239     }
1240     else
1241     {
1242         WriteShort(dest, entno * 8 + chan);
1243     }
1244     if (sflags & SND_LARGESOUND)
1245         WriteShort(dest, idx);
1246     else
1247         WriteByte(dest, idx);
1248
1249     WriteCoord(dest, o_x);
1250     WriteCoord(dest, o_y);
1251     WriteCoord(dest, o_z);
1252 }
1253 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1254 {
1255     vector o;
1256
1257     if (!sound_allowed(dest, e))
1258         return;
1259
1260     o = e.origin + 0.5 * (e.mins + e.maxs);
1261     soundtoat(dest, e, o, chan, samp, vol, atten);
1262 }
1263 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1264 {
1265     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1266 }
1267 void stopsoundto(float dest, entity e, float chan)
1268 {
1269     float entno;
1270
1271     if (!sound_allowed(dest, e))
1272         return;
1273
1274     entno = num_for_edict(e);
1275
1276     if (entno >= 8192 || chan < 0 || chan > 7)
1277     {
1278         float idx, sflags;
1279         idx = precache_sound_index("misc/null.wav");
1280         sflags = SND_LARGEENTITY;
1281         if (idx >= 256)
1282             sflags |= SND_LARGESOUND;
1283         WriteByte(dest, SVC_SOUND);
1284         WriteByte(dest, sflags);
1285         WriteShort(dest, entno);
1286         WriteByte(dest, chan);
1287         if (sflags & SND_LARGESOUND)
1288             WriteShort(dest, idx);
1289         else
1290             WriteByte(dest, idx);
1291         WriteCoord(dest, e.origin_x);
1292         WriteCoord(dest, e.origin_y);
1293         WriteCoord(dest, e.origin_z);
1294     }
1295     else
1296     {
1297         WriteByte(dest, SVC_STOPSOUND);
1298         WriteShort(dest, entno * 8 + chan);
1299     }
1300 }
1301 void stopsound(entity e, float chan)
1302 {
1303     if (!sound_allowed(MSG_BROADCAST, e))
1304         return;
1305
1306     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1307     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1308 }
1309
1310 void play2(entity e, string filename)
1311 {
1312     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1313     msg_entity = e;
1314     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1315 }
1316
1317 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1318 .float spamtime;
1319 float spamsound(entity e, float chan, string samp, float vol, float atten)
1320 {
1321     if (!sound_allowed(MSG_BROADCAST, e))
1322         return FALSE;
1323
1324     if (time > e.spamtime)
1325     {
1326         e.spamtime = time;
1327         sound(e, chan, samp, vol, atten);
1328         return TRUE;
1329     }
1330     return FALSE;
1331 }
1332
1333 void play2team(float t, string filename)
1334 {
1335     entity head;
1336
1337     if (autocvar_bot_sound_monopoly)
1338         return;
1339
1340     FOR_EACH_REALPLAYER(head)
1341     {
1342         if (head.team == t)
1343             play2(head, filename);
1344     }
1345 }
1346
1347 void play2all(string samp)
1348 {
1349     if (autocvar_bot_sound_monopoly)
1350         return;
1351
1352     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1353 }
1354
1355 void PrecachePlayerSounds(string f);
1356 void precache_playermodel(string m)
1357 {
1358         float globhandle, i, n;
1359         string f;
1360
1361         if(substring(m, -9,5) == "_lod1")
1362                 return;
1363         if(substring(m, -9,5) == "_lod2")
1364                 return;
1365         precache_model(m);
1366         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1367         if(fexists(f))
1368                 precache_model(f);
1369         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1370         if(fexists(f))
1371                 precache_model(f);
1372
1373         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1374         if (globhandle < 0)
1375                 return;
1376         n = search_getsize(globhandle);
1377         for (i = 0; i < n; ++i)
1378         {
1379                 //print(search_getfilename(globhandle, i), "\n");
1380                 f = search_getfilename(globhandle, i);
1381                 PrecachePlayerSounds(f);
1382         }
1383         search_end(globhandle);
1384 }
1385 void precache_all_playermodels(string pattern)
1386 {
1387         float globhandle, i, n;
1388         string f;
1389
1390         globhandle = search_begin(pattern, TRUE, FALSE);
1391         if (globhandle < 0)
1392                 return;
1393         n = search_getsize(globhandle);
1394         for (i = 0; i < n; ++i)
1395         {
1396                 //print(search_getfilename(globhandle, i), "\n");
1397                 f = search_getfilename(globhandle, i);
1398                 precache_playermodel(f);
1399         }
1400         search_end(globhandle);
1401 }
1402
1403 void precache()
1404 {
1405     // gamemode related things
1406     precache_model ("models/misc/chatbubble.spr");
1407
1408 #ifdef TTURRETS_ENABLED
1409     if (autocvar_g_turrets)
1410         turrets_precash();
1411 #endif
1412
1413     // Precache all player models if desired
1414     if (autocvar_sv_precacheplayermodels)
1415     {
1416         PrecachePlayerSounds("sound/player/default.sounds");
1417         precache_all_playermodels("models/player/*.zym");
1418         precache_all_playermodels("models/player/*.dpm");
1419         precache_all_playermodels("models/player/*.md3");
1420         precache_all_playermodels("models/player/*.psk");
1421         precache_all_playermodels("models/player/*.iqm");
1422     }
1423
1424     if (autocvar_sv_defaultcharacter)
1425     {
1426         string s;
1427         s = autocvar_sv_defaultplayermodel_red;
1428         if (s != "")
1429             precache_playermodel(s);
1430         s = autocvar_sv_defaultplayermodel_blue;
1431         if (s != "")
1432             precache_playermodel(s);
1433         s = autocvar_sv_defaultplayermodel_yellow;
1434         if (s != "")
1435             precache_playermodel(s);
1436         s = autocvar_sv_defaultplayermodel_pink;
1437         if (s != "")
1438             precache_playermodel(s);
1439         s = autocvar_sv_defaultplayermodel;
1440         if (s != "")
1441             precache_playermodel(s);
1442     }
1443
1444     if (g_footsteps)
1445     {
1446         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1447         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1448     }
1449
1450     // gore and miscellaneous sounds
1451     //precache_sound ("misc/h2ohit.wav");
1452     precache_model ("models/hook.md3");
1453     precache_sound ("misc/armorimpact.wav");
1454     precache_sound ("misc/bodyimpact1.wav");
1455     precache_sound ("misc/bodyimpact2.wav");
1456     precache_sound ("misc/gib.wav");
1457     precache_sound ("misc/gib_splat01.wav");
1458     precache_sound ("misc/gib_splat02.wav");
1459     precache_sound ("misc/gib_splat03.wav");
1460     precache_sound ("misc/gib_splat04.wav");
1461     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1462     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1463     precache_sound ("misc/null.wav");
1464     precache_sound ("misc/spawn.wav");
1465     precache_sound ("misc/talk.wav");
1466     precache_sound ("misc/teleport.wav");
1467     precache_sound ("misc/poweroff.wav");
1468     precache_sound ("player/lava.wav");
1469     precache_sound ("player/slime.wav");
1470
1471     precache_model ("models/sprites/0.spr32");
1472     precache_model ("models/sprites/1.spr32");
1473     precache_model ("models/sprites/2.spr32");
1474     precache_model ("models/sprites/3.spr32");
1475     precache_model ("models/sprites/4.spr32");
1476     precache_model ("models/sprites/5.spr32");
1477     precache_model ("models/sprites/6.spr32");
1478     precache_model ("models/sprites/7.spr32");
1479     precache_model ("models/sprites/8.spr32");
1480     precache_model ("models/sprites/9.spr32");
1481     precache_model ("models/sprites/10.spr32");
1482
1483     // common weapon precaches
1484         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1485     precache_sound ("weapons/weapon_switch.wav");
1486     precache_sound ("weapons/weaponpickup.wav");
1487     precache_sound ("weapons/unavailable.wav");
1488     precache_sound ("weapons/dryfire.wav");
1489     if (g_grappling_hook)
1490     {
1491         precache_sound ("weapons/hook_fire.wav"); // hook
1492         precache_sound ("weapons/hook_impact.wav"); // hook
1493     }
1494
1495     if(autocvar_sv_precacheweapons)
1496     {
1497         //precache weapon models/sounds
1498         float wep;
1499         wep = WEP_FIRST;
1500         while (wep <= WEP_LAST)
1501         {
1502             weapon_action(wep, WR_PRECACHE);
1503             wep = wep + 1;
1504         }
1505     }
1506
1507     precache_model("models/elaser.mdl");
1508     precache_model("models/laser.mdl");
1509     precache_model("models/ebomb.mdl");
1510
1511 #if 0
1512     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1513
1514     if (!self.noise && self.music) // quake 3 uses the music field
1515         self.noise = self.music;
1516
1517     // plays music for the level if there is any
1518     if (self.noise)
1519     {
1520         precache_sound (self.noise);
1521         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1522     }
1523 #endif
1524 }
1525
1526 // WARNING: this kills the trace globals
1527 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1528 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1529
1530 #define INITPRIO_FIRST              0
1531 #define INITPRIO_GAMETYPE           0
1532 #define INITPRIO_GAMETYPE_FALLBACK  1
1533 #define INITPRIO_FINDTARGET        10
1534 #define INITPRIO_DROPTOFLOOR       20
1535 #define INITPRIO_SETLOCATION       90
1536 #define INITPRIO_LINKDOORS         91
1537 #define INITPRIO_LAST              99
1538
1539 .void(void) initialize_entity;
1540 .float initialize_entity_order;
1541 .entity initialize_entity_next;
1542 entity initialize_entity_first;
1543
1544 void make_safe_for_remove(entity e)
1545 {
1546     if (e.initialize_entity)
1547     {
1548         entity ent, prev = world;
1549         for (ent = initialize_entity_first; ent; )
1550         {
1551             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1552             {
1553                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1554                 // skip it in linked list
1555                 if (prev)
1556                 {
1557                     prev.initialize_entity_next = ent.initialize_entity_next;
1558                     ent = prev.initialize_entity_next;
1559                 }
1560                 else
1561                 {
1562                     initialize_entity_first = ent.initialize_entity_next;
1563                     ent = initialize_entity_first;
1564                 }
1565             }
1566             else
1567             {
1568                 prev = ent;
1569                 ent = ent.initialize_entity_next;
1570             }
1571         }
1572     }
1573 }
1574
1575 void objerror(string s)
1576 {
1577     make_safe_for_remove(self);
1578     builtin_objerror(s);
1579 }
1580
1581 .float remove_except_protected_forbidden;
1582 void remove_except_protected(entity e)
1583 {
1584         if(e.remove_except_protected_forbidden)
1585                 error("not allowed to remove this at this point");
1586         builtin_remove(e);
1587 }
1588
1589 void remove_unsafely(entity e)
1590 {
1591     if(e.classname == "spike")
1592         error("Removing spikes is forbidden (crylink bug), please report");
1593     builtin_remove(e);
1594 }
1595
1596 void remove_safely(entity e)
1597 {
1598     make_safe_for_remove(e);
1599     builtin_remove(e);
1600 }
1601
1602 void InitializeEntity(entity e, void(void) func, float order)
1603 {
1604     entity prev, cur;
1605
1606     if (!e || e.initialize_entity)
1607     {
1608         // make a proxy initializer entity
1609         entity e_old;
1610         e_old = e;
1611         e = spawn();
1612         e.classname = "initialize_entity";
1613         e.enemy = e_old;
1614     }
1615
1616     e.initialize_entity = func;
1617     e.initialize_entity_order = order;
1618
1619     cur = initialize_entity_first;
1620     prev = world;
1621     for (;;)
1622     {
1623         if (!cur || cur.initialize_entity_order > order)
1624         {
1625             // insert between prev and cur
1626             if (prev)
1627                 prev.initialize_entity_next = e;
1628             else
1629                 initialize_entity_first = e;
1630             e.initialize_entity_next = cur;
1631             return;
1632         }
1633         prev = cur;
1634         cur = cur.initialize_entity_next;
1635     }
1636 }
1637 void InitializeEntitiesRun()
1638 {
1639     entity startoflist;
1640     startoflist = initialize_entity_first;
1641     initialize_entity_first = world;
1642     remove = remove_except_protected;
1643     for (self = startoflist; self; self = self.initialize_entity_next)
1644     {
1645         self.remove_except_protected_forbidden = 1;
1646     }
1647     for (self = startoflist; self; )
1648     {
1649         entity e;
1650         var void(void) func;
1651         e = self.initialize_entity_next;
1652         func = self.initialize_entity;
1653         self.initialize_entity_order = 0;
1654         self.initialize_entity = func_null;
1655         self.initialize_entity_next = world;
1656         self.remove_except_protected_forbidden = 0;
1657         if (self.classname == "initialize_entity")
1658         {
1659             entity e_old;
1660             e_old = self.enemy;
1661             builtin_remove(self);
1662             self = e_old;
1663         }
1664         //dprint("Delayed initialization: ", self.classname, "\n");
1665         if(func)
1666             func();
1667         else
1668         {
1669             eprint(self);
1670             backtrace(strcat("Null function in: ", self.classname, "\n"));
1671         }
1672         self = e;
1673     }
1674     remove = remove_unsafely;
1675 }
1676
1677 .float uncustomizeentityforclient_set;
1678 .void(void) uncustomizeentityforclient;
1679 void UncustomizeEntitiesRun()
1680 {
1681     entity oldself;
1682     oldself = self;
1683     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1684         self.uncustomizeentityforclient();
1685     self = oldself;
1686 }
1687 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1688 {
1689     e.customizeentityforclient = customizer;
1690     e.uncustomizeentityforclient = uncustomizer;
1691     e.uncustomizeentityforclient_set = !!uncustomizer;
1692 }
1693
1694 .float nottargeted;
1695 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1696
1697 void() SUB_Remove;
1698 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1699 {
1700     vector mi, ma;
1701
1702     if (e.classname == "")
1703         e.classname = "net_linked";
1704
1705     if (e.model == "" || self.modelindex == 0)
1706     {
1707         mi = e.mins;
1708         ma = e.maxs;
1709         setmodel(e, "null");
1710         setsize(e, mi, ma);
1711     }
1712
1713     e.SendEntity = sendfunc;
1714     e.SendFlags = 0xFFFFFF;
1715
1716     if (!docull)
1717         e.effects |= EF_NODEPTHTEST;
1718
1719     if (dt)
1720     {
1721         e.nextthink = time + dt;
1722         e.think = SUB_Remove;
1723     }
1724 }
1725
1726 void adaptor_think2touch()
1727 {
1728     entity o;
1729     o = other;
1730     other = world;
1731     self.touch();
1732     other = o;
1733 }
1734
1735 void adaptor_think2use()
1736 {
1737     entity o, a;
1738     o = other;
1739     a = activator;
1740     activator = world;
1741     other = world;
1742     self.use();
1743     other = o;
1744     activator = a;
1745 }
1746
1747 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1748 {
1749         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1750                 self.projectiledeathtype |= HITTYPE_SPLASH;
1751         adaptor_think2use();
1752 }
1753
1754 // deferred dropping
1755 void DropToFloor_Handler()
1756 {
1757     builtin_droptofloor();
1758     self.dropped_origin = self.origin;
1759 }
1760
1761 void droptofloor()
1762 {
1763     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1764 }
1765
1766
1767
1768 float trace_hits_box_a0, trace_hits_box_a1;
1769
1770 float trace_hits_box_1d(float end, float thmi, float thma)
1771 {
1772     if (end == 0)
1773     {
1774         // just check if x is in range
1775         if (0 < thmi)
1776             return FALSE;
1777         if (0 > thma)
1778             return FALSE;
1779     }
1780     else
1781     {
1782         // do the trace with respect to x
1783         // 0 -> end has to stay in thmi -> thma
1784         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1785         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1786         if (trace_hits_box_a0 > trace_hits_box_a1)
1787             return FALSE;
1788     }
1789     return TRUE;
1790 }
1791
1792 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1793 {
1794     end -= start;
1795     thmi -= start;
1796     thma -= start;
1797     // now it is a trace from 0 to end
1798
1799     trace_hits_box_a0 = 0;
1800     trace_hits_box_a1 = 1;
1801
1802     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1803         return FALSE;
1804     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1805         return FALSE;
1806     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1807         return FALSE;
1808
1809     return TRUE;
1810 }
1811
1812 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1813 {
1814     return trace_hits_box(start, end, thmi - ma, thma - mi);
1815 }
1816
1817 float SUB_NoImpactCheck()
1818 {
1819         // zero hitcontents = this is not the real impact, but either the
1820         // mirror-impact of something hitting the projectile instead of the
1821         // projectile hitting the something, or a touchareagrid one. Neither of
1822         // these stop the projectile from moving, so...
1823         if(trace_dphitcontents == 0)
1824         {
1825                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1826                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1827                 checkclient();
1828         }
1829     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1830         return 1;
1831     if (other == world && self.size != '0 0 0')
1832     {
1833         vector tic;
1834         tic = self.velocity * sys_frametime;
1835         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1836         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1837         if (trace_fraction >= 1)
1838         {
1839             dprint("Odd... did not hit...?\n");
1840         }
1841         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1842         {
1843             dprint("Detected and prevented the sky-grapple bug.\n");
1844             return 1;
1845         }
1846     }
1847
1848     return 0;
1849 }
1850
1851 #define SUB_OwnerCheck() (other && (other == self.owner))
1852
1853 void RemoveGrapplingHook(entity pl);
1854 void W_Crylink_Dequeue(entity e);
1855 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1856 {
1857         if(SUB_OwnerCheck())
1858                 return TRUE;
1859         if(SUB_NoImpactCheck())
1860         {
1861                 if(self.classname == "grapplinghook")
1862                         RemoveGrapplingHook(self.realowner);
1863                 else if(self.classname == "spike")
1864                 {
1865                         W_Crylink_Dequeue(self);
1866                         remove(self);
1867                 }
1868                 else
1869                         remove(self);
1870                 return TRUE;
1871         }
1872         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1873                 UpdateCSQCProjectile(self);
1874         return FALSE;
1875 }
1876 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1877
1878 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1879 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1880
1881 void URI_Get_Callback(float id, float status, string data)
1882 {
1883         if(url_URI_Get_Callback(id, status, data))
1884         {
1885                 // handled
1886         }
1887         else if (id == URI_GET_DISCARD)
1888         {
1889                 // discard
1890         }
1891         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1892         {
1893                 // sv_cmd curl
1894                 Curl_URI_Get_Callback(id, status, data);
1895         }
1896         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1897         {
1898                 // online ban list
1899                 OnlineBanList_URI_Get_Callback(id, status, data);
1900         }
1901         else
1902         {
1903                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1904         }
1905 }
1906
1907 string uid2name(string myuid) {
1908         string s;
1909         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1910
1911         // FIXME remove this later after 0.6 release
1912         // convert old style broken records to correct style
1913         if(s == "")
1914         {
1915                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1916                 if(s != "")
1917                 {
1918                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1919                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1920                 }
1921         }
1922
1923         if(s == "")
1924                 s = "^1Unregistered Player";
1925         return s;
1926 }
1927
1928 float race_readTime(string map, float pos)
1929 {
1930         string rr;
1931         if(g_cts)
1932                 rr = CTS_RECORD;
1933         else
1934                 rr = RACE_RECORD;
1935
1936         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1937 }
1938
1939 string race_readUID(string map, float pos)
1940 {
1941         string rr;
1942         if(g_cts)
1943                 rr = CTS_RECORD;
1944         else
1945                 rr = RACE_RECORD;
1946
1947         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1948 }
1949
1950 float race_readPos(string map, float t) {
1951         float i;
1952         for (i = 1; i <= RANKINGS_CNT; ++i)
1953                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1954                         return i;
1955
1956         return 0; // pos is zero if unranked
1957 }
1958
1959 void race_writeTime(string map, float t, string myuid)
1960 {
1961         string rr;
1962         if(g_cts)
1963                 rr = CTS_RECORD;
1964         else
1965                 rr = RACE_RECORD;
1966
1967         float newpos;
1968         newpos = race_readPos(map, t);
1969
1970         float i, prevpos = 0;
1971         for(i = 1; i <= RANKINGS_CNT; ++i)
1972         {
1973                 if(race_readUID(map, i) == myuid)
1974                         prevpos = i;
1975         }
1976         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1977                 for (i = prevpos; i > newpos; --i) {
1978                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1979                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1980                 }
1981         } else { // player has no ranked record yet
1982                 for (i = RANKINGS_CNT; i > newpos; --i) {
1983                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1984                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1985                 }
1986         }
1987
1988         // store new time itself
1989         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1990         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1991 }
1992
1993 string race_readName(string map, float pos)
1994 {
1995         string rr;
1996         if(g_cts)
1997                 rr = CTS_RECORD;
1998         else
1999                 rr = RACE_RECORD;
2000
2001         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2002 }
2003
2004 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2005 {
2006     float m, i;
2007     vector start, org, delta, end, enddown, mstart;
2008     entity sp;
2009
2010     m = e.dphitcontentsmask;
2011     e.dphitcontentsmask = goodcontents | badcontents;
2012
2013     org = world.mins;
2014     delta = world.maxs - world.mins;
2015
2016     start = end = org;
2017
2018     for (i = 0; i < attempts; ++i)
2019     {
2020         start_x = org_x + random() * delta_x;
2021         start_y = org_y + random() * delta_y;
2022         start_z = org_z + random() * delta_z;
2023
2024         // rule 1: start inside world bounds, and outside
2025         // solid, and don't start from somewhere where you can
2026         // fall down to evil
2027         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2028         if (trace_fraction >= 1)
2029             continue;
2030         if (trace_startsolid)
2031             continue;
2032         if (trace_dphitcontents & badcontents)
2033             continue;
2034         if (trace_dphitq3surfaceflags & badsurfaceflags)
2035             continue;
2036
2037         // rule 2: if we are too high, lower the point
2038         if (trace_fraction * delta_z > maxaboveground)
2039             start = trace_endpos + '0 0 1' * maxaboveground;
2040         enddown = trace_endpos;
2041
2042         // rule 3: make sure we aren't outside the map. This only works
2043         // for somewhat well formed maps. A good rule of thumb is that
2044         // the map should have a convex outside hull.
2045         // these can be traceLINES as we already verified the starting box
2046         mstart = start + 0.5 * (e.mins + e.maxs);
2047         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2048         if (trace_fraction >= 1)
2049             continue;
2050         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2051         if (trace_fraction >= 1)
2052             continue;
2053         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2054         if (trace_fraction >= 1)
2055             continue;
2056         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2057         if (trace_fraction >= 1)
2058             continue;
2059         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2060         if (trace_fraction >= 1)
2061             continue;
2062
2063         // rule 4: we must "see" some spawnpoint
2064         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2065                 if(checkpvs(mstart, sp))
2066                         break;
2067         if(!sp)
2068         {
2069                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2070                         if(checkpvs(mstart, sp))
2071                                 break;
2072                 if(!sp)
2073                         continue;
2074         }
2075
2076         // find a random vector to "look at"
2077         end_x = org_x + random() * delta_x;
2078         end_y = org_y + random() * delta_y;
2079         end_z = org_z + random() * delta_z;
2080         end = start + normalize(end - start) * vlen(delta);
2081
2082         // rule 4: start TO end must not be too short
2083         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2084         if (trace_startsolid)
2085             continue;
2086         if (trace_fraction < minviewdistance / vlen(delta))
2087             continue;
2088
2089         // rule 5: don't want to look at sky
2090         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2091             continue;
2092
2093         // rule 6: we must not end up in trigger_hurt
2094         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2095             continue;
2096
2097         break;
2098     }
2099
2100     e.dphitcontentsmask = m;
2101
2102     if (i < attempts)
2103     {
2104         setorigin(e, start);
2105         e.angles = vectoangles(end - start);
2106         dprint("Needed ", ftos(i + 1), " attempts\n");
2107         return TRUE;
2108     }
2109     else
2110         return FALSE;
2111 }
2112
2113 float zcurveparticles_effectno;
2114 vector zcurveparticles_start;
2115 float zcurveparticles_spd;
2116
2117 void endzcurveparticles()
2118 {
2119         if(zcurveparticles_effectno)
2120         {
2121                 // terminator
2122                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2123         }
2124         zcurveparticles_effectno = 0;
2125 }
2126
2127 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2128 {
2129         spd = bound(0, floor(spd / 16), 32767);
2130         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2131         {
2132                 endzcurveparticles();
2133                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2134                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2135                 WriteShort(MSG_BROADCAST, effectno);
2136                 WriteCoord(MSG_BROADCAST, start_x);
2137                 WriteCoord(MSG_BROADCAST, start_y);
2138                 WriteCoord(MSG_BROADCAST, start_z);
2139                 zcurveparticles_effectno = effectno;
2140                 zcurveparticles_start = start;
2141         }
2142         else
2143                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2144         WriteCoord(MSG_BROADCAST, end_x);
2145         WriteCoord(MSG_BROADCAST, end_y);
2146         WriteCoord(MSG_BROADCAST, end_z);
2147         WriteCoord(MSG_BROADCAST, end_dz);
2148         zcurveparticles_spd = spd;
2149 }
2150
2151 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2152 {
2153         float end_dz;
2154         vector vecxy, velxy;
2155
2156         vecxy = end - start;
2157         vecxy_z = 0;
2158         velxy = vel;
2159         velxy_z = 0;
2160
2161         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2162         {
2163                 endzcurveparticles();
2164                 trailparticles(world, effectno, start, end);
2165                 return;
2166         }
2167
2168         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2169         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2170 }
2171
2172 void write_recordmarker(entity pl, float tstart, float dt)
2173 {
2174     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2175
2176     // also write a marker into demo files for demotc-race-record-extractor to find
2177     stuffcmd(pl,
2178              strcat(
2179                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2180                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2181 }
2182
2183 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2184 {
2185         switch(algn)
2186         {
2187                 default:
2188                 case 3: // right
2189                         break;
2190
2191                 case 4: // left
2192                         vecs_y = -vecs_y;
2193                         break;
2194
2195                 case 1:
2196                         if(allowcenter) // 2: allow center handedness
2197                         {
2198                                 // center
2199                                 vecs_y = 0;
2200                                 vecs_z -= 2;
2201                         }
2202                         else
2203                         {
2204                                 // right
2205                         }
2206                         break;
2207
2208                 case 2:
2209                         if(allowcenter) // 2: allow center handedness
2210                         {
2211                                 // center
2212                                 vecs_y = 0;
2213                                 vecs_z -= 2;
2214                         }
2215                         else
2216                         {
2217                                 // left
2218                                 vecs_y = -vecs_y;
2219                         }
2220                         break;
2221         }
2222         return vecs;
2223 }
2224
2225 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2226 {
2227         string s;
2228         vector v;
2229
2230         if (autocvar_g_shootfromeye)
2231         {
2232                 if (visual)
2233                 {
2234                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2235                         else { vecs_y = 0; vecs_z -= 2; }
2236                 }
2237                 else
2238                 {
2239                         vecs_y = 0;
2240                         vecs_z = 0;
2241                 }
2242         }
2243         else if (autocvar_g_shootfromcenter)
2244         {
2245                 vecs_y = 0;
2246                 vecs_z -= 2;
2247         }
2248         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2249         {
2250                 v = stov(s);
2251                 if (y_is_right)
2252                         v_y = -v_y;
2253                 if (v_x != 0)
2254                         vecs_x = v_x;
2255                 vecs_y = v_y;
2256                 vecs_z = v_z;
2257         }
2258         else if (autocvar_g_shootfromclient)
2259         {
2260                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2261         }
2262         return vecs;
2263 }
2264
2265 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2266 {
2267         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2268 }
2269
2270
2271 void attach_sameorigin(entity e, entity to, string tag)
2272 {
2273     vector org, t_forward, t_left, t_up, e_forward, e_up;
2274     float tagscale;
2275
2276     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2277     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2278     t_forward = v_forward * tagscale;
2279     t_left = v_right * -tagscale;
2280     t_up = v_up * tagscale;
2281
2282     e.origin_x = org * t_forward;
2283     e.origin_y = org * t_left;
2284     e.origin_z = org * t_up;
2285
2286     // current forward and up directions
2287     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2288                 e.angles = AnglesTransform_FromVAngles(e.angles);
2289         else
2290                 e.angles = AnglesTransform_FromAngles(e.angles);
2291     fixedmakevectors(e.angles);
2292
2293     // untransform forward, up!
2294     e_forward_x = v_forward * t_forward;
2295     e_forward_y = v_forward * t_left;
2296     e_forward_z = v_forward * t_up;
2297     e_up_x = v_up * t_forward;
2298     e_up_y = v_up * t_left;
2299     e_up_z = v_up * t_up;
2300
2301     e.angles = fixedvectoangles2(e_forward, e_up);
2302     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2303                 e.angles = AnglesTransform_ToVAngles(e.angles);
2304         else
2305                 e.angles = AnglesTransform_ToAngles(e.angles);
2306
2307     setattachment(e, to, tag);
2308     setorigin(e, e.origin);
2309 }
2310
2311 void detach_sameorigin(entity e)
2312 {
2313     vector org;
2314     org = gettaginfo(e, 0);
2315     e.angles = fixedvectoangles2(v_forward, v_up);
2316     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2317                 e.angles = AnglesTransform_ToVAngles(e.angles);
2318         else
2319                 e.angles = AnglesTransform_ToAngles(e.angles);
2320     setorigin(e, org);
2321     setattachment(e, world, "");
2322     setorigin(e, e.origin);
2323 }
2324
2325 void follow_sameorigin(entity e, entity to)
2326 {
2327     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2328     e.aiment = to; // make the hole follow bmodel
2329     e.punchangle = to.angles; // the original angles of bmodel
2330     e.view_ofs = e.origin - to.origin; // relative origin
2331     e.v_angle = e.angles - to.angles; // relative angles
2332 }
2333
2334 void unfollow_sameorigin(entity e)
2335 {
2336     e.movetype = MOVETYPE_NONE;
2337 }
2338
2339 entity gettaginfo_relative_ent;
2340 vector gettaginfo_relative(entity e, float tag)
2341 {
2342     if (!gettaginfo_relative_ent)
2343     {
2344         gettaginfo_relative_ent = spawn();
2345         gettaginfo_relative_ent.effects = EF_NODRAW;
2346     }
2347     gettaginfo_relative_ent.model = e.model;
2348     gettaginfo_relative_ent.modelindex = e.modelindex;
2349     gettaginfo_relative_ent.frame = e.frame;
2350     return gettaginfo(gettaginfo_relative_ent, tag);
2351 }
2352
2353 .float scale2;
2354
2355 float modeleffect_SendEntity(entity to, float sf)
2356 {
2357         float f;
2358         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2359
2360         f = 0;
2361         if(self.velocity != '0 0 0')
2362                 f |= 1;
2363         if(self.angles != '0 0 0')
2364                 f |= 2;
2365         if(self.avelocity != '0 0 0')
2366                 f |= 4;
2367
2368         WriteByte(MSG_ENTITY, f);
2369         WriteShort(MSG_ENTITY, self.modelindex);
2370         WriteByte(MSG_ENTITY, self.skin);
2371         WriteByte(MSG_ENTITY, self.frame);
2372         WriteCoord(MSG_ENTITY, self.origin_x);
2373         WriteCoord(MSG_ENTITY, self.origin_y);
2374         WriteCoord(MSG_ENTITY, self.origin_z);
2375         if(f & 1)
2376         {
2377                 WriteCoord(MSG_ENTITY, self.velocity_x);
2378                 WriteCoord(MSG_ENTITY, self.velocity_y);
2379                 WriteCoord(MSG_ENTITY, self.velocity_z);
2380         }
2381         if(f & 2)
2382         {
2383                 WriteCoord(MSG_ENTITY, self.angles_x);
2384                 WriteCoord(MSG_ENTITY, self.angles_y);
2385                 WriteCoord(MSG_ENTITY, self.angles_z);
2386         }
2387         if(f & 4)
2388         {
2389                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2390                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2391                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2392         }
2393         WriteShort(MSG_ENTITY, self.scale * 256.0);
2394         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2395         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2396         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2397         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2398
2399         return TRUE;
2400 }
2401
2402 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2403 {
2404         entity e;
2405         float sz;
2406         e = spawn();
2407         e.classname = "modeleffect";
2408         setmodel(e, m);
2409         e.frame = f;
2410         setorigin(e, o);
2411         e.velocity = v;
2412         e.angles = ang;
2413         e.avelocity = angv;
2414         e.alpha = a;
2415         e.teleport_time = t1;
2416         e.fade_time = t2;
2417         e.skin = s;
2418         if(s0 >= 0)
2419                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2420         else
2421                 e.scale = -s0;
2422         if(s2 >= 0)
2423                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2424         else
2425                 e.scale2 = -s2;
2426         sz = max(e.scale, e.scale2);
2427         setsize(e, e.mins * sz, e.maxs * sz);
2428         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2429 }
2430
2431 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2432 {
2433         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2434 }
2435
2436 float randombit(float bits)
2437 {
2438         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2439                 return bits;
2440
2441         float n, f, b, r;
2442
2443         r = random();
2444         b = 0;
2445         n = 0;
2446
2447         for(f = 1; f <= bits; f *= 2)
2448         {
2449                 if(bits & f)
2450                 {
2451                         ++n;
2452                         r *= n;
2453                         if(r <= 1)
2454                                 b = f;
2455                         else
2456                                 r = (r - 1) / (n - 1);
2457                 }
2458         }
2459
2460         return b;
2461 }
2462
2463 float randombits(float bits, float k, float error_return)
2464 {
2465         float r;
2466         r = 0;
2467         while(k > 0 && bits != r)
2468         {
2469                 r += randombit(bits - r);
2470                 --k;
2471         }
2472         if(error_return)
2473                 if(k > 0)
2474                         return -1; // all
2475         return r;
2476 }
2477
2478 void randombit_test(float bits, float iter)
2479 {
2480         while(iter > 0)
2481         {
2482                 print(ftos(randombit(bits)), "\n");
2483                 --iter;
2484         }
2485 }
2486
2487 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2488 {
2489         if(halflifedist > 0)
2490                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2491         else if(halflifedist < 0)
2492                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2493         else
2494                 return 1;
2495 }
2496
2497
2498
2499
2500 #ifdef RELEASE
2501 #define cvar_string_normal builtin_cvar_string
2502 #define cvar_normal builtin_cvar
2503 #else
2504 string cvar_string_normal(string n)
2505 {
2506         if not(cvar_type(n) & 1)
2507                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2508         return builtin_cvar_string(n);
2509 }
2510
2511 float cvar_normal(string n)
2512 {
2513         return stof(cvar_string_normal(n));
2514 }
2515 #endif
2516 #define cvar_set_normal builtin_cvar_set
2517
2518 void defer_think()
2519 {
2520     entity oself;
2521
2522     oself           = self;
2523     self            = self.owner;
2524     oself.think     = SUB_Remove;
2525     oself.nextthink = time;
2526
2527     oself.use();
2528 }
2529
2530 /*
2531     Execute func() after time + fdelay.
2532     self when func is executed = self when defer is called
2533 */
2534 void defer(float fdelay, void() func)
2535 {
2536     entity e;
2537
2538     e           = spawn();
2539     e.owner     = self;
2540     e.use       = func;
2541     e.think     = defer_think;
2542     e.nextthink = time + fdelay;
2543 }
2544
2545 .string aiment_classname;
2546 .float aiment_deadflag;
2547 void SetMovetypeFollow(entity ent, entity e)
2548 {
2549         // FIXME this may not be warpzone aware
2550         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2551         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2552         ent.aiment = e; // make the hole follow bmodel
2553         ent.punchangle = e.angles; // the original angles of bmodel
2554         ent.view_ofs = ent.origin - e.origin; // relative origin
2555         ent.v_angle = ent.angles - e.angles; // relative angles
2556         ent.aiment_classname = strzone(e.classname);
2557         ent.aiment_deadflag = e.deadflag;
2558 }
2559 void UnsetMovetypeFollow(entity ent)
2560 {
2561         ent.movetype = MOVETYPE_FLY;
2562         PROJECTILE_MAKETRIGGER(ent);
2563         ent.aiment = world;
2564 }
2565 float LostMovetypeFollow(entity ent)
2566 {
2567 /*
2568         if(ent.movetype != MOVETYPE_FOLLOW)
2569                 if(ent.aiment)
2570                         error("???");
2571 */
2572         if(ent.aiment)
2573         {
2574                 if(ent.aiment.classname != ent.aiment_classname)
2575                         return 1;
2576                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2577                         return 1;
2578         }
2579         return 0;
2580 }
2581
2582 float isPushable(entity e)
2583 {
2584         if(e.iscreature)
2585                 return TRUE;
2586         if(e.pushable)
2587                 return TRUE;
2588         switch(e.classname)
2589         {
2590                 case "body":
2591                 case "droppedweapon":
2592                 case "keepawayball":
2593                 case "nexball_basketball":
2594                 case "nexball_football":
2595                         return TRUE;
2596                 case "bullet": // antilagged bullets can't hit this either
2597                         return FALSE;
2598         }
2599         if (e.projectiledeathtype)
2600                 return TRUE;
2601         return FALSE;
2602 }