qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(cvar_string("sv_adminnick") != "")
  25                 return cvar_string("sv_adminnick");
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(cvar("sv_fragmessage_information_ping")) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(cvar("sv_fragmessage_information_handicap"))
 104                         if(cvar("sv_fragmessage_information_handicap") == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(cvar("sv_fragmessage_information_handicap")) {
 114                 if(cvar("sv_fragmessage_information_handicap") == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (cvar("sv_eventlog_files"))
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = cvar("sv_eventlog_files_counter") + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (cvar("sv_eventlog_files_timestamps"))
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (cvar("sv_eventlog_console"))
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 193     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 194     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 195     PL_HEAD                                 = stov(cvar_string("sv_player_headsize"));
 196     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 197     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 198     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (cvar("r_showbboxes"))
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471                 else if (escape == "v") {
 472                         float weapon_number;
 473                         local entity stats;
 474
 475                         if(self.classname == "spectator")
 476                                 stats = self.enemy;
 477                         else
 478                                 stats = self;
 479
 480                         weapon_number = stats.weapon;
 481
 482                         if (!weapon_number)
 483                                 weapon_number = stats.switchweapon;
 484
 485                         if (!weapon_number)
 486                                 weapon_number = stats.cnt;
 487
 488                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 489                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 490                         else
 491                                 replacement = "~"; // or something to indicate NULL, not available
 492                 }
 493
 494                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 495                 p = p + strlen(replacement);
 496         }
 497         return msg;
 498 }
 499
 500 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 501         return (value == 0) ? FALSE : TRUE;
 502 }
 503
 504 /*
 505 =============
 506 GetCvars
 507 =============
 508 Called with:
 509   0:  sends the request
 510   >0: receives a cvar from name=argv(f) value=argv(f+1)
 511 */
 512 void GetCvars_handleString(string thisname, float f, .string field, string name)
 513 {
 514         if (f < 0)
 515         {
 516                 if (self.field)
 517                         strunzone(self.field);
 518                 self.field = string_null;
 519         }
 520         else if (f > 0)
 521         {
 522                 if (thisname == name)
 523                 {
 524                         if (self.field)
 525                                 strunzone(self.field);
 526                         self.field = strzone(argv(f + 1));
 527                 }
 528         }
 529         else
 530                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 531 }
 532 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 533 {
 534         GetCvars_handleString(thisname, f, field, name);
 535         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 536                 if (thisname == name)
 537                 {
 538                         string s;
 539                         s = func(strcat1(self.field));
 540                         if (s != self.field)
 541                         {
 542                                 strunzone(self.field);
 543                                 self.field = strzone(s);
 544                         }
 545                 }
 546 }
 547 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 548 {
 549         if (f < 0)
 550         {
 551         }
 552         else if (f > 0)
 553         {
 554                 if (thisname == name)
 555                         self.field = stof(argv(f + 1));
 556         }
 557         else
 558                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559 }
 560 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 561 {
 562         if (f < 0)
 563         {
 564         }
 565         else if (f > 0)
 566         {
 567                 if (thisname == name)
 568                 {
 569                         if(!self.field)
 570                         {
 571                                 self.field = stof(argv(f + 1));
 572                                 if(!self.field)
 573                                         self.field = -1;
 574                         }
 575                 }
 576         }
 577         else
 578         {
 579                 if(!self.field)
 580                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 581         }
 582 }
 583 float w_getbestweapon(entity e);
 584 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 585 {
 586         string o;
 587         o = W_FixWeaponOrder_ForceComplete(wo);
 588         if(self.weaponorder_byimpulse)
 589         {
 590                 strunzone(self.weaponorder_byimpulse);
 591                 self.weaponorder_byimpulse = string_null;
 592         }
 593         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 594         return o;
 595 }
 596 void GetCvars(float f)
 597 {
 598         string s;
 599
 600         if (f > 0)
 601                 s = strcat1(argv(f));
 602
 603         get_cvars_f = f;
 604         get_cvars_s = s;
 605         MUTATOR_CALLHOOK(GetCvars);
 606         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 607         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 608         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 609         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 610         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 611         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 613         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 614         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 615         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 616         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 617         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 618         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 619         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 620         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 621         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 622         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 623         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 624         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 625         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 626         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 627         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 628         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 629         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 630         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 631
 632         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 633         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 634
 635 #ifdef ALLOW_FORCEMODELS
 636         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 637         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 638 #endif
 639         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 640         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 641
 642         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 643         if (f > 0)
 644         {
 645                 if (s == "cl_weaponpriority")
 646                         self.switchweapon = w_getbestweapon(self);
 647         }
 648 }
 649
 650 float fexists(string f)
 651 {
 652     float fh;
 653     fh = fopen(f, FILE_READ);
 654     if (fh < 0)
 655         return FALSE;
 656     fclose(fh);
 657     return TRUE;
 658 }
 659
 660 void backtrace(string msg)
 661 {
 662     float dev, war;
 663     dev = cvar("developer");
 664     war = cvar("prvm_backtraceforwarnings");
 665     cvar_set("developer", "1");
 666     cvar_set("prvm_backtraceforwarnings", "1");
 667     print("\n");
 668     print("--- CUT HERE ---\nWARNING: ");
 669     print(msg);
 670     print("\n");
 671     remove(world); // isn't there any better way to cause a backtrace?
 672     print("\n--- CUT UNTIL HERE ---\n");
 673     cvar_set("developer", ftos(dev));
 674     cvar_set("prvm_backtraceforwarnings", ftos(war));
 675 }
 676
 677 string Team_ColorCode(float teamid)
 678 {
 679     if (teamid == COLOR_TEAM1)
 680         return "^1";
 681     else if (teamid == COLOR_TEAM2)
 682         return "^4";
 683     else if (teamid == COLOR_TEAM3)
 684         return "^3";
 685     else if (teamid == COLOR_TEAM4)
 686         return "^6";
 687     else
 688         return "^7";
 689 }
 690
 691 string Team_ColorName(float t)
 692 {
 693     // fixme: Search for team entities and get their .netname's!
 694     if (t == COLOR_TEAM1)
 695         return "Red";
 696     if (t == COLOR_TEAM2)
 697         return "Blue";
 698     if (t == COLOR_TEAM3)
 699         return "Yellow";
 700     if (t == COLOR_TEAM4)
 701         return "Pink";
 702     return "Neutral";
 703 }
 704
 705 string Team_ColorNameLowerCase(float t)
 706 {
 707     // fixme: Search for team entities and get their .netname's!
 708     if (t == COLOR_TEAM1)
 709         return "red";
 710     if (t == COLOR_TEAM2)
 711         return "blue";
 712     if (t == COLOR_TEAM3)
 713         return "yellow";
 714     if (t == COLOR_TEAM4)
 715         return "pink";
 716     return "neutral";
 717 }
 718
 719 float ColourToNumber(string team_colour)
 720 {
 721         if (team_colour == "red")
 722                 return COLOR_TEAM1;
 723
 724         if (team_colour == "blue")
 725                 return COLOR_TEAM2;
 726
 727         if (team_colour == "yellow")
 728                 return COLOR_TEAM3;
 729
 730         if (team_colour == "pink")
 731                 return COLOR_TEAM4;
 732
 733         if (team_colour == "auto")
 734                 return 0;
 735
 736         return -1;
 737 }
 738
 739 float NumberToTeamNumber(float number)
 740 {
 741         if (number == 1)
 742                 return COLOR_TEAM1;
 743
 744         if (number == 2)
 745                 return COLOR_TEAM2;
 746
 747         if (number == 3)
 748                 return COLOR_TEAM3;
 749
 750         if (number == 4)
 751                 return COLOR_TEAM4;
 752
 753         return -1;
 754 }
 755
 756 #define CENTERPRIO_POINT 1
 757 #define CENTERPRIO_SPAM 2
 758 #define CENTERPRIO_VOTE 4
 759 #define CENTERPRIO_NORMAL 5
 760 #define CENTERPRIO_SHIELDING 7
 761 #define CENTERPRIO_MAPVOTE 9
 762 #define CENTERPRIO_IDLEKICK 50
 763 #define CENTERPRIO_ADMIN 99
 764 .float centerprint_priority;
 765 .float centerprint_expires;
 766 void centerprint_atprio(entity e, float prio, string s)
 767 {
 768     if (intermission_running)
 769         if (prio < CENTERPRIO_MAPVOTE)
 770             return;
 771     if (time > e.centerprint_expires)
 772         e.centerprint_priority = 0;
 773     if (prio >= e.centerprint_priority)
 774     {
 775         e.centerprint_priority = prio;
 776         if (timeoutStatus == 2)
 777             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 778         else
 779             e.centerprint_expires = time + e.cvar_scr_centertime;
 780         centerprint_builtin(e, s);
 781     }
 782 }
 783 void centerprint_expire(entity e, float prio)
 784 {
 785     if (prio == e.centerprint_priority)
 786     {
 787         e.centerprint_priority = 0;
 788         centerprint_builtin(e, "");
 789     }
 790 }
 791 void centerprint(entity e, string s)
 792 {
 793     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 794 }
 795
 796 // decolorizes and team colors the player name when needed
 797 string playername(entity p)
 798 {
 799     string t;
 800     if (teams_matter && !intermission_running && p.classname == "player")
 801     {
 802         t = Team_ColorCode(p.team);
 803         return strcat(t, strdecolorize(p.netname));
 804     }
 805     else
 806         return p.netname;
 807 }
 808
 809 vector randompos(vector m1, vector m2)
 810 {
 811     local vector v;
 812     m2 = m2 - m1;
 813     v_x = m2_x * random() + m1_x;
 814     v_y = m2_y * random() + m1_y;
 815     v_z = m2_z * random() + m1_z;
 816     return  v;
 817 };
 818
 819 float g_pickup_shells;
 820 float g_pickup_shells_max;
 821 float g_pickup_nails;
 822 float g_pickup_nails_max;
 823 float g_pickup_rockets;
 824 float g_pickup_rockets_max;
 825 float g_pickup_cells;
 826 float g_pickup_cells_max;
 827 float g_pickup_fuel;
 828 float g_pickup_fuel_jetpack;
 829 float g_pickup_fuel_max;
 830 float g_pickup_armorsmall;
 831 float g_pickup_armorsmall_max;
 832 float g_pickup_armorsmall_anyway;
 833 float g_pickup_armormedium;
 834 float g_pickup_armormedium_max;
 835 float g_pickup_armormedium_anyway;
 836 float g_pickup_armorbig;
 837 float g_pickup_armorbig_max;
 838 float g_pickup_armorbig_anyway;
 839 float g_pickup_armorlarge;
 840 float g_pickup_armorlarge_max;
 841 float g_pickup_armorlarge_anyway;
 842 float g_pickup_healthsmall;
 843 float g_pickup_healthsmall_max;
 844 float g_pickup_healthsmall_anyway;
 845 float g_pickup_healthmedium;
 846 float g_pickup_healthmedium_max;
 847 float g_pickup_healthmedium_anyway;
 848 float g_pickup_healthlarge;
 849 float g_pickup_healthlarge_max;
 850 float g_pickup_healthlarge_anyway;
 851 float g_pickup_healthmega;
 852 float g_pickup_healthmega_max;
 853 float g_pickup_healthmega_anyway;
 854 float g_pickup_ammo_anyway;
 855 float g_pickup_weapons_anyway;
 856 float g_weaponarena;
 857 float g_weaponarena_random;
 858 float g_weaponarena_random_with_laser;
 859 string g_weaponarena_list;
 860 float g_weaponspeedfactor;
 861 float g_weaponratefactor;
 862 float g_weapondamagefactor;
 863 float g_weaponforcefactor;
 864 float g_weaponspreadfactor;
 865
 866 float start_weapons;
 867 float start_items;
 868 float start_ammo_shells;
 869 float start_ammo_nails;
 870 float start_ammo_rockets;
 871 float start_ammo_cells;
 872 float start_ammo_fuel;
 873 float start_health;
 874 float start_armorvalue;
 875 float warmup_start_weapons;
 876 float warmup_start_ammo_shells;
 877 float warmup_start_ammo_nails;
 878 float warmup_start_ammo_rockets;
 879 float warmup_start_ammo_cells;
 880 float warmup_start_ammo_fuel;
 881 float warmup_start_health;
 882 float warmup_start_armorvalue;
 883 float g_weapon_stay;
 884 float g_ghost_items;
 885
 886 entity get_weaponinfo(float w);
 887
 888 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 889 {
 890         var float i = weaponinfo.weapon;
 891
 892         if (!i)
 893                 return 0;
 894
 895         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 896
 897         if (t < 0) // "default" weapon selection
 898         {
 899                 if (g_lms || g_ca || allguns)
 900                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 901                 else if(t < -1)
 902                         t = 0;
 903                 else if (g_race || g_cts)
 904                         t = (i == WEP_LASER);
 905                 else if (g_nexball)
 906                         t = 0; // weapon is set a few lines later
 907                 else
 908                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 909                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 910                         t |= (i == WEP_HOOK);
 911         }
 912
 913         // we cannot disable porto in Nexball, we must force it
 914         if(g_nexball && i == WEP_PORTO)
 915                 t = 1;
 916
 917         return t;
 918 }
 919
 920 void readplayerstartcvars()
 921 {
 922         entity e;
 923         float i, j, t;
 924         string s;
 925
 926         // initialize starting values for players
 927         start_weapons = 0;
 928         start_items = 0;
 929         start_ammo_shells = 0;
 930         start_ammo_nails = 0;
 931         start_ammo_rockets = 0;
 932         start_ammo_cells = 0;
 933         start_health = cvar("g_balance_health_start");
 934         start_armorvalue = cvar("g_balance_armor_start");
 935
 936         g_weaponarena = 0;
 937         s = cvar_string("g_weaponarena");
 938         if (s == "0")
 939         {
 940         }
 941         else if (s == "all")
 942         {
 943                 g_weaponarena_list = "All Weapons";
 944                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 945                 {
 946                         e = get_weaponinfo(j);
 947                         g_weaponarena |= e.weapons;
 948                         weapon_action(e.weapon, WR_PRECACHE);
 949                 }
 950         }
 951         else if (s == "most")
 952         {
 953                 g_weaponarena_list = "Most Weapons";
 954                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 955                 {
 956                         e = get_weaponinfo(j);
 957                         if (e.spawnflags & WEP_FLAG_NORMAL)
 958                         {
 959                                 g_weaponarena |= e.weapons;
 960                                 weapon_action(e.weapon, WR_PRECACHE);
 961                         }
 962                 }
 963         }
 964         else if (s == "none")
 965         {
 966                 g_weaponarena_list = "No Weapons";
 967                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 968         }
 969         else
 970         {
 971                 t = tokenize_console(s);
 972                 g_weaponarena_list = "";
 973                 for (i = 0; i < t; ++i)
 974                 {
 975                         s = argv(i);
 976                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 977                         {
 978                                 e = get_weaponinfo(j);
 979                                 if (e.netname == s)
 980                                 {
 981                                         g_weaponarena |= e.weapons;
 982                                         weapon_action(e.weapon, WR_PRECACHE);
 983                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 984                                         break;
 985                                 }
 986                         }
 987                         if (j > WEP_LAST)
 988                         {
 989                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 990                         }
 991                 }
 992                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 993         }
 994
 995         if(g_weaponarena)
 996                 g_weaponarena_random = cvar("g_weaponarena_random");
 997         else
 998                 g_weaponarena_random = 0;
 999         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
1000
1001         if (g_weaponarena)
1002         {
1003                 start_weapons = g_weaponarena;
1004                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
1005                         start_ammo_rockets = 999;
1006                 if (g_weaponarena & WEPBIT_SHOTGUN)
1007                         start_ammo_shells = 999;
1008                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
1009                         start_ammo_cells = 999;
1010                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
1011                         start_ammo_nails = 999;
1012                 if (g_weaponarena & WEPBIT_HOOK)
1013                         start_ammo_fuel = 999;
1014                 start_items |= IT_UNLIMITED_AMMO;
1015         }
1016         else if (g_minstagib)
1017         {
1018                 start_health = 100;
1019                 start_armorvalue = 0;
1020                 start_weapons = WEPBIT_MINSTANEX;
1021                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1022                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1023                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1024                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1025
1026                 if (g_minstagib_invis_alpha <= 0)
1027                         g_minstagib_invis_alpha = -1;
1028         }
1029         else
1030         {
1031                 if (g_lms || g_ca)
1032                 {
1033                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1034                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1035                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1036                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1037                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1038                         start_health = cvar("g_lms_start_health");
1039                         start_armorvalue = cvar("g_lms_start_armor");
1040                 }
1041                 else
1042                 {
1043                         start_ammo_shells = cvar("g_start_ammo_shells");
1044                         start_ammo_nails = cvar("g_start_ammo_nails");
1045                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1046                         start_ammo_cells = cvar("g_start_ammo_cells");
1047                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1048                 }
1049
1050                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1051                 {
1052                         e = get_weaponinfo(i);
1053                         if(want_weapon("g_start_weapon_", e, FALSE))
1054                                 start_weapons |= e.weapons;
1055                 }
1056         }
1057
1058         if (inWarmupStage)
1059         {
1060                 warmup_start_ammo_shells = start_ammo_shells;
1061                 warmup_start_ammo_nails = start_ammo_nails;
1062                 warmup_start_ammo_rockets = start_ammo_rockets;
1063                 warmup_start_ammo_cells = start_ammo_cells;
1064                 warmup_start_ammo_fuel = start_ammo_fuel;
1065                 warmup_start_health = start_health;
1066                 warmup_start_armorvalue = start_armorvalue;
1067                 warmup_start_weapons = start_weapons;
1068
1069                 if (!g_weaponarena && !g_minstagib && !g_ca)
1070                 {
1071                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1072                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1073                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1074                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1075                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1076                         warmup_start_health = cvar("g_warmup_start_health");
1077                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1078                         warmup_start_weapons = 0;
1079                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1080                         {
1081                                 e = get_weaponinfo(i);
1082                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1083                                         warmup_start_weapons |= e.weapons;
1084                         }
1085                 }
1086         }
1087
1088         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1089         {
1090                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1091                 start_items |= IT_FUEL_REGEN;
1092                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1093                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1094         }
1095
1096         if(!cvar("g_use_ammunition"))
1097         {
1098                 start_ammo_shells = cvar("g_pickup_shells_max");
1099                 start_ammo_nails = cvar("g_pickup_nails_max");
1100                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1101                 start_ammo_cells = cvar("g_pickup_cells_max");
1102                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1103                 start_items |= IT_UNLIMITED_AMMO;
1104                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1105                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1106                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1107                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1108                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1109                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1110         }
1111
1112         if (g_jetpack)
1113                 start_items |= IT_JETPACK;
1114
1115         if (g_weapon_stay == 2)
1116         {
1117                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1118                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1119                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1120                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1121                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1122                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1123                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1124                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1125                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1126                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1127         }
1128
1129         MUTATOR_CALLHOOK(SetStartItems);
1130
1131         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1132         {
1133                 e = get_weaponinfo(i);
1134                 if(e.weapons & (start_weapons | warmup_start_weapons))
1135                         weapon_action(e.weapon, WR_PRECACHE);
1136         }
1137
1138         start_ammo_shells = max(0, start_ammo_shells);
1139         start_ammo_nails = max(0, start_ammo_nails);
1140         start_ammo_cells = max(0, start_ammo_cells);
1141         start_ammo_rockets = max(0, start_ammo_rockets);
1142         start_ammo_fuel = max(0, start_ammo_fuel);
1143
1144         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1145         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1146         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1147         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1148         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1149 }
1150
1151 float g_bugrigs;
1152 float g_bugrigs_planar_movement;
1153 float g_bugrigs_planar_movement_car_jumping;
1154 float g_bugrigs_reverse_spinning;
1155 float g_bugrigs_reverse_speeding;
1156 float g_bugrigs_reverse_stopping;
1157 float g_bugrigs_air_steering;
1158 float g_bugrigs_angle_smoothing;
1159 float g_bugrigs_friction_floor;
1160 float g_bugrigs_friction_brake;
1161 float g_bugrigs_friction_air;
1162 float g_bugrigs_accel;
1163 float g_bugrigs_speed_ref;
1164 float g_bugrigs_speed_pow;
1165 float g_bugrigs_steer;
1166
1167 float g_touchexplode;
1168 float g_touchexplode_radius;
1169 float g_touchexplode_damage;
1170 float g_touchexplode_edgedamage;
1171 float g_touchexplode_force;
1172
1173 float sv_autotaunt;
1174 float sv_taunt;
1175
1176 float sv_pitch_min;
1177 float sv_pitch_max;
1178 float sv_pitch_fixyaw;
1179
1180 float sv_accuracy_data_share;
1181
1182 void readlevelcvars(void)
1183 {
1184         // first load all the mutators
1185         if(cvar("g_nix"))
1186                 MUTATOR_ADD(mutator_nix);
1187         if(cvar("g_dodging"))
1188                 MUTATOR_ADD(mutator_dodging);
1189         if(cvar("g_rocket_flying"))
1190                 MUTATOR_ADD(mutator_rocketflying);
1191         if(cvar("g_vampire"))
1192                 MUTATOR_ADD(mutator_vampire);
1193
1194         serverflags = 0;
1195         if(cvar("sv_allow_fullbright"))
1196                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1197
1198     g_bugrigs = cvar("g_bugrigs");
1199     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1200     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1201     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1202     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1203     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1204     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1205     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1206     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1207     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1208     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1209     g_bugrigs_accel = cvar("g_bugrigs_accel");
1210     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1211     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1212     g_bugrigs_steer = cvar("g_bugrigs_steer");
1213
1214     g_touchexplode = cvar("g_touchexplode");
1215     g_touchexplode_radius = cvar("g_touchexplode_radius");
1216     g_touchexplode_damage = cvar("g_touchexplode_damage");
1217     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1218     g_touchexplode_force = cvar("g_touchexplode_force");
1219
1220 #ifdef ALLOW_FORCEMODELS
1221         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1222 #endif
1223         sv_loddistance1 = cvar("sv_loddistance1");
1224         sv_loddistance2 = cvar("sv_loddistance2");
1225
1226         if(sv_loddistance2 <= sv_loddistance1)
1227                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1228
1229         sv_clones = cvar("sv_clones");
1230         sv_gentle = cvar("sv_gentle");
1231         sv_foginterval = cvar("sv_foginterval");
1232         g_cloaked = cvar("g_cloaked");
1233         g_jump_grunt = cvar("g_jump_grunt");
1234         g_footsteps = cvar("g_footsteps");
1235         g_grappling_hook = cvar("g_grappling_hook");
1236         g_jetpack = cvar("g_jetpack");
1237         g_midair = cvar("g_midair");
1238         g_minstagib = cvar("g_minstagib");
1239         g_norecoil = cvar("g_norecoil");
1240         g_bloodloss = cvar("g_bloodloss");
1241         sv_maxidle = cvar("sv_maxidle");
1242         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1243         sv_pogostick = cvar("sv_pogostick");
1244         g_ctf_reverse = cvar("g_ctf_reverse");
1245         sv_autotaunt = cvar("sv_autotaunt");
1246         sv_taunt = cvar("sv_taunt");
1247
1248         inWarmupStage = cvar("g_warmup");
1249         g_warmup_limit = cvar("g_warmup_limit");
1250         g_warmup_allguns = cvar("g_warmup_allguns");
1251         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1252
1253         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1254                 inWarmupStage = 0; // these modes cannot work together, sorry
1255
1256         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1257         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1258         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1259         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1260         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1261         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1262         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1263         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1264         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1265         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1266         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1267         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1268
1269         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1270         g_weaponratefactor = cvar("g_weaponratefactor");
1271         g_weapondamagefactor = cvar("g_weapondamagefactor");
1272         g_weaponforcefactor = cvar("g_weaponforcefactor");
1273         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1274
1275         g_pickup_shells = cvar("g_pickup_shells");
1276         g_pickup_shells_max = cvar("g_pickup_shells_max");
1277         g_pickup_nails = cvar("g_pickup_nails");
1278         g_pickup_nails_max = cvar("g_pickup_nails_max");
1279         g_pickup_rockets = cvar("g_pickup_rockets");
1280         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1281         g_pickup_cells = cvar("g_pickup_cells");
1282         g_pickup_cells_max = cvar("g_pickup_cells_max");
1283         g_pickup_fuel = cvar("g_pickup_fuel");
1284         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1285         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1286         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1287         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1288         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1289         g_pickup_armormedium = cvar("g_pickup_armormedium");
1290         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1291         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1292         g_pickup_armorbig = cvar("g_pickup_armorbig");
1293         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1294         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1295         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1296         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1297         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1298         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1299         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1300         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1301         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1302         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1303         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1304         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1305         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1306         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1307         g_pickup_healthmega = cvar("g_pickup_healthmega");
1308         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1309         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1310
1311         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1312         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1313
1314         g_pinata = cvar("g_pinata");
1315
1316         g_weapon_stay = cvar("g_weapon_stay");
1317
1318         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1319                 g_weapon_stay = 1;
1320
1321         g_ghost_items = cvar("g_ghost_items");
1322
1323         if(g_ghost_items >= 1)
1324                 g_ghost_items = 0.25; // default alpha value
1325
1326         if not(inWarmupStage && !g_ca)
1327                 game_starttime = cvar("g_start_delay");
1328
1329         sv_pitch_min = cvar("sv_pitch_min");
1330         sv_pitch_max = cvar("sv_pitch_max");
1331         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1332
1333         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1334
1335         readplayerstartcvars();
1336 }
1337
1338 /*
1339 // TODO sound pack system
1340 string soundpack;
1341
1342 string precache_sound_builtin (string s) = #19;
1343 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1344 string precache_sound(string s)
1345 {
1346         return precache_sound_builtin(strcat(soundpack, s));
1347 }
1348 void play2(entity e, string filename)
1349 {
1350         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1351 }
1352 void sound(entity e, float chan, string samp, float vol, float atten)
1353 {
1354         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1355 }
1356 */
1357
1358 // Sound functions
1359 string precache_sound (string s) = #19;
1360 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1361 float precache_sound_index (string s) = #19;
1362
1363 #define SND_VOLUME      1
1364 #define SND_ATTENUATION 2
1365 #define SND_LARGEENTITY 8
1366 #define SND_LARGESOUND  16
1367
1368 float sound_allowed(float dest, entity e)
1369 {
1370     // sounds from world may always pass
1371     for (;;)
1372     {
1373         if (e.classname == "body")
1374             e = e.enemy;
1375         if (e.owner && e.owner != e)
1376             e = e.owner;
1377         else
1378             break;
1379     }
1380     // sounds to self may always pass
1381     if (dest == MSG_ONE)
1382         if (e == msg_entity)
1383             return TRUE;
1384     // sounds by players can be removed
1385     if (cvar("bot_sound_monopoly"))
1386         if (clienttype(e) == CLIENTTYPE_REAL)
1387             return FALSE;
1388     // anything else may pass
1389     return TRUE;
1390 }
1391
1392 void sound(entity e, float chan, string samp, float vol, float atten)
1393 {
1394     if (!sound_allowed(MSG_BROADCAST, e))
1395         return;
1396     sound_builtin(e, chan, samp, vol, atten);
1397 }
1398 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1399 {
1400     float entno, idx;
1401
1402     if (!sound_allowed(dest, e))
1403         return;
1404
1405     entno = num_for_edict(e);
1406     idx = precache_sound_index(samp);
1407
1408     float sflags;
1409     sflags = 0;
1410
1411     atten = floor(atten * 64);
1412     vol = floor(vol * 255);
1413
1414     if (vol != 255)
1415         sflags |= SND_VOLUME;
1416     if (atten != 64)
1417         sflags |= SND_ATTENUATION;
1418     if (entno >= 8192)
1419         sflags |= SND_LARGEENTITY;
1420     if (idx >= 256)
1421         sflags |= SND_LARGESOUND;
1422
1423     WriteByte(dest, SVC_SOUND);
1424     WriteByte(dest, sflags);
1425     if (sflags & SND_VOLUME)
1426         WriteByte(dest, vol);
1427     if (sflags & SND_ATTENUATION)
1428         WriteByte(dest, atten);
1429     if (sflags & SND_LARGEENTITY)
1430     {
1431         WriteShort(dest, entno);
1432         WriteByte(dest, chan);
1433     }
1434     else
1435     {
1436         WriteShort(dest, entno * 8 + chan);
1437     }
1438     if (sflags & SND_LARGESOUND)
1439         WriteShort(dest, idx);
1440     else
1441         WriteByte(dest, idx);
1442
1443     WriteCoord(dest, o_x);
1444     WriteCoord(dest, o_y);
1445     WriteCoord(dest, o_z);
1446 }
1447 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1448 {
1449     vector o;
1450
1451     if (!sound_allowed(dest, e))
1452         return;
1453
1454     o = e.origin + 0.5 * (e.mins + e.maxs);
1455     soundtoat(dest, e, o, chan, samp, vol, atten);
1456 }
1457 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1458 {
1459     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1460 }
1461 void stopsoundto(float dest, entity e, float chan)
1462 {
1463     float entno;
1464
1465     if (!sound_allowed(dest, e))
1466         return;
1467
1468     entno = num_for_edict(e);
1469
1470     if (entno >= 8192)
1471     {
1472         float idx, sflags;
1473         idx = precache_sound_index("misc/null.wav");
1474         sflags = SND_LARGEENTITY;
1475         if (idx >= 256)
1476             sflags |= SND_LARGESOUND;
1477         WriteByte(dest, SVC_SOUND);
1478         WriteByte(dest, sflags);
1479         WriteShort(dest, entno);
1480         WriteByte(dest, chan);
1481         if (sflags & SND_LARGESOUND)
1482             WriteShort(dest, idx);
1483         else
1484             WriteByte(dest, idx);
1485         WriteCoord(dest, e.origin_x);
1486         WriteCoord(dest, e.origin_y);
1487         WriteCoord(dest, e.origin_z);
1488     }
1489     else
1490     {
1491         WriteByte(dest, SVC_STOPSOUND);
1492         WriteShort(dest, entno * 8 + chan);
1493     }
1494 }
1495 void stopsound(entity e, float chan)
1496 {
1497     if (!sound_allowed(MSG_BROADCAST, e))
1498         return;
1499
1500     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1501     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1502 }
1503
1504 void play2(entity e, string filename)
1505 {
1506     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1507     msg_entity = e;
1508     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1509 }
1510
1511 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1512 .float spamtime;
1513 float spamsound(entity e, float chan, string samp, float vol, float atten)
1514 {
1515     if (!sound_allowed(MSG_BROADCAST, e))
1516         return FALSE;
1517
1518     if (time > e.spamtime)
1519     {
1520         e.spamtime = time;
1521         sound(e, chan, samp, vol, atten);
1522         return TRUE;
1523     }
1524     return FALSE;
1525 }
1526
1527 void play2team(float t, string filename)
1528 {
1529     local entity head;
1530
1531     if (cvar("bot_sound_monopoly"))
1532         return;
1533
1534     FOR_EACH_REALPLAYER(head)
1535     {
1536         if (head.team == t)
1537             play2(head, filename);
1538     }
1539 }
1540
1541 void play2all(string samp)
1542 {
1543     if (cvar("bot_sound_monopoly"))
1544         return;
1545
1546     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1547 }
1548
1549 void PrecachePlayerSounds(string f);
1550 void precache_playermodel(string m)
1551 {
1552         float globhandle, i, n;
1553         string f;
1554
1555         if(substring(m, -9,5) == "_lod1")
1556                 return;
1557         if(substring(m, -9,5) == "_lod2")
1558                 return;
1559         precache_model(m);
1560         if(sv_loddistance1)
1561         {
1562                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1563                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1564         }
1565
1566         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1567         if (globhandle < 0)
1568                 return;
1569         n = search_getsize(globhandle);
1570         for (i = 0; i < n; ++i)
1571         {
1572                 //print(search_getfilename(globhandle, i), "\n");
1573                 f = search_getfilename(globhandle, i);
1574                 PrecachePlayerSounds(f);
1575         }
1576         search_end(globhandle);
1577 }
1578 void precache_all_playermodels(string pattern)
1579 {
1580         float globhandle, i, n;
1581         string f;
1582
1583         globhandle = search_begin(pattern, TRUE, FALSE);
1584         if (globhandle < 0)
1585                 return;
1586         n = search_getsize(globhandle);
1587         for (i = 0; i < n; ++i)
1588         {
1589                 //print(search_getfilename(globhandle, i), "\n");
1590                 f = search_getfilename(globhandle, i);
1591                 precache_playermodel(f);
1592         }
1593         search_end(globhandle);
1594 }
1595
1596 void precache()
1597 {
1598     // gamemode related things
1599     precache_model ("models/misc/chatbubble.spr");
1600     precache_model ("models/misc/teambubble.spr");
1601     if (g_runematch)
1602     {
1603         precache_model ("models/runematch/curse.mdl");
1604         precache_model ("models/runematch/rune.mdl");
1605     }
1606
1607 #ifdef TTURRETS_ENABLED
1608     if (cvar("g_turrets"))
1609         turrets_precash();
1610 #endif
1611
1612     // Precache all player models if desired
1613     if (cvar("sv_precacheplayermodels"))
1614     {
1615         PrecachePlayerSounds("sound/player/default.sounds");
1616         precache_all_playermodels("models/player/*.zym");
1617         precache_all_playermodels("models/player/*.dpm");
1618         precache_all_playermodels("models/player/*.md3");
1619         precache_all_playermodels("models/player/*.psk");
1620         precache_all_playermodels("models/player/*.iqm");
1621     }
1622
1623     if (cvar("sv_defaultcharacter"))
1624     {
1625         string s;
1626         s = cvar_string("sv_defaultplayermodel_red");
1627         if (s != "")
1628             precache_playermodel(s);
1629         s = cvar_string("sv_defaultplayermodel_blue");
1630         if (s != "")
1631             precache_playermodel(s);
1632         s = cvar_string("sv_defaultplayermodel_yellow");
1633         if (s != "")
1634             precache_playermodel(s);
1635         s = cvar_string("sv_defaultplayermodel_pink");
1636         if (s != "")
1637             precache_playermodel(s);
1638         s = cvar_string("sv_defaultplayermodel");
1639         if (s != "")
1640             precache_playermodel(s);
1641     }
1642
1643     if (g_footsteps)
1644     {
1645         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1646         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1647     }
1648
1649     // gore and miscellaneous sounds
1650     //precache_sound ("misc/h2ohit.wav");
1651     precache_model ("models/hook.md3");
1652     precache_sound ("misc/armorimpact.wav");
1653     precache_sound ("misc/bodyimpact1.wav");
1654     precache_sound ("misc/bodyimpact2.wav");
1655     precache_sound ("misc/gib.wav");
1656     precache_sound ("misc/gib_splat01.wav");
1657     precache_sound ("misc/gib_splat02.wav");
1658     precache_sound ("misc/gib_splat03.wav");
1659     precache_sound ("misc/gib_splat04.wav");
1660     precache_sound ("misc/hit.wav");
1661         precache_sound ("misc/typehit.wav");
1662     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1663     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1664     precache_sound ("misc/null.wav");
1665     precache_sound ("misc/spawn.wav");
1666     precache_sound ("misc/talk.wav");
1667     precache_sound ("misc/teleport.wav");
1668     precache_sound ("misc/poweroff.wav");
1669     precache_sound ("player/lava.wav");
1670     precache_sound ("player/slime.wav");
1671
1672     if (g_jetpack)
1673         precache_sound ("misc/jetpack_fly.wav");
1674
1675     precache_model ("models/sprites/0.spr32");
1676     precache_model ("models/sprites/1.spr32");
1677     precache_model ("models/sprites/2.spr32");
1678     precache_model ("models/sprites/3.spr32");
1679     precache_model ("models/sprites/4.spr32");
1680     precache_model ("models/sprites/5.spr32");
1681     precache_model ("models/sprites/6.spr32");
1682     precache_model ("models/sprites/7.spr32");
1683     precache_model ("models/sprites/8.spr32");
1684     precache_model ("models/sprites/9.spr32");
1685     precache_model ("models/sprites/10.spr32");
1686
1687     // common weapon precaches
1688     precache_sound ("weapons/weapon_switch.wav");
1689     precache_sound ("weapons/weaponpickup.wav");
1690     precache_sound ("weapons/unavailable.wav");
1691     precache_sound ("weapons/dryfire.wav");
1692     if (g_grappling_hook)
1693     {
1694         precache_sound ("weapons/hook_fire.wav"); // hook
1695         precache_sound ("weapons/hook_impact.wav"); // hook
1696     }
1697
1698     if(cvar("sv_precacheweapons"))
1699     {
1700         //precache weapon models/sounds
1701         local float wep;
1702         wep = WEP_FIRST;
1703         while (wep <= WEP_LAST)
1704         {
1705             weapon_action(wep, WR_PRECACHE);
1706             wep = wep + 1;
1707         }
1708     }
1709
1710     precache_model("models/elaser.mdl");
1711     precache_model("models/laser.mdl");
1712     precache_model("models/ebomb.mdl");
1713
1714 #if 0
1715     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1716
1717     if (!self.noise && self.music) // quake 3 uses the music field
1718         self.noise = self.music;
1719
1720     // plays music for the level if there is any
1721     if (self.noise)
1722     {
1723         precache_sound (self.noise);
1724         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1725     }
1726 #endif
1727 }
1728
1729 // sorry, but using \ in macros breaks line numbers
1730 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1731 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1732 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1733
1734 // WARNING: this kills the trace globals
1735 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1736 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1737
1738 #define INITPRIO_FIRST              0
1739 #define INITPRIO_GAMETYPE           0
1740 #define INITPRIO_GAMETYPE_FALLBACK  1
1741 #define INITPRIO_FINDTARGET        10
1742 #define INITPRIO_DROPTOFLOOR       20
1743 #define INITPRIO_SETLOCATION       90
1744 #define INITPRIO_LINKDOORS         91
1745 #define INITPRIO_LAST              99
1746
1747 .void(void) initialize_entity;
1748 .float initialize_entity_order;
1749 .entity initialize_entity_next;
1750 entity initialize_entity_first;
1751
1752 void make_safe_for_remove(entity e)
1753 {
1754     if (e.initialize_entity)
1755     {
1756         entity ent, prev;
1757         for (ent = initialize_entity_first; ent; )
1758         {
1759             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1760             {
1761                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1762                 // skip it in linked list
1763                 if (prev)
1764                 {
1765                     prev.initialize_entity_next = ent.initialize_entity_next;
1766                     ent = prev.initialize_entity_next;
1767                 }
1768                 else
1769                 {
1770                     initialize_entity_first = ent.initialize_entity_next;
1771                     ent = initialize_entity_first;
1772                 }
1773             }
1774             else
1775             {
1776                 prev = ent;
1777                 ent = ent.initialize_entity_next;
1778             }
1779         }
1780     }
1781 }
1782
1783 void objerror(string s)
1784 {
1785     make_safe_for_remove(self);
1786     objerror_builtin(s);
1787 }
1788
1789 void remove_unsafely(entity e)
1790 {
1791     remove_builtin(e);
1792 }
1793
1794 void remove_safely(entity e)
1795 {
1796     make_safe_for_remove(e);
1797     remove_builtin(e);
1798 }
1799
1800 void InitializeEntity(entity e, void(void) func, float order)
1801 {
1802     entity prev, cur;
1803
1804     if (!e || e.initialize_entity)
1805     {
1806         // make a proxy initializer entity
1807         entity e_old;
1808         e_old = e;
1809         e = spawn();
1810         e.classname = "initialize_entity";
1811         e.enemy = e_old;
1812     }
1813
1814     e.initialize_entity = func;
1815     e.initialize_entity_order = order;
1816
1817     cur = initialize_entity_first;
1818     for (;;)
1819     {
1820         if (!cur || cur.initialize_entity_order > order)
1821         {
1822             // insert between prev and cur
1823             if (prev)
1824                 prev.initialize_entity_next = e;
1825             else
1826                 initialize_entity_first = e;
1827             e.initialize_entity_next = cur;
1828             return;
1829         }
1830         prev = cur;
1831         cur = cur.initialize_entity_next;
1832     }
1833 }
1834 void InitializeEntitiesRun()
1835 {
1836     entity startoflist;
1837     startoflist = initialize_entity_first;
1838     initialize_entity_first = world;
1839     for (self = startoflist; self; )
1840     {
1841         entity e;
1842         var void(void) func;
1843         e = self.initialize_entity_next;
1844         func = self.initialize_entity;
1845         self.initialize_entity_order = 0;
1846         self.initialize_entity = func_null;
1847         self.initialize_entity_next = world;
1848         if (self.classname == "initialize_entity")
1849         {
1850             entity e_old;
1851             e_old = self.enemy;
1852             remove_builtin(self);
1853             self = e_old;
1854         }
1855         //dprint("Delayed initialization: ", self.classname, "\n");
1856         func();
1857         self = e;
1858     }
1859 }
1860
1861 .float uncustomizeentityforclient_set;
1862 .void(void) uncustomizeentityforclient;
1863 void(void) SUB_Nullpointer = #0;
1864 void UncustomizeEntitiesRun()
1865 {
1866     entity oldself;
1867     oldself = self;
1868     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1869         self.uncustomizeentityforclient();
1870     self = oldself;
1871 }
1872 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1873 {
1874     e.customizeentityforclient = customizer;
1875     e.uncustomizeentityforclient = uncustomizer;
1876     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1877 }
1878
1879 .float nottargeted;
1880 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1881
1882 void() SUB_Remove;
1883 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1884 {
1885     vector mi, ma;
1886
1887     if (e.classname == "")
1888         e.classname = "net_linked";
1889
1890     if (e.model == "" || self.modelindex == 0)
1891     {
1892         mi = e.mins;
1893         ma = e.maxs;
1894         setmodel(e, "null");
1895         setsize(e, mi, ma);
1896     }
1897
1898     e.SendEntity = sendfunc;
1899     e.SendFlags = 0xFFFFFF;
1900
1901     if (!docull)
1902         e.effects |= EF_NODEPTHTEST;
1903
1904     if (dt)
1905     {
1906         e.nextthink = time + dt;
1907         e.think = SUB_Remove;
1908     }
1909 }
1910
1911 void adaptor_think2touch()
1912 {
1913     entity o;
1914     o = other;
1915     other = world;
1916     self.touch();
1917     other = o;
1918 }
1919
1920 void adaptor_think2use()
1921 {
1922     entity o, a;
1923     o = other;
1924     a = activator;
1925     activator = world;
1926     other = world;
1927     self.use();
1928     other = o;
1929     activator = a;
1930 }
1931
1932 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1933 {
1934         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1935                 self.projectiledeathtype |= HITTYPE_SPLASH;
1936         adaptor_think2use();
1937 }
1938
1939 // deferred dropping
1940 void DropToFloor_Handler()
1941 {
1942     droptofloor_builtin();
1943     self.dropped_origin = self.origin;
1944 }
1945
1946 void droptofloor()
1947 {
1948     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1949 }
1950
1951
1952
1953 float trace_hits_box_a0, trace_hits_box_a1;
1954
1955 float trace_hits_box_1d(float end, float thmi, float thma)
1956 {
1957     if (end == 0)
1958     {
1959         // just check if x is in range
1960         if (0 < thmi)
1961             return FALSE;
1962         if (0 > thma)
1963             return FALSE;
1964     }
1965     else
1966     {
1967         // do the trace with respect to x
1968         // 0 -> end has to stay in thmi -> thma
1969         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1970         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1971         if (trace_hits_box_a0 > trace_hits_box_a1)
1972             return FALSE;
1973     }
1974     return TRUE;
1975 }
1976
1977 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1978 {
1979     end -= start;
1980     thmi -= start;
1981     thma -= start;
1982     // now it is a trace from 0 to end
1983
1984     trace_hits_box_a0 = 0;
1985     trace_hits_box_a1 = 1;
1986
1987     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1988         return FALSE;
1989     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1990         return FALSE;
1991     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1992         return FALSE;
1993
1994     return TRUE;
1995 }
1996
1997 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1998 {
1999     return trace_hits_box(start, end, thmi - ma, thma - mi);
2000 }
2001
2002 float SUB_NoImpactCheck()
2003 {
2004         // zero hitcontents = this is not the real impact, but either the
2005         // mirror-impact of something hitting the projectile instead of the
2006         // projectile hitting the something, or a touchareagrid one. Neither of
2007         // these stop the projectile from moving, so...
2008         if(trace_dphitcontents == 0)
2009         {
2010                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2011                 checkclient();
2012         }
2013     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2014         return 1;
2015     if (other == world && self.size != '0 0 0')
2016     {
2017         vector tic;
2018         tic = self.velocity * sys_frametime;
2019         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2020         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2021         if (trace_fraction >= 1)
2022         {
2023             dprint("Odd... did not hit...?\n");
2024         }
2025         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2026         {
2027             dprint("Detected and prevented the sky-grapple bug.\n");
2028             return 1;
2029         }
2030     }
2031
2032     return 0;
2033 }
2034
2035 #define SUB_OwnerCheck() (other && (other == self.owner))
2036
2037 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2038 {
2039         if(SUB_OwnerCheck())
2040                 return TRUE;
2041         if(SUB_NoImpactCheck())
2042         {
2043                 remove(self);
2044                 return TRUE;
2045         }
2046         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2047                 UpdateCSQCProjectileNextFrame(self);
2048         return FALSE;
2049 }
2050 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2051
2052 float MAX_IPBAN_URIS = 16;
2053
2054 float URI_GET_DISCARD   = 0;
2055 float URI_GET_IPBAN     = 1;
2056 float URI_GET_IPBAN_END = 16;
2057
2058 void URI_Get_Callback(float id, float status, string data)
2059 {
2060     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2061     dprint(data);
2062     dprint("\nEnd of data.\n");
2063
2064     if (id == URI_GET_DISCARD)
2065     {
2066         // discard
2067     }
2068     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2069     {
2070         // online ban list
2071         OnlineBanList_URI_Get_Callback(id, status, data);
2072     }
2073     else
2074     {
2075         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2076     }
2077 }
2078
2079 void print_to(entity e, string s)
2080 {
2081     if (e)
2082         sprint(e, strcat(s, "\n"));
2083     else
2084         print(s, "\n");
2085 }
2086
2087 string uid2name(string myuid) {
2088         string s;
2089         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2090
2091         if(s == "")
2092                 s = "^1Unregistered Player";
2093         return s;
2094 }
2095
2096 float race_readTime(string map, float pos)
2097 {
2098         string rr;
2099         if(g_cts)
2100                 rr = CTS_RECORD;
2101         else
2102                 rr = RACE_RECORD;
2103
2104         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2105 }
2106
2107 string race_readUID(string map, float pos)
2108 {
2109         string rr;
2110         if(g_cts)
2111                 rr = CTS_RECORD;
2112         else
2113                 rr = RACE_RECORD;
2114
2115         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2116 }
2117
2118 float race_readPos(string map, float t) {
2119         float i;
2120         for (i = 1; i <= RANKINGS_CNT; ++i)
2121                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2122                         return i;
2123
2124         return 0; // pos is zero if unranked
2125 }
2126
2127 void race_writeTime(string map, float t, string myuid)
2128 {
2129         string rr;
2130         if(g_cts)
2131                 rr = CTS_RECORD;
2132         else
2133                 rr = RACE_RECORD;
2134
2135         float newpos;
2136         newpos = race_readPos(map, t);
2137
2138         float i, prevpos;
2139         for(i = 1; i <= RANKINGS_CNT; ++i)
2140         {
2141                 if(race_readUID(map, i) == myuid)
2142                         prevpos = i;
2143         }
2144         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2145                 for (i = prevpos; i > newpos; --i) {
2146                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2147                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2148                 }
2149         } else { // player has no ranked record yet
2150                 for (i = RANKINGS_CNT; i > newpos; --i) {
2151                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2152                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2153                 }
2154         }
2155
2156         // store new time itself
2157         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2158         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2159 }
2160
2161 string race_readName(string map, float pos)
2162 {
2163         string rr;
2164         if(g_cts)
2165                 rr = CTS_RECORD;
2166         else
2167                 rr = RACE_RECORD;
2168
2169         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2170 }
2171
2172 string race_placeName(float pos) {
2173         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2174         {
2175                 if(mod(pos, 10) == 1)
2176                         return strcat(ftos(pos), "st");
2177                 else if(mod(pos, 10) == 2)
2178                         return strcat(ftos(pos), "nd");
2179                 else if(mod(pos, 10) == 3)
2180                         return strcat(ftos(pos), "rd");
2181                 else
2182                         return strcat(ftos(pos), "th");
2183         }
2184         else
2185                 return strcat(ftos(pos), "th");
2186 }
2187 string getrecords(float page) // 50 records per page
2188 {
2189     float rec;
2190     string h;
2191     float r;
2192     float i;
2193     string s;
2194
2195     rec = 0;
2196
2197     s = "";
2198
2199     if (g_ctf)
2200     {
2201         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2202         {
2203             if (MapInfo_Get_ByID(i))
2204             {
2205                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2206                 if (r == 0)
2207                     continue;
2208                 // TODO: uid2name
2209                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2210                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2211                 ++rec;
2212             }
2213         }
2214     }
2215
2216     if (g_race)
2217     {
2218         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2219         {
2220             if (MapInfo_Get_ByID(i))
2221             {
2222                 r = race_readTime(MapInfo_Map_bspname, 1);
2223                 if (r == 0)
2224                     continue;
2225                 h = race_readName(MapInfo_Map_bspname, 1);
2226                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2227                 ++rec;
2228             }
2229         }
2230     }
2231
2232     if (g_cts)
2233     {
2234         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2235         {
2236             if (MapInfo_Get_ByID(i))
2237             {
2238                 r = race_readTime(MapInfo_Map_bspname, 1);
2239                 if (r == 0)
2240                     continue;
2241                 h = race_readName(MapInfo_Map_bspname, 1);
2242                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2243                 ++rec;
2244             }
2245         }
2246     }
2247
2248     MapInfo_ClearTemps();
2249
2250     if (s == "" && page == 0)
2251         return "No records are available on this server.\n";
2252     else
2253         return s;
2254 }
2255
2256 string getrankings()
2257 {
2258     string n;
2259     float t;
2260     float i;
2261     string s;
2262     string p;
2263     string map;
2264
2265     s = "";
2266
2267     map = GetMapname();
2268
2269     for (i = 1; i <= RANKINGS_CNT; ++i)
2270     {
2271         t = race_readTime(map, i);
2272         if (t == 0)
2273             continue;
2274         n = race_readName(map, i);
2275         p = race_placeName(i);
2276         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2277     }
2278
2279     MapInfo_ClearTemps();
2280
2281     if (s == "")
2282         return strcat("No records are available for the map: ", map, "\n");
2283     else
2284         return strcat("Records for ", map, ":\n", s);
2285 }
2286
2287 #define LADDER_FIRSTPOINT 100
2288 #define LADDER_CNT 10
2289         // position X still gives LADDER_FIRSTPOINT/X points
2290 #define LADDER_SIZE 30
2291         // ladder shows the top X players
2292 string top_uids[LADDER_SIZE];
2293 float top_scores[LADDER_SIZE];
2294 string getladder()
2295 {
2296     float i, j, k, uidcnt;
2297     string s, temp_s;
2298
2299     s = "";
2300     temp_s = "";
2301
2302     string rr;
2303     if(g_cts)
2304         rr = CTS_RECORD;
2305     else
2306         rr = RACE_RECORD;
2307
2308     string myuid;
2309
2310     for (k = 0; k < MapInfo_count; ++k)
2311     {
2312         if (MapInfo_Get_ByID(k))
2313         {
2314                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2315                         if(i == 0) // speed award
2316                         {
2317                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2318                                         continue;
2319
2320                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2321                         }
2322                         else // normal record, if it exists (else break)
2323                         {
2324                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2325                                         continue;
2326
2327                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2328                         }
2329
2330                         // string s contains:
2331                         // arg 0 = # of speed recs
2332                         // arg 1 = # of 1st place recs
2333                         // arg 2 = # of 2nd place recs
2334                         // ... etc
2335                         // LADDER_CNT+1 = total points
2336
2337                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2338                         if (temp_s == "")
2339                         {
2340                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2341                             ++uidcnt;
2342                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2343                             {
2344                                 if(j != LADDER_CNT + 1)
2345                                     temp_s = strcat(temp_s, "0 ");
2346                                 else
2347                                     temp_s = strcat(temp_s, "0");
2348                             }
2349                         }
2350
2351                         tokenize_console(temp_s);
2352                         s = "";
2353
2354                         if(i == 0) // speed award
2355                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2356                             {
2357                                 if(j == 0) // speed award
2358                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2359                                 else
2360                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2361                             }
2362                         else // record
2363                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2364                             {
2365                                 if(j == 0)
2366                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2367                                 else if(j == i) // wanted rec!
2368                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2369                                 else
2370                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2371                             }
2372
2373                         // total points are (by default) calculated like this:
2374                         // speedrec = floor(100 / 10) = 10 points
2375                         // 1st place = floor(100 / 1) = 100 points
2376                         // 2nd place = floor(100 / 2) = 50 points
2377                         // 3rd place = floor(100 / 3) = 33 points
2378                         // 4th place = floor(100 / 4) = 25 points
2379                         // 5th place = floor(100 / 5) = 20 points
2380                         // ... etc
2381
2382                         if(i == 0)
2383                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2384                         else
2385                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2386
2387                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2388                 }
2389         }
2390     }
2391
2392     float thiscnt;
2393     string thisuid;
2394     for (i = 0; i <= uidcnt; ++i) // for each known uid
2395     {
2396         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2397         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2398         tokenize_console(temp_s);
2399         thiscnt = stof(argv(LADDER_CNT+1));
2400
2401         if(thiscnt > top_scores[LADDER_SIZE-1])
2402         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2403         {
2404             if(thiscnt > top_scores[j])
2405             {
2406                 for (k = LADDER_SIZE-1; k >= j; --k)
2407                 {
2408                     top_uids[k] = top_uids[k-1];
2409                     top_scores[k] = top_scores[k-1];
2410                 }
2411                 top_uids[j] = thisuid;
2412                 top_scores[j] = thiscnt;
2413                 break;
2414             }
2415         }
2416     }
2417
2418     s = "^3-----------------------\n\n";
2419
2420     s = strcat(s, "Pos ^3|");
2421     s = strcat(s, " ^7Total  ^3|");
2422     for (i = 1; i <= LADDER_CNT; ++i)
2423     {
2424         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2425     }
2426     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2427
2428     s = strcat(s, "\n^3----+--------");
2429     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2430     {
2431         s = strcat(s, "+-----");
2432     }
2433 #if LADDER_CNT > 9
2434     for (i = 1; i <= LADDER_CNT - 9; ++i)
2435     {
2436         s = strcat(s, "+------");
2437     }
2438 #endif
2439
2440     s = strcat(s, "+--------------+--------------------\n");
2441
2442     for (i = 0; i < LADDER_SIZE; ++i)
2443     {
2444         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2445         tokenize_console(temp_s);
2446         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2447             continue;
2448         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2449         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2450         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2451         {
2452             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2453         }
2454 #if LADDER_CNT > 9
2455         for (j = 10; j <= LADDER_CNT; ++j)
2456         {
2457             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2458         }
2459 #endif
2460
2461         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2462         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2463     }
2464
2465     MapInfo_ClearTemps();
2466
2467     if (s == "")
2468         return "No ladder on this server!\n";
2469     else
2470         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2471 }
2472
2473
2474 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2475 {
2476     float m, i;
2477     vector start, org, delta, end, enddown, mstart;
2478
2479     m = e.dphitcontentsmask;
2480     e.dphitcontentsmask = goodcontents | badcontents;
2481
2482     org = world.mins;
2483     delta = world.maxs - world.mins;
2484
2485     for (i = 0; i < attempts; ++i)
2486     {
2487         start_x = org_x + random() * delta_x;
2488         start_y = org_y + random() * delta_y;
2489         start_z = org_z + random() * delta_z;
2490
2491         // rule 1: start inside world bounds, and outside
2492         // solid, and don't start from somewhere where you can
2493         // fall down to evil
2494         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2495         if (trace_fraction >= 1)
2496             continue;
2497         if (trace_startsolid)
2498             continue;
2499         if (trace_dphitcontents & badcontents)
2500             continue;
2501         if (trace_dphitq3surfaceflags & badsurfaceflags)
2502             continue;
2503
2504         // rule 2: if we are too high, lower the point
2505         if (trace_fraction * delta_z > maxaboveground)
2506             start = trace_endpos + '0 0 1' * maxaboveground;
2507         enddown = trace_endpos;
2508
2509         // rule 3: make sure we aren't outside the map. This only works
2510         // for somewhat well formed maps. A good rule of thumb is that
2511         // the map should have a convex outside hull.
2512         // these can be traceLINES as we already verified the starting box
2513         mstart = start + 0.5 * (e.mins + e.maxs);
2514         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2524         if (trace_fraction >= 1)
2525             continue;
2526         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2527         if (trace_fraction >= 1)
2528             continue;
2529
2530         // find a random vector to "look at"
2531         end_x = org_x + random() * delta_x;
2532         end_y = org_y + random() * delta_y;
2533         end_z = org_z + random() * delta_z;
2534         end = start + normalize(end - start) * vlen(delta);
2535
2536         // rule 4: start TO end must not be too short
2537         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2538         if (trace_startsolid)
2539             continue;
2540         if (trace_fraction < minviewdistance / vlen(delta))
2541             continue;
2542
2543         // rule 5: don't want to look at sky
2544         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2545             continue;
2546
2547         // rule 6: we must not end up in trigger_hurt
2548         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2549         {
2550             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2551             continue;
2552         }
2553
2554         break;
2555     }
2556
2557     e.dphitcontentsmask = m;
2558
2559     if (i < attempts)
2560     {
2561         setorigin(e, start);
2562         e.angles = vectoangles(end - start);
2563         dprint("Needed ", ftos(i + 1), " attempts\n");
2564         return TRUE;
2565     }
2566     else
2567         return FALSE;
2568 }
2569
2570 float zcurveparticles_effectno;
2571 vector zcurveparticles_start;
2572 float zcurveparticles_spd;
2573
2574 void endzcurveparticles()
2575 {
2576         if(zcurveparticles_effectno)
2577         {
2578                 // terminator
2579                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2580         }
2581         zcurveparticles_effectno = 0;
2582 }
2583
2584 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2585 {
2586         spd = bound(0, floor(spd / 16), 32767);
2587         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2588         {
2589                 endzcurveparticles();
2590                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2591                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2592                 WriteShort(MSG_BROADCAST, effectno);
2593                 WriteCoord(MSG_BROADCAST, start_x);
2594                 WriteCoord(MSG_BROADCAST, start_y);
2595                 WriteCoord(MSG_BROADCAST, start_z);
2596                 zcurveparticles_effectno = effectno;
2597                 zcurveparticles_start = start;
2598         }
2599         else
2600                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2601         WriteCoord(MSG_BROADCAST, end_x);
2602         WriteCoord(MSG_BROADCAST, end_y);
2603         WriteCoord(MSG_BROADCAST, end_z);
2604         WriteCoord(MSG_BROADCAST, end_dz);
2605         zcurveparticles_spd = spd;
2606 }
2607
2608 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2609 {
2610         float end_dz;
2611         vector vecxy, velxy;
2612
2613         vecxy = end - start;
2614         vecxy_z = 0;
2615         velxy = vel;
2616         velxy_z = 0;
2617
2618         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2619         {
2620                 endzcurveparticles();
2621                 trailparticles(world, effectno, start, end);
2622                 return;
2623         }
2624
2625         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2626         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2627 }
2628
2629 string GetGametype(); // g_world.qc
2630 void write_recordmarker(entity pl, float tstart, float dt)
2631 {
2632     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2633
2634     // also write a marker into demo files for demotc-race-record-extractor to find
2635     stuffcmd(pl,
2636              strcat(
2637                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2638                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2639 }
2640
2641 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2642 {
2643         switch(algn)
2644         {
2645                 case 1: // right
2646                         break;
2647
2648                 case 2: // left
2649                         vecs_y = -vecs_y;
2650                         break;
2651
2652                 default:
2653                 case 3:
2654                         if(allowcenter) // 2: allow center handedness
2655                         {
2656                                 // center
2657                                 vecs_y = 0;
2658                                 vecs_z -= 2;
2659                         }
2660                         else
2661                         {
2662                                 // right
2663                         }
2664                         break;
2665
2666                 case 4:
2667                         if(allowcenter) // 2: allow center handedness
2668                         {
2669                                 // center
2670                                 vecs_y = 0;
2671                                 vecs_z -= 2;
2672                         }
2673                         else
2674                         {
2675                                 // left
2676                                 vecs_y = -vecs_y;
2677                         }
2678                         break;
2679         }
2680         return vecs;
2681 }
2682
2683 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2684 {
2685         string s;
2686         vector v;
2687
2688         if (cvar("g_shootfromeye"))
2689         {
2690                 if (visual)
2691                 {
2692                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2693                 }
2694                 else
2695                 {
2696                         vecs_y = 0;
2697                         vecs_z = 0;
2698                 }
2699         }
2700         else if (cvar("g_shootfromcenter"))
2701         {
2702                 if (visual)
2703                 {
2704                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2705                 }
2706                 else
2707                 {
2708                         vecs_y = 0;
2709                         vecs_z -= 2;
2710                 }
2711         }
2712         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2713         {
2714                 v = stov(s);
2715                 if (y_is_right)
2716                         v_y = -v_y;
2717                 if (v_x != 0)
2718                         vecs_x = v_x;
2719                 vecs_y = v_y;
2720                 vecs_z = v_z;
2721         }
2722         else if (cvar("g_shootfromclient"))
2723         {
2724                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2725         }
2726         return vecs;
2727 }
2728
2729 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2730 {
2731         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2732 }
2733
2734
2735 void attach_sameorigin(entity e, entity to, string tag)
2736 {
2737     vector org, t_forward, t_left, t_up, e_forward, e_up;
2738     vector org0, ang0;
2739     float tagscale;
2740
2741     ang0 = e.angles;
2742     org0 = e.origin;
2743
2744     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2745     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2746     t_forward = v_forward * tagscale;
2747     t_left = v_right * -tagscale;
2748     t_up = v_up * tagscale;
2749
2750     e.origin_x = org * t_forward;
2751     e.origin_y = org * t_left;
2752     e.origin_z = org * t_up;
2753
2754     // current forward and up directions
2755     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2756                 e.angles = AnglesTransform_FromVAngles(e.angles);
2757         else
2758                 e.angles = AnglesTransform_FromAngles(e.angles);
2759     fixedmakevectors(e.angles);
2760
2761     // untransform forward, up!
2762     e_forward_x = v_forward * t_forward;
2763     e_forward_y = v_forward * t_left;
2764     e_forward_z = v_forward * t_up;
2765     e_up_x = v_up * t_forward;
2766     e_up_y = v_up * t_left;
2767     e_up_z = v_up * t_up;
2768
2769     e.angles = fixedvectoangles2(e_forward, e_up);
2770     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2771                 e.angles = AnglesTransform_ToVAngles(e.angles);
2772         else
2773                 e.angles = AnglesTransform_ToAngles(e.angles);
2774
2775     setattachment(e, to, tag);
2776     setorigin(e, e.origin);
2777 }
2778
2779 void detach_sameorigin(entity e)
2780 {
2781     vector org;
2782     org = gettaginfo(e, 0);
2783     e.angles = fixedvectoangles2(v_forward, v_up);
2784     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2785                 e.angles = AnglesTransform_ToVAngles(e.angles);
2786         else
2787                 e.angles = AnglesTransform_ToAngles(e.angles);
2788     setorigin(e, org);
2789     setattachment(e, world, "");
2790     setorigin(e, e.origin);
2791 }
2792
2793 void follow_sameorigin(entity e, entity to)
2794 {
2795     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2796     e.aiment = to; // make the hole follow bmodel
2797     e.punchangle = to.angles; // the original angles of bmodel
2798     e.view_ofs = e.origin - to.origin; // relative origin
2799     e.v_angle = e.angles - to.angles; // relative angles
2800 }
2801
2802 void unfollow_sameorigin(entity e)
2803 {
2804     e.movetype = MOVETYPE_NONE;
2805 }
2806
2807 entity gettaginfo_relative_ent;
2808 vector gettaginfo_relative(entity e, float tag)
2809 {
2810     if (!gettaginfo_relative_ent)
2811     {
2812         gettaginfo_relative_ent = spawn();
2813         gettaginfo_relative_ent.effects = EF_NODRAW;
2814     }
2815     gettaginfo_relative_ent.model = e.model;
2816     gettaginfo_relative_ent.modelindex = e.modelindex;
2817     gettaginfo_relative_ent.frame = e.frame;
2818     return gettaginfo(gettaginfo_relative_ent, tag);
2819 }
2820
2821 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2822 {
2823     float p;
2824     p = pow(2, chan);
2825     if (pl.soundentity.cnt & p)
2826         return;
2827     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2828     pl.soundentity.cnt |= p;
2829 }
2830
2831 void SoundEntity_StopSound(entity pl, float chan)
2832 {
2833     float p;
2834     p = pow(2, chan);
2835     if (pl.soundentity.cnt & p)
2836     {
2837         stopsoundto(MSG_ALL, pl.soundentity, chan);
2838         pl.soundentity.cnt &~= p;
2839     }
2840 }
2841
2842 void SoundEntity_Attach(entity pl)
2843 {
2844     pl.soundentity = spawn();
2845     pl.soundentity.classname = "soundentity";
2846     pl.soundentity.owner = pl;
2847     setattachment(pl.soundentity, pl, "");
2848     setmodel(pl.soundentity, "null");
2849 }
2850
2851 void SoundEntity_Detach(entity pl)
2852 {
2853     float i;
2854     for (i = 0; i <= 7; ++i)
2855         SoundEntity_StopSound(pl, i);
2856 }
2857
2858
2859 float ParseCommandPlayerSlotTarget_firsttoken;
2860 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2861 {
2862     string s;
2863     entity e, head;
2864     float n;
2865
2866     s = string_null;
2867
2868     ParseCommandPlayerSlotTarget_firsttoken = -1;
2869
2870     if (tokens > idx)
2871     {
2872         if (substring(argv(idx), 0, 1) == "#")
2873         {
2874             s = substring(argv(idx), 1, -1);
2875             ++idx;
2876             if (s == "")
2877                 if (tokens > idx)
2878                 {
2879                     s = argv(idx);
2880                     ++idx;
2881                 }
2882                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2883             if (s == ftos(stof(s)))
2884             {
2885                 e = edict_num(stof(s));
2886                 if (e.flags & FL_CLIENT)
2887                     return e;
2888             }
2889         }
2890         else
2891         {
2892             // it must be a nick name
2893             s = argv(idx);
2894             ++idx;
2895                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2896
2897             n = 0;
2898             FOR_EACH_CLIENT(head)
2899             if (head.netname == s)
2900             {
2901                 e = head;
2902                 ++n;
2903             }
2904             if (n == 1)
2905                 return e;
2906
2907             s = strdecolorize(s);
2908             n = 0;
2909             FOR_EACH_CLIENT(head)
2910             if (strdecolorize(head.netname) == s)
2911             {
2912                 e = head;
2913                 ++n;
2914             }
2915             if (n == 1)
2916                 return e;
2917         }
2918     }
2919
2920     return world;
2921 }
2922
2923 .float scale2;
2924
2925 float modeleffect_SendEntity(entity to, float sf)
2926 {
2927         float f;
2928         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2929
2930         f = 0;
2931         if(self.velocity != '0 0 0')
2932                 f |= 1;
2933         if(self.angles != '0 0 0')
2934                 f |= 2;
2935         if(self.avelocity != '0 0 0')
2936                 f |= 4;
2937
2938         WriteByte(MSG_ENTITY, f);
2939         WriteShort(MSG_ENTITY, self.modelindex);
2940         WriteByte(MSG_ENTITY, self.skin);
2941         WriteByte(MSG_ENTITY, self.frame);
2942         WriteCoord(MSG_ENTITY, self.origin_x);
2943         WriteCoord(MSG_ENTITY, self.origin_y);
2944         WriteCoord(MSG_ENTITY, self.origin_z);
2945         if(f & 1)
2946         {
2947                 WriteCoord(MSG_ENTITY, self.velocity_x);
2948                 WriteCoord(MSG_ENTITY, self.velocity_y);
2949                 WriteCoord(MSG_ENTITY, self.velocity_z);
2950         }
2951         if(f & 2)
2952         {
2953                 WriteCoord(MSG_ENTITY, self.angles_x);
2954                 WriteCoord(MSG_ENTITY, self.angles_y);
2955                 WriteCoord(MSG_ENTITY, self.angles_z);
2956         }
2957         if(f & 4)
2958         {
2959                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2960                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2961                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2962         }
2963         WriteShort(MSG_ENTITY, self.scale * 256.0);
2964         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2965         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2966         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2967         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2968
2969         return TRUE;
2970 }
2971
2972 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2973 {
2974         entity e;
2975         float sz;
2976         e = spawn();
2977         e.classname = "modeleffect";
2978         setmodel(e, m);
2979         e.frame = f;
2980         setorigin(e, o);
2981         e.velocity = v;
2982         e.angles = ang;
2983         e.avelocity = angv;
2984         e.alpha = a;
2985         e.teleport_time = t1;
2986         e.fade_time = t2;
2987         e.skin = s;
2988         if(s0 >= 0)
2989                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2990         else
2991                 e.scale = -s0;
2992         if(s2 >= 0)
2993                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2994         else
2995                 e.scale2 = -s2;
2996         sz = max(e.scale, e.scale2);
2997         setsize(e, e.mins * sz, e.maxs * sz);
2998         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2999 }
3000
3001 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
3002 {
3003         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3004 }
3005
3006 float randombit(float bits)
3007 {
3008         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3009                 return bits;
3010
3011         float n, f, b, r;
3012
3013         r = random();
3014         b = 0;
3015         n = 0;
3016
3017         for(f = 1; f <= bits; f *= 2)
3018         {
3019                 if(bits & f)
3020                 {
3021                         ++n;
3022                         r *= n;
3023                         if(r <= 1)
3024                                 b = f;
3025                         else
3026                                 r = (r - 1) / (n - 1);
3027                 }
3028         }
3029
3030         return b;
3031 }
3032
3033 float randombits(float bits, float k, float error_return)
3034 {
3035         float r;
3036         r = 0;
3037         while(k > 0 && bits != r)
3038         {
3039                 r += randombit(bits - r);
3040                 --k;
3041         }
3042         if(error_return)
3043                 if(k > 0)
3044                         return -1; // all
3045         return r;
3046 }
3047
3048 void randombit_test(float bits, float iter)
3049 {
3050         while(iter > 0)
3051         {
3052                 print(ftos(randombit(bits)), "\n");
3053                 --iter;
3054         }
3055 }
3056
3057 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3058 {
3059         if(halflifedist > 0)
3060                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3061         else if(halflifedist < 0)
3062                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3063         else
3064                 return 1;
3065 }
3066
3067
3068
3069
3070 #ifdef RELEASE
3071 #define cvar_string_normal cvar_string_builtin
3072 #define cvar_normal cvar_builtin
3073 #else
3074 string cvar_string_normal(string n)
3075 {
3076         if not(cvar_type(n) & 1)
3077                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3078         return cvar_string_builtin(n);
3079 }
3080
3081 float cvar_normal(string n)
3082 {
3083         return stof(cvar_string_normal(n));
3084 }
3085 #endif
3086 #define cvar_set_normal cvar_set_builtin
3087
3088 void defer_think()
3089 {
3090     entity oself;
3091
3092     oself           = self;
3093     self            = self.owner;
3094     oself.think     = SUB_Remove;
3095     oself.nextthink = time;
3096
3097     oself.use();
3098 }
3099
3100 /*
3101     Execute func() after time + fdelay.
3102     self when func is executed = self when defer is called
3103 */
3104 void defer(float fdelay, void() func)
3105 {
3106     entity e;
3107
3108     e           = spawn();
3109     e.owner     = self;
3110     e.use       = func;
3111     e.think     = defer_think;
3112     e.nextthink = time + fdelay;
3113 }