Merge branch 'master' into Mario/buffs
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void crosshair_trace_plusvisibletriggers(entity pl)
12 {
13         entity first;
14         entity e;
15         first = findchainfloat(solid, SOLID_TRIGGER);
16
17         for (e = first; e; e = e.chain)
18                 if (e.model != "")
19                         e.solid = SOLID_BSP;
20
21         crosshair_trace(pl);
22
23         for (e = first; e; e = e.chain)
24                 e.solid = SOLID_TRIGGER;
25 }
26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
27 void WarpZone_crosshair_trace(entity pl)
28 {
29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
30 }
31
32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
33 void() spawnpoint_use;
34 string GetMapname();
35
36 string admin_name(void)
37 {
38         if(autocvar_sv_adminnick != "")
39                 return autocvar_sv_adminnick;
40         else
41                 return "SERVER ADMIN";
42 }
43
44 float DistributeEvenly_amount;
45 float DistributeEvenly_totalweight;
46 void DistributeEvenly_Init(float amount, float totalweight)
47 {
48     if (DistributeEvenly_amount)
49     {
50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
52     }
53     if (totalweight == 0)
54         DistributeEvenly_amount = 0;
55     else
56         DistributeEvenly_amount = amount;
57     DistributeEvenly_totalweight = totalweight;
58 }
59 float DistributeEvenly_Get(float weight)
60 {
61     float f;
62     if (weight <= 0)
63         return 0;
64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
65     DistributeEvenly_totalweight -= weight;
66     DistributeEvenly_amount -= f;
67     return f;
68 }
69 float DistributeEvenly_GetRandomized(float weight)
70 {
71     float f;
72     if (weight <= 0)
73         return 0;
74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
75     DistributeEvenly_totalweight -= weight;
76     DistributeEvenly_amount -= f;
77     return f;
78 }
79
80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
81
82 const string STR_PLAYER = "player";
83 const string STR_SPECTATOR = "spectator";
84 const string STR_OBSERVER = "observer";
85
86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
93
94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
97
98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
101
102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
103
104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
105
106 // copies a string to a tempstring (so one can strunzone it)
107 string strcat1(string s) = #115; // FRIK_FILE
108
109 float logfile_open;
110 float logfile;
111
112 void GameLogEcho(string s)
113 {
114     string fn;
115     float matches;
116
117     if (autocvar_sv_eventlog_files)
118     {
119         if (!logfile_open)
120         {
121             logfile_open = TRUE;
122             matches = autocvar_sv_eventlog_files_counter + 1;
123             cvar_set("sv_eventlog_files_counter", ftos(matches));
124             fn = ftos(matches);
125             if (strlen(fn) < 8)
126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
128             logfile = fopen(fn, FILE_APPEND);
129             fputs(logfile, ":logversion:3\n");
130         }
131         if (logfile >= 0)
132         {
133             if (autocvar_sv_eventlog_files_timestamps)
134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
135             else
136                 fputs(logfile, strcat(s, "\n"));
137         }
138     }
139     if (autocvar_sv_eventlog_console)
140     {
141         print(s, "\n");
142     }
143 }
144
145 void GameLogInit()
146 {
147     logfile_open = 0;
148     // will be opened later
149 }
150
151 void GameLogClose()
152 {
153     if (logfile_open && logfile >= 0)
154     {
155         fclose(logfile);
156         logfile = -1;
157     }
158 }
159
160 #define strstr strstrofs
161 /*
162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
165 // BE CONSTANT OR strzoneD!
166 float strstr(string haystack, string needle, float offset)
167 {
168         float len, endpos;
169         string found;
170         len = strlen(needle);
171         endpos = strlen(haystack) - len;
172         while(offset <= endpos)
173         {
174                 found = substring(haystack, offset, len);
175                 if(found == needle)
176                         return offset;
177                 offset = offset + 1;
178         }
179         return -1;
180 }
181 */
182
183 const float NUM_NEAREST_ENTITIES = 4;
184 entity nearest_entity[NUM_NEAREST_ENTITIES];
185 float nearest_length[NUM_NEAREST_ENTITIES];
186 entity findnearest(vector point, .string field, string value, vector axismod)
187 {
188     entity localhead;
189     float i;
190     float j;
191     float len;
192     vector dist;
193
194     float num_nearest;
195     num_nearest = 0;
196
197     localhead = find(world, field, value);
198     while (localhead)
199     {
200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
201             dist = localhead.oldorigin;
202         else
203             dist = localhead.origin;
204         dist = dist - point;
205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
206         len = vlen(dist);
207
208         for (i = 0; i < num_nearest; ++i)
209         {
210             if (len < nearest_length[i])
211                 break;
212         }
213
214         // now i tells us where to insert at
215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
216         if (i < NUM_NEAREST_ENTITIES)
217         {
218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
219             {
220                 nearest_length[j + 1] = nearest_length[j];
221                 nearest_entity[j + 1] = nearest_entity[j];
222             }
223             nearest_length[i] = len;
224             nearest_entity[i] = localhead;
225             if (num_nearest < NUM_NEAREST_ENTITIES)
226                 num_nearest = num_nearest + 1;
227         }
228
229         localhead = find(localhead, field, value);
230     }
231
232     // now use the first one from our list that we can see
233     for (i = 0; i < num_nearest; ++i)
234     {
235         traceline(point, nearest_entity[i].origin, TRUE, world);
236         if (trace_fraction == 1)
237         {
238             if (i != 0)
239             {
240                 dprint("Nearest point (");
241                 dprint(nearest_entity[0].netname);
242                 dprint(") is not visible, using a visible one.\n");
243             }
244             return nearest_entity[i];
245         }
246     }
247
248     if (num_nearest == 0)
249         return world;
250
251     dprint("Not seeing any location point, using nearest as fallback.\n");
252     /* DEBUGGING CODE:
253     dprint("Candidates were: ");
254     for(j = 0; j < num_nearest; ++j)
255     {
256         if(j != 0)
257                 dprint(", ");
258         dprint(nearest_entity[j].netname);
259     }
260     dprint("\n");
261     */
262
263     return nearest_entity[0];
264 }
265
266 void spawnfunc_target_location()
267 {
268     self.classname = "target_location";
269     // location name in netname
270     // eventually support: count, teamgame selectors, line of sight?
271 }
272
273 void spawnfunc_info_location()
274 {
275     self.classname = "target_location";
276     self.message = self.netname;
277 }
278
279 string NearestLocation(vector p)
280 {
281     entity loc;
282     string ret;
283     ret = "somewhere";
284     loc = findnearest(p, classname, "target_location", '1 1 1');
285     if (loc)
286     {
287         ret = loc.message;
288     }
289     else
290     {
291         loc = findnearest(p, target, "###item###", '1 1 4');
292         if (loc)
293             ret = loc.netname;
294     }
295     return ret;
296 }
297
298 string formatmessage(string msg)
299 {
300         float p, p1, p2;
301         float n;
302         vector cursor;
303         entity cursor_ent;
304         string escape;
305         string replacement;
306         p = 0;
307         n = 7;
308
309         WarpZone_crosshair_trace(self);
310         cursor = trace_endpos;
311         cursor_ent = trace_ent;
312
313         while (1) {
314                 if (n < 1)
315                         break; // too many replacements
316
317                 n = n - 1;
318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
320
321                 if (p1 < 0)
322                         p1 = p2;
323
324                 if (p2 < 0)
325                         p2 = p1;
326
327                 p = min(p1, p2);
328
329                 if (p < 0)
330                         break;
331
332                 replacement = substring(msg, p, 2);
333                 escape = substring(msg, p + 1, 1);
334
335                 if (escape == "%")
336                         replacement = "%";
337                 else if (escape == "\\")
338                         replacement = "\\";
339                 else if (escape == "n")
340                         replacement = "\n";
341                 else if (escape == "a")
342                         replacement = ftos(floor(self.armorvalue));
343                 else if (escape == "h")
344                         replacement = ftos(floor(self.health));
345                 else if (escape == "l")
346                         replacement = NearestLocation(self.origin);
347                 else if (escape == "y")
348                         replacement = NearestLocation(cursor);
349                 else if (escape == "d")
350                         replacement = NearestLocation(self.death_origin);
351                 else if (escape == "w") {
352                         float wep;
353                         wep = self.weapon;
354                         if (!wep)
355                                 wep = self.switchweapon;
356                         if (!wep)
357                                 wep = self.cnt;
358                         replacement = W_Name(wep);
359                 } else if (escape == "W") {
360                         if (self.items & IT_SHELLS) replacement = "shells";
361                         else if (self.items & IT_NAILS) replacement = "bullets";
362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
363                         else if (self.items & IT_CELLS) replacement = "cells";
364                         else replacement = "batteries"; // ;)
365                 } else if (escape == "x") {
366                         replacement = cursor_ent.netname;
367                         if (replacement == "" || !cursor_ent)
368                                 replacement = "nothing";
369                 } else if (escape == "s")
370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
371                 else if (escape == "S")
372                         replacement = ftos(vlen(self.velocity));
373
374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
375                 p = p + strlen(replacement);
376         }
377         return msg;
378 }
379
380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
381         return (value == 0) ? FALSE : TRUE;
382 }
383
384 /*
385 =============
386 GetCvars
387 =============
388 Called with:
389   0:  sends the request
390   >0: receives a cvar from name=argv(f) value=argv(f+1)
391 */
392 void GetCvars_handleString(string thisname, float f, .string field, string name)
393 {
394         if (f < 0)
395         {
396                 if (self.field)
397                         strunzone(self.field);
398                 self.field = string_null;
399         }
400         else if (f > 0)
401         {
402                 if (thisname == name)
403                 {
404                         if (self.field)
405                                 strunzone(self.field);
406                         self.field = strzone(argv(f + 1));
407                 }
408         }
409         else
410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
411 }
412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
413 {
414         GetCvars_handleString(thisname, f, field, name);
415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
416                 if (thisname == name)
417                 {
418                         string s;
419                         s = func(strcat1(self.field));
420                         if (s != self.field)
421                         {
422                                 strunzone(self.field);
423                                 self.field = strzone(s);
424                         }
425                 }
426 }
427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
428 {
429         if (f < 0)
430         {
431         }
432         else if (f > 0)
433         {
434                 if (thisname == name)
435                         self.field = stof(argv(f + 1));
436         }
437         else
438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
439 }
440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
441 {
442         if (f < 0)
443         {
444         }
445         else if (f > 0)
446         {
447                 if (thisname == name)
448                 {
449                         if(!self.field)
450                         {
451                                 self.field = stof(argv(f + 1));
452                                 if(!self.field)
453                                         self.field = -1;
454                         }
455                 }
456         }
457         else
458         {
459                 if(!self.field)
460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
461         }
462 }
463 float w_getbestweapon(entity e);
464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
465 {
466         string o;
467         o = W_FixWeaponOrder_ForceComplete(wo);
468         if(self.weaponorder_byimpulse)
469         {
470                 strunzone(self.weaponorder_byimpulse);
471                 self.weaponorder_byimpulse = string_null;
472         }
473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
474         return o;
475 }
476 void GetCvars(float f)
477 {
478         string s = string_null;
479
480         if (f > 0)
481                 s = strcat1(argv(f));
482
483         get_cvars_f = f;
484         get_cvars_s = s;
485
486         MUTATOR_CALLHOOK(GetCvars);
487
488         Notification_GetCvars();
489
490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
513
514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
516
517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
522
523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
524         if (f > 0)
525         {
526                 if (s == "cl_weaponpriority")
527                         self.switchweapon = w_getbestweapon(self);
528                 if (s == "cl_allow_uidtracking")
529                         PlayerStats_AddPlayer(self);
530         }
531 }
532
533 // decolorizes and team colors the player name when needed
534 string playername(entity p)
535 {
536     string t;
537     if (teamplay && !intermission_running && IS_PLAYER(p))
538     {
539         t = Team_ColorCode(p.team);
540         return strcat(t, strdecolorize(p.netname));
541     }
542     else
543         return p.netname;
544 }
545
546 vector randompos(vector m1, vector m2)
547 {
548     vector v;
549     m2 = m2 - m1;
550     v_x = m2_x * random() + m1_x;
551     v_y = m2_y * random() + m1_y;
552     v_z = m2_z * random() + m1_z;
553     return  v;
554 }
555
556 //#NO AUTOCVARS START
557
558 float g_pickup_shells;
559 float g_pickup_shells_max;
560 float g_pickup_nails;
561 float g_pickup_nails_max;
562 float g_pickup_rockets;
563 float g_pickup_rockets_max;
564 float g_pickup_cells;
565 float g_pickup_cells_max;
566 float g_pickup_fuel;
567 float g_pickup_fuel_jetpack;
568 float g_pickup_fuel_max;
569 float g_pickup_armorsmall;
570 float g_pickup_armorsmall_max;
571 float g_pickup_armorsmall_anyway;
572 float g_pickup_armormedium;
573 float g_pickup_armormedium_max;
574 float g_pickup_armormedium_anyway;
575 float g_pickup_armorbig;
576 float g_pickup_armorbig_max;
577 float g_pickup_armorbig_anyway;
578 float g_pickup_armorlarge;
579 float g_pickup_armorlarge_max;
580 float g_pickup_armorlarge_anyway;
581 float g_pickup_healthsmall;
582 float g_pickup_healthsmall_max;
583 float g_pickup_healthsmall_anyway;
584 float g_pickup_healthmedium;
585 float g_pickup_healthmedium_max;
586 float g_pickup_healthmedium_anyway;
587 float g_pickup_healthlarge;
588 float g_pickup_healthlarge_max;
589 float g_pickup_healthlarge_anyway;
590 float g_pickup_healthmega;
591 float g_pickup_healthmega_max;
592 float g_pickup_healthmega_anyway;
593 float g_pickup_ammo_anyway;
594 float g_pickup_weapons_anyway;
595 float g_weaponarena;
596 WepSet g_weaponarena_weapons;
597 float g_weaponarena_random;
598 float g_weaponarena_random_with_laser;
599 string g_weaponarena_list;
600 float g_weaponspeedfactor;
601 float g_weaponratefactor;
602 float g_weapondamagefactor;
603 float g_weaponforcefactor;
604 float g_weaponspreadfactor;
605
606 WepSet start_weapons;
607 WepSet start_weapons_default;
608 WepSet start_weapons_defaultmask;
609 float start_items;
610 float start_ammo_shells;
611 float start_ammo_nails;
612 float start_ammo_rockets;
613 float start_ammo_cells;
614 float start_ammo_fuel;
615 float start_health;
616 float start_armorvalue;
617 WepSet warmup_start_weapons;
618 WepSet warmup_start_weapons_default;
619 WepSet warmup_start_weapons_defaultmask;
620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
621 float warmup_start_ammo_shells;
622 float warmup_start_ammo_nails;
623 float warmup_start_ammo_rockets;
624 float warmup_start_ammo_cells;
625 float warmup_start_ammo_fuel;
626 float warmup_start_health;
627 float warmup_start_armorvalue;
628 float g_weapon_stay;
629
630 entity get_weaponinfo(float w);
631
632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
633 {
634         var float i = weaponinfo.weapon;
635         var float d = 0;
636
637         if (!i)
638                 return 0;
639
640         if (g_lms || g_ca || allguns)
641         {
642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
643                         d = TRUE;
644                 else
645                         d = FALSE;
646         }
647         else if (g_cts)
648                 d = (i == WEP_SHOTGUN);
649         else if (g_nexball)
650                 d = 0; // weapon is set a few lines later
651         else
652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
653
654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
655                 d |= (i == WEP_HOOK);
656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
657                 d = 0;
658
659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
660
661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
662
663         // bit order in t:
664         // 1: want or not
665         // 2: is default?
666         // 4: is set by default?
667         if(t < 0)
668                 t = 4 | (3 * d);
669         else
670                 t |= (2 * d);
671
672         return t;
673 }
674
675 void readplayerstartcvars()
676 {
677         entity e;
678         float i, j, t;
679         string s;
680
681         // initialize starting values for players
682         start_weapons = '0 0 0';
683         start_weapons_default = '0 0 0';
684         start_weapons_defaultmask = '0 0 0';
685         start_items = 0;
686         start_ammo_shells = 0;
687         start_ammo_nails = 0;
688         start_ammo_rockets = 0;
689         start_ammo_cells = 0;
690         start_health = cvar("g_balance_health_start");
691         start_armorvalue = cvar("g_balance_armor_start");
692
693         g_weaponarena = 0;
694         g_weaponarena_weapons = '0 0 0';
695
696         s = cvar_string("g_weaponarena");
697         if (s == "0" || s == "")
698         {
699                 if(g_ca)
700                         s = "most";
701         }
702
703         if (s == "0" || s == "")
704         {
705                 // no arena
706         }
707         else if (s == "off")
708         {
709                 // forcibly turn off weaponarena
710         }
711         else if (s == "all")
712         {
713                 g_weaponarena = 1;
714                 g_weaponarena_list = "All Weapons";
715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
716                 {
717                         e = get_weaponinfo(j);
718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
720                 }
721         }
722         else if (s == "most")
723         {
724                 g_weaponarena = 1;
725                 g_weaponarena_list = "Most Weapons";
726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
727                 {
728                         e = get_weaponinfo(j);
729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
732                 }
733         }
734         else if (s == "none")
735         {
736                 g_weaponarena = 1;
737                 g_weaponarena_list = "No Weapons";
738         }
739         else
740         {
741                 g_weaponarena = 1;
742                 t = tokenize_console(s);
743                 g_weaponarena_list = "";
744                 for (i = 0; i < t; ++i)
745                 {
746                         s = argv(i);
747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
748                         {
749                                 e = get_weaponinfo(j);
750                                 if (e.netname == s)
751                                 {
752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
754                                         break;
755                                 }
756                         }
757                         if (j > WEP_LAST)
758                         {
759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
760                         }
761                 }
762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
763         }
764
765         if(g_weaponarena)
766                 g_weaponarena_random = cvar("g_weaponarena_random");
767         else
768                 g_weaponarena_random = 0;
769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
770
771         if (g_weaponarena)
772         {
773                 g_weapon_stay = 0; // incompatible
774                 start_weapons = g_weaponarena_weapons;
775                 start_items |= IT_UNLIMITED_AMMO;
776         }
777         else
778         {
779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
780                 {
781                         e = get_weaponinfo(i);
782                         float w = want_weapon("g_start_weapon_", e, FALSE);
783                         if(w & 1)
784                                 start_weapons |= WepSet_FromWeapon(i);
785                         if(w & 2)
786                                 start_weapons_default |= WepSet_FromWeapon(i);
787                         if(w & 4)
788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
789                 }
790         }
791
792         if(!cvar("g_use_ammunition"))
793                 start_items |= IT_UNLIMITED_AMMO;
794
795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
796         {
797                 start_ammo_rockets = 999;
798                 start_ammo_shells = 999;
799                 start_ammo_cells = 999;
800                 start_ammo_nails = 999;
801                 start_ammo_fuel = 999;
802         }
803         else
804         {
805                 start_ammo_shells = cvar("g_start_ammo_shells");
806                 start_ammo_nails = cvar("g_start_ammo_nails");
807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
808                 start_ammo_cells = cvar("g_start_ammo_cells");
809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
810         }
811
812         if (warmup_stage)
813         {
814                 warmup_start_ammo_shells = start_ammo_shells;
815                 warmup_start_ammo_nails = start_ammo_nails;
816                 warmup_start_ammo_rockets = start_ammo_rockets;
817                 warmup_start_ammo_cells = start_ammo_cells;
818                 warmup_start_ammo_fuel = start_ammo_fuel;
819                 warmup_start_health = start_health;
820                 warmup_start_armorvalue = start_armorvalue;
821                 warmup_start_weapons = start_weapons;
822                 warmup_start_weapons_default = start_weapons_default;
823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
824
825                 if (!g_weaponarena && !g_ca)
826                 {
827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
832                         warmup_start_health = cvar("g_warmup_start_health");
833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
834                         warmup_start_weapons = '0 0 0';
835                         warmup_start_weapons_default = '0 0 0';
836                         warmup_start_weapons_defaultmask = '0 0 0';
837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
838                         {
839                                 e = get_weaponinfo(i);
840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
841                                 if(w & 1)
842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
843                                 if(w & 2)
844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
845                                 if(w & 4)
846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
847                         }
848                 }
849         }
850
851         if (g_jetpack)
852                 start_items |= IT_JETPACK;
853
854         MUTATOR_CALLHOOK(SetStartItems);
855
856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
857         {
858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
859                 start_items |= IT_FUEL_REGEN;
860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
862         }
863
864         WepSet precache_weapons = start_weapons;
865         if (g_warmup_allguns != 1)
866                 precache_weapons |= warmup_start_weapons;
867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
868         {
869                 e = get_weaponinfo(i);
870                 if(precache_weapons & WepSet_FromWeapon(i))
871                         weapon_action(i, WR_PRECACHE);
872         }
873
874         start_ammo_shells = max(0, start_ammo_shells);
875         start_ammo_nails = max(0, start_ammo_nails);
876         start_ammo_cells = max(0, start_ammo_cells);
877         start_ammo_rockets = max(0, start_ammo_rockets);
878         start_ammo_fuel = max(0, start_ammo_fuel);
879
880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
885 }
886
887 float g_bugrigs;
888 float g_bugrigs_planar_movement;
889 float g_bugrigs_planar_movement_car_jumping;
890 float g_bugrigs_reverse_spinning;
891 float g_bugrigs_reverse_speeding;
892 float g_bugrigs_reverse_stopping;
893 float g_bugrigs_air_steering;
894 float g_bugrigs_angle_smoothing;
895 float g_bugrigs_friction_floor;
896 float g_bugrigs_friction_brake;
897 float g_bugrigs_friction_air;
898 float g_bugrigs_accel;
899 float g_bugrigs_speed_ref;
900 float g_bugrigs_speed_pow;
901 float g_bugrigs_steer;
902
903 float sv_autotaunt;
904 float sv_taunt;
905
906 string GetGametype(); // g_world.qc
907 void readlevelcvars(void)
908 {
909         // load mutators
910         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
911                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
912
913         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
914         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
915         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
916         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
917         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
918         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
919         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
920         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
921         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
922         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
923         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
924         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
925         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
926         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
927         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
928         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
929         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
930         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
931         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
932         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
933         CHECK_MUTATOR_ADD("g_buffs", mutator_buffs, 1);
934
935         #undef CHECK_MUTATOR_ADD
936
937         if(cvar("sv_allow_fullbright"))
938                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
939
940     g_bugrigs = cvar("g_bugrigs");
941     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
942     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
943     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
944     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
945     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
946     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
947     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
948     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
949     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
950     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
951     g_bugrigs_accel = cvar("g_bugrigs_accel");
952     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
953     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
954     g_bugrigs_steer = cvar("g_bugrigs_steer");
955
956         g_minstagib = cvar("g_minstagib");
957
958         sv_clones = cvar("sv_clones");
959         sv_foginterval = cvar("sv_foginterval");
960         g_cloaked = cvar("g_cloaked");
961     if(g_cts)
962         g_cloaked = 1; // always enable cloak in CTS
963         g_footsteps = cvar("g_footsteps");
964         g_grappling_hook = cvar("g_grappling_hook");
965         g_jetpack = cvar("g_jetpack");
966         sv_maxidle = cvar("sv_maxidle");
967         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
968         sv_autotaunt = cvar("sv_autotaunt");
969         sv_taunt = cvar("sv_taunt");
970
971         warmup_stage = cvar("g_warmup");
972         g_warmup_limit = cvar("g_warmup_limit");
973         g_warmup_allguns = cvar("g_warmup_allguns");
974         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
975
976         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
977                 warmup_stage = 0; // these modes cannot work together, sorry
978
979         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
980         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
981         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
982         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
983         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
984         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
985         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
986         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
987         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
988         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
989         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
990         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
991         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
992         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
993
994         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
995         g_weaponratefactor = cvar("g_weaponratefactor");
996         g_weapondamagefactor = cvar("g_weapondamagefactor");
997         g_weaponforcefactor = cvar("g_weaponforcefactor");
998         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
999
1000         g_pickup_shells = cvar("g_pickup_shells");
1001         g_pickup_shells_max = cvar("g_pickup_shells_max");
1002         g_pickup_nails = cvar("g_pickup_nails");
1003         g_pickup_nails_max = cvar("g_pickup_nails_max");
1004         g_pickup_rockets = cvar("g_pickup_rockets");
1005         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1006         g_pickup_cells = cvar("g_pickup_cells");
1007         g_pickup_cells_max = cvar("g_pickup_cells_max");
1008         g_pickup_fuel = cvar("g_pickup_fuel");
1009         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1010         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1011         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1012         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1013         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1014         g_pickup_armormedium = cvar("g_pickup_armormedium");
1015         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1016         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1017         g_pickup_armorbig = cvar("g_pickup_armorbig");
1018         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1019         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1020         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1021         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1022         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1023         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1024         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1025         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1026         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1027         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1028         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1029         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1030         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1031         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1032         g_pickup_healthmega = cvar("g_pickup_healthmega");
1033         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1034         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1035
1036         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1037         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1038
1039     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1040     if(!g_weapon_stay)
1041         g_weapon_stay = cvar("g_weapon_stay");
1042
1043         if (!warmup_stage)
1044                 game_starttime = time + cvar("g_start_delay");
1045
1046         readplayerstartcvars();
1047 }
1048
1049 //#NO AUTOCVARS END
1050
1051 // Sound functions
1052 string precache_sound (string s) = #19;
1053 float precache_sound_index (string s) = #19;
1054
1055 #define SND_VOLUME      1
1056 #define SND_ATTENUATION 2
1057 #define SND_LARGEENTITY 8
1058 #define SND_LARGESOUND  16
1059
1060 float sound_allowed(float dest, entity e)
1061 {
1062     // sounds from world may always pass
1063     for (;;)
1064     {
1065         if (e.classname == "body")
1066             e = e.enemy;
1067         else if (e.realowner && e.realowner != e)
1068             e = e.realowner;
1069         else if (e.owner && e.owner != e)
1070             e = e.owner;
1071         else
1072             break;
1073     }
1074     // sounds to self may always pass
1075     if (dest == MSG_ONE)
1076         if (e == msg_entity)
1077             return TRUE;
1078     // sounds by players can be removed
1079     if (autocvar_bot_sound_monopoly)
1080         if (IS_REAL_CLIENT(e))
1081             return FALSE;
1082     // anything else may pass
1083     return TRUE;
1084 }
1085
1086 #undef sound
1087 void sound(entity e, float chan, string samp, float vol, float atten)
1088 {
1089     if (!sound_allowed(MSG_BROADCAST, e))
1090         return;
1091     sound7(e, chan, samp, vol, atten, 0, 0);
1092 }
1093
1094 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1095 {
1096     float entno, idx;
1097
1098     if (!sound_allowed(dest, e))
1099         return;
1100
1101     entno = num_for_edict(e);
1102     idx = precache_sound_index(samp);
1103
1104     float sflags;
1105     sflags = 0;
1106
1107     atten = floor(atten * 64);
1108     vol = floor(vol * 255);
1109
1110     if (vol != 255)
1111         sflags |= SND_VOLUME;
1112     if (atten != 64)
1113         sflags |= SND_ATTENUATION;
1114     if (entno >= 8192 || chan < 0 || chan > 7)
1115         sflags |= SND_LARGEENTITY;
1116     if (idx >= 256)
1117         sflags |= SND_LARGESOUND;
1118
1119     WriteByte(dest, SVC_SOUND);
1120     WriteByte(dest, sflags);
1121     if (sflags & SND_VOLUME)
1122         WriteByte(dest, vol);
1123     if (sflags & SND_ATTENUATION)
1124         WriteByte(dest, atten);
1125     if (sflags & SND_LARGEENTITY)
1126     {
1127         WriteShort(dest, entno);
1128         WriteByte(dest, chan);
1129     }
1130     else
1131     {
1132         WriteShort(dest, entno * 8 + chan);
1133     }
1134     if (sflags & SND_LARGESOUND)
1135         WriteShort(dest, idx);
1136     else
1137         WriteByte(dest, idx);
1138
1139     WriteCoord(dest, o_x);
1140     WriteCoord(dest, o_y);
1141     WriteCoord(dest, o_z);
1142 }
1143 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1144 {
1145     vector o;
1146
1147     if (!sound_allowed(dest, e))
1148         return;
1149
1150     o = e.origin + 0.5 * (e.mins + e.maxs);
1151     soundtoat(dest, e, o, chan, samp, vol, atten);
1152 }
1153 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1154 {
1155     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1156 }
1157 void stopsoundto(float dest, entity e, float chan)
1158 {
1159     float entno;
1160
1161     if (!sound_allowed(dest, e))
1162         return;
1163
1164     entno = num_for_edict(e);
1165
1166     if (entno >= 8192 || chan < 0 || chan > 7)
1167     {
1168         float idx, sflags;
1169         idx = precache_sound_index("misc/null.wav");
1170         sflags = SND_LARGEENTITY;
1171         if (idx >= 256)
1172             sflags |= SND_LARGESOUND;
1173         WriteByte(dest, SVC_SOUND);
1174         WriteByte(dest, sflags);
1175         WriteShort(dest, entno);
1176         WriteByte(dest, chan);
1177         if (sflags & SND_LARGESOUND)
1178             WriteShort(dest, idx);
1179         else
1180             WriteByte(dest, idx);
1181         WriteCoord(dest, e.origin_x);
1182         WriteCoord(dest, e.origin_y);
1183         WriteCoord(dest, e.origin_z);
1184     }
1185     else
1186     {
1187         WriteByte(dest, SVC_STOPSOUND);
1188         WriteShort(dest, entno * 8 + chan);
1189     }
1190 }
1191 void stopsound(entity e, float chan)
1192 {
1193     if (!sound_allowed(MSG_BROADCAST, e))
1194         return;
1195
1196     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1197     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1198 }
1199
1200 void play2(entity e, string filename)
1201 {
1202     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1203     msg_entity = e;
1204     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1205 }
1206
1207 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1208 .float spamtime;
1209 float spamsound(entity e, float chan, string samp, float vol, float atten)
1210 {
1211     if (!sound_allowed(MSG_BROADCAST, e))
1212         return FALSE;
1213
1214     if (time > e.spamtime)
1215     {
1216         e.spamtime = time;
1217         sound(e, chan, samp, vol, atten);
1218         return TRUE;
1219     }
1220     return FALSE;
1221 }
1222
1223 void play2team(float t, string filename)
1224 {
1225     entity head;
1226
1227     if (autocvar_bot_sound_monopoly)
1228         return;
1229
1230     FOR_EACH_REALPLAYER(head)
1231     {
1232         if (head.team == t)
1233             play2(head, filename);
1234     }
1235 }
1236
1237 void play2all(string samp)
1238 {
1239     if (autocvar_bot_sound_monopoly)
1240         return;
1241
1242     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1243 }
1244
1245 void PrecachePlayerSounds(string f);
1246 void precache_playermodel(string m)
1247 {
1248         float globhandle, i, n;
1249         string f;
1250
1251         if(substring(m, -9,5) == "_lod1")
1252                 return;
1253         if(substring(m, -9,5) == "_lod2")
1254                 return;
1255         precache_model(m);
1256         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1257         if(fexists(f))
1258                 precache_model(f);
1259         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1260         if(fexists(f))
1261                 precache_model(f);
1262
1263         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1264         if (globhandle < 0)
1265                 return;
1266         n = search_getsize(globhandle);
1267         for (i = 0; i < n; ++i)
1268         {
1269                 //print(search_getfilename(globhandle, i), "\n");
1270                 f = search_getfilename(globhandle, i);
1271                 PrecachePlayerSounds(f);
1272         }
1273         search_end(globhandle);
1274 }
1275 void precache_all_playermodels(string pattern)
1276 {
1277         float globhandle, i, n;
1278         string f;
1279
1280         globhandle = search_begin(pattern, TRUE, FALSE);
1281         if (globhandle < 0)
1282                 return;
1283         n = search_getsize(globhandle);
1284         for (i = 0; i < n; ++i)
1285         {
1286                 //print(search_getfilename(globhandle, i), "\n");
1287                 f = search_getfilename(globhandle, i);
1288                 precache_playermodel(f);
1289         }
1290         search_end(globhandle);
1291 }
1292
1293 void precache()
1294 {
1295     // gamemode related things
1296     precache_model ("models/misc/chatbubble.spr");
1297
1298 #ifdef TTURRETS_ENABLED
1299     if (autocvar_g_turrets)
1300         turrets_precash();
1301 #endif
1302
1303     // Precache all player models if desired
1304     if (autocvar_sv_precacheplayermodels)
1305     {
1306         PrecachePlayerSounds("sound/player/default.sounds");
1307         precache_all_playermodels("models/player/*.zym");
1308         precache_all_playermodels("models/player/*.dpm");
1309         precache_all_playermodels("models/player/*.md3");
1310         precache_all_playermodels("models/player/*.psk");
1311         precache_all_playermodels("models/player/*.iqm");
1312     }
1313
1314     if (autocvar_sv_defaultcharacter)
1315     {
1316         string s;
1317         s = autocvar_sv_defaultplayermodel_red;
1318         if (s != "")
1319             precache_playermodel(s);
1320         s = autocvar_sv_defaultplayermodel_blue;
1321         if (s != "")
1322             precache_playermodel(s);
1323         s = autocvar_sv_defaultplayermodel_yellow;
1324         if (s != "")
1325             precache_playermodel(s);
1326         s = autocvar_sv_defaultplayermodel_pink;
1327         if (s != "")
1328             precache_playermodel(s);
1329         s = autocvar_sv_defaultplayermodel;
1330         if (s != "")
1331             precache_playermodel(s);
1332     }
1333
1334     if (g_footsteps)
1335     {
1336         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1337         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1338     }
1339
1340     // gore and miscellaneous sounds
1341     //precache_sound ("misc/h2ohit.wav");
1342     precache_model ("models/hook.md3");
1343     precache_sound ("misc/armorimpact.wav");
1344     precache_sound ("misc/bodyimpact1.wav");
1345     precache_sound ("misc/bodyimpact2.wav");
1346     precache_sound ("misc/gib.wav");
1347     precache_sound ("misc/gib_splat01.wav");
1348     precache_sound ("misc/gib_splat02.wav");
1349     precache_sound ("misc/gib_splat03.wav");
1350     precache_sound ("misc/gib_splat04.wav");
1351     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1352     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1353     precache_sound ("misc/null.wav");
1354     precache_sound ("misc/spawn.wav");
1355     precache_sound ("misc/talk.wav");
1356     precache_sound ("misc/teleport.wav");
1357     precache_sound ("misc/poweroff.wav");
1358     precache_sound ("player/lava.wav");
1359     precache_sound ("player/slime.wav");
1360
1361     precache_model ("models/sprites/0.spr32");
1362     precache_model ("models/sprites/1.spr32");
1363     precache_model ("models/sprites/2.spr32");
1364     precache_model ("models/sprites/3.spr32");
1365     precache_model ("models/sprites/4.spr32");
1366     precache_model ("models/sprites/5.spr32");
1367     precache_model ("models/sprites/6.spr32");
1368     precache_model ("models/sprites/7.spr32");
1369     precache_model ("models/sprites/8.spr32");
1370     precache_model ("models/sprites/9.spr32");
1371     precache_model ("models/sprites/10.spr32");
1372
1373     // common weapon precaches
1374         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1375     precache_sound ("weapons/weapon_switch.wav");
1376     precache_sound ("weapons/weaponpickup.wav");
1377     precache_sound ("weapons/unavailable.wav");
1378     precache_sound ("weapons/dryfire.wav");
1379     if (g_grappling_hook)
1380     {
1381         precache_sound ("weapons/hook_fire.wav"); // hook
1382         precache_sound ("weapons/hook_impact.wav"); // hook
1383     }
1384
1385     if(autocvar_sv_precacheweapons)
1386     {
1387         //precache weapon models/sounds
1388         float wep;
1389         wep = WEP_FIRST;
1390         while (wep <= WEP_LAST)
1391         {
1392             weapon_action(wep, WR_PRECACHE);
1393             wep = wep + 1;
1394         }
1395     }
1396
1397     precache_model("models/elaser.mdl");
1398     precache_model("models/laser.mdl");
1399     precache_model("models/ebomb.mdl");
1400
1401 #if 0
1402     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1403
1404     if (!self.noise && self.music) // quake 3 uses the music field
1405         self.noise = self.music;
1406
1407     // plays music for the level if there is any
1408     if (self.noise)
1409     {
1410         precache_sound (self.noise);
1411         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1412     }
1413 #endif
1414
1415 #include "precache-for-csqc.inc"
1416 }
1417
1418 // WARNING: this kills the trace globals
1419 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1420 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1421
1422 #define INITPRIO_FIRST              0
1423 #define INITPRIO_GAMETYPE           0
1424 #define INITPRIO_GAMETYPE_FALLBACK  1
1425 #define INITPRIO_FINDTARGET        10
1426 #define INITPRIO_DROPTOFLOOR       20
1427 #define INITPRIO_SETLOCATION       90
1428 #define INITPRIO_LINKDOORS         91
1429 #define INITPRIO_LAST              99
1430
1431 .void(void) initialize_entity;
1432 .float initialize_entity_order;
1433 .entity initialize_entity_next;
1434 entity initialize_entity_first;
1435
1436 void make_safe_for_remove(entity e)
1437 {
1438     if (e.initialize_entity)
1439     {
1440         entity ent, prev = world;
1441         for (ent = initialize_entity_first; ent; )
1442         {
1443             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1444             {
1445                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1446                 // skip it in linked list
1447                 if (prev)
1448                 {
1449                     prev.initialize_entity_next = ent.initialize_entity_next;
1450                     ent = prev.initialize_entity_next;
1451                 }
1452                 else
1453                 {
1454                     initialize_entity_first = ent.initialize_entity_next;
1455                     ent = initialize_entity_first;
1456                 }
1457             }
1458             else
1459             {
1460                 prev = ent;
1461                 ent = ent.initialize_entity_next;
1462             }
1463         }
1464     }
1465 }
1466
1467 void objerror(string s)
1468 {
1469     make_safe_for_remove(self);
1470     builtin_objerror(s);
1471 }
1472
1473 .float remove_except_protected_forbidden;
1474 void remove_except_protected(entity e)
1475 {
1476         if(e.remove_except_protected_forbidden)
1477                 error("not allowed to remove this at this point");
1478         builtin_remove(e);
1479 }
1480
1481 void remove_unsafely(entity e)
1482 {
1483     if(e.classname == "spike")
1484         error("Removing spikes is forbidden (crylink bug), please report");
1485     builtin_remove(e);
1486 }
1487
1488 void remove_safely(entity e)
1489 {
1490     make_safe_for_remove(e);
1491     builtin_remove(e);
1492 }
1493
1494 void InitializeEntity(entity e, void(void) func, float order)
1495 {
1496     entity prev, cur;
1497
1498     if (!e || e.initialize_entity)
1499     {
1500         // make a proxy initializer entity
1501         entity e_old;
1502         e_old = e;
1503         e = spawn();
1504         e.classname = "initialize_entity";
1505         e.enemy = e_old;
1506     }
1507
1508     e.initialize_entity = func;
1509     e.initialize_entity_order = order;
1510
1511     cur = initialize_entity_first;
1512     prev = world;
1513     for (;;)
1514     {
1515         if (!cur || cur.initialize_entity_order > order)
1516         {
1517             // insert between prev and cur
1518             if (prev)
1519                 prev.initialize_entity_next = e;
1520             else
1521                 initialize_entity_first = e;
1522             e.initialize_entity_next = cur;
1523             return;
1524         }
1525         prev = cur;
1526         cur = cur.initialize_entity_next;
1527     }
1528 }
1529 void InitializeEntitiesRun()
1530 {
1531     entity startoflist;
1532     startoflist = initialize_entity_first;
1533     initialize_entity_first = world;
1534     remove = remove_except_protected;
1535     for (self = startoflist; self; self = self.initialize_entity_next)
1536     {
1537         self.remove_except_protected_forbidden = 1;
1538     }
1539     for (self = startoflist; self; )
1540     {
1541         entity e;
1542         var void(void) func;
1543         e = self.initialize_entity_next;
1544         func = self.initialize_entity;
1545         self.initialize_entity_order = 0;
1546         self.initialize_entity = func_null;
1547         self.initialize_entity_next = world;
1548         self.remove_except_protected_forbidden = 0;
1549         if (self.classname == "initialize_entity")
1550         {
1551             entity e_old;
1552             e_old = self.enemy;
1553             builtin_remove(self);
1554             self = e_old;
1555         }
1556         //dprint("Delayed initialization: ", self.classname, "\n");
1557         if(func)
1558             func();
1559         else
1560         {
1561             eprint(self);
1562             backtrace(strcat("Null function in: ", self.classname, "\n"));
1563         }
1564         self = e;
1565     }
1566     remove = remove_unsafely;
1567 }
1568
1569 .float uncustomizeentityforclient_set;
1570 .void(void) uncustomizeentityforclient;
1571 void UncustomizeEntitiesRun()
1572 {
1573     entity oldself;
1574     oldself = self;
1575     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1576         self.uncustomizeentityforclient();
1577     self = oldself;
1578 }
1579 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1580 {
1581     e.customizeentityforclient = customizer;
1582     e.uncustomizeentityforclient = uncustomizer;
1583     e.uncustomizeentityforclient_set = !!uncustomizer;
1584 }
1585
1586 .float nottargeted;
1587 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1588
1589 void() SUB_Remove;
1590 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1591 {
1592     vector mi, ma;
1593
1594     if (e.classname == "")
1595         e.classname = "net_linked";
1596
1597     if (e.model == "" || self.modelindex == 0)
1598     {
1599         mi = e.mins;
1600         ma = e.maxs;
1601         setmodel(e, "null");
1602         setsize(e, mi, ma);
1603     }
1604
1605     e.SendEntity = sendfunc;
1606     e.SendFlags = 0xFFFFFF;
1607
1608     if (!docull)
1609         e.effects |= EF_NODEPTHTEST;
1610
1611     if (dt)
1612     {
1613         e.nextthink = time + dt;
1614         e.think = SUB_Remove;
1615     }
1616 }
1617
1618 void adaptor_think2touch()
1619 {
1620     entity o;
1621     o = other;
1622     other = world;
1623     self.touch();
1624     other = o;
1625 }
1626
1627 void adaptor_think2use()
1628 {
1629     entity o, a;
1630     o = other;
1631     a = activator;
1632     activator = world;
1633     other = world;
1634     self.use();
1635     other = o;
1636     activator = a;
1637 }
1638
1639 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1640 {
1641         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1642                 self.projectiledeathtype |= HITTYPE_SPLASH;
1643         adaptor_think2use();
1644 }
1645
1646 // deferred dropping
1647 void DropToFloor_Handler()
1648 {
1649     builtin_droptofloor();
1650     self.dropped_origin = self.origin;
1651 }
1652
1653 void droptofloor()
1654 {
1655     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1656 }
1657
1658
1659
1660 float trace_hits_box_a0, trace_hits_box_a1;
1661
1662 float trace_hits_box_1d(float end, float thmi, float thma)
1663 {
1664     if (end == 0)
1665     {
1666         // just check if x is in range
1667         if (0 < thmi)
1668             return FALSE;
1669         if (0 > thma)
1670             return FALSE;
1671     }
1672     else
1673     {
1674         // do the trace with respect to x
1675         // 0 -> end has to stay in thmi -> thma
1676         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1677         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1678         if (trace_hits_box_a0 > trace_hits_box_a1)
1679             return FALSE;
1680     }
1681     return TRUE;
1682 }
1683
1684 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1685 {
1686     end -= start;
1687     thmi -= start;
1688     thma -= start;
1689     // now it is a trace from 0 to end
1690
1691     trace_hits_box_a0 = 0;
1692     trace_hits_box_a1 = 1;
1693
1694     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1695         return FALSE;
1696     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1697         return FALSE;
1698     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1699         return FALSE;
1700
1701     return TRUE;
1702 }
1703
1704 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1705 {
1706     return trace_hits_box(start, end, thmi - ma, thma - mi);
1707 }
1708
1709 float SUB_NoImpactCheck()
1710 {
1711         // zero hitcontents = this is not the real impact, but either the
1712         // mirror-impact of something hitting the projectile instead of the
1713         // projectile hitting the something, or a touchareagrid one. Neither of
1714         // these stop the projectile from moving, so...
1715         if(trace_dphitcontents == 0)
1716         {
1717                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1718                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1719                 checkclient();
1720         }
1721     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1722         return 1;
1723     if (other == world && self.size != '0 0 0')
1724     {
1725         vector tic;
1726         tic = self.velocity * sys_frametime;
1727         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1728         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1729         if (trace_fraction >= 1)
1730         {
1731             dprint("Odd... did not hit...?\n");
1732         }
1733         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1734         {
1735             dprint("Detected and prevented the sky-grapple bug.\n");
1736             return 1;
1737         }
1738     }
1739
1740     return 0;
1741 }
1742
1743 #define SUB_OwnerCheck() (other && (other == self.owner))
1744
1745 void RemoveGrapplingHook(entity pl);
1746 void W_Crylink_Dequeue(entity e);
1747 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1748 {
1749         if(SUB_OwnerCheck())
1750                 return TRUE;
1751         if(SUB_NoImpactCheck())
1752         {
1753                 if(self.classname == "grapplinghook")
1754                         RemoveGrapplingHook(self.realowner);
1755                 else if(self.classname == "spike")
1756                 {
1757                         W_Crylink_Dequeue(self);
1758                         remove(self);
1759                 }
1760                 else
1761                         remove(self);
1762                 return TRUE;
1763         }
1764         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1765                 UpdateCSQCProjectile(self);
1766         return FALSE;
1767 }
1768 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1769
1770 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1771 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1772
1773 void URI_Get_Callback(float id, float status, string data)
1774 {
1775         if(url_URI_Get_Callback(id, status, data))
1776         {
1777                 // handled
1778         }
1779         else if (id == URI_GET_DISCARD)
1780         {
1781                 // discard
1782         }
1783         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1784         {
1785                 // sv_cmd curl
1786                 Curl_URI_Get_Callback(id, status, data);
1787         }
1788         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1789         {
1790                 // online ban list
1791                 OnlineBanList_URI_Get_Callback(id, status, data);
1792         }
1793         else
1794         {
1795                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1796         }
1797 }
1798
1799 string uid2name(string myuid) {
1800         string s;
1801         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1802
1803         // FIXME remove this later after 0.6 release
1804         // convert old style broken records to correct style
1805         if(s == "")
1806         {
1807                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1808                 if(s != "")
1809                 {
1810                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1811                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1812                 }
1813         }
1814
1815         if(s == "")
1816                 s = "^1Unregistered Player";
1817         return s;
1818 }
1819
1820 float race_readTime(string map, float pos)
1821 {
1822         string rr;
1823         if(g_cts)
1824                 rr = CTS_RECORD;
1825         else
1826                 rr = RACE_RECORD;
1827
1828         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1829 }
1830
1831 string race_readUID(string map, float pos)
1832 {
1833         string rr;
1834         if(g_cts)
1835                 rr = CTS_RECORD;
1836         else
1837                 rr = RACE_RECORD;
1838
1839         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1840 }
1841
1842 float race_readPos(string map, float t) {
1843         float i;
1844         for (i = 1; i <= RANKINGS_CNT; ++i)
1845                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1846                         return i;
1847
1848         return 0; // pos is zero if unranked
1849 }
1850
1851 void race_writeTime(string map, float t, string myuid)
1852 {
1853         string rr;
1854         if(g_cts)
1855                 rr = CTS_RECORD;
1856         else
1857                 rr = RACE_RECORD;
1858
1859         float newpos;
1860         newpos = race_readPos(map, t);
1861
1862         float i, prevpos = 0;
1863         for(i = 1; i <= RANKINGS_CNT; ++i)
1864         {
1865                 if(race_readUID(map, i) == myuid)
1866                         prevpos = i;
1867         }
1868         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1869                 for (i = prevpos; i > newpos; --i) {
1870                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1871                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1872                 }
1873         } else { // player has no ranked record yet
1874                 for (i = RANKINGS_CNT; i > newpos; --i) {
1875                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1876                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1877                 }
1878         }
1879
1880         // store new time itself
1881         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1882         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1883 }
1884
1885 string race_readName(string map, float pos)
1886 {
1887         string rr;
1888         if(g_cts)
1889                 rr = CTS_RECORD;
1890         else
1891                 rr = RACE_RECORD;
1892
1893         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1894 }
1895
1896 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1897 {
1898     float m, i;
1899     vector start, org, delta, end, enddown, mstart;
1900     entity sp;
1901
1902     m = e.dphitcontentsmask;
1903     e.dphitcontentsmask = goodcontents | badcontents;
1904
1905     org = world.mins;
1906     delta = world.maxs - world.mins;
1907
1908     start = end = org;
1909
1910     for (i = 0; i < attempts; ++i)
1911     {
1912         start_x = org_x + random() * delta_x;
1913         start_y = org_y + random() * delta_y;
1914         start_z = org_z + random() * delta_z;
1915
1916         // rule 1: start inside world bounds, and outside
1917         // solid, and don't start from somewhere where you can
1918         // fall down to evil
1919         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1920         if (trace_fraction >= 1)
1921             continue;
1922         if (trace_startsolid)
1923             continue;
1924         if (trace_dphitcontents & badcontents)
1925             continue;
1926         if (trace_dphitq3surfaceflags & badsurfaceflags)
1927             continue;
1928
1929         // rule 2: if we are too high, lower the point
1930         if (trace_fraction * delta_z > maxaboveground)
1931             start = trace_endpos + '0 0 1' * maxaboveground;
1932         enddown = trace_endpos;
1933
1934         // rule 3: make sure we aren't outside the map. This only works
1935         // for somewhat well formed maps. A good rule of thumb is that
1936         // the map should have a convex outside hull.
1937         // these can be traceLINES as we already verified the starting box
1938         mstart = start + 0.5 * (e.mins + e.maxs);
1939         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1940         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1941             continue;
1942         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1943         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1944             continue;
1945         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1946         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1947             continue;
1948         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1949         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1950             continue;
1951         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1952         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1953             continue;
1954
1955         // rule 4: we must "see" some spawnpoint or item
1956         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1957                 if(checkpvs(mstart, sp))
1958                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1959                                 break;
1960         if(!sp)
1961         {
1962                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1963                         if(checkpvs(mstart, sp))
1964                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1965                                         break;
1966                 if(!sp)
1967                         continue;
1968         }
1969
1970         // find a random vector to "look at"
1971         end_x = org_x + random() * delta_x;
1972         end_y = org_y + random() * delta_y;
1973         end_z = org_z + random() * delta_z;
1974         end = start + normalize(end - start) * vlen(delta);
1975
1976         // rule 4: start TO end must not be too short
1977         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1978         if (trace_startsolid)
1979             continue;
1980         if (trace_fraction < minviewdistance / vlen(delta))
1981             continue;
1982
1983         // rule 5: don't want to look at sky
1984         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1985             continue;
1986
1987         // rule 6: we must not end up in trigger_hurt
1988         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1989             continue;
1990
1991         break;
1992     }
1993
1994     e.dphitcontentsmask = m;
1995
1996     if (i < attempts)
1997     {
1998         setorigin(e, start);
1999         e.angles = vectoangles(end - start);
2000         dprint("Needed ", ftos(i + 1), " attempts\n");
2001         return TRUE;
2002     }
2003     else
2004         return FALSE;
2005 }
2006
2007 void write_recordmarker(entity pl, float tstart, float dt)
2008 {
2009     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2010
2011     // also write a marker into demo files for demotc-race-record-extractor to find
2012     stuffcmd(pl,
2013              strcat(
2014                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2015                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2016 }
2017
2018 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2019 {
2020         switch(algn)
2021         {
2022                 default:
2023                 case 3: // right
2024                         break;
2025
2026                 case 4: // left
2027                         vecs_y = -vecs_y;
2028                         break;
2029
2030                 case 1:
2031                         if(allowcenter) // 2: allow center handedness
2032                         {
2033                                 // center
2034                                 vecs_y = 0;
2035                                 vecs_z -= 2;
2036                         }
2037                         else
2038                         {
2039                                 // right
2040                         }
2041                         break;
2042
2043                 case 2:
2044                         if(allowcenter) // 2: allow center handedness
2045                         {
2046                                 // center
2047                                 vecs_y = 0;
2048                                 vecs_z -= 2;
2049                         }
2050                         else
2051                         {
2052                                 // left
2053                                 vecs_y = -vecs_y;
2054                         }
2055                         break;
2056         }
2057         return vecs;
2058 }
2059
2060 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2061 {
2062         string s;
2063         vector v;
2064
2065         if (autocvar_g_shootfromeye)
2066         {
2067                 if (visual)
2068                 {
2069                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2070                         else { vecs_y = 0; vecs_z -= 2; }
2071                 }
2072                 else
2073                 {
2074                         vecs_y = 0;
2075                         vecs_z = 0;
2076                 }
2077         }
2078         else if (autocvar_g_shootfromcenter)
2079         {
2080                 vecs_y = 0;
2081                 vecs_z -= 2;
2082         }
2083         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2084         {
2085                 v = stov(s);
2086                 if (y_is_right)
2087                         v_y = -v_y;
2088                 if (v_x != 0)
2089                         vecs_x = v_x;
2090                 vecs_y = v_y;
2091                 vecs_z = v_z;
2092         }
2093         else if (autocvar_g_shootfromclient)
2094         {
2095                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2096         }
2097         return vecs;
2098 }
2099
2100 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2101 {
2102         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2103 }
2104
2105
2106 void attach_sameorigin(entity e, entity to, string tag)
2107 {
2108     vector org, t_forward, t_left, t_up, e_forward, e_up;
2109     float tagscale;
2110
2111     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2112     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2113     t_forward = v_forward * tagscale;
2114     t_left = v_right * -tagscale;
2115     t_up = v_up * tagscale;
2116
2117     e.origin_x = org * t_forward;
2118     e.origin_y = org * t_left;
2119     e.origin_z = org * t_up;
2120
2121     // current forward and up directions
2122     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2123                 e.angles = AnglesTransform_FromVAngles(e.angles);
2124         else
2125                 e.angles = AnglesTransform_FromAngles(e.angles);
2126     fixedmakevectors(e.angles);
2127
2128     // untransform forward, up!
2129     e_forward_x = v_forward * t_forward;
2130     e_forward_y = v_forward * t_left;
2131     e_forward_z = v_forward * t_up;
2132     e_up_x = v_up * t_forward;
2133     e_up_y = v_up * t_left;
2134     e_up_z = v_up * t_up;
2135
2136     e.angles = fixedvectoangles2(e_forward, e_up);
2137     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2138                 e.angles = AnglesTransform_ToVAngles(e.angles);
2139         else
2140                 e.angles = AnglesTransform_ToAngles(e.angles);
2141
2142     setattachment(e, to, tag);
2143     setorigin(e, e.origin);
2144 }
2145
2146 void detach_sameorigin(entity e)
2147 {
2148     vector org;
2149     org = gettaginfo(e, 0);
2150     e.angles = fixedvectoangles2(v_forward, v_up);
2151     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2152                 e.angles = AnglesTransform_ToVAngles(e.angles);
2153         else
2154                 e.angles = AnglesTransform_ToAngles(e.angles);
2155     setorigin(e, org);
2156     setattachment(e, world, "");
2157     setorigin(e, e.origin);
2158 }
2159
2160 void follow_sameorigin(entity e, entity to)
2161 {
2162     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2163     e.aiment = to; // make the hole follow bmodel
2164     e.punchangle = to.angles; // the original angles of bmodel
2165     e.view_ofs = e.origin - to.origin; // relative origin
2166     e.v_angle = e.angles - to.angles; // relative angles
2167 }
2168
2169 void unfollow_sameorigin(entity e)
2170 {
2171     e.movetype = MOVETYPE_NONE;
2172 }
2173
2174 entity gettaginfo_relative_ent;
2175 vector gettaginfo_relative(entity e, float tag)
2176 {
2177     if (!gettaginfo_relative_ent)
2178     {
2179         gettaginfo_relative_ent = spawn();
2180         gettaginfo_relative_ent.effects = EF_NODRAW;
2181     }
2182     gettaginfo_relative_ent.model = e.model;
2183     gettaginfo_relative_ent.modelindex = e.modelindex;
2184     gettaginfo_relative_ent.frame = e.frame;
2185     return gettaginfo(gettaginfo_relative_ent, tag);
2186 }
2187
2188 .float scale2;
2189
2190 float modeleffect_SendEntity(entity to, float sf)
2191 {
2192         float f;
2193         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2194
2195         f = 0;
2196         if(self.velocity != '0 0 0')
2197                 f |= 1;
2198         if(self.angles != '0 0 0')
2199                 f |= 2;
2200         if(self.avelocity != '0 0 0')
2201                 f |= 4;
2202
2203         WriteByte(MSG_ENTITY, f);
2204         WriteShort(MSG_ENTITY, self.modelindex);
2205         WriteByte(MSG_ENTITY, self.skin);
2206         WriteByte(MSG_ENTITY, self.frame);
2207         WriteCoord(MSG_ENTITY, self.origin_x);
2208         WriteCoord(MSG_ENTITY, self.origin_y);
2209         WriteCoord(MSG_ENTITY, self.origin_z);
2210         if(f & 1)
2211         {
2212                 WriteCoord(MSG_ENTITY, self.velocity_x);
2213                 WriteCoord(MSG_ENTITY, self.velocity_y);
2214                 WriteCoord(MSG_ENTITY, self.velocity_z);
2215         }
2216         if(f & 2)
2217         {
2218                 WriteCoord(MSG_ENTITY, self.angles_x);
2219                 WriteCoord(MSG_ENTITY, self.angles_y);
2220                 WriteCoord(MSG_ENTITY, self.angles_z);
2221         }
2222         if(f & 4)
2223         {
2224                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2225                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2226                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2227         }
2228         WriteShort(MSG_ENTITY, self.scale * 256.0);
2229         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2230         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2231         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2232         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2233
2234         return TRUE;
2235 }
2236
2237 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2238 {
2239         entity e;
2240         float sz;
2241         e = spawn();
2242         e.classname = "modeleffect";
2243         setmodel(e, m);
2244         e.frame = f;
2245         setorigin(e, o);
2246         e.velocity = v;
2247         e.angles = ang;
2248         e.avelocity = angv;
2249         e.alpha = a;
2250         e.teleport_time = t1;
2251         e.fade_time = t2;
2252         e.skin = s;
2253         if(s0 >= 0)
2254                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2255         else
2256                 e.scale = -s0;
2257         if(s2 >= 0)
2258                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2259         else
2260                 e.scale2 = -s2;
2261         sz = max(e.scale, e.scale2);
2262         setsize(e, e.mins * sz, e.maxs * sz);
2263         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2264 }
2265
2266 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2267 {
2268         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2269 }
2270
2271 float randombit(float bits)
2272 {
2273         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2274                 return bits;
2275
2276         float n, f, b, r;
2277
2278         r = random();
2279         b = 0;
2280         n = 0;
2281
2282         for(f = 1; f <= bits; f *= 2)
2283         {
2284                 if(bits & f)
2285                 {
2286                         ++n;
2287                         r *= n;
2288                         if(r <= 1)
2289                                 b = f;
2290                         else
2291                                 r = (r - 1) / (n - 1);
2292                 }
2293         }
2294
2295         return b;
2296 }
2297
2298 float randombits(float bits, float k, float error_return)
2299 {
2300         float r;
2301         r = 0;
2302         while(k > 0 && bits != r)
2303         {
2304                 r += randombit(bits - r);
2305                 --k;
2306         }
2307         if(error_return)
2308                 if(k > 0)
2309                         return -1; // all
2310         return r;
2311 }
2312
2313 void randombit_test(float bits, float iter)
2314 {
2315         while(iter > 0)
2316         {
2317                 print(ftos(randombit(bits)), "\n");
2318                 --iter;
2319         }
2320 }
2321
2322 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2323 {
2324         if(halflifedist > 0)
2325                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2326         else if(halflifedist < 0)
2327                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2328         else
2329                 return 1;
2330 }
2331
2332
2333
2334
2335 #ifdef RELEASE
2336 #define cvar_string_normal builtin_cvar_string
2337 #define cvar_normal builtin_cvar
2338 #else
2339 string cvar_string_normal(string n)
2340 {
2341         if (!(cvar_type(n) & 1))
2342                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2343         return builtin_cvar_string(n);
2344 }
2345
2346 float cvar_normal(string n)
2347 {
2348         return stof(cvar_string_normal(n));
2349 }
2350 #endif
2351 #define cvar_set_normal builtin_cvar_set
2352
2353 void defer_think()
2354 {
2355     entity oself;
2356
2357     oself           = self;
2358     self            = self.owner;
2359     oself.think     = SUB_Remove;
2360     oself.nextthink = time;
2361
2362     oself.use();
2363 }
2364
2365 /*
2366     Execute func() after time + fdelay.
2367     self when func is executed = self when defer is called
2368 */
2369 void defer(float fdelay, void() func)
2370 {
2371     entity e;
2372
2373     e           = spawn();
2374     e.owner     = self;
2375     e.use       = func;
2376     e.think     = defer_think;
2377     e.nextthink = time + fdelay;
2378 }
2379
2380 .string aiment_classname;
2381 .float aiment_deadflag;
2382 void SetMovetypeFollow(entity ent, entity e)
2383 {
2384         // FIXME this may not be warpzone aware
2385         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2386         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2387         ent.aiment = e; // make the hole follow bmodel
2388         ent.punchangle = e.angles; // the original angles of bmodel
2389         ent.view_ofs = ent.origin - e.origin; // relative origin
2390         ent.v_angle = ent.angles - e.angles; // relative angles
2391         ent.aiment_classname = strzone(e.classname);
2392         ent.aiment_deadflag = e.deadflag;
2393 }
2394 void UnsetMovetypeFollow(entity ent)
2395 {
2396         ent.movetype = MOVETYPE_FLY;
2397         PROJECTILE_MAKETRIGGER(ent);
2398         ent.aiment = world;
2399 }
2400 float LostMovetypeFollow(entity ent)
2401 {
2402 /*
2403         if(ent.movetype != MOVETYPE_FOLLOW)
2404                 if(ent.aiment)
2405                         error("???");
2406 */
2407         if(ent.aiment)
2408         {
2409                 if(ent.aiment.classname != ent.aiment_classname)
2410                         return 1;
2411                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2412                         return 1;
2413         }
2414         return 0;
2415 }
2416
2417 float isPushable(entity e)
2418 {
2419         if(e.iscreature)
2420                 return TRUE;
2421         if(e.pushable)
2422                 return TRUE;
2423         switch(e.classname)
2424         {
2425                 case "body":
2426                 case "droppedweapon":
2427                 case "keepawayball":
2428                 case "nexball_basketball":
2429                 case "nexball_football":
2430                         return TRUE;
2431                 case "bullet": // antilagged bullets can't hit this either
2432                         return FALSE;
2433         }
2434         if (e.projectiledeathtype)
2435                 return TRUE;
2436         return FALSE;
2437 }