Merge remote branch 'origin/fruitiex/ctsfix'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
12 void WarpZone_crosshair_trace(entity pl)
13 {
14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
15 }
16
17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
18 void() spawnpoint_use;
19 string GetMapname();
20 string ColoredTeamName(float t);
21
22 string admin_name(void)
23 {
24         if(autocvar_sv_adminnick != "")
25                 return autocvar_sv_adminnick;
26         else
27                 return "SERVER ADMIN";
28 }
29
30 float DistributeEvenly_amount;
31 float DistributeEvenly_totalweight;
32 void DistributeEvenly_Init(float amount, float totalweight)
33 {
34     if (DistributeEvenly_amount)
35     {
36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
38     }
39     if (totalweight == 0)
40         DistributeEvenly_amount = 0;
41     else
42         DistributeEvenly_amount = amount;
43     DistributeEvenly_totalweight = totalweight;
44 }
45 float DistributeEvenly_Get(float weight)
46 {
47     float f;
48     if (weight <= 0)
49         return 0;
50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
51     DistributeEvenly_totalweight -= weight;
52     DistributeEvenly_amount -= f;
53     return f;
54 }
55
56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
57
58
59 string STR_PLAYER = "player";
60 string STR_SPECTATOR = "spectator";
61 string STR_OBSERVER = "observer";
62
63 #if 0
64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
68 #else
69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
74 #endif
75
76 // copies a string to a tempstring (so one can strunzone it)
77 string strcat1(string s) = #115; // FRIK_FILE
78
79 float logfile_open;
80 float logfile;
81
82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
83 {
84         local float nPlayerHealth = rint(enPlayer.health);
85         local float nPlayerArmor = rint(enPlayer.armorvalue);
86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
87         local float nPlayerPing = rint(enPlayer.ping);
88         local string strPlayerPingColor;
89         local string strMessage;
90         if(nPlayerPing >= 150)
91                 strPlayerPingColor = "^1";
92         else
93                 strPlayerPingColor = "^2";
94
95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
97
98         if(autocvar_sv_fragmessage_information_ping) {
99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
100                         strMessage = strcat(strMessage, " ^7(^2Bot");
101                 else
102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
103                 if(autocvar_sv_fragmessage_information_handicap)
104                         if(autocvar_sv_fragmessage_information_handicap == 2)
105                                 if(nPlayerHandicap <= 1)
106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
107                                 else
108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
109                         else if not(nPlayerHandicap <= 1)
110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
111                 else
112                         strMessage = strcat(strMessage, "^7)");
113         } else if(autocvar_sv_fragmessage_information_handicap) {
114                 if(autocvar_sv_fragmessage_information_handicap == 2)
115                         if(nPlayerHandicap <= 1)
116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
117                         else
118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
119                 else if(nPlayerHandicap > 1)
120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
121         }
122         return strMessage;
123 }
124 void bcenterprint(string s)
125 {
126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
127     entity head;
128     FOR_EACH_PLAYER(head)
129     if (clienttype(head) == CLIENTTYPE_REAL)
130         centerprint(head, s);
131 }
132
133 void GameLogEcho(string s)
134 {
135     string fn;
136     float matches;
137
138     if (autocvar_sv_eventlog_files)
139     {
140         if (!logfile_open)
141         {
142             logfile_open = TRUE;
143             matches = autocvar_sv_eventlog_files_counter + 1;
144             cvar_set("sv_eventlog_files_counter", ftos(matches));
145             fn = ftos(matches);
146             if (strlen(fn) < 8)
147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
149             logfile = fopen(fn, FILE_APPEND);
150             fputs(logfile, ":logversion:3\n");
151         }
152         if (logfile >= 0)
153         {
154             if (autocvar_sv_eventlog_files_timestamps)
155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
156             else
157                 fputs(logfile, strcat(s, "\n"));
158         }
159     }
160     if (autocvar_sv_eventlog_console)
161     {
162         print(s, "\n");
163     }
164 }
165
166 void GameLogInit()
167 {
168     logfile_open = 0;
169     // will be opened later
170 }
171
172 void GameLogClose()
173 {
174     if (logfile_open && logfile >= 0)
175     {
176         fclose(logfile);
177         logfile = -1;
178     }
179 }
180
181 vector PL_VIEW_OFS;
182 vector PL_MIN;
183 vector PL_MAX;
184 vector PL_HEAD;
185 vector PL_CROUCH_VIEW_OFS;
186 vector PL_CROUCH_MIN;
187 vector PL_CROUCH_MAX;
188
189 float spawnpoint_nag;
190 void relocate_spawnpoint()
191 {
192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
193     PL_MIN                                  = stov(autocvar_sv_player_mins);
194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
199
200     // nudge off the floor
201     setorigin(self, self.origin + '0 0 1');
202
203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
204     if (trace_startsolid)
205     {
206         vector o;
207         o = self.origin;
208         self.mins = PL_MIN;
209         self.maxs = PL_MAX;
210         if (!move_out_of_solid(self))
211             objerror("could not get out of solid at all!");
212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
214         print(" ", ftos(self.origin_y - o_y));
215         print(" ", ftos(self.origin_z - o_z), "'\n");
216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
217         {
218             if (!spawnpoint_nag)
219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
220             spawnpoint_nag = 1;
221         }
222         else
223         {
224             setorigin(self, o);
225             self.mins = self.maxs = '0 0 0';
226             objerror("player spawn point in solid, mapper sucks!\n");
227             return;
228         }
229     }
230
231     self.use = spawnpoint_use;
232     self.team_saved = self.team;
233     if (!self.cnt)
234         self.cnt = 1;
235
236     if (have_team_spawns != 0)
237         if (self.team)
238             have_team_spawns = 1;
239
240     if (autocvar_r_showbboxes)
241     {
242         // show where spawnpoints point at too
243         makevectors(self.angles);
244         entity e;
245         e = spawn();
246         e.classname = "info_player_foo";
247         setorigin(e, self.origin + v_forward * 24);
248         setsize(e, '-8 -8 -8', '8 8 8');
249         e.solid = SOLID_TRIGGER;
250     }
251 }
252
253 #define strstr strstrofs
254 /*
255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
258 // BE CONSTANT OR strzoneD!
259 float strstr(string haystack, string needle, float offset)
260 {
261         float len, endpos;
262         string found;
263         len = strlen(needle);
264         endpos = strlen(haystack) - len;
265         while(offset <= endpos)
266         {
267                 found = substring(haystack, offset, len);
268                 if(found == needle)
269                         return offset;
270                 offset = offset + 1;
271         }
272         return -1;
273 }
274 */
275
276 float NUM_NEAREST_ENTITIES = 4;
277 entity nearest_entity[NUM_NEAREST_ENTITIES];
278 float nearest_length[NUM_NEAREST_ENTITIES];
279 entity findnearest(vector point, .string field, string value, vector axismod)
280 {
281     entity localhead;
282     float i;
283     float j;
284     float len;
285     vector dist;
286
287     float num_nearest;
288     num_nearest = 0;
289
290     localhead = find(world, field, value);
291     while (localhead)
292     {
293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
294             dist = localhead.oldorigin;
295         else
296             dist = localhead.origin;
297         dist = dist - point;
298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
299         len = vlen(dist);
300
301         for (i = 0; i < num_nearest; ++i)
302         {
303             if (len < nearest_length[i])
304                 break;
305         }
306
307         // now i tells us where to insert at
308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
309         if (i < NUM_NEAREST_ENTITIES)
310         {
311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
312             {
313                 nearest_length[j + 1] = nearest_length[j];
314                 nearest_entity[j + 1] = nearest_entity[j];
315             }
316             nearest_length[i] = len;
317             nearest_entity[i] = localhead;
318             if (num_nearest < NUM_NEAREST_ENTITIES)
319                 num_nearest = num_nearest + 1;
320         }
321
322         localhead = find(localhead, field, value);
323     }
324
325     // now use the first one from our list that we can see
326     for (i = 0; i < num_nearest; ++i)
327     {
328         traceline(point, nearest_entity[i].origin, TRUE, world);
329         if (trace_fraction == 1)
330         {
331             if (i != 0)
332             {
333                 dprint("Nearest point (");
334                 dprint(nearest_entity[0].netname);
335                 dprint(") is not visible, using a visible one.\n");
336             }
337             return nearest_entity[i];
338         }
339     }
340
341     if (num_nearest == 0)
342         return world;
343
344     dprint("Not seeing any location point, using nearest as fallback.\n");
345     /* DEBUGGING CODE:
346     dprint("Candidates were: ");
347     for(j = 0; j < num_nearest; ++j)
348     {
349         if(j != 0)
350                 dprint(", ");
351         dprint(nearest_entity[j].netname);
352     }
353     dprint("\n");
354     */
355
356     return nearest_entity[0];
357 }
358
359 void spawnfunc_target_location()
360 {
361     self.classname = "target_location";
362     // location name in netname
363     // eventually support: count, teamgame selectors, line of sight?
364 };
365
366 void spawnfunc_info_location()
367 {
368     self.classname = "target_location";
369     self.message = self.netname;
370 };
371
372 string NearestLocation(vector p)
373 {
374     entity loc;
375     string ret;
376     ret = "somewhere";
377     loc = findnearest(p, classname, "target_location", '1 1 1');
378     if (loc)
379     {
380         ret = loc.message;
381     }
382     else
383     {
384         loc = findnearest(p, target, "###item###", '1 1 4');
385         if (loc)
386             ret = loc.netname;
387     }
388     return ret;
389 }
390
391 string formatmessage(string msg)
392 {
393         float p, p1, p2;
394         float n;
395         vector cursor;
396         entity cursor_ent;
397         string escape;
398         string replacement;
399         p = 0;
400         n = 7;
401
402         WarpZone_crosshair_trace(self);
403         cursor = trace_endpos;
404         cursor_ent = trace_ent;
405
406         while (1) {
407                 if (n < 1)
408                         break; // too many replacements
409
410                 n = n - 1;
411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
413
414                 if (p1 < 0)
415                         p1 = p2;
416
417                 if (p2 < 0)
418                         p2 = p1;
419
420                 p = min(p1, p2);
421
422                 if (p < 0)
423                         break;
424
425                 replacement = substring(msg, p, 2);
426                 escape = substring(msg, p + 1, 1);
427
428                 if (escape == "%")
429                         replacement = "%";
430                 else if (escape == "\\")
431                         replacement = "\\";
432                 else if (escape == "n")
433                         replacement = "\n";
434                 else if (escape == "a")
435                         replacement = ftos(floor(self.armorvalue));
436                 else if (escape == "h")
437                         replacement = ftos(floor(self.health));
438                 else if (escape == "l")
439                         replacement = NearestLocation(self.origin);
440                 else if (escape == "y")
441                         replacement = NearestLocation(cursor);
442                 else if (escape == "d")
443                         replacement = NearestLocation(self.death_origin);
444                 else if (escape == "w") {
445                         float wep;
446                         wep = self.weapon;
447                         if (!wep)
448                                 wep = self.switchweapon;
449                         if (!wep)
450                                 wep = self.cnt;
451                         replacement = W_Name(wep);
452                 } else if (escape == "W") {
453                         if (self.items & IT_SHELLS) replacement = "shells";
454                         else if (self.items & IT_NAILS) replacement = "bullets";
455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
456                         else if (self.items & IT_CELLS) replacement = "cells";
457                         else replacement = "batteries"; // ;)
458                 } else if (escape == "x") {
459                         replacement = cursor_ent.netname;
460                         if (!replacement || !cursor_ent)
461                                 replacement = "nothing";
462                 } else if (escape == "p") {
463                         if (self.last_selected_player)
464                                 replacement = self.last_selected_player.netname;
465                         else
466                                 replacement = "(nobody)";
467                 } else if (escape == "s")
468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
469                 else if (escape == "S")
470                         replacement = ftos(vlen(self.velocity));
471
472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
473                 p = p + strlen(replacement);
474         }
475         return msg;
476 }
477
478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
479         return (value == 0) ? FALSE : TRUE;
480 }
481
482 /*
483 =============
484 GetCvars
485 =============
486 Called with:
487   0:  sends the request
488   >0: receives a cvar from name=argv(f) value=argv(f+1)
489 */
490 void GetCvars_handleString(string thisname, float f, .string field, string name)
491 {
492         if (f < 0)
493         {
494                 if (self.field)
495                         strunzone(self.field);
496                 self.field = string_null;
497         }
498         else if (f > 0)
499         {
500                 if (thisname == name)
501                 {
502                         if (self.field)
503                                 strunzone(self.field);
504                         self.field = strzone(argv(f + 1));
505                 }
506         }
507         else
508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
509 }
510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
511 {
512         GetCvars_handleString(thisname, f, field, name);
513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
514                 if (thisname == name)
515                 {
516                         string s;
517                         s = func(strcat1(self.field));
518                         if (s != self.field)
519                         {
520                                 strunzone(self.field);
521                                 self.field = strzone(s);
522                         }
523                 }
524 }
525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
526 {
527         if (f < 0)
528         {
529         }
530         else if (f > 0)
531         {
532                 if (thisname == name)
533                         self.field = stof(argv(f + 1));
534         }
535         else
536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
537 }
538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
539 {
540         if (f < 0)
541         {
542         }
543         else if (f > 0)
544         {
545                 if (thisname == name)
546                 {
547                         if(!self.field)
548                         {
549                                 self.field = stof(argv(f + 1));
550                                 if(!self.field)
551                                         self.field = -1;
552                         }
553                 }
554         }
555         else
556         {
557                 if(!self.field)
558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
559         }
560 }
561 float w_getbestweapon(entity e);
562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
563 {
564         string o;
565         o = W_FixWeaponOrder_ForceComplete(wo);
566         if(self.weaponorder_byimpulse)
567         {
568                 strunzone(self.weaponorder_byimpulse);
569                 self.weaponorder_byimpulse = string_null;
570         }
571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
572         return o;
573 }
574 void GetCvars(float f)
575 {
576         string s;
577
578         if (f > 0)
579                 s = strcat1(argv(f));
580
581         get_cvars_f = f;
582         get_cvars_s = s;
583         MUTATOR_CALLHOOK(GetCvars);
584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
609
610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
612
613 #ifdef ALLOW_FORCEMODELS
614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
616 #endif
617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
619
620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
621         if (f > 0)
622         {
623                 if (s == "cl_weaponpriority")
624                         self.switchweapon = w_getbestweapon(self);
625         }
626 }
627
628 float fexists(string f)
629 {
630     float fh;
631     fh = fopen(f, FILE_READ);
632     if (fh < 0)
633         return FALSE;
634     fclose(fh);
635     return TRUE;
636 }
637
638 void backtrace(string msg)
639 {
640     float dev, war;
641     dev = autocvar_developer;
642     war = autocvar_prvm_backtraceforwarnings;
643     cvar_set("developer", "1");
644     cvar_set("prvm_backtraceforwarnings", "1");
645     print("\n");
646     print("--- CUT HERE ---\nWARNING: ");
647     print(msg);
648     print("\n");
649     remove(world); // isn't there any better way to cause a backtrace?
650     print("\n--- CUT UNTIL HERE ---\n");
651     cvar_set("developer", ftos(dev));
652     cvar_set("prvm_backtraceforwarnings", ftos(war));
653 }
654
655 string Team_ColorCode(float teamid)
656 {
657     if (teamid == COLOR_TEAM1)
658         return "^1";
659     else if (teamid == COLOR_TEAM2)
660         return "^4";
661     else if (teamid == COLOR_TEAM3)
662         return "^3";
663     else if (teamid == COLOR_TEAM4)
664         return "^6";
665     else
666         return "^7";
667 }
668
669 string Team_ColorName(float t)
670 {
671     // fixme: Search for team entities and get their .netname's!
672     if (t == COLOR_TEAM1)
673         return "Red";
674     if (t == COLOR_TEAM2)
675         return "Blue";
676     if (t == COLOR_TEAM3)
677         return "Yellow";
678     if (t == COLOR_TEAM4)
679         return "Pink";
680     return "Neutral";
681 }
682
683 string Team_ColorNameLowerCase(float t)
684 {
685     // fixme: Search for team entities and get their .netname's!
686     if (t == COLOR_TEAM1)
687         return "red";
688     if (t == COLOR_TEAM2)
689         return "blue";
690     if (t == COLOR_TEAM3)
691         return "yellow";
692     if (t == COLOR_TEAM4)
693         return "pink";
694     return "neutral";
695 }
696
697 float ColourToNumber(string team_colour)
698 {
699         if (team_colour == "red")
700                 return COLOR_TEAM1;
701
702         if (team_colour == "blue")
703                 return COLOR_TEAM2;
704
705         if (team_colour == "yellow")
706                 return COLOR_TEAM3;
707
708         if (team_colour == "pink")
709                 return COLOR_TEAM4;
710
711         if (team_colour == "auto")
712                 return 0;
713
714         return -1;
715 }
716
717 float NumberToTeamNumber(float number)
718 {
719         if (number == 1)
720                 return COLOR_TEAM1;
721
722         if (number == 2)
723                 return COLOR_TEAM2;
724
725         if (number == 3)
726                 return COLOR_TEAM3;
727
728         if (number == 4)
729                 return COLOR_TEAM4;
730
731         return -1;
732 }
733
734 #define CENTERPRIO_POINT 1
735 #define CENTERPRIO_SPAM 2
736 #define CENTERPRIO_VOTE 4
737 #define CENTERPRIO_NORMAL 5
738 #define CENTERPRIO_SHIELDING 7
739 #define CENTERPRIO_MAPVOTE 9
740 #define CENTERPRIO_IDLEKICK 50
741 #define CENTERPRIO_ADMIN 99
742 .float centerprint_priority;
743 .float centerprint_expires;
744 void centerprint_atprio(entity e, float prio, string s)
745 {
746     if (intermission_running)
747         if (prio < CENTERPRIO_MAPVOTE)
748             return;
749     if (time > e.centerprint_expires)
750         e.centerprint_priority = 0;
751     if (prio >= e.centerprint_priority)
752     {
753         e.centerprint_priority = prio;
754         if (timeoutStatus == 2)
755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
756         else
757             e.centerprint_expires = time + e.cvar_scr_centertime;
758         centerprint_builtin(e, s);
759     }
760 }
761 void centerprint_expire(entity e, float prio)
762 {
763     if (prio == e.centerprint_priority)
764     {
765         e.centerprint_priority = 0;
766         centerprint_builtin(e, "");
767     }
768 }
769 void centerprint(entity e, string s)
770 {
771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
772 }
773
774 // decolorizes and team colors the player name when needed
775 string playername(entity p)
776 {
777     string t;
778     if (teams_matter && !intermission_running && p.classname == "player")
779     {
780         t = Team_ColorCode(p.team);
781         return strcat(t, strdecolorize(p.netname));
782     }
783     else
784         return p.netname;
785 }
786
787 vector randompos(vector m1, vector m2)
788 {
789     local vector v;
790     m2 = m2 - m1;
791     v_x = m2_x * random() + m1_x;
792     v_y = m2_y * random() + m1_y;
793     v_z = m2_z * random() + m1_z;
794     return  v;
795 };
796
797 //#NO AUTOCVARS START
798
799 float g_pickup_shells;
800 float g_pickup_shells_max;
801 float g_pickup_nails;
802 float g_pickup_nails_max;
803 float g_pickup_rockets;
804 float g_pickup_rockets_max;
805 float g_pickup_cells;
806 float g_pickup_cells_max;
807 float g_pickup_fuel;
808 float g_pickup_fuel_jetpack;
809 float g_pickup_fuel_max;
810 float g_pickup_armorsmall;
811 float g_pickup_armorsmall_max;
812 float g_pickup_armorsmall_anyway;
813 float g_pickup_armormedium;
814 float g_pickup_armormedium_max;
815 float g_pickup_armormedium_anyway;
816 float g_pickup_armorbig;
817 float g_pickup_armorbig_max;
818 float g_pickup_armorbig_anyway;
819 float g_pickup_armorlarge;
820 float g_pickup_armorlarge_max;
821 float g_pickup_armorlarge_anyway;
822 float g_pickup_healthsmall;
823 float g_pickup_healthsmall_max;
824 float g_pickup_healthsmall_anyway;
825 float g_pickup_healthmedium;
826 float g_pickup_healthmedium_max;
827 float g_pickup_healthmedium_anyway;
828 float g_pickup_healthlarge;
829 float g_pickup_healthlarge_max;
830 float g_pickup_healthlarge_anyway;
831 float g_pickup_healthmega;
832 float g_pickup_healthmega_max;
833 float g_pickup_healthmega_anyway;
834 float g_pickup_ammo_anyway;
835 float g_pickup_weapons_anyway;
836 float g_weaponarena;
837 float g_weaponarena_random;
838 float g_weaponarena_random_with_laser;
839 string g_weaponarena_list;
840 float g_weaponspeedfactor;
841 float g_weaponratefactor;
842 float g_weapondamagefactor;
843 float g_weaponforcefactor;
844 float g_weaponspreadfactor;
845
846 float start_weapons;
847 float start_items;
848 float start_ammo_shells;
849 float start_ammo_nails;
850 float start_ammo_rockets;
851 float start_ammo_cells;
852 float start_ammo_fuel;
853 float start_health;
854 float start_armorvalue;
855 float warmup_start_weapons;
856 float warmup_start_ammo_shells;
857 float warmup_start_ammo_nails;
858 float warmup_start_ammo_rockets;
859 float warmup_start_ammo_cells;
860 float warmup_start_ammo_fuel;
861 float warmup_start_health;
862 float warmup_start_armorvalue;
863 float g_weapon_stay;
864 float g_ghost_items;
865
866 entity get_weaponinfo(float w);
867
868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
869 {
870         var float i = weaponinfo.weapon;
871
872         if (!i)
873                 return 0;
874
875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
876
877         if (t < 0) // "default" weapon selection
878         {
879                 if (g_lms || g_ca || allguns)
880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
881                 else if(t < -1)
882                         t = 0;
883                 else if (g_race)
884                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
885                 else if (g_cts)
886                         t = (i == WEP_SHOTGUN);
887                 else if (g_nexball)
888                         t = 0; // weapon is set a few lines later
889                 else
890                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
891                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
892                         t |= (i == WEP_HOOK);
893         }
894
895         // we cannot disable porto in Nexball, we must force it
896         if(g_nexball && i == WEP_PORTO)
897                 t = 1;
898
899         return t;
900 }
901
902 void readplayerstartcvars()
903 {
904         entity e;
905         float i, j, t;
906         string s;
907
908         // initialize starting values for players
909         start_weapons = 0;
910         start_items = 0;
911         start_ammo_shells = 0;
912         start_ammo_nails = 0;
913         start_ammo_rockets = 0;
914         start_ammo_cells = 0;
915         start_health = cvar("g_balance_health_start");
916         start_armorvalue = cvar("g_balance_armor_start");
917
918         g_weaponarena = 0;
919         s = cvar_string("g_weaponarena");
920         if (s == "0")
921         {
922         }
923         else if (s == "all")
924         {
925                 g_weaponarena_list = "All Weapons";
926                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
927                 {
928                         e = get_weaponinfo(j);
929                         g_weaponarena |= e.weapons;
930                         weapon_action(e.weapon, WR_PRECACHE);
931                 }
932         }
933         else if (s == "most")
934         {
935                 g_weaponarena_list = "Most Weapons";
936                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
937                 {
938                         e = get_weaponinfo(j);
939                         if (e.spawnflags & WEP_FLAG_NORMAL)
940                         {
941                                 g_weaponarena |= e.weapons;
942                                 weapon_action(e.weapon, WR_PRECACHE);
943                         }
944                 }
945         }
946         else if (s == "none")
947         {
948                 g_weaponarena_list = "No Weapons";
949                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
950         }
951         else
952         {
953                 t = tokenize_console(s);
954                 g_weaponarena_list = "";
955                 for (i = 0; i < t; ++i)
956                 {
957                         s = argv(i);
958                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
959                         {
960                                 e = get_weaponinfo(j);
961                                 if (e.netname == s)
962                                 {
963                                         g_weaponarena |= e.weapons;
964                                         weapon_action(e.weapon, WR_PRECACHE);
965                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
966                                         break;
967                                 }
968                         }
969                         if (j > WEP_LAST)
970                         {
971                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
972                         }
973                 }
974                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
975         }
976
977         if(g_weaponarena)
978                 g_weaponarena_random = cvar("g_weaponarena_random");
979         else
980                 g_weaponarena_random = 0;
981         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
982
983         if (g_weaponarena)
984         {
985                 start_weapons = g_weaponarena;
986                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
987                 {
988                         e = get_weaponinfo(j);
989                         if(start_weapons & e.weapons)
990                         {
991                                 if(e.items & IT_ROCKETS)
992                                         start_ammo_rockets = 999;
993                                 if(e.items & IT_SHELLS)
994                                         start_ammo_shells = 999;
995                                 if(e.items & IT_CELLS)
996                                         start_ammo_cells = 999;
997                                 if(e.items & IT_NAILS)
998                                         start_ammo_nails = 999;
999                                 if(e.items & IT_FUEL)
1000                                         start_ammo_fuel = 999;
1001                         }
1002                 }
1003                 start_items |= IT_UNLIMITED_AMMO;
1004         }
1005         else if (g_minstagib)
1006         {
1007                 start_health = 100;
1008                 start_armorvalue = 0;
1009                 start_weapons = WEPBIT_MINSTANEX;
1010                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1011                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1012                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1013                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1014
1015                 if (g_minstagib_invis_alpha <= 0)
1016                         g_minstagib_invis_alpha = -1;
1017         }
1018         else
1019         {
1020                 if (g_lms || g_ca)
1021                 {
1022                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1023                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1024                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1025                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1026                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1027                         start_health = cvar("g_lms_start_health");
1028                         start_armorvalue = cvar("g_lms_start_armor");
1029                 }
1030                 else
1031                 {
1032                         start_ammo_shells = cvar("g_start_ammo_shells");
1033                         start_ammo_nails = cvar("g_start_ammo_nails");
1034                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1035                         start_ammo_cells = cvar("g_start_ammo_cells");
1036                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1037                 }
1038
1039                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1040                 {
1041                         e = get_weaponinfo(i);
1042                         if(want_weapon("g_start_weapon_", e, FALSE))
1043                                 start_weapons |= e.weapons;
1044                 }
1045         }
1046
1047         if (inWarmupStage)
1048         {
1049                 warmup_start_ammo_shells = start_ammo_shells;
1050                 warmup_start_ammo_nails = start_ammo_nails;
1051                 warmup_start_ammo_rockets = start_ammo_rockets;
1052                 warmup_start_ammo_cells = start_ammo_cells;
1053                 warmup_start_ammo_fuel = start_ammo_fuel;
1054                 warmup_start_health = start_health;
1055                 warmup_start_armorvalue = start_armorvalue;
1056                 warmup_start_weapons = start_weapons;
1057
1058                 if (!g_weaponarena && !g_minstagib && !g_ca)
1059                 {
1060                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1061                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1062                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1063                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1064                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1065                         warmup_start_health = cvar("g_warmup_start_health");
1066                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1067                         warmup_start_weapons = 0;
1068                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1069                         {
1070                                 e = get_weaponinfo(i);
1071                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1072                                         warmup_start_weapons |= e.weapons;
1073                         }
1074                 }
1075         }
1076
1077         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1078         {
1079                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1080                 start_items |= IT_FUEL_REGEN;
1081                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1082                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1083         }
1084
1085         if(!cvar("g_use_ammunition"))
1086         {
1087                 start_ammo_shells = cvar("g_pickup_shells_max");
1088                 start_ammo_nails = cvar("g_pickup_nails_max");
1089                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1090                 start_ammo_cells = cvar("g_pickup_cells_max");
1091                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1092                 start_items |= IT_UNLIMITED_AMMO;
1093                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1094                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1095                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1096                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1097                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1098                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1099         }
1100
1101         if (g_jetpack)
1102                 start_items |= IT_JETPACK;
1103
1104         if (g_weapon_stay == 2)
1105         {
1106                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1107                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1108                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1109                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1110                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1111                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1112                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1113                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1114                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1115                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1116         }
1117
1118         MUTATOR_CALLHOOK(SetStartItems);
1119
1120         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1121         {
1122                 e = get_weaponinfo(i);
1123                 if(e.weapons & (start_weapons | warmup_start_weapons))
1124                         weapon_action(e.weapon, WR_PRECACHE);
1125         }
1126
1127         start_ammo_shells = max(0, start_ammo_shells);
1128         start_ammo_nails = max(0, start_ammo_nails);
1129         start_ammo_cells = max(0, start_ammo_cells);
1130         start_ammo_rockets = max(0, start_ammo_rockets);
1131         start_ammo_fuel = max(0, start_ammo_fuel);
1132
1133         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1134         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1135         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1136         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1137         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1138 }
1139
1140 float g_bugrigs;
1141 float g_bugrigs_planar_movement;
1142 float g_bugrigs_planar_movement_car_jumping;
1143 float g_bugrigs_reverse_spinning;
1144 float g_bugrigs_reverse_speeding;
1145 float g_bugrigs_reverse_stopping;
1146 float g_bugrigs_air_steering;
1147 float g_bugrigs_angle_smoothing;
1148 float g_bugrigs_friction_floor;
1149 float g_bugrigs_friction_brake;
1150 float g_bugrigs_friction_air;
1151 float g_bugrigs_accel;
1152 float g_bugrigs_speed_ref;
1153 float g_bugrigs_speed_pow;
1154 float g_bugrigs_steer;
1155
1156 float g_touchexplode;
1157 float g_touchexplode_radius;
1158 float g_touchexplode_damage;
1159 float g_touchexplode_edgedamage;
1160 float g_touchexplode_force;
1161
1162 float sv_autotaunt;
1163 float sv_taunt;
1164
1165 float sv_pitch_min;
1166 float sv_pitch_max;
1167 float sv_pitch_fixyaw;
1168
1169 string GetGametype(); // g_world.qc
1170 void readlevelcvars(void)
1171 {
1172         // first load all the mutators
1173         if(cvar("g_nix"))
1174                 MUTATOR_ADD(mutator_nix);
1175         if(cvar("g_dodging"))
1176                 MUTATOR_ADD(mutator_dodging);
1177         if(cvar("g_rocket_flying"))
1178                 MUTATOR_ADD(mutator_rocketflying);
1179         if(cvar("g_vampire"))
1180                 MUTATOR_ADD(mutator_vampire);
1181
1182         if(cvar("sv_allow_fullbright"))
1183                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1184
1185     g_bugrigs = cvar("g_bugrigs");
1186     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1187     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1188     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1189     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1190     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1191     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1192     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1193     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1194     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1195     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1196     g_bugrigs_accel = cvar("g_bugrigs_accel");
1197     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1198     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1199     g_bugrigs_steer = cvar("g_bugrigs_steer");
1200
1201     g_touchexplode = cvar("g_touchexplode");
1202     g_touchexplode_radius = cvar("g_touchexplode_radius");
1203     g_touchexplode_damage = cvar("g_touchexplode_damage");
1204     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1205     g_touchexplode_force = cvar("g_touchexplode_force");
1206
1207 #ifdef ALLOW_FORCEMODELS
1208         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1209 #endif
1210         sv_loddistance1 = cvar("sv_loddistance1");
1211         sv_loddistance2 = cvar("sv_loddistance2");
1212
1213         if(sv_loddistance2 <= sv_loddistance1)
1214                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1215
1216         sv_clones = cvar("sv_clones");
1217         sv_gentle = cvar("sv_gentle");
1218         sv_foginterval = cvar("sv_foginterval");
1219         g_cloaked = cvar("g_cloaked");
1220     if(g_cts)
1221         g_cloaked = 1; // always enable cloak in CTS
1222         g_jump_grunt = cvar("g_jump_grunt");
1223         g_footsteps = cvar("g_footsteps");
1224         g_grappling_hook = cvar("g_grappling_hook");
1225         g_jetpack = cvar("g_jetpack");
1226         g_midair = cvar("g_midair");
1227         g_minstagib = cvar("g_minstagib");
1228         g_norecoil = cvar("g_norecoil");
1229         g_bloodloss = cvar("g_bloodloss");
1230         sv_maxidle = cvar("sv_maxidle");
1231         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1232         sv_pogostick = cvar("sv_pogostick");
1233         g_ctf_reverse = cvar("g_ctf_reverse");
1234         sv_autotaunt = cvar("sv_autotaunt");
1235         sv_taunt = cvar("sv_taunt");
1236
1237         inWarmupStage = cvar("g_warmup");
1238         g_warmup_limit = cvar("g_warmup_limit");
1239         g_warmup_allguns = cvar("g_warmup_allguns");
1240         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1241
1242         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1243                 inWarmupStage = 0; // these modes cannot work together, sorry
1244
1245         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1246         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1247         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1248         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1249         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1250         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1251         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1252         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1253         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1254         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1255         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1256         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1257
1258         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1259         g_weaponratefactor = cvar("g_weaponratefactor");
1260         g_weapondamagefactor = cvar("g_weapondamagefactor");
1261         g_weaponforcefactor = cvar("g_weaponforcefactor");
1262         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1263
1264         g_pickup_shells = cvar("g_pickup_shells");
1265         g_pickup_shells_max = cvar("g_pickup_shells_max");
1266         g_pickup_nails = cvar("g_pickup_nails");
1267         g_pickup_nails_max = cvar("g_pickup_nails_max");
1268         g_pickup_rockets = cvar("g_pickup_rockets");
1269         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1270         g_pickup_cells = cvar("g_pickup_cells");
1271         g_pickup_cells_max = cvar("g_pickup_cells_max");
1272         g_pickup_fuel = cvar("g_pickup_fuel");
1273         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1274         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1275         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1276         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1277         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1278         g_pickup_armormedium = cvar("g_pickup_armormedium");
1279         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1280         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1281         g_pickup_armorbig = cvar("g_pickup_armorbig");
1282         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1283         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1284         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1285         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1286         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1287         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1288         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1289         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1290         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1291         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1292         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1293         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1294         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1295         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1296         g_pickup_healthmega = cvar("g_pickup_healthmega");
1297         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1298         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1299
1300         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1301         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1302
1303         g_pinata = cvar("g_pinata");
1304
1305     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1306     if(!g_weapon_stay)
1307         g_weapon_stay = cvar("g_weapon_stay");
1308
1309         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1310                 g_weapon_stay = 1;
1311
1312         g_ghost_items = cvar("g_ghost_items");
1313
1314         if(g_ghost_items >= 1)
1315                 g_ghost_items = 0.25; // default alpha value
1316
1317         if not(inWarmupStage && !g_ca)
1318                 game_starttime = cvar("g_start_delay");
1319
1320         sv_pitch_min = cvar("sv_pitch_min");
1321         sv_pitch_max = cvar("sv_pitch_max");
1322         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1323
1324         readplayerstartcvars();
1325 }
1326
1327 //#NO AUTOCVARS END
1328
1329 // Sound functions
1330 string precache_sound (string s) = #19;
1331 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1332 float precache_sound_index (string s) = #19;
1333
1334 #define SND_VOLUME      1
1335 #define SND_ATTENUATION 2
1336 #define SND_LARGEENTITY 8
1337 #define SND_LARGESOUND  16
1338
1339 float sound_allowed(float dest, entity e)
1340 {
1341     // sounds from world may always pass
1342     for (;;)
1343     {
1344         if (e.classname == "body")
1345             e = e.enemy;
1346         if (e.owner && e.owner != e)
1347             e = e.owner;
1348         else
1349             break;
1350     }
1351     // sounds to self may always pass
1352     if (dest == MSG_ONE)
1353         if (e == msg_entity)
1354             return TRUE;
1355     // sounds by players can be removed
1356     if (autocvar_bot_sound_monopoly)
1357         if (clienttype(e) == CLIENTTYPE_REAL)
1358             return FALSE;
1359     // anything else may pass
1360     return TRUE;
1361 }
1362
1363 void sound(entity e, float chan, string samp, float vol, float atten)
1364 {
1365     if (!sound_allowed(MSG_BROADCAST, e))
1366         return;
1367     sound_builtin(e, chan, samp, vol, atten);
1368 }
1369 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1370 {
1371     float entno, idx;
1372
1373     if (!sound_allowed(dest, e))
1374         return;
1375
1376     entno = num_for_edict(e);
1377     idx = precache_sound_index(samp);
1378
1379     float sflags;
1380     sflags = 0;
1381
1382     atten = floor(atten * 64);
1383     vol = floor(vol * 255);
1384
1385     if (vol != 255)
1386         sflags |= SND_VOLUME;
1387     if (atten != 64)
1388         sflags |= SND_ATTENUATION;
1389     if (entno >= 8192)
1390         sflags |= SND_LARGEENTITY;
1391     if (idx >= 256)
1392         sflags |= SND_LARGESOUND;
1393
1394     WriteByte(dest, SVC_SOUND);
1395     WriteByte(dest, sflags);
1396     if (sflags & SND_VOLUME)
1397         WriteByte(dest, vol);
1398     if (sflags & SND_ATTENUATION)
1399         WriteByte(dest, atten);
1400     if (sflags & SND_LARGEENTITY)
1401     {
1402         WriteShort(dest, entno);
1403         WriteByte(dest, chan);
1404     }
1405     else
1406     {
1407         WriteShort(dest, entno * 8 + chan);
1408     }
1409     if (sflags & SND_LARGESOUND)
1410         WriteShort(dest, idx);
1411     else
1412         WriteByte(dest, idx);
1413
1414     WriteCoord(dest, o_x);
1415     WriteCoord(dest, o_y);
1416     WriteCoord(dest, o_z);
1417 }
1418 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1419 {
1420     vector o;
1421
1422     if (!sound_allowed(dest, e))
1423         return;
1424
1425     o = e.origin + 0.5 * (e.mins + e.maxs);
1426     soundtoat(dest, e, o, chan, samp, vol, atten);
1427 }
1428 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1429 {
1430     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1431 }
1432 void stopsoundto(float dest, entity e, float chan)
1433 {
1434     float entno;
1435
1436     if (!sound_allowed(dest, e))
1437         return;
1438
1439     entno = num_for_edict(e);
1440
1441     if (entno >= 8192)
1442     {
1443         float idx, sflags;
1444         idx = precache_sound_index("misc/null.wav");
1445         sflags = SND_LARGEENTITY;
1446         if (idx >= 256)
1447             sflags |= SND_LARGESOUND;
1448         WriteByte(dest, SVC_SOUND);
1449         WriteByte(dest, sflags);
1450         WriteShort(dest, entno);
1451         WriteByte(dest, chan);
1452         if (sflags & SND_LARGESOUND)
1453             WriteShort(dest, idx);
1454         else
1455             WriteByte(dest, idx);
1456         WriteCoord(dest, e.origin_x);
1457         WriteCoord(dest, e.origin_y);
1458         WriteCoord(dest, e.origin_z);
1459     }
1460     else
1461     {
1462         WriteByte(dest, SVC_STOPSOUND);
1463         WriteShort(dest, entno * 8 + chan);
1464     }
1465 }
1466 void stopsound(entity e, float chan)
1467 {
1468     if (!sound_allowed(MSG_BROADCAST, e))
1469         return;
1470
1471     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1472     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1473 }
1474
1475 void play2(entity e, string filename)
1476 {
1477     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1478     msg_entity = e;
1479     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1480 }
1481
1482 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1483 .float spamtime;
1484 float spamsound(entity e, float chan, string samp, float vol, float atten)
1485 {
1486     if (!sound_allowed(MSG_BROADCAST, e))
1487         return FALSE;
1488
1489     if (time > e.spamtime)
1490     {
1491         e.spamtime = time;
1492         sound(e, chan, samp, vol, atten);
1493         return TRUE;
1494     }
1495     return FALSE;
1496 }
1497
1498 void play2team(float t, string filename)
1499 {
1500     local entity head;
1501
1502     if (autocvar_bot_sound_monopoly)
1503         return;
1504
1505     FOR_EACH_REALPLAYER(head)
1506     {
1507         if (head.team == t)
1508             play2(head, filename);
1509     }
1510 }
1511
1512 void play2all(string samp)
1513 {
1514     if (autocvar_bot_sound_monopoly)
1515         return;
1516
1517     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1518 }
1519
1520 void PrecachePlayerSounds(string f);
1521 void precache_playermodel(string m)
1522 {
1523         float globhandle, i, n;
1524         string f;
1525
1526         if(substring(m, -9,5) == "_lod1")
1527                 return;
1528         if(substring(m, -9,5) == "_lod2")
1529                 return;
1530         precache_model(m);
1531         if(sv_loddistance1)
1532         {
1533                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1534                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1535         }
1536
1537         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1538         if (globhandle < 0)
1539                 return;
1540         n = search_getsize(globhandle);
1541         for (i = 0; i < n; ++i)
1542         {
1543                 //print(search_getfilename(globhandle, i), "\n");
1544                 f = search_getfilename(globhandle, i);
1545                 PrecachePlayerSounds(f);
1546         }
1547         search_end(globhandle);
1548 }
1549 void precache_all_playermodels(string pattern)
1550 {
1551         float globhandle, i, n;
1552         string f;
1553
1554         globhandle = search_begin(pattern, TRUE, FALSE);
1555         if (globhandle < 0)
1556                 return;
1557         n = search_getsize(globhandle);
1558         for (i = 0; i < n; ++i)
1559         {
1560                 //print(search_getfilename(globhandle, i), "\n");
1561                 f = search_getfilename(globhandle, i);
1562                 precache_playermodel(f);
1563         }
1564         search_end(globhandle);
1565 }
1566
1567 void precache()
1568 {
1569     // gamemode related things
1570     precache_model ("models/misc/chatbubble.spr");
1571     precache_model ("models/misc/teambubble.spr");
1572     if (g_runematch)
1573     {
1574         precache_model ("models/runematch/curse.mdl");
1575         precache_model ("models/runematch/rune.mdl");
1576     }
1577
1578 #ifdef TTURRETS_ENABLED
1579     if (autocvar_g_turrets)
1580         turrets_precash();
1581 #endif
1582
1583     // Precache all player models if desired
1584     if (autocvar_sv_precacheplayermodels)
1585     {
1586         PrecachePlayerSounds("sound/player/default.sounds");
1587         precache_all_playermodels("models/player/*.zym");
1588         precache_all_playermodels("models/player/*.dpm");
1589         precache_all_playermodels("models/player/*.md3");
1590         precache_all_playermodels("models/player/*.psk");
1591         precache_all_playermodels("models/player/*.iqm");
1592     }
1593
1594     if (autocvar_sv_defaultcharacter)
1595     {
1596         string s;
1597         s = autocvar_sv_defaultplayermodel_red;
1598         if (s != "")
1599             precache_playermodel(s);
1600         s = autocvar_sv_defaultplayermodel_blue;
1601         if (s != "")
1602             precache_playermodel(s);
1603         s = autocvar_sv_defaultplayermodel_yellow;
1604         if (s != "")
1605             precache_playermodel(s);
1606         s = autocvar_sv_defaultplayermodel_pink;
1607         if (s != "")
1608             precache_playermodel(s);
1609         s = autocvar_sv_defaultplayermodel;
1610         if (s != "")
1611             precache_playermodel(s);
1612     }
1613
1614     if (g_footsteps)
1615     {
1616         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1617         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1618     }
1619
1620     // gore and miscellaneous sounds
1621     //precache_sound ("misc/h2ohit.wav");
1622     precache_model ("models/hook.md3");
1623     precache_sound ("misc/armorimpact.wav");
1624     precache_sound ("misc/bodyimpact1.wav");
1625     precache_sound ("misc/bodyimpact2.wav");
1626     precache_sound ("misc/gib.wav");
1627     precache_sound ("misc/gib_splat01.wav");
1628     precache_sound ("misc/gib_splat02.wav");
1629     precache_sound ("misc/gib_splat03.wav");
1630     precache_sound ("misc/gib_splat04.wav");
1631     precache_sound ("misc/hit.wav");
1632         precache_sound ("misc/typehit.wav");
1633     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1634     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1635     precache_sound ("misc/null.wav");
1636     precache_sound ("misc/spawn.wav");
1637     precache_sound ("misc/talk.wav");
1638     precache_sound ("misc/teleport.wav");
1639     precache_sound ("misc/poweroff.wav");
1640     precache_sound ("player/lava.wav");
1641     precache_sound ("player/slime.wav");
1642
1643     if (g_jetpack)
1644         precache_sound ("misc/jetpack_fly.wav");
1645
1646     precache_model ("models/sprites/0.spr32");
1647     precache_model ("models/sprites/1.spr32");
1648     precache_model ("models/sprites/2.spr32");
1649     precache_model ("models/sprites/3.spr32");
1650     precache_model ("models/sprites/4.spr32");
1651     precache_model ("models/sprites/5.spr32");
1652     precache_model ("models/sprites/6.spr32");
1653     precache_model ("models/sprites/7.spr32");
1654     precache_model ("models/sprites/8.spr32");
1655     precache_model ("models/sprites/9.spr32");
1656     precache_model ("models/sprites/10.spr32");
1657
1658     // common weapon precaches
1659     precache_sound ("weapons/weapon_switch.wav");
1660     precache_sound ("weapons/weaponpickup.wav");
1661     precache_sound ("weapons/unavailable.wav");
1662     precache_sound ("weapons/dryfire.wav");
1663     if (g_grappling_hook)
1664     {
1665         precache_sound ("weapons/hook_fire.wav"); // hook
1666         precache_sound ("weapons/hook_impact.wav"); // hook
1667     }
1668
1669     if(autocvar_sv_precacheweapons)
1670     {
1671         //precache weapon models/sounds
1672         local float wep;
1673         wep = WEP_FIRST;
1674         while (wep <= WEP_LAST)
1675         {
1676             weapon_action(wep, WR_PRECACHE);
1677             wep = wep + 1;
1678         }
1679     }
1680
1681     precache_model("models/elaser.mdl");
1682     precache_model("models/laser.mdl");
1683     precache_model("models/ebomb.mdl");
1684
1685 #if 0
1686     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1687
1688     if (!self.noise && self.music) // quake 3 uses the music field
1689         self.noise = self.music;
1690
1691     // plays music for the level if there is any
1692     if (self.noise)
1693     {
1694         precache_sound (self.noise);
1695         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1696     }
1697 #endif
1698 }
1699
1700 // sorry, but using \ in macros breaks line numbers
1701 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1702 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1703 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1704
1705 // WARNING: this kills the trace globals
1706 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1707 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1708
1709 #define INITPRIO_FIRST              0
1710 #define INITPRIO_GAMETYPE           0
1711 #define INITPRIO_GAMETYPE_FALLBACK  1
1712 #define INITPRIO_FINDTARGET        10
1713 #define INITPRIO_DROPTOFLOOR       20
1714 #define INITPRIO_SETLOCATION       90
1715 #define INITPRIO_LINKDOORS         91
1716 #define INITPRIO_LAST              99
1717
1718 .void(void) initialize_entity;
1719 .float initialize_entity_order;
1720 .entity initialize_entity_next;
1721 entity initialize_entity_first;
1722
1723 void make_safe_for_remove(entity e)
1724 {
1725     if (e.initialize_entity)
1726     {
1727         entity ent, prev;
1728         for (ent = initialize_entity_first; ent; )
1729         {
1730             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1731             {
1732                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1733                 // skip it in linked list
1734                 if (prev)
1735                 {
1736                     prev.initialize_entity_next = ent.initialize_entity_next;
1737                     ent = prev.initialize_entity_next;
1738                 }
1739                 else
1740                 {
1741                     initialize_entity_first = ent.initialize_entity_next;
1742                     ent = initialize_entity_first;
1743                 }
1744             }
1745             else
1746             {
1747                 prev = ent;
1748                 ent = ent.initialize_entity_next;
1749             }
1750         }
1751     }
1752 }
1753
1754 void objerror(string s)
1755 {
1756     make_safe_for_remove(self);
1757     objerror_builtin(s);
1758 }
1759
1760 .float remove_except_protected_forbidden;
1761 void remove_except_protected(entity e)
1762 {
1763         if(e.remove_except_protected_forbidden)
1764                 error("not allowed to remove this at this point");
1765         remove_builtin(e);
1766 }
1767
1768 void remove_unsafely(entity e)
1769 {
1770     remove_builtin(e);
1771 }
1772
1773 void remove_safely(entity e)
1774 {
1775     make_safe_for_remove(e);
1776     remove_builtin(e);
1777 }
1778
1779 void InitializeEntity(entity e, void(void) func, float order)
1780 {
1781     entity prev, cur;
1782
1783     if (!e || e.initialize_entity)
1784     {
1785         // make a proxy initializer entity
1786         entity e_old;
1787         e_old = e;
1788         e = spawn();
1789         e.classname = "initialize_entity";
1790         e.enemy = e_old;
1791     }
1792
1793     e.initialize_entity = func;
1794     e.initialize_entity_order = order;
1795
1796     cur = initialize_entity_first;
1797     for (;;)
1798     {
1799         if (!cur || cur.initialize_entity_order > order)
1800         {
1801             // insert between prev and cur
1802             if (prev)
1803                 prev.initialize_entity_next = e;
1804             else
1805                 initialize_entity_first = e;
1806             e.initialize_entity_next = cur;
1807             return;
1808         }
1809         prev = cur;
1810         cur = cur.initialize_entity_next;
1811     }
1812 }
1813 void InitializeEntitiesRun()
1814 {
1815     entity startoflist;
1816     startoflist = initialize_entity_first;
1817     initialize_entity_first = world;
1818     remove = remove_except_protected;
1819     for (self = startoflist; self; self = self.initialize_entity_next)
1820     {
1821         self.remove_except_protected_forbidden = 1;
1822     }
1823     for (self = startoflist; self; )
1824     {
1825         entity e;
1826         var void(void) func;
1827         e = self.initialize_entity_next;
1828         func = self.initialize_entity;
1829         self.initialize_entity_order = 0;
1830         self.initialize_entity = func_null;
1831         self.initialize_entity_next = world;
1832         self.remove_except_protected_forbidden = 0;
1833         if (self.classname == "initialize_entity")
1834         {
1835             entity e_old;
1836             e_old = self.enemy;
1837             remove_builtin(self);
1838             self = e_old;
1839         }
1840         //dprint("Delayed initialization: ", self.classname, "\n");
1841         if(func != func_null)
1842             func();
1843         else
1844         {
1845             eprint(self);
1846             backtrace(strcat("Null function in: ", self.classname, "\n"));
1847         }
1848         self = e;
1849     }
1850     remove = remove_unsafely;
1851 }
1852
1853 .float uncustomizeentityforclient_set;
1854 .void(void) uncustomizeentityforclient;
1855 void(void) SUB_Nullpointer = #0;
1856 void UncustomizeEntitiesRun()
1857 {
1858     entity oldself;
1859     oldself = self;
1860     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1861         self.uncustomizeentityforclient();
1862     self = oldself;
1863 }
1864 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1865 {
1866     e.customizeentityforclient = customizer;
1867     e.uncustomizeentityforclient = uncustomizer;
1868     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1869 }
1870
1871 .float nottargeted;
1872 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1873
1874 void() SUB_Remove;
1875 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1876 {
1877     vector mi, ma;
1878
1879     if (e.classname == "")
1880         e.classname = "net_linked";
1881
1882     if (e.model == "" || self.modelindex == 0)
1883     {
1884         mi = e.mins;
1885         ma = e.maxs;
1886         setmodel(e, "null");
1887         setsize(e, mi, ma);
1888     }
1889
1890     e.SendEntity = sendfunc;
1891     e.SendFlags = 0xFFFFFF;
1892
1893     if (!docull)
1894         e.effects |= EF_NODEPTHTEST;
1895
1896     if (dt)
1897     {
1898         e.nextthink = time + dt;
1899         e.think = SUB_Remove;
1900     }
1901 }
1902
1903 void adaptor_think2touch()
1904 {
1905     entity o;
1906     o = other;
1907     other = world;
1908     self.touch();
1909     other = o;
1910 }
1911
1912 void adaptor_think2use()
1913 {
1914     entity o, a;
1915     o = other;
1916     a = activator;
1917     activator = world;
1918     other = world;
1919     self.use();
1920     other = o;
1921     activator = a;
1922 }
1923
1924 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1925 {
1926         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1927                 self.projectiledeathtype |= HITTYPE_SPLASH;
1928         adaptor_think2use();
1929 }
1930
1931 // deferred dropping
1932 void DropToFloor_Handler()
1933 {
1934     droptofloor_builtin();
1935     self.dropped_origin = self.origin;
1936 }
1937
1938 void droptofloor()
1939 {
1940     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1941 }
1942
1943
1944
1945 float trace_hits_box_a0, trace_hits_box_a1;
1946
1947 float trace_hits_box_1d(float end, float thmi, float thma)
1948 {
1949     if (end == 0)
1950     {
1951         // just check if x is in range
1952         if (0 < thmi)
1953             return FALSE;
1954         if (0 > thma)
1955             return FALSE;
1956     }
1957     else
1958     {
1959         // do the trace with respect to x
1960         // 0 -> end has to stay in thmi -> thma
1961         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1962         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1963         if (trace_hits_box_a0 > trace_hits_box_a1)
1964             return FALSE;
1965     }
1966     return TRUE;
1967 }
1968
1969 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1970 {
1971     end -= start;
1972     thmi -= start;
1973     thma -= start;
1974     // now it is a trace from 0 to end
1975
1976     trace_hits_box_a0 = 0;
1977     trace_hits_box_a1 = 1;
1978
1979     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1980         return FALSE;
1981     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1982         return FALSE;
1983     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1984         return FALSE;
1985
1986     return TRUE;
1987 }
1988
1989 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1990 {
1991     return trace_hits_box(start, end, thmi - ma, thma - mi);
1992 }
1993
1994 float SUB_NoImpactCheck()
1995 {
1996         // zero hitcontents = this is not the real impact, but either the
1997         // mirror-impact of something hitting the projectile instead of the
1998         // projectile hitting the something, or a touchareagrid one. Neither of
1999         // these stop the projectile from moving, so...
2000         if(trace_dphitcontents == 0)
2001         {
2002                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2003                 checkclient();
2004         }
2005     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2006         return 1;
2007     if (other == world && self.size != '0 0 0')
2008     {
2009         vector tic;
2010         tic = self.velocity * sys_frametime;
2011         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2012         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2013         if (trace_fraction >= 1)
2014         {
2015             dprint("Odd... did not hit...?\n");
2016         }
2017         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2018         {
2019             dprint("Detected and prevented the sky-grapple bug.\n");
2020             return 1;
2021         }
2022     }
2023
2024     return 0;
2025 }
2026
2027 #define SUB_OwnerCheck() (other && (other == self.owner))
2028
2029 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2030 {
2031         if(SUB_OwnerCheck())
2032                 return TRUE;
2033         if(SUB_NoImpactCheck())
2034         {
2035                 remove(self);
2036                 return TRUE;
2037         }
2038         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2039                 UpdateCSQCProjectileNextFrame(self);
2040         return FALSE;
2041 }
2042 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2043
2044 float MAX_IPBAN_URIS           = 16;
2045                               
2046 float URI_GET_DISCARD          = 0;
2047 float URI_GET_IPBAN            = 1;
2048 float URI_GET_IPBAN_END        = 16;
2049 float URI_GET_PLAYERSTATS_SENT = 17;
2050
2051 void URI_Get_Callback(float id, float status, string data)
2052 {
2053     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2054     dprint(data);
2055     dprint("\nEnd of data.\n");
2056
2057     if (id == URI_GET_DISCARD)
2058     {
2059         // discard
2060     }
2061     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2062     {
2063         // online ban list
2064         OnlineBanList_URI_Get_Callback(id, status, data);
2065     }
2066     else if (id == URI_GET_PLAYERSTATS_SENT)
2067     {
2068         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2069     }
2070     else
2071     {
2072         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2073     }
2074 }
2075
2076 void print_to(entity e, string s)
2077 {
2078     if (e)
2079         sprint(e, strcat(s, "\n"));
2080     else
2081         print(s, "\n");
2082 }
2083
2084 string uid2name(string myuid) {
2085         string s;
2086         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2087         
2088         if(s == "")
2089                 s = "^1Unregistered Player";
2090         return s;
2091 }
2092
2093 float race_readTime(string map, float pos)
2094 {
2095         string rr;
2096         if(g_cts)
2097                 rr = CTS_RECORD;
2098         else
2099                 rr = RACE_RECORD;
2100
2101         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2102 }
2103
2104 string race_readUID(string map, float pos)
2105 {
2106         string rr;
2107         if(g_cts)
2108                 rr = CTS_RECORD;
2109         else
2110                 rr = RACE_RECORD;
2111
2112         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2113 }
2114
2115 float race_readPos(string map, float t) {
2116         float i;
2117         for (i = 1; i <= RANKINGS_CNT; ++i)
2118                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2119                         return i;
2120
2121         return 0; // pos is zero if unranked
2122 }
2123
2124 void race_writeTime(string map, float t, string myuid)
2125 {
2126         string rr;
2127         if(g_cts)
2128                 rr = CTS_RECORD;
2129         else
2130                 rr = RACE_RECORD;
2131
2132         float newpos;
2133         newpos = race_readPos(map, t);
2134
2135         float i, prevpos;
2136         for(i = 1; i <= RANKINGS_CNT; ++i)
2137         {
2138                 if(race_readUID(map, i) == myuid)
2139                         prevpos = i;
2140         }
2141         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2142                 for (i = prevpos; i > newpos; --i) {
2143                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2144                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2145                 }
2146         } else { // player has no ranked record yet
2147                 for (i = RANKINGS_CNT; i > newpos; --i) {
2148                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2149                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2150                 }
2151         }
2152
2153         // store new time itself
2154         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2155         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2156 }
2157
2158 string race_readName(string map, float pos)
2159 {
2160         string rr;
2161         if(g_cts)
2162                 rr = CTS_RECORD;
2163         else
2164                 rr = RACE_RECORD;
2165
2166         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2167 }
2168
2169 string race_placeName(float pos) {
2170         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2171         {
2172                 if(mod(pos, 10) == 1)
2173                         return strcat(ftos(pos), "st");
2174                 else if(mod(pos, 10) == 2)
2175                         return strcat(ftos(pos), "nd");
2176                 else if(mod(pos, 10) == 3)
2177                         return strcat(ftos(pos), "rd");
2178                 else
2179                         return strcat(ftos(pos), "th");
2180         }
2181         else
2182                 return strcat(ftos(pos), "th");
2183 }
2184 string getrecords(float page) // 50 records per page
2185 {
2186     float rec;
2187     string h;
2188     float r;
2189     float i;
2190     string s;
2191
2192     rec = 0;
2193
2194     s = "";
2195
2196     if (g_ctf)
2197     {
2198         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2199         {
2200             if (MapInfo_Get_ByID(i))
2201             {
2202                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2203                 if (r == 0)
2204                     continue;
2205                 // TODO: uid2name
2206                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2207                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2208                 ++rec;
2209             }
2210         }
2211     }
2212
2213     if (g_race)
2214     {
2215         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2216         {
2217             if (MapInfo_Get_ByID(i))
2218             {
2219                 r = race_readTime(MapInfo_Map_bspname, 1);
2220                 if (r == 0)
2221                     continue;
2222                 h = race_readName(MapInfo_Map_bspname, 1);
2223                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2224                 ++rec;
2225             }
2226         }
2227     }
2228
2229     if (g_cts)
2230     {
2231         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2232         {
2233             if (MapInfo_Get_ByID(i))
2234             {
2235                 r = race_readTime(MapInfo_Map_bspname, 1);
2236                 if (r == 0)
2237                     continue;
2238                 h = race_readName(MapInfo_Map_bspname, 1);
2239                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2240                 ++rec;
2241             }
2242         }
2243     }
2244
2245     MapInfo_ClearTemps();
2246
2247     if (s == "" && page == 0)
2248         return "No records are available on this server.\n";
2249     else
2250         return s;
2251 }
2252
2253 string getrankings()
2254 {
2255     string n;
2256     float t;
2257     float i;
2258     string s;
2259     string p;
2260     string map;
2261
2262     s = "";
2263
2264     map = GetMapname();
2265
2266     for (i = 1; i <= RANKINGS_CNT; ++i)
2267     {
2268         t = race_readTime(map, i);
2269         if (t == 0)
2270             continue;
2271         n = race_readName(map, i);
2272         p = race_placeName(i);
2273         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2274     }
2275
2276     MapInfo_ClearTemps();
2277
2278     if (s == "")
2279         return strcat("No records are available for the map: ", map, "\n");
2280     else
2281         return strcat("Records for ", map, ":\n", s);
2282 }
2283
2284 #define LADDER_FIRSTPOINT 100
2285 #define LADDER_CNT 10
2286         // position X still gives LADDER_FIRSTPOINT/X points
2287 #define LADDER_SIZE 30
2288         // ladder shows the top X players
2289 string top_uids[LADDER_SIZE];
2290 float top_scores[LADDER_SIZE];
2291 string getladder()
2292 {
2293     float i, j, k, uidcnt;
2294     string s, temp_s;
2295
2296     s = "";
2297     temp_s = "";
2298
2299     string rr;
2300     if(g_cts)
2301         rr = CTS_RECORD;
2302     else
2303         rr = RACE_RECORD;
2304
2305     string myuid;
2306
2307     for (k = 0; k < MapInfo_count; ++k)
2308     {
2309         if (MapInfo_Get_ByID(k))
2310         {
2311                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2312                         if(i == 0) // speed award
2313                         {
2314                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2315                                         continue;
2316
2317                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2318                         }
2319                         else // normal record, if it exists (else break)
2320                         {
2321                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2322                                         continue;
2323
2324                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2325                         }
2326
2327                         // string s contains:
2328                         // arg 0 = # of speed recs
2329                         // arg 1 = # of 1st place recs
2330                         // arg 2 = # of 2nd place recs
2331                         // ... etc
2332                         // LADDER_CNT+1 = total points
2333
2334                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2335                         if (temp_s == "")
2336                         {
2337                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2338                             ++uidcnt;
2339                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2340                             {
2341                                 if(j != LADDER_CNT + 1)
2342                                     temp_s = strcat(temp_s, "0 ");
2343                                 else
2344                                     temp_s = strcat(temp_s, "0");
2345                             }
2346                         }
2347
2348                         tokenize_console(temp_s);
2349                         s = "";
2350
2351                         if(i == 0) // speed award
2352                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2353                             {
2354                                 if(j == 0) // speed award
2355                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2356                                 else
2357                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2358                             }
2359                         else // record
2360                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2361                             {
2362                                 if(j == 0)
2363                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2364                                 else if(j == i) // wanted rec!
2365                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2366                                 else
2367                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2368                             }
2369
2370                         // total points are (by default) calculated like this:
2371                         // speedrec = floor(100 / 10) = 10 points
2372                         // 1st place = floor(100 / 1) = 100 points
2373                         // 2nd place = floor(100 / 2) = 50 points
2374                         // 3rd place = floor(100 / 3) = 33 points
2375                         // 4th place = floor(100 / 4) = 25 points
2376                         // 5th place = floor(100 / 5) = 20 points
2377                         // ... etc
2378
2379                         if(i == 0)
2380                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2381                         else
2382                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2383
2384                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2385                 }
2386         }
2387     }
2388
2389     float thiscnt;
2390     string thisuid;
2391     for (i = 0; i <= uidcnt; ++i) // for each known uid
2392     {
2393         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2394         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2395         tokenize_console(temp_s);
2396         thiscnt = stof(argv(LADDER_CNT+1));
2397
2398         if(thiscnt > top_scores[LADDER_SIZE-1])
2399         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2400         {
2401             if(thiscnt > top_scores[j])
2402             {
2403                 for (k = LADDER_SIZE-1; k >= j; --k)
2404                 {
2405                     top_uids[k] = top_uids[k-1];
2406                     top_scores[k] = top_scores[k-1];
2407                 }
2408                 top_uids[j] = thisuid;
2409                 top_scores[j] = thiscnt;
2410                 break;
2411             }
2412         }
2413     }
2414
2415     s = "^3-----------------------\n\n";
2416
2417     s = strcat(s, "Pos ^3|");
2418     s = strcat(s, " ^7Total  ^3|");
2419     for (i = 1; i <= LADDER_CNT; ++i)
2420     {
2421         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2422     }
2423     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2424
2425     s = strcat(s, "\n^3----+--------");
2426     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2427     {
2428         s = strcat(s, "+-----");
2429     }
2430 #if LADDER_CNT > 9
2431     for (i = 1; i <= LADDER_CNT - 9; ++i)
2432     {
2433         s = strcat(s, "+------");
2434     }
2435 #endif
2436
2437     s = strcat(s, "+--------------+--------------------\n");
2438
2439     for (i = 0; i < LADDER_SIZE; ++i)
2440     {
2441         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2442         tokenize_console(temp_s);
2443         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2444             continue;
2445         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2446         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2447         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2448         {
2449             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2450         }
2451 #if LADDER_CNT > 9
2452         for (j = 10; j <= LADDER_CNT; ++j)
2453         {
2454             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2455         }
2456 #endif
2457
2458         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2459         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2460     }
2461
2462     MapInfo_ClearTemps();
2463
2464     if (s == "")
2465         return "No ladder on this server!\n";
2466     else
2467         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2468 }
2469
2470
2471 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2472 {
2473     float m, i;
2474     vector start, org, delta, end, enddown, mstart;
2475
2476     m = e.dphitcontentsmask;
2477     e.dphitcontentsmask = goodcontents | badcontents;
2478
2479     org = world.mins;
2480     delta = world.maxs - world.mins;
2481
2482     for (i = 0; i < attempts; ++i)
2483     {
2484         start_x = org_x + random() * delta_x;
2485         start_y = org_y + random() * delta_y;
2486         start_z = org_z + random() * delta_z;
2487
2488         // rule 1: start inside world bounds, and outside
2489         // solid, and don't start from somewhere where you can
2490         // fall down to evil
2491         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2492         if (trace_fraction >= 1)
2493             continue;
2494         if (trace_startsolid)
2495             continue;
2496         if (trace_dphitcontents & badcontents)
2497             continue;
2498         if (trace_dphitq3surfaceflags & badsurfaceflags)
2499             continue;
2500
2501         // rule 2: if we are too high, lower the point
2502         if (trace_fraction * delta_z > maxaboveground)
2503             start = trace_endpos + '0 0 1' * maxaboveground;
2504         enddown = trace_endpos;
2505
2506         // rule 3: make sure we aren't outside the map. This only works
2507         // for somewhat well formed maps. A good rule of thumb is that
2508         // the map should have a convex outside hull.
2509         // these can be traceLINES as we already verified the starting box
2510         mstart = start + 0.5 * (e.mins + e.maxs);
2511         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2512         if (trace_fraction >= 1)
2513             continue;
2514         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2524         if (trace_fraction >= 1)
2525             continue;
2526
2527         // find a random vector to "look at"
2528         end_x = org_x + random() * delta_x;
2529         end_y = org_y + random() * delta_y;
2530         end_z = org_z + random() * delta_z;
2531         end = start + normalize(end - start) * vlen(delta);
2532
2533         // rule 4: start TO end must not be too short
2534         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2535         if (trace_startsolid)
2536             continue;
2537         if (trace_fraction < minviewdistance / vlen(delta))
2538             continue;
2539
2540         // rule 5: don't want to look at sky
2541         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2542             continue;
2543
2544         // rule 6: we must not end up in trigger_hurt
2545         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2546         {
2547             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2548             continue;
2549         }
2550
2551         break;
2552     }
2553
2554     e.dphitcontentsmask = m;
2555
2556     if (i < attempts)
2557     {
2558         setorigin(e, start);
2559         e.angles = vectoangles(end - start);
2560         dprint("Needed ", ftos(i + 1), " attempts\n");
2561         return TRUE;
2562     }
2563     else
2564         return FALSE;
2565 }
2566
2567 float zcurveparticles_effectno;
2568 vector zcurveparticles_start;
2569 float zcurveparticles_spd;
2570
2571 void endzcurveparticles()
2572 {
2573         if(zcurveparticles_effectno)
2574         {
2575                 // terminator
2576                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2577         }
2578         zcurveparticles_effectno = 0;
2579 }
2580
2581 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2582 {
2583         spd = bound(0, floor(spd / 16), 32767);
2584         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2585         {
2586                 endzcurveparticles();
2587                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2588                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2589                 WriteShort(MSG_BROADCAST, effectno);
2590                 WriteCoord(MSG_BROADCAST, start_x);
2591                 WriteCoord(MSG_BROADCAST, start_y);
2592                 WriteCoord(MSG_BROADCAST, start_z);
2593                 zcurveparticles_effectno = effectno;
2594                 zcurveparticles_start = start;
2595         }
2596         else
2597                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2598         WriteCoord(MSG_BROADCAST, end_x);
2599         WriteCoord(MSG_BROADCAST, end_y);
2600         WriteCoord(MSG_BROADCAST, end_z);
2601         WriteCoord(MSG_BROADCAST, end_dz);
2602         zcurveparticles_spd = spd;
2603 }
2604
2605 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2606 {
2607         float end_dz;
2608         vector vecxy, velxy;
2609
2610         vecxy = end - start;
2611         vecxy_z = 0;
2612         velxy = vel;
2613         velxy_z = 0;
2614
2615         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2616         {
2617                 endzcurveparticles();
2618                 trailparticles(world, effectno, start, end);
2619                 return;
2620         }
2621
2622         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2623         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2624 }
2625
2626 void write_recordmarker(entity pl, float tstart, float dt)
2627 {
2628     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2629
2630     // also write a marker into demo files for demotc-race-record-extractor to find
2631     stuffcmd(pl,
2632              strcat(
2633                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2634                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2635 }
2636
2637 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2638 {
2639         switch(algn)
2640         {
2641                 case 1: // right
2642                         break;
2643
2644                 case 2: // left
2645                         vecs_y = -vecs_y;
2646                         break;
2647
2648                 default:
2649                 case 3:
2650                         if(allowcenter) // 2: allow center handedness
2651                         {
2652                                 // center
2653                                 vecs_y = 0;
2654                                 vecs_z -= 2;
2655                         }
2656                         else
2657                         {
2658                                 // right
2659                         }
2660                         break;
2661
2662                 case 4:
2663                         if(allowcenter) // 2: allow center handedness
2664                         {
2665                                 // center
2666                                 vecs_y = 0;
2667                                 vecs_z -= 2;
2668                         }
2669                         else
2670                         {
2671                                 // left
2672                                 vecs_y = -vecs_y;
2673                         }
2674                         break;
2675         }
2676         return vecs;
2677 }
2678
2679 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2680 {
2681         string s;
2682         vector v;
2683
2684         if (autocvar_g_shootfromeye)
2685         {
2686                 if (visual)
2687                 {
2688                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2689                 }
2690                 else
2691                 {
2692                         vecs_y = 0;
2693                         vecs_z = 0;
2694                 }
2695         }
2696         else if (autocvar_g_shootfromcenter)
2697         {
2698                 if (visual)
2699                 {
2700                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2701                 }
2702                 else
2703                 {
2704                         vecs_y = 0;
2705                         vecs_z -= 2;
2706                 }
2707         }
2708         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2709         {
2710                 v = stov(s);
2711                 if (y_is_right)
2712                         v_y = -v_y;
2713                 if (v_x != 0)
2714                         vecs_x = v_x;
2715                 vecs_y = v_y;
2716                 vecs_z = v_z;
2717         }
2718         else if (autocvar_g_shootfromclient)
2719         {
2720                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2721         }
2722         return vecs;
2723 }
2724
2725 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2726 {
2727         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2728 }
2729
2730
2731 void attach_sameorigin(entity e, entity to, string tag)
2732 {
2733     vector org, t_forward, t_left, t_up, e_forward, e_up;
2734     vector org0, ang0;
2735     float tagscale;
2736
2737     ang0 = e.angles;
2738     org0 = e.origin;
2739
2740     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2741     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2742     t_forward = v_forward * tagscale;
2743     t_left = v_right * -tagscale;
2744     t_up = v_up * tagscale;
2745
2746     e.origin_x = org * t_forward;
2747     e.origin_y = org * t_left;
2748     e.origin_z = org * t_up;
2749
2750     // current forward and up directions
2751     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2752                 e.angles = AnglesTransform_FromVAngles(e.angles);
2753         else
2754                 e.angles = AnglesTransform_FromAngles(e.angles);
2755     fixedmakevectors(e.angles);
2756
2757     // untransform forward, up!
2758     e_forward_x = v_forward * t_forward;
2759     e_forward_y = v_forward * t_left;
2760     e_forward_z = v_forward * t_up;
2761     e_up_x = v_up * t_forward;
2762     e_up_y = v_up * t_left;
2763     e_up_z = v_up * t_up;
2764
2765     e.angles = fixedvectoangles2(e_forward, e_up);
2766     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2767                 e.angles = AnglesTransform_ToVAngles(e.angles);
2768         else
2769                 e.angles = AnglesTransform_ToAngles(e.angles);
2770
2771     setattachment(e, to, tag);
2772     setorigin(e, e.origin);
2773 }
2774
2775 void detach_sameorigin(entity e)
2776 {
2777     vector org;
2778     org = gettaginfo(e, 0);
2779     e.angles = fixedvectoangles2(v_forward, v_up);
2780     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2781                 e.angles = AnglesTransform_ToVAngles(e.angles);
2782         else
2783                 e.angles = AnglesTransform_ToAngles(e.angles);
2784     setorigin(e, org);
2785     setattachment(e, world, "");
2786     setorigin(e, e.origin);
2787 }
2788
2789 void follow_sameorigin(entity e, entity to)
2790 {
2791     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2792     e.aiment = to; // make the hole follow bmodel
2793     e.punchangle = to.angles; // the original angles of bmodel
2794     e.view_ofs = e.origin - to.origin; // relative origin
2795     e.v_angle = e.angles - to.angles; // relative angles
2796 }
2797
2798 void unfollow_sameorigin(entity e)
2799 {
2800     e.movetype = MOVETYPE_NONE;
2801 }
2802
2803 entity gettaginfo_relative_ent;
2804 vector gettaginfo_relative(entity e, float tag)
2805 {
2806     if (!gettaginfo_relative_ent)
2807     {
2808         gettaginfo_relative_ent = spawn();
2809         gettaginfo_relative_ent.effects = EF_NODRAW;
2810     }
2811     gettaginfo_relative_ent.model = e.model;
2812     gettaginfo_relative_ent.modelindex = e.modelindex;
2813     gettaginfo_relative_ent.frame = e.frame;
2814     return gettaginfo(gettaginfo_relative_ent, tag);
2815 }
2816
2817 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2818 {
2819     float p;
2820     p = pow(2, chan);
2821     if (pl.soundentity.cnt & p)
2822         return;
2823     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2824     pl.soundentity.cnt |= p;
2825 }
2826
2827 void SoundEntity_StopSound(entity pl, float chan)
2828 {
2829     float p;
2830     p = pow(2, chan);
2831     if (pl.soundentity.cnt & p)
2832     {
2833         stopsoundto(MSG_ALL, pl.soundentity, chan);
2834         pl.soundentity.cnt &~= p;
2835     }
2836 }
2837
2838 void SoundEntity_Attach(entity pl)
2839 {
2840     pl.soundentity = spawn();
2841     pl.soundentity.classname = "soundentity";
2842     pl.soundentity.owner = pl;
2843     setattachment(pl.soundentity, pl, "");
2844     setmodel(pl.soundentity, "null");
2845 }
2846
2847 void SoundEntity_Detach(entity pl)
2848 {
2849     float i;
2850     for (i = 0; i <= 7; ++i)
2851         SoundEntity_StopSound(pl, i);
2852 }
2853
2854
2855 float ParseCommandPlayerSlotTarget_firsttoken;
2856 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2857 {
2858     string s;
2859     entity e, head;
2860     float n;
2861
2862     s = string_null;
2863
2864     ParseCommandPlayerSlotTarget_firsttoken = -1;
2865
2866     if (tokens > idx)
2867     {
2868         if (substring(argv(idx), 0, 1) == "#")
2869         {
2870             s = substring(argv(idx), 1, -1);
2871             ++idx;
2872             if (s == "")
2873                 if (tokens > idx)
2874                 {
2875                     s = argv(idx);
2876                     ++idx;
2877                 }
2878                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2879             if (s == ftos(stof(s)))
2880             {
2881                 e = edict_num(stof(s));
2882                 if (e.flags & FL_CLIENT)
2883                     return e;
2884             }
2885         }
2886         else
2887         {
2888             // it must be a nick name
2889             s = argv(idx);
2890             ++idx;
2891                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2892
2893             n = 0;
2894             FOR_EACH_CLIENT(head)
2895             if (head.netname == s)
2896             {
2897                 e = head;
2898                 ++n;
2899             }
2900             if (n == 1)
2901                 return e;
2902
2903             s = strdecolorize(s);
2904             n = 0;
2905             FOR_EACH_CLIENT(head)
2906             if (strdecolorize(head.netname) == s)
2907             {
2908                 e = head;
2909                 ++n;
2910             }
2911             if (n == 1)
2912                 return e;
2913         }
2914     }
2915
2916     return world;
2917 }
2918
2919 .float scale2;
2920
2921 float modeleffect_SendEntity(entity to, float sf)
2922 {
2923         float f;
2924         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2925
2926         f = 0;
2927         if(self.velocity != '0 0 0')
2928                 f |= 1;
2929         if(self.angles != '0 0 0')
2930                 f |= 2;
2931         if(self.avelocity != '0 0 0')
2932                 f |= 4;
2933
2934         WriteByte(MSG_ENTITY, f);
2935         WriteShort(MSG_ENTITY, self.modelindex);
2936         WriteByte(MSG_ENTITY, self.skin);
2937         WriteByte(MSG_ENTITY, self.frame);
2938         WriteCoord(MSG_ENTITY, self.origin_x);
2939         WriteCoord(MSG_ENTITY, self.origin_y);
2940         WriteCoord(MSG_ENTITY, self.origin_z);
2941         if(f & 1)
2942         {
2943                 WriteCoord(MSG_ENTITY, self.velocity_x);
2944                 WriteCoord(MSG_ENTITY, self.velocity_y);
2945                 WriteCoord(MSG_ENTITY, self.velocity_z);
2946         }
2947         if(f & 2)
2948         {
2949                 WriteCoord(MSG_ENTITY, self.angles_x);
2950                 WriteCoord(MSG_ENTITY, self.angles_y);
2951                 WriteCoord(MSG_ENTITY, self.angles_z);
2952         }
2953         if(f & 4)
2954         {
2955                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2956                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2957                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2958         }
2959         WriteShort(MSG_ENTITY, self.scale * 256.0);
2960         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2961         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2962         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2963         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2964
2965         return TRUE;
2966 }
2967
2968 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2969 {
2970         entity e;
2971         float sz;
2972         e = spawn();
2973         e.classname = "modeleffect";
2974         setmodel(e, m);
2975         e.frame = f;
2976         setorigin(e, o);
2977         e.velocity = v;
2978         e.angles = ang;
2979         e.avelocity = angv;
2980         e.alpha = a;
2981         e.teleport_time = t1;
2982         e.fade_time = t2;
2983         e.skin = s;
2984         if(s0 >= 0)
2985                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2986         else
2987                 e.scale = -s0;
2988         if(s2 >= 0)
2989                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2990         else
2991                 e.scale2 = -s2;
2992         sz = max(e.scale, e.scale2);
2993         setsize(e, e.mins * sz, e.maxs * sz);
2994         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2995 }
2996
2997 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2998 {
2999         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3000 }
3001
3002 float randombit(float bits)
3003 {
3004         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3005                 return bits;
3006
3007         float n, f, b, r;
3008
3009         r = random();
3010         b = 0;
3011         n = 0;
3012
3013         for(f = 1; f <= bits; f *= 2)
3014         {
3015                 if(bits & f)
3016                 {
3017                         ++n;
3018                         r *= n;
3019                         if(r <= 1)
3020                                 b = f;
3021                         else
3022                                 r = (r - 1) / (n - 1);
3023                 }
3024         }
3025
3026         return b;
3027 }
3028
3029 float randombits(float bits, float k, float error_return)
3030 {
3031         float r;
3032         r = 0;
3033         while(k > 0 && bits != r)
3034         {
3035                 r += randombit(bits - r);
3036                 --k;
3037         }
3038         if(error_return)
3039                 if(k > 0)
3040                         return -1; // all
3041         return r;
3042 }
3043
3044 void randombit_test(float bits, float iter)
3045 {
3046         while(iter > 0)
3047         {
3048                 print(ftos(randombit(bits)), "\n");
3049                 --iter;
3050         }
3051 }
3052
3053 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3054 {
3055         if(halflifedist > 0)
3056                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3057         else if(halflifedist < 0)
3058                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3059         else
3060                 return 1;
3061 }
3062
3063
3064
3065
3066 #ifdef RELEASE
3067 #define cvar_string_normal cvar_string_builtin
3068 #define cvar_normal cvar_builtin
3069 #else
3070 string cvar_string_normal(string n)
3071 {
3072         if not(cvar_type(n) & 1)
3073                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3074         return cvar_string_builtin(n);
3075 }
3076
3077 float cvar_normal(string n)
3078 {
3079         return stof(cvar_string_normal(n));
3080 }
3081 #endif
3082 #define cvar_set_normal cvar_set_builtin
3083
3084 void defer_think()
3085 {
3086     entity oself;
3087
3088     oself           = self;
3089     self            = self.owner;
3090     oself.think     = SUB_Remove;
3091     oself.nextthink = time;
3092
3093     oself.use();
3094 }
3095
3096 /*
3097     Execute func() after time + fdelay.
3098     self when func is executed = self when defer is called
3099 */
3100 void defer(float fdelay, void() func)
3101 {
3102     entity e;
3103
3104     e           = spawn();
3105     e.owner     = self;
3106     e.use       = func;
3107     e.think     = defer_think;
3108     e.nextthink = time + fdelay;
3109 }