6e722797b5d6f71db0d631b47d7130726b07cb38
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 #include "miscfunctions.qh"
2
3 #include "antilag.qh"
4 #include "command/common.qh"
5 #include "constants.qh"
6 #include "g_hook.qh"
7 #include "ipban.qh"
8 #include <server/mutators/_mod.qh>
9 #include "../common/t_items.qh"
10 #include "resources.qh"
11 #include "items.qh"
12 #include "player.qh"
13 #include "weapons/accuracy.qh"
14 #include "weapons/csqcprojectile.qh"
15 #include "weapons/selection.qh"
16 #include "../common/command/_mod.qh"
17 #include "../common/constants.qh"
18 #include <common/net_linked.qh>
19 #include <common/weapons/weapon/crylink.qh>
20 #include "../common/deathtypes/all.qh"
21 #include "../common/mapinfo.qh"
22 #include "../common/notifications/all.qh"
23 #include "../common/playerstats.qh"
24 #include "../common/teams.qh"
25 #include "../common/mapobjects/subs.qh"
26 #include "../common/util.qh"
27 #include "../common/turrets/sv_turrets.qh"
28 #include <common/weapons/_all.qh>
29 #include "../common/vehicles/sv_vehicles.qh"
30 #include "../common/vehicles/vehicle.qh"
31 #include "../common/items/_mod.qh"
32 #include "../common/state.qh"
33 #include "../common/effects/qc/globalsound.qh"
34 #include "../common/wepent.qh"
35 #include "../lib/csqcmodel/sv_model.qh"
36 #include "../lib/warpzone/anglestransform.qh"
37 #include "../lib/warpzone/server.qh"
38
39 void crosshair_trace(entity pl)
40 {
41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
42 }
43
44 void crosshair_trace_plusvisibletriggers(entity pl)
45 {
46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
47 }
48
49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
50 {
51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
52 }
53
54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
55 {
56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
57         {
58                 if(it.model != "")
59                 {
60                         it.solid = SOLID_BSP;
61                         IL_PUSH(g_ctrace_changed, it);
62                 }
63         });
64
65         if (is_wz)
66                 WarpZone_crosshair_trace(pl);
67         else
68                 crosshair_trace(pl);
69
70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
71
72         IL_CLEAR(g_ctrace_changed);
73 }
74
75 void WarpZone_crosshair_trace(entity pl)
76 {
77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
78 }
79
80 void dedicated_print(string input)
81 {
82         if (server_is_dedicated) print(input);
83 }
84
85 void GameLogEcho(string s)
86 {
87     string fn;
88     int matches;
89
90     if (autocvar_sv_eventlog_files)
91     {
92         if (!logfile_open)
93         {
94             logfile_open = true;
95             matches = autocvar_sv_eventlog_files_counter + 1;
96             cvar_set("sv_eventlog_files_counter", itos(matches));
97             fn = ftos(matches);
98             if (strlen(fn) < 8)
99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
101             logfile = fopen(fn, FILE_APPEND);
102             fputs(logfile, ":logversion:3\n");
103         }
104         if (logfile >= 0)
105         {
106             if (autocvar_sv_eventlog_files_timestamps)
107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
108             else
109                 fputs(logfile, strcat(s, "\n"));
110         }
111     }
112     if (autocvar_sv_eventlog_console)
113     {
114         dedicated_print(strcat(s, "\n"));
115     }
116 }
117
118 void GameLogInit()
119 {
120     logfile_open = 0;
121     // will be opened later
122 }
123
124 void GameLogClose()
125 {
126     if (logfile_open && logfile >= 0)
127     {
128         fclose(logfile);
129         logfile = -1;
130     }
131 }
132
133 entity findnearest(vector point, bool checkitems, vector axismod)
134 {
135     vector dist;
136     int num_nearest = 0;
137
138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
139     {
140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
141             dist = it.oldorigin;
142         else
143             dist = it.origin;
144         dist = dist - point;
145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
146         float len = vlen2(dist);
147
148         int l;
149         for (l = 0; l < num_nearest; ++l)
150         {
151             if (len < nearest_length[l])
152                 break;
153         }
154
155         // now i tells us where to insert at
156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
157         if (l < NUM_NEAREST_ENTITIES)
158         {
159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
160             {
161                 nearest_length[j + 1] = nearest_length[j];
162                 nearest_entity[j + 1] = nearest_entity[j];
163             }
164             nearest_length[l] = len;
165             nearest_entity[l] = it;
166             if (num_nearest < NUM_NEAREST_ENTITIES)
167                 num_nearest = num_nearest + 1;
168         }
169     });
170
171     // now use the first one from our list that we can see
172     for (int j = 0; j < num_nearest; ++j)
173     {
174         traceline(point, nearest_entity[j].origin, true, NULL);
175         if (trace_fraction == 1)
176         {
177             if (j != 0)
178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
179             return nearest_entity[j];
180         }
181     }
182
183     if (num_nearest == 0)
184         return NULL;
185
186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
187     /* DEBUGGING CODE:
188     dprint("Candidates were: ");
189     for(j = 0; j < num_nearest; ++j)
190     {
191         if(j != 0)
192                 dprint(", ");
193         dprint(nearest_entity[j].netname);
194     }
195     dprint("\n");
196     */
197
198     return nearest_entity[0];
199 }
200
201 string NearestLocation(vector p)
202 {
203     string ret = "somewhere";
204     entity loc = findnearest(p, false, '1 1 1');
205     if (loc)
206         ret = loc.message;
207     else
208     {
209         loc = findnearest(p, true, '1 1 4');
210         if (loc)
211             ret = loc.netname;
212     }
213     return ret;
214 }
215
216 string AmmoNameFromWeaponentity(Weapon wep)
217 {
218         string ammoitems = "batteries";
219         switch (wep.ammo_type)
220         {
221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
227         }
228         return ammoitems;
229 }
230
231 string formatmessage(entity this, string msg)
232 {
233         float p, p1, p2;
234         float n;
235         vector cursor = '0 0 0';
236         entity cursor_ent = NULL;
237         string escape;
238         string replacement;
239         p = 0;
240         n = 7;
241         bool traced = false;
242
243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
244         msg = M_ARGV(1, string);
245
246         while (1) {
247                 if (n < 1)
248                         break; // too many replacements
249
250                 n = n - 1;
251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
253
254                 if (p1 < 0)
255                         p1 = p2;
256
257                 if (p2 < 0)
258                         p2 = p1;
259
260                 p = min(p1, p2);
261
262                 if (p < 0)
263                         break;
264
265                 if(!traced)
266                 {
267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
268                         cursor = trace_endpos;
269                         cursor_ent = trace_ent;
270                         traced = true;
271                 }
272
273                 replacement = substring(msg, p, 2);
274                 escape = substring(msg, p + 1, 1);
275
276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
277
278                 switch(escape)
279                 {
280                         case "%": replacement = "%"; break;
281                         case "\\":replacement = "\\"; break;
282                         case "n": replacement = "\n"; break;
283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
285                         case "l": replacement = NearestLocation(this.origin); break;
286                         case "y": replacement = NearestLocation(cursor); break;
287                         case "d": replacement = NearestLocation(this.death_origin); break;
288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
292                         case "S": replacement = ftos(vlen(this.velocity)); break;
293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
295                         default:
296                         {
297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
298                                 replacement = M_ARGV(2, string);
299                                 break;
300                         }
301                 }
302
303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
304                 p = p + strlen(replacement);
305         }
306         return msg;
307 }
308
309 /*
310 =============
311 GetCvars
312 =============
313 Called with:
314   0:  sends the request
315   >0: receives a cvar from name=argv(f) value=argv(f+1)
316 */
317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
318 {
319         if (f < 0)
320         {
321                 strfree(store.(field));
322         }
323         else if (f > 0)
324         {
325                 if (thisname == name)
326                 {
327                         strcpy(store.(field), argv(f + 1));
328                 }
329         }
330         else
331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
332 }
333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
334 {
335         GetCvars_handleString(this, store, thisname, f, field, name);
336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
337                 if (thisname == name)
338                 {
339                         string s = func(this, strcat1(store.(field)));
340                         if (s != store.(field))
341                         {
342                                 strcpy(store.(field), s);
343                         }
344                 }
345 }
346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
347 {
348         if (f < 0)
349         {
350         }
351         else if (f > 0)
352         {
353                 if (thisname == name)
354                         store.(field) = stof(argv(f + 1));
355         }
356         else
357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
358 }
359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
360 {
361         if (f < 0)
362         {
363         }
364         else if (f > 0)
365         {
366                 if (thisname == name)
367                 {
368                         if (!store.(field))
369                         {
370                                 store.(field) = stof(argv(f + 1));
371                                 if (!store.(field))
372                                         store.(field) = -1;
373                         }
374                 }
375         }
376         else
377         {
378                 if (!store.(field))
379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
380         }
381 }
382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
383 {
384         string o = W_FixWeaponOrder_ForceComplete(wo);
385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
386         return o;
387 }
388
389 REPLICATE(autoswitch, bool, "cl_autoswitch");
390
391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
392
393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
394
395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
396
397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
398
399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
400
401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
402
403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
404
405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
406
407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
408
409 REPLICATE(cvar_cl_physics, string, "cl_physics");
410
411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
412
413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
414
415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
416
417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
418
419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
420
421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
422
423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
424
425 /**
426  * @param f -1: cleanup, 0: request, 1: receive
427  */
428 void GetCvars(entity this, entity store, int f)
429 {
430         string s = string_null;
431
432         if (f > 0)
433                 s = strcat1(argv(f));
434
435         get_cvars_f = f;
436         get_cvars_s = s;
437         MUTATOR_CALLHOOK(GetCvars);
438
439         Notification_GetCvars(this);
440
441         ReplicateVars(this, store, s, f);
442
443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
454
455         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
456
457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
458         if (f > 0)
459         {
460                 if (s == "cl_weaponpriority")
461                 {
462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
463                         {
464                                 .entity weaponentity = weaponentities[slot];
465                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
466                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
467                         }
468                 }
469                 if (s == "cl_allow_uidtracking")
470                         PlayerStats_GameReport_AddPlayer(this);
471         }
472 }
473
474 // decolorizes and team colors the player name when needed
475 string playername(entity p, bool team_colorize)
476 {
477     string t;
478     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
479     {
480         t = Team_ColorCode(p.team);
481         return strcat(t, strdecolorize(p.netname));
482     }
483     else
484         return p.netname;
485 }
486
487 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
488 {
489         int i = weaponinfo.m_id;
490         int d = 0;
491         bool allow_mutatorblocked = false;
492
493         if(!i)
494                 return 0;
495
496         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
497         d = M_ARGV(1, float);
498         allguns = M_ARGV(2, bool);
499         allow_mutatorblocked = M_ARGV(3, bool);
500
501         if(allguns)
502         {
503                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
504                         d = true;
505                 else
506                         d = false;
507         }
508         else if(!mutator_returnvalue)
509                 d = !(!weaponinfo.weaponstart);
510
511         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
512                 d = 0;
513
514         float t = weaponinfo.weaponstartoverride;
515
516         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
517
518         // bit order in t:
519         // 1: want or not
520         // 2: is default?
521         // 4: is set by default?
522         if(t < 0)
523                 t = 4 | (3 * d);
524         else
525                 t |= (2 * d);
526
527         return t;
528 }
529
530 void readplayerstartcvars()
531 {
532         float i, t;
533         string s;
534
535         // initialize starting values for players
536         start_weapons = '0 0 0';
537         start_weapons_default = '0 0 0';
538         start_weapons_defaultmask = '0 0 0';
539         start_items = 0;
540         start_ammo_shells = 0;
541         start_ammo_nails = 0;
542         start_ammo_rockets = 0;
543         start_ammo_cells = 0;
544         start_ammo_plasma = 0;
545         if (random_start_ammo == NULL)
546         {
547                 random_start_ammo = spawn();
548         }
549         start_health = cvar("g_balance_health_start");
550         start_armorvalue = cvar("g_balance_armor_start");
551
552         g_weaponarena = 0;
553         g_weaponarena_weapons = '0 0 0';
554
555         s = cvar_string("g_weaponarena");
556
557         MUTATOR_CALLHOOK(SetWeaponArena, s);
558         s = M_ARGV(0, string);
559
560         if (s == "0" || s == "")
561         {
562                 // no arena
563         }
564         else if (s == "off")
565         {
566                 // forcibly turn off weaponarena
567         }
568         else if (s == "all" || s == "1")
569         {
570                 g_weaponarena = 1;
571                 g_weaponarena_list = "All Weapons";
572                 FOREACH(Weapons, it != WEP_Null, {
573                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
574                                 g_weaponarena_weapons |= (it.m_wepset);
575                 });
576         }
577         else if (s == "devall")
578         {
579                 g_weaponarena = 1;
580                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
581                 FOREACH(Weapons, it != WEP_Null,
582                 {
583                         g_weaponarena_weapons |= (it.m_wepset);
584                 });
585         }
586         else if (s == "most")
587         {
588                 g_weaponarena = 1;
589                 g_weaponarena_list = "Most Weapons";
590                 FOREACH(Weapons, it != WEP_Null, {
591                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
592                                 if(it.spawnflags & WEP_FLAG_NORMAL)
593                                         g_weaponarena_weapons |= (it.m_wepset);
594                 });
595         }
596         else if (s == "none")
597         {
598                 g_weaponarena = 1;
599                 g_weaponarena_list = "No Weapons";
600         }
601         else
602         {
603                 g_weaponarena = 1;
604                 t = tokenize_console(s);
605                 g_weaponarena_list = "";
606                 for (i = 0; i < t; ++i)
607                 {
608                         s = argv(i);
609                         Weapon wep = Weapons_fromstr(s);
610                         if(wep != WEP_Null)
611                         {
612                                 g_weaponarena_weapons |= (wep.m_wepset);
613                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
614                         }
615                 }
616                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
617         }
618
619         if (g_weaponarena)
620         {
621                 g_weapon_stay = 0; // incompatible
622                 start_weapons = g_weaponarena_weapons;
623                 start_items |= IT_UNLIMITED_AMMO;
624         }
625         else
626         {
627                 FOREACH(Weapons, it != WEP_Null, {
628                         int w = want_weapon(it, false);
629                         WepSet s = it.m_wepset;
630                         if(w & 1)
631                                 start_weapons |= s;
632                         if(w & 2)
633                                 start_weapons_default |= s;
634                         if(w & 4)
635                                 start_weapons_defaultmask |= s;
636                 });
637         }
638
639         if(cvar("g_balance_superweapons_time") < 0)
640                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
641
642         if(!cvar("g_use_ammunition"))
643                 start_items |= IT_UNLIMITED_AMMO;
644
645         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
646         {
647                 start_ammo_shells = 999;
648                 start_ammo_nails = 999;
649                 start_ammo_rockets = 999;
650                 start_ammo_cells = 999;
651                 start_ammo_plasma = 999;
652                 start_ammo_fuel = 999;
653         }
654         else
655         {
656                 start_ammo_shells = cvar("g_start_ammo_shells");
657                 start_ammo_nails = cvar("g_start_ammo_nails");
658                 start_ammo_rockets = cvar("g_start_ammo_rockets");
659                 start_ammo_cells = cvar("g_start_ammo_cells");
660                 start_ammo_plasma = cvar("g_start_ammo_plasma");
661                 start_ammo_fuel = cvar("g_start_ammo_fuel");
662                 random_start_weapons_count = cvar("g_random_start_weapons_count");
663                 SetResource(random_start_ammo, RES_SHELLS, cvar(
664                         "g_random_start_shells"));
665                 SetResource(random_start_ammo, RES_BULLETS, cvar(
666                         "g_random_start_bullets"));
667                 SetResource(random_start_ammo, RES_ROCKETS,
668                         cvar("g_random_start_rockets"));
669                 SetResource(random_start_ammo, RES_CELLS, cvar(
670                         "g_random_start_cells"));
671                 SetResource(random_start_ammo, RES_PLASMA, cvar(
672                         "g_random_start_plasma"));
673         }
674
675         if (warmup_stage)
676         {
677                 warmup_start_ammo_shells = start_ammo_shells;
678                 warmup_start_ammo_nails = start_ammo_nails;
679                 warmup_start_ammo_rockets = start_ammo_rockets;
680                 warmup_start_ammo_cells = start_ammo_cells;
681                 warmup_start_ammo_plasma = start_ammo_plasma;
682                 warmup_start_ammo_fuel = start_ammo_fuel;
683                 warmup_start_health = start_health;
684                 warmup_start_armorvalue = start_armorvalue;
685                 warmup_start_weapons = start_weapons;
686                 warmup_start_weapons_default = start_weapons_default;
687                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
688
689                 if (!g_weaponarena && !g_ca && !g_freezetag)
690                 {
691                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
692                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
693                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
694                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
695                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
696                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
697                         warmup_start_health = cvar("g_warmup_start_health");
698                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
699                         warmup_start_weapons = '0 0 0';
700                         warmup_start_weapons_default = '0 0 0';
701                         warmup_start_weapons_defaultmask = '0 0 0';
702                         FOREACH(Weapons, it != WEP_Null, {
703                                 int w = want_weapon(it, g_warmup_allguns);
704                                 WepSet s = (it.m_wepset);
705                                 if(w & 1)
706                                         warmup_start_weapons |= s;
707                                 if(w & 2)
708                                         warmup_start_weapons_default |= s;
709                                 if(w & 4)
710                                         warmup_start_weapons_defaultmask |= s;
711                         });
712                 }
713         }
714
715         if (g_jetpack)
716                 start_items |= ITEM_Jetpack.m_itemid;
717
718         MUTATOR_CALLHOOK(SetStartItems);
719
720         if (start_items & ITEM_Jetpack.m_itemid)
721         {
722                 start_items |= ITEM_JetpackRegen.m_itemid;
723                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
724                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
725         }
726
727         WepSet precache_weapons = start_weapons;
728         if (g_warmup_allguns != 1)
729                 precache_weapons |= warmup_start_weapons;
730         FOREACH(Weapons, it != WEP_Null, {
731                 if(precache_weapons & (it.m_wepset))
732                         it.wr_init(it);
733         });
734
735         start_ammo_shells = max(0, start_ammo_shells);
736         start_ammo_nails = max(0, start_ammo_nails);
737         start_ammo_rockets = max(0, start_ammo_rockets);
738         start_ammo_cells = max(0, start_ammo_cells);
739         start_ammo_plasma = max(0, start_ammo_plasma);
740         start_ammo_fuel = max(0, start_ammo_fuel);
741         SetResource(random_start_ammo, RES_SHELLS, max(0,
742                 GetResource(random_start_ammo, RES_SHELLS)));
743         SetResource(random_start_ammo, RES_BULLETS, max(0,
744                 GetResource(random_start_ammo, RES_BULLETS)));
745         SetResource(random_start_ammo, RES_ROCKETS, max(0,
746                 GetResource(random_start_ammo, RES_ROCKETS)));
747         SetResource(random_start_ammo, RES_CELLS, max(0,
748                 GetResource(random_start_ammo, RES_CELLS)));
749         SetResource(random_start_ammo, RES_PLASMA, max(0,
750                 GetResource(random_start_ammo, RES_PLASMA)));
751
752         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
753         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
754         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
755         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
756         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
757         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
758 }
759
760 void precache_playermodel(string m)
761 {
762         float globhandle, i, n;
763         string f;
764
765         if(substring(m, -9,5) == "_lod1")
766                 return;
767         if(substring(m, -9,5) == "_lod2")
768                 return;
769         precache_model(m);
770         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
771         if(fexists(f))
772                 precache_model(f);
773         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
774         if(fexists(f))
775                 precache_model(f);
776
777         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
778         if (globhandle < 0)
779                 return;
780         n = search_getsize(globhandle);
781         for (i = 0; i < n; ++i)
782         {
783                 //print(search_getfilename(globhandle, i), "\n");
784                 f = search_getfilename(globhandle, i);
785                 PrecachePlayerSounds(f);
786         }
787         search_end(globhandle);
788 }
789 void precache_all_playermodels(string pattern)
790 {
791         int globhandle = search_begin(pattern, true, false);
792         if (globhandle < 0) return;
793         int n = search_getsize(globhandle);
794         for (int i = 0; i < n; ++i)
795         {
796                 string s = search_getfilename(globhandle, i);
797                 precache_playermodel(s);
798         }
799         search_end(globhandle);
800 }
801
802 void precache_playermodels(string s)
803 {
804         FOREACH_WORD(s, true, { precache_playermodel(it); });
805 }
806
807 void precache()
808 {
809     // gamemode related things
810
811     // Precache all player models if desired
812     if (autocvar_sv_precacheplayermodels)
813     {
814         PrecachePlayerSounds("sound/player/default.sounds");
815         precache_all_playermodels("models/player/*.zym");
816         precache_all_playermodels("models/player/*.dpm");
817         precache_all_playermodels("models/player/*.md3");
818         precache_all_playermodels("models/player/*.psk");
819         precache_all_playermodels("models/player/*.iqm");
820     }
821
822     if (autocvar_sv_defaultcharacter)
823     {
824                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
825                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
826                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
827                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
828                 precache_playermodels(autocvar_sv_defaultplayermodel);
829     }
830
831 #if 0
832     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
833
834     if (!this.noise && this.music) // quake 3 uses the music field
835         this.noise = this.music;
836
837     // plays music for the level if there is any
838     if (this.noise)
839     {
840         precache_sound (this.noise);
841         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
842     }
843 #endif
844 }
845
846
847 void make_safe_for_remove(entity e)
848 {
849     if (e.initialize_entity)
850     {
851         entity ent, prev = NULL;
852         for (ent = initialize_entity_first; ent; )
853         {
854             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
855             {
856                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
857                 // skip it in linked list
858                 if (prev)
859                 {
860                     prev.initialize_entity_next = ent.initialize_entity_next;
861                     ent = prev.initialize_entity_next;
862                 }
863                 else
864                 {
865                     initialize_entity_first = ent.initialize_entity_next;
866                     ent = initialize_entity_first;
867                 }
868             }
869             else
870             {
871                 prev = ent;
872                 ent = ent.initialize_entity_next;
873             }
874         }
875     }
876 }
877
878 .float remove_except_protected_forbidden;
879 void remove_except_protected(entity e)
880 {
881         if(e.remove_except_protected_forbidden)
882                 error("not allowed to remove this at this point");
883         builtin_remove(e);
884 }
885
886 void remove_unsafely(entity e)
887 {
888     if(e.classname == "spike")
889         error("Removing spikes is forbidden (crylink bug), please report");
890     builtin_remove(e);
891 }
892
893 void remove_safely(entity e)
894 {
895     make_safe_for_remove(e);
896     builtin_remove(e);
897 }
898
899 void InitializeEntity(entity e, void(entity this) func, int order)
900 {
901     entity prev, cur;
902
903     if (!e || e.initialize_entity)
904     {
905         // make a proxy initializer entity
906         entity e_old = e;
907         e = new(initialize_entity);
908         e.enemy = e_old;
909     }
910
911     e.initialize_entity = func;
912     e.initialize_entity_order = order;
913
914     cur = initialize_entity_first;
915     prev = NULL;
916     for (;;)
917     {
918         if (!cur || cur.initialize_entity_order > order)
919         {
920             // insert between prev and cur
921             if (prev)
922                 prev.initialize_entity_next = e;
923             else
924                 initialize_entity_first = e;
925             e.initialize_entity_next = cur;
926             return;
927         }
928         prev = cur;
929         cur = cur.initialize_entity_next;
930     }
931 }
932 void InitializeEntitiesRun()
933 {
934     entity startoflist = initialize_entity_first;
935     initialize_entity_first = NULL;
936     delete_fn = remove_except_protected;
937     for (entity e = startoflist; e; e = e.initialize_entity_next)
938     {
939                 e.remove_except_protected_forbidden = 1;
940     }
941     for (entity e = startoflist; e; )
942     {
943                 e.remove_except_protected_forbidden = 0;
944         e.initialize_entity_order = 0;
945         entity next = e.initialize_entity_next;
946         e.initialize_entity_next = NULL;
947         var void(entity this) func = e.initialize_entity;
948         e.initialize_entity = func_null;
949         if (e.classname == "initialize_entity")
950         {
951             entity wrappee = e.enemy;
952             builtin_remove(e);
953             e = wrappee;
954         }
955         //dprint("Delayed initialization: ", e.classname, "\n");
956         if (func)
957         {
958                 func(e);
959         }
960         else
961         {
962             eprint(e);
963             backtrace(strcat("Null function in: ", e.classname, "\n"));
964         }
965         e = next;
966     }
967     delete_fn = remove_unsafely;
968 }
969
970 .float(entity) isEliminated;
971 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
972 {
973         Stream out = MSG_ENTITY;
974         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
975         serialize(byte, out, sendflags);
976         if (sendflags & 1) {
977                 for (int i = 1; i <= maxclients; i += 8) {
978                         int f = 0;
979                         entity e = edict_num(i);
980                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
981                                 if (eliminatedPlayers.isEliminated(e)) {
982                                         f |= BIT(b);
983                                 }
984                         }
985                         serialize(byte, out, f);
986                 }
987         }
988         return true;
989 }
990
991 void EliminatedPlayers_Init(float(entity) isEliminated_func)
992 {
993         if(eliminatedPlayers)
994         {
995                 backtrace("Can't spawn eliminatedPlayers again!");
996                 return;
997         }
998         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
999         eliminatedPlayers.isEliminated = isEliminated_func;
1000 }
1001
1002
1003
1004
1005 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1006 {
1007         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1008                 this.projectiledeathtype |= HITTYPE_SPLASH;
1009         adaptor_think2use(this);
1010 }
1011
1012 // deferred dropping
1013 void DropToFloor_Handler(entity this)
1014 {
1015     WITHSELF(this, builtin_droptofloor());
1016     this.dropped_origin = this.origin;
1017 }
1018
1019 void droptofloor(entity this)
1020 {
1021     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1022 }
1023
1024
1025
1026 float trace_hits_box_a0, trace_hits_box_a1;
1027
1028 float trace_hits_box_1d(float end, float thmi, float thma)
1029 {
1030     if (end == 0)
1031     {
1032         // just check if x is in range
1033         if (0 < thmi)
1034             return false;
1035         if (0 > thma)
1036             return false;
1037     }
1038     else
1039     {
1040         // do the trace with respect to x
1041         // 0 -> end has to stay in thmi -> thma
1042         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1043         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1044         if (trace_hits_box_a0 > trace_hits_box_a1)
1045             return false;
1046     }
1047     return true;
1048 }
1049
1050 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1051 {
1052     end -= start;
1053     thmi -= start;
1054     thma -= start;
1055     // now it is a trace from 0 to end
1056
1057     trace_hits_box_a0 = 0;
1058     trace_hits_box_a1 = 1;
1059
1060     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1061         return false;
1062     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1063         return false;
1064     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1065         return false;
1066
1067     return true;
1068 }
1069
1070 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1071 {
1072     return trace_hits_box(start, end, thmi - ma, thma - mi);
1073 }
1074
1075 bool SUB_NoImpactCheck(entity this, entity toucher)
1076 {
1077         // zero hitcontents = this is not the real impact, but either the
1078         // mirror-impact of something hitting the projectile instead of the
1079         // projectile hitting the something, or a touchareagrid one. Neither of
1080         // these stop the projectile from moving, so...
1081         if(trace_dphitcontents == 0)
1082         {
1083                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1084                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1085         }
1086     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1087         return true;
1088     if (toucher == NULL && this.size != '0 0 0')
1089     {
1090         vector tic;
1091         tic = this.velocity * sys_frametime;
1092         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1093         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1094         if (trace_fraction >= 1)
1095         {
1096             LOG_TRACE("Odd... did not hit...?");
1097         }
1098         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1099         {
1100             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1101             return true;
1102         }
1103     }
1104
1105     return false;
1106 }
1107
1108 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1109
1110 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1111 {
1112         if(SUB_OwnerCheck(this, toucher))
1113                 return true;
1114         if(SUB_NoImpactCheck(this, toucher))
1115         {
1116                 if(this.classname == "nade")
1117                         return false; // no checks here
1118                 else if(this.classname == "grapplinghook")
1119                         RemoveHook(this);
1120                 else if(this.classname == "spike")
1121                 {
1122                         W_Crylink_Dequeue(this);
1123                         delete(this);
1124                 }
1125                 else
1126                         delete(this);
1127                 return true;
1128         }
1129         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1130                 UpdateCSQCProjectile(this);
1131         return false;
1132 }
1133
1134 /** engine callback */
1135 void URI_Get_Callback(float id, float status, string data)
1136 {
1137         if(url_URI_Get_Callback(id, status, data))
1138         {
1139                 // handled
1140         }
1141         else if (id == URI_GET_DISCARD)
1142         {
1143                 // discard
1144         }
1145         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1146         {
1147                 // sv_cmd curl
1148                 Curl_URI_Get_Callback(id, status, data);
1149         }
1150         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1151         {
1152                 // online ban list
1153                 OnlineBanList_URI_Get_Callback(id, status, data);
1154         }
1155         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1156         {
1157                 // handled by a mutator
1158         }
1159         else
1160         {
1161                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1162         }
1163 }
1164
1165 string uid2name(string myuid) {
1166         string s;
1167         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1168
1169         // FIXME remove this later after 0.6 release
1170         // convert old style broken records to correct style
1171         if(s == "")
1172         {
1173                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1174                 if(s != "")
1175                 {
1176                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1177                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1178                 }
1179         }
1180
1181         if(s == "")
1182                 s = "^1Unregistered Player";
1183         return s;
1184 }
1185
1186 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1187 {
1188     float m, i;
1189     vector start, org, delta, end, enddown, mstart;
1190
1191     m = e.dphitcontentsmask;
1192     e.dphitcontentsmask = goodcontents | badcontents;
1193
1194     org = boundmin;
1195     delta = boundmax - boundmin;
1196
1197     start = end = org;
1198
1199     for (i = 0; i < attempts; ++i)
1200     {
1201         start.x = org.x + random() * delta.x;
1202         start.y = org.y + random() * delta.y;
1203         start.z = org.z + random() * delta.z;
1204
1205         // rule 1: start inside world bounds, and outside
1206         // solid, and don't start from somewhere where you can
1207         // fall down to evil
1208         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1209         if (trace_fraction >= 1)
1210             continue;
1211         if (trace_startsolid)
1212             continue;
1213         if (trace_dphitcontents & badcontents)
1214             continue;
1215         if (trace_dphitq3surfaceflags & badsurfaceflags)
1216             continue;
1217
1218         // rule 2: if we are too high, lower the point
1219         if (trace_fraction * delta.z > maxaboveground)
1220             start = trace_endpos + '0 0 1' * maxaboveground;
1221         enddown = trace_endpos;
1222
1223         // rule 3: make sure we aren't outside the map. This only works
1224         // for somewhat well formed maps. A good rule of thumb is that
1225         // the map should have a convex outside hull.
1226         // these can be traceLINES as we already verified the starting box
1227         mstart = start + 0.5 * (e.mins + e.maxs);
1228         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1229         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1230             continue;
1231         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1232         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1233             continue;
1234         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1235         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1236             continue;
1237         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1238         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1239             continue;
1240         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1241         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1242             continue;
1243
1244         // rule 4: we must "see" some spawnpoint or item
1245     entity sp = NULL;
1246     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1247     {
1248         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1249         {
1250                 sp = it;
1251                 break;
1252         }
1253     });
1254         if(!sp)
1255         {
1256                 int items_checked = 0;
1257                 IL_EACH(g_items, checkpvs(mstart, it),
1258                 {
1259                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1260                         {
1261                                 sp = it;
1262                                 break;
1263                         }
1264
1265                         ++items_checked;
1266                         if(items_checked >= attempts)
1267                                 break; // sanity
1268                 });
1269
1270                 if(!sp)
1271                         continue;
1272         }
1273
1274         // find a random vector to "look at"
1275         end.x = org.x + random() * delta.x;
1276         end.y = org.y + random() * delta.y;
1277         end.z = org.z + random() * delta.z;
1278         end = start + normalize(end - start) * vlen(delta);
1279
1280         // rule 4: start TO end must not be too short
1281         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1282         if (trace_startsolid)
1283             continue;
1284         if (trace_fraction < minviewdistance / vlen(delta))
1285             continue;
1286
1287         // rule 5: don't want to look at sky
1288         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1289             continue;
1290
1291         // rule 6: we must not end up in trigger_hurt
1292         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1293             continue;
1294
1295         break;
1296     }
1297
1298     e.dphitcontentsmask = m;
1299
1300     if (i < attempts)
1301     {
1302         setorigin(e, start);
1303         e.angles = vectoangles(end - start);
1304         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1305         return true;
1306     }
1307     else
1308         return false;
1309 }
1310
1311 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1312 {
1313         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1314 }
1315
1316 void write_recordmarker(entity pl, float tstart, float dt)
1317 {
1318     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1319
1320     // also write a marker into demo files for demotc-race-record-extractor to find
1321     stuffcmd(pl,
1322              strcat(
1323                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1324                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1325 }
1326
1327 void attach_sameorigin(entity e, entity to, string tag)
1328 {
1329     vector org, t_forward, t_left, t_up, e_forward, e_up;
1330     float tagscale;
1331
1332     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1333     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1334     t_forward = v_forward * tagscale;
1335     t_left = v_right * -tagscale;
1336     t_up = v_up * tagscale;
1337
1338     e.origin_x = org * t_forward;
1339     e.origin_y = org * t_left;
1340     e.origin_z = org * t_up;
1341
1342     // current forward and up directions
1343     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1344                 e.angles = AnglesTransform_FromVAngles(e.angles);
1345         else
1346                 e.angles = AnglesTransform_FromAngles(e.angles);
1347     fixedmakevectors(e.angles);
1348
1349     // untransform forward, up!
1350     e_forward.x = v_forward * t_forward;
1351     e_forward.y = v_forward * t_left;
1352     e_forward.z = v_forward * t_up;
1353     e_up.x = v_up * t_forward;
1354     e_up.y = v_up * t_left;
1355     e_up.z = v_up * t_up;
1356
1357     e.angles = fixedvectoangles2(e_forward, e_up);
1358     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1359                 e.angles = AnglesTransform_ToVAngles(e.angles);
1360         else
1361                 e.angles = AnglesTransform_ToAngles(e.angles);
1362
1363     setattachment(e, to, tag);
1364     setorigin(e, e.origin);
1365 }
1366
1367 void detach_sameorigin(entity e)
1368 {
1369     vector org;
1370     org = gettaginfo(e, 0);
1371     e.angles = fixedvectoangles2(v_forward, v_up);
1372     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1373                 e.angles = AnglesTransform_ToVAngles(e.angles);
1374         else
1375                 e.angles = AnglesTransform_ToAngles(e.angles);
1376     setorigin(e, org);
1377     setattachment(e, NULL, "");
1378     setorigin(e, e.origin);
1379 }
1380
1381 void follow_sameorigin(entity e, entity to)
1382 {
1383     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1384     e.aiment = to; // make the hole follow bmodel
1385     e.punchangle = to.angles; // the original angles of bmodel
1386     e.view_ofs = e.origin - to.origin; // relative origin
1387     e.v_angle = e.angles - to.angles; // relative angles
1388 }
1389
1390 void unfollow_sameorigin(entity e)
1391 {
1392     set_movetype(e, MOVETYPE_NONE);
1393 }
1394
1395 entity gettaginfo_relative_ent;
1396 vector gettaginfo_relative(entity e, float tag)
1397 {
1398     if (!gettaginfo_relative_ent)
1399     {
1400         gettaginfo_relative_ent = spawn();
1401         gettaginfo_relative_ent.effects = EF_NODRAW;
1402     }
1403     gettaginfo_relative_ent.model = e.model;
1404     gettaginfo_relative_ent.modelindex = e.modelindex;
1405     gettaginfo_relative_ent.frame = e.frame;
1406     return gettaginfo(gettaginfo_relative_ent, tag);
1407 }
1408
1409 .string aiment_classname;
1410 .float aiment_deadflag;
1411 void SetMovetypeFollow(entity ent, entity e)
1412 {
1413         // FIXME this may not be warpzone aware
1414         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1415         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1416         ent.aiment = e; // make the hole follow bmodel
1417         ent.punchangle = e.angles; // the original angles of bmodel
1418         ent.view_ofs = ent.origin - e.origin; // relative origin
1419         ent.v_angle = ent.angles - e.angles; // relative angles
1420         ent.aiment_classname = strzone(e.classname);
1421         ent.aiment_deadflag = e.deadflag;
1422 }
1423 void UnsetMovetypeFollow(entity ent)
1424 {
1425         set_movetype(ent, MOVETYPE_FLY);
1426         PROJECTILE_MAKETRIGGER(ent);
1427         ent.aiment = NULL;
1428 }
1429 float LostMovetypeFollow(entity ent)
1430 {
1431 /*
1432         if(ent.move_movetype != MOVETYPE_FOLLOW)
1433                 if(ent.aiment)
1434                         error("???");
1435 */
1436         if(ent.aiment)
1437         {
1438                 if(ent.aiment.classname != ent.aiment_classname)
1439                         return 1;
1440                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1441                         return 1;
1442         }
1443         return 0;
1444 }
1445
1446 .bool pushable;
1447 bool isPushable(entity e)
1448 {
1449         if(e.pushable)
1450                 return true;
1451         if(IS_VEHICLE(e))
1452                 return false;
1453         if(e.iscreature)
1454                 return true;
1455         if (Item_IsLoot(e))
1456         {
1457                 return true;
1458         }
1459         switch(e.classname)
1460         {
1461                 case "body":
1462                         return true;
1463                 case "bullet": // antilagged bullets can't hit this either
1464                         return false;
1465         }
1466         if (e.projectiledeathtype)
1467                 return true;
1468         return false;
1469 }