qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = WEP_NAME(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else if (self.items & IT_PLASMA) replacement = "plasma";
 365                         else replacement = "batteries"; // ;)
 366                 } else if (escape == "x") {
 367                         replacement = cursor_ent.netname;
 368                         if (replacement == "" || !cursor_ent)
 369                                 replacement = "nothing";
 370                 } else if (escape == "s")
 371                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 372                 else if (escape == "S")
 373                         replacement = ftos(vlen(self.velocity));
 374
 375                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 376                 p = p + strlen(replacement);
 377         }
 378         return msg;
 379 }
 380
 381 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 382         return (value == 0) ? FALSE : TRUE;
 383 }
 384
 385 /*
 386 =============
 387 GetCvars
 388 =============
 389 Called with:
 390   0:  sends the request
 391   >0: receives a cvar from name=argv(f) value=argv(f+1)
 392 */
 393 void GetCvars_handleString(string thisname, float f, .string field, string name)
 394 {
 395         if (f < 0)
 396         {
 397                 if (self.field)
 398                         strunzone(self.field);
 399                 self.field = string_null;
 400         }
 401         else if (f > 0)
 402         {
 403                 if (thisname == name)
 404                 {
 405                         if (self.field)
 406                                 strunzone(self.field);
 407                         self.field = strzone(argv(f + 1));
 408                 }
 409         }
 410         else
 411                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 412 }
 413 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 414 {
 415         GetCvars_handleString(thisname, f, field, name);
 416         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 417                 if (thisname == name)
 418                 {
 419                         string s;
 420                         s = func(strcat1(self.field));
 421                         if (s != self.field)
 422                         {
 423                                 strunzone(self.field);
 424                                 self.field = strzone(s);
 425                         }
 426                 }
 427 }
 428 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 429 {
 430         if (f < 0)
 431         {
 432         }
 433         else if (f > 0)
 434         {
 435                 if (thisname == name)
 436                         self.field = stof(argv(f + 1));
 437         }
 438         else
 439                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 440 }
 441 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 442 {
 443         if (f < 0)
 444         {
 445         }
 446         else if (f > 0)
 447         {
 448                 if (thisname == name)
 449                 {
 450                         if(!self.field)
 451                         {
 452                                 self.field = stof(argv(f + 1));
 453                                 if(!self.field)
 454                                         self.field = -1;
 455                         }
 456                 }
 457         }
 458         else
 459         {
 460                 if(!self.field)
 461                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462         }
 463 }
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_plasma;
 567 float g_pickup_plasma_max;
 568 float g_pickup_fuel;
 569 float g_pickup_fuel_jetpack;
 570 float g_pickup_fuel_max;
 571 float g_pickup_armorsmall;
 572 float g_pickup_armorsmall_max;
 573 float g_pickup_armorsmall_anyway;
 574 float g_pickup_armormedium;
 575 float g_pickup_armormedium_max;
 576 float g_pickup_armormedium_anyway;
 577 float g_pickup_armorbig;
 578 float g_pickup_armorbig_max;
 579 float g_pickup_armorbig_anyway;
 580 float g_pickup_armorlarge;
 581 float g_pickup_armorlarge_max;
 582 float g_pickup_armorlarge_anyway;
 583 float g_pickup_healthsmall;
 584 float g_pickup_healthsmall_max;
 585 float g_pickup_healthsmall_anyway;
 586 float g_pickup_healthmedium;
 587 float g_pickup_healthmedium_max;
 588 float g_pickup_healthmedium_anyway;
 589 float g_pickup_healthlarge;
 590 float g_pickup_healthlarge_max;
 591 float g_pickup_healthlarge_anyway;
 592 float g_pickup_healthmega;
 593 float g_pickup_healthmega_max;
 594 float g_pickup_healthmega_anyway;
 595 float g_pickup_ammo_anyway;
 596 float g_pickup_weapons_anyway;
 597 float g_weaponarena;
 598 WepSet g_weaponarena_weapons;
 599 float g_weaponarena_random;
 600 float g_weaponarena_random_with_laser;
 601 string g_weaponarena_list;
 602 float g_weaponspeedfactor;
 603 float g_weaponratefactor;
 604 float g_weapondamagefactor;
 605 float g_weaponforcefactor;
 606 float g_weaponspreadfactor;
 607
 608 WepSet start_weapons;
 609 WepSet start_weapons_default;
 610 WepSet start_weapons_defaultmask;
 611 float start_items;
 612 float start_ammo_shells;
 613 float start_ammo_nails;
 614 float start_ammo_rockets;
 615 float start_ammo_cells;
 616 float start_ammo_plasma;
 617 float start_ammo_fuel;
 618 float start_health;
 619 float start_armorvalue;
 620 WepSet warmup_start_weapons;
 621 WepSet warmup_start_weapons_default;
 622 WepSet warmup_start_weapons_defaultmask;
 623 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 624 float warmup_start_ammo_shells;
 625 float warmup_start_ammo_nails;
 626 float warmup_start_ammo_rockets;
 627 float warmup_start_ammo_cells;
 628 float warmup_start_ammo_plasma;
 629 float warmup_start_ammo_fuel;
 630 float warmup_start_health;
 631 float warmup_start_armorvalue;
 632 float g_weapon_stay;
 633
 634 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 635 {
 636         var float i = weaponinfo.weapon;
 637         var float d = 0;
 638
 639         if (!i)
 640                 return 0;
 641
 642         if (g_lms || g_ca || allguns)
 643         {
 644                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 645                         d = TRUE;
 646                 else
 647                         d = FALSE;
 648         }
 649         else if (g_cts)
 650                 d = (i == WEP_SHOTGUN);
 651         else if (g_nexball)
 652                 d = 0; // weapon is set a few lines later
 653         else
 654                 d = !(!weaponinfo.weaponstart);
 655
 656         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 657                 d |= (i == WEP_HOOK);
 658         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 659                 d = 0;
 660
 661         var float t = weaponinfo.weaponstartoverride;
 662
 663         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 664
 665         // bit order in t:
 666         // 1: want or not
 667         // 2: is default?
 668         // 4: is set by default?
 669         if(t < 0)
 670                 t = 4 | (3 * d);
 671         else
 672                 t |= (2 * d);
 673
 674         return t;
 675 }
 676
 677 void readplayerstartcvars()
 678 {
 679         entity e;
 680         float i, j, t;
 681         string s;
 682
 683         // initialize starting values for players
 684         start_weapons = '0 0 0';
 685         start_weapons_default = '0 0 0';
 686         start_weapons_defaultmask = '0 0 0';
 687         start_items = 0;
 688         start_ammo_shells = 0;
 689         start_ammo_nails = 0;
 690         start_ammo_rockets = 0;
 691         start_ammo_cells = 0;
 692         start_ammo_plasma = 0;
 693         start_health = cvar("g_balance_health_start");
 694         start_armorvalue = cvar("g_balance_armor_start");
 695
 696         g_weaponarena = 0;
 697         g_weaponarena_weapons = '0 0 0';
 698
 699         s = cvar_string("g_weaponarena");
 700         if (s == "0" || s == "")
 701         {
 702                 if(g_ca)
 703                         s = "most";
 704         }
 705
 706         if (s == "0" || s == "")
 707         {
 708                 // no arena
 709         }
 710         else if (s == "off")
 711         {
 712                 // forcibly turn off weaponarena
 713         }
 714         else if (s == "all")
 715         {
 716                 g_weaponarena = 1;
 717                 g_weaponarena_list = "All Weapons";
 718                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 719                 {
 720                         e = get_weaponinfo(j);
 721                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 722                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 723                 }
 724         }
 725         else if (s == "most")
 726         {
 727                 g_weaponarena = 1;
 728                 g_weaponarena_list = "Most Weapons";
 729                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 730                 {
 731                         e = get_weaponinfo(j);
 732                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 733                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 734                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 735                 }
 736         }
 737         else if (s == "none")
 738         {
 739                 g_weaponarena = 1;
 740                 g_weaponarena_list = "No Weapons";
 741         }
 742         else
 743         {
 744                 g_weaponarena = 1;
 745                 t = tokenize_console(s);
 746                 g_weaponarena_list = "";
 747                 for (i = 0; i < t; ++i)
 748                 {
 749                         s = argv(i);
 750                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 751                         {
 752                                 e = get_weaponinfo(j);
 753                                 if (e.netname == s)
 754                                 {
 755                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 756                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 757                                         break;
 758                                 }
 759                         }
 760                         if (j > WEP_LAST)
 761                         {
 762                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 763                         }
 764                 }
 765                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 766         }
 767
 768         if(g_weaponarena)
 769                 g_weaponarena_random = cvar("g_weaponarena_random");
 770         else
 771                 g_weaponarena_random = 0;
 772         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 773
 774         if (g_weaponarena)
 775         {
 776                 g_weapon_stay = 0; // incompatible
 777                 start_weapons = g_weaponarena_weapons;
 778                 start_items |= IT_UNLIMITED_AMMO;
 779         }
 780         else
 781         {
 782                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 783                 {
 784                         e = get_weaponinfo(i);
 785                         float w = want_weapon(e, FALSE);
 786                         if(w & 1)
 787                                 start_weapons |= WepSet_FromWeapon(i);
 788                         if(w & 2)
 789                                 start_weapons_default |= WepSet_FromWeapon(i);
 790                         if(w & 4)
 791                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 792                 }
 793         }
 794
 795         if(!cvar("g_use_ammunition"))
 796                 start_items |= IT_UNLIMITED_AMMO;
 797
 798         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 799         {
 800                 start_ammo_rockets = 999;
 801                 start_ammo_shells = 999;
 802                 start_ammo_cells = 999;
 803                 start_ammo_plasma = 999;
 804                 start_ammo_nails = 999;
 805                 start_ammo_fuel = 999;
 806         }
 807         else
 808         {
 809                 start_ammo_shells = cvar("g_start_ammo_shells");
 810                 start_ammo_nails = cvar("g_start_ammo_nails");
 811                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 812                 start_ammo_cells = cvar("g_start_ammo_cells");
 813                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 814                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 815         }
 816
 817         if (warmup_stage)
 818         {
 819                 warmup_start_ammo_shells = start_ammo_shells;
 820                 warmup_start_ammo_nails = start_ammo_nails;
 821                 warmup_start_ammo_rockets = start_ammo_rockets;
 822                 warmup_start_ammo_cells = start_ammo_cells;
 823                 warmup_start_ammo_fuel = start_ammo_fuel;
 824                 warmup_start_health = start_health;
 825                 warmup_start_armorvalue = start_armorvalue;
 826                 warmup_start_weapons = start_weapons;
 827                 warmup_start_weapons_default = start_weapons_default;
 828                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 829
 830                 if (!g_weaponarena && !g_ca)
 831                 {
 832                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 833                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 834                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 835                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 836                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 837                         warmup_start_health = cvar("g_warmup_start_health");
 838                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 839                         warmup_start_weapons = '0 0 0';
 840                         warmup_start_weapons_default = '0 0 0';
 841                         warmup_start_weapons_defaultmask = '0 0 0';
 842                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 843                         {
 844                                 e = get_weaponinfo(i);
 845                                 float w = want_weapon(e, g_warmup_allguns);
 846                                 if(w & 1)
 847                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 848                                 if(w & 2)
 849                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 850                                 if(w & 4)
 851                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 852                         }
 853                 }
 854         }
 855
 856         if (g_jetpack)
 857                 start_items |= IT_JETPACK;
 858
 859         MUTATOR_CALLHOOK(SetStartItems);
 860
 861         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 862         {
 863                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 864                 start_items |= IT_FUEL_REGEN;
 865                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 866                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 867         }
 868
 869         WepSet precache_weapons = start_weapons;
 870         if (g_warmup_allguns != 1)
 871                 precache_weapons |= warmup_start_weapons;
 872         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 873         {
 874                 e = get_weaponinfo(i);
 875                 if(precache_weapons & WepSet_FromWeapon(i))
 876                         WEP_ACTION(i, WR_INIT);
 877         }
 878
 879         start_ammo_shells = max(0, start_ammo_shells);
 880         start_ammo_nails = max(0, start_ammo_nails);
 881         start_ammo_cells = max(0, start_ammo_cells);
 882         start_ammo_plasma = max(0, start_ammo_plasma);
 883         start_ammo_rockets = max(0, start_ammo_rockets);
 884         start_ammo_fuel = max(0, start_ammo_fuel);
 885
 886         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 887         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 888         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 889         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 890         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 891         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 892 }
 893
 894 float g_bugrigs;
 895 float g_bugrigs_planar_movement;
 896 float g_bugrigs_planar_movement_car_jumping;
 897 float g_bugrigs_reverse_spinning;
 898 float g_bugrigs_reverse_speeding;
 899 float g_bugrigs_reverse_stopping;
 900 float g_bugrigs_air_steering;
 901 float g_bugrigs_angle_smoothing;
 902 float g_bugrigs_friction_floor;
 903 float g_bugrigs_friction_brake;
 904 float g_bugrigs_friction_air;
 905 float g_bugrigs_accel;
 906 float g_bugrigs_speed_ref;
 907 float g_bugrigs_speed_pow;
 908 float g_bugrigs_steer;
 909
 910 float sv_autotaunt;
 911 float sv_taunt;
 912
 913 string GetGametype(); // g_world.qc
 914 void readlevelcvars(void)
 915 {
 916         // load mutators
 917         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 918                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 919
 920         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 921         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
 922         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 923         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 924         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 925         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 926         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 927         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 928         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 929         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 930         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 931         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 932         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 933         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 934         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 935         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 936         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 937         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 938         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 939         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 940
 941         #undef CHECK_MUTATOR_ADD
 942
 943         if(cvar("sv_allow_fullbright"))
 944                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 945
 946     g_bugrigs = cvar("g_bugrigs");
 947     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 948     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 949     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 950     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 951     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 952     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 953     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 954     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 955     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 956     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 957     g_bugrigs_accel = cvar("g_bugrigs_accel");
 958     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 959     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 960     g_bugrigs_steer = cvar("g_bugrigs_steer");
 961
 962         g_minstagib = cvar("g_minstagib");
 963
 964         sv_clones = cvar("sv_clones");
 965         sv_foginterval = cvar("sv_foginterval");
 966         g_cloaked = cvar("g_cloaked");
 967     if(g_cts)
 968         g_cloaked = 1; // always enable cloak in CTS
 969         g_footsteps = cvar("g_footsteps");
 970         g_grappling_hook = cvar("g_grappling_hook");
 971         g_jetpack = cvar("g_jetpack");
 972         sv_maxidle = cvar("sv_maxidle");
 973         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 974         sv_autotaunt = cvar("sv_autotaunt");
 975         sv_taunt = cvar("sv_taunt");
 976
 977         warmup_stage = cvar("g_warmup");
 978         g_warmup_limit = cvar("g_warmup_limit");
 979         g_warmup_allguns = cvar("g_warmup_allguns");
 980         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 981
 982         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 983                 warmup_stage = 0; // these modes cannot work together, sorry
 984
 985         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 986         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 987         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 988         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 989         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 990         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 991         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 992         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 993         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 994         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 995         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 996         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 997         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 998         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 999
1000         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1001         g_weaponratefactor = cvar("g_weaponratefactor");
1002         g_weapondamagefactor = cvar("g_weapondamagefactor");
1003         g_weaponforcefactor = cvar("g_weaponforcefactor");
1004         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1005
1006         g_pickup_shells = cvar("g_pickup_shells");
1007         g_pickup_shells_max = cvar("g_pickup_shells_max");
1008         g_pickup_nails = cvar("g_pickup_nails");
1009         g_pickup_nails_max = cvar("g_pickup_nails_max");
1010         g_pickup_rockets = cvar("g_pickup_rockets");
1011         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1012         g_pickup_cells = cvar("g_pickup_cells");
1013         g_pickup_cells_max = cvar("g_pickup_cells_max");
1014         g_pickup_plasma = cvar("g_pickup_plasma");
1015         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
1016         g_pickup_fuel = cvar("g_pickup_fuel");
1017         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1018         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1019         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1020         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1021         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1022         g_pickup_armormedium = cvar("g_pickup_armormedium");
1023         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1024         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1025         g_pickup_armorbig = cvar("g_pickup_armorbig");
1026         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1027         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1028         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1029         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1030         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1031         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1032         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1033         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1034         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1035         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1036         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1037         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1038         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1039         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1040         g_pickup_healthmega = cvar("g_pickup_healthmega");
1041         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1042         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1043
1044         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1045         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1046
1047     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1048     if(!g_weapon_stay)
1049         g_weapon_stay = cvar("g_weapon_stay");
1050
1051         if (!warmup_stage)
1052                 game_starttime = time + cvar("g_start_delay");
1053
1054         readplayerstartcvars();
1055 }
1056
1057 //#NO AUTOCVARS END
1058
1059 // Sound functions
1060 string precache_sound (string s) = #19;
1061 float precache_sound_index (string s) = #19;
1062
1063 #define SND_VOLUME      1
1064 #define SND_ATTENUATION 2
1065 #define SND_LARGEENTITY 8
1066 #define SND_LARGESOUND  16
1067
1068 float sound_allowed(float dest, entity e)
1069 {
1070     // sounds from world may always pass
1071     for (;;)
1072     {
1073         if (e.classname == "body")
1074             e = e.enemy;
1075         else if (e.realowner && e.realowner != e)
1076             e = e.realowner;
1077         else if (e.owner && e.owner != e)
1078             e = e.owner;
1079         else
1080             break;
1081     }
1082     // sounds to self may always pass
1083     if (dest == MSG_ONE)
1084         if (e == msg_entity)
1085             return TRUE;
1086     // sounds by players can be removed
1087     if (autocvar_bot_sound_monopoly)
1088         if (IS_REAL_CLIENT(e))
1089             return FALSE;
1090     // anything else may pass
1091     return TRUE;
1092 }
1093
1094 #ifdef COMPAT_XON010_CHANNELS
1095 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1096 void sound(entity e, float chan, string samp, float vol, float atten)
1097 {
1098     if (!sound_allowed(MSG_BROADCAST, e))
1099         return;
1100     builtin_sound(e, chan, samp, vol, atten);
1101 }
1102 #else
1103 #undef sound
1104 void sound(entity e, float chan, string samp, float vol, float atten)
1105 {
1106     if (!sound_allowed(MSG_BROADCAST, e))
1107         return;
1108     sound7(e, chan, samp, vol, atten, 0, 0);
1109 }
1110 #endif
1111
1112 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1113 {
1114     float entno, idx;
1115
1116     if (!sound_allowed(dest, e))
1117         return;
1118
1119     entno = num_for_edict(e);
1120     idx = precache_sound_index(samp);
1121
1122     float sflags;
1123     sflags = 0;
1124
1125     atten = floor(atten * 64);
1126     vol = floor(vol * 255);
1127
1128     if (vol != 255)
1129         sflags |= SND_VOLUME;
1130     if (atten != 64)
1131         sflags |= SND_ATTENUATION;
1132     if (entno >= 8192 || chan < 0 || chan > 7)
1133         sflags |= SND_LARGEENTITY;
1134     if (idx >= 256)
1135         sflags |= SND_LARGESOUND;
1136
1137     WriteByte(dest, SVC_SOUND);
1138     WriteByte(dest, sflags);
1139     if (sflags & SND_VOLUME)
1140         WriteByte(dest, vol);
1141     if (sflags & SND_ATTENUATION)
1142         WriteByte(dest, atten);
1143     if (sflags & SND_LARGEENTITY)
1144     {
1145         WriteShort(dest, entno);
1146         WriteByte(dest, chan);
1147     }
1148     else
1149     {
1150         WriteShort(dest, entno * 8 + chan);
1151     }
1152     if (sflags & SND_LARGESOUND)
1153         WriteShort(dest, idx);
1154     else
1155         WriteByte(dest, idx);
1156
1157     WriteCoord(dest, o_x);
1158     WriteCoord(dest, o_y);
1159     WriteCoord(dest, o_z);
1160 }
1161 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1162 {
1163     vector o;
1164
1165     if (!sound_allowed(dest, e))
1166         return;
1167
1168     o = e.origin + 0.5 * (e.mins + e.maxs);
1169     soundtoat(dest, e, o, chan, samp, vol, atten);
1170 }
1171 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1172 {
1173     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1174 }
1175 void stopsoundto(float dest, entity e, float chan)
1176 {
1177     float entno;
1178
1179     if (!sound_allowed(dest, e))
1180         return;
1181
1182     entno = num_for_edict(e);
1183
1184     if (entno >= 8192 || chan < 0 || chan > 7)
1185     {
1186         float idx, sflags;
1187         idx = precache_sound_index("misc/null.wav");
1188         sflags = SND_LARGEENTITY;
1189         if (idx >= 256)
1190             sflags |= SND_LARGESOUND;
1191         WriteByte(dest, SVC_SOUND);
1192         WriteByte(dest, sflags);
1193         WriteShort(dest, entno);
1194         WriteByte(dest, chan);
1195         if (sflags & SND_LARGESOUND)
1196             WriteShort(dest, idx);
1197         else
1198             WriteByte(dest, idx);
1199         WriteCoord(dest, e.origin_x);
1200         WriteCoord(dest, e.origin_y);
1201         WriteCoord(dest, e.origin_z);
1202     }
1203     else
1204     {
1205         WriteByte(dest, SVC_STOPSOUND);
1206         WriteShort(dest, entno * 8 + chan);
1207     }
1208 }
1209 void stopsound(entity e, float chan)
1210 {
1211     if (!sound_allowed(MSG_BROADCAST, e))
1212         return;
1213
1214     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1215     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1216 }
1217
1218 void play2(entity e, string filename)
1219 {
1220     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1221     msg_entity = e;
1222     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1223 }
1224
1225 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1226 .float spamtime;
1227 float spamsound(entity e, float chan, string samp, float vol, float atten)
1228 {
1229     if (!sound_allowed(MSG_BROADCAST, e))
1230         return FALSE;
1231
1232     if (time > e.spamtime)
1233     {
1234         e.spamtime = time;
1235         sound(e, chan, samp, vol, atten);
1236         return TRUE;
1237     }
1238     return FALSE;
1239 }
1240
1241 void play2team(float t, string filename)
1242 {
1243     entity head;
1244
1245     if (autocvar_bot_sound_monopoly)
1246         return;
1247
1248     FOR_EACH_REALPLAYER(head)
1249     {
1250         if (head.team == t)
1251             play2(head, filename);
1252     }
1253 }
1254
1255 void play2all(string samp)
1256 {
1257     if (autocvar_bot_sound_monopoly)
1258         return;
1259
1260     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1261 }
1262
1263 void PrecachePlayerSounds(string f);
1264 void precache_playermodel(string m)
1265 {
1266         float globhandle, i, n;
1267         string f;
1268
1269         if(substring(m, -9,5) == "_lod1")
1270                 return;
1271         if(substring(m, -9,5) == "_lod2")
1272                 return;
1273         precache_model(m);
1274         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1275         if(fexists(f))
1276                 precache_model(f);
1277         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1278         if(fexists(f))
1279                 precache_model(f);
1280
1281         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1282         if (globhandle < 0)
1283                 return;
1284         n = search_getsize(globhandle);
1285         for (i = 0; i < n; ++i)
1286         {
1287                 //print(search_getfilename(globhandle, i), "\n");
1288                 f = search_getfilename(globhandle, i);
1289                 PrecachePlayerSounds(f);
1290         }
1291         search_end(globhandle);
1292 }
1293 void precache_all_playermodels(string pattern)
1294 {
1295         float globhandle, i, n;
1296         string f;
1297
1298         globhandle = search_begin(pattern, TRUE, FALSE);
1299         if (globhandle < 0)
1300                 return;
1301         n = search_getsize(globhandle);
1302         for (i = 0; i < n; ++i)
1303         {
1304                 //print(search_getfilename(globhandle, i), "\n");
1305                 f = search_getfilename(globhandle, i);
1306                 precache_playermodel(f);
1307         }
1308         search_end(globhandle);
1309 }
1310
1311 void precache()
1312 {
1313     // gamemode related things
1314     precache_model ("models/misc/chatbubble.spr");
1315
1316 #ifdef TTURRETS_ENABLED
1317     if (autocvar_g_turrets)
1318         turrets_precash();
1319 #endif
1320
1321     // Precache all player models if desired
1322     if (autocvar_sv_precacheplayermodels)
1323     {
1324         PrecachePlayerSounds("sound/player/default.sounds");
1325         precache_all_playermodels("models/player/*.zym");
1326         precache_all_playermodels("models/player/*.dpm");
1327         precache_all_playermodels("models/player/*.md3");
1328         precache_all_playermodels("models/player/*.psk");
1329         precache_all_playermodels("models/player/*.iqm");
1330     }
1331
1332     if (autocvar_sv_defaultcharacter)
1333     {
1334         string s;
1335         s = autocvar_sv_defaultplayermodel_red;
1336         if (s != "")
1337             precache_playermodel(s);
1338         s = autocvar_sv_defaultplayermodel_blue;
1339         if (s != "")
1340             precache_playermodel(s);
1341         s = autocvar_sv_defaultplayermodel_yellow;
1342         if (s != "")
1343             precache_playermodel(s);
1344         s = autocvar_sv_defaultplayermodel_pink;
1345         if (s != "")
1346             precache_playermodel(s);
1347         s = autocvar_sv_defaultplayermodel;
1348         if (s != "")
1349             precache_playermodel(s);
1350     }
1351
1352     if (g_footsteps)
1353     {
1354         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1355         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1356     }
1357
1358     // gore and miscellaneous sounds
1359     //precache_sound ("misc/h2ohit.wav");
1360     precache_model ("models/hook.md3");
1361     precache_sound ("misc/armorimpact.wav");
1362     precache_sound ("misc/bodyimpact1.wav");
1363     precache_sound ("misc/bodyimpact2.wav");
1364     precache_sound ("misc/gib.wav");
1365     precache_sound ("misc/gib_splat01.wav");
1366     precache_sound ("misc/gib_splat02.wav");
1367     precache_sound ("misc/gib_splat03.wav");
1368     precache_sound ("misc/gib_splat04.wav");
1369     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1370     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1371     precache_sound ("misc/null.wav");
1372     precache_sound ("misc/spawn.wav");
1373     precache_sound ("misc/talk.wav");
1374     precache_sound ("misc/teleport.wav");
1375     precache_sound ("misc/poweroff.wav");
1376     precache_sound ("player/lava.wav");
1377     precache_sound ("player/slime.wav");
1378
1379     precache_model ("models/sprites/0.spr32");
1380     precache_model ("models/sprites/1.spr32");
1381     precache_model ("models/sprites/2.spr32");
1382     precache_model ("models/sprites/3.spr32");
1383     precache_model ("models/sprites/4.spr32");
1384     precache_model ("models/sprites/5.spr32");
1385     precache_model ("models/sprites/6.spr32");
1386     precache_model ("models/sprites/7.spr32");
1387     precache_model ("models/sprites/8.spr32");
1388     precache_model ("models/sprites/9.spr32");
1389     precache_model ("models/sprites/10.spr32");
1390
1391     // common weapon precaches
1392         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1393     precache_sound ("weapons/weapon_switch.wav");
1394     precache_sound ("weapons/weaponpickup.wav");
1395     precache_sound ("weapons/unavailable.wav");
1396     precache_sound ("weapons/dryfire.wav");
1397     if (g_grappling_hook)
1398     {
1399         precache_sound ("weapons/hook_fire.wav"); // hook
1400         precache_sound ("weapons/hook_impact.wav"); // hook
1401     }
1402
1403     precache_model("models/elaser.mdl");
1404     precache_model("models/laser.mdl");
1405     precache_model("models/ebomb.mdl");
1406
1407 #if 0
1408     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1409
1410     if (!self.noise && self.music) // quake 3 uses the music field
1411         self.noise = self.music;
1412
1413     // plays music for the level if there is any
1414     if (self.noise)
1415     {
1416         precache_sound (self.noise);
1417         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1418     }
1419 #endif
1420
1421 #include "precache-for-csqc.inc"
1422 }
1423
1424 // WARNING: this kills the trace globals
1425 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1426 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1427
1428 #define INITPRIO_FIRST              0
1429 #define INITPRIO_GAMETYPE           0
1430 #define INITPRIO_GAMETYPE_FALLBACK  1
1431 #define INITPRIO_FINDTARGET        10
1432 #define INITPRIO_DROPTOFLOOR       20
1433 #define INITPRIO_SETLOCATION       90
1434 #define INITPRIO_LINKDOORS         91
1435 #define INITPRIO_LAST              99
1436
1437 .void(void) initialize_entity;
1438 .float initialize_entity_order;
1439 .entity initialize_entity_next;
1440 entity initialize_entity_first;
1441
1442 void make_safe_for_remove(entity e)
1443 {
1444     if (e.initialize_entity)
1445     {
1446         entity ent, prev = world;
1447         for (ent = initialize_entity_first; ent; )
1448         {
1449             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1450             {
1451                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1452                 // skip it in linked list
1453                 if (prev)
1454                 {
1455                     prev.initialize_entity_next = ent.initialize_entity_next;
1456                     ent = prev.initialize_entity_next;
1457                 }
1458                 else
1459                 {
1460                     initialize_entity_first = ent.initialize_entity_next;
1461                     ent = initialize_entity_first;
1462                 }
1463             }
1464             else
1465             {
1466                 prev = ent;
1467                 ent = ent.initialize_entity_next;
1468             }
1469         }
1470     }
1471 }
1472
1473 void objerror(string s)
1474 {
1475     make_safe_for_remove(self);
1476     builtin_objerror(s);
1477 }
1478
1479 .float remove_except_protected_forbidden;
1480 void remove_except_protected(entity e)
1481 {
1482         if(e.remove_except_protected_forbidden)
1483                 error("not allowed to remove this at this point");
1484         builtin_remove(e);
1485 }
1486
1487 void remove_unsafely(entity e)
1488 {
1489     if(e.classname == "spike")
1490         error("Removing spikes is forbidden (crylink bug), please report");
1491     builtin_remove(e);
1492 }
1493
1494 void remove_safely(entity e)
1495 {
1496     make_safe_for_remove(e);
1497     builtin_remove(e);
1498 }
1499
1500 void InitializeEntity(entity e, void(void) func, float order)
1501 {
1502     entity prev, cur;
1503
1504     if (!e || e.initialize_entity)
1505     {
1506         // make a proxy initializer entity
1507         entity e_old;
1508         e_old = e;
1509         e = spawn();
1510         e.classname = "initialize_entity";
1511         e.enemy = e_old;
1512     }
1513
1514     e.initialize_entity = func;
1515     e.initialize_entity_order = order;
1516
1517     cur = initialize_entity_first;
1518     prev = world;
1519     for (;;)
1520     {
1521         if (!cur || cur.initialize_entity_order > order)
1522         {
1523             // insert between prev and cur
1524             if (prev)
1525                 prev.initialize_entity_next = e;
1526             else
1527                 initialize_entity_first = e;
1528             e.initialize_entity_next = cur;
1529             return;
1530         }
1531         prev = cur;
1532         cur = cur.initialize_entity_next;
1533     }
1534 }
1535 void InitializeEntitiesRun()
1536 {
1537     entity startoflist;
1538     startoflist = initialize_entity_first;
1539     initialize_entity_first = world;
1540     remove = remove_except_protected;
1541     for (self = startoflist; self; self = self.initialize_entity_next)
1542     {
1543         self.remove_except_protected_forbidden = 1;
1544     }
1545     for (self = startoflist; self; )
1546     {
1547         entity e;
1548         var void(void) func;
1549         e = self.initialize_entity_next;
1550         func = self.initialize_entity;
1551         self.initialize_entity_order = 0;
1552         self.initialize_entity = func_null;
1553         self.initialize_entity_next = world;
1554         self.remove_except_protected_forbidden = 0;
1555         if (self.classname == "initialize_entity")
1556         {
1557             entity e_old;
1558             e_old = self.enemy;
1559             builtin_remove(self);
1560             self = e_old;
1561         }
1562         //dprint("Delayed initialization: ", self.classname, "\n");
1563         if(func)
1564             func();
1565         else
1566         {
1567             eprint(self);
1568             backtrace(strcat("Null function in: ", self.classname, "\n"));
1569         }
1570         self = e;
1571     }
1572     remove = remove_unsafely;
1573 }
1574
1575 .float uncustomizeentityforclient_set;
1576 .void(void) uncustomizeentityforclient;
1577 void UncustomizeEntitiesRun()
1578 {
1579     entity oldself;
1580     oldself = self;
1581     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1582         self.uncustomizeentityforclient();
1583     self = oldself;
1584 }
1585 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1586 {
1587     e.customizeentityforclient = customizer;
1588     e.uncustomizeentityforclient = uncustomizer;
1589     e.uncustomizeentityforclient_set = !!uncustomizer;
1590 }
1591
1592 .float nottargeted;
1593 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1594
1595 void() SUB_Remove;
1596 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1597 {
1598     vector mi, ma;
1599
1600     if (e.classname == "")
1601         e.classname = "net_linked";
1602
1603     if (e.model == "" || self.modelindex == 0)
1604     {
1605         mi = e.mins;
1606         ma = e.maxs;
1607         setmodel(e, "null");
1608         setsize(e, mi, ma);
1609     }
1610
1611     e.SendEntity = sendfunc;
1612     e.SendFlags = 0xFFFFFF;
1613
1614     if (!docull)
1615         e.effects |= EF_NODEPTHTEST;
1616
1617     if (dt)
1618     {
1619         e.nextthink = time + dt;
1620         e.think = SUB_Remove;
1621     }
1622 }
1623
1624 void adaptor_think2touch()
1625 {
1626     entity o;
1627     o = other;
1628     other = world;
1629     self.touch();
1630     other = o;
1631 }
1632
1633 void adaptor_think2use()
1634 {
1635     entity o, a;
1636     o = other;
1637     a = activator;
1638     activator = world;
1639     other = world;
1640     self.use();
1641     other = o;
1642     activator = a;
1643 }
1644
1645 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1646 {
1647         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1648                 self.projectiledeathtype |= HITTYPE_SPLASH;
1649         adaptor_think2use();
1650 }
1651
1652 // deferred dropping
1653 void DropToFloor_Handler()
1654 {
1655     builtin_droptofloor();
1656     self.dropped_origin = self.origin;
1657 }
1658
1659 void droptofloor()
1660 {
1661     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1662 }
1663
1664
1665
1666 float trace_hits_box_a0, trace_hits_box_a1;
1667
1668 float trace_hits_box_1d(float end, float thmi, float thma)
1669 {
1670     if (end == 0)
1671     {
1672         // just check if x is in range
1673         if (0 < thmi)
1674             return FALSE;
1675         if (0 > thma)
1676             return FALSE;
1677     }
1678     else
1679     {
1680         // do the trace with respect to x
1681         // 0 -> end has to stay in thmi -> thma
1682         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1683         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1684         if (trace_hits_box_a0 > trace_hits_box_a1)
1685             return FALSE;
1686     }
1687     return TRUE;
1688 }
1689
1690 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1691 {
1692     end -= start;
1693     thmi -= start;
1694     thma -= start;
1695     // now it is a trace from 0 to end
1696
1697     trace_hits_box_a0 = 0;
1698     trace_hits_box_a1 = 1;
1699
1700     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1701         return FALSE;
1702     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1703         return FALSE;
1704     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1705         return FALSE;
1706
1707     return TRUE;
1708 }
1709
1710 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1711 {
1712     return trace_hits_box(start, end, thmi - ma, thma - mi);
1713 }
1714
1715 float SUB_NoImpactCheck()
1716 {
1717         // zero hitcontents = this is not the real impact, but either the
1718         // mirror-impact of something hitting the projectile instead of the
1719         // projectile hitting the something, or a touchareagrid one. Neither of
1720         // these stop the projectile from moving, so...
1721         if(trace_dphitcontents == 0)
1722         {
1723                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1724                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1725                 checkclient();
1726         }
1727     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1728         return 1;
1729     if (other == world && self.size != '0 0 0')
1730     {
1731         vector tic;
1732         tic = self.velocity * sys_frametime;
1733         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1734         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1735         if (trace_fraction >= 1)
1736         {
1737             dprint("Odd... did not hit...?\n");
1738         }
1739         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1740         {
1741             dprint("Detected and prevented the sky-grapple bug.\n");
1742             return 1;
1743         }
1744     }
1745
1746     return 0;
1747 }
1748
1749 #define SUB_OwnerCheck() (other && (other == self.owner))
1750
1751 void RemoveGrapplingHook(entity pl);
1752 void W_Crylink_Dequeue(entity e);
1753 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1754 {
1755         if(SUB_OwnerCheck())
1756                 return TRUE;
1757         if(SUB_NoImpactCheck())
1758         {
1759                 if(self.classname == "grapplinghook")
1760                         RemoveGrapplingHook(self.realowner);
1761                 else if(self.classname == "spike")
1762                 {
1763                         W_Crylink_Dequeue(self);
1764                         remove(self);
1765                 }
1766                 else
1767                         remove(self);
1768                 return TRUE;
1769         }
1770         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1771                 UpdateCSQCProjectile(self);
1772         return FALSE;
1773 }
1774 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1775
1776 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1777 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1778
1779 void URI_Get_Callback(float id, float status, string data)
1780 {
1781         if(url_URI_Get_Callback(id, status, data))
1782         {
1783                 // handled
1784         }
1785         else if (id == URI_GET_DISCARD)
1786         {
1787                 // discard
1788         }
1789         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1790         {
1791                 // sv_cmd curl
1792                 Curl_URI_Get_Callback(id, status, data);
1793         }
1794         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1795         {
1796                 // online ban list
1797                 OnlineBanList_URI_Get_Callback(id, status, data);
1798         }
1799         else
1800         {
1801                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1802         }
1803 }
1804
1805 string uid2name(string myuid) {
1806         string s;
1807         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1808
1809         // FIXME remove this later after 0.6 release
1810         // convert old style broken records to correct style
1811         if(s == "")
1812         {
1813                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1814                 if(s != "")
1815                 {
1816                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1817                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1818                 }
1819         }
1820
1821         if(s == "")
1822                 s = "^1Unregistered Player";
1823         return s;
1824 }
1825
1826 float race_readTime(string map, float pos)
1827 {
1828         string rr;
1829         if(g_cts)
1830                 rr = CTS_RECORD;
1831         else
1832                 rr = RACE_RECORD;
1833
1834         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1835 }
1836
1837 string race_readUID(string map, float pos)
1838 {
1839         string rr;
1840         if(g_cts)
1841                 rr = CTS_RECORD;
1842         else
1843                 rr = RACE_RECORD;
1844
1845         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1846 }
1847
1848 float race_readPos(string map, float t) {
1849         float i;
1850         for (i = 1; i <= RANKINGS_CNT; ++i)
1851                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1852                         return i;
1853
1854         return 0; // pos is zero if unranked
1855 }
1856
1857 void race_writeTime(string map, float t, string myuid)
1858 {
1859         string rr;
1860         if(g_cts)
1861                 rr = CTS_RECORD;
1862         else
1863                 rr = RACE_RECORD;
1864
1865         float newpos;
1866         newpos = race_readPos(map, t);
1867
1868         float i, prevpos = 0;
1869         for(i = 1; i <= RANKINGS_CNT; ++i)
1870         {
1871                 if(race_readUID(map, i) == myuid)
1872                         prevpos = i;
1873         }
1874         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1875                 for (i = prevpos; i > newpos; --i) {
1876                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1877                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1878                 }
1879         } else { // player has no ranked record yet
1880                 for (i = RANKINGS_CNT; i > newpos; --i) {
1881                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1882                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1883                 }
1884         }
1885
1886         // store new time itself
1887         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1888         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1889 }
1890
1891 string race_readName(string map, float pos)
1892 {
1893         string rr;
1894         if(g_cts)
1895                 rr = CTS_RECORD;
1896         else
1897                 rr = RACE_RECORD;
1898
1899         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1900 }
1901
1902 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1903 {
1904     float m, i;
1905     vector start, org, delta, end, enddown, mstart;
1906     entity sp;
1907
1908     m = e.dphitcontentsmask;
1909     e.dphitcontentsmask = goodcontents | badcontents;
1910
1911     org = world.mins;
1912     delta = world.maxs - world.mins;
1913
1914     start = end = org;
1915
1916     for (i = 0; i < attempts; ++i)
1917     {
1918         start_x = org_x + random() * delta_x;
1919         start_y = org_y + random() * delta_y;
1920         start_z = org_z + random() * delta_z;
1921
1922         // rule 1: start inside world bounds, and outside
1923         // solid, and don't start from somewhere where you can
1924         // fall down to evil
1925         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1926         if (trace_fraction >= 1)
1927             continue;
1928         if (trace_startsolid)
1929             continue;
1930         if (trace_dphitcontents & badcontents)
1931             continue;
1932         if (trace_dphitq3surfaceflags & badsurfaceflags)
1933             continue;
1934
1935         // rule 2: if we are too high, lower the point
1936         if (trace_fraction * delta_z > maxaboveground)
1937             start = trace_endpos + '0 0 1' * maxaboveground;
1938         enddown = trace_endpos;
1939
1940         // rule 3: make sure we aren't outside the map. This only works
1941         // for somewhat well formed maps. A good rule of thumb is that
1942         // the map should have a convex outside hull.
1943         // these can be traceLINES as we already verified the starting box
1944         mstart = start + 0.5 * (e.mins + e.maxs);
1945         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1946         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1947             continue;
1948         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1949         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1950             continue;
1951         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1952         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1953             continue;
1954         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1955         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1956             continue;
1957         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1958         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1959             continue;
1960
1961         // rule 4: we must "see" some spawnpoint or item
1962         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1963                 if(checkpvs(mstart, sp))
1964                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1965                                 break;
1966         if(!sp)
1967         {
1968                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1969                         if(checkpvs(mstart, sp))
1970                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1971                                         break;
1972                 if(!sp)
1973                         continue;
1974         }
1975
1976         // find a random vector to "look at"
1977         end_x = org_x + random() * delta_x;
1978         end_y = org_y + random() * delta_y;
1979         end_z = org_z + random() * delta_z;
1980         end = start + normalize(end - start) * vlen(delta);
1981
1982         // rule 4: start TO end must not be too short
1983         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1984         if (trace_startsolid)
1985             continue;
1986         if (trace_fraction < minviewdistance / vlen(delta))
1987             continue;
1988
1989         // rule 5: don't want to look at sky
1990         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1991             continue;
1992
1993         // rule 6: we must not end up in trigger_hurt
1994         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1995             continue;
1996
1997         break;
1998     }
1999
2000     e.dphitcontentsmask = m;
2001
2002     if (i < attempts)
2003     {
2004         setorigin(e, start);
2005         e.angles = vectoangles(end - start);
2006         dprint("Needed ", ftos(i + 1), " attempts\n");
2007         return TRUE;
2008     }
2009     else
2010         return FALSE;
2011 }
2012
2013 void write_recordmarker(entity pl, float tstart, float dt)
2014 {
2015     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2016
2017     // also write a marker into demo files for demotc-race-record-extractor to find
2018     stuffcmd(pl,
2019              strcat(
2020                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2021                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2022 }
2023
2024 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2025 {
2026         switch(algn)
2027         {
2028                 default:
2029                 case 3: // right
2030                         break;
2031
2032                 case 4: // left
2033                         vecs_y = -vecs_y;
2034                         break;
2035
2036                 case 1:
2037                         if(allowcenter) // 2: allow center handedness
2038                         {
2039                                 // center
2040                                 vecs_y = 0;
2041                                 vecs_z -= 2;
2042                         }
2043                         else
2044                         {
2045                                 // right
2046                         }
2047                         break;
2048
2049                 case 2:
2050                         if(allowcenter) // 2: allow center handedness
2051                         {
2052                                 // center
2053                                 vecs_y = 0;
2054                                 vecs_z -= 2;
2055                         }
2056                         else
2057                         {
2058                                 // left
2059                                 vecs_y = -vecs_y;
2060                         }
2061                         break;
2062         }
2063         return vecs;
2064 }
2065
2066 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2067 {
2068         string s;
2069         vector v;
2070
2071         if (autocvar_g_shootfromeye)
2072         {
2073                 if (visual)
2074                 {
2075                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2076                         else { vecs_y = 0; vecs_z -= 2; }
2077                 }
2078                 else
2079                 {
2080                         vecs_y = 0;
2081                         vecs_z = 0;
2082                 }
2083         }
2084         else if (autocvar_g_shootfromcenter)
2085         {
2086                 vecs_y = 0;
2087                 vecs_z -= 2;
2088         }
2089         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2090         {
2091                 v = stov(s);
2092                 if (y_is_right)
2093                         v_y = -v_y;
2094                 if (v_x != 0)
2095                         vecs_x = v_x;
2096                 vecs_y = v_y;
2097                 vecs_z = v_z;
2098         }
2099         else if (autocvar_g_shootfromclient)
2100         {
2101                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2102         }
2103         return vecs;
2104 }
2105
2106 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2107 {
2108         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2109 }
2110
2111
2112 void attach_sameorigin(entity e, entity to, string tag)
2113 {
2114     vector org, t_forward, t_left, t_up, e_forward, e_up;
2115     float tagscale;
2116
2117     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2118     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2119     t_forward = v_forward * tagscale;
2120     t_left = v_right * -tagscale;
2121     t_up = v_up * tagscale;
2122
2123     e.origin_x = org * t_forward;
2124     e.origin_y = org * t_left;
2125     e.origin_z = org * t_up;
2126
2127     // current forward and up directions
2128     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2129                 e.angles = AnglesTransform_FromVAngles(e.angles);
2130         else
2131                 e.angles = AnglesTransform_FromAngles(e.angles);
2132     fixedmakevectors(e.angles);
2133
2134     // untransform forward, up!
2135     e_forward_x = v_forward * t_forward;
2136     e_forward_y = v_forward * t_left;
2137     e_forward_z = v_forward * t_up;
2138     e_up_x = v_up * t_forward;
2139     e_up_y = v_up * t_left;
2140     e_up_z = v_up * t_up;
2141
2142     e.angles = fixedvectoangles2(e_forward, e_up);
2143     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2144                 e.angles = AnglesTransform_ToVAngles(e.angles);
2145         else
2146                 e.angles = AnglesTransform_ToAngles(e.angles);
2147
2148     setattachment(e, to, tag);
2149     setorigin(e, e.origin);
2150 }
2151
2152 void detach_sameorigin(entity e)
2153 {
2154     vector org;
2155     org = gettaginfo(e, 0);
2156     e.angles = fixedvectoangles2(v_forward, v_up);
2157     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2158                 e.angles = AnglesTransform_ToVAngles(e.angles);
2159         else
2160                 e.angles = AnglesTransform_ToAngles(e.angles);
2161     setorigin(e, org);
2162     setattachment(e, world, "");
2163     setorigin(e, e.origin);
2164 }
2165
2166 void follow_sameorigin(entity e, entity to)
2167 {
2168     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2169     e.aiment = to; // make the hole follow bmodel
2170     e.punchangle = to.angles; // the original angles of bmodel
2171     e.view_ofs = e.origin - to.origin; // relative origin
2172     e.v_angle = e.angles - to.angles; // relative angles
2173 }
2174
2175 void unfollow_sameorigin(entity e)
2176 {
2177     e.movetype = MOVETYPE_NONE;
2178 }
2179
2180 entity gettaginfo_relative_ent;
2181 vector gettaginfo_relative(entity e, float tag)
2182 {
2183     if (!gettaginfo_relative_ent)
2184     {
2185         gettaginfo_relative_ent = spawn();
2186         gettaginfo_relative_ent.effects = EF_NODRAW;
2187     }
2188     gettaginfo_relative_ent.model = e.model;
2189     gettaginfo_relative_ent.modelindex = e.modelindex;
2190     gettaginfo_relative_ent.frame = e.frame;
2191     return gettaginfo(gettaginfo_relative_ent, tag);
2192 }
2193
2194 .float scale2;
2195
2196 float modeleffect_SendEntity(entity to, float sf)
2197 {
2198         float f;
2199         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2200
2201         f = 0;
2202         if(self.velocity != '0 0 0')
2203                 f |= 1;
2204         if(self.angles != '0 0 0')
2205                 f |= 2;
2206         if(self.avelocity != '0 0 0')
2207                 f |= 4;
2208
2209         WriteByte(MSG_ENTITY, f);
2210         WriteShort(MSG_ENTITY, self.modelindex);
2211         WriteByte(MSG_ENTITY, self.skin);
2212         WriteByte(MSG_ENTITY, self.frame);
2213         WriteCoord(MSG_ENTITY, self.origin_x);
2214         WriteCoord(MSG_ENTITY, self.origin_y);
2215         WriteCoord(MSG_ENTITY, self.origin_z);
2216         if(f & 1)
2217         {
2218                 WriteCoord(MSG_ENTITY, self.velocity_x);
2219                 WriteCoord(MSG_ENTITY, self.velocity_y);
2220                 WriteCoord(MSG_ENTITY, self.velocity_z);
2221         }
2222         if(f & 2)
2223         {
2224                 WriteCoord(MSG_ENTITY, self.angles_x);
2225                 WriteCoord(MSG_ENTITY, self.angles_y);
2226                 WriteCoord(MSG_ENTITY, self.angles_z);
2227         }
2228         if(f & 4)
2229         {
2230                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2231                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2232                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2233         }
2234         WriteShort(MSG_ENTITY, self.scale * 256.0);
2235         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2236         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2237         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2238         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2239
2240         return TRUE;
2241 }
2242
2243 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2244 {
2245         entity e;
2246         float sz;
2247         e = spawn();
2248         e.classname = "modeleffect";
2249         setmodel(e, m);
2250         e.frame = f;
2251         setorigin(e, o);
2252         e.velocity = v;
2253         e.angles = ang;
2254         e.avelocity = angv;
2255         e.alpha = a;
2256         e.teleport_time = t1;
2257         e.fade_time = t2;
2258         e.skin = s;
2259         if(s0 >= 0)
2260                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2261         else
2262                 e.scale = -s0;
2263         if(s2 >= 0)
2264                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2265         else
2266                 e.scale2 = -s2;
2267         sz = max(e.scale, e.scale2);
2268         setsize(e, e.mins * sz, e.maxs * sz);
2269         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2270 }
2271
2272 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2273 {
2274         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2275 }
2276
2277 float randombit(float bits)
2278 {
2279         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2280                 return bits;
2281
2282         float n, f, b, r;
2283
2284         r = random();
2285         b = 0;
2286         n = 0;
2287
2288         for(f = 1; f <= bits; f *= 2)
2289         {
2290                 if(bits & f)
2291                 {
2292                         ++n;
2293                         r *= n;
2294                         if(r <= 1)
2295                                 b = f;
2296                         else
2297                                 r = (r - 1) / (n - 1);
2298                 }
2299         }
2300
2301         return b;
2302 }
2303
2304 float randombits(float bits, float k, float error_return)
2305 {
2306         float r;
2307         r = 0;
2308         while(k > 0 && bits != r)
2309         {
2310                 r += randombit(bits - r);
2311                 --k;
2312         }
2313         if(error_return)
2314                 if(k > 0)
2315                         return -1; // all
2316         return r;
2317 }
2318
2319 void randombit_test(float bits, float iter)
2320 {
2321         while(iter > 0)
2322         {
2323                 print(ftos(randombit(bits)), "\n");
2324                 --iter;
2325         }
2326 }
2327
2328 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2329 {
2330         if(halflifedist > 0)
2331                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2332         else if(halflifedist < 0)
2333                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2334         else
2335                 return 1;
2336 }
2337
2338
2339
2340
2341 #ifdef RELEASE
2342 #define cvar_string_normal builtin_cvar_string
2343 #define cvar_normal builtin_cvar
2344 #else
2345 string cvar_string_normal(string n)
2346 {
2347         if (!(cvar_type(n) & 1))
2348                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2349         return builtin_cvar_string(n);
2350 }
2351
2352 float cvar_normal(string n)
2353 {
2354         return stof(cvar_string_normal(n));
2355 }
2356 #endif
2357 #define cvar_set_normal builtin_cvar_set
2358
2359 void defer_think()
2360 {
2361     entity oself;
2362
2363     oself           = self;
2364     self            = self.owner;
2365     oself.think     = SUB_Remove;
2366     oself.nextthink = time;
2367
2368     oself.use();
2369 }
2370
2371 /*
2372     Execute func() after time + fdelay.
2373     self when func is executed = self when defer is called
2374 */
2375 void defer(float fdelay, void() func)
2376 {
2377     entity e;
2378
2379     e           = spawn();
2380     e.owner     = self;
2381     e.use       = func;
2382     e.think     = defer_think;
2383     e.nextthink = time + fdelay;
2384 }
2385
2386 .string aiment_classname;
2387 .float aiment_deadflag;
2388 void SetMovetypeFollow(entity ent, entity e)
2389 {
2390         // FIXME this may not be warpzone aware
2391         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2392         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2393         ent.aiment = e; // make the hole follow bmodel
2394         ent.punchangle = e.angles; // the original angles of bmodel
2395         ent.view_ofs = ent.origin - e.origin; // relative origin
2396         ent.v_angle = ent.angles - e.angles; // relative angles
2397         ent.aiment_classname = strzone(e.classname);
2398         ent.aiment_deadflag = e.deadflag;
2399 }
2400 void UnsetMovetypeFollow(entity ent)
2401 {
2402         ent.movetype = MOVETYPE_FLY;
2403         PROJECTILE_MAKETRIGGER(ent);
2404         ent.aiment = world;
2405 }
2406 float LostMovetypeFollow(entity ent)
2407 {
2408 /*
2409         if(ent.movetype != MOVETYPE_FOLLOW)
2410                 if(ent.aiment)
2411                         error("???");
2412 */
2413         if(ent.aiment)
2414         {
2415                 if(ent.aiment.classname != ent.aiment_classname)
2416                         return 1;
2417                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2418                         return 1;
2419         }
2420         return 0;
2421 }
2422
2423 float isPushable(entity e)
2424 {
2425         if(e.iscreature)
2426                 return TRUE;
2427         if(e.pushable)
2428                 return TRUE;
2429         switch(e.classname)
2430         {
2431                 case "body":
2432                 case "droppedweapon":
2433                 case "keepawayball":
2434                 case "nexball_basketball":
2435                 case "nexball_football":
2436                         return TRUE;
2437                 case "bullet": // antilagged bullets can't hit this either
2438                         return FALSE;
2439         }
2440         if (e.projectiledeathtype)
2441                 return TRUE;
2442         return FALSE;
2443 }