qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f > 0)
 433                 s = strcat1(argv(f));
 434
 435         get_cvars_f = f;
 436         get_cvars_s = s;
 437         MUTATOR_CALLHOOK(GetCvars);
 438
 439         Notification_GetCvars(this);
 440
 441         ReplicateVars(this, store, s, f);
 442
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 454
 455         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 456
 457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 458         if (f > 0)
 459         {
 460                 if (s == "cl_weaponpriority")
 461                 {
 462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 463                         {
 464                                 .entity weaponentity = weaponentities[slot];
 465                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 466                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 467                         }
 468                 }
 469                 if (s == "cl_allow_uidtracking")
 470                         PlayerStats_GameReport_AddPlayer(this);
 471         }
 472 }
 473
 474 // decolorizes and team colors the player name when needed
 475 string playername(entity p, bool team_colorize)
 476 {
 477     string t;
 478     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 479     {
 480         t = Team_ColorCode(p.team);
 481         return strcat(t, strdecolorize(p.netname));
 482     }
 483     else
 484         return p.netname;
 485 }
 486
 487 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 488 {
 489         int i = weaponinfo.m_id;
 490         int d = 0;
 491         bool allow_mutatorblocked = false;
 492
 493         if(!i)
 494                 return 0;
 495
 496         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 497         d = M_ARGV(1, float);
 498         allguns = M_ARGV(2, bool);
 499         allow_mutatorblocked = M_ARGV(3, bool);
 500
 501         if(allguns)
 502                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & WEP_FLAG_HIDDEN));
 503         else if(!mutator_returnvalue)
 504                 d = !(!weaponinfo.weaponstart);
 505
 506         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 507                 d = 0;
 508
 509         float t = weaponinfo.weaponstartoverride;
 510
 511         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 512
 513         // bit order in t:
 514         // 1: want or not
 515         // 2: is default?
 516         // 4: is set by default?
 517         if(t < 0)
 518                 t = 4 | (3 * d);
 519         else
 520                 t |= (2 * d);
 521
 522         return t;
 523 }
 524
 525 /// Weapons the player normally starts with outside weapon arena.
 526 WepSet weapons_start()
 527 {
 528         WepSet ret = '0 0 0';
 529         FOREACH(Weapons, it != WEP_Null, {
 530                 int w = want_weapon(it, false); // TODO too complicated? see my MR, test CTS/courtfun - ballstealer
 531                 if(w & 1)
 532                         ret |= it.m_wepset;
 533         });
 534         return ret;
 535 }
 536
 537 WepSet weapons_all()
 538 {
 539         WepSet ret = '0 0 0';
 540         FOREACH(Weapons, it != WEP_Null, {
 541                 if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 542                         ret |= it.m_wepset;
 543         });
 544         return ret;
 545 }
 546
 547 WepSet weapons_devall()
 548 {
 549         WepSet ret = '0 0 0';
 550         FOREACH(Weapons, it != WEP_Null,
 551         {
 552                 ret |= it.m_wepset;
 553         });
 554         return ret;
 555 }
 556
 557 WepSet weapons_most()
 558 {
 559         WepSet ret = '0 0 0';
 560         FOREACH(Weapons, it != WEP_Null, {
 561                 if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && (it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & WEP_FLAG_HIDDEN))
 562                         ret |= it.m_wepset;
 563         });
 564         return ret;
 565 }
 566
 567 void weaponarena_available_all_update(entity this)
 568 {
 569         LOG_INFOF("weaponarena_available_all_update %v\n", weaponsInMapAll);
 570
 571         if (weaponsInMapAll)
 572         {
 573                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 574         }
 575         else
 576         {
 577                 // if no weapons are available on the map, just fall back to all weapons arena
 578                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 579         }
 580 }
 581
 582 void weaponarena_available_devall_update(entity this)
 583 {
 584         LOG_INFOF("weaponarena_available_devall_update %v\n", weaponsInMapAll);
 585
 586         if (weaponsInMapAll)
 587         {
 588                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 589         }
 590         else
 591         {
 592                 // if no weapons are available on the map, just fall back to devall weapons arena
 593                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 594         }
 595 }
 596
 597 void weaponarena_available_most_update(entity this) // TODO cleanup
 598 {
 599         LOG_INFOF("weaponarena_available_most_update %v\n", weaponsInMapAll);
 600
 601         if (weaponsInMapAll)
 602         {
 603                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 604         }
 605         else
 606         {
 607                 // if no weapons are available on the map, just fall back to most weapons arena
 608                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 609         }
 610 }
 611
 612 void readplayerstartcvars()
 613 {
 614         LOG_INFOF("readplayerstartcvars\n");
 615         float i, t;
 616
 617         // initialize starting values for players
 618         start_weapons = '0 0 0';
 619         start_weapons_default = '0 0 0';
 620         start_weapons_defaultmask = '0 0 0';
 621         start_items = 0;
 622         start_ammo_shells = 0;
 623         start_ammo_nails = 0;
 624         start_ammo_rockets = 0;
 625         start_ammo_cells = 0;
 626         start_ammo_plasma = 0;
 627         if (random_start_ammo == NULL)
 628         {
 629                 random_start_ammo = spawn();
 630         }
 631         start_health = cvar("g_balance_health_start");
 632         start_armorvalue = cvar("g_balance_armor_start");
 633
 634         g_weaponarena = 0;
 635         g_weaponarena_weapons = '0 0 0';
 636
 637         string s = cvar_string("g_weaponarena");
 638
 639         MUTATOR_CALLHOOK(SetWeaponArena, s);
 640         s = M_ARGV(0, string);
 641         LOG_INFOF("arena: %s", s);
 642
 643         if (s == "0" || s == "")
 644         {
 645                 // no arena
 646         }
 647         else if (s == "off") // TODO remove? CA and others don't respect this
 648         {
 649                 // forcibly turn off weaponarena
 650         }
 651         else if (s == "all" || s == "1")
 652         {
 653                 g_weaponarena = 1;
 654                 g_weaponarena_list = "All Weapons";
 655                 g_weaponarena_weapons = weapons_all();
 656         }
 657         else if (s == "devall")
 658         {
 659                 g_weaponarena = 1;
 660                 g_weaponarena_list = "Dev All Weapons";
 661                 g_weaponarena_weapons = weapons_devall();
 662         }
 663         else if (s == "most")
 664         {
 665                 g_weaponarena = 1;
 666                 g_weaponarena_list = "Most Weapons";
 667                 g_weaponarena_weapons = weapons_most();
 668         }
 669         else if (s == "all_available")
 670         {
 671                 g_weaponarena = 1;
 672                 g_weaponarena_list = "All Available Weapons";
 673
 674                 // this needs to run after weaponsInMapAll is initialized
 675                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 676         }
 677         else if (s == "devall_available")
 678         {
 679                 g_weaponarena = 1;
 680                 g_weaponarena_list = "Dev All Available Weapons";
 681
 682                 // this needs to run after weaponsInMapAll is initialized
 683                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 684         }
 685         else if (s == "most_available")
 686         {
 687                 g_weaponarena = 1;
 688                 g_weaponarena_list = "Most Available Weapons";
 689
 690                 // this needs to run after weaponsInMapAll is initialized
 691                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 692         }
 693         else if (s == "none")
 694         {
 695                 g_weaponarena = 1;
 696                 g_weaponarena_list = "No Weapons";
 697         }
 698         else
 699         {
 700                 g_weaponarena = 1;
 701                 t = tokenize_console(s);
 702                 g_weaponarena_list = "";
 703                 for (i = 0; i < t; ++i)
 704                 {
 705                         s = argv(i);
 706                         Weapon wep = Weapons_fromstr(s);
 707                         if(wep != WEP_Null)
 708                         {
 709                                 g_weaponarena_weapons |= (wep.m_wepset);
 710                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 711                         }
 712                 }
 713                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 714         }
 715
 716         if (g_weaponarena)
 717         {
 718                 g_weapon_stay = 0; // incompatible
 719                 start_weapons = g_weaponarena_weapons;
 720                 start_items |= IT_UNLIMITED_AMMO;
 721         }
 722         else
 723         {
 724                 FOREACH(Weapons, it != WEP_Null, {
 725                         int w = want_weapon(it, false);
 726                         WepSet s = it.m_wepset;
 727                         if(w & 1)
 728                                 start_weapons |= s;
 729                         if(w & 2)
 730                                 start_weapons_default |= s;
 731                         if(w & 4)
 732                                 start_weapons_defaultmask |= s;
 733                 });
 734         }
 735
 736         if(cvar("g_balance_superweapons_time") < 0)
 737                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 738
 739         if(!cvar("g_use_ammunition"))
 740                 start_items |= IT_UNLIMITED_AMMO;
 741
 742         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 743         {
 744                 start_ammo_shells = 999;
 745                 start_ammo_nails = 999;
 746                 start_ammo_rockets = 999;
 747                 start_ammo_cells = 999;
 748                 start_ammo_plasma = 999;
 749                 start_ammo_fuel = 999;
 750         }
 751         else
 752         {
 753                 start_ammo_shells = cvar("g_start_ammo_shells");
 754                 start_ammo_nails = cvar("g_start_ammo_nails");
 755                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 756                 start_ammo_cells = cvar("g_start_ammo_cells");
 757                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 758                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 759                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 760                 SetResource(random_start_ammo, RES_SHELLS, cvar(
 761                         "g_random_start_shells"));
 762                 SetResource(random_start_ammo, RES_BULLETS, cvar(
 763                         "g_random_start_bullets"));
 764                 SetResource(random_start_ammo, RES_ROCKETS,
 765                         cvar("g_random_start_rockets"));
 766                 SetResource(random_start_ammo, RES_CELLS, cvar(
 767                         "g_random_start_cells"));
 768                 SetResource(random_start_ammo, RES_PLASMA, cvar(
 769                         "g_random_start_plasma"));
 770         }
 771
 772         if (warmup_stage && !g_ca && !g_freezetag) // TODO remove?
 773         {
 774                 warmup_start_ammo_shells = start_ammo_shells;
 775                 warmup_start_ammo_nails = start_ammo_nails;
 776                 warmup_start_ammo_rockets = start_ammo_rockets;
 777                 warmup_start_ammo_cells = start_ammo_cells;
 778                 warmup_start_ammo_plasma = start_ammo_plasma;
 779                 warmup_start_ammo_fuel = start_ammo_fuel;
 780                 warmup_start_health = start_health;
 781                 warmup_start_armorvalue = start_armorvalue;
 782                 warmup_start_weapons = start_weapons;
 783                 warmup_start_weapons_default = start_weapons_default;
 784                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 785
 786                 if (!g_weaponarena)
 787                 {
 788                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 789                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 790                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 791                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 792                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 793                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 794                         warmup_start_health = cvar("g_warmup_start_health");
 795                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 796                         warmup_start_weapons = '0 0 0';
 797                         warmup_start_weapons_default = '0 0 0';
 798                         warmup_start_weapons_defaultmask = '0 0 0';
 799                         FOREACH(Weapons, it != WEP_Null, {
 800                                 int w = want_weapon(it, g_warmup_allguns);
 801                                 WepSet s = (it.m_wepset);
 802                                 if(w & 1)
 803                                         warmup_start_weapons |= s;
 804                                 if(w & 2)
 805                                         warmup_start_weapons_default |= s;
 806                                 if(w & 4)
 807                                         warmup_start_weapons_defaultmask |= s;
 808                         });
 809                 }
 810         }
 811
 812         if (g_jetpack)
 813                 start_items |= ITEM_Jetpack.m_itemid;
 814
 815         MUTATOR_CALLHOOK(SetStartItems);
 816
 817         if (start_items & ITEM_Jetpack.m_itemid)
 818         {
 819                 start_items |= ITEM_JetpackRegen.m_itemid;
 820                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 821                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 822         }
 823
 824         start_ammo_shells = max(0, start_ammo_shells);
 825         start_ammo_nails = max(0, start_ammo_nails);
 826         start_ammo_rockets = max(0, start_ammo_rockets);
 827         start_ammo_cells = max(0, start_ammo_cells);
 828         start_ammo_plasma = max(0, start_ammo_plasma);
 829         start_ammo_fuel = max(0, start_ammo_fuel);
 830         SetResource(random_start_ammo, RES_SHELLS, max(0,
 831                 GetResource(random_start_ammo, RES_SHELLS)));
 832         SetResource(random_start_ammo, RES_BULLETS, max(0,
 833                 GetResource(random_start_ammo, RES_BULLETS)));
 834         SetResource(random_start_ammo, RES_ROCKETS, max(0,
 835                 GetResource(random_start_ammo, RES_ROCKETS)));
 836         SetResource(random_start_ammo, RES_CELLS, max(0,
 837                 GetResource(random_start_ammo, RES_CELLS)));
 838         SetResource(random_start_ammo, RES_PLASMA, max(0,
 839                 GetResource(random_start_ammo, RES_PLASMA)));
 840
 841         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 842         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 843         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 844         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 845         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 846         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 847 }
 848
 849 void precache_playermodel(string m)
 850 {
 851         float globhandle, i, n;
 852         string f;
 853
 854         if(substring(m, -9, 5) == "_lod1")
 855                 return;
 856         if(substring(m, -9, 5) == "_lod2")
 857                 return;
 858         precache_model(m);
 859         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 860         if(fexists(f))
 861                 precache_model(f);
 862         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 863         if(fexists(f))
 864                 precache_model(f);
 865
 866         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 867         if (globhandle < 0)
 868                 return;
 869         n = search_getsize(globhandle);
 870         for (i = 0; i < n; ++i)
 871         {
 872                 //print(search_getfilename(globhandle, i), "\n");
 873                 f = search_getfilename(globhandle, i);
 874                 PrecachePlayerSounds(f);
 875         }
 876         search_end(globhandle);
 877 }
 878 void precache_all_playermodels(string pattern)
 879 {
 880         int globhandle = search_begin(pattern, true, false);
 881         if (globhandle < 0) return;
 882         int n = search_getsize(globhandle);
 883         for (int i = 0; i < n; ++i)
 884         {
 885                 string s = search_getfilename(globhandle, i);
 886                 precache_playermodel(s);
 887         }
 888         search_end(globhandle);
 889 }
 890
 891 void precache_playermodels(string s)
 892 {
 893         FOREACH_WORD(s, true, { precache_playermodel(it); });
 894 }
 895
 896 void precache()
 897 {
 898     // gamemode related things
 899
 900     // Precache all player models if desired
 901     if (autocvar_sv_precacheplayermodels)
 902     {
 903         PrecachePlayerSounds("sound/player/default.sounds");
 904         precache_all_playermodels("models/player/*.zym");
 905         precache_all_playermodels("models/player/*.dpm");
 906         precache_all_playermodels("models/player/*.md3");
 907         precache_all_playermodels("models/player/*.psk");
 908         precache_all_playermodels("models/player/*.iqm");
 909     }
 910
 911     if (autocvar_sv_defaultcharacter)
 912     {
 913                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 914                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 915                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 916                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 917                 precache_playermodels(autocvar_sv_defaultplayermodel);
 918     }
 919
 920 #if 0
 921     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 922
 923     if (!this.noise && this.music) // quake 3 uses the music field
 924         this.noise = this.music;
 925
 926     // plays music for the level if there is any
 927     if (this.noise)
 928     {
 929         precache_sound (this.noise);
 930         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 931     }
 932 #endif
 933 }
 934
 935
 936 void make_safe_for_remove(entity e)
 937 {
 938     if (e.initialize_entity)
 939     {
 940         entity ent, prev = NULL;
 941         for (ent = initialize_entity_first; ent; )
 942         {
 943             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 944             {
 945                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 946                 // skip it in linked list
 947                 if (prev)
 948                 {
 949                     prev.initialize_entity_next = ent.initialize_entity_next;
 950                     ent = prev.initialize_entity_next;
 951                 }
 952                 else
 953                 {
 954                     initialize_entity_first = ent.initialize_entity_next;
 955                     ent = initialize_entity_first;
 956                 }
 957             }
 958             else
 959             {
 960                 prev = ent;
 961                 ent = ent.initialize_entity_next;
 962             }
 963         }
 964     }
 965 }
 966
 967 .float remove_except_protected_forbidden;
 968 void remove_except_protected(entity e)
 969 {
 970         if(e.remove_except_protected_forbidden)
 971                 error("not allowed to remove this at this point");
 972         builtin_remove(e);
 973 }
 974
 975 void remove_unsafely(entity e)
 976 {
 977     if(e.classname == "spike")
 978         error("Removing spikes is forbidden (crylink bug), please report");
 979     builtin_remove(e);
 980 }
 981
 982 void remove_safely(entity e)
 983 {
 984     make_safe_for_remove(e);
 985     builtin_remove(e);
 986 }
 987
 988 void InitializeEntity(entity e, void(entity this) func, int order)
 989 {
 990     entity prev, cur;
 991
 992     if (!e || e.initialize_entity)
 993     {
 994         // make a proxy initializer entity
 995         entity e_old = e;
 996         e = new(initialize_entity);
 997         e.enemy = e_old;
 998     }
 999
1000     e.initialize_entity = func;
1001     e.initialize_entity_order = order;
1002
1003     cur = initialize_entity_first;
1004     prev = NULL;
1005     for (;;)
1006     {
1007         if (!cur || cur.initialize_entity_order > order)
1008         {
1009             // insert between prev and cur
1010             if (prev)
1011                 prev.initialize_entity_next = e;
1012             else
1013                 initialize_entity_first = e;
1014             e.initialize_entity_next = cur;
1015             return;
1016         }
1017         prev = cur;
1018         cur = cur.initialize_entity_next;
1019     }
1020 }
1021 void InitializeEntitiesRun()
1022 {
1023     entity startoflist = initialize_entity_first;
1024     initialize_entity_first = NULL;
1025     delete_fn = remove_except_protected;
1026     for (entity e = startoflist; e; e = e.initialize_entity_next)
1027     {
1028                 e.remove_except_protected_forbidden = 1;
1029     }
1030     for (entity e = startoflist; e; )
1031     {
1032                 e.remove_except_protected_forbidden = 0;
1033         e.initialize_entity_order = 0;
1034         entity next = e.initialize_entity_next;
1035         e.initialize_entity_next = NULL;
1036         var void(entity this) func = e.initialize_entity;
1037         e.initialize_entity = func_null;
1038         if (e.classname == "initialize_entity")
1039         {
1040             entity wrappee = e.enemy;
1041             builtin_remove(e);
1042             e = wrappee;
1043         }
1044         //dprint("Delayed initialization: ", e.classname, "\n");
1045         if (func)
1046         {
1047                 func(e);
1048         }
1049         else
1050         {
1051             eprint(e);
1052             backtrace(strcat("Null function in: ", e.classname, "\n"));
1053         }
1054         e = next;
1055     }
1056     delete_fn = remove_unsafely;
1057 }
1058
1059 .float(entity) isEliminated;
1060 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1061 {
1062         Stream out = MSG_ENTITY;
1063         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1064         serialize(byte, out, sendflags);
1065         if (sendflags & 1) {
1066                 for (int i = 1; i <= maxclients; i += 8) {
1067                         int f = 0;
1068                         entity e = edict_num(i);
1069                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1070                                 if (eliminatedPlayers.isEliminated(e)) {
1071                                         f |= BIT(b);
1072                                 }
1073                         }
1074                         serialize(byte, out, f);
1075                 }
1076         }
1077         return true;
1078 }
1079
1080 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1081 {
1082         if(eliminatedPlayers)
1083         {
1084                 backtrace("Can't spawn eliminatedPlayers again!");
1085                 return;
1086         }
1087         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1088         eliminatedPlayers.isEliminated = isEliminated_func;
1089 }
1090
1091
1092
1093
1094 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1095 {
1096         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1097                 this.projectiledeathtype |= HITTYPE_SPLASH;
1098         adaptor_think2use(this);
1099 }
1100
1101 // deferred dropping
1102 void DropToFloor_Handler(entity this)
1103 {
1104     WITHSELF(this, builtin_droptofloor());
1105     this.dropped_origin = this.origin;
1106 }
1107
1108 void droptofloor(entity this)
1109 {
1110     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1111 }
1112
1113
1114
1115 float trace_hits_box_a0, trace_hits_box_a1;
1116
1117 float trace_hits_box_1d(float end, float thmi, float thma)
1118 {
1119     if (end == 0)
1120     {
1121         // just check if x is in range
1122         if (0 < thmi)
1123             return false;
1124         if (0 > thma)
1125             return false;
1126     }
1127     else
1128     {
1129         // do the trace with respect to x
1130         // 0 -> end has to stay in thmi -> thma
1131         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1132         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1133         if (trace_hits_box_a0 > trace_hits_box_a1)
1134             return false;
1135     }
1136     return true;
1137 }
1138
1139 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1140 {
1141     end -= start;
1142     thmi -= start;
1143     thma -= start;
1144     // now it is a trace from 0 to end
1145
1146     trace_hits_box_a0 = 0;
1147     trace_hits_box_a1 = 1;
1148
1149     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1150         return false;
1151     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1152         return false;
1153     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1154         return false;
1155
1156     return true;
1157 }
1158
1159 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1160 {
1161     return trace_hits_box(start, end, thmi - ma, thma - mi);
1162 }
1163
1164 bool SUB_NoImpactCheck(entity this, entity toucher)
1165 {
1166         // zero hitcontents = this is not the real impact, but either the
1167         // mirror-impact of something hitting the projectile instead of the
1168         // projectile hitting the something, or a touchareagrid one. Neither of
1169         // these stop the projectile from moving, so...
1170         if(trace_dphitcontents == 0)
1171         {
1172                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1173                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1174         }
1175     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1176         return true;
1177     if (toucher == NULL && this.size != '0 0 0')
1178     {
1179         vector tic;
1180         tic = this.velocity * sys_frametime;
1181         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1182         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1183         if (trace_fraction >= 1)
1184         {
1185             LOG_TRACE("Odd... did not hit...?");
1186         }
1187         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1188         {
1189             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1190             return true;
1191         }
1192     }
1193
1194     return false;
1195 }
1196
1197 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1198
1199 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1200 {
1201         if(SUB_OwnerCheck(this, toucher))
1202                 return true;
1203         if(SUB_NoImpactCheck(this, toucher))
1204         {
1205                 if(this.classname == "nade")
1206                         return false; // no checks here
1207                 else if(this.classname == "grapplinghook")
1208                         RemoveHook(this);
1209                 else if(this.classname == "spike")
1210                 {
1211                         W_Crylink_Dequeue(this);
1212                         delete(this);
1213                 }
1214                 else
1215                         delete(this);
1216                 return true;
1217         }
1218         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1219                 UpdateCSQCProjectile(this);
1220         return false;
1221 }
1222
1223 /** engine callback */
1224 void URI_Get_Callback(float id, float status, string data)
1225 {
1226         if(url_URI_Get_Callback(id, status, data))
1227         {
1228                 // handled
1229         }
1230         else if (id == URI_GET_DISCARD)
1231         {
1232                 // discard
1233         }
1234         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1235         {
1236                 // sv_cmd curl
1237                 Curl_URI_Get_Callback(id, status, data);
1238         }
1239         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1240         {
1241                 // online ban list
1242                 OnlineBanList_URI_Get_Callback(id, status, data);
1243         }
1244         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1245         {
1246                 // handled by a mutator
1247         }
1248         else
1249         {
1250                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1251         }
1252 }
1253
1254 string uid2name(string myuid) {
1255         string s;
1256         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1257
1258         // FIXME remove this later after 0.6 release
1259         // convert old style broken records to correct style
1260         if(s == "")
1261         {
1262                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1263                 if(s != "")
1264                 {
1265                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1266                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1267                 }
1268         }
1269
1270         if(s == "")
1271                 s = "^1Unregistered Player";
1272         return s;
1273 }
1274
1275 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1276 {
1277     float m, i;
1278     vector start, org, delta, end, enddown, mstart;
1279
1280     m = e.dphitcontentsmask;
1281     e.dphitcontentsmask = goodcontents | badcontents;
1282
1283     org = boundmin;
1284     delta = boundmax - boundmin;
1285
1286     start = end = org;
1287
1288     for (i = 0; i < attempts; ++i)
1289     {
1290         start.x = org.x + random() * delta.x;
1291         start.y = org.y + random() * delta.y;
1292         start.z = org.z + random() * delta.z;
1293
1294         // rule 1: start inside world bounds, and outside
1295         // solid, and don't start from somewhere where you can
1296         // fall down to evil
1297         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1298         if (trace_fraction >= 1)
1299             continue;
1300         if (trace_startsolid)
1301             continue;
1302         if (trace_dphitcontents & badcontents)
1303             continue;
1304         if (trace_dphitq3surfaceflags & badsurfaceflags)
1305             continue;
1306
1307         // rule 2: if we are too high, lower the point
1308         if (trace_fraction * delta.z > maxaboveground)
1309             start = trace_endpos + '0 0 1' * maxaboveground;
1310         enddown = trace_endpos;
1311
1312         // rule 3: make sure we aren't outside the map. This only works
1313         // for somewhat well formed maps. A good rule of thumb is that
1314         // the map should have a convex outside hull.
1315         // these can be traceLINES as we already verified the starting box
1316         mstart = start + 0.5 * (e.mins + e.maxs);
1317         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1318         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1319             continue;
1320         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1321         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1322             continue;
1323         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1324         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1325             continue;
1326         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1327         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1328             continue;
1329         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1330         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1331             continue;
1332
1333         // rule 4: we must "see" some spawnpoint or item
1334     entity sp = NULL;
1335     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1336     {
1337         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1338         {
1339                 sp = it;
1340                 break;
1341         }
1342     });
1343         if(!sp)
1344         {
1345                 int items_checked = 0;
1346                 IL_EACH(g_items, checkpvs(mstart, it),
1347                 {
1348                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1349                         {
1350                                 sp = it;
1351                                 break;
1352                         }
1353
1354                         ++items_checked;
1355                         if(items_checked >= attempts)
1356                                 break; // sanity
1357                 });
1358
1359                 if(!sp)
1360                         continue;
1361         }
1362
1363         // find a random vector to "look at"
1364         end.x = org.x + random() * delta.x;
1365         end.y = org.y + random() * delta.y;
1366         end.z = org.z + random() * delta.z;
1367         end = start + normalize(end - start) * vlen(delta);
1368
1369         // rule 4: start TO end must not be too short
1370         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1371         if (trace_startsolid)
1372             continue;
1373         if (trace_fraction < minviewdistance / vlen(delta))
1374             continue;
1375
1376         // rule 5: don't want to look at sky
1377         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1378             continue;
1379
1380         // rule 6: we must not end up in trigger_hurt
1381         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1382             continue;
1383
1384         break;
1385     }
1386
1387     e.dphitcontentsmask = m;
1388
1389     if (i < attempts)
1390     {
1391         setorigin(e, start);
1392         e.angles = vectoangles(end - start);
1393         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1394         return true;
1395     }
1396     else
1397         return false;
1398 }
1399
1400 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1401 {
1402         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1403 }
1404
1405 void write_recordmarker(entity pl, float tstart, float dt)
1406 {
1407     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1408
1409     // also write a marker into demo files for demotc-race-record-extractor to find
1410     stuffcmd(pl,
1411              strcat(
1412                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1413                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1414 }
1415
1416 void attach_sameorigin(entity e, entity to, string tag)
1417 {
1418     vector org, t_forward, t_left, t_up, e_forward, e_up;
1419     float tagscale;
1420
1421     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1422     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1423     t_forward = v_forward * tagscale;
1424     t_left = v_right * -tagscale;
1425     t_up = v_up * tagscale;
1426
1427     e.origin_x = org * t_forward;
1428     e.origin_y = org * t_left;
1429     e.origin_z = org * t_up;
1430
1431     // current forward and up directions
1432     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1433                 e.angles = AnglesTransform_FromVAngles(e.angles);
1434         else
1435                 e.angles = AnglesTransform_FromAngles(e.angles);
1436     fixedmakevectors(e.angles);
1437
1438     // untransform forward, up!
1439     e_forward.x = v_forward * t_forward;
1440     e_forward.y = v_forward * t_left;
1441     e_forward.z = v_forward * t_up;
1442     e_up.x = v_up * t_forward;
1443     e_up.y = v_up * t_left;
1444     e_up.z = v_up * t_up;
1445
1446     e.angles = fixedvectoangles2(e_forward, e_up);
1447     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1448                 e.angles = AnglesTransform_ToVAngles(e.angles);
1449         else
1450                 e.angles = AnglesTransform_ToAngles(e.angles);
1451
1452     setattachment(e, to, tag);
1453     setorigin(e, e.origin);
1454 }
1455
1456 void detach_sameorigin(entity e)
1457 {
1458     vector org;
1459     org = gettaginfo(e, 0);
1460     e.angles = fixedvectoangles2(v_forward, v_up);
1461     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1462                 e.angles = AnglesTransform_ToVAngles(e.angles);
1463         else
1464                 e.angles = AnglesTransform_ToAngles(e.angles);
1465     setorigin(e, org);
1466     setattachment(e, NULL, "");
1467     setorigin(e, e.origin);
1468 }
1469
1470 void follow_sameorigin(entity e, entity to)
1471 {
1472     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1473     e.aiment = to; // make the hole follow bmodel
1474     e.punchangle = to.angles; // the original angles of bmodel
1475     e.view_ofs = e.origin - to.origin; // relative origin
1476     e.v_angle = e.angles - to.angles; // relative angles
1477 }
1478
1479 void unfollow_sameorigin(entity e)
1480 {
1481     set_movetype(e, MOVETYPE_NONE);
1482 }
1483
1484 entity gettaginfo_relative_ent;
1485 vector gettaginfo_relative(entity e, float tag)
1486 {
1487     if (!gettaginfo_relative_ent)
1488     {
1489         gettaginfo_relative_ent = spawn();
1490         gettaginfo_relative_ent.effects = EF_NODRAW;
1491     }
1492     gettaginfo_relative_ent.model = e.model;
1493     gettaginfo_relative_ent.modelindex = e.modelindex;
1494     gettaginfo_relative_ent.frame = e.frame;
1495     return gettaginfo(gettaginfo_relative_ent, tag);
1496 }
1497
1498 .string aiment_classname;
1499 .float aiment_deadflag;
1500 void SetMovetypeFollow(entity ent, entity e)
1501 {
1502         // FIXME this may not be warpzone aware
1503         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1504         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1505         ent.aiment = e; // make the hole follow bmodel
1506         ent.punchangle = e.angles; // the original angles of bmodel
1507         ent.view_ofs = ent.origin - e.origin; // relative origin
1508         ent.v_angle = ent.angles - e.angles; // relative angles
1509         ent.aiment_classname = strzone(e.classname);
1510         ent.aiment_deadflag = e.deadflag;
1511 }
1512 void UnsetMovetypeFollow(entity ent)
1513 {
1514         set_movetype(ent, MOVETYPE_FLY);
1515         PROJECTILE_MAKETRIGGER(ent);
1516         ent.aiment = NULL;
1517 }
1518 float LostMovetypeFollow(entity ent)
1519 {
1520 /*
1521         if(ent.move_movetype != MOVETYPE_FOLLOW)
1522                 if(ent.aiment)
1523                         error("???");
1524 */
1525         if(ent.aiment)
1526         {
1527                 if(ent.aiment.classname != ent.aiment_classname)
1528                         return 1;
1529                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1530                         return 1;
1531         }
1532         return 0;
1533 }
1534
1535 .bool pushable;
1536 bool isPushable(entity e)
1537 {
1538         if(e.pushable)
1539                 return true;
1540         if(IS_VEHICLE(e))
1541                 return false;
1542         if(e.iscreature)
1543                 return true;
1544         if (Item_IsLoot(e))
1545         {
1546                 return true;
1547         }
1548         switch(e.classname)
1549         {
1550                 case "body":
1551                         return true;
1552                 case "bullet": // antilagged bullets can't hit this either
1553                         return false;
1554         }
1555         if (e.projectiledeathtype)
1556                 return true;
1557         return false;
1558 }