Split the gamelog code out of miscfunctions and into its own file
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 #include "miscfunctions.qh"
2
3 #include "antilag.qh"
4 #include "command/common.qh"
5 #include "constants.qh"
6 #include "g_hook.qh"
7 #include <server/gamelog.qh>
8 #include "ipban.qh"
9 #include <server/mutators/_mod.qh>
10 #include "../common/t_items.qh"
11 #include "mapvoting.qh"
12 #include "resources.qh"
13 #include "items.qh"
14 #include "player.qh"
15 #include "weapons/accuracy.qh"
16 #include "weapons/csqcprojectile.qh"
17 #include "weapons/selection.qh"
18 #include "../common/command/_mod.qh"
19 #include "../common/constants.qh"
20 #include <common/net_linked.qh>
21 #include <common/weapons/weapon/crylink.qh>
22 #include "../common/deathtypes/all.qh"
23 #include "../common/mapinfo.qh"
24 #include "../common/notifications/all.qh"
25 #include "../common/playerstats.qh"
26 #include "../common/teams.qh"
27 #include "../common/mapobjects/subs.qh"
28 #include "../common/util.qh"
29 #include "../common/turrets/sv_turrets.qh"
30 #include <common/weapons/_all.qh>
31 #include "../common/vehicles/sv_vehicles.qh"
32 #include "../common/vehicles/vehicle.qh"
33 #include "../common/items/_mod.qh"
34 #include "../common/state.qh"
35 #include "../common/effects/qc/globalsound.qh"
36 #include "../common/wepent.qh"
37 #include <common/weapons/weapon.qh>
38 #include "../lib/csqcmodel/sv_model.qh"
39 #include "../lib/warpzone/anglestransform.qh"
40 #include "../lib/warpzone/server.qh"
41
42 void crosshair_trace(entity pl)
43 {
44         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
45 }
46
47 void crosshair_trace_plusvisibletriggers(entity pl)
48 {
49         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
50 }
51
52 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
53 {
54         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
55 }
56
57 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
58 {
59         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
60         {
61                 if(it.model != "")
62                 {
63                         it.solid = SOLID_BSP;
64                         IL_PUSH(g_ctrace_changed, it);
65                 }
66         });
67
68         if (is_wz)
69                 WarpZone_crosshair_trace(pl);
70         else
71                 crosshair_trace(pl);
72
73         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
74
75         IL_CLEAR(g_ctrace_changed);
76 }
77
78 void WarpZone_crosshair_trace(entity pl)
79 {
80         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
81 }
82
83 void dedicated_print(string input)
84 {
85         if (server_is_dedicated) print(input);
86 }
87
88 entity findnearest(vector point, bool checkitems, vector axismod)
89 {
90     vector dist;
91     int num_nearest = 0;
92
93     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
94     {
95         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
96             dist = it.oldorigin;
97         else
98             dist = it.origin;
99         dist = dist - point;
100         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
101         float len = vlen2(dist);
102
103         int l;
104         for (l = 0; l < num_nearest; ++l)
105         {
106             if (len < nearest_length[l])
107                 break;
108         }
109
110         // now i tells us where to insert at
111         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
112         if (l < NUM_NEAREST_ENTITIES)
113         {
114             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
115             {
116                 nearest_length[j + 1] = nearest_length[j];
117                 nearest_entity[j + 1] = nearest_entity[j];
118             }
119             nearest_length[l] = len;
120             nearest_entity[l] = it;
121             if (num_nearest < NUM_NEAREST_ENTITIES)
122                 num_nearest = num_nearest + 1;
123         }
124     });
125
126     // now use the first one from our list that we can see
127     for (int j = 0; j < num_nearest; ++j)
128     {
129         traceline(point, nearest_entity[j].origin, true, NULL);
130         if (trace_fraction == 1)
131         {
132             if (j != 0)
133                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
134             return nearest_entity[j];
135         }
136     }
137
138     if (num_nearest == 0)
139         return NULL;
140
141     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
142     /* DEBUGGING CODE:
143     dprint("Candidates were: ");
144     for(j = 0; j < num_nearest; ++j)
145     {
146         if(j != 0)
147                 dprint(", ");
148         dprint(nearest_entity[j].netname);
149     }
150     dprint("\n");
151     */
152
153     return nearest_entity[0];
154 }
155
156 string NearestLocation(vector p)
157 {
158     string ret = "somewhere";
159     entity loc = findnearest(p, false, '1 1 1');
160     if (loc)
161         ret = loc.message;
162     else
163     {
164         loc = findnearest(p, true, '1 1 4');
165         if (loc)
166             ret = loc.netname;
167     }
168     return ret;
169 }
170
171 string PlayerHealth(entity this)
172 {
173         float myhealth = floor(GetResource(this, RES_HEALTH));
174         if(myhealth == -666)
175                 return "spectating";
176         else if(myhealth == -2342 || (myhealth == 2342 && mapvote_initialized))
177                 return "observing";
178         else if(myhealth <= 0 || IS_DEAD(this))
179                 return "dead";
180         return ftos(myhealth);
181 }
182
183 string WeaponNameFromWeaponentity(entity this, .entity weaponentity)
184 {
185         entity wepent = this.(weaponentity);
186         if(!wepent)
187                 return "none";
188         else if(wepent.m_weapon != WEP_Null)
189                 return wepent.m_weapon.m_name;
190         else if(wepent.m_switchweapon != WEP_Null)
191                 return wepent.m_switchweapon.m_name;
192         return "none"; //REGISTRY_GET(Weapons, wepent.cnt).m_name;
193 }
194
195 string formatmessage(entity this, string msg)
196 {
197         float p, p1, p2;
198         float n;
199         vector cursor = '0 0 0';
200         entity cursor_ent = NULL;
201         string escape;
202         string replacement;
203         p = 0;
204         n = 7;
205         bool traced = false;
206
207         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
208         msg = M_ARGV(1, string);
209
210         while (1) {
211                 if (n < 1)
212                         break; // too many replacements
213
214                 n = n - 1;
215                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
216                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
217
218                 if (p1 < 0)
219                         p1 = p2;
220
221                 if (p2 < 0)
222                         p2 = p1;
223
224                 p = min(p1, p2);
225
226                 if (p < 0)
227                         break;
228
229                 if(!traced)
230                 {
231                         WarpZone_crosshair_trace_plusvisibletriggers(this);
232                         cursor = trace_endpos;
233                         cursor_ent = trace_ent;
234                         traced = true;
235                 }
236
237                 replacement = substring(msg, p, 2);
238                 escape = substring(msg, p + 1, 1);
239
240                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
241
242                 switch(escape)
243                 {
244                         case "%": replacement = "%"; break;
245                         case "\\":replacement = "\\"; break;
246                         case "n": replacement = "\n"; break;
247                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
248                         case "h": replacement = PlayerHealth(this); break;
249                         case "l": replacement = NearestLocation(this.origin); break;
250                         case "y": replacement = NearestLocation(cursor); break;
251                         case "d": replacement = NearestLocation(this.death_origin); break;
252                         case "w": replacement = WeaponNameFromWeaponentity(this, weaponentity); break;
253                         case "W": replacement = GetAmmoName(this.(weaponentity).m_weapon.ammo_type); break;
254                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
255                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
256                         case "S": replacement = ftos(vlen(this.velocity)); break;
257                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
258                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
259                         default:
260                         {
261                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
262                                 replacement = M_ARGV(2, string);
263                                 break;
264                         }
265                 }
266
267                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
268                 p = p + strlen(replacement);
269         }
270         return msg;
271 }
272
273 /*
274 =============
275 GetCvars
276 =============
277 Called with:
278   0:  sends the request
279   >0: receives a cvar from name=argv(f) value=argv(f+1)
280 */
281 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
282 {
283         if (f < 0)
284         {
285                 strfree(store.(field));
286         }
287         else if (f > 0)
288         {
289                 if (thisname == name)
290                 {
291                         strcpy(store.(field), argv(f + 1));
292                 }
293         }
294         else
295                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
296 }
297 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
298 {
299         GetCvars_handleString(this, store, thisname, f, field, name);
300         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
301                 if (thisname == name)
302                 {
303                         string s = func(this, strcat1(store.(field)));
304                         if (s != store.(field))
305                         {
306                                 strcpy(store.(field), s);
307                         }
308                 }
309 }
310 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
311 {
312         if (f < 0)
313         {
314         }
315         else if (f > 0)
316         {
317                 if (thisname == name)
318                         store.(field) = stof(argv(f + 1));
319         }
320         else
321                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
322 }
323 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
324 {
325         if (f < 0)
326         {
327         }
328         else if (f > 0)
329         {
330                 if (thisname == name)
331                 {
332                         if (!store.(field))
333                         {
334                                 store.(field) = stof(argv(f + 1));
335                                 if (!store.(field))
336                                         store.(field) = -1;
337                         }
338                 }
339         }
340         else
341         {
342                 if (!store.(field))
343                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
344         }
345 }
346 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
347 {
348         string o = W_FixWeaponOrder_ForceComplete(wo);
349         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
350         return o;
351 }
352
353 REPLICATE(autoswitch, bool, "cl_autoswitch");
354
355 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
356
357 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
358
359 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
360
361 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
362
363 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
364
365 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
366
367 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
368
369 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
370
371 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
372
373 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
374
375 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
376
377 REPLICATE(cvar_cl_physics, string, "cl_physics");
378
379 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
380
381 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
382
383 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
384
385 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
386
387 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
388
389 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
390
391 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
392
393 /**
394  * @param f -1: cleanup, 0: request, 1: receive
395  */
396 void GetCvars(entity this, entity store, int f)
397 {
398         string s = string_null;
399
400         if (f == 0)
401                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
402
403         if (f > 0)
404                 s = strcat1(argv(f));
405
406         get_cvars_f = f;
407         get_cvars_s = s;
408         MUTATOR_CALLHOOK(GetCvars);
409
410         Notification_GetCvars(this);
411
412         ReplicateVars(this, store, s, f);
413
414         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
415         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
416         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
417         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
418         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
419         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
420         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
421         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
422         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
425
426         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
427
428         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
429         if (f > 0)
430         {
431                 if (s == "cl_weaponpriority")
432                 {
433                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
434                         {
435                                 .entity weaponentity = weaponentities[slot];
436                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
437                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
438                         }
439                 }
440                 if (s == "cl_allow_uidtracking")
441                         PlayerStats_GameReport_AddPlayer(this);
442                 //if (s == "cl_gunalign")
443                         //W_ResetGunAlign(this, store.cvar_cl_gunalign);
444         }
445 }
446
447 // decolorizes and team colors the player name when needed
448 string playername(entity p, bool team_colorize)
449 {
450     string t;
451     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
452     {
453         t = Team_ColorCode(p.team);
454         return strcat(t, strdecolorize(p.netname));
455     }
456     else
457         return p.netname;
458 }
459
460 float want_weapon(entity weaponinfo, float allguns)
461 {
462         int d = 0;
463         bool allow_mutatorblocked = false;
464
465         if(!weaponinfo.m_id)
466                 return 0;
467
468         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
469         d = M_ARGV(1, float);
470         allguns = M_ARGV(2, bool);
471         allow_mutatorblocked = M_ARGV(3, bool);
472
473         if(allguns)
474                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
475         else if(!mutator_returnvalue)
476                 d = !(!weaponinfo.weaponstart);
477
478         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
479                 d = 0;
480
481         float t = weaponinfo.weaponstartoverride;
482
483         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
484
485         // bit order in t:
486         // 1: want or not
487         // 2: is default?
488         // 4: is set by default?
489         if(t < 0)
490                 t = 4 | (3 * d);
491         else
492                 t |= (2 * d);
493
494         return t;
495 }
496
497 /// Weapons the player normally starts with outside weapon arena.
498 WepSet weapons_start()
499 {
500         WepSet ret = '0 0 0';
501         FOREACH(Weapons, it != WEP_Null, {
502                 int w = want_weapon(it, false);
503                 if (w & 1)
504                         ret |= it.m_wepset;
505         });
506         return ret;
507 }
508
509 WepSet weapons_all()
510 {
511         WepSet ret = '0 0 0';
512         FOREACH(Weapons, it != WEP_Null, {
513                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
514                         ret |= it.m_wepset;
515         });
516         return ret;
517 }
518
519 WepSet weapons_devall()
520 {
521         WepSet ret = '0 0 0';
522         FOREACH(Weapons, it != WEP_Null,
523         {
524                 ret |= it.m_wepset;
525         });
526         return ret;
527 }
528
529 WepSet weapons_most()
530 {
531         WepSet ret = '0 0 0';
532         FOREACH(Weapons, it != WEP_Null, {
533                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
534                         ret |= it.m_wepset;
535         });
536         return ret;
537 }
538
539 void weaponarena_available_all_update(entity this)
540 {
541         if (weaponsInMapAll)
542         {
543                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
544         }
545         else
546         {
547                 // if no weapons are available on the map, just fall back to all weapons arena
548                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
549         }
550 }
551
552 void weaponarena_available_devall_update(entity this)
553 {
554         if (weaponsInMapAll)
555         {
556                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
557         }
558         else
559         {
560                 // if no weapons are available on the map, just fall back to devall weapons arena
561                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
562         }
563 }
564
565 void weaponarena_available_most_update(entity this)
566 {
567         if (weaponsInMapAll)
568         {
569                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
570         }
571         else
572         {
573                 // if no weapons are available on the map, just fall back to most weapons arena
574                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
575         }
576 }
577
578 void readplayerstartcvars()
579 {
580         // initialize starting values for players
581         start_weapons = '0 0 0';
582         start_weapons_default = '0 0 0';
583         start_weapons_defaultmask = '0 0 0';
584         start_items = 0;
585         start_ammo_shells = 0;
586         start_ammo_nails = 0;
587         start_ammo_rockets = 0;
588         start_ammo_cells = 0;
589         start_ammo_plasma = 0;
590         if (random_start_ammo == NULL)
591         {
592                 random_start_ammo = spawn();
593         }
594         start_health = cvar("g_balance_health_start");
595         start_armorvalue = cvar("g_balance_armor_start");
596
597         g_weaponarena = 0;
598         g_weaponarena_weapons = '0 0 0';
599
600         string s = cvar_string("g_weaponarena");
601
602         MUTATOR_CALLHOOK(SetWeaponArena, s);
603         s = M_ARGV(0, string);
604
605         if (s == "0" || s == "")
606         {
607                 // no arena
608         }
609         else if (s == "off")
610         {
611                 // forcibly turn off weaponarena
612         }
613         else if (s == "all" || s == "1")
614         {
615                 g_weaponarena = 1;
616                 g_weaponarena_list = "All Weapons";
617                 g_weaponarena_weapons = weapons_all();
618         }
619         else if (s == "devall")
620         {
621                 g_weaponarena = 1;
622                 g_weaponarena_list = "Dev All Weapons";
623                 g_weaponarena_weapons = weapons_devall();
624         }
625         else if (s == "most")
626         {
627                 g_weaponarena = 1;
628                 g_weaponarena_list = "Most Weapons";
629                 g_weaponarena_weapons = weapons_most();
630         }
631         else if (s == "all_available")
632         {
633                 g_weaponarena = 1;
634                 g_weaponarena_list = "All Available Weapons";
635
636                 // this needs to run after weaponsInMapAll is initialized
637                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
638         }
639         else if (s == "devall_available")
640         {
641                 g_weaponarena = 1;
642                 g_weaponarena_list = "Dev All Available Weapons";
643
644                 // this needs to run after weaponsInMapAll is initialized
645                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
646         }
647         else if (s == "most_available")
648         {
649                 g_weaponarena = 1;
650                 g_weaponarena_list = "Most Available Weapons";
651
652                 // this needs to run after weaponsInMapAll is initialized
653                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
654         }
655         else if (s == "none")
656         {
657                 g_weaponarena = 1;
658                 g_weaponarena_list = "No Weapons";
659         }
660         else
661         {
662                 g_weaponarena = 1;
663                 float t = tokenize_console(s);
664                 g_weaponarena_list = "";
665                 for (int j = 0; j < t; ++j)
666                 {
667                         s = argv(j);
668                         Weapon wep = Weapon_from_name(s);
669                         if(wep != WEP_Null)
670                         {
671                                 g_weaponarena_weapons |= (wep.m_wepset);
672                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
673                         }
674                 }
675                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
676         }
677
678         if (g_weaponarena)
679         {
680                 g_weapon_stay = 0; // incompatible
681                 start_weapons = g_weaponarena_weapons;
682                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
683         }
684         else
685         {
686                 FOREACH(Weapons, it != WEP_Null, {
687                         int w = want_weapon(it, false);
688                         WepSet s = it.m_wepset;
689                         if(w & 1)
690                                 start_weapons |= s;
691                         if(w & 2)
692                                 start_weapons_default |= s;
693                         if(w & 4)
694                                 start_weapons_defaultmask |= s;
695                 });
696         }
697
698         if(cvar("g_balance_superweapons_time") < 0)
699                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
700
701         if(!cvar("g_use_ammunition"))
702                 start_items |= IT_UNLIMITED_AMMO;
703
704         if(start_items & IT_UNLIMITED_AMMO)
705         {
706                 start_ammo_shells = 999;
707                 start_ammo_nails = 999;
708                 start_ammo_rockets = 999;
709                 start_ammo_cells = 999;
710                 start_ammo_plasma = 999;
711                 start_ammo_fuel = 999;
712         }
713         else
714         {
715                 start_ammo_shells = cvar("g_start_ammo_shells");
716                 start_ammo_nails = cvar("g_start_ammo_nails");
717                 start_ammo_rockets = cvar("g_start_ammo_rockets");
718                 start_ammo_cells = cvar("g_start_ammo_cells");
719                 start_ammo_plasma = cvar("g_start_ammo_plasma");
720                 start_ammo_fuel = cvar("g_start_ammo_fuel");
721                 random_start_weapons_count = cvar("g_random_start_weapons_count");
722                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
723                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
724                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
725                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
726                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
727         }
728
729         warmup_start_ammo_shells = start_ammo_shells;
730         warmup_start_ammo_nails = start_ammo_nails;
731         warmup_start_ammo_rockets = start_ammo_rockets;
732         warmup_start_ammo_cells = start_ammo_cells;
733         warmup_start_ammo_plasma = start_ammo_plasma;
734         warmup_start_ammo_fuel = start_ammo_fuel;
735         warmup_start_health = start_health;
736         warmup_start_armorvalue = start_armorvalue;
737         warmup_start_weapons = start_weapons;
738         warmup_start_weapons_default = start_weapons_default;
739         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
740
741         if (!g_weaponarena)
742         {
743                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
744                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
745                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
746                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
747                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
748                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
749                 warmup_start_health = cvar("g_warmup_start_health");
750                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
751                 warmup_start_weapons = '0 0 0';
752                 warmup_start_weapons_default = '0 0 0';
753                 warmup_start_weapons_defaultmask = '0 0 0';
754                 FOREACH(Weapons, it != WEP_Null, {
755                         int w = want_weapon(it, g_warmup_allguns);
756                         WepSet s = it.m_wepset;
757                         if(w & 1)
758                                 warmup_start_weapons |= s;
759                         if(w & 2)
760                                 warmup_start_weapons_default |= s;
761                         if(w & 4)
762                                 warmup_start_weapons_defaultmask |= s;
763                 });
764         }
765
766         if (g_jetpack)
767                 start_items |= ITEM_Jetpack.m_itemid;
768
769         MUTATOR_CALLHOOK(SetStartItems);
770
771         if (start_items & ITEM_Jetpack.m_itemid)
772         {
773                 start_items |= ITEM_JetpackRegen.m_itemid;
774                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
775                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
776         }
777
778         start_ammo_shells = max(0, start_ammo_shells);
779         start_ammo_nails = max(0, start_ammo_nails);
780         start_ammo_rockets = max(0, start_ammo_rockets);
781         start_ammo_cells = max(0, start_ammo_cells);
782         start_ammo_plasma = max(0, start_ammo_plasma);
783         start_ammo_fuel = max(0, start_ammo_fuel);
784         SetResource(random_start_ammo, RES_SHELLS,
785                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
786         SetResource(random_start_ammo, RES_BULLETS,
787                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
788         SetResource(random_start_ammo, RES_ROCKETS,
789                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
790         SetResource(random_start_ammo, RES_CELLS,
791                 max(0, GetResource(random_start_ammo, RES_CELLS)));
792         SetResource(random_start_ammo, RES_PLASMA,
793                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
794
795         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
796         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
797         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
798         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
799         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
800         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
801 }
802
803 void precache_playermodel(string m)
804 {
805         int globhandle, i, n;
806         string f;
807
808         // remove :<skinnumber> suffix
809         int j = strstrofs(m, ":", 0);
810         if(j >= 0)
811                 m = substring(m, 0, j);
812
813         if(substring(m, -9, 5) == "_lod1")
814                 return;
815         if(substring(m, -9, 5) == "_lod2")
816                 return;
817         precache_model(m);
818         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
819         if(fexists(f))
820                 precache_model(f);
821         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
822         if(fexists(f))
823                 precache_model(f);
824
825         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
826         if (globhandle < 0)
827                 return;
828         n = search_getsize(globhandle);
829         for (i = 0; i < n; ++i)
830         {
831                 //print(search_getfilename(globhandle, i), "\n");
832                 f = search_getfilename(globhandle, i);
833                 PrecachePlayerSounds(f);
834         }
835         search_end(globhandle);
836 }
837 void precache_all_playermodels(string pattern)
838 {
839         int globhandle = search_begin(pattern, true, false);
840         if (globhandle < 0) return;
841         int n = search_getsize(globhandle);
842         for (int i = 0; i < n; ++i)
843         {
844                 string s = search_getfilename(globhandle, i);
845                 precache_playermodel(s);
846         }
847         search_end(globhandle);
848 }
849
850 void precache_playermodels(string s)
851 {
852         FOREACH_WORD(s, true, { precache_playermodel(it); });
853 }
854
855 PRECACHE(PlayerModels)
856 {
857     // Precache all player models if desired
858     if (autocvar_sv_precacheplayermodels)
859     {
860         PrecachePlayerSounds("sound/player/default.sounds");
861         precache_all_playermodels("models/player/*.zym");
862         precache_all_playermodels("models/player/*.dpm");
863         precache_all_playermodels("models/player/*.md3");
864         precache_all_playermodels("models/player/*.psk");
865         precache_all_playermodels("models/player/*.iqm");
866     }
867
868     if (autocvar_sv_defaultcharacter)
869     {
870                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
871                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
872                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
873                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
874                 precache_playermodels(autocvar_sv_defaultplayermodel);
875     }
876 }
877
878
879 void make_safe_for_remove(entity e)
880 {
881     if (e.initialize_entity)
882     {
883         entity ent, prev = NULL;
884         for (ent = initialize_entity_first; ent; )
885         {
886             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
887             {
888                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
889                 // skip it in linked list
890                 if (prev)
891                 {
892                     prev.initialize_entity_next = ent.initialize_entity_next;
893                     ent = prev.initialize_entity_next;
894                 }
895                 else
896                 {
897                     initialize_entity_first = ent.initialize_entity_next;
898                     ent = initialize_entity_first;
899                 }
900             }
901             else
902             {
903                 prev = ent;
904                 ent = ent.initialize_entity_next;
905             }
906         }
907     }
908 }
909
910 .float remove_except_protected_forbidden;
911 void remove_except_protected(entity e)
912 {
913         if(e.remove_except_protected_forbidden)
914                 error("not allowed to remove this at this point");
915         builtin_remove(e);
916 }
917
918 void remove_unsafely(entity e)
919 {
920     if(e.classname == "spike")
921         error("Removing spikes is forbidden (crylink bug), please report");
922     builtin_remove(e);
923 }
924
925 void remove_safely(entity e)
926 {
927     make_safe_for_remove(e);
928     builtin_remove(e);
929 }
930
931 void InitializeEntity(entity e, void(entity this) func, int order)
932 {
933     entity prev, cur;
934
935     if (!e || e.initialize_entity)
936     {
937         // make a proxy initializer entity
938         entity e_old = e;
939         e = new(initialize_entity);
940         e.enemy = e_old;
941     }
942
943     e.initialize_entity = func;
944     e.initialize_entity_order = order;
945
946     cur = initialize_entity_first;
947     prev = NULL;
948     for (;;)
949     {
950         if (!cur || cur.initialize_entity_order > order)
951         {
952             // insert between prev and cur
953             if (prev)
954                 prev.initialize_entity_next = e;
955             else
956                 initialize_entity_first = e;
957             e.initialize_entity_next = cur;
958             return;
959         }
960         prev = cur;
961         cur = cur.initialize_entity_next;
962     }
963 }
964 void InitializeEntitiesRun()
965 {
966     entity startoflist = initialize_entity_first;
967     initialize_entity_first = NULL;
968     delete_fn = remove_except_protected;
969     for (entity e = startoflist; e; e = e.initialize_entity_next)
970     {
971                 e.remove_except_protected_forbidden = 1;
972     }
973     for (entity e = startoflist; e; )
974     {
975                 e.remove_except_protected_forbidden = 0;
976         e.initialize_entity_order = 0;
977         entity next = e.initialize_entity_next;
978         e.initialize_entity_next = NULL;
979         var void(entity this) func = e.initialize_entity;
980         e.initialize_entity = func_null;
981         if (e.classname == "initialize_entity")
982         {
983             entity wrappee = e.enemy;
984             builtin_remove(e);
985             e = wrappee;
986         }
987         //dprint("Delayed initialization: ", e.classname, "\n");
988         if (func)
989         {
990                 func(e);
991         }
992         else
993         {
994             eprint(e);
995             backtrace(strcat("Null function in: ", e.classname, "\n"));
996         }
997         e = next;
998     }
999     delete_fn = remove_unsafely;
1000 }
1001
1002 .float(entity) isEliminated;
1003 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1004 {
1005         Stream out = MSG_ENTITY;
1006         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1007         serialize(byte, out, sendflags);
1008         if (sendflags & 1) {
1009                 for (int i = 1; i <= maxclients; i += 8) {
1010                         int f = 0;
1011                         entity e = edict_num(i);
1012                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1013                                 if (eliminatedPlayers.isEliminated(e)) {
1014                                         f |= BIT(b);
1015                                 }
1016                         }
1017                         serialize(byte, out, f);
1018                 }
1019         }
1020         return true;
1021 }
1022
1023 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1024 {
1025         if(eliminatedPlayers)
1026         {
1027                 backtrace("Can't spawn eliminatedPlayers again!");
1028                 return;
1029         }
1030         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1031         eliminatedPlayers.isEliminated = isEliminated_func;
1032 }
1033
1034
1035
1036
1037 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1038 {
1039         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1040                 this.projectiledeathtype |= HITTYPE_SPLASH;
1041         adaptor_think2use(this);
1042 }
1043
1044 // deferred dropping
1045 void DropToFloor_Handler(entity this)
1046 {
1047     WITHSELF(this, builtin_droptofloor());
1048     this.dropped_origin = this.origin;
1049 }
1050
1051 void droptofloor(entity this)
1052 {
1053     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1054 }
1055
1056
1057
1058 float trace_hits_box_a0, trace_hits_box_a1;
1059
1060 float trace_hits_box_1d(float end, float thmi, float thma)
1061 {
1062     if (end == 0)
1063     {
1064         // just check if x is in range
1065         if (0 < thmi)
1066             return false;
1067         if (0 > thma)
1068             return false;
1069     }
1070     else
1071     {
1072         // do the trace with respect to x
1073         // 0 -> end has to stay in thmi -> thma
1074         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1075         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1076         if (trace_hits_box_a0 > trace_hits_box_a1)
1077             return false;
1078     }
1079     return true;
1080 }
1081
1082 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1083 {
1084     end -= start;
1085     thmi -= start;
1086     thma -= start;
1087     // now it is a trace from 0 to end
1088
1089     trace_hits_box_a0 = 0;
1090     trace_hits_box_a1 = 1;
1091
1092     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1093         return false;
1094     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1095         return false;
1096     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1097         return false;
1098
1099     return true;
1100 }
1101
1102 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1103 {
1104     return trace_hits_box(start, end, thmi - ma, thma - mi);
1105 }
1106
1107 bool SUB_NoImpactCheck(entity this, entity toucher)
1108 {
1109         // zero hitcontents = this is not the real impact, but either the
1110         // mirror-impact of something hitting the projectile instead of the
1111         // projectile hitting the something, or a touchareagrid one. Neither of
1112         // these stop the projectile from moving, so...
1113         if(trace_dphitcontents == 0)
1114         {
1115                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1116                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1117         }
1118     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1119         return true;
1120     if (toucher == NULL && this.size != '0 0 0')
1121     {
1122         vector tic;
1123         tic = this.velocity * sys_frametime;
1124         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1125         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1126         if (trace_fraction >= 1)
1127         {
1128             LOG_TRACE("Odd... did not hit...?");
1129         }
1130         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1131         {
1132             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1133             return true;
1134         }
1135     }
1136
1137     return false;
1138 }
1139
1140 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1141 {
1142         // owner check
1143         if(toucher && toucher == this.owner)
1144                 return true;
1145         if(SUB_NoImpactCheck(this, toucher))
1146         {
1147                 if(this.classname == "nade")
1148                         return false; // no checks here
1149                 else if(this.classname == "grapplinghook")
1150                         RemoveHook(this);
1151                 else
1152                         delete(this);
1153                 return true;
1154         }
1155         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1156                 UpdateCSQCProjectile(this);
1157         return false;
1158 }
1159
1160 /** engine callback */
1161 void URI_Get_Callback(float id, float status, string data)
1162 {
1163         if(url_URI_Get_Callback(id, status, data))
1164         {
1165                 // handled
1166         }
1167         else if (id == URI_GET_DISCARD)
1168         {
1169                 // discard
1170         }
1171         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1172         {
1173                 // sv_cmd curl
1174                 Curl_URI_Get_Callback(id, status, data);
1175         }
1176         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1177         {
1178                 // online ban list
1179                 OnlineBanList_URI_Get_Callback(id, status, data);
1180         }
1181         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1182         {
1183                 // handled by a mutator
1184         }
1185         else
1186         {
1187                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1188         }
1189 }
1190
1191 string uid2name(string myuid)
1192 {
1193         string s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1194
1195         // FIXME remove this later after 0.6 release
1196         // convert old style broken records to correct style
1197         if(s == "")
1198         {
1199                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1200                 if(s != "")
1201                 {
1202                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1203                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1204                 }
1205         }
1206
1207         if(s == "")
1208                 s = "^1Unregistered Player";
1209         return s;
1210 }
1211
1212 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1213 {
1214     float m = e.dphitcontentsmask;
1215     e.dphitcontentsmask = goodcontents | badcontents;
1216
1217     vector org = boundmin;
1218     vector delta = boundmax - boundmin;
1219
1220     vector start, end;
1221     start = end = org;
1222     int j; // used after the loop
1223     for(j = 0; j < attempts; ++j)
1224     {
1225         start.x = org.x + random() * delta.x;
1226         start.y = org.y + random() * delta.y;
1227         start.z = org.z + random() * delta.z;
1228
1229         // rule 1: start inside world bounds, and outside
1230         // solid, and don't start from somewhere where you can
1231         // fall down to evil
1232         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1233         if (trace_fraction >= 1)
1234             continue;
1235         if (trace_startsolid)
1236             continue;
1237         if (trace_dphitcontents & badcontents)
1238             continue;
1239         if (trace_dphitq3surfaceflags & badsurfaceflags)
1240             continue;
1241
1242         // rule 2: if we are too high, lower the point
1243         if (trace_fraction * delta.z > maxaboveground)
1244             start = trace_endpos + '0 0 1' * maxaboveground;
1245         vector enddown = trace_endpos;
1246
1247         // rule 3: make sure we aren't outside the map. This only works
1248         // for somewhat well formed maps. A good rule of thumb is that
1249         // the map should have a convex outside hull.
1250         // these can be traceLINES as we already verified the starting box
1251         vector mstart = start + 0.5 * (e.mins + e.maxs);
1252         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1253         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1254             continue;
1255         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1256         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1257             continue;
1258         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1259         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1260             continue;
1261         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1262         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1263             continue;
1264         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1265         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1266             continue;
1267
1268                 // rule 4: we must "see" some spawnpoint or item
1269             entity sp = NULL;
1270             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1271             {
1272                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1273                 {
1274                         sp = it;
1275                         break;
1276                 }
1277             });
1278                 if(!sp)
1279                 {
1280                         int items_checked = 0;
1281                         IL_EACH(g_items, checkpvs(mstart, it),
1282                         {
1283                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1284                                 {
1285                                         sp = it;
1286                                         break;
1287                                 }
1288
1289                                 ++items_checked;
1290                                 if(items_checked >= attempts)
1291                                         break; // sanity
1292                         });
1293
1294                         if(!sp)
1295                                 continue;
1296                 }
1297
1298         // find a random vector to "look at"
1299         end.x = org.x + random() * delta.x;
1300         end.y = org.y + random() * delta.y;
1301         end.z = org.z + random() * delta.z;
1302         end = start + normalize(end - start) * vlen(delta);
1303
1304         // rule 4: start TO end must not be too short
1305         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1306         if(trace_startsolid)
1307             continue;
1308         if(trace_fraction < minviewdistance / vlen(delta))
1309             continue;
1310
1311         // rule 5: don't want to look at sky
1312         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1313             continue;
1314
1315         // rule 6: we must not end up in trigger_hurt
1316         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1317             continue;
1318
1319         break;
1320     }
1321
1322     e.dphitcontentsmask = m;
1323
1324     if(j < attempts)
1325     {
1326         setorigin(e, start);
1327         e.angles = vectoangles(end - start);
1328         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1329         return true;
1330     }
1331     return false;
1332 }
1333
1334 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1335 {
1336         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1337 }
1338
1339 void write_recordmarker(entity pl, float tstart, float dt)
1340 {
1341     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1342
1343     // also write a marker into demo files for demotc-race-record-extractor to find
1344     stuffcmd(pl,
1345              strcat(
1346                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1347                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1348 }
1349
1350 void attach_sameorigin(entity e, entity to, string tag)
1351 {
1352     vector org, t_forward, t_left, t_up, e_forward, e_up;
1353     float tagscale;
1354
1355     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1356     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1357     t_forward = v_forward * tagscale;
1358     t_left = v_right * -tagscale;
1359     t_up = v_up * tagscale;
1360
1361     e.origin_x = org * t_forward;
1362     e.origin_y = org * t_left;
1363     e.origin_z = org * t_up;
1364
1365     // current forward and up directions
1366     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1367                 e.angles = AnglesTransform_FromVAngles(e.angles);
1368         else
1369                 e.angles = AnglesTransform_FromAngles(e.angles);
1370     fixedmakevectors(e.angles);
1371
1372     // untransform forward, up!
1373     e_forward.x = v_forward * t_forward;
1374     e_forward.y = v_forward * t_left;
1375     e_forward.z = v_forward * t_up;
1376     e_up.x = v_up * t_forward;
1377     e_up.y = v_up * t_left;
1378     e_up.z = v_up * t_up;
1379
1380     e.angles = fixedvectoangles2(e_forward, e_up);
1381     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1382                 e.angles = AnglesTransform_ToVAngles(e.angles);
1383         else
1384                 e.angles = AnglesTransform_ToAngles(e.angles);
1385
1386     setattachment(e, to, tag);
1387     setorigin(e, e.origin);
1388 }
1389
1390 void detach_sameorigin(entity e)
1391 {
1392     vector org;
1393     org = gettaginfo(e, 0);
1394     e.angles = fixedvectoangles2(v_forward, v_up);
1395     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1396                 e.angles = AnglesTransform_ToVAngles(e.angles);
1397         else
1398                 e.angles = AnglesTransform_ToAngles(e.angles);
1399     setorigin(e, org);
1400     setattachment(e, NULL, "");
1401     setorigin(e, e.origin);
1402 }
1403
1404 void follow_sameorigin(entity e, entity to)
1405 {
1406     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1407     e.aiment = to; // make the hole follow bmodel
1408     e.punchangle = to.angles; // the original angles of bmodel
1409     e.view_ofs = e.origin - to.origin; // relative origin
1410     e.v_angle = e.angles - to.angles; // relative angles
1411 }
1412
1413 #if 0
1414 // TODO: unused, likely for a reason, possibly needs extensions (allow setting the new movetype as a parameter?)
1415 void unfollow_sameorigin(entity e)
1416 {
1417     set_movetype(e, MOVETYPE_NONE);
1418 }
1419 #endif
1420
1421 .string aiment_classname;
1422 .float aiment_deadflag;
1423 void SetMovetypeFollow(entity ent, entity e)
1424 {
1425         // FIXME this may not be warpzone aware
1426         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1427         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1428         ent.aiment = e; // make the hole follow bmodel
1429         ent.punchangle = e.angles; // the original angles of bmodel
1430         ent.view_ofs = ent.origin - e.origin; // relative origin
1431         ent.v_angle = ent.angles - e.angles; // relative angles
1432         ent.aiment_classname = strzone(e.classname);
1433         ent.aiment_deadflag = e.deadflag;
1434 }
1435 void UnsetMovetypeFollow(entity ent)
1436 {
1437         set_movetype(ent, MOVETYPE_FLY);
1438         PROJECTILE_MAKETRIGGER(ent);
1439         ent.aiment = NULL;
1440 }
1441 float LostMovetypeFollow(entity ent)
1442 {
1443 /*
1444         if(ent.move_movetype != MOVETYPE_FOLLOW)
1445                 if(ent.aiment)
1446                         error("???");
1447 */
1448         if(ent.aiment)
1449         {
1450                 if(ent.aiment.classname != ent.aiment_classname)
1451                         return 1;
1452                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1453                         return 1;
1454         }
1455         return 0;
1456 }
1457
1458 .bool pushable;
1459 bool isPushable(entity e)
1460 {
1461         if(e.pushable)
1462                 return true;
1463         if(IS_VEHICLE(e))
1464                 return false;
1465         if(e.iscreature)
1466                 return true;
1467         if (Item_IsLoot(e))
1468         {
1469                 return true;
1470         }
1471         switch(e.classname)
1472         {
1473                 case "body":
1474                         return true;
1475                 case "bullet": // antilagged bullets can't hit this either
1476                         return false;
1477         }
1478         if (e.projectiledeathtype)
1479                 return true;
1480         return false;
1481 }