qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 vector PL_VIEW_OFS;
 155 vector PL_MIN;
 156 vector PL_MAX;
 157 vector PL_HEAD;
 158 vector PL_CROUCH_VIEW_OFS;
 159 vector PL_CROUCH_MIN;
 160 vector PL_CROUCH_MAX;
 161
 162 float spawnpoint_nag;
 163 void relocate_spawnpoint()
 164 {
 165     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 166     PL_MIN                                  = stov(autocvar_sv_player_mins);
 167     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 168     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 169     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 170     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 171     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 172
 173     // nudge off the floor
 174     setorigin(self, self.origin + '0 0 1');
 175
 176     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 177     if (trace_startsolid)
 178     {
 179         vector o;
 180         o = self.origin;
 181         self.mins = PL_MIN;
 182         self.maxs = PL_MAX;
 183         if (!move_out_of_solid(self))
 184             objerror("could not get out of solid at all!");
 185         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 186         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 187         print(" ", ftos(self.origin_y - o_y));
 188         print(" ", ftos(self.origin_z - o_z), "'\n");
 189         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 190         {
 191             if (!spawnpoint_nag)
 192                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 193             spawnpoint_nag = 1;
 194         }
 195         else
 196         {
 197             setorigin(self, o);
 198             self.mins = self.maxs = '0 0 0';
 199             objerror("player spawn point in solid, mapper sucks!\n");
 200             return;
 201         }
 202     }
 203
 204     self.use = spawnpoint_use;
 205     self.team_saved = self.team;
 206     if (!self.cnt)
 207         self.cnt = 1;
 208
 209     if (have_team_spawns != 0)
 210         if (self.team)
 211             have_team_spawns = 1;
 212     have_team_spawns_forteam[self.team] = 1;
 213
 214     if (autocvar_r_showbboxes)
 215     {
 216         // show where spawnpoints point at too
 217         makevectors(self.angles);
 218         entity e;
 219         e = spawn();
 220         e.classname = "info_player_foo";
 221         setorigin(e, self.origin + v_forward * 24);
 222         setsize(e, '-8 -8 -8', '8 8 8');
 223         e.solid = SOLID_TRIGGER;
 224     }
 225 }
 226
 227 #define strstr strstrofs
 228 /*
 229 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 230 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 231 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 232 // BE CONSTANT OR strzoneD!
 233 float strstr(string haystack, string needle, float offset)
 234 {
 235         float len, endpos;
 236         string found;
 237         len = strlen(needle);
 238         endpos = strlen(haystack) - len;
 239         while(offset <= endpos)
 240         {
 241                 found = substring(haystack, offset, len);
 242                 if(found == needle)
 243                         return offset;
 244                 offset = offset + 1;
 245         }
 246         return -1;
 247 }
 248 */
 249
 250 float NUM_NEAREST_ENTITIES = 4;
 251 entity nearest_entity[NUM_NEAREST_ENTITIES];
 252 float nearest_length[NUM_NEAREST_ENTITIES];
 253 entity findnearest(vector point, .string field, string value, vector axismod)
 254 {
 255     entity localhead;
 256     float i;
 257     float j;
 258     float len;
 259     vector dist;
 260
 261     float num_nearest;
 262     num_nearest = 0;
 263
 264     localhead = find(world, field, value);
 265     while (localhead)
 266     {
 267         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 268             dist = localhead.oldorigin;
 269         else
 270             dist = localhead.origin;
 271         dist = dist - point;
 272         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 273         len = vlen(dist);
 274
 275         for (i = 0; i < num_nearest; ++i)
 276         {
 277             if (len < nearest_length[i])
 278                 break;
 279         }
 280
 281         // now i tells us where to insert at
 282         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 283         if (i < NUM_NEAREST_ENTITIES)
 284         {
 285             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 286             {
 287                 nearest_length[j + 1] = nearest_length[j];
 288                 nearest_entity[j + 1] = nearest_entity[j];
 289             }
 290             nearest_length[i] = len;
 291             nearest_entity[i] = localhead;
 292             if (num_nearest < NUM_NEAREST_ENTITIES)
 293                 num_nearest = num_nearest + 1;
 294         }
 295
 296         localhead = find(localhead, field, value);
 297     }
 298
 299     // now use the first one from our list that we can see
 300     for (i = 0; i < num_nearest; ++i)
 301     {
 302         traceline(point, nearest_entity[i].origin, TRUE, world);
 303         if (trace_fraction == 1)
 304         {
 305             if (i != 0)
 306             {
 307                 dprint("Nearest point (");
 308                 dprint(nearest_entity[0].netname);
 309                 dprint(") is not visible, using a visible one.\n");
 310             }
 311             return nearest_entity[i];
 312         }
 313     }
 314
 315     if (num_nearest == 0)
 316         return world;
 317
 318     dprint("Not seeing any location point, using nearest as fallback.\n");
 319     /* DEBUGGING CODE:
 320     dprint("Candidates were: ");
 321     for(j = 0; j < num_nearest; ++j)
 322     {
 323         if(j != 0)
 324                 dprint(", ");
 325         dprint(nearest_entity[j].netname);
 326     }
 327     dprint("\n");
 328     */
 329
 330     return nearest_entity[0];
 331 }
 332
 333 void spawnfunc_target_location()
 334 {
 335     self.classname = "target_location";
 336     // location name in netname
 337     // eventually support: count, teamgame selectors, line of sight?
 338 }
 339
 340 void spawnfunc_info_location()
 341 {
 342     self.classname = "target_location";
 343     self.message = self.netname;
 344 }
 345
 346 string NearestLocation(vector p)
 347 {
 348     entity loc;
 349     string ret;
 350     ret = "somewhere";
 351     loc = findnearest(p, classname, "target_location", '1 1 1');
 352     if (loc)
 353     {
 354         ret = loc.message;
 355     }
 356     else
 357     {
 358         loc = findnearest(p, target, "###item###", '1 1 4');
 359         if (loc)
 360             ret = loc.netname;
 361     }
 362     return ret;
 363 }
 364
 365 string formatmessage(string msg)
 366 {
 367         float p, p1, p2;
 368         float n;
 369         vector cursor;
 370         entity cursor_ent;
 371         string escape;
 372         string replacement;
 373         p = 0;
 374         n = 7;
 375
 376         WarpZone_crosshair_trace(self);
 377         cursor = trace_endpos;
 378         cursor_ent = trace_ent;
 379
 380         while (1) {
 381                 if (n < 1)
 382                         break; // too many replacements
 383
 384                 n = n - 1;
 385                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 386                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 387
 388                 if (p1 < 0)
 389                         p1 = p2;
 390
 391                 if (p2 < 0)
 392                         p2 = p1;
 393
 394                 p = min(p1, p2);
 395
 396                 if (p < 0)
 397                         break;
 398
 399                 replacement = substring(msg, p, 2);
 400                 escape = substring(msg, p + 1, 1);
 401
 402                 if (escape == "%")
 403                         replacement = "%";
 404                 else if (escape == "\\")
 405                         replacement = "\\";
 406                 else if (escape == "n")
 407                         replacement = "\n";
 408                 else if (escape == "a")
 409                         replacement = ftos(floor(self.armorvalue));
 410                 else if (escape == "h")
 411                         replacement = ftos(floor(self.health));
 412                 else if (escape == "l")
 413                         replacement = NearestLocation(self.origin);
 414                 else if (escape == "y")
 415                         replacement = NearestLocation(cursor);
 416                 else if (escape == "d")
 417                         replacement = NearestLocation(self.death_origin);
 418                 else if (escape == "w") {
 419                         float wep;
 420                         wep = self.weapon;
 421                         if (!wep)
 422                                 wep = self.switchweapon;
 423                         if (!wep)
 424                                 wep = self.cnt;
 425                         replacement = W_Name(wep);
 426                 } else if (escape == "W") {
 427                         if (self.items & IT_SHELLS) replacement = "shells";
 428                         else if (self.items & IT_NAILS) replacement = "bullets";
 429                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 430                         else if (self.items & IT_CELLS) replacement = "cells";
 431                         else replacement = "batteries"; // ;)
 432                 } else if (escape == "x") {
 433                         replacement = cursor_ent.netname;
 434                         if (!replacement || !cursor_ent)
 435                                 replacement = "nothing";
 436                 } else if (escape == "s")
 437                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 438                 else if (escape == "S")
 439                         replacement = ftos(vlen(self.velocity));
 440
 441                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 442                 p = p + strlen(replacement);
 443         }
 444         return msg;
 445 }
 446
 447 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 448         return (value == 0) ? FALSE : TRUE;
 449 }
 450
 451 /*
 452 =============
 453 GetCvars
 454 =============
 455 Called with:
 456   0:  sends the request
 457   >0: receives a cvar from name=argv(f) value=argv(f+1)
 458 */
 459 void GetCvars_handleString(string thisname, float f, .string field, string name)
 460 {
 461         if (f < 0)
 462         {
 463                 if (self.field)
 464                         strunzone(self.field);
 465                 self.field = string_null;
 466         }
 467         else if (f > 0)
 468         {
 469                 if (thisname == name)
 470                 {
 471                         if (self.field)
 472                                 strunzone(self.field);
 473                         self.field = strzone(argv(f + 1));
 474                 }
 475         }
 476         else
 477                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 478 }
 479 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 480 {
 481         GetCvars_handleString(thisname, f, field, name);
 482         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 483                 if (thisname == name)
 484                 {
 485                         string s;
 486                         s = func(strcat1(self.field));
 487                         if (s != self.field)
 488                         {
 489                                 strunzone(self.field);
 490                                 self.field = strzone(s);
 491                         }
 492                 }
 493 }
 494 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 495 {
 496         if (f < 0)
 497         {
 498         }
 499         else if (f > 0)
 500         {
 501                 if (thisname == name)
 502                         self.field = stof(argv(f + 1));
 503         }
 504         else
 505                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 506 }
 507 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 508 {
 509         if (f < 0)
 510         {
 511         }
 512         else if (f > 0)
 513         {
 514                 if (thisname == name)
 515                 {
 516                         if(!self.field)
 517                         {
 518                                 self.field = stof(argv(f + 1));
 519                                 if(!self.field)
 520                                         self.field = -1;
 521                         }
 522                 }
 523         }
 524         else
 525         {
 526                 if(!self.field)
 527                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 528         }
 529 }
 530 float w_getbestweapon(entity e);
 531 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 532 {
 533         string o;
 534         o = W_FixWeaponOrder_ForceComplete(wo);
 535         if(self.weaponorder_byimpulse)
 536         {
 537                 strunzone(self.weaponorder_byimpulse);
 538                 self.weaponorder_byimpulse = string_null;
 539         }
 540         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 541         return o;
 542 }
 543 void GetCvars(float f)
 544 {
 545         string s;
 546
 547         if (f > 0)
 548                 s = strcat1(argv(f));
 549
 550         get_cvars_f = f;
 551         get_cvars_s = s;
 552         MUTATOR_CALLHOOK(GetCvars);
 553         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 554         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 555         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 556         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 557         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 558         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 566         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 567         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 568         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 569         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 570         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 571         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 572         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 573         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 574         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 575         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 576         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 577
 578         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 579         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 580
 581 #ifdef ALLOW_FORCEMODELS
 582         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 583         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 584 #endif
 585         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 586         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 587         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 588         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 589         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 590
 591         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 592         if (f > 0)
 593         {
 594                 if (s == "cl_weaponpriority")
 595                         self.switchweapon = w_getbestweapon(self);
 596                 if (s == "cl_allow_uidtracking")
 597                         PlayerStats_AddPlayer(self);
 598         }
 599 }
 600
 601 void backtrace(string msg)
 602 {
 603     float dev, war;
 604     dev = autocvar_developer;
 605     war = autocvar_prvm_backtraceforwarnings;
 606     cvar_set("developer", "1");
 607     cvar_set("prvm_backtraceforwarnings", "1");
 608     print("\n");
 609     print("--- CUT HERE ---\nWARNING: ");
 610     print(msg);
 611     print("\n");
 612     remove(world); // isn't there any better way to cause a backtrace?
 613     print("\n--- CUT UNTIL HERE ---\n");
 614     cvar_set("developer", ftos(dev));
 615     cvar_set("prvm_backtraceforwarnings", ftos(war));
 616 }
 617
 618 string Team_ColorCode(float teamid)
 619 {
 620     if (teamid == COLOR_TEAM1)
 621         return "^1";
 622     else if (teamid == COLOR_TEAM2)
 623         return "^4";
 624     else if (teamid == COLOR_TEAM3)
 625         return "^3";
 626     else if (teamid == COLOR_TEAM4)
 627         return "^6";
 628     else
 629         return "^7";
 630 }
 631
 632 string Team_ColorName(float t)
 633 {
 634     // fixme: Search for team entities and get their .netname's!
 635     if (t == COLOR_TEAM1)
 636         return "Red";
 637     if (t == COLOR_TEAM2)
 638         return "Blue";
 639     if (t == COLOR_TEAM3)
 640         return "Yellow";
 641     if (t == COLOR_TEAM4)
 642         return "Pink";
 643     return "Neutral";
 644 }
 645
 646 string Team_ColorNameLowerCase(float t)
 647 {
 648     // fixme: Search for team entities and get their .netname's!
 649     if (t == COLOR_TEAM1)
 650         return "red";
 651     if (t == COLOR_TEAM2)
 652         return "blue";
 653     if (t == COLOR_TEAM3)
 654         return "yellow";
 655     if (t == COLOR_TEAM4)
 656         return "pink";
 657     return "neutral";
 658 }
 659
 660 float ColourToNumber(string team_colour)
 661 {
 662         if (team_colour == "red")
 663                 return COLOR_TEAM1;
 664
 665         if (team_colour == "blue")
 666                 return COLOR_TEAM2;
 667
 668         if (team_colour == "yellow")
 669                 return COLOR_TEAM3;
 670
 671         if (team_colour == "pink")
 672                 return COLOR_TEAM4;
 673
 674         if (team_colour == "auto")
 675                 return 0;
 676
 677         return -1;
 678 }
 679
 680 float NumberToTeamNumber(float number)
 681 {
 682         if (number == 1)
 683                 return COLOR_TEAM1;
 684
 685         if (number == 2)
 686                 return COLOR_TEAM2;
 687
 688         if (number == 3)
 689                 return COLOR_TEAM3;
 690
 691         if (number == 4)
 692                 return COLOR_TEAM4;
 693
 694         return -1;
 695 }
 696
 697 // decolorizes and team colors the player name when needed
 698 string playername(entity p)
 699 {
 700     string t;
 701     if (teamplay && !intermission_running && p.classname == "player")
 702     {
 703         t = Team_ColorCode(p.team);
 704         return strcat(t, strdecolorize(p.netname));
 705     }
 706     else
 707         return p.netname;
 708 }
 709
 710 vector randompos(vector m1, vector m2)
 711 {
 712     vector v;
 713     m2 = m2 - m1;
 714     v_x = m2_x * random() + m1_x;
 715     v_y = m2_y * random() + m1_y;
 716     v_z = m2_z * random() + m1_z;
 717     return  v;
 718 }
 719
 720 //#NO AUTOCVARS START
 721
 722 float g_pickup_shells;
 723 float g_pickup_shells_max;
 724 float g_pickup_nails;
 725 float g_pickup_nails_max;
 726 float g_pickup_rockets;
 727 float g_pickup_rockets_max;
 728 float g_pickup_cells;
 729 float g_pickup_cells_max;
 730 float g_pickup_fuel;
 731 float g_pickup_fuel_jetpack;
 732 float g_pickup_fuel_max;
 733 float g_pickup_armorsmall;
 734 float g_pickup_armorsmall_max;
 735 float g_pickup_armorsmall_anyway;
 736 float g_pickup_armormedium;
 737 float g_pickup_armormedium_max;
 738 float g_pickup_armormedium_anyway;
 739 float g_pickup_armorbig;
 740 float g_pickup_armorbig_max;
 741 float g_pickup_armorbig_anyway;
 742 float g_pickup_armorlarge;
 743 float g_pickup_armorlarge_max;
 744 float g_pickup_armorlarge_anyway;
 745 float g_pickup_healthsmall;
 746 float g_pickup_healthsmall_max;
 747 float g_pickup_healthsmall_anyway;
 748 float g_pickup_healthmedium;
 749 float g_pickup_healthmedium_max;
 750 float g_pickup_healthmedium_anyway;
 751 float g_pickup_healthlarge;
 752 float g_pickup_healthlarge_max;
 753 float g_pickup_healthlarge_anyway;
 754 float g_pickup_healthmega;
 755 float g_pickup_healthmega_max;
 756 float g_pickup_healthmega_anyway;
 757 float g_pickup_ammo_anyway;
 758 float g_pickup_weapons_anyway;
 759 float g_weaponarena;
 760 float g_weaponarena_random;
 761 float g_weaponarena_random_with_laser;
 762 string g_weaponarena_list;
 763 float g_weaponspeedfactor;
 764 float g_weaponratefactor;
 765 float g_weapondamagefactor;
 766 float g_weaponforcefactor;
 767 float g_weaponspreadfactor;
 768
 769 float start_weapons;
 770 float start_items;
 771 float start_ammo_shells;
 772 float start_ammo_nails;
 773 float start_ammo_rockets;
 774 float start_ammo_cells;
 775 float start_ammo_fuel;
 776 float start_health;
 777 float start_armorvalue;
 778 float warmup_start_weapons;
 779 float warmup_start_ammo_shells;
 780 float warmup_start_ammo_nails;
 781 float warmup_start_ammo_rockets;
 782 float warmup_start_ammo_cells;
 783 float warmup_start_ammo_fuel;
 784 float warmup_start_health;
 785 float warmup_start_armorvalue;
 786 float g_weapon_stay;
 787 float g_ghost_items;
 788
 789 entity get_weaponinfo(float w);
 790
 791 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 792 {
 793         var float i = weaponinfo.weapon;
 794
 795         if (!i)
 796                 return 0;
 797
 798         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 799
 800         if (t < 0) // "default" weapon selection
 801         {
 802                 if (g_lms || g_ca || allguns)
 803                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 804                 else if(t < -1)
 805                         t = 0;
 806                 else if (g_cts)
 807                         t = (i == WEP_SHOTGUN);
 808                 else if (g_nexball)
 809                         t = 0; // weapon is set a few lines later
 810                 else
 811                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 812                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 813                         t |= (i == WEP_HOOK);
 814         }
 815
 816         // we cannot disable porto in Nexball, we must force it
 817         if(g_nexball && i == WEP_PORTO)
 818                 t = 1;
 819
 820         return t;
 821 }
 822
 823 void readplayerstartcvars()
 824 {
 825         entity e;
 826         float i, j, t;
 827         string s;
 828
 829         // initialize starting values for players
 830         start_weapons = 0;
 831         start_items = 0;
 832         start_ammo_shells = 0;
 833         start_ammo_nails = 0;
 834         start_ammo_rockets = 0;
 835         start_ammo_cells = 0;
 836         start_health = cvar("g_balance_health_start");
 837         start_armorvalue = cvar("g_balance_armor_start");
 838
 839         g_weaponarena = 0;
 840         s = cvar_string("g_weaponarena");
 841         if (s == "0" || s == "")
 842         {
 843                 if(g_lms || g_ca)
 844                         s = "most";
 845         }
 846
 847         if (s == "0" || s == "")
 848         {
 849                 // no arena
 850         }
 851         else if (s == "off")
 852         {
 853                 // forcibly turn off weaponarena
 854         }
 855         else if (s == "all")
 856         {
 857                 g_weaponarena_list = "All Weapons";
 858                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 859                 {
 860                         e = get_weaponinfo(j);
 861                         g_weaponarena |= e.weapons;
 862                         weapon_action(e.weapon, WR_PRECACHE);
 863                 }
 864         }
 865         else if (s == "most")
 866         {
 867                 g_weaponarena_list = "Most Weapons";
 868                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 869                 {
 870                         e = get_weaponinfo(j);
 871                         if (e.spawnflags & WEP_FLAG_NORMAL)
 872                         {
 873                                 g_weaponarena |= e.weapons;
 874                                 weapon_action(e.weapon, WR_PRECACHE);
 875                         }
 876                 }
 877         }
 878         else if (s == "none")
 879         {
 880                 g_weaponarena_list = "No Weapons";
 881                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 882         }
 883         else
 884         {
 885                 t = tokenize_console(s);
 886                 g_weaponarena_list = "";
 887                 for (i = 0; i < t; ++i)
 888                 {
 889                         s = argv(i);
 890                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 891                         {
 892                                 e = get_weaponinfo(j);
 893                                 if (e.netname == s)
 894                                 {
 895                                         g_weaponarena |= e.weapons;
 896                                         weapon_action(e.weapon, WR_PRECACHE);
 897                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 898                                         break;
 899                                 }
 900                         }
 901                         if (j > WEP_LAST)
 902                         {
 903                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 904                         }
 905                 }
 906                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 907         }
 908
 909         if(g_weaponarena)
 910                 g_weaponarena_random = cvar("g_weaponarena_random");
 911         else
 912                 g_weaponarena_random = 0;
 913         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 914
 915         if (g_weaponarena)
 916         {
 917                 start_weapons = g_weaponarena;
 918                 if(!(g_lms || g_ca))
 919                         start_items |= IT_UNLIMITED_AMMO;
 920         }
 921         else if (g_minstagib)
 922         {
 923                 start_health = 100;
 924                 start_armorvalue = 0;
 925                 start_weapons = WEPBIT_MINSTANEX;
 926                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 927                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 928
 929                 if (g_minstagib_invis_alpha <= 0)
 930                         g_minstagib_invis_alpha = -1;
 931         }
 932         else
 933         {
 934                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 935                 {
 936                         e = get_weaponinfo(i);
 937                         if(want_weapon("g_start_weapon_", e, FALSE))
 938                                 start_weapons |= e.weapons;
 939                 }
 940         }
 941
 942         if(!cvar("g_use_ammunition"))
 943                 start_items |= IT_UNLIMITED_AMMO;
 944
 945         if(g_minstagib)
 946         {
 947                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 948                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 949         }
 950         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 951         {
 952                 start_ammo_rockets = 999;
 953                 start_ammo_shells = 999;
 954                 start_ammo_cells = 999;
 955                 start_ammo_nails = 999;
 956                 start_ammo_fuel = 999;
 957         }
 958         else
 959         {
 960                 if(g_lms || g_ca)
 961                 {
 962                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 963                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 964                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 965                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 966                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 967                 }
 968                 else
 969                 {
 970                         start_ammo_shells = cvar("g_start_ammo_shells");
 971                         start_ammo_nails = cvar("g_start_ammo_nails");
 972                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 973                         start_ammo_cells = cvar("g_start_ammo_cells");
 974                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 975                 }
 976         }
 977
 978         if (g_lms || g_ca)
 979         {
 980                 start_health = cvar("g_lms_start_health");
 981                 start_armorvalue = cvar("g_lms_start_armor");
 982         }
 983
 984         if (inWarmupStage)
 985         {
 986                 warmup_start_ammo_shells = start_ammo_shells;
 987                 warmup_start_ammo_nails = start_ammo_nails;
 988                 warmup_start_ammo_rockets = start_ammo_rockets;
 989                 warmup_start_ammo_cells = start_ammo_cells;
 990                 warmup_start_ammo_fuel = start_ammo_fuel;
 991                 warmup_start_health = start_health;
 992                 warmup_start_armorvalue = start_armorvalue;
 993                 warmup_start_weapons = start_weapons;
 994
 995                 if (!g_weaponarena && !g_minstagib && !g_ca)
 996                 {
 997                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 998                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 999                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1000                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1001                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1002                         warmup_start_health = cvar("g_warmup_start_health");
1003                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1004                         warmup_start_weapons = 0;
1005                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1006                         {
1007                                 e = get_weaponinfo(i);
1008                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1009                                         warmup_start_weapons |= e.weapons;
1010                         }
1011                 }
1012         }
1013
1014         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1015         {
1016                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1017                 start_items |= IT_FUEL_REGEN;
1018                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1019                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1020         }
1021
1022         if (g_jetpack)
1023                 start_items |= IT_JETPACK;
1024
1025         if (g_weapon_stay == 2)
1026         {
1027                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1028                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1029                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1030                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1031                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1032                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1033                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1034                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1035                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1036                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1037         }
1038
1039         MUTATOR_CALLHOOK(SetStartItems);
1040
1041         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1042         {
1043                 e = get_weaponinfo(i);
1044                 if(e.weapons & (start_weapons | warmup_start_weapons))
1045                         weapon_action(e.weapon, WR_PRECACHE);
1046         }
1047
1048         start_ammo_shells = max(0, start_ammo_shells);
1049         start_ammo_nails = max(0, start_ammo_nails);
1050         start_ammo_cells = max(0, start_ammo_cells);
1051         start_ammo_rockets = max(0, start_ammo_rockets);
1052         start_ammo_fuel = max(0, start_ammo_fuel);
1053
1054         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1055         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1056         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1057         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1058         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1059 }
1060
1061 float g_bugrigs;
1062 float g_bugrigs_planar_movement;
1063 float g_bugrigs_planar_movement_car_jumping;
1064 float g_bugrigs_reverse_spinning;
1065 float g_bugrigs_reverse_speeding;
1066 float g_bugrigs_reverse_stopping;
1067 float g_bugrigs_air_steering;
1068 float g_bugrigs_angle_smoothing;
1069 float g_bugrigs_friction_floor;
1070 float g_bugrigs_friction_brake;
1071 float g_bugrigs_friction_air;
1072 float g_bugrigs_accel;
1073 float g_bugrigs_speed_ref;
1074 float g_bugrigs_speed_pow;
1075 float g_bugrigs_steer;
1076
1077 float g_touchexplode;
1078 float g_touchexplode_radius;
1079 float g_touchexplode_damage;
1080 float g_touchexplode_edgedamage;
1081 float g_touchexplode_force;
1082
1083 float sv_autotaunt;
1084 float sv_taunt;
1085
1086 float sv_pitch_min;
1087 float sv_pitch_max;
1088 float sv_pitch_fixyaw;
1089
1090 string GetGametype(); // g_world.qc
1091 void readlevelcvars(void)
1092 {
1093         // first load all the mutators
1094         if(cvar("g_invincible_projectiles"))
1095                 MUTATOR_ADD(mutator_invincibleprojectiles);
1096         if(cvar("g_nix"))
1097                 MUTATOR_ADD(mutator_nix);
1098         if(cvar("g_dodging"))
1099                 MUTATOR_ADD(mutator_dodging);
1100         if(cvar("g_rocket_flying"))
1101                 MUTATOR_ADD(mutator_rocketflying);
1102         if(cvar("g_vampire"))
1103                 MUTATOR_ADD(mutator_vampire);
1104         if(cvar("g_spawn_near_teammate"))
1105                 MUTATOR_ADD(mutator_spawn_near_teammate);
1106
1107         // is this a mutator? is this a mode?
1108         if(cvar("g_sandbox"))
1109                 MUTATOR_ADD(sandbox);
1110
1111         if(cvar("sv_allow_fullbright"))
1112                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1113
1114     g_bugrigs = cvar("g_bugrigs");
1115     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1116     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1117     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1118     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1119     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1120     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1121     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1122     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1123     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1124     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1125     g_bugrigs_accel = cvar("g_bugrigs_accel");
1126     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1127     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1128     g_bugrigs_steer = cvar("g_bugrigs_steer");
1129
1130     g_touchexplode = cvar("g_touchexplode");
1131     g_touchexplode_radius = cvar("g_touchexplode_radius");
1132     g_touchexplode_damage = cvar("g_touchexplode_damage");
1133     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1134     g_touchexplode_force = cvar("g_touchexplode_force");
1135
1136 #ifdef ALLOW_FORCEMODELS
1137         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1138 #endif
1139         sv_loddistance1 = cvar("sv_loddistance1");
1140         sv_loddistance2 = cvar("sv_loddistance2");
1141
1142         if(sv_loddistance2 <= sv_loddistance1)
1143                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1144
1145         sv_clones = cvar("sv_clones");
1146         sv_gentle = cvar("sv_gentle");
1147         sv_foginterval = cvar("sv_foginterval");
1148         g_cloaked = cvar("g_cloaked");
1149     if(g_cts)
1150         g_cloaked = 1; // always enable cloak in CTS
1151         g_jump_grunt = cvar("g_jump_grunt");
1152         g_footsteps = cvar("g_footsteps");
1153         g_grappling_hook = cvar("g_grappling_hook");
1154         g_jetpack = cvar("g_jetpack");
1155         g_midair = cvar("g_midair");
1156         g_minstagib = cvar("g_minstagib");
1157         g_norecoil = cvar("g_norecoil");
1158         g_bloodloss = cvar("g_bloodloss");
1159         sv_maxidle = cvar("sv_maxidle");
1160         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1161         g_ctf_reverse = cvar("g_ctf_reverse");
1162         sv_autotaunt = cvar("sv_autotaunt");
1163         sv_taunt = cvar("sv_taunt");
1164
1165         inWarmupStage = cvar("g_warmup");
1166         g_warmup_limit = cvar("g_warmup_limit");
1167         g_warmup_allguns = cvar("g_warmup_allguns");
1168         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1169
1170         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1171                 inWarmupStage = 0; // these modes cannot work together, sorry
1172
1173         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1174         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1175         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1176         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1177         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1178         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1179         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1180         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1181         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1182         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1183         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1184         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1185
1186         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1187         g_weaponratefactor = cvar("g_weaponratefactor");
1188         g_weapondamagefactor = cvar("g_weapondamagefactor");
1189         g_weaponforcefactor = cvar("g_weaponforcefactor");
1190         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1191
1192         g_pickup_shells = cvar("g_pickup_shells");
1193         g_pickup_shells_max = cvar("g_pickup_shells_max");
1194         g_pickup_nails = cvar("g_pickup_nails");
1195         g_pickup_nails_max = cvar("g_pickup_nails_max");
1196         g_pickup_rockets = cvar("g_pickup_rockets");
1197         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1198         g_pickup_cells = cvar("g_pickup_cells");
1199         g_pickup_cells_max = cvar("g_pickup_cells_max");
1200         g_pickup_fuel = cvar("g_pickup_fuel");
1201         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1202         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1203         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1204         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1205         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1206         g_pickup_armormedium = cvar("g_pickup_armormedium");
1207         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1208         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1209         g_pickup_armorbig = cvar("g_pickup_armorbig");
1210         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1211         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1212         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1213         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1214         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1215         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1216         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1217         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1218         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1219         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1220         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1221         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1222         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1223         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1224         g_pickup_healthmega = cvar("g_pickup_healthmega");
1225         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1226         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1227
1228         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1229         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1230
1231         g_pinata = cvar("g_pinata");
1232
1233     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1234     if(!g_weapon_stay)
1235         g_weapon_stay = cvar("g_weapon_stay");
1236
1237         g_ghost_items = cvar("g_ghost_items");
1238
1239         if(g_ghost_items >= 1)
1240                 g_ghost_items = 0.25; // default alpha value
1241
1242         if not(inWarmupStage && !g_ca)
1243                 game_starttime = cvar("g_start_delay");
1244
1245         sv_pitch_min = cvar("sv_pitch_min");
1246         sv_pitch_max = cvar("sv_pitch_max");
1247         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1248
1249         readplayerstartcvars();
1250 }
1251
1252 //#NO AUTOCVARS END
1253
1254 // Sound functions
1255 string precache_sound (string s) = #19;
1256 float precache_sound_index (string s) = #19;
1257
1258 #define SND_VOLUME      1
1259 #define SND_ATTENUATION 2
1260 #define SND_LARGEENTITY 8
1261 #define SND_LARGESOUND  16
1262
1263 float sound_allowed(float dest, entity e)
1264 {
1265     // sounds from world may always pass
1266     for (;;)
1267     {
1268         if (e.classname == "body")
1269             e = e.enemy;
1270         else if (e.realowner && e.realowner != e)
1271             e = e.realowner;
1272         else if (e.owner && e.owner != e)
1273             e = e.owner;
1274         else
1275             break;
1276     }
1277     // sounds to self may always pass
1278     if (dest == MSG_ONE)
1279         if (e == msg_entity)
1280             return TRUE;
1281     // sounds by players can be removed
1282     if (autocvar_bot_sound_monopoly)
1283         if (clienttype(e) == CLIENTTYPE_REAL)
1284             return FALSE;
1285     // anything else may pass
1286     return TRUE;
1287 }
1288
1289 #ifdef COMPAT_XON010_CHANNELS
1290 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1291 void sound(entity e, float chan, string samp, float vol, float atten)
1292 {
1293     if (!sound_allowed(MSG_BROADCAST, e))
1294         return;
1295     builtin_sound(e, chan, samp, vol, atten);
1296 }
1297 #else
1298 #undef sound
1299 void sound(entity e, float chan, string samp, float vol, float atten)
1300 {
1301     if (!sound_allowed(MSG_BROADCAST, e))
1302         return;
1303     sound7(e, chan, samp, vol, atten, 0, 0);
1304 }
1305 #endif
1306
1307 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1308 {
1309     float entno, idx;
1310
1311     if (!sound_allowed(dest, e))
1312         return;
1313
1314     entno = num_for_edict(e);
1315     idx = precache_sound_index(samp);
1316
1317     float sflags;
1318     sflags = 0;
1319
1320     atten = floor(atten * 64);
1321     vol = floor(vol * 255);
1322
1323     if (vol != 255)
1324         sflags |= SND_VOLUME;
1325     if (atten != 64)
1326         sflags |= SND_ATTENUATION;
1327     if (entno >= 8192 || chan < 0 || chan > 7)
1328         sflags |= SND_LARGEENTITY;
1329     if (idx >= 256)
1330         sflags |= SND_LARGESOUND;
1331
1332     WriteByte(dest, SVC_SOUND);
1333     WriteByte(dest, sflags);
1334     if (sflags & SND_VOLUME)
1335         WriteByte(dest, vol);
1336     if (sflags & SND_ATTENUATION)
1337         WriteByte(dest, atten);
1338     if (sflags & SND_LARGEENTITY)
1339     {
1340         WriteShort(dest, entno);
1341         WriteByte(dest, chan);
1342     }
1343     else
1344     {
1345         WriteShort(dest, entno * 8 + chan);
1346     }
1347     if (sflags & SND_LARGESOUND)
1348         WriteShort(dest, idx);
1349     else
1350         WriteByte(dest, idx);
1351
1352     WriteCoord(dest, o_x);
1353     WriteCoord(dest, o_y);
1354     WriteCoord(dest, o_z);
1355 }
1356 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1357 {
1358     vector o;
1359
1360     if (!sound_allowed(dest, e))
1361         return;
1362
1363     o = e.origin + 0.5 * (e.mins + e.maxs);
1364     soundtoat(dest, e, o, chan, samp, vol, atten);
1365 }
1366 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1367 {
1368     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1369 }
1370 void stopsoundto(float dest, entity e, float chan)
1371 {
1372     float entno;
1373
1374     if (!sound_allowed(dest, e))
1375         return;
1376
1377     entno = num_for_edict(e);
1378
1379     if (entno >= 8192 || chan < 0 || chan > 7)
1380     {
1381         float idx, sflags;
1382         idx = precache_sound_index("misc/null.wav");
1383         sflags = SND_LARGEENTITY;
1384         if (idx >= 256)
1385             sflags |= SND_LARGESOUND;
1386         WriteByte(dest, SVC_SOUND);
1387         WriteByte(dest, sflags);
1388         WriteShort(dest, entno);
1389         WriteByte(dest, chan);
1390         if (sflags & SND_LARGESOUND)
1391             WriteShort(dest, idx);
1392         else
1393             WriteByte(dest, idx);
1394         WriteCoord(dest, e.origin_x);
1395         WriteCoord(dest, e.origin_y);
1396         WriteCoord(dest, e.origin_z);
1397     }
1398     else
1399     {
1400         WriteByte(dest, SVC_STOPSOUND);
1401         WriteShort(dest, entno * 8 + chan);
1402     }
1403 }
1404 void stopsound(entity e, float chan)
1405 {
1406     if (!sound_allowed(MSG_BROADCAST, e))
1407         return;
1408
1409     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1410     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1411 }
1412
1413 void play2(entity e, string filename)
1414 {
1415     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1416     msg_entity = e;
1417     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1418 }
1419
1420 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1421 .float spamtime;
1422 float spamsound(entity e, float chan, string samp, float vol, float atten)
1423 {
1424     if (!sound_allowed(MSG_BROADCAST, e))
1425         return FALSE;
1426
1427     if (time > e.spamtime)
1428     {
1429         e.spamtime = time;
1430         sound(e, chan, samp, vol, atten);
1431         return TRUE;
1432     }
1433     return FALSE;
1434 }
1435
1436 void play2team(float t, string filename)
1437 {
1438     entity head;
1439
1440     if (autocvar_bot_sound_monopoly)
1441         return;
1442
1443     FOR_EACH_REALPLAYER(head)
1444     {
1445         if (head.team == t)
1446             play2(head, filename);
1447     }
1448 }
1449
1450 void play2all(string samp)
1451 {
1452     if (autocvar_bot_sound_monopoly)
1453         return;
1454
1455     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1456 }
1457
1458 void PrecachePlayerSounds(string f);
1459 void precache_playermodel(string m)
1460 {
1461         float globhandle, i, n;
1462         string f;
1463
1464         if(substring(m, -9,5) == "_lod1")
1465                 return;
1466         if(substring(m, -9,5) == "_lod2")
1467                 return;
1468         precache_model(m);
1469         if(sv_loddistance1)
1470         {
1471                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1472                 if(fexists(f))
1473                         precache_model(f);
1474                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1475                 if(fexists(f))
1476                         precache_model(f);
1477         }
1478
1479         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1480         if (globhandle < 0)
1481                 return;
1482         n = search_getsize(globhandle);
1483         for (i = 0; i < n; ++i)
1484         {
1485                 //print(search_getfilename(globhandle, i), "\n");
1486                 f = search_getfilename(globhandle, i);
1487                 PrecachePlayerSounds(f);
1488         }
1489         search_end(globhandle);
1490 }
1491 void precache_all_playermodels(string pattern)
1492 {
1493         float globhandle, i, n;
1494         string f;
1495
1496         globhandle = search_begin(pattern, TRUE, FALSE);
1497         if (globhandle < 0)
1498                 return;
1499         n = search_getsize(globhandle);
1500         for (i = 0; i < n; ++i)
1501         {
1502                 //print(search_getfilename(globhandle, i), "\n");
1503                 f = search_getfilename(globhandle, i);
1504                 precache_playermodel(f);
1505         }
1506         search_end(globhandle);
1507 }
1508
1509 void precache()
1510 {
1511     // gamemode related things
1512     precache_model ("models/misc/chatbubble.spr");
1513     if (g_runematch)
1514     {
1515         precache_model ("models/runematch/curse.mdl");
1516         precache_model ("models/runematch/rune.mdl");
1517     }
1518
1519 #ifdef TTURRETS_ENABLED
1520     if (autocvar_g_turrets)
1521         turrets_precash();
1522 #endif
1523
1524     // Precache all player models if desired
1525     if (autocvar_sv_precacheplayermodels)
1526     {
1527         PrecachePlayerSounds("sound/player/default.sounds");
1528         precache_all_playermodels("models/player/*.zym");
1529         precache_all_playermodels("models/player/*.dpm");
1530         precache_all_playermodels("models/player/*.md3");
1531         precache_all_playermodels("models/player/*.psk");
1532         precache_all_playermodels("models/player/*.iqm");
1533     }
1534
1535     if (autocvar_sv_defaultcharacter)
1536     {
1537         string s;
1538         s = autocvar_sv_defaultplayermodel_red;
1539         if (s != "")
1540             precache_playermodel(s);
1541         s = autocvar_sv_defaultplayermodel_blue;
1542         if (s != "")
1543             precache_playermodel(s);
1544         s = autocvar_sv_defaultplayermodel_yellow;
1545         if (s != "")
1546             precache_playermodel(s);
1547         s = autocvar_sv_defaultplayermodel_pink;
1548         if (s != "")
1549             precache_playermodel(s);
1550         s = autocvar_sv_defaultplayermodel;
1551         if (s != "")
1552             precache_playermodel(s);
1553     }
1554
1555     if (g_footsteps)
1556     {
1557         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1558         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1559     }
1560
1561     // gore and miscellaneous sounds
1562     //precache_sound ("misc/h2ohit.wav");
1563     precache_model ("models/hook.md3");
1564     precache_sound ("misc/armorimpact.wav");
1565     precache_sound ("misc/bodyimpact1.wav");
1566     precache_sound ("misc/bodyimpact2.wav");
1567     precache_sound ("misc/gib.wav");
1568     precache_sound ("misc/gib_splat01.wav");
1569     precache_sound ("misc/gib_splat02.wav");
1570     precache_sound ("misc/gib_splat03.wav");
1571     precache_sound ("misc/gib_splat04.wav");
1572     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1573     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1574     precache_sound ("misc/null.wav");
1575     precache_sound ("misc/spawn.wav");
1576     precache_sound ("misc/talk.wav");
1577     precache_sound ("misc/teleport.wav");
1578     precache_sound ("misc/poweroff.wav");
1579     precache_sound ("player/lava.wav");
1580     precache_sound ("player/slime.wav");
1581
1582     if (g_jetpack)
1583         precache_sound ("misc/jetpack_fly.wav");
1584
1585     precache_model ("models/sprites/0.spr32");
1586     precache_model ("models/sprites/1.spr32");
1587     precache_model ("models/sprites/2.spr32");
1588     precache_model ("models/sprites/3.spr32");
1589     precache_model ("models/sprites/4.spr32");
1590     precache_model ("models/sprites/5.spr32");
1591     precache_model ("models/sprites/6.spr32");
1592     precache_model ("models/sprites/7.spr32");
1593     precache_model ("models/sprites/8.spr32");
1594     precache_model ("models/sprites/9.spr32");
1595     precache_model ("models/sprites/10.spr32");
1596
1597     // common weapon precaches
1598         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1599     precache_sound ("weapons/weapon_switch.wav");
1600     precache_sound ("weapons/weaponpickup.wav");
1601     precache_sound ("weapons/unavailable.wav");
1602     precache_sound ("weapons/dryfire.wav");
1603     if (g_grappling_hook)
1604     {
1605         precache_sound ("weapons/hook_fire.wav"); // hook
1606         precache_sound ("weapons/hook_impact.wav"); // hook
1607     }
1608
1609     if(autocvar_sv_precacheweapons)
1610     {
1611         //precache weapon models/sounds
1612         float wep;
1613         wep = WEP_FIRST;
1614         while (wep <= WEP_LAST)
1615         {
1616             weapon_action(wep, WR_PRECACHE);
1617             wep = wep + 1;
1618         }
1619     }
1620
1621     precache_model("models/elaser.mdl");
1622     precache_model("models/laser.mdl");
1623     precache_model("models/ebomb.mdl");
1624
1625 #if 0
1626     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1627
1628     if (!self.noise && self.music) // quake 3 uses the music field
1629         self.noise = self.music;
1630
1631     // plays music for the level if there is any
1632     if (self.noise)
1633     {
1634         precache_sound (self.noise);
1635         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1636     }
1637 #endif
1638 }
1639
1640 // sorry, but using \ in macros breaks line numbers
1641 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1642 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1643 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1644
1645
1646 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1647 {
1648         if (clienttype(e) == CLIENTTYPE_REAL)
1649         {
1650                 msg_entity = e;
1651                 WRITESPECTATABLE_MSG_ONE({
1652                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1653                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1654                         WriteByte(MSG_ONE, id);
1655                         WriteString(MSG_ONE, s);
1656                         if (id != 0 && s != "")
1657                         {
1658                                 WriteByte(MSG_ONE, duration);
1659                                 WriteByte(MSG_ONE, countdown_num);
1660                         }
1661                 });
1662         }
1663 }
1664 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1665 {
1666         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1667 }
1668 // WARNING: this kills the trace globals
1669 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1670 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1671
1672 #define INITPRIO_FIRST              0
1673 #define INITPRIO_GAMETYPE           0
1674 #define INITPRIO_GAMETYPE_FALLBACK  1
1675 #define INITPRIO_FINDTARGET        10
1676 #define INITPRIO_DROPTOFLOOR       20
1677 #define INITPRIO_SETLOCATION       90
1678 #define INITPRIO_LINKDOORS         91
1679 #define INITPRIO_LAST              99
1680
1681 .void(void) initialize_entity;
1682 .float initialize_entity_order;
1683 .entity initialize_entity_next;
1684 entity initialize_entity_first;
1685
1686 void make_safe_for_remove(entity e)
1687 {
1688     if (e.initialize_entity)
1689     {
1690         entity ent, prev;
1691         for (ent = initialize_entity_first; ent; )
1692         {
1693             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1694             {
1695                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1696                 // skip it in linked list
1697                 if (prev)
1698                 {
1699                     prev.initialize_entity_next = ent.initialize_entity_next;
1700                     ent = prev.initialize_entity_next;
1701                 }
1702                 else
1703                 {
1704                     initialize_entity_first = ent.initialize_entity_next;
1705                     ent = initialize_entity_first;
1706                 }
1707             }
1708             else
1709             {
1710                 prev = ent;
1711                 ent = ent.initialize_entity_next;
1712             }
1713         }
1714     }
1715 }
1716
1717 void objerror(string s)
1718 {
1719     make_safe_for_remove(self);
1720     builtin_objerror(s);
1721 }
1722
1723 .float remove_except_protected_forbidden;
1724 void remove_except_protected(entity e)
1725 {
1726         if(e.remove_except_protected_forbidden)
1727                 error("not allowed to remove this at this point");
1728         builtin_remove(e);
1729 }
1730
1731 void remove_unsafely(entity e)
1732 {
1733     if(e.classname == "spike")
1734         error("Removing spikes is forbidden (crylink bug), please report");
1735     builtin_remove(e);
1736 }
1737
1738 void remove_safely(entity e)
1739 {
1740     make_safe_for_remove(e);
1741     builtin_remove(e);
1742 }
1743
1744 void InitializeEntity(entity e, void(void) func, float order)
1745 {
1746     entity prev, cur;
1747
1748     if (!e || e.initialize_entity)
1749     {
1750         // make a proxy initializer entity
1751         entity e_old;
1752         e_old = e;
1753         e = spawn();
1754         e.classname = "initialize_entity";
1755         e.enemy = e_old;
1756     }
1757
1758     e.initialize_entity = func;
1759     e.initialize_entity_order = order;
1760
1761     cur = initialize_entity_first;
1762     for (;;)
1763     {
1764         if (!cur || cur.initialize_entity_order > order)
1765         {
1766             // insert between prev and cur
1767             if (prev)
1768                 prev.initialize_entity_next = e;
1769             else
1770                 initialize_entity_first = e;
1771             e.initialize_entity_next = cur;
1772             return;
1773         }
1774         prev = cur;
1775         cur = cur.initialize_entity_next;
1776     }
1777 }
1778 void InitializeEntitiesRun()
1779 {
1780     entity startoflist;
1781     startoflist = initialize_entity_first;
1782     initialize_entity_first = world;
1783     remove = remove_except_protected;
1784     for (self = startoflist; self; self = self.initialize_entity_next)
1785     {
1786         self.remove_except_protected_forbidden = 1;
1787     }
1788     for (self = startoflist; self; )
1789     {
1790         entity e;
1791         var void(void) func;
1792         e = self.initialize_entity_next;
1793         func = self.initialize_entity;
1794         self.initialize_entity_order = 0;
1795         self.initialize_entity = func_null;
1796         self.initialize_entity_next = world;
1797         self.remove_except_protected_forbidden = 0;
1798         if (self.classname == "initialize_entity")
1799         {
1800             entity e_old;
1801             e_old = self.enemy;
1802             builtin_remove(self);
1803             self = e_old;
1804         }
1805         //dprint("Delayed initialization: ", self.classname, "\n");
1806         if(func != func_null)
1807             func();
1808         else
1809         {
1810             eprint(self);
1811             backtrace(strcat("Null function in: ", self.classname, "\n"));
1812         }
1813         self = e;
1814     }
1815     remove = remove_unsafely;
1816 }
1817
1818 .float uncustomizeentityforclient_set;
1819 .void(void) uncustomizeentityforclient;
1820 void(void) SUB_Nullpointer = #0;
1821 void UncustomizeEntitiesRun()
1822 {
1823     entity oldself;
1824     oldself = self;
1825     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1826         self.uncustomizeentityforclient();
1827     self = oldself;
1828 }
1829 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1830 {
1831     e.customizeentityforclient = customizer;
1832     e.uncustomizeentityforclient = uncustomizer;
1833     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1834 }
1835
1836 .float nottargeted;
1837 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1838
1839 void() SUB_Remove;
1840 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1841 {
1842     vector mi, ma;
1843
1844     if (e.classname == "")
1845         e.classname = "net_linked";
1846
1847     if (e.model == "" || self.modelindex == 0)
1848     {
1849         mi = e.mins;
1850         ma = e.maxs;
1851         setmodel(e, "null");
1852         setsize(e, mi, ma);
1853     }
1854
1855     e.SendEntity = sendfunc;
1856     e.SendFlags = 0xFFFFFF;
1857
1858     if (!docull)
1859         e.effects |= EF_NODEPTHTEST;
1860
1861     if (dt)
1862     {
1863         e.nextthink = time + dt;
1864         e.think = SUB_Remove;
1865     }
1866 }
1867
1868 void adaptor_think2touch()
1869 {
1870     entity o;
1871     o = other;
1872     other = world;
1873     self.touch();
1874     other = o;
1875 }
1876
1877 void adaptor_think2use()
1878 {
1879     entity o, a;
1880     o = other;
1881     a = activator;
1882     activator = world;
1883     other = world;
1884     self.use();
1885     other = o;
1886     activator = a;
1887 }
1888
1889 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1890 {
1891         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1892                 self.projectiledeathtype |= HITTYPE_SPLASH;
1893         adaptor_think2use();
1894 }
1895
1896 // deferred dropping
1897 void DropToFloor_Handler()
1898 {
1899     builtin_droptofloor();
1900     self.dropped_origin = self.origin;
1901 }
1902
1903 void droptofloor()
1904 {
1905     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1906 }
1907
1908
1909
1910 float trace_hits_box_a0, trace_hits_box_a1;
1911
1912 float trace_hits_box_1d(float end, float thmi, float thma)
1913 {
1914     if (end == 0)
1915     {
1916         // just check if x is in range
1917         if (0 < thmi)
1918             return FALSE;
1919         if (0 > thma)
1920             return FALSE;
1921     }
1922     else
1923     {
1924         // do the trace with respect to x
1925         // 0 -> end has to stay in thmi -> thma
1926         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1927         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1928         if (trace_hits_box_a0 > trace_hits_box_a1)
1929             return FALSE;
1930     }
1931     return TRUE;
1932 }
1933
1934 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1935 {
1936     end -= start;
1937     thmi -= start;
1938     thma -= start;
1939     // now it is a trace from 0 to end
1940
1941     trace_hits_box_a0 = 0;
1942     trace_hits_box_a1 = 1;
1943
1944     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1945         return FALSE;
1946     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1947         return FALSE;
1948     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1949         return FALSE;
1950
1951     return TRUE;
1952 }
1953
1954 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1955 {
1956     return trace_hits_box(start, end, thmi - ma, thma - mi);
1957 }
1958
1959 float SUB_NoImpactCheck()
1960 {
1961         // zero hitcontents = this is not the real impact, but either the
1962         // mirror-impact of something hitting the projectile instead of the
1963         // projectile hitting the something, or a touchareagrid one. Neither of
1964         // these stop the projectile from moving, so...
1965         if(trace_dphitcontents == 0)
1966         {
1967                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1968                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1969                 checkclient();
1970         }
1971     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1972         return 1;
1973     if (other == world && self.size != '0 0 0')
1974     {
1975         vector tic;
1976         tic = self.velocity * sys_frametime;
1977         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1978         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1979         if (trace_fraction >= 1)
1980         {
1981             dprint("Odd... did not hit...?\n");
1982         }
1983         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1984         {
1985             dprint("Detected and prevented the sky-grapple bug.\n");
1986             return 1;
1987         }
1988     }
1989
1990     return 0;
1991 }
1992
1993 #define SUB_OwnerCheck() (other && (other == self.owner))
1994
1995 void RemoveGrapplingHook(entity pl);
1996 void W_Crylink_Dequeue(entity e);
1997 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1998 {
1999         if(SUB_OwnerCheck())
2000                 return TRUE;
2001         if(SUB_NoImpactCheck())
2002         {
2003                 if(self.classname == "grapplinghook")
2004                         RemoveGrapplingHook(self.realowner);
2005                 else if(self.classname == "spike")
2006                 {
2007                         W_Crylink_Dequeue(self);
2008                         remove(self);
2009                 }
2010                 else
2011                         remove(self);
2012                 return TRUE;
2013         }
2014         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2015                 UpdateCSQCProjectile(self);
2016         return FALSE;
2017 }
2018 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2019
2020 float MAX_IPBAN_URIS           = 16;
2021
2022 float URI_GET_DISCARD          = 0;
2023 float URI_GET_IPBAN            = 1;
2024 float URI_GET_IPBAN_END        = 16;
2025
2026 void URI_Get_Callback(float id, float status, string data)
2027 {
2028     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2029     dprint(data);
2030     dprint("\nEnd of data.\n");
2031
2032     if(url_URI_Get_Callback(id, status, data))
2033     {
2034         // handled
2035     }
2036     else if (id == URI_GET_DISCARD)
2037     {
2038         // discard
2039     }
2040     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2041     {
2042         // online ban list
2043         OnlineBanList_URI_Get_Callback(id, status, data);
2044     }
2045     else
2046     {
2047         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2048     }
2049 }
2050
2051 void print_to(entity e, string s)
2052 {
2053     if (e)
2054         sprint(e, strcat(s, "\n"));
2055     else
2056         print(s, "\n");
2057 }
2058
2059 string uid2name(string myuid) {
2060         string s;
2061         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2062
2063         // FIXME remove this later after 0.6 release
2064         // convert old style broken records to correct style
2065         if(s == "")
2066         {
2067                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2068                 if(s != "")
2069                 {
2070                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2071                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2072                 }
2073         }
2074
2075         if(s == "")
2076                 s = "^1Unregistered Player";
2077         return s;
2078 }
2079
2080 float race_readTime(string map, float pos)
2081 {
2082         string rr;
2083         if(g_cts)
2084                 rr = CTS_RECORD;
2085         else
2086                 rr = RACE_RECORD;
2087
2088         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2089 }
2090
2091 string race_readUID(string map, float pos)
2092 {
2093         string rr;
2094         if(g_cts)
2095                 rr = CTS_RECORD;
2096         else
2097                 rr = RACE_RECORD;
2098
2099         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2100 }
2101
2102 float race_readPos(string map, float t) {
2103         float i;
2104         for (i = 1; i <= RANKINGS_CNT; ++i)
2105                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2106                         return i;
2107
2108         return 0; // pos is zero if unranked
2109 }
2110
2111 void race_writeTime(string map, float t, string myuid)
2112 {
2113         string rr;
2114         if(g_cts)
2115                 rr = CTS_RECORD;
2116         else
2117                 rr = RACE_RECORD;
2118
2119         float newpos;
2120         newpos = race_readPos(map, t);
2121
2122         float i, prevpos;
2123         for(i = 1; i <= RANKINGS_CNT; ++i)
2124         {
2125                 if(race_readUID(map, i) == myuid)
2126                         prevpos = i;
2127         }
2128         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2129                 for (i = prevpos; i > newpos; --i) {
2130                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2131                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2132                 }
2133         } else { // player has no ranked record yet
2134                 for (i = RANKINGS_CNT; i > newpos; --i) {
2135                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2136                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2137                 }
2138         }
2139
2140         // store new time itself
2141         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2142         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2143 }
2144
2145 string race_readName(string map, float pos)
2146 {
2147         string rr;
2148         if(g_cts)
2149                 rr = CTS_RECORD;
2150         else
2151                 rr = RACE_RECORD;
2152
2153         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2154 }
2155
2156 string race_placeName(float pos) {
2157         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2158         {
2159                 if(mod(pos, 10) == 1)
2160                         return strcat(ftos(pos), "st");
2161                 else if(mod(pos, 10) == 2)
2162                         return strcat(ftos(pos), "nd");
2163                 else if(mod(pos, 10) == 3)
2164                         return strcat(ftos(pos), "rd");
2165                 else
2166                         return strcat(ftos(pos), "th");
2167         }
2168         else
2169                 return strcat(ftos(pos), "th");
2170 }
2171 string getrecords(float page) // 50 records per page
2172 {
2173     float rec;
2174     string h;
2175     float r;
2176     float i;
2177     string s;
2178
2179     rec = 0;
2180
2181     s = "";
2182
2183     if (g_ctf)
2184     {
2185         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2186         {
2187             if (MapInfo_Get_ByID(i))
2188             {
2189                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2190                 if (r == 0)
2191                     continue;
2192                 // TODO: uid2name
2193                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2194                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2195                 ++rec;
2196             }
2197         }
2198     }
2199
2200     if (g_race)
2201     {
2202         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2203         {
2204             if (MapInfo_Get_ByID(i))
2205             {
2206                 r = race_readTime(MapInfo_Map_bspname, 1);
2207                 if (r == 0)
2208                     continue;
2209                 h = race_readName(MapInfo_Map_bspname, 1);
2210                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2211                 ++rec;
2212             }
2213         }
2214     }
2215
2216     if (g_cts)
2217     {
2218         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2219         {
2220             if (MapInfo_Get_ByID(i))
2221             {
2222                 r = race_readTime(MapInfo_Map_bspname, 1);
2223                 if (r == 0)
2224                     continue;
2225                 h = race_readName(MapInfo_Map_bspname, 1);
2226                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2227                 ++rec;
2228             }
2229         }
2230     }
2231
2232     MapInfo_ClearTemps();
2233
2234     if (s == "" && page == 0)
2235         return "No records are available on this server.\n";
2236     else
2237         return s;
2238 }
2239
2240 string getrankings()
2241 {
2242     string n;
2243     float t;
2244     float i;
2245     string s;
2246     string p;
2247     string map;
2248
2249     s = "";
2250
2251     map = GetMapname();
2252
2253     for (i = 1; i <= RANKINGS_CNT; ++i)
2254     {
2255         t = race_readTime(map, i);
2256         if (t == 0)
2257             continue;
2258         n = race_readName(map, i);
2259         p = race_placeName(i);
2260         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2261     }
2262
2263     MapInfo_ClearTemps();
2264
2265     if (s == "")
2266         return strcat("No records are available for the map: ", map, "\n");
2267     else
2268         return strcat("Records for ", map, ":\n", s);
2269 }
2270
2271 #define LADDER_FIRSTPOINT 100
2272 #define LADDER_CNT 10
2273         // position X still gives LADDER_FIRSTPOINT/X points
2274 #define LADDER_SIZE 30
2275         // ladder shows the top X players
2276 string top_uids[LADDER_SIZE];
2277 float top_scores[LADDER_SIZE];
2278 string getladder()
2279 {
2280     float i, j, k, uidcnt;
2281     string s, temp_s;
2282
2283     s = "";
2284     temp_s = "";
2285
2286     string rr;
2287     if(g_cts)
2288         rr = CTS_RECORD;
2289     else
2290         rr = RACE_RECORD;
2291
2292     string myuid;
2293
2294     for (k = 0; k < MapInfo_count; ++k)
2295     {
2296         if (MapInfo_Get_ByID(k))
2297         {
2298                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2299                         if(i == 0) // speed award
2300                         {
2301                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2302                                         continue;
2303
2304                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2305                         }
2306                         else // normal record, if it exists (else break)
2307                         {
2308                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2309                                         continue;
2310
2311                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2312                         }
2313
2314                         // string s contains:
2315                         // arg 0 = # of speed recs
2316                         // arg 1 = # of 1st place recs
2317                         // arg 2 = # of 2nd place recs
2318                         // ... etc
2319                         // LADDER_CNT+1 = total points
2320
2321                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2322                         if (temp_s == "")
2323                         {
2324                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2325                             ++uidcnt;
2326                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2327                             {
2328                                 if(j != LADDER_CNT + 1)
2329                                     temp_s = strcat(temp_s, "0 ");
2330                                 else
2331                                     temp_s = strcat(temp_s, "0");
2332                             }
2333                         }
2334
2335                         tokenize_console(temp_s);
2336                         s = "";
2337
2338                         if(i == 0) // speed award
2339                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2340                             {
2341                                 if(j == 0) // speed award
2342                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2343                                 else
2344                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2345                             }
2346                         else // record
2347                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2348                             {
2349                                 if(j == 0)
2350                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2351                                 else if(j == i) // wanted rec!
2352                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2353                                 else
2354                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2355                             }
2356
2357                         // total points are (by default) calculated like this:
2358                         // speedrec = floor(100 / 10) = 10 points
2359                         // 1st place = floor(100 / 1) = 100 points
2360                         // 2nd place = floor(100 / 2) = 50 points
2361                         // 3rd place = floor(100 / 3) = 33 points
2362                         // 4th place = floor(100 / 4) = 25 points
2363                         // 5th place = floor(100 / 5) = 20 points
2364                         // ... etc
2365
2366                         if(i == 0)
2367                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2368                         else
2369                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2370
2371                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2372                 }
2373         }
2374     }
2375
2376     float thiscnt;
2377     string thisuid;
2378     for (i = 0; i <= uidcnt; ++i) // for each known uid
2379     {
2380         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2381         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2382         tokenize_console(temp_s);
2383         thiscnt = stof(argv(LADDER_CNT+1));
2384
2385         if(thiscnt > top_scores[LADDER_SIZE-1])
2386         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2387         {
2388             if(thiscnt > top_scores[j])
2389             {
2390                 for (k = LADDER_SIZE-1; k >= j; --k)
2391                 {
2392                     top_uids[k] = top_uids[k-1];
2393                     top_scores[k] = top_scores[k-1];
2394                 }
2395                 top_uids[j] = thisuid;
2396                 top_scores[j] = thiscnt;
2397                 break;
2398             }
2399         }
2400     }
2401
2402     s = "^3-----------------------\n\n";
2403
2404     s = strcat(s, "Pos ^3|");
2405     s = strcat(s, " ^7Total  ^3|");
2406     for (i = 1; i <= LADDER_CNT; ++i)
2407     {
2408         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2409     }
2410     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2411
2412     s = strcat(s, "\n^3----+--------");
2413     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2414     {
2415         s = strcat(s, "+-----");
2416     }
2417 #if LADDER_CNT > 9
2418     for (i = 1; i <= LADDER_CNT - 9; ++i)
2419     {
2420         s = strcat(s, "+------");
2421     }
2422 #endif
2423
2424     s = strcat(s, "+--------------+--------------------\n");
2425
2426     for (i = 0; i < LADDER_SIZE; ++i)
2427     {
2428         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2429         tokenize_console(temp_s);
2430         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2431             continue;
2432         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2433         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2434         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2435         {
2436             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2437         }
2438 #if LADDER_CNT > 9
2439         for (j = 10; j <= LADDER_CNT; ++j)
2440         {
2441             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2442         }
2443 #endif
2444
2445         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2446         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2447     }
2448
2449     MapInfo_ClearTemps();
2450
2451     if (s == "")
2452         return "No ladder on this server!\n";
2453     else
2454         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2455 }
2456
2457
2458 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2459 {
2460     float m, i;
2461     vector start, org, delta, end, enddown, mstart;
2462     entity sp;
2463
2464     m = e.dphitcontentsmask;
2465     e.dphitcontentsmask = goodcontents | badcontents;
2466
2467     org = world.mins;
2468     delta = world.maxs - world.mins;
2469
2470     for (i = 0; i < attempts; ++i)
2471     {
2472         start_x = org_x + random() * delta_x;
2473         start_y = org_y + random() * delta_y;
2474         start_z = org_z + random() * delta_z;
2475
2476         // rule 1: start inside world bounds, and outside
2477         // solid, and don't start from somewhere where you can
2478         // fall down to evil
2479         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2480         if (trace_fraction >= 1)
2481             continue;
2482         if (trace_startsolid)
2483             continue;
2484         if (trace_dphitcontents & badcontents)
2485             continue;
2486         if (trace_dphitq3surfaceflags & badsurfaceflags)
2487             continue;
2488
2489         // rule 2: if we are too high, lower the point
2490         if (trace_fraction * delta_z > maxaboveground)
2491             start = trace_endpos + '0 0 1' * maxaboveground;
2492         enddown = trace_endpos;
2493
2494         // rule 3: make sure we aren't outside the map. This only works
2495         // for somewhat well formed maps. A good rule of thumb is that
2496         // the map should have a convex outside hull.
2497         // these can be traceLINES as we already verified the starting box
2498         mstart = start + 0.5 * (e.mins + e.maxs);
2499         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2500         if (trace_fraction >= 1)
2501             continue;
2502         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2503         if (trace_fraction >= 1)
2504             continue;
2505         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2506         if (trace_fraction >= 1)
2507             continue;
2508         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2509         if (trace_fraction >= 1)
2510             continue;
2511         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2512         if (trace_fraction >= 1)
2513             continue;
2514
2515         // rule 4: we must "see" some spawnpoint
2516         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2517                 if(checkpvs(mstart, sp))
2518                         break;
2519         if(!sp)
2520         {
2521                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2522                         if(checkpvs(mstart, sp))
2523                                 break;
2524                 if(!sp)
2525                         continue;
2526         }
2527
2528         // find a random vector to "look at"
2529         end_x = org_x + random() * delta_x;
2530         end_y = org_y + random() * delta_y;
2531         end_z = org_z + random() * delta_z;
2532         end = start + normalize(end - start) * vlen(delta);
2533
2534         // rule 4: start TO end must not be too short
2535         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2536         if (trace_startsolid)
2537             continue;
2538         if (trace_fraction < minviewdistance / vlen(delta))
2539             continue;
2540
2541         // rule 5: don't want to look at sky
2542         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2543             continue;
2544
2545         // rule 6: we must not end up in trigger_hurt
2546         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2547             continue;
2548
2549         break;
2550     }
2551
2552     e.dphitcontentsmask = m;
2553
2554     if (i < attempts)
2555     {
2556         setorigin(e, start);
2557         e.angles = vectoangles(end - start);
2558         dprint("Needed ", ftos(i + 1), " attempts\n");
2559         return TRUE;
2560     }
2561     else
2562         return FALSE;
2563 }
2564
2565 float zcurveparticles_effectno;
2566 vector zcurveparticles_start;
2567 float zcurveparticles_spd;
2568
2569 void endzcurveparticles()
2570 {
2571         if(zcurveparticles_effectno)
2572         {
2573                 // terminator
2574                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2575         }
2576         zcurveparticles_effectno = 0;
2577 }
2578
2579 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2580 {
2581         spd = bound(0, floor(spd / 16), 32767);
2582         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2583         {
2584                 endzcurveparticles();
2585                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2586                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2587                 WriteShort(MSG_BROADCAST, effectno);
2588                 WriteCoord(MSG_BROADCAST, start_x);
2589                 WriteCoord(MSG_BROADCAST, start_y);
2590                 WriteCoord(MSG_BROADCAST, start_z);
2591                 zcurveparticles_effectno = effectno;
2592                 zcurveparticles_start = start;
2593         }
2594         else
2595                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2596         WriteCoord(MSG_BROADCAST, end_x);
2597         WriteCoord(MSG_BROADCAST, end_y);
2598         WriteCoord(MSG_BROADCAST, end_z);
2599         WriteCoord(MSG_BROADCAST, end_dz);
2600         zcurveparticles_spd = spd;
2601 }
2602
2603 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2604 {
2605         float end_dz;
2606         vector vecxy, velxy;
2607
2608         vecxy = end - start;
2609         vecxy_z = 0;
2610         velxy = vel;
2611         velxy_z = 0;
2612
2613         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2614         {
2615                 endzcurveparticles();
2616                 trailparticles(world, effectno, start, end);
2617                 return;
2618         }
2619
2620         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2621         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2622 }
2623
2624 void write_recordmarker(entity pl, float tstart, float dt)
2625 {
2626     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2627
2628     // also write a marker into demo files for demotc-race-record-extractor to find
2629     stuffcmd(pl,
2630              strcat(
2631                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2632                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2633 }
2634
2635 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2636 {
2637         switch(algn)
2638         {
2639                 default:
2640                 case 3: // right
2641                         break;
2642
2643                 case 4: // left
2644                         vecs_y = -vecs_y;
2645                         break;
2646
2647                 case 1:
2648                         if(allowcenter) // 2: allow center handedness
2649                         {
2650                                 // center
2651                                 vecs_y = 0;
2652                                 vecs_z -= 2;
2653                         }
2654                         else
2655                         {
2656                                 // right
2657                         }
2658                         break;
2659
2660                 case 2:
2661                         if(allowcenter) // 2: allow center handedness
2662                         {
2663                                 // center
2664                                 vecs_y = 0;
2665                                 vecs_z -= 2;
2666                         }
2667                         else
2668                         {
2669                                 // left
2670                                 vecs_y = -vecs_y;
2671                         }
2672                         break;
2673         }
2674         return vecs;
2675 }
2676
2677 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2678 {
2679         string s;
2680         vector v;
2681
2682         if (autocvar_g_shootfromeye)
2683         {
2684                 if (visual)
2685                 {
2686                         vecs_y = 0;
2687                         vecs_z -= 2;
2688                 }
2689                 else
2690                 {
2691                         vecs_y = 0;
2692                         vecs_z = 0;
2693                 }
2694         }
2695         else if (autocvar_g_shootfromcenter)
2696         {
2697                 vecs_y = 0;
2698                 vecs_z -= 2;
2699         }
2700         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2701         {
2702                 v = stov(s);
2703                 if (y_is_right)
2704                         v_y = -v_y;
2705                 if (v_x != 0)
2706                         vecs_x = v_x;
2707                 vecs_y = v_y;
2708                 vecs_z = v_z;
2709         }
2710         else if (autocvar_g_shootfromclient)
2711         {
2712                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2713         }
2714         return vecs;
2715 }
2716
2717 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2718 {
2719         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2720 }
2721
2722
2723 void attach_sameorigin(entity e, entity to, string tag)
2724 {
2725     vector org, t_forward, t_left, t_up, e_forward, e_up;
2726     vector org0, ang0;
2727     float tagscale;
2728
2729     ang0 = e.angles;
2730     org0 = e.origin;
2731
2732     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2733     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2734     t_forward = v_forward * tagscale;
2735     t_left = v_right * -tagscale;
2736     t_up = v_up * tagscale;
2737
2738     e.origin_x = org * t_forward;
2739     e.origin_y = org * t_left;
2740     e.origin_z = org * t_up;
2741
2742     // current forward and up directions
2743     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2744                 e.angles = AnglesTransform_FromVAngles(e.angles);
2745         else
2746                 e.angles = AnglesTransform_FromAngles(e.angles);
2747     fixedmakevectors(e.angles);
2748
2749     // untransform forward, up!
2750     e_forward_x = v_forward * t_forward;
2751     e_forward_y = v_forward * t_left;
2752     e_forward_z = v_forward * t_up;
2753     e_up_x = v_up * t_forward;
2754     e_up_y = v_up * t_left;
2755     e_up_z = v_up * t_up;
2756
2757     e.angles = fixedvectoangles2(e_forward, e_up);
2758     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2759                 e.angles = AnglesTransform_ToVAngles(e.angles);
2760         else
2761                 e.angles = AnglesTransform_ToAngles(e.angles);
2762
2763     setattachment(e, to, tag);
2764     setorigin(e, e.origin);
2765 }
2766
2767 void detach_sameorigin(entity e)
2768 {
2769     vector org;
2770     org = gettaginfo(e, 0);
2771     e.angles = fixedvectoangles2(v_forward, v_up);
2772     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2773                 e.angles = AnglesTransform_ToVAngles(e.angles);
2774         else
2775                 e.angles = AnglesTransform_ToAngles(e.angles);
2776     setorigin(e, org);
2777     setattachment(e, world, "");
2778     setorigin(e, e.origin);
2779 }
2780
2781 void follow_sameorigin(entity e, entity to)
2782 {
2783     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2784     e.aiment = to; // make the hole follow bmodel
2785     e.punchangle = to.angles; // the original angles of bmodel
2786     e.view_ofs = e.origin - to.origin; // relative origin
2787     e.v_angle = e.angles - to.angles; // relative angles
2788 }
2789
2790 void unfollow_sameorigin(entity e)
2791 {
2792     e.movetype = MOVETYPE_NONE;
2793 }
2794
2795 entity gettaginfo_relative_ent;
2796 vector gettaginfo_relative(entity e, float tag)
2797 {
2798     if (!gettaginfo_relative_ent)
2799     {
2800         gettaginfo_relative_ent = spawn();
2801         gettaginfo_relative_ent.effects = EF_NODRAW;
2802     }
2803     gettaginfo_relative_ent.model = e.model;
2804     gettaginfo_relative_ent.modelindex = e.modelindex;
2805     gettaginfo_relative_ent.frame = e.frame;
2806     return gettaginfo(gettaginfo_relative_ent, tag);
2807 }
2808
2809 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2810 {
2811     float p;
2812     p = pow(2, chan);
2813     if (pl.soundentity.cnt & p)
2814         return;
2815     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2816     pl.soundentity.cnt |= p;
2817 }
2818
2819 void SoundEntity_StopSound(entity pl, float chan)
2820 {
2821     float p;
2822     p = pow(2, chan);
2823     if (pl.soundentity.cnt & p)
2824     {
2825         stopsoundto(MSG_ALL, pl.soundentity, chan);
2826         pl.soundentity.cnt &~= p;
2827     }
2828 }
2829
2830 void SoundEntity_Attach(entity pl)
2831 {
2832     pl.soundentity = spawn();
2833     pl.soundentity.classname = "soundentity";
2834     pl.soundentity.owner = pl;
2835     setattachment(pl.soundentity, pl, "");
2836     setmodel(pl.soundentity, "null");
2837 }
2838
2839 void SoundEntity_Detach(entity pl)
2840 {
2841     float i;
2842     for (i = 0; i <= 7; ++i)
2843         SoundEntity_StopSound(pl, i);
2844 }
2845
2846
2847 float ParseCommandPlayerSlotTarget_firsttoken;
2848 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2849 {
2850         string s;
2851         entity e, head;
2852         float n;
2853
2854         s = string_null;
2855
2856         ParseCommandPlayerSlotTarget_firsttoken = -1;
2857
2858         if (tokens > idx)
2859         {
2860                 if (substring(argv(idx), 0, 1) == "#")
2861                 {
2862                         s = substring(argv(idx), 1, -1);
2863                         ++idx;
2864                         if (s == "") if (tokens > idx)
2865                         {
2866                                 s = argv(idx);
2867                                 ++idx;
2868                         }
2869                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2870                         n = stof(s);
2871                         if (s == ftos(n) && n > 0 && n <= maxclients)
2872                         {
2873                                 e = edict_num(n);
2874                                 if (e.flags & FL_CLIENT)
2875                                         return e;
2876                         }
2877                 }
2878                 else
2879                 {
2880                         // it must be a nick name
2881                         s = argv(idx);
2882                         ++idx;
2883                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2884
2885                         n = 0;
2886                         FOR_EACH_CLIENT(head)
2887                                 if (head.netname == s)
2888                                 {
2889                                         e = head;
2890                                         ++n;
2891                                 }
2892                         if (n == 1)
2893                                 return e;
2894
2895                         s = strdecolorize(s);
2896                         n = 0;
2897                         FOR_EACH_CLIENT(head)
2898                                 if (strdecolorize(head.netname) == s)
2899                                 {
2900                                         e = head;
2901                                         ++n;
2902                                 }
2903                         if (n == 1)
2904                                 return e;
2905                 }
2906         }
2907
2908         return world;
2909 }
2910
2911 .float scale2;
2912
2913 float modeleffect_SendEntity(entity to, float sf)
2914 {
2915         float f;
2916         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2917
2918         f = 0;
2919         if(self.velocity != '0 0 0')
2920                 f |= 1;
2921         if(self.angles != '0 0 0')
2922                 f |= 2;
2923         if(self.avelocity != '0 0 0')
2924                 f |= 4;
2925
2926         WriteByte(MSG_ENTITY, f);
2927         WriteShort(MSG_ENTITY, self.modelindex);
2928         WriteByte(MSG_ENTITY, self.skin);
2929         WriteByte(MSG_ENTITY, self.frame);
2930         WriteCoord(MSG_ENTITY, self.origin_x);
2931         WriteCoord(MSG_ENTITY, self.origin_y);
2932         WriteCoord(MSG_ENTITY, self.origin_z);
2933         if(f & 1)
2934         {
2935                 WriteCoord(MSG_ENTITY, self.velocity_x);
2936                 WriteCoord(MSG_ENTITY, self.velocity_y);
2937                 WriteCoord(MSG_ENTITY, self.velocity_z);
2938         }
2939         if(f & 2)
2940         {
2941                 WriteCoord(MSG_ENTITY, self.angles_x);
2942                 WriteCoord(MSG_ENTITY, self.angles_y);
2943                 WriteCoord(MSG_ENTITY, self.angles_z);
2944         }
2945         if(f & 4)
2946         {
2947                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2948                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2949                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2950         }
2951         WriteShort(MSG_ENTITY, self.scale * 256.0);
2952         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2953         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2954         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2955         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2956
2957         return TRUE;
2958 }
2959
2960 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2961 {
2962         entity e;
2963         float sz;
2964         e = spawn();
2965         e.classname = "modeleffect";
2966         setmodel(e, m);
2967         e.frame = f;
2968         setorigin(e, o);
2969         e.velocity = v;
2970         e.angles = ang;
2971         e.avelocity = angv;
2972         e.alpha = a;
2973         e.teleport_time = t1;
2974         e.fade_time = t2;
2975         e.skin = s;
2976         if(s0 >= 0)
2977                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2978         else
2979                 e.scale = -s0;
2980         if(s2 >= 0)
2981                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2982         else
2983                 e.scale2 = -s2;
2984         sz = max(e.scale, e.scale2);
2985         setsize(e, e.mins * sz, e.maxs * sz);
2986         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2987 }
2988
2989 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2990 {
2991         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2992 }
2993
2994 float randombit(float bits)
2995 {
2996         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2997                 return bits;
2998
2999         float n, f, b, r;
3000
3001         r = random();
3002         b = 0;
3003         n = 0;
3004
3005         for(f = 1; f <= bits; f *= 2)
3006         {
3007                 if(bits & f)
3008                 {
3009                         ++n;
3010                         r *= n;
3011                         if(r <= 1)
3012                                 b = f;
3013                         else
3014                                 r = (r - 1) / (n - 1);
3015                 }
3016         }
3017
3018         return b;
3019 }
3020
3021 float randombits(float bits, float k, float error_return)
3022 {
3023         float r;
3024         r = 0;
3025         while(k > 0 && bits != r)
3026         {
3027                 r += randombit(bits - r);
3028                 --k;
3029         }
3030         if(error_return)
3031                 if(k > 0)
3032                         return -1; // all
3033         return r;
3034 }
3035
3036 void randombit_test(float bits, float iter)
3037 {
3038         while(iter > 0)
3039         {
3040                 print(ftos(randombit(bits)), "\n");
3041                 --iter;
3042         }
3043 }
3044
3045 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3046 {
3047         if(halflifedist > 0)
3048                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3049         else if(halflifedist < 0)
3050                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3051         else
3052                 return 1;
3053 }
3054
3055
3056
3057
3058 #ifdef RELEASE
3059 #define cvar_string_normal builtin_cvar_string
3060 #define cvar_normal builtin_cvar
3061 #else
3062 string cvar_string_normal(string n)
3063 {
3064         if not(cvar_type(n) & 1)
3065                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3066         return builtin_cvar_string(n);
3067 }
3068
3069 float cvar_normal(string n)
3070 {
3071         return stof(cvar_string_normal(n));
3072 }
3073 #endif
3074 #define cvar_set_normal builtin_cvar_set
3075
3076 void defer_think()
3077 {
3078     entity oself;
3079
3080     oself           = self;
3081     self            = self.owner;
3082     oself.think     = SUB_Remove;
3083     oself.nextthink = time;
3084
3085     oself.use();
3086 }
3087
3088 /*
3089     Execute func() after time + fdelay.
3090     self when func is executed = self when defer is called
3091 */
3092 void defer(float fdelay, void() func)
3093 {
3094     entity e;
3095
3096     e           = spawn();
3097     e.owner     = self;
3098     e.use       = func;
3099     e.think     = defer_think;
3100     e.nextthink = time + fdelay;
3101 }
3102
3103 .string aiment_classname;
3104 .float aiment_deadflag;
3105 void SetMovetypeFollow(entity ent, entity e)
3106 {
3107         // FIXME this may not be warpzone aware
3108         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3109         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3110         ent.aiment = e; // make the hole follow bmodel
3111         ent.punchangle = e.angles; // the original angles of bmodel
3112         ent.view_ofs = ent.origin - e.origin; // relative origin
3113         ent.v_angle = ent.angles - e.angles; // relative angles
3114         ent.aiment_classname = strzone(e.classname);
3115         ent.aiment_deadflag = e.deadflag;
3116 }
3117 void UnsetMovetypeFollow(entity ent)
3118 {
3119         ent.movetype = MOVETYPE_FLY;
3120         PROJECTILE_MAKETRIGGER(ent);
3121         ent.aiment = world;
3122 }
3123 float LostMovetypeFollow(entity ent)
3124 {
3125 /*
3126         if(ent.movetype != MOVETYPE_FOLLOW)
3127                 if(ent.aiment)
3128                         error("???");
3129 */
3130         if(ent.aiment)
3131         {
3132                 if(ent.aiment.classname != ent.aiment_classname)
3133                         return 1;
3134                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3135                         return 1;
3136         }
3137         return 0;
3138 }
3139
3140 float isPushable(entity e)
3141 {
3142         if(e.iscreature)
3143                 return TRUE;
3144         switch(e.classname)
3145         {
3146                 case "body":
3147                 case "droppedweapon":
3148                 case "keepawayball":
3149                 case "nexball_basketball":
3150                 case "nexball_football":
3151                         return TRUE;
3152                 case "bullet": // antilagged bullets can't hit this either
3153                         return FALSE;
3154         }
3155         if (e.projectiledeathtype)
3156                 return TRUE;
3157         return FALSE;
3158 }
3159
3160 // used by gamecommand/clientcommand/votecommand/bancommand system
3161 float GetFilteredNumber(string input)
3162 {
3163         entity tmp_player, selection;
3164         float output, matches;
3165
3166         // check and see if we can get a number from input like "#3" or "3"
3167         if(substring(input, 0, 1) == "#")
3168                 output = stof(substring(input, 1, -1));
3169         else
3170                 output = stof(input);
3171
3172         // if we can't, check and see if we can match the input to the netname of any player in the game
3173         if not(output)
3174         {
3175                 FOR_EACH_CLIENT(tmp_player)
3176                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
3177                                 selection = tmp_player;
3178
3179                 if (selection) { output = num_for_edict(selection); }
3180         }
3181
3182         print(strcat("input: ", input, ", output: ", ftos(output), ",\n"));
3183         return output;
3184 }