merge some changes from my autocvarizer branch that change nothing but make code...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
12 void WarpZone_crosshair_trace(entity pl)
13 {
14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
15 }
16
17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
18 void() spawnpoint_use;
19 string GetMapname();
20 string ColoredTeamName(float t);
21
22 string admin_name(void)
23 {
24         if(cvar_string("sv_adminnick") != "")
25                 return cvar_string("sv_adminnick");
26         else
27                 return "SERVER ADMIN";
28 }
29
30 float DistributeEvenly_amount;
31 float DistributeEvenly_totalweight;
32 void DistributeEvenly_Init(float amount, float totalweight)
33 {
34     if (DistributeEvenly_amount)
35     {
36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
38     }
39     if (totalweight == 0)
40         DistributeEvenly_amount = 0;
41     else
42         DistributeEvenly_amount = amount;
43     DistributeEvenly_totalweight = totalweight;
44 }
45 float DistributeEvenly_Get(float weight)
46 {
47     float f;
48     if (weight <= 0)
49         return 0;
50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
51     DistributeEvenly_totalweight -= weight;
52     DistributeEvenly_amount -= f;
53     return f;
54 }
55
56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
57
58
59 string STR_PLAYER = "player";
60 string STR_SPECTATOR = "spectator";
61 string STR_OBSERVER = "observer";
62
63 #if 0
64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
68 #else
69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
74 #endif
75
76 // copies a string to a tempstring (so one can strunzone it)
77 string strcat1(string s) = #115; // FRIK_FILE
78
79 float logfile_open;
80 float logfile;
81
82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
83 {
84         local float nPlayerHealth = rint(enPlayer.health);
85         local float nPlayerArmor = rint(enPlayer.armorvalue);
86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
87         local float nPlayerPing = rint(enPlayer.ping);
88         local string strPlayerPingColor;
89         local string strMessage;
90         if(nPlayerPing >= 150)
91                 strPlayerPingColor = "^1";
92         else
93                 strPlayerPingColor = "^2";
94
95         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
97
98         if(cvar("sv_fragmessage_information_ping")) {
99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
100                         strMessage = strcat(strMessage, " ^7(^2Bot");
101                 else
102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
103                 if(cvar("sv_fragmessage_information_handicap"))
104                         if(cvar("sv_fragmessage_information_handicap") == 2)
105                                 if(nPlayerHandicap <= 1)
106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
107                                 else
108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
109                         else if not(nPlayerHandicap <= 1)
110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
111                 else
112                         strMessage = strcat(strMessage, "^7)");
113         } else if(cvar("sv_fragmessage_information_handicap")) {
114                 if(cvar("sv_fragmessage_information_handicap") == 2)
115                         if(nPlayerHandicap <= 1)
116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
117                         else
118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
119                 else if(nPlayerHandicap > 1)
120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
121         }
122         return strMessage;
123 }
124 void bcenterprint(string s)
125 {
126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
127     entity head;
128     FOR_EACH_PLAYER(head)
129     if (clienttype(head) == CLIENTTYPE_REAL)
130         centerprint(head, s);
131 }
132
133 void GameLogEcho(string s)
134 {
135     string fn;
136     float matches;
137
138     if (cvar("sv_eventlog_files"))
139     {
140         if (!logfile_open)
141         {
142             logfile_open = TRUE;
143             matches = cvar("sv_eventlog_files_counter") + 1;
144             cvar_set("sv_eventlog_files_counter", ftos(matches));
145             fn = ftos(matches);
146             if (strlen(fn) < 8)
147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
148             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
149             logfile = fopen(fn, FILE_APPEND);
150             fputs(logfile, ":logversion:3\n");
151         }
152         if (logfile >= 0)
153         {
154             if (cvar("sv_eventlog_files_timestamps"))
155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
156             else
157                 fputs(logfile, strcat(s, "\n"));
158         }
159     }
160     if (cvar("sv_eventlog_console"))
161     {
162         print(s, "\n");
163     }
164 }
165
166 void GameLogInit()
167 {
168     logfile_open = 0;
169     // will be opened later
170 }
171
172 void GameLogClose()
173 {
174     if (logfile_open && logfile >= 0)
175     {
176         fclose(logfile);
177         logfile = -1;
178     }
179 }
180
181 vector PL_VIEW_OFS;
182 vector PL_MIN;
183 vector PL_MAX;
184 vector PL_HEAD;
185 vector PL_CROUCH_VIEW_OFS;
186 vector PL_CROUCH_MIN;
187 vector PL_CROUCH_MAX;
188
189 float spawnpoint_nag;
190 void relocate_spawnpoint()
191 {
192     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
193     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
194     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
195     PL_HEAD                                 = stov(cvar_string("sv_player_headsize"));
196     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
197     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
198     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
199
200     // nudge off the floor
201     setorigin(self, self.origin + '0 0 1');
202
203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
204     if (trace_startsolid)
205     {
206         vector o;
207         o = self.origin;
208         self.mins = PL_MIN;
209         self.maxs = PL_MAX;
210         if (!move_out_of_solid(self))
211             objerror("could not get out of solid at all!");
212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
214         print(" ", ftos(self.origin_y - o_y));
215         print(" ", ftos(self.origin_z - o_z), "'\n");
216         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
217         {
218             if (!spawnpoint_nag)
219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
220             spawnpoint_nag = 1;
221         }
222         else
223         {
224             setorigin(self, o);
225             self.mins = self.maxs = '0 0 0';
226             objerror("player spawn point in solid, mapper sucks!\n");
227             return;
228         }
229     }
230
231     self.use = spawnpoint_use;
232     self.team_saved = self.team;
233     if (!self.cnt)
234         self.cnt = 1;
235
236     if (have_team_spawns != 0)
237         if (self.team)
238             have_team_spawns = 1;
239
240     if (cvar("r_showbboxes"))
241     {
242         // show where spawnpoints point at too
243         makevectors(self.angles);
244         entity e;
245         e = spawn();
246         e.classname = "info_player_foo";
247         setorigin(e, self.origin + v_forward * 24);
248         setsize(e, '-8 -8 -8', '8 8 8');
249         e.solid = SOLID_TRIGGER;
250     }
251 }
252
253 #define strstr strstrofs
254 /*
255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
258 // BE CONSTANT OR strzoneD!
259 float strstr(string haystack, string needle, float offset)
260 {
261         float len, endpos;
262         string found;
263         len = strlen(needle);
264         endpos = strlen(haystack) - len;
265         while(offset <= endpos)
266         {
267                 found = substring(haystack, offset, len);
268                 if(found == needle)
269                         return offset;
270                 offset = offset + 1;
271         }
272         return -1;
273 }
274 */
275
276 float NUM_NEAREST_ENTITIES = 4;
277 entity nearest_entity[NUM_NEAREST_ENTITIES];
278 float nearest_length[NUM_NEAREST_ENTITIES];
279 entity findnearest(vector point, .string field, string value, vector axismod)
280 {
281     entity localhead;
282     float i;
283     float j;
284     float len;
285     vector dist;
286
287     float num_nearest;
288     num_nearest = 0;
289
290     localhead = find(world, field, value);
291     while (localhead)
292     {
293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
294             dist = localhead.oldorigin;
295         else
296             dist = localhead.origin;
297         dist = dist - point;
298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
299         len = vlen(dist);
300
301         for (i = 0; i < num_nearest; ++i)
302         {
303             if (len < nearest_length[i])
304                 break;
305         }
306
307         // now i tells us where to insert at
308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
309         if (i < NUM_NEAREST_ENTITIES)
310         {
311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
312             {
313                 nearest_length[j + 1] = nearest_length[j];
314                 nearest_entity[j + 1] = nearest_entity[j];
315             }
316             nearest_length[i] = len;
317             nearest_entity[i] = localhead;
318             if (num_nearest < NUM_NEAREST_ENTITIES)
319                 num_nearest = num_nearest + 1;
320         }
321
322         localhead = find(localhead, field, value);
323     }
324
325     // now use the first one from our list that we can see
326     for (i = 0; i < num_nearest; ++i)
327     {
328         traceline(point, nearest_entity[i].origin, TRUE, world);
329         if (trace_fraction == 1)
330         {
331             if (i != 0)
332             {
333                 dprint("Nearest point (");
334                 dprint(nearest_entity[0].netname);
335                 dprint(") is not visible, using a visible one.\n");
336             }
337             return nearest_entity[i];
338         }
339     }
340
341     if (num_nearest == 0)
342         return world;
343
344     dprint("Not seeing any location point, using nearest as fallback.\n");
345     /* DEBUGGING CODE:
346     dprint("Candidates were: ");
347     for(j = 0; j < num_nearest; ++j)
348     {
349         if(j != 0)
350                 dprint(", ");
351         dprint(nearest_entity[j].netname);
352     }
353     dprint("\n");
354     */
355
356     return nearest_entity[0];
357 }
358
359 void spawnfunc_target_location()
360 {
361     self.classname = "target_location";
362     // location name in netname
363     // eventually support: count, teamgame selectors, line of sight?
364 };
365
366 void spawnfunc_info_location()
367 {
368     self.classname = "target_location";
369     self.message = self.netname;
370 };
371
372 string NearestLocation(vector p)
373 {
374     entity loc;
375     string ret;
376     ret = "somewhere";
377     loc = findnearest(p, classname, "target_location", '1 1 1');
378     if (loc)
379     {
380         ret = loc.message;
381     }
382     else
383     {
384         loc = findnearest(p, target, "###item###", '1 1 4');
385         if (loc)
386             ret = loc.netname;
387     }
388     return ret;
389 }
390
391 string formatmessage(string msg)
392 {
393         float p, p1, p2;
394         float n;
395         vector cursor;
396         entity cursor_ent;
397         string escape;
398         string replacement;
399         p = 0;
400         n = 7;
401
402         WarpZone_crosshair_trace(self);
403         cursor = trace_endpos;
404         cursor_ent = trace_ent;
405
406         while (1) {
407                 if (n < 1)
408                         break; // too many replacements
409
410                 n = n - 1;
411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
413
414                 if (p1 < 0)
415                         p1 = p2;
416
417                 if (p2 < 0)
418                         p2 = p1;
419
420                 p = min(p1, p2);
421
422                 if (p < 0)
423                         break;
424
425                 replacement = substring(msg, p, 2);
426                 escape = substring(msg, p + 1, 1);
427
428                 if (escape == "%")
429                         replacement = "%";
430                 else if (escape == "\\")
431                         replacement = "\\";
432                 else if (escape == "n")
433                         replacement = "\n";
434                 else if (escape == "a")
435                         replacement = ftos(floor(self.armorvalue));
436                 else if (escape == "h")
437                         replacement = ftos(floor(self.health));
438                 else if (escape == "l")
439                         replacement = NearestLocation(self.origin);
440                 else if (escape == "y")
441                         replacement = NearestLocation(cursor);
442                 else if (escape == "d")
443                         replacement = NearestLocation(self.death_origin);
444                 else if (escape == "w") {
445                         float wep;
446                         wep = self.weapon;
447                         if (!wep)
448                                 wep = self.switchweapon;
449                         if (!wep)
450                                 wep = self.cnt;
451                         replacement = W_Name(wep);
452                 } else if (escape == "W") {
453                         if (self.items & IT_SHELLS) replacement = "shells";
454                         else if (self.items & IT_NAILS) replacement = "bullets";
455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
456                         else if (self.items & IT_CELLS) replacement = "cells";
457                         else replacement = "batteries"; // ;)
458                 } else if (escape == "x") {
459                         replacement = cursor_ent.netname;
460                         if (!replacement || !cursor_ent)
461                                 replacement = "nothing";
462                 } else if (escape == "p") {
463                         if (self.last_selected_player)
464                                 replacement = self.last_selected_player.netname;
465                         else
466                                 replacement = "(nobody)";
467                 } else if (escape == "s")
468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
469                 else if (escape == "S")
470                         replacement = ftos(vlen(self.velocity));
471
472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
473                 p = p + strlen(replacement);
474         }
475         return msg;
476 }
477
478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
479         return (value == 0) ? FALSE : TRUE;
480 }
481
482 /*
483 =============
484 GetCvars
485 =============
486 Called with:
487   0:  sends the request
488   >0: receives a cvar from name=argv(f) value=argv(f+1)
489 */
490 void GetCvars_handleString(string thisname, float f, .string field, string name)
491 {
492         if (f < 0)
493         {
494                 if (self.field)
495                         strunzone(self.field);
496                 self.field = string_null;
497         }
498         else if (f > 0)
499         {
500                 if (thisname == name)
501                 {
502                         if (self.field)
503                                 strunzone(self.field);
504                         self.field = strzone(argv(f + 1));
505                 }
506         }
507         else
508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
509 }
510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
511 {
512         GetCvars_handleString(thisname, f, field, name);
513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
514                 if (thisname == name)
515                 {
516                         string s;
517                         s = func(strcat1(self.field));
518                         if (s != self.field)
519                         {
520                                 strunzone(self.field);
521                                 self.field = strzone(s);
522                         }
523                 }
524 }
525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
526 {
527         if (f < 0)
528         {
529         }
530         else if (f > 0)
531         {
532                 if (thisname == name)
533                         self.field = stof(argv(f + 1));
534         }
535         else
536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
537 }
538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
539 {
540         if (f < 0)
541         {
542         }
543         else if (f > 0)
544         {
545                 if (thisname == name)
546                 {
547                         if(!self.field)
548                         {
549                                 self.field = stof(argv(f + 1));
550                                 if(!self.field)
551                                         self.field = -1;
552                         }
553                 }
554         }
555         else
556         {
557                 if(!self.field)
558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
559         }
560 }
561 float w_getbestweapon(entity e);
562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
563 {
564         string o;
565         o = W_FixWeaponOrder_ForceComplete(wo);
566         if(self.weaponorder_byimpulse)
567         {
568                 strunzone(self.weaponorder_byimpulse);
569                 self.weaponorder_byimpulse = string_null;
570         }
571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
572         return o;
573 }
574 void GetCvars(float f)
575 {
576         string s;
577
578         if (f > 0)
579                 s = strcat1(argv(f));
580
581         get_cvars_f = f;
582         get_cvars_s = s;
583         MUTATOR_CALLHOOK(GetCvars);
584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
609
610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
612
613 #ifdef ALLOW_FORCEMODELS
614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
616 #endif
617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
619
620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
621         if (f > 0)
622         {
623                 if (s == "cl_weaponpriority")
624                         self.switchweapon = w_getbestweapon(self);
625         }
626 }
627
628 float fexists(string f)
629 {
630     float fh;
631     fh = fopen(f, FILE_READ);
632     if (fh < 0)
633         return FALSE;
634     fclose(fh);
635     return TRUE;
636 }
637
638 void backtrace(string msg)
639 {
640     float dev, war;
641     dev = cvar("developer");
642     war = cvar("prvm_backtraceforwarnings");
643     cvar_set("developer", "1");
644     cvar_set("prvm_backtraceforwarnings", "1");
645     print("\n");
646     print("--- CUT HERE ---\nWARNING: ");
647     print(msg);
648     print("\n");
649     remove(world); // isn't there any better way to cause a backtrace?
650     print("\n--- CUT UNTIL HERE ---\n");
651     cvar_set("developer", ftos(dev));
652     cvar_set("prvm_backtraceforwarnings", ftos(war));
653 }
654
655 string Team_ColorCode(float teamid)
656 {
657     if (teamid == COLOR_TEAM1)
658         return "^1";
659     else if (teamid == COLOR_TEAM2)
660         return "^4";
661     else if (teamid == COLOR_TEAM3)
662         return "^3";
663     else if (teamid == COLOR_TEAM4)
664         return "^6";
665     else
666         return "^7";
667 }
668
669 string Team_ColorName(float t)
670 {
671     // fixme: Search for team entities and get their .netname's!
672     if (t == COLOR_TEAM1)
673         return "Red";
674     if (t == COLOR_TEAM2)
675         return "Blue";
676     if (t == COLOR_TEAM3)
677         return "Yellow";
678     if (t == COLOR_TEAM4)
679         return "Pink";
680     return "Neutral";
681 }
682
683 string Team_ColorNameLowerCase(float t)
684 {
685     // fixme: Search for team entities and get their .netname's!
686     if (t == COLOR_TEAM1)
687         return "red";
688     if (t == COLOR_TEAM2)
689         return "blue";
690     if (t == COLOR_TEAM3)
691         return "yellow";
692     if (t == COLOR_TEAM4)
693         return "pink";
694     return "neutral";
695 }
696
697 float ColourToNumber(string team_colour)
698 {
699         if (team_colour == "red")
700                 return COLOR_TEAM1;
701
702         if (team_colour == "blue")
703                 return COLOR_TEAM2;
704
705         if (team_colour == "yellow")
706                 return COLOR_TEAM3;
707
708         if (team_colour == "pink")
709                 return COLOR_TEAM4;
710
711         if (team_colour == "auto")
712                 return 0;
713
714         return -1;
715 }
716
717 float NumberToTeamNumber(float number)
718 {
719         if (number == 1)
720                 return COLOR_TEAM1;
721
722         if (number == 2)
723                 return COLOR_TEAM2;
724
725         if (number == 3)
726                 return COLOR_TEAM3;
727
728         if (number == 4)
729                 return COLOR_TEAM4;
730
731         return -1;
732 }
733
734 #define CENTERPRIO_POINT 1
735 #define CENTERPRIO_SPAM 2
736 #define CENTERPRIO_VOTE 4
737 #define CENTERPRIO_NORMAL 5
738 #define CENTERPRIO_SHIELDING 7
739 #define CENTERPRIO_MAPVOTE 9
740 #define CENTERPRIO_IDLEKICK 50
741 #define CENTERPRIO_ADMIN 99
742 .float centerprint_priority;
743 .float centerprint_expires;
744 void centerprint_atprio(entity e, float prio, string s)
745 {
746     if (intermission_running)
747         if (prio < CENTERPRIO_MAPVOTE)
748             return;
749     if (time > e.centerprint_expires)
750         e.centerprint_priority = 0;
751     if (prio >= e.centerprint_priority)
752     {
753         e.centerprint_priority = prio;
754         if (timeoutStatus == 2)
755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
756         else
757             e.centerprint_expires = time + e.cvar_scr_centertime;
758         centerprint_builtin(e, s);
759     }
760 }
761 void centerprint_expire(entity e, float prio)
762 {
763     if (prio == e.centerprint_priority)
764     {
765         e.centerprint_priority = 0;
766         centerprint_builtin(e, "");
767     }
768 }
769 void centerprint(entity e, string s)
770 {
771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
772 }
773
774 // decolorizes and team colors the player name when needed
775 string playername(entity p)
776 {
777     string t;
778     if (teams_matter && !intermission_running && p.classname == "player")
779     {
780         t = Team_ColorCode(p.team);
781         return strcat(t, strdecolorize(p.netname));
782     }
783     else
784         return p.netname;
785 }
786
787 vector randompos(vector m1, vector m2)
788 {
789     local vector v;
790     m2 = m2 - m1;
791     v_x = m2_x * random() + m1_x;
792     v_y = m2_y * random() + m1_y;
793     v_z = m2_z * random() + m1_z;
794     return  v;
795 };
796
797 //#NO AUTOCVARS START
798
799 float g_pickup_shells;
800 float g_pickup_shells_max;
801 float g_pickup_nails;
802 float g_pickup_nails_max;
803 float g_pickup_rockets;
804 float g_pickup_rockets_max;
805 float g_pickup_cells;
806 float g_pickup_cells_max;
807 float g_pickup_fuel;
808 float g_pickup_fuel_jetpack;
809 float g_pickup_fuel_max;
810 float g_pickup_armorsmall;
811 float g_pickup_armorsmall_max;
812 float g_pickup_armorsmall_anyway;
813 float g_pickup_armormedium;
814 float g_pickup_armormedium_max;
815 float g_pickup_armormedium_anyway;
816 float g_pickup_armorbig;
817 float g_pickup_armorbig_max;
818 float g_pickup_armorbig_anyway;
819 float g_pickup_armorlarge;
820 float g_pickup_armorlarge_max;
821 float g_pickup_armorlarge_anyway;
822 float g_pickup_healthsmall;
823 float g_pickup_healthsmall_max;
824 float g_pickup_healthsmall_anyway;
825 float g_pickup_healthmedium;
826 float g_pickup_healthmedium_max;
827 float g_pickup_healthmedium_anyway;
828 float g_pickup_healthlarge;
829 float g_pickup_healthlarge_max;
830 float g_pickup_healthlarge_anyway;
831 float g_pickup_healthmega;
832 float g_pickup_healthmega_max;
833 float g_pickup_healthmega_anyway;
834 float g_pickup_ammo_anyway;
835 float g_pickup_weapons_anyway;
836 float g_weaponarena;
837 float g_weaponarena_random;
838 float g_weaponarena_random_with_laser;
839 string g_weaponarena_list;
840 float g_weaponspeedfactor;
841 float g_weaponratefactor;
842 float g_weapondamagefactor;
843 float g_weaponforcefactor;
844 float g_weaponspreadfactor;
845
846 float start_weapons;
847 float start_items;
848 float start_ammo_shells;
849 float start_ammo_nails;
850 float start_ammo_rockets;
851 float start_ammo_cells;
852 float start_ammo_fuel;
853 float start_health;
854 float start_armorvalue;
855 float warmup_start_weapons;
856 float warmup_start_ammo_shells;
857 float warmup_start_ammo_nails;
858 float warmup_start_ammo_rockets;
859 float warmup_start_ammo_cells;
860 float warmup_start_ammo_fuel;
861 float warmup_start_health;
862 float warmup_start_armorvalue;
863 float g_weapon_stay;
864 float g_ghost_items;
865
866 entity get_weaponinfo(float w);
867
868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
869 {
870         var float i = weaponinfo.weapon;
871
872         if (!i)
873                 return 0;
874
875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
876
877         if (t < 0) // "default" weapon selection
878         {
879                 if (g_lms || g_ca || allguns)
880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
881                 else if(t < -1)
882                         t = 0;
883                 else if (g_race || g_cts)
884                         t = (i == WEP_LASER);
885                 else if (g_nexball)
886                         t = 0; // weapon is set a few lines later
887                 else
888                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
889                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
890                         t |= (i == WEP_HOOK);
891         }
892
893         // we cannot disable porto in Nexball, we must force it
894         if(g_nexball && i == WEP_PORTO)
895                 t = 1;
896
897         return t;
898 }
899
900 void readplayerstartcvars()
901 {
902         entity e;
903         float i, j, t;
904         string s;
905
906         // initialize starting values for players
907         start_weapons = 0;
908         start_items = 0;
909         start_ammo_shells = 0;
910         start_ammo_nails = 0;
911         start_ammo_rockets = 0;
912         start_ammo_cells = 0;
913         start_health = cvar("g_balance_health_start");
914         start_armorvalue = cvar("g_balance_armor_start");
915
916         g_weaponarena = 0;
917         s = cvar_string("g_weaponarena");
918         if (s == "0")
919         {
920         }
921         else if (s == "all")
922         {
923                 g_weaponarena_list = "All Weapons";
924                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
925                 {
926                         e = get_weaponinfo(j);
927                         g_weaponarena |= e.weapons;
928                         weapon_action(e.weapon, WR_PRECACHE);
929                 }
930         }
931         else if (s == "most")
932         {
933                 g_weaponarena_list = "Most Weapons";
934                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
935                 {
936                         e = get_weaponinfo(j);
937                         if (e.spawnflags & WEP_FLAG_NORMAL)
938                         {
939                                 g_weaponarena |= e.weapons;
940                                 weapon_action(e.weapon, WR_PRECACHE);
941                         }
942                 }
943         }
944         else if (s == "none")
945         {
946                 g_weaponarena_list = "No Weapons";
947                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
948         }
949         else
950         {
951                 t = tokenize_console(s);
952                 g_weaponarena_list = "";
953                 for (i = 0; i < t; ++i)
954                 {
955                         s = argv(i);
956                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
957                         {
958                                 e = get_weaponinfo(j);
959                                 if (e.netname == s)
960                                 {
961                                         g_weaponarena |= e.weapons;
962                                         weapon_action(e.weapon, WR_PRECACHE);
963                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
964                                         break;
965                                 }
966                         }
967                         if (j > WEP_LAST)
968                         {
969                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
970                         }
971                 }
972                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
973         }
974
975         if(g_weaponarena)
976                 g_weaponarena_random = cvar("g_weaponarena_random");
977         else
978                 g_weaponarena_random = 0;
979         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
980
981         if (g_weaponarena)
982         {
983                 start_weapons = g_weaponarena;
984                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
985                         start_ammo_rockets = 999;
986                 if (g_weaponarena & WEPBIT_SHOTGUN)
987                         start_ammo_shells = 999;
988                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
989                         start_ammo_cells = 999;
990                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
991                         start_ammo_nails = 999;
992                 if (g_weaponarena & WEPBIT_HOOK)
993                         start_ammo_fuel = 999;
994                 start_items |= IT_UNLIMITED_AMMO;
995         }
996         else if (g_minstagib)
997         {
998                 start_health = 100;
999                 start_armorvalue = 0;
1000                 start_weapons = WEPBIT_MINSTANEX;
1001                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1002                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1003                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1004                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1005
1006                 if (g_minstagib_invis_alpha <= 0)
1007                         g_minstagib_invis_alpha = -1;
1008         }
1009         else
1010         {
1011                 if (g_lms || g_ca)
1012                 {
1013                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1014                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1015                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1016                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1017                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1018                         start_health = cvar("g_lms_start_health");
1019                         start_armorvalue = cvar("g_lms_start_armor");
1020                 }
1021                 else
1022                 {
1023                         start_ammo_shells = cvar("g_start_ammo_shells");
1024                         start_ammo_nails = cvar("g_start_ammo_nails");
1025                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1026                         start_ammo_cells = cvar("g_start_ammo_cells");
1027                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1028                 }
1029
1030                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1031                 {
1032                         e = get_weaponinfo(i);
1033                         if(want_weapon("g_start_weapon_", e, FALSE))
1034                                 start_weapons |= e.weapons;
1035                 }
1036         }
1037
1038         if (inWarmupStage)
1039         {
1040                 warmup_start_ammo_shells = start_ammo_shells;
1041                 warmup_start_ammo_nails = start_ammo_nails;
1042                 warmup_start_ammo_rockets = start_ammo_rockets;
1043                 warmup_start_ammo_cells = start_ammo_cells;
1044                 warmup_start_ammo_fuel = start_ammo_fuel;
1045                 warmup_start_health = start_health;
1046                 warmup_start_armorvalue = start_armorvalue;
1047                 warmup_start_weapons = start_weapons;
1048
1049                 if (!g_weaponarena && !g_minstagib && !g_ca)
1050                 {
1051                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1052                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1053                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1054                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1055                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1056                         warmup_start_health = cvar("g_warmup_start_health");
1057                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1058                         warmup_start_weapons = 0;
1059                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1060                         {
1061                                 e = get_weaponinfo(i);
1062                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1063                                         warmup_start_weapons |= e.weapons;
1064                         }
1065                 }
1066         }
1067
1068         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1069         {
1070                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1071                 start_items |= IT_FUEL_REGEN;
1072                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1073                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1074         }
1075
1076         if(!cvar("g_use_ammunition"))
1077         {
1078                 start_ammo_shells = cvar("g_pickup_shells_max");
1079                 start_ammo_nails = cvar("g_pickup_nails_max");
1080                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1081                 start_ammo_cells = cvar("g_pickup_cells_max");
1082                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1083                 start_items |= IT_UNLIMITED_AMMO;
1084                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1085                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1086                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1087                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1088                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1089                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1090         }
1091
1092         if (g_jetpack)
1093                 start_items |= IT_JETPACK;
1094
1095         if (g_weapon_stay == 2)
1096         {
1097                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1098                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1099                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1100                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1101                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1102                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1103                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1104                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1105                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1106                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1107         }
1108
1109         MUTATOR_CALLHOOK(SetStartItems);
1110
1111         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1112         {
1113                 e = get_weaponinfo(i);
1114                 if(e.weapons & (start_weapons | warmup_start_weapons))
1115                         weapon_action(e.weapon, WR_PRECACHE);
1116         }
1117
1118         start_ammo_shells = max(0, start_ammo_shells);
1119         start_ammo_nails = max(0, start_ammo_nails);
1120         start_ammo_cells = max(0, start_ammo_cells);
1121         start_ammo_rockets = max(0, start_ammo_rockets);
1122         start_ammo_fuel = max(0, start_ammo_fuel);
1123
1124         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1125         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1126         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1127         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1128         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1129 }
1130
1131 float g_bugrigs;
1132 float g_bugrigs_planar_movement;
1133 float g_bugrigs_planar_movement_car_jumping;
1134 float g_bugrigs_reverse_spinning;
1135 float g_bugrigs_reverse_speeding;
1136 float g_bugrigs_reverse_stopping;
1137 float g_bugrigs_air_steering;
1138 float g_bugrigs_angle_smoothing;
1139 float g_bugrigs_friction_floor;
1140 float g_bugrigs_friction_brake;
1141 float g_bugrigs_friction_air;
1142 float g_bugrigs_accel;
1143 float g_bugrigs_speed_ref;
1144 float g_bugrigs_speed_pow;
1145 float g_bugrigs_steer;
1146
1147 float g_touchexplode;
1148 float g_touchexplode_radius;
1149 float g_touchexplode_damage;
1150 float g_touchexplode_edgedamage;
1151 float g_touchexplode_force;
1152
1153 float sv_autotaunt;
1154 float sv_taunt;
1155
1156 float sv_pitch_min;
1157 float sv_pitch_max;
1158 float sv_pitch_fixyaw;
1159
1160 float sv_accuracy_data_share;
1161
1162 void readlevelcvars(void)
1163 {
1164         // first load all the mutators
1165         if(cvar("g_nix"))
1166                 MUTATOR_ADD(mutator_nix);
1167         if(cvar("g_dodging"))
1168                 MUTATOR_ADD(mutator_dodging);
1169         if(cvar("g_rocket_flying"))
1170                 MUTATOR_ADD(mutator_rocketflying);
1171         if(cvar("g_vampire"))
1172                 MUTATOR_ADD(mutator_vampire);
1173
1174         serverflags = 0;
1175         if(cvar("sv_allow_fullbright"))
1176                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1177
1178     g_bugrigs = cvar("g_bugrigs");
1179     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1180     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1181     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1182     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1183     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1184     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1185     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1186     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1187     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1188     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1189     g_bugrigs_accel = cvar("g_bugrigs_accel");
1190     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1191     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1192     g_bugrigs_steer = cvar("g_bugrigs_steer");
1193
1194     g_touchexplode = cvar("g_touchexplode");
1195     g_touchexplode_radius = cvar("g_touchexplode_radius");
1196     g_touchexplode_damage = cvar("g_touchexplode_damage");
1197     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1198     g_touchexplode_force = cvar("g_touchexplode_force");
1199
1200 #ifdef ALLOW_FORCEMODELS
1201         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1202 #endif
1203         sv_loddistance1 = cvar("sv_loddistance1");
1204         sv_loddistance2 = cvar("sv_loddistance2");
1205
1206         if(sv_loddistance2 <= sv_loddistance1)
1207                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1208
1209         sv_clones = cvar("sv_clones");
1210         sv_gentle = cvar("sv_gentle");
1211         sv_foginterval = cvar("sv_foginterval");
1212         g_cloaked = cvar("g_cloaked");
1213         g_jump_grunt = cvar("g_jump_grunt");
1214         g_footsteps = cvar("g_footsteps");
1215         g_grappling_hook = cvar("g_grappling_hook");
1216         g_jetpack = cvar("g_jetpack");
1217         g_midair = cvar("g_midair");
1218         g_minstagib = cvar("g_minstagib");
1219         g_norecoil = cvar("g_norecoil");
1220         g_bloodloss = cvar("g_bloodloss");
1221         sv_maxidle = cvar("sv_maxidle");
1222         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1223         sv_pogostick = cvar("sv_pogostick");
1224         g_ctf_reverse = cvar("g_ctf_reverse");
1225         sv_autotaunt = cvar("sv_autotaunt");
1226         sv_taunt = cvar("sv_taunt");
1227
1228         inWarmupStage = cvar("g_warmup");
1229         g_warmup_limit = cvar("g_warmup_limit");
1230         g_warmup_allguns = cvar("g_warmup_allguns");
1231         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1232
1233         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1234                 inWarmupStage = 0; // these modes cannot work together, sorry
1235
1236         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1237         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1238         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1239         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1240         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1241         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1242         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1243         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1244         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1245         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1246         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1247         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1248
1249         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1250         g_weaponratefactor = cvar("g_weaponratefactor");
1251         g_weapondamagefactor = cvar("g_weapondamagefactor");
1252         g_weaponforcefactor = cvar("g_weaponforcefactor");
1253         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1254
1255         g_pickup_shells = cvar("g_pickup_shells");
1256         g_pickup_shells_max = cvar("g_pickup_shells_max");
1257         g_pickup_nails = cvar("g_pickup_nails");
1258         g_pickup_nails_max = cvar("g_pickup_nails_max");
1259         g_pickup_rockets = cvar("g_pickup_rockets");
1260         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1261         g_pickup_cells = cvar("g_pickup_cells");
1262         g_pickup_cells_max = cvar("g_pickup_cells_max");
1263         g_pickup_fuel = cvar("g_pickup_fuel");
1264         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1265         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1266         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1267         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1268         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1269         g_pickup_armormedium = cvar("g_pickup_armormedium");
1270         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1271         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1272         g_pickup_armorbig = cvar("g_pickup_armorbig");
1273         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1274         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1275         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1276         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1277         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1278         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1279         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1280         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1281         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1282         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1283         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1284         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1285         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1286         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1287         g_pickup_healthmega = cvar("g_pickup_healthmega");
1288         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1289         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1290
1291         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1292         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1293
1294         g_pinata = cvar("g_pinata");
1295
1296         g_weapon_stay = cvar("g_weapon_stay");
1297
1298         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1299                 g_weapon_stay = 1;
1300
1301         g_ghost_items = cvar("g_ghost_items");
1302
1303         if(g_ghost_items >= 1)
1304                 g_ghost_items = 0.25; // default alpha value
1305
1306         if not(inWarmupStage && !g_ca)
1307                 game_starttime = cvar("g_start_delay");
1308
1309         sv_pitch_min = cvar("sv_pitch_min");
1310         sv_pitch_max = cvar("sv_pitch_max");
1311         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1312
1313         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1314
1315         readplayerstartcvars();
1316 }
1317
1318 //#NO AUTOCVARS END
1319
1320 // Sound functions
1321 string precache_sound (string s) = #19;
1322 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1323 float precache_sound_index (string s) = #19;
1324
1325 #define SND_VOLUME      1
1326 #define SND_ATTENUATION 2
1327 #define SND_LARGEENTITY 8
1328 #define SND_LARGESOUND  16
1329
1330 float sound_allowed(float dest, entity e)
1331 {
1332     // sounds from world may always pass
1333     for (;;)
1334     {
1335         if (e.classname == "body")
1336             e = e.enemy;
1337         if (e.owner && e.owner != e)
1338             e = e.owner;
1339         else
1340             break;
1341     }
1342     // sounds to self may always pass
1343     if (dest == MSG_ONE)
1344         if (e == msg_entity)
1345             return TRUE;
1346     // sounds by players can be removed
1347     if (cvar("bot_sound_monopoly"))
1348         if (clienttype(e) == CLIENTTYPE_REAL)
1349             return FALSE;
1350     // anything else may pass
1351     return TRUE;
1352 }
1353
1354 void sound(entity e, float chan, string samp, float vol, float atten)
1355 {
1356     if (!sound_allowed(MSG_BROADCAST, e))
1357         return;
1358     sound_builtin(e, chan, samp, vol, atten);
1359 }
1360 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1361 {
1362     float entno, idx;
1363
1364     if (!sound_allowed(dest, e))
1365         return;
1366
1367     entno = num_for_edict(e);
1368     idx = precache_sound_index(samp);
1369
1370     float sflags;
1371     sflags = 0;
1372
1373     atten = floor(atten * 64);
1374     vol = floor(vol * 255);
1375
1376     if (vol != 255)
1377         sflags |= SND_VOLUME;
1378     if (atten != 64)
1379         sflags |= SND_ATTENUATION;
1380     if (entno >= 8192)
1381         sflags |= SND_LARGEENTITY;
1382     if (idx >= 256)
1383         sflags |= SND_LARGESOUND;
1384
1385     WriteByte(dest, SVC_SOUND);
1386     WriteByte(dest, sflags);
1387     if (sflags & SND_VOLUME)
1388         WriteByte(dest, vol);
1389     if (sflags & SND_ATTENUATION)
1390         WriteByte(dest, atten);
1391     if (sflags & SND_LARGEENTITY)
1392     {
1393         WriteShort(dest, entno);
1394         WriteByte(dest, chan);
1395     }
1396     else
1397     {
1398         WriteShort(dest, entno * 8 + chan);
1399     }
1400     if (sflags & SND_LARGESOUND)
1401         WriteShort(dest, idx);
1402     else
1403         WriteByte(dest, idx);
1404
1405     WriteCoord(dest, o_x);
1406     WriteCoord(dest, o_y);
1407     WriteCoord(dest, o_z);
1408 }
1409 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1410 {
1411     vector o;
1412
1413     if (!sound_allowed(dest, e))
1414         return;
1415
1416     o = e.origin + 0.5 * (e.mins + e.maxs);
1417     soundtoat(dest, e, o, chan, samp, vol, atten);
1418 }
1419 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1420 {
1421     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1422 }
1423 void stopsoundto(float dest, entity e, float chan)
1424 {
1425     float entno;
1426
1427     if (!sound_allowed(dest, e))
1428         return;
1429
1430     entno = num_for_edict(e);
1431
1432     if (entno >= 8192)
1433     {
1434         float idx, sflags;
1435         idx = precache_sound_index("misc/null.wav");
1436         sflags = SND_LARGEENTITY;
1437         if (idx >= 256)
1438             sflags |= SND_LARGESOUND;
1439         WriteByte(dest, SVC_SOUND);
1440         WriteByte(dest, sflags);
1441         WriteShort(dest, entno);
1442         WriteByte(dest, chan);
1443         if (sflags & SND_LARGESOUND)
1444             WriteShort(dest, idx);
1445         else
1446             WriteByte(dest, idx);
1447         WriteCoord(dest, e.origin_x);
1448         WriteCoord(dest, e.origin_y);
1449         WriteCoord(dest, e.origin_z);
1450     }
1451     else
1452     {
1453         WriteByte(dest, SVC_STOPSOUND);
1454         WriteShort(dest, entno * 8 + chan);
1455     }
1456 }
1457 void stopsound(entity e, float chan)
1458 {
1459     if (!sound_allowed(MSG_BROADCAST, e))
1460         return;
1461
1462     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1463     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1464 }
1465
1466 void play2(entity e, string filename)
1467 {
1468     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1469     msg_entity = e;
1470     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1471 }
1472
1473 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1474 .float spamtime;
1475 float spamsound(entity e, float chan, string samp, float vol, float atten)
1476 {
1477     if (!sound_allowed(MSG_BROADCAST, e))
1478         return FALSE;
1479
1480     if (time > e.spamtime)
1481     {
1482         e.spamtime = time;
1483         sound(e, chan, samp, vol, atten);
1484         return TRUE;
1485     }
1486     return FALSE;
1487 }
1488
1489 void play2team(float t, string filename)
1490 {
1491     local entity head;
1492
1493     if (cvar("bot_sound_monopoly"))
1494         return;
1495
1496     FOR_EACH_REALPLAYER(head)
1497     {
1498         if (head.team == t)
1499             play2(head, filename);
1500     }
1501 }
1502
1503 void play2all(string samp)
1504 {
1505     if (cvar("bot_sound_monopoly"))
1506         return;
1507
1508     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1509 }
1510
1511 void PrecachePlayerSounds(string f);
1512 void precache_playermodel(string m)
1513 {
1514         float globhandle, i, n;
1515         string f;
1516
1517         if(substring(m, -9,5) == "_lod1")
1518                 return;
1519         if(substring(m, -9,5) == "_lod2")
1520                 return;
1521         precache_model(m);
1522         if(sv_loddistance1)
1523         {
1524                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1525                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1526         }
1527
1528         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1529         if (globhandle < 0)
1530                 return;
1531         n = search_getsize(globhandle);
1532         for (i = 0; i < n; ++i)
1533         {
1534                 //print(search_getfilename(globhandle, i), "\n");
1535                 f = search_getfilename(globhandle, i);
1536                 PrecachePlayerSounds(f);
1537         }
1538         search_end(globhandle);
1539 }
1540 void precache_all_playermodels(string pattern)
1541 {
1542         float globhandle, i, n;
1543         string f;
1544
1545         globhandle = search_begin(pattern, TRUE, FALSE);
1546         if (globhandle < 0)
1547                 return;
1548         n = search_getsize(globhandle);
1549         for (i = 0; i < n; ++i)
1550         {
1551                 //print(search_getfilename(globhandle, i), "\n");
1552                 f = search_getfilename(globhandle, i);
1553                 precache_playermodel(f);
1554         }
1555         search_end(globhandle);
1556 }
1557
1558 void precache()
1559 {
1560     // gamemode related things
1561     precache_model ("models/misc/chatbubble.spr");
1562     precache_model ("models/misc/teambubble.spr");
1563     if (g_runematch)
1564     {
1565         precache_model ("models/runematch/curse.mdl");
1566         precache_model ("models/runematch/rune.mdl");
1567     }
1568
1569 #ifdef TTURRETS_ENABLED
1570     if (cvar("g_turrets"))
1571         turrets_precash();
1572 #endif
1573
1574     // Precache all player models if desired
1575     if (cvar("sv_precacheplayermodels"))
1576     {
1577         PrecachePlayerSounds("sound/player/default.sounds");
1578         precache_all_playermodels("models/player/*.zym");
1579         precache_all_playermodels("models/player/*.dpm");
1580         precache_all_playermodels("models/player/*.md3");
1581         precache_all_playermodels("models/player/*.psk");
1582         precache_all_playermodels("models/player/*.iqm");
1583     }
1584
1585     if (cvar("sv_defaultcharacter"))
1586     {
1587         string s;
1588         s = cvar_string("sv_defaultplayermodel_red");
1589         if (s != "")
1590             precache_playermodel(s);
1591         s = cvar_string("sv_defaultplayermodel_blue");
1592         if (s != "")
1593             precache_playermodel(s);
1594         s = cvar_string("sv_defaultplayermodel_yellow");
1595         if (s != "")
1596             precache_playermodel(s);
1597         s = cvar_string("sv_defaultplayermodel_pink");
1598         if (s != "")
1599             precache_playermodel(s);
1600         s = cvar_string("sv_defaultplayermodel");
1601         if (s != "")
1602             precache_playermodel(s);
1603     }
1604
1605     if (g_footsteps)
1606     {
1607         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1608         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1609     }
1610
1611     // gore and miscellaneous sounds
1612     //precache_sound ("misc/h2ohit.wav");
1613     precache_model ("models/hook.md3");
1614     precache_sound ("misc/armorimpact.wav");
1615     precache_sound ("misc/bodyimpact1.wav");
1616     precache_sound ("misc/bodyimpact2.wav");
1617     precache_sound ("misc/gib.wav");
1618     precache_sound ("misc/gib_splat01.wav");
1619     precache_sound ("misc/gib_splat02.wav");
1620     precache_sound ("misc/gib_splat03.wav");
1621     precache_sound ("misc/gib_splat04.wav");
1622     precache_sound ("misc/hit.wav");
1623         precache_sound ("misc/typehit.wav");
1624     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1625     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1626     precache_sound ("misc/null.wav");
1627     precache_sound ("misc/spawn.wav");
1628     precache_sound ("misc/talk.wav");
1629     precache_sound ("misc/teleport.wav");
1630     precache_sound ("misc/poweroff.wav");
1631     precache_sound ("player/lava.wav");
1632     precache_sound ("player/slime.wav");
1633
1634     if (g_jetpack)
1635         precache_sound ("misc/jetpack_fly.wav");
1636
1637     precache_model ("models/sprites/0.spr32");
1638     precache_model ("models/sprites/1.spr32");
1639     precache_model ("models/sprites/2.spr32");
1640     precache_model ("models/sprites/3.spr32");
1641     precache_model ("models/sprites/4.spr32");
1642     precache_model ("models/sprites/5.spr32");
1643     precache_model ("models/sprites/6.spr32");
1644     precache_model ("models/sprites/7.spr32");
1645     precache_model ("models/sprites/8.spr32");
1646     precache_model ("models/sprites/9.spr32");
1647     precache_model ("models/sprites/10.spr32");
1648
1649     // common weapon precaches
1650     precache_sound ("weapons/weapon_switch.wav");
1651     precache_sound ("weapons/weaponpickup.wav");
1652     precache_sound ("weapons/unavailable.wav");
1653     precache_sound ("weapons/dryfire.wav");
1654     if (g_grappling_hook)
1655     {
1656         precache_sound ("weapons/hook_fire.wav"); // hook
1657         precache_sound ("weapons/hook_impact.wav"); // hook
1658     }
1659
1660     if(cvar("sv_precacheweapons"))
1661     {
1662         //precache weapon models/sounds
1663         local float wep;
1664         wep = WEP_FIRST;
1665         while (wep <= WEP_LAST)
1666         {
1667             weapon_action(wep, WR_PRECACHE);
1668             wep = wep + 1;
1669         }
1670     }
1671
1672     precache_model("models/elaser.mdl");
1673     precache_model("models/laser.mdl");
1674     precache_model("models/ebomb.mdl");
1675
1676 #if 0
1677     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1678
1679     if (!self.noise && self.music) // quake 3 uses the music field
1680         self.noise = self.music;
1681
1682     // plays music for the level if there is any
1683     if (self.noise)
1684     {
1685         precache_sound (self.noise);
1686         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1687     }
1688 #endif
1689 }
1690
1691 // sorry, but using \ in macros breaks line numbers
1692 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1693 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1694 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1695
1696 // WARNING: this kills the trace globals
1697 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1698 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1699
1700 #define INITPRIO_FIRST              0
1701 #define INITPRIO_GAMETYPE           0
1702 #define INITPRIO_GAMETYPE_FALLBACK  1
1703 #define INITPRIO_FINDTARGET        10
1704 #define INITPRIO_DROPTOFLOOR       20
1705 #define INITPRIO_SETLOCATION       90
1706 #define INITPRIO_LINKDOORS         91
1707 #define INITPRIO_LAST              99
1708
1709 .void(void) initialize_entity;
1710 .float initialize_entity_order;
1711 .entity initialize_entity_next;
1712 entity initialize_entity_first;
1713
1714 void make_safe_for_remove(entity e)
1715 {
1716     if (e.initialize_entity)
1717     {
1718         entity ent, prev;
1719         for (ent = initialize_entity_first; ent; )
1720         {
1721             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1722             {
1723                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1724                 // skip it in linked list
1725                 if (prev)
1726                 {
1727                     prev.initialize_entity_next = ent.initialize_entity_next;
1728                     ent = prev.initialize_entity_next;
1729                 }
1730                 else
1731                 {
1732                     initialize_entity_first = ent.initialize_entity_next;
1733                     ent = initialize_entity_first;
1734                 }
1735             }
1736             else
1737             {
1738                 prev = ent;
1739                 ent = ent.initialize_entity_next;
1740             }
1741         }
1742     }
1743 }
1744
1745 void objerror(string s)
1746 {
1747     make_safe_for_remove(self);
1748     objerror_builtin(s);
1749 }
1750
1751 void remove_unsafely(entity e)
1752 {
1753     remove_builtin(e);
1754 }
1755
1756 void remove_safely(entity e)
1757 {
1758     make_safe_for_remove(e);
1759     remove_builtin(e);
1760 }
1761
1762 void InitializeEntity(entity e, void(void) func, float order)
1763 {
1764     entity prev, cur;
1765
1766     if (!e || e.initialize_entity)
1767     {
1768         // make a proxy initializer entity
1769         entity e_old;
1770         e_old = e;
1771         e = spawn();
1772         e.classname = "initialize_entity";
1773         e.enemy = e_old;
1774     }
1775
1776     e.initialize_entity = func;
1777     e.initialize_entity_order = order;
1778
1779     cur = initialize_entity_first;
1780     for (;;)
1781     {
1782         if (!cur || cur.initialize_entity_order > order)
1783         {
1784             // insert between prev and cur
1785             if (prev)
1786                 prev.initialize_entity_next = e;
1787             else
1788                 initialize_entity_first = e;
1789             e.initialize_entity_next = cur;
1790             return;
1791         }
1792         prev = cur;
1793         cur = cur.initialize_entity_next;
1794     }
1795 }
1796 void InitializeEntitiesRun()
1797 {
1798     entity startoflist;
1799     startoflist = initialize_entity_first;
1800     initialize_entity_first = world;
1801     for (self = startoflist; self; )
1802     {
1803         entity e;
1804         var void(void) func;
1805         e = self.initialize_entity_next;
1806         func = self.initialize_entity;
1807         self.initialize_entity_order = 0;
1808         self.initialize_entity = func_null;
1809         self.initialize_entity_next = world;
1810         if (self.classname == "initialize_entity")
1811         {
1812             entity e_old;
1813             e_old = self.enemy;
1814             remove_builtin(self);
1815             self = e_old;
1816         }
1817         //dprint("Delayed initialization: ", self.classname, "\n");
1818         func();
1819         self = e;
1820     }
1821 }
1822
1823 .float uncustomizeentityforclient_set;
1824 .void(void) uncustomizeentityforclient;
1825 void(void) SUB_Nullpointer = #0;
1826 void UncustomizeEntitiesRun()
1827 {
1828     entity oldself;
1829     oldself = self;
1830     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1831         self.uncustomizeentityforclient();
1832     self = oldself;
1833 }
1834 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1835 {
1836     e.customizeentityforclient = customizer;
1837     e.uncustomizeentityforclient = uncustomizer;
1838     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1839 }
1840
1841 .float nottargeted;
1842 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1843
1844 void() SUB_Remove;
1845 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1846 {
1847     vector mi, ma;
1848
1849     if (e.classname == "")
1850         e.classname = "net_linked";
1851
1852     if (e.model == "" || self.modelindex == 0)
1853     {
1854         mi = e.mins;
1855         ma = e.maxs;
1856         setmodel(e, "null");
1857         setsize(e, mi, ma);
1858     }
1859
1860     e.SendEntity = sendfunc;
1861     e.SendFlags = 0xFFFFFF;
1862
1863     if (!docull)
1864         e.effects |= EF_NODEPTHTEST;
1865
1866     if (dt)
1867     {
1868         e.nextthink = time + dt;
1869         e.think = SUB_Remove;
1870     }
1871 }
1872
1873 void adaptor_think2touch()
1874 {
1875     entity o;
1876     o = other;
1877     other = world;
1878     self.touch();
1879     other = o;
1880 }
1881
1882 void adaptor_think2use()
1883 {
1884     entity o, a;
1885     o = other;
1886     a = activator;
1887     activator = world;
1888     other = world;
1889     self.use();
1890     other = o;
1891     activator = a;
1892 }
1893
1894 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1895 {
1896         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1897                 self.projectiledeathtype |= HITTYPE_SPLASH;
1898         adaptor_think2use();
1899 }
1900
1901 // deferred dropping
1902 void DropToFloor_Handler()
1903 {
1904     droptofloor_builtin();
1905     self.dropped_origin = self.origin;
1906 }
1907
1908 void droptofloor()
1909 {
1910     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1911 }
1912
1913
1914
1915 float trace_hits_box_a0, trace_hits_box_a1;
1916
1917 float trace_hits_box_1d(float end, float thmi, float thma)
1918 {
1919     if (end == 0)
1920     {
1921         // just check if x is in range
1922         if (0 < thmi)
1923             return FALSE;
1924         if (0 > thma)
1925             return FALSE;
1926     }
1927     else
1928     {
1929         // do the trace with respect to x
1930         // 0 -> end has to stay in thmi -> thma
1931         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1932         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1933         if (trace_hits_box_a0 > trace_hits_box_a1)
1934             return FALSE;
1935     }
1936     return TRUE;
1937 }
1938
1939 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1940 {
1941     end -= start;
1942     thmi -= start;
1943     thma -= start;
1944     // now it is a trace from 0 to end
1945
1946     trace_hits_box_a0 = 0;
1947     trace_hits_box_a1 = 1;
1948
1949     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1950         return FALSE;
1951     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1952         return FALSE;
1953     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1954         return FALSE;
1955
1956     return TRUE;
1957 }
1958
1959 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1960 {
1961     return trace_hits_box(start, end, thmi - ma, thma - mi);
1962 }
1963
1964 float SUB_NoImpactCheck()
1965 {
1966         // zero hitcontents = this is not the real impact, but either the
1967         // mirror-impact of something hitting the projectile instead of the
1968         // projectile hitting the something, or a touchareagrid one. Neither of
1969         // these stop the projectile from moving, so...
1970         if(trace_dphitcontents == 0)
1971         {
1972                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1973                 checkclient();
1974         }
1975     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1976         return 1;
1977     if (other == world && self.size != '0 0 0')
1978     {
1979         vector tic;
1980         tic = self.velocity * sys_frametime;
1981         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1982         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1983         if (trace_fraction >= 1)
1984         {
1985             dprint("Odd... did not hit...?\n");
1986         }
1987         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1988         {
1989             dprint("Detected and prevented the sky-grapple bug.\n");
1990             return 1;
1991         }
1992     }
1993
1994     return 0;
1995 }
1996
1997 #define SUB_OwnerCheck() (other && (other == self.owner))
1998
1999 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2000 {
2001         if(SUB_OwnerCheck())
2002                 return TRUE;
2003         if(SUB_NoImpactCheck())
2004         {
2005                 remove(self);
2006                 return TRUE;
2007         }
2008         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2009                 UpdateCSQCProjectileNextFrame(self);
2010         return FALSE;
2011 }
2012 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2013
2014 float MAX_IPBAN_URIS           = 16;
2015                               
2016 float URI_GET_DISCARD          = 0;
2017 float URI_GET_IPBAN            = 1;
2018 float URI_GET_IPBAN_END        = 16;
2019 float URI_GET_PLAYERSTATS_SENT = 17;
2020
2021 void URI_Get_Callback(float id, float status, string data)
2022 {
2023     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2024     dprint(data);
2025     dprint("\nEnd of data.\n");
2026
2027     if (id == URI_GET_DISCARD)
2028     {
2029         // discard
2030     }
2031     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2032     {
2033         // online ban list
2034         OnlineBanList_URI_Get_Callback(id, status, data);
2035     }
2036     else if (id == URI_GET_PLAYERSTATS_SENT)
2037     {
2038         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2039     }
2040     else
2041     {
2042         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2043     }
2044 }
2045
2046 void print_to(entity e, string s)
2047 {
2048     if (e)
2049         sprint(e, strcat(s, "\n"));
2050     else
2051         print(s, "\n");
2052 }
2053
2054 string uid2name(string myuid) {
2055         string s;
2056         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2057         
2058         if(s == "")
2059                 s = "^1Unregistered Player";
2060         return s;
2061 }
2062
2063 float race_readTime(string map, float pos)
2064 {
2065         string rr;
2066         if(g_cts)
2067                 rr = CTS_RECORD;
2068         else
2069                 rr = RACE_RECORD;
2070
2071         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2072 }
2073
2074 string race_readUID(string map, float pos)
2075 {
2076         string rr;
2077         if(g_cts)
2078                 rr = CTS_RECORD;
2079         else
2080                 rr = RACE_RECORD;
2081
2082         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2083 }
2084
2085 float race_readPos(string map, float t) {
2086         float i;
2087         for (i = 1; i <= RANKINGS_CNT; ++i)
2088                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2089                         return i;
2090
2091         return 0; // pos is zero if unranked
2092 }
2093
2094 void race_writeTime(string map, float t, string myuid)
2095 {
2096         string rr;
2097         if(g_cts)
2098                 rr = CTS_RECORD;
2099         else
2100                 rr = RACE_RECORD;
2101
2102         float newpos;
2103         newpos = race_readPos(map, t);
2104
2105         float i, prevpos;
2106         for(i = 1; i <= RANKINGS_CNT; ++i)
2107         {
2108                 if(race_readUID(map, i) == myuid)
2109                         prevpos = i;
2110         }
2111         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2112                 for (i = prevpos; i > newpos; --i) {
2113                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2114                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2115                 }
2116         } else { // player has no ranked record yet
2117                 for (i = RANKINGS_CNT; i > newpos; --i) {
2118                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2119                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2120                 }
2121         }
2122
2123         // store new time itself
2124         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2125         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2126 }
2127
2128 string race_readName(string map, float pos)
2129 {
2130         string rr;
2131         if(g_cts)
2132                 rr = CTS_RECORD;
2133         else
2134                 rr = RACE_RECORD;
2135
2136         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2137 }
2138
2139 string race_placeName(float pos) {
2140         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2141         {
2142                 if(mod(pos, 10) == 1)
2143                         return strcat(ftos(pos), "st");
2144                 else if(mod(pos, 10) == 2)
2145                         return strcat(ftos(pos), "nd");
2146                 else if(mod(pos, 10) == 3)
2147                         return strcat(ftos(pos), "rd");
2148                 else
2149                         return strcat(ftos(pos), "th");
2150         }
2151         else
2152                 return strcat(ftos(pos), "th");
2153 }
2154 string getrecords(float page) // 50 records per page
2155 {
2156     float rec;
2157     string h;
2158     float r;
2159     float i;
2160     string s;
2161
2162     rec = 0;
2163
2164     s = "";
2165
2166     if (g_ctf)
2167     {
2168         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2169         {
2170             if (MapInfo_Get_ByID(i))
2171             {
2172                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2173                 if (r == 0)
2174                     continue;
2175                 // TODO: uid2name
2176                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2177                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2178                 ++rec;
2179             }
2180         }
2181     }
2182
2183     if (g_race)
2184     {
2185         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2186         {
2187             if (MapInfo_Get_ByID(i))
2188             {
2189                 r = race_readTime(MapInfo_Map_bspname, 1);
2190                 if (r == 0)
2191                     continue;
2192                 h = race_readName(MapInfo_Map_bspname, 1);
2193                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2194                 ++rec;
2195             }
2196         }
2197     }
2198
2199     if (g_cts)
2200     {
2201         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2202         {
2203             if (MapInfo_Get_ByID(i))
2204             {
2205                 r = race_readTime(MapInfo_Map_bspname, 1);
2206                 if (r == 0)
2207                     continue;
2208                 h = race_readName(MapInfo_Map_bspname, 1);
2209                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2210                 ++rec;
2211             }
2212         }
2213     }
2214
2215     MapInfo_ClearTemps();
2216
2217     if (s == "" && page == 0)
2218         return "No records are available on this server.\n";
2219     else
2220         return s;
2221 }
2222
2223 string getrankings()
2224 {
2225     string n;
2226     float t;
2227     float i;
2228     string s;
2229     string p;
2230     string map;
2231
2232     s = "";
2233
2234     map = GetMapname();
2235
2236     for (i = 1; i <= RANKINGS_CNT; ++i)
2237     {
2238         t = race_readTime(map, i);
2239         if (t == 0)
2240             continue;
2241         n = race_readName(map, i);
2242         p = race_placeName(i);
2243         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2244     }
2245
2246     MapInfo_ClearTemps();
2247
2248     if (s == "")
2249         return strcat("No records are available for the map: ", map, "\n");
2250     else
2251         return strcat("Records for ", map, ":\n", s);
2252 }
2253
2254 #define LADDER_FIRSTPOINT 100
2255 #define LADDER_CNT 10
2256         // position X still gives LADDER_FIRSTPOINT/X points
2257 #define LADDER_SIZE 30
2258         // ladder shows the top X players
2259 string top_uids[LADDER_SIZE];
2260 float top_scores[LADDER_SIZE];
2261 string getladder()
2262 {
2263     float i, j, k, uidcnt;
2264     string s, temp_s;
2265
2266     s = "";
2267     temp_s = "";
2268
2269     string rr;
2270     if(g_cts)
2271         rr = CTS_RECORD;
2272     else
2273         rr = RACE_RECORD;
2274
2275     string myuid;
2276
2277     for (k = 0; k < MapInfo_count; ++k)
2278     {
2279         if (MapInfo_Get_ByID(k))
2280         {
2281                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2282                         if(i == 0) // speed award
2283                         {
2284                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2285                                         continue;
2286
2287                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2288                         }
2289                         else // normal record, if it exists (else break)
2290                         {
2291                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2292                                         continue;
2293
2294                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2295                         }
2296
2297                         // string s contains:
2298                         // arg 0 = # of speed recs
2299                         // arg 1 = # of 1st place recs
2300                         // arg 2 = # of 2nd place recs
2301                         // ... etc
2302                         // LADDER_CNT+1 = total points
2303
2304                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2305                         if (temp_s == "")
2306                         {
2307                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2308                             ++uidcnt;
2309                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2310                             {
2311                                 if(j != LADDER_CNT + 1)
2312                                     temp_s = strcat(temp_s, "0 ");
2313                                 else
2314                                     temp_s = strcat(temp_s, "0");
2315                             }
2316                         }
2317
2318                         tokenize_console(temp_s);
2319                         s = "";
2320
2321                         if(i == 0) // speed award
2322                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2323                             {
2324                                 if(j == 0) // speed award
2325                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2326                                 else
2327                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2328                             }
2329                         else // record
2330                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2331                             {
2332                                 if(j == 0)
2333                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2334                                 else if(j == i) // wanted rec!
2335                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2336                                 else
2337                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2338                             }
2339
2340                         // total points are (by default) calculated like this:
2341                         // speedrec = floor(100 / 10) = 10 points
2342                         // 1st place = floor(100 / 1) = 100 points
2343                         // 2nd place = floor(100 / 2) = 50 points
2344                         // 3rd place = floor(100 / 3) = 33 points
2345                         // 4th place = floor(100 / 4) = 25 points
2346                         // 5th place = floor(100 / 5) = 20 points
2347                         // ... etc
2348
2349                         if(i == 0)
2350                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2351                         else
2352                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2353
2354                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2355                 }
2356         }
2357     }
2358
2359     float thiscnt;
2360     string thisuid;
2361     for (i = 0; i <= uidcnt; ++i) // for each known uid
2362     {
2363         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2364         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2365         tokenize_console(temp_s);
2366         thiscnt = stof(argv(LADDER_CNT+1));
2367
2368         if(thiscnt > top_scores[LADDER_SIZE-1])
2369         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2370         {
2371             if(thiscnt > top_scores[j])
2372             {
2373                 for (k = LADDER_SIZE-1; k >= j; --k)
2374                 {
2375                     top_uids[k] = top_uids[k-1];
2376                     top_scores[k] = top_scores[k-1];
2377                 }
2378                 top_uids[j] = thisuid;
2379                 top_scores[j] = thiscnt;
2380                 break;
2381             }
2382         }
2383     }
2384
2385     s = "^3-----------------------\n\n";
2386
2387     s = strcat(s, "Pos ^3|");
2388     s = strcat(s, " ^7Total  ^3|");
2389     for (i = 1; i <= LADDER_CNT; ++i)
2390     {
2391         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2392     }
2393     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2394
2395     s = strcat(s, "\n^3----+--------");
2396     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2397     {
2398         s = strcat(s, "+-----");
2399     }
2400 #if LADDER_CNT > 9
2401     for (i = 1; i <= LADDER_CNT - 9; ++i)
2402     {
2403         s = strcat(s, "+------");
2404     }
2405 #endif
2406
2407     s = strcat(s, "+--------------+--------------------\n");
2408
2409     for (i = 0; i < LADDER_SIZE; ++i)
2410     {
2411         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2412         tokenize_console(temp_s);
2413         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2414             continue;
2415         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2416         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2417         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2418         {
2419             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2420         }
2421 #if LADDER_CNT > 9
2422         for (j = 10; j <= LADDER_CNT; ++j)
2423         {
2424             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2425         }
2426 #endif
2427
2428         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2429         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2430     }
2431
2432     MapInfo_ClearTemps();
2433
2434     if (s == "")
2435         return "No ladder on this server!\n";
2436     else
2437         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2438 }
2439
2440
2441 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2442 {
2443     float m, i;
2444     vector start, org, delta, end, enddown, mstart;
2445
2446     m = e.dphitcontentsmask;
2447     e.dphitcontentsmask = goodcontents | badcontents;
2448
2449     org = world.mins;
2450     delta = world.maxs - world.mins;
2451
2452     for (i = 0; i < attempts; ++i)
2453     {
2454         start_x = org_x + random() * delta_x;
2455         start_y = org_y + random() * delta_y;
2456         start_z = org_z + random() * delta_z;
2457
2458         // rule 1: start inside world bounds, and outside
2459         // solid, and don't start from somewhere where you can
2460         // fall down to evil
2461         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2462         if (trace_fraction >= 1)
2463             continue;
2464         if (trace_startsolid)
2465             continue;
2466         if (trace_dphitcontents & badcontents)
2467             continue;
2468         if (trace_dphitq3surfaceflags & badsurfaceflags)
2469             continue;
2470
2471         // rule 2: if we are too high, lower the point
2472         if (trace_fraction * delta_z > maxaboveground)
2473             start = trace_endpos + '0 0 1' * maxaboveground;
2474         enddown = trace_endpos;
2475
2476         // rule 3: make sure we aren't outside the map. This only works
2477         // for somewhat well formed maps. A good rule of thumb is that
2478         // the map should have a convex outside hull.
2479         // these can be traceLINES as we already verified the starting box
2480         mstart = start + 0.5 * (e.mins + e.maxs);
2481         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2482         if (trace_fraction >= 1)
2483             continue;
2484         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2485         if (trace_fraction >= 1)
2486             continue;
2487         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2488         if (trace_fraction >= 1)
2489             continue;
2490         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2491         if (trace_fraction >= 1)
2492             continue;
2493         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2494         if (trace_fraction >= 1)
2495             continue;
2496
2497         // find a random vector to "look at"
2498         end_x = org_x + random() * delta_x;
2499         end_y = org_y + random() * delta_y;
2500         end_z = org_z + random() * delta_z;
2501         end = start + normalize(end - start) * vlen(delta);
2502
2503         // rule 4: start TO end must not be too short
2504         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2505         if (trace_startsolid)
2506             continue;
2507         if (trace_fraction < minviewdistance / vlen(delta))
2508             continue;
2509
2510         // rule 5: don't want to look at sky
2511         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2512             continue;
2513
2514         // rule 6: we must not end up in trigger_hurt
2515         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2516         {
2517             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2518             continue;
2519         }
2520
2521         break;
2522     }
2523
2524     e.dphitcontentsmask = m;
2525
2526     if (i < attempts)
2527     {
2528         setorigin(e, start);
2529         e.angles = vectoangles(end - start);
2530         dprint("Needed ", ftos(i + 1), " attempts\n");
2531         return TRUE;
2532     }
2533     else
2534         return FALSE;
2535 }
2536
2537 float zcurveparticles_effectno;
2538 vector zcurveparticles_start;
2539 float zcurveparticles_spd;
2540
2541 void endzcurveparticles()
2542 {
2543         if(zcurveparticles_effectno)
2544         {
2545                 // terminator
2546                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2547         }
2548         zcurveparticles_effectno = 0;
2549 }
2550
2551 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2552 {
2553         spd = bound(0, floor(spd / 16), 32767);
2554         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2555         {
2556                 endzcurveparticles();
2557                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2558                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2559                 WriteShort(MSG_BROADCAST, effectno);
2560                 WriteCoord(MSG_BROADCAST, start_x);
2561                 WriteCoord(MSG_BROADCAST, start_y);
2562                 WriteCoord(MSG_BROADCAST, start_z);
2563                 zcurveparticles_effectno = effectno;
2564                 zcurveparticles_start = start;
2565         }
2566         else
2567                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2568         WriteCoord(MSG_BROADCAST, end_x);
2569         WriteCoord(MSG_BROADCAST, end_y);
2570         WriteCoord(MSG_BROADCAST, end_z);
2571         WriteCoord(MSG_BROADCAST, end_dz);
2572         zcurveparticles_spd = spd;
2573 }
2574
2575 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2576 {
2577         float end_dz;
2578         vector vecxy, velxy;
2579
2580         vecxy = end - start;
2581         vecxy_z = 0;
2582         velxy = vel;
2583         velxy_z = 0;
2584
2585         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2586         {
2587                 endzcurveparticles();
2588                 trailparticles(world, effectno, start, end);
2589                 return;
2590         }
2591
2592         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2593         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2594 }
2595
2596 string GetGametype(); // g_world.qc
2597 void write_recordmarker(entity pl, float tstart, float dt)
2598 {
2599     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2600
2601     // also write a marker into demo files for demotc-race-record-extractor to find
2602     stuffcmd(pl,
2603              strcat(
2604                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2605                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2606 }
2607
2608 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2609 {
2610         switch(algn)
2611         {
2612                 case 1: // right
2613                         break;
2614
2615                 case 2: // left
2616                         vecs_y = -vecs_y;
2617                         break;
2618
2619                 default:
2620                 case 3:
2621                         if(allowcenter) // 2: allow center handedness
2622                         {
2623                                 // center
2624                                 vecs_y = 0;
2625                                 vecs_z -= 2;
2626                         }
2627                         else
2628                         {
2629                                 // right
2630                         }
2631                         break;
2632
2633                 case 4:
2634                         if(allowcenter) // 2: allow center handedness
2635                         {
2636                                 // center
2637                                 vecs_y = 0;
2638                                 vecs_z -= 2;
2639                         }
2640                         else
2641                         {
2642                                 // left
2643                                 vecs_y = -vecs_y;
2644                         }
2645                         break;
2646         }
2647         return vecs;
2648 }
2649
2650 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2651 {
2652         string s;
2653         vector v;
2654
2655         if (cvar("g_shootfromeye"))
2656         {
2657                 if (visual)
2658                 {
2659                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2660                 }
2661                 else
2662                 {
2663                         vecs_y = 0;
2664                         vecs_z = 0;
2665                 }
2666         }
2667         else if (cvar("g_shootfromcenter"))
2668         {
2669                 if (visual)
2670                 {
2671                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2672                 }
2673                 else
2674                 {
2675                         vecs_y = 0;
2676                         vecs_z -= 2;
2677                 }
2678         }
2679         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2680         {
2681                 v = stov(s);
2682                 if (y_is_right)
2683                         v_y = -v_y;
2684                 if (v_x != 0)
2685                         vecs_x = v_x;
2686                 vecs_y = v_y;
2687                 vecs_z = v_z;
2688         }
2689         else if (cvar("g_shootfromclient"))
2690         {
2691                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2692         }
2693         return vecs;
2694 }
2695
2696 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2697 {
2698         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2699 }
2700
2701
2702 void attach_sameorigin(entity e, entity to, string tag)
2703 {
2704     vector org, t_forward, t_left, t_up, e_forward, e_up;
2705     vector org0, ang0;
2706     float tagscale;
2707
2708     ang0 = e.angles;
2709     org0 = e.origin;
2710
2711     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2712     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2713     t_forward = v_forward * tagscale;
2714     t_left = v_right * -tagscale;
2715     t_up = v_up * tagscale;
2716
2717     e.origin_x = org * t_forward;
2718     e.origin_y = org * t_left;
2719     e.origin_z = org * t_up;
2720
2721     // current forward and up directions
2722     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2723                 e.angles = AnglesTransform_FromVAngles(e.angles);
2724         else
2725                 e.angles = AnglesTransform_FromAngles(e.angles);
2726     fixedmakevectors(e.angles);
2727
2728     // untransform forward, up!
2729     e_forward_x = v_forward * t_forward;
2730     e_forward_y = v_forward * t_left;
2731     e_forward_z = v_forward * t_up;
2732     e_up_x = v_up * t_forward;
2733     e_up_y = v_up * t_left;
2734     e_up_z = v_up * t_up;
2735
2736     e.angles = fixedvectoangles2(e_forward, e_up);
2737     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2738                 e.angles = AnglesTransform_ToVAngles(e.angles);
2739         else
2740                 e.angles = AnglesTransform_ToAngles(e.angles);
2741
2742     setattachment(e, to, tag);
2743     setorigin(e, e.origin);
2744 }
2745
2746 void detach_sameorigin(entity e)
2747 {
2748     vector org;
2749     org = gettaginfo(e, 0);
2750     e.angles = fixedvectoangles2(v_forward, v_up);
2751     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2752                 e.angles = AnglesTransform_ToVAngles(e.angles);
2753         else
2754                 e.angles = AnglesTransform_ToAngles(e.angles);
2755     setorigin(e, org);
2756     setattachment(e, world, "");
2757     setorigin(e, e.origin);
2758 }
2759
2760 void follow_sameorigin(entity e, entity to)
2761 {
2762     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2763     e.aiment = to; // make the hole follow bmodel
2764     e.punchangle = to.angles; // the original angles of bmodel
2765     e.view_ofs = e.origin - to.origin; // relative origin
2766     e.v_angle = e.angles - to.angles; // relative angles
2767 }
2768
2769 void unfollow_sameorigin(entity e)
2770 {
2771     e.movetype = MOVETYPE_NONE;
2772 }
2773
2774 entity gettaginfo_relative_ent;
2775 vector gettaginfo_relative(entity e, float tag)
2776 {
2777     if (!gettaginfo_relative_ent)
2778     {
2779         gettaginfo_relative_ent = spawn();
2780         gettaginfo_relative_ent.effects = EF_NODRAW;
2781     }
2782     gettaginfo_relative_ent.model = e.model;
2783     gettaginfo_relative_ent.modelindex = e.modelindex;
2784     gettaginfo_relative_ent.frame = e.frame;
2785     return gettaginfo(gettaginfo_relative_ent, tag);
2786 }
2787
2788 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2789 {
2790     float p;
2791     p = pow(2, chan);
2792     if (pl.soundentity.cnt & p)
2793         return;
2794     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2795     pl.soundentity.cnt |= p;
2796 }
2797
2798 void SoundEntity_StopSound(entity pl, float chan)
2799 {
2800     float p;
2801     p = pow(2, chan);
2802     if (pl.soundentity.cnt & p)
2803     {
2804         stopsoundto(MSG_ALL, pl.soundentity, chan);
2805         pl.soundentity.cnt &~= p;
2806     }
2807 }
2808
2809 void SoundEntity_Attach(entity pl)
2810 {
2811     pl.soundentity = spawn();
2812     pl.soundentity.classname = "soundentity";
2813     pl.soundentity.owner = pl;
2814     setattachment(pl.soundentity, pl, "");
2815     setmodel(pl.soundentity, "null");
2816 }
2817
2818 void SoundEntity_Detach(entity pl)
2819 {
2820     float i;
2821     for (i = 0; i <= 7; ++i)
2822         SoundEntity_StopSound(pl, i);
2823 }
2824
2825
2826 float ParseCommandPlayerSlotTarget_firsttoken;
2827 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2828 {
2829     string s;
2830     entity e, head;
2831     float n;
2832
2833     s = string_null;
2834
2835     ParseCommandPlayerSlotTarget_firsttoken = -1;
2836
2837     if (tokens > idx)
2838     {
2839         if (substring(argv(idx), 0, 1) == "#")
2840         {
2841             s = substring(argv(idx), 1, -1);
2842             ++idx;
2843             if (s == "")
2844                 if (tokens > idx)
2845                 {
2846                     s = argv(idx);
2847                     ++idx;
2848                 }
2849                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2850             if (s == ftos(stof(s)))
2851             {
2852                 e = edict_num(stof(s));
2853                 if (e.flags & FL_CLIENT)
2854                     return e;
2855             }
2856         }
2857         else
2858         {
2859             // it must be a nick name
2860             s = argv(idx);
2861             ++idx;
2862                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2863
2864             n = 0;
2865             FOR_EACH_CLIENT(head)
2866             if (head.netname == s)
2867             {
2868                 e = head;
2869                 ++n;
2870             }
2871             if (n == 1)
2872                 return e;
2873
2874             s = strdecolorize(s);
2875             n = 0;
2876             FOR_EACH_CLIENT(head)
2877             if (strdecolorize(head.netname) == s)
2878             {
2879                 e = head;
2880                 ++n;
2881             }
2882             if (n == 1)
2883                 return e;
2884         }
2885     }
2886
2887     return world;
2888 }
2889
2890 .float scale2;
2891
2892 float modeleffect_SendEntity(entity to, float sf)
2893 {
2894         float f;
2895         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2896
2897         f = 0;
2898         if(self.velocity != '0 0 0')
2899                 f |= 1;
2900         if(self.angles != '0 0 0')
2901                 f |= 2;
2902         if(self.avelocity != '0 0 0')
2903                 f |= 4;
2904
2905         WriteByte(MSG_ENTITY, f);
2906         WriteShort(MSG_ENTITY, self.modelindex);
2907         WriteByte(MSG_ENTITY, self.skin);
2908         WriteByte(MSG_ENTITY, self.frame);
2909         WriteCoord(MSG_ENTITY, self.origin_x);
2910         WriteCoord(MSG_ENTITY, self.origin_y);
2911         WriteCoord(MSG_ENTITY, self.origin_z);
2912         if(f & 1)
2913         {
2914                 WriteCoord(MSG_ENTITY, self.velocity_x);
2915                 WriteCoord(MSG_ENTITY, self.velocity_y);
2916                 WriteCoord(MSG_ENTITY, self.velocity_z);
2917         }
2918         if(f & 2)
2919         {
2920                 WriteCoord(MSG_ENTITY, self.angles_x);
2921                 WriteCoord(MSG_ENTITY, self.angles_y);
2922                 WriteCoord(MSG_ENTITY, self.angles_z);
2923         }
2924         if(f & 4)
2925         {
2926                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2927                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2928                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2929         }
2930         WriteShort(MSG_ENTITY, self.scale * 256.0);
2931         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2932         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2933         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2934         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2935
2936         return TRUE;
2937 }
2938
2939 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2940 {
2941         entity e;
2942         float sz;
2943         e = spawn();
2944         e.classname = "modeleffect";
2945         setmodel(e, m);
2946         e.frame = f;
2947         setorigin(e, o);
2948         e.velocity = v;
2949         e.angles = ang;
2950         e.avelocity = angv;
2951         e.alpha = a;
2952         e.teleport_time = t1;
2953         e.fade_time = t2;
2954         e.skin = s;
2955         if(s0 >= 0)
2956                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2957         else
2958                 e.scale = -s0;
2959         if(s2 >= 0)
2960                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2961         else
2962                 e.scale2 = -s2;
2963         sz = max(e.scale, e.scale2);
2964         setsize(e, e.mins * sz, e.maxs * sz);
2965         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2966 }
2967
2968 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2969 {
2970         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2971 }
2972
2973 float randombit(float bits)
2974 {
2975         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2976                 return bits;
2977
2978         float n, f, b, r;
2979
2980         r = random();
2981         b = 0;
2982         n = 0;
2983
2984         for(f = 1; f <= bits; f *= 2)
2985         {
2986                 if(bits & f)
2987                 {
2988                         ++n;
2989                         r *= n;
2990                         if(r <= 1)
2991                                 b = f;
2992                         else
2993                                 r = (r - 1) / (n - 1);
2994                 }
2995         }
2996
2997         return b;
2998 }
2999
3000 float randombits(float bits, float k, float error_return)
3001 {
3002         float r;
3003         r = 0;
3004         while(k > 0 && bits != r)
3005         {
3006                 r += randombit(bits - r);
3007                 --k;
3008         }
3009         if(error_return)
3010                 if(k > 0)
3011                         return -1; // all
3012         return r;
3013 }
3014
3015 void randombit_test(float bits, float iter)
3016 {
3017         while(iter > 0)
3018         {
3019                 print(ftos(randombit(bits)), "\n");
3020                 --iter;
3021         }
3022 }
3023
3024 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3025 {
3026         if(halflifedist > 0)
3027                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3028         else if(halflifedist < 0)
3029                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3030         else
3031                 return 1;
3032 }
3033
3034
3035
3036
3037 #ifdef RELEASE
3038 #define cvar_string_normal cvar_string_builtin
3039 #define cvar_normal cvar_builtin
3040 #else
3041 string cvar_string_normal(string n)
3042 {
3043         if not(cvar_type(n) & 1)
3044                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3045         return cvar_string_builtin(n);
3046 }
3047
3048 float cvar_normal(string n)
3049 {
3050         return stof(cvar_string_normal(n));
3051 }
3052 #endif
3053 #define cvar_set_normal cvar_set_builtin
3054
3055 void defer_think()
3056 {
3057     entity oself;
3058
3059     oself           = self;
3060     self            = self.owner;
3061     oself.think     = SUB_Remove;
3062     oself.nextthink = time;
3063
3064     oself.use();
3065 }
3066
3067 /*
3068     Execute func() after time + fdelay.
3069     self when func is executed = self when defer is called
3070 */
3071 void defer(float fdelay, void() func)
3072 {
3073     entity e;
3074
3075     e           = spawn();
3076     e.owner     = self;
3077     e.use       = func;
3078     e.think     = defer_think;
3079     e.nextthink = time + fdelay;
3080 }