qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_race || g_cts)
 884                         t = (i == WEP_SHOTGUN);
 885                 else if (g_nexball)
 886                         t = 0; // weapon is set a few lines later
 887                 else
 888                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 889                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 890                         t |= (i == WEP_HOOK);
 891         }
 892
 893         // we cannot disable porto in Nexball, we must force it
 894         if(g_nexball && i == WEP_PORTO)
 895                 t = 1;
 896
 897         return t;
 898 }
 899
 900 void readplayerstartcvars()
 901 {
 902         entity e;
 903         float i, j, t;
 904         string s;
 905
 906         // initialize starting values for players
 907         start_weapons = 0;
 908         start_items = 0;
 909         start_ammo_shells = 0;
 910         start_ammo_nails = 0;
 911         start_ammo_rockets = 0;
 912         start_ammo_cells = 0;
 913         start_health = cvar("g_balance_health_start");
 914         start_armorvalue = cvar("g_balance_armor_start");
 915
 916         g_weaponarena = 0;
 917         s = cvar_string("g_weaponarena");
 918         if (s == "0")
 919         {
 920         }
 921         else if (s == "all")
 922         {
 923                 g_weaponarena_list = "All Weapons";
 924                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 925                 {
 926                         e = get_weaponinfo(j);
 927                         g_weaponarena |= e.weapons;
 928                         weapon_action(e.weapon, WR_PRECACHE);
 929                 }
 930         }
 931         else if (s == "most")
 932         {
 933                 g_weaponarena_list = "Most Weapons";
 934                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 935                 {
 936                         e = get_weaponinfo(j);
 937                         if (e.spawnflags & WEP_FLAG_NORMAL)
 938                         {
 939                                 g_weaponarena |= e.weapons;
 940                                 weapon_action(e.weapon, WR_PRECACHE);
 941                         }
 942                 }
 943         }
 944         else if (s == "none")
 945         {
 946                 g_weaponarena_list = "No Weapons";
 947                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 948         }
 949         else
 950         {
 951                 t = tokenize_console(s);
 952                 g_weaponarena_list = "";
 953                 for (i = 0; i < t; ++i)
 954                 {
 955                         s = argv(i);
 956                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 957                         {
 958                                 e = get_weaponinfo(j);
 959                                 if (e.netname == s)
 960                                 {
 961                                         g_weaponarena |= e.weapons;
 962                                         weapon_action(e.weapon, WR_PRECACHE);
 963                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 964                                         break;
 965                                 }
 966                         }
 967                         if (j > WEP_LAST)
 968                         {
 969                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 970                         }
 971                 }
 972                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 973         }
 974
 975         if(g_weaponarena)
 976                 g_weaponarena_random = cvar("g_weaponarena_random");
 977         else
 978                 g_weaponarena_random = 0;
 979         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 980
 981         if (g_weaponarena)
 982         {
 983                 start_weapons = g_weaponarena;
 984                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 985                         start_ammo_rockets = 999;
 986                 if (g_weaponarena & WEPBIT_SHOTGUN)
 987                         start_ammo_shells = 999;
 988                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 989                         start_ammo_cells = 999;
 990                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 991                         start_ammo_nails = 999;
 992                 if (g_weaponarena & WEPBIT_HOOK)
 993                         start_ammo_fuel = 999;
 994                 start_items |= IT_UNLIMITED_AMMO;
 995         }
 996         else if (g_minstagib)
 997         {
 998                 start_health = 100;
 999                 start_armorvalue = 0;
1000                 start_weapons = WEPBIT_MINSTANEX;
1001                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1002                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1003                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1004                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1005
1006                 if (g_minstagib_invis_alpha <= 0)
1007                         g_minstagib_invis_alpha = -1;
1008         }
1009         else
1010         {
1011                 if (g_lms || g_ca)
1012                 {
1013                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1014                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1015                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1016                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1017                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1018                         start_health = cvar("g_lms_start_health");
1019                         start_armorvalue = cvar("g_lms_start_armor");
1020                 }
1021                 else
1022                 {
1023                         start_ammo_shells = cvar("g_start_ammo_shells");
1024                         start_ammo_nails = cvar("g_start_ammo_nails");
1025                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1026                         start_ammo_cells = cvar("g_start_ammo_cells");
1027                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1028                 }
1029
1030                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1031                 {
1032                         e = get_weaponinfo(i);
1033                         if(want_weapon("g_start_weapon_", e, FALSE))
1034                                 start_weapons |= e.weapons;
1035                 }
1036         }
1037
1038         if (inWarmupStage)
1039         {
1040                 warmup_start_ammo_shells = start_ammo_shells;
1041                 warmup_start_ammo_nails = start_ammo_nails;
1042                 warmup_start_ammo_rockets = start_ammo_rockets;
1043                 warmup_start_ammo_cells = start_ammo_cells;
1044                 warmup_start_ammo_fuel = start_ammo_fuel;
1045                 warmup_start_health = start_health;
1046                 warmup_start_armorvalue = start_armorvalue;
1047                 warmup_start_weapons = start_weapons;
1048
1049                 if (!g_weaponarena && !g_minstagib && !g_ca)
1050                 {
1051                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1052                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1053                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1054                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1055                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1056                         warmup_start_health = cvar("g_warmup_start_health");
1057                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1058                         warmup_start_weapons = 0;
1059                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1060                         {
1061                                 e = get_weaponinfo(i);
1062                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1063                                         warmup_start_weapons |= e.weapons;
1064                         }
1065                 }
1066         }
1067
1068         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1069         {
1070                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1071                 start_items |= IT_FUEL_REGEN;
1072                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1073                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1074         }
1075
1076         if(!cvar("g_use_ammunition"))
1077         {
1078                 start_ammo_shells = cvar("g_pickup_shells_max");
1079                 start_ammo_nails = cvar("g_pickup_nails_max");
1080                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1081                 start_ammo_cells = cvar("g_pickup_cells_max");
1082                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1083                 start_items |= IT_UNLIMITED_AMMO;
1084                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1085                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1086                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1087                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1088                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1089                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1090         }
1091
1092         if (g_jetpack)
1093                 start_items |= IT_JETPACK;
1094
1095         if (g_weapon_stay == 2)
1096         {
1097                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1098                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1099                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1100                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1101                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1102                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1103                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1104                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1105                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1106                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1107         }
1108
1109         MUTATOR_CALLHOOK(SetStartItems);
1110
1111         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1112         {
1113                 e = get_weaponinfo(i);
1114                 if(e.weapons & (start_weapons | warmup_start_weapons))
1115                         weapon_action(e.weapon, WR_PRECACHE);
1116         }
1117
1118         start_ammo_shells = max(0, start_ammo_shells);
1119         start_ammo_nails = max(0, start_ammo_nails);
1120         start_ammo_cells = max(0, start_ammo_cells);
1121         start_ammo_rockets = max(0, start_ammo_rockets);
1122         start_ammo_fuel = max(0, start_ammo_fuel);
1123
1124         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1125         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1126         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1127         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1128         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1129 }
1130
1131 float g_bugrigs;
1132 float g_bugrigs_planar_movement;
1133 float g_bugrigs_planar_movement_car_jumping;
1134 float g_bugrigs_reverse_spinning;
1135 float g_bugrigs_reverse_speeding;
1136 float g_bugrigs_reverse_stopping;
1137 float g_bugrigs_air_steering;
1138 float g_bugrigs_angle_smoothing;
1139 float g_bugrigs_friction_floor;
1140 float g_bugrigs_friction_brake;
1141 float g_bugrigs_friction_air;
1142 float g_bugrigs_accel;
1143 float g_bugrigs_speed_ref;
1144 float g_bugrigs_speed_pow;
1145 float g_bugrigs_steer;
1146
1147 float g_touchexplode;
1148 float g_touchexplode_radius;
1149 float g_touchexplode_damage;
1150 float g_touchexplode_edgedamage;
1151 float g_touchexplode_force;
1152
1153 float sv_autotaunt;
1154 float sv_taunt;
1155
1156 float sv_pitch_min;
1157 float sv_pitch_max;
1158 float sv_pitch_fixyaw;
1159
1160 void readlevelcvars(void)
1161 {
1162         // first load all the mutators
1163         if(cvar("g_nix"))
1164                 MUTATOR_ADD(mutator_nix);
1165         if(cvar("g_dodging"))
1166                 MUTATOR_ADD(mutator_dodging);
1167         if(cvar("g_rocket_flying"))
1168                 MUTATOR_ADD(mutator_rocketflying);
1169         if(cvar("g_vampire"))
1170                 MUTATOR_ADD(mutator_vampire);
1171
1172         if(cvar("sv_allow_fullbright"))
1173                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1174
1175     g_bugrigs = cvar("g_bugrigs");
1176     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1177     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1178     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1179     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1180     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1181     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1182     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1183     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1184     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1185     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1186     g_bugrigs_accel = cvar("g_bugrigs_accel");
1187     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1188     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1189     g_bugrigs_steer = cvar("g_bugrigs_steer");
1190
1191     g_touchexplode = cvar("g_touchexplode");
1192     g_touchexplode_radius = cvar("g_touchexplode_radius");
1193     g_touchexplode_damage = cvar("g_touchexplode_damage");
1194     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1195     g_touchexplode_force = cvar("g_touchexplode_force");
1196
1197 #ifdef ALLOW_FORCEMODELS
1198         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1199 #endif
1200         sv_loddistance1 = cvar("sv_loddistance1");
1201         sv_loddistance2 = cvar("sv_loddistance2");
1202
1203         if(sv_loddistance2 <= sv_loddistance1)
1204                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1205
1206         sv_clones = cvar("sv_clones");
1207         sv_gentle = cvar("sv_gentle");
1208         sv_foginterval = cvar("sv_foginterval");
1209         g_cloaked = cvar("g_cloaked");
1210         g_jump_grunt = cvar("g_jump_grunt");
1211         g_footsteps = cvar("g_footsteps");
1212         g_grappling_hook = cvar("g_grappling_hook");
1213         g_jetpack = cvar("g_jetpack");
1214         g_midair = cvar("g_midair");
1215         g_minstagib = cvar("g_minstagib");
1216         g_norecoil = cvar("g_norecoil");
1217         g_bloodloss = cvar("g_bloodloss");
1218         sv_maxidle = cvar("sv_maxidle");
1219         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1220         sv_pogostick = cvar("sv_pogostick");
1221         g_ctf_reverse = cvar("g_ctf_reverse");
1222         sv_autotaunt = cvar("sv_autotaunt");
1223         sv_taunt = cvar("sv_taunt");
1224
1225         inWarmupStage = cvar("g_warmup");
1226         g_warmup_limit = cvar("g_warmup_limit");
1227         g_warmup_allguns = cvar("g_warmup_allguns");
1228         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1229
1230         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1231                 inWarmupStage = 0; // these modes cannot work together, sorry
1232
1233         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1234         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1235         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1236         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1237         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1238         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1239         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1240         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1241         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1242         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1243         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1244         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1245
1246         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1247         g_weaponratefactor = cvar("g_weaponratefactor");
1248         g_weapondamagefactor = cvar("g_weapondamagefactor");
1249         g_weaponforcefactor = cvar("g_weaponforcefactor");
1250         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1251
1252         g_pickup_shells = cvar("g_pickup_shells");
1253         g_pickup_shells_max = cvar("g_pickup_shells_max");
1254         g_pickup_nails = cvar("g_pickup_nails");
1255         g_pickup_nails_max = cvar("g_pickup_nails_max");
1256         g_pickup_rockets = cvar("g_pickup_rockets");
1257         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1258         g_pickup_cells = cvar("g_pickup_cells");
1259         g_pickup_cells_max = cvar("g_pickup_cells_max");
1260         g_pickup_fuel = cvar("g_pickup_fuel");
1261         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1262         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1263         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1264         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1265         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1266         g_pickup_armormedium = cvar("g_pickup_armormedium");
1267         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1268         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1269         g_pickup_armorbig = cvar("g_pickup_armorbig");
1270         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1271         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1272         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1273         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1274         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1275         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1276         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1277         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1278         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1279         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1280         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1281         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1282         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1283         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1284         g_pickup_healthmega = cvar("g_pickup_healthmega");
1285         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1286         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1287
1288         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1289         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1290
1291         g_pinata = cvar("g_pinata");
1292
1293         g_weapon_stay = cvar("g_weapon_stay");
1294
1295         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1296                 g_weapon_stay = 1;
1297
1298         g_ghost_items = cvar("g_ghost_items");
1299
1300         if(g_ghost_items >= 1)
1301                 g_ghost_items = 0.25; // default alpha value
1302
1303         if not(inWarmupStage && !g_ca)
1304                 game_starttime = cvar("g_start_delay");
1305
1306         sv_pitch_min = cvar("sv_pitch_min");
1307         sv_pitch_max = cvar("sv_pitch_max");
1308         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1309
1310         readplayerstartcvars();
1311 }
1312
1313 //#NO AUTOCVARS END
1314
1315 // Sound functions
1316 string precache_sound (string s) = #19;
1317 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1318 float precache_sound_index (string s) = #19;
1319
1320 #define SND_VOLUME      1
1321 #define SND_ATTENUATION 2
1322 #define SND_LARGEENTITY 8
1323 #define SND_LARGESOUND  16
1324
1325 float sound_allowed(float dest, entity e)
1326 {
1327     // sounds from world may always pass
1328     for (;;)
1329     {
1330         if (e.classname == "body")
1331             e = e.enemy;
1332         if (e.owner && e.owner != e)
1333             e = e.owner;
1334         else
1335             break;
1336     }
1337     // sounds to self may always pass
1338     if (dest == MSG_ONE)
1339         if (e == msg_entity)
1340             return TRUE;
1341     // sounds by players can be removed
1342     if (autocvar_bot_sound_monopoly)
1343         if (clienttype(e) == CLIENTTYPE_REAL)
1344             return FALSE;
1345     // anything else may pass
1346     return TRUE;
1347 }
1348
1349 void sound(entity e, float chan, string samp, float vol, float atten)
1350 {
1351     if (!sound_allowed(MSG_BROADCAST, e))
1352         return;
1353     sound_builtin(e, chan, samp, vol, atten);
1354 }
1355 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1356 {
1357     float entno, idx;
1358
1359     if (!sound_allowed(dest, e))
1360         return;
1361
1362     entno = num_for_edict(e);
1363     idx = precache_sound_index(samp);
1364
1365     float sflags;
1366     sflags = 0;
1367
1368     atten = floor(atten * 64);
1369     vol = floor(vol * 255);
1370
1371     if (vol != 255)
1372         sflags |= SND_VOLUME;
1373     if (atten != 64)
1374         sflags |= SND_ATTENUATION;
1375     if (entno >= 8192)
1376         sflags |= SND_LARGEENTITY;
1377     if (idx >= 256)
1378         sflags |= SND_LARGESOUND;
1379
1380     WriteByte(dest, SVC_SOUND);
1381     WriteByte(dest, sflags);
1382     if (sflags & SND_VOLUME)
1383         WriteByte(dest, vol);
1384     if (sflags & SND_ATTENUATION)
1385         WriteByte(dest, atten);
1386     if (sflags & SND_LARGEENTITY)
1387     {
1388         WriteShort(dest, entno);
1389         WriteByte(dest, chan);
1390     }
1391     else
1392     {
1393         WriteShort(dest, entno * 8 + chan);
1394     }
1395     if (sflags & SND_LARGESOUND)
1396         WriteShort(dest, idx);
1397     else
1398         WriteByte(dest, idx);
1399
1400     WriteCoord(dest, o_x);
1401     WriteCoord(dest, o_y);
1402     WriteCoord(dest, o_z);
1403 }
1404 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1405 {
1406     vector o;
1407
1408     if (!sound_allowed(dest, e))
1409         return;
1410
1411     o = e.origin + 0.5 * (e.mins + e.maxs);
1412     soundtoat(dest, e, o, chan, samp, vol, atten);
1413 }
1414 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1415 {
1416     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1417 }
1418 void stopsoundto(float dest, entity e, float chan)
1419 {
1420     float entno;
1421
1422     if (!sound_allowed(dest, e))
1423         return;
1424
1425     entno = num_for_edict(e);
1426
1427     if (entno >= 8192)
1428     {
1429         float idx, sflags;
1430         idx = precache_sound_index("misc/null.wav");
1431         sflags = SND_LARGEENTITY;
1432         if (idx >= 256)
1433             sflags |= SND_LARGESOUND;
1434         WriteByte(dest, SVC_SOUND);
1435         WriteByte(dest, sflags);
1436         WriteShort(dest, entno);
1437         WriteByte(dest, chan);
1438         if (sflags & SND_LARGESOUND)
1439             WriteShort(dest, idx);
1440         else
1441             WriteByte(dest, idx);
1442         WriteCoord(dest, e.origin_x);
1443         WriteCoord(dest, e.origin_y);
1444         WriteCoord(dest, e.origin_z);
1445     }
1446     else
1447     {
1448         WriteByte(dest, SVC_STOPSOUND);
1449         WriteShort(dest, entno * 8 + chan);
1450     }
1451 }
1452 void stopsound(entity e, float chan)
1453 {
1454     if (!sound_allowed(MSG_BROADCAST, e))
1455         return;
1456
1457     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1458     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1459 }
1460
1461 void play2(entity e, string filename)
1462 {
1463     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1464     msg_entity = e;
1465     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1466 }
1467
1468 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1469 .float spamtime;
1470 float spamsound(entity e, float chan, string samp, float vol, float atten)
1471 {
1472     if (!sound_allowed(MSG_BROADCAST, e))
1473         return FALSE;
1474
1475     if (time > e.spamtime)
1476     {
1477         e.spamtime = time;
1478         sound(e, chan, samp, vol, atten);
1479         return TRUE;
1480     }
1481     return FALSE;
1482 }
1483
1484 void play2team(float t, string filename)
1485 {
1486     local entity head;
1487
1488     if (autocvar_bot_sound_monopoly)
1489         return;
1490
1491     FOR_EACH_REALPLAYER(head)
1492     {
1493         if (head.team == t)
1494             play2(head, filename);
1495     }
1496 }
1497
1498 void play2all(string samp)
1499 {
1500     if (autocvar_bot_sound_monopoly)
1501         return;
1502
1503     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1504 }
1505
1506 void PrecachePlayerSounds(string f);
1507 void precache_playermodel(string m)
1508 {
1509         float globhandle, i, n;
1510         string f;
1511
1512         if(substring(m, -9,5) == "_lod1")
1513                 return;
1514         if(substring(m, -9,5) == "_lod2")
1515                 return;
1516         precache_model(m);
1517         if(sv_loddistance1)
1518         {
1519                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1520                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1521         }
1522
1523         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1524         if (globhandle < 0)
1525                 return;
1526         n = search_getsize(globhandle);
1527         for (i = 0; i < n; ++i)
1528         {
1529                 //print(search_getfilename(globhandle, i), "\n");
1530                 f = search_getfilename(globhandle, i);
1531                 PrecachePlayerSounds(f);
1532         }
1533         search_end(globhandle);
1534 }
1535 void precache_all_playermodels(string pattern)
1536 {
1537         float globhandle, i, n;
1538         string f;
1539
1540         globhandle = search_begin(pattern, TRUE, FALSE);
1541         if (globhandle < 0)
1542                 return;
1543         n = search_getsize(globhandle);
1544         for (i = 0; i < n; ++i)
1545         {
1546                 //print(search_getfilename(globhandle, i), "\n");
1547                 f = search_getfilename(globhandle, i);
1548                 precache_playermodel(f);
1549         }
1550         search_end(globhandle);
1551 }
1552
1553 void precache()
1554 {
1555     // gamemode related things
1556     precache_model ("models/misc/chatbubble.spr");
1557     precache_model ("models/misc/teambubble.spr");
1558     if (g_runematch)
1559     {
1560         precache_model ("models/runematch/curse.mdl");
1561         precache_model ("models/runematch/rune.mdl");
1562     }
1563
1564 #ifdef TTURRETS_ENABLED
1565     if (autocvar_g_turrets)
1566         turrets_precash();
1567 #endif
1568
1569     // Precache all player models if desired
1570     if (autocvar_sv_precacheplayermodels)
1571     {
1572         PrecachePlayerSounds("sound/player/default.sounds");
1573         precache_all_playermodels("models/player/*.zym");
1574         precache_all_playermodels("models/player/*.dpm");
1575         precache_all_playermodels("models/player/*.md3");
1576         precache_all_playermodels("models/player/*.psk");
1577         precache_all_playermodels("models/player/*.iqm");
1578     }
1579
1580     if (autocvar_sv_defaultcharacter)
1581     {
1582         string s;
1583         s = autocvar_sv_defaultplayermodel_red;
1584         if (s != "")
1585             precache_playermodel(s);
1586         s = autocvar_sv_defaultplayermodel_blue;
1587         if (s != "")
1588             precache_playermodel(s);
1589         s = autocvar_sv_defaultplayermodel_yellow;
1590         if (s != "")
1591             precache_playermodel(s);
1592         s = autocvar_sv_defaultplayermodel_pink;
1593         if (s != "")
1594             precache_playermodel(s);
1595         s = autocvar_sv_defaultplayermodel;
1596         if (s != "")
1597             precache_playermodel(s);
1598     }
1599
1600     if (g_footsteps)
1601     {
1602         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1603         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1604     }
1605
1606     // gore and miscellaneous sounds
1607     //precache_sound ("misc/h2ohit.wav");
1608     precache_model ("models/hook.md3");
1609     precache_sound ("misc/armorimpact.wav");
1610     precache_sound ("misc/bodyimpact1.wav");
1611     precache_sound ("misc/bodyimpact2.wav");
1612     precache_sound ("misc/gib.wav");
1613     precache_sound ("misc/gib_splat01.wav");
1614     precache_sound ("misc/gib_splat02.wav");
1615     precache_sound ("misc/gib_splat03.wav");
1616     precache_sound ("misc/gib_splat04.wav");
1617     precache_sound ("misc/hit.wav");
1618         precache_sound ("misc/typehit.wav");
1619     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1620     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1621     precache_sound ("misc/null.wav");
1622     precache_sound ("misc/spawn.wav");
1623     precache_sound ("misc/talk.wav");
1624     precache_sound ("misc/teleport.wav");
1625     precache_sound ("misc/poweroff.wav");
1626     precache_sound ("player/lava.wav");
1627     precache_sound ("player/slime.wav");
1628
1629     if (g_jetpack)
1630         precache_sound ("misc/jetpack_fly.wav");
1631
1632     precache_model ("models/sprites/0.spr32");
1633     precache_model ("models/sprites/1.spr32");
1634     precache_model ("models/sprites/2.spr32");
1635     precache_model ("models/sprites/3.spr32");
1636     precache_model ("models/sprites/4.spr32");
1637     precache_model ("models/sprites/5.spr32");
1638     precache_model ("models/sprites/6.spr32");
1639     precache_model ("models/sprites/7.spr32");
1640     precache_model ("models/sprites/8.spr32");
1641     precache_model ("models/sprites/9.spr32");
1642     precache_model ("models/sprites/10.spr32");
1643
1644     // common weapon precaches
1645     precache_sound ("weapons/weapon_switch.wav");
1646     precache_sound ("weapons/weaponpickup.wav");
1647     precache_sound ("weapons/unavailable.wav");
1648     precache_sound ("weapons/dryfire.wav");
1649     if (g_grappling_hook)
1650     {
1651         precache_sound ("weapons/hook_fire.wav"); // hook
1652         precache_sound ("weapons/hook_impact.wav"); // hook
1653     }
1654
1655     if(autocvar_sv_precacheweapons)
1656     {
1657         //precache weapon models/sounds
1658         local float wep;
1659         wep = WEP_FIRST;
1660         while (wep <= WEP_LAST)
1661         {
1662             weapon_action(wep, WR_PRECACHE);
1663             wep = wep + 1;
1664         }
1665     }
1666
1667     precache_model("models/elaser.mdl");
1668     precache_model("models/laser.mdl");
1669     precache_model("models/ebomb.mdl");
1670
1671 #if 0
1672     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1673
1674     if (!self.noise && self.music) // quake 3 uses the music field
1675         self.noise = self.music;
1676
1677     // plays music for the level if there is any
1678     if (self.noise)
1679     {
1680         precache_sound (self.noise);
1681         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1682     }
1683 #endif
1684 }
1685
1686 // sorry, but using \ in macros breaks line numbers
1687 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1688 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1689 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1690
1691 // WARNING: this kills the trace globals
1692 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1693 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1694
1695 #define INITPRIO_FIRST              0
1696 #define INITPRIO_GAMETYPE           0
1697 #define INITPRIO_GAMETYPE_FALLBACK  1
1698 #define INITPRIO_FINDTARGET        10
1699 #define INITPRIO_DROPTOFLOOR       20
1700 #define INITPRIO_SETLOCATION       90
1701 #define INITPRIO_LINKDOORS         91
1702 #define INITPRIO_LAST              99
1703
1704 .void(void) initialize_entity;
1705 .float initialize_entity_order;
1706 .entity initialize_entity_next;
1707 entity initialize_entity_first;
1708
1709 void make_safe_for_remove(entity e)
1710 {
1711     if (e.initialize_entity)
1712     {
1713         entity ent, prev;
1714         for (ent = initialize_entity_first; ent; )
1715         {
1716             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1717             {
1718                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1719                 // skip it in linked list
1720                 if (prev)
1721                 {
1722                     prev.initialize_entity_next = ent.initialize_entity_next;
1723                     ent = prev.initialize_entity_next;
1724                 }
1725                 else
1726                 {
1727                     initialize_entity_first = ent.initialize_entity_next;
1728                     ent = initialize_entity_first;
1729                 }
1730             }
1731             else
1732             {
1733                 prev = ent;
1734                 ent = ent.initialize_entity_next;
1735             }
1736         }
1737     }
1738 }
1739
1740 void objerror(string s)
1741 {
1742     make_safe_for_remove(self);
1743     objerror_builtin(s);
1744 }
1745
1746 void remove_unsafely(entity e)
1747 {
1748     remove_builtin(e);
1749 }
1750
1751 void remove_safely(entity e)
1752 {
1753     make_safe_for_remove(e);
1754     remove_builtin(e);
1755 }
1756
1757 void InitializeEntity(entity e, void(void) func, float order)
1758 {
1759     entity prev, cur;
1760
1761     if (!e || e.initialize_entity)
1762     {
1763         // make a proxy initializer entity
1764         entity e_old;
1765         e_old = e;
1766         e = spawn();
1767         e.classname = "initialize_entity";
1768         e.enemy = e_old;
1769     }
1770
1771     e.initialize_entity = func;
1772     e.initialize_entity_order = order;
1773
1774     cur = initialize_entity_first;
1775     for (;;)
1776     {
1777         if (!cur || cur.initialize_entity_order > order)
1778         {
1779             // insert between prev and cur
1780             if (prev)
1781                 prev.initialize_entity_next = e;
1782             else
1783                 initialize_entity_first = e;
1784             e.initialize_entity_next = cur;
1785             return;
1786         }
1787         prev = cur;
1788         cur = cur.initialize_entity_next;
1789     }
1790 }
1791 void InitializeEntitiesRun()
1792 {
1793     entity startoflist;
1794     startoflist = initialize_entity_first;
1795     initialize_entity_first = world;
1796     for (self = startoflist; self; )
1797     {
1798         entity e;
1799         var void(void) func;
1800         e = self.initialize_entity_next;
1801         func = self.initialize_entity;
1802         self.initialize_entity_order = 0;
1803         self.initialize_entity = func_null;
1804         self.initialize_entity_next = world;
1805         if (self.classname == "initialize_entity")
1806         {
1807             entity e_old;
1808             e_old = self.enemy;
1809             remove_builtin(self);
1810             self = e_old;
1811         }
1812         //dprint("Delayed initialization: ", self.classname, "\n");
1813         if(func != func_null)
1814             func();
1815         else
1816             dprint("^1WARNING: Skipped initialization: ", self.classname, "\n");
1817         self = e;
1818     }
1819 }
1820
1821 .float uncustomizeentityforclient_set;
1822 .void(void) uncustomizeentityforclient;
1823 void(void) SUB_Nullpointer = #0;
1824 void UncustomizeEntitiesRun()
1825 {
1826     entity oldself;
1827     oldself = self;
1828     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1829         self.uncustomizeentityforclient();
1830     self = oldself;
1831 }
1832 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1833 {
1834     e.customizeentityforclient = customizer;
1835     e.uncustomizeentityforclient = uncustomizer;
1836     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1837 }
1838
1839 .float nottargeted;
1840 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1841
1842 void() SUB_Remove;
1843 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1844 {
1845     vector mi, ma;
1846
1847     if (e.classname == "")
1848         e.classname = "net_linked";
1849
1850     if (e.model == "" || self.modelindex == 0)
1851     {
1852         mi = e.mins;
1853         ma = e.maxs;
1854         setmodel(e, "null");
1855         setsize(e, mi, ma);
1856     }
1857
1858     e.SendEntity = sendfunc;
1859     e.SendFlags = 0xFFFFFF;
1860
1861     if (!docull)
1862         e.effects |= EF_NODEPTHTEST;
1863
1864     if (dt)
1865     {
1866         e.nextthink = time + dt;
1867         e.think = SUB_Remove;
1868     }
1869 }
1870
1871 void adaptor_think2touch()
1872 {
1873     entity o;
1874     o = other;
1875     other = world;
1876     self.touch();
1877     other = o;
1878 }
1879
1880 void adaptor_think2use()
1881 {
1882     entity o, a;
1883     o = other;
1884     a = activator;
1885     activator = world;
1886     other = world;
1887     self.use();
1888     other = o;
1889     activator = a;
1890 }
1891
1892 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1893 {
1894         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1895                 self.projectiledeathtype |= HITTYPE_SPLASH;
1896         adaptor_think2use();
1897 }
1898
1899 // deferred dropping
1900 void DropToFloor_Handler()
1901 {
1902     droptofloor_builtin();
1903     self.dropped_origin = self.origin;
1904 }
1905
1906 void droptofloor()
1907 {
1908     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1909 }
1910
1911
1912
1913 float trace_hits_box_a0, trace_hits_box_a1;
1914
1915 float trace_hits_box_1d(float end, float thmi, float thma)
1916 {
1917     if (end == 0)
1918     {
1919         // just check if x is in range
1920         if (0 < thmi)
1921             return FALSE;
1922         if (0 > thma)
1923             return FALSE;
1924     }
1925     else
1926     {
1927         // do the trace with respect to x
1928         // 0 -> end has to stay in thmi -> thma
1929         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1930         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1931         if (trace_hits_box_a0 > trace_hits_box_a1)
1932             return FALSE;
1933     }
1934     return TRUE;
1935 }
1936
1937 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1938 {
1939     end -= start;
1940     thmi -= start;
1941     thma -= start;
1942     // now it is a trace from 0 to end
1943
1944     trace_hits_box_a0 = 0;
1945     trace_hits_box_a1 = 1;
1946
1947     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1948         return FALSE;
1949     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1950         return FALSE;
1951     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1952         return FALSE;
1953
1954     return TRUE;
1955 }
1956
1957 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1958 {
1959     return trace_hits_box(start, end, thmi - ma, thma - mi);
1960 }
1961
1962 float SUB_NoImpactCheck()
1963 {
1964         // zero hitcontents = this is not the real impact, but either the
1965         // mirror-impact of something hitting the projectile instead of the
1966         // projectile hitting the something, or a touchareagrid one. Neither of
1967         // these stop the projectile from moving, so...
1968         if(trace_dphitcontents == 0)
1969         {
1970                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1971                 checkclient();
1972         }
1973     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1974         return 1;
1975     if (other == world && self.size != '0 0 0')
1976     {
1977         vector tic;
1978         tic = self.velocity * sys_frametime;
1979         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1980         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1981         if (trace_fraction >= 1)
1982         {
1983             dprint("Odd... did not hit...?\n");
1984         }
1985         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1986         {
1987             dprint("Detected and prevented the sky-grapple bug.\n");
1988             return 1;
1989         }
1990     }
1991
1992     return 0;
1993 }
1994
1995 #define SUB_OwnerCheck() (other && (other == self.owner))
1996
1997 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1998 {
1999         if(SUB_OwnerCheck())
2000                 return TRUE;
2001         if(SUB_NoImpactCheck())
2002         {
2003                 remove(self);
2004                 return TRUE;
2005         }
2006         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2007                 UpdateCSQCProjectileNextFrame(self);
2008         return FALSE;
2009 }
2010 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2011
2012 float MAX_IPBAN_URIS           = 16;
2013
2014 float URI_GET_DISCARD          = 0;
2015 float URI_GET_IPBAN            = 1;
2016 float URI_GET_IPBAN_END        = 16;
2017 float URI_GET_PLAYERSTATS_SENT = 17;
2018
2019 void URI_Get_Callback(float id, float status, string data)
2020 {
2021     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2022     dprint(data);
2023     dprint("\nEnd of data.\n");
2024
2025     if (id == URI_GET_DISCARD)
2026     {
2027         // discard
2028     }
2029     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2030     {
2031         // online ban list
2032         OnlineBanList_URI_Get_Callback(id, status, data);
2033     }
2034     else if (id == URI_GET_PLAYERSTATS_SENT)
2035     {
2036         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2037     }
2038     else
2039     {
2040         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2041     }
2042 }
2043
2044 void print_to(entity e, string s)
2045 {
2046     if (e)
2047         sprint(e, strcat(s, "\n"));
2048     else
2049         print(s, "\n");
2050 }
2051
2052 string uid2name(string myuid) {
2053         string s;
2054         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2055
2056         if(s == "")
2057                 s = "^1Unregistered Player";
2058         return s;
2059 }
2060
2061 float race_readTime(string map, float pos)
2062 {
2063         string rr;
2064         if(g_cts)
2065                 rr = CTS_RECORD;
2066         else
2067                 rr = RACE_RECORD;
2068
2069         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2070 }
2071
2072 string race_readUID(string map, float pos)
2073 {
2074         string rr;
2075         if(g_cts)
2076                 rr = CTS_RECORD;
2077         else
2078                 rr = RACE_RECORD;
2079
2080         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2081 }
2082
2083 float race_readPos(string map, float t) {
2084         float i;
2085         for (i = 1; i <= RANKINGS_CNT; ++i)
2086                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2087                         return i;
2088
2089         return 0; // pos is zero if unranked
2090 }
2091
2092 void race_writeTime(string map, float t, string myuid)
2093 {
2094         string rr;
2095         if(g_cts)
2096                 rr = CTS_RECORD;
2097         else
2098                 rr = RACE_RECORD;
2099
2100         float newpos;
2101         newpos = race_readPos(map, t);
2102
2103         float i, prevpos;
2104         for(i = 1; i <= RANKINGS_CNT; ++i)
2105         {
2106                 if(race_readUID(map, i) == myuid)
2107                         prevpos = i;
2108         }
2109         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2110                 for (i = prevpos; i > newpos; --i) {
2111                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2112                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2113                 }
2114         } else { // player has no ranked record yet
2115                 for (i = RANKINGS_CNT; i > newpos; --i) {
2116                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2117                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2118                 }
2119         }
2120
2121         // store new time itself
2122         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2123         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2124 }
2125
2126 string race_readName(string map, float pos)
2127 {
2128         string rr;
2129         if(g_cts)
2130                 rr = CTS_RECORD;
2131         else
2132                 rr = RACE_RECORD;
2133
2134         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2135 }
2136
2137 string race_placeName(float pos) {
2138         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2139         {
2140                 if(mod(pos, 10) == 1)
2141                         return strcat(ftos(pos), "st");
2142                 else if(mod(pos, 10) == 2)
2143                         return strcat(ftos(pos), "nd");
2144                 else if(mod(pos, 10) == 3)
2145                         return strcat(ftos(pos), "rd");
2146                 else
2147                         return strcat(ftos(pos), "th");
2148         }
2149         else
2150                 return strcat(ftos(pos), "th");
2151 }
2152 string getrecords(float page) // 50 records per page
2153 {
2154     float rec;
2155     string h;
2156     float r;
2157     float i;
2158     string s;
2159
2160     rec = 0;
2161
2162     s = "";
2163
2164     if (g_ctf)
2165     {
2166         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2167         {
2168             if (MapInfo_Get_ByID(i))
2169             {
2170                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2171                 if (r == 0)
2172                     continue;
2173                 // TODO: uid2name
2174                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2175                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2176                 ++rec;
2177             }
2178         }
2179     }
2180
2181     if (g_race)
2182     {
2183         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2184         {
2185             if (MapInfo_Get_ByID(i))
2186             {
2187                 r = race_readTime(MapInfo_Map_bspname, 1);
2188                 if (r == 0)
2189                     continue;
2190                 h = race_readName(MapInfo_Map_bspname, 1);
2191                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2192                 ++rec;
2193             }
2194         }
2195     }
2196
2197     if (g_cts)
2198     {
2199         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2200         {
2201             if (MapInfo_Get_ByID(i))
2202             {
2203                 r = race_readTime(MapInfo_Map_bspname, 1);
2204                 if (r == 0)
2205                     continue;
2206                 h = race_readName(MapInfo_Map_bspname, 1);
2207                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2208                 ++rec;
2209             }
2210         }
2211     }
2212
2213     MapInfo_ClearTemps();
2214
2215     if (s == "" && page == 0)
2216         return "No records are available on this server.\n";
2217     else
2218         return s;
2219 }
2220
2221 string getrankings()
2222 {
2223     string n;
2224     float t;
2225     float i;
2226     string s;
2227     string p;
2228     string map;
2229
2230     s = "";
2231
2232     map = GetMapname();
2233
2234     for (i = 1; i <= RANKINGS_CNT; ++i)
2235     {
2236         t = race_readTime(map, i);
2237         if (t == 0)
2238             continue;
2239         n = race_readName(map, i);
2240         p = race_placeName(i);
2241         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2242     }
2243
2244     MapInfo_ClearTemps();
2245
2246     if (s == "")
2247         return strcat("No records are available for the map: ", map, "\n");
2248     else
2249         return strcat("Records for ", map, ":\n", s);
2250 }
2251
2252 #define LADDER_FIRSTPOINT 100
2253 #define LADDER_CNT 10
2254         // position X still gives LADDER_FIRSTPOINT/X points
2255 #define LADDER_SIZE 30
2256         // ladder shows the top X players
2257 string top_uids[LADDER_SIZE];
2258 float top_scores[LADDER_SIZE];
2259 string getladder()
2260 {
2261     float i, j, k, uidcnt;
2262     string s, temp_s;
2263
2264     s = "";
2265     temp_s = "";
2266
2267     string rr;
2268     if(g_cts)
2269         rr = CTS_RECORD;
2270     else
2271         rr = RACE_RECORD;
2272
2273     string myuid;
2274
2275     for (k = 0; k < MapInfo_count; ++k)
2276     {
2277         if (MapInfo_Get_ByID(k))
2278         {
2279                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2280                         if(i == 0) // speed award
2281                         {
2282                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2283                                         continue;
2284
2285                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2286                         }
2287                         else // normal record, if it exists (else break)
2288                         {
2289                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2290                                         continue;
2291
2292                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2293                         }
2294
2295                         // string s contains:
2296                         // arg 0 = # of speed recs
2297                         // arg 1 = # of 1st place recs
2298                         // arg 2 = # of 2nd place recs
2299                         // ... etc
2300                         // LADDER_CNT+1 = total points
2301
2302                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2303                         if (temp_s == "")
2304                         {
2305                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2306                             ++uidcnt;
2307                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2308                             {
2309                                 if(j != LADDER_CNT + 1)
2310                                     temp_s = strcat(temp_s, "0 ");
2311                                 else
2312                                     temp_s = strcat(temp_s, "0");
2313                             }
2314                         }
2315
2316                         tokenize_console(temp_s);
2317                         s = "";
2318
2319                         if(i == 0) // speed award
2320                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2321                             {
2322                                 if(j == 0) // speed award
2323                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2324                                 else
2325                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2326                             }
2327                         else // record
2328                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2329                             {
2330                                 if(j == 0)
2331                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2332                                 else if(j == i) // wanted rec!
2333                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2334                                 else
2335                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2336                             }
2337
2338                         // total points are (by default) calculated like this:
2339                         // speedrec = floor(100 / 10) = 10 points
2340                         // 1st place = floor(100 / 1) = 100 points
2341                         // 2nd place = floor(100 / 2) = 50 points
2342                         // 3rd place = floor(100 / 3) = 33 points
2343                         // 4th place = floor(100 / 4) = 25 points
2344                         // 5th place = floor(100 / 5) = 20 points
2345                         // ... etc
2346
2347                         if(i == 0)
2348                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2349                         else
2350                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2351
2352                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2353                 }
2354         }
2355     }
2356
2357     float thiscnt;
2358     string thisuid;
2359     for (i = 0; i <= uidcnt; ++i) // for each known uid
2360     {
2361         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2362         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2363         tokenize_console(temp_s);
2364         thiscnt = stof(argv(LADDER_CNT+1));
2365
2366         if(thiscnt > top_scores[LADDER_SIZE-1])
2367         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2368         {
2369             if(thiscnt > top_scores[j])
2370             {
2371                 for (k = LADDER_SIZE-1; k >= j; --k)
2372                 {
2373                     top_uids[k] = top_uids[k-1];
2374                     top_scores[k] = top_scores[k-1];
2375                 }
2376                 top_uids[j] = thisuid;
2377                 top_scores[j] = thiscnt;
2378                 break;
2379             }
2380         }
2381     }
2382
2383     s = "^3-----------------------\n\n";
2384
2385     s = strcat(s, "Pos ^3|");
2386     s = strcat(s, " ^7Total  ^3|");
2387     for (i = 1; i <= LADDER_CNT; ++i)
2388     {
2389         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2390     }
2391     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2392
2393     s = strcat(s, "\n^3----+--------");
2394     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2395     {
2396         s = strcat(s, "+-----");
2397     }
2398 #if LADDER_CNT > 9
2399     for (i = 1; i <= LADDER_CNT - 9; ++i)
2400     {
2401         s = strcat(s, "+------");
2402     }
2403 #endif
2404
2405     s = strcat(s, "+--------------+--------------------\n");
2406
2407     for (i = 0; i < LADDER_SIZE; ++i)
2408     {
2409         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2410         tokenize_console(temp_s);
2411         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2412             continue;
2413         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2414         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2415         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2416         {
2417             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2418         }
2419 #if LADDER_CNT > 9
2420         for (j = 10; j <= LADDER_CNT; ++j)
2421         {
2422             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2423         }
2424 #endif
2425
2426         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2427         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2428     }
2429
2430     MapInfo_ClearTemps();
2431
2432     if (s == "")
2433         return "No ladder on this server!\n";
2434     else
2435         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2436 }
2437
2438
2439 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2440 {
2441     float m, i;
2442     vector start, org, delta, end, enddown, mstart;
2443
2444     m = e.dphitcontentsmask;
2445     e.dphitcontentsmask = goodcontents | badcontents;
2446
2447     org = world.mins;
2448     delta = world.maxs - world.mins;
2449
2450     for (i = 0; i < attempts; ++i)
2451     {
2452         start_x = org_x + random() * delta_x;
2453         start_y = org_y + random() * delta_y;
2454         start_z = org_z + random() * delta_z;
2455
2456         // rule 1: start inside world bounds, and outside
2457         // solid, and don't start from somewhere where you can
2458         // fall down to evil
2459         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2460         if (trace_fraction >= 1)
2461             continue;
2462         if (trace_startsolid)
2463             continue;
2464         if (trace_dphitcontents & badcontents)
2465             continue;
2466         if (trace_dphitq3surfaceflags & badsurfaceflags)
2467             continue;
2468
2469         // rule 2: if we are too high, lower the point
2470         if (trace_fraction * delta_z > maxaboveground)
2471             start = trace_endpos + '0 0 1' * maxaboveground;
2472         enddown = trace_endpos;
2473
2474         // rule 3: make sure we aren't outside the map. This only works
2475         // for somewhat well formed maps. A good rule of thumb is that
2476         // the map should have a convex outside hull.
2477         // these can be traceLINES as we already verified the starting box
2478         mstart = start + 0.5 * (e.mins + e.maxs);
2479         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2480         if (trace_fraction >= 1)
2481             continue;
2482         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2483         if (trace_fraction >= 1)
2484             continue;
2485         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2486         if (trace_fraction >= 1)
2487             continue;
2488         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2489         if (trace_fraction >= 1)
2490             continue;
2491         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2492         if (trace_fraction >= 1)
2493             continue;
2494
2495         // find a random vector to "look at"
2496         end_x = org_x + random() * delta_x;
2497         end_y = org_y + random() * delta_y;
2498         end_z = org_z + random() * delta_z;
2499         end = start + normalize(end - start) * vlen(delta);
2500
2501         // rule 4: start TO end must not be too short
2502         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2503         if (trace_startsolid)
2504             continue;
2505         if (trace_fraction < minviewdistance / vlen(delta))
2506             continue;
2507
2508         // rule 5: don't want to look at sky
2509         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2510             continue;
2511
2512         // rule 6: we must not end up in trigger_hurt
2513         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2514         {
2515             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2516             continue;
2517         }
2518
2519         break;
2520     }
2521
2522     e.dphitcontentsmask = m;
2523
2524     if (i < attempts)
2525     {
2526         setorigin(e, start);
2527         e.angles = vectoangles(end - start);
2528         dprint("Needed ", ftos(i + 1), " attempts\n");
2529         return TRUE;
2530     }
2531     else
2532         return FALSE;
2533 }
2534
2535 float zcurveparticles_effectno;
2536 vector zcurveparticles_start;
2537 float zcurveparticles_spd;
2538
2539 void endzcurveparticles()
2540 {
2541         if(zcurveparticles_effectno)
2542         {
2543                 // terminator
2544                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2545         }
2546         zcurveparticles_effectno = 0;
2547 }
2548
2549 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2550 {
2551         spd = bound(0, floor(spd / 16), 32767);
2552         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2553         {
2554                 endzcurveparticles();
2555                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2556                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2557                 WriteShort(MSG_BROADCAST, effectno);
2558                 WriteCoord(MSG_BROADCAST, start_x);
2559                 WriteCoord(MSG_BROADCAST, start_y);
2560                 WriteCoord(MSG_BROADCAST, start_z);
2561                 zcurveparticles_effectno = effectno;
2562                 zcurveparticles_start = start;
2563         }
2564         else
2565                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2566         WriteCoord(MSG_BROADCAST, end_x);
2567         WriteCoord(MSG_BROADCAST, end_y);
2568         WriteCoord(MSG_BROADCAST, end_z);
2569         WriteCoord(MSG_BROADCAST, end_dz);
2570         zcurveparticles_spd = spd;
2571 }
2572
2573 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2574 {
2575         float end_dz;
2576         vector vecxy, velxy;
2577
2578         vecxy = end - start;
2579         vecxy_z = 0;
2580         velxy = vel;
2581         velxy_z = 0;
2582
2583         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2584         {
2585                 endzcurveparticles();
2586                 trailparticles(world, effectno, start, end);
2587                 return;
2588         }
2589
2590         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2591         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2592 }
2593
2594 string GetGametype(); // g_world.qc
2595 void write_recordmarker(entity pl, float tstart, float dt)
2596 {
2597     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2598
2599     // also write a marker into demo files for demotc-race-record-extractor to find
2600     stuffcmd(pl,
2601              strcat(
2602                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2603                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2604 }
2605
2606 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2607 {
2608         switch(algn)
2609         {
2610                 case 1: // right
2611                         break;
2612
2613                 case 2: // left
2614                         vecs_y = -vecs_y;
2615                         break;
2616
2617                 default:
2618                 case 3:
2619                         if(allowcenter) // 2: allow center handedness
2620                         {
2621                                 // center
2622                                 vecs_y = 0;
2623                                 vecs_z -= 2;
2624                         }
2625                         else
2626                         {
2627                                 // right
2628                         }
2629                         break;
2630
2631                 case 4:
2632                         if(allowcenter) // 2: allow center handedness
2633                         {
2634                                 // center
2635                                 vecs_y = 0;
2636                                 vecs_z -= 2;
2637                         }
2638                         else
2639                         {
2640                                 // left
2641                                 vecs_y = -vecs_y;
2642                         }
2643                         break;
2644         }
2645         return vecs;
2646 }
2647
2648 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2649 {
2650         string s;
2651         vector v;
2652
2653         if (autocvar_g_shootfromeye)
2654         {
2655                 if (visual)
2656                 {
2657                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2658                 }
2659                 else
2660                 {
2661                         vecs_y = 0;
2662                         vecs_z = 0;
2663                 }
2664         }
2665         else if (autocvar_g_shootfromcenter)
2666         {
2667                 if (visual)
2668                 {
2669                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2670                 }
2671                 else
2672                 {
2673                         vecs_y = 0;
2674                         vecs_z -= 2;
2675                 }
2676         }
2677         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2678         {
2679                 v = stov(s);
2680                 if (y_is_right)
2681                         v_y = -v_y;
2682                 if (v_x != 0)
2683                         vecs_x = v_x;
2684                 vecs_y = v_y;
2685                 vecs_z = v_z;
2686         }
2687         else if (autocvar_g_shootfromclient)
2688         {
2689                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2690         }
2691         return vecs;
2692 }
2693
2694 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2695 {
2696         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2697 }
2698
2699
2700 void attach_sameorigin(entity e, entity to, string tag)
2701 {
2702     vector org, t_forward, t_left, t_up, e_forward, e_up;
2703     vector org0, ang0;
2704     float tagscale;
2705
2706     ang0 = e.angles;
2707     org0 = e.origin;
2708
2709     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2710     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2711     t_forward = v_forward * tagscale;
2712     t_left = v_right * -tagscale;
2713     t_up = v_up * tagscale;
2714
2715     e.origin_x = org * t_forward;
2716     e.origin_y = org * t_left;
2717     e.origin_z = org * t_up;
2718
2719     // current forward and up directions
2720     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2721                 e.angles = AnglesTransform_FromVAngles(e.angles);
2722         else
2723                 e.angles = AnglesTransform_FromAngles(e.angles);
2724     fixedmakevectors(e.angles);
2725
2726     // untransform forward, up!
2727     e_forward_x = v_forward * t_forward;
2728     e_forward_y = v_forward * t_left;
2729     e_forward_z = v_forward * t_up;
2730     e_up_x = v_up * t_forward;
2731     e_up_y = v_up * t_left;
2732     e_up_z = v_up * t_up;
2733
2734     e.angles = fixedvectoangles2(e_forward, e_up);
2735     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2736                 e.angles = AnglesTransform_ToVAngles(e.angles);
2737         else
2738                 e.angles = AnglesTransform_ToAngles(e.angles);
2739
2740     setattachment(e, to, tag);
2741     setorigin(e, e.origin);
2742 }
2743
2744 void detach_sameorigin(entity e)
2745 {
2746     vector org;
2747     org = gettaginfo(e, 0);
2748     e.angles = fixedvectoangles2(v_forward, v_up);
2749     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2750                 e.angles = AnglesTransform_ToVAngles(e.angles);
2751         else
2752                 e.angles = AnglesTransform_ToAngles(e.angles);
2753     setorigin(e, org);
2754     setattachment(e, world, "");
2755     setorigin(e, e.origin);
2756 }
2757
2758 void follow_sameorigin(entity e, entity to)
2759 {
2760     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2761     e.aiment = to; // make the hole follow bmodel
2762     e.punchangle = to.angles; // the original angles of bmodel
2763     e.view_ofs = e.origin - to.origin; // relative origin
2764     e.v_angle = e.angles - to.angles; // relative angles
2765 }
2766
2767 void unfollow_sameorigin(entity e)
2768 {
2769     e.movetype = MOVETYPE_NONE;
2770 }
2771
2772 entity gettaginfo_relative_ent;
2773 vector gettaginfo_relative(entity e, float tag)
2774 {
2775     if (!gettaginfo_relative_ent)
2776     {
2777         gettaginfo_relative_ent = spawn();
2778         gettaginfo_relative_ent.effects = EF_NODRAW;
2779     }
2780     gettaginfo_relative_ent.model = e.model;
2781     gettaginfo_relative_ent.modelindex = e.modelindex;
2782     gettaginfo_relative_ent.frame = e.frame;
2783     return gettaginfo(gettaginfo_relative_ent, tag);
2784 }
2785
2786 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2787 {
2788     float p;
2789     p = pow(2, chan);
2790     if (pl.soundentity.cnt & p)
2791         return;
2792     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2793     pl.soundentity.cnt |= p;
2794 }
2795
2796 void SoundEntity_StopSound(entity pl, float chan)
2797 {
2798     float p;
2799     p = pow(2, chan);
2800     if (pl.soundentity.cnt & p)
2801     {
2802         stopsoundto(MSG_ALL, pl.soundentity, chan);
2803         pl.soundentity.cnt &~= p;
2804     }
2805 }
2806
2807 void SoundEntity_Attach(entity pl)
2808 {
2809     pl.soundentity = spawn();
2810     pl.soundentity.classname = "soundentity";
2811     pl.soundentity.owner = pl;
2812     setattachment(pl.soundentity, pl, "");
2813     setmodel(pl.soundentity, "null");
2814 }
2815
2816 void SoundEntity_Detach(entity pl)
2817 {
2818     float i;
2819     for (i = 0; i <= 7; ++i)
2820         SoundEntity_StopSound(pl, i);
2821 }
2822
2823
2824 float ParseCommandPlayerSlotTarget_firsttoken;
2825 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2826 {
2827     string s;
2828     entity e, head;
2829     float n;
2830
2831     s = string_null;
2832
2833     ParseCommandPlayerSlotTarget_firsttoken = -1;
2834
2835     if (tokens > idx)
2836     {
2837         if (substring(argv(idx), 0, 1) == "#")
2838         {
2839             s = substring(argv(idx), 1, -1);
2840             ++idx;
2841             if (s == "")
2842                 if (tokens > idx)
2843                 {
2844                     s = argv(idx);
2845                     ++idx;
2846                 }
2847                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2848             if (s == ftos(stof(s)))
2849             {
2850                 e = edict_num(stof(s));
2851                 if (e.flags & FL_CLIENT)
2852                     return e;
2853             }
2854         }
2855         else
2856         {
2857             // it must be a nick name
2858             s = argv(idx);
2859             ++idx;
2860                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2861
2862             n = 0;
2863             FOR_EACH_CLIENT(head)
2864             if (head.netname == s)
2865             {
2866                 e = head;
2867                 ++n;
2868             }
2869             if (n == 1)
2870                 return e;
2871
2872             s = strdecolorize(s);
2873             n = 0;
2874             FOR_EACH_CLIENT(head)
2875             if (strdecolorize(head.netname) == s)
2876             {
2877                 e = head;
2878                 ++n;
2879             }
2880             if (n == 1)
2881                 return e;
2882         }
2883     }
2884
2885     return world;
2886 }
2887
2888 .float scale2;
2889
2890 float modeleffect_SendEntity(entity to, float sf)
2891 {
2892         float f;
2893         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2894
2895         f = 0;
2896         if(self.velocity != '0 0 0')
2897                 f |= 1;
2898         if(self.angles != '0 0 0')
2899                 f |= 2;
2900         if(self.avelocity != '0 0 0')
2901                 f |= 4;
2902
2903         WriteByte(MSG_ENTITY, f);
2904         WriteShort(MSG_ENTITY, self.modelindex);
2905         WriteByte(MSG_ENTITY, self.skin);
2906         WriteByte(MSG_ENTITY, self.frame);
2907         WriteCoord(MSG_ENTITY, self.origin_x);
2908         WriteCoord(MSG_ENTITY, self.origin_y);
2909         WriteCoord(MSG_ENTITY, self.origin_z);
2910         if(f & 1)
2911         {
2912                 WriteCoord(MSG_ENTITY, self.velocity_x);
2913                 WriteCoord(MSG_ENTITY, self.velocity_y);
2914                 WriteCoord(MSG_ENTITY, self.velocity_z);
2915         }
2916         if(f & 2)
2917         {
2918                 WriteCoord(MSG_ENTITY, self.angles_x);
2919                 WriteCoord(MSG_ENTITY, self.angles_y);
2920                 WriteCoord(MSG_ENTITY, self.angles_z);
2921         }
2922         if(f & 4)
2923         {
2924                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2925                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2926                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2927         }
2928         WriteShort(MSG_ENTITY, self.scale * 256.0);
2929         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2930         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2931         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2932         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2933
2934         return TRUE;
2935 }
2936
2937 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2938 {
2939         entity e;
2940         float sz;
2941         e = spawn();
2942         e.classname = "modeleffect";
2943         setmodel(e, m);
2944         e.frame = f;
2945         setorigin(e, o);
2946         e.velocity = v;
2947         e.angles = ang;
2948         e.avelocity = angv;
2949         e.alpha = a;
2950         e.teleport_time = t1;
2951         e.fade_time = t2;
2952         e.skin = s;
2953         if(s0 >= 0)
2954                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2955         else
2956                 e.scale = -s0;
2957         if(s2 >= 0)
2958                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2959         else
2960                 e.scale2 = -s2;
2961         sz = max(e.scale, e.scale2);
2962         setsize(e, e.mins * sz, e.maxs * sz);
2963         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2964 }
2965
2966 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2967 {
2968         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2969 }
2970
2971 float randombit(float bits)
2972 {
2973         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2974                 return bits;
2975
2976         float n, f, b, r;
2977
2978         r = random();
2979         b = 0;
2980         n = 0;
2981
2982         for(f = 1; f <= bits; f *= 2)
2983         {
2984                 if(bits & f)
2985                 {
2986                         ++n;
2987                         r *= n;
2988                         if(r <= 1)
2989                                 b = f;
2990                         else
2991                                 r = (r - 1) / (n - 1);
2992                 }
2993         }
2994
2995         return b;
2996 }
2997
2998 float randombits(float bits, float k, float error_return)
2999 {
3000         float r;
3001         r = 0;
3002         while(k > 0 && bits != r)
3003         {
3004                 r += randombit(bits - r);
3005                 --k;
3006         }
3007         if(error_return)
3008                 if(k > 0)
3009                         return -1; // all
3010         return r;
3011 }
3012
3013 void randombit_test(float bits, float iter)
3014 {
3015         while(iter > 0)
3016         {
3017                 print(ftos(randombit(bits)), "\n");
3018                 --iter;
3019         }
3020 }
3021
3022 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3023 {
3024         if(halflifedist > 0)
3025                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3026         else if(halflifedist < 0)
3027                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3028         else
3029                 return 1;
3030 }
3031
3032
3033
3034
3035 #ifdef RELEASE
3036 #define cvar_string_normal cvar_string_builtin
3037 #define cvar_normal cvar_builtin
3038 #else
3039 string cvar_string_normal(string n)
3040 {
3041         if not(cvar_type(n) & 1)
3042                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3043         return cvar_string_builtin(n);
3044 }
3045
3046 float cvar_normal(string n)
3047 {
3048         return stof(cvar_string_normal(n));
3049 }
3050 #endif
3051 #define cvar_set_normal cvar_set_builtin
3052
3053 void defer_think()
3054 {
3055     entity oself;
3056
3057     oself           = self;
3058     self            = self.owner;
3059     oself.think     = SUB_Remove;
3060     oself.nextthink = time;
3061
3062     oself.use();
3063 }
3064
3065 /*
3066     Execute func() after time + fdelay.
3067     self when func is executed = self when defer is called
3068 */
3069 void defer(float fdelay, void() func)
3070 {
3071     entity e;
3072
3073     e           = spawn();
3074     e.owner     = self;
3075     e.use       = func;
3076     e.think     = defer_think;
3077     e.nextthink = time + fdelay;
3078 }