qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(cvar_string("sv_adminnick") != "")
  25                 return cvar_string("sv_adminnick");
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(cvar("sv_fragmessage_information_ping")) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(cvar("sv_fragmessage_information_handicap"))
 104                         if(cvar("sv_fragmessage_information_handicap") == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(cvar("sv_fragmessage_information_handicap")) {
 114                 if(cvar("sv_fragmessage_information_handicap") == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (cvar("sv_eventlog_files"))
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = cvar("sv_eventlog_files_counter") + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (cvar("sv_eventlog_files_timestamps"))
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (cvar("sv_eventlog_console"))
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 193     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 194     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 195     PL_HEAD                                 = stov(cvar_string("sv_player_headsize"));
 196     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 197     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 198     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (cvar("r_showbboxes"))
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471                 else if (escape == "v") {
 472                         float weapon_number;
 473                         local entity stats;
 474
 475                         if(self.classname == "spectator")
 476                                 stats = self.enemy;
 477                         else
 478                                 stats = self;
 479
 480                         weapon_number = stats.weapon;
 481
 482                         if (!weapon_number)
 483                                 weapon_number = stats.switchweapon;
 484
 485                         if (!weapon_number)
 486                                 weapon_number = stats.cnt;
 487
 488                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 489                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 490                         else
 491                                 replacement = "~"; // or something to indicate NULL, not available
 492                 }
 493
 494                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 495                 p = p + strlen(replacement);
 496         }
 497         return msg;
 498 }
 499
 500 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 501         return (value == 0) ? FALSE : TRUE;
 502 }
 503
 504 /*
 505 =============
 506 GetCvars
 507 =============
 508 Called with:
 509   0:  sends the request
 510   >0: receives a cvar from name=argv(f) value=argv(f+1)
 511 */
 512 void GetCvars_handleString(string thisname, float f, .string field, string name)
 513 {
 514         if (f < 0)
 515         {
 516                 if (self.field)
 517                         strunzone(self.field);
 518                 self.field = string_null;
 519         }
 520         else if (f > 0)
 521         {
 522                 if (thisname == name)
 523                 {
 524                         if (self.field)
 525                                 strunzone(self.field);
 526                         self.field = strzone(argv(f + 1));
 527                 }
 528         }
 529         else
 530                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 531 }
 532 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 533 {
 534         GetCvars_handleString(thisname, f, field, name);
 535         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 536                 if (thisname == name)
 537                 {
 538                         string s;
 539                         s = func(strcat1(self.field));
 540                         if (s != self.field)
 541                         {
 542                                 strunzone(self.field);
 543                                 self.field = strzone(s);
 544                         }
 545                 }
 546 }
 547 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 548 {
 549         if (f < 0)
 550         {
 551         }
 552         else if (f > 0)
 553         {
 554                 if (thisname == name)
 555                         self.field = stof(argv(f + 1));
 556         }
 557         else
 558                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559 }
 560 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 561 {
 562         if (f < 0)
 563         {
 564         }
 565         else if (f > 0)
 566         {
 567                 if (thisname == name)
 568                 {
 569                         if(!self.field)
 570                         {
 571                                 self.field = stof(argv(f + 1));
 572                                 if(!self.field)
 573                                         self.field = -1;
 574                         }
 575                 }
 576         }
 577         else
 578         {
 579                 if(!self.field)
 580                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 581         }
 582 }
 583 float w_getbestweapon(entity e);
 584 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 585 {
 586         string o;
 587         o = W_FixWeaponOrder_ForceComplete(wo);
 588         if(self.weaponorder_byimpulse)
 589         {
 590                 strunzone(self.weaponorder_byimpulse);
 591                 self.weaponorder_byimpulse = string_null;
 592         }
 593         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 594         return o;
 595 }
 596 void GetCvars(float f)
 597 {
 598         string s;
 599
 600         if (f > 0)
 601                 s = strcat1(argv(f));
 602
 603         get_cvars_f = f;
 604         get_cvars_s = s;
 605         MUTATOR_CALLHOOK(GetCvars);
 606         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 607         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 608         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 609         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 610         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 611         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 613         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 614         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 615         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 616         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 617         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 618         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 619         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 620         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 621         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 622         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 623         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 624         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 625         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 626         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 627         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 628         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 629         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 630         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 631
 632         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 633         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 634
 635 #ifdef ALLOW_FORCEMODELS
 636         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 637         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 638 #endif
 639         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 640         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 641
 642         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 643         if (f > 0)
 644         {
 645                 if (s == "cl_weaponpriority")
 646                         self.switchweapon = w_getbestweapon(self);
 647         }
 648 }
 649
 650 float fexists(string f)
 651 {
 652     float fh;
 653     fh = fopen(f, FILE_READ);
 654     if (fh < 0)
 655         return FALSE;
 656     fclose(fh);
 657     return TRUE;
 658 }
 659
 660 void backtrace(string msg)
 661 {
 662     float dev, war;
 663     dev = cvar("developer");
 664     war = cvar("prvm_backtraceforwarnings");
 665     cvar_set("developer", "1");
 666     cvar_set("prvm_backtraceforwarnings", "1");
 667     print("\n");
 668     print("--- CUT HERE ---\nWARNING: ");
 669     print(msg);
 670     print("\n");
 671     remove(world); // isn't there any better way to cause a backtrace?
 672     print("\n--- CUT UNTIL HERE ---\n");
 673     cvar_set("developer", ftos(dev));
 674     cvar_set("prvm_backtraceforwarnings", ftos(war));
 675 }
 676
 677 string Team_ColorCode(float teamid)
 678 {
 679     if (teamid == COLOR_TEAM1)
 680         return "^1";
 681     else if (teamid == COLOR_TEAM2)
 682         return "^4";
 683     else if (teamid == COLOR_TEAM3)
 684         return "^3";
 685     else if (teamid == COLOR_TEAM4)
 686         return "^6";
 687     else
 688         return "^7";
 689 }
 690
 691 string Team_ColorName(float t)
 692 {
 693     // fixme: Search for team entities and get their .netname's!
 694     if (t == COLOR_TEAM1)
 695         return "Red";
 696     if (t == COLOR_TEAM2)
 697         return "Blue";
 698     if (t == COLOR_TEAM3)
 699         return "Yellow";
 700     if (t == COLOR_TEAM4)
 701         return "Pink";
 702     return "Neutral";
 703 }
 704
 705 string Team_ColorNameLowerCase(float t)
 706 {
 707     // fixme: Search for team entities and get their .netname's!
 708     if (t == COLOR_TEAM1)
 709         return "red";
 710     if (t == COLOR_TEAM2)
 711         return "blue";
 712     if (t == COLOR_TEAM3)
 713         return "yellow";
 714     if (t == COLOR_TEAM4)
 715         return "pink";
 716     return "neutral";
 717 }
 718
 719 float ColourToNumber(string team_colour)
 720 {
 721         if (team_colour == "red")
 722                 return COLOR_TEAM1;
 723
 724         if (team_colour == "blue")
 725                 return COLOR_TEAM2;
 726
 727         if (team_colour == "yellow")
 728                 return COLOR_TEAM3;
 729
 730         if (team_colour == "pink")
 731                 return COLOR_TEAM4;
 732
 733         if (team_colour == "auto")
 734                 return 0;
 735
 736         return -1;
 737 }
 738
 739 float NumberToTeamNumber(float number)
 740 {
 741         if (number == 1)
 742                 return COLOR_TEAM1;
 743
 744         if (number == 2)
 745                 return COLOR_TEAM2;
 746
 747         if (number == 3)
 748                 return COLOR_TEAM3;
 749
 750         if (number == 4)
 751                 return COLOR_TEAM4;
 752
 753         return -1;
 754 }
 755
 756 #define CENTERPRIO_POINT 1
 757 #define CENTERPRIO_SPAM 2
 758 #define CENTERPRIO_VOTE 4
 759 #define CENTERPRIO_NORMAL 5
 760 #define CENTERPRIO_SHIELDING 7
 761 #define CENTERPRIO_MAPVOTE 9
 762 #define CENTERPRIO_IDLEKICK 50
 763 #define CENTERPRIO_ADMIN 99
 764 .float centerprint_priority;
 765 .float centerprint_expires;
 766 void centerprint_atprio(entity e, float prio, string s)
 767 {
 768     if (intermission_running)
 769         if (prio < CENTERPRIO_MAPVOTE)
 770             return;
 771     if (time > e.centerprint_expires)
 772         e.centerprint_priority = 0;
 773     if (prio >= e.centerprint_priority)
 774     {
 775         e.centerprint_priority = prio;
 776         if (timeoutStatus == 2)
 777             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 778         else
 779             e.centerprint_expires = time + e.cvar_scr_centertime;
 780         centerprint_builtin(e, s);
 781     }
 782 }
 783 void centerprint_expire(entity e, float prio)
 784 {
 785     if (prio == e.centerprint_priority)
 786     {
 787         e.centerprint_priority = 0;
 788         centerprint_builtin(e, "");
 789     }
 790 }
 791 void centerprint(entity e, string s)
 792 {
 793     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 794 }
 795
 796 // decolorizes and team colors the player name when needed
 797 string playername(entity p)
 798 {
 799     string t;
 800     if (teams_matter && !intermission_running && p.classname == "player")
 801     {
 802         t = Team_ColorCode(p.team);
 803         return strcat(t, strdecolorize(p.netname));
 804     }
 805     else
 806         return p.netname;
 807 }
 808
 809 vector randompos(vector m1, vector m2)
 810 {
 811     local vector v;
 812     m2 = m2 - m1;
 813     v_x = m2_x * random() + m1_x;
 814     v_y = m2_y * random() + m1_y;
 815     v_z = m2_z * random() + m1_z;
 816     return  v;
 817 };
 818
 819 float g_pickup_shells;
 820 float g_pickup_shells_max;
 821 float g_pickup_nails;
 822 float g_pickup_nails_max;
 823 float g_pickup_rockets;
 824 float g_pickup_rockets_max;
 825 float g_pickup_cells;
 826 float g_pickup_cells_max;
 827 float g_pickup_fuel;
 828 float g_pickup_fuel_jetpack;
 829 float g_pickup_fuel_max;
 830 float g_pickup_armorsmall;
 831 float g_pickup_armorsmall_max;
 832 float g_pickup_armorsmall_anyway;
 833 float g_pickup_armormedium;
 834 float g_pickup_armormedium_max;
 835 float g_pickup_armormedium_anyway;
 836 float g_pickup_armorbig;
 837 float g_pickup_armorbig_max;
 838 float g_pickup_armorbig_anyway;
 839 float g_pickup_armorlarge;
 840 float g_pickup_armorlarge_max;
 841 float g_pickup_armorlarge_anyway;
 842 float g_pickup_healthsmall;
 843 float g_pickup_healthsmall_max;
 844 float g_pickup_healthsmall_anyway;
 845 float g_pickup_healthmedium;
 846 float g_pickup_healthmedium_max;
 847 float g_pickup_healthmedium_anyway;
 848 float g_pickup_healthlarge;
 849 float g_pickup_healthlarge_max;
 850 float g_pickup_healthlarge_anyway;
 851 float g_pickup_healthmega;
 852 float g_pickup_healthmega_max;
 853 float g_pickup_healthmega_anyway;
 854 float g_pickup_ammo_anyway;
 855 float g_pickup_weapons_anyway;
 856 float g_weaponarena;
 857 float g_weaponarena_random;
 858 string g_weaponarena_list;
 859 float g_weaponspeedfactor;
 860 float g_weaponratefactor;
 861 float g_weapondamagefactor;
 862 float g_weaponforcefactor;
 863 float g_weaponspreadfactor;
 864
 865 float start_weapons;
 866 float start_items;
 867 float start_ammo_shells;
 868 float start_ammo_nails;
 869 float start_ammo_rockets;
 870 float start_ammo_cells;
 871 float start_ammo_fuel;
 872 float start_health;
 873 float start_armorvalue;
 874 float warmup_start_weapons;
 875 float warmup_start_ammo_shells;
 876 float warmup_start_ammo_nails;
 877 float warmup_start_ammo_rockets;
 878 float warmup_start_ammo_cells;
 879 float warmup_start_ammo_fuel;
 880 float warmup_start_health;
 881 float warmup_start_armorvalue;
 882 float g_weapon_stay;
 883 float g_ghost_items;
 884
 885 entity get_weaponinfo(float w);
 886
 887 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 888 {
 889         var float i = weaponinfo.weapon;
 890
 891         if (!i)
 892                 return 0;
 893
 894         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 895
 896         if (t < 0) // "default" weapon selection
 897         {
 898                 if (g_lms || g_ca || allguns)
 899                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 900                 else if(t < -1)
 901                         t = 0;
 902                 else if (g_race || g_cts)
 903                         t = (i == WEP_LASER);
 904                 else if (g_nexball)
 905                         t = 0; // weapon is set a few lines later
 906                 else
 907                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 908                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 909                         t |= (i == WEP_HOOK);
 910         }
 911
 912         // we cannot disable porto in Nexball, we must force it
 913         if(g_nexball && i == WEP_PORTO)
 914                 t = 1;
 915
 916         return t;
 917 }
 918
 919 void readplayerstartcvars()
 920 {
 921         entity e;
 922         float i, j, t;
 923         string s;
 924
 925         // initialize starting values for players
 926         start_weapons = 0;
 927         start_items = 0;
 928         start_ammo_shells = 0;
 929         start_ammo_nails = 0;
 930         start_ammo_rockets = 0;
 931         start_ammo_cells = 0;
 932         start_health = cvar("g_balance_health_start");
 933         start_armorvalue = cvar("g_balance_armor_start");
 934
 935         g_weaponarena = 0;
 936         s = cvar_string("g_weaponarena");
 937         if (s == "0")
 938         {
 939         }
 940         else if (s == "all")
 941         {
 942                 g_weaponarena_list = "All Weapons";
 943                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 944                 {
 945                         e = get_weaponinfo(j);
 946                         g_weaponarena |= e.weapons;
 947                         weapon_action(e.weapon, WR_PRECACHE);
 948                 }
 949         }
 950         else if (s == "most")
 951         {
 952                 g_weaponarena_list = "Most Weapons";
 953                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 954                 {
 955                         e = get_weaponinfo(j);
 956                         if (e.spawnflags & WEP_FLAG_NORMAL)
 957                         {
 958                                 g_weaponarena |= e.weapons;
 959                                 weapon_action(e.weapon, WR_PRECACHE);
 960                         }
 961                 }
 962         }
 963         else if (s == "none")
 964         {
 965                 g_weaponarena_list = "No Weapons";
 966                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 967         }
 968         else
 969         {
 970                 t = tokenize_console(s);
 971                 g_weaponarena_list = "";
 972                 for (i = 0; i < t; ++i)
 973                 {
 974                         s = argv(i);
 975                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 976                         {
 977                                 e = get_weaponinfo(j);
 978                                 if (e.netname == s)
 979                                 {
 980                                         g_weaponarena |= e.weapons;
 981                                         weapon_action(e.weapon, WR_PRECACHE);
 982                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 983                                         break;
 984                                 }
 985                         }
 986                         if (j > WEP_LAST)
 987                         {
 988                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 989                         }
 990                 }
 991                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 992         }
 993
 994         if(g_weaponarena)
 995                 g_weaponarena_random = cvar("g_weaponarena_random");
 996         else
 997                 g_weaponarena_random = 0;
 998
 999         if (g_weaponarena)
1000         {
1001                 start_weapons = g_weaponarena;
1002                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
1003                         start_ammo_rockets = 999;
1004                 if (g_weaponarena & WEPBIT_SHOTGUN)
1005                         start_ammo_shells = 999;
1006                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
1007                         start_ammo_cells = 999;
1008                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
1009                         start_ammo_nails = 999;
1010                 if (g_weaponarena & WEPBIT_HOOK)
1011                         start_ammo_fuel = 999;
1012                 start_items |= IT_UNLIMITED_AMMO;
1013         }
1014         else if (g_minstagib)
1015         {
1016                 start_health = 100;
1017                 start_armorvalue = 0;
1018                 start_weapons = WEPBIT_MINSTANEX;
1019                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1020                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1021                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1022                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1023
1024                 if (g_minstagib_invis_alpha <= 0)
1025                         g_minstagib_invis_alpha = -1;
1026         }
1027         else
1028         {
1029                 if (g_lms || g_ca)
1030                 {
1031                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1032                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1033                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1034                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1035                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1036                         start_health = cvar("g_lms_start_health");
1037                         start_armorvalue = cvar("g_lms_start_armor");
1038                 }
1039                 else
1040                 {
1041                         start_ammo_shells = cvar("g_start_ammo_shells");
1042                         start_ammo_nails = cvar("g_start_ammo_nails");
1043                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1044                         start_ammo_cells = cvar("g_start_ammo_cells");
1045                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1046                 }
1047
1048                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1049                 {
1050                         e = get_weaponinfo(i);
1051                         if(want_weapon("g_start_weapon_", e, FALSE))
1052                                 start_weapons |= e.weapons;
1053                 }
1054         }
1055
1056         if (inWarmupStage)
1057         {
1058                 warmup_start_ammo_shells = start_ammo_shells;
1059                 warmup_start_ammo_nails = start_ammo_nails;
1060                 warmup_start_ammo_rockets = start_ammo_rockets;
1061                 warmup_start_ammo_cells = start_ammo_cells;
1062                 warmup_start_ammo_fuel = start_ammo_fuel;
1063                 warmup_start_health = start_health;
1064                 warmup_start_armorvalue = start_armorvalue;
1065                 warmup_start_weapons = start_weapons;
1066
1067                 if (!g_weaponarena && !g_minstagib && !g_ca)
1068                 {
1069                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1070                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1071                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1072                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1073                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1074                         warmup_start_health = cvar("g_warmup_start_health");
1075                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1076                         warmup_start_weapons = 0;
1077                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1078                         {
1079                                 e = get_weaponinfo(i);
1080                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1081                                         warmup_start_weapons |= e.weapons;
1082                         }
1083                 }
1084         }
1085
1086         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1087         {
1088                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1089                 start_items |= IT_FUEL_REGEN;
1090                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1091                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1092         }
1093
1094         if(!cvar("g_use_ammunition"))
1095         {
1096                 start_ammo_shells = cvar("g_pickup_shells_max");
1097                 start_ammo_nails = cvar("g_pickup_nails_max");
1098                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1099                 start_ammo_cells = cvar("g_pickup_cells_max");
1100                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1101                 start_items |= IT_UNLIMITED_AMMO;
1102                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1103                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1104                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1105                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1106                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1107                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1108         }
1109
1110         if (g_jetpack)
1111                 start_items |= IT_JETPACK;
1112
1113         if (g_weapon_stay == 2)
1114         {
1115                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1116                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1117                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1118                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1119                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1120                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1121                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1122                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1123                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1124                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1125         }
1126
1127         MUTATOR_CALLHOOK(SetStartItems);
1128
1129         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1130         {
1131                 e = get_weaponinfo(i);
1132                 if(e.weapons & (start_weapons | warmup_start_weapons))
1133                         weapon_action(e.weapon, WR_PRECACHE);
1134         }
1135
1136         start_ammo_shells = max(0, start_ammo_shells);
1137         start_ammo_nails = max(0, start_ammo_nails);
1138         start_ammo_cells = max(0, start_ammo_cells);
1139         start_ammo_rockets = max(0, start_ammo_rockets);
1140         start_ammo_fuel = max(0, start_ammo_fuel);
1141
1142         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1143         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1144         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1145         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1146         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1147 }
1148
1149 float g_bugrigs;
1150 float g_bugrigs_planar_movement;
1151 float g_bugrigs_planar_movement_car_jumping;
1152 float g_bugrigs_reverse_spinning;
1153 float g_bugrigs_reverse_speeding;
1154 float g_bugrigs_reverse_stopping;
1155 float g_bugrigs_air_steering;
1156 float g_bugrigs_angle_smoothing;
1157 float g_bugrigs_friction_floor;
1158 float g_bugrigs_friction_brake;
1159 float g_bugrigs_friction_air;
1160 float g_bugrigs_accel;
1161 float g_bugrigs_speed_ref;
1162 float g_bugrigs_speed_pow;
1163 float g_bugrigs_steer;
1164
1165 float g_touchexplode;
1166 float g_touchexplode_radius;
1167 float g_touchexplode_damage;
1168 float g_touchexplode_edgedamage;
1169 float g_touchexplode_force;
1170
1171 float sv_autotaunt;
1172 float sv_taunt;
1173
1174 float sv_pitch_min;
1175 float sv_pitch_max;
1176 float sv_pitch_fixyaw;
1177
1178 float sv_accuracy_data_share;
1179
1180 void readlevelcvars(void)
1181 {
1182         // first load all the mutators
1183         if(cvar("g_nix"))
1184                 MUTATOR_ADD(mutator_nix);
1185         if(cvar("g_dodging"))
1186                 MUTATOR_ADD(mutator_dodging);
1187         if(cvar("g_rocket_flying"))
1188                 MUTATOR_ADD(mutator_rocketflying);
1189
1190     g_bugrigs = cvar("g_bugrigs");
1191     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1192     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1193     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1194     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1195     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1196     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1197     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1198     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1199     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1200     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1201     g_bugrigs_accel = cvar("g_bugrigs_accel");
1202     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1203     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1204     g_bugrigs_steer = cvar("g_bugrigs_steer");
1205
1206     g_touchexplode = cvar("g_touchexplode");
1207     g_touchexplode_radius = cvar("g_touchexplode_radius");
1208     g_touchexplode_damage = cvar("g_touchexplode_damage");
1209     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1210     g_touchexplode_force = cvar("g_touchexplode_force");
1211
1212 #ifdef ALLOW_FORCEMODELS
1213         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1214 #endif
1215         sv_loddistance1 = cvar("sv_loddistance1");
1216         sv_loddistance2 = cvar("sv_loddistance2");
1217
1218         if(sv_loddistance2 <= sv_loddistance1)
1219                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1220
1221         sv_clones = cvar("sv_clones");
1222         sv_gentle = cvar("sv_gentle");
1223         sv_foginterval = cvar("sv_foginterval");
1224         g_cloaked = cvar("g_cloaked");
1225         g_jump_grunt = cvar("g_jump_grunt");
1226         g_footsteps = cvar("g_footsteps");
1227         g_grappling_hook = cvar("g_grappling_hook");
1228         g_jetpack = cvar("g_jetpack");
1229         g_laserguided_missile = cvar("g_laserguided_missile");
1230         g_midair = cvar("g_midair");
1231         g_minstagib = cvar("g_minstagib");
1232         g_norecoil = cvar("g_norecoil");
1233         g_vampire = cvar("g_vampire");
1234         g_bloodloss = cvar("g_bloodloss");
1235         sv_maxidle = cvar("sv_maxidle");
1236         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1237         sv_pogostick = cvar("sv_pogostick");
1238         g_ctf_reverse = cvar("g_ctf_reverse");
1239         sv_autotaunt = cvar("sv_autotaunt");
1240         sv_taunt = cvar("sv_taunt");
1241
1242         inWarmupStage = cvar("g_warmup");
1243         g_warmup_limit = cvar("g_warmup_limit");
1244         g_warmup_allguns = cvar("g_warmup_allguns");
1245         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1246
1247         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1248                 inWarmupStage = 0; // these modes cannot work together, sorry
1249
1250         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1251         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1252         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1253         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1254         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1255         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1256         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1257         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1258         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1259         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1260         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1261         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1262
1263         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1264         g_weaponratefactor = cvar("g_weaponratefactor");
1265         g_weapondamagefactor = cvar("g_weapondamagefactor");
1266         g_weaponforcefactor = cvar("g_weaponforcefactor");
1267         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1268
1269         g_pickup_shells = cvar("g_pickup_shells");
1270         g_pickup_shells_max = cvar("g_pickup_shells_max");
1271         g_pickup_nails = cvar("g_pickup_nails");
1272         g_pickup_nails_max = cvar("g_pickup_nails_max");
1273         g_pickup_rockets = cvar("g_pickup_rockets");
1274         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1275         g_pickup_cells = cvar("g_pickup_cells");
1276         g_pickup_cells_max = cvar("g_pickup_cells_max");
1277         g_pickup_fuel = cvar("g_pickup_fuel");
1278         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1279         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1280         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1281         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1282         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1283         g_pickup_armormedium = cvar("g_pickup_armormedium");
1284         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1285         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1286         g_pickup_armorbig = cvar("g_pickup_armorbig");
1287         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1288         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1289         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1290         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1291         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1292         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1293         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1294         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1295         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1296         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1297         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1298         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1299         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1300         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1301         g_pickup_healthmega = cvar("g_pickup_healthmega");
1302         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1303         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1304
1305         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1306         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1307
1308         g_pinata = cvar("g_pinata");
1309
1310         g_weapon_stay = cvar("g_weapon_stay");
1311
1312         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1313                 g_weapon_stay = 1;
1314
1315         g_ghost_items = cvar("g_ghost_items");
1316
1317         if(g_ghost_items >= 1)
1318                 g_ghost_items = 0.25; // default alpha value
1319
1320         if not(inWarmupStage && !g_ca)
1321                 game_starttime = cvar("g_start_delay");
1322
1323         sv_pitch_min = cvar("sv_pitch_min");
1324         sv_pitch_max = cvar("sv_pitch_max");
1325         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1326
1327         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1328
1329         readplayerstartcvars();
1330 }
1331
1332 /*
1333 // TODO sound pack system
1334 string soundpack;
1335
1336 string precache_sound_builtin (string s) = #19;
1337 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1338 string precache_sound(string s)
1339 {
1340         return precache_sound_builtin(strcat(soundpack, s));
1341 }
1342 void play2(entity e, string filename)
1343 {
1344         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1345 }
1346 void sound(entity e, float chan, string samp, float vol, float atten)
1347 {
1348         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1349 }
1350 */
1351
1352 // Sound functions
1353 string precache_sound (string s) = #19;
1354 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1355 float precache_sound_index (string s) = #19;
1356
1357 #define SND_VOLUME      1
1358 #define SND_ATTENUATION 2
1359 #define SND_LARGEENTITY 8
1360 #define SND_LARGESOUND  16
1361
1362 float sound_allowed(float dest, entity e)
1363 {
1364     // sounds from world may always pass
1365     for (;;)
1366     {
1367         if (e.classname == "body")
1368             e = e.enemy;
1369         if (e.owner && e.owner != e)
1370             e = e.owner;
1371         else
1372             break;
1373     }
1374     // sounds to self may always pass
1375     if (dest == MSG_ONE)
1376         if (e == msg_entity)
1377             return TRUE;
1378     // sounds by players can be removed
1379     if (cvar("bot_sound_monopoly"))
1380         if (clienttype(e) == CLIENTTYPE_REAL)
1381             return FALSE;
1382     // anything else may pass
1383     return TRUE;
1384 }
1385
1386 void sound(entity e, float chan, string samp, float vol, float atten)
1387 {
1388     if (!sound_allowed(MSG_BROADCAST, e))
1389         return;
1390     sound_builtin(e, chan, samp, vol, atten);
1391 }
1392 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1393 {
1394     float entno, idx;
1395
1396     if (!sound_allowed(dest, e))
1397         return;
1398
1399     entno = num_for_edict(e);
1400     idx = precache_sound_index(samp);
1401
1402     float sflags;
1403     sflags = 0;
1404
1405     atten = floor(atten * 64);
1406     vol = floor(vol * 255);
1407
1408     if (vol != 255)
1409         sflags |= SND_VOLUME;
1410     if (atten != 64)
1411         sflags |= SND_ATTENUATION;
1412     if (entno >= 8192)
1413         sflags |= SND_LARGEENTITY;
1414     if (idx >= 256)
1415         sflags |= SND_LARGESOUND;
1416
1417     WriteByte(dest, SVC_SOUND);
1418     WriteByte(dest, sflags);
1419     if (sflags & SND_VOLUME)
1420         WriteByte(dest, vol);
1421     if (sflags & SND_ATTENUATION)
1422         WriteByte(dest, atten);
1423     if (sflags & SND_LARGEENTITY)
1424     {
1425         WriteShort(dest, entno);
1426         WriteByte(dest, chan);
1427     }
1428     else
1429     {
1430         WriteShort(dest, entno * 8 + chan);
1431     }
1432     if (sflags & SND_LARGESOUND)
1433         WriteShort(dest, idx);
1434     else
1435         WriteByte(dest, idx);
1436
1437     WriteCoord(dest, o_x);
1438     WriteCoord(dest, o_y);
1439     WriteCoord(dest, o_z);
1440 }
1441 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1442 {
1443     vector o;
1444
1445     if (!sound_allowed(dest, e))
1446         return;
1447
1448     o = e.origin + 0.5 * (e.mins + e.maxs);
1449     soundtoat(dest, e, o, chan, samp, vol, atten);
1450 }
1451 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1452 {
1453     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1454 }
1455 void stopsoundto(float dest, entity e, float chan)
1456 {
1457     float entno;
1458
1459     if (!sound_allowed(dest, e))
1460         return;
1461
1462     entno = num_for_edict(e);
1463
1464     if (entno >= 8192)
1465     {
1466         float idx, sflags;
1467         idx = precache_sound_index("misc/null.wav");
1468         sflags = SND_LARGEENTITY;
1469         if (idx >= 256)
1470             sflags |= SND_LARGESOUND;
1471         WriteByte(dest, SVC_SOUND);
1472         WriteByte(dest, sflags);
1473         WriteShort(dest, entno);
1474         WriteByte(dest, chan);
1475         if (sflags & SND_LARGESOUND)
1476             WriteShort(dest, idx);
1477         else
1478             WriteByte(dest, idx);
1479         WriteCoord(dest, e.origin_x);
1480         WriteCoord(dest, e.origin_y);
1481         WriteCoord(dest, e.origin_z);
1482     }
1483     else
1484     {
1485         WriteByte(dest, SVC_STOPSOUND);
1486         WriteShort(dest, entno * 8 + chan);
1487     }
1488 }
1489 void stopsound(entity e, float chan)
1490 {
1491     if (!sound_allowed(MSG_BROADCAST, e))
1492         return;
1493
1494     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1495     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1496 }
1497
1498 void play2(entity e, string filename)
1499 {
1500     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1501     msg_entity = e;
1502     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1503 }
1504
1505 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1506 .float spamtime;
1507 float spamsound(entity e, float chan, string samp, float vol, float atten)
1508 {
1509     if (!sound_allowed(MSG_BROADCAST, e))
1510         return FALSE;
1511
1512     if (time > e.spamtime)
1513     {
1514         e.spamtime = time;
1515         sound(e, chan, samp, vol, atten);
1516         return TRUE;
1517     }
1518     return FALSE;
1519 }
1520
1521 void play2team(float t, string filename)
1522 {
1523     local entity head;
1524
1525     if (cvar("bot_sound_monopoly"))
1526         return;
1527
1528     FOR_EACH_REALPLAYER(head)
1529     {
1530         if (head.team == t)
1531             play2(head, filename);
1532     }
1533 }
1534
1535 void play2all(string samp)
1536 {
1537     if (cvar("bot_sound_monopoly"))
1538         return;
1539
1540     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1541 }
1542
1543 void PrecachePlayerSounds(string f);
1544 void precache_playermodel(string m)
1545 {
1546         float globhandle, i, n;
1547         string f;
1548
1549         if(substring(m, -9,5) == "_lod1")
1550                 return;
1551         if(substring(m, -9,5) == "_lod2")
1552                 return;
1553         precache_model(m);
1554         if(sv_loddistance1)
1555         {
1556                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1557                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1558         }
1559
1560         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1561         if (globhandle < 0)
1562                 return;
1563         n = search_getsize(globhandle);
1564         for (i = 0; i < n; ++i)
1565         {
1566                 //print(search_getfilename(globhandle, i), "\n");
1567                 f = search_getfilename(globhandle, i);
1568                 PrecachePlayerSounds(f);
1569         }
1570         search_end(globhandle);
1571 }
1572 void precache_all_playermodels(string pattern)
1573 {
1574         float globhandle, i, n;
1575         string f;
1576
1577         globhandle = search_begin(pattern, TRUE, FALSE);
1578         if (globhandle < 0)
1579                 return;
1580         n = search_getsize(globhandle);
1581         for (i = 0; i < n; ++i)
1582         {
1583                 //print(search_getfilename(globhandle, i), "\n");
1584                 f = search_getfilename(globhandle, i);
1585                 precache_playermodel(f);
1586         }
1587         search_end(globhandle);
1588 }
1589
1590 void precache()
1591 {
1592     // gamemode related things
1593     precache_model ("models/misc/chatbubble.spr");
1594     precache_model ("models/misc/teambubble.spr");
1595     if (g_runematch)
1596     {
1597         precache_model ("models/runematch/curse.mdl");
1598         precache_model ("models/runematch/rune.mdl");
1599     }
1600
1601 #ifdef TTURRETS_ENABLED
1602     if (cvar("g_turrets"))
1603         turrets_precash();
1604 #endif
1605
1606     // Precache all player models if desired
1607     if (cvar("sv_precacheplayermodels"))
1608     {
1609         PrecachePlayerSounds("sound/player/default.sounds");
1610         precache_all_playermodels("models/player/*.zym");
1611         precache_all_playermodels("models/player/*.dpm");
1612         precache_all_playermodels("models/player/*.md3");
1613         precache_all_playermodels("models/player/*.psk");
1614         precache_all_playermodels("models/player/*.iqm");
1615     }
1616
1617     if (cvar("sv_defaultcharacter"))
1618     {
1619         string s;
1620         s = cvar_string("sv_defaultplayermodel_red");
1621         if (s != "")
1622             precache_playermodel(s);
1623         s = cvar_string("sv_defaultplayermodel_blue");
1624         if (s != "")
1625             precache_playermodel(s);
1626         s = cvar_string("sv_defaultplayermodel_yellow");
1627         if (s != "")
1628             precache_playermodel(s);
1629         s = cvar_string("sv_defaultplayermodel_pink");
1630         if (s != "")
1631             precache_playermodel(s);
1632         s = cvar_string("sv_defaultplayermodel");
1633         if (s != "")
1634             precache_playermodel(s);
1635     }
1636
1637     if (g_footsteps)
1638     {
1639         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1640         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1641     }
1642
1643     // gore and miscellaneous sounds
1644     //precache_sound ("misc/h2ohit.wav");
1645     precache_model ("models/hook.md3");
1646     precache_sound ("misc/armorimpact.wav");
1647     precache_sound ("misc/bodyimpact1.wav");
1648     precache_sound ("misc/bodyimpact2.wav");
1649     precache_sound ("misc/gib.wav");
1650     precache_sound ("misc/gib_splat01.wav");
1651     precache_sound ("misc/gib_splat02.wav");
1652     precache_sound ("misc/gib_splat03.wav");
1653     precache_sound ("misc/gib_splat04.wav");
1654     precache_sound ("misc/hit.wav");
1655         precache_sound ("misc/typehit.wav");
1656     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1657     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1658     precache_sound ("misc/null.wav");
1659     precache_sound ("misc/spawn.wav");
1660     precache_sound ("misc/talk.wav");
1661     precache_sound ("misc/teleport.wav");
1662     precache_sound ("misc/poweroff.wav");
1663     precache_sound ("player/lava.wav");
1664     precache_sound ("player/slime.wav");
1665
1666     if (g_jetpack)
1667         precache_sound ("misc/jetpack_fly.wav");
1668
1669     precache_model ("models/sprites/0.spr32");
1670     precache_model ("models/sprites/1.spr32");
1671     precache_model ("models/sprites/2.spr32");
1672     precache_model ("models/sprites/3.spr32");
1673     precache_model ("models/sprites/4.spr32");
1674     precache_model ("models/sprites/5.spr32");
1675     precache_model ("models/sprites/6.spr32");
1676     precache_model ("models/sprites/7.spr32");
1677     precache_model ("models/sprites/8.spr32");
1678     precache_model ("models/sprites/9.spr32");
1679     precache_model ("models/sprites/10.spr32");
1680
1681     // common weapon precaches
1682     precache_sound ("weapons/weapon_switch.wav");
1683     precache_sound ("weapons/weaponpickup.wav");
1684     precache_sound ("weapons/unavailable.wav");
1685     precache_sound ("weapons/dryfire.wav");
1686     if (g_grappling_hook)
1687     {
1688         precache_sound ("weapons/hook_fire.wav"); // hook
1689         precache_sound ("weapons/hook_impact.wav"); // hook
1690     }
1691
1692     if(cvar("sv_precacheweapons"))
1693     {
1694         //precache weapon models/sounds
1695         local float wep;
1696         wep = WEP_FIRST;
1697         while (wep <= WEP_LAST)
1698         {
1699             weapon_action(wep, WR_PRECACHE);
1700             wep = wep + 1;
1701         }
1702     }
1703
1704     precache_model("models/elaser.mdl");
1705     precache_model("models/laser.mdl");
1706     precache_model("models/ebomb.mdl");
1707
1708 #if 0
1709     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1710
1711     if (!self.noise && self.music) // quake 3 uses the music field
1712         self.noise = self.music;
1713
1714     // plays music for the level if there is any
1715     if (self.noise)
1716     {
1717         precache_sound (self.noise);
1718         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1719     }
1720 #endif
1721 }
1722
1723 // sorry, but using \ in macros breaks line numbers
1724 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1725 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1726 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1727
1728 // WARNING: this kills the trace globals
1729 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1730 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1731
1732 #define INITPRIO_FIRST              0
1733 #define INITPRIO_GAMETYPE           0
1734 #define INITPRIO_GAMETYPE_FALLBACK  1
1735 #define INITPRIO_FINDTARGET        10
1736 #define INITPRIO_DROPTOFLOOR       20
1737 #define INITPRIO_SETLOCATION       90
1738 #define INITPRIO_LINKDOORS         91
1739 #define INITPRIO_LAST              99
1740
1741 .void(void) initialize_entity;
1742 .float initialize_entity_order;
1743 .entity initialize_entity_next;
1744 entity initialize_entity_first;
1745
1746 void make_safe_for_remove(entity e)
1747 {
1748     if (e.initialize_entity)
1749     {
1750         entity ent, prev;
1751         for (ent = initialize_entity_first; ent; )
1752         {
1753             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1754             {
1755                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1756                 // skip it in linked list
1757                 if (prev)
1758                 {
1759                     prev.initialize_entity_next = ent.initialize_entity_next;
1760                     ent = prev.initialize_entity_next;
1761                 }
1762                 else
1763                 {
1764                     initialize_entity_first = ent.initialize_entity_next;
1765                     ent = initialize_entity_first;
1766                 }
1767             }
1768             else
1769             {
1770                 prev = ent;
1771                 ent = ent.initialize_entity_next;
1772             }
1773         }
1774     }
1775 }
1776
1777 void objerror(string s)
1778 {
1779     make_safe_for_remove(self);
1780     objerror_builtin(s);
1781 }
1782
1783 void remove_unsafely(entity e)
1784 {
1785     remove_builtin(e);
1786 }
1787
1788 void remove_safely(entity e)
1789 {
1790     make_safe_for_remove(e);
1791     remove_builtin(e);
1792 }
1793
1794 void InitializeEntity(entity e, void(void) func, float order)
1795 {
1796     entity prev, cur;
1797
1798     if (!e || e.initialize_entity)
1799     {
1800         // make a proxy initializer entity
1801         entity e_old;
1802         e_old = e;
1803         e = spawn();
1804         e.classname = "initialize_entity";
1805         e.enemy = e_old;
1806     }
1807
1808     e.initialize_entity = func;
1809     e.initialize_entity_order = order;
1810
1811     cur = initialize_entity_first;
1812     for (;;)
1813     {
1814         if (!cur || cur.initialize_entity_order > order)
1815         {
1816             // insert between prev and cur
1817             if (prev)
1818                 prev.initialize_entity_next = e;
1819             else
1820                 initialize_entity_first = e;
1821             e.initialize_entity_next = cur;
1822             return;
1823         }
1824         prev = cur;
1825         cur = cur.initialize_entity_next;
1826     }
1827 }
1828 void InitializeEntitiesRun()
1829 {
1830     entity startoflist;
1831     startoflist = initialize_entity_first;
1832     initialize_entity_first = world;
1833     for (self = startoflist; self; )
1834     {
1835         entity e;
1836         var void(void) func;
1837         e = self.initialize_entity_next;
1838         func = self.initialize_entity;
1839         self.initialize_entity_order = 0;
1840         self.initialize_entity = func_null;
1841         self.initialize_entity_next = world;
1842         if (self.classname == "initialize_entity")
1843         {
1844             entity e_old;
1845             e_old = self.enemy;
1846             remove_builtin(self);
1847             self = e_old;
1848         }
1849         //dprint("Delayed initialization: ", self.classname, "\n");
1850         func();
1851         self = e;
1852     }
1853 }
1854
1855 .float uncustomizeentityforclient_set;
1856 .void(void) uncustomizeentityforclient;
1857 void(void) SUB_Nullpointer = #0;
1858 void UncustomizeEntitiesRun()
1859 {
1860     entity oldself;
1861     oldself = self;
1862     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1863         self.uncustomizeentityforclient();
1864     self = oldself;
1865 }
1866 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1867 {
1868     e.customizeentityforclient = customizer;
1869     e.uncustomizeentityforclient = uncustomizer;
1870     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1871 }
1872
1873 .float nottargeted;
1874 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1875
1876 void() SUB_Remove;
1877 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1878 {
1879     vector mi, ma;
1880
1881     if (e.classname == "")
1882         e.classname = "net_linked";
1883
1884     if (e.model == "" || self.modelindex == 0)
1885     {
1886         mi = e.mins;
1887         ma = e.maxs;
1888         setmodel(e, "null");
1889         setsize(e, mi, ma);
1890     }
1891
1892     e.SendEntity = sendfunc;
1893     e.SendFlags = 0xFFFFFF;
1894
1895     if (!docull)
1896         e.effects |= EF_NODEPTHTEST;
1897
1898     if (dt)
1899     {
1900         e.nextthink = time + dt;
1901         e.think = SUB_Remove;
1902     }
1903 }
1904
1905 void adaptor_think2touch()
1906 {
1907     entity o;
1908     o = other;
1909     other = world;
1910     self.touch();
1911     other = o;
1912 }
1913
1914 void adaptor_think2use()
1915 {
1916     entity o, a;
1917     o = other;
1918     a = activator;
1919     activator = world;
1920     other = world;
1921     self.use();
1922     other = o;
1923     activator = a;
1924 }
1925
1926 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1927 {
1928         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1929                 self.projectiledeathtype |= HITTYPE_SPLASH;
1930         adaptor_think2use();
1931 }
1932
1933 // deferred dropping
1934 void DropToFloor_Handler()
1935 {
1936     droptofloor_builtin();
1937     self.dropped_origin = self.origin;
1938 }
1939
1940 void droptofloor()
1941 {
1942     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1943 }
1944
1945
1946
1947 float trace_hits_box_a0, trace_hits_box_a1;
1948
1949 float trace_hits_box_1d(float end, float thmi, float thma)
1950 {
1951     if (end == 0)
1952     {
1953         // just check if x is in range
1954         if (0 < thmi)
1955             return FALSE;
1956         if (0 > thma)
1957             return FALSE;
1958     }
1959     else
1960     {
1961         // do the trace with respect to x
1962         // 0 -> end has to stay in thmi -> thma
1963         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1964         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1965         if (trace_hits_box_a0 > trace_hits_box_a1)
1966             return FALSE;
1967     }
1968     return TRUE;
1969 }
1970
1971 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1972 {
1973     end -= start;
1974     thmi -= start;
1975     thma -= start;
1976     // now it is a trace from 0 to end
1977
1978     trace_hits_box_a0 = 0;
1979     trace_hits_box_a1 = 1;
1980
1981     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1982         return FALSE;
1983     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1984         return FALSE;
1985     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1986         return FALSE;
1987
1988     return TRUE;
1989 }
1990
1991 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1992 {
1993     return trace_hits_box(start, end, thmi - ma, thma - mi);
1994 }
1995
1996 float SUB_NoImpactCheck()
1997 {
1998         // zero hitcontents = this is not the real impact, but either the
1999         // mirror-impact of something hitting the projectile instead of the
2000         // projectile hitting the something, or a touchareagrid one. Neither of
2001         // these stop the projectile from moving, so...
2002         if(trace_dphitcontents == 0)
2003         {
2004                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2005                 checkclient();
2006         }
2007     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2008         return 1;
2009     if (other == world && self.size != '0 0 0')
2010     {
2011         vector tic;
2012         tic = self.velocity * sys_frametime;
2013         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2014         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2015         if (trace_fraction >= 1)
2016         {
2017             dprint("Odd... did not hit...?\n");
2018         }
2019         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2020         {
2021             dprint("Detected and prevented the sky-grapple bug.\n");
2022             return 1;
2023         }
2024     }
2025
2026     return 0;
2027 }
2028
2029 #define SUB_OwnerCheck() (other && (other == self.owner))
2030
2031 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2032 {
2033         if(SUB_OwnerCheck())
2034                 return TRUE;
2035         if(SUB_NoImpactCheck())
2036         {
2037                 remove(self);
2038                 return TRUE;
2039         }
2040         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2041                 UpdateCSQCProjectileNextFrame(self);
2042         return FALSE;
2043 }
2044 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2045
2046 float MAX_IPBAN_URIS = 16;
2047
2048 float URI_GET_DISCARD   = 0;
2049 float URI_GET_IPBAN     = 1;
2050 float URI_GET_IPBAN_END = 16;
2051
2052 void URI_Get_Callback(float id, float status, string data)
2053 {
2054     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2055     dprint(data);
2056     dprint("\nEnd of data.\n");
2057
2058     if (id == URI_GET_DISCARD)
2059     {
2060         // discard
2061     }
2062     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2063     {
2064         // online ban list
2065         OnlineBanList_URI_Get_Callback(id, status, data);
2066     }
2067     else
2068     {
2069         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2070     }
2071 }
2072
2073 void print_to(entity e, string s)
2074 {
2075     if (e)
2076         sprint(e, strcat(s, "\n"));
2077     else
2078         print(s, "\n");
2079 }
2080
2081 string uid2name(string myuid) {
2082         string s;
2083         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2084
2085         if(s == "")
2086                 s = "^1Unregistered Player";
2087         return s;
2088 }
2089
2090 float race_readTime(string map, float pos)
2091 {
2092         string rr;
2093         if(g_cts)
2094                 rr = CTS_RECORD;
2095         else
2096                 rr = RACE_RECORD;
2097
2098         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2099 }
2100
2101 string race_readUID(string map, float pos)
2102 {
2103         string rr;
2104         if(g_cts)
2105                 rr = CTS_RECORD;
2106         else
2107                 rr = RACE_RECORD;
2108
2109         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2110 }
2111
2112 float race_readPos(string map, float t) {
2113         float i;
2114         for (i = 1; i <= RANKINGS_CNT; ++i)
2115                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2116                         return i;
2117
2118         return 0; // pos is zero if unranked
2119 }
2120
2121 void race_writeTime(string map, float t, string myuid)
2122 {
2123         string rr;
2124         if(g_cts)
2125                 rr = CTS_RECORD;
2126         else
2127                 rr = RACE_RECORD;
2128
2129         float newpos;
2130         newpos = race_readPos(map, t);
2131
2132         float i, prevpos;
2133         for(i = 1; i <= RANKINGS_CNT; ++i)
2134         {
2135                 if(race_readUID(map, i) == myuid)
2136                         prevpos = i;
2137         }
2138         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2139                 for (i = prevpos; i > newpos; --i) {
2140                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2141                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2142                 }
2143         } else { // player has no ranked record yet
2144                 for (i = RANKINGS_CNT; i > newpos; --i) {
2145                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2146                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2147                 }
2148         }
2149
2150         // store new time itself
2151         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2152         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2153 }
2154
2155 string race_readName(string map, float pos)
2156 {
2157         string rr;
2158         if(g_cts)
2159                 rr = CTS_RECORD;
2160         else
2161                 rr = RACE_RECORD;
2162
2163         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2164 }
2165
2166 string race_placeName(float pos) {
2167         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2168         {
2169                 if(mod(pos, 10) == 1)
2170                         return strcat(ftos(pos), "st");
2171                 else if(mod(pos, 10) == 2)
2172                         return strcat(ftos(pos), "nd");
2173                 else if(mod(pos, 10) == 3)
2174                         return strcat(ftos(pos), "rd");
2175                 else
2176                         return strcat(ftos(pos), "th");
2177         }
2178         else
2179                 return strcat(ftos(pos), "th");
2180 }
2181 string getrecords(float page) // 50 records per page
2182 {
2183     float rec;
2184     string h;
2185     float r;
2186     float i;
2187     string s;
2188
2189     rec = 0;
2190
2191     s = "";
2192
2193     if (g_ctf)
2194     {
2195         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2196         {
2197             if (MapInfo_Get_ByID(i))
2198             {
2199                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2200                 if (r == 0)
2201                     continue;
2202                 // TODO: uid2name
2203                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2204                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2205                 ++rec;
2206             }
2207         }
2208     }
2209
2210     if (g_race)
2211     {
2212         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2213         {
2214             if (MapInfo_Get_ByID(i))
2215             {
2216                 r = race_readTime(MapInfo_Map_bspname, 1);
2217                 if (r == 0)
2218                     continue;
2219                 h = race_readName(MapInfo_Map_bspname, 1);
2220                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2221                 ++rec;
2222             }
2223         }
2224     }
2225
2226     if (g_cts)
2227     {
2228         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2229         {
2230             if (MapInfo_Get_ByID(i))
2231             {
2232                 r = race_readTime(MapInfo_Map_bspname, 1);
2233                 if (r == 0)
2234                     continue;
2235                 h = race_readName(MapInfo_Map_bspname, 1);
2236                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2237                 ++rec;
2238             }
2239         }
2240     }
2241
2242     MapInfo_ClearTemps();
2243
2244     if (s == "" && page == 0)
2245         return "No records are available on this server.\n";
2246     else
2247         return s;
2248 }
2249
2250 string getrankings()
2251 {
2252     string n;
2253     float t;
2254     float i;
2255     string s;
2256     string p;
2257     string map;
2258
2259     s = "";
2260
2261     map = GetMapname();
2262
2263     for (i = 1; i <= RANKINGS_CNT; ++i)
2264     {
2265         t = race_readTime(map, i);
2266         if (t == 0)
2267             continue;
2268         n = race_readName(map, i);
2269         p = race_placeName(i);
2270         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2271     }
2272
2273     MapInfo_ClearTemps();
2274
2275     if (s == "")
2276         return strcat("No records are available for the map: ", map, "\n");
2277     else
2278         return strcat("Records for ", map, ":\n", s);
2279 }
2280
2281 #define LADDER_FIRSTPOINT 100
2282 #define LADDER_CNT 10
2283         // position X still gives LADDER_FIRSTPOINT/X points
2284 #define LADDER_SIZE 30
2285         // ladder shows the top X players
2286 string top_uids[LADDER_SIZE];
2287 float top_scores[LADDER_SIZE];
2288 string getladder()
2289 {
2290     float i, j, k, uidcnt;
2291     string s, temp_s;
2292
2293     s = "";
2294     temp_s = "";
2295
2296     string rr;
2297     if(g_cts)
2298         rr = CTS_RECORD;
2299     else
2300         rr = RACE_RECORD;
2301
2302     string myuid;
2303
2304     for (k = 0; k < MapInfo_count; ++k)
2305     {
2306         if (MapInfo_Get_ByID(k))
2307         {
2308                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2309                         if(i == 0) // speed award
2310                         {
2311                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2312                                         continue;
2313
2314                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2315                         }
2316                         else // normal record, if it exists (else break)
2317                         {
2318                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2319                                         continue;
2320
2321                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2322                         }
2323
2324                         // string s contains:
2325                         // arg 0 = # of speed recs
2326                         // arg 1 = # of 1st place recs
2327                         // arg 2 = # of 2nd place recs
2328                         // ... etc
2329                         // LADDER_CNT+1 = total points
2330
2331                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2332                         if (temp_s == "")
2333                         {
2334                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2335                             ++uidcnt;
2336                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2337                             {
2338                                 if(j != LADDER_CNT + 1)
2339                                     temp_s = strcat(temp_s, "0 ");
2340                                 else
2341                                     temp_s = strcat(temp_s, "0");
2342                             }
2343                         }
2344
2345                         tokenize_console(temp_s);
2346                         s = "";
2347
2348                         if(i == 0) // speed award
2349                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2350                             {
2351                                 if(j == 0) // speed award
2352                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2353                                 else
2354                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2355                             }
2356                         else // record
2357                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2358                             {
2359                                 if(j == 0)
2360                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2361                                 else if(j == i) // wanted rec!
2362                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2363                                 else
2364                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2365                             }
2366
2367                         // total points are (by default) calculated like this:
2368                         // speedrec = floor(100 / 10) = 10 points
2369                         // 1st place = floor(100 / 1) = 100 points
2370                         // 2nd place = floor(100 / 2) = 50 points
2371                         // 3rd place = floor(100 / 3) = 33 points
2372                         // 4th place = floor(100 / 4) = 25 points
2373                         // 5th place = floor(100 / 5) = 20 points
2374                         // ... etc
2375
2376                         if(i == 0)
2377                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2378                         else
2379                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2380
2381                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2382                 }
2383         }
2384     }
2385
2386     float thiscnt;
2387     string thisuid;
2388     for (i = 0; i <= uidcnt; ++i) // for each known uid
2389     {
2390         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2391         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2392         tokenize_console(temp_s);
2393         thiscnt = stof(argv(LADDER_CNT+1));
2394
2395         if(thiscnt > top_scores[LADDER_SIZE-1])
2396         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2397         {
2398             if(thiscnt > top_scores[j])
2399             {
2400                 for (k = LADDER_SIZE-1; k >= j; --k)
2401                 {
2402                     top_uids[k] = top_uids[k-1];
2403                     top_scores[k] = top_scores[k-1];
2404                 }
2405                 top_uids[j] = thisuid;
2406                 top_scores[j] = thiscnt;
2407                 break;
2408             }
2409         }
2410     }
2411
2412     s = "^3-----------------------\n\n";
2413
2414     s = strcat(s, "Pos ^3|");
2415     s = strcat(s, " ^7Total  ^3|");
2416     for (i = 1; i <= LADDER_CNT; ++i)
2417     {
2418         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2419     }
2420     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2421
2422     s = strcat(s, "\n^3----+--------");
2423     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2424     {
2425         s = strcat(s, "+-----");
2426     }
2427 #if LADDER_CNT > 9
2428     for (i = 1; i <= LADDER_CNT - 9; ++i)
2429     {
2430         s = strcat(s, "+------");
2431     }
2432 #endif
2433
2434     s = strcat(s, "+--------------+--------------------\n");
2435
2436     for (i = 0; i < LADDER_SIZE; ++i)
2437     {
2438         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2439         tokenize_console(temp_s);
2440         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2441             continue;
2442         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2443         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2444         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2445         {
2446             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2447         }
2448 #if LADDER_CNT > 9
2449         for (j = 10; j <= LADDER_CNT; ++j)
2450         {
2451             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2452         }
2453 #endif
2454
2455         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2456         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2457     }
2458
2459     MapInfo_ClearTemps();
2460
2461     if (s == "")
2462         return "No ladder on this server!\n";
2463     else
2464         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2465 }
2466
2467
2468 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2469 {
2470     float m, i;
2471     vector start, org, delta, end, enddown, mstart;
2472
2473     m = e.dphitcontentsmask;
2474     e.dphitcontentsmask = goodcontents | badcontents;
2475
2476     org = world.mins;
2477     delta = world.maxs - world.mins;
2478
2479     for (i = 0; i < attempts; ++i)
2480     {
2481         start_x = org_x + random() * delta_x;
2482         start_y = org_y + random() * delta_y;
2483         start_z = org_z + random() * delta_z;
2484
2485         // rule 1: start inside world bounds, and outside
2486         // solid, and don't start from somewhere where you can
2487         // fall down to evil
2488         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2489         if (trace_fraction >= 1)
2490             continue;
2491         if (trace_startsolid)
2492             continue;
2493         if (trace_dphitcontents & badcontents)
2494             continue;
2495         if (trace_dphitq3surfaceflags & badsurfaceflags)
2496             continue;
2497
2498         // rule 2: if we are too high, lower the point
2499         if (trace_fraction * delta_z > maxaboveground)
2500             start = trace_endpos + '0 0 1' * maxaboveground;
2501         enddown = trace_endpos;
2502
2503         // rule 3: make sure we aren't outside the map. This only works
2504         // for somewhat well formed maps. A good rule of thumb is that
2505         // the map should have a convex outside hull.
2506         // these can be traceLINES as we already verified the starting box
2507         mstart = start + 0.5 * (e.mins + e.maxs);
2508         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2509         if (trace_fraction >= 1)
2510             continue;
2511         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2512         if (trace_fraction >= 1)
2513             continue;
2514         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523
2524         // find a random vector to "look at"
2525         end_x = org_x + random() * delta_x;
2526         end_y = org_y + random() * delta_y;
2527         end_z = org_z + random() * delta_z;
2528         end = start + normalize(end - start) * vlen(delta);
2529
2530         // rule 4: start TO end must not be too short
2531         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2532         if (trace_startsolid)
2533             continue;
2534         if (trace_fraction < minviewdistance / vlen(delta))
2535             continue;
2536
2537         // rule 5: don't want to look at sky
2538         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2539             continue;
2540
2541         // rule 6: we must not end up in trigger_hurt
2542         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2543         {
2544             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2545             continue;
2546         }
2547
2548         break;
2549     }
2550
2551     e.dphitcontentsmask = m;
2552
2553     if (i < attempts)
2554     {
2555         setorigin(e, start);
2556         e.angles = vectoangles(end - start);
2557         dprint("Needed ", ftos(i + 1), " attempts\n");
2558         return TRUE;
2559     }
2560     else
2561         return FALSE;
2562 }
2563
2564 float zcurveparticles_effectno;
2565 vector zcurveparticles_start;
2566 float zcurveparticles_spd;
2567
2568 void endzcurveparticles()
2569 {
2570         if(zcurveparticles_effectno)
2571         {
2572                 // terminator
2573                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2574         }
2575         zcurveparticles_effectno = 0;
2576 }
2577
2578 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2579 {
2580         spd = bound(0, floor(spd / 16), 32767);
2581         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2582         {
2583                 endzcurveparticles();
2584                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2585                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2586                 WriteShort(MSG_BROADCAST, effectno);
2587                 WriteCoord(MSG_BROADCAST, start_x);
2588                 WriteCoord(MSG_BROADCAST, start_y);
2589                 WriteCoord(MSG_BROADCAST, start_z);
2590                 zcurveparticles_effectno = effectno;
2591                 zcurveparticles_start = start;
2592         }
2593         else
2594                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2595         WriteCoord(MSG_BROADCAST, end_x);
2596         WriteCoord(MSG_BROADCAST, end_y);
2597         WriteCoord(MSG_BROADCAST, end_z);
2598         WriteCoord(MSG_BROADCAST, end_dz);
2599         zcurveparticles_spd = spd;
2600 }
2601
2602 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2603 {
2604         float end_dz;
2605         vector vecxy, velxy;
2606
2607         vecxy = end - start;
2608         vecxy_z = 0;
2609         velxy = vel;
2610         velxy_z = 0;
2611
2612         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2613         {
2614                 endzcurveparticles();
2615                 trailparticles(world, effectno, start, end);
2616                 return;
2617         }
2618
2619         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2620         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2621 }
2622
2623 string GetGametype(); // g_world.qc
2624 void write_recordmarker(entity pl, float tstart, float dt)
2625 {
2626     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2627
2628     // also write a marker into demo files for demotc-race-record-extractor to find
2629     stuffcmd(pl,
2630              strcat(
2631                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2632                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2633 }
2634
2635 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2636 {
2637         switch(algn)
2638         {
2639                 case 1: // right
2640                         break;
2641
2642                 case 2: // left
2643                         vecs_y = -vecs_y;
2644                         break;
2645
2646                 default:
2647                 case 3:
2648                         if(allowcenter) // 2: allow center handedness
2649                         {
2650                                 // center
2651                                 vecs_y = 0;
2652                                 vecs_z -= 2;
2653                         }
2654                         else
2655                         {
2656                                 // right
2657                         }
2658                         break;
2659
2660                 case 4:
2661                         if(allowcenter) // 2: allow center handedness
2662                         {
2663                                 // center
2664                                 vecs_y = 0;
2665                                 vecs_z -= 2;
2666                         }
2667                         else
2668                         {
2669                                 // left
2670                                 vecs_y = -vecs_y;
2671                         }
2672                         break;
2673         }
2674         return vecs;
2675 }
2676
2677 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2678 {
2679         string s;
2680         vector v;
2681
2682         if (cvar("g_shootfromeye"))
2683         {
2684                 if (visual)
2685                 {
2686                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2687                 }
2688                 else
2689                 {
2690                         vecs_y = 0;
2691                         vecs_z = 0;
2692                 }
2693         }
2694         else if (cvar("g_shootfromcenter"))
2695         {
2696                 if (visual)
2697                 {
2698                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2699                 }
2700                 else
2701                 {
2702                         vecs_y = 0;
2703                         vecs_z -= 2;
2704                 }
2705         }
2706         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2707         {
2708                 v = stov(s);
2709                 if (y_is_right)
2710                         v_y = -v_y;
2711                 if (v_x != 0)
2712                         vecs_x = v_x;
2713                 vecs_y = v_y;
2714                 vecs_z = v_z;
2715         }
2716         else if (cvar("g_shootfromclient"))
2717         {
2718                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2), algn);
2719         }
2720         return vecs;
2721 }
2722
2723 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2724 {
2725         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2726 }
2727
2728
2729 void attach_sameorigin(entity e, entity to, string tag)
2730 {
2731     vector org, t_forward, t_left, t_up, e_forward, e_up;
2732     vector org0, ang0;
2733     float tagscale;
2734
2735     ang0 = e.angles;
2736     org0 = e.origin;
2737
2738     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2739     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2740     t_forward = v_forward * tagscale;
2741     t_left = v_right * -tagscale;
2742     t_up = v_up * tagscale;
2743
2744     e.origin_x = org * t_forward;
2745     e.origin_y = org * t_left;
2746     e.origin_z = org * t_up;
2747
2748     // current forward and up directions
2749     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2750                 e.angles = AnglesTransform_FromVAngles(e.angles);
2751         else
2752                 e.angles = AnglesTransform_FromAngles(e.angles);
2753     fixedmakevectors(e.angles);
2754
2755     // untransform forward, up!
2756     e_forward_x = v_forward * t_forward;
2757     e_forward_y = v_forward * t_left;
2758     e_forward_z = v_forward * t_up;
2759     e_up_x = v_up * t_forward;
2760     e_up_y = v_up * t_left;
2761     e_up_z = v_up * t_up;
2762
2763     e.angles = fixedvectoangles2(e_forward, e_up);
2764     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2765                 e.angles = AnglesTransform_ToVAngles(e.angles);
2766         else
2767                 e.angles = AnglesTransform_ToAngles(e.angles);
2768
2769     setattachment(e, to, tag);
2770     setorigin(e, e.origin);
2771 }
2772
2773 void detach_sameorigin(entity e)
2774 {
2775     vector org;
2776     org = gettaginfo(e, 0);
2777     e.angles = fixedvectoangles2(v_forward, v_up);
2778     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2779                 e.angles = AnglesTransform_ToVAngles(e.angles);
2780         else
2781                 e.angles = AnglesTransform_ToAngles(e.angles);
2782     setorigin(e, org);
2783     setattachment(e, world, "");
2784     setorigin(e, e.origin);
2785 }
2786
2787 void follow_sameorigin(entity e, entity to)
2788 {
2789     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2790     e.aiment = to; // make the hole follow bmodel
2791     e.punchangle = to.angles; // the original angles of bmodel
2792     e.view_ofs = e.origin - to.origin; // relative origin
2793     e.v_angle = e.angles - to.angles; // relative angles
2794 }
2795
2796 void unfollow_sameorigin(entity e)
2797 {
2798     e.movetype = MOVETYPE_NONE;
2799 }
2800
2801 entity gettaginfo_relative_ent;
2802 vector gettaginfo_relative(entity e, float tag)
2803 {
2804     if (!gettaginfo_relative_ent)
2805     {
2806         gettaginfo_relative_ent = spawn();
2807         gettaginfo_relative_ent.effects = EF_NODRAW;
2808     }
2809     gettaginfo_relative_ent.model = e.model;
2810     gettaginfo_relative_ent.modelindex = e.modelindex;
2811     gettaginfo_relative_ent.frame = e.frame;
2812     return gettaginfo(gettaginfo_relative_ent, tag);
2813 }
2814
2815 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2816 {
2817     float p;
2818     p = pow(2, chan);
2819     if (pl.soundentity.cnt & p)
2820         return;
2821     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2822     pl.soundentity.cnt |= p;
2823 }
2824
2825 void SoundEntity_StopSound(entity pl, float chan)
2826 {
2827     float p;
2828     p = pow(2, chan);
2829     if (pl.soundentity.cnt & p)
2830     {
2831         stopsoundto(MSG_ALL, pl.soundentity, chan);
2832         pl.soundentity.cnt &~= p;
2833     }
2834 }
2835
2836 void SoundEntity_Attach(entity pl)
2837 {
2838     pl.soundentity = spawn();
2839     pl.soundentity.classname = "soundentity";
2840     pl.soundentity.owner = pl;
2841     setattachment(pl.soundentity, pl, "");
2842     setmodel(pl.soundentity, "null");
2843 }
2844
2845 void SoundEntity_Detach(entity pl)
2846 {
2847     float i;
2848     for (i = 0; i <= 7; ++i)
2849         SoundEntity_StopSound(pl, i);
2850 }
2851
2852
2853 float ParseCommandPlayerSlotTarget_firsttoken;
2854 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2855 {
2856     string s;
2857     entity e, head;
2858     float n;
2859
2860     s = string_null;
2861
2862     ParseCommandPlayerSlotTarget_firsttoken = -1;
2863
2864     if (tokens > idx)
2865     {
2866         if (substring(argv(idx), 0, 1) == "#")
2867         {
2868             s = substring(argv(idx), 1, -1);
2869             ++idx;
2870             if (s == "")
2871                 if (tokens > idx)
2872                 {
2873                     s = argv(idx);
2874                     ++idx;
2875                 }
2876                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2877             if (s == ftos(stof(s)))
2878             {
2879                 e = edict_num(stof(s));
2880                 if (e.flags & FL_CLIENT)
2881                     return e;
2882             }
2883         }
2884         else
2885         {
2886             // it must be a nick name
2887             s = argv(idx);
2888             ++idx;
2889                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2890
2891             n = 0;
2892             FOR_EACH_CLIENT(head)
2893             if (head.netname == s)
2894             {
2895                 e = head;
2896                 ++n;
2897             }
2898             if (n == 1)
2899                 return e;
2900
2901             s = strdecolorize(s);
2902             n = 0;
2903             FOR_EACH_CLIENT(head)
2904             if (strdecolorize(head.netname) == s)
2905             {
2906                 e = head;
2907                 ++n;
2908             }
2909             if (n == 1)
2910                 return e;
2911         }
2912     }
2913
2914     return world;
2915 }
2916
2917 .float scale2;
2918
2919 float modeleffect_SendEntity(entity to, float sf)
2920 {
2921         float f;
2922         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2923
2924         f = 0;
2925         if(self.velocity != '0 0 0')
2926                 f |= 1;
2927         if(self.angles != '0 0 0')
2928                 f |= 2;
2929         if(self.avelocity != '0 0 0')
2930                 f |= 4;
2931
2932         WriteByte(MSG_ENTITY, f);
2933         WriteShort(MSG_ENTITY, self.modelindex);
2934         WriteByte(MSG_ENTITY, self.skin);
2935         WriteByte(MSG_ENTITY, self.frame);
2936         WriteCoord(MSG_ENTITY, self.origin_x);
2937         WriteCoord(MSG_ENTITY, self.origin_y);
2938         WriteCoord(MSG_ENTITY, self.origin_z);
2939         if(f & 1)
2940         {
2941                 WriteCoord(MSG_ENTITY, self.velocity_x);
2942                 WriteCoord(MSG_ENTITY, self.velocity_y);
2943                 WriteCoord(MSG_ENTITY, self.velocity_z);
2944         }
2945         if(f & 2)
2946         {
2947                 WriteCoord(MSG_ENTITY, self.angles_x);
2948                 WriteCoord(MSG_ENTITY, self.angles_y);
2949                 WriteCoord(MSG_ENTITY, self.angles_z);
2950         }
2951         if(f & 4)
2952         {
2953                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2954                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2955                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2956         }
2957         WriteShort(MSG_ENTITY, self.scale * 256.0);
2958         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2959         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2960         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2961         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2962
2963         return TRUE;
2964 }
2965
2966 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2967 {
2968         entity e;
2969         float sz;
2970         e = spawn();
2971         e.classname = "modeleffect";
2972         setmodel(e, m);
2973         e.frame = f;
2974         setorigin(e, o);
2975         e.velocity = v;
2976         e.angles = ang;
2977         e.avelocity = angv;
2978         e.alpha = a;
2979         e.teleport_time = t1;
2980         e.fade_time = t2;
2981         e.skin = s;
2982         if(s0 >= 0)
2983                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2984         else
2985                 e.scale = -s0;
2986         if(s2 >= 0)
2987                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2988         else
2989                 e.scale2 = -s2;
2990         sz = max(e.scale, e.scale2);
2991         setsize(e, e.mins * sz, e.maxs * sz);
2992         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2993 }
2994
2995 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2996 {
2997         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2998 }
2999
3000 float randombit(float bits)
3001 {
3002         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3003                 return bits;
3004
3005         float n, f, b, r;
3006
3007         r = random();
3008         b = 0;
3009         n = 0;
3010
3011         for(f = 1; f <= bits; f *= 2)
3012         {
3013                 if(bits & f)
3014                 {
3015                         ++n;
3016                         r *= n;
3017                         if(r <= 1)
3018                                 b = f;
3019                         else
3020                                 r = (r - 1) / (n - 1);
3021                 }
3022         }
3023
3024         return b;
3025 }
3026
3027 float randombits(float bits, float k, float error_return)
3028 {
3029         float r;
3030         r = 0;
3031         while(k > 0 && bits != r)
3032         {
3033                 r += randombit(bits - r);
3034                 --k;
3035         }
3036         if(error_return)
3037                 if(k > 0)
3038                         return -1; // all
3039         return r;
3040 }
3041
3042 void randombit_test(float bits, float iter)
3043 {
3044         while(iter > 0)
3045         {
3046                 print(ftos(randombit(bits)), "\n");
3047                 --iter;
3048         }
3049 }
3050
3051 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3052 {
3053         if(halflifedist > 0)
3054                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3055         else if(halflifedist < 0)
3056                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3057         else
3058                 return 1;
3059 }
3060
3061
3062
3063
3064 #ifdef RELEASE
3065 #define cvar_string_normal cvar_string_builtin
3066 #define cvar_normal cvar_builtin
3067 #else
3068 string cvar_string_normal(string n)
3069 {
3070         if not(cvar_type(n) & 1)
3071                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3072         return cvar_string_builtin(n);
3073 }
3074
3075 float cvar_normal(string n)
3076 {
3077         return stof(cvar_string_normal(n));
3078 }
3079 #endif
3080 #define cvar_set_normal cvar_set_builtin
3081
3082 void defer_think()
3083 {
3084     entity oself;
3085
3086     oself           = self;
3087     self            = self.owner;
3088     oself.think     = SUB_Remove;
3089     oself.nextthink = time;
3090
3091     oself.use();
3092 }
3093
3094 /*
3095     Execute func() after time + fdelay.
3096     self when func is executed = self when defer is called
3097 */
3098 void defer(float fdelay, void() func)
3099 {
3100     entity e;
3101
3102     e           = spawn();
3103     e.owner     = self;
3104     e.use       = func;
3105     e.think     = defer_think;
3106     e.nextthink = time + fdelay;
3107 }