qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239     have_team_spawns_forteam[self.team] = 1;
 240
 241     if (autocvar_r_showbboxes)
 242     {
 243         // show where spawnpoints point at too
 244         makevectors(self.angles);
 245         entity e;
 246         e = spawn();
 247         e.classname = "info_player_foo";
 248         setorigin(e, self.origin + v_forward * 24);
 249         setsize(e, '-8 -8 -8', '8 8 8');
 250         e.solid = SOLID_TRIGGER;
 251     }
 252 }
 253
 254 #define strstr strstrofs
 255 /*
 256 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 257 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 258 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 259 // BE CONSTANT OR strzoneD!
 260 float strstr(string haystack, string needle, float offset)
 261 {
 262         float len, endpos;
 263         string found;
 264         len = strlen(needle);
 265         endpos = strlen(haystack) - len;
 266         while(offset <= endpos)
 267         {
 268                 found = substring(haystack, offset, len);
 269                 if(found == needle)
 270                         return offset;
 271                 offset = offset + 1;
 272         }
 273         return -1;
 274 }
 275 */
 276
 277 float NUM_NEAREST_ENTITIES = 4;
 278 entity nearest_entity[NUM_NEAREST_ENTITIES];
 279 float nearest_length[NUM_NEAREST_ENTITIES];
 280 entity findnearest(vector point, .string field, string value, vector axismod)
 281 {
 282     entity localhead;
 283     float i;
 284     float j;
 285     float len;
 286     vector dist;
 287
 288     float num_nearest;
 289     num_nearest = 0;
 290
 291     localhead = find(world, field, value);
 292     while (localhead)
 293     {
 294         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 295             dist = localhead.oldorigin;
 296         else
 297             dist = localhead.origin;
 298         dist = dist - point;
 299         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 300         len = vlen(dist);
 301
 302         for (i = 0; i < num_nearest; ++i)
 303         {
 304             if (len < nearest_length[i])
 305                 break;
 306         }
 307
 308         // now i tells us where to insert at
 309         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 310         if (i < NUM_NEAREST_ENTITIES)
 311         {
 312             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 313             {
 314                 nearest_length[j + 1] = nearest_length[j];
 315                 nearest_entity[j + 1] = nearest_entity[j];
 316             }
 317             nearest_length[i] = len;
 318             nearest_entity[i] = localhead;
 319             if (num_nearest < NUM_NEAREST_ENTITIES)
 320                 num_nearest = num_nearest + 1;
 321         }
 322
 323         localhead = find(localhead, field, value);
 324     }
 325
 326     // now use the first one from our list that we can see
 327     for (i = 0; i < num_nearest; ++i)
 328     {
 329         traceline(point, nearest_entity[i].origin, TRUE, world);
 330         if (trace_fraction == 1)
 331         {
 332             if (i != 0)
 333             {
 334                 dprint("Nearest point (");
 335                 dprint(nearest_entity[0].netname);
 336                 dprint(") is not visible, using a visible one.\n");
 337             }
 338             return nearest_entity[i];
 339         }
 340     }
 341
 342     if (num_nearest == 0)
 343         return world;
 344
 345     dprint("Not seeing any location point, using nearest as fallback.\n");
 346     /* DEBUGGING CODE:
 347     dprint("Candidates were: ");
 348     for(j = 0; j < num_nearest; ++j)
 349     {
 350         if(j != 0)
 351                 dprint(", ");
 352         dprint(nearest_entity[j].netname);
 353     }
 354     dprint("\n");
 355     */
 356
 357     return nearest_entity[0];
 358 }
 359
 360 void spawnfunc_target_location()
 361 {
 362     self.classname = "target_location";
 363     // location name in netname
 364     // eventually support: count, teamgame selectors, line of sight?
 365 };
 366
 367 void spawnfunc_info_location()
 368 {
 369     self.classname = "target_location";
 370     self.message = self.netname;
 371 };
 372
 373 string NearestLocation(vector p)
 374 {
 375     entity loc;
 376     string ret;
 377     ret = "somewhere";
 378     loc = findnearest(p, classname, "target_location", '1 1 1');
 379     if (loc)
 380     {
 381         ret = loc.message;
 382     }
 383     else
 384     {
 385         loc = findnearest(p, target, "###item###", '1 1 4');
 386         if (loc)
 387             ret = loc.netname;
 388     }
 389     return ret;
 390 }
 391
 392 string formatmessage(string msg)
 393 {
 394         float p, p1, p2;
 395         float n;
 396         vector cursor;
 397         entity cursor_ent;
 398         string escape;
 399         string replacement;
 400         p = 0;
 401         n = 7;
 402
 403         WarpZone_crosshair_trace(self);
 404         cursor = trace_endpos;
 405         cursor_ent = trace_ent;
 406
 407         while (1) {
 408                 if (n < 1)
 409                         break; // too many replacements
 410
 411                 n = n - 1;
 412                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 413                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 414
 415                 if (p1 < 0)
 416                         p1 = p2;
 417
 418                 if (p2 < 0)
 419                         p2 = p1;
 420
 421                 p = min(p1, p2);
 422
 423                 if (p < 0)
 424                         break;
 425
 426                 replacement = substring(msg, p, 2);
 427                 escape = substring(msg, p + 1, 1);
 428
 429                 if (escape == "%")
 430                         replacement = "%";
 431                 else if (escape == "\\")
 432                         replacement = "\\";
 433                 else if (escape == "n")
 434                         replacement = "\n";
 435                 else if (escape == "a")
 436                         replacement = ftos(floor(self.armorvalue));
 437                 else if (escape == "h")
 438                         replacement = ftos(floor(self.health));
 439                 else if (escape == "l")
 440                         replacement = NearestLocation(self.origin);
 441                 else if (escape == "y")
 442                         replacement = NearestLocation(cursor);
 443                 else if (escape == "d")
 444                         replacement = NearestLocation(self.death_origin);
 445                 else if (escape == "w") {
 446                         float wep;
 447                         wep = self.weapon;
 448                         if (!wep)
 449                                 wep = self.switchweapon;
 450                         if (!wep)
 451                                 wep = self.cnt;
 452                         replacement = W_Name(wep);
 453                 } else if (escape == "W") {
 454                         if (self.items & IT_SHELLS) replacement = "shells";
 455                         else if (self.items & IT_NAILS) replacement = "bullets";
 456                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 457                         else if (self.items & IT_CELLS) replacement = "cells";
 458                         else replacement = "batteries"; // ;)
 459                 } else if (escape == "x") {
 460                         replacement = cursor_ent.netname;
 461                         if (!replacement || !cursor_ent)
 462                                 replacement = "nothing";
 463                 } else if (escape == "s")
 464                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 465                 else if (escape == "S")
 466                         replacement = ftos(vlen(self.velocity));
 467
 468                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 469                 p = p + strlen(replacement);
 470         }
 471         return msg;
 472 }
 473
 474 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 475         return (value == 0) ? FALSE : TRUE;
 476 }
 477
 478 /*
 479 =============
 480 GetCvars
 481 =============
 482 Called with:
 483   0:  sends the request
 484   >0: receives a cvar from name=argv(f) value=argv(f+1)
 485 */
 486 void GetCvars_handleString(string thisname, float f, .string field, string name)
 487 {
 488         if (f < 0)
 489         {
 490                 if (self.field)
 491                         strunzone(self.field);
 492                 self.field = string_null;
 493         }
 494         else if (f > 0)
 495         {
 496                 if (thisname == name)
 497                 {
 498                         if (self.field)
 499                                 strunzone(self.field);
 500                         self.field = strzone(argv(f + 1));
 501                 }
 502         }
 503         else
 504                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 505 }
 506 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 507 {
 508         GetCvars_handleString(thisname, f, field, name);
 509         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 510                 if (thisname == name)
 511                 {
 512                         string s;
 513                         s = func(strcat1(self.field));
 514                         if (s != self.field)
 515                         {
 516                                 strunzone(self.field);
 517                                 self.field = strzone(s);
 518                         }
 519                 }
 520 }
 521 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 522 {
 523         if (f < 0)
 524         {
 525         }
 526         else if (f > 0)
 527         {
 528                 if (thisname == name)
 529                         self.field = stof(argv(f + 1));
 530         }
 531         else
 532                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 533 }
 534 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 535 {
 536         if (f < 0)
 537         {
 538         }
 539         else if (f > 0)
 540         {
 541                 if (thisname == name)
 542                 {
 543                         if(!self.field)
 544                         {
 545                                 self.field = stof(argv(f + 1));
 546                                 if(!self.field)
 547                                         self.field = -1;
 548                         }
 549                 }
 550         }
 551         else
 552         {
 553                 if(!self.field)
 554                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 555         }
 556 }
 557 float w_getbestweapon(entity e);
 558 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 559 {
 560         string o;
 561         o = W_FixWeaponOrder_ForceComplete(wo);
 562         if(self.weaponorder_byimpulse)
 563         {
 564                 strunzone(self.weaponorder_byimpulse);
 565                 self.weaponorder_byimpulse = string_null;
 566         }
 567         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 568         return o;
 569 }
 570 void GetCvars(float f)
 571 {
 572         string s;
 573
 574         if (f > 0)
 575                 s = strcat1(argv(f));
 576
 577         get_cvars_f = f;
 578         get_cvars_s = s;
 579         MUTATOR_CALLHOOK(GetCvars);
 580         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 581         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 582         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 583         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 584         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 585         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 586         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 587         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 588         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 589         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 597         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 598         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 599         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 600         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 601         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 602         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 603
 604         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 605         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 606
 607 #ifdef ALLOW_FORCEMODELS
 608         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 609         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 610 #endif
 611         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 612         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 613         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 614
 615         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 616         if (f > 0)
 617         {
 618                 if (s == "cl_weaponpriority")
 619                         self.switchweapon = w_getbestweapon(self);
 620                 if (s == "cl_allow_uidtracking")
 621                         PlayerStats_AddPlayer(self);
 622         }
 623 }
 624
 625 void backtrace(string msg)
 626 {
 627     float dev, war;
 628     dev = autocvar_developer;
 629     war = autocvar_prvm_backtraceforwarnings;
 630     cvar_set("developer", "1");
 631     cvar_set("prvm_backtraceforwarnings", "1");
 632     print("\n");
 633     print("--- CUT HERE ---\nWARNING: ");
 634     print(msg);
 635     print("\n");
 636     remove(world); // isn't there any better way to cause a backtrace?
 637     print("\n--- CUT UNTIL HERE ---\n");
 638     cvar_set("developer", ftos(dev));
 639     cvar_set("prvm_backtraceforwarnings", ftos(war));
 640 }
 641
 642 string Team_ColorCode(float teamid)
 643 {
 644     if (teamid == COLOR_TEAM1)
 645         return "^1";
 646     else if (teamid == COLOR_TEAM2)
 647         return "^4";
 648     else if (teamid == COLOR_TEAM3)
 649         return "^3";
 650     else if (teamid == COLOR_TEAM4)
 651         return "^6";
 652     else
 653         return "^7";
 654 }
 655
 656 string Team_ColorName(float t)
 657 {
 658     // fixme: Search for team entities and get their .netname's!
 659     if (t == COLOR_TEAM1)
 660         return "Red";
 661     if (t == COLOR_TEAM2)
 662         return "Blue";
 663     if (t == COLOR_TEAM3)
 664         return "Yellow";
 665     if (t == COLOR_TEAM4)
 666         return "Pink";
 667     return "Neutral";
 668 }
 669
 670 string Team_ColorNameLowerCase(float t)
 671 {
 672     // fixme: Search for team entities and get their .netname's!
 673     if (t == COLOR_TEAM1)
 674         return "red";
 675     if (t == COLOR_TEAM2)
 676         return "blue";
 677     if (t == COLOR_TEAM3)
 678         return "yellow";
 679     if (t == COLOR_TEAM4)
 680         return "pink";
 681     return "neutral";
 682 }
 683
 684 float ColourToNumber(string team_colour)
 685 {
 686         if (team_colour == "red")
 687                 return COLOR_TEAM1;
 688
 689         if (team_colour == "blue")
 690                 return COLOR_TEAM2;
 691
 692         if (team_colour == "yellow")
 693                 return COLOR_TEAM3;
 694
 695         if (team_colour == "pink")
 696                 return COLOR_TEAM4;
 697
 698         if (team_colour == "auto")
 699                 return 0;
 700
 701         return -1;
 702 }
 703
 704 float NumberToTeamNumber(float number)
 705 {
 706         if (number == 1)
 707                 return COLOR_TEAM1;
 708
 709         if (number == 2)
 710                 return COLOR_TEAM2;
 711
 712         if (number == 3)
 713                 return COLOR_TEAM3;
 714
 715         if (number == 4)
 716                 return COLOR_TEAM4;
 717
 718         return -1;
 719 }
 720
 721 #define CENTERPRIO_POINT 1
 722 #define CENTERPRIO_SPAM 2
 723 #define CENTERPRIO_VOTE 4
 724 #define CENTERPRIO_NORMAL 5
 725 #define CENTERPRIO_SHIELDING 7
 726 #define CENTERPRIO_MAPVOTE 9
 727 #define CENTERPRIO_IDLEKICK 50
 728 #define CENTERPRIO_ADMIN 99
 729 .float centerprint_priority;
 730 .float centerprint_expires;
 731 void centerprint_atprio(entity e, float prio, string s)
 732 {
 733     if (intermission_running)
 734         if (prio < CENTERPRIO_MAPVOTE)
 735             return;
 736     if (time > e.centerprint_expires)
 737         e.centerprint_priority = 0;
 738     if (prio >= e.centerprint_priority)
 739     {
 740         e.centerprint_priority = prio;
 741         if (timeoutStatus == 2)
 742             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 743         else
 744             e.centerprint_expires = time + e.cvar_scr_centertime;
 745         centerprint_builtin(e, s);
 746     }
 747 }
 748 void centerprint_expire(entity e, float prio)
 749 {
 750     if (prio == e.centerprint_priority)
 751     {
 752         e.centerprint_priority = 0;
 753         centerprint_builtin(e, "");
 754     }
 755 }
 756 void centerprint(entity e, string s)
 757 {
 758     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 759 }
 760
 761 // decolorizes and team colors the player name when needed
 762 string playername(entity p)
 763 {
 764     string t;
 765     if (teamplay && !intermission_running && p.classname == "player")
 766     {
 767         t = Team_ColorCode(p.team);
 768         return strcat(t, strdecolorize(p.netname));
 769     }
 770     else
 771         return p.netname;
 772 }
 773
 774 vector randompos(vector m1, vector m2)
 775 {
 776     local vector v;
 777     m2 = m2 - m1;
 778     v_x = m2_x * random() + m1_x;
 779     v_y = m2_y * random() + m1_y;
 780     v_z = m2_z * random() + m1_z;
 781     return  v;
 782 };
 783
 784 //#NO AUTOCVARS START
 785
 786 float g_pickup_shells;
 787 float g_pickup_shells_max;
 788 float g_pickup_nails;
 789 float g_pickup_nails_max;
 790 float g_pickup_rockets;
 791 float g_pickup_rockets_max;
 792 float g_pickup_cells;
 793 float g_pickup_cells_max;
 794 float g_pickup_fuel;
 795 float g_pickup_fuel_jetpack;
 796 float g_pickup_fuel_max;
 797 float g_pickup_armorsmall;
 798 float g_pickup_armorsmall_max;
 799 float g_pickup_armorsmall_anyway;
 800 float g_pickup_armormedium;
 801 float g_pickup_armormedium_max;
 802 float g_pickup_armormedium_anyway;
 803 float g_pickup_armorbig;
 804 float g_pickup_armorbig_max;
 805 float g_pickup_armorbig_anyway;
 806 float g_pickup_armorlarge;
 807 float g_pickup_armorlarge_max;
 808 float g_pickup_armorlarge_anyway;
 809 float g_pickup_healthsmall;
 810 float g_pickup_healthsmall_max;
 811 float g_pickup_healthsmall_anyway;
 812 float g_pickup_healthmedium;
 813 float g_pickup_healthmedium_max;
 814 float g_pickup_healthmedium_anyway;
 815 float g_pickup_healthlarge;
 816 float g_pickup_healthlarge_max;
 817 float g_pickup_healthlarge_anyway;
 818 float g_pickup_healthmega;
 819 float g_pickup_healthmega_max;
 820 float g_pickup_healthmega_anyway;
 821 float g_pickup_ammo_anyway;
 822 float g_pickup_weapons_anyway;
 823 float g_weaponarena;
 824 float g_weaponarena_random;
 825 float g_weaponarena_random_with_laser;
 826 string g_weaponarena_list;
 827 float g_weaponspeedfactor;
 828 float g_weaponratefactor;
 829 float g_weapondamagefactor;
 830 float g_weaponforcefactor;
 831 float g_weaponspreadfactor;
 832
 833 float start_weapons;
 834 float start_items;
 835 float start_ammo_shells;
 836 float start_ammo_nails;
 837 float start_ammo_rockets;
 838 float start_ammo_cells;
 839 float start_ammo_fuel;
 840 float start_health;
 841 float start_armorvalue;
 842 float warmup_start_weapons;
 843 float warmup_start_ammo_shells;
 844 float warmup_start_ammo_nails;
 845 float warmup_start_ammo_rockets;
 846 float warmup_start_ammo_cells;
 847 float warmup_start_ammo_fuel;
 848 float warmup_start_health;
 849 float warmup_start_armorvalue;
 850 float g_weapon_stay;
 851 float g_ghost_items;
 852
 853 entity get_weaponinfo(float w);
 854
 855 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 856 {
 857         var float i = weaponinfo.weapon;
 858
 859         if (!i)
 860                 return 0;
 861
 862         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 863
 864         if (t < 0) // "default" weapon selection
 865         {
 866                 if (g_lms || g_ca || allguns)
 867                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 868                 else if(t < -1)
 869                         t = 0;
 870                 else if (g_cts)
 871                         t = (i == WEP_SHOTGUN);
 872                 else if (g_nexball)
 873                         t = 0; // weapon is set a few lines later
 874                 else
 875                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 876                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 877                         t |= (i == WEP_HOOK);
 878         }
 879
 880         // we cannot disable porto in Nexball, we must force it
 881         if(g_nexball && i == WEP_PORTO)
 882                 t = 1;
 883
 884         return t;
 885 }
 886
 887 void readplayerstartcvars()
 888 {
 889         entity e;
 890         float i, j, t;
 891         string s;
 892
 893         // initialize starting values for players
 894         start_weapons = 0;
 895         start_items = 0;
 896         start_ammo_shells = 0;
 897         start_ammo_nails = 0;
 898         start_ammo_rockets = 0;
 899         start_ammo_cells = 0;
 900         start_health = cvar("g_balance_health_start");
 901         start_armorvalue = cvar("g_balance_armor_start");
 902
 903         g_weaponarena = 0;
 904         s = cvar_string("g_weaponarena");
 905         if (s == "0" || s == "")
 906         {
 907                 if(g_lms || g_ca)
 908                         s = "most";
 909         }
 910
 911         if (s == "0" || s == "")
 912         {
 913                 // no arena
 914         }
 915         else if (s == "off")
 916         {
 917                 // forcibly turn off weaponarena
 918         }
 919         else if (s == "all")
 920         {
 921                 g_weaponarena_list = "All Weapons";
 922                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 923                 {
 924                         e = get_weaponinfo(j);
 925                         g_weaponarena |= e.weapons;
 926                         weapon_action(e.weapon, WR_PRECACHE);
 927                 }
 928         }
 929         else if (s == "most")
 930         {
 931                 g_weaponarena_list = "Most Weapons";
 932                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 933                 {
 934                         e = get_weaponinfo(j);
 935                         if (e.spawnflags & WEP_FLAG_NORMAL)
 936                         {
 937                                 g_weaponarena |= e.weapons;
 938                                 weapon_action(e.weapon, WR_PRECACHE);
 939                         }
 940                 }
 941         }
 942         else if (s == "none")
 943         {
 944                 g_weaponarena_list = "No Weapons";
 945                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 946         }
 947         else
 948         {
 949                 t = tokenize_console(s);
 950                 g_weaponarena_list = "";
 951                 for (i = 0; i < t; ++i)
 952                 {
 953                         s = argv(i);
 954                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 955                         {
 956                                 e = get_weaponinfo(j);
 957                                 if (e.netname == s)
 958                                 {
 959                                         g_weaponarena |= e.weapons;
 960                                         weapon_action(e.weapon, WR_PRECACHE);
 961                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 962                                         break;
 963                                 }
 964                         }
 965                         if (j > WEP_LAST)
 966                         {
 967                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 968                         }
 969                 }
 970                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 971         }
 972
 973         if(g_weaponarena)
 974                 g_weaponarena_random = cvar("g_weaponarena_random");
 975         else
 976                 g_weaponarena_random = 0;
 977         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 978
 979         if (g_weaponarena)
 980         {
 981                 start_weapons = g_weaponarena;
 982                 if(!(g_lms || g_ca))
 983                         start_items |= IT_UNLIMITED_AMMO;
 984         }
 985         else if (g_minstagib)
 986         {
 987                 start_health = 100;
 988                 start_armorvalue = 0;
 989                 start_weapons = WEPBIT_MINSTANEX;
 990                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 991                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 992
 993                 if (g_minstagib_invis_alpha <= 0)
 994                         g_minstagib_invis_alpha = -1;
 995         }
 996         else
 997         {
 998                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 999                 {
1000                         e = get_weaponinfo(i);
1001                         if(want_weapon("g_start_weapon_", e, FALSE))
1002                                 start_weapons |= e.weapons;
1003                 }
1004         }
1005
1006         if(!cvar("g_use_ammunition"))
1007                 start_items |= IT_UNLIMITED_AMMO;
1008
1009         if(g_minstagib)
1010         {
1011                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1012                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1013         }
1014         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
1015         {
1016                 start_ammo_rockets = 999;
1017                 start_ammo_shells = 999;
1018                 start_ammo_cells = 999;
1019                 start_ammo_nails = 999;
1020                 start_ammo_fuel = 999;
1021         }
1022         else
1023         {
1024                 if(g_lms || g_ca)
1025                 {
1026                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1027                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1028                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1029                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1030                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1031                 }
1032                 else
1033                 {
1034                         start_ammo_shells = cvar("g_start_ammo_shells");
1035                         start_ammo_nails = cvar("g_start_ammo_nails");
1036                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1037                         start_ammo_cells = cvar("g_start_ammo_cells");
1038                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1039                 }
1040         }
1041
1042         if (g_lms || g_ca)
1043         {
1044                 start_health = cvar("g_lms_start_health");
1045                 start_armorvalue = cvar("g_lms_start_armor");
1046         }
1047
1048         if (inWarmupStage)
1049         {
1050                 warmup_start_ammo_shells = start_ammo_shells;
1051                 warmup_start_ammo_nails = start_ammo_nails;
1052                 warmup_start_ammo_rockets = start_ammo_rockets;
1053                 warmup_start_ammo_cells = start_ammo_cells;
1054                 warmup_start_ammo_fuel = start_ammo_fuel;
1055                 warmup_start_health = start_health;
1056                 warmup_start_armorvalue = start_armorvalue;
1057                 warmup_start_weapons = start_weapons;
1058
1059                 if (!g_weaponarena && !g_minstagib && !g_ca)
1060                 {
1061                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1062                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1063                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1064                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1065                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1066                         warmup_start_health = cvar("g_warmup_start_health");
1067                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1068                         warmup_start_weapons = 0;
1069                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1070                         {
1071                                 e = get_weaponinfo(i);
1072                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1073                                         warmup_start_weapons |= e.weapons;
1074                         }
1075                 }
1076         }
1077
1078         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1079         {
1080                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1081                 start_items |= IT_FUEL_REGEN;
1082                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1083                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1084         }
1085
1086         if (g_jetpack)
1087                 start_items |= IT_JETPACK;
1088
1089         if (g_weapon_stay == 2)
1090         {
1091                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1092                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1093                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1094                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1095                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1096                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1097                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1098                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1099                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1100                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1101         }
1102
1103         MUTATOR_CALLHOOK(SetStartItems);
1104
1105         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1106         {
1107                 e = get_weaponinfo(i);
1108                 if(e.weapons & (start_weapons | warmup_start_weapons))
1109                         weapon_action(e.weapon, WR_PRECACHE);
1110         }
1111
1112         start_ammo_shells = max(0, start_ammo_shells);
1113         start_ammo_nails = max(0, start_ammo_nails);
1114         start_ammo_cells = max(0, start_ammo_cells);
1115         start_ammo_rockets = max(0, start_ammo_rockets);
1116         start_ammo_fuel = max(0, start_ammo_fuel);
1117
1118         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1119         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1120         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1121         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1122         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1123 }
1124
1125 float g_bugrigs;
1126 float g_bugrigs_planar_movement;
1127 float g_bugrigs_planar_movement_car_jumping;
1128 float g_bugrigs_reverse_spinning;
1129 float g_bugrigs_reverse_speeding;
1130 float g_bugrigs_reverse_stopping;
1131 float g_bugrigs_air_steering;
1132 float g_bugrigs_angle_smoothing;
1133 float g_bugrigs_friction_floor;
1134 float g_bugrigs_friction_brake;
1135 float g_bugrigs_friction_air;
1136 float g_bugrigs_accel;
1137 float g_bugrigs_speed_ref;
1138 float g_bugrigs_speed_pow;
1139 float g_bugrigs_steer;
1140
1141 float g_touchexplode;
1142 float g_touchexplode_radius;
1143 float g_touchexplode_damage;
1144 float g_touchexplode_edgedamage;
1145 float g_touchexplode_force;
1146
1147 float sv_autotaunt;
1148 float sv_taunt;
1149
1150 float sv_pitch_min;
1151 float sv_pitch_max;
1152 float sv_pitch_fixyaw;
1153
1154 string GetGametype(); // g_world.qc
1155 void readlevelcvars(void)
1156 {
1157         // first load all the mutators
1158         if(cvar("g_nix"))
1159                 MUTATOR_ADD(mutator_nix);
1160         if(cvar("g_dodging"))
1161                 MUTATOR_ADD(mutator_dodging);
1162         if(cvar("g_rocket_flying"))
1163                 MUTATOR_ADD(mutator_rocketflying);
1164         if(cvar("g_vampire"))
1165                 MUTATOR_ADD(mutator_vampire);
1166
1167         if(cvar("sv_allow_fullbright"))
1168                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1169
1170     g_bugrigs = cvar("g_bugrigs");
1171     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1172     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1173     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1174     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1175     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1176     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1177     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1178     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1179     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1180     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1181     g_bugrigs_accel = cvar("g_bugrigs_accel");
1182     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1183     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1184     g_bugrigs_steer = cvar("g_bugrigs_steer");
1185
1186     g_touchexplode = cvar("g_touchexplode");
1187     g_touchexplode_radius = cvar("g_touchexplode_radius");
1188     g_touchexplode_damage = cvar("g_touchexplode_damage");
1189     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1190     g_touchexplode_force = cvar("g_touchexplode_force");
1191
1192 #ifdef ALLOW_FORCEMODELS
1193         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1194 #endif
1195         sv_loddistance1 = cvar("sv_loddistance1");
1196         sv_loddistance2 = cvar("sv_loddistance2");
1197
1198         if(sv_loddistance2 <= sv_loddistance1)
1199                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1200
1201         sv_clones = cvar("sv_clones");
1202         sv_gentle = cvar("sv_gentle");
1203         sv_foginterval = cvar("sv_foginterval");
1204         g_cloaked = cvar("g_cloaked");
1205     if(g_cts)
1206         g_cloaked = 1; // always enable cloak in CTS
1207         g_jump_grunt = cvar("g_jump_grunt");
1208         g_footsteps = cvar("g_footsteps");
1209         g_grappling_hook = cvar("g_grappling_hook");
1210         g_jetpack = cvar("g_jetpack");
1211         g_midair = cvar("g_midair");
1212         g_minstagib = cvar("g_minstagib");
1213         g_norecoil = cvar("g_norecoil");
1214         g_bloodloss = cvar("g_bloodloss");
1215         sv_maxidle = cvar("sv_maxidle");
1216         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1217         sv_pogostick = cvar("sv_pogostick");
1218         g_ctf_reverse = cvar("g_ctf_reverse");
1219         sv_autotaunt = cvar("sv_autotaunt");
1220         sv_taunt = cvar("sv_taunt");
1221
1222         inWarmupStage = cvar("g_warmup");
1223         g_warmup_limit = cvar("g_warmup_limit");
1224         g_warmup_allguns = cvar("g_warmup_allguns");
1225         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1226
1227         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1228                 inWarmupStage = 0; // these modes cannot work together, sorry
1229
1230         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1231         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1232         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1233         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1234         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1235         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1236         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1237         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1238         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1239         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1240         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1241         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1242
1243         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1244         g_weaponratefactor = cvar("g_weaponratefactor");
1245         g_weapondamagefactor = cvar("g_weapondamagefactor");
1246         g_weaponforcefactor = cvar("g_weaponforcefactor");
1247         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1248
1249         g_pickup_shells = cvar("g_pickup_shells");
1250         g_pickup_shells_max = cvar("g_pickup_shells_max");
1251         g_pickup_nails = cvar("g_pickup_nails");
1252         g_pickup_nails_max = cvar("g_pickup_nails_max");
1253         g_pickup_rockets = cvar("g_pickup_rockets");
1254         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1255         g_pickup_cells = cvar("g_pickup_cells");
1256         g_pickup_cells_max = cvar("g_pickup_cells_max");
1257         g_pickup_fuel = cvar("g_pickup_fuel");
1258         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1259         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1260         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1261         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1262         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1263         g_pickup_armormedium = cvar("g_pickup_armormedium");
1264         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1265         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1266         g_pickup_armorbig = cvar("g_pickup_armorbig");
1267         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1268         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1269         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1270         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1271         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1272         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1273         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1274         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1275         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1276         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1277         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1278         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1279         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1280         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1281         g_pickup_healthmega = cvar("g_pickup_healthmega");
1282         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1283         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1284
1285         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1286         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1287
1288         g_pinata = cvar("g_pinata");
1289
1290     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1291     if(!g_weapon_stay)
1292         g_weapon_stay = cvar("g_weapon_stay");
1293
1294         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1295                 g_weapon_stay = 1;
1296
1297         g_ghost_items = cvar("g_ghost_items");
1298
1299         if(g_ghost_items >= 1)
1300                 g_ghost_items = 0.25; // default alpha value
1301
1302         if not(inWarmupStage && !g_ca)
1303                 game_starttime = cvar("g_start_delay");
1304
1305         sv_pitch_min = cvar("sv_pitch_min");
1306         sv_pitch_max = cvar("sv_pitch_max");
1307         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1308
1309         readplayerstartcvars();
1310 }
1311
1312 //#NO AUTOCVARS END
1313
1314 // Sound functions
1315 string precache_sound (string s) = #19;
1316 float precache_sound_index (string s) = #19;
1317
1318 #define SND_VOLUME      1
1319 #define SND_ATTENUATION 2
1320 #define SND_LARGEENTITY 8
1321 #define SND_LARGESOUND  16
1322
1323 float sound_allowed(float dest, entity e)
1324 {
1325     // sounds from world may always pass
1326     for (;;)
1327     {
1328         if (e.classname == "body")
1329             e = e.enemy;
1330         if (e.owner && e.owner != e)
1331             e = e.owner;
1332         else
1333             break;
1334     }
1335     // sounds to self may always pass
1336     if (dest == MSG_ONE)
1337         if (e == msg_entity)
1338             return TRUE;
1339     // sounds by players can be removed
1340     if (autocvar_bot_sound_monopoly)
1341         if (clienttype(e) == CLIENTTYPE_REAL)
1342             return FALSE;
1343     // anything else may pass
1344     return TRUE;
1345 }
1346
1347 #ifdef COMPAT_XON010_CHANNELS
1348 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1349 void sound(entity e, float chan, string samp, float vol, float atten)
1350 {
1351     if (!sound_allowed(MSG_BROADCAST, e))
1352         return;
1353     sound_builtin(e, chan, samp, vol, atten);
1354 }
1355 #else
1356 #undef sound
1357 void sound(entity e, float chan, string samp, float vol, float atten)
1358 {
1359     if (!sound_allowed(MSG_BROADCAST, e))
1360         return;
1361     sound7(e, chan, samp, vol, atten, 0, 0);
1362 }
1363 #endif
1364
1365 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1366 {
1367     float entno, idx;
1368
1369     if (!sound_allowed(dest, e))
1370         return;
1371
1372     entno = num_for_edict(e);
1373     idx = precache_sound_index(samp);
1374
1375     float sflags;
1376     sflags = 0;
1377
1378     atten = floor(atten * 64);
1379     vol = floor(vol * 255);
1380
1381     if (vol != 255)
1382         sflags |= SND_VOLUME;
1383     if (atten != 64)
1384         sflags |= SND_ATTENUATION;
1385     if (entno >= 8192 || chan < 0 || chan > 7)
1386         sflags |= SND_LARGEENTITY;
1387     if (idx >= 256)
1388         sflags |= SND_LARGESOUND;
1389
1390     WriteByte(dest, SVC_SOUND);
1391     WriteByte(dest, sflags);
1392     if (sflags & SND_VOLUME)
1393         WriteByte(dest, vol);
1394     if (sflags & SND_ATTENUATION)
1395         WriteByte(dest, atten);
1396     if (sflags & SND_LARGEENTITY)
1397     {
1398         WriteShort(dest, entno);
1399         WriteByte(dest, chan);
1400     }
1401     else
1402     {
1403         WriteShort(dest, entno * 8 + chan);
1404     }
1405     if (sflags & SND_LARGESOUND)
1406         WriteShort(dest, idx);
1407     else
1408         WriteByte(dest, idx);
1409
1410     WriteCoord(dest, o_x);
1411     WriteCoord(dest, o_y);
1412     WriteCoord(dest, o_z);
1413 }
1414 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1415 {
1416     vector o;
1417
1418     if (!sound_allowed(dest, e))
1419         return;
1420
1421     o = e.origin + 0.5 * (e.mins + e.maxs);
1422     soundtoat(dest, e, o, chan, samp, vol, atten);
1423 }
1424 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1425 {
1426     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1427 }
1428 void stopsoundto(float dest, entity e, float chan)
1429 {
1430     float entno;
1431
1432     if (!sound_allowed(dest, e))
1433         return;
1434
1435     entno = num_for_edict(e);
1436
1437     if (entno >= 8192 || chan < 0 || chan > 7)
1438     {
1439         float idx, sflags;
1440         idx = precache_sound_index("misc/null.wav");
1441         sflags = SND_LARGEENTITY;
1442         if (idx >= 256)
1443             sflags |= SND_LARGESOUND;
1444         WriteByte(dest, SVC_SOUND);
1445         WriteByte(dest, sflags);
1446         WriteShort(dest, entno);
1447         WriteByte(dest, chan);
1448         if (sflags & SND_LARGESOUND)
1449             WriteShort(dest, idx);
1450         else
1451             WriteByte(dest, idx);
1452         WriteCoord(dest, e.origin_x);
1453         WriteCoord(dest, e.origin_y);
1454         WriteCoord(dest, e.origin_z);
1455     }
1456     else
1457     {
1458         WriteByte(dest, SVC_STOPSOUND);
1459         WriteShort(dest, entno * 8 + chan);
1460     }
1461 }
1462 void stopsound(entity e, float chan)
1463 {
1464     if (!sound_allowed(MSG_BROADCAST, e))
1465         return;
1466
1467     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1468     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1469 }
1470
1471 void play2(entity e, string filename)
1472 {
1473     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1474     msg_entity = e;
1475     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1476 }
1477
1478 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1479 .float spamtime;
1480 float spamsound(entity e, float chan, string samp, float vol, float atten)
1481 {
1482     if (!sound_allowed(MSG_BROADCAST, e))
1483         return FALSE;
1484
1485     if (time > e.spamtime)
1486     {
1487         e.spamtime = time;
1488         sound(e, chan, samp, vol, atten);
1489         return TRUE;
1490     }
1491     return FALSE;
1492 }
1493
1494 void play2team(float t, string filename)
1495 {
1496     local entity head;
1497
1498     if (autocvar_bot_sound_monopoly)
1499         return;
1500
1501     FOR_EACH_REALPLAYER(head)
1502     {
1503         if (head.team == t)
1504             play2(head, filename);
1505     }
1506 }
1507
1508 void play2all(string samp)
1509 {
1510     if (autocvar_bot_sound_monopoly)
1511         return;
1512
1513     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1514 }
1515
1516 void PrecachePlayerSounds(string f);
1517 void precache_playermodel(string m)
1518 {
1519         float globhandle, i, n;
1520         string f;
1521
1522         if(substring(m, -9,5) == "_lod1")
1523                 return;
1524         if(substring(m, -9,5) == "_lod2")
1525                 return;
1526         precache_model(m);
1527         if(sv_loddistance1)
1528         {
1529                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1530                 if(fexists(f))
1531                         precache_model(f);
1532                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1533                 if(fexists(f))
1534                         precache_model(f);
1535         }
1536
1537         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1538         if (globhandle < 0)
1539                 return;
1540         n = search_getsize(globhandle);
1541         for (i = 0; i < n; ++i)
1542         {
1543                 //print(search_getfilename(globhandle, i), "\n");
1544                 f = search_getfilename(globhandle, i);
1545                 PrecachePlayerSounds(f);
1546         }
1547         search_end(globhandle);
1548 }
1549 void precache_all_playermodels(string pattern)
1550 {
1551         float globhandle, i, n;
1552         string f;
1553
1554         globhandle = search_begin(pattern, TRUE, FALSE);
1555         if (globhandle < 0)
1556                 return;
1557         n = search_getsize(globhandle);
1558         for (i = 0; i < n; ++i)
1559         {
1560                 //print(search_getfilename(globhandle, i), "\n");
1561                 f = search_getfilename(globhandle, i);
1562                 precache_playermodel(f);
1563         }
1564         search_end(globhandle);
1565 }
1566
1567 void precache()
1568 {
1569     // gamemode related things
1570     precache_model ("models/misc/chatbubble.spr");
1571     if (g_runematch)
1572     {
1573         precache_model ("models/runematch/curse.mdl");
1574         precache_model ("models/runematch/rune.mdl");
1575     }
1576
1577 #ifdef TTURRETS_ENABLED
1578     if (autocvar_g_turrets)
1579         turrets_precash();
1580 #endif
1581
1582     // Precache all player models if desired
1583     if (autocvar_sv_precacheplayermodels)
1584     {
1585         PrecachePlayerSounds("sound/player/default.sounds");
1586         precache_all_playermodels("models/player/*.zym");
1587         precache_all_playermodels("models/player/*.dpm");
1588         precache_all_playermodels("models/player/*.md3");
1589         precache_all_playermodels("models/player/*.psk");
1590         precache_all_playermodels("models/player/*.iqm");
1591     }
1592
1593     if (autocvar_sv_defaultcharacter)
1594     {
1595         string s;
1596         s = autocvar_sv_defaultplayermodel_red;
1597         if (s != "")
1598             precache_playermodel(s);
1599         s = autocvar_sv_defaultplayermodel_blue;
1600         if (s != "")
1601             precache_playermodel(s);
1602         s = autocvar_sv_defaultplayermodel_yellow;
1603         if (s != "")
1604             precache_playermodel(s);
1605         s = autocvar_sv_defaultplayermodel_pink;
1606         if (s != "")
1607             precache_playermodel(s);
1608         s = autocvar_sv_defaultplayermodel;
1609         if (s != "")
1610             precache_playermodel(s);
1611     }
1612
1613     if (g_footsteps)
1614     {
1615         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1616         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1617     }
1618
1619     // gore and miscellaneous sounds
1620     //precache_sound ("misc/h2ohit.wav");
1621     precache_model ("models/hook.md3");
1622     precache_sound ("misc/armorimpact.wav");
1623     precache_sound ("misc/bodyimpact1.wav");
1624     precache_sound ("misc/bodyimpact2.wav");
1625     precache_sound ("misc/gib.wav");
1626     precache_sound ("misc/gib_splat01.wav");
1627     precache_sound ("misc/gib_splat02.wav");
1628     precache_sound ("misc/gib_splat03.wav");
1629     precache_sound ("misc/gib_splat04.wav");
1630     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1631     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1632     precache_sound ("misc/null.wav");
1633     precache_sound ("misc/spawn.wav");
1634     precache_sound ("misc/talk.wav");
1635     precache_sound ("misc/teleport.wav");
1636     precache_sound ("misc/poweroff.wav");
1637     precache_sound ("player/lava.wav");
1638     precache_sound ("player/slime.wav");
1639
1640     if (g_jetpack)
1641         precache_sound ("misc/jetpack_fly.wav");
1642
1643     precache_model ("models/sprites/0.spr32");
1644     precache_model ("models/sprites/1.spr32");
1645     precache_model ("models/sprites/2.spr32");
1646     precache_model ("models/sprites/3.spr32");
1647     precache_model ("models/sprites/4.spr32");
1648     precache_model ("models/sprites/5.spr32");
1649     precache_model ("models/sprites/6.spr32");
1650     precache_model ("models/sprites/7.spr32");
1651     precache_model ("models/sprites/8.spr32");
1652     precache_model ("models/sprites/9.spr32");
1653     precache_model ("models/sprites/10.spr32");
1654
1655     // common weapon precaches
1656         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1657     precache_sound ("weapons/weapon_switch.wav");
1658     precache_sound ("weapons/weaponpickup.wav");
1659     precache_sound ("weapons/unavailable.wav");
1660     precache_sound ("weapons/dryfire.wav");
1661     if (g_grappling_hook)
1662     {
1663         precache_sound ("weapons/hook_fire.wav"); // hook
1664         precache_sound ("weapons/hook_impact.wav"); // hook
1665     }
1666
1667     if(autocvar_sv_precacheweapons)
1668     {
1669         //precache weapon models/sounds
1670         local float wep;
1671         wep = WEP_FIRST;
1672         while (wep <= WEP_LAST)
1673         {
1674             weapon_action(wep, WR_PRECACHE);
1675             wep = wep + 1;
1676         }
1677     }
1678
1679     precache_model("models/elaser.mdl");
1680     precache_model("models/laser.mdl");
1681     precache_model("models/ebomb.mdl");
1682
1683 #if 0
1684     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1685
1686     if (!self.noise && self.music) // quake 3 uses the music field
1687         self.noise = self.music;
1688
1689     // plays music for the level if there is any
1690     if (self.noise)
1691     {
1692         precache_sound (self.noise);
1693         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1694     }
1695 #endif
1696 }
1697
1698 // sorry, but using \ in macros breaks line numbers
1699 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1700 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1701 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1702
1703 // WARNING: this kills the trace globals
1704 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1705 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1706
1707 #define INITPRIO_FIRST              0
1708 #define INITPRIO_GAMETYPE           0
1709 #define INITPRIO_GAMETYPE_FALLBACK  1
1710 #define INITPRIO_FINDTARGET        10
1711 #define INITPRIO_DROPTOFLOOR       20
1712 #define INITPRIO_SETLOCATION       90
1713 #define INITPRIO_LINKDOORS         91
1714 #define INITPRIO_LAST              99
1715
1716 .void(void) initialize_entity;
1717 .float initialize_entity_order;
1718 .entity initialize_entity_next;
1719 entity initialize_entity_first;
1720
1721 void make_safe_for_remove(entity e)
1722 {
1723     if (e.initialize_entity)
1724     {
1725         entity ent, prev;
1726         for (ent = initialize_entity_first; ent; )
1727         {
1728             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1729             {
1730                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1731                 // skip it in linked list
1732                 if (prev)
1733                 {
1734                     prev.initialize_entity_next = ent.initialize_entity_next;
1735                     ent = prev.initialize_entity_next;
1736                 }
1737                 else
1738                 {
1739                     initialize_entity_first = ent.initialize_entity_next;
1740                     ent = initialize_entity_first;
1741                 }
1742             }
1743             else
1744             {
1745                 prev = ent;
1746                 ent = ent.initialize_entity_next;
1747             }
1748         }
1749     }
1750 }
1751
1752 void objerror(string s)
1753 {
1754     make_safe_for_remove(self);
1755     objerror_builtin(s);
1756 }
1757
1758 .float remove_except_protected_forbidden;
1759 void remove_except_protected(entity e)
1760 {
1761         if(e.remove_except_protected_forbidden)
1762                 error("not allowed to remove this at this point");
1763         remove_builtin(e);
1764 }
1765
1766 void remove_unsafely(entity e)
1767 {
1768     remove_builtin(e);
1769 }
1770
1771 void remove_safely(entity e)
1772 {
1773     make_safe_for_remove(e);
1774     remove_builtin(e);
1775 }
1776
1777 void InitializeEntity(entity e, void(void) func, float order)
1778 {
1779     entity prev, cur;
1780
1781     if (!e || e.initialize_entity)
1782     {
1783         // make a proxy initializer entity
1784         entity e_old;
1785         e_old = e;
1786         e = spawn();
1787         e.classname = "initialize_entity";
1788         e.enemy = e_old;
1789     }
1790
1791     e.initialize_entity = func;
1792     e.initialize_entity_order = order;
1793
1794     cur = initialize_entity_first;
1795     for (;;)
1796     {
1797         if (!cur || cur.initialize_entity_order > order)
1798         {
1799             // insert between prev and cur
1800             if (prev)
1801                 prev.initialize_entity_next = e;
1802             else
1803                 initialize_entity_first = e;
1804             e.initialize_entity_next = cur;
1805             return;
1806         }
1807         prev = cur;
1808         cur = cur.initialize_entity_next;
1809     }
1810 }
1811 void InitializeEntitiesRun()
1812 {
1813     entity startoflist;
1814     startoflist = initialize_entity_first;
1815     initialize_entity_first = world;
1816     remove = remove_except_protected;
1817     for (self = startoflist; self; self = self.initialize_entity_next)
1818     {
1819         self.remove_except_protected_forbidden = 1;
1820     }
1821     for (self = startoflist; self; )
1822     {
1823         entity e;
1824         var void(void) func;
1825         e = self.initialize_entity_next;
1826         func = self.initialize_entity;
1827         self.initialize_entity_order = 0;
1828         self.initialize_entity = func_null;
1829         self.initialize_entity_next = world;
1830         self.remove_except_protected_forbidden = 0;
1831         if (self.classname == "initialize_entity")
1832         {
1833             entity e_old;
1834             e_old = self.enemy;
1835             remove_builtin(self);
1836             self = e_old;
1837         }
1838         //dprint("Delayed initialization: ", self.classname, "\n");
1839         if(func != func_null)
1840             func();
1841         else
1842         {
1843             eprint(self);
1844             backtrace(strcat("Null function in: ", self.classname, "\n"));
1845         }
1846         self = e;
1847     }
1848     remove = remove_unsafely;
1849 }
1850
1851 .float uncustomizeentityforclient_set;
1852 .void(void) uncustomizeentityforclient;
1853 void(void) SUB_Nullpointer = #0;
1854 void UncustomizeEntitiesRun()
1855 {
1856     entity oldself;
1857     oldself = self;
1858     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1859         self.uncustomizeentityforclient();
1860     self = oldself;
1861 }
1862 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1863 {
1864     e.customizeentityforclient = customizer;
1865     e.uncustomizeentityforclient = uncustomizer;
1866     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1867 }
1868
1869 .float nottargeted;
1870 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1871
1872 void() SUB_Remove;
1873 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1874 {
1875     vector mi, ma;
1876
1877     if (e.classname == "")
1878         e.classname = "net_linked";
1879
1880     if (e.model == "" || self.modelindex == 0)
1881     {
1882         mi = e.mins;
1883         ma = e.maxs;
1884         setmodel(e, "null");
1885         setsize(e, mi, ma);
1886     }
1887
1888     e.SendEntity = sendfunc;
1889     e.SendFlags = 0xFFFFFF;
1890
1891     if (!docull)
1892         e.effects |= EF_NODEPTHTEST;
1893
1894     if (dt)
1895     {
1896         e.nextthink = time + dt;
1897         e.think = SUB_Remove;
1898     }
1899 }
1900
1901 void adaptor_think2touch()
1902 {
1903     entity o;
1904     o = other;
1905     other = world;
1906     self.touch();
1907     other = o;
1908 }
1909
1910 void adaptor_think2use()
1911 {
1912     entity o, a;
1913     o = other;
1914     a = activator;
1915     activator = world;
1916     other = world;
1917     self.use();
1918     other = o;
1919     activator = a;
1920 }
1921
1922 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1923 {
1924         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1925                 self.projectiledeathtype |= HITTYPE_SPLASH;
1926         adaptor_think2use();
1927 }
1928
1929 // deferred dropping
1930 void DropToFloor_Handler()
1931 {
1932     droptofloor_builtin();
1933     self.dropped_origin = self.origin;
1934 }
1935
1936 void droptofloor()
1937 {
1938     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1939 }
1940
1941
1942
1943 float trace_hits_box_a0, trace_hits_box_a1;
1944
1945 float trace_hits_box_1d(float end, float thmi, float thma)
1946 {
1947     if (end == 0)
1948     {
1949         // just check if x is in range
1950         if (0 < thmi)
1951             return FALSE;
1952         if (0 > thma)
1953             return FALSE;
1954     }
1955     else
1956     {
1957         // do the trace with respect to x
1958         // 0 -> end has to stay in thmi -> thma
1959         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1960         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1961         if (trace_hits_box_a0 > trace_hits_box_a1)
1962             return FALSE;
1963     }
1964     return TRUE;
1965 }
1966
1967 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1968 {
1969     end -= start;
1970     thmi -= start;
1971     thma -= start;
1972     // now it is a trace from 0 to end
1973
1974     trace_hits_box_a0 = 0;
1975     trace_hits_box_a1 = 1;
1976
1977     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1978         return FALSE;
1979     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1980         return FALSE;
1981     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1982         return FALSE;
1983
1984     return TRUE;
1985 }
1986
1987 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1988 {
1989     return trace_hits_box(start, end, thmi - ma, thma - mi);
1990 }
1991
1992 float SUB_NoImpactCheck()
1993 {
1994         // zero hitcontents = this is not the real impact, but either the
1995         // mirror-impact of something hitting the projectile instead of the
1996         // projectile hitting the something, or a touchareagrid one. Neither of
1997         // these stop the projectile from moving, so...
1998         if(trace_dphitcontents == 0)
1999         {
2000                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2001                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
2002                 checkclient();
2003         }
2004     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2005         return 1;
2006     if (other == world && self.size != '0 0 0')
2007     {
2008         vector tic;
2009         tic = self.velocity * sys_frametime;
2010         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2011         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2012         if (trace_fraction >= 1)
2013         {
2014             dprint("Odd... did not hit...?\n");
2015         }
2016         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2017         {
2018             dprint("Detected and prevented the sky-grapple bug.\n");
2019             return 1;
2020         }
2021     }
2022
2023     return 0;
2024 }
2025
2026 #define SUB_OwnerCheck() (other && (other == self.owner))
2027
2028 void RemoveGrapplingHook(entity pl);
2029 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2030 {
2031         if(SUB_OwnerCheck())
2032                 return TRUE;
2033         if(SUB_NoImpactCheck())
2034         {
2035                 if(self.classname == "grapplinghook")
2036                         RemoveGrapplingHook(self.realowner);
2037                 else
2038                         remove(self);
2039                 return TRUE;
2040         }
2041         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2042                 UpdateCSQCProjectileNextFrame(self);
2043         return FALSE;
2044 }
2045 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2046
2047 float MAX_IPBAN_URIS           = 16;
2048
2049 float URI_GET_DISCARD          = 0;
2050 float URI_GET_IPBAN            = 1;
2051 float URI_GET_IPBAN_END        = 16;
2052 float URI_GET_PLAYERSTATS_SENT = 17;
2053
2054 void URI_Get_Callback(float id, float status, string data)
2055 {
2056     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2057     dprint(data);
2058     dprint("\nEnd of data.\n");
2059
2060     if (id == URI_GET_DISCARD)
2061     {
2062         // discard
2063     }
2064     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2065     {
2066         // online ban list
2067         OnlineBanList_URI_Get_Callback(id, status, data);
2068     }
2069     else if (id == URI_GET_PLAYERSTATS_SENT)
2070     {
2071         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2072     }
2073     else
2074     {
2075         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2076     }
2077 }
2078
2079 void print_to(entity e, string s)
2080 {
2081     if (e)
2082         sprint(e, strcat(s, "\n"));
2083     else
2084         print(s, "\n");
2085 }
2086
2087 string uid2name(string myuid) {
2088         string s;
2089         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2090
2091         if(s == "")
2092                 s = "^1Unregistered Player";
2093         return s;
2094 }
2095
2096 float race_readTime(string map, float pos)
2097 {
2098         string rr;
2099         if(g_cts)
2100                 rr = CTS_RECORD;
2101         else
2102                 rr = RACE_RECORD;
2103
2104         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2105 }
2106
2107 string race_readUID(string map, float pos)
2108 {
2109         string rr;
2110         if(g_cts)
2111                 rr = CTS_RECORD;
2112         else
2113                 rr = RACE_RECORD;
2114
2115         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2116 }
2117
2118 float race_readPos(string map, float t) {
2119         float i;
2120         for (i = 1; i <= RANKINGS_CNT; ++i)
2121                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2122                         return i;
2123
2124         return 0; // pos is zero if unranked
2125 }
2126
2127 void race_writeTime(string map, float t, string myuid)
2128 {
2129         string rr;
2130         if(g_cts)
2131                 rr = CTS_RECORD;
2132         else
2133                 rr = RACE_RECORD;
2134
2135         float newpos;
2136         newpos = race_readPos(map, t);
2137
2138         float i, prevpos;
2139         for(i = 1; i <= RANKINGS_CNT; ++i)
2140         {
2141                 if(race_readUID(map, i) == myuid)
2142                         prevpos = i;
2143         }
2144         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2145                 for (i = prevpos; i > newpos; --i) {
2146                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2147                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2148                 }
2149         } else { // player has no ranked record yet
2150                 for (i = RANKINGS_CNT; i > newpos; --i) {
2151                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2152                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2153                 }
2154         }
2155
2156         // store new time itself
2157         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2158         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2159 }
2160
2161 string race_readName(string map, float pos)
2162 {
2163         string rr;
2164         if(g_cts)
2165                 rr = CTS_RECORD;
2166         else
2167                 rr = RACE_RECORD;
2168
2169         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2170 }
2171
2172 string race_placeName(float pos) {
2173         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2174         {
2175                 if(mod(pos, 10) == 1)
2176                         return strcat(ftos(pos), "st");
2177                 else if(mod(pos, 10) == 2)
2178                         return strcat(ftos(pos), "nd");
2179                 else if(mod(pos, 10) == 3)
2180                         return strcat(ftos(pos), "rd");
2181                 else
2182                         return strcat(ftos(pos), "th");
2183         }
2184         else
2185                 return strcat(ftos(pos), "th");
2186 }
2187 string getrecords(float page) // 50 records per page
2188 {
2189     float rec;
2190     string h;
2191     float r;
2192     float i;
2193     string s;
2194
2195     rec = 0;
2196
2197     s = "";
2198
2199     if (g_ctf)
2200     {
2201         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2202         {
2203             if (MapInfo_Get_ByID(i))
2204             {
2205                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2206                 if (r == 0)
2207                     continue;
2208                 // TODO: uid2name
2209                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2210                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2211                 ++rec;
2212             }
2213         }
2214     }
2215
2216     if (g_race)
2217     {
2218         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2219         {
2220             if (MapInfo_Get_ByID(i))
2221             {
2222                 r = race_readTime(MapInfo_Map_bspname, 1);
2223                 if (r == 0)
2224                     continue;
2225                 h = race_readName(MapInfo_Map_bspname, 1);
2226                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2227                 ++rec;
2228             }
2229         }
2230     }
2231
2232     if (g_cts)
2233     {
2234         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2235         {
2236             if (MapInfo_Get_ByID(i))
2237             {
2238                 r = race_readTime(MapInfo_Map_bspname, 1);
2239                 if (r == 0)
2240                     continue;
2241                 h = race_readName(MapInfo_Map_bspname, 1);
2242                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2243                 ++rec;
2244             }
2245         }
2246     }
2247
2248     MapInfo_ClearTemps();
2249
2250     if (s == "" && page == 0)
2251         return "No records are available on this server.\n";
2252     else
2253         return s;
2254 }
2255
2256 string getrankings()
2257 {
2258     string n;
2259     float t;
2260     float i;
2261     string s;
2262     string p;
2263     string map;
2264
2265     s = "";
2266
2267     map = GetMapname();
2268
2269     for (i = 1; i <= RANKINGS_CNT; ++i)
2270     {
2271         t = race_readTime(map, i);
2272         if (t == 0)
2273             continue;
2274         n = race_readName(map, i);
2275         p = race_placeName(i);
2276         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2277     }
2278
2279     MapInfo_ClearTemps();
2280
2281     if (s == "")
2282         return strcat("No records are available for the map: ", map, "\n");
2283     else
2284         return strcat("Records for ", map, ":\n", s);
2285 }
2286
2287 #define LADDER_FIRSTPOINT 100
2288 #define LADDER_CNT 10
2289         // position X still gives LADDER_FIRSTPOINT/X points
2290 #define LADDER_SIZE 30
2291         // ladder shows the top X players
2292 string top_uids[LADDER_SIZE];
2293 float top_scores[LADDER_SIZE];
2294 string getladder()
2295 {
2296     float i, j, k, uidcnt;
2297     string s, temp_s;
2298
2299     s = "";
2300     temp_s = "";
2301
2302     string rr;
2303     if(g_cts)
2304         rr = CTS_RECORD;
2305     else
2306         rr = RACE_RECORD;
2307
2308     string myuid;
2309
2310     for (k = 0; k < MapInfo_count; ++k)
2311     {
2312         if (MapInfo_Get_ByID(k))
2313         {
2314                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2315                         if(i == 0) // speed award
2316                         {
2317                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2318                                         continue;
2319
2320                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2321                         }
2322                         else // normal record, if it exists (else break)
2323                         {
2324                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2325                                         continue;
2326
2327                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2328                         }
2329
2330                         // string s contains:
2331                         // arg 0 = # of speed recs
2332                         // arg 1 = # of 1st place recs
2333                         // arg 2 = # of 2nd place recs
2334                         // ... etc
2335                         // LADDER_CNT+1 = total points
2336
2337                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2338                         if (temp_s == "")
2339                         {
2340                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2341                             ++uidcnt;
2342                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2343                             {
2344                                 if(j != LADDER_CNT + 1)
2345                                     temp_s = strcat(temp_s, "0 ");
2346                                 else
2347                                     temp_s = strcat(temp_s, "0");
2348                             }
2349                         }
2350
2351                         tokenize_console(temp_s);
2352                         s = "";
2353
2354                         if(i == 0) // speed award
2355                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2356                             {
2357                                 if(j == 0) // speed award
2358                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2359                                 else
2360                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2361                             }
2362                         else // record
2363                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2364                             {
2365                                 if(j == 0)
2366                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2367                                 else if(j == i) // wanted rec!
2368                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2369                                 else
2370                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2371                             }
2372
2373                         // total points are (by default) calculated like this:
2374                         // speedrec = floor(100 / 10) = 10 points
2375                         // 1st place = floor(100 / 1) = 100 points
2376                         // 2nd place = floor(100 / 2) = 50 points
2377                         // 3rd place = floor(100 / 3) = 33 points
2378                         // 4th place = floor(100 / 4) = 25 points
2379                         // 5th place = floor(100 / 5) = 20 points
2380                         // ... etc
2381
2382                         if(i == 0)
2383                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2384                         else
2385                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2386
2387                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2388                 }
2389         }
2390     }
2391
2392     float thiscnt;
2393     string thisuid;
2394     for (i = 0; i <= uidcnt; ++i) // for each known uid
2395     {
2396         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2397         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2398         tokenize_console(temp_s);
2399         thiscnt = stof(argv(LADDER_CNT+1));
2400
2401         if(thiscnt > top_scores[LADDER_SIZE-1])
2402         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2403         {
2404             if(thiscnt > top_scores[j])
2405             {
2406                 for (k = LADDER_SIZE-1; k >= j; --k)
2407                 {
2408                     top_uids[k] = top_uids[k-1];
2409                     top_scores[k] = top_scores[k-1];
2410                 }
2411                 top_uids[j] = thisuid;
2412                 top_scores[j] = thiscnt;
2413                 break;
2414             }
2415         }
2416     }
2417
2418     s = "^3-----------------------\n\n";
2419
2420     s = strcat(s, "Pos ^3|");
2421     s = strcat(s, " ^7Total  ^3|");
2422     for (i = 1; i <= LADDER_CNT; ++i)
2423     {
2424         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2425     }
2426     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2427
2428     s = strcat(s, "\n^3----+--------");
2429     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2430     {
2431         s = strcat(s, "+-----");
2432     }
2433 #if LADDER_CNT > 9
2434     for (i = 1; i <= LADDER_CNT - 9; ++i)
2435     {
2436         s = strcat(s, "+------");
2437     }
2438 #endif
2439
2440     s = strcat(s, "+--------------+--------------------\n");
2441
2442     for (i = 0; i < LADDER_SIZE; ++i)
2443     {
2444         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2445         tokenize_console(temp_s);
2446         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2447             continue;
2448         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2449         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2450         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2451         {
2452             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2453         }
2454 #if LADDER_CNT > 9
2455         for (j = 10; j <= LADDER_CNT; ++j)
2456         {
2457             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2458         }
2459 #endif
2460
2461         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2462         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2463     }
2464
2465     MapInfo_ClearTemps();
2466
2467     if (s == "")
2468         return "No ladder on this server!\n";
2469     else
2470         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2471 }
2472
2473
2474 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2475 {
2476     float m, i;
2477     vector start, org, delta, end, enddown, mstart;
2478
2479     m = e.dphitcontentsmask;
2480     e.dphitcontentsmask = goodcontents | badcontents;
2481
2482     org = world.mins;
2483     delta = world.maxs - world.mins;
2484
2485     for (i = 0; i < attempts; ++i)
2486     {
2487         start_x = org_x + random() * delta_x;
2488         start_y = org_y + random() * delta_y;
2489         start_z = org_z + random() * delta_z;
2490
2491         // rule 1: start inside world bounds, and outside
2492         // solid, and don't start from somewhere where you can
2493         // fall down to evil
2494         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2495         if (trace_fraction >= 1)
2496             continue;
2497         if (trace_startsolid)
2498             continue;
2499         if (trace_dphitcontents & badcontents)
2500             continue;
2501         if (trace_dphitq3surfaceflags & badsurfaceflags)
2502             continue;
2503
2504         // rule 2: if we are too high, lower the point
2505         if (trace_fraction * delta_z > maxaboveground)
2506             start = trace_endpos + '0 0 1' * maxaboveground;
2507         enddown = trace_endpos;
2508
2509         // rule 3: make sure we aren't outside the map. This only works
2510         // for somewhat well formed maps. A good rule of thumb is that
2511         // the map should have a convex outside hull.
2512         // these can be traceLINES as we already verified the starting box
2513         mstart = start + 0.5 * (e.mins + e.maxs);
2514         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2524         if (trace_fraction >= 1)
2525             continue;
2526         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2527         if (trace_fraction >= 1)
2528             continue;
2529
2530         // find a random vector to "look at"
2531         end_x = org_x + random() * delta_x;
2532         end_y = org_y + random() * delta_y;
2533         end_z = org_z + random() * delta_z;
2534         end = start + normalize(end - start) * vlen(delta);
2535
2536         // rule 4: start TO end must not be too short
2537         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2538         if (trace_startsolid)
2539             continue;
2540         if (trace_fraction < minviewdistance / vlen(delta))
2541             continue;
2542
2543         // rule 5: don't want to look at sky
2544         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2545             continue;
2546
2547         // rule 6: we must not end up in trigger_hurt
2548         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2549             continue;
2550
2551         break;
2552     }
2553
2554     e.dphitcontentsmask = m;
2555
2556     if (i < attempts)
2557     {
2558         setorigin(e, start);
2559         e.angles = vectoangles(end - start);
2560         dprint("Needed ", ftos(i + 1), " attempts\n");
2561         return TRUE;
2562     }
2563     else
2564         return FALSE;
2565 }
2566
2567 float zcurveparticles_effectno;
2568 vector zcurveparticles_start;
2569 float zcurveparticles_spd;
2570
2571 void endzcurveparticles()
2572 {
2573         if(zcurveparticles_effectno)
2574         {
2575                 // terminator
2576                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2577         }
2578         zcurveparticles_effectno = 0;
2579 }
2580
2581 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2582 {
2583         spd = bound(0, floor(spd / 16), 32767);
2584         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2585         {
2586                 endzcurveparticles();
2587                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2588                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2589                 WriteShort(MSG_BROADCAST, effectno);
2590                 WriteCoord(MSG_BROADCAST, start_x);
2591                 WriteCoord(MSG_BROADCAST, start_y);
2592                 WriteCoord(MSG_BROADCAST, start_z);
2593                 zcurveparticles_effectno = effectno;
2594                 zcurveparticles_start = start;
2595         }
2596         else
2597                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2598         WriteCoord(MSG_BROADCAST, end_x);
2599         WriteCoord(MSG_BROADCAST, end_y);
2600         WriteCoord(MSG_BROADCAST, end_z);
2601         WriteCoord(MSG_BROADCAST, end_dz);
2602         zcurveparticles_spd = spd;
2603 }
2604
2605 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2606 {
2607         float end_dz;
2608         vector vecxy, velxy;
2609
2610         vecxy = end - start;
2611         vecxy_z = 0;
2612         velxy = vel;
2613         velxy_z = 0;
2614
2615         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2616         {
2617                 endzcurveparticles();
2618                 trailparticles(world, effectno, start, end);
2619                 return;
2620         }
2621
2622         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2623         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2624 }
2625
2626 void write_recordmarker(entity pl, float tstart, float dt)
2627 {
2628     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2629
2630     // also write a marker into demo files for demotc-race-record-extractor to find
2631     stuffcmd(pl,
2632              strcat(
2633                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2634                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2635 }
2636
2637 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2638 {
2639         switch(algn)
2640         {
2641                 default:
2642                 case 3: // right
2643                         break;
2644
2645                 case 4: // left
2646                         vecs_y = -vecs_y;
2647                         break;
2648
2649                 case 1:
2650                         if(allowcenter) // 2: allow center handedness
2651                         {
2652                                 // center
2653                                 vecs_y = 0;
2654                                 vecs_z -= 2;
2655                         }
2656                         else
2657                         {
2658                                 // right
2659                         }
2660                         break;
2661
2662                 case 2:
2663                         if(allowcenter) // 2: allow center handedness
2664                         {
2665                                 // center
2666                                 vecs_y = 0;
2667                                 vecs_z -= 2;
2668                         }
2669                         else
2670                         {
2671                                 // left
2672                                 vecs_y = -vecs_y;
2673                         }
2674                         break;
2675         }
2676         return vecs;
2677 }
2678
2679 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2680 {
2681         string s;
2682         vector v;
2683
2684         if (autocvar_g_shootfromeye)
2685         {
2686                 if (visual)
2687                 {
2688                         vecs_y = 0;
2689                         vecs_z -= 2;
2690                 }
2691                 else
2692                 {
2693                         vecs_y = 0;
2694                         vecs_z = 0;
2695                 }
2696         }
2697         else if (autocvar_g_shootfromcenter)
2698         {
2699                 vecs_y = 0;
2700                 vecs_z -= 2;
2701         }
2702         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2703         {
2704                 v = stov(s);
2705                 if (y_is_right)
2706                         v_y = -v_y;
2707                 if (v_x != 0)
2708                         vecs_x = v_x;
2709                 vecs_y = v_y;
2710                 vecs_z = v_z;
2711         }
2712         else if (autocvar_g_shootfromclient)
2713         {
2714                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2715         }
2716         return vecs;
2717 }
2718
2719 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2720 {
2721         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2722 }
2723
2724
2725 void attach_sameorigin(entity e, entity to, string tag)
2726 {
2727     vector org, t_forward, t_left, t_up, e_forward, e_up;
2728     vector org0, ang0;
2729     float tagscale;
2730
2731     ang0 = e.angles;
2732     org0 = e.origin;
2733
2734     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2735     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2736     t_forward = v_forward * tagscale;
2737     t_left = v_right * -tagscale;
2738     t_up = v_up * tagscale;
2739
2740     e.origin_x = org * t_forward;
2741     e.origin_y = org * t_left;
2742     e.origin_z = org * t_up;
2743
2744     // current forward and up directions
2745     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2746                 e.angles = AnglesTransform_FromVAngles(e.angles);
2747         else
2748                 e.angles = AnglesTransform_FromAngles(e.angles);
2749     fixedmakevectors(e.angles);
2750
2751     // untransform forward, up!
2752     e_forward_x = v_forward * t_forward;
2753     e_forward_y = v_forward * t_left;
2754     e_forward_z = v_forward * t_up;
2755     e_up_x = v_up * t_forward;
2756     e_up_y = v_up * t_left;
2757     e_up_z = v_up * t_up;
2758
2759     e.angles = fixedvectoangles2(e_forward, e_up);
2760     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2761                 e.angles = AnglesTransform_ToVAngles(e.angles);
2762         else
2763                 e.angles = AnglesTransform_ToAngles(e.angles);
2764
2765     setattachment(e, to, tag);
2766     setorigin(e, e.origin);
2767 }
2768
2769 void detach_sameorigin(entity e)
2770 {
2771     vector org;
2772     org = gettaginfo(e, 0);
2773     e.angles = fixedvectoangles2(v_forward, v_up);
2774     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2775                 e.angles = AnglesTransform_ToVAngles(e.angles);
2776         else
2777                 e.angles = AnglesTransform_ToAngles(e.angles);
2778     setorigin(e, org);
2779     setattachment(e, world, "");
2780     setorigin(e, e.origin);
2781 }
2782
2783 void follow_sameorigin(entity e, entity to)
2784 {
2785     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2786     e.aiment = to; // make the hole follow bmodel
2787     e.punchangle = to.angles; // the original angles of bmodel
2788     e.view_ofs = e.origin - to.origin; // relative origin
2789     e.v_angle = e.angles - to.angles; // relative angles
2790 }
2791
2792 void unfollow_sameorigin(entity e)
2793 {
2794     e.movetype = MOVETYPE_NONE;
2795 }
2796
2797 entity gettaginfo_relative_ent;
2798 vector gettaginfo_relative(entity e, float tag)
2799 {
2800     if (!gettaginfo_relative_ent)
2801     {
2802         gettaginfo_relative_ent = spawn();
2803         gettaginfo_relative_ent.effects = EF_NODRAW;
2804     }
2805     gettaginfo_relative_ent.model = e.model;
2806     gettaginfo_relative_ent.modelindex = e.modelindex;
2807     gettaginfo_relative_ent.frame = e.frame;
2808     return gettaginfo(gettaginfo_relative_ent, tag);
2809 }
2810
2811 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2812 {
2813     float p;
2814     p = pow(2, chan);
2815     if (pl.soundentity.cnt & p)
2816         return;
2817     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2818     pl.soundentity.cnt |= p;
2819 }
2820
2821 void SoundEntity_StopSound(entity pl, float chan)
2822 {
2823     float p;
2824     p = pow(2, chan);
2825     if (pl.soundentity.cnt & p)
2826     {
2827         stopsoundto(MSG_ALL, pl.soundentity, chan);
2828         pl.soundentity.cnt &~= p;
2829     }
2830 }
2831
2832 void SoundEntity_Attach(entity pl)
2833 {
2834     pl.soundentity = spawn();
2835     pl.soundentity.classname = "soundentity";
2836     pl.soundentity.owner = pl;
2837     setattachment(pl.soundentity, pl, "");
2838     setmodel(pl.soundentity, "null");
2839 }
2840
2841 void SoundEntity_Detach(entity pl)
2842 {
2843     float i;
2844     for (i = 0; i <= 7; ++i)
2845         SoundEntity_StopSound(pl, i);
2846 }
2847
2848
2849 float ParseCommandPlayerSlotTarget_firsttoken;
2850 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2851 {
2852         string s;
2853         entity e, head;
2854         float n;
2855
2856         s = string_null;
2857
2858         ParseCommandPlayerSlotTarget_firsttoken = -1;
2859
2860         if (tokens > idx)
2861         {
2862                 if (substring(argv(idx), 0, 1) == "#")
2863                 {
2864                         s = substring(argv(idx), 1, -1);
2865                         ++idx;
2866                         if (s == "") if (tokens > idx)
2867                         {
2868                                 s = argv(idx);
2869                                 ++idx;
2870                         }
2871                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2872                         n = stof(s);
2873                         if (s == ftos(n) && n > 0 && n <= maxclients)
2874                         {
2875                                 e = edict_num(n);
2876                                 if (e.flags & FL_CLIENT)
2877                                         return e;
2878                         }
2879                 }
2880                 else
2881                 {
2882                         // it must be a nick name
2883                         s = argv(idx);
2884                         ++idx;
2885                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2886
2887                         n = 0;
2888                         FOR_EACH_CLIENT(head)
2889                                 if (head.netname == s)
2890                                 {
2891                                         e = head;
2892                                         ++n;
2893                                 }
2894                         if (n == 1)
2895                                 return e;
2896
2897                         s = strdecolorize(s);
2898                         n = 0;
2899                         FOR_EACH_CLIENT(head)
2900                                 if (strdecolorize(head.netname) == s)
2901                                 {
2902                                         e = head;
2903                                         ++n;
2904                                 }
2905                         if (n == 1)
2906                                 return e;
2907                 }
2908         }
2909
2910         return world;
2911 }
2912
2913 .float scale2;
2914
2915 float modeleffect_SendEntity(entity to, float sf)
2916 {
2917         float f;
2918         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2919
2920         f = 0;
2921         if(self.velocity != '0 0 0')
2922                 f |= 1;
2923         if(self.angles != '0 0 0')
2924                 f |= 2;
2925         if(self.avelocity != '0 0 0')
2926                 f |= 4;
2927
2928         WriteByte(MSG_ENTITY, f);
2929         WriteShort(MSG_ENTITY, self.modelindex);
2930         WriteByte(MSG_ENTITY, self.skin);
2931         WriteByte(MSG_ENTITY, self.frame);
2932         WriteCoord(MSG_ENTITY, self.origin_x);
2933         WriteCoord(MSG_ENTITY, self.origin_y);
2934         WriteCoord(MSG_ENTITY, self.origin_z);
2935         if(f & 1)
2936         {
2937                 WriteCoord(MSG_ENTITY, self.velocity_x);
2938                 WriteCoord(MSG_ENTITY, self.velocity_y);
2939                 WriteCoord(MSG_ENTITY, self.velocity_z);
2940         }
2941         if(f & 2)
2942         {
2943                 WriteCoord(MSG_ENTITY, self.angles_x);
2944                 WriteCoord(MSG_ENTITY, self.angles_y);
2945                 WriteCoord(MSG_ENTITY, self.angles_z);
2946         }
2947         if(f & 4)
2948         {
2949                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2950                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2951                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2952         }
2953         WriteShort(MSG_ENTITY, self.scale * 256.0);
2954         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2955         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2956         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2957         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2958
2959         return TRUE;
2960 }
2961
2962 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2963 {
2964         entity e;
2965         float sz;
2966         e = spawn();
2967         e.classname = "modeleffect";
2968         setmodel(e, m);
2969         e.frame = f;
2970         setorigin(e, o);
2971         e.velocity = v;
2972         e.angles = ang;
2973         e.avelocity = angv;
2974         e.alpha = a;
2975         e.teleport_time = t1;
2976         e.fade_time = t2;
2977         e.skin = s;
2978         if(s0 >= 0)
2979                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2980         else
2981                 e.scale = -s0;
2982         if(s2 >= 0)
2983                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2984         else
2985                 e.scale2 = -s2;
2986         sz = max(e.scale, e.scale2);
2987         setsize(e, e.mins * sz, e.maxs * sz);
2988         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2989 }
2990
2991 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2992 {
2993         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2994 }
2995
2996 float randombit(float bits)
2997 {
2998         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2999                 return bits;
3000
3001         float n, f, b, r;
3002
3003         r = random();
3004         b = 0;
3005         n = 0;
3006
3007         for(f = 1; f <= bits; f *= 2)
3008         {
3009                 if(bits & f)
3010                 {
3011                         ++n;
3012                         r *= n;
3013                         if(r <= 1)
3014                                 b = f;
3015                         else
3016                                 r = (r - 1) / (n - 1);
3017                 }
3018         }
3019
3020         return b;
3021 }
3022
3023 float randombits(float bits, float k, float error_return)
3024 {
3025         float r;
3026         r = 0;
3027         while(k > 0 && bits != r)
3028         {
3029                 r += randombit(bits - r);
3030                 --k;
3031         }
3032         if(error_return)
3033                 if(k > 0)
3034                         return -1; // all
3035         return r;
3036 }
3037
3038 void randombit_test(float bits, float iter)
3039 {
3040         while(iter > 0)
3041         {
3042                 print(ftos(randombit(bits)), "\n");
3043                 --iter;
3044         }
3045 }
3046
3047 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3048 {
3049         if(halflifedist > 0)
3050                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3051         else if(halflifedist < 0)
3052                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3053         else
3054                 return 1;
3055 }
3056
3057
3058
3059
3060 #ifdef RELEASE
3061 #define cvar_string_normal cvar_string_builtin
3062 #define cvar_normal cvar_builtin
3063 #else
3064 string cvar_string_normal(string n)
3065 {
3066         if not(cvar_type(n) & 1)
3067                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3068         return cvar_string_builtin(n);
3069 }
3070
3071 float cvar_normal(string n)
3072 {
3073         return stof(cvar_string_normal(n));
3074 }
3075 #endif
3076 #define cvar_set_normal cvar_set_builtin
3077
3078 void defer_think()
3079 {
3080     entity oself;
3081
3082     oself           = self;
3083     self            = self.owner;
3084     oself.think     = SUB_Remove;
3085     oself.nextthink = time;
3086
3087     oself.use();
3088 }
3089
3090 /*
3091     Execute func() after time + fdelay.
3092     self when func is executed = self when defer is called
3093 */
3094 void defer(float fdelay, void() func)
3095 {
3096     entity e;
3097
3098     e           = spawn();
3099     e.owner     = self;
3100     e.use       = func;
3101     e.think     = defer_think;
3102     e.nextthink = time + fdelay;
3103 }
3104
3105 .string aiment_classname;
3106 .float aiment_deadflag;
3107 void SetMovetypeFollow(entity ent, entity e)
3108 {
3109         // FIXME this may not be warpzone aware
3110         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3111         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3112         ent.aiment = e; // make the hole follow bmodel
3113         ent.punchangle = e.angles; // the original angles of bmodel
3114         ent.view_ofs = ent.origin - e.origin; // relative origin
3115         ent.v_angle = ent.angles - e.angles; // relative angles
3116         ent.aiment_classname = strzone(e.classname);
3117         ent.aiment_deadflag = e.deadflag;
3118 }
3119 void UnsetMovetypeFollow(entity ent)
3120 {
3121         ent.movetype = MOVETYPE_FLY;
3122         PROJECTILE_MAKETRIGGER(ent);
3123         ent.aiment = world;
3124 }
3125 float LostMovetypeFollow(entity ent)
3126 {
3127 /*
3128         if(ent.movetype != MOVETYPE_FOLLOW)
3129                 if(ent.aiment)
3130                         error("???");
3131 */
3132         if(ent.aiment)
3133         {
3134                 if(ent.aiment.classname != ent.aiment_classname)
3135                         return 1;
3136                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3137                         return 1;
3138         }
3139         return 0;
3140 }
3141
3142 float isPushable(entity e)
3143 {
3144         if(e.iscreature)
3145                 return TRUE;
3146         switch(e.classname)
3147         {
3148                 case "body":
3149                 case "droppedweapon":
3150                 case "keepawayball":
3151                 case "nexball_basketball":
3152                 case "nexball_football":
3153                         return TRUE;
3154                 case "bullet": // antilagged bullets can't hit this either
3155                         return FALSE;
3156         }
3157         if (e.projectiledeathtype)
3158                 return TRUE;
3159         return FALSE;
3160 }