qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = true;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, true, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = WEP_NAME(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else if (self.items & IT_PLASMA) replacement = "plasma";
 365                         else replacement = "batteries"; // ;)
 366                 } else if (escape == "x") {
 367                         replacement = cursor_ent.netname;
 368                         if (replacement == "" || !cursor_ent)
 369                                 replacement = "nothing";
 370                 } else if (escape == "s")
 371                         replacement = ftos(vlen(self.velocity - self.velocity.z * '0 0 1'));
 372                 else if (escape == "S")
 373                         replacement = ftos(vlen(self.velocity));
 374
 375                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 376                 p = p + strlen(replacement);
 377         }
 378         return msg;
 379 }
 380
 381 float boolean(float value) { // if value is 0 return false (0), otherwise return true (1)
 382         return (value == 0) ? false : true;
 383 }
 384
 385 /*
 386 =============
 387 GetCvars
 388 =============
 389 Called with:
 390   0:  sends the request
 391   >0: receives a cvar from name=argv(f) value=argv(f+1)
 392 */
 393 void GetCvars_handleString(string thisname, float f, .string field, string name)
 394 {
 395         if (f < 0)
 396         {
 397                 if (self.field)
 398                         strunzone(self.field);
 399                 self.field = string_null;
 400         }
 401         else if (f > 0)
 402         {
 403                 if (thisname == name)
 404                 {
 405                         if (self.field)
 406                                 strunzone(self.field);
 407                         self.field = strzone(argv(f + 1));
 408                 }
 409         }
 410         else
 411                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 412 }
 413 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 414 {
 415         GetCvars_handleString(thisname, f, field, name);
 416         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 417                 if (thisname == name)
 418                 {
 419                         string s;
 420                         s = func(strcat1(self.field));
 421                         if (s != self.field)
 422                         {
 423                                 strunzone(self.field);
 424                                 self.field = strzone(s);
 425                         }
 426                 }
 427 }
 428 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 429 {
 430         if (f < 0)
 431         {
 432         }
 433         else if (f > 0)
 434         {
 435                 if (thisname == name)
 436                         self.field = stof(argv(f + 1));
 437         }
 438         else
 439                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 440 }
 441 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 442 {
 443         if (f < 0)
 444         {
 445         }
 446         else if (f > 0)
 447         {
 448                 if (thisname == name)
 449                 {
 450                         if(!self.field)
 451                         {
 452                                 self.field = stof(argv(f + 1));
 453                                 if(!self.field)
 454                                         self.field = -1;
 455                         }
 456                 }
 457         }
 458         else
 459         {
 460                 if(!self.field)
 461                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462         }
 463 }
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 493         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 494         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 495         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 507         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 508         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 509         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 511         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 513         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 514
 515         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 516         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 517
 518         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 520         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 521         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 522         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 523
 524         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 525         if (f > 0)
 526         {
 527                 if (s == "cl_weaponpriority")
 528                         self.switchweapon = w_getbestweapon(self);
 529                 if (s == "cl_allow_uidtracking")
 530                         PlayerStats_GameReport_AddPlayer(self);
 531         }
 532 }
 533
 534 // decolorizes and team colors the player name when needed
 535 string playername(entity p)
 536 {
 537     string t;
 538     if (teamplay && !intermission_running && IS_PLAYER(p))
 539     {
 540         t = Team_ColorCode(p.team);
 541         return strcat(t, strdecolorize(p.netname));
 542     }
 543     else
 544         return p.netname;
 545 }
 546
 547 vector randompos(vector m1, vector m2)
 548 {
 549     vector v;
 550     m2 = m2 - m1;
 551     v_x = m2_x * random() + m1_x;
 552     v_y = m2_y * random() + m1_y;
 553     v_z = m2_z * random() + m1_z;
 554     return  v;
 555 }
 556
 557 //#NO AUTOCVARS START
 558
 559 float g_pickup_shells;
 560 float g_pickup_shells_max;
 561 float g_pickup_nails;
 562 float g_pickup_nails_max;
 563 float g_pickup_rockets;
 564 float g_pickup_rockets_max;
 565 float g_pickup_cells;
 566 float g_pickup_cells_max;
 567 float g_pickup_plasma;
 568 float g_pickup_plasma_max;
 569 float g_pickup_fuel;
 570 float g_pickup_fuel_jetpack;
 571 float g_pickup_fuel_max;
 572 float g_pickup_armorsmall;
 573 float g_pickup_armorsmall_max;
 574 float g_pickup_armorsmall_anyway;
 575 float g_pickup_armormedium;
 576 float g_pickup_armormedium_max;
 577 float g_pickup_armormedium_anyway;
 578 float g_pickup_armorbig;
 579 float g_pickup_armorbig_max;
 580 float g_pickup_armorbig_anyway;
 581 float g_pickup_armorlarge;
 582 float g_pickup_armorlarge_max;
 583 float g_pickup_armorlarge_anyway;
 584 float g_pickup_healthsmall;
 585 float g_pickup_healthsmall_max;
 586 float g_pickup_healthsmall_anyway;
 587 float g_pickup_healthmedium;
 588 float g_pickup_healthmedium_max;
 589 float g_pickup_healthmedium_anyway;
 590 float g_pickup_healthlarge;
 591 float g_pickup_healthlarge_max;
 592 float g_pickup_healthlarge_anyway;
 593 float g_pickup_healthmega;
 594 float g_pickup_healthmega_max;
 595 float g_pickup_healthmega_anyway;
 596 float g_pickup_ammo_anyway;
 597 float g_pickup_weapons_anyway;
 598 float g_weaponarena;
 599 WepSet g_weaponarena_weapons;
 600 float g_weaponarena_random;
 601 float g_weaponarena_random_with_blaster;
 602 string g_weaponarena_list;
 603 float g_weaponspeedfactor;
 604 float g_weaponratefactor;
 605 float g_weapondamagefactor;
 606 float g_weaponforcefactor;
 607 float g_weaponspreadfactor;
 608
 609 WepSet start_weapons;
 610 WepSet start_weapons_default;
 611 WepSet start_weapons_defaultmask;
 612 float start_items;
 613 float start_ammo_shells;
 614 float start_ammo_nails;
 615 float start_ammo_rockets;
 616 float start_ammo_cells;
 617 float start_ammo_plasma;
 618 float start_ammo_fuel;
 619 float start_health;
 620 float start_armorvalue;
 621 WepSet warmup_start_weapons;
 622 WepSet warmup_start_weapons_default;
 623 WepSet warmup_start_weapons_defaultmask;
 624 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 625 float warmup_start_ammo_shells;
 626 float warmup_start_ammo_nails;
 627 float warmup_start_ammo_rockets;
 628 float warmup_start_ammo_cells;
 629 float warmup_start_ammo_plasma;
 630 float warmup_start_ammo_fuel;
 631 float warmup_start_health;
 632 float warmup_start_armorvalue;
 633 float g_weapon_stay;
 634
 635 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 636 {
 637         float i = weaponinfo.weapon;
 638         float d = 0;
 639
 640         if (!i)
 641                 return 0;
 642
 643         if (g_lms || g_ca || allguns)
 644         {
 645                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 646                         d = true;
 647                 else
 648                         d = false;
 649         }
 650         else if (g_cts)
 651                 d = (i == WEP_SHOTGUN);
 652         else if (g_nexball)
 653                 d = 0; // weapon is set a few lines later
 654         else
 655                 d = !(!weaponinfo.weaponstart);
 656
 657         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 658                 d |= (i == WEP_HOOK);
 659         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 660                 d = 0;
 661
 662         float t = weaponinfo.weaponstartoverride;
 663
 664         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 665
 666         // bit order in t:
 667         // 1: want or not
 668         // 2: is default?
 669         // 4: is set by default?
 670         if(t < 0)
 671                 t = 4 | (3 * d);
 672         else
 673                 t |= (2 * d);
 674
 675         return t;
 676 }
 677
 678 void readplayerstartcvars()
 679 {
 680         entity e;
 681         float i, j, t;
 682         string s;
 683
 684         // initialize starting values for players
 685         start_weapons = '0 0 0';
 686         start_weapons_default = '0 0 0';
 687         start_weapons_defaultmask = '0 0 0';
 688         start_items = 0;
 689         start_ammo_shells = 0;
 690         start_ammo_nails = 0;
 691         start_ammo_rockets = 0;
 692         start_ammo_cells = 0;
 693         start_ammo_plasma = 0;
 694         start_health = cvar("g_balance_health_start");
 695         start_armorvalue = cvar("g_balance_armor_start");
 696
 697         g_weaponarena = 0;
 698         g_weaponarena_weapons = '0 0 0';
 699
 700         s = cvar_string("g_weaponarena");
 701         if (s == "0" || s == "")
 702         {
 703                 if(g_ca)
 704                         s = "most";
 705         }
 706
 707         if (s == "0" || s == "")
 708         {
 709                 // no arena
 710         }
 711         else if (s == "off")
 712         {
 713                 // forcibly turn off weaponarena
 714         }
 715         else if (s == "all" || s == "1")
 716         {
 717                 g_weaponarena = 1;
 718                 g_weaponarena_list = "All Weapons";
 719                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 720                 {
 721                         e = get_weaponinfo(j);
 722                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 723                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 724                 }
 725         }
 726         else if (s == "most")
 727         {
 728                 g_weaponarena = 1;
 729                 g_weaponarena_list = "Most Weapons";
 730                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 731                 {
 732                         e = get_weaponinfo(j);
 733                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 734                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 735                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 736                 }
 737         }
 738         else if (s == "none")
 739         {
 740                 g_weaponarena = 1;
 741                 g_weaponarena_list = "No Weapons";
 742         }
 743         else
 744         {
 745                 g_weaponarena = 1;
 746                 t = tokenize_console(s);
 747                 g_weaponarena_list = "";
 748                 for (i = 0; i < t; ++i)
 749                 {
 750                         s = argv(i);
 751                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 752                         {
 753                                 e = get_weaponinfo(j);
 754                                 if (e.netname == s)
 755                                 {
 756                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 757                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 758                                         break;
 759                                 }
 760                         }
 761                         if (j > WEP_LAST)
 762                         {
 763                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 764                         }
 765                 }
 766                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 767         }
 768
 769         if(g_weaponarena)
 770                 g_weaponarena_random = cvar("g_weaponarena_random");
 771         else
 772                 g_weaponarena_random = 0;
 773         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 774
 775         if (g_weaponarena)
 776         {
 777                 g_weapon_stay = 0; // incompatible
 778                 start_weapons = g_weaponarena_weapons;
 779                 start_items |= IT_UNLIMITED_AMMO;
 780         }
 781         else
 782         {
 783                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 784                 {
 785                         e = get_weaponinfo(i);
 786                         float w = want_weapon(e, false);
 787                         if(w & 1)
 788                                 start_weapons |= WepSet_FromWeapon(i);
 789                         if(w & 2)
 790                                 start_weapons_default |= WepSet_FromWeapon(i);
 791                         if(w & 4)
 792                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 793                 }
 794         }
 795
 796         if(!cvar("g_use_ammunition"))
 797                 start_items |= IT_UNLIMITED_AMMO;
 798
 799         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 800         {
 801                 start_ammo_shells = 999;
 802                 start_ammo_nails = 999;
 803                 start_ammo_rockets = 999;
 804                 start_ammo_cells = 999;
 805                 start_ammo_plasma = 999;
 806                 start_ammo_fuel = 999;
 807         }
 808         else
 809         {
 810                 start_ammo_shells = cvar("g_start_ammo_shells");
 811                 start_ammo_nails = cvar("g_start_ammo_nails");
 812                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 813                 start_ammo_cells = cvar("g_start_ammo_cells");
 814                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 815                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 816         }
 817
 818         if (warmup_stage)
 819         {
 820                 warmup_start_ammo_shells = start_ammo_shells;
 821                 warmup_start_ammo_nails = start_ammo_nails;
 822                 warmup_start_ammo_rockets = start_ammo_rockets;
 823                 warmup_start_ammo_cells = start_ammo_cells;
 824                 warmup_start_ammo_plasma = start_ammo_plasma;
 825                 warmup_start_ammo_fuel = start_ammo_fuel;
 826                 warmup_start_health = start_health;
 827                 warmup_start_armorvalue = start_armorvalue;
 828                 warmup_start_weapons = start_weapons;
 829                 warmup_start_weapons_default = start_weapons_default;
 830                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 831
 832                 if (!g_weaponarena && !g_ca)
 833                 {
 834                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 835                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 836                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 837                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 838                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 839                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 840                         warmup_start_health = cvar("g_warmup_start_health");
 841                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 842                         warmup_start_weapons = '0 0 0';
 843                         warmup_start_weapons_default = '0 0 0';
 844                         warmup_start_weapons_defaultmask = '0 0 0';
 845                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 846                         {
 847                                 e = get_weaponinfo(i);
 848                                 float w = want_weapon(e, g_warmup_allguns);
 849                                 if(w & 1)
 850                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 851                                 if(w & 2)
 852                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 853                                 if(w & 4)
 854                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 855                         }
 856                 }
 857         }
 858
 859         if (g_jetpack)
 860                 start_items |= IT_JETPACK;
 861
 862         MUTATOR_CALLHOOK(SetStartItems);
 863
 864         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 865         {
 866                 start_items |= IT_FUEL_REGEN;
 867                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 868                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 869         }
 870
 871         WepSet precache_weapons = start_weapons;
 872         if (g_warmup_allguns != 1)
 873                 precache_weapons |= warmup_start_weapons;
 874         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 875         {
 876                 e = get_weaponinfo(i);
 877                 if(precache_weapons & WepSet_FromWeapon(i))
 878                         WEP_ACTION(i, WR_INIT);
 879         }
 880
 881         start_ammo_shells = max(0, start_ammo_shells);
 882         start_ammo_nails = max(0, start_ammo_nails);
 883         start_ammo_rockets = max(0, start_ammo_rockets);
 884         start_ammo_cells = max(0, start_ammo_cells);
 885         start_ammo_plasma = max(0, start_ammo_plasma);
 886         start_ammo_fuel = max(0, start_ammo_fuel);
 887
 888         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 889         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 890         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 891         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 892         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 893         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 894 }
 895
 896 float g_bugrigs;
 897 float g_bugrigs_planar_movement;
 898 float g_bugrigs_planar_movement_car_jumping;
 899 float g_bugrigs_reverse_spinning;
 900 float g_bugrigs_reverse_speeding;
 901 float g_bugrigs_reverse_stopping;
 902 float g_bugrigs_air_steering;
 903 float g_bugrigs_angle_smoothing;
 904 float g_bugrigs_friction_floor;
 905 float g_bugrigs_friction_brake;
 906 float g_bugrigs_friction_air;
 907 float g_bugrigs_accel;
 908 float g_bugrigs_speed_ref;
 909 float g_bugrigs_speed_pow;
 910 float g_bugrigs_steer;
 911
 912 float sv_autotaunt;
 913 float sv_taunt;
 914
 915 string GetGametype(); // g_world.qc
 916 void mutators_add(); // mutators.qc
 917 void readlevelcvars(void)
 918 {
 919         // load mutators
 920         mutators_add();
 921
 922         if(cvar("sv_allow_fullbright"))
 923                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 924
 925     g_bugrigs = cvar("g_bugrigs");
 926     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 927     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 928     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 929     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 930     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 931     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 932     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 933     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 934     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 935     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 936     g_bugrigs_accel = cvar("g_bugrigs_accel");
 937     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 938     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 939     g_bugrigs_steer = cvar("g_bugrigs_steer");
 940
 941         g_instagib = cvar("g_instagib");
 942
 943         sv_clones = cvar("sv_clones");
 944         sv_foginterval = cvar("sv_foginterval");
 945         g_cloaked = cvar("g_cloaked");
 946         g_footsteps = cvar("g_footsteps");
 947         g_grappling_hook = cvar("g_grappling_hook");
 948         g_jetpack = cvar("g_jetpack");
 949         sv_maxidle = cvar("sv_maxidle");
 950         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 951         sv_autotaunt = cvar("sv_autotaunt");
 952         sv_taunt = cvar("sv_taunt");
 953
 954         warmup_stage = cvar("g_warmup");
 955         g_warmup_limit = cvar("g_warmup_limit");
 956         g_warmup_allguns = cvar("g_warmup_allguns");
 957         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 958
 959         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 960                 warmup_stage = 0; // these modes cannot work together, sorry
 961
 962         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 963         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 964         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 965         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 966         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 967         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 968         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 969         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 970         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 971         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 972         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 973         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 974         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 975         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 976
 977         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 978         g_weaponratefactor = cvar("g_weaponratefactor");
 979         g_weapondamagefactor = cvar("g_weapondamagefactor");
 980         g_weaponforcefactor = cvar("g_weaponforcefactor");
 981         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 982
 983         g_pickup_shells = cvar("g_pickup_shells");
 984         g_pickup_shells_max = cvar("g_pickup_shells_max");
 985         g_pickup_nails = cvar("g_pickup_nails");
 986         g_pickup_nails_max = cvar("g_pickup_nails_max");
 987         g_pickup_rockets = cvar("g_pickup_rockets");
 988         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 989         g_pickup_cells = cvar("g_pickup_cells");
 990         g_pickup_cells_max = cvar("g_pickup_cells_max");
 991         g_pickup_plasma = cvar("g_pickup_plasma");
 992         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 993         g_pickup_fuel = cvar("g_pickup_fuel");
 994         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 995         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 996         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 997         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 998         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 999         g_pickup_armormedium = cvar("g_pickup_armormedium");
1000         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1001         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1002         g_pickup_armorbig = cvar("g_pickup_armorbig");
1003         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1004         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1005         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1006         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1007         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1008         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1009         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1010         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1011         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1012         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1013         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1014         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1015         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1016         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1017         g_pickup_healthmega = cvar("g_pickup_healthmega");
1018         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1019         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1020
1021         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1022         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1023
1024     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1025     if(!g_weapon_stay)
1026         g_weapon_stay = cvar("g_weapon_stay");
1027
1028         if (!warmup_stage)
1029                 game_starttime = time + cvar("g_start_delay");
1030
1031         readplayerstartcvars();
1032 }
1033
1034 //#NO AUTOCVARS END
1035
1036 // Sound functions
1037 string precache_sound (string s) = #19;
1038 float precache_sound_index (string s) = #19;
1039
1040 const float SND_VOLUME = 1;
1041 const float SND_ATTENUATION = 2;
1042 const float SND_LARGEENTITY = 8;
1043 const float SND_LARGESOUND = 16;
1044
1045 float sound_allowed(float dest, entity e)
1046 {
1047     // sounds from world may always pass
1048     for(0;;)
1049     {
1050         if (e.classname == "body")
1051             e = e.enemy;
1052         else if (e.realowner && e.realowner != e)
1053             e = e.realowner;
1054         else if (e.owner && e.owner != e)
1055             e = e.owner;
1056         else
1057             break;
1058     }
1059     // sounds to self may always pass
1060     if (dest == MSG_ONE)
1061         if (e == msg_entity)
1062             return true;
1063     // sounds by players can be removed
1064     if (autocvar_bot_sound_monopoly)
1065         if (IS_REAL_CLIENT(e))
1066             return false;
1067     // anything else may pass
1068     return true;
1069 }
1070
1071 #undef sound
1072 void sound(entity e, float chan, string samp, float vol, float atten)
1073 {
1074     if (!sound_allowed(MSG_BROADCAST, e))
1075         return;
1076     sound7(e, chan, samp, vol, atten, 0, 0);
1077 }
1078
1079 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1080 {
1081     float entno, idx;
1082
1083     if (!sound_allowed(dest, e))
1084         return;
1085
1086     entno = num_for_edict(e);
1087     idx = precache_sound_index(samp);
1088
1089     float sflags;
1090     sflags = 0;
1091
1092     atten = floor(atten * 64);
1093     vol = floor(vol * 255);
1094
1095     if (vol != 255)
1096         sflags |= SND_VOLUME;
1097     if (atten != 64)
1098         sflags |= SND_ATTENUATION;
1099     if (entno >= 8192 || chan < 0 || chan > 7)
1100         sflags |= SND_LARGEENTITY;
1101     if (idx >= 256)
1102         sflags |= SND_LARGESOUND;
1103
1104     WriteByte(dest, SVC_SOUND);
1105     WriteByte(dest, sflags);
1106     if (sflags & SND_VOLUME)
1107         WriteByte(dest, vol);
1108     if (sflags & SND_ATTENUATION)
1109         WriteByte(dest, atten);
1110     if (sflags & SND_LARGEENTITY)
1111     {
1112         WriteShort(dest, entno);
1113         WriteByte(dest, chan);
1114     }
1115     else
1116     {
1117         WriteShort(dest, entno * 8 + chan);
1118     }
1119     if (sflags & SND_LARGESOUND)
1120         WriteShort(dest, idx);
1121     else
1122         WriteByte(dest, idx);
1123
1124     WriteCoord(dest, o.x);
1125     WriteCoord(dest, o.y);
1126     WriteCoord(dest, o.z);
1127 }
1128 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1129 {
1130     vector o;
1131
1132     if (!sound_allowed(dest, e))
1133         return;
1134
1135     o = e.origin + 0.5 * (e.mins + e.maxs);
1136     soundtoat(dest, e, o, chan, samp, vol, atten);
1137 }
1138 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1139 {
1140     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1141 }
1142 void stopsoundto(float dest, entity e, float chan)
1143 {
1144     float entno;
1145
1146     if (!sound_allowed(dest, e))
1147         return;
1148
1149     entno = num_for_edict(e);
1150
1151     if (entno >= 8192 || chan < 0 || chan > 7)
1152     {
1153         float idx, sflags;
1154         idx = precache_sound_index("misc/null.wav");
1155         sflags = SND_LARGEENTITY;
1156         if (idx >= 256)
1157             sflags |= SND_LARGESOUND;
1158         WriteByte(dest, SVC_SOUND);
1159         WriteByte(dest, sflags);
1160         WriteShort(dest, entno);
1161         WriteByte(dest, chan);
1162         if (sflags & SND_LARGESOUND)
1163             WriteShort(dest, idx);
1164         else
1165             WriteByte(dest, idx);
1166         WriteCoord(dest, e.origin.x);
1167         WriteCoord(dest, e.origin.y);
1168         WriteCoord(dest, e.origin.z);
1169     }
1170     else
1171     {
1172         WriteByte(dest, SVC_STOPSOUND);
1173         WriteShort(dest, entno * 8 + chan);
1174     }
1175 }
1176 void stopsound(entity e, float chan)
1177 {
1178     if (!sound_allowed(MSG_BROADCAST, e))
1179         return;
1180
1181     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1182     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1183 }
1184
1185 void play2(entity e, string filename)
1186 {
1187     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1188     msg_entity = e;
1189     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1190 }
1191
1192 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1193 .float spamtime;
1194 float spamsound(entity e, float chan, string samp, float vol, float atten)
1195 {
1196     if (!sound_allowed(MSG_BROADCAST, e))
1197         return false;
1198
1199     if (time > e.spamtime)
1200     {
1201         e.spamtime = time;
1202         sound(e, chan, samp, vol, atten);
1203         return true;
1204     }
1205     return false;
1206 }
1207
1208 void play2team(float t, string filename)
1209 {
1210     entity head;
1211
1212     if (autocvar_bot_sound_monopoly)
1213         return;
1214
1215     FOR_EACH_REALPLAYER(head)
1216     {
1217         if (head.team == t)
1218             play2(head, filename);
1219     }
1220 }
1221
1222 void play2all(string samp)
1223 {
1224     if (autocvar_bot_sound_monopoly)
1225         return;
1226
1227     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1228 }
1229
1230 void PrecachePlayerSounds(string f);
1231 void precache_playermodel(string m)
1232 {
1233         float globhandle, i, n;
1234         string f;
1235
1236         if(substring(m, -9,5) == "_lod1")
1237                 return;
1238         if(substring(m, -9,5) == "_lod2")
1239                 return;
1240         precache_model(m);
1241         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1242         if(fexists(f))
1243                 precache_model(f);
1244         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1245         if(fexists(f))
1246                 precache_model(f);
1247
1248         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
1249         if (globhandle < 0)
1250                 return;
1251         n = search_getsize(globhandle);
1252         for (i = 0; i < n; ++i)
1253         {
1254                 //print(search_getfilename(globhandle, i), "\n");
1255                 f = search_getfilename(globhandle, i);
1256                 PrecachePlayerSounds(f);
1257         }
1258         search_end(globhandle);
1259 }
1260 void precache_all_playermodels(string pattern)
1261 {
1262         float globhandle, i, n;
1263         string f;
1264
1265         globhandle = search_begin(pattern, true, false);
1266         if (globhandle < 0)
1267                 return;
1268         n = search_getsize(globhandle);
1269         for (i = 0; i < n; ++i)
1270         {
1271                 //print(search_getfilename(globhandle, i), "\n");
1272                 f = search_getfilename(globhandle, i);
1273                 precache_playermodel(f);
1274         }
1275         search_end(globhandle);
1276 }
1277
1278 void precache()
1279 {
1280     // gamemode related things
1281     precache_model ("models/misc/chatbubble.spr");
1282         precache_model("models/ice/ice.md3");
1283
1284 #ifdef TTURRETS_ENABLED
1285     if (autocvar_g_turrets)
1286         turrets_precash();
1287 #endif
1288
1289     // Precache all player models if desired
1290     if (autocvar_sv_precacheplayermodels)
1291     {
1292         PrecachePlayerSounds("sound/player/default.sounds");
1293         precache_all_playermodels("models/player/*.zym");
1294         precache_all_playermodels("models/player/*.dpm");
1295         precache_all_playermodels("models/player/*.md3");
1296         precache_all_playermodels("models/player/*.psk");
1297         precache_all_playermodels("models/player/*.iqm");
1298     }
1299
1300     if (autocvar_sv_defaultcharacter)
1301     {
1302         string s;
1303         s = autocvar_sv_defaultplayermodel_red;
1304         if (s != "")
1305             precache_playermodel(s);
1306         s = autocvar_sv_defaultplayermodel_blue;
1307         if (s != "")
1308             precache_playermodel(s);
1309         s = autocvar_sv_defaultplayermodel_yellow;
1310         if (s != "")
1311             precache_playermodel(s);
1312         s = autocvar_sv_defaultplayermodel_pink;
1313         if (s != "")
1314             precache_playermodel(s);
1315         s = autocvar_sv_defaultplayermodel;
1316         if (s != "")
1317             precache_playermodel(s);
1318     }
1319
1320     if (g_footsteps)
1321     {
1322         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1323         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1324     }
1325
1326     // gore and miscellaneous sounds
1327     //precache_sound ("misc/h2ohit.wav");
1328     precache_model ("models/hook.md3");
1329     precache_sound ("misc/armorimpact.wav");
1330     precache_sound ("misc/bodyimpact1.wav");
1331     precache_sound ("misc/bodyimpact2.wav");
1332     precache_sound ("misc/gib.wav");
1333     precache_sound ("misc/gib_splat01.wav");
1334     precache_sound ("misc/gib_splat02.wav");
1335     precache_sound ("misc/gib_splat03.wav");
1336     precache_sound ("misc/gib_splat04.wav");
1337     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1338     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1339     precache_sound ("misc/null.wav");
1340     precache_sound ("misc/spawn.wav");
1341     precache_sound ("misc/talk.wav");
1342     precache_sound ("misc/teleport.wav");
1343     precache_sound ("misc/poweroff.wav");
1344     precache_sound ("player/lava.wav");
1345     precache_sound ("player/slime.wav");
1346
1347     precache_model ("models/sprites/0.spr32");
1348     precache_model ("models/sprites/1.spr32");
1349     precache_model ("models/sprites/2.spr32");
1350     precache_model ("models/sprites/3.spr32");
1351     precache_model ("models/sprites/4.spr32");
1352     precache_model ("models/sprites/5.spr32");
1353     precache_model ("models/sprites/6.spr32");
1354     precache_model ("models/sprites/7.spr32");
1355     precache_model ("models/sprites/8.spr32");
1356     precache_model ("models/sprites/9.spr32");
1357     precache_model ("models/sprites/10.spr32");
1358
1359     // common weapon precaches
1360         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1361     precache_sound ("weapons/weapon_switch.wav");
1362     precache_sound ("weapons/weaponpickup.wav");
1363     precache_sound ("weapons/unavailable.wav");
1364     precache_sound ("weapons/dryfire.wav");
1365     if (g_grappling_hook)
1366     {
1367         precache_sound ("weapons/hook_fire.wav"); // hook
1368         precache_sound ("weapons/hook_impact.wav"); // hook
1369     }
1370
1371     precache_model("models/elaser.mdl");
1372     precache_model("models/laser.mdl");
1373     precache_model("models/ebomb.mdl");
1374
1375 #if 0
1376     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1377
1378     if (!self.noise && self.music) // quake 3 uses the music field
1379         self.noise = self.music;
1380
1381     // plays music for the level if there is any
1382     if (self.noise)
1383     {
1384         precache_sound (self.noise);
1385         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1386     }
1387 #endif
1388
1389 #include "precache-for-csqc.inc"
1390 }
1391
1392 // WARNING: this kills the trace globals
1393 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1394 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1395
1396 const float INITPRIO_FIRST                              = 0;
1397 const float INITPRIO_GAMETYPE                   = 0;
1398 const float INITPRIO_GAMETYPE_FALLBACK  = 1;
1399 const float INITPRIO_FINDTARGET                 = 10;
1400 const float INITPRIO_DROPTOFLOOR                = 20;
1401 const float INITPRIO_SETLOCATION                = 90;
1402 const float INITPRIO_LINKDOORS                  = 91;
1403 const float INITPRIO_LAST                               = 99;
1404
1405 .void(void) initialize_entity;
1406 .float initialize_entity_order;
1407 .entity initialize_entity_next;
1408 entity initialize_entity_first;
1409
1410 void make_safe_for_remove(entity e)
1411 {
1412     if (e.initialize_entity)
1413     {
1414         entity ent, prev = world;
1415         for (ent = initialize_entity_first; ent; )
1416         {
1417             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1418             {
1419                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1420                 // skip it in linked list
1421                 if (prev)
1422                 {
1423                     prev.initialize_entity_next = ent.initialize_entity_next;
1424                     ent = prev.initialize_entity_next;
1425                 }
1426                 else
1427                 {
1428                     initialize_entity_first = ent.initialize_entity_next;
1429                     ent = initialize_entity_first;
1430                 }
1431             }
1432             else
1433             {
1434                 prev = ent;
1435                 ent = ent.initialize_entity_next;
1436             }
1437         }
1438     }
1439 }
1440
1441 void objerror(string s)
1442 {
1443     make_safe_for_remove(self);
1444     builtin_objerror(s);
1445 }
1446
1447 .float remove_except_protected_forbidden;
1448 void remove_except_protected(entity e)
1449 {
1450         if(e.remove_except_protected_forbidden)
1451                 error("not allowed to remove this at this point");
1452         builtin_remove(e);
1453 }
1454
1455 void remove_unsafely(entity e)
1456 {
1457     if(e.classname == "spike")
1458         error("Removing spikes is forbidden (crylink bug), please report");
1459     builtin_remove(e);
1460 }
1461
1462 void remove_safely(entity e)
1463 {
1464     make_safe_for_remove(e);
1465     builtin_remove(e);
1466 }
1467
1468 void InitializeEntity(entity e, void(void) func, float order)
1469 {
1470     entity prev, cur;
1471
1472     if (!e || e.initialize_entity)
1473     {
1474         // make a proxy initializer entity
1475         entity e_old;
1476         e_old = e;
1477         e = spawn();
1478         e.classname = "initialize_entity";
1479         e.enemy = e_old;
1480     }
1481
1482     e.initialize_entity = func;
1483     e.initialize_entity_order = order;
1484
1485     cur = initialize_entity_first;
1486     prev = world;
1487     for(0;;)
1488     {
1489         if (!cur || cur.initialize_entity_order > order)
1490         {
1491             // insert between prev and cur
1492             if (prev)
1493                 prev.initialize_entity_next = e;
1494             else
1495                 initialize_entity_first = e;
1496             e.initialize_entity_next = cur;
1497             return;
1498         }
1499         prev = cur;
1500         cur = cur.initialize_entity_next;
1501     }
1502 }
1503 void InitializeEntitiesRun()
1504 {
1505     entity startoflist;
1506     startoflist = initialize_entity_first;
1507     initialize_entity_first = world;
1508     remove = remove_except_protected;
1509     for (self = startoflist; self; self = self.initialize_entity_next)
1510     {
1511         self.remove_except_protected_forbidden = 1;
1512     }
1513     for (self = startoflist; self; )
1514     {
1515         entity e;
1516         var void(void) func;
1517         e = self.initialize_entity_next;
1518         func = self.initialize_entity;
1519         self.initialize_entity_order = 0;
1520         self.initialize_entity = func_null;
1521         self.initialize_entity_next = world;
1522         self.remove_except_protected_forbidden = 0;
1523         if (self.classname == "initialize_entity")
1524         {
1525             entity e_old;
1526             e_old = self.enemy;
1527             builtin_remove(self);
1528             self = e_old;
1529         }
1530         //dprint("Delayed initialization: ", self.classname, "\n");
1531         if(func)
1532             func();
1533         else
1534         {
1535             eprint(self);
1536             backtrace(strcat("Null function in: ", self.classname, "\n"));
1537         }
1538         self = e;
1539     }
1540     remove = remove_unsafely;
1541 }
1542
1543 .float uncustomizeentityforclient_set;
1544 .void(void) uncustomizeentityforclient;
1545 void UncustomizeEntitiesRun()
1546 {
1547     entity oldself;
1548     oldself = self;
1549     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1550         self.uncustomizeentityforclient();
1551     self = oldself;
1552 }
1553 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1554 {
1555     e.customizeentityforclient = customizer;
1556     e.uncustomizeentityforclient = uncustomizer;
1557     e.uncustomizeentityforclient_set = !!uncustomizer;
1558 }
1559
1560 .float nottargeted;
1561 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1562
1563 void() SUB_Remove;
1564 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1565 {
1566     vector mi, ma;
1567
1568     if (e.classname == "")
1569         e.classname = "net_linked";
1570
1571     if (e.model == "" || self.modelindex == 0)
1572     {
1573         mi = e.mins;
1574         ma = e.maxs;
1575         setmodel(e, "null");
1576         setsize(e, mi, ma);
1577     }
1578
1579     e.SendEntity = sendfunc;
1580     e.SendFlags = 0xFFFFFF;
1581
1582     if (!docull)
1583         e.effects |= EF_NODEPTHTEST;
1584
1585     if (dt)
1586     {
1587         e.nextthink = time + dt;
1588         e.think = SUB_Remove;
1589     }
1590 }
1591
1592
1593 entity eliminatedPlayers;
1594 .float(entity) isEliminated;
1595 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1596 {
1597         float i, f, b;
1598         entity e;
1599         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1600         WriteByte(MSG_ENTITY, sendflags);
1601
1602         if(sendflags & 1)
1603         {
1604                 for(i = 1; i <= maxclients; i += 8)
1605                 {
1606                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1607                         {
1608                                 if(eliminatedPlayers.isEliminated(e))
1609                                         f |= b;
1610                         }
1611                         WriteByte(MSG_ENTITY, f);
1612                 }
1613         }
1614
1615         return true;
1616 }
1617
1618 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1619 {
1620         if(eliminatedPlayers)
1621         {
1622                 backtrace("Can't spawn eliminatedPlayers again!");
1623                 return;
1624         }
1625         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1626         eliminatedPlayers.isEliminated = isEliminated_func;
1627 }
1628
1629
1630 void adaptor_think2touch()
1631 {
1632     entity o;
1633     o = other;
1634     other = world;
1635     self.touch();
1636     other = o;
1637 }
1638
1639 void adaptor_think2use()
1640 {
1641     entity o, a;
1642     o = other;
1643     a = activator;
1644     activator = world;
1645     other = world;
1646     self.use();
1647     other = o;
1648     activator = a;
1649 }
1650
1651 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1652 {
1653         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1654                 self.projectiledeathtype |= HITTYPE_SPLASH;
1655         adaptor_think2use();
1656 }
1657
1658 // deferred dropping
1659 void DropToFloor_Handler()
1660 {
1661     builtin_droptofloor();
1662     self.dropped_origin = self.origin;
1663 }
1664
1665 void droptofloor()
1666 {
1667     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1668 }
1669
1670
1671
1672 float trace_hits_box_a0, trace_hits_box_a1;
1673
1674 float trace_hits_box_1d(float end, float thmi, float thma)
1675 {
1676     if (end == 0)
1677     {
1678         // just check if x is in range
1679         if (0 < thmi)
1680             return false;
1681         if (0 > thma)
1682             return false;
1683     }
1684     else
1685     {
1686         // do the trace with respect to x
1687         // 0 -> end has to stay in thmi -> thma
1688         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1689         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1690         if (trace_hits_box_a0 > trace_hits_box_a1)
1691             return false;
1692     }
1693     return true;
1694 }
1695
1696 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1697 {
1698     end -= start;
1699     thmi -= start;
1700     thma -= start;
1701     // now it is a trace from 0 to end
1702
1703     trace_hits_box_a0 = 0;
1704     trace_hits_box_a1 = 1;
1705
1706     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1707         return false;
1708     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1709         return false;
1710     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1711         return false;
1712
1713     return true;
1714 }
1715
1716 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1717 {
1718     return trace_hits_box(start, end, thmi - ma, thma - mi);
1719 }
1720
1721 float SUB_NoImpactCheck()
1722 {
1723         // zero hitcontents = this is not the real impact, but either the
1724         // mirror-impact of something hitting the projectile instead of the
1725         // projectile hitting the something, or a touchareagrid one. Neither of
1726         // these stop the projectile from moving, so...
1727         if(trace_dphitcontents == 0)
1728         {
1729                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1730                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1731                 checkclient();
1732         }
1733     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1734         return 1;
1735     if (other == world && self.size != '0 0 0')
1736     {
1737         vector tic;
1738         tic = self.velocity * sys_frametime;
1739         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1740         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1741         if (trace_fraction >= 1)
1742         {
1743             dprint("Odd... did not hit...?\n");
1744         }
1745         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1746         {
1747             dprint("Detected and prevented the sky-grapple bug.\n");
1748             return 1;
1749         }
1750     }
1751
1752     return 0;
1753 }
1754
1755 #define SUB_OwnerCheck() (other && (other == self.owner))
1756
1757 void RemoveGrapplingHook(entity pl);
1758 void W_Crylink_Dequeue(entity e);
1759 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1760 {
1761         if(SUB_OwnerCheck())
1762                 return true;
1763         if(SUB_NoImpactCheck())
1764         {
1765                 if(self.classname == "nade")
1766                         return false; // no checks here
1767                 else if(self.classname == "grapplinghook")
1768                         RemoveGrapplingHook(self.realowner);
1769                 else if(self.classname == "spike")
1770                 {
1771                         W_Crylink_Dequeue(self);
1772                         remove(self);
1773                 }
1774                 else
1775                         remove(self);
1776                 return true;
1777         }
1778         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1779                 UpdateCSQCProjectile(self);
1780         return false;
1781 }
1782 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1783
1784 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1785 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1786
1787 void URI_Get_Callback(float id, float status, string data)
1788 {
1789         if(url_URI_Get_Callback(id, status, data))
1790         {
1791                 // handled
1792         }
1793         else if (id == URI_GET_DISCARD)
1794         {
1795                 // discard
1796         }
1797         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1798         {
1799                 // sv_cmd curl
1800                 Curl_URI_Get_Callback(id, status, data);
1801         }
1802         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1803         {
1804                 // online ban list
1805                 OnlineBanList_URI_Get_Callback(id, status, data);
1806         }
1807         else
1808         {
1809                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1810         }
1811 }
1812
1813 string uid2name(string myuid) {
1814         string s;
1815         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1816
1817         // FIXME remove this later after 0.6 release
1818         // convert old style broken records to correct style
1819         if(s == "")
1820         {
1821                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1822                 if(s != "")
1823                 {
1824                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1825                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1826                 }
1827         }
1828
1829         if(s == "")
1830                 s = "^1Unregistered Player";
1831         return s;
1832 }
1833
1834 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1835 {
1836     float m, i;
1837     vector start, org, delta, end, enddown, mstart;
1838     entity sp;
1839
1840     m = e.dphitcontentsmask;
1841     e.dphitcontentsmask = goodcontents | badcontents;
1842
1843     org = world.mins;
1844     delta = world.maxs - world.mins;
1845
1846     start = end = org;
1847
1848     for (i = 0; i < attempts; ++i)
1849     {
1850         start_x = org.x + random() * delta.x;
1851         start_y = org.y + random() * delta.y;
1852         start_z = org.z + random() * delta.z;
1853
1854         // rule 1: start inside world bounds, and outside
1855         // solid, and don't start from somewhere where you can
1856         // fall down to evil
1857         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1858         if (trace_fraction >= 1)
1859             continue;
1860         if (trace_startsolid)
1861             continue;
1862         if (trace_dphitcontents & badcontents)
1863             continue;
1864         if (trace_dphitq3surfaceflags & badsurfaceflags)
1865             continue;
1866
1867         // rule 2: if we are too high, lower the point
1868         if (trace_fraction * delta.z > maxaboveground)
1869             start = trace_endpos + '0 0 1' * maxaboveground;
1870         enddown = trace_endpos;
1871
1872         // rule 3: make sure we aren't outside the map. This only works
1873         // for somewhat well formed maps. A good rule of thumb is that
1874         // the map should have a convex outside hull.
1875         // these can be traceLINES as we already verified the starting box
1876         mstart = start + 0.5 * (e.mins + e.maxs);
1877         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1878         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1879             continue;
1880         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1881         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1882             continue;
1883         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1884         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1885             continue;
1886         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1887         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1888             continue;
1889         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1890         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1891             continue;
1892
1893         // rule 4: we must "see" some spawnpoint or item
1894         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1895                 if(checkpvs(mstart, sp))
1896                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1897                                 break;
1898         if(!sp)
1899         {
1900                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1901                         if(checkpvs(mstart, sp))
1902                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1903                                         break;
1904                 if(!sp)
1905                         continue;
1906         }
1907
1908         // find a random vector to "look at"
1909         end_x = org.x + random() * delta.x;
1910         end_y = org.y + random() * delta.y;
1911         end_z = org.z + random() * delta.z;
1912         end = start + normalize(end - start) * vlen(delta);
1913
1914         // rule 4: start TO end must not be too short
1915         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1916         if (trace_startsolid)
1917             continue;
1918         if (trace_fraction < minviewdistance / vlen(delta))
1919             continue;
1920
1921         // rule 5: don't want to look at sky
1922         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1923             continue;
1924
1925         // rule 6: we must not end up in trigger_hurt
1926         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1927             continue;
1928
1929         break;
1930     }
1931
1932     e.dphitcontentsmask = m;
1933
1934     if (i < attempts)
1935     {
1936         setorigin(e, start);
1937         e.angles = vectoangles(end - start);
1938         dprint("Needed ", ftos(i + 1), " attempts\n");
1939         return true;
1940     }
1941     else
1942         return false;
1943 }
1944
1945 void write_recordmarker(entity pl, float tstart, float dt)
1946 {
1947     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1948
1949     // also write a marker into demo files for demotc-race-record-extractor to find
1950     stuffcmd(pl,
1951              strcat(
1952                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1953                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1954 }
1955
1956 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1957 {
1958         switch(algn)
1959         {
1960                 default:
1961                 case 3: // right
1962                         break;
1963
1964                 case 4: // left
1965                         vecs_y = -vecs.y;
1966                         break;
1967
1968                 case 1:
1969                         if(allowcenter) // 2: allow center handedness
1970                         {
1971                                 // center
1972                                 vecs_y = 0;
1973                                 vecs.z -= 2;
1974                         }
1975                         else
1976                         {
1977                                 // right
1978                         }
1979                         break;
1980
1981                 case 2:
1982                         if(allowcenter) // 2: allow center handedness
1983                         {
1984                                 // center
1985                                 vecs_y = 0;
1986                                 vecs.z -= 2;
1987                         }
1988                         else
1989                         {
1990                                 // left
1991                                 vecs_y = -vecs.y;
1992                         }
1993                         break;
1994         }
1995         return vecs;
1996 }
1997
1998 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1999 {
2000         string s;
2001         vector v;
2002
2003         if (autocvar_g_shootfromeye)
2004         {
2005                 if (visual)
2006                 {
2007                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2008                         else { vecs_y = 0; vecs.z -= 2; }
2009                 }
2010                 else
2011                 {
2012                         vecs_y = 0;
2013                         vecs_z = 0;
2014                 }
2015         }
2016         else if (autocvar_g_shootfromcenter)
2017         {
2018                 vecs_y = 0;
2019                 vecs.z -= 2;
2020         }
2021         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2022         {
2023                 v = stov(s);
2024                 if (y_is_right)
2025                         v_y = -v.y;
2026                 if (v.x != 0)
2027                         vecs_x = v.x;
2028                 vecs_y = v.y;
2029                 vecs_z = v.z;
2030         }
2031         else if (autocvar_g_shootfromclient)
2032         {
2033                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2034         }
2035         return vecs;
2036 }
2037
2038 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2039 {
2040         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2041 }
2042
2043
2044 void attach_sameorigin(entity e, entity to, string tag)
2045 {
2046     vector org, t_forward, t_left, t_up, e_forward, e_up;
2047     float tagscale;
2048
2049     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2050     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2051     t_forward = v_forward * tagscale;
2052     t_left = v_right * -tagscale;
2053     t_up = v_up * tagscale;
2054
2055     e.origin_x = org * t_forward;
2056     e.origin_y = org * t_left;
2057     e.origin_z = org * t_up;
2058
2059     // current forward and up directions
2060     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2061                 e.angles = AnglesTransform_FromVAngles(e.angles);
2062         else
2063                 e.angles = AnglesTransform_FromAngles(e.angles);
2064     fixedmakevectors(e.angles);
2065
2066     // untransform forward, up!
2067     e_forward_x = v_forward * t_forward;
2068     e_forward_y = v_forward * t_left;
2069     e_forward_z = v_forward * t_up;
2070     e_up_x = v_up * t_forward;
2071     e_up_y = v_up * t_left;
2072     e_up_z = v_up * t_up;
2073
2074     e.angles = fixedvectoangles2(e_forward, e_up);
2075     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2076                 e.angles = AnglesTransform_ToVAngles(e.angles);
2077         else
2078                 e.angles = AnglesTransform_ToAngles(e.angles);
2079
2080     setattachment(e, to, tag);
2081     setorigin(e, e.origin);
2082 }
2083
2084 void detach_sameorigin(entity e)
2085 {
2086     vector org;
2087     org = gettaginfo(e, 0);
2088     e.angles = fixedvectoangles2(v_forward, v_up);
2089     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2090                 e.angles = AnglesTransform_ToVAngles(e.angles);
2091         else
2092                 e.angles = AnglesTransform_ToAngles(e.angles);
2093     setorigin(e, org);
2094     setattachment(e, world, "");
2095     setorigin(e, e.origin);
2096 }
2097
2098 void follow_sameorigin(entity e, entity to)
2099 {
2100     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2101     e.aiment = to; // make the hole follow bmodel
2102     e.punchangle = to.angles; // the original angles of bmodel
2103     e.view_ofs = e.origin - to.origin; // relative origin
2104     e.v_angle = e.angles - to.angles; // relative angles
2105 }
2106
2107 void unfollow_sameorigin(entity e)
2108 {
2109     e.movetype = MOVETYPE_NONE;
2110 }
2111
2112 entity gettaginfo_relative_ent;
2113 vector gettaginfo_relative(entity e, float tag)
2114 {
2115     if (!gettaginfo_relative_ent)
2116     {
2117         gettaginfo_relative_ent = spawn();
2118         gettaginfo_relative_ent.effects = EF_NODRAW;
2119     }
2120     gettaginfo_relative_ent.model = e.model;
2121     gettaginfo_relative_ent.modelindex = e.modelindex;
2122     gettaginfo_relative_ent.frame = e.frame;
2123     return gettaginfo(gettaginfo_relative_ent, tag);
2124 }
2125
2126 .float scale2;
2127
2128 float modeleffect_SendEntity(entity to, float sf)
2129 {
2130         float f;
2131         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2132
2133         f = 0;
2134         if(self.velocity != '0 0 0')
2135                 f |= 1;
2136         if(self.angles != '0 0 0')
2137                 f |= 2;
2138         if(self.avelocity != '0 0 0')
2139                 f |= 4;
2140
2141         WriteByte(MSG_ENTITY, f);
2142         WriteShort(MSG_ENTITY, self.modelindex);
2143         WriteByte(MSG_ENTITY, self.skin);
2144         WriteByte(MSG_ENTITY, self.frame);
2145         WriteCoord(MSG_ENTITY, self.origin.x);
2146         WriteCoord(MSG_ENTITY, self.origin.y);
2147         WriteCoord(MSG_ENTITY, self.origin.z);
2148         if(f & 1)
2149         {
2150                 WriteCoord(MSG_ENTITY, self.velocity.x);
2151                 WriteCoord(MSG_ENTITY, self.velocity.y);
2152                 WriteCoord(MSG_ENTITY, self.velocity.z);
2153         }
2154         if(f & 2)
2155         {
2156                 WriteCoord(MSG_ENTITY, self.angles.x);
2157                 WriteCoord(MSG_ENTITY, self.angles.y);
2158                 WriteCoord(MSG_ENTITY, self.angles.z);
2159         }
2160         if(f & 4)
2161         {
2162                 WriteCoord(MSG_ENTITY, self.avelocity.x);
2163                 WriteCoord(MSG_ENTITY, self.avelocity.y);
2164                 WriteCoord(MSG_ENTITY, self.avelocity.z);
2165         }
2166         WriteShort(MSG_ENTITY, self.scale * 256.0);
2167         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2168         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2169         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2170         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2171
2172         return true;
2173 }
2174
2175 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2176 {
2177         entity e;
2178         float sz;
2179         e = spawn();
2180         e.classname = "modeleffect";
2181         setmodel(e, m);
2182         e.frame = f;
2183         setorigin(e, o);
2184         e.velocity = v;
2185         e.angles = ang;
2186         e.avelocity = angv;
2187         e.alpha = a;
2188         e.teleport_time = t1;
2189         e.fade_time = t2;
2190         e.skin = s;
2191         if(s0 >= 0)
2192                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
2193         else
2194                 e.scale = -s0;
2195         if(s2 >= 0)
2196                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
2197         else
2198                 e.scale2 = -s2;
2199         sz = max(e.scale, e.scale2);
2200         setsize(e, e.mins * sz, e.maxs * sz);
2201         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
2202 }
2203
2204 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2205 {
2206         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2207 }
2208
2209 float randombit(float bits)
2210 {
2211         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2212                 return bits;
2213
2214         float n, f, b, r;
2215
2216         r = random();
2217         b = 0;
2218         n = 0;
2219
2220         for(f = 1; f <= bits; f *= 2)
2221         {
2222                 if(bits & f)
2223                 {
2224                         ++n;
2225                         r *= n;
2226                         if(r <= 1)
2227                                 b = f;
2228                         else
2229                                 r = (r - 1) / (n - 1);
2230                 }
2231         }
2232
2233         return b;
2234 }
2235
2236 float randombits(float bits, float k, float error_return)
2237 {
2238         float r;
2239         r = 0;
2240         while(k > 0 && bits != r)
2241         {
2242                 r += randombit(bits - r);
2243                 --k;
2244         }
2245         if(error_return)
2246                 if(k > 0)
2247                         return -1; // all
2248         return r;
2249 }
2250
2251 void randombit_test(float bits, float iter)
2252 {
2253         while(iter > 0)
2254         {
2255                 print(ftos(randombit(bits)), "\n");
2256                 --iter;
2257         }
2258 }
2259
2260 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2261 {
2262         if(halflifedist > 0)
2263                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2264         else if(halflifedist < 0)
2265                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2266         else
2267                 return 1;
2268 }
2269
2270
2271
2272
2273 #ifdef RELEASE
2274 #define cvar_string_normal builtin_cvar_string
2275 #define cvar_normal builtin_cvar
2276 #else
2277 string cvar_string_normal(string n)
2278 {
2279         if (!(cvar_type(n) & 1))
2280                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2281         return builtin_cvar_string(n);
2282 }
2283
2284 float cvar_normal(string n)
2285 {
2286         return stof(cvar_string_normal(n));
2287 }
2288 #endif
2289 #define cvar_set_normal builtin_cvar_set
2290
2291 void defer_think()
2292 {
2293     entity oself;
2294
2295     oself           = self;
2296     self            = self.owner;
2297     oself.think     = SUB_Remove;
2298     oself.nextthink = time;
2299
2300     oself.use();
2301 }
2302
2303 /*
2304     Execute func() after time + fdelay.
2305     self when func is executed = self when defer is called
2306 */
2307 void defer(float fdelay, void() func)
2308 {
2309     entity e;
2310
2311     e           = spawn();
2312     e.owner     = self;
2313     e.use       = func;
2314     e.think     = defer_think;
2315     e.nextthink = time + fdelay;
2316 }
2317
2318 .string aiment_classname;
2319 .float aiment_deadflag;
2320 void SetMovetypeFollow(entity ent, entity e)
2321 {
2322         // FIXME this may not be warpzone aware
2323         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2324         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2325         ent.aiment = e; // make the hole follow bmodel
2326         ent.punchangle = e.angles; // the original angles of bmodel
2327         ent.view_ofs = ent.origin - e.origin; // relative origin
2328         ent.v_angle = ent.angles - e.angles; // relative angles
2329         ent.aiment_classname = strzone(e.classname);
2330         ent.aiment_deadflag = e.deadflag;
2331 }
2332 void UnsetMovetypeFollow(entity ent)
2333 {
2334         ent.movetype = MOVETYPE_FLY;
2335         PROJECTILE_MAKETRIGGER(ent);
2336         ent.aiment = world;
2337 }
2338 float LostMovetypeFollow(entity ent)
2339 {
2340 /*
2341         if(ent.movetype != MOVETYPE_FOLLOW)
2342                 if(ent.aiment)
2343                         error("???");
2344 */
2345         if(ent.aiment)
2346         {
2347                 if(ent.aiment.classname != ent.aiment_classname)
2348                         return 1;
2349                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2350                         return 1;
2351         }
2352         return 0;
2353 }
2354
2355 float isPushable(entity e)
2356 {
2357         if(e.iscreature)
2358                 return true;
2359         if(e.pushable)
2360                 return true;
2361         switch(e.classname)
2362         {
2363                 case "body":
2364                 case "droppedweapon":
2365                 case "keepawayball":
2366                 case "nexball_basketball":
2367                 case "nexball_football":
2368                         return true;
2369                 case "bullet": // antilagged bullets can't hit this either
2370                         return false;
2371         }
2372         if (e.projectiledeathtype)
2373                 return true;
2374         return false;
2375 }