Move dedicated_print to miscfunctions (not a client-specific function)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 #include "miscfunctions.qh"
2
3 #include "antilag.qh"
4 #include "command/common.qh"
5 #include "constants.qh"
6 #include "g_hook.qh"
7 #include "ipban.qh"
8 #include <server/mutators/_mod.qh>
9 #include "../common/t_items.qh"
10 #include "resources.qh"
11 #include "items.qh"
12 #include "player.qh"
13 #include "weapons/accuracy.qh"
14 #include "weapons/csqcprojectile.qh"
15 #include "weapons/selection.qh"
16 #include "../common/command/_mod.qh"
17 #include "../common/constants.qh"
18 #include <common/net_linked.qh>
19 #include "../common/deathtypes/all.qh"
20 #include "../common/mapinfo.qh"
21 #include "../common/notifications/all.qh"
22 #include "../common/playerstats.qh"
23 #include "../common/teams.qh"
24 #include "../common/mapobjects/subs.qh"
25 #include "../common/util.qh"
26 #include "../common/turrets/sv_turrets.qh"
27 #include <common/weapons/_all.qh>
28 #include "../common/vehicles/sv_vehicles.qh"
29 #include "../common/vehicles/vehicle.qh"
30 #include "../common/items/_mod.qh"
31 #include "../common/state.qh"
32 #include "../common/effects/qc/globalsound.qh"
33 #include "../common/wepent.qh"
34 #include "../lib/csqcmodel/sv_model.qh"
35 #include "../lib/warpzone/anglestransform.qh"
36 #include "../lib/warpzone/server.qh"
37
38 void crosshair_trace(entity pl)
39 {
40         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
41 }
42 .bool ctrace_solidchanged;
43 void crosshair_trace_plusvisibletriggers(entity pl)
44 {
45         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
46         {
47                 if(it.model != "")
48                 {
49                         it.solid = SOLID_BSP;
50                         it.ctrace_solidchanged = true;
51                         IL_PUSH(g_ctrace_changed, it);
52                 }
53         });
54
55         crosshair_trace(pl);
56
57         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
58         {
59                 it.solid = SOLID_TRIGGER;
60                 it.ctrace_solidchanged = false;
61         });
62
63         IL_CLEAR(g_ctrace_changed);
64 }
65 void WarpZone_crosshair_trace(entity pl)
66 {
67         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
68 }
69
70 void dedicated_print(string input)
71 {
72         if (server_is_dedicated) print(input);
73 }
74
75 void GameLogEcho(string s)
76 {
77     string fn;
78     int matches;
79
80     if (autocvar_sv_eventlog_files)
81     {
82         if (!logfile_open)
83         {
84             logfile_open = true;
85             matches = autocvar_sv_eventlog_files_counter + 1;
86             cvar_set("sv_eventlog_files_counter", itos(matches));
87             fn = ftos(matches);
88             if (strlen(fn) < 8)
89                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
90             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
91             logfile = fopen(fn, FILE_APPEND);
92             fputs(logfile, ":logversion:3\n");
93         }
94         if (logfile >= 0)
95         {
96             if (autocvar_sv_eventlog_files_timestamps)
97                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
98             else
99                 fputs(logfile, strcat(s, "\n"));
100         }
101     }
102     if (autocvar_sv_eventlog_console)
103     {
104         dedicated_print(strcat(s, "\n"));
105     }
106 }
107
108 void GameLogInit()
109 {
110     logfile_open = 0;
111     // will be opened later
112 }
113
114 void GameLogClose()
115 {
116     if (logfile_open && logfile >= 0)
117     {
118         fclose(logfile);
119         logfile = -1;
120     }
121 }
122
123 entity findnearest(vector point, bool checkitems, vector axismod)
124 {
125     vector dist;
126     int num_nearest = 0;
127
128     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
129     {
130         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
131             dist = it.oldorigin;
132         else
133             dist = it.origin;
134         dist = dist - point;
135         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
136         float len = vlen2(dist);
137
138         int l;
139         for (l = 0; l < num_nearest; ++l)
140         {
141             if (len < nearest_length[l])
142                 break;
143         }
144
145         // now i tells us where to insert at
146         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
147         if (l < NUM_NEAREST_ENTITIES)
148         {
149             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
150             {
151                 nearest_length[j + 1] = nearest_length[j];
152                 nearest_entity[j + 1] = nearest_entity[j];
153             }
154             nearest_length[l] = len;
155             nearest_entity[l] = it;
156             if (num_nearest < NUM_NEAREST_ENTITIES)
157                 num_nearest = num_nearest + 1;
158         }
159     });
160
161     // now use the first one from our list that we can see
162     for (int j = 0; j < num_nearest; ++j)
163     {
164         traceline(point, nearest_entity[j].origin, true, NULL);
165         if (trace_fraction == 1)
166         {
167             if (j != 0)
168                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
169             return nearest_entity[j];
170         }
171     }
172
173     if (num_nearest == 0)
174         return NULL;
175
176     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
177     /* DEBUGGING CODE:
178     dprint("Candidates were: ");
179     for(j = 0; j < num_nearest; ++j)
180     {
181         if(j != 0)
182                 dprint(", ");
183         dprint(nearest_entity[j].netname);
184     }
185     dprint("\n");
186     */
187
188     return nearest_entity[0];
189 }
190
191 string NearestLocation(vector p)
192 {
193     string ret = "somewhere";
194     entity loc = findnearest(p, false, '1 1 1');
195     if (loc)
196         ret = loc.message;
197     else
198     {
199         loc = findnearest(p, true, '1 1 4');
200         if (loc)
201             ret = loc.netname;
202     }
203     return ret;
204 }
205
206 string AmmoNameFromWeaponentity(Weapon wep)
207 {
208         string ammoitems = "batteries";
209         switch (wep.ammo_type)
210         {
211                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
212                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
213                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
214                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
215                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
216                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
217         }
218         return ammoitems;
219 }
220
221 string formatmessage(entity this, string msg)
222 {
223         float p, p1, p2;
224         float n;
225         vector cursor;
226         entity cursor_ent;
227         string escape;
228         string replacement;
229         p = 0;
230         n = 7;
231
232         WarpZone_crosshair_trace(this);
233         cursor = trace_endpos;
234         cursor_ent = trace_ent;
235
236         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
237         msg = M_ARGV(1, string);
238
239         while (1) {
240                 if (n < 1)
241                         break; // too many replacements
242
243                 n = n - 1;
244                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
245                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
246
247                 if (p1 < 0)
248                         p1 = p2;
249
250                 if (p2 < 0)
251                         p2 = p1;
252
253                 p = min(p1, p2);
254
255                 if (p < 0)
256                         break;
257
258                 replacement = substring(msg, p, 2);
259                 escape = substring(msg, p + 1, 1);
260
261                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
262
263                 switch(escape)
264                 {
265                         case "%": replacement = "%"; break;
266                         case "\\":replacement = "\\"; break;
267                         case "n": replacement = "\n"; break;
268                         case "a": replacement = ftos(floor(this.armorvalue)); break;
269                         case "h": replacement = ftos(floor(this.health)); break;
270                         case "l": replacement = NearestLocation(this.origin); break;
271                         case "y": replacement = NearestLocation(cursor); break;
272                         case "d": replacement = NearestLocation(this.death_origin); break;
273                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
274                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
275                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
276                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
277                         case "S": replacement = ftos(vlen(this.velocity)); break;
278                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
279                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
280                         default:
281                         {
282                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
283                                 replacement = M_ARGV(2, string);
284                                 break;
285                         }
286                 }
287
288                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
289                 p = p + strlen(replacement);
290         }
291         return msg;
292 }
293
294 /*
295 =============
296 GetCvars
297 =============
298 Called with:
299   0:  sends the request
300   >0: receives a cvar from name=argv(f) value=argv(f+1)
301 */
302 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
303 {
304         if (f < 0)
305         {
306                 strfree(store.(field));
307         }
308         else if (f > 0)
309         {
310                 if (thisname == name)
311                 {
312                         strcpy(store.(field), argv(f + 1));
313                 }
314         }
315         else
316                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
317 }
318 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
319 {
320         GetCvars_handleString(this, store, thisname, f, field, name);
321         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
322                 if (thisname == name)
323                 {
324                         string s = func(this, strcat1(store.(field)));
325                         if (s != store.(field))
326                         {
327                                 strcpy(store.(field), s);
328                         }
329                 }
330 }
331 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
332 {
333         if (f < 0)
334         {
335         }
336         else if (f > 0)
337         {
338                 if (thisname == name)
339                         store.(field) = stof(argv(f + 1));
340         }
341         else
342                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
343 }
344 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
345 {
346         if (f < 0)
347         {
348         }
349         else if (f > 0)
350         {
351                 if (thisname == name)
352                 {
353                         if (!store.(field))
354                         {
355                                 store.(field) = stof(argv(f + 1));
356                                 if (!store.(field))
357                                         store.(field) = -1;
358                         }
359                 }
360         }
361         else
362         {
363                 if (!store.(field))
364                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
365         }
366 }
367 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
368 {
369         string o = W_FixWeaponOrder_ForceComplete(wo);
370         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
371         return o;
372 }
373
374 REPLICATE(autoswitch, bool, "cl_autoswitch");
375
376 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
377
378 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
379
380 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
381
382 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
383
384 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
385
386 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
387
388 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
389
390 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
391
392 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
393
394 REPLICATE(cvar_cl_physics, string, "cl_physics");
395
396 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
397
398 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
399
400 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
401
402 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
403
404 /**
405  * @param f -1: cleanup, 0: request, 1: receive
406  */
407 void GetCvars(entity this, entity store, int f)
408 {
409         string s = string_null;
410
411         if (f > 0)
412                 s = strcat1(argv(f));
413
414         get_cvars_f = f;
415         get_cvars_s = s;
416         MUTATOR_CALLHOOK(GetCvars);
417
418         Notification_GetCvars(this);
419
420         ReplicateVars(this, store, s, f);
421
422         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
425         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
433
434         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
435
436         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
437         if (f > 0)
438         {
439                 if (s == "cl_weaponpriority")
440                 {
441                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
442                         {
443                                 .entity weaponentity = weaponentities[slot];
444                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
445                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
446                         }
447                 }
448                 if (s == "cl_allow_uidtracking")
449                         PlayerStats_GameReport_AddPlayer(this);
450         }
451 }
452
453 // decolorizes and team colors the player name when needed
454 string playername(entity p, bool team_colorize)
455 {
456     string t;
457     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
458     {
459         t = Team_ColorCode(p.team);
460         return strcat(t, strdecolorize(p.netname));
461     }
462     else
463         return p.netname;
464 }
465
466 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
467 {
468         int i = weaponinfo.m_id;
469         int d = 0;
470         bool allow_mutatorblocked = false;
471
472         if(!i)
473                 return 0;
474
475         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
476         d = M_ARGV(1, float);
477         allguns = M_ARGV(2, bool);
478         allow_mutatorblocked = M_ARGV(3, bool);
479
480         if(allguns)
481         {
482                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
483                         d = true;
484                 else
485                         d = false;
486         }
487         else if(!mutator_returnvalue)
488                 d = !(!weaponinfo.weaponstart);
489
490         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
491                 d = 0;
492
493         float t = weaponinfo.weaponstartoverride;
494
495         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
496
497         // bit order in t:
498         // 1: want or not
499         // 2: is default?
500         // 4: is set by default?
501         if(t < 0)
502                 t = 4 | (3 * d);
503         else
504                 t |= (2 * d);
505
506         return t;
507 }
508
509 void readplayerstartcvars()
510 {
511         float i, t;
512         string s;
513
514         // initialize starting values for players
515         start_weapons = '0 0 0';
516         start_weapons_default = '0 0 0';
517         start_weapons_defaultmask = '0 0 0';
518         start_items = 0;
519         start_ammo_shells = 0;
520         start_ammo_nails = 0;
521         start_ammo_rockets = 0;
522         start_ammo_cells = 0;
523         start_ammo_plasma = 0;
524         if (random_start_ammo == NULL)
525         {
526                 random_start_ammo = spawn();
527         }
528         start_health = cvar("g_balance_health_start");
529         start_armorvalue = cvar("g_balance_armor_start");
530
531         g_weaponarena = 0;
532         g_weaponarena_weapons = '0 0 0';
533
534         s = cvar_string("g_weaponarena");
535
536         MUTATOR_CALLHOOK(SetWeaponArena, s);
537         s = M_ARGV(0, string);
538
539         if (s == "0" || s == "")
540         {
541                 // no arena
542         }
543         else if (s == "off")
544         {
545                 // forcibly turn off weaponarena
546         }
547         else if (s == "all" || s == "1")
548         {
549                 g_weaponarena = 1;
550                 g_weaponarena_list = "All Weapons";
551                 FOREACH(Weapons, it != WEP_Null, {
552                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
553                                 g_weaponarena_weapons |= (it.m_wepset);
554                 });
555         }
556         else if (s == "devall")
557         {
558                 g_weaponarena = 1;
559                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
560                 FOREACH(Weapons, it != WEP_Null,
561                 {
562                         g_weaponarena_weapons |= (it.m_wepset);
563                 });
564         }
565         else if (s == "most")
566         {
567                 g_weaponarena = 1;
568                 g_weaponarena_list = "Most Weapons";
569                 FOREACH(Weapons, it != WEP_Null, {
570                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
571                                 if(it.spawnflags & WEP_FLAG_NORMAL)
572                                         g_weaponarena_weapons |= (it.m_wepset);
573                 });
574         }
575         else if (s == "none")
576         {
577                 g_weaponarena = 1;
578                 g_weaponarena_list = "No Weapons";
579         }
580         else
581         {
582                 g_weaponarena = 1;
583                 t = tokenize_console(s);
584                 g_weaponarena_list = "";
585                 for (i = 0; i < t; ++i)
586                 {
587                         s = argv(i);
588                         FOREACH(Weapons, it != WEP_Null, {
589                                 if(it.netname == s)
590                                 {
591                                         g_weaponarena_weapons |= (it.m_wepset);
592                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
593                                         break;
594                                 }
595                         });
596                 }
597                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
598         }
599
600         if (g_weaponarena)
601         {
602                 g_weapon_stay = 0; // incompatible
603                 start_weapons = g_weaponarena_weapons;
604                 start_items |= IT_UNLIMITED_AMMO;
605         }
606         else
607         {
608                 FOREACH(Weapons, it != WEP_Null, {
609                         int w = want_weapon(it, false);
610                         WepSet s = it.m_wepset;
611                         if(w & 1)
612                                 start_weapons |= s;
613                         if(w & 2)
614                                 start_weapons_default |= s;
615                         if(w & 4)
616                                 start_weapons_defaultmask |= s;
617                 });
618         }
619
620         if(!cvar("g_use_ammunition"))
621                 start_items |= IT_UNLIMITED_AMMO;
622
623         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
624         {
625                 start_ammo_shells = 999;
626                 start_ammo_nails = 999;
627                 start_ammo_rockets = 999;
628                 start_ammo_cells = 999;
629                 start_ammo_plasma = 999;
630                 start_ammo_fuel = 999;
631         }
632         else
633         {
634                 start_ammo_shells = cvar("g_start_ammo_shells");
635                 start_ammo_nails = cvar("g_start_ammo_nails");
636                 start_ammo_rockets = cvar("g_start_ammo_rockets");
637                 start_ammo_cells = cvar("g_start_ammo_cells");
638                 start_ammo_plasma = cvar("g_start_ammo_plasma");
639                 start_ammo_fuel = cvar("g_start_ammo_fuel");
640                 random_start_weapons_count = cvar("g_random_start_weapons_count");
641                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
642                         "g_random_start_shells"));
643                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
644                         "g_random_start_bullets"));
645                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
646                         cvar("g_random_start_rockets"));
647                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
648                         "g_random_start_cells"));
649                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
650                         "g_random_start_plasma"));
651         }
652
653         if (warmup_stage)
654         {
655                 warmup_start_ammo_shells = start_ammo_shells;
656                 warmup_start_ammo_nails = start_ammo_nails;
657                 warmup_start_ammo_rockets = start_ammo_rockets;
658                 warmup_start_ammo_cells = start_ammo_cells;
659                 warmup_start_ammo_plasma = start_ammo_plasma;
660                 warmup_start_ammo_fuel = start_ammo_fuel;
661                 warmup_start_health = start_health;
662                 warmup_start_armorvalue = start_armorvalue;
663                 warmup_start_weapons = start_weapons;
664                 warmup_start_weapons_default = start_weapons_default;
665                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
666
667                 if (!g_weaponarena && !g_ca && !g_freezetag)
668                 {
669                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
670                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
671                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
672                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
673                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
674                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
675                         warmup_start_health = cvar("g_warmup_start_health");
676                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
677                         warmup_start_weapons = '0 0 0';
678                         warmup_start_weapons_default = '0 0 0';
679                         warmup_start_weapons_defaultmask = '0 0 0';
680                         FOREACH(Weapons, it != WEP_Null, {
681                                 int w = want_weapon(it, g_warmup_allguns);
682                                 WepSet s = (it.m_wepset);
683                                 if(w & 1)
684                                         warmup_start_weapons |= s;
685                                 if(w & 2)
686                                         warmup_start_weapons_default |= s;
687                                 if(w & 4)
688                                         warmup_start_weapons_defaultmask |= s;
689                         });
690                 }
691         }
692
693         if (g_jetpack)
694                 start_items |= ITEM_Jetpack.m_itemid;
695
696         MUTATOR_CALLHOOK(SetStartItems);
697
698         if (start_items & ITEM_Jetpack.m_itemid)
699         {
700                 start_items |= ITEM_JetpackRegen.m_itemid;
701                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
702                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
703         }
704
705         WepSet precache_weapons = start_weapons;
706         if (g_warmup_allguns != 1)
707                 precache_weapons |= warmup_start_weapons;
708         FOREACH(Weapons, it != WEP_Null, {
709                 if(precache_weapons & (it.m_wepset))
710                         it.wr_init(it);
711         });
712
713         start_ammo_shells = max(0, start_ammo_shells);
714         start_ammo_nails = max(0, start_ammo_nails);
715         start_ammo_rockets = max(0, start_ammo_rockets);
716         start_ammo_cells = max(0, start_ammo_cells);
717         start_ammo_plasma = max(0, start_ammo_plasma);
718         start_ammo_fuel = max(0, start_ammo_fuel);
719         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
720                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
721         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
722                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
723         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
724                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
725         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
726                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
727         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
728                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
729
730         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
731         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
732         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
733         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
734         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
735         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
736 }
737
738 void precache_playermodel(string m)
739 {
740         float globhandle, i, n;
741         string f;
742
743         if(substring(m, -9,5) == "_lod1")
744                 return;
745         if(substring(m, -9,5) == "_lod2")
746                 return;
747         precache_model(m);
748         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
749         if(fexists(f))
750                 precache_model(f);
751         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
752         if(fexists(f))
753                 precache_model(f);
754
755         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
756         if (globhandle < 0)
757                 return;
758         n = search_getsize(globhandle);
759         for (i = 0; i < n; ++i)
760         {
761                 //print(search_getfilename(globhandle, i), "\n");
762                 f = search_getfilename(globhandle, i);
763                 PrecachePlayerSounds(f);
764         }
765         search_end(globhandle);
766 }
767 void precache_all_playermodels(string pattern)
768 {
769         int globhandle = search_begin(pattern, true, false);
770         if (globhandle < 0) return;
771         int n = search_getsize(globhandle);
772         for (int i = 0; i < n; ++i)
773         {
774                 string s = search_getfilename(globhandle, i);
775                 precache_playermodel(s);
776         }
777         search_end(globhandle);
778 }
779
780 void precache_playermodels(string s)
781 {
782         FOREACH_WORD(s, true, { precache_playermodel(it); });
783 }
784
785 void precache()
786 {
787     // gamemode related things
788
789     // Precache all player models if desired
790     if (autocvar_sv_precacheplayermodels)
791     {
792         PrecachePlayerSounds("sound/player/default.sounds");
793         precache_all_playermodels("models/player/*.zym");
794         precache_all_playermodels("models/player/*.dpm");
795         precache_all_playermodels("models/player/*.md3");
796         precache_all_playermodels("models/player/*.psk");
797         precache_all_playermodels("models/player/*.iqm");
798     }
799
800     if (autocvar_sv_defaultcharacter)
801     {
802                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
803                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
804                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
805                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
806                 precache_playermodels(autocvar_sv_defaultplayermodel);
807     }
808
809 #if 0
810     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
811
812     if (!this.noise && this.music) // quake 3 uses the music field
813         this.noise = this.music;
814
815     // plays music for the level if there is any
816     if (this.noise)
817     {
818         precache_sound (this.noise);
819         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
820     }
821 #endif
822 }
823
824
825 void make_safe_for_remove(entity e)
826 {
827     if (e.initialize_entity)
828     {
829         entity ent, prev = NULL;
830         for (ent = initialize_entity_first; ent; )
831         {
832             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
833             {
834                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
835                 // skip it in linked list
836                 if (prev)
837                 {
838                     prev.initialize_entity_next = ent.initialize_entity_next;
839                     ent = prev.initialize_entity_next;
840                 }
841                 else
842                 {
843                     initialize_entity_first = ent.initialize_entity_next;
844                     ent = initialize_entity_first;
845                 }
846             }
847             else
848             {
849                 prev = ent;
850                 ent = ent.initialize_entity_next;
851             }
852         }
853     }
854 }
855
856 .float remove_except_protected_forbidden;
857 void remove_except_protected(entity e)
858 {
859         if(e.remove_except_protected_forbidden)
860                 error("not allowed to remove this at this point");
861         builtin_remove(e);
862 }
863
864 void remove_unsafely(entity e)
865 {
866     if(e.classname == "spike")
867         error("Removing spikes is forbidden (crylink bug), please report");
868     builtin_remove(e);
869 }
870
871 void remove_safely(entity e)
872 {
873     make_safe_for_remove(e);
874     builtin_remove(e);
875 }
876
877 void InitializeEntity(entity e, void(entity this) func, float order)
878 {
879     entity prev, cur;
880
881     if (!e || e.initialize_entity)
882     {
883         // make a proxy initializer entity
884         entity e_old = e;
885         e = new(initialize_entity);
886         e.enemy = e_old;
887     }
888
889     e.initialize_entity = func;
890     e.initialize_entity_order = order;
891
892     cur = initialize_entity_first;
893     prev = NULL;
894     for (;;)
895     {
896         if (!cur || cur.initialize_entity_order > order)
897         {
898             // insert between prev and cur
899             if (prev)
900                 prev.initialize_entity_next = e;
901             else
902                 initialize_entity_first = e;
903             e.initialize_entity_next = cur;
904             return;
905         }
906         prev = cur;
907         cur = cur.initialize_entity_next;
908     }
909 }
910 void InitializeEntitiesRun()
911 {
912     entity startoflist = initialize_entity_first;
913     initialize_entity_first = NULL;
914     delete_fn = remove_except_protected;
915     for (entity e = startoflist; e; e = e.initialize_entity_next)
916     {
917                 e.remove_except_protected_forbidden = 1;
918     }
919     for (entity e = startoflist; e; )
920     {
921                 e.remove_except_protected_forbidden = 0;
922         e.initialize_entity_order = 0;
923         entity next = e.initialize_entity_next;
924         e.initialize_entity_next = NULL;
925         var void(entity this) func = e.initialize_entity;
926         e.initialize_entity = func_null;
927         if (e.classname == "initialize_entity")
928         {
929             entity wrappee = e.enemy;
930             builtin_remove(e);
931             e = wrappee;
932         }
933         //dprint("Delayed initialization: ", e.classname, "\n");
934         if (func)
935         {
936                 func(e);
937         }
938         else
939         {
940             eprint(e);
941             backtrace(strcat("Null function in: ", e.classname, "\n"));
942         }
943         e = next;
944     }
945     delete_fn = remove_unsafely;
946 }
947
948 .float(entity) isEliminated;
949 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
950 {
951         Stream out = MSG_ENTITY;
952         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
953         serialize(byte, out, sendflags);
954         if (sendflags & 1) {
955                 for (int i = 1; i <= maxclients; i += 8) {
956                         int f = 0;
957                         entity e = edict_num(i);
958                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
959                                 if (eliminatedPlayers.isEliminated(e)) {
960                                         f |= BIT(b);
961                                 }
962                         }
963                         serialize(byte, out, f);
964                 }
965         }
966         return true;
967 }
968
969 void EliminatedPlayers_Init(float(entity) isEliminated_func)
970 {
971         if(eliminatedPlayers)
972         {
973                 backtrace("Can't spawn eliminatedPlayers again!");
974                 return;
975         }
976         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
977         eliminatedPlayers.isEliminated = isEliminated_func;
978 }
979
980
981
982
983 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
984 {
985         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
986                 this.projectiledeathtype |= HITTYPE_SPLASH;
987         adaptor_think2use(this);
988 }
989
990 // deferred dropping
991 void DropToFloor_Handler(entity this)
992 {
993     WITHSELF(this, builtin_droptofloor());
994     this.dropped_origin = this.origin;
995 }
996
997 void droptofloor(entity this)
998 {
999     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1000 }
1001
1002
1003
1004 float trace_hits_box_a0, trace_hits_box_a1;
1005
1006 float trace_hits_box_1d(float end, float thmi, float thma)
1007 {
1008     if (end == 0)
1009     {
1010         // just check if x is in range
1011         if (0 < thmi)
1012             return false;
1013         if (0 > thma)
1014             return false;
1015     }
1016     else
1017     {
1018         // do the trace with respect to x
1019         // 0 -> end has to stay in thmi -> thma
1020         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1021         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1022         if (trace_hits_box_a0 > trace_hits_box_a1)
1023             return false;
1024     }
1025     return true;
1026 }
1027
1028 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1029 {
1030     end -= start;
1031     thmi -= start;
1032     thma -= start;
1033     // now it is a trace from 0 to end
1034
1035     trace_hits_box_a0 = 0;
1036     trace_hits_box_a1 = 1;
1037
1038     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1039         return false;
1040     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1041         return false;
1042     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1043         return false;
1044
1045     return true;
1046 }
1047
1048 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1049 {
1050     return trace_hits_box(start, end, thmi - ma, thma - mi);
1051 }
1052
1053 bool SUB_NoImpactCheck(entity this, entity toucher)
1054 {
1055         // zero hitcontents = this is not the real impact, but either the
1056         // mirror-impact of something hitting the projectile instead of the
1057         // projectile hitting the something, or a touchareagrid one. Neither of
1058         // these stop the projectile from moving, so...
1059         if(trace_dphitcontents == 0)
1060         {
1061                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1062                 checkclient(this);
1063         }
1064     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1065         return true;
1066     if (toucher == NULL && this.size != '0 0 0')
1067     {
1068         vector tic;
1069         tic = this.velocity * sys_frametime;
1070         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1071         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1072         if (trace_fraction >= 1)
1073         {
1074             LOG_TRACE("Odd... did not hit...?");
1075         }
1076         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1077         {
1078             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1079             return true;
1080         }
1081     }
1082
1083     return false;
1084 }
1085
1086 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1087
1088 void W_Crylink_Dequeue(entity e);
1089 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1090 {
1091         if(SUB_OwnerCheck(this, toucher))
1092                 return true;
1093         if(SUB_NoImpactCheck(this, toucher))
1094         {
1095                 if(this.classname == "nade")
1096                         return false; // no checks here
1097                 else if(this.classname == "grapplinghook")
1098                         RemoveHook(this);
1099                 else if(this.classname == "spike")
1100                 {
1101                         W_Crylink_Dequeue(this);
1102                         delete(this);
1103                 }
1104                 else
1105                         delete(this);
1106                 return true;
1107         }
1108         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1109                 UpdateCSQCProjectile(this);
1110         return false;
1111 }
1112
1113 /** engine callback */
1114 void URI_Get_Callback(float id, float status, string data)
1115 {
1116         if(url_URI_Get_Callback(id, status, data))
1117         {
1118                 // handled
1119         }
1120         else if (id == URI_GET_DISCARD)
1121         {
1122                 // discard
1123         }
1124         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1125         {
1126                 // sv_cmd curl
1127                 Curl_URI_Get_Callback(id, status, data);
1128         }
1129         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1130         {
1131                 // online ban list
1132                 OnlineBanList_URI_Get_Callback(id, status, data);
1133         }
1134         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1135         {
1136                 // handled by a mutator
1137         }
1138         else
1139         {
1140                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1141         }
1142 }
1143
1144 string uid2name(string myuid) {
1145         string s;
1146         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1147
1148         // FIXME remove this later after 0.6 release
1149         // convert old style broken records to correct style
1150         if(s == "")
1151         {
1152                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1153                 if(s != "")
1154                 {
1155                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1156                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1157                 }
1158         }
1159
1160         if(s == "")
1161                 s = "^1Unregistered Player";
1162         return s;
1163 }
1164
1165 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1166 {
1167     float m, i;
1168     vector start, org, delta, end, enddown, mstart;
1169
1170     m = e.dphitcontentsmask;
1171     e.dphitcontentsmask = goodcontents | badcontents;
1172
1173     org = boundmin;
1174     delta = boundmax - boundmin;
1175
1176     start = end = org;
1177
1178     for (i = 0; i < attempts; ++i)
1179     {
1180         start.x = org.x + random() * delta.x;
1181         start.y = org.y + random() * delta.y;
1182         start.z = org.z + random() * delta.z;
1183
1184         // rule 1: start inside world bounds, and outside
1185         // solid, and don't start from somewhere where you can
1186         // fall down to evil
1187         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1188         if (trace_fraction >= 1)
1189             continue;
1190         if (trace_startsolid)
1191             continue;
1192         if (trace_dphitcontents & badcontents)
1193             continue;
1194         if (trace_dphitq3surfaceflags & badsurfaceflags)
1195             continue;
1196
1197         // rule 2: if we are too high, lower the point
1198         if (trace_fraction * delta.z > maxaboveground)
1199             start = trace_endpos + '0 0 1' * maxaboveground;
1200         enddown = trace_endpos;
1201
1202         // rule 3: make sure we aren't outside the map. This only works
1203         // for somewhat well formed maps. A good rule of thumb is that
1204         // the map should have a convex outside hull.
1205         // these can be traceLINES as we already verified the starting box
1206         mstart = start + 0.5 * (e.mins + e.maxs);
1207         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1208         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1209             continue;
1210         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1211         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1212             continue;
1213         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1214         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1215             continue;
1216         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1217         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1218             continue;
1219         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1220         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1221             continue;
1222
1223         // rule 4: we must "see" some spawnpoint or item
1224     entity sp = NULL;
1225     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1226     {
1227         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1228         {
1229                 sp = it;
1230                 break;
1231         }
1232     });
1233         if(!sp)
1234         {
1235                 int items_checked = 0;
1236                 IL_EACH(g_items, checkpvs(mstart, it),
1237                 {
1238                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1239                         {
1240                                 sp = it;
1241                                 break;
1242                         }
1243
1244                         ++items_checked;
1245                         if(items_checked >= attempts)
1246                                 break; // sanity
1247                 });
1248
1249                 if(!sp)
1250                         continue;
1251         }
1252
1253         // find a random vector to "look at"
1254         end.x = org.x + random() * delta.x;
1255         end.y = org.y + random() * delta.y;
1256         end.z = org.z + random() * delta.z;
1257         end = start + normalize(end - start) * vlen(delta);
1258
1259         // rule 4: start TO end must not be too short
1260         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1261         if (trace_startsolid)
1262             continue;
1263         if (trace_fraction < minviewdistance / vlen(delta))
1264             continue;
1265
1266         // rule 5: don't want to look at sky
1267         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1268             continue;
1269
1270         // rule 6: we must not end up in trigger_hurt
1271         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1272             continue;
1273
1274         break;
1275     }
1276
1277     e.dphitcontentsmask = m;
1278
1279     if (i < attempts)
1280     {
1281         setorigin(e, start);
1282         e.angles = vectoangles(end - start);
1283         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1284         return true;
1285     }
1286     else
1287         return false;
1288 }
1289
1290 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1291 {
1292         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1293 }
1294
1295 void write_recordmarker(entity pl, float tstart, float dt)
1296 {
1297     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1298
1299     // also write a marker into demo files for demotc-race-record-extractor to find
1300     stuffcmd(pl,
1301              strcat(
1302                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1303                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1304 }
1305
1306 void attach_sameorigin(entity e, entity to, string tag)
1307 {
1308     vector org, t_forward, t_left, t_up, e_forward, e_up;
1309     float tagscale;
1310
1311     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1312     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1313     t_forward = v_forward * tagscale;
1314     t_left = v_right * -tagscale;
1315     t_up = v_up * tagscale;
1316
1317     e.origin_x = org * t_forward;
1318     e.origin_y = org * t_left;
1319     e.origin_z = org * t_up;
1320
1321     // current forward and up directions
1322     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1323                 e.angles = AnglesTransform_FromVAngles(e.angles);
1324         else
1325                 e.angles = AnglesTransform_FromAngles(e.angles);
1326     fixedmakevectors(e.angles);
1327
1328     // untransform forward, up!
1329     e_forward.x = v_forward * t_forward;
1330     e_forward.y = v_forward * t_left;
1331     e_forward.z = v_forward * t_up;
1332     e_up.x = v_up * t_forward;
1333     e_up.y = v_up * t_left;
1334     e_up.z = v_up * t_up;
1335
1336     e.angles = fixedvectoangles2(e_forward, e_up);
1337     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1338                 e.angles = AnglesTransform_ToVAngles(e.angles);
1339         else
1340                 e.angles = AnglesTransform_ToAngles(e.angles);
1341
1342     setattachment(e, to, tag);
1343     setorigin(e, e.origin);
1344 }
1345
1346 void detach_sameorigin(entity e)
1347 {
1348     vector org;
1349     org = gettaginfo(e, 0);
1350     e.angles = fixedvectoangles2(v_forward, v_up);
1351     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1352                 e.angles = AnglesTransform_ToVAngles(e.angles);
1353         else
1354                 e.angles = AnglesTransform_ToAngles(e.angles);
1355     setorigin(e, org);
1356     setattachment(e, NULL, "");
1357     setorigin(e, e.origin);
1358 }
1359
1360 void follow_sameorigin(entity e, entity to)
1361 {
1362     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1363     e.aiment = to; // make the hole follow bmodel
1364     e.punchangle = to.angles; // the original angles of bmodel
1365     e.view_ofs = e.origin - to.origin; // relative origin
1366     e.v_angle = e.angles - to.angles; // relative angles
1367 }
1368
1369 void unfollow_sameorigin(entity e)
1370 {
1371     set_movetype(e, MOVETYPE_NONE);
1372 }
1373
1374 entity gettaginfo_relative_ent;
1375 vector gettaginfo_relative(entity e, float tag)
1376 {
1377     if (!gettaginfo_relative_ent)
1378     {
1379         gettaginfo_relative_ent = spawn();
1380         gettaginfo_relative_ent.effects = EF_NODRAW;
1381     }
1382     gettaginfo_relative_ent.model = e.model;
1383     gettaginfo_relative_ent.modelindex = e.modelindex;
1384     gettaginfo_relative_ent.frame = e.frame;
1385     return gettaginfo(gettaginfo_relative_ent, tag);
1386 }
1387
1388 .string aiment_classname;
1389 .float aiment_deadflag;
1390 void SetMovetypeFollow(entity ent, entity e)
1391 {
1392         // FIXME this may not be warpzone aware
1393         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1394         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1395         ent.aiment = e; // make the hole follow bmodel
1396         ent.punchangle = e.angles; // the original angles of bmodel
1397         ent.view_ofs = ent.origin - e.origin; // relative origin
1398         ent.v_angle = ent.angles - e.angles; // relative angles
1399         ent.aiment_classname = strzone(e.classname);
1400         ent.aiment_deadflag = e.deadflag;
1401 }
1402 void UnsetMovetypeFollow(entity ent)
1403 {
1404         set_movetype(ent, MOVETYPE_FLY);
1405         PROJECTILE_MAKETRIGGER(ent);
1406         ent.aiment = NULL;
1407 }
1408 float LostMovetypeFollow(entity ent)
1409 {
1410 /*
1411         if(ent.move_movetype != MOVETYPE_FOLLOW)
1412                 if(ent.aiment)
1413                         error("???");
1414 */
1415         if(ent.aiment)
1416         {
1417                 if(ent.aiment.classname != ent.aiment_classname)
1418                         return 1;
1419                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1420                         return 1;
1421         }
1422         return 0;
1423 }
1424
1425 .bool pushable;
1426 bool isPushable(entity e)
1427 {
1428         if(e.pushable)
1429                 return true;
1430         if(IS_VEHICLE(e))
1431                 return false;
1432         if(e.iscreature)
1433                 return true;
1434         if (Item_IsLoot(e))
1435         {
1436                 return true;
1437         }
1438         switch(e.classname)
1439         {
1440                 case "body":
1441                         return true;
1442                 case "bullet": // antilagged bullets can't hit this either
1443                         return false;
1444         }
1445         if (e.projectiledeathtype)
1446                 return true;
1447         return false;
1448 }