qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WepSet g_weaponarena_weapons;
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WepSet start_weapons;
 607 WepSet start_weapons_default;
 608 WepSet start_weapons_defaultmask;
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WepSet warmup_start_weapons;
 618 WepSet warmup_start_weapons_default;
 619 WepSet warmup_start_weapons_defaultmask;
 620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 621 float warmup_start_ammo_shells;
 622 float warmup_start_ammo_nails;
 623 float warmup_start_ammo_rockets;
 624 float warmup_start_ammo_cells;
 625 float warmup_start_ammo_fuel;
 626 float warmup_start_health;
 627 float warmup_start_armorvalue;
 628 float g_weapon_stay;
 629
 630 entity get_weaponinfo(float w);
 631
 632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 633 {
 634         var float i = weaponinfo.weapon;
 635         var float d = 0;
 636
 637         if (!i)
 638                 return 0;
 639
 640         if (g_lms || g_ca || allguns)
 641         {
 642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 643                         d = TRUE;
 644                 else
 645                         d = FALSE;
 646         }
 647         else if (g_cts)
 648                 d = (i == WEP_SHOTGUN);
 649         else if (g_nexball)
 650                 d = 0; // weapon is set a few lines later
 651         else
 652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 653
 654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 655                 d |= (i == WEP_HOOK);
 656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 657                 d = 0;
 658
 659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 660
 661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 662
 663         // bit order in t:
 664         // 1: want or not
 665         // 2: is default?
 666         // 4: is set by default?
 667         if(t < 0)
 668                 t = 4 | (3 * d);
 669         else
 670                 t |= (2 * d);
 671
 672         return t;
 673 }
 674
 675 void readplayerstartcvars()
 676 {
 677         entity e;
 678         float i, j, t;
 679         string s;
 680
 681         // initialize starting values for players
 682         start_weapons = '0 0 0';
 683         start_weapons_default = '0 0 0';
 684         start_weapons_defaultmask = '0 0 0';
 685         start_items = 0;
 686         start_ammo_shells = 0;
 687         start_ammo_nails = 0;
 688         start_ammo_rockets = 0;
 689         start_ammo_cells = 0;
 690         start_health = cvar("g_balance_health_start");
 691         start_armorvalue = cvar("g_balance_armor_start");
 692
 693         g_weaponarena = 0;
 694         g_weaponarena_weapons = '0 0 0';
 695
 696         s = cvar_string("g_weaponarena");
 697         if (s == "0" || s == "")
 698         {
 699                 if(g_ca)
 700                         s = "most";
 701         }
 702
 703         if (s == "0" || s == "")
 704         {
 705                 // no arena
 706         }
 707         else if (s == "off")
 708         {
 709                 // forcibly turn off weaponarena
 710         }
 711         else if (s == "all" || s == "1")
 712         {
 713                 g_weaponarena = 1;
 714                 g_weaponarena_list = "All Weapons";
 715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 716                 {
 717                         e = get_weaponinfo(j);
 718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 720                 }
 721         }
 722         else if (s == "most")
 723         {
 724                 g_weaponarena = 1;
 725                 g_weaponarena_list = "Most Weapons";
 726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 727                 {
 728                         e = get_weaponinfo(j);
 729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 732                 }
 733         }
 734         else if (s == "none")
 735         {
 736                 g_weaponarena = 1;
 737                 g_weaponarena_list = "No Weapons";
 738         }
 739         else
 740         {
 741                 g_weaponarena = 1;
 742                 t = tokenize_console(s);
 743                 g_weaponarena_list = "";
 744                 for (i = 0; i < t; ++i)
 745                 {
 746                         s = argv(i);
 747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 748                         {
 749                                 e = get_weaponinfo(j);
 750                                 if (e.netname == s)
 751                                 {
 752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 754                                         break;
 755                                 }
 756                         }
 757                         if (j > WEP_LAST)
 758                         {
 759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 760                         }
 761                 }
 762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 763         }
 764
 765         if(g_weaponarena)
 766                 g_weaponarena_random = cvar("g_weaponarena_random");
 767         else
 768                 g_weaponarena_random = 0;
 769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 770
 771         if (g_weaponarena)
 772         {
 773                 g_weapon_stay = 0; // incompatible
 774                 start_weapons = g_weaponarena_weapons;
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 start_weapons |= WepSet_FromWeapon(i);
 785                         if(w & 2)
 786                                 start_weapons_default |= WepSet_FromWeapon(i);
 787                         if(w & 4)
 788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (warmup_stage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 warmup_start_weapons = start_weapons;
 822                 warmup_start_weapons_default = start_weapons_default;
 823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         warmup_start_weapons = '0 0 0';
 835                         warmup_start_weapons_default = '0 0 0';
 836                         warmup_start_weapons_defaultmask = '0 0 0';
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 841                                 if(w & 1)
 842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 843                                 if(w & 2)
 844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 845                                 if(w & 4)
 846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         WepSet precache_weapons = start_weapons;
 865         if (g_warmup_allguns != 1)
 866                 precache_weapons |= warmup_start_weapons;
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(precache_weapons & WepSet_FromWeapon(i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void mutators_add(); // mutators.qc
 908 void readlevelcvars(void)
 909 {
 910         // load mutators
 911         mutators_add();
 912
 913         if(cvar("sv_allow_fullbright"))
 914                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 915
 916     g_bugrigs = cvar("g_bugrigs");
 917     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 918     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 919     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 920     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 921     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 922     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 923     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 924     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 925     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 926     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 927     g_bugrigs_accel = cvar("g_bugrigs_accel");
 928     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 929     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 930     g_bugrigs_steer = cvar("g_bugrigs_steer");
 931
 932         g_instagib = cvar("g_instagib");
 933
 934         sv_clones = cvar("sv_clones");
 935         sv_foginterval = cvar("sv_foginterval");
 936         g_cloaked = cvar("g_cloaked");
 937         g_footsteps = cvar("g_footsteps");
 938         g_grappling_hook = cvar("g_grappling_hook");
 939         g_jetpack = cvar("g_jetpack");
 940         sv_maxidle = cvar("sv_maxidle");
 941         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 942         sv_autotaunt = cvar("sv_autotaunt");
 943         sv_taunt = cvar("sv_taunt");
 944
 945         warmup_stage = cvar("g_warmup");
 946         g_warmup_limit = cvar("g_warmup_limit");
 947         g_warmup_allguns = cvar("g_warmup_allguns");
 948         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 949
 950         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 951                 warmup_stage = 0; // these modes cannot work together, sorry
 952
 953         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 954         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 955         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 956         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 957         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 958         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 959         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 960         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 961         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 962         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 963         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 964         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 965         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 966         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 967
 968         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 969         g_weaponratefactor = cvar("g_weaponratefactor");
 970         g_weapondamagefactor = cvar("g_weapondamagefactor");
 971         g_weaponforcefactor = cvar("g_weaponforcefactor");
 972         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 973
 974         g_pickup_shells = cvar("g_pickup_shells");
 975         g_pickup_shells_max = cvar("g_pickup_shells_max");
 976         g_pickup_nails = cvar("g_pickup_nails");
 977         g_pickup_nails_max = cvar("g_pickup_nails_max");
 978         g_pickup_rockets = cvar("g_pickup_rockets");
 979         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 980         g_pickup_cells = cvar("g_pickup_cells");
 981         g_pickup_cells_max = cvar("g_pickup_cells_max");
 982         g_pickup_fuel = cvar("g_pickup_fuel");
 983         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 984         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 985         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 986         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 987         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 988         g_pickup_armormedium = cvar("g_pickup_armormedium");
 989         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 990         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
 991         g_pickup_armorbig = cvar("g_pickup_armorbig");
 992         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
 993         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
 994         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
 995         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
 996         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
 997         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
 998         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
 999         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1000         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1001         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1002         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1003         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1004         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1005         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1006         g_pickup_healthmega = cvar("g_pickup_healthmega");
1007         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1008         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1009
1010         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1011         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1012
1013     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1014     if(!g_weapon_stay)
1015         g_weapon_stay = cvar("g_weapon_stay");
1016
1017         if (!warmup_stage)
1018                 game_starttime = time + cvar("g_start_delay");
1019
1020         readplayerstartcvars();
1021 }
1022
1023 //#NO AUTOCVARS END
1024
1025 // Sound functions
1026 string precache_sound (string s) = #19;
1027 float precache_sound_index (string s) = #19;
1028
1029 #define SND_VOLUME      1
1030 #define SND_ATTENUATION 2
1031 #define SND_LARGEENTITY 8
1032 #define SND_LARGESOUND  16
1033
1034 float sound_allowed(float dest, entity e)
1035 {
1036     // sounds from world may always pass
1037     for (;;)
1038     {
1039         if (e.classname == "body")
1040             e = e.enemy;
1041         else if (e.realowner && e.realowner != e)
1042             e = e.realowner;
1043         else if (e.owner && e.owner != e)
1044             e = e.owner;
1045         else
1046             break;
1047     }
1048     // sounds to self may always pass
1049     if (dest == MSG_ONE)
1050         if (e == msg_entity)
1051             return TRUE;
1052     // sounds by players can be removed
1053     if (autocvar_bot_sound_monopoly)
1054         if (IS_REAL_CLIENT(e))
1055             return FALSE;
1056     // anything else may pass
1057     return TRUE;
1058 }
1059
1060 #undef sound
1061 void sound(entity e, float chan, string samp, float vol, float atten)
1062 {
1063     if (!sound_allowed(MSG_BROADCAST, e))
1064         return;
1065     sound7(e, chan, samp, vol, atten, 0, 0);
1066 }
1067
1068 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1069 {
1070     float entno, idx;
1071
1072     if (!sound_allowed(dest, e))
1073         return;
1074
1075     entno = num_for_edict(e);
1076     idx = precache_sound_index(samp);
1077
1078     float sflags;
1079     sflags = 0;
1080
1081     atten = floor(atten * 64);
1082     vol = floor(vol * 255);
1083
1084     if (vol != 255)
1085         sflags |= SND_VOLUME;
1086     if (atten != 64)
1087         sflags |= SND_ATTENUATION;
1088     if (entno >= 8192 || chan < 0 || chan > 7)
1089         sflags |= SND_LARGEENTITY;
1090     if (idx >= 256)
1091         sflags |= SND_LARGESOUND;
1092
1093     WriteByte(dest, SVC_SOUND);
1094     WriteByte(dest, sflags);
1095     if (sflags & SND_VOLUME)
1096         WriteByte(dest, vol);
1097     if (sflags & SND_ATTENUATION)
1098         WriteByte(dest, atten);
1099     if (sflags & SND_LARGEENTITY)
1100     {
1101         WriteShort(dest, entno);
1102         WriteByte(dest, chan);
1103     }
1104     else
1105     {
1106         WriteShort(dest, entno * 8 + chan);
1107     }
1108     if (sflags & SND_LARGESOUND)
1109         WriteShort(dest, idx);
1110     else
1111         WriteByte(dest, idx);
1112
1113     WriteCoord(dest, o_x);
1114     WriteCoord(dest, o_y);
1115     WriteCoord(dest, o_z);
1116 }
1117 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1118 {
1119     vector o;
1120
1121     if (!sound_allowed(dest, e))
1122         return;
1123
1124     o = e.origin + 0.5 * (e.mins + e.maxs);
1125     soundtoat(dest, e, o, chan, samp, vol, atten);
1126 }
1127 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1128 {
1129     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1130 }
1131 void stopsoundto(float dest, entity e, float chan)
1132 {
1133     float entno;
1134
1135     if (!sound_allowed(dest, e))
1136         return;
1137
1138     entno = num_for_edict(e);
1139
1140     if (entno >= 8192 || chan < 0 || chan > 7)
1141     {
1142         float idx, sflags;
1143         idx = precache_sound_index("misc/null.wav");
1144         sflags = SND_LARGEENTITY;
1145         if (idx >= 256)
1146             sflags |= SND_LARGESOUND;
1147         WriteByte(dest, SVC_SOUND);
1148         WriteByte(dest, sflags);
1149         WriteShort(dest, entno);
1150         WriteByte(dest, chan);
1151         if (sflags & SND_LARGESOUND)
1152             WriteShort(dest, idx);
1153         else
1154             WriteByte(dest, idx);
1155         WriteCoord(dest, e.origin_x);
1156         WriteCoord(dest, e.origin_y);
1157         WriteCoord(dest, e.origin_z);
1158     }
1159     else
1160     {
1161         WriteByte(dest, SVC_STOPSOUND);
1162         WriteShort(dest, entno * 8 + chan);
1163     }
1164 }
1165 void stopsound(entity e, float chan)
1166 {
1167     if (!sound_allowed(MSG_BROADCAST, e))
1168         return;
1169
1170     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1171     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1172 }
1173
1174 void play2(entity e, string filename)
1175 {
1176     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1177     msg_entity = e;
1178     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1179 }
1180
1181 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1182 .float spamtime;
1183 float spamsound(entity e, float chan, string samp, float vol, float atten)
1184 {
1185     if (!sound_allowed(MSG_BROADCAST, e))
1186         return FALSE;
1187
1188     if (time > e.spamtime)
1189     {
1190         e.spamtime = time;
1191         sound(e, chan, samp, vol, atten);
1192         return TRUE;
1193     }
1194     return FALSE;
1195 }
1196
1197 void play2team(float t, string filename)
1198 {
1199     entity head;
1200
1201     if (autocvar_bot_sound_monopoly)
1202         return;
1203
1204     FOR_EACH_REALPLAYER(head)
1205     {
1206         if (head.team == t)
1207             play2(head, filename);
1208     }
1209 }
1210
1211 void play2all(string samp)
1212 {
1213     if (autocvar_bot_sound_monopoly)
1214         return;
1215
1216     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1217 }
1218
1219 void PrecachePlayerSounds(string f);
1220 void precache_playermodel(string m)
1221 {
1222         float globhandle, i, n;
1223         string f;
1224
1225         if(substring(m, -9,5) == "_lod1")
1226                 return;
1227         if(substring(m, -9,5) == "_lod2")
1228                 return;
1229         precache_model(m);
1230         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1231         if(fexists(f))
1232                 precache_model(f);
1233         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1234         if(fexists(f))
1235                 precache_model(f);
1236
1237         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1238         if (globhandle < 0)
1239                 return;
1240         n = search_getsize(globhandle);
1241         for (i = 0; i < n; ++i)
1242         {
1243                 //print(search_getfilename(globhandle, i), "\n");
1244                 f = search_getfilename(globhandle, i);
1245                 PrecachePlayerSounds(f);
1246         }
1247         search_end(globhandle);
1248 }
1249 void precache_all_playermodels(string pattern)
1250 {
1251         float globhandle, i, n;
1252         string f;
1253
1254         globhandle = search_begin(pattern, TRUE, FALSE);
1255         if (globhandle < 0)
1256                 return;
1257         n = search_getsize(globhandle);
1258         for (i = 0; i < n; ++i)
1259         {
1260                 //print(search_getfilename(globhandle, i), "\n");
1261                 f = search_getfilename(globhandle, i);
1262                 precache_playermodel(f);
1263         }
1264         search_end(globhandle);
1265 }
1266
1267 void precache()
1268 {
1269     // gamemode related things
1270     precache_model ("models/misc/chatbubble.spr");
1271         precache_model("models/ice/ice.md3");
1272
1273 #ifdef TTURRETS_ENABLED
1274     if (autocvar_g_turrets)
1275         turrets_precash();
1276 #endif
1277
1278     // Precache all player models if desired
1279     if (autocvar_sv_precacheplayermodels)
1280     {
1281         PrecachePlayerSounds("sound/player/default.sounds");
1282         precache_all_playermodels("models/player/*.zym");
1283         precache_all_playermodels("models/player/*.dpm");
1284         precache_all_playermodels("models/player/*.md3");
1285         precache_all_playermodels("models/player/*.psk");
1286         precache_all_playermodels("models/player/*.iqm");
1287     }
1288
1289     if (autocvar_sv_defaultcharacter)
1290     {
1291         string s;
1292         s = autocvar_sv_defaultplayermodel_red;
1293         if (s != "")
1294             precache_playermodel(s);
1295         s = autocvar_sv_defaultplayermodel_blue;
1296         if (s != "")
1297             precache_playermodel(s);
1298         s = autocvar_sv_defaultplayermodel_yellow;
1299         if (s != "")
1300             precache_playermodel(s);
1301         s = autocvar_sv_defaultplayermodel_pink;
1302         if (s != "")
1303             precache_playermodel(s);
1304         s = autocvar_sv_defaultplayermodel;
1305         if (s != "")
1306             precache_playermodel(s);
1307     }
1308
1309     if (g_footsteps)
1310     {
1311         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1312         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1313     }
1314
1315     // gore and miscellaneous sounds
1316     //precache_sound ("misc/h2ohit.wav");
1317     precache_model ("models/hook.md3");
1318     precache_sound ("misc/armorimpact.wav");
1319     precache_sound ("misc/bodyimpact1.wav");
1320     precache_sound ("misc/bodyimpact2.wav");
1321     precache_sound ("misc/gib.wav");
1322     precache_sound ("misc/gib_splat01.wav");
1323     precache_sound ("misc/gib_splat02.wav");
1324     precache_sound ("misc/gib_splat03.wav");
1325     precache_sound ("misc/gib_splat04.wav");
1326     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1327     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1328     precache_sound ("misc/null.wav");
1329     precache_sound ("misc/spawn.wav");
1330     precache_sound ("misc/talk.wav");
1331     precache_sound ("misc/teleport.wav");
1332     precache_sound ("misc/poweroff.wav");
1333     precache_sound ("player/lava.wav");
1334     precache_sound ("player/slime.wav");
1335
1336     precache_model ("models/sprites/0.spr32");
1337     precache_model ("models/sprites/1.spr32");
1338     precache_model ("models/sprites/2.spr32");
1339     precache_model ("models/sprites/3.spr32");
1340     precache_model ("models/sprites/4.spr32");
1341     precache_model ("models/sprites/5.spr32");
1342     precache_model ("models/sprites/6.spr32");
1343     precache_model ("models/sprites/7.spr32");
1344     precache_model ("models/sprites/8.spr32");
1345     precache_model ("models/sprites/9.spr32");
1346     precache_model ("models/sprites/10.spr32");
1347
1348     // common weapon precaches
1349         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1350     precache_sound ("weapons/weapon_switch.wav");
1351     precache_sound ("weapons/weaponpickup.wav");
1352     precache_sound ("weapons/unavailable.wav");
1353     precache_sound ("weapons/dryfire.wav");
1354     if (g_grappling_hook)
1355     {
1356         precache_sound ("weapons/hook_fire.wav"); // hook
1357         precache_sound ("weapons/hook_impact.wav"); // hook
1358     }
1359
1360     if(autocvar_sv_precacheweapons)
1361     {
1362         //precache weapon models/sounds
1363         float wep;
1364         wep = WEP_FIRST;
1365         while (wep <= WEP_LAST)
1366         {
1367             weapon_action(wep, WR_PRECACHE);
1368             wep = wep + 1;
1369         }
1370     }
1371
1372     precache_model("models/elaser.mdl");
1373     precache_model("models/laser.mdl");
1374     precache_model("models/ebomb.mdl");
1375
1376 #if 0
1377     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1378
1379     if (!self.noise && self.music) // quake 3 uses the music field
1380         self.noise = self.music;
1381
1382     // plays music for the level if there is any
1383     if (self.noise)
1384     {
1385         precache_sound (self.noise);
1386         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1387     }
1388 #endif
1389
1390 #include "precache-for-csqc.inc"
1391 }
1392
1393 // WARNING: this kills the trace globals
1394 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1395 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1396
1397 #define INITPRIO_FIRST              0
1398 #define INITPRIO_GAMETYPE           0
1399 #define INITPRIO_GAMETYPE_FALLBACK  1
1400 #define INITPRIO_FINDTARGET        10
1401 #define INITPRIO_DROPTOFLOOR       20
1402 #define INITPRIO_SETLOCATION       90
1403 #define INITPRIO_LINKDOORS         91
1404 #define INITPRIO_LAST              99
1405
1406 .void(void) initialize_entity;
1407 .float initialize_entity_order;
1408 .entity initialize_entity_next;
1409 entity initialize_entity_first;
1410
1411 void make_safe_for_remove(entity e)
1412 {
1413     if (e.initialize_entity)
1414     {
1415         entity ent, prev = world;
1416         for (ent = initialize_entity_first; ent; )
1417         {
1418             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1419             {
1420                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1421                 // skip it in linked list
1422                 if (prev)
1423                 {
1424                     prev.initialize_entity_next = ent.initialize_entity_next;
1425                     ent = prev.initialize_entity_next;
1426                 }
1427                 else
1428                 {
1429                     initialize_entity_first = ent.initialize_entity_next;
1430                     ent = initialize_entity_first;
1431                 }
1432             }
1433             else
1434             {
1435                 prev = ent;
1436                 ent = ent.initialize_entity_next;
1437             }
1438         }
1439     }
1440 }
1441
1442 void objerror(string s)
1443 {
1444     make_safe_for_remove(self);
1445     builtin_objerror(s);
1446 }
1447
1448 .float remove_except_protected_forbidden;
1449 void remove_except_protected(entity e)
1450 {
1451         if(e.remove_except_protected_forbidden)
1452                 error("not allowed to remove this at this point");
1453         builtin_remove(e);
1454 }
1455
1456 void remove_unsafely(entity e)
1457 {
1458     if(e.classname == "spike")
1459         error("Removing spikes is forbidden (crylink bug), please report");
1460     builtin_remove(e);
1461 }
1462
1463 void remove_safely(entity e)
1464 {
1465     make_safe_for_remove(e);
1466     builtin_remove(e);
1467 }
1468
1469 void InitializeEntity(entity e, void(void) func, float order)
1470 {
1471     entity prev, cur;
1472
1473     if (!e || e.initialize_entity)
1474     {
1475         // make a proxy initializer entity
1476         entity e_old;
1477         e_old = e;
1478         e = spawn();
1479         e.classname = "initialize_entity";
1480         e.enemy = e_old;
1481     }
1482
1483     e.initialize_entity = func;
1484     e.initialize_entity_order = order;
1485
1486     cur = initialize_entity_first;
1487     prev = world;
1488     for (;;)
1489     {
1490         if (!cur || cur.initialize_entity_order > order)
1491         {
1492             // insert between prev and cur
1493             if (prev)
1494                 prev.initialize_entity_next = e;
1495             else
1496                 initialize_entity_first = e;
1497             e.initialize_entity_next = cur;
1498             return;
1499         }
1500         prev = cur;
1501         cur = cur.initialize_entity_next;
1502     }
1503 }
1504 void InitializeEntitiesRun()
1505 {
1506     entity startoflist;
1507     startoflist = initialize_entity_first;
1508     initialize_entity_first = world;
1509     remove = remove_except_protected;
1510     for (self = startoflist; self; self = self.initialize_entity_next)
1511     {
1512         self.remove_except_protected_forbidden = 1;
1513     }
1514     for (self = startoflist; self; )
1515     {
1516         entity e;
1517         var void(void) func;
1518         e = self.initialize_entity_next;
1519         func = self.initialize_entity;
1520         self.initialize_entity_order = 0;
1521         self.initialize_entity = func_null;
1522         self.initialize_entity_next = world;
1523         self.remove_except_protected_forbidden = 0;
1524         if (self.classname == "initialize_entity")
1525         {
1526             entity e_old;
1527             e_old = self.enemy;
1528             builtin_remove(self);
1529             self = e_old;
1530         }
1531         //dprint("Delayed initialization: ", self.classname, "\n");
1532         if(func)
1533             func();
1534         else
1535         {
1536             eprint(self);
1537             backtrace(strcat("Null function in: ", self.classname, "\n"));
1538         }
1539         self = e;
1540     }
1541     remove = remove_unsafely;
1542 }
1543
1544 .float uncustomizeentityforclient_set;
1545 .void(void) uncustomizeentityforclient;
1546 void UncustomizeEntitiesRun()
1547 {
1548     entity oldself;
1549     oldself = self;
1550     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1551         self.uncustomizeentityforclient();
1552     self = oldself;
1553 }
1554 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1555 {
1556     e.customizeentityforclient = customizer;
1557     e.uncustomizeentityforclient = uncustomizer;
1558     e.uncustomizeentityforclient_set = !!uncustomizer;
1559 }
1560
1561 .float nottargeted;
1562 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1563
1564 void() SUB_Remove;
1565 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1566 {
1567     vector mi, ma;
1568
1569     if (e.classname == "")
1570         e.classname = "net_linked";
1571
1572     if (e.model == "" || self.modelindex == 0)
1573     {
1574         mi = e.mins;
1575         ma = e.maxs;
1576         setmodel(e, "null");
1577         setsize(e, mi, ma);
1578     }
1579
1580     e.SendEntity = sendfunc;
1581     e.SendFlags = 0xFFFFFF;
1582
1583     if (!docull)
1584         e.effects |= EF_NODEPTHTEST;
1585
1586     if (dt)
1587     {
1588         e.nextthink = time + dt;
1589         e.think = SUB_Remove;
1590     }
1591 }
1592
1593
1594 entity eliminatedPlayers;
1595 .float(entity) isEliminated;
1596 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1597 {
1598         float i, f, b;
1599         entity e;
1600         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1601         WriteByte(MSG_ENTITY, sendflags);
1602
1603         if(sendflags & 1)
1604         {
1605                 for(i = 1; i <= maxclients; i += 8)
1606                 {
1607                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1608                         {
1609                                 if(eliminatedPlayers.isEliminated(e))
1610                                         f |= b;
1611                         }
1612                         WriteByte(MSG_ENTITY, f);
1613                 }
1614         }
1615
1616         return TRUE;
1617 }
1618
1619 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1620 {
1621         if(eliminatedPlayers)
1622         {
1623                 backtrace("Can't spawn eliminatedPlayers again!");
1624                 return;
1625         }
1626         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1627         eliminatedPlayers.isEliminated = isEliminated_func;
1628 }
1629
1630
1631 void adaptor_think2touch()
1632 {
1633     entity o;
1634     o = other;
1635     other = world;
1636     self.touch();
1637     other = o;
1638 }
1639
1640 void adaptor_think2use()
1641 {
1642     entity o, a;
1643     o = other;
1644     a = activator;
1645     activator = world;
1646     other = world;
1647     self.use();
1648     other = o;
1649     activator = a;
1650 }
1651
1652 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1653 {
1654         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1655                 self.projectiledeathtype |= HITTYPE_SPLASH;
1656         adaptor_think2use();
1657 }
1658
1659 // deferred dropping
1660 void DropToFloor_Handler()
1661 {
1662     builtin_droptofloor();
1663     self.dropped_origin = self.origin;
1664 }
1665
1666 void droptofloor()
1667 {
1668     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1669 }
1670
1671
1672
1673 float trace_hits_box_a0, trace_hits_box_a1;
1674
1675 float trace_hits_box_1d(float end, float thmi, float thma)
1676 {
1677     if (end == 0)
1678     {
1679         // just check if x is in range
1680         if (0 < thmi)
1681             return FALSE;
1682         if (0 > thma)
1683             return FALSE;
1684     }
1685     else
1686     {
1687         // do the trace with respect to x
1688         // 0 -> end has to stay in thmi -> thma
1689         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1690         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1691         if (trace_hits_box_a0 > trace_hits_box_a1)
1692             return FALSE;
1693     }
1694     return TRUE;
1695 }
1696
1697 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1698 {
1699     end -= start;
1700     thmi -= start;
1701     thma -= start;
1702     // now it is a trace from 0 to end
1703
1704     trace_hits_box_a0 = 0;
1705     trace_hits_box_a1 = 1;
1706
1707     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1708         return FALSE;
1709     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1710         return FALSE;
1711     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1712         return FALSE;
1713
1714     return TRUE;
1715 }
1716
1717 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1718 {
1719     return trace_hits_box(start, end, thmi - ma, thma - mi);
1720 }
1721
1722 float SUB_NoImpactCheck()
1723 {
1724         // zero hitcontents = this is not the real impact, but either the
1725         // mirror-impact of something hitting the projectile instead of the
1726         // projectile hitting the something, or a touchareagrid one. Neither of
1727         // these stop the projectile from moving, so...
1728         if(trace_dphitcontents == 0)
1729         {
1730                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1731                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1732                 checkclient();
1733         }
1734     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1735         return 1;
1736     if (other == world && self.size != '0 0 0')
1737     {
1738         vector tic;
1739         tic = self.velocity * sys_frametime;
1740         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1741         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1742         if (trace_fraction >= 1)
1743         {
1744             dprint("Odd... did not hit...?\n");
1745         }
1746         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1747         {
1748             dprint("Detected and prevented the sky-grapple bug.\n");
1749             return 1;
1750         }
1751     }
1752
1753     return 0;
1754 }
1755
1756 #define SUB_OwnerCheck() (other && (other == self.owner))
1757
1758 void RemoveGrapplingHook(entity pl);
1759 void W_Crylink_Dequeue(entity e);
1760 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1761 {
1762         if(SUB_OwnerCheck())
1763                 return TRUE;
1764         if(SUB_NoImpactCheck())
1765         {
1766                 if(self.classname == "grapplinghook")
1767                         RemoveGrapplingHook(self.realowner);
1768                 else if(self.classname == "spike")
1769                 {
1770                         W_Crylink_Dequeue(self);
1771                         remove(self);
1772                 }
1773                 else
1774                         remove(self);
1775                 return TRUE;
1776         }
1777         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1778                 UpdateCSQCProjectile(self);
1779         return FALSE;
1780 }
1781 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1782
1783 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1784 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1785
1786 void URI_Get_Callback(float id, float status, string data)
1787 {
1788         if(url_URI_Get_Callback(id, status, data))
1789         {
1790                 // handled
1791         }
1792         else if (id == URI_GET_DISCARD)
1793         {
1794                 // discard
1795         }
1796         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1797         {
1798                 // sv_cmd curl
1799                 Curl_URI_Get_Callback(id, status, data);
1800         }
1801         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1802         {
1803                 // online ban list
1804                 OnlineBanList_URI_Get_Callback(id, status, data);
1805         }
1806         else
1807         {
1808                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1809         }
1810 }
1811
1812 string uid2name(string myuid) {
1813         string s;
1814         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1815
1816         // FIXME remove this later after 0.6 release
1817         // convert old style broken records to correct style
1818         if(s == "")
1819         {
1820                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1821                 if(s != "")
1822                 {
1823                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1824                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1825                 }
1826         }
1827
1828         if(s == "")
1829                 s = "^1Unregistered Player";
1830         return s;
1831 }
1832
1833 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1834 {
1835     float m, i;
1836     vector start, org, delta, end, enddown, mstart;
1837     entity sp;
1838
1839     m = e.dphitcontentsmask;
1840     e.dphitcontentsmask = goodcontents | badcontents;
1841
1842     org = world.mins;
1843     delta = world.maxs - world.mins;
1844
1845     start = end = org;
1846
1847     for (i = 0; i < attempts; ++i)
1848     {
1849         start_x = org_x + random() * delta_x;
1850         start_y = org_y + random() * delta_y;
1851         start_z = org_z + random() * delta_z;
1852
1853         // rule 1: start inside world bounds, and outside
1854         // solid, and don't start from somewhere where you can
1855         // fall down to evil
1856         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1857         if (trace_fraction >= 1)
1858             continue;
1859         if (trace_startsolid)
1860             continue;
1861         if (trace_dphitcontents & badcontents)
1862             continue;
1863         if (trace_dphitq3surfaceflags & badsurfaceflags)
1864             continue;
1865
1866         // rule 2: if we are too high, lower the point
1867         if (trace_fraction * delta_z > maxaboveground)
1868             start = trace_endpos + '0 0 1' * maxaboveground;
1869         enddown = trace_endpos;
1870
1871         // rule 3: make sure we aren't outside the map. This only works
1872         // for somewhat well formed maps. A good rule of thumb is that
1873         // the map should have a convex outside hull.
1874         // these can be traceLINES as we already verified the starting box
1875         mstart = start + 0.5 * (e.mins + e.maxs);
1876         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1877         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1878             continue;
1879         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1880         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1881             continue;
1882         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1883         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1884             continue;
1885         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1886         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1887             continue;
1888         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1889         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1890             continue;
1891
1892         // rule 4: we must "see" some spawnpoint or item
1893         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1894                 if(checkpvs(mstart, sp))
1895                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1896                                 break;
1897         if(!sp)
1898         {
1899                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1900                         if(checkpvs(mstart, sp))
1901                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1902                                         break;
1903                 if(!sp)
1904                         continue;
1905         }
1906
1907         // find a random vector to "look at"
1908         end_x = org_x + random() * delta_x;
1909         end_y = org_y + random() * delta_y;
1910         end_z = org_z + random() * delta_z;
1911         end = start + normalize(end - start) * vlen(delta);
1912
1913         // rule 4: start TO end must not be too short
1914         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1915         if (trace_startsolid)
1916             continue;
1917         if (trace_fraction < minviewdistance / vlen(delta))
1918             continue;
1919
1920         // rule 5: don't want to look at sky
1921         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1922             continue;
1923
1924         // rule 6: we must not end up in trigger_hurt
1925         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1926             continue;
1927
1928         break;
1929     }
1930
1931     e.dphitcontentsmask = m;
1932
1933     if (i < attempts)
1934     {
1935         setorigin(e, start);
1936         e.angles = vectoangles(end - start);
1937         dprint("Needed ", ftos(i + 1), " attempts\n");
1938         return TRUE;
1939     }
1940     else
1941         return FALSE;
1942 }
1943
1944 void write_recordmarker(entity pl, float tstart, float dt)
1945 {
1946     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1947
1948     // also write a marker into demo files for demotc-race-record-extractor to find
1949     stuffcmd(pl,
1950              strcat(
1951                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1952                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1953 }
1954
1955 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1956 {
1957         switch(algn)
1958         {
1959                 default:
1960                 case 3: // right
1961                         break;
1962
1963                 case 4: // left
1964                         vecs_y = -vecs_y;
1965                         break;
1966
1967                 case 1:
1968                         if(allowcenter) // 2: allow center handedness
1969                         {
1970                                 // center
1971                                 vecs_y = 0;
1972                                 vecs_z -= 2;
1973                         }
1974                         else
1975                         {
1976                                 // right
1977                         }
1978                         break;
1979
1980                 case 2:
1981                         if(allowcenter) // 2: allow center handedness
1982                         {
1983                                 // center
1984                                 vecs_y = 0;
1985                                 vecs_z -= 2;
1986                         }
1987                         else
1988                         {
1989                                 // left
1990                                 vecs_y = -vecs_y;
1991                         }
1992                         break;
1993         }
1994         return vecs;
1995 }
1996
1997 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1998 {
1999         string s;
2000         vector v;
2001
2002         if (autocvar_g_shootfromeye)
2003         {
2004                 if (visual)
2005                 {
2006                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2007                         else { vecs_y = 0; vecs_z -= 2; }
2008                 }
2009                 else
2010                 {
2011                         vecs_y = 0;
2012                         vecs_z = 0;
2013                 }
2014         }
2015         else if (autocvar_g_shootfromcenter)
2016         {
2017                 vecs_y = 0;
2018                 vecs_z -= 2;
2019         }
2020         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2021         {
2022                 v = stov(s);
2023                 if (y_is_right)
2024                         v_y = -v_y;
2025                 if (v_x != 0)
2026                         vecs_x = v_x;
2027                 vecs_y = v_y;
2028                 vecs_z = v_z;
2029         }
2030         else if (autocvar_g_shootfromclient)
2031         {
2032                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2033         }
2034         return vecs;
2035 }
2036
2037 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2038 {
2039         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2040 }
2041
2042
2043 void attach_sameorigin(entity e, entity to, string tag)
2044 {
2045     vector org, t_forward, t_left, t_up, e_forward, e_up;
2046     float tagscale;
2047
2048     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2049     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2050     t_forward = v_forward * tagscale;
2051     t_left = v_right * -tagscale;
2052     t_up = v_up * tagscale;
2053
2054     e.origin_x = org * t_forward;
2055     e.origin_y = org * t_left;
2056     e.origin_z = org * t_up;
2057
2058     // current forward and up directions
2059     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2060                 e.angles = AnglesTransform_FromVAngles(e.angles);
2061         else
2062                 e.angles = AnglesTransform_FromAngles(e.angles);
2063     fixedmakevectors(e.angles);
2064
2065     // untransform forward, up!
2066     e_forward_x = v_forward * t_forward;
2067     e_forward_y = v_forward * t_left;
2068     e_forward_z = v_forward * t_up;
2069     e_up_x = v_up * t_forward;
2070     e_up_y = v_up * t_left;
2071     e_up_z = v_up * t_up;
2072
2073     e.angles = fixedvectoangles2(e_forward, e_up);
2074     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2075                 e.angles = AnglesTransform_ToVAngles(e.angles);
2076         else
2077                 e.angles = AnglesTransform_ToAngles(e.angles);
2078
2079     setattachment(e, to, tag);
2080     setorigin(e, e.origin);
2081 }
2082
2083 void detach_sameorigin(entity e)
2084 {
2085     vector org;
2086     org = gettaginfo(e, 0);
2087     e.angles = fixedvectoangles2(v_forward, v_up);
2088     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2089                 e.angles = AnglesTransform_ToVAngles(e.angles);
2090         else
2091                 e.angles = AnglesTransform_ToAngles(e.angles);
2092     setorigin(e, org);
2093     setattachment(e, world, "");
2094     setorigin(e, e.origin);
2095 }
2096
2097 void follow_sameorigin(entity e, entity to)
2098 {
2099     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2100     e.aiment = to; // make the hole follow bmodel
2101     e.punchangle = to.angles; // the original angles of bmodel
2102     e.view_ofs = e.origin - to.origin; // relative origin
2103     e.v_angle = e.angles - to.angles; // relative angles
2104 }
2105
2106 void unfollow_sameorigin(entity e)
2107 {
2108     e.movetype = MOVETYPE_NONE;
2109 }
2110
2111 entity gettaginfo_relative_ent;
2112 vector gettaginfo_relative(entity e, float tag)
2113 {
2114     if (!gettaginfo_relative_ent)
2115     {
2116         gettaginfo_relative_ent = spawn();
2117         gettaginfo_relative_ent.effects = EF_NODRAW;
2118     }
2119     gettaginfo_relative_ent.model = e.model;
2120     gettaginfo_relative_ent.modelindex = e.modelindex;
2121     gettaginfo_relative_ent.frame = e.frame;
2122     return gettaginfo(gettaginfo_relative_ent, tag);
2123 }
2124
2125 .float scale2;
2126
2127 float modeleffect_SendEntity(entity to, float sf)
2128 {
2129         float f;
2130         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2131
2132         f = 0;
2133         if(self.velocity != '0 0 0')
2134                 f |= 1;
2135         if(self.angles != '0 0 0')
2136                 f |= 2;
2137         if(self.avelocity != '0 0 0')
2138                 f |= 4;
2139
2140         WriteByte(MSG_ENTITY, f);
2141         WriteShort(MSG_ENTITY, self.modelindex);
2142         WriteByte(MSG_ENTITY, self.skin);
2143         WriteByte(MSG_ENTITY, self.frame);
2144         WriteCoord(MSG_ENTITY, self.origin_x);
2145         WriteCoord(MSG_ENTITY, self.origin_y);
2146         WriteCoord(MSG_ENTITY, self.origin_z);
2147         if(f & 1)
2148         {
2149                 WriteCoord(MSG_ENTITY, self.velocity_x);
2150                 WriteCoord(MSG_ENTITY, self.velocity_y);
2151                 WriteCoord(MSG_ENTITY, self.velocity_z);
2152         }
2153         if(f & 2)
2154         {
2155                 WriteCoord(MSG_ENTITY, self.angles_x);
2156                 WriteCoord(MSG_ENTITY, self.angles_y);
2157                 WriteCoord(MSG_ENTITY, self.angles_z);
2158         }
2159         if(f & 4)
2160         {
2161                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2162                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2163                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2164         }
2165         WriteShort(MSG_ENTITY, self.scale * 256.0);
2166         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2167         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2168         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2169         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2170
2171         return TRUE;
2172 }
2173
2174 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2175 {
2176         entity e;
2177         float sz;
2178         e = spawn();
2179         e.classname = "modeleffect";
2180         setmodel(e, m);
2181         e.frame = f;
2182         setorigin(e, o);
2183         e.velocity = v;
2184         e.angles = ang;
2185         e.avelocity = angv;
2186         e.alpha = a;
2187         e.teleport_time = t1;
2188         e.fade_time = t2;
2189         e.skin = s;
2190         if(s0 >= 0)
2191                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2192         else
2193                 e.scale = -s0;
2194         if(s2 >= 0)
2195                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2196         else
2197                 e.scale2 = -s2;
2198         sz = max(e.scale, e.scale2);
2199         setsize(e, e.mins * sz, e.maxs * sz);
2200         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2201 }
2202
2203 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2204 {
2205         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2206 }
2207
2208 float randombit(float bits)
2209 {
2210         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2211                 return bits;
2212
2213         float n, f, b, r;
2214
2215         r = random();
2216         b = 0;
2217         n = 0;
2218
2219         for(f = 1; f <= bits; f *= 2)
2220         {
2221                 if(bits & f)
2222                 {
2223                         ++n;
2224                         r *= n;
2225                         if(r <= 1)
2226                                 b = f;
2227                         else
2228                                 r = (r - 1) / (n - 1);
2229                 }
2230         }
2231
2232         return b;
2233 }
2234
2235 float randombits(float bits, float k, float error_return)
2236 {
2237         float r;
2238         r = 0;
2239         while(k > 0 && bits != r)
2240         {
2241                 r += randombit(bits - r);
2242                 --k;
2243         }
2244         if(error_return)
2245                 if(k > 0)
2246                         return -1; // all
2247         return r;
2248 }
2249
2250 void randombit_test(float bits, float iter)
2251 {
2252         while(iter > 0)
2253         {
2254                 print(ftos(randombit(bits)), "\n");
2255                 --iter;
2256         }
2257 }
2258
2259 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2260 {
2261         if(halflifedist > 0)
2262                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2263         else if(halflifedist < 0)
2264                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2265         else
2266                 return 1;
2267 }
2268
2269
2270
2271
2272 #ifdef RELEASE
2273 #define cvar_string_normal builtin_cvar_string
2274 #define cvar_normal builtin_cvar
2275 #else
2276 string cvar_string_normal(string n)
2277 {
2278         if (!(cvar_type(n) & 1))
2279                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2280         return builtin_cvar_string(n);
2281 }
2282
2283 float cvar_normal(string n)
2284 {
2285         return stof(cvar_string_normal(n));
2286 }
2287 #endif
2288 #define cvar_set_normal builtin_cvar_set
2289
2290 void defer_think()
2291 {
2292     entity oself;
2293
2294     oself           = self;
2295     self            = self.owner;
2296     oself.think     = SUB_Remove;
2297     oself.nextthink = time;
2298
2299     oself.use();
2300 }
2301
2302 /*
2303     Execute func() after time + fdelay.
2304     self when func is executed = self when defer is called
2305 */
2306 void defer(float fdelay, void() func)
2307 {
2308     entity e;
2309
2310     e           = spawn();
2311     e.owner     = self;
2312     e.use       = func;
2313     e.think     = defer_think;
2314     e.nextthink = time + fdelay;
2315 }
2316
2317 .string aiment_classname;
2318 .float aiment_deadflag;
2319 void SetMovetypeFollow(entity ent, entity e)
2320 {
2321         // FIXME this may not be warpzone aware
2322         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2323         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2324         ent.aiment = e; // make the hole follow bmodel
2325         ent.punchangle = e.angles; // the original angles of bmodel
2326         ent.view_ofs = ent.origin - e.origin; // relative origin
2327         ent.v_angle = ent.angles - e.angles; // relative angles
2328         ent.aiment_classname = strzone(e.classname);
2329         ent.aiment_deadflag = e.deadflag;
2330 }
2331 void UnsetMovetypeFollow(entity ent)
2332 {
2333         ent.movetype = MOVETYPE_FLY;
2334         PROJECTILE_MAKETRIGGER(ent);
2335         ent.aiment = world;
2336 }
2337 float LostMovetypeFollow(entity ent)
2338 {
2339 /*
2340         if(ent.movetype != MOVETYPE_FOLLOW)
2341                 if(ent.aiment)
2342                         error("???");
2343 */
2344         if(ent.aiment)
2345         {
2346                 if(ent.aiment.classname != ent.aiment_classname)
2347                         return 1;
2348                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2349                         return 1;
2350         }
2351         return 0;
2352 }
2353
2354 float isPushable(entity e)
2355 {
2356         if(e.iscreature)
2357                 return TRUE;
2358         if(e.pushable)
2359                 return TRUE;
2360         switch(e.classname)
2361         {
2362                 case "body":
2363                 case "droppedweapon":
2364                 case "keepawayball":
2365                 case "nexball_basketball":
2366                 case "nexball_football":
2367                         return TRUE;
2368                 case "bullet": // antilagged bullets can't hit this either
2369                         return FALSE;
2370         }
2371         if (e.projectiledeathtype)
2372                 return TRUE;
2373         return FALSE;
2374 }