Remove a redundant mutator hook
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void crosshair_trace_plusvisibletriggers(entity pl)
12 {
13         entity first;
14         entity e;
15         first = findchainfloat(solid, SOLID_TRIGGER);
16
17         for (e = first; e; e = e.chain)
18                 if (e.model != "")
19                         e.solid = SOLID_BSP;
20
21         crosshair_trace(pl);
22
23         for (e = first; e; e = e.chain)
24                 e.solid = SOLID_TRIGGER;
25 }
26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
27 void WarpZone_crosshair_trace(entity pl)
28 {
29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
30 }
31
32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
33 void() spawnpoint_use;
34 string GetMapname();
35
36 string admin_name(void)
37 {
38         if(autocvar_sv_adminnick != "")
39                 return autocvar_sv_adminnick;
40         else
41                 return "SERVER ADMIN";
42 }
43
44 float DistributeEvenly_amount;
45 float DistributeEvenly_totalweight;
46 void DistributeEvenly_Init(float amount, float totalweight)
47 {
48     if (DistributeEvenly_amount)
49     {
50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
52     }
53     if (totalweight == 0)
54         DistributeEvenly_amount = 0;
55     else
56         DistributeEvenly_amount = amount;
57     DistributeEvenly_totalweight = totalweight;
58 }
59 float DistributeEvenly_Get(float weight)
60 {
61     float f;
62     if (weight <= 0)
63         return 0;
64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
65     DistributeEvenly_totalweight -= weight;
66     DistributeEvenly_amount -= f;
67     return f;
68 }
69 float DistributeEvenly_GetRandomized(float weight)
70 {
71     float f;
72     if (weight <= 0)
73         return 0;
74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
75     DistributeEvenly_totalweight -= weight;
76     DistributeEvenly_amount -= f;
77     return f;
78 }
79
80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
81
82 string STR_PLAYER = "player";
83 string STR_SPECTATOR = "spectator";
84 string STR_OBSERVER = "observer";
85
86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
93
94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
97
98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
101
102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
103
104 // copies a string to a tempstring (so one can strunzone it)
105 string strcat1(string s) = #115; // FRIK_FILE
106
107 float logfile_open;
108 float logfile;
109
110 void GameLogEcho(string s)
111 {
112     string fn;
113     float matches;
114
115     if (autocvar_sv_eventlog_files)
116     {
117         if (!logfile_open)
118         {
119             logfile_open = TRUE;
120             matches = autocvar_sv_eventlog_files_counter + 1;
121             cvar_set("sv_eventlog_files_counter", ftos(matches));
122             fn = ftos(matches);
123             if (strlen(fn) < 8)
124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
126             logfile = fopen(fn, FILE_APPEND);
127             fputs(logfile, ":logversion:3\n");
128         }
129         if (logfile >= 0)
130         {
131             if (autocvar_sv_eventlog_files_timestamps)
132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
133             else
134                 fputs(logfile, strcat(s, "\n"));
135         }
136     }
137     if (autocvar_sv_eventlog_console)
138     {
139         print(s, "\n");
140     }
141 }
142
143 void GameLogInit()
144 {
145     logfile_open = 0;
146     // will be opened later
147 }
148
149 void GameLogClose()
150 {
151     if (logfile_open && logfile >= 0)
152     {
153         fclose(logfile);
154         logfile = -1;
155     }
156 }
157
158 float spawnpoint_nag;
159 void relocate_spawnpoint()
160 {
161     // nudge off the floor
162     setorigin(self, self.origin + '0 0 1');
163
164     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
165     if (trace_startsolid)
166     {
167         vector o;
168         o = self.origin;
169         self.mins = PL_MIN;
170         self.maxs = PL_MAX;
171         if (!move_out_of_solid(self))
172             objerror("could not get out of solid at all!");
173         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
174         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
175         print(" ", ftos(self.origin_y - o_y));
176         print(" ", ftos(self.origin_z - o_z), "'\n");
177         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
178         {
179             if (!spawnpoint_nag)
180                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
181             spawnpoint_nag = 1;
182         }
183         else
184         {
185             setorigin(self, o);
186             self.mins = self.maxs = '0 0 0';
187             objerror("player spawn point in solid, mapper sucks!\n");
188             return;
189         }
190     }
191
192     self.use = spawnpoint_use;
193     self.team_saved = self.team;
194     if (!self.cnt)
195         self.cnt = 1;
196
197     if (have_team_spawns != 0)
198         if (self.team)
199             have_team_spawns = 1;
200     have_team_spawns_forteam[self.team] = 1;
201
202     if (autocvar_r_showbboxes)
203     {
204         // show where spawnpoints point at too
205         makevectors(self.angles);
206         entity e;
207         e = spawn();
208         e.classname = "info_player_foo";
209         setorigin(e, self.origin + v_forward * 24);
210         setsize(e, '-8 -8 -8', '8 8 8');
211         e.solid = SOLID_TRIGGER;
212     }
213 }
214
215 #define strstr strstrofs
216 /*
217 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
218 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
219 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
220 // BE CONSTANT OR strzoneD!
221 float strstr(string haystack, string needle, float offset)
222 {
223         float len, endpos;
224         string found;
225         len = strlen(needle);
226         endpos = strlen(haystack) - len;
227         while(offset <= endpos)
228         {
229                 found = substring(haystack, offset, len);
230                 if(found == needle)
231                         return offset;
232                 offset = offset + 1;
233         }
234         return -1;
235 }
236 */
237
238 float NUM_NEAREST_ENTITIES = 4;
239 entity nearest_entity[NUM_NEAREST_ENTITIES];
240 float nearest_length[NUM_NEAREST_ENTITIES];
241 entity findnearest(vector point, .string field, string value, vector axismod)
242 {
243     entity localhead;
244     float i;
245     float j;
246     float len;
247     vector dist;
248
249     float num_nearest;
250     num_nearest = 0;
251
252     localhead = find(world, field, value);
253     while (localhead)
254     {
255         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
256             dist = localhead.oldorigin;
257         else
258             dist = localhead.origin;
259         dist = dist - point;
260         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
261         len = vlen(dist);
262
263         for (i = 0; i < num_nearest; ++i)
264         {
265             if (len < nearest_length[i])
266                 break;
267         }
268
269         // now i tells us where to insert at
270         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
271         if (i < NUM_NEAREST_ENTITIES)
272         {
273             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
274             {
275                 nearest_length[j + 1] = nearest_length[j];
276                 nearest_entity[j + 1] = nearest_entity[j];
277             }
278             nearest_length[i] = len;
279             nearest_entity[i] = localhead;
280             if (num_nearest < NUM_NEAREST_ENTITIES)
281                 num_nearest = num_nearest + 1;
282         }
283
284         localhead = find(localhead, field, value);
285     }
286
287     // now use the first one from our list that we can see
288     for (i = 0; i < num_nearest; ++i)
289     {
290         traceline(point, nearest_entity[i].origin, TRUE, world);
291         if (trace_fraction == 1)
292         {
293             if (i != 0)
294             {
295                 dprint("Nearest point (");
296                 dprint(nearest_entity[0].netname);
297                 dprint(") is not visible, using a visible one.\n");
298             }
299             return nearest_entity[i];
300         }
301     }
302
303     if (num_nearest == 0)
304         return world;
305
306     dprint("Not seeing any location point, using nearest as fallback.\n");
307     /* DEBUGGING CODE:
308     dprint("Candidates were: ");
309     for(j = 0; j < num_nearest; ++j)
310     {
311         if(j != 0)
312                 dprint(", ");
313         dprint(nearest_entity[j].netname);
314     }
315     dprint("\n");
316     */
317
318     return nearest_entity[0];
319 }
320
321 void spawnfunc_target_location()
322 {
323     self.classname = "target_location";
324     // location name in netname
325     // eventually support: count, teamgame selectors, line of sight?
326 }
327
328 void spawnfunc_info_location()
329 {
330     self.classname = "target_location";
331     self.message = self.netname;
332 }
333
334 string NearestLocation(vector p)
335 {
336     entity loc;
337     string ret;
338     ret = "somewhere";
339     loc = findnearest(p, classname, "target_location", '1 1 1');
340     if (loc)
341     {
342         ret = loc.message;
343     }
344     else
345     {
346         loc = findnearest(p, target, "###item###", '1 1 4');
347         if (loc)
348             ret = loc.netname;
349     }
350     return ret;
351 }
352
353 string formatmessage(string msg)
354 {
355         float p, p1, p2;
356         float n;
357         vector cursor;
358         entity cursor_ent;
359         string escape;
360         string replacement;
361         p = 0;
362         n = 7;
363
364         WarpZone_crosshair_trace(self);
365         cursor = trace_endpos;
366         cursor_ent = trace_ent;
367
368         while (1) {
369                 if (n < 1)
370                         break; // too many replacements
371
372                 n = n - 1;
373                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
374                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
375
376                 if (p1 < 0)
377                         p1 = p2;
378
379                 if (p2 < 0)
380                         p2 = p1;
381
382                 p = min(p1, p2);
383
384                 if (p < 0)
385                         break;
386
387                 replacement = substring(msg, p, 2);
388                 escape = substring(msg, p + 1, 1);
389
390                 if (escape == "%")
391                         replacement = "%";
392                 else if (escape == "\\")
393                         replacement = "\\";
394                 else if (escape == "n")
395                         replacement = "\n";
396                 else if (escape == "a")
397                         replacement = ftos(floor(self.armorvalue));
398                 else if (escape == "h")
399                         replacement = ftos(floor(self.health));
400                 else if (escape == "l")
401                         replacement = NearestLocation(self.origin);
402                 else if (escape == "y")
403                         replacement = NearestLocation(cursor);
404                 else if (escape == "d")
405                         replacement = NearestLocation(self.death_origin);
406                 else if (escape == "w") {
407                         float wep;
408                         wep = self.weapon;
409                         if (!wep)
410                                 wep = self.switchweapon;
411                         if (!wep)
412                                 wep = self.cnt;
413                         replacement = W_Name(wep);
414                 } else if (escape == "W") {
415                         if (self.items & IT_SHELLS) replacement = "shells";
416                         else if (self.items & IT_NAILS) replacement = "bullets";
417                         else if (self.items & IT_ROCKETS) replacement = "rockets";
418                         else if (self.items & IT_CELLS) replacement = "cells";
419                         else replacement = "batteries"; // ;)
420                 } else if (escape == "x") {
421                         replacement = cursor_ent.netname;
422                         if (replacement == "" || !cursor_ent)
423                                 replacement = "nothing";
424                 } else if (escape == "s")
425                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
426                 else if (escape == "S")
427                         replacement = ftos(vlen(self.velocity));
428
429                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
430                 p = p + strlen(replacement);
431         }
432         return msg;
433 }
434
435 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
436         return (value == 0) ? FALSE : TRUE;
437 }
438
439 /*
440 =============
441 GetCvars
442 =============
443 Called with:
444   0:  sends the request
445   >0: receives a cvar from name=argv(f) value=argv(f+1)
446 */
447 void GetCvars_handleString(string thisname, float f, .string field, string name)
448 {
449         if (f < 0)
450         {
451                 if (self.field)
452                         strunzone(self.field);
453                 self.field = string_null;
454         }
455         else if (f > 0)
456         {
457                 if (thisname == name)
458                 {
459                         if (self.field)
460                                 strunzone(self.field);
461                         self.field = strzone(argv(f + 1));
462                 }
463         }
464         else
465                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
466 }
467 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
468 {
469         GetCvars_handleString(thisname, f, field, name);
470         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
471                 if (thisname == name)
472                 {
473                         string s;
474                         s = func(strcat1(self.field));
475                         if (s != self.field)
476                         {
477                                 strunzone(self.field);
478                                 self.field = strzone(s);
479                         }
480                 }
481 }
482 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
483 {
484         if (f < 0)
485         {
486         }
487         else if (f > 0)
488         {
489                 if (thisname == name)
490                         self.field = stof(argv(f + 1));
491         }
492         else
493                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
494 }
495 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
496 {
497         if (f < 0)
498         {
499         }
500         else if (f > 0)
501         {
502                 if (thisname == name)
503                 {
504                         if(!self.field)
505                         {
506                                 self.field = stof(argv(f + 1));
507                                 if(!self.field)
508                                         self.field = -1;
509                         }
510                 }
511         }
512         else
513         {
514                 if(!self.field)
515                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
516         }
517 }
518 float w_getbestweapon(entity e);
519 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
520 {
521         string o;
522         o = W_FixWeaponOrder_ForceComplete(wo);
523         if(self.weaponorder_byimpulse)
524         {
525                 strunzone(self.weaponorder_byimpulse);
526                 self.weaponorder_byimpulse = string_null;
527         }
528         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
529         return o;
530 }
531 void GetCvars(float f)
532 {
533         string s = string_null;
534
535         if (f > 0)
536                 s = strcat1(argv(f));
537
538         get_cvars_f = f;
539         get_cvars_s = s;
540
541         MUTATOR_CALLHOOK(GetCvars);
542
543         Notification_GetCvars();
544
545         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
546         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
547         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
548         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
549         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
561         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
562         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
563         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
564         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
565         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
566         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
567         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
568
569         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
570         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
571
572         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
573         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
574         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
575         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
576         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
577
578         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
579         if (f > 0)
580         {
581                 if (s == "cl_weaponpriority")
582                         self.switchweapon = w_getbestweapon(self);
583                 if (s == "cl_allow_uidtracking")
584                         PlayerStats_AddPlayer(self);
585         }
586 }
587
588 // decolorizes and team colors the player name when needed
589 string playername(entity p)
590 {
591     string t;
592     if (teamplay && !intermission_running && p.classname == "player")
593     {
594         t = Team_ColorCode(p.team);
595         return strcat(t, strdecolorize(p.netname));
596     }
597     else
598         return p.netname;
599 }
600
601 vector randompos(vector m1, vector m2)
602 {
603     vector v;
604     m2 = m2 - m1;
605     v_x = m2_x * random() + m1_x;
606     v_y = m2_y * random() + m1_y;
607     v_z = m2_z * random() + m1_z;
608     return  v;
609 }
610
611 //#NO AUTOCVARS START
612
613 float g_pickup_shells;
614 float g_pickup_shells_max;
615 float g_pickup_nails;
616 float g_pickup_nails_max;
617 float g_pickup_rockets;
618 float g_pickup_rockets_max;
619 float g_pickup_cells;
620 float g_pickup_cells_max;
621 float g_pickup_fuel;
622 float g_pickup_fuel_jetpack;
623 float g_pickup_fuel_max;
624 float g_pickup_armorsmall;
625 float g_pickup_armorsmall_max;
626 float g_pickup_armorsmall_anyway;
627 float g_pickup_armormedium;
628 float g_pickup_armormedium_max;
629 float g_pickup_armormedium_anyway;
630 float g_pickup_armorbig;
631 float g_pickup_armorbig_max;
632 float g_pickup_armorbig_anyway;
633 float g_pickup_armorlarge;
634 float g_pickup_armorlarge_max;
635 float g_pickup_armorlarge_anyway;
636 float g_pickup_healthsmall;
637 float g_pickup_healthsmall_max;
638 float g_pickup_healthsmall_anyway;
639 float g_pickup_healthmedium;
640 float g_pickup_healthmedium_max;
641 float g_pickup_healthmedium_anyway;
642 float g_pickup_healthlarge;
643 float g_pickup_healthlarge_max;
644 float g_pickup_healthlarge_anyway;
645 float g_pickup_healthmega;
646 float g_pickup_healthmega_max;
647 float g_pickup_healthmega_anyway;
648 float g_pickup_ammo_anyway;
649 float g_pickup_weapons_anyway;
650 float g_weaponarena;
651 WEPSET_DECLARE_A(g_weaponarena_weapons);
652 float g_weaponarena_random;
653 float g_weaponarena_random_with_laser;
654 string g_weaponarena_list;
655 float g_weaponspeedfactor;
656 float g_weaponratefactor;
657 float g_weapondamagefactor;
658 float g_weaponforcefactor;
659 float g_weaponspreadfactor;
660
661 WEPSET_DECLARE_A(start_weapons);
662 WEPSET_DECLARE_A(start_weapons_default);
663 WEPSET_DECLARE_A(start_weapons_defaultmask);
664 float start_items;
665 float start_ammo_shells;
666 float start_ammo_nails;
667 float start_ammo_rockets;
668 float start_ammo_cells;
669 float start_ammo_fuel;
670 float start_health;
671 float start_armorvalue;
672 WEPSET_DECLARE_A(warmup_start_weapons);
673 WEPSET_DECLARE_A(warmup_start_weapons_default);
674 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
675 float warmup_start_ammo_shells;
676 float warmup_start_ammo_nails;
677 float warmup_start_ammo_rockets;
678 float warmup_start_ammo_cells;
679 float warmup_start_ammo_fuel;
680 float warmup_start_health;
681 float warmup_start_armorvalue;
682 float g_weapon_stay;
683
684 entity get_weaponinfo(float w);
685
686 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
687 {
688         var float i = weaponinfo.weapon;
689         var float d = 0;
690
691         if (!i)
692                 return 0;
693
694         if (g_lms || g_ca || allguns)
695         {
696                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
697                         d = TRUE;
698                 else
699                         d = FALSE;
700         }
701         else if (g_cts)
702                 d = (i == WEP_SHOTGUN);
703         else if (g_nexball)
704                 d = 0; // weapon is set a few lines later
705         else
706                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
707                 
708         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
709                 d |= (i == WEP_HOOK);
710         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
711                 d = 0;
712
713         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
714         
715         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
716         
717         // bit order in t:
718         // 1: want or not
719         // 2: is default?
720         // 4: is set by default?
721         if(t < 0)
722                 t = 4 | (3 * d);
723         else
724                 t |= (2 * d);
725
726         return t;
727 }
728
729 void readplayerstartcvars()
730 {
731         entity e;
732         float i, j, t;
733         string s;
734
735         // initialize starting values for players
736         WEPSET_CLEAR_A(start_weapons);
737         WEPSET_CLEAR_A(start_weapons_default);
738         WEPSET_CLEAR_A(start_weapons_defaultmask);
739         start_items = 0;
740         start_ammo_shells = 0;
741         start_ammo_nails = 0;
742         start_ammo_rockets = 0;
743         start_ammo_cells = 0;
744         start_health = cvar("g_balance_health_start");
745         start_armorvalue = cvar("g_balance_armor_start");
746
747         g_weaponarena = 0;
748         WEPSET_CLEAR_A(g_weaponarena_weapons);
749
750         s = cvar_string("g_weaponarena");
751         if (s == "0" || s == "")
752         {
753                 if(g_lms || g_ca)
754                         s = "most";
755         }
756
757         if (s == "0" || s == "")
758         {
759                 // no arena
760         }
761         else if (s == "off")
762         {
763                 // forcibly turn off weaponarena
764         }
765         else if (s == "all")
766         {
767                 g_weaponarena = 1;
768                 g_weaponarena_list = "All Weapons";
769                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
770                 {
771                         e = get_weaponinfo(j);
772                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
773                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
774                 }
775         }
776         else if (s == "most")
777         {
778                 g_weaponarena = 1;
779                 g_weaponarena_list = "Most Weapons";
780                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
781                 {
782                         e = get_weaponinfo(j);
783                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
784                                 if (e.spawnflags & WEP_FLAG_NORMAL)
785                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
786                 }
787         }
788         else if (s == "none")
789         {
790                 g_weaponarena = 1;
791                 g_weaponarena_list = "No Weapons";
792         }
793         else
794         {
795                 g_weaponarena = 1;
796                 t = tokenize_console(s);
797                 g_weaponarena_list = "";
798                 for (i = 0; i < t; ++i)
799                 {
800                         s = argv(i);
801                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
802                         {
803                                 e = get_weaponinfo(j);
804                                 if (e.netname == s)
805                                 {
806                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
807                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
808                                         break;
809                                 }
810                         }
811                         if (j > WEP_LAST)
812                         {
813                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
814                         }
815                 }
816                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
817         }
818
819         if(g_weaponarena)
820                 g_weaponarena_random = cvar("g_weaponarena_random");
821         else
822                 g_weaponarena_random = 0;
823         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
824
825         if (g_weaponarena)
826         {
827                 g_pinata = 0; // incompatible
828                 g_weapon_stay = 0; // incompatible
829                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
830                 if(!(g_lms || g_ca))
831                         start_items |= IT_UNLIMITED_AMMO;
832         }
833         else
834         {
835                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
836                 {
837                         e = get_weaponinfo(i);
838                         float w = want_weapon("g_start_weapon_", e, FALSE);
839                         if(w & 1)
840                                 WEPSET_OR_AW(start_weapons, i);
841                         if(w & 2)
842                                 WEPSET_OR_AW(start_weapons_default, i);
843                         if(w & 4)
844                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
845                 }
846         }
847
848         if(!cvar("g_use_ammunition"))
849                 start_items |= IT_UNLIMITED_AMMO;
850
851         if(cvar("g_nexball"))
852                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
853
854         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
855         {
856                 start_ammo_rockets = 999;
857                 start_ammo_shells = 999;
858                 start_ammo_cells = 999;
859                 start_ammo_nails = 999;
860                 start_ammo_fuel = 999;
861         }
862         else
863         {
864                 if(g_lms || g_ca)
865                 {
866                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
867                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
868                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
869                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
870                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
871                 }
872                 else
873                 {
874                         start_ammo_shells = cvar("g_start_ammo_shells");
875                         start_ammo_nails = cvar("g_start_ammo_nails");
876                         start_ammo_rockets = cvar("g_start_ammo_rockets");
877                         start_ammo_cells = cvar("g_start_ammo_cells");
878                         start_ammo_fuel = cvar("g_start_ammo_fuel");
879                 }
880         }
881
882         if (g_lms || g_ca)
883         {
884                 start_health = cvar("g_lms_start_health");
885                 start_armorvalue = cvar("g_lms_start_armor");
886         }
887
888         if (inWarmupStage)
889         {
890                 warmup_start_ammo_shells = start_ammo_shells;
891                 warmup_start_ammo_nails = start_ammo_nails;
892                 warmup_start_ammo_rockets = start_ammo_rockets;
893                 warmup_start_ammo_cells = start_ammo_cells;
894                 warmup_start_ammo_fuel = start_ammo_fuel;
895                 warmup_start_health = start_health;
896                 warmup_start_armorvalue = start_armorvalue;
897                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
898                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
899                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
900
901                 if (!g_weaponarena && !g_ca)
902                 {
903                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
904                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
905                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
906                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
907                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
908                         warmup_start_health = cvar("g_warmup_start_health");
909                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
910                         WEPSET_CLEAR_A(warmup_start_weapons);
911                         WEPSET_CLEAR_A(warmup_start_weapons_default);
912                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
913                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
914                         {
915                                 e = get_weaponinfo(i);
916                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
917                                 if(w & 1)
918                                         WEPSET_OR_AW(warmup_start_weapons, i);
919                                 if(w & 2)
920                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
921                                 if(w & 4)
922                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
923                         }
924                 }
925         }
926
927         if (g_jetpack)
928                 start_items |= IT_JETPACK;
929
930         MUTATOR_CALLHOOK(SetStartItems);
931
932         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
933         {
934                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
935                 start_items |= IT_FUEL_REGEN;
936                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
937                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
938         }
939
940         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
941         {
942                 e = get_weaponinfo(i);
943                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
944                         weapon_action(i, WR_PRECACHE);
945         }
946
947         start_ammo_shells = max(0, start_ammo_shells);
948         start_ammo_nails = max(0, start_ammo_nails);
949         start_ammo_cells = max(0, start_ammo_cells);
950         start_ammo_rockets = max(0, start_ammo_rockets);
951         start_ammo_fuel = max(0, start_ammo_fuel);
952
953         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
954         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
955         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
956         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
957         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
958 }
959
960 float g_bugrigs;
961 float g_bugrigs_planar_movement;
962 float g_bugrigs_planar_movement_car_jumping;
963 float g_bugrigs_reverse_spinning;
964 float g_bugrigs_reverse_speeding;
965 float g_bugrigs_reverse_stopping;
966 float g_bugrigs_air_steering;
967 float g_bugrigs_angle_smoothing;
968 float g_bugrigs_friction_floor;
969 float g_bugrigs_friction_brake;
970 float g_bugrigs_friction_air;
971 float g_bugrigs_accel;
972 float g_bugrigs_speed_ref;
973 float g_bugrigs_speed_pow;
974 float g_bugrigs_steer;
975
976 float g_touchexplode;
977 float g_touchexplode_radius;
978 float g_touchexplode_damage;
979 float g_touchexplode_edgedamage;
980 float g_touchexplode_force;
981
982 float sv_autotaunt;
983 float sv_taunt;
984
985 string GetGametype(); // g_world.qc
986 void readlevelcvars(void)
987 {
988         // load ALL the mutators
989         if(cvar("g_dodging"))
990                 MUTATOR_ADD(mutator_dodging);
991         if(cvar("g_spawn_near_teammate"))
992                 MUTATOR_ADD(mutator_spawn_near_teammate);
993         if(cvar("g_physical_items"))
994                 MUTATOR_ADD(mutator_physical_items);
995         if(cvar("g_minstagib"))
996                 MUTATOR_ADD(mutator_minstagib);
997         if(cvar("g_invincible_projectiles"))
998                 MUTATOR_ADD(mutator_invincibleprojectiles);
999         if(cvar("g_new_toys"))
1000                 MUTATOR_ADD(mutator_new_toys);
1001         if(!cvar("g_minstagib")) // TODO: nix support?
1002         if(cvar("g_nix"))
1003                 MUTATOR_ADD(mutator_nix);
1004         if(cvar("g_rocket_flying"))
1005                 MUTATOR_ADD(mutator_rocketflying);
1006         if(cvar("g_vampire"))
1007                 MUTATOR_ADD(mutator_vampire);           
1008         if(cvar("g_superspectate"))
1009                 MUTATOR_ADD(mutator_superspec);
1010
1011         // is this a mutator? is this a mode?
1012         if(cvar("g_sandbox"))
1013                 MUTATOR_ADD(sandbox);
1014
1015         if(cvar("sv_allow_fullbright"))
1016                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1017
1018     g_bugrigs = cvar("g_bugrigs");
1019     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1020     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1021     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1022     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1023     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1024     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1025     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1026     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1027     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1028     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1029     g_bugrigs_accel = cvar("g_bugrigs_accel");
1030     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1031     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1032     g_bugrigs_steer = cvar("g_bugrigs_steer");
1033         
1034         g_minstagib = cvar("g_minstagib");
1035
1036     g_touchexplode = cvar("g_touchexplode");
1037     g_touchexplode_radius = cvar("g_touchexplode_radius");
1038     g_touchexplode_damage = cvar("g_touchexplode_damage");
1039     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1040     g_touchexplode_force = cvar("g_touchexplode_force");
1041
1042         sv_clones = cvar("sv_clones");
1043         sv_foginterval = cvar("sv_foginterval");
1044         g_cloaked = cvar("g_cloaked");
1045     if(g_cts)
1046         g_cloaked = 1; // always enable cloak in CTS
1047         g_jump_grunt = cvar("g_jump_grunt");
1048         g_footsteps = cvar("g_footsteps");
1049         g_grappling_hook = cvar("g_grappling_hook");
1050         g_jetpack = cvar("g_jetpack");
1051         g_midair = cvar("g_midair");
1052         g_norecoil = cvar("g_norecoil");
1053         g_bloodloss = cvar("g_bloodloss");
1054         sv_maxidle = cvar("sv_maxidle");
1055         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1056         sv_autotaunt = cvar("sv_autotaunt");
1057         sv_taunt = cvar("sv_taunt");
1058
1059         inWarmupStage = cvar("g_warmup");
1060         g_warmup_limit = cvar("g_warmup_limit");
1061         g_warmup_allguns = cvar("g_warmup_allguns");
1062         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1063
1064         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
1065                 inWarmupStage = 0; // these modes cannot work together, sorry
1066
1067         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1068         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1069         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1070         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1071         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1072         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1073         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1074         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1075         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1076         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1077         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1078         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1079         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1080         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1081
1082         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1083         g_weaponratefactor = cvar("g_weaponratefactor");
1084         g_weapondamagefactor = cvar("g_weapondamagefactor");
1085         g_weaponforcefactor = cvar("g_weaponforcefactor");
1086         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1087
1088         g_pickup_shells = cvar("g_pickup_shells");
1089         g_pickup_shells_max = cvar("g_pickup_shells_max");
1090         g_pickup_nails = cvar("g_pickup_nails");
1091         g_pickup_nails_max = cvar("g_pickup_nails_max");
1092         g_pickup_rockets = cvar("g_pickup_rockets");
1093         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1094         g_pickup_cells = cvar("g_pickup_cells");
1095         g_pickup_cells_max = cvar("g_pickup_cells_max");
1096         g_pickup_fuel = cvar("g_pickup_fuel");
1097         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1098         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1099         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1100         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1101         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1102         g_pickup_armormedium = cvar("g_pickup_armormedium");
1103         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1104         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1105         g_pickup_armorbig = cvar("g_pickup_armorbig");
1106         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1107         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1108         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1109         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1110         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1111         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1112         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1113         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1114         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1115         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1116         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1117         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1118         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1119         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1120         g_pickup_healthmega = cvar("g_pickup_healthmega");
1121         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1122         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1123
1124         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1125         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1126
1127         g_pinata = cvar("g_pinata");
1128
1129     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1130     if(!g_weapon_stay)
1131         g_weapon_stay = cvar("g_weapon_stay");
1132
1133         if not(inWarmupStage && !g_ca)
1134                 game_starttime = cvar("g_start_delay");
1135
1136         readplayerstartcvars();
1137 }
1138
1139 //#NO AUTOCVARS END
1140
1141 // Sound functions
1142 string precache_sound (string s) = #19;
1143 float precache_sound_index (string s) = #19;
1144
1145 #define SND_VOLUME      1
1146 #define SND_ATTENUATION 2
1147 #define SND_LARGEENTITY 8
1148 #define SND_LARGESOUND  16
1149
1150 float sound_allowed(float dest, entity e)
1151 {
1152     // sounds from world may always pass
1153     for (;;)
1154     {
1155         if (e.classname == "body")
1156             e = e.enemy;
1157         else if (e.realowner && e.realowner != e)
1158             e = e.realowner;
1159         else if (e.owner && e.owner != e)
1160             e = e.owner;
1161         else
1162             break;
1163     }
1164     // sounds to self may always pass
1165     if (dest == MSG_ONE)
1166         if (e == msg_entity)
1167             return TRUE;
1168     // sounds by players can be removed
1169     if (autocvar_bot_sound_monopoly)
1170         if (clienttype(e) == CLIENTTYPE_REAL)
1171             return FALSE;
1172     // anything else may pass
1173     return TRUE;
1174 }
1175
1176 #ifdef COMPAT_XON010_CHANNELS
1177 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1178 void sound(entity e, float chan, string samp, float vol, float atten)
1179 {
1180     if (!sound_allowed(MSG_BROADCAST, e))
1181         return;
1182     builtin_sound(e, chan, samp, vol, atten);
1183 }
1184 #else
1185 #undef sound
1186 void sound(entity e, float chan, string samp, float vol, float atten)
1187 {
1188     if (!sound_allowed(MSG_BROADCAST, e))
1189         return;
1190     sound7(e, chan, samp, vol, atten, 0, 0);
1191 }
1192 #endif
1193
1194 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1195 {
1196     float entno, idx;
1197
1198     if (!sound_allowed(dest, e))
1199         return;
1200
1201     entno = num_for_edict(e);
1202     idx = precache_sound_index(samp);
1203
1204     float sflags;
1205     sflags = 0;
1206
1207     atten = floor(atten * 64);
1208     vol = floor(vol * 255);
1209
1210     if (vol != 255)
1211         sflags |= SND_VOLUME;
1212     if (atten != 64)
1213         sflags |= SND_ATTENUATION;
1214     if (entno >= 8192 || chan < 0 || chan > 7)
1215         sflags |= SND_LARGEENTITY;
1216     if (idx >= 256)
1217         sflags |= SND_LARGESOUND;
1218
1219     WriteByte(dest, SVC_SOUND);
1220     WriteByte(dest, sflags);
1221     if (sflags & SND_VOLUME)
1222         WriteByte(dest, vol);
1223     if (sflags & SND_ATTENUATION)
1224         WriteByte(dest, atten);
1225     if (sflags & SND_LARGEENTITY)
1226     {
1227         WriteShort(dest, entno);
1228         WriteByte(dest, chan);
1229     }
1230     else
1231     {
1232         WriteShort(dest, entno * 8 + chan);
1233     }
1234     if (sflags & SND_LARGESOUND)
1235         WriteShort(dest, idx);
1236     else
1237         WriteByte(dest, idx);
1238
1239     WriteCoord(dest, o_x);
1240     WriteCoord(dest, o_y);
1241     WriteCoord(dest, o_z);
1242 }
1243 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1244 {
1245     vector o;
1246
1247     if (!sound_allowed(dest, e))
1248         return;
1249
1250     o = e.origin + 0.5 * (e.mins + e.maxs);
1251     soundtoat(dest, e, o, chan, samp, vol, atten);
1252 }
1253 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1254 {
1255     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1256 }
1257 void stopsoundto(float dest, entity e, float chan)
1258 {
1259     float entno;
1260
1261     if (!sound_allowed(dest, e))
1262         return;
1263
1264     entno = num_for_edict(e);
1265
1266     if (entno >= 8192 || chan < 0 || chan > 7)
1267     {
1268         float idx, sflags;
1269         idx = precache_sound_index("misc/null.wav");
1270         sflags = SND_LARGEENTITY;
1271         if (idx >= 256)
1272             sflags |= SND_LARGESOUND;
1273         WriteByte(dest, SVC_SOUND);
1274         WriteByte(dest, sflags);
1275         WriteShort(dest, entno);
1276         WriteByte(dest, chan);
1277         if (sflags & SND_LARGESOUND)
1278             WriteShort(dest, idx);
1279         else
1280             WriteByte(dest, idx);
1281         WriteCoord(dest, e.origin_x);
1282         WriteCoord(dest, e.origin_y);
1283         WriteCoord(dest, e.origin_z);
1284     }
1285     else
1286     {
1287         WriteByte(dest, SVC_STOPSOUND);
1288         WriteShort(dest, entno * 8 + chan);
1289     }
1290 }
1291 void stopsound(entity e, float chan)
1292 {
1293     if (!sound_allowed(MSG_BROADCAST, e))
1294         return;
1295
1296     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1297     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1298 }
1299
1300 void play2(entity e, string filename)
1301 {
1302     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1303     msg_entity = e;
1304     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1305 }
1306
1307 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1308 .float spamtime;
1309 float spamsound(entity e, float chan, string samp, float vol, float atten)
1310 {
1311     if (!sound_allowed(MSG_BROADCAST, e))
1312         return FALSE;
1313
1314     if (time > e.spamtime)
1315     {
1316         e.spamtime = time;
1317         sound(e, chan, samp, vol, atten);
1318         return TRUE;
1319     }
1320     return FALSE;
1321 }
1322
1323 void play2team(float t, string filename)
1324 {
1325     entity head;
1326
1327     if (autocvar_bot_sound_monopoly)
1328         return;
1329
1330     FOR_EACH_REALPLAYER(head)
1331     {
1332         if (head.team == t)
1333             play2(head, filename);
1334     }
1335 }
1336
1337 void play2all(string samp)
1338 {
1339     if (autocvar_bot_sound_monopoly)
1340         return;
1341
1342     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1343 }
1344
1345 void PrecachePlayerSounds(string f);
1346 void precache_playermodel(string m)
1347 {
1348         float globhandle, i, n;
1349         string f;
1350
1351         if(substring(m, -9,5) == "_lod1")
1352                 return;
1353         if(substring(m, -9,5) == "_lod2")
1354                 return;
1355         precache_model(m);
1356         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1357         if(fexists(f))
1358                 precache_model(f);
1359         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1360         if(fexists(f))
1361                 precache_model(f);
1362
1363         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1364         if (globhandle < 0)
1365                 return;
1366         n = search_getsize(globhandle);
1367         for (i = 0; i < n; ++i)
1368         {
1369                 //print(search_getfilename(globhandle, i), "\n");
1370                 f = search_getfilename(globhandle, i);
1371                 PrecachePlayerSounds(f);
1372         }
1373         search_end(globhandle);
1374 }
1375 void precache_all_playermodels(string pattern)
1376 {
1377         float globhandle, i, n;
1378         string f;
1379
1380         globhandle = search_begin(pattern, TRUE, FALSE);
1381         if (globhandle < 0)
1382                 return;
1383         n = search_getsize(globhandle);
1384         for (i = 0; i < n; ++i)
1385         {
1386                 //print(search_getfilename(globhandle, i), "\n");
1387                 f = search_getfilename(globhandle, i);
1388                 precache_playermodel(f);
1389         }
1390         search_end(globhandle);
1391 }
1392
1393 void precache()
1394 {
1395     // gamemode related things
1396     precache_model ("models/misc/chatbubble.spr");
1397
1398 #ifdef TTURRETS_ENABLED
1399     if (autocvar_g_turrets)
1400         turrets_precash();
1401 #endif
1402
1403     // Precache all player models if desired
1404     if (autocvar_sv_precacheplayermodels)
1405     {
1406         PrecachePlayerSounds("sound/player/default.sounds");
1407         precache_all_playermodels("models/player/*.zym");
1408         precache_all_playermodels("models/player/*.dpm");
1409         precache_all_playermodels("models/player/*.md3");
1410         precache_all_playermodels("models/player/*.psk");
1411         precache_all_playermodels("models/player/*.iqm");
1412     }
1413
1414     if (autocvar_sv_defaultcharacter)
1415     {
1416         string s;
1417         s = autocvar_sv_defaultplayermodel_red;
1418         if (s != "")
1419             precache_playermodel(s);
1420         s = autocvar_sv_defaultplayermodel_blue;
1421         if (s != "")
1422             precache_playermodel(s);
1423         s = autocvar_sv_defaultplayermodel_yellow;
1424         if (s != "")
1425             precache_playermodel(s);
1426         s = autocvar_sv_defaultplayermodel_pink;
1427         if (s != "")
1428             precache_playermodel(s);
1429         s = autocvar_sv_defaultplayermodel;
1430         if (s != "")
1431             precache_playermodel(s);
1432     }
1433
1434     if (g_footsteps)
1435     {
1436         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1437         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1438     }
1439
1440     // gore and miscellaneous sounds
1441     //precache_sound ("misc/h2ohit.wav");
1442     precache_model ("models/hook.md3");
1443     precache_sound ("misc/armorimpact.wav");
1444     precache_sound ("misc/bodyimpact1.wav");
1445     precache_sound ("misc/bodyimpact2.wav");
1446     precache_sound ("misc/gib.wav");
1447     precache_sound ("misc/gib_splat01.wav");
1448     precache_sound ("misc/gib_splat02.wav");
1449     precache_sound ("misc/gib_splat03.wav");
1450     precache_sound ("misc/gib_splat04.wav");
1451     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1452     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1453     precache_sound ("misc/null.wav");
1454     precache_sound ("misc/spawn.wav");
1455     precache_sound ("misc/talk.wav");
1456     precache_sound ("misc/teleport.wav");
1457     precache_sound ("misc/poweroff.wav");
1458     precache_sound ("player/lava.wav");
1459     precache_sound ("player/slime.wav");
1460
1461     precache_model ("models/sprites/0.spr32");
1462     precache_model ("models/sprites/1.spr32");
1463     precache_model ("models/sprites/2.spr32");
1464     precache_model ("models/sprites/3.spr32");
1465     precache_model ("models/sprites/4.spr32");
1466     precache_model ("models/sprites/5.spr32");
1467     precache_model ("models/sprites/6.spr32");
1468     precache_model ("models/sprites/7.spr32");
1469     precache_model ("models/sprites/8.spr32");
1470     precache_model ("models/sprites/9.spr32");
1471     precache_model ("models/sprites/10.spr32");
1472
1473     // common weapon precaches
1474         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1475     precache_sound ("weapons/weapon_switch.wav");
1476     precache_sound ("weapons/weaponpickup.wav");
1477     precache_sound ("weapons/unavailable.wav");
1478     precache_sound ("weapons/dryfire.wav");
1479     if (g_grappling_hook)
1480     {
1481         precache_sound ("weapons/hook_fire.wav"); // hook
1482         precache_sound ("weapons/hook_impact.wav"); // hook
1483     }
1484
1485     if(autocvar_sv_precacheweapons)
1486     {
1487         //precache weapon models/sounds
1488         float wep;
1489         wep = WEP_FIRST;
1490         while (wep <= WEP_LAST)
1491         {
1492             weapon_action(wep, WR_PRECACHE);
1493             wep = wep + 1;
1494         }
1495     }
1496
1497     precache_model("models/elaser.mdl");
1498     precache_model("models/laser.mdl");
1499     precache_model("models/ebomb.mdl");
1500
1501 #if 0
1502     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1503
1504     if (!self.noise && self.music) // quake 3 uses the music field
1505         self.noise = self.music;
1506
1507     // plays music for the level if there is any
1508     if (self.noise)
1509     {
1510         precache_sound (self.noise);
1511         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1512     }
1513 #endif
1514 }
1515
1516 // WARNING: this kills the trace globals
1517 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1518 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1519
1520 #define INITPRIO_FIRST              0
1521 #define INITPRIO_GAMETYPE           0
1522 #define INITPRIO_GAMETYPE_FALLBACK  1
1523 #define INITPRIO_FINDTARGET        10
1524 #define INITPRIO_DROPTOFLOOR       20
1525 #define INITPRIO_SETLOCATION       90
1526 #define INITPRIO_LINKDOORS         91
1527 #define INITPRIO_LAST              99
1528
1529 .void(void) initialize_entity;
1530 .float initialize_entity_order;
1531 .entity initialize_entity_next;
1532 entity initialize_entity_first;
1533
1534 void make_safe_for_remove(entity e)
1535 {
1536     if (e.initialize_entity)
1537     {
1538         entity ent, prev = world;
1539         for (ent = initialize_entity_first; ent; )
1540         {
1541             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1542             {
1543                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1544                 // skip it in linked list
1545                 if (prev)
1546                 {
1547                     prev.initialize_entity_next = ent.initialize_entity_next;
1548                     ent = prev.initialize_entity_next;
1549                 }
1550                 else
1551                 {
1552                     initialize_entity_first = ent.initialize_entity_next;
1553                     ent = initialize_entity_first;
1554                 }
1555             }
1556             else
1557             {
1558                 prev = ent;
1559                 ent = ent.initialize_entity_next;
1560             }
1561         }
1562     }
1563 }
1564
1565 void objerror(string s)
1566 {
1567     make_safe_for_remove(self);
1568     builtin_objerror(s);
1569 }
1570
1571 .float remove_except_protected_forbidden;
1572 void remove_except_protected(entity e)
1573 {
1574         if(e.remove_except_protected_forbidden)
1575                 error("not allowed to remove this at this point");
1576         builtin_remove(e);
1577 }
1578
1579 void remove_unsafely(entity e)
1580 {
1581     if(e.classname == "spike")
1582         error("Removing spikes is forbidden (crylink bug), please report");
1583     builtin_remove(e);
1584 }
1585
1586 void remove_safely(entity e)
1587 {
1588     make_safe_for_remove(e);
1589     builtin_remove(e);
1590 }
1591
1592 void InitializeEntity(entity e, void(void) func, float order)
1593 {
1594     entity prev, cur;
1595
1596     if (!e || e.initialize_entity)
1597     {
1598         // make a proxy initializer entity
1599         entity e_old;
1600         e_old = e;
1601         e = spawn();
1602         e.classname = "initialize_entity";
1603         e.enemy = e_old;
1604     }
1605
1606     e.initialize_entity = func;
1607     e.initialize_entity_order = order;
1608
1609     cur = initialize_entity_first;
1610     prev = world;
1611     for (;;)
1612     {
1613         if (!cur || cur.initialize_entity_order > order)
1614         {
1615             // insert between prev and cur
1616             if (prev)
1617                 prev.initialize_entity_next = e;
1618             else
1619                 initialize_entity_first = e;
1620             e.initialize_entity_next = cur;
1621             return;
1622         }
1623         prev = cur;
1624         cur = cur.initialize_entity_next;
1625     }
1626 }
1627 void InitializeEntitiesRun()
1628 {
1629     entity startoflist;
1630     startoflist = initialize_entity_first;
1631     initialize_entity_first = world;
1632     remove = remove_except_protected;
1633     for (self = startoflist; self; self = self.initialize_entity_next)
1634     {
1635         self.remove_except_protected_forbidden = 1;
1636     }
1637     for (self = startoflist; self; )
1638     {
1639         entity e;
1640         var void(void) func;
1641         e = self.initialize_entity_next;
1642         func = self.initialize_entity;
1643         self.initialize_entity_order = 0;
1644         self.initialize_entity = func_null;
1645         self.initialize_entity_next = world;
1646         self.remove_except_protected_forbidden = 0;
1647         if (self.classname == "initialize_entity")
1648         {
1649             entity e_old;
1650             e_old = self.enemy;
1651             builtin_remove(self);
1652             self = e_old;
1653         }
1654         //dprint("Delayed initialization: ", self.classname, "\n");
1655         if(func)
1656             func();
1657         else
1658         {
1659             eprint(self);
1660             backtrace(strcat("Null function in: ", self.classname, "\n"));
1661         }
1662         self = e;
1663     }
1664     remove = remove_unsafely;
1665 }
1666
1667 .float uncustomizeentityforclient_set;
1668 .void(void) uncustomizeentityforclient;
1669 void UncustomizeEntitiesRun()
1670 {
1671     entity oldself;
1672     oldself = self;
1673     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1674         self.uncustomizeentityforclient();
1675     self = oldself;
1676 }
1677 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1678 {
1679     e.customizeentityforclient = customizer;
1680     e.uncustomizeentityforclient = uncustomizer;
1681     e.uncustomizeentityforclient_set = !!uncustomizer;
1682 }
1683
1684 .float nottargeted;
1685 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1686
1687 void() SUB_Remove;
1688 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1689 {
1690     vector mi, ma;
1691
1692     if (e.classname == "")
1693         e.classname = "net_linked";
1694
1695     if (e.model == "" || self.modelindex == 0)
1696     {
1697         mi = e.mins;
1698         ma = e.maxs;
1699         setmodel(e, "null");
1700         setsize(e, mi, ma);
1701     }
1702
1703     e.SendEntity = sendfunc;
1704     e.SendFlags = 0xFFFFFF;
1705
1706     if (!docull)
1707         e.effects |= EF_NODEPTHTEST;
1708
1709     if (dt)
1710     {
1711         e.nextthink = time + dt;
1712         e.think = SUB_Remove;
1713     }
1714 }
1715
1716 void adaptor_think2touch()
1717 {
1718     entity o;
1719     o = other;
1720     other = world;
1721     self.touch();
1722     other = o;
1723 }
1724
1725 void adaptor_think2use()
1726 {
1727     entity o, a;
1728     o = other;
1729     a = activator;
1730     activator = world;
1731     other = world;
1732     self.use();
1733     other = o;
1734     activator = a;
1735 }
1736
1737 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1738 {
1739         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1740                 self.projectiledeathtype |= HITTYPE_SPLASH;
1741         adaptor_think2use();
1742 }
1743
1744 // deferred dropping
1745 void DropToFloor_Handler()
1746 {
1747     builtin_droptofloor();
1748     self.dropped_origin = self.origin;
1749 }
1750
1751 void droptofloor()
1752 {
1753     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1754 }
1755
1756
1757
1758 float trace_hits_box_a0, trace_hits_box_a1;
1759
1760 float trace_hits_box_1d(float end, float thmi, float thma)
1761 {
1762     if (end == 0)
1763     {
1764         // just check if x is in range
1765         if (0 < thmi)
1766             return FALSE;
1767         if (0 > thma)
1768             return FALSE;
1769     }
1770     else
1771     {
1772         // do the trace with respect to x
1773         // 0 -> end has to stay in thmi -> thma
1774         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1775         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1776         if (trace_hits_box_a0 > trace_hits_box_a1)
1777             return FALSE;
1778     }
1779     return TRUE;
1780 }
1781
1782 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1783 {
1784     end -= start;
1785     thmi -= start;
1786     thma -= start;
1787     // now it is a trace from 0 to end
1788
1789     trace_hits_box_a0 = 0;
1790     trace_hits_box_a1 = 1;
1791
1792     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1793         return FALSE;
1794     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1795         return FALSE;
1796     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1797         return FALSE;
1798
1799     return TRUE;
1800 }
1801
1802 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1803 {
1804     return trace_hits_box(start, end, thmi - ma, thma - mi);
1805 }
1806
1807 float SUB_NoImpactCheck()
1808 {
1809         // zero hitcontents = this is not the real impact, but either the
1810         // mirror-impact of something hitting the projectile instead of the
1811         // projectile hitting the something, or a touchareagrid one. Neither of
1812         // these stop the projectile from moving, so...
1813         if(trace_dphitcontents == 0)
1814         {
1815                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1816                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1817                 checkclient();
1818         }
1819     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1820         return 1;
1821     if (other == world && self.size != '0 0 0')
1822     {
1823         vector tic;
1824         tic = self.velocity * sys_frametime;
1825         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1826         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1827         if (trace_fraction >= 1)
1828         {
1829             dprint("Odd... did not hit...?\n");
1830         }
1831         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1832         {
1833             dprint("Detected and prevented the sky-grapple bug.\n");
1834             return 1;
1835         }
1836     }
1837
1838     return 0;
1839 }
1840
1841 #define SUB_OwnerCheck() (other && (other == self.owner))
1842
1843 void RemoveGrapplingHook(entity pl);
1844 void W_Crylink_Dequeue(entity e);
1845 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1846 {
1847         if(SUB_OwnerCheck())
1848                 return TRUE;
1849         if(SUB_NoImpactCheck())
1850         {
1851                 if(self.classname == "grapplinghook")
1852                         RemoveGrapplingHook(self.realowner);
1853                 else if(self.classname == "spike")
1854                 {
1855                         W_Crylink_Dequeue(self);
1856                         remove(self);
1857                 }
1858                 else
1859                         remove(self);
1860                 return TRUE;
1861         }
1862         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1863                 UpdateCSQCProjectile(self);
1864         return FALSE;
1865 }
1866 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1867
1868 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1869 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1870
1871 void URI_Get_Callback(float id, float status, string data)
1872 {
1873         if(url_URI_Get_Callback(id, status, data))
1874         {
1875                 // handled
1876         }
1877         else if (id == URI_GET_DISCARD)
1878         {
1879                 // discard
1880         }
1881         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1882         {
1883                 // sv_cmd curl
1884                 Curl_URI_Get_Callback(id, status, data);
1885         }
1886         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1887         {
1888                 // online ban list
1889                 OnlineBanList_URI_Get_Callback(id, status, data);
1890         }
1891         else
1892         {
1893                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1894         }
1895 }
1896
1897 string uid2name(string myuid) {
1898         string s;
1899         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1900
1901         // FIXME remove this later after 0.6 release
1902         // convert old style broken records to correct style
1903         if(s == "")
1904         {
1905                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1906                 if(s != "")
1907                 {
1908                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1909                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1910                 }
1911         }
1912         
1913         if(s == "")
1914                 s = "^1Unregistered Player";
1915         return s;
1916 }
1917
1918 float race_readTime(string map, float pos)
1919 {
1920         string rr;
1921         if(g_cts)
1922                 rr = CTS_RECORD;
1923         else
1924                 rr = RACE_RECORD;
1925
1926         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1927 }
1928
1929 string race_readUID(string map, float pos)
1930 {
1931         string rr;
1932         if(g_cts)
1933                 rr = CTS_RECORD;
1934         else
1935                 rr = RACE_RECORD;
1936
1937         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1938 }
1939
1940 float race_readPos(string map, float t) {
1941         float i;
1942         for (i = 1; i <= RANKINGS_CNT; ++i)
1943                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1944                         return i;
1945
1946         return 0; // pos is zero if unranked
1947 }
1948
1949 void race_writeTime(string map, float t, string myuid)
1950 {
1951         string rr;
1952         if(g_cts)
1953                 rr = CTS_RECORD;
1954         else
1955                 rr = RACE_RECORD;
1956
1957         float newpos;
1958         newpos = race_readPos(map, t);
1959
1960         float i, prevpos = 0;
1961         for(i = 1; i <= RANKINGS_CNT; ++i)
1962         {
1963                 if(race_readUID(map, i) == myuid)
1964                         prevpos = i;
1965         }
1966         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1967                 for (i = prevpos; i > newpos; --i) {
1968                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1969                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1970                 }
1971         } else { // player has no ranked record yet
1972                 for (i = RANKINGS_CNT; i > newpos; --i) {
1973                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1974                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1975                 }
1976         }
1977
1978         // store new time itself
1979         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1980         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1981 }
1982
1983 string race_readName(string map, float pos)
1984 {
1985         string rr;
1986         if(g_cts)
1987                 rr = CTS_RECORD;
1988         else
1989                 rr = RACE_RECORD;
1990
1991         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1992 }
1993
1994 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1995 {
1996     float m, i;
1997     vector start, org, delta, end, enddown, mstart;
1998     entity sp;
1999
2000     m = e.dphitcontentsmask;
2001     e.dphitcontentsmask = goodcontents | badcontents;
2002
2003     org = world.mins;
2004     delta = world.maxs - world.mins;
2005
2006     start = end = org;
2007
2008     for (i = 0; i < attempts; ++i)
2009     {
2010         start_x = org_x + random() * delta_x;
2011         start_y = org_y + random() * delta_y;
2012         start_z = org_z + random() * delta_z;
2013
2014         // rule 1: start inside world bounds, and outside
2015         // solid, and don't start from somewhere where you can
2016         // fall down to evil
2017         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2018         if (trace_fraction >= 1)
2019             continue;
2020         if (trace_startsolid)
2021             continue;
2022         if (trace_dphitcontents & badcontents)
2023             continue;
2024         if (trace_dphitq3surfaceflags & badsurfaceflags)
2025             continue;
2026
2027         // rule 2: if we are too high, lower the point
2028         if (trace_fraction * delta_z > maxaboveground)
2029             start = trace_endpos + '0 0 1' * maxaboveground;
2030         enddown = trace_endpos;
2031
2032         // rule 3: make sure we aren't outside the map. This only works
2033         // for somewhat well formed maps. A good rule of thumb is that
2034         // the map should have a convex outside hull.
2035         // these can be traceLINES as we already verified the starting box
2036         mstart = start + 0.5 * (e.mins + e.maxs);
2037         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2038         if (trace_fraction >= 1)
2039             continue;
2040         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2041         if (trace_fraction >= 1)
2042             continue;
2043         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2044         if (trace_fraction >= 1)
2045             continue;
2046         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2047         if (trace_fraction >= 1)
2048             continue;
2049         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2050         if (trace_fraction >= 1)
2051             continue;
2052
2053         // rule 4: we must "see" some spawnpoint
2054         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2055                 if(checkpvs(mstart, sp))
2056                         break;
2057         if(!sp)
2058         {
2059                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2060                         if(checkpvs(mstart, sp))
2061                                 break;
2062                 if(!sp)
2063                         continue;
2064         }
2065
2066         // find a random vector to "look at"
2067         end_x = org_x + random() * delta_x;
2068         end_y = org_y + random() * delta_y;
2069         end_z = org_z + random() * delta_z;
2070         end = start + normalize(end - start) * vlen(delta);
2071
2072         // rule 4: start TO end must not be too short
2073         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2074         if (trace_startsolid)
2075             continue;
2076         if (trace_fraction < minviewdistance / vlen(delta))
2077             continue;
2078
2079         // rule 5: don't want to look at sky
2080         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2081             continue;
2082
2083         // rule 6: we must not end up in trigger_hurt
2084         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2085             continue;
2086
2087         break;
2088     }
2089
2090     e.dphitcontentsmask = m;
2091
2092     if (i < attempts)
2093     {
2094         setorigin(e, start);
2095         e.angles = vectoangles(end - start);
2096         dprint("Needed ", ftos(i + 1), " attempts\n");
2097         return TRUE;
2098     }
2099     else
2100         return FALSE;
2101 }
2102
2103 float zcurveparticles_effectno;
2104 vector zcurveparticles_start;
2105 float zcurveparticles_spd;
2106
2107 void endzcurveparticles()
2108 {
2109         if(zcurveparticles_effectno)
2110         {
2111                 // terminator
2112                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2113         }
2114         zcurveparticles_effectno = 0;
2115 }
2116
2117 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2118 {
2119         spd = bound(0, floor(spd / 16), 32767);
2120         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2121         {
2122                 endzcurveparticles();
2123                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2124                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2125                 WriteShort(MSG_BROADCAST, effectno);
2126                 WriteCoord(MSG_BROADCAST, start_x);
2127                 WriteCoord(MSG_BROADCAST, start_y);
2128                 WriteCoord(MSG_BROADCAST, start_z);
2129                 zcurveparticles_effectno = effectno;
2130                 zcurveparticles_start = start;
2131         }
2132         else
2133                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2134         WriteCoord(MSG_BROADCAST, end_x);
2135         WriteCoord(MSG_BROADCAST, end_y);
2136         WriteCoord(MSG_BROADCAST, end_z);
2137         WriteCoord(MSG_BROADCAST, end_dz);
2138         zcurveparticles_spd = spd;
2139 }
2140
2141 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2142 {
2143         float end_dz;
2144         vector vecxy, velxy;
2145
2146         vecxy = end - start;
2147         vecxy_z = 0;
2148         velxy = vel;
2149         velxy_z = 0;
2150
2151         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2152         {
2153                 endzcurveparticles();
2154                 trailparticles(world, effectno, start, end);
2155                 return;
2156         }
2157
2158         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2159         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2160 }
2161
2162 void write_recordmarker(entity pl, float tstart, float dt)
2163 {
2164     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2165
2166     // also write a marker into demo files for demotc-race-record-extractor to find
2167     stuffcmd(pl,
2168              strcat(
2169                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2170                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2171 }
2172
2173 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2174 {
2175         switch(algn)
2176         {
2177                 default:
2178                 case 3: // right
2179                         break;
2180
2181                 case 4: // left
2182                         vecs_y = -vecs_y;
2183                         break;
2184
2185                 case 1:
2186                         if(allowcenter) // 2: allow center handedness
2187                         {
2188                                 // center
2189                                 vecs_y = 0;
2190                                 vecs_z -= 2;
2191                         }
2192                         else
2193                         {
2194                                 // right
2195                         }
2196                         break;
2197
2198                 case 2:
2199                         if(allowcenter) // 2: allow center handedness
2200                         {
2201                                 // center
2202                                 vecs_y = 0;
2203                                 vecs_z -= 2;
2204                         }
2205                         else
2206                         {
2207                                 // left
2208                                 vecs_y = -vecs_y;
2209                         }
2210                         break;
2211         }
2212         return vecs;
2213 }
2214
2215 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2216 {
2217         string s;
2218         vector v;
2219
2220         if (autocvar_g_shootfromeye)
2221         {
2222                 if (visual)
2223                 {
2224                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2225                         else { vecs_y = 0; vecs_z -= 2; }
2226                 }
2227                 else
2228                 {
2229                         vecs_y = 0;
2230                         vecs_z = 0;
2231                 }
2232         }
2233         else if (autocvar_g_shootfromcenter)
2234         {
2235                 vecs_y = 0;
2236                 vecs_z -= 2;
2237         }
2238         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2239         {
2240                 v = stov(s);
2241                 if (y_is_right)
2242                         v_y = -v_y;
2243                 if (v_x != 0)
2244                         vecs_x = v_x;
2245                 vecs_y = v_y;
2246                 vecs_z = v_z;
2247         }
2248         else if (autocvar_g_shootfromclient)
2249         {
2250                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2251         }
2252         return vecs;
2253 }
2254
2255 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2256 {
2257         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2258 }
2259
2260
2261 void attach_sameorigin(entity e, entity to, string tag)
2262 {
2263     vector org, t_forward, t_left, t_up, e_forward, e_up;
2264     float tagscale;
2265
2266     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2267     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2268     t_forward = v_forward * tagscale;
2269     t_left = v_right * -tagscale;
2270     t_up = v_up * tagscale;
2271
2272     e.origin_x = org * t_forward;
2273     e.origin_y = org * t_left;
2274     e.origin_z = org * t_up;
2275
2276     // current forward and up directions
2277     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2278                 e.angles = AnglesTransform_FromVAngles(e.angles);
2279         else
2280                 e.angles = AnglesTransform_FromAngles(e.angles);
2281     fixedmakevectors(e.angles);
2282
2283     // untransform forward, up!
2284     e_forward_x = v_forward * t_forward;
2285     e_forward_y = v_forward * t_left;
2286     e_forward_z = v_forward * t_up;
2287     e_up_x = v_up * t_forward;
2288     e_up_y = v_up * t_left;
2289     e_up_z = v_up * t_up;
2290
2291     e.angles = fixedvectoangles2(e_forward, e_up);
2292     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2293                 e.angles = AnglesTransform_ToVAngles(e.angles);
2294         else
2295                 e.angles = AnglesTransform_ToAngles(e.angles);
2296
2297     setattachment(e, to, tag);
2298     setorigin(e, e.origin);
2299 }
2300
2301 void detach_sameorigin(entity e)
2302 {
2303     vector org;
2304     org = gettaginfo(e, 0);
2305     e.angles = fixedvectoangles2(v_forward, v_up);
2306     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2307                 e.angles = AnglesTransform_ToVAngles(e.angles);
2308         else
2309                 e.angles = AnglesTransform_ToAngles(e.angles);
2310     setorigin(e, org);
2311     setattachment(e, world, "");
2312     setorigin(e, e.origin);
2313 }
2314
2315 void follow_sameorigin(entity e, entity to)
2316 {
2317     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2318     e.aiment = to; // make the hole follow bmodel
2319     e.punchangle = to.angles; // the original angles of bmodel
2320     e.view_ofs = e.origin - to.origin; // relative origin
2321     e.v_angle = e.angles - to.angles; // relative angles
2322 }
2323
2324 void unfollow_sameorigin(entity e)
2325 {
2326     e.movetype = MOVETYPE_NONE;
2327 }
2328
2329 entity gettaginfo_relative_ent;
2330 vector gettaginfo_relative(entity e, float tag)
2331 {
2332     if (!gettaginfo_relative_ent)
2333     {
2334         gettaginfo_relative_ent = spawn();
2335         gettaginfo_relative_ent.effects = EF_NODRAW;
2336     }
2337     gettaginfo_relative_ent.model = e.model;
2338     gettaginfo_relative_ent.modelindex = e.modelindex;
2339     gettaginfo_relative_ent.frame = e.frame;
2340     return gettaginfo(gettaginfo_relative_ent, tag);
2341 }
2342
2343 .float scale2;
2344
2345 float modeleffect_SendEntity(entity to, float sf)
2346 {
2347         float f;
2348         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2349
2350         f = 0;
2351         if(self.velocity != '0 0 0')
2352                 f |= 1;
2353         if(self.angles != '0 0 0')
2354                 f |= 2;
2355         if(self.avelocity != '0 0 0')
2356                 f |= 4;
2357
2358         WriteByte(MSG_ENTITY, f);
2359         WriteShort(MSG_ENTITY, self.modelindex);
2360         WriteByte(MSG_ENTITY, self.skin);
2361         WriteByte(MSG_ENTITY, self.frame);
2362         WriteCoord(MSG_ENTITY, self.origin_x);
2363         WriteCoord(MSG_ENTITY, self.origin_y);
2364         WriteCoord(MSG_ENTITY, self.origin_z);
2365         if(f & 1)
2366         {
2367                 WriteCoord(MSG_ENTITY, self.velocity_x);
2368                 WriteCoord(MSG_ENTITY, self.velocity_y);
2369                 WriteCoord(MSG_ENTITY, self.velocity_z);
2370         }
2371         if(f & 2)
2372         {
2373                 WriteCoord(MSG_ENTITY, self.angles_x);
2374                 WriteCoord(MSG_ENTITY, self.angles_y);
2375                 WriteCoord(MSG_ENTITY, self.angles_z);
2376         }
2377         if(f & 4)
2378         {
2379                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2380                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2381                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2382         }
2383         WriteShort(MSG_ENTITY, self.scale * 256.0);
2384         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2385         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2386         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2387         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2388
2389         return TRUE;
2390 }
2391
2392 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2393 {
2394         entity e;
2395         float sz;
2396         e = spawn();
2397         e.classname = "modeleffect";
2398         setmodel(e, m);
2399         e.frame = f;
2400         setorigin(e, o);
2401         e.velocity = v;
2402         e.angles = ang;
2403         e.avelocity = angv;
2404         e.alpha = a;
2405         e.teleport_time = t1;
2406         e.fade_time = t2;
2407         e.skin = s;
2408         if(s0 >= 0)
2409                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2410         else
2411                 e.scale = -s0;
2412         if(s2 >= 0)
2413                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2414         else
2415                 e.scale2 = -s2;
2416         sz = max(e.scale, e.scale2);
2417         setsize(e, e.mins * sz, e.maxs * sz);
2418         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2419 }
2420
2421 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2422 {
2423         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2424 }
2425
2426 float randombit(float bits)
2427 {
2428         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2429                 return bits;
2430
2431         float n, f, b, r;
2432
2433         r = random();
2434         b = 0;
2435         n = 0;
2436
2437         for(f = 1; f <= bits; f *= 2)
2438         {
2439                 if(bits & f)
2440                 {
2441                         ++n;
2442                         r *= n;
2443                         if(r <= 1)
2444                                 b = f;
2445                         else
2446                                 r = (r - 1) / (n - 1);
2447                 }
2448         }
2449
2450         return b;
2451 }
2452
2453 float randombits(float bits, float k, float error_return)
2454 {
2455         float r;
2456         r = 0;
2457         while(k > 0 && bits != r)
2458         {
2459                 r += randombit(bits - r);
2460                 --k;
2461         }
2462         if(error_return)
2463                 if(k > 0)
2464                         return -1; // all
2465         return r;
2466 }
2467
2468 void randombit_test(float bits, float iter)
2469 {
2470         while(iter > 0)
2471         {
2472                 print(ftos(randombit(bits)), "\n");
2473                 --iter;
2474         }
2475 }
2476
2477 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2478 {
2479         if(halflifedist > 0)
2480                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2481         else if(halflifedist < 0)
2482                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2483         else
2484                 return 1;
2485 }
2486
2487
2488
2489
2490 #ifdef RELEASE
2491 #define cvar_string_normal builtin_cvar_string
2492 #define cvar_normal builtin_cvar
2493 #else
2494 string cvar_string_normal(string n)
2495 {
2496         if not(cvar_type(n) & 1)
2497                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2498         return builtin_cvar_string(n);
2499 }
2500
2501 float cvar_normal(string n)
2502 {
2503         return stof(cvar_string_normal(n));
2504 }
2505 #endif
2506 #define cvar_set_normal builtin_cvar_set
2507
2508 void defer_think()
2509 {
2510     entity oself;
2511
2512     oself           = self;
2513     self            = self.owner;
2514     oself.think     = SUB_Remove;
2515     oself.nextthink = time;
2516
2517     oself.use();
2518 }
2519
2520 /*
2521     Execute func() after time + fdelay.
2522     self when func is executed = self when defer is called
2523 */
2524 void defer(float fdelay, void() func)
2525 {
2526     entity e;
2527
2528     e           = spawn();
2529     e.owner     = self;
2530     e.use       = func;
2531     e.think     = defer_think;
2532     e.nextthink = time + fdelay;
2533 }
2534
2535 .string aiment_classname;
2536 .float aiment_deadflag;
2537 void SetMovetypeFollow(entity ent, entity e)
2538 {
2539         // FIXME this may not be warpzone aware
2540         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2541         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2542         ent.aiment = e; // make the hole follow bmodel
2543         ent.punchangle = e.angles; // the original angles of bmodel
2544         ent.view_ofs = ent.origin - e.origin; // relative origin
2545         ent.v_angle = ent.angles - e.angles; // relative angles
2546         ent.aiment_classname = strzone(e.classname);
2547         ent.aiment_deadflag = e.deadflag;
2548 }
2549 void UnsetMovetypeFollow(entity ent)
2550 {
2551         ent.movetype = MOVETYPE_FLY;
2552         PROJECTILE_MAKETRIGGER(ent);
2553         ent.aiment = world;
2554 }
2555 float LostMovetypeFollow(entity ent)
2556 {
2557 /*
2558         if(ent.movetype != MOVETYPE_FOLLOW)
2559                 if(ent.aiment)
2560                         error("???");
2561 */
2562         if(ent.aiment)
2563         {
2564                 if(ent.aiment.classname != ent.aiment_classname)
2565                         return 1;
2566                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2567                         return 1;
2568         }
2569         return 0;
2570 }
2571
2572 float isPushable(entity e)
2573 {
2574         if(e.iscreature)
2575                 return TRUE;
2576         if(e.pushable)
2577                 return TRUE;
2578         switch(e.classname)
2579         {
2580                 case "body":
2581                 case "droppedweapon":
2582                 case "keepawayball":
2583                 case "nexball_basketball":
2584                 case "nexball_football":
2585                         return TRUE;
2586                 case "bullet": // antilagged bullets can't hit this either
2587                         return FALSE;
2588         }
2589         if (e.projectiledeathtype)
2590                 return TRUE;
2591         return FALSE;
2592 }