qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         float nPlayerHealth = rint(enPlayer.health);
  85         float nPlayerArmor = rint(enPlayer.armorvalue);
  86         float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         float nPlayerPing = rint(enPlayer.ping);
  88         string strPlayerPingColor;
  89         string strMessage;
  90
  91         if(nPlayerPing >= 150)
  92                 strPlayerPingColor = "^1";
  93         else
  94                 strPlayerPingColor = "^2";
  95
  96         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  97                 strMessage = strcat(strMessage, "^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  98
  99         if(autocvar_sv_fragmessage_information_ping) {
 100                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 101                         strMessage = strcat(strMessage, " ^7(^2Bot");
 102                 else
 103                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 104                 if(autocvar_sv_fragmessage_information_handicap)
 105                         if(autocvar_sv_fragmessage_information_handicap == 2)
 106                                 if(nPlayerHandicap <= 1)
 107                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 108                                 else
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 110                         else if not(nPlayerHandicap <= 1)
 111                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                 else
 113                         strMessage = strcat(strMessage, "^7)");
 114         } else if(autocvar_sv_fragmessage_information_handicap) {
 115                 if(autocvar_sv_fragmessage_information_handicap == 2)
 116                         if(nPlayerHandicap <= 1)
 117                                 strMessage = strcat(strMessage, "^7(Handicap ^2Off^7)");
 118                         else
 119                                 strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 120                 else if(nPlayerHandicap > 1)
 121                         strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122         }
 123
 124         if(strMessage) // add new line to the beginning if there is a message
 125                 strMessage = strcat("\n", strMessage);
 126
 127         return strMessage;
 128 }
 129 void bcenterprint(string s)
 130 {
 131     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 132     entity head;
 133     FOR_EACH_PLAYER(head)
 134     if (clienttype(head) == CLIENTTYPE_REAL)
 135         centerprint(head, s);
 136 }
 137
 138 void GameLogEcho(string s)
 139 {
 140     string fn;
 141     float matches;
 142
 143     if (autocvar_sv_eventlog_files)
 144     {
 145         if (!logfile_open)
 146         {
 147             logfile_open = TRUE;
 148             matches = autocvar_sv_eventlog_files_counter + 1;
 149             cvar_set("sv_eventlog_files_counter", ftos(matches));
 150             fn = ftos(matches);
 151             if (strlen(fn) < 8)
 152                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 153             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 154             logfile = fopen(fn, FILE_APPEND);
 155             fputs(logfile, ":logversion:3\n");
 156         }
 157         if (logfile >= 0)
 158         {
 159             if (autocvar_sv_eventlog_files_timestamps)
 160                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 161             else
 162                 fputs(logfile, strcat(s, "\n"));
 163         }
 164     }
 165     if (autocvar_sv_eventlog_console)
 166     {
 167         print(s, "\n");
 168     }
 169 }
 170
 171 void GameLogInit()
 172 {
 173     logfile_open = 0;
 174     // will be opened later
 175 }
 176
 177 void GameLogClose()
 178 {
 179     if (logfile_open && logfile >= 0)
 180     {
 181         fclose(logfile);
 182         logfile = -1;
 183     }
 184 }
 185
 186 vector PL_VIEW_OFS;
 187 vector PL_MIN;
 188 vector PL_MAX;
 189 vector PL_HEAD;
 190 vector PL_CROUCH_VIEW_OFS;
 191 vector PL_CROUCH_MIN;
 192 vector PL_CROUCH_MAX;
 193
 194 float spawnpoint_nag;
 195 void relocate_spawnpoint()
 196 {
 197     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 198     PL_MIN                                  = stov(autocvar_sv_player_mins);
 199     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 200     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 201     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 202     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 203     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 204
 205     // nudge off the floor
 206     setorigin(self, self.origin + '0 0 1');
 207
 208     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 209     if (trace_startsolid)
 210     {
 211         vector o;
 212         o = self.origin;
 213         self.mins = PL_MIN;
 214         self.maxs = PL_MAX;
 215         if (!move_out_of_solid(self))
 216             objerror("could not get out of solid at all!");
 217         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 218         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 219         print(" ", ftos(self.origin_y - o_y));
 220         print(" ", ftos(self.origin_z - o_z), "'\n");
 221         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 222         {
 223             if (!spawnpoint_nag)
 224                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 225             spawnpoint_nag = 1;
 226         }
 227         else
 228         {
 229             setorigin(self, o);
 230             self.mins = self.maxs = '0 0 0';
 231             objerror("player spawn point in solid, mapper sucks!\n");
 232             return;
 233         }
 234     }
 235
 236     self.use = spawnpoint_use;
 237     self.team_saved = self.team;
 238     if (!self.cnt)
 239         self.cnt = 1;
 240
 241     if (have_team_spawns != 0)
 242         if (self.team)
 243             have_team_spawns = 1;
 244     have_team_spawns_forteam[self.team] = 1;
 245
 246     if (autocvar_r_showbboxes)
 247     {
 248         // show where spawnpoints point at too
 249         makevectors(self.angles);
 250         entity e;
 251         e = spawn();
 252         e.classname = "info_player_foo";
 253         setorigin(e, self.origin + v_forward * 24);
 254         setsize(e, '-8 -8 -8', '8 8 8');
 255         e.solid = SOLID_TRIGGER;
 256     }
 257 }
 258
 259 #define strstr strstrofs
 260 /*
 261 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 262 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 263 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 264 // BE CONSTANT OR strzoneD!
 265 float strstr(string haystack, string needle, float offset)
 266 {
 267         float len, endpos;
 268         string found;
 269         len = strlen(needle);
 270         endpos = strlen(haystack) - len;
 271         while(offset <= endpos)
 272         {
 273                 found = substring(haystack, offset, len);
 274                 if(found == needle)
 275                         return offset;
 276                 offset = offset + 1;
 277         }
 278         return -1;
 279 }
 280 */
 281
 282 float NUM_NEAREST_ENTITIES = 4;
 283 entity nearest_entity[NUM_NEAREST_ENTITIES];
 284 float nearest_length[NUM_NEAREST_ENTITIES];
 285 entity findnearest(vector point, .string field, string value, vector axismod)
 286 {
 287     entity localhead;
 288     float i;
 289     float j;
 290     float len;
 291     vector dist;
 292
 293     float num_nearest;
 294     num_nearest = 0;
 295
 296     localhead = find(world, field, value);
 297     while (localhead)
 298     {
 299         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 300             dist = localhead.oldorigin;
 301         else
 302             dist = localhead.origin;
 303         dist = dist - point;
 304         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 305         len = vlen(dist);
 306
 307         for (i = 0; i < num_nearest; ++i)
 308         {
 309             if (len < nearest_length[i])
 310                 break;
 311         }
 312
 313         // now i tells us where to insert at
 314         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 315         if (i < NUM_NEAREST_ENTITIES)
 316         {
 317             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 318             {
 319                 nearest_length[j + 1] = nearest_length[j];
 320                 nearest_entity[j + 1] = nearest_entity[j];
 321             }
 322             nearest_length[i] = len;
 323             nearest_entity[i] = localhead;
 324             if (num_nearest < NUM_NEAREST_ENTITIES)
 325                 num_nearest = num_nearest + 1;
 326         }
 327
 328         localhead = find(localhead, field, value);
 329     }
 330
 331     // now use the first one from our list that we can see
 332     for (i = 0; i < num_nearest; ++i)
 333     {
 334         traceline(point, nearest_entity[i].origin, TRUE, world);
 335         if (trace_fraction == 1)
 336         {
 337             if (i != 0)
 338             {
 339                 dprint("Nearest point (");
 340                 dprint(nearest_entity[0].netname);
 341                 dprint(") is not visible, using a visible one.\n");
 342             }
 343             return nearest_entity[i];
 344         }
 345     }
 346
 347     if (num_nearest == 0)
 348         return world;
 349
 350     dprint("Not seeing any location point, using nearest as fallback.\n");
 351     /* DEBUGGING CODE:
 352     dprint("Candidates were: ");
 353     for(j = 0; j < num_nearest; ++j)
 354     {
 355         if(j != 0)
 356                 dprint(", ");
 357         dprint(nearest_entity[j].netname);
 358     }
 359     dprint("\n");
 360     */
 361
 362     return nearest_entity[0];
 363 }
 364
 365 void spawnfunc_target_location()
 366 {
 367     self.classname = "target_location";
 368     // location name in netname
 369     // eventually support: count, teamgame selectors, line of sight?
 370 };
 371
 372 void spawnfunc_info_location()
 373 {
 374     self.classname = "target_location";
 375     self.message = self.netname;
 376 };
 377
 378 string NearestLocation(vector p)
 379 {
 380     entity loc;
 381     string ret;
 382     ret = "somewhere";
 383     loc = findnearest(p, classname, "target_location", '1 1 1');
 384     if (loc)
 385     {
 386         ret = loc.message;
 387     }
 388     else
 389     {
 390         loc = findnearest(p, target, "###item###", '1 1 4');
 391         if (loc)
 392             ret = loc.netname;
 393     }
 394     return ret;
 395 }
 396
 397 string formatmessage(string msg)
 398 {
 399         float p, p1, p2;
 400         float n;
 401         vector cursor;
 402         entity cursor_ent;
 403         string escape;
 404         string replacement;
 405         p = 0;
 406         n = 7;
 407
 408         WarpZone_crosshair_trace(self);
 409         cursor = trace_endpos;
 410         cursor_ent = trace_ent;
 411
 412         while (1) {
 413                 if (n < 1)
 414                         break; // too many replacements
 415
 416                 n = n - 1;
 417                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 418                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 419
 420                 if (p1 < 0)
 421                         p1 = p2;
 422
 423                 if (p2 < 0)
 424                         p2 = p1;
 425
 426                 p = min(p1, p2);
 427
 428                 if (p < 0)
 429                         break;
 430
 431                 replacement = substring(msg, p, 2);
 432                 escape = substring(msg, p + 1, 1);
 433
 434                 if (escape == "%")
 435                         replacement = "%";
 436                 else if (escape == "\\")
 437                         replacement = "\\";
 438                 else if (escape == "n")
 439                         replacement = "\n";
 440                 else if (escape == "a")
 441                         replacement = ftos(floor(self.armorvalue));
 442                 else if (escape == "h")
 443                         replacement = ftos(floor(self.health));
 444                 else if (escape == "l")
 445                         replacement = NearestLocation(self.origin);
 446                 else if (escape == "y")
 447                         replacement = NearestLocation(cursor);
 448                 else if (escape == "d")
 449                         replacement = NearestLocation(self.death_origin);
 450                 else if (escape == "w") {
 451                         float wep;
 452                         wep = self.weapon;
 453                         if (!wep)
 454                                 wep = self.switchweapon;
 455                         if (!wep)
 456                                 wep = self.cnt;
 457                         replacement = W_Name(wep);
 458                 } else if (escape == "W") {
 459                         if (self.items & IT_SHELLS) replacement = "shells";
 460                         else if (self.items & IT_NAILS) replacement = "bullets";
 461                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 462                         else if (self.items & IT_CELLS) replacement = "cells";
 463                         else replacement = "batteries"; // ;)
 464                 } else if (escape == "x") {
 465                         replacement = cursor_ent.netname;
 466                         if (!replacement || !cursor_ent)
 467                                 replacement = "nothing";
 468                 } else if (escape == "s")
 469                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 470                 else if (escape == "S")
 471                         replacement = ftos(vlen(self.velocity));
 472
 473                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 474                 p = p + strlen(replacement);
 475         }
 476         return msg;
 477 }
 478
 479 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 480         return (value == 0) ? FALSE : TRUE;
 481 }
 482
 483 /*
 484 =============
 485 GetCvars
 486 =============
 487 Called with:
 488   0:  sends the request
 489   >0: receives a cvar from name=argv(f) value=argv(f+1)
 490 */
 491 void GetCvars_handleString(string thisname, float f, .string field, string name)
 492 {
 493         if (f < 0)
 494         {
 495                 if (self.field)
 496                         strunzone(self.field);
 497                 self.field = string_null;
 498         }
 499         else if (f > 0)
 500         {
 501                 if (thisname == name)
 502                 {
 503                         if (self.field)
 504                                 strunzone(self.field);
 505                         self.field = strzone(argv(f + 1));
 506                 }
 507         }
 508         else
 509                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 510 }
 511 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 512 {
 513         GetCvars_handleString(thisname, f, field, name);
 514         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 515                 if (thisname == name)
 516                 {
 517                         string s;
 518                         s = func(strcat1(self.field));
 519                         if (s != self.field)
 520                         {
 521                                 strunzone(self.field);
 522                                 self.field = strzone(s);
 523                         }
 524                 }
 525 }
 526 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 527 {
 528         if (f < 0)
 529         {
 530         }
 531         else if (f > 0)
 532         {
 533                 if (thisname == name)
 534                         self.field = stof(argv(f + 1));
 535         }
 536         else
 537                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 538 }
 539 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 540 {
 541         if (f < 0)
 542         {
 543         }
 544         else if (f > 0)
 545         {
 546                 if (thisname == name)
 547                 {
 548                         if(!self.field)
 549                         {
 550                                 self.field = stof(argv(f + 1));
 551                                 if(!self.field)
 552                                         self.field = -1;
 553                         }
 554                 }
 555         }
 556         else
 557         {
 558                 if(!self.field)
 559                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 560         }
 561 }
 562 float w_getbestweapon(entity e);
 563 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 564 {
 565         string o;
 566         o = W_FixWeaponOrder_ForceComplete(wo);
 567         if(self.weaponorder_byimpulse)
 568         {
 569                 strunzone(self.weaponorder_byimpulse);
 570                 self.weaponorder_byimpulse = string_null;
 571         }
 572         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 573         return o;
 574 }
 575 void GetCvars(float f)
 576 {
 577         string s;
 578
 579         if (f > 0)
 580                 s = strcat1(argv(f));
 581
 582         get_cvars_f = f;
 583         get_cvars_s = s;
 584         MUTATOR_CALLHOOK(GetCvars);
 585         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 586         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 587         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 588         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 589         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 608
 609         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 610         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 611
 612 #ifdef ALLOW_FORCEMODELS
 613         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 615 #endif
 616         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 617         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625                 if (s == "cl_allow_uidtracking")
 626                         PlayerStats_AddPlayer(self);
 627         }
 628 }
 629
 630 void backtrace(string msg)
 631 {
 632     float dev, war;
 633     dev = autocvar_developer;
 634     war = autocvar_prvm_backtraceforwarnings;
 635     cvar_set("developer", "1");
 636     cvar_set("prvm_backtraceforwarnings", "1");
 637     print("\n");
 638     print("--- CUT HERE ---\nWARNING: ");
 639     print(msg);
 640     print("\n");
 641     remove(world); // isn't there any better way to cause a backtrace?
 642     print("\n--- CUT UNTIL HERE ---\n");
 643     cvar_set("developer", ftos(dev));
 644     cvar_set("prvm_backtraceforwarnings", ftos(war));
 645 }
 646
 647 string Team_ColorCode(float teamid)
 648 {
 649     if (teamid == COLOR_TEAM1)
 650         return "^1";
 651     else if (teamid == COLOR_TEAM2)
 652         return "^4";
 653     else if (teamid == COLOR_TEAM3)
 654         return "^3";
 655     else if (teamid == COLOR_TEAM4)
 656         return "^6";
 657     else
 658         return "^7";
 659 }
 660
 661 string Team_ColorName(float t)
 662 {
 663     // fixme: Search for team entities and get their .netname's!
 664     if (t == COLOR_TEAM1)
 665         return "Red";
 666     if (t == COLOR_TEAM2)
 667         return "Blue";
 668     if (t == COLOR_TEAM3)
 669         return "Yellow";
 670     if (t == COLOR_TEAM4)
 671         return "Pink";
 672     return "Neutral";
 673 }
 674
 675 string Team_ColorNameLowerCase(float t)
 676 {
 677     // fixme: Search for team entities and get their .netname's!
 678     if (t == COLOR_TEAM1)
 679         return "red";
 680     if (t == COLOR_TEAM2)
 681         return "blue";
 682     if (t == COLOR_TEAM3)
 683         return "yellow";
 684     if (t == COLOR_TEAM4)
 685         return "pink";
 686     return "neutral";
 687 }
 688
 689 float ColourToNumber(string team_colour)
 690 {
 691         if (team_colour == "red")
 692                 return COLOR_TEAM1;
 693
 694         if (team_colour == "blue")
 695                 return COLOR_TEAM2;
 696
 697         if (team_colour == "yellow")
 698                 return COLOR_TEAM3;
 699
 700         if (team_colour == "pink")
 701                 return COLOR_TEAM4;
 702
 703         if (team_colour == "auto")
 704                 return 0;
 705
 706         return -1;
 707 }
 708
 709 float NumberToTeamNumber(float number)
 710 {
 711         if (number == 1)
 712                 return COLOR_TEAM1;
 713
 714         if (number == 2)
 715                 return COLOR_TEAM2;
 716
 717         if (number == 3)
 718                 return COLOR_TEAM3;
 719
 720         if (number == 4)
 721                 return COLOR_TEAM4;
 722
 723         return -1;
 724 }
 725
 726 // decolorizes and team colors the player name when needed
 727 string playername(entity p)
 728 {
 729     string t;
 730     if (teamplay && !intermission_running && p.classname == "player")
 731     {
 732         t = Team_ColorCode(p.team);
 733         return strcat(t, strdecolorize(p.netname));
 734     }
 735     else
 736         return p.netname;
 737 }
 738
 739 vector randompos(vector m1, vector m2)
 740 {
 741     local vector v;
 742     m2 = m2 - m1;
 743     v_x = m2_x * random() + m1_x;
 744     v_y = m2_y * random() + m1_y;
 745     v_z = m2_z * random() + m1_z;
 746     return  v;
 747 };
 748
 749 //#NO AUTOCVARS START
 750
 751 float g_pickup_shells;
 752 float g_pickup_shells_max;
 753 float g_pickup_nails;
 754 float g_pickup_nails_max;
 755 float g_pickup_rockets;
 756 float g_pickup_rockets_max;
 757 float g_pickup_cells;
 758 float g_pickup_cells_max;
 759 float g_pickup_fuel;
 760 float g_pickup_fuel_jetpack;
 761 float g_pickup_fuel_max;
 762 float g_pickup_armorsmall;
 763 float g_pickup_armorsmall_max;
 764 float g_pickup_armorsmall_anyway;
 765 float g_pickup_armormedium;
 766 float g_pickup_armormedium_max;
 767 float g_pickup_armormedium_anyway;
 768 float g_pickup_armorbig;
 769 float g_pickup_armorbig_max;
 770 float g_pickup_armorbig_anyway;
 771 float g_pickup_armorlarge;
 772 float g_pickup_armorlarge_max;
 773 float g_pickup_armorlarge_anyway;
 774 float g_pickup_healthsmall;
 775 float g_pickup_healthsmall_max;
 776 float g_pickup_healthsmall_anyway;
 777 float g_pickup_healthmedium;
 778 float g_pickup_healthmedium_max;
 779 float g_pickup_healthmedium_anyway;
 780 float g_pickup_healthlarge;
 781 float g_pickup_healthlarge_max;
 782 float g_pickup_healthlarge_anyway;
 783 float g_pickup_healthmega;
 784 float g_pickup_healthmega_max;
 785 float g_pickup_healthmega_anyway;
 786 float g_pickup_ammo_anyway;
 787 float g_pickup_weapons_anyway;
 788 float g_weaponarena;
 789 float g_weaponarena_random;
 790 float g_weaponarena_random_with_laser;
 791 string g_weaponarena_list;
 792 float g_weaponspeedfactor;
 793 float g_weaponratefactor;
 794 float g_weapondamagefactor;
 795 float g_weaponforcefactor;
 796 float g_weaponspreadfactor;
 797
 798 float start_weapons;
 799 float start_items;
 800 float start_ammo_shells;
 801 float start_ammo_nails;
 802 float start_ammo_rockets;
 803 float start_ammo_cells;
 804 float start_ammo_fuel;
 805 float start_health;
 806 float start_armorvalue;
 807 float warmup_start_weapons;
 808 float warmup_start_ammo_shells;
 809 float warmup_start_ammo_nails;
 810 float warmup_start_ammo_rockets;
 811 float warmup_start_ammo_cells;
 812 float warmup_start_ammo_fuel;
 813 float warmup_start_health;
 814 float warmup_start_armorvalue;
 815 float g_weapon_stay;
 816 float g_ghost_items;
 817
 818 entity get_weaponinfo(float w);
 819
 820 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 821 {
 822         var float i = weaponinfo.weapon;
 823
 824         if (!i)
 825                 return 0;
 826
 827         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 828
 829         if (t < 0) // "default" weapon selection
 830         {
 831                 if (g_lms || g_ca || allguns)
 832                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 833                 else if(t < -1)
 834                         t = 0;
 835                 else if (g_cts)
 836                         t = (i == WEP_SHOTGUN);
 837                 else if (g_nexball)
 838                         t = 0; // weapon is set a few lines later
 839                 else
 840                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 841                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 842                         t |= (i == WEP_HOOK);
 843         }
 844
 845         // we cannot disable porto in Nexball, we must force it
 846         if(g_nexball && i == WEP_PORTO)
 847                 t = 1;
 848
 849         return t;
 850 }
 851
 852 void readplayerstartcvars()
 853 {
 854         entity e;
 855         float i, j, t;
 856         string s;
 857
 858         // initialize starting values for players
 859         start_weapons = 0;
 860         start_items = 0;
 861         start_ammo_shells = 0;
 862         start_ammo_nails = 0;
 863         start_ammo_rockets = 0;
 864         start_ammo_cells = 0;
 865         start_health = cvar("g_balance_health_start");
 866         start_armorvalue = cvar("g_balance_armor_start");
 867
 868         g_weaponarena = 0;
 869         s = cvar_string("g_weaponarena");
 870         if (s == "0" || s == "")
 871         {
 872                 if(g_lms || g_ca)
 873                         s = "most";
 874         }
 875
 876         if (s == "0" || s == "")
 877         {
 878                 // no arena
 879         }
 880         else if (s == "off")
 881         {
 882                 // forcibly turn off weaponarena
 883         }
 884         else if (s == "all")
 885         {
 886                 g_weaponarena_list = "All Weapons";
 887                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 888                 {
 889                         e = get_weaponinfo(j);
 890                         g_weaponarena |= e.weapons;
 891                         weapon_action(e.weapon, WR_PRECACHE);
 892                 }
 893         }
 894         else if (s == "most")
 895         {
 896                 g_weaponarena_list = "Most Weapons";
 897                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 898                 {
 899                         e = get_weaponinfo(j);
 900                         if (e.spawnflags & WEP_FLAG_NORMAL)
 901                         {
 902                                 g_weaponarena |= e.weapons;
 903                                 weapon_action(e.weapon, WR_PRECACHE);
 904                         }
 905                 }
 906         }
 907         else if (s == "none")
 908         {
 909                 g_weaponarena_list = "No Weapons";
 910                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 911         }
 912         else
 913         {
 914                 t = tokenize_console(s);
 915                 g_weaponarena_list = "";
 916                 for (i = 0; i < t; ++i)
 917                 {
 918                         s = argv(i);
 919                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 920                         {
 921                                 e = get_weaponinfo(j);
 922                                 if (e.netname == s)
 923                                 {
 924                                         g_weaponarena |= e.weapons;
 925                                         weapon_action(e.weapon, WR_PRECACHE);
 926                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 927                                         break;
 928                                 }
 929                         }
 930                         if (j > WEP_LAST)
 931                         {
 932                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 933                         }
 934                 }
 935                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 936         }
 937
 938         if(g_weaponarena)
 939                 g_weaponarena_random = cvar("g_weaponarena_random");
 940         else
 941                 g_weaponarena_random = 0;
 942         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 943
 944         if (g_weaponarena)
 945         {
 946                 start_weapons = g_weaponarena;
 947                 if(!(g_lms || g_ca))
 948                         start_items |= IT_UNLIMITED_AMMO;
 949         }
 950         else if (g_minstagib)
 951         {
 952                 start_health = 100;
 953                 start_armorvalue = 0;
 954                 start_weapons = WEPBIT_MINSTANEX;
 955                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 956                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 957
 958                 if (g_minstagib_invis_alpha <= 0)
 959                         g_minstagib_invis_alpha = -1;
 960         }
 961         else
 962         {
 963                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 964                 {
 965                         e = get_weaponinfo(i);
 966                         if(want_weapon("g_start_weapon_", e, FALSE))
 967                                 start_weapons |= e.weapons;
 968                 }
 969         }
 970
 971         if(!cvar("g_use_ammunition"))
 972                 start_items |= IT_UNLIMITED_AMMO;
 973
 974         if(g_minstagib)
 975         {
 976                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 977                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 978         }
 979         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 980         {
 981                 start_ammo_rockets = 999;
 982                 start_ammo_shells = 999;
 983                 start_ammo_cells = 999;
 984                 start_ammo_nails = 999;
 985                 start_ammo_fuel = 999;
 986         }
 987         else
 988         {
 989                 if(g_lms || g_ca)
 990                 {
 991                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 992                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 993                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 994                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 995                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 996                 }
 997                 else
 998                 {
 999                         start_ammo_shells = cvar("g_start_ammo_shells");
1000                         start_ammo_nails = cvar("g_start_ammo_nails");
1001                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1002                         start_ammo_cells = cvar("g_start_ammo_cells");
1003                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1004                 }
1005         }
1006
1007         if (g_lms || g_ca)
1008         {
1009                 start_health = cvar("g_lms_start_health");
1010                 start_armorvalue = cvar("g_lms_start_armor");
1011         }
1012
1013         if (inWarmupStage)
1014         {
1015                 warmup_start_ammo_shells = start_ammo_shells;
1016                 warmup_start_ammo_nails = start_ammo_nails;
1017                 warmup_start_ammo_rockets = start_ammo_rockets;
1018                 warmup_start_ammo_cells = start_ammo_cells;
1019                 warmup_start_ammo_fuel = start_ammo_fuel;
1020                 warmup_start_health = start_health;
1021                 warmup_start_armorvalue = start_armorvalue;
1022                 warmup_start_weapons = start_weapons;
1023
1024                 if (!g_weaponarena && !g_minstagib && !g_ca)
1025                 {
1026                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1027                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1028                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1029                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1030                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1031                         warmup_start_health = cvar("g_warmup_start_health");
1032                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1033                         warmup_start_weapons = 0;
1034                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1035                         {
1036                                 e = get_weaponinfo(i);
1037                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1038                                         warmup_start_weapons |= e.weapons;
1039                         }
1040                 }
1041         }
1042
1043         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1044         {
1045                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1046                 start_items |= IT_FUEL_REGEN;
1047                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1048                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1049         }
1050
1051         if (g_jetpack)
1052                 start_items |= IT_JETPACK;
1053
1054         if (g_weapon_stay == 2)
1055         {
1056                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1057                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1058                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1059                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1060                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1061                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1062                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1063                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1064                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1065                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1066         }
1067
1068         MUTATOR_CALLHOOK(SetStartItems);
1069
1070         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1071         {
1072                 e = get_weaponinfo(i);
1073                 if(e.weapons & (start_weapons | warmup_start_weapons))
1074                         weapon_action(e.weapon, WR_PRECACHE);
1075         }
1076
1077         start_ammo_shells = max(0, start_ammo_shells);
1078         start_ammo_nails = max(0, start_ammo_nails);
1079         start_ammo_cells = max(0, start_ammo_cells);
1080         start_ammo_rockets = max(0, start_ammo_rockets);
1081         start_ammo_fuel = max(0, start_ammo_fuel);
1082
1083         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1084         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1085         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1086         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1087         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1088 }
1089
1090 float g_bugrigs;
1091 float g_bugrigs_planar_movement;
1092 float g_bugrigs_planar_movement_car_jumping;
1093 float g_bugrigs_reverse_spinning;
1094 float g_bugrigs_reverse_speeding;
1095 float g_bugrigs_reverse_stopping;
1096 float g_bugrigs_air_steering;
1097 float g_bugrigs_angle_smoothing;
1098 float g_bugrigs_friction_floor;
1099 float g_bugrigs_friction_brake;
1100 float g_bugrigs_friction_air;
1101 float g_bugrigs_accel;
1102 float g_bugrigs_speed_ref;
1103 float g_bugrigs_speed_pow;
1104 float g_bugrigs_steer;
1105
1106 float g_touchexplode;
1107 float g_touchexplode_radius;
1108 float g_touchexplode_damage;
1109 float g_touchexplode_edgedamage;
1110 float g_touchexplode_force;
1111
1112 float sv_autotaunt;
1113 float sv_taunt;
1114
1115 float sv_pitch_min;
1116 float sv_pitch_max;
1117 float sv_pitch_fixyaw;
1118
1119 string GetGametype(); // g_world.qc
1120 void readlevelcvars(void)
1121 {
1122         // first load all the mutators
1123         if(cvar("g_nix"))
1124                 MUTATOR_ADD(mutator_nix);
1125         if(cvar("g_dodging"))
1126                 MUTATOR_ADD(mutator_dodging);
1127         if(cvar("g_rocket_flying"))
1128                 MUTATOR_ADD(mutator_rocketflying);
1129         if(cvar("g_vampire"))
1130                 MUTATOR_ADD(mutator_vampire);
1131
1132         if(cvar("sv_allow_fullbright"))
1133                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1134
1135     g_bugrigs = cvar("g_bugrigs");
1136     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1137     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1138     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1139     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1140     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1141     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1142     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1143     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1144     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1145     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1146     g_bugrigs_accel = cvar("g_bugrigs_accel");
1147     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1148     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1149     g_bugrigs_steer = cvar("g_bugrigs_steer");
1150
1151     g_touchexplode = cvar("g_touchexplode");
1152     g_touchexplode_radius = cvar("g_touchexplode_radius");
1153     g_touchexplode_damage = cvar("g_touchexplode_damage");
1154     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1155     g_touchexplode_force = cvar("g_touchexplode_force");
1156
1157 #ifdef ALLOW_FORCEMODELS
1158         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1159 #endif
1160         sv_loddistance1 = cvar("sv_loddistance1");
1161         sv_loddistance2 = cvar("sv_loddistance2");
1162
1163         if(sv_loddistance2 <= sv_loddistance1)
1164                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1165
1166         sv_clones = cvar("sv_clones");
1167         sv_gentle = cvar("sv_gentle");
1168         sv_foginterval = cvar("sv_foginterval");
1169         g_cloaked = cvar("g_cloaked");
1170     if(g_cts)
1171         g_cloaked = 1; // always enable cloak in CTS
1172         g_jump_grunt = cvar("g_jump_grunt");
1173         g_footsteps = cvar("g_footsteps");
1174         g_grappling_hook = cvar("g_grappling_hook");
1175         g_jetpack = cvar("g_jetpack");
1176         g_midair = cvar("g_midair");
1177         g_minstagib = cvar("g_minstagib");
1178         g_norecoil = cvar("g_norecoil");
1179         g_bloodloss = cvar("g_bloodloss");
1180         sv_maxidle = cvar("sv_maxidle");
1181         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1182         sv_pogostick = cvar("sv_pogostick");
1183         g_ctf_reverse = cvar("g_ctf_reverse");
1184         sv_autotaunt = cvar("sv_autotaunt");
1185         sv_taunt = cvar("sv_taunt");
1186
1187         inWarmupStage = cvar("g_warmup");
1188         g_warmup_limit = cvar("g_warmup_limit");
1189         g_warmup_allguns = cvar("g_warmup_allguns");
1190         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1191
1192         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1193                 inWarmupStage = 0; // these modes cannot work together, sorry
1194
1195         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1196         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1197         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1198         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1199         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1200         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1201         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1202         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1203         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1204         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1205         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1206         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1207
1208         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1209         g_weaponratefactor = cvar("g_weaponratefactor");
1210         g_weapondamagefactor = cvar("g_weapondamagefactor");
1211         g_weaponforcefactor = cvar("g_weaponforcefactor");
1212         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1213
1214         g_pickup_shells = cvar("g_pickup_shells");
1215         g_pickup_shells_max = cvar("g_pickup_shells_max");
1216         g_pickup_nails = cvar("g_pickup_nails");
1217         g_pickup_nails_max = cvar("g_pickup_nails_max");
1218         g_pickup_rockets = cvar("g_pickup_rockets");
1219         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1220         g_pickup_cells = cvar("g_pickup_cells");
1221         g_pickup_cells_max = cvar("g_pickup_cells_max");
1222         g_pickup_fuel = cvar("g_pickup_fuel");
1223         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1224         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1225         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1226         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1227         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1228         g_pickup_armormedium = cvar("g_pickup_armormedium");
1229         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1230         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1231         g_pickup_armorbig = cvar("g_pickup_armorbig");
1232         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1233         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1234         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1235         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1236         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1237         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1238         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1239         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1240         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1241         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1242         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1243         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1244         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1245         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1246         g_pickup_healthmega = cvar("g_pickup_healthmega");
1247         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1248         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1249
1250         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1251         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1252
1253         g_pinata = cvar("g_pinata");
1254
1255     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1256     if(!g_weapon_stay)
1257         g_weapon_stay = cvar("g_weapon_stay");
1258
1259         g_ghost_items = cvar("g_ghost_items");
1260
1261         if(g_ghost_items >= 1)
1262                 g_ghost_items = 0.25; // default alpha value
1263
1264         if not(inWarmupStage && !g_ca)
1265                 game_starttime = cvar("g_start_delay");
1266
1267         sv_pitch_min = cvar("sv_pitch_min");
1268         sv_pitch_max = cvar("sv_pitch_max");
1269         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1270
1271         readplayerstartcvars();
1272 }
1273
1274 //#NO AUTOCVARS END
1275
1276 // Sound functions
1277 string precache_sound (string s) = #19;
1278 float precache_sound_index (string s) = #19;
1279
1280 #define SND_VOLUME      1
1281 #define SND_ATTENUATION 2
1282 #define SND_LARGEENTITY 8
1283 #define SND_LARGESOUND  16
1284
1285 float sound_allowed(float dest, entity e)
1286 {
1287     // sounds from world may always pass
1288     for (;;)
1289     {
1290         if (e.classname == "body")
1291             e = e.enemy;
1292         if (e.owner && e.owner != e)
1293             e = e.owner;
1294         else
1295             break;
1296     }
1297     // sounds to self may always pass
1298     if (dest == MSG_ONE)
1299         if (e == msg_entity)
1300             return TRUE;
1301     // sounds by players can be removed
1302     if (autocvar_bot_sound_monopoly)
1303         if (clienttype(e) == CLIENTTYPE_REAL)
1304             return FALSE;
1305     // anything else may pass
1306     return TRUE;
1307 }
1308
1309 #ifdef COMPAT_XON010_CHANNELS
1310 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1311 void sound(entity e, float chan, string samp, float vol, float atten)
1312 {
1313     if (!sound_allowed(MSG_BROADCAST, e))
1314         return;
1315     sound_builtin(e, chan, samp, vol, atten);
1316 }
1317 #else
1318 #undef sound
1319 void sound(entity e, float chan, string samp, float vol, float atten)
1320 {
1321     if (!sound_allowed(MSG_BROADCAST, e))
1322         return;
1323     sound7(e, chan, samp, vol, atten, 0, 0);
1324 }
1325 #endif
1326
1327 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1328 {
1329     float entno, idx;
1330
1331     if (!sound_allowed(dest, e))
1332         return;
1333
1334     entno = num_for_edict(e);
1335     idx = precache_sound_index(samp);
1336
1337     float sflags;
1338     sflags = 0;
1339
1340     atten = floor(atten * 64);
1341     vol = floor(vol * 255);
1342
1343     if (vol != 255)
1344         sflags |= SND_VOLUME;
1345     if (atten != 64)
1346         sflags |= SND_ATTENUATION;
1347     if (entno >= 8192 || chan < 0 || chan > 7)
1348         sflags |= SND_LARGEENTITY;
1349     if (idx >= 256)
1350         sflags |= SND_LARGESOUND;
1351
1352     WriteByte(dest, SVC_SOUND);
1353     WriteByte(dest, sflags);
1354     if (sflags & SND_VOLUME)
1355         WriteByte(dest, vol);
1356     if (sflags & SND_ATTENUATION)
1357         WriteByte(dest, atten);
1358     if (sflags & SND_LARGEENTITY)
1359     {
1360         WriteShort(dest, entno);
1361         WriteByte(dest, chan);
1362     }
1363     else
1364     {
1365         WriteShort(dest, entno * 8 + chan);
1366     }
1367     if (sflags & SND_LARGESOUND)
1368         WriteShort(dest, idx);
1369     else
1370         WriteByte(dest, idx);
1371
1372     WriteCoord(dest, o_x);
1373     WriteCoord(dest, o_y);
1374     WriteCoord(dest, o_z);
1375 }
1376 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1377 {
1378     vector o;
1379
1380     if (!sound_allowed(dest, e))
1381         return;
1382
1383     o = e.origin + 0.5 * (e.mins + e.maxs);
1384     soundtoat(dest, e, o, chan, samp, vol, atten);
1385 }
1386 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1387 {
1388     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1389 }
1390 void stopsoundto(float dest, entity e, float chan)
1391 {
1392     float entno;
1393
1394     if (!sound_allowed(dest, e))
1395         return;
1396
1397     entno = num_for_edict(e);
1398
1399     if (entno >= 8192 || chan < 0 || chan > 7)
1400     {
1401         float idx, sflags;
1402         idx = precache_sound_index("misc/null.wav");
1403         sflags = SND_LARGEENTITY;
1404         if (idx >= 256)
1405             sflags |= SND_LARGESOUND;
1406         WriteByte(dest, SVC_SOUND);
1407         WriteByte(dest, sflags);
1408         WriteShort(dest, entno);
1409         WriteByte(dest, chan);
1410         if (sflags & SND_LARGESOUND)
1411             WriteShort(dest, idx);
1412         else
1413             WriteByte(dest, idx);
1414         WriteCoord(dest, e.origin_x);
1415         WriteCoord(dest, e.origin_y);
1416         WriteCoord(dest, e.origin_z);
1417     }
1418     else
1419     {
1420         WriteByte(dest, SVC_STOPSOUND);
1421         WriteShort(dest, entno * 8 + chan);
1422     }
1423 }
1424 void stopsound(entity e, float chan)
1425 {
1426     if (!sound_allowed(MSG_BROADCAST, e))
1427         return;
1428
1429     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1430     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1431 }
1432
1433 void play2(entity e, string filename)
1434 {
1435     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1436     msg_entity = e;
1437     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1438 }
1439
1440 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1441 .float spamtime;
1442 float spamsound(entity e, float chan, string samp, float vol, float atten)
1443 {
1444     if (!sound_allowed(MSG_BROADCAST, e))
1445         return FALSE;
1446
1447     if (time > e.spamtime)
1448     {
1449         e.spamtime = time;
1450         sound(e, chan, samp, vol, atten);
1451         return TRUE;
1452     }
1453     return FALSE;
1454 }
1455
1456 void play2team(float t, string filename)
1457 {
1458     local entity head;
1459
1460     if (autocvar_bot_sound_monopoly)
1461         return;
1462
1463     FOR_EACH_REALPLAYER(head)
1464     {
1465         if (head.team == t)
1466             play2(head, filename);
1467     }
1468 }
1469
1470 void play2all(string samp)
1471 {
1472     if (autocvar_bot_sound_monopoly)
1473         return;
1474
1475     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1476 }
1477
1478 void PrecachePlayerSounds(string f);
1479 void precache_playermodel(string m)
1480 {
1481         float globhandle, i, n;
1482         string f;
1483
1484         if(substring(m, -9,5) == "_lod1")
1485                 return;
1486         if(substring(m, -9,5) == "_lod2")
1487                 return;
1488         precache_model(m);
1489         if(sv_loddistance1)
1490         {
1491                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1492                 if(fexists(f))
1493                         precache_model(f);
1494                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1495                 if(fexists(f))
1496                         precache_model(f);
1497         }
1498
1499         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1500         if (globhandle < 0)
1501                 return;
1502         n = search_getsize(globhandle);
1503         for (i = 0; i < n; ++i)
1504         {
1505                 //print(search_getfilename(globhandle, i), "\n");
1506                 f = search_getfilename(globhandle, i);
1507                 PrecachePlayerSounds(f);
1508         }
1509         search_end(globhandle);
1510 }
1511 void precache_all_playermodels(string pattern)
1512 {
1513         float globhandle, i, n;
1514         string f;
1515
1516         globhandle = search_begin(pattern, TRUE, FALSE);
1517         if (globhandle < 0)
1518                 return;
1519         n = search_getsize(globhandle);
1520         for (i = 0; i < n; ++i)
1521         {
1522                 //print(search_getfilename(globhandle, i), "\n");
1523                 f = search_getfilename(globhandle, i);
1524                 precache_playermodel(f);
1525         }
1526         search_end(globhandle);
1527 }
1528
1529 void precache()
1530 {
1531     // gamemode related things
1532     precache_model ("models/misc/chatbubble.spr");
1533     if (g_runematch)
1534     {
1535         precache_model ("models/runematch/curse.mdl");
1536         precache_model ("models/runematch/rune.mdl");
1537     }
1538
1539 #ifdef TTURRETS_ENABLED
1540     if (autocvar_g_turrets)
1541         turrets_precash();
1542 #endif
1543
1544     // Precache all player models if desired
1545     if (autocvar_sv_precacheplayermodels)
1546     {
1547         PrecachePlayerSounds("sound/player/default.sounds");
1548         precache_all_playermodels("models/player/*.zym");
1549         precache_all_playermodels("models/player/*.dpm");
1550         precache_all_playermodels("models/player/*.md3");
1551         precache_all_playermodels("models/player/*.psk");
1552         precache_all_playermodels("models/player/*.iqm");
1553     }
1554
1555     if (autocvar_sv_defaultcharacter)
1556     {
1557         string s;
1558         s = autocvar_sv_defaultplayermodel_red;
1559         if (s != "")
1560             precache_playermodel(s);
1561         s = autocvar_sv_defaultplayermodel_blue;
1562         if (s != "")
1563             precache_playermodel(s);
1564         s = autocvar_sv_defaultplayermodel_yellow;
1565         if (s != "")
1566             precache_playermodel(s);
1567         s = autocvar_sv_defaultplayermodel_pink;
1568         if (s != "")
1569             precache_playermodel(s);
1570         s = autocvar_sv_defaultplayermodel;
1571         if (s != "")
1572             precache_playermodel(s);
1573     }
1574
1575     if (g_footsteps)
1576     {
1577         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1578         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1579     }
1580
1581     // gore and miscellaneous sounds
1582     //precache_sound ("misc/h2ohit.wav");
1583     precache_model ("models/hook.md3");
1584     precache_sound ("misc/armorimpact.wav");
1585     precache_sound ("misc/bodyimpact1.wav");
1586     precache_sound ("misc/bodyimpact2.wav");
1587     precache_sound ("misc/gib.wav");
1588     precache_sound ("misc/gib_splat01.wav");
1589     precache_sound ("misc/gib_splat02.wav");
1590     precache_sound ("misc/gib_splat03.wav");
1591     precache_sound ("misc/gib_splat04.wav");
1592     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1593     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1594     precache_sound ("misc/null.wav");
1595     precache_sound ("misc/spawn.wav");
1596     precache_sound ("misc/talk.wav");
1597     precache_sound ("misc/teleport.wav");
1598     precache_sound ("misc/poweroff.wav");
1599     precache_sound ("player/lava.wav");
1600     precache_sound ("player/slime.wav");
1601
1602     if (g_jetpack)
1603         precache_sound ("misc/jetpack_fly.wav");
1604
1605     precache_model ("models/sprites/0.spr32");
1606     precache_model ("models/sprites/1.spr32");
1607     precache_model ("models/sprites/2.spr32");
1608     precache_model ("models/sprites/3.spr32");
1609     precache_model ("models/sprites/4.spr32");
1610     precache_model ("models/sprites/5.spr32");
1611     precache_model ("models/sprites/6.spr32");
1612     precache_model ("models/sprites/7.spr32");
1613     precache_model ("models/sprites/8.spr32");
1614     precache_model ("models/sprites/9.spr32");
1615     precache_model ("models/sprites/10.spr32");
1616
1617     // common weapon precaches
1618         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1619     precache_sound ("weapons/weapon_switch.wav");
1620     precache_sound ("weapons/weaponpickup.wav");
1621     precache_sound ("weapons/unavailable.wav");
1622     precache_sound ("weapons/dryfire.wav");
1623     if (g_grappling_hook)
1624     {
1625         precache_sound ("weapons/hook_fire.wav"); // hook
1626         precache_sound ("weapons/hook_impact.wav"); // hook
1627     }
1628
1629     if(autocvar_sv_precacheweapons)
1630     {
1631         //precache weapon models/sounds
1632         local float wep;
1633         wep = WEP_FIRST;
1634         while (wep <= WEP_LAST)
1635         {
1636             weapon_action(wep, WR_PRECACHE);
1637             wep = wep + 1;
1638         }
1639     }
1640
1641     precache_model("models/elaser.mdl");
1642     precache_model("models/laser.mdl");
1643     precache_model("models/ebomb.mdl");
1644
1645 #if 0
1646     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1647
1648     if (!self.noise && self.music) // quake 3 uses the music field
1649         self.noise = self.music;
1650
1651     // plays music for the level if there is any
1652     if (self.noise)
1653     {
1654         precache_sound (self.noise);
1655         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1656     }
1657 #endif
1658 }
1659
1660 // sorry, but using \ in macros breaks line numbers
1661 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1662 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1663 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1664
1665
1666 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1667 {
1668         if (clienttype(e) == CLIENTTYPE_REAL)
1669         {
1670                 msg_entity = e;
1671                 WRITESPECTATABLE_MSG_ONE({
1672                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1673                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1674                         WriteByte(MSG_ONE, id);
1675                         WriteString(MSG_ONE, s);
1676                         if (id != 0 && s != "")
1677                         {
1678                                 WriteByte(MSG_ONE, duration);
1679                                 WriteByte(MSG_ONE, countdown_num);
1680                         }
1681                 });
1682         }
1683 }
1684 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1685 {
1686         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1687 }
1688 // WARNING: this kills the trace globals
1689 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1690 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1691
1692 #define INITPRIO_FIRST              0
1693 #define INITPRIO_GAMETYPE           0
1694 #define INITPRIO_GAMETYPE_FALLBACK  1
1695 #define INITPRIO_FINDTARGET        10
1696 #define INITPRIO_DROPTOFLOOR       20
1697 #define INITPRIO_SETLOCATION       90
1698 #define INITPRIO_LINKDOORS         91
1699 #define INITPRIO_LAST              99
1700
1701 .void(void) initialize_entity;
1702 .float initialize_entity_order;
1703 .entity initialize_entity_next;
1704 entity initialize_entity_first;
1705
1706 void make_safe_for_remove(entity e)
1707 {
1708     if (e.initialize_entity)
1709     {
1710         entity ent, prev;
1711         for (ent = initialize_entity_first; ent; )
1712         {
1713             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1714             {
1715                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1716                 // skip it in linked list
1717                 if (prev)
1718                 {
1719                     prev.initialize_entity_next = ent.initialize_entity_next;
1720                     ent = prev.initialize_entity_next;
1721                 }
1722                 else
1723                 {
1724                     initialize_entity_first = ent.initialize_entity_next;
1725                     ent = initialize_entity_first;
1726                 }
1727             }
1728             else
1729             {
1730                 prev = ent;
1731                 ent = ent.initialize_entity_next;
1732             }
1733         }
1734     }
1735 }
1736
1737 void objerror(string s)
1738 {
1739     make_safe_for_remove(self);
1740     objerror_builtin(s);
1741 }
1742
1743 .float remove_except_protected_forbidden;
1744 void remove_except_protected(entity e)
1745 {
1746         if(e.remove_except_protected_forbidden)
1747                 error("not allowed to remove this at this point");
1748         remove_builtin(e);
1749 }
1750
1751 void remove_unsafely(entity e)
1752 {
1753     if(e.classname == "spike")
1754         error("Removing spikes is forbidden (crylink bug), please report");
1755     remove_builtin(e);
1756 }
1757
1758 void remove_safely(entity e)
1759 {
1760     make_safe_for_remove(e);
1761     remove_builtin(e);
1762 }
1763
1764 void InitializeEntity(entity e, void(void) func, float order)
1765 {
1766     entity prev, cur;
1767
1768     if (!e || e.initialize_entity)
1769     {
1770         // make a proxy initializer entity
1771         entity e_old;
1772         e_old = e;
1773         e = spawn();
1774         e.classname = "initialize_entity";
1775         e.enemy = e_old;
1776     }
1777
1778     e.initialize_entity = func;
1779     e.initialize_entity_order = order;
1780
1781     cur = initialize_entity_first;
1782     for (;;)
1783     {
1784         if (!cur || cur.initialize_entity_order > order)
1785         {
1786             // insert between prev and cur
1787             if (prev)
1788                 prev.initialize_entity_next = e;
1789             else
1790                 initialize_entity_first = e;
1791             e.initialize_entity_next = cur;
1792             return;
1793         }
1794         prev = cur;
1795         cur = cur.initialize_entity_next;
1796     }
1797 }
1798 void InitializeEntitiesRun()
1799 {
1800     entity startoflist;
1801     startoflist = initialize_entity_first;
1802     initialize_entity_first = world;
1803     remove = remove_except_protected;
1804     for (self = startoflist; self; self = self.initialize_entity_next)
1805     {
1806         self.remove_except_protected_forbidden = 1;
1807     }
1808     for (self = startoflist; self; )
1809     {
1810         entity e;
1811         var void(void) func;
1812         e = self.initialize_entity_next;
1813         func = self.initialize_entity;
1814         self.initialize_entity_order = 0;
1815         self.initialize_entity = func_null;
1816         self.initialize_entity_next = world;
1817         self.remove_except_protected_forbidden = 0;
1818         if (self.classname == "initialize_entity")
1819         {
1820             entity e_old;
1821             e_old = self.enemy;
1822             remove_builtin(self);
1823             self = e_old;
1824         }
1825         //dprint("Delayed initialization: ", self.classname, "\n");
1826         if(func != func_null)
1827             func();
1828         else
1829         {
1830             eprint(self);
1831             backtrace(strcat("Null function in: ", self.classname, "\n"));
1832         }
1833         self = e;
1834     }
1835     remove = remove_unsafely;
1836 }
1837
1838 .float uncustomizeentityforclient_set;
1839 .void(void) uncustomizeentityforclient;
1840 void(void) SUB_Nullpointer = #0;
1841 void UncustomizeEntitiesRun()
1842 {
1843     entity oldself;
1844     oldself = self;
1845     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1846         self.uncustomizeentityforclient();
1847     self = oldself;
1848 }
1849 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1850 {
1851     e.customizeentityforclient = customizer;
1852     e.uncustomizeentityforclient = uncustomizer;
1853     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1854 }
1855
1856 .float nottargeted;
1857 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1858
1859 void() SUB_Remove;
1860 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1861 {
1862     vector mi, ma;
1863
1864     if (e.classname == "")
1865         e.classname = "net_linked";
1866
1867     if (e.model == "" || self.modelindex == 0)
1868     {
1869         mi = e.mins;
1870         ma = e.maxs;
1871         setmodel(e, "null");
1872         setsize(e, mi, ma);
1873     }
1874
1875     e.SendEntity = sendfunc;
1876     e.SendFlags = 0xFFFFFF;
1877
1878     if (!docull)
1879         e.effects |= EF_NODEPTHTEST;
1880
1881     if (dt)
1882     {
1883         e.nextthink = time + dt;
1884         e.think = SUB_Remove;
1885     }
1886 }
1887
1888 void adaptor_think2touch()
1889 {
1890     entity o;
1891     o = other;
1892     other = world;
1893     self.touch();
1894     other = o;
1895 }
1896
1897 void adaptor_think2use()
1898 {
1899     entity o, a;
1900     o = other;
1901     a = activator;
1902     activator = world;
1903     other = world;
1904     self.use();
1905     other = o;
1906     activator = a;
1907 }
1908
1909 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1910 {
1911         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1912                 self.projectiledeathtype |= HITTYPE_SPLASH;
1913         adaptor_think2use();
1914 }
1915
1916 // deferred dropping
1917 void DropToFloor_Handler()
1918 {
1919     droptofloor_builtin();
1920     self.dropped_origin = self.origin;
1921 }
1922
1923 void droptofloor()
1924 {
1925     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1926 }
1927
1928
1929
1930 float trace_hits_box_a0, trace_hits_box_a1;
1931
1932 float trace_hits_box_1d(float end, float thmi, float thma)
1933 {
1934     if (end == 0)
1935     {
1936         // just check if x is in range
1937         if (0 < thmi)
1938             return FALSE;
1939         if (0 > thma)
1940             return FALSE;
1941     }
1942     else
1943     {
1944         // do the trace with respect to x
1945         // 0 -> end has to stay in thmi -> thma
1946         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1947         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1948         if (trace_hits_box_a0 > trace_hits_box_a1)
1949             return FALSE;
1950     }
1951     return TRUE;
1952 }
1953
1954 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1955 {
1956     end -= start;
1957     thmi -= start;
1958     thma -= start;
1959     // now it is a trace from 0 to end
1960
1961     trace_hits_box_a0 = 0;
1962     trace_hits_box_a1 = 1;
1963
1964     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1965         return FALSE;
1966     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1967         return FALSE;
1968     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1969         return FALSE;
1970
1971     return TRUE;
1972 }
1973
1974 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1975 {
1976     return trace_hits_box(start, end, thmi - ma, thma - mi);
1977 }
1978
1979 float SUB_NoImpactCheck()
1980 {
1981         // zero hitcontents = this is not the real impact, but either the
1982         // mirror-impact of something hitting the projectile instead of the
1983         // projectile hitting the something, or a touchareagrid one. Neither of
1984         // these stop the projectile from moving, so...
1985         if(trace_dphitcontents == 0)
1986         {
1987                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1988                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1989                 checkclient();
1990         }
1991     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1992         return 1;
1993     if (other == world && self.size != '0 0 0')
1994     {
1995         vector tic;
1996         tic = self.velocity * sys_frametime;
1997         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1998         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1999         if (trace_fraction >= 1)
2000         {
2001             dprint("Odd... did not hit...?\n");
2002         }
2003         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2004         {
2005             dprint("Detected and prevented the sky-grapple bug.\n");
2006             return 1;
2007         }
2008     }
2009
2010     return 0;
2011 }
2012
2013 #define SUB_OwnerCheck() (other && (other == self.owner))
2014
2015 void RemoveGrapplingHook(entity pl);
2016 void W_Crylink_Dequeue(entity e);
2017 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2018 {
2019         if(SUB_OwnerCheck())
2020                 return TRUE;
2021         if(SUB_NoImpactCheck())
2022         {
2023                 if(self.classname == "grapplinghook")
2024                         RemoveGrapplingHook(self.realowner);
2025                 else if(self.classname == "spike")
2026                 {
2027                         W_Crylink_Dequeue(self);
2028                         remove(self);
2029                 }
2030                 else
2031                         remove(self);
2032                 return TRUE;
2033         }
2034         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2035                 UpdateCSQCProjectile(self);
2036         return FALSE;
2037 }
2038 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2039
2040 float MAX_IPBAN_URIS           = 16;
2041
2042 float URI_GET_DISCARD          = 0;
2043 float URI_GET_IPBAN            = 1;
2044 float URI_GET_IPBAN_END        = 16;
2045 float URI_GET_PLAYERSTATS_SENT = 17;
2046
2047 void URI_Get_Callback(float id, float status, string data)
2048 {
2049     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2050     dprint(data);
2051     dprint("\nEnd of data.\n");
2052
2053     if(url_URI_Get_Callback(id, status, data))
2054     {
2055         // handled
2056     }
2057     else if (id == URI_GET_DISCARD)
2058     {
2059         // discard
2060     }
2061     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2062     {
2063         // online ban list
2064         OnlineBanList_URI_Get_Callback(id, status, data);
2065     }
2066     else if (id == URI_GET_PLAYERSTATS_SENT)
2067     {
2068         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2069     }
2070     else
2071     {
2072         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2073     }
2074 }
2075
2076 void print_to(entity e, string s)
2077 {
2078     if (e)
2079         sprint(e, strcat(s, "\n"));
2080     else
2081         print(s, "\n");
2082 }
2083
2084 string uid2name(string myuid) {
2085         string s;
2086         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2087
2088         if(s == "")
2089                 s = "^1Unregistered Player";
2090         return s;
2091 }
2092
2093 float race_readTime(string map, float pos)
2094 {
2095         string rr;
2096         if(g_cts)
2097                 rr = CTS_RECORD;
2098         else
2099                 rr = RACE_RECORD;
2100
2101         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2102 }
2103
2104 string race_readUID(string map, float pos)
2105 {
2106         string rr;
2107         if(g_cts)
2108                 rr = CTS_RECORD;
2109         else
2110                 rr = RACE_RECORD;
2111
2112         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2113 }
2114
2115 float race_readPos(string map, float t) {
2116         float i;
2117         for (i = 1; i <= RANKINGS_CNT; ++i)
2118                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2119                         return i;
2120
2121         return 0; // pos is zero if unranked
2122 }
2123
2124 void race_writeTime(string map, float t, string myuid)
2125 {
2126         string rr;
2127         if(g_cts)
2128                 rr = CTS_RECORD;
2129         else
2130                 rr = RACE_RECORD;
2131
2132         float newpos;
2133         newpos = race_readPos(map, t);
2134
2135         float i, prevpos;
2136         for(i = 1; i <= RANKINGS_CNT; ++i)
2137         {
2138                 if(race_readUID(map, i) == myuid)
2139                         prevpos = i;
2140         }
2141         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2142                 for (i = prevpos; i > newpos; --i) {
2143                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2144                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2145                 }
2146         } else { // player has no ranked record yet
2147                 for (i = RANKINGS_CNT; i > newpos; --i) {
2148                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2149                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2150                 }
2151         }
2152
2153         // store new time itself
2154         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2155         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2156 }
2157
2158 string race_readName(string map, float pos)
2159 {
2160         string rr;
2161         if(g_cts)
2162                 rr = CTS_RECORD;
2163         else
2164                 rr = RACE_RECORD;
2165
2166         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2167 }
2168
2169 string race_placeName(float pos) {
2170         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2171         {
2172                 if(mod(pos, 10) == 1)
2173                         return strcat(ftos(pos), "st");
2174                 else if(mod(pos, 10) == 2)
2175                         return strcat(ftos(pos), "nd");
2176                 else if(mod(pos, 10) == 3)
2177                         return strcat(ftos(pos), "rd");
2178                 else
2179                         return strcat(ftos(pos), "th");
2180         }
2181         else
2182                 return strcat(ftos(pos), "th");
2183 }
2184 string getrecords(float page) // 50 records per page
2185 {
2186     float rec;
2187     string h;
2188     float r;
2189     float i;
2190     string s;
2191
2192     rec = 0;
2193
2194     s = "";
2195
2196     if (g_ctf)
2197     {
2198         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2199         {
2200             if (MapInfo_Get_ByID(i))
2201             {
2202                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2203                 if (r == 0)
2204                     continue;
2205                 // TODO: uid2name
2206                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2207                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2208                 ++rec;
2209             }
2210         }
2211     }
2212
2213     if (g_race)
2214     {
2215         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2216         {
2217             if (MapInfo_Get_ByID(i))
2218             {
2219                 r = race_readTime(MapInfo_Map_bspname, 1);
2220                 if (r == 0)
2221                     continue;
2222                 h = race_readName(MapInfo_Map_bspname, 1);
2223                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2224                 ++rec;
2225             }
2226         }
2227     }
2228
2229     if (g_cts)
2230     {
2231         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2232         {
2233             if (MapInfo_Get_ByID(i))
2234             {
2235                 r = race_readTime(MapInfo_Map_bspname, 1);
2236                 if (r == 0)
2237                     continue;
2238                 h = race_readName(MapInfo_Map_bspname, 1);
2239                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2240                 ++rec;
2241             }
2242         }
2243     }
2244
2245     MapInfo_ClearTemps();
2246
2247     if (s == "" && page == 0)
2248         return "No records are available on this server.\n";
2249     else
2250         return s;
2251 }
2252
2253 string getrankings()
2254 {
2255     string n;
2256     float t;
2257     float i;
2258     string s;
2259     string p;
2260     string map;
2261
2262     s = "";
2263
2264     map = GetMapname();
2265
2266     for (i = 1; i <= RANKINGS_CNT; ++i)
2267     {
2268         t = race_readTime(map, i);
2269         if (t == 0)
2270             continue;
2271         n = race_readName(map, i);
2272         p = race_placeName(i);
2273         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2274     }
2275
2276     MapInfo_ClearTemps();
2277
2278     if (s == "")
2279         return strcat("No records are available for the map: ", map, "\n");
2280     else
2281         return strcat("Records for ", map, ":\n", s);
2282 }
2283
2284 #define LADDER_FIRSTPOINT 100
2285 #define LADDER_CNT 10
2286         // position X still gives LADDER_FIRSTPOINT/X points
2287 #define LADDER_SIZE 30
2288         // ladder shows the top X players
2289 string top_uids[LADDER_SIZE];
2290 float top_scores[LADDER_SIZE];
2291 string getladder()
2292 {
2293     float i, j, k, uidcnt;
2294     string s, temp_s;
2295
2296     s = "";
2297     temp_s = "";
2298
2299     string rr;
2300     if(g_cts)
2301         rr = CTS_RECORD;
2302     else
2303         rr = RACE_RECORD;
2304
2305     string myuid;
2306
2307     for (k = 0; k < MapInfo_count; ++k)
2308     {
2309         if (MapInfo_Get_ByID(k))
2310         {
2311                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2312                         if(i == 0) // speed award
2313                         {
2314                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2315                                         continue;
2316
2317                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2318                         }
2319                         else // normal record, if it exists (else break)
2320                         {
2321                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2322                                         continue;
2323
2324                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2325                         }
2326
2327                         // string s contains:
2328                         // arg 0 = # of speed recs
2329                         // arg 1 = # of 1st place recs
2330                         // arg 2 = # of 2nd place recs
2331                         // ... etc
2332                         // LADDER_CNT+1 = total points
2333
2334                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2335                         if (temp_s == "")
2336                         {
2337                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2338                             ++uidcnt;
2339                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2340                             {
2341                                 if(j != LADDER_CNT + 1)
2342                                     temp_s = strcat(temp_s, "0 ");
2343                                 else
2344                                     temp_s = strcat(temp_s, "0");
2345                             }
2346                         }
2347
2348                         tokenize_console(temp_s);
2349                         s = "";
2350
2351                         if(i == 0) // speed award
2352                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2353                             {
2354                                 if(j == 0) // speed award
2355                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2356                                 else
2357                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2358                             }
2359                         else // record
2360                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2361                             {
2362                                 if(j == 0)
2363                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2364                                 else if(j == i) // wanted rec!
2365                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2366                                 else
2367                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2368                             }
2369
2370                         // total points are (by default) calculated like this:
2371                         // speedrec = floor(100 / 10) = 10 points
2372                         // 1st place = floor(100 / 1) = 100 points
2373                         // 2nd place = floor(100 / 2) = 50 points
2374                         // 3rd place = floor(100 / 3) = 33 points
2375                         // 4th place = floor(100 / 4) = 25 points
2376                         // 5th place = floor(100 / 5) = 20 points
2377                         // ... etc
2378
2379                         if(i == 0)
2380                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2381                         else
2382                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2383
2384                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2385                 }
2386         }
2387     }
2388
2389     float thiscnt;
2390     string thisuid;
2391     for (i = 0; i <= uidcnt; ++i) // for each known uid
2392     {
2393         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2394         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2395         tokenize_console(temp_s);
2396         thiscnt = stof(argv(LADDER_CNT+1));
2397
2398         if(thiscnt > top_scores[LADDER_SIZE-1])
2399         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2400         {
2401             if(thiscnt > top_scores[j])
2402             {
2403                 for (k = LADDER_SIZE-1; k >= j; --k)
2404                 {
2405                     top_uids[k] = top_uids[k-1];
2406                     top_scores[k] = top_scores[k-1];
2407                 }
2408                 top_uids[j] = thisuid;
2409                 top_scores[j] = thiscnt;
2410                 break;
2411             }
2412         }
2413     }
2414
2415     s = "^3-----------------------\n\n";
2416
2417     s = strcat(s, "Pos ^3|");
2418     s = strcat(s, " ^7Total  ^3|");
2419     for (i = 1; i <= LADDER_CNT; ++i)
2420     {
2421         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2422     }
2423     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2424
2425     s = strcat(s, "\n^3----+--------");
2426     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2427     {
2428         s = strcat(s, "+-----");
2429     }
2430 #if LADDER_CNT > 9
2431     for (i = 1; i <= LADDER_CNT - 9; ++i)
2432     {
2433         s = strcat(s, "+------");
2434     }
2435 #endif
2436
2437     s = strcat(s, "+--------------+--------------------\n");
2438
2439     for (i = 0; i < LADDER_SIZE; ++i)
2440     {
2441         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2442         tokenize_console(temp_s);
2443         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2444             continue;
2445         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2446         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2447         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2448         {
2449             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2450         }
2451 #if LADDER_CNT > 9
2452         for (j = 10; j <= LADDER_CNT; ++j)
2453         {
2454             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2455         }
2456 #endif
2457
2458         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2459         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2460     }
2461
2462     MapInfo_ClearTemps();
2463
2464     if (s == "")
2465         return "No ladder on this server!\n";
2466     else
2467         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2468 }
2469
2470
2471 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2472 {
2473     float m, i;
2474     vector start, org, delta, end, enddown, mstart;
2475     entity sp;
2476
2477     m = e.dphitcontentsmask;
2478     e.dphitcontentsmask = goodcontents | badcontents;
2479
2480     org = world.mins;
2481     delta = world.maxs - world.mins;
2482
2483     for (i = 0; i < attempts; ++i)
2484     {
2485         start_x = org_x + random() * delta_x;
2486         start_y = org_y + random() * delta_y;
2487         start_z = org_z + random() * delta_z;
2488
2489         // rule 1: start inside world bounds, and outside
2490         // solid, and don't start from somewhere where you can
2491         // fall down to evil
2492         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2493         if (trace_fraction >= 1)
2494             continue;
2495         if (trace_startsolid)
2496             continue;
2497         if (trace_dphitcontents & badcontents)
2498             continue;
2499         if (trace_dphitq3surfaceflags & badsurfaceflags)
2500             continue;
2501
2502         // rule 2: if we are too high, lower the point
2503         if (trace_fraction * delta_z > maxaboveground)
2504             start = trace_endpos + '0 0 1' * maxaboveground;
2505         enddown = trace_endpos;
2506
2507         // rule 3: make sure we aren't outside the map. This only works
2508         // for somewhat well formed maps. A good rule of thumb is that
2509         // the map should have a convex outside hull.
2510         // these can be traceLINES as we already verified the starting box
2511         mstart = start + 0.5 * (e.mins + e.maxs);
2512         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2513         if (trace_fraction >= 1)
2514             continue;
2515         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2516         if (trace_fraction >= 1)
2517             continue;
2518         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2519         if (trace_fraction >= 1)
2520             continue;
2521         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2522         if (trace_fraction >= 1)
2523             continue;
2524         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2525         if (trace_fraction >= 1)
2526             continue;
2527
2528         // rule 4: we must "see" some spawnpoint
2529         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2530                 if(checkpvs(mstart, sp))
2531                         break;
2532         if(!sp)
2533         {
2534                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2535                         if(checkpvs(mstart, sp))
2536                                 break;
2537                 if(!sp)
2538                         continue;
2539         }
2540
2541         // find a random vector to "look at"
2542         end_x = org_x + random() * delta_x;
2543         end_y = org_y + random() * delta_y;
2544         end_z = org_z + random() * delta_z;
2545         end = start + normalize(end - start) * vlen(delta);
2546
2547         // rule 4: start TO end must not be too short
2548         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2549         if (trace_startsolid)
2550             continue;
2551         if (trace_fraction < minviewdistance / vlen(delta))
2552             continue;
2553
2554         // rule 5: don't want to look at sky
2555         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2556             continue;
2557
2558         // rule 6: we must not end up in trigger_hurt
2559         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2560             continue;
2561
2562         break;
2563     }
2564
2565     e.dphitcontentsmask = m;
2566
2567     if (i < attempts)
2568     {
2569         setorigin(e, start);
2570         e.angles = vectoangles(end - start);
2571         dprint("Needed ", ftos(i + 1), " attempts\n");
2572         return TRUE;
2573     }
2574     else
2575         return FALSE;
2576 }
2577
2578 float zcurveparticles_effectno;
2579 vector zcurveparticles_start;
2580 float zcurveparticles_spd;
2581
2582 void endzcurveparticles()
2583 {
2584         if(zcurveparticles_effectno)
2585         {
2586                 // terminator
2587                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2588         }
2589         zcurveparticles_effectno = 0;
2590 }
2591
2592 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2593 {
2594         spd = bound(0, floor(spd / 16), 32767);
2595         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2596         {
2597                 endzcurveparticles();
2598                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2599                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2600                 WriteShort(MSG_BROADCAST, effectno);
2601                 WriteCoord(MSG_BROADCAST, start_x);
2602                 WriteCoord(MSG_BROADCAST, start_y);
2603                 WriteCoord(MSG_BROADCAST, start_z);
2604                 zcurveparticles_effectno = effectno;
2605                 zcurveparticles_start = start;
2606         }
2607         else
2608                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2609         WriteCoord(MSG_BROADCAST, end_x);
2610         WriteCoord(MSG_BROADCAST, end_y);
2611         WriteCoord(MSG_BROADCAST, end_z);
2612         WriteCoord(MSG_BROADCAST, end_dz);
2613         zcurveparticles_spd = spd;
2614 }
2615
2616 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2617 {
2618         float end_dz;
2619         vector vecxy, velxy;
2620
2621         vecxy = end - start;
2622         vecxy_z = 0;
2623         velxy = vel;
2624         velxy_z = 0;
2625
2626         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2627         {
2628                 endzcurveparticles();
2629                 trailparticles(world, effectno, start, end);
2630                 return;
2631         }
2632
2633         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2634         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2635 }
2636
2637 void write_recordmarker(entity pl, float tstart, float dt)
2638 {
2639     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2640
2641     // also write a marker into demo files for demotc-race-record-extractor to find
2642     stuffcmd(pl,
2643              strcat(
2644                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2645                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2646 }
2647
2648 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2649 {
2650         switch(algn)
2651         {
2652                 default:
2653                 case 3: // right
2654                         break;
2655
2656                 case 4: // left
2657                         vecs_y = -vecs_y;
2658                         break;
2659
2660                 case 1:
2661                         if(allowcenter) // 2: allow center handedness
2662                         {
2663                                 // center
2664                                 vecs_y = 0;
2665                                 vecs_z -= 2;
2666                         }
2667                         else
2668                         {
2669                                 // right
2670                         }
2671                         break;
2672
2673                 case 2:
2674                         if(allowcenter) // 2: allow center handedness
2675                         {
2676                                 // center
2677                                 vecs_y = 0;
2678                                 vecs_z -= 2;
2679                         }
2680                         else
2681                         {
2682                                 // left
2683                                 vecs_y = -vecs_y;
2684                         }
2685                         break;
2686         }
2687         return vecs;
2688 }
2689
2690 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2691 {
2692         string s;
2693         vector v;
2694
2695         if (autocvar_g_shootfromeye)
2696         {
2697                 if (visual)
2698                 {
2699                         vecs_y = 0;
2700                         vecs_z -= 2;
2701                 }
2702                 else
2703                 {
2704                         vecs_y = 0;
2705                         vecs_z = 0;
2706                 }
2707         }
2708         else if (autocvar_g_shootfromcenter)
2709         {
2710                 vecs_y = 0;
2711                 vecs_z -= 2;
2712         }
2713         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2714         {
2715                 v = stov(s);
2716                 if (y_is_right)
2717                         v_y = -v_y;
2718                 if (v_x != 0)
2719                         vecs_x = v_x;
2720                 vecs_y = v_y;
2721                 vecs_z = v_z;
2722         }
2723         else if (autocvar_g_shootfromclient)
2724         {
2725                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2726         }
2727         return vecs;
2728 }
2729
2730 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2731 {
2732         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2733 }
2734
2735
2736 void attach_sameorigin(entity e, entity to, string tag)
2737 {
2738     vector org, t_forward, t_left, t_up, e_forward, e_up;
2739     vector org0, ang0;
2740     float tagscale;
2741
2742     ang0 = e.angles;
2743     org0 = e.origin;
2744
2745     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2746     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2747     t_forward = v_forward * tagscale;
2748     t_left = v_right * -tagscale;
2749     t_up = v_up * tagscale;
2750
2751     e.origin_x = org * t_forward;
2752     e.origin_y = org * t_left;
2753     e.origin_z = org * t_up;
2754
2755     // current forward and up directions
2756     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2757                 e.angles = AnglesTransform_FromVAngles(e.angles);
2758         else
2759                 e.angles = AnglesTransform_FromAngles(e.angles);
2760     fixedmakevectors(e.angles);
2761
2762     // untransform forward, up!
2763     e_forward_x = v_forward * t_forward;
2764     e_forward_y = v_forward * t_left;
2765     e_forward_z = v_forward * t_up;
2766     e_up_x = v_up * t_forward;
2767     e_up_y = v_up * t_left;
2768     e_up_z = v_up * t_up;
2769
2770     e.angles = fixedvectoangles2(e_forward, e_up);
2771     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2772                 e.angles = AnglesTransform_ToVAngles(e.angles);
2773         else
2774                 e.angles = AnglesTransform_ToAngles(e.angles);
2775
2776     setattachment(e, to, tag);
2777     setorigin(e, e.origin);
2778 }
2779
2780 void detach_sameorigin(entity e)
2781 {
2782     vector org;
2783     org = gettaginfo(e, 0);
2784     e.angles = fixedvectoangles2(v_forward, v_up);
2785     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2786                 e.angles = AnglesTransform_ToVAngles(e.angles);
2787         else
2788                 e.angles = AnglesTransform_ToAngles(e.angles);
2789     setorigin(e, org);
2790     setattachment(e, world, "");
2791     setorigin(e, e.origin);
2792 }
2793
2794 void follow_sameorigin(entity e, entity to)
2795 {
2796     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2797     e.aiment = to; // make the hole follow bmodel
2798     e.punchangle = to.angles; // the original angles of bmodel
2799     e.view_ofs = e.origin - to.origin; // relative origin
2800     e.v_angle = e.angles - to.angles; // relative angles
2801 }
2802
2803 void unfollow_sameorigin(entity e)
2804 {
2805     e.movetype = MOVETYPE_NONE;
2806 }
2807
2808 entity gettaginfo_relative_ent;
2809 vector gettaginfo_relative(entity e, float tag)
2810 {
2811     if (!gettaginfo_relative_ent)
2812     {
2813         gettaginfo_relative_ent = spawn();
2814         gettaginfo_relative_ent.effects = EF_NODRAW;
2815     }
2816     gettaginfo_relative_ent.model = e.model;
2817     gettaginfo_relative_ent.modelindex = e.modelindex;
2818     gettaginfo_relative_ent.frame = e.frame;
2819     return gettaginfo(gettaginfo_relative_ent, tag);
2820 }
2821
2822 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2823 {
2824     float p;
2825     p = pow(2, chan);
2826     if (pl.soundentity.cnt & p)
2827         return;
2828     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2829     pl.soundentity.cnt |= p;
2830 }
2831
2832 void SoundEntity_StopSound(entity pl, float chan)
2833 {
2834     float p;
2835     p = pow(2, chan);
2836     if (pl.soundentity.cnt & p)
2837     {
2838         stopsoundto(MSG_ALL, pl.soundentity, chan);
2839         pl.soundentity.cnt &~= p;
2840     }
2841 }
2842
2843 void SoundEntity_Attach(entity pl)
2844 {
2845     pl.soundentity = spawn();
2846     pl.soundentity.classname = "soundentity";
2847     pl.soundentity.owner = pl;
2848     setattachment(pl.soundentity, pl, "");
2849     setmodel(pl.soundentity, "null");
2850 }
2851
2852 void SoundEntity_Detach(entity pl)
2853 {
2854     float i;
2855     for (i = 0; i <= 7; ++i)
2856         SoundEntity_StopSound(pl, i);
2857 }
2858
2859
2860 float ParseCommandPlayerSlotTarget_firsttoken;
2861 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2862 {
2863         string s;
2864         entity e, head;
2865         float n;
2866
2867         s = string_null;
2868
2869         ParseCommandPlayerSlotTarget_firsttoken = -1;
2870
2871         if (tokens > idx)
2872         {
2873                 if (substring(argv(idx), 0, 1) == "#")
2874                 {
2875                         s = substring(argv(idx), 1, -1);
2876                         ++idx;
2877                         if (s == "") if (tokens > idx)
2878                         {
2879                                 s = argv(idx);
2880                                 ++idx;
2881                         }
2882                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2883                         n = stof(s);
2884                         if (s == ftos(n) && n > 0 && n <= maxclients)
2885                         {
2886                                 e = edict_num(n);
2887                                 if (e.flags & FL_CLIENT)
2888                                         return e;
2889                         }
2890                 }
2891                 else
2892                 {
2893                         // it must be a nick name
2894                         s = argv(idx);
2895                         ++idx;
2896                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2897
2898                         n = 0;
2899                         FOR_EACH_CLIENT(head)
2900                                 if (head.netname == s)
2901                                 {
2902                                         e = head;
2903                                         ++n;
2904                                 }
2905                         if (n == 1)
2906                                 return e;
2907
2908                         s = strdecolorize(s);
2909                         n = 0;
2910                         FOR_EACH_CLIENT(head)
2911                                 if (strdecolorize(head.netname) == s)
2912                                 {
2913                                         e = head;
2914                                         ++n;
2915                                 }
2916                         if (n == 1)
2917                                 return e;
2918                 }
2919         }
2920
2921         return world;
2922 }
2923
2924 .float scale2;
2925
2926 float modeleffect_SendEntity(entity to, float sf)
2927 {
2928         float f;
2929         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2930
2931         f = 0;
2932         if(self.velocity != '0 0 0')
2933                 f |= 1;
2934         if(self.angles != '0 0 0')
2935                 f |= 2;
2936         if(self.avelocity != '0 0 0')
2937                 f |= 4;
2938
2939         WriteByte(MSG_ENTITY, f);
2940         WriteShort(MSG_ENTITY, self.modelindex);
2941         WriteByte(MSG_ENTITY, self.skin);
2942         WriteByte(MSG_ENTITY, self.frame);
2943         WriteCoord(MSG_ENTITY, self.origin_x);
2944         WriteCoord(MSG_ENTITY, self.origin_y);
2945         WriteCoord(MSG_ENTITY, self.origin_z);
2946         if(f & 1)
2947         {
2948                 WriteCoord(MSG_ENTITY, self.velocity_x);
2949                 WriteCoord(MSG_ENTITY, self.velocity_y);
2950                 WriteCoord(MSG_ENTITY, self.velocity_z);
2951         }
2952         if(f & 2)
2953         {
2954                 WriteCoord(MSG_ENTITY, self.angles_x);
2955                 WriteCoord(MSG_ENTITY, self.angles_y);
2956                 WriteCoord(MSG_ENTITY, self.angles_z);
2957         }
2958         if(f & 4)
2959         {
2960                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2961                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2962                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2963         }
2964         WriteShort(MSG_ENTITY, self.scale * 256.0);
2965         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2966         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2967         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2968         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2969
2970         return TRUE;
2971 }
2972
2973 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2974 {
2975         entity e;
2976         float sz;
2977         e = spawn();
2978         e.classname = "modeleffect";
2979         setmodel(e, m);
2980         e.frame = f;
2981         setorigin(e, o);
2982         e.velocity = v;
2983         e.angles = ang;
2984         e.avelocity = angv;
2985         e.alpha = a;
2986         e.teleport_time = t1;
2987         e.fade_time = t2;
2988         e.skin = s;
2989         if(s0 >= 0)
2990                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2991         else
2992                 e.scale = -s0;
2993         if(s2 >= 0)
2994                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2995         else
2996                 e.scale2 = -s2;
2997         sz = max(e.scale, e.scale2);
2998         setsize(e, e.mins * sz, e.maxs * sz);
2999         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
3000 }
3001
3002 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
3003 {
3004         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3005 }
3006
3007 float randombit(float bits)
3008 {
3009         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3010                 return bits;
3011
3012         float n, f, b, r;
3013
3014         r = random();
3015         b = 0;
3016         n = 0;
3017
3018         for(f = 1; f <= bits; f *= 2)
3019         {
3020                 if(bits & f)
3021                 {
3022                         ++n;
3023                         r *= n;
3024                         if(r <= 1)
3025                                 b = f;
3026                         else
3027                                 r = (r - 1) / (n - 1);
3028                 }
3029         }
3030
3031         return b;
3032 }
3033
3034 float randombits(float bits, float k, float error_return)
3035 {
3036         float r;
3037         r = 0;
3038         while(k > 0 && bits != r)
3039         {
3040                 r += randombit(bits - r);
3041                 --k;
3042         }
3043         if(error_return)
3044                 if(k > 0)
3045                         return -1; // all
3046         return r;
3047 }
3048
3049 void randombit_test(float bits, float iter)
3050 {
3051         while(iter > 0)
3052         {
3053                 print(ftos(randombit(bits)), "\n");
3054                 --iter;
3055         }
3056 }
3057
3058 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3059 {
3060         if(halflifedist > 0)
3061                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3062         else if(halflifedist < 0)
3063                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3064         else
3065                 return 1;
3066 }
3067
3068
3069
3070
3071 #ifdef RELEASE
3072 #define cvar_string_normal cvar_string_builtin
3073 #define cvar_normal cvar_builtin
3074 #else
3075 string cvar_string_normal(string n)
3076 {
3077         if not(cvar_type(n) & 1)
3078                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3079         return cvar_string_builtin(n);
3080 }
3081
3082 float cvar_normal(string n)
3083 {
3084         return stof(cvar_string_normal(n));
3085 }
3086 #endif
3087 #define cvar_set_normal cvar_set_builtin
3088
3089 void defer_think()
3090 {
3091     entity oself;
3092
3093     oself           = self;
3094     self            = self.owner;
3095     oself.think     = SUB_Remove;
3096     oself.nextthink = time;
3097
3098     oself.use();
3099 }
3100
3101 /*
3102     Execute func() after time + fdelay.
3103     self when func is executed = self when defer is called
3104 */
3105 void defer(float fdelay, void() func)
3106 {
3107     entity e;
3108
3109     e           = spawn();
3110     e.owner     = self;
3111     e.use       = func;
3112     e.think     = defer_think;
3113     e.nextthink = time + fdelay;
3114 }
3115
3116 .string aiment_classname;
3117 .float aiment_deadflag;
3118 void SetMovetypeFollow(entity ent, entity e)
3119 {
3120         // FIXME this may not be warpzone aware
3121         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3122         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3123         ent.aiment = e; // make the hole follow bmodel
3124         ent.punchangle = e.angles; // the original angles of bmodel
3125         ent.view_ofs = ent.origin - e.origin; // relative origin
3126         ent.v_angle = ent.angles - e.angles; // relative angles
3127         ent.aiment_classname = strzone(e.classname);
3128         ent.aiment_deadflag = e.deadflag;
3129 }
3130 void UnsetMovetypeFollow(entity ent)
3131 {
3132         ent.movetype = MOVETYPE_FLY;
3133         PROJECTILE_MAKETRIGGER(ent);
3134         ent.aiment = world;
3135 }
3136 float LostMovetypeFollow(entity ent)
3137 {
3138 /*
3139         if(ent.movetype != MOVETYPE_FOLLOW)
3140                 if(ent.aiment)
3141                         error("???");
3142 */
3143         if(ent.aiment)
3144         {
3145                 if(ent.aiment.classname != ent.aiment_classname)
3146                         return 1;
3147                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3148                         return 1;
3149         }
3150         return 0;
3151 }
3152
3153 float isPushable(entity e)
3154 {
3155         if(e.iscreature)
3156                 return TRUE;
3157         switch(e.classname)
3158         {
3159                 case "body":
3160                 case "droppedweapon":
3161                 case "keepawayball":
3162                 case "nexball_basketball":
3163                 case "nexball_football":
3164                         return TRUE;
3165                 case "bullet": // antilagged bullets can't hit this either
3166                         return FALSE;
3167         }
3168         if (e.projectiledeathtype)
3169                 return TRUE;
3170         return FALSE;
3171 }