qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "antilag.qh"
   3 #include "command/common.qh"
   4 #include "constants.qh"
   5 #include "g_hook.qh"
   6 #include "ipban.qh"
   7 #include "mutators/_mod.qh"
   8 #include "../common/t_items.qh"
   9 #include "weapons/accuracy.qh"
  10 #include "weapons/csqcprojectile.qh"
  11 #include "weapons/selection.qh"
  12 #include "../common/command/_mod.qh"
  13 #include "../common/constants.qh"
  14 #include <common/net_linked.qh>
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/notifications/all.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/triggers/subs.qh"
  21 #include "../common/util.qh"
  22 #include "../common/turrets/sv_turrets.qh"
  23 #include <common/weapons/_all.qh>
  24 #include "../common/vehicles/sv_vehicles.qh"
  25 #include "../common/vehicles/vehicle.qh"
  26 #include "../common/items/_mod.qh"
  27 #include "../common/state.qh"
  28 #include "../common/effects/qc/globalsound.qh"
  29 #include "../common/wepent.qh"
  30 #include "../lib/csqcmodel/sv_model.qh"
  31 #include "../lib/warpzone/anglestransform.qh"
  32 #include "../lib/warpzone/server.qh"
  33
  34 void crosshair_trace(entity pl)
  35 {
  36         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  37 }
  38 .bool ctrace_solidchanged;
  39 void crosshair_trace_plusvisibletriggers(entity pl)
  40 {
  41         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  42         {
  43                 if(it.model != "")
  44                 {
  45                         it.solid = SOLID_BSP;
  46                         it.ctrace_solidchanged = true;
  47                         IL_PUSH(g_ctrace_changed, it);
  48                 }
  49         });
  50
  51         crosshair_trace(pl);
  52
  53         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  54         {
  55                 it.solid = SOLID_TRIGGER;
  56                 it.ctrace_solidchanged = false;
  57         });
  58
  59         IL_CLEAR(g_ctrace_changed);
  60 }
  61 void WarpZone_crosshair_trace(entity pl)
  62 {
  63         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  64 }
  65
  66
  67 void GameLogEcho(string s)
  68 {
  69     string fn;
  70     int matches;
  71
  72     if (autocvar_sv_eventlog_files)
  73     {
  74         if (!logfile_open)
  75         {
  76             logfile_open = true;
  77             matches = autocvar_sv_eventlog_files_counter + 1;
  78             cvar_set("sv_eventlog_files_counter", itos(matches));
  79             fn = ftos(matches);
  80             if (strlen(fn) < 8)
  81                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  82             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  83             logfile = fopen(fn, FILE_APPEND);
  84             fputs(logfile, ":logversion:3\n");
  85         }
  86         if (logfile >= 0)
  87         {
  88             if (autocvar_sv_eventlog_files_timestamps)
  89                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  90             else
  91                 fputs(logfile, strcat(s, "\n"));
  92         }
  93     }
  94     if (autocvar_sv_eventlog_console)
  95     {
  96         dedicated_print(strcat(s, "\n"));
  97     }
  98 }
  99
 100 void GameLogInit()
 101 {
 102     logfile_open = 0;
 103     // will be opened later
 104 }
 105
 106 void GameLogClose()
 107 {
 108     if (logfile_open && logfile >= 0)
 109     {
 110         fclose(logfile);
 111         logfile = -1;
 112     }
 113 }
 114
 115 entity findnearest(vector point, bool checkitems, vector axismod)
 116 {
 117     vector dist;
 118     int num_nearest = 0;
 119
 120     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 121     {
 122         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 123             dist = it.oldorigin;
 124         else
 125             dist = it.origin;
 126         dist = dist - point;
 127         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 128         float len = vlen2(dist);
 129
 130         int l;
 131         for (l = 0; l < num_nearest; ++l)
 132         {
 133             if (len < nearest_length[l])
 134                 break;
 135         }
 136
 137         // now i tells us where to insert at
 138         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 139         if (l < NUM_NEAREST_ENTITIES)
 140         {
 141             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 142             {
 143                 nearest_length[j + 1] = nearest_length[j];
 144                 nearest_entity[j + 1] = nearest_entity[j];
 145             }
 146             nearest_length[l] = len;
 147             nearest_entity[l] = it;
 148             if (num_nearest < NUM_NEAREST_ENTITIES)
 149                 num_nearest = num_nearest + 1;
 150         }
 151     });
 152
 153     // now use the first one from our list that we can see
 154     for (int j = 0; j < num_nearest; ++j)
 155     {
 156         traceline(point, nearest_entity[j].origin, true, NULL);
 157         if (trace_fraction == 1)
 158         {
 159             if (j != 0)
 160                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 161             return nearest_entity[j];
 162         }
 163     }
 164
 165     if (num_nearest == 0)
 166         return NULL;
 167
 168     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 169     /* DEBUGGING CODE:
 170     dprint("Candidates were: ");
 171     for(j = 0; j < num_nearest; ++j)
 172     {
 173         if(j != 0)
 174                 dprint(", ");
 175         dprint(nearest_entity[j].netname);
 176     }
 177     dprint("\n");
 178     */
 179
 180     return nearest_entity[0];
 181 }
 182
 183 string NearestLocation(vector p)
 184 {
 185     string ret = "somewhere";
 186     entity loc = findnearest(p, false, '1 1 1');
 187     if (loc)
 188         ret = loc.message;
 189     else
 190     {
 191         loc = findnearest(p, true, '1 1 4');
 192         if (loc)
 193             ret = loc.netname;
 194     }
 195     return ret;
 196 }
 197
 198 string AmmoNameFromWeaponentity(entity wpn)
 199 {
 200         string ammoitems = "batteries";
 201         switch((wpn.m_weapon).ammo_field)
 202         {
 203                 case ammo_shells:  ammoitems = ITEM_Shells.m_name;      break;
 204                 case ammo_nails:   ammoitems = ITEM_Bullets.m_name;     break;
 205                 case ammo_rockets: ammoitems = ITEM_Rockets.m_name;     break;
 206                 case ammo_cells:   ammoitems = ITEM_Cells.m_name;       break;
 207                 case ammo_plasma:  ammoitems = ITEM_Plasma.m_name;      break;
 208                 case ammo_fuel:    ammoitems = ITEM_JetpackFuel.m_name; break;
 209         }
 210         return ammoitems;
 211 }
 212
 213 string formatmessage(entity this, string msg)
 214 {
 215         float p, p1, p2;
 216         float n;
 217         vector cursor;
 218         entity cursor_ent;
 219         string escape;
 220         string replacement;
 221         p = 0;
 222         n = 7;
 223
 224         WarpZone_crosshair_trace(this);
 225         cursor = trace_endpos;
 226         cursor_ent = trace_ent;
 227
 228         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 229         msg = M_ARGV(1, string);
 230
 231         while (1) {
 232                 if (n < 1)
 233                         break; // too many replacements
 234
 235                 n = n - 1;
 236                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 237                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 238
 239                 if (p1 < 0)
 240                         p1 = p2;
 241
 242                 if (p2 < 0)
 243                         p2 = p1;
 244
 245                 p = min(p1, p2);
 246
 247                 if (p < 0)
 248                         break;
 249
 250                 replacement = substring(msg, p, 2);
 251                 escape = substring(msg, p + 1, 1);
 252
 253                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 254
 255                 switch(escape)
 256                 {
 257                         case "%": replacement = "%"; break;
 258                         case "\\":replacement = "\\"; break;
 259                         case "n": replacement = "\n"; break;
 260                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 261                         case "h": replacement = ftos(floor(this.health)); break;
 262                         case "l": replacement = NearestLocation(this.origin); break;
 263                         case "y": replacement = NearestLocation(cursor); break;
 264                         case "d": replacement = NearestLocation(this.death_origin); break;
 265                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 266                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 267                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 268                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 269                         case "S": replacement = ftos(vlen(this.velocity)); break;
 270                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 271                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 272                         default:
 273                         {
 274                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 275                                 replacement = M_ARGV(2, string);
 276                                 break;
 277                         }
 278                 }
 279
 280                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 281                 p = p + strlen(replacement);
 282         }
 283         return msg;
 284 }
 285
 286 /*
 287 =============
 288 GetCvars
 289 =============
 290 Called with:
 291   0:  sends the request
 292   >0: receives a cvar from name=argv(f) value=argv(f+1)
 293 */
 294 void GetCvars_handleString(entity this, string thisname, float f, .string field, string name)
 295 {
 296         if (f < 0)
 297         {
 298                 if (this.(field))
 299                         strunzone(this.(field));
 300                 this.(field) = string_null;
 301         }
 302         else if (f > 0)
 303         {
 304                 if (thisname == name)
 305                 {
 306                         if (this.(field))
 307                                 strunzone(this.(field));
 308                         this.(field) = strzone(argv(f + 1));
 309                 }
 310         }
 311         else
 312                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 313 }
 314 void GetCvars_handleString_Fixup(entity this, string thisname, float f, .string field, string name, string(entity, string) func)
 315 {
 316         GetCvars_handleString(this, thisname, f, field, name);
 317         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 318                 if (thisname == name)
 319                 {
 320                         string s = func(this, strcat1(this.(field)));
 321                         if (s != this.(field))
 322                         {
 323                                 strunzone(this.(field));
 324                                 this.(field) = strzone(s);
 325                         }
 326                 }
 327 }
 328 void GetCvars_handleFloat(entity this, string thisname, float f, .float field, string name)
 329 {
 330         if (f < 0)
 331         {
 332         }
 333         else if (f > 0)
 334         {
 335                 if (thisname == name)
 336                         this.(field) = stof(argv(f + 1));
 337         }
 338         else
 339                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 340 }
 341 void GetCvars_handleFloatOnce(entity this, string thisname, float f, .float field, string name)
 342 {
 343         if (f < 0)
 344         {
 345         }
 346         else if (f > 0)
 347         {
 348                 if (thisname == name)
 349                 {
 350                         if (!this.(field))
 351                         {
 352                                 this.(field) = stof(argv(f + 1));
 353                                 if (!this.(field))
 354                                         this.(field) = -1;
 355                         }
 356                 }
 357         }
 358         else
 359         {
 360                 if (!this.(field))
 361                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 362         }
 363 }
 364 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 365 {
 366         string o;
 367         o = W_FixWeaponOrder_ForceComplete(wo);
 368         if(this.weaponorder_byimpulse)
 369         {
 370                 strunzone(this.weaponorder_byimpulse);
 371                 this.weaponorder_byimpulse = string_null;
 372         }
 373         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 374         return o;
 375 }
 376
 377 REPLICATE(autoswitch, bool, "cl_autoswitch");
 378
 379 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 380
 381 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 382
 383 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 384
 385 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 386
 387 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 388
 389 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 390
 391 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 392
 393 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 394
 395 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 396
 397 REPLICATE(cvar_cl_physics, string, "cl_physics");
 398
 399 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 400
 401 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 402
 403 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 404
 405 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 406
 407 /**
 408  * @param f -1: cleanup, 0: request, 1: receive
 409  */
 410 void GetCvars(entity this, int f)
 411 {
 412         string s = string_null;
 413
 414         if (f > 0)
 415                 s = strcat1(argv(f));
 416
 417         get_cvars_f = f;
 418         get_cvars_s = s;
 419         MUTATOR_CALLHOOK(GetCvars);
 420
 421         Notification_GetCvars(this);
 422
 423         ReplicateVars(this, s, f);
 424
 425         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 426         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 427         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 428         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 436
 437         GetCvars_handleFloat(this, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 438
 439         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 440         if (f > 0)
 441         {
 442                 if (s == "cl_weaponpriority")
 443                 {
 444                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 445                         {
 446                                 .entity weaponentity = weaponentities[slot];
 447                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 448                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 449                         }
 450                 }
 451                 if (s == "cl_allow_uidtracking")
 452                         PlayerStats_GameReport_AddPlayer(this);
 453         }
 454 }
 455
 456 // decolorizes and team colors the player name when needed
 457 string playername(entity p, bool team_colorize)
 458 {
 459     string t;
 460     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 461     {
 462         t = Team_ColorCode(p.team);
 463         return strcat(t, strdecolorize(p.netname));
 464     }
 465     else
 466         return ColorTranslateRGB(p.netname);
 467 }
 468
 469 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 470 {
 471         int i = weaponinfo.m_id;
 472         int d = 0;
 473         bool allow_mutatorblocked = false;
 474
 475         if(!i)
 476                 return 0;
 477
 478         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 479         d = M_ARGV(1, float);
 480         allguns = M_ARGV(2, bool);
 481         allow_mutatorblocked = M_ARGV(3, bool);
 482
 483         if(allguns)
 484         {
 485                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 486                         d = true;
 487                 else
 488                         d = false;
 489         }
 490         else if(!mutator_returnvalue)
 491                 d = !(!weaponinfo.weaponstart);
 492
 493         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 494                 d = 0;
 495
 496         float t = weaponinfo.weaponstartoverride;
 497
 498         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 499
 500         // bit order in t:
 501         // 1: want or not
 502         // 2: is default?
 503         // 4: is set by default?
 504         if(t < 0)
 505                 t = 4 | (3 * d);
 506         else
 507                 t |= (2 * d);
 508
 509         return t;
 510 }
 511
 512 void readplayerstartcvars()
 513 {
 514         float i, t;
 515         string s;
 516
 517         // initialize starting values for players
 518         start_weapons = '0 0 0';
 519         start_weapons_default = '0 0 0';
 520         start_weapons_defaultmask = '0 0 0';
 521         start_items = 0;
 522         start_ammo_shells = 0;
 523         start_ammo_nails = 0;
 524         start_ammo_rockets = 0;
 525         start_ammo_cells = 0;
 526         start_ammo_plasma = 0;
 527         start_health = cvar("g_balance_health_start");
 528         start_armorvalue = cvar("g_balance_armor_start");
 529
 530         g_weaponarena = 0;
 531         g_weaponarena_weapons = '0 0 0';
 532
 533         s = cvar_string("g_weaponarena");
 534
 535         MUTATOR_CALLHOOK(SetWeaponArena, s);
 536         s = M_ARGV(0, string);
 537
 538         if (s == "0" || s == "")
 539         {
 540                 // no arena
 541         }
 542         else if (s == "off")
 543         {
 544                 // forcibly turn off weaponarena
 545         }
 546         else if (s == "all" || s == "1")
 547         {
 548                 g_weaponarena = 1;
 549                 g_weaponarena_list = "All Weapons";
 550                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 551                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 552                                 g_weaponarena_weapons |= (it.m_wepset);
 553                 ));
 554         }
 555         else if (s == "devall")
 556         {
 557                 g_weaponarena = 1;
 558                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 559                 FOREACH(Weapons, it != WEP_Null,
 560                 {
 561                         g_weaponarena_weapons |= (it.m_wepset);
 562                 });
 563         }
 564         else if (s == "most")
 565         {
 566                 g_weaponarena = 1;
 567                 g_weaponarena_list = "Most Weapons";
 568                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 569                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 570                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 571                                         g_weaponarena_weapons |= (it.m_wepset);
 572                 ));
 573         }
 574         else if (s == "none")
 575         {
 576                 g_weaponarena = 1;
 577                 g_weaponarena_list = "No Weapons";
 578         }
 579         else
 580         {
 581                 g_weaponarena = 1;
 582                 t = tokenize_console(s);
 583                 g_weaponarena_list = "";
 584                 for (i = 0; i < t; ++i)
 585                 {
 586                         s = argv(i);
 587                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 588                                 if(it.netname == s)
 589                                 {
 590                                         g_weaponarena_weapons |= (it.m_wepset);
 591                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 592                                         break;
 593                                 }
 594                         ));
 595                 }
 596                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 597         }
 598
 599         if(g_weaponarena)
 600                 g_weaponarena_random = cvar("g_weaponarena_random");
 601         else
 602                 g_weaponarena_random = 0;
 603         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 604
 605         if (g_weaponarena)
 606         {
 607                 g_weapon_stay = 0; // incompatible
 608                 start_weapons = g_weaponarena_weapons;
 609                 start_items |= IT_UNLIMITED_AMMO;
 610         }
 611         else
 612         {
 613                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 614                         int w = want_weapon(it, false);
 615                         WepSet s = it.m_wepset;
 616                         if(w & 1)
 617                                 start_weapons |= s;
 618                         if(w & 2)
 619                                 start_weapons_default |= s;
 620                         if(w & 4)
 621                                 start_weapons_defaultmask |= s;
 622                 ));
 623         }
 624
 625         if(!cvar("g_use_ammunition"))
 626                 start_items |= IT_UNLIMITED_AMMO;
 627
 628         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 629         {
 630                 start_ammo_shells = 999;
 631                 start_ammo_nails = 999;
 632                 start_ammo_rockets = 999;
 633                 start_ammo_cells = 999;
 634                 start_ammo_plasma = 999;
 635                 start_ammo_fuel = 999;
 636         }
 637         else
 638         {
 639                 start_ammo_shells = cvar("g_start_ammo_shells");
 640                 start_ammo_nails = cvar("g_start_ammo_nails");
 641                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 642                 start_ammo_cells = cvar("g_start_ammo_cells");
 643                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 644                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 645         }
 646
 647         if (warmup_stage)
 648         {
 649                 warmup_start_ammo_shells = start_ammo_shells;
 650                 warmup_start_ammo_nails = start_ammo_nails;
 651                 warmup_start_ammo_rockets = start_ammo_rockets;
 652                 warmup_start_ammo_cells = start_ammo_cells;
 653                 warmup_start_ammo_plasma = start_ammo_plasma;
 654                 warmup_start_ammo_fuel = start_ammo_fuel;
 655                 warmup_start_health = start_health;
 656                 warmup_start_armorvalue = start_armorvalue;
 657                 warmup_start_weapons = start_weapons;
 658                 warmup_start_weapons_default = start_weapons_default;
 659                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 660
 661                 if (!g_weaponarena && !g_ca && !g_freezetag)
 662                 {
 663                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 664                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 665                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 666                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 667                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 668                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 669                         warmup_start_health = cvar("g_warmup_start_health");
 670                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 671                         warmup_start_weapons = '0 0 0';
 672                         warmup_start_weapons_default = '0 0 0';
 673                         warmup_start_weapons_defaultmask = '0 0 0';
 674                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 675                                 int w = want_weapon(it, g_warmup_allguns);
 676                                 WepSet s = (it.m_wepset);
 677                                 if(w & 1)
 678                                         warmup_start_weapons |= s;
 679                                 if(w & 2)
 680                                         warmup_start_weapons_default |= s;
 681                                 if(w & 4)
 682                                         warmup_start_weapons_defaultmask |= s;
 683                         ));
 684                 }
 685         }
 686
 687         if (g_jetpack)
 688                 start_items |= ITEM_Jetpack.m_itemid;
 689
 690         MUTATOR_CALLHOOK(SetStartItems);
 691
 692         if (start_items & ITEM_Jetpack.m_itemid)
 693         {
 694                 start_items |= ITEM_JetpackRegen.m_itemid;
 695                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 696                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 697         }
 698
 699         WepSet precache_weapons = start_weapons;
 700         if (g_warmup_allguns != 1)
 701                 precache_weapons |= warmup_start_weapons;
 702         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 703                 if(precache_weapons & (it.m_wepset))
 704                         it.wr_init(it);
 705         ));
 706
 707         start_ammo_shells = max(0, start_ammo_shells);
 708         start_ammo_nails = max(0, start_ammo_nails);
 709         start_ammo_rockets = max(0, start_ammo_rockets);
 710         start_ammo_cells = max(0, start_ammo_cells);
 711         start_ammo_plasma = max(0, start_ammo_plasma);
 712         start_ammo_fuel = max(0, start_ammo_fuel);
 713
 714         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 715         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 716         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 717         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 718         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 719         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 720 }
 721
 722 void precache_playermodel(string m)
 723 {
 724         float globhandle, i, n;
 725         string f;
 726
 727         if(substring(m, -9,5) == "_lod1")
 728                 return;
 729         if(substring(m, -9,5) == "_lod2")
 730                 return;
 731         precache_model(m);
 732         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 733         if(fexists(f))
 734                 precache_model(f);
 735         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 736         if(fexists(f))
 737                 precache_model(f);
 738
 739         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 740         if (globhandle < 0)
 741                 return;
 742         n = search_getsize(globhandle);
 743         for (i = 0; i < n; ++i)
 744         {
 745                 //print(search_getfilename(globhandle, i), "\n");
 746                 f = search_getfilename(globhandle, i);
 747                 PrecachePlayerSounds(f);
 748         }
 749         search_end(globhandle);
 750 }
 751 void precache_all_playermodels(string pattern)
 752 {
 753         int globhandle = search_begin(pattern, true, false);
 754         if (globhandle < 0) return;
 755         int n = search_getsize(globhandle);
 756         for (int i = 0; i < n; ++i)
 757         {
 758                 string s = search_getfilename(globhandle, i);
 759                 precache_playermodel(s);
 760         }
 761         search_end(globhandle);
 762 }
 763
 764 void precache_playermodels(string s)
 765 {
 766         FOREACH_WORD(s, true, LAMBDA(precache_playermodel(it)));
 767 }
 768
 769 void precache()
 770 {
 771     // gamemode related things
 772
 773     // Precache all player models if desired
 774     if (autocvar_sv_precacheplayermodels)
 775     {
 776         PrecachePlayerSounds("sound/player/default.sounds");
 777         precache_all_playermodels("models/player/*.zym");
 778         precache_all_playermodels("models/player/*.dpm");
 779         precache_all_playermodels("models/player/*.md3");
 780         precache_all_playermodels("models/player/*.psk");
 781         precache_all_playermodels("models/player/*.iqm");
 782     }
 783
 784     if (autocvar_sv_defaultcharacter)
 785     {
 786                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 787                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 788                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 789                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 790                 precache_playermodels(autocvar_sv_defaultplayermodel);
 791     }
 792
 793 #if 0
 794     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 795
 796     if (!this.noise && this.music) // quake 3 uses the music field
 797         this.noise = this.music;
 798
 799     // plays music for the level if there is any
 800     if (this.noise)
 801     {
 802         precache_sound (this.noise);
 803         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 804     }
 805 #endif
 806 }
 807
 808
 809 void make_safe_for_remove(entity e)
 810 {
 811     if (e.initialize_entity)
 812     {
 813         entity ent, prev = NULL;
 814         for (ent = initialize_entity_first; ent; )
 815         {
 816             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 817             {
 818                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 819                 // skip it in linked list
 820                 if (prev)
 821                 {
 822                     prev.initialize_entity_next = ent.initialize_entity_next;
 823                     ent = prev.initialize_entity_next;
 824                 }
 825                 else
 826                 {
 827                     initialize_entity_first = ent.initialize_entity_next;
 828                     ent = initialize_entity_first;
 829                 }
 830             }
 831             else
 832             {
 833                 prev = ent;
 834                 ent = ent.initialize_entity_next;
 835             }
 836         }
 837     }
 838 }
 839
 840 .float remove_except_protected_forbidden;
 841 void remove_except_protected(entity e)
 842 {
 843         if(e.remove_except_protected_forbidden)
 844                 error("not allowed to remove this at this point");
 845         builtin_remove(e);
 846 }
 847
 848 void remove_unsafely(entity e)
 849 {
 850     if(e.classname == "spike")
 851         error("Removing spikes is forbidden (crylink bug), please report");
 852     builtin_remove(e);
 853 }
 854
 855 void remove_safely(entity e)
 856 {
 857     make_safe_for_remove(e);
 858     builtin_remove(e);
 859 }
 860
 861 void InitializeEntity(entity e, void(entity this) func, float order)
 862 {
 863     entity prev, cur;
 864
 865     if (!e || e.initialize_entity)
 866     {
 867         // make a proxy initializer entity
 868         entity e_old = e;
 869         e = new(initialize_entity);
 870         e.enemy = e_old;
 871     }
 872
 873     e.initialize_entity = func;
 874     e.initialize_entity_order = order;
 875
 876     cur = initialize_entity_first;
 877     prev = NULL;
 878     for (;;)
 879     {
 880         if (!cur || cur.initialize_entity_order > order)
 881         {
 882             // insert between prev and cur
 883             if (prev)
 884                 prev.initialize_entity_next = e;
 885             else
 886                 initialize_entity_first = e;
 887             e.initialize_entity_next = cur;
 888             return;
 889         }
 890         prev = cur;
 891         cur = cur.initialize_entity_next;
 892     }
 893 }
 894 void InitializeEntitiesRun()
 895 {
 896     entity startoflist = initialize_entity_first;
 897     initialize_entity_first = NULL;
 898     delete_fn = remove_except_protected;
 899     for (entity e = startoflist; e; e = e.initialize_entity_next)
 900     {
 901                 e.remove_except_protected_forbidden = 1;
 902     }
 903     for (entity e = startoflist; e; )
 904     {
 905                 e.remove_except_protected_forbidden = 0;
 906         e.initialize_entity_order = 0;
 907         entity next = e.initialize_entity_next;
 908         e.initialize_entity_next = NULL;
 909         var void(entity this) func = e.initialize_entity;
 910         e.initialize_entity = func_null;
 911         if (e.classname == "initialize_entity")
 912         {
 913             entity wrappee = e.enemy;
 914             builtin_remove(e);
 915             e = wrappee;
 916         }
 917         //dprint("Delayed initialization: ", e.classname, "\n");
 918         if (func)
 919         {
 920                 func(e);
 921         }
 922         else
 923         {
 924             eprint(e);
 925             backtrace(strcat("Null function in: ", e.classname, "\n"));
 926         }
 927         e = next;
 928     }
 929     delete_fn = remove_unsafely;
 930 }
 931
 932 .float(entity) isEliminated;
 933 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 934 {
 935         float i, f, b;
 936         entity e;
 937         WriteHeader(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 938         WriteByte(MSG_ENTITY, sendflags);
 939
 940         if(sendflags & 1)
 941         {
 942                 for(i = 1; i <= maxclients; i += 8)
 943                 {
 944                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 945                         {
 946                                 if(eliminatedPlayers.isEliminated(e))
 947                                         f |= b;
 948                         }
 949                         WriteByte(MSG_ENTITY, f);
 950                 }
 951         }
 952
 953         return true;
 954 }
 955
 956 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 957 {
 958         if(eliminatedPlayers)
 959         {
 960                 backtrace("Can't spawn eliminatedPlayers again!");
 961                 return;
 962         }
 963         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 964         eliminatedPlayers.isEliminated = isEliminated_func;
 965 }
 966
 967
 968
 969
 970 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 971 {
 972         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 973                 this.projectiledeathtype |= HITTYPE_SPLASH;
 974         adaptor_think2use(this);
 975 }
 976
 977 // deferred dropping
 978 void DropToFloor_Handler(entity this)
 979 {
 980     WITHSELF(this, builtin_droptofloor());
 981     this.dropped_origin = this.origin;
 982 }
 983
 984 void droptofloor(entity this)
 985 {
 986     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
 987 }
 988
 989
 990
 991 float trace_hits_box_a0, trace_hits_box_a1;
 992
 993 float trace_hits_box_1d(float end, float thmi, float thma)
 994 {
 995     if (end == 0)
 996     {
 997         // just check if x is in range
 998         if (0 < thmi)
 999             return false;
1000         if (0 > thma)
1001             return false;
1002     }
1003     else
1004     {
1005         // do the trace with respect to x
1006         // 0 -> end has to stay in thmi -> thma
1007         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1008         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1009         if (trace_hits_box_a0 > trace_hits_box_a1)
1010             return false;
1011     }
1012     return true;
1013 }
1014
1015 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1016 {
1017     end -= start;
1018     thmi -= start;
1019     thma -= start;
1020     // now it is a trace from 0 to end
1021
1022     trace_hits_box_a0 = 0;
1023     trace_hits_box_a1 = 1;
1024
1025     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1026         return false;
1027     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1028         return false;
1029     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1030         return false;
1031
1032     return true;
1033 }
1034
1035 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1036 {
1037     return trace_hits_box(start, end, thmi - ma, thma - mi);
1038 }
1039
1040 bool SUB_NoImpactCheck(entity this, entity toucher)
1041 {
1042         // zero hitcontents = this is not the real impact, but either the
1043         // mirror-impact of something hitting the projectile instead of the
1044         // projectile hitting the something, or a touchareagrid one. Neither of
1045         // these stop the projectile from moving, so...
1046         if(trace_dphitcontents == 0)
1047         {
1048                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1049                 checkclient(this);
1050         }
1051     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1052         return true;
1053     if (toucher == NULL && this.size != '0 0 0')
1054     {
1055         vector tic;
1056         tic = this.velocity * sys_frametime;
1057         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1058         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1059         if (trace_fraction >= 1)
1060         {
1061             LOG_TRACE("Odd... did not hit...?");
1062         }
1063         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1064         {
1065             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1066             return true;
1067         }
1068     }
1069
1070     return false;
1071 }
1072
1073 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1074
1075 void W_Crylink_Dequeue(entity e);
1076 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1077 {
1078         if(SUB_OwnerCheck(this, toucher))
1079                 return true;
1080         if(SUB_NoImpactCheck(this, toucher))
1081         {
1082                 if(this.classname == "nade")
1083                         return false; // no checks here
1084                 else if(this.classname == "grapplinghook")
1085                         RemoveHook(this);
1086                 else if(this.classname == "spike")
1087                 {
1088                         W_Crylink_Dequeue(this);
1089                         delete(this);
1090                 }
1091                 else
1092                         delete(this);
1093                 return true;
1094         }
1095         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1096                 UpdateCSQCProjectile(this);
1097         return false;
1098 }
1099
1100 /** engine callback */
1101 void URI_Get_Callback(float id, float status, string data)
1102 {
1103         if(url_URI_Get_Callback(id, status, data))
1104         {
1105                 // handled
1106         }
1107         else if (id == URI_GET_DISCARD)
1108         {
1109                 // discard
1110         }
1111         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1112         {
1113                 // sv_cmd curl
1114                 Curl_URI_Get_Callback(id, status, data);
1115         }
1116         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1117         {
1118                 // online ban list
1119                 OnlineBanList_URI_Get_Callback(id, status, data);
1120         }
1121         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1122         {
1123                 // handled by a mutator
1124         }
1125         else
1126         {
1127                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1128         }
1129 }
1130
1131 string uid2name(string myuid) {
1132         string s;
1133         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1134
1135         // FIXME remove this later after 0.6 release
1136         // convert old style broken records to correct style
1137         if(s == "")
1138         {
1139                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1140                 if(s != "")
1141                 {
1142                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1143                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1144                 }
1145         }
1146
1147         if(s == "")
1148                 s = "^1Unregistered Player";
1149         return s;
1150 }
1151
1152 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1153 {
1154     float m, i;
1155     vector start, org, delta, end, enddown, mstart;
1156
1157     m = e.dphitcontentsmask;
1158     e.dphitcontentsmask = goodcontents | badcontents;
1159
1160     org = boundmin;
1161     delta = boundmax - boundmin;
1162
1163     start = end = org;
1164
1165     for (i = 0; i < attempts; ++i)
1166     {
1167         start.x = org.x + random() * delta.x;
1168         start.y = org.y + random() * delta.y;
1169         start.z = org.z + random() * delta.z;
1170
1171         // rule 1: start inside world bounds, and outside
1172         // solid, and don't start from somewhere where you can
1173         // fall down to evil
1174         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1175         if (trace_fraction >= 1)
1176             continue;
1177         if (trace_startsolid)
1178             continue;
1179         if (trace_dphitcontents & badcontents)
1180             continue;
1181         if (trace_dphitq3surfaceflags & badsurfaceflags)
1182             continue;
1183
1184         // rule 2: if we are too high, lower the point
1185         if (trace_fraction * delta.z > maxaboveground)
1186             start = trace_endpos + '0 0 1' * maxaboveground;
1187         enddown = trace_endpos;
1188
1189         // rule 3: make sure we aren't outside the map. This only works
1190         // for somewhat well formed maps. A good rule of thumb is that
1191         // the map should have a convex outside hull.
1192         // these can be traceLINES as we already verified the starting box
1193         mstart = start + 0.5 * (e.mins + e.maxs);
1194         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1195         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1196             continue;
1197         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1198         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1199             continue;
1200         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1201         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1202             continue;
1203         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1204         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1205             continue;
1206         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1207         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1208             continue;
1209
1210         // rule 4: we must "see" some spawnpoint or item
1211     entity sp = NULL;
1212     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1213     {
1214         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1215         {
1216                 sp = it;
1217                 break;
1218         }
1219     });
1220         if(!sp)
1221         {
1222                 IL_EACH(g_items, checkpvs(mstart, it),
1223                 {
1224                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1225                         {
1226                                 sp = it;
1227                                 break;
1228                         }
1229                 });
1230
1231                 if(!sp)
1232                         continue;
1233         }
1234
1235         // find a random vector to "look at"
1236         end.x = org.x + random() * delta.x;
1237         end.y = org.y + random() * delta.y;
1238         end.z = org.z + random() * delta.z;
1239         end = start + normalize(end - start) * vlen(delta);
1240
1241         // rule 4: start TO end must not be too short
1242         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1243         if (trace_startsolid)
1244             continue;
1245         if (trace_fraction < minviewdistance / vlen(delta))
1246             continue;
1247
1248         // rule 5: don't want to look at sky
1249         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1250             continue;
1251
1252         // rule 6: we must not end up in trigger_hurt
1253         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1254             continue;
1255
1256         break;
1257     }
1258
1259     e.dphitcontentsmask = m;
1260
1261     if (i < attempts)
1262     {
1263         setorigin(e, start);
1264         e.angles = vectoangles(end - start);
1265         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1266         return true;
1267     }
1268     else
1269         return false;
1270 }
1271
1272 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1273 {
1274         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1275 }
1276
1277 void write_recordmarker(entity pl, float tstart, float dt)
1278 {
1279     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1280
1281     // also write a marker into demo files for demotc-race-record-extractor to find
1282     stuffcmd(pl,
1283              strcat(
1284                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1285                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1286 }
1287
1288 void attach_sameorigin(entity e, entity to, string tag)
1289 {
1290     vector org, t_forward, t_left, t_up, e_forward, e_up;
1291     float tagscale;
1292
1293     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1294     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1295     t_forward = v_forward * tagscale;
1296     t_left = v_right * -tagscale;
1297     t_up = v_up * tagscale;
1298
1299     e.origin_x = org * t_forward;
1300     e.origin_y = org * t_left;
1301     e.origin_z = org * t_up;
1302
1303     // current forward and up directions
1304     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1305                 e.angles = AnglesTransform_FromVAngles(e.angles);
1306         else
1307                 e.angles = AnglesTransform_FromAngles(e.angles);
1308     fixedmakevectors(e.angles);
1309
1310     // untransform forward, up!
1311     e_forward.x = v_forward * t_forward;
1312     e_forward.y = v_forward * t_left;
1313     e_forward.z = v_forward * t_up;
1314     e_up.x = v_up * t_forward;
1315     e_up.y = v_up * t_left;
1316     e_up.z = v_up * t_up;
1317
1318     e.angles = fixedvectoangles2(e_forward, e_up);
1319     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1320                 e.angles = AnglesTransform_ToVAngles(e.angles);
1321         else
1322                 e.angles = AnglesTransform_ToAngles(e.angles);
1323
1324     setattachment(e, to, tag);
1325     setorigin(e, e.origin);
1326 }
1327
1328 void detach_sameorigin(entity e)
1329 {
1330     vector org;
1331     org = gettaginfo(e, 0);
1332     e.angles = fixedvectoangles2(v_forward, v_up);
1333     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1334                 e.angles = AnglesTransform_ToVAngles(e.angles);
1335         else
1336                 e.angles = AnglesTransform_ToAngles(e.angles);
1337     setorigin(e, org);
1338     setattachment(e, NULL, "");
1339     setorigin(e, e.origin);
1340 }
1341
1342 void follow_sameorigin(entity e, entity to)
1343 {
1344     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1345     e.aiment = to; // make the hole follow bmodel
1346     e.punchangle = to.angles; // the original angles of bmodel
1347     e.view_ofs = e.origin - to.origin; // relative origin
1348     e.v_angle = e.angles - to.angles; // relative angles
1349 }
1350
1351 void unfollow_sameorigin(entity e)
1352 {
1353     set_movetype(e, MOVETYPE_NONE);
1354 }
1355
1356 entity gettaginfo_relative_ent;
1357 vector gettaginfo_relative(entity e, float tag)
1358 {
1359     if (!gettaginfo_relative_ent)
1360     {
1361         gettaginfo_relative_ent = spawn();
1362         gettaginfo_relative_ent.effects = EF_NODRAW;
1363     }
1364     gettaginfo_relative_ent.model = e.model;
1365     gettaginfo_relative_ent.modelindex = e.modelindex;
1366     gettaginfo_relative_ent.frame = e.frame;
1367     return gettaginfo(gettaginfo_relative_ent, tag);
1368 }
1369
1370 .string aiment_classname;
1371 .float aiment_deadflag;
1372 void SetMovetypeFollow(entity ent, entity e)
1373 {
1374         // FIXME this may not be warpzone aware
1375         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1376         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1377         ent.aiment = e; // make the hole follow bmodel
1378         ent.punchangle = e.angles; // the original angles of bmodel
1379         ent.view_ofs = ent.origin - e.origin; // relative origin
1380         ent.v_angle = ent.angles - e.angles; // relative angles
1381         ent.aiment_classname = strzone(e.classname);
1382         ent.aiment_deadflag = e.deadflag;
1383 }
1384 void UnsetMovetypeFollow(entity ent)
1385 {
1386         set_movetype(ent, MOVETYPE_FLY);
1387         PROJECTILE_MAKETRIGGER(ent);
1388         ent.aiment = NULL;
1389 }
1390 float LostMovetypeFollow(entity ent)
1391 {
1392 /*
1393         if(ent.move_movetype != MOVETYPE_FOLLOW)
1394                 if(ent.aiment)
1395                         error("???");
1396 */
1397         if(ent.aiment)
1398         {
1399                 if(ent.aiment.classname != ent.aiment_classname)
1400                         return 1;
1401                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1402                         return 1;
1403         }
1404         return 0;
1405 }
1406
1407 .bool pushable;
1408 bool isPushable(entity e)
1409 {
1410         if(e.pushable)
1411                 return true;
1412         if(IS_VEHICLE(e))
1413                 return false;
1414         if(e.iscreature)
1415                 return true;
1416         switch(e.classname)
1417         {
1418                 case "body":
1419                 case "droppedweapon":
1420                         return true;
1421                 case "bullet": // antilagged bullets can't hit this either
1422                         return false;
1423         }
1424         if (e.projectiledeathtype)
1425                 return true;
1426         return false;
1427 }