qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 float w_getbestweapon(entity e);
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 511
 512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 514
 515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 520
 521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 522         if (f > 0)
 523         {
 524                 if (s == "cl_weaponpriority")
 525                         self.switchweapon = w_getbestweapon(self);
 526                 if (s == "cl_allow_uidtracking")
 527                         PlayerStats_AddPlayer(self);
 528         }
 529 }
 530
 531 // decolorizes and team colors the player name when needed
 532 string playername(entity p)
 533 {
 534     string t;
 535     if (teamplay && !intermission_running && IS_PLAYER(p))
 536     {
 537         t = Team_ColorCode(p.team);
 538         return strcat(t, strdecolorize(p.netname));
 539     }
 540     else
 541         return p.netname;
 542 }
 543
 544 vector randompos(vector m1, vector m2)
 545 {
 546     vector v;
 547     m2 = m2 - m1;
 548     v_x = m2_x * random() + m1_x;
 549     v_y = m2_y * random() + m1_y;
 550     v_z = m2_z * random() + m1_z;
 551     return  v;
 552 }
 553
 554 //#NO AUTOCVARS START
 555
 556 float g_pickup_shells;
 557 float g_pickup_shells_max;
 558 float g_pickup_nails;
 559 float g_pickup_nails_max;
 560 float g_pickup_rockets;
 561 float g_pickup_rockets_max;
 562 float g_pickup_cells;
 563 float g_pickup_cells_max;
 564 float g_pickup_fuel;
 565 float g_pickup_fuel_jetpack;
 566 float g_pickup_fuel_max;
 567 float g_pickup_armorsmall;
 568 float g_pickup_armorsmall_max;
 569 float g_pickup_armorsmall_anyway;
 570 float g_pickup_armormedium;
 571 float g_pickup_armormedium_max;
 572 float g_pickup_armormedium_anyway;
 573 float g_pickup_armorbig;
 574 float g_pickup_armorbig_max;
 575 float g_pickup_armorbig_anyway;
 576 float g_pickup_armorlarge;
 577 float g_pickup_armorlarge_max;
 578 float g_pickup_armorlarge_anyway;
 579 float g_pickup_healthsmall;
 580 float g_pickup_healthsmall_max;
 581 float g_pickup_healthsmall_anyway;
 582 float g_pickup_healthmedium;
 583 float g_pickup_healthmedium_max;
 584 float g_pickup_healthmedium_anyway;
 585 float g_pickup_healthlarge;
 586 float g_pickup_healthlarge_max;
 587 float g_pickup_healthlarge_anyway;
 588 float g_pickup_healthmega;
 589 float g_pickup_healthmega_max;
 590 float g_pickup_healthmega_anyway;
 591 float g_pickup_ammo_anyway;
 592 float g_pickup_weapons_anyway;
 593 float g_weaponarena;
 594 WEPSET_DECLARE_A(g_weaponarena_weapons);
 595 float g_weaponarena_random;
 596 float g_weaponarena_random_with_laser;
 597 string g_weaponarena_list;
 598 float g_weaponspeedfactor;
 599 float g_weaponratefactor;
 600 float g_weapondamagefactor;
 601 float g_weaponforcefactor;
 602 float g_weaponspreadfactor;
 603
 604 WEPSET_DECLARE_A(start_weapons);
 605 WEPSET_DECLARE_A(start_weapons_default);
 606 WEPSET_DECLARE_A(start_weapons_defaultmask);
 607 float start_items;
 608 float start_ammo_shells;
 609 float start_ammo_nails;
 610 float start_ammo_rockets;
 611 float start_ammo_cells;
 612 float start_ammo_fuel;
 613 float start_health;
 614 float start_armorvalue;
 615 WEPSET_DECLARE_A(warmup_start_weapons);
 616 WEPSET_DECLARE_A(warmup_start_weapons_default);
 617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN);
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         WEPSET_CLEAR_A(start_weapons);
 680         WEPSET_CLEAR_A(start_weapons_default);
 681         WEPSET_CLEAR_A(start_weapons_defaultmask);
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         WEPSET_CLEAR_A(g_weaponarena_weapons);
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_weapon_stay = 0; // incompatible
 771                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 772                 start_items |= IT_UNLIMITED_AMMO;
 773         }
 774         else
 775         {
 776                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 777                 {
 778                         e = get_weaponinfo(i);
 779                         float w = want_weapon("g_start_weapon_", e, FALSE);
 780                         if(w & 1)
 781                                 WEPSET_OR_AW(start_weapons, i);
 782                         if(w & 2)
 783                                 WEPSET_OR_AW(start_weapons_default, i);
 784                         if(w & 4)
 785                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 786                 }
 787         }
 788
 789         if(!cvar("g_use_ammunition"))
 790                 start_items |= IT_UNLIMITED_AMMO;
 791
 792         if(cvar("g_nexball"))
 793                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (inWarmupStage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 822                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 823                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         WEPSET_CLEAR_A(warmup_start_weapons);
 835                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 836                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 841                                 if(w & 1)
 842                                         WEPSET_OR_AW(warmup_start_weapons, i);
 843                                 if(w & 2)
 844                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 845                                 if(w & 4)
 846                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 865         {
 866                 e = get_weaponinfo(i);
 867                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 868                         weapon_action(i, WR_PRECACHE);
 869         }
 870
 871         start_ammo_shells = max(0, start_ammo_shells);
 872         start_ammo_nails = max(0, start_ammo_nails);
 873         start_ammo_cells = max(0, start_ammo_cells);
 874         start_ammo_rockets = max(0, start_ammo_rockets);
 875         start_ammo_fuel = max(0, start_ammo_fuel);
 876
 877         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 878         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 879         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 880         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 881         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 882 }
 883
 884 float g_bugrigs;
 885 float g_bugrigs_planar_movement;
 886 float g_bugrigs_planar_movement_car_jumping;
 887 float g_bugrigs_reverse_spinning;
 888 float g_bugrigs_reverse_speeding;
 889 float g_bugrigs_reverse_stopping;
 890 float g_bugrigs_air_steering;
 891 float g_bugrigs_angle_smoothing;
 892 float g_bugrigs_friction_floor;
 893 float g_bugrigs_friction_brake;
 894 float g_bugrigs_friction_air;
 895 float g_bugrigs_accel;
 896 float g_bugrigs_speed_ref;
 897 float g_bugrigs_speed_pow;
 898 float g_bugrigs_steer;
 899
 900 float sv_autotaunt;
 901 float sv_taunt;
 902
 903 string GetGametype(); // g_world.qc
 904 void readlevelcvars(void)
 905 {
 906         // load mutators
 907         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 908                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 909
 910         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 911         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 912         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 913         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 914         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 915         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 921         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 923
 924         #undef CHECK_MUTATOR_ADD
 925
 926         if(cvar("sv_allow_fullbright"))
 927                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 928
 929     g_bugrigs = cvar("g_bugrigs");
 930     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 931     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 932     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 933     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 934     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 935     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 936     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 937     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 938     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 939     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 940     g_bugrigs_accel = cvar("g_bugrigs_accel");
 941     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 942     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 943     g_bugrigs_steer = cvar("g_bugrigs_steer");
 944
 945         g_minstagib = cvar("g_minstagib");
 946
 947         sv_clones = cvar("sv_clones");
 948         sv_foginterval = cvar("sv_foginterval");
 949         g_cloaked = cvar("g_cloaked");
 950     if(g_cts)
 951         g_cloaked = 1; // always enable cloak in CTS
 952         g_jump_grunt = cvar("g_jump_grunt");
 953         g_footsteps = cvar("g_footsteps");
 954         g_grappling_hook = cvar("g_grappling_hook");
 955         g_jetpack = cvar("g_jetpack");
 956         g_midair = cvar("g_midair");
 957         g_norecoil = cvar("g_norecoil");
 958         g_bloodloss = cvar("g_bloodloss");
 959         sv_maxidle = cvar("sv_maxidle");
 960         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 961         sv_autotaunt = cvar("sv_autotaunt");
 962         sv_taunt = cvar("sv_taunt");
 963
 964         inWarmupStage = cvar("g_warmup");
 965         g_warmup_limit = cvar("g_warmup_limit");
 966         g_warmup_allguns = cvar("g_warmup_allguns");
 967         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 968
 969         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
 970                 inWarmupStage = 0; // these modes cannot work together, sorry
 971
 972         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 973         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 974         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 975         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 976         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 977         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 978         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 979         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 980         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 981         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 982         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 983         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 984         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 985         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 986
 987         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 988         g_weaponratefactor = cvar("g_weaponratefactor");
 989         g_weapondamagefactor = cvar("g_weapondamagefactor");
 990         g_weaponforcefactor = cvar("g_weaponforcefactor");
 991         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 992
 993         g_pickup_shells = cvar("g_pickup_shells");
 994         g_pickup_shells_max = cvar("g_pickup_shells_max");
 995         g_pickup_nails = cvar("g_pickup_nails");
 996         g_pickup_nails_max = cvar("g_pickup_nails_max");
 997         g_pickup_rockets = cvar("g_pickup_rockets");
 998         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 999         g_pickup_cells = cvar("g_pickup_cells");
1000         g_pickup_cells_max = cvar("g_pickup_cells_max");
1001         g_pickup_fuel = cvar("g_pickup_fuel");
1002         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1003         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1004         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1005         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1006         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1007         g_pickup_armormedium = cvar("g_pickup_armormedium");
1008         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1009         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1010         g_pickup_armorbig = cvar("g_pickup_armorbig");
1011         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1012         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1013         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1014         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1015         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1016         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1017         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1018         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1019         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1020         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1021         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1022         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1023         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1024         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1025         g_pickup_healthmega = cvar("g_pickup_healthmega");
1026         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1027         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1028
1029         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1030         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1031
1032     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1033     if(!g_weapon_stay)
1034         g_weapon_stay = cvar("g_weapon_stay");
1035
1036         if not(inWarmupStage)
1037                 game_starttime = time + cvar("g_start_delay");
1038
1039         readplayerstartcvars();
1040 }
1041
1042 //#NO AUTOCVARS END
1043
1044 // Sound functions
1045 string precache_sound (string s) = #19;
1046 float precache_sound_index (string s) = #19;
1047
1048 #define SND_VOLUME      1
1049 #define SND_ATTENUATION 2
1050 #define SND_LARGEENTITY 8
1051 #define SND_LARGESOUND  16
1052
1053 float sound_allowed(float dest, entity e)
1054 {
1055     // sounds from world may always pass
1056     for (;;)
1057     {
1058         if (e.classname == "body")
1059             e = e.enemy;
1060         else if (e.realowner && e.realowner != e)
1061             e = e.realowner;
1062         else if (e.owner && e.owner != e)
1063             e = e.owner;
1064         else
1065             break;
1066     }
1067     // sounds to self may always pass
1068     if (dest == MSG_ONE)
1069         if (e == msg_entity)
1070             return TRUE;
1071     // sounds by players can be removed
1072     if (autocvar_bot_sound_monopoly)
1073         if (IS_REAL_CLIENT(e))
1074             return FALSE;
1075     // anything else may pass
1076     return TRUE;
1077 }
1078
1079 #ifdef COMPAT_XON010_CHANNELS
1080 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1081 void sound(entity e, float chan, string samp, float vol, float atten)
1082 {
1083     if (!sound_allowed(MSG_BROADCAST, e))
1084         return;
1085     builtin_sound(e, chan, samp, vol, atten);
1086 }
1087 #else
1088 #undef sound
1089 void sound(entity e, float chan, string samp, float vol, float atten)
1090 {
1091     if (!sound_allowed(MSG_BROADCAST, e))
1092         return;
1093     sound7(e, chan, samp, vol, atten, 0, 0);
1094 }
1095 #endif
1096
1097 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1098 {
1099     float entno, idx;
1100
1101     if (!sound_allowed(dest, e))
1102         return;
1103
1104     entno = num_for_edict(e);
1105     idx = precache_sound_index(samp);
1106
1107     float sflags;
1108     sflags = 0;
1109
1110     atten = floor(atten * 64);
1111     vol = floor(vol * 255);
1112
1113     if (vol != 255)
1114         sflags |= SND_VOLUME;
1115     if (atten != 64)
1116         sflags |= SND_ATTENUATION;
1117     if (entno >= 8192 || chan < 0 || chan > 7)
1118         sflags |= SND_LARGEENTITY;
1119     if (idx >= 256)
1120         sflags |= SND_LARGESOUND;
1121
1122     WriteByte(dest, SVC_SOUND);
1123     WriteByte(dest, sflags);
1124     if (sflags & SND_VOLUME)
1125         WriteByte(dest, vol);
1126     if (sflags & SND_ATTENUATION)
1127         WriteByte(dest, atten);
1128     if (sflags & SND_LARGEENTITY)
1129     {
1130         WriteShort(dest, entno);
1131         WriteByte(dest, chan);
1132     }
1133     else
1134     {
1135         WriteShort(dest, entno * 8 + chan);
1136     }
1137     if (sflags & SND_LARGESOUND)
1138         WriteShort(dest, idx);
1139     else
1140         WriteByte(dest, idx);
1141
1142     WriteCoord(dest, o_x);
1143     WriteCoord(dest, o_y);
1144     WriteCoord(dest, o_z);
1145 }
1146 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1147 {
1148     vector o;
1149
1150     if (!sound_allowed(dest, e))
1151         return;
1152
1153     o = e.origin + 0.5 * (e.mins + e.maxs);
1154     soundtoat(dest, e, o, chan, samp, vol, atten);
1155 }
1156 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1157 {
1158     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1159 }
1160 void stopsoundto(float dest, entity e, float chan)
1161 {
1162     float entno;
1163
1164     if (!sound_allowed(dest, e))
1165         return;
1166
1167     entno = num_for_edict(e);
1168
1169     if (entno >= 8192 || chan < 0 || chan > 7)
1170     {
1171         float idx, sflags;
1172         idx = precache_sound_index("misc/null.wav");
1173         sflags = SND_LARGEENTITY;
1174         if (idx >= 256)
1175             sflags |= SND_LARGESOUND;
1176         WriteByte(dest, SVC_SOUND);
1177         WriteByte(dest, sflags);
1178         WriteShort(dest, entno);
1179         WriteByte(dest, chan);
1180         if (sflags & SND_LARGESOUND)
1181             WriteShort(dest, idx);
1182         else
1183             WriteByte(dest, idx);
1184         WriteCoord(dest, e.origin_x);
1185         WriteCoord(dest, e.origin_y);
1186         WriteCoord(dest, e.origin_z);
1187     }
1188     else
1189     {
1190         WriteByte(dest, SVC_STOPSOUND);
1191         WriteShort(dest, entno * 8 + chan);
1192     }
1193 }
1194 void stopsound(entity e, float chan)
1195 {
1196     if (!sound_allowed(MSG_BROADCAST, e))
1197         return;
1198
1199     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1200     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1201 }
1202
1203 void play2(entity e, string filename)
1204 {
1205     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1206     msg_entity = e;
1207     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1208 }
1209
1210 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1211 .float spamtime;
1212 float spamsound(entity e, float chan, string samp, float vol, float atten)
1213 {
1214     if (!sound_allowed(MSG_BROADCAST, e))
1215         return FALSE;
1216
1217     if (time > e.spamtime)
1218     {
1219         e.spamtime = time;
1220         sound(e, chan, samp, vol, atten);
1221         return TRUE;
1222     }
1223     return FALSE;
1224 }
1225
1226 void play2team(float t, string filename)
1227 {
1228     entity head;
1229
1230     if (autocvar_bot_sound_monopoly)
1231         return;
1232
1233     FOR_EACH_REALPLAYER(head)
1234     {
1235         if (head.team == t)
1236             play2(head, filename);
1237     }
1238 }
1239
1240 void play2all(string samp)
1241 {
1242     if (autocvar_bot_sound_monopoly)
1243         return;
1244
1245     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1246 }
1247
1248 void PrecachePlayerSounds(string f);
1249 void precache_playermodel(string m)
1250 {
1251         float globhandle, i, n;
1252         string f;
1253
1254         if(substring(m, -9,5) == "_lod1")
1255                 return;
1256         if(substring(m, -9,5) == "_lod2")
1257                 return;
1258         precache_model(m);
1259         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1260         if(fexists(f))
1261                 precache_model(f);
1262         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1263         if(fexists(f))
1264                 precache_model(f);
1265
1266         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1267         if (globhandle < 0)
1268                 return;
1269         n = search_getsize(globhandle);
1270         for (i = 0; i < n; ++i)
1271         {
1272                 //print(search_getfilename(globhandle, i), "\n");
1273                 f = search_getfilename(globhandle, i);
1274                 PrecachePlayerSounds(f);
1275         }
1276         search_end(globhandle);
1277 }
1278 void precache_all_playermodels(string pattern)
1279 {
1280         float globhandle, i, n;
1281         string f;
1282
1283         globhandle = search_begin(pattern, TRUE, FALSE);
1284         if (globhandle < 0)
1285                 return;
1286         n = search_getsize(globhandle);
1287         for (i = 0; i < n; ++i)
1288         {
1289                 //print(search_getfilename(globhandle, i), "\n");
1290                 f = search_getfilename(globhandle, i);
1291                 precache_playermodel(f);
1292         }
1293         search_end(globhandle);
1294 }
1295
1296 void precache()
1297 {
1298     // gamemode related things
1299     precache_model ("models/misc/chatbubble.spr");
1300
1301 #ifdef TTURRETS_ENABLED
1302     if (autocvar_g_turrets)
1303         turrets_precash();
1304 #endif
1305
1306     // Precache all player models if desired
1307     if (autocvar_sv_precacheplayermodels)
1308     {
1309         PrecachePlayerSounds("sound/player/default.sounds");
1310         precache_all_playermodels("models/player/*.zym");
1311         precache_all_playermodels("models/player/*.dpm");
1312         precache_all_playermodels("models/player/*.md3");
1313         precache_all_playermodels("models/player/*.psk");
1314         precache_all_playermodels("models/player/*.iqm");
1315     }
1316
1317     if (autocvar_sv_defaultcharacter)
1318     {
1319         string s;
1320         s = autocvar_sv_defaultplayermodel_red;
1321         if (s != "")
1322             precache_playermodel(s);
1323         s = autocvar_sv_defaultplayermodel_blue;
1324         if (s != "")
1325             precache_playermodel(s);
1326         s = autocvar_sv_defaultplayermodel_yellow;
1327         if (s != "")
1328             precache_playermodel(s);
1329         s = autocvar_sv_defaultplayermodel_pink;
1330         if (s != "")
1331             precache_playermodel(s);
1332         s = autocvar_sv_defaultplayermodel;
1333         if (s != "")
1334             precache_playermodel(s);
1335     }
1336
1337     if (g_footsteps)
1338     {
1339         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1340         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1341     }
1342
1343     // gore and miscellaneous sounds
1344     //precache_sound ("misc/h2ohit.wav");
1345     precache_model ("models/hook.md3");
1346     precache_sound ("misc/armorimpact.wav");
1347     precache_sound ("misc/bodyimpact1.wav");
1348     precache_sound ("misc/bodyimpact2.wav");
1349     precache_sound ("misc/gib.wav");
1350     precache_sound ("misc/gib_splat01.wav");
1351     precache_sound ("misc/gib_splat02.wav");
1352     precache_sound ("misc/gib_splat03.wav");
1353     precache_sound ("misc/gib_splat04.wav");
1354     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1355     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1356     precache_sound ("misc/null.wav");
1357     precache_sound ("misc/spawn.wav");
1358     precache_sound ("misc/talk.wav");
1359     precache_sound ("misc/teleport.wav");
1360     precache_sound ("misc/poweroff.wav");
1361     precache_sound ("player/lava.wav");
1362     precache_sound ("player/slime.wav");
1363
1364     precache_model ("models/sprites/0.spr32");
1365     precache_model ("models/sprites/1.spr32");
1366     precache_model ("models/sprites/2.spr32");
1367     precache_model ("models/sprites/3.spr32");
1368     precache_model ("models/sprites/4.spr32");
1369     precache_model ("models/sprites/5.spr32");
1370     precache_model ("models/sprites/6.spr32");
1371     precache_model ("models/sprites/7.spr32");
1372     precache_model ("models/sprites/8.spr32");
1373     precache_model ("models/sprites/9.spr32");
1374     precache_model ("models/sprites/10.spr32");
1375
1376     // common weapon precaches
1377         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1378     precache_sound ("weapons/weapon_switch.wav");
1379     precache_sound ("weapons/weaponpickup.wav");
1380     precache_sound ("weapons/unavailable.wav");
1381     precache_sound ("weapons/dryfire.wav");
1382     if (g_grappling_hook)
1383     {
1384         precache_sound ("weapons/hook_fire.wav"); // hook
1385         precache_sound ("weapons/hook_impact.wav"); // hook
1386     }
1387
1388     if(autocvar_sv_precacheweapons)
1389     {
1390         //precache weapon models/sounds
1391         float wep;
1392         wep = WEP_FIRST;
1393         while (wep <= WEP_LAST)
1394         {
1395             weapon_action(wep, WR_PRECACHE);
1396             wep = wep + 1;
1397         }
1398     }
1399
1400     precache_model("models/elaser.mdl");
1401     precache_model("models/laser.mdl");
1402     precache_model("models/ebomb.mdl");
1403
1404 #if 0
1405     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1406
1407     if (!self.noise && self.music) // quake 3 uses the music field
1408         self.noise = self.music;
1409
1410     // plays music for the level if there is any
1411     if (self.noise)
1412     {
1413         precache_sound (self.noise);
1414         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1415     }
1416 #endif
1417 }
1418
1419 // WARNING: this kills the trace globals
1420 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1421 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1422
1423 #define INITPRIO_FIRST              0
1424 #define INITPRIO_GAMETYPE           0
1425 #define INITPRIO_GAMETYPE_FALLBACK  1
1426 #define INITPRIO_FINDTARGET        10
1427 #define INITPRIO_DROPTOFLOOR       20
1428 #define INITPRIO_SETLOCATION       90
1429 #define INITPRIO_LINKDOORS         91
1430 #define INITPRIO_LAST              99
1431
1432 .void(void) initialize_entity;
1433 .float initialize_entity_order;
1434 .entity initialize_entity_next;
1435 entity initialize_entity_first;
1436
1437 void make_safe_for_remove(entity e)
1438 {
1439     if (e.initialize_entity)
1440     {
1441         entity ent, prev = world;
1442         for (ent = initialize_entity_first; ent; )
1443         {
1444             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1445             {
1446                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1447                 // skip it in linked list
1448                 if (prev)
1449                 {
1450                     prev.initialize_entity_next = ent.initialize_entity_next;
1451                     ent = prev.initialize_entity_next;
1452                 }
1453                 else
1454                 {
1455                     initialize_entity_first = ent.initialize_entity_next;
1456                     ent = initialize_entity_first;
1457                 }
1458             }
1459             else
1460             {
1461                 prev = ent;
1462                 ent = ent.initialize_entity_next;
1463             }
1464         }
1465     }
1466 }
1467
1468 void objerror(string s)
1469 {
1470     make_safe_for_remove(self);
1471     builtin_objerror(s);
1472 }
1473
1474 .float remove_except_protected_forbidden;
1475 void remove_except_protected(entity e)
1476 {
1477         if(e.remove_except_protected_forbidden)
1478                 error("not allowed to remove this at this point");
1479         builtin_remove(e);
1480 }
1481
1482 void remove_unsafely(entity e)
1483 {
1484     if(e.classname == "spike")
1485         error("Removing spikes is forbidden (crylink bug), please report");
1486     builtin_remove(e);
1487 }
1488
1489 void remove_safely(entity e)
1490 {
1491     make_safe_for_remove(e);
1492     builtin_remove(e);
1493 }
1494
1495 void InitializeEntity(entity e, void(void) func, float order)
1496 {
1497     entity prev, cur;
1498
1499     if (!e || e.initialize_entity)
1500     {
1501         // make a proxy initializer entity
1502         entity e_old;
1503         e_old = e;
1504         e = spawn();
1505         e.classname = "initialize_entity";
1506         e.enemy = e_old;
1507     }
1508
1509     e.initialize_entity = func;
1510     e.initialize_entity_order = order;
1511
1512     cur = initialize_entity_first;
1513     prev = world;
1514     for (;;)
1515     {
1516         if (!cur || cur.initialize_entity_order > order)
1517         {
1518             // insert between prev and cur
1519             if (prev)
1520                 prev.initialize_entity_next = e;
1521             else
1522                 initialize_entity_first = e;
1523             e.initialize_entity_next = cur;
1524             return;
1525         }
1526         prev = cur;
1527         cur = cur.initialize_entity_next;
1528     }
1529 }
1530 void InitializeEntitiesRun()
1531 {
1532     entity startoflist;
1533     startoflist = initialize_entity_first;
1534     initialize_entity_first = world;
1535     remove = remove_except_protected;
1536     for (self = startoflist; self; self = self.initialize_entity_next)
1537     {
1538         self.remove_except_protected_forbidden = 1;
1539     }
1540     for (self = startoflist; self; )
1541     {
1542         entity e;
1543         var void(void) func;
1544         e = self.initialize_entity_next;
1545         func = self.initialize_entity;
1546         self.initialize_entity_order = 0;
1547         self.initialize_entity = func_null;
1548         self.initialize_entity_next = world;
1549         self.remove_except_protected_forbidden = 0;
1550         if (self.classname == "initialize_entity")
1551         {
1552             entity e_old;
1553             e_old = self.enemy;
1554             builtin_remove(self);
1555             self = e_old;
1556         }
1557         //dprint("Delayed initialization: ", self.classname, "\n");
1558         if(func)
1559             func();
1560         else
1561         {
1562             eprint(self);
1563             backtrace(strcat("Null function in: ", self.classname, "\n"));
1564         }
1565         self = e;
1566     }
1567     remove = remove_unsafely;
1568 }
1569
1570 .float uncustomizeentityforclient_set;
1571 .void(void) uncustomizeentityforclient;
1572 void UncustomizeEntitiesRun()
1573 {
1574     entity oldself;
1575     oldself = self;
1576     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1577         self.uncustomizeentityforclient();
1578     self = oldself;
1579 }
1580 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1581 {
1582     e.customizeentityforclient = customizer;
1583     e.uncustomizeentityforclient = uncustomizer;
1584     e.uncustomizeentityforclient_set = !!uncustomizer;
1585 }
1586
1587 .float nottargeted;
1588 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1589
1590 void() SUB_Remove;
1591 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1592 {
1593     vector mi, ma;
1594
1595     if (e.classname == "")
1596         e.classname = "net_linked";
1597
1598     if (e.model == "" || self.modelindex == 0)
1599     {
1600         mi = e.mins;
1601         ma = e.maxs;
1602         setmodel(e, "null");
1603         setsize(e, mi, ma);
1604     }
1605
1606     e.SendEntity = sendfunc;
1607     e.SendFlags = 0xFFFFFF;
1608
1609     if (!docull)
1610         e.effects |= EF_NODEPTHTEST;
1611
1612     if (dt)
1613     {
1614         e.nextthink = time + dt;
1615         e.think = SUB_Remove;
1616     }
1617 }
1618
1619 void adaptor_think2touch()
1620 {
1621     entity o;
1622     o = other;
1623     other = world;
1624     self.touch();
1625     other = o;
1626 }
1627
1628 void adaptor_think2use()
1629 {
1630     entity o, a;
1631     o = other;
1632     a = activator;
1633     activator = world;
1634     other = world;
1635     self.use();
1636     other = o;
1637     activator = a;
1638 }
1639
1640 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1641 {
1642         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1643                 self.projectiledeathtype |= HITTYPE_SPLASH;
1644         adaptor_think2use();
1645 }
1646
1647 // deferred dropping
1648 void DropToFloor_Handler()
1649 {
1650     builtin_droptofloor();
1651     self.dropped_origin = self.origin;
1652 }
1653
1654 void droptofloor()
1655 {
1656     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1657 }
1658
1659
1660
1661 float trace_hits_box_a0, trace_hits_box_a1;
1662
1663 float trace_hits_box_1d(float end, float thmi, float thma)
1664 {
1665     if (end == 0)
1666     {
1667         // just check if x is in range
1668         if (0 < thmi)
1669             return FALSE;
1670         if (0 > thma)
1671             return FALSE;
1672     }
1673     else
1674     {
1675         // do the trace with respect to x
1676         // 0 -> end has to stay in thmi -> thma
1677         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1678         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1679         if (trace_hits_box_a0 > trace_hits_box_a1)
1680             return FALSE;
1681     }
1682     return TRUE;
1683 }
1684
1685 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1686 {
1687     end -= start;
1688     thmi -= start;
1689     thma -= start;
1690     // now it is a trace from 0 to end
1691
1692     trace_hits_box_a0 = 0;
1693     trace_hits_box_a1 = 1;
1694
1695     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1696         return FALSE;
1697     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1698         return FALSE;
1699     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1700         return FALSE;
1701
1702     return TRUE;
1703 }
1704
1705 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1706 {
1707     return trace_hits_box(start, end, thmi - ma, thma - mi);
1708 }
1709
1710 float SUB_NoImpactCheck()
1711 {
1712         // zero hitcontents = this is not the real impact, but either the
1713         // mirror-impact of something hitting the projectile instead of the
1714         // projectile hitting the something, or a touchareagrid one. Neither of
1715         // these stop the projectile from moving, so...
1716         if(trace_dphitcontents == 0)
1717         {
1718                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1719                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1720                 checkclient();
1721         }
1722     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1723         return 1;
1724     if (other == world && self.size != '0 0 0')
1725     {
1726         vector tic;
1727         tic = self.velocity * sys_frametime;
1728         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1729         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1730         if (trace_fraction >= 1)
1731         {
1732             dprint("Odd... did not hit...?\n");
1733         }
1734         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1735         {
1736             dprint("Detected and prevented the sky-grapple bug.\n");
1737             return 1;
1738         }
1739     }
1740
1741     return 0;
1742 }
1743
1744 #define SUB_OwnerCheck() (other && (other == self.owner))
1745
1746 void RemoveGrapplingHook(entity pl);
1747 void W_Crylink_Dequeue(entity e);
1748 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1749 {
1750         if(SUB_OwnerCheck())
1751                 return TRUE;
1752         if(SUB_NoImpactCheck())
1753         {
1754                 if(self.classname == "grapplinghook")
1755                         RemoveGrapplingHook(self.realowner);
1756                 else if(self.classname == "spike")
1757                 {
1758                         W_Crylink_Dequeue(self);
1759                         remove(self);
1760                 }
1761                 else
1762                         remove(self);
1763                 return TRUE;
1764         }
1765         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1766                 UpdateCSQCProjectile(self);
1767         return FALSE;
1768 }
1769 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1770
1771 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1772 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1773
1774 void URI_Get_Callback(float id, float status, string data)
1775 {
1776         if(url_URI_Get_Callback(id, status, data))
1777         {
1778                 // handled
1779         }
1780         else if (id == URI_GET_DISCARD)
1781         {
1782                 // discard
1783         }
1784         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1785         {
1786                 // sv_cmd curl
1787                 Curl_URI_Get_Callback(id, status, data);
1788         }
1789         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1790         {
1791                 // online ban list
1792                 OnlineBanList_URI_Get_Callback(id, status, data);
1793         }
1794         else
1795         {
1796                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1797         }
1798 }
1799
1800 string uid2name(string myuid) {
1801         string s;
1802         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1803
1804         // FIXME remove this later after 0.6 release
1805         // convert old style broken records to correct style
1806         if(s == "")
1807         {
1808                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1809                 if(s != "")
1810                 {
1811                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1812                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1813                 }
1814         }
1815
1816         if(s == "")
1817                 s = "^1Unregistered Player";
1818         return s;
1819 }
1820
1821 float race_readTime(string map, float pos)
1822 {
1823         string rr;
1824         if(g_cts)
1825                 rr = CTS_RECORD;
1826         else
1827                 rr = RACE_RECORD;
1828
1829         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1830 }
1831
1832 string race_readUID(string map, float pos)
1833 {
1834         string rr;
1835         if(g_cts)
1836                 rr = CTS_RECORD;
1837         else
1838                 rr = RACE_RECORD;
1839
1840         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1841 }
1842
1843 float race_readPos(string map, float t) {
1844         float i;
1845         for (i = 1; i <= RANKINGS_CNT; ++i)
1846                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1847                         return i;
1848
1849         return 0; // pos is zero if unranked
1850 }
1851
1852 void race_writeTime(string map, float t, string myuid)
1853 {
1854         string rr;
1855         if(g_cts)
1856                 rr = CTS_RECORD;
1857         else
1858                 rr = RACE_RECORD;
1859
1860         float newpos;
1861         newpos = race_readPos(map, t);
1862
1863         float i, prevpos = 0;
1864         for(i = 1; i <= RANKINGS_CNT; ++i)
1865         {
1866                 if(race_readUID(map, i) == myuid)
1867                         prevpos = i;
1868         }
1869         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1870                 for (i = prevpos; i > newpos; --i) {
1871                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1872                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1873                 }
1874         } else { // player has no ranked record yet
1875                 for (i = RANKINGS_CNT; i > newpos; --i) {
1876                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1877                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1878                 }
1879         }
1880
1881         // store new time itself
1882         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1883         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1884 }
1885
1886 string race_readName(string map, float pos)
1887 {
1888         string rr;
1889         if(g_cts)
1890                 rr = CTS_RECORD;
1891         else
1892                 rr = RACE_RECORD;
1893
1894         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1895 }
1896
1897 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1898 {
1899     float m, i;
1900     vector start, org, delta, end, enddown, mstart;
1901     entity sp;
1902
1903     m = e.dphitcontentsmask;
1904     e.dphitcontentsmask = goodcontents | badcontents;
1905
1906     org = world.mins;
1907     delta = world.maxs - world.mins;
1908
1909     start = end = org;
1910
1911     for (i = 0; i < attempts; ++i)
1912     {
1913         start_x = org_x + random() * delta_x;
1914         start_y = org_y + random() * delta_y;
1915         start_z = org_z + random() * delta_z;
1916
1917         // rule 1: start inside world bounds, and outside
1918         // solid, and don't start from somewhere where you can
1919         // fall down to evil
1920         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1921         if (trace_fraction >= 1)
1922             continue;
1923         if (trace_startsolid)
1924             continue;
1925         if (trace_dphitcontents & badcontents)
1926             continue;
1927         if (trace_dphitq3surfaceflags & badsurfaceflags)
1928             continue;
1929
1930         // rule 2: if we are too high, lower the point
1931         if (trace_fraction * delta_z > maxaboveground)
1932             start = trace_endpos + '0 0 1' * maxaboveground;
1933         enddown = trace_endpos;
1934
1935         // rule 3: make sure we aren't outside the map. This only works
1936         // for somewhat well formed maps. A good rule of thumb is that
1937         // the map should have a convex outside hull.
1938         // these can be traceLINES as we already verified the starting box
1939         mstart = start + 0.5 * (e.mins + e.maxs);
1940         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1941         if (trace_fraction >= 1)
1942             continue;
1943         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1944         if (trace_fraction >= 1)
1945             continue;
1946         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1947         if (trace_fraction >= 1)
1948             continue;
1949         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1950         if (trace_fraction >= 1)
1951             continue;
1952         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1953         if (trace_fraction >= 1)
1954             continue;
1955
1956         // rule 4: we must "see" some spawnpoint
1957         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1958                 if(checkpvs(mstart, sp))
1959                         break;
1960         if(!sp)
1961         {
1962                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1963                         if(checkpvs(mstart, sp))
1964                                 break;
1965                 if(!sp)
1966                         continue;
1967         }
1968
1969         // find a random vector to "look at"
1970         end_x = org_x + random() * delta_x;
1971         end_y = org_y + random() * delta_y;
1972         end_z = org_z + random() * delta_z;
1973         end = start + normalize(end - start) * vlen(delta);
1974
1975         // rule 4: start TO end must not be too short
1976         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1977         if (trace_startsolid)
1978             continue;
1979         if (trace_fraction < minviewdistance / vlen(delta))
1980             continue;
1981
1982         // rule 5: don't want to look at sky
1983         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1984             continue;
1985
1986         // rule 6: we must not end up in trigger_hurt
1987         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1988             continue;
1989
1990         break;
1991     }
1992
1993     e.dphitcontentsmask = m;
1994
1995     if (i < attempts)
1996     {
1997         setorigin(e, start);
1998         e.angles = vectoangles(end - start);
1999         dprint("Needed ", ftos(i + 1), " attempts\n");
2000         return TRUE;
2001     }
2002     else
2003         return FALSE;
2004 }
2005
2006 float zcurveparticles_effectno;
2007 vector zcurveparticles_start;
2008 float zcurveparticles_spd;
2009
2010 void endzcurveparticles()
2011 {
2012         if(zcurveparticles_effectno)
2013         {
2014                 // terminator
2015                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2016         }
2017         zcurveparticles_effectno = 0;
2018 }
2019
2020 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2021 {
2022         spd = bound(0, floor(spd / 16), 32767);
2023         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2024         {
2025                 endzcurveparticles();
2026                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2027                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2028                 WriteShort(MSG_BROADCAST, effectno);
2029                 WriteCoord(MSG_BROADCAST, start_x);
2030                 WriteCoord(MSG_BROADCAST, start_y);
2031                 WriteCoord(MSG_BROADCAST, start_z);
2032                 zcurveparticles_effectno = effectno;
2033                 zcurveparticles_start = start;
2034         }
2035         else
2036                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2037         WriteCoord(MSG_BROADCAST, end_x);
2038         WriteCoord(MSG_BROADCAST, end_y);
2039         WriteCoord(MSG_BROADCAST, end_z);
2040         WriteCoord(MSG_BROADCAST, end_dz);
2041         zcurveparticles_spd = spd;
2042 }
2043
2044 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2045 {
2046         float end_dz;
2047         vector vecxy, velxy;
2048
2049         vecxy = end - start;
2050         vecxy_z = 0;
2051         velxy = vel;
2052         velxy_z = 0;
2053
2054         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2055         {
2056                 endzcurveparticles();
2057                 trailparticles(world, effectno, start, end);
2058                 return;
2059         }
2060
2061         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2062         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2063 }
2064
2065 void write_recordmarker(entity pl, float tstart, float dt)
2066 {
2067     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2068
2069     // also write a marker into demo files for demotc-race-record-extractor to find
2070     stuffcmd(pl,
2071              strcat(
2072                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2073                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2074 }
2075
2076 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2077 {
2078         switch(algn)
2079         {
2080                 default:
2081                 case 3: // right
2082                         break;
2083
2084                 case 4: // left
2085                         vecs_y = -vecs_y;
2086                         break;
2087
2088                 case 1:
2089                         if(allowcenter) // 2: allow center handedness
2090                         {
2091                                 // center
2092                                 vecs_y = 0;
2093                                 vecs_z -= 2;
2094                         }
2095                         else
2096                         {
2097                                 // right
2098                         }
2099                         break;
2100
2101                 case 2:
2102                         if(allowcenter) // 2: allow center handedness
2103                         {
2104                                 // center
2105                                 vecs_y = 0;
2106                                 vecs_z -= 2;
2107                         }
2108                         else
2109                         {
2110                                 // left
2111                                 vecs_y = -vecs_y;
2112                         }
2113                         break;
2114         }
2115         return vecs;
2116 }
2117
2118 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2119 {
2120         string s;
2121         vector v;
2122
2123         if (autocvar_g_shootfromeye)
2124         {
2125                 if (visual)
2126                 {
2127                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2128                         else { vecs_y = 0; vecs_z -= 2; }
2129                 }
2130                 else
2131                 {
2132                         vecs_y = 0;
2133                         vecs_z = 0;
2134                 }
2135         }
2136         else if (autocvar_g_shootfromcenter)
2137         {
2138                 vecs_y = 0;
2139                 vecs_z -= 2;
2140         }
2141         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2142         {
2143                 v = stov(s);
2144                 if (y_is_right)
2145                         v_y = -v_y;
2146                 if (v_x != 0)
2147                         vecs_x = v_x;
2148                 vecs_y = v_y;
2149                 vecs_z = v_z;
2150         }
2151         else if (autocvar_g_shootfromclient)
2152         {
2153                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2154         }
2155         return vecs;
2156 }
2157
2158 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2159 {
2160         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2161 }
2162
2163
2164 void attach_sameorigin(entity e, entity to, string tag)
2165 {
2166     vector org, t_forward, t_left, t_up, e_forward, e_up;
2167     float tagscale;
2168
2169     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2170     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2171     t_forward = v_forward * tagscale;
2172     t_left = v_right * -tagscale;
2173     t_up = v_up * tagscale;
2174
2175     e.origin_x = org * t_forward;
2176     e.origin_y = org * t_left;
2177     e.origin_z = org * t_up;
2178
2179     // current forward and up directions
2180     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2181                 e.angles = AnglesTransform_FromVAngles(e.angles);
2182         else
2183                 e.angles = AnglesTransform_FromAngles(e.angles);
2184     fixedmakevectors(e.angles);
2185
2186     // untransform forward, up!
2187     e_forward_x = v_forward * t_forward;
2188     e_forward_y = v_forward * t_left;
2189     e_forward_z = v_forward * t_up;
2190     e_up_x = v_up * t_forward;
2191     e_up_y = v_up * t_left;
2192     e_up_z = v_up * t_up;
2193
2194     e.angles = fixedvectoangles2(e_forward, e_up);
2195     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2196                 e.angles = AnglesTransform_ToVAngles(e.angles);
2197         else
2198                 e.angles = AnglesTransform_ToAngles(e.angles);
2199
2200     setattachment(e, to, tag);
2201     setorigin(e, e.origin);
2202 }
2203
2204 void detach_sameorigin(entity e)
2205 {
2206     vector org;
2207     org = gettaginfo(e, 0);
2208     e.angles = fixedvectoangles2(v_forward, v_up);
2209     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2210                 e.angles = AnglesTransform_ToVAngles(e.angles);
2211         else
2212                 e.angles = AnglesTransform_ToAngles(e.angles);
2213     setorigin(e, org);
2214     setattachment(e, world, "");
2215     setorigin(e, e.origin);
2216 }
2217
2218 void follow_sameorigin(entity e, entity to)
2219 {
2220     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2221     e.aiment = to; // make the hole follow bmodel
2222     e.punchangle = to.angles; // the original angles of bmodel
2223     e.view_ofs = e.origin - to.origin; // relative origin
2224     e.v_angle = e.angles - to.angles; // relative angles
2225 }
2226
2227 void unfollow_sameorigin(entity e)
2228 {
2229     e.movetype = MOVETYPE_NONE;
2230 }
2231
2232 entity gettaginfo_relative_ent;
2233 vector gettaginfo_relative(entity e, float tag)
2234 {
2235     if (!gettaginfo_relative_ent)
2236     {
2237         gettaginfo_relative_ent = spawn();
2238         gettaginfo_relative_ent.effects = EF_NODRAW;
2239     }
2240     gettaginfo_relative_ent.model = e.model;
2241     gettaginfo_relative_ent.modelindex = e.modelindex;
2242     gettaginfo_relative_ent.frame = e.frame;
2243     return gettaginfo(gettaginfo_relative_ent, tag);
2244 }
2245
2246 .float scale2;
2247
2248 float modeleffect_SendEntity(entity to, float sf)
2249 {
2250         float f;
2251         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2252
2253         f = 0;
2254         if(self.velocity != '0 0 0')
2255                 f |= 1;
2256         if(self.angles != '0 0 0')
2257                 f |= 2;
2258         if(self.avelocity != '0 0 0')
2259                 f |= 4;
2260
2261         WriteByte(MSG_ENTITY, f);
2262         WriteShort(MSG_ENTITY, self.modelindex);
2263         WriteByte(MSG_ENTITY, self.skin);
2264         WriteByte(MSG_ENTITY, self.frame);
2265         WriteCoord(MSG_ENTITY, self.origin_x);
2266         WriteCoord(MSG_ENTITY, self.origin_y);
2267         WriteCoord(MSG_ENTITY, self.origin_z);
2268         if(f & 1)
2269         {
2270                 WriteCoord(MSG_ENTITY, self.velocity_x);
2271                 WriteCoord(MSG_ENTITY, self.velocity_y);
2272                 WriteCoord(MSG_ENTITY, self.velocity_z);
2273         }
2274         if(f & 2)
2275         {
2276                 WriteCoord(MSG_ENTITY, self.angles_x);
2277                 WriteCoord(MSG_ENTITY, self.angles_y);
2278                 WriteCoord(MSG_ENTITY, self.angles_z);
2279         }
2280         if(f & 4)
2281         {
2282                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2283                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2284                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2285         }
2286         WriteShort(MSG_ENTITY, self.scale * 256.0);
2287         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2288         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2289         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2290         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2291
2292         return TRUE;
2293 }
2294
2295 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2296 {
2297         entity e;
2298         float sz;
2299         e = spawn();
2300         e.classname = "modeleffect";
2301         setmodel(e, m);
2302         e.frame = f;
2303         setorigin(e, o);
2304         e.velocity = v;
2305         e.angles = ang;
2306         e.avelocity = angv;
2307         e.alpha = a;
2308         e.teleport_time = t1;
2309         e.fade_time = t2;
2310         e.skin = s;
2311         if(s0 >= 0)
2312                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2313         else
2314                 e.scale = -s0;
2315         if(s2 >= 0)
2316                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2317         else
2318                 e.scale2 = -s2;
2319         sz = max(e.scale, e.scale2);
2320         setsize(e, e.mins * sz, e.maxs * sz);
2321         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2322 }
2323
2324 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2325 {
2326         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2327 }
2328
2329 float randombit(float bits)
2330 {
2331         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2332                 return bits;
2333
2334         float n, f, b, r;
2335
2336         r = random();
2337         b = 0;
2338         n = 0;
2339
2340         for(f = 1; f <= bits; f *= 2)
2341         {
2342                 if(bits & f)
2343                 {
2344                         ++n;
2345                         r *= n;
2346                         if(r <= 1)
2347                                 b = f;
2348                         else
2349                                 r = (r - 1) / (n - 1);
2350                 }
2351         }
2352
2353         return b;
2354 }
2355
2356 float randombits(float bits, float k, float error_return)
2357 {
2358         float r;
2359         r = 0;
2360         while(k > 0 && bits != r)
2361         {
2362                 r += randombit(bits - r);
2363                 --k;
2364         }
2365         if(error_return)
2366                 if(k > 0)
2367                         return -1; // all
2368         return r;
2369 }
2370
2371 void randombit_test(float bits, float iter)
2372 {
2373         while(iter > 0)
2374         {
2375                 print(ftos(randombit(bits)), "\n");
2376                 --iter;
2377         }
2378 }
2379
2380 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2381 {
2382         if(halflifedist > 0)
2383                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2384         else if(halflifedist < 0)
2385                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2386         else
2387                 return 1;
2388 }
2389
2390
2391
2392
2393 #ifdef RELEASE
2394 #define cvar_string_normal builtin_cvar_string
2395 #define cvar_normal builtin_cvar
2396 #else
2397 string cvar_string_normal(string n)
2398 {
2399         if not(cvar_type(n) & 1)
2400                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2401         return builtin_cvar_string(n);
2402 }
2403
2404 float cvar_normal(string n)
2405 {
2406         return stof(cvar_string_normal(n));
2407 }
2408 #endif
2409 #define cvar_set_normal builtin_cvar_set
2410
2411 void defer_think()
2412 {
2413     entity oself;
2414
2415     oself           = self;
2416     self            = self.owner;
2417     oself.think     = SUB_Remove;
2418     oself.nextthink = time;
2419
2420     oself.use();
2421 }
2422
2423 /*
2424     Execute func() after time + fdelay.
2425     self when func is executed = self when defer is called
2426 */
2427 void defer(float fdelay, void() func)
2428 {
2429     entity e;
2430
2431     e           = spawn();
2432     e.owner     = self;
2433     e.use       = func;
2434     e.think     = defer_think;
2435     e.nextthink = time + fdelay;
2436 }
2437
2438 .string aiment_classname;
2439 .float aiment_deadflag;
2440 void SetMovetypeFollow(entity ent, entity e)
2441 {
2442         // FIXME this may not be warpzone aware
2443         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2444         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2445         ent.aiment = e; // make the hole follow bmodel
2446         ent.punchangle = e.angles; // the original angles of bmodel
2447         ent.view_ofs = ent.origin - e.origin; // relative origin
2448         ent.v_angle = ent.angles - e.angles; // relative angles
2449         ent.aiment_classname = strzone(e.classname);
2450         ent.aiment_deadflag = e.deadflag;
2451 }
2452 void UnsetMovetypeFollow(entity ent)
2453 {
2454         ent.movetype = MOVETYPE_FLY;
2455         PROJECTILE_MAKETRIGGER(ent);
2456         ent.aiment = world;
2457 }
2458 float LostMovetypeFollow(entity ent)
2459 {
2460 /*
2461         if(ent.movetype != MOVETYPE_FOLLOW)
2462                 if(ent.aiment)
2463                         error("???");
2464 */
2465         if(ent.aiment)
2466         {
2467                 if(ent.aiment.classname != ent.aiment_classname)
2468                         return 1;
2469                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2470                         return 1;
2471         }
2472         return 0;
2473 }
2474
2475 float isPushable(entity e)
2476 {
2477         if(e.iscreature)
2478                 return TRUE;
2479         if(e.pushable)
2480                 return TRUE;
2481         switch(e.classname)
2482         {
2483                 case "body":
2484                 case "droppedweapon":
2485                 case "keepawayball":
2486                 case "nexball_basketball":
2487                 case "nexball_football":
2488                         return TRUE;
2489                 case "bullet": // antilagged bullets can't hit this either
2490                         return FALSE;
2491         }
2492         if (e.projectiledeathtype)
2493                 return TRUE;
2494         return FALSE;
2495 }