qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = WEP_NAME(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else if (self.items & IT_PLASMA) replacement = "plasma";
 365                         else replacement = "batteries"; // ;)
 366                 } else if (escape == "x") {
 367                         replacement = cursor_ent.netname;
 368                         if (replacement == "" || !cursor_ent)
 369                                 replacement = "nothing";
 370                 } else if (escape == "s")
 371                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 372                 else if (escape == "S")
 373                         replacement = ftos(vlen(self.velocity));
 374
 375                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 376                 p = p + strlen(replacement);
 377         }
 378         return msg;
 379 }
 380
 381 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 382         return (value == 0) ? FALSE : TRUE;
 383 }
 384
 385 /*
 386 =============
 387 GetCvars
 388 =============
 389 Called with:
 390   0:  sends the request
 391   >0: receives a cvar from name=argv(f) value=argv(f+1)
 392 */
 393 void GetCvars_handleString(string thisname, float f, .string field, string name)
 394 {
 395         if (f < 0)
 396         {
 397                 if (self.field)
 398                         strunzone(self.field);
 399                 self.field = string_null;
 400         }
 401         else if (f > 0)
 402         {
 403                 if (thisname == name)
 404                 {
 405                         if (self.field)
 406                                 strunzone(self.field);
 407                         self.field = strzone(argv(f + 1));
 408                 }
 409         }
 410         else
 411                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 412 }
 413 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 414 {
 415         GetCvars_handleString(thisname, f, field, name);
 416         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 417                 if (thisname == name)
 418                 {
 419                         string s;
 420                         s = func(strcat1(self.field));
 421                         if (s != self.field)
 422                         {
 423                                 strunzone(self.field);
 424                                 self.field = strzone(s);
 425                         }
 426                 }
 427 }
 428 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 429 {
 430         if (f < 0)
 431         {
 432         }
 433         else if (f > 0)
 434         {
 435                 if (thisname == name)
 436                         self.field = stof(argv(f + 1));
 437         }
 438         else
 439                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 440 }
 441 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 442 {
 443         if (f < 0)
 444         {
 445         }
 446         else if (f > 0)
 447         {
 448                 if (thisname == name)
 449                 {
 450                         if(!self.field)
 451                         {
 452                                 self.field = stof(argv(f + 1));
 453                                 if(!self.field)
 454                                         self.field = -1;
 455                         }
 456                 }
 457         }
 458         else
 459         {
 460                 if(!self.field)
 461                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462         }
 463 }
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 493         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 494         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 495         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 507         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 508         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 509         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 511         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 513         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 514
 515         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 516         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 517
 518         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 520         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 521         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 522         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 523
 524         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 525         if (f > 0)
 526         {
 527                 if (s == "cl_weaponpriority")
 528                         self.switchweapon = w_getbestweapon(self);
 529                 if (s == "cl_allow_uidtracking")
 530                         PlayerStats_GameReport_AddPlayer(self);
 531         }
 532 }
 533
 534 // decolorizes and team colors the player name when needed
 535 string playername(entity p)
 536 {
 537     string t;
 538     if (teamplay && !intermission_running && IS_PLAYER(p))
 539     {
 540         t = Team_ColorCode(p.team);
 541         return strcat(t, strdecolorize(p.netname));
 542     }
 543     else
 544         return p.netname;
 545 }
 546
 547 vector randompos(vector m1, vector m2)
 548 {
 549     vector v;
 550     m2 = m2 - m1;
 551     v_x = m2_x * random() + m1_x;
 552     v_y = m2_y * random() + m1_y;
 553     v_z = m2_z * random() + m1_z;
 554     return  v;
 555 }
 556
 557 //#NO AUTOCVARS START
 558
 559 float g_pickup_shells;
 560 float g_pickup_shells_max;
 561 float g_pickup_nails;
 562 float g_pickup_nails_max;
 563 float g_pickup_rockets;
 564 float g_pickup_rockets_max;
 565 float g_pickup_cells;
 566 float g_pickup_cells_max;
 567 float g_pickup_plasma;
 568 float g_pickup_plasma_max;
 569 float g_pickup_fuel;
 570 float g_pickup_fuel_jetpack;
 571 float g_pickup_fuel_max;
 572 float g_pickup_armorsmall;
 573 float g_pickup_armorsmall_max;
 574 float g_pickup_armorsmall_anyway;
 575 float g_pickup_armormedium;
 576 float g_pickup_armormedium_max;
 577 float g_pickup_armormedium_anyway;
 578 float g_pickup_armorbig;
 579 float g_pickup_armorbig_max;
 580 float g_pickup_armorbig_anyway;
 581 float g_pickup_armorlarge;
 582 float g_pickup_armorlarge_max;
 583 float g_pickup_armorlarge_anyway;
 584 float g_pickup_healthsmall;
 585 float g_pickup_healthsmall_max;
 586 float g_pickup_healthsmall_anyway;
 587 float g_pickup_healthmedium;
 588 float g_pickup_healthmedium_max;
 589 float g_pickup_healthmedium_anyway;
 590 float g_pickup_healthlarge;
 591 float g_pickup_healthlarge_max;
 592 float g_pickup_healthlarge_anyway;
 593 float g_pickup_healthmega;
 594 float g_pickup_healthmega_max;
 595 float g_pickup_healthmega_anyway;
 596 float g_pickup_ammo_anyway;
 597 float g_pickup_weapons_anyway;
 598 float g_weaponarena;
 599 WepSet g_weaponarena_weapons;
 600 float g_weaponarena_random;
 601 float g_weaponarena_random_with_blaster;
 602 string g_weaponarena_list;
 603 float g_weaponspeedfactor;
 604 float g_weaponratefactor;
 605 float g_weapondamagefactor;
 606 float g_weaponforcefactor;
 607 float g_weaponspreadfactor;
 608
 609 WepSet start_weapons;
 610 WepSet start_weapons_default;
 611 WepSet start_weapons_defaultmask;
 612 float start_items;
 613 float start_ammo_shells;
 614 float start_ammo_nails;
 615 float start_ammo_rockets;
 616 float start_ammo_cells;
 617 float start_ammo_plasma;
 618 float start_ammo_fuel;
 619 float start_health;
 620 float start_armorvalue;
 621 WepSet warmup_start_weapons;
 622 WepSet warmup_start_weapons_default;
 623 WepSet warmup_start_weapons_defaultmask;
 624 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 625 float warmup_start_ammo_shells;
 626 float warmup_start_ammo_nails;
 627 float warmup_start_ammo_rockets;
 628 float warmup_start_ammo_cells;
 629 float warmup_start_ammo_plasma;
 630 float warmup_start_ammo_fuel;
 631 float warmup_start_health;
 632 float warmup_start_armorvalue;
 633 float g_weapon_stay;
 634
 635 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 636 {
 637         var float i = weaponinfo.weapon;
 638         var float d = 0;
 639
 640         if (!i)
 641                 return 0;
 642
 643         if (g_lms || g_ca || allguns)
 644         {
 645                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 646                         d = TRUE;
 647                 else
 648                         d = FALSE;
 649         }
 650         else if (g_cts)
 651                 d = (i == WEP_SHOTGUN);
 652         else if (g_nexball)
 653                 d = 0; // weapon is set a few lines later
 654         else
 655                 d = !(!weaponinfo.weaponstart);
 656
 657         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 658                 d |= (i == WEP_HOOK);
 659         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 660                 d = 0;
 661
 662         var float t = weaponinfo.weaponstartoverride;
 663
 664         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 665
 666         // bit order in t:
 667         // 1: want or not
 668         // 2: is default?
 669         // 4: is set by default?
 670         if(t < 0)
 671                 t = 4 | (3 * d);
 672         else
 673                 t |= (2 * d);
 674
 675         return t;
 676 }
 677
 678 void readplayerstartcvars()
 679 {
 680         entity e;
 681         float i, j, t;
 682         string s;
 683
 684         // initialize starting values for players
 685         start_weapons = '0 0 0';
 686         start_weapons_default = '0 0 0';
 687         start_weapons_defaultmask = '0 0 0';
 688         start_items = 0;
 689         start_ammo_shells = 0;
 690         start_ammo_nails = 0;
 691         start_ammo_rockets = 0;
 692         start_ammo_cells = 0;
 693         start_ammo_plasma = 0;
 694         start_health = cvar("g_balance_health_start");
 695         start_armorvalue = cvar("g_balance_armor_start");
 696
 697         g_weaponarena = 0;
 698         g_weaponarena_weapons = '0 0 0';
 699
 700         s = cvar_string("g_weaponarena");
 701         if (s == "0" || s == "")
 702         {
 703                 if(g_ca)
 704                         s = "most";
 705         }
 706
 707         if (s == "0" || s == "")
 708         {
 709                 // no arena
 710         }
 711         else if (s == "off")
 712         {
 713                 // forcibly turn off weaponarena
 714         }
 715         else if (s == "all" || s == "1")
 716         {
 717                 g_weaponarena = 1;
 718                 g_weaponarena_list = "All Weapons";
 719                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 720                 {
 721                         e = get_weaponinfo(j);
 722                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 723                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 724                 }
 725         }
 726         else if (s == "most")
 727         {
 728                 g_weaponarena = 1;
 729                 g_weaponarena_list = "Most Weapons";
 730                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 731                 {
 732                         e = get_weaponinfo(j);
 733                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 734                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 735                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 736                 }
 737         }
 738         else if (s == "none")
 739         {
 740                 g_weaponarena = 1;
 741                 g_weaponarena_list = "No Weapons";
 742         }
 743         else
 744         {
 745                 g_weaponarena = 1;
 746                 t = tokenize_console(s);
 747                 g_weaponarena_list = "";
 748                 for (i = 0; i < t; ++i)
 749                 {
 750                         s = argv(i);
 751                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 752                         {
 753                                 e = get_weaponinfo(j);
 754                                 if (e.netname == s)
 755                                 {
 756                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 757                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 758                                         break;
 759                                 }
 760                         }
 761                         if (j > WEP_LAST)
 762                         {
 763                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 764                         }
 765                 }
 766                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 767         }
 768
 769         if(g_weaponarena)
 770                 g_weaponarena_random = cvar("g_weaponarena_random");
 771         else
 772                 g_weaponarena_random = 0;
 773         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 774
 775         if (g_weaponarena)
 776         {
 777                 g_weapon_stay = 0; // incompatible
 778                 start_weapons = g_weaponarena_weapons;
 779                 start_items |= IT_UNLIMITED_AMMO;
 780         }
 781         else
 782         {
 783                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 784                 {
 785                         e = get_weaponinfo(i);
 786                         float w = want_weapon(e, FALSE);
 787                         if(w & 1)
 788                                 start_weapons |= WepSet_FromWeapon(i);
 789                         if(w & 2)
 790                                 start_weapons_default |= WepSet_FromWeapon(i);
 791                         if(w & 4)
 792                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 793                 }
 794         }
 795
 796         if(!cvar("g_use_ammunition"))
 797                 start_items |= IT_UNLIMITED_AMMO;
 798
 799         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 800         {
 801                 start_ammo_shells = 999;
 802                 start_ammo_nails = 999;
 803                 start_ammo_rockets = 999;
 804                 start_ammo_cells = 999;
 805                 start_ammo_plasma = 999;
 806                 start_ammo_fuel = 999;
 807         }
 808         else
 809         {
 810                 start_ammo_shells = cvar("g_start_ammo_shells");
 811                 start_ammo_nails = cvar("g_start_ammo_nails");
 812                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 813                 start_ammo_cells = cvar("g_start_ammo_cells");
 814                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 815                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 816         }
 817
 818         if (warmup_stage)
 819         {
 820                 warmup_start_ammo_shells = start_ammo_shells;
 821                 warmup_start_ammo_nails = start_ammo_nails;
 822                 warmup_start_ammo_rockets = start_ammo_rockets;
 823                 warmup_start_ammo_cells = start_ammo_cells;
 824                 warmup_start_ammo_plasma = start_ammo_plasma;
 825                 warmup_start_ammo_fuel = start_ammo_fuel;
 826                 warmup_start_health = start_health;
 827                 warmup_start_armorvalue = start_armorvalue;
 828                 warmup_start_weapons = start_weapons;
 829                 warmup_start_weapons_default = start_weapons_default;
 830                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 831
 832                 if (!g_weaponarena && !g_ca)
 833                 {
 834                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 835                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 836                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 837                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 838                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 839                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 840                         warmup_start_health = cvar("g_warmup_start_health");
 841                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 842                         warmup_start_weapons = '0 0 0';
 843                         warmup_start_weapons_default = '0 0 0';
 844                         warmup_start_weapons_defaultmask = '0 0 0';
 845                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 846                         {
 847                                 e = get_weaponinfo(i);
 848                                 float w = want_weapon(e, g_warmup_allguns);
 849                                 if(w & 1)
 850                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 851                                 if(w & 2)
 852                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 853                                 if(w & 4)
 854                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 855                         }
 856                 }
 857         }
 858
 859         if (g_jetpack)
 860                 start_items |= IT_JETPACK;
 861
 862         MUTATOR_CALLHOOK(SetStartItems);
 863
 864         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 865         {
 866                 start_items |= IT_FUEL_REGEN;
 867                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 868                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 869         }
 870
 871         WepSet precache_weapons = start_weapons;
 872         if (g_warmup_allguns != 1)
 873                 precache_weapons |= warmup_start_weapons;
 874         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 875         {
 876                 e = get_weaponinfo(i);
 877                 if(precache_weapons & WepSet_FromWeapon(i))
 878                         WEP_ACTION(i, WR_INIT);
 879         }
 880
 881         start_ammo_shells = max(0, start_ammo_shells);
 882         start_ammo_nails = max(0, start_ammo_nails);
 883         start_ammo_rockets = max(0, start_ammo_rockets);
 884         start_ammo_cells = max(0, start_ammo_cells);
 885         start_ammo_plasma = max(0, start_ammo_plasma);
 886         start_ammo_fuel = max(0, start_ammo_fuel);
 887
 888         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 889         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 890         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 891         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 892         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 893         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 894 }
 895
 896 float g_bugrigs;
 897 float g_bugrigs_planar_movement;
 898 float g_bugrigs_planar_movement_car_jumping;
 899 float g_bugrigs_reverse_spinning;
 900 float g_bugrigs_reverse_speeding;
 901 float g_bugrigs_reverse_stopping;
 902 float g_bugrigs_air_steering;
 903 float g_bugrigs_angle_smoothing;
 904 float g_bugrigs_friction_floor;
 905 float g_bugrigs_friction_brake;
 906 float g_bugrigs_friction_air;
 907 float g_bugrigs_accel;
 908 float g_bugrigs_speed_ref;
 909 float g_bugrigs_speed_pow;
 910 float g_bugrigs_steer;
 911
 912 float sv_autotaunt;
 913 float sv_taunt;
 914
 915 string GetGametype(); // g_world.qc
 916 void mutators_add(); // mutators.qc
 917 void readlevelcvars(void)
 918 {
 919         // load mutators
 920         mutators_add();
 921
 922         if(cvar("sv_allow_fullbright"))
 923                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 924
 925     g_bugrigs = cvar("g_bugrigs");
 926     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 927     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 928     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 929     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 930     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 931     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 932     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 933     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 934     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 935     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 936     g_bugrigs_accel = cvar("g_bugrigs_accel");
 937     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 938     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 939     g_bugrigs_steer = cvar("g_bugrigs_steer");
 940
 941         g_instagib = cvar("g_instagib");
 942
 943         sv_clones = cvar("sv_clones");
 944         sv_foginterval = cvar("sv_foginterval");
 945         g_cloaked = cvar("g_cloaked");
 946         g_footsteps = cvar("g_footsteps");
 947         g_grappling_hook = cvar("g_grappling_hook");
 948         g_jetpack = cvar("g_jetpack");
 949         sv_maxidle = cvar("sv_maxidle");
 950         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 951         sv_autotaunt = cvar("sv_autotaunt");
 952         sv_taunt = cvar("sv_taunt");
 953
 954         warmup_stage = cvar("g_warmup");
 955         g_warmup_limit = cvar("g_warmup_limit");
 956         g_warmup_allguns = cvar("g_warmup_allguns");
 957         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 958
 959         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 960                 warmup_stage = 0; // these modes cannot work together, sorry
 961
 962         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 963         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 964         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 965         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 966         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 967         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 968         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 969         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 970         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 971         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 972         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 973         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 974         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 975         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 976
 977         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 978         g_weaponratefactor = cvar("g_weaponratefactor");
 979         g_weapondamagefactor = cvar("g_weapondamagefactor");
 980         g_weaponforcefactor = cvar("g_weaponforcefactor");
 981         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 982
 983         g_pickup_shells = cvar("g_pickup_shells");
 984         g_pickup_shells_max = cvar("g_pickup_shells_max");
 985         g_pickup_nails = cvar("g_pickup_nails");
 986         g_pickup_nails_max = cvar("g_pickup_nails_max");
 987         g_pickup_rockets = cvar("g_pickup_rockets");
 988         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 989         g_pickup_cells = cvar("g_pickup_cells");
 990         g_pickup_cells_max = cvar("g_pickup_cells_max");
 991         g_pickup_plasma = cvar("g_pickup_plasma");
 992         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 993         g_pickup_fuel = cvar("g_pickup_fuel");
 994         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 995         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 996         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 997         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 998         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 999         g_pickup_armormedium = cvar("g_pickup_armormedium");
1000         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1001         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1002         g_pickup_armorbig = cvar("g_pickup_armorbig");
1003         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1004         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1005         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1006         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1007         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1008         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1009         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1010         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1011         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1012         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1013         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1014         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1015         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1016         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1017         g_pickup_healthmega = cvar("g_pickup_healthmega");
1018         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1019         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1020
1021         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1022         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1023
1024     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1025     if(!g_weapon_stay)
1026         g_weapon_stay = cvar("g_weapon_stay");
1027
1028         if (!warmup_stage)
1029                 game_starttime = time + cvar("g_start_delay");
1030
1031         float i;
1032         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1033                 WEP_ACTION(i, WR_INIT);
1034
1035         readplayerstartcvars();
1036 }
1037
1038 //#NO AUTOCVARS END
1039
1040 // Sound functions
1041 string precache_sound (string s) = #19;
1042 float precache_sound_index (string s) = #19;
1043
1044 #define SND_VOLUME      1
1045 #define SND_ATTENUATION 2
1046 #define SND_LARGEENTITY 8
1047 #define SND_LARGESOUND  16
1048
1049 float sound_allowed(float dest, entity e)
1050 {
1051     // sounds from world may always pass
1052     for (;;)
1053     {
1054         if (e.classname == "body")
1055             e = e.enemy;
1056         else if (e.realowner && e.realowner != e)
1057             e = e.realowner;
1058         else if (e.owner && e.owner != e)
1059             e = e.owner;
1060         else
1061             break;
1062     }
1063     // sounds to self may always pass
1064     if (dest == MSG_ONE)
1065         if (e == msg_entity)
1066             return TRUE;
1067     // sounds by players can be removed
1068     if (autocvar_bot_sound_monopoly)
1069         if (IS_REAL_CLIENT(e))
1070             return FALSE;
1071     // anything else may pass
1072     return TRUE;
1073 }
1074
1075 #undef sound
1076 void sound(entity e, float chan, string samp, float vol, float atten)
1077 {
1078     if (!sound_allowed(MSG_BROADCAST, e))
1079         return;
1080     sound7(e, chan, samp, vol, atten, 0, 0);
1081 }
1082
1083 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1084 {
1085     float entno, idx;
1086
1087     if (!sound_allowed(dest, e))
1088         return;
1089
1090     entno = num_for_edict(e);
1091     idx = precache_sound_index(samp);
1092
1093     float sflags;
1094     sflags = 0;
1095
1096     atten = floor(atten * 64);
1097     vol = floor(vol * 255);
1098
1099     if (vol != 255)
1100         sflags |= SND_VOLUME;
1101     if (atten != 64)
1102         sflags |= SND_ATTENUATION;
1103     if (entno >= 8192 || chan < 0 || chan > 7)
1104         sflags |= SND_LARGEENTITY;
1105     if (idx >= 256)
1106         sflags |= SND_LARGESOUND;
1107
1108     WriteByte(dest, SVC_SOUND);
1109     WriteByte(dest, sflags);
1110     if (sflags & SND_VOLUME)
1111         WriteByte(dest, vol);
1112     if (sflags & SND_ATTENUATION)
1113         WriteByte(dest, atten);
1114     if (sflags & SND_LARGEENTITY)
1115     {
1116         WriteShort(dest, entno);
1117         WriteByte(dest, chan);
1118     }
1119     else
1120     {
1121         WriteShort(dest, entno * 8 + chan);
1122     }
1123     if (sflags & SND_LARGESOUND)
1124         WriteShort(dest, idx);
1125     else
1126         WriteByte(dest, idx);
1127
1128     WriteCoord(dest, o_x);
1129     WriteCoord(dest, o_y);
1130     WriteCoord(dest, o_z);
1131 }
1132 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1133 {
1134     vector o;
1135
1136     if (!sound_allowed(dest, e))
1137         return;
1138
1139     o = e.origin + 0.5 * (e.mins + e.maxs);
1140     soundtoat(dest, e, o, chan, samp, vol, atten);
1141 }
1142 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1143 {
1144     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1145 }
1146 void stopsoundto(float dest, entity e, float chan)
1147 {
1148     float entno;
1149
1150     if (!sound_allowed(dest, e))
1151         return;
1152
1153     entno = num_for_edict(e);
1154
1155     if (entno >= 8192 || chan < 0 || chan > 7)
1156     {
1157         float idx, sflags;
1158         idx = precache_sound_index("misc/null.wav");
1159         sflags = SND_LARGEENTITY;
1160         if (idx >= 256)
1161             sflags |= SND_LARGESOUND;
1162         WriteByte(dest, SVC_SOUND);
1163         WriteByte(dest, sflags);
1164         WriteShort(dest, entno);
1165         WriteByte(dest, chan);
1166         if (sflags & SND_LARGESOUND)
1167             WriteShort(dest, idx);
1168         else
1169             WriteByte(dest, idx);
1170         WriteCoord(dest, e.origin_x);
1171         WriteCoord(dest, e.origin_y);
1172         WriteCoord(dest, e.origin_z);
1173     }
1174     else
1175     {
1176         WriteByte(dest, SVC_STOPSOUND);
1177         WriteShort(dest, entno * 8 + chan);
1178     }
1179 }
1180 void stopsound(entity e, float chan)
1181 {
1182     if (!sound_allowed(MSG_BROADCAST, e))
1183         return;
1184
1185     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1186     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1187 }
1188
1189 void play2(entity e, string filename)
1190 {
1191     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1192     msg_entity = e;
1193     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1194 }
1195
1196 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1197 .float spamtime;
1198 float spamsound(entity e, float chan, string samp, float vol, float atten)
1199 {
1200     if (!sound_allowed(MSG_BROADCAST, e))
1201         return FALSE;
1202
1203     if (time > e.spamtime)
1204     {
1205         e.spamtime = time;
1206         sound(e, chan, samp, vol, atten);
1207         return TRUE;
1208     }
1209     return FALSE;
1210 }
1211
1212 void play2team(float t, string filename)
1213 {
1214     entity head;
1215
1216     if (autocvar_bot_sound_monopoly)
1217         return;
1218
1219     FOR_EACH_REALPLAYER(head)
1220     {
1221         if (head.team == t)
1222             play2(head, filename);
1223     }
1224 }
1225
1226 void play2all(string samp)
1227 {
1228     if (autocvar_bot_sound_monopoly)
1229         return;
1230
1231     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1232 }
1233
1234 void PrecachePlayerSounds(string f);
1235 void precache_playermodel(string m)
1236 {
1237         float globhandle, i, n;
1238         string f;
1239
1240         if(substring(m, -9,5) == "_lod1")
1241                 return;
1242         if(substring(m, -9,5) == "_lod2")
1243                 return;
1244         precache_model(m);
1245         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1246         if(fexists(f))
1247                 precache_model(f);
1248         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1249         if(fexists(f))
1250                 precache_model(f);
1251
1252         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1253         if (globhandle < 0)
1254                 return;
1255         n = search_getsize(globhandle);
1256         for (i = 0; i < n; ++i)
1257         {
1258                 //print(search_getfilename(globhandle, i), "\n");
1259                 f = search_getfilename(globhandle, i);
1260                 PrecachePlayerSounds(f);
1261         }
1262         search_end(globhandle);
1263 }
1264 void precache_all_playermodels(string pattern)
1265 {
1266         float globhandle, i, n;
1267         string f;
1268
1269         globhandle = search_begin(pattern, TRUE, FALSE);
1270         if (globhandle < 0)
1271                 return;
1272         n = search_getsize(globhandle);
1273         for (i = 0; i < n; ++i)
1274         {
1275                 //print(search_getfilename(globhandle, i), "\n");
1276                 f = search_getfilename(globhandle, i);
1277                 precache_playermodel(f);
1278         }
1279         search_end(globhandle);
1280 }
1281
1282 void precache()
1283 {
1284     // gamemode related things
1285     precache_model ("models/misc/chatbubble.spr");
1286         precache_model("models/ice/ice.md3");
1287
1288 #ifdef TTURRETS_ENABLED
1289     if (autocvar_g_turrets)
1290         turrets_precash();
1291 #endif
1292
1293     // Precache all player models if desired
1294     if (autocvar_sv_precacheplayermodels)
1295     {
1296         PrecachePlayerSounds("sound/player/default.sounds");
1297         precache_all_playermodels("models/player/*.zym");
1298         precache_all_playermodels("models/player/*.dpm");
1299         precache_all_playermodels("models/player/*.md3");
1300         precache_all_playermodels("models/player/*.psk");
1301         precache_all_playermodels("models/player/*.iqm");
1302     }
1303
1304     if (autocvar_sv_defaultcharacter)
1305     {
1306         string s;
1307         s = autocvar_sv_defaultplayermodel_red;
1308         if (s != "")
1309             precache_playermodel(s);
1310         s = autocvar_sv_defaultplayermodel_blue;
1311         if (s != "")
1312             precache_playermodel(s);
1313         s = autocvar_sv_defaultplayermodel_yellow;
1314         if (s != "")
1315             precache_playermodel(s);
1316         s = autocvar_sv_defaultplayermodel_pink;
1317         if (s != "")
1318             precache_playermodel(s);
1319         s = autocvar_sv_defaultplayermodel;
1320         if (s != "")
1321             precache_playermodel(s);
1322     }
1323
1324     if (g_footsteps)
1325     {
1326         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1327         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1328     }
1329
1330     // gore and miscellaneous sounds
1331     //precache_sound ("misc/h2ohit.wav");
1332     precache_model ("models/hook.md3");
1333     precache_sound ("misc/armorimpact.wav");
1334     precache_sound ("misc/bodyimpact1.wav");
1335     precache_sound ("misc/bodyimpact2.wav");
1336     precache_sound ("misc/gib.wav");
1337     precache_sound ("misc/gib_splat01.wav");
1338     precache_sound ("misc/gib_splat02.wav");
1339     precache_sound ("misc/gib_splat03.wav");
1340     precache_sound ("misc/gib_splat04.wav");
1341     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1342     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1343     precache_sound ("misc/null.wav");
1344     precache_sound ("misc/spawn.wav");
1345     precache_sound ("misc/talk.wav");
1346     precache_sound ("misc/teleport.wav");
1347     precache_sound ("misc/poweroff.wav");
1348     precache_sound ("player/lava.wav");
1349     precache_sound ("player/slime.wav");
1350
1351     precache_model ("models/sprites/0.spr32");
1352     precache_model ("models/sprites/1.spr32");
1353     precache_model ("models/sprites/2.spr32");
1354     precache_model ("models/sprites/3.spr32");
1355     precache_model ("models/sprites/4.spr32");
1356     precache_model ("models/sprites/5.spr32");
1357     precache_model ("models/sprites/6.spr32");
1358     precache_model ("models/sprites/7.spr32");
1359     precache_model ("models/sprites/8.spr32");
1360     precache_model ("models/sprites/9.spr32");
1361     precache_model ("models/sprites/10.spr32");
1362
1363     // common weapon precaches
1364         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1365     precache_sound ("weapons/weapon_switch.wav");
1366     precache_sound ("weapons/weaponpickup.wav");
1367     precache_sound ("weapons/unavailable.wav");
1368     precache_sound ("weapons/dryfire.wav");
1369     if (g_grappling_hook)
1370     {
1371         precache_sound ("weapons/hook_fire.wav"); // hook
1372         precache_sound ("weapons/hook_impact.wav"); // hook
1373     }
1374
1375     precache_model("models/elaser.mdl");
1376     precache_model("models/laser.mdl");
1377     precache_model("models/ebomb.mdl");
1378
1379 #if 0
1380     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1381
1382     if (!self.noise && self.music) // quake 3 uses the music field
1383         self.noise = self.music;
1384
1385     // plays music for the level if there is any
1386     if (self.noise)
1387     {
1388         precache_sound (self.noise);
1389         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1390     }
1391 #endif
1392
1393 #include "precache-for-csqc.inc"
1394 }
1395
1396 // WARNING: this kills the trace globals
1397 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1398 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1399
1400 #define INITPRIO_FIRST              0
1401 #define INITPRIO_GAMETYPE           0
1402 #define INITPRIO_GAMETYPE_FALLBACK  1
1403 #define INITPRIO_FINDTARGET        10
1404 #define INITPRIO_DROPTOFLOOR       20
1405 #define INITPRIO_SETLOCATION       90
1406 #define INITPRIO_LINKDOORS         91
1407 #define INITPRIO_LAST              99
1408
1409 .void(void) initialize_entity;
1410 .float initialize_entity_order;
1411 .entity initialize_entity_next;
1412 entity initialize_entity_first;
1413
1414 void make_safe_for_remove(entity e)
1415 {
1416     if (e.initialize_entity)
1417     {
1418         entity ent, prev = world;
1419         for (ent = initialize_entity_first; ent; )
1420         {
1421             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1422             {
1423                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1424                 // skip it in linked list
1425                 if (prev)
1426                 {
1427                     prev.initialize_entity_next = ent.initialize_entity_next;
1428                     ent = prev.initialize_entity_next;
1429                 }
1430                 else
1431                 {
1432                     initialize_entity_first = ent.initialize_entity_next;
1433                     ent = initialize_entity_first;
1434                 }
1435             }
1436             else
1437             {
1438                 prev = ent;
1439                 ent = ent.initialize_entity_next;
1440             }
1441         }
1442     }
1443 }
1444
1445 void objerror(string s)
1446 {
1447     make_safe_for_remove(self);
1448     builtin_objerror(s);
1449 }
1450
1451 .float remove_except_protected_forbidden;
1452 void remove_except_protected(entity e)
1453 {
1454         if(e.remove_except_protected_forbidden)
1455                 error("not allowed to remove this at this point");
1456         builtin_remove(e);
1457 }
1458
1459 void remove_unsafely(entity e)
1460 {
1461     if(e.classname == "spike")
1462         error("Removing spikes is forbidden (crylink bug), please report");
1463     builtin_remove(e);
1464 }
1465
1466 void remove_safely(entity e)
1467 {
1468     make_safe_for_remove(e);
1469     builtin_remove(e);
1470 }
1471
1472 void InitializeEntity(entity e, void(void) func, float order)
1473 {
1474     entity prev, cur;
1475
1476     if (!e || e.initialize_entity)
1477     {
1478         // make a proxy initializer entity
1479         entity e_old;
1480         e_old = e;
1481         e = spawn();
1482         e.classname = "initialize_entity";
1483         e.enemy = e_old;
1484     }
1485
1486     e.initialize_entity = func;
1487     e.initialize_entity_order = order;
1488
1489     cur = initialize_entity_first;
1490     prev = world;
1491     for (;;)
1492     {
1493         if (!cur || cur.initialize_entity_order > order)
1494         {
1495             // insert between prev and cur
1496             if (prev)
1497                 prev.initialize_entity_next = e;
1498             else
1499                 initialize_entity_first = e;
1500             e.initialize_entity_next = cur;
1501             return;
1502         }
1503         prev = cur;
1504         cur = cur.initialize_entity_next;
1505     }
1506 }
1507 void InitializeEntitiesRun()
1508 {
1509     entity startoflist;
1510     startoflist = initialize_entity_first;
1511     initialize_entity_first = world;
1512     remove = remove_except_protected;
1513     for (self = startoflist; self; self = self.initialize_entity_next)
1514     {
1515         self.remove_except_protected_forbidden = 1;
1516     }
1517     for (self = startoflist; self; )
1518     {
1519         entity e;
1520         var void(void) func;
1521         e = self.initialize_entity_next;
1522         func = self.initialize_entity;
1523         self.initialize_entity_order = 0;
1524         self.initialize_entity = func_null;
1525         self.initialize_entity_next = world;
1526         self.remove_except_protected_forbidden = 0;
1527         if (self.classname == "initialize_entity")
1528         {
1529             entity e_old;
1530             e_old = self.enemy;
1531             builtin_remove(self);
1532             self = e_old;
1533         }
1534         //dprint("Delayed initialization: ", self.classname, "\n");
1535         if(func)
1536             func();
1537         else
1538         {
1539             eprint(self);
1540             backtrace(strcat("Null function in: ", self.classname, "\n"));
1541         }
1542         self = e;
1543     }
1544     remove = remove_unsafely;
1545 }
1546
1547 .float uncustomizeentityforclient_set;
1548 .void(void) uncustomizeentityforclient;
1549 void UncustomizeEntitiesRun()
1550 {
1551     entity oldself;
1552     oldself = self;
1553     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1554         self.uncustomizeentityforclient();
1555     self = oldself;
1556 }
1557 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1558 {
1559     e.customizeentityforclient = customizer;
1560     e.uncustomizeentityforclient = uncustomizer;
1561     e.uncustomizeentityforclient_set = !!uncustomizer;
1562 }
1563
1564 .float nottargeted;
1565 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1566
1567 void() SUB_Remove;
1568 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1569 {
1570     vector mi, ma;
1571
1572     if (e.classname == "")
1573         e.classname = "net_linked";
1574
1575     if (e.model == "" || self.modelindex == 0)
1576     {
1577         mi = e.mins;
1578         ma = e.maxs;
1579         setmodel(e, "null");
1580         setsize(e, mi, ma);
1581     }
1582
1583     e.SendEntity = sendfunc;
1584     e.SendFlags = 0xFFFFFF;
1585
1586     if (!docull)
1587         e.effects |= EF_NODEPTHTEST;
1588
1589     if (dt)
1590     {
1591         e.nextthink = time + dt;
1592         e.think = SUB_Remove;
1593     }
1594 }
1595
1596
1597 entity eliminatedPlayers;
1598 .float(entity) isEliminated;
1599 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1600 {
1601         float i, f, b;
1602         entity e;
1603         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1604         WriteByte(MSG_ENTITY, sendflags);
1605
1606         if(sendflags & 1)
1607         {
1608                 for(i = 1; i <= maxclients; i += 8)
1609                 {
1610                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1611                         {
1612                                 if(eliminatedPlayers.isEliminated(e))
1613                                         f |= b;
1614                         }
1615                         WriteByte(MSG_ENTITY, f);
1616                 }
1617         }
1618
1619         return TRUE;
1620 }
1621
1622 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1623 {
1624         if(eliminatedPlayers)
1625         {
1626                 backtrace("Can't spawn eliminatedPlayers again!");
1627                 return;
1628         }
1629         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1630         eliminatedPlayers.isEliminated = isEliminated_func;
1631 }
1632
1633
1634 void adaptor_think2touch()
1635 {
1636     entity o;
1637     o = other;
1638     other = world;
1639     self.touch();
1640     other = o;
1641 }
1642
1643 void adaptor_think2use()
1644 {
1645     entity o, a;
1646     o = other;
1647     a = activator;
1648     activator = world;
1649     other = world;
1650     self.use();
1651     other = o;
1652     activator = a;
1653 }
1654
1655 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1656 {
1657         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1658                 self.projectiledeathtype |= HITTYPE_SPLASH;
1659         adaptor_think2use();
1660 }
1661
1662 // deferred dropping
1663 void DropToFloor_Handler()
1664 {
1665     builtin_droptofloor();
1666     self.dropped_origin = self.origin;
1667 }
1668
1669 void droptofloor()
1670 {
1671     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1672 }
1673
1674
1675
1676 float trace_hits_box_a0, trace_hits_box_a1;
1677
1678 float trace_hits_box_1d(float end, float thmi, float thma)
1679 {
1680     if (end == 0)
1681     {
1682         // just check if x is in range
1683         if (0 < thmi)
1684             return FALSE;
1685         if (0 > thma)
1686             return FALSE;
1687     }
1688     else
1689     {
1690         // do the trace with respect to x
1691         // 0 -> end has to stay in thmi -> thma
1692         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1693         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1694         if (trace_hits_box_a0 > trace_hits_box_a1)
1695             return FALSE;
1696     }
1697     return TRUE;
1698 }
1699
1700 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1701 {
1702     end -= start;
1703     thmi -= start;
1704     thma -= start;
1705     // now it is a trace from 0 to end
1706
1707     trace_hits_box_a0 = 0;
1708     trace_hits_box_a1 = 1;
1709
1710     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1711         return FALSE;
1712     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1713         return FALSE;
1714     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1715         return FALSE;
1716
1717     return TRUE;
1718 }
1719
1720 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1721 {
1722     return trace_hits_box(start, end, thmi - ma, thma - mi);
1723 }
1724
1725 float SUB_NoImpactCheck()
1726 {
1727         // zero hitcontents = this is not the real impact, but either the
1728         // mirror-impact of something hitting the projectile instead of the
1729         // projectile hitting the something, or a touchareagrid one. Neither of
1730         // these stop the projectile from moving, so...
1731         if(trace_dphitcontents == 0)
1732         {
1733                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1734                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1735                 checkclient();
1736         }
1737     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1738         return 1;
1739     if (other == world && self.size != '0 0 0')
1740     {
1741         vector tic;
1742         tic = self.velocity * sys_frametime;
1743         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1744         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1745         if (trace_fraction >= 1)
1746         {
1747             dprint("Odd... did not hit...?\n");
1748         }
1749         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1750         {
1751             dprint("Detected and prevented the sky-grapple bug.\n");
1752             return 1;
1753         }
1754     }
1755
1756     return 0;
1757 }
1758
1759 #define SUB_OwnerCheck() (other && (other == self.owner))
1760
1761 void RemoveGrapplingHook(entity pl);
1762 void W_Crylink_Dequeue(entity e);
1763 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1764 {
1765         if(SUB_OwnerCheck())
1766                 return TRUE;
1767         if(SUB_NoImpactCheck())
1768         {
1769                 if(self.classname == "nade")
1770                         return FALSE; // no checks here
1771                 else if(self.classname == "grapplinghook")
1772                         RemoveGrapplingHook(self.realowner);
1773                 else if(self.classname == "spike")
1774                 {
1775                         W_Crylink_Dequeue(self);
1776                         remove(self);
1777                 }
1778                 else
1779                         remove(self);
1780                 return TRUE;
1781         }
1782         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1783                 UpdateCSQCProjectile(self);
1784         return FALSE;
1785 }
1786 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1787
1788 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1789 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1790
1791 void URI_Get_Callback(float id, float status, string data)
1792 {
1793         if(url_URI_Get_Callback(id, status, data))
1794         {
1795                 // handled
1796         }
1797         else if (id == URI_GET_DISCARD)
1798         {
1799                 // discard
1800         }
1801         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1802         {
1803                 // sv_cmd curl
1804                 Curl_URI_Get_Callback(id, status, data);
1805         }
1806         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1807         {
1808                 // online ban list
1809                 OnlineBanList_URI_Get_Callback(id, status, data);
1810         }
1811         else
1812         {
1813                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1814         }
1815 }
1816
1817 string uid2name(string myuid) {
1818         string s;
1819         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1820
1821         // FIXME remove this later after 0.6 release
1822         // convert old style broken records to correct style
1823         if(s == "")
1824         {
1825                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1826                 if(s != "")
1827                 {
1828                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1829                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1830                 }
1831         }
1832
1833         if(s == "")
1834                 s = "^1Unregistered Player";
1835         return s;
1836 }
1837
1838 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1839 {
1840     float m, i;
1841     vector start, org, delta, end, enddown, mstart;
1842     entity sp;
1843
1844     m = e.dphitcontentsmask;
1845     e.dphitcontentsmask = goodcontents | badcontents;
1846
1847     org = world.mins;
1848     delta = world.maxs - world.mins;
1849
1850     start = end = org;
1851
1852     for (i = 0; i < attempts; ++i)
1853     {
1854         start_x = org_x + random() * delta_x;
1855         start_y = org_y + random() * delta_y;
1856         start_z = org_z + random() * delta_z;
1857
1858         // rule 1: start inside world bounds, and outside
1859         // solid, and don't start from somewhere where you can
1860         // fall down to evil
1861         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1862         if (trace_fraction >= 1)
1863             continue;
1864         if (trace_startsolid)
1865             continue;
1866         if (trace_dphitcontents & badcontents)
1867             continue;
1868         if (trace_dphitq3surfaceflags & badsurfaceflags)
1869             continue;
1870
1871         // rule 2: if we are too high, lower the point
1872         if (trace_fraction * delta_z > maxaboveground)
1873             start = trace_endpos + '0 0 1' * maxaboveground;
1874         enddown = trace_endpos;
1875
1876         // rule 3: make sure we aren't outside the map. This only works
1877         // for somewhat well formed maps. A good rule of thumb is that
1878         // the map should have a convex outside hull.
1879         // these can be traceLINES as we already verified the starting box
1880         mstart = start + 0.5 * (e.mins + e.maxs);
1881         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1882         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1883             continue;
1884         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1885         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1886             continue;
1887         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1888         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1889             continue;
1890         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1891         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1892             continue;
1893         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1894         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1895             continue;
1896
1897         // rule 4: we must "see" some spawnpoint or item
1898         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1899                 if(checkpvs(mstart, sp))
1900                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1901                                 break;
1902         if(!sp)
1903         {
1904                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1905                         if(checkpvs(mstart, sp))
1906                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1907                                         break;
1908                 if(!sp)
1909                         continue;
1910         }
1911
1912         // find a random vector to "look at"
1913         end_x = org_x + random() * delta_x;
1914         end_y = org_y + random() * delta_y;
1915         end_z = org_z + random() * delta_z;
1916         end = start + normalize(end - start) * vlen(delta);
1917
1918         // rule 4: start TO end must not be too short
1919         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1920         if (trace_startsolid)
1921             continue;
1922         if (trace_fraction < minviewdistance / vlen(delta))
1923             continue;
1924
1925         // rule 5: don't want to look at sky
1926         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1927             continue;
1928
1929         // rule 6: we must not end up in trigger_hurt
1930         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1931             continue;
1932
1933         break;
1934     }
1935
1936     e.dphitcontentsmask = m;
1937
1938     if (i < attempts)
1939     {
1940         setorigin(e, start);
1941         e.angles = vectoangles(end - start);
1942         dprint("Needed ", ftos(i + 1), " attempts\n");
1943         return TRUE;
1944     }
1945     else
1946         return FALSE;
1947 }
1948
1949 void write_recordmarker(entity pl, float tstart, float dt)
1950 {
1951     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1952
1953     // also write a marker into demo files for demotc-race-record-extractor to find
1954     stuffcmd(pl,
1955              strcat(
1956                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1957                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1958 }
1959
1960 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1961 {
1962         switch(algn)
1963         {
1964                 default:
1965                 case 3: // right
1966                         break;
1967
1968                 case 4: // left
1969                         vecs_y = -vecs_y;
1970                         break;
1971
1972                 case 1:
1973                         if(allowcenter) // 2: allow center handedness
1974                         {
1975                                 // center
1976                                 vecs_y = 0;
1977                                 vecs_z -= 2;
1978                         }
1979                         else
1980                         {
1981                                 // right
1982                         }
1983                         break;
1984
1985                 case 2:
1986                         if(allowcenter) // 2: allow center handedness
1987                         {
1988                                 // center
1989                                 vecs_y = 0;
1990                                 vecs_z -= 2;
1991                         }
1992                         else
1993                         {
1994                                 // left
1995                                 vecs_y = -vecs_y;
1996                         }
1997                         break;
1998         }
1999         return vecs;
2000 }
2001
2002 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2003 {
2004         string s;
2005         vector v;
2006
2007         if (autocvar_g_shootfromeye)
2008         {
2009                 if (visual)
2010                 {
2011                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2012                         else { vecs_y = 0; vecs_z -= 2; }
2013                 }
2014                 else
2015                 {
2016                         vecs_y = 0;
2017                         vecs_z = 0;
2018                 }
2019         }
2020         else if (autocvar_g_shootfromcenter)
2021         {
2022                 vecs_y = 0;
2023                 vecs_z -= 2;
2024         }
2025         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2026         {
2027                 v = stov(s);
2028                 if (y_is_right)
2029                         v_y = -v_y;
2030                 if (v_x != 0)
2031                         vecs_x = v_x;
2032                 vecs_y = v_y;
2033                 vecs_z = v_z;
2034         }
2035         else if (autocvar_g_shootfromclient)
2036         {
2037                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2038         }
2039         return vecs;
2040 }
2041
2042 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2043 {
2044         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2045 }
2046
2047
2048 void attach_sameorigin(entity e, entity to, string tag)
2049 {
2050     vector org, t_forward, t_left, t_up, e_forward, e_up;
2051     float tagscale;
2052
2053     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2054     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2055     t_forward = v_forward * tagscale;
2056     t_left = v_right * -tagscale;
2057     t_up = v_up * tagscale;
2058
2059     e.origin_x = org * t_forward;
2060     e.origin_y = org * t_left;
2061     e.origin_z = org * t_up;
2062
2063     // current forward and up directions
2064     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2065                 e.angles = AnglesTransform_FromVAngles(e.angles);
2066         else
2067                 e.angles = AnglesTransform_FromAngles(e.angles);
2068     fixedmakevectors(e.angles);
2069
2070     // untransform forward, up!
2071     e_forward_x = v_forward * t_forward;
2072     e_forward_y = v_forward * t_left;
2073     e_forward_z = v_forward * t_up;
2074     e_up_x = v_up * t_forward;
2075     e_up_y = v_up * t_left;
2076     e_up_z = v_up * t_up;
2077
2078     e.angles = fixedvectoangles2(e_forward, e_up);
2079     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2080                 e.angles = AnglesTransform_ToVAngles(e.angles);
2081         else
2082                 e.angles = AnglesTransform_ToAngles(e.angles);
2083
2084     setattachment(e, to, tag);
2085     setorigin(e, e.origin);
2086 }
2087
2088 void detach_sameorigin(entity e)
2089 {
2090     vector org;
2091     org = gettaginfo(e, 0);
2092     e.angles = fixedvectoangles2(v_forward, v_up);
2093     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2094                 e.angles = AnglesTransform_ToVAngles(e.angles);
2095         else
2096                 e.angles = AnglesTransform_ToAngles(e.angles);
2097     setorigin(e, org);
2098     setattachment(e, world, "");
2099     setorigin(e, e.origin);
2100 }
2101
2102 void follow_sameorigin(entity e, entity to)
2103 {
2104     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2105     e.aiment = to; // make the hole follow bmodel
2106     e.punchangle = to.angles; // the original angles of bmodel
2107     e.view_ofs = e.origin - to.origin; // relative origin
2108     e.v_angle = e.angles - to.angles; // relative angles
2109 }
2110
2111 void unfollow_sameorigin(entity e)
2112 {
2113     e.movetype = MOVETYPE_NONE;
2114 }
2115
2116 entity gettaginfo_relative_ent;
2117 vector gettaginfo_relative(entity e, float tag)
2118 {
2119     if (!gettaginfo_relative_ent)
2120     {
2121         gettaginfo_relative_ent = spawn();
2122         gettaginfo_relative_ent.effects = EF_NODRAW;
2123     }
2124     gettaginfo_relative_ent.model = e.model;
2125     gettaginfo_relative_ent.modelindex = e.modelindex;
2126     gettaginfo_relative_ent.frame = e.frame;
2127     return gettaginfo(gettaginfo_relative_ent, tag);
2128 }
2129
2130 .float scale2;
2131
2132 float modeleffect_SendEntity(entity to, float sf)
2133 {
2134         float f;
2135         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2136
2137         f = 0;
2138         if(self.velocity != '0 0 0')
2139                 f |= 1;
2140         if(self.angles != '0 0 0')
2141                 f |= 2;
2142         if(self.avelocity != '0 0 0')
2143                 f |= 4;
2144
2145         WriteByte(MSG_ENTITY, f);
2146         WriteShort(MSG_ENTITY, self.modelindex);
2147         WriteByte(MSG_ENTITY, self.skin);
2148         WriteByte(MSG_ENTITY, self.frame);
2149         WriteCoord(MSG_ENTITY, self.origin_x);
2150         WriteCoord(MSG_ENTITY, self.origin_y);
2151         WriteCoord(MSG_ENTITY, self.origin_z);
2152         if(f & 1)
2153         {
2154                 WriteCoord(MSG_ENTITY, self.velocity_x);
2155                 WriteCoord(MSG_ENTITY, self.velocity_y);
2156                 WriteCoord(MSG_ENTITY, self.velocity_z);
2157         }
2158         if(f & 2)
2159         {
2160                 WriteCoord(MSG_ENTITY, self.angles_x);
2161                 WriteCoord(MSG_ENTITY, self.angles_y);
2162                 WriteCoord(MSG_ENTITY, self.angles_z);
2163         }
2164         if(f & 4)
2165         {
2166                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2167                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2168                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2169         }
2170         WriteShort(MSG_ENTITY, self.scale * 256.0);
2171         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2172         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2173         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2174         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2175
2176         return TRUE;
2177 }
2178
2179 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2180 {
2181         entity e;
2182         float sz;
2183         e = spawn();
2184         e.classname = "modeleffect";
2185         setmodel(e, m);
2186         e.frame = f;
2187         setorigin(e, o);
2188         e.velocity = v;
2189         e.angles = ang;
2190         e.avelocity = angv;
2191         e.alpha = a;
2192         e.teleport_time = t1;
2193         e.fade_time = t2;
2194         e.skin = s;
2195         if(s0 >= 0)
2196                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2197         else
2198                 e.scale = -s0;
2199         if(s2 >= 0)
2200                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2201         else
2202                 e.scale2 = -s2;
2203         sz = max(e.scale, e.scale2);
2204         setsize(e, e.mins * sz, e.maxs * sz);
2205         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2206 }
2207
2208 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2209 {
2210         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2211 }
2212
2213 float randombit(float bits)
2214 {
2215         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2216                 return bits;
2217
2218         float n, f, b, r;
2219
2220         r = random();
2221         b = 0;
2222         n = 0;
2223
2224         for(f = 1; f <= bits; f *= 2)
2225         {
2226                 if(bits & f)
2227                 {
2228                         ++n;
2229                         r *= n;
2230                         if(r <= 1)
2231                                 b = f;
2232                         else
2233                                 r = (r - 1) / (n - 1);
2234                 }
2235         }
2236
2237         return b;
2238 }
2239
2240 float randombits(float bits, float k, float error_return)
2241 {
2242         float r;
2243         r = 0;
2244         while(k > 0 && bits != r)
2245         {
2246                 r += randombit(bits - r);
2247                 --k;
2248         }
2249         if(error_return)
2250                 if(k > 0)
2251                         return -1; // all
2252         return r;
2253 }
2254
2255 void randombit_test(float bits, float iter)
2256 {
2257         while(iter > 0)
2258         {
2259                 print(ftos(randombit(bits)), "\n");
2260                 --iter;
2261         }
2262 }
2263
2264 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2265 {
2266         if(halflifedist > 0)
2267                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2268         else if(halflifedist < 0)
2269                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2270         else
2271                 return 1;
2272 }
2273
2274
2275
2276
2277 #ifdef RELEASE
2278 #define cvar_string_normal builtin_cvar_string
2279 #define cvar_normal builtin_cvar
2280 #else
2281 string cvar_string_normal(string n)
2282 {
2283         if (!(cvar_type(n) & 1))
2284                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2285         return builtin_cvar_string(n);
2286 }
2287
2288 float cvar_normal(string n)
2289 {
2290         return stof(cvar_string_normal(n));
2291 }
2292 #endif
2293 #define cvar_set_normal builtin_cvar_set
2294
2295 void defer_think()
2296 {
2297     entity oself;
2298
2299     oself           = self;
2300     self            = self.owner;
2301     oself.think     = SUB_Remove;
2302     oself.nextthink = time;
2303
2304     oself.use();
2305 }
2306
2307 /*
2308     Execute func() after time + fdelay.
2309     self when func is executed = self when defer is called
2310 */
2311 void defer(float fdelay, void() func)
2312 {
2313     entity e;
2314
2315     e           = spawn();
2316     e.owner     = self;
2317     e.use       = func;
2318     e.think     = defer_think;
2319     e.nextthink = time + fdelay;
2320 }
2321
2322 .string aiment_classname;
2323 .float aiment_deadflag;
2324 void SetMovetypeFollow(entity ent, entity e)
2325 {
2326         // FIXME this may not be warpzone aware
2327         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2328         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2329         ent.aiment = e; // make the hole follow bmodel
2330         ent.punchangle = e.angles; // the original angles of bmodel
2331         ent.view_ofs = ent.origin - e.origin; // relative origin
2332         ent.v_angle = ent.angles - e.angles; // relative angles
2333         ent.aiment_classname = strzone(e.classname);
2334         ent.aiment_deadflag = e.deadflag;
2335 }
2336 void UnsetMovetypeFollow(entity ent)
2337 {
2338         ent.movetype = MOVETYPE_FLY;
2339         PROJECTILE_MAKETRIGGER(ent);
2340         ent.aiment = world;
2341 }
2342 float LostMovetypeFollow(entity ent)
2343 {
2344 /*
2345         if(ent.movetype != MOVETYPE_FOLLOW)
2346                 if(ent.aiment)
2347                         error("???");
2348 */
2349         if(ent.aiment)
2350         {
2351                 if(ent.aiment.classname != ent.aiment_classname)
2352                         return 1;
2353                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2354                         return 1;
2355         }
2356         return 0;
2357 }
2358
2359 float isPushable(entity e)
2360 {
2361         if(e.iscreature)
2362                 return TRUE;
2363         if(e.pushable)
2364                 return TRUE;
2365         switch(e.classname)
2366         {
2367                 case "body":
2368                 case "droppedweapon":
2369                 case "keepawayball":
2370                 case "nexball_basketball":
2371                 case "nexball_football":
2372                         return TRUE;
2373                 case "bullet": // antilagged bullets can't hit this either
2374                         return FALSE;
2375         }
2376         if (e.projectiledeathtype)
2377                 return TRUE;
2378         return FALSE;
2379 }