qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 /**
 420  * @param f -1: cleanup, 0: request, 1: receive
 421  */
 422 void GetCvars(entity this, entity store, int f)
 423 {
 424         string s = string_null;
 425
 426         if (f > 0)
 427                 s = strcat1(argv(f));
 428
 429         get_cvars_f = f;
 430         get_cvars_s = s;
 431         MUTATOR_CALLHOOK(GetCvars);
 432
 433         Notification_GetCvars(this);
 434
 435         ReplicateVars(this, store, s, f);
 436
 437         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 438         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 439         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 440         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 441         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 442         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 448
 449         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 450
 451         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 452         if (f > 0)
 453         {
 454                 if (s == "cl_weaponpriority")
 455                 {
 456                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 457                         {
 458                                 .entity weaponentity = weaponentities[slot];
 459                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 460                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 461                         }
 462                 }
 463                 if (s == "cl_allow_uidtracking")
 464                         PlayerStats_GameReport_AddPlayer(this);
 465         }
 466 }
 467
 468 // decolorizes and team colors the player name when needed
 469 string playername(entity p, bool team_colorize)
 470 {
 471     string t;
 472     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 473     {
 474         t = Team_ColorCode(p.team);
 475         return strcat(t, strdecolorize(p.netname));
 476     }
 477     else
 478         return p.netname;
 479 }
 480
 481 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 482 {
 483         int i = weaponinfo.m_id;
 484         int d = 0;
 485         bool allow_mutatorblocked = false;
 486
 487         if(!i)
 488                 return 0;
 489
 490         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 491         d = M_ARGV(1, float);
 492         allguns = M_ARGV(2, bool);
 493         allow_mutatorblocked = M_ARGV(3, bool);
 494
 495         if(allguns)
 496         {
 497                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 498                         d = true;
 499                 else
 500                         d = false;
 501         }
 502         else if(!mutator_returnvalue)
 503                 d = !(!weaponinfo.weaponstart);
 504
 505         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 506                 d = 0;
 507
 508         float t = weaponinfo.weaponstartoverride;
 509
 510         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 511
 512         // bit order in t:
 513         // 1: want or not
 514         // 2: is default?
 515         // 4: is set by default?
 516         if(t < 0)
 517                 t = 4 | (3 * d);
 518         else
 519                 t |= (2 * d);
 520
 521         return t;
 522 }
 523
 524 void readplayerstartcvars()
 525 {
 526         float i, t;
 527         string s;
 528
 529         // initialize starting values for players
 530         start_weapons = '0 0 0';
 531         start_weapons_default = '0 0 0';
 532         start_weapons_defaultmask = '0 0 0';
 533         start_items = 0;
 534         start_ammo_shells = 0;
 535         start_ammo_nails = 0;
 536         start_ammo_rockets = 0;
 537         start_ammo_cells = 0;
 538         start_ammo_plasma = 0;
 539         if (random_start_ammo == NULL)
 540         {
 541                 random_start_ammo = spawn();
 542         }
 543         start_health = cvar("g_balance_health_start");
 544         start_armorvalue = cvar("g_balance_armor_start");
 545
 546         g_weaponarena = 0;
 547         g_weaponarena_weapons = '0 0 0';
 548
 549         s = cvar_string("g_weaponarena");
 550
 551         MUTATOR_CALLHOOK(SetWeaponArena, s);
 552         s = M_ARGV(0, string);
 553
 554         if (s == "0" || s == "")
 555         {
 556                 // no arena
 557         }
 558         else if (s == "off")
 559         {
 560                 // forcibly turn off weaponarena
 561         }
 562         else if (s == "all" || s == "1")
 563         {
 564                 g_weaponarena = 1;
 565                 g_weaponarena_list = "All Weapons";
 566                 FOREACH(Weapons, it != WEP_Null, {
 567                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 568                                 g_weaponarena_weapons |= (it.m_wepset);
 569                 });
 570         }
 571         else if (s == "devall")
 572         {
 573                 g_weaponarena = 1;
 574                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 575                 FOREACH(Weapons, it != WEP_Null,
 576                 {
 577                         g_weaponarena_weapons |= (it.m_wepset);
 578                 });
 579         }
 580         else if (s == "most")
 581         {
 582                 g_weaponarena = 1;
 583                 g_weaponarena_list = "Most Weapons";
 584                 FOREACH(Weapons, it != WEP_Null, {
 585                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 586                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 587                                         g_weaponarena_weapons |= (it.m_wepset);
 588                 });
 589         }
 590         else if (s == "none")
 591         {
 592                 g_weaponarena = 1;
 593                 g_weaponarena_list = "No Weapons";
 594         }
 595         else
 596         {
 597                 g_weaponarena = 1;
 598                 t = tokenize_console(s);
 599                 g_weaponarena_list = "";
 600                 for (i = 0; i < t; ++i)
 601                 {
 602                         s = argv(i);
 603                         FOREACH(Weapons, it != WEP_Null, {
 604                                 if(it.netname == s)
 605                                 {
 606                                         g_weaponarena_weapons |= (it.m_wepset);
 607                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 608                                         break;
 609                                 }
 610                         });
 611                 }
 612                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 613         }
 614
 615         if (g_weaponarena)
 616         {
 617                 g_weapon_stay = 0; // incompatible
 618                 start_weapons = g_weaponarena_weapons;
 619                 start_items |= IT_UNLIMITED_AMMO;
 620         }
 621         else
 622         {
 623                 FOREACH(Weapons, it != WEP_Null, {
 624                         int w = want_weapon(it, false);
 625                         WepSet s = it.m_wepset;
 626                         if(w & 1)
 627                                 start_weapons |= s;
 628                         if(w & 2)
 629                                 start_weapons_default |= s;
 630                         if(w & 4)
 631                                 start_weapons_defaultmask |= s;
 632                 });
 633         }
 634
 635         if(!cvar("g_use_ammunition"))
 636                 start_items |= IT_UNLIMITED_AMMO;
 637
 638         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 639         {
 640                 start_ammo_shells = 999;
 641                 start_ammo_nails = 999;
 642                 start_ammo_rockets = 999;
 643                 start_ammo_cells = 999;
 644                 start_ammo_plasma = 999;
 645                 start_ammo_fuel = 999;
 646         }
 647         else
 648         {
 649                 start_ammo_shells = cvar("g_start_ammo_shells");
 650                 start_ammo_nails = cvar("g_start_ammo_nails");
 651                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 652                 start_ammo_cells = cvar("g_start_ammo_cells");
 653                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 654                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 655                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 656                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 657                         "g_random_start_shells"));
 658                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 659                         "g_random_start_bullets"));
 660                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 661                         cvar("g_random_start_rockets"));
 662                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 663                         "g_random_start_cells"));
 664                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 665                         "g_random_start_plasma"));
 666         }
 667
 668         if (warmup_stage)
 669         {
 670                 warmup_start_ammo_shells = start_ammo_shells;
 671                 warmup_start_ammo_nails = start_ammo_nails;
 672                 warmup_start_ammo_rockets = start_ammo_rockets;
 673                 warmup_start_ammo_cells = start_ammo_cells;
 674                 warmup_start_ammo_plasma = start_ammo_plasma;
 675                 warmup_start_ammo_fuel = start_ammo_fuel;
 676                 warmup_start_health = start_health;
 677                 warmup_start_armorvalue = start_armorvalue;
 678                 warmup_start_weapons = start_weapons;
 679                 warmup_start_weapons_default = start_weapons_default;
 680                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 681
 682                 if (!g_weaponarena && !g_ca && !g_freezetag)
 683                 {
 684                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 685                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 686                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 687                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 688                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 689                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 690                         warmup_start_health = cvar("g_warmup_start_health");
 691                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 692                         warmup_start_weapons = '0 0 0';
 693                         warmup_start_weapons_default = '0 0 0';
 694                         warmup_start_weapons_defaultmask = '0 0 0';
 695                         FOREACH(Weapons, it != WEP_Null, {
 696                                 int w = want_weapon(it, g_warmup_allguns);
 697                                 WepSet s = (it.m_wepset);
 698                                 if(w & 1)
 699                                         warmup_start_weapons |= s;
 700                                 if(w & 2)
 701                                         warmup_start_weapons_default |= s;
 702                                 if(w & 4)
 703                                         warmup_start_weapons_defaultmask |= s;
 704                         });
 705                 }
 706         }
 707
 708         if (g_jetpack)
 709                 start_items |= ITEM_Jetpack.m_itemid;
 710
 711         MUTATOR_CALLHOOK(SetStartItems);
 712
 713         if (start_items & ITEM_Jetpack.m_itemid)
 714         {
 715                 start_items |= ITEM_JetpackRegen.m_itemid;
 716                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 717                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 718         }
 719
 720         WepSet precache_weapons = start_weapons;
 721         if (g_warmup_allguns != 1)
 722                 precache_weapons |= warmup_start_weapons;
 723         FOREACH(Weapons, it != WEP_Null, {
 724                 if(precache_weapons & (it.m_wepset))
 725                         it.wr_init(it);
 726         });
 727
 728         start_ammo_shells = max(0, start_ammo_shells);
 729         start_ammo_nails = max(0, start_ammo_nails);
 730         start_ammo_rockets = max(0, start_ammo_rockets);
 731         start_ammo_cells = max(0, start_ammo_cells);
 732         start_ammo_plasma = max(0, start_ammo_plasma);
 733         start_ammo_fuel = max(0, start_ammo_fuel);
 734         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 735                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 736         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 737                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 738         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 739                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 740         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 741                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 742         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 743                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 744
 745         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 746         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 747         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 748         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 749         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 750         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 751 }
 752
 753 void precache_playermodel(string m)
 754 {
 755         float globhandle, i, n;
 756         string f;
 757
 758         if(substring(m, -9,5) == "_lod1")
 759                 return;
 760         if(substring(m, -9,5) == "_lod2")
 761                 return;
 762         precache_model(m);
 763         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 764         if(fexists(f))
 765                 precache_model(f);
 766         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 767         if(fexists(f))
 768                 precache_model(f);
 769
 770         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 771         if (globhandle < 0)
 772                 return;
 773         n = search_getsize(globhandle);
 774         for (i = 0; i < n; ++i)
 775         {
 776                 //print(search_getfilename(globhandle, i), "\n");
 777                 f = search_getfilename(globhandle, i);
 778                 PrecachePlayerSounds(f);
 779         }
 780         search_end(globhandle);
 781 }
 782 void precache_all_playermodels(string pattern)
 783 {
 784         int globhandle = search_begin(pattern, true, false);
 785         if (globhandle < 0) return;
 786         int n = search_getsize(globhandle);
 787         for (int i = 0; i < n; ++i)
 788         {
 789                 string s = search_getfilename(globhandle, i);
 790                 precache_playermodel(s);
 791         }
 792         search_end(globhandle);
 793 }
 794
 795 void precache_playermodels(string s)
 796 {
 797         FOREACH_WORD(s, true, { precache_playermodel(it); });
 798 }
 799
 800 void precache()
 801 {
 802     // gamemode related things
 803
 804     // Precache all player models if desired
 805     if (autocvar_sv_precacheplayermodels)
 806     {
 807         PrecachePlayerSounds("sound/player/default.sounds");
 808         precache_all_playermodels("models/player/*.zym");
 809         precache_all_playermodels("models/player/*.dpm");
 810         precache_all_playermodels("models/player/*.md3");
 811         precache_all_playermodels("models/player/*.psk");
 812         precache_all_playermodels("models/player/*.iqm");
 813     }
 814
 815     if (autocvar_sv_defaultcharacter)
 816     {
 817                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 818                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 819                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 820                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 821                 precache_playermodels(autocvar_sv_defaultplayermodel);
 822     }
 823
 824 #if 0
 825     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 826
 827     if (!this.noise && this.music) // quake 3 uses the music field
 828         this.noise = this.music;
 829
 830     // plays music for the level if there is any
 831     if (this.noise)
 832     {
 833         precache_sound (this.noise);
 834         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 835     }
 836 #endif
 837 }
 838
 839
 840 void make_safe_for_remove(entity e)
 841 {
 842     if (e.initialize_entity)
 843     {
 844         entity ent, prev = NULL;
 845         for (ent = initialize_entity_first; ent; )
 846         {
 847             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 848             {
 849                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 850                 // skip it in linked list
 851                 if (prev)
 852                 {
 853                     prev.initialize_entity_next = ent.initialize_entity_next;
 854                     ent = prev.initialize_entity_next;
 855                 }
 856                 else
 857                 {
 858                     initialize_entity_first = ent.initialize_entity_next;
 859                     ent = initialize_entity_first;
 860                 }
 861             }
 862             else
 863             {
 864                 prev = ent;
 865                 ent = ent.initialize_entity_next;
 866             }
 867         }
 868     }
 869 }
 870
 871 .float remove_except_protected_forbidden;
 872 void remove_except_protected(entity e)
 873 {
 874         if(e.remove_except_protected_forbidden)
 875                 error("not allowed to remove this at this point");
 876         builtin_remove(e);
 877 }
 878
 879 void remove_unsafely(entity e)
 880 {
 881     if(e.classname == "spike")
 882         error("Removing spikes is forbidden (crylink bug), please report");
 883     builtin_remove(e);
 884 }
 885
 886 void remove_safely(entity e)
 887 {
 888     make_safe_for_remove(e);
 889     builtin_remove(e);
 890 }
 891
 892 void InitializeEntity(entity e, void(entity this) func, int order)
 893 {
 894     entity prev, cur;
 895
 896     if (!e || e.initialize_entity)
 897     {
 898         // make a proxy initializer entity
 899         entity e_old = e;
 900         e = new(initialize_entity);
 901         e.enemy = e_old;
 902     }
 903
 904     e.initialize_entity = func;
 905     e.initialize_entity_order = order;
 906
 907     cur = initialize_entity_first;
 908     prev = NULL;
 909     for (;;)
 910     {
 911         if (!cur || cur.initialize_entity_order > order)
 912         {
 913             // insert between prev and cur
 914             if (prev)
 915                 prev.initialize_entity_next = e;
 916             else
 917                 initialize_entity_first = e;
 918             e.initialize_entity_next = cur;
 919             return;
 920         }
 921         prev = cur;
 922         cur = cur.initialize_entity_next;
 923     }
 924 }
 925 void InitializeEntitiesRun()
 926 {
 927     entity startoflist = initialize_entity_first;
 928     initialize_entity_first = NULL;
 929     delete_fn = remove_except_protected;
 930     for (entity e = startoflist; e; e = e.initialize_entity_next)
 931     {
 932                 e.remove_except_protected_forbidden = 1;
 933     }
 934     for (entity e = startoflist; e; )
 935     {
 936                 e.remove_except_protected_forbidden = 0;
 937         e.initialize_entity_order = 0;
 938         entity next = e.initialize_entity_next;
 939         e.initialize_entity_next = NULL;
 940         var void(entity this) func = e.initialize_entity;
 941         e.initialize_entity = func_null;
 942         if (e.classname == "initialize_entity")
 943         {
 944             entity wrappee = e.enemy;
 945             builtin_remove(e);
 946             e = wrappee;
 947         }
 948         //dprint("Delayed initialization: ", e.classname, "\n");
 949         if (func)
 950         {
 951                 func(e);
 952         }
 953         else
 954         {
 955             eprint(e);
 956             backtrace(strcat("Null function in: ", e.classname, "\n"));
 957         }
 958         e = next;
 959     }
 960     delete_fn = remove_unsafely;
 961 }
 962
 963 .float(entity) isEliminated;
 964 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 965 {
 966         Stream out = MSG_ENTITY;
 967         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 968         serialize(byte, out, sendflags);
 969         if (sendflags & 1) {
 970                 for (int i = 1; i <= maxclients; i += 8) {
 971                         int f = 0;
 972                         entity e = edict_num(i);
 973                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 974                                 if (eliminatedPlayers.isEliminated(e)) {
 975                                         f |= BIT(b);
 976                                 }
 977                         }
 978                         serialize(byte, out, f);
 979                 }
 980         }
 981         return true;
 982 }
 983
 984 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 985 {
 986         if(eliminatedPlayers)
 987         {
 988                 backtrace("Can't spawn eliminatedPlayers again!");
 989                 return;
 990         }
 991         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 992         eliminatedPlayers.isEliminated = isEliminated_func;
 993 }
 994
 995
 996
 997
 998 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 999 {
1000         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1001                 this.projectiledeathtype |= HITTYPE_SPLASH;
1002         adaptor_think2use(this);
1003 }
1004
1005 // deferred dropping
1006 void DropToFloor_Handler(entity this)
1007 {
1008     WITHSELF(this, builtin_droptofloor());
1009     this.dropped_origin = this.origin;
1010 }
1011
1012 void droptofloor(entity this)
1013 {
1014     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1015 }
1016
1017
1018
1019 float trace_hits_box_a0, trace_hits_box_a1;
1020
1021 float trace_hits_box_1d(float end, float thmi, float thma)
1022 {
1023     if (end == 0)
1024     {
1025         // just check if x is in range
1026         if (0 < thmi)
1027             return false;
1028         if (0 > thma)
1029             return false;
1030     }
1031     else
1032     {
1033         // do the trace with respect to x
1034         // 0 -> end has to stay in thmi -> thma
1035         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1036         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1037         if (trace_hits_box_a0 > trace_hits_box_a1)
1038             return false;
1039     }
1040     return true;
1041 }
1042
1043 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1044 {
1045     end -= start;
1046     thmi -= start;
1047     thma -= start;
1048     // now it is a trace from 0 to end
1049
1050     trace_hits_box_a0 = 0;
1051     trace_hits_box_a1 = 1;
1052
1053     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1054         return false;
1055     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1056         return false;
1057     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1058         return false;
1059
1060     return true;
1061 }
1062
1063 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1064 {
1065     return trace_hits_box(start, end, thmi - ma, thma - mi);
1066 }
1067
1068 bool SUB_NoImpactCheck(entity this, entity toucher)
1069 {
1070         // zero hitcontents = this is not the real impact, but either the
1071         // mirror-impact of something hitting the projectile instead of the
1072         // projectile hitting the something, or a touchareagrid one. Neither of
1073         // these stop the projectile from moving, so...
1074         if(trace_dphitcontents == 0)
1075         {
1076                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1077                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1078         }
1079     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1080         return true;
1081     if (toucher == NULL && this.size != '0 0 0')
1082     {
1083         vector tic;
1084         tic = this.velocity * sys_frametime;
1085         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1086         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1087         if (trace_fraction >= 1)
1088         {
1089             LOG_TRACE("Odd... did not hit...?");
1090         }
1091         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1092         {
1093             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1094             return true;
1095         }
1096     }
1097
1098     return false;
1099 }
1100
1101 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1102
1103 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1104 {
1105         if(SUB_OwnerCheck(this, toucher))
1106                 return true;
1107         if(SUB_NoImpactCheck(this, toucher))
1108         {
1109                 if(this.classname == "nade")
1110                         return false; // no checks here
1111                 else if(this.classname == "grapplinghook")
1112                         RemoveHook(this);
1113                 else if(this.classname == "spike")
1114                 {
1115                         W_Crylink_Dequeue(this);
1116                         delete(this);
1117                 }
1118                 else
1119                         delete(this);
1120                 return true;
1121         }
1122         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1123                 UpdateCSQCProjectile(this);
1124         return false;
1125 }
1126
1127 /** engine callback */
1128 void URI_Get_Callback(float id, float status, string data)
1129 {
1130         if(url_URI_Get_Callback(id, status, data))
1131         {
1132                 // handled
1133         }
1134         else if (id == URI_GET_DISCARD)
1135         {
1136                 // discard
1137         }
1138         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1139         {
1140                 // sv_cmd curl
1141                 Curl_URI_Get_Callback(id, status, data);
1142         }
1143         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1144         {
1145                 // online ban list
1146                 OnlineBanList_URI_Get_Callback(id, status, data);
1147         }
1148         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1149         {
1150                 // handled by a mutator
1151         }
1152         else
1153         {
1154                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1155         }
1156 }
1157
1158 string uid2name(string myuid) {
1159         string s;
1160         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1161
1162         // FIXME remove this later after 0.6 release
1163         // convert old style broken records to correct style
1164         if(s == "")
1165         {
1166                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1167                 if(s != "")
1168                 {
1169                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1170                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1171                 }
1172         }
1173
1174         if(s == "")
1175                 s = "^1Unregistered Player";
1176         return s;
1177 }
1178
1179 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1180 {
1181     float m, i;
1182     vector start, org, delta, end, enddown, mstart;
1183
1184     m = e.dphitcontentsmask;
1185     e.dphitcontentsmask = goodcontents | badcontents;
1186
1187     org = boundmin;
1188     delta = boundmax - boundmin;
1189
1190     start = end = org;
1191
1192     for (i = 0; i < attempts; ++i)
1193     {
1194         start.x = org.x + random() * delta.x;
1195         start.y = org.y + random() * delta.y;
1196         start.z = org.z + random() * delta.z;
1197
1198         // rule 1: start inside world bounds, and outside
1199         // solid, and don't start from somewhere where you can
1200         // fall down to evil
1201         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1202         if (trace_fraction >= 1)
1203             continue;
1204         if (trace_startsolid)
1205             continue;
1206         if (trace_dphitcontents & badcontents)
1207             continue;
1208         if (trace_dphitq3surfaceflags & badsurfaceflags)
1209             continue;
1210
1211         // rule 2: if we are too high, lower the point
1212         if (trace_fraction * delta.z > maxaboveground)
1213             start = trace_endpos + '0 0 1' * maxaboveground;
1214         enddown = trace_endpos;
1215
1216         // rule 3: make sure we aren't outside the map. This only works
1217         // for somewhat well formed maps. A good rule of thumb is that
1218         // the map should have a convex outside hull.
1219         // these can be traceLINES as we already verified the starting box
1220         mstart = start + 0.5 * (e.mins + e.maxs);
1221         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1222         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1223             continue;
1224         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1225         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1226             continue;
1227         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1228         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1229             continue;
1230         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1231         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1232             continue;
1233         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1234         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1235             continue;
1236
1237         // rule 4: we must "see" some spawnpoint or item
1238     entity sp = NULL;
1239     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1240     {
1241         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1242         {
1243                 sp = it;
1244                 break;
1245         }
1246     });
1247         if(!sp)
1248         {
1249                 int items_checked = 0;
1250                 IL_EACH(g_items, checkpvs(mstart, it),
1251                 {
1252                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1253                         {
1254                                 sp = it;
1255                                 break;
1256                         }
1257
1258                         ++items_checked;
1259                         if(items_checked >= attempts)
1260                                 break; // sanity
1261                 });
1262
1263                 if(!sp)
1264                         continue;
1265         }
1266
1267         // find a random vector to "look at"
1268         end.x = org.x + random() * delta.x;
1269         end.y = org.y + random() * delta.y;
1270         end.z = org.z + random() * delta.z;
1271         end = start + normalize(end - start) * vlen(delta);
1272
1273         // rule 4: start TO end must not be too short
1274         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1275         if (trace_startsolid)
1276             continue;
1277         if (trace_fraction < minviewdistance / vlen(delta))
1278             continue;
1279
1280         // rule 5: don't want to look at sky
1281         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1282             continue;
1283
1284         // rule 6: we must not end up in trigger_hurt
1285         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1286             continue;
1287
1288         break;
1289     }
1290
1291     e.dphitcontentsmask = m;
1292
1293     if (i < attempts)
1294     {
1295         setorigin(e, start);
1296         e.angles = vectoangles(end - start);
1297         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1298         return true;
1299     }
1300     else
1301         return false;
1302 }
1303
1304 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1305 {
1306         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1307 }
1308
1309 void write_recordmarker(entity pl, float tstart, float dt)
1310 {
1311     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1312
1313     // also write a marker into demo files for demotc-race-record-extractor to find
1314     stuffcmd(pl,
1315              strcat(
1316                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1317                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1318 }
1319
1320 void attach_sameorigin(entity e, entity to, string tag)
1321 {
1322     vector org, t_forward, t_left, t_up, e_forward, e_up;
1323     float tagscale;
1324
1325     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1326     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1327     t_forward = v_forward * tagscale;
1328     t_left = v_right * -tagscale;
1329     t_up = v_up * tagscale;
1330
1331     e.origin_x = org * t_forward;
1332     e.origin_y = org * t_left;
1333     e.origin_z = org * t_up;
1334
1335     // current forward and up directions
1336     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1337                 e.angles = AnglesTransform_FromVAngles(e.angles);
1338         else
1339                 e.angles = AnglesTransform_FromAngles(e.angles);
1340     fixedmakevectors(e.angles);
1341
1342     // untransform forward, up!
1343     e_forward.x = v_forward * t_forward;
1344     e_forward.y = v_forward * t_left;
1345     e_forward.z = v_forward * t_up;
1346     e_up.x = v_up * t_forward;
1347     e_up.y = v_up * t_left;
1348     e_up.z = v_up * t_up;
1349
1350     e.angles = fixedvectoangles2(e_forward, e_up);
1351     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1352                 e.angles = AnglesTransform_ToVAngles(e.angles);
1353         else
1354                 e.angles = AnglesTransform_ToAngles(e.angles);
1355
1356     setattachment(e, to, tag);
1357     setorigin(e, e.origin);
1358 }
1359
1360 void detach_sameorigin(entity e)
1361 {
1362     vector org;
1363     org = gettaginfo(e, 0);
1364     e.angles = fixedvectoangles2(v_forward, v_up);
1365     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1366                 e.angles = AnglesTransform_ToVAngles(e.angles);
1367         else
1368                 e.angles = AnglesTransform_ToAngles(e.angles);
1369     setorigin(e, org);
1370     setattachment(e, NULL, "");
1371     setorigin(e, e.origin);
1372 }
1373
1374 void follow_sameorigin(entity e, entity to)
1375 {
1376     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1377     e.aiment = to; // make the hole follow bmodel
1378     e.punchangle = to.angles; // the original angles of bmodel
1379     e.view_ofs = e.origin - to.origin; // relative origin
1380     e.v_angle = e.angles - to.angles; // relative angles
1381 }
1382
1383 void unfollow_sameorigin(entity e)
1384 {
1385     set_movetype(e, MOVETYPE_NONE);
1386 }
1387
1388 entity gettaginfo_relative_ent;
1389 vector gettaginfo_relative(entity e, float tag)
1390 {
1391     if (!gettaginfo_relative_ent)
1392     {
1393         gettaginfo_relative_ent = spawn();
1394         gettaginfo_relative_ent.effects = EF_NODRAW;
1395     }
1396     gettaginfo_relative_ent.model = e.model;
1397     gettaginfo_relative_ent.modelindex = e.modelindex;
1398     gettaginfo_relative_ent.frame = e.frame;
1399     return gettaginfo(gettaginfo_relative_ent, tag);
1400 }
1401
1402 .string aiment_classname;
1403 .float aiment_deadflag;
1404 void SetMovetypeFollow(entity ent, entity e)
1405 {
1406         // FIXME this may not be warpzone aware
1407         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1408         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1409         ent.aiment = e; // make the hole follow bmodel
1410         ent.punchangle = e.angles; // the original angles of bmodel
1411         ent.view_ofs = ent.origin - e.origin; // relative origin
1412         ent.v_angle = ent.angles - e.angles; // relative angles
1413         ent.aiment_classname = strzone(e.classname);
1414         ent.aiment_deadflag = e.deadflag;
1415 }
1416 void UnsetMovetypeFollow(entity ent)
1417 {
1418         set_movetype(ent, MOVETYPE_FLY);
1419         PROJECTILE_MAKETRIGGER(ent);
1420         ent.aiment = NULL;
1421 }
1422 float LostMovetypeFollow(entity ent)
1423 {
1424 /*
1425         if(ent.move_movetype != MOVETYPE_FOLLOW)
1426                 if(ent.aiment)
1427                         error("???");
1428 */
1429         if(ent.aiment)
1430         {
1431                 if(ent.aiment.classname != ent.aiment_classname)
1432                         return 1;
1433                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1434                         return 1;
1435         }
1436         return 0;
1437 }
1438
1439 .bool pushable;
1440 bool isPushable(entity e)
1441 {
1442         if(e.pushable)
1443                 return true;
1444         if(IS_VEHICLE(e))
1445                 return false;
1446         if(e.iscreature)
1447                 return true;
1448         if (Item_IsLoot(e))
1449         {
1450                 return true;
1451         }
1452         switch(e.classname)
1453         {
1454                 case "body":
1455                         return true;
1456                 case "bullet": // antilagged bullets can't hit this either
1457                         return false;
1458         }
1459         if (e.projectiledeathtype)
1460                 return true;
1461         return false;
1462 }