qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "weapons/accuracy.qh"
  12 #include "weapons/csqcprojectile.qh"
  13 #include "weapons/selection.qh"
  14 #include "../common/command/_mod.qh"
  15 #include "../common/constants.qh"
  16 #include <common/net_linked.qh>
  17 #include "../common/deathtypes/all.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/notifications/all.qh"
  20 #include "../common/playerstats.qh"
  21 #include "../common/teams.qh"
  22 #include "../common/triggers/subs.qh"
  23 #include "../common/util.qh"
  24 #include "../common/turrets/sv_turrets.qh"
  25 #include <common/weapons/_all.qh>
  26 #include "../common/vehicles/sv_vehicles.qh"
  27 #include "../common/vehicles/vehicle.qh"
  28 #include "../common/items/_mod.qh"
  29 #include "../common/state.qh"
  30 #include "../common/effects/qc/globalsound.qh"
  31 #include "../common/wepent.qh"
  32 #include "../lib/csqcmodel/sv_model.qh"
  33 #include "../lib/warpzone/anglestransform.qh"
  34 #include "../lib/warpzone/server.qh"
  35
  36 void crosshair_trace(entity pl)
  37 {
  38         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  39 }
  40 .bool ctrace_solidchanged;
  41 void crosshair_trace_plusvisibletriggers(entity pl)
  42 {
  43         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  44         {
  45                 if(it.model != "")
  46                 {
  47                         it.solid = SOLID_BSP;
  48                         it.ctrace_solidchanged = true;
  49                         IL_PUSH(g_ctrace_changed, it);
  50                 }
  51         });
  52
  53         crosshair_trace(pl);
  54
  55         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  56         {
  57                 it.solid = SOLID_TRIGGER;
  58                 it.ctrace_solidchanged = false;
  59         });
  60
  61         IL_CLEAR(g_ctrace_changed);
  62 }
  63 void WarpZone_crosshair_trace(entity pl)
  64 {
  65         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  66 }
  67
  68
  69 void GameLogEcho(string s)
  70 {
  71     string fn;
  72     int matches;
  73
  74     if (autocvar_sv_eventlog_files)
  75     {
  76         if (!logfile_open)
  77         {
  78             logfile_open = true;
  79             matches = autocvar_sv_eventlog_files_counter + 1;
  80             cvar_set("sv_eventlog_files_counter", itos(matches));
  81             fn = ftos(matches);
  82             if (strlen(fn) < 8)
  83                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  84             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  85             logfile = fopen(fn, FILE_APPEND);
  86             fputs(logfile, ":logversion:3\n");
  87         }
  88         if (logfile >= 0)
  89         {
  90             if (autocvar_sv_eventlog_files_timestamps)
  91                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  92             else
  93                 fputs(logfile, strcat(s, "\n"));
  94         }
  95     }
  96     if (autocvar_sv_eventlog_console)
  97     {
  98         dedicated_print(strcat(s, "\n"));
  99     }
 100 }
 101
 102 void GameLogInit()
 103 {
 104     logfile_open = 0;
 105     // will be opened later
 106 }
 107
 108 void GameLogClose()
 109 {
 110     if (logfile_open && logfile >= 0)
 111     {
 112         fclose(logfile);
 113         logfile = -1;
 114     }
 115 }
 116
 117 entity findnearest(vector point, bool checkitems, vector axismod)
 118 {
 119     vector dist;
 120     int num_nearest = 0;
 121
 122     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 123     {
 124         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 125             dist = it.oldorigin;
 126         else
 127             dist = it.origin;
 128         dist = dist - point;
 129         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 130         float len = vlen2(dist);
 131
 132         int l;
 133         for (l = 0; l < num_nearest; ++l)
 134         {
 135             if (len < nearest_length[l])
 136                 break;
 137         }
 138
 139         // now i tells us where to insert at
 140         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 141         if (l < NUM_NEAREST_ENTITIES)
 142         {
 143             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 144             {
 145                 nearest_length[j + 1] = nearest_length[j];
 146                 nearest_entity[j + 1] = nearest_entity[j];
 147             }
 148             nearest_length[l] = len;
 149             nearest_entity[l] = it;
 150             if (num_nearest < NUM_NEAREST_ENTITIES)
 151                 num_nearest = num_nearest + 1;
 152         }
 153     });
 154
 155     // now use the first one from our list that we can see
 156     for (int j = 0; j < num_nearest; ++j)
 157     {
 158         traceline(point, nearest_entity[j].origin, true, NULL);
 159         if (trace_fraction == 1)
 160         {
 161             if (j != 0)
 162                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 163             return nearest_entity[j];
 164         }
 165     }
 166
 167     if (num_nearest == 0)
 168         return NULL;
 169
 170     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 171     /* DEBUGGING CODE:
 172     dprint("Candidates were: ");
 173     for(j = 0; j < num_nearest; ++j)
 174     {
 175         if(j != 0)
 176                 dprint(", ");
 177         dprint(nearest_entity[j].netname);
 178     }
 179     dprint("\n");
 180     */
 181
 182     return nearest_entity[0];
 183 }
 184
 185 string NearestLocation(vector p)
 186 {
 187     string ret = "somewhere";
 188     entity loc = findnearest(p, false, '1 1 1');
 189     if (loc)
 190         ret = loc.message;
 191     else
 192     {
 193         loc = findnearest(p, true, '1 1 4');
 194         if (loc)
 195             ret = loc.netname;
 196     }
 197     return ret;
 198 }
 199
 200 string AmmoNameFromWeaponentity(entity wpn)
 201 {
 202         string ammoitems = "batteries";
 203         switch ((wpn.m_weapon).ammo_type)
 204         {
 205                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 206                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 207                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 208                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 209                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 210                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 211         }
 212         return ammoitems;
 213 }
 214
 215 string formatmessage(entity this, string msg)
 216 {
 217         float p, p1, p2;
 218         float n;
 219         vector cursor;
 220         entity cursor_ent;
 221         string escape;
 222         string replacement;
 223         p = 0;
 224         n = 7;
 225
 226         WarpZone_crosshair_trace(this);
 227         cursor = trace_endpos;
 228         cursor_ent = trace_ent;
 229
 230         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 231         msg = M_ARGV(1, string);
 232
 233         while (1) {
 234                 if (n < 1)
 235                         break; // too many replacements
 236
 237                 n = n - 1;
 238                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 239                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 240
 241                 if (p1 < 0)
 242                         p1 = p2;
 243
 244                 if (p2 < 0)
 245                         p2 = p1;
 246
 247                 p = min(p1, p2);
 248
 249                 if (p < 0)
 250                         break;
 251
 252                 replacement = substring(msg, p, 2);
 253                 escape = substring(msg, p + 1, 1);
 254
 255                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 256
 257                 switch(escape)
 258                 {
 259                         case "%": replacement = "%"; break;
 260                         case "\\":replacement = "\\"; break;
 261                         case "n": replacement = "\n"; break;
 262                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 263                         case "h": replacement = ftos(floor(this.health)); break;
 264                         case "l": replacement = NearestLocation(this.origin); break;
 265                         case "y": replacement = NearestLocation(cursor); break;
 266                         case "d": replacement = NearestLocation(this.death_origin); break;
 267                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 268                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 269                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 270                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 271                         case "S": replacement = ftos(vlen(this.velocity)); break;
 272                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 273                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 274                         default:
 275                         {
 276                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 277                                 replacement = M_ARGV(2, string);
 278                                 break;
 279                         }
 280                 }
 281
 282                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 283                 p = p + strlen(replacement);
 284         }
 285         return msg;
 286 }
 287
 288 /*
 289 =============
 290 GetCvars
 291 =============
 292 Called with:
 293   0:  sends the request
 294   >0: receives a cvar from name=argv(f) value=argv(f+1)
 295 */
 296 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 297 {
 298         if (f < 0)
 299         {
 300                 if (store.(field))
 301                         strunzone(store.(field));
 302                 store.(field) = string_null;
 303         }
 304         else if (f > 0)
 305         {
 306                 if (thisname == name)
 307                 {
 308                         if (store.(field))
 309                                 strunzone(store.(field));
 310                         store.(field) = strzone(argv(f + 1));
 311                 }
 312         }
 313         else
 314                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 315 }
 316 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 317 {
 318         GetCvars_handleString(this, store, thisname, f, field, name);
 319         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 320                 if (thisname == name)
 321                 {
 322                         string s = func(this, strcat1(store.(field)));
 323                         if (s != store.(field))
 324                         {
 325                                 strunzone(store.(field));
 326                                 store.(field) = strzone(s);
 327                         }
 328                 }
 329 }
 330 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 331 {
 332         if (f < 0)
 333         {
 334         }
 335         else if (f > 0)
 336         {
 337                 if (thisname == name)
 338                         store.(field) = stof(argv(f + 1));
 339         }
 340         else
 341                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 342 }
 343 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 344 {
 345         if (f < 0)
 346         {
 347         }
 348         else if (f > 0)
 349         {
 350                 if (thisname == name)
 351                 {
 352                         if (!store.(field))
 353                         {
 354                                 store.(field) = stof(argv(f + 1));
 355                                 if (!store.(field))
 356                                         store.(field) = -1;
 357                         }
 358                 }
 359         }
 360         else
 361         {
 362                 if (!store.(field))
 363                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 364         }
 365 }
 366 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 367 {
 368         string o;
 369         o = W_FixWeaponOrder_ForceComplete(wo);
 370         if(this.weaponorder_byimpulse)
 371         {
 372                 strunzone(this.weaponorder_byimpulse);
 373                 this.weaponorder_byimpulse = string_null;
 374         }
 375         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 376         return o;
 377 }
 378
 379 REPLICATE(autoswitch, bool, "cl_autoswitch");
 380
 381 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 382
 383 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 384
 385 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 386
 387 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 388
 389 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 390
 391 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 392
 393 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 394
 395 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 396
 397 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 398
 399 REPLICATE(cvar_cl_physics, string, "cl_physics");
 400
 401 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 402
 403 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 404
 405 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 406
 407 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 408
 409 /**
 410  * @param f -1: cleanup, 0: request, 1: receive
 411  */
 412 void GetCvars(entity this, entity store, int f)
 413 {
 414         string s = string_null;
 415
 416         if (f > 0)
 417                 s = strcat1(argv(f));
 418
 419         get_cvars_f = f;
 420         get_cvars_s = s;
 421         MUTATOR_CALLHOOK(GetCvars);
 422
 423         Notification_GetCvars(this);
 424
 425         ReplicateVars(this, store, s, f);
 426
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 438
 439         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 440
 441         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 442         if (f > 0)
 443         {
 444                 if (s == "cl_weaponpriority")
 445                 {
 446                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 447                         {
 448                                 .entity weaponentity = weaponentities[slot];
 449                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 450                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 451                         }
 452                 }
 453                 if (s == "cl_allow_uidtracking")
 454                         PlayerStats_GameReport_AddPlayer(this);
 455         }
 456 }
 457
 458 // decolorizes and team colors the player name when needed
 459 string playername(entity p, bool team_colorize)
 460 {
 461     string t;
 462     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 463     {
 464         t = Team_ColorCode(p.team);
 465         return strcat(t, strdecolorize(p.netname));
 466     }
 467     else
 468         return p.netname;
 469 }
 470
 471 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 472 {
 473         int i = weaponinfo.m_id;
 474         int d = 0;
 475         bool allow_mutatorblocked = false;
 476
 477         if(!i)
 478                 return 0;
 479
 480         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 481         d = M_ARGV(1, float);
 482         allguns = M_ARGV(2, bool);
 483         allow_mutatorblocked = M_ARGV(3, bool);
 484
 485         if(allguns)
 486         {
 487                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 488                         d = true;
 489                 else
 490                         d = false;
 491         }
 492         else if(!mutator_returnvalue)
 493                 d = !(!weaponinfo.weaponstart);
 494
 495         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 496                 d = 0;
 497
 498         float t = weaponinfo.weaponstartoverride;
 499
 500         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 501
 502         // bit order in t:
 503         // 1: want or not
 504         // 2: is default?
 505         // 4: is set by default?
 506         if(t < 0)
 507                 t = 4 | (3 * d);
 508         else
 509                 t |= (2 * d);
 510
 511         return t;
 512 }
 513
 514 void readplayerstartcvars()
 515 {
 516         float i, t;
 517         string s;
 518
 519         // initialize starting values for players
 520         start_weapons = '0 0 0';
 521         start_weapons_default = '0 0 0';
 522         start_weapons_defaultmask = '0 0 0';
 523         start_items = 0;
 524         start_ammo_shells = 0;
 525         start_ammo_nails = 0;
 526         start_ammo_rockets = 0;
 527         start_ammo_cells = 0;
 528         start_ammo_plasma = 0;
 529         if (random_start_ammo == NULL)
 530         {
 531                 random_start_ammo = spawn();
 532         }
 533         start_health = cvar("g_balance_health_start");
 534         start_armorvalue = cvar("g_balance_armor_start");
 535
 536         g_weaponarena = 0;
 537         g_weaponarena_weapons = '0 0 0';
 538
 539         s = cvar_string("g_weaponarena");
 540
 541         MUTATOR_CALLHOOK(SetWeaponArena, s);
 542         s = M_ARGV(0, string);
 543
 544         if (s == "0" || s == "")
 545         {
 546                 // no arena
 547         }
 548         else if (s == "off")
 549         {
 550                 // forcibly turn off weaponarena
 551         }
 552         else if (s == "all" || s == "1")
 553         {
 554                 g_weaponarena = 1;
 555                 g_weaponarena_list = "All Weapons";
 556                 FOREACH(Weapons, it != WEP_Null, {
 557                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 558                                 g_weaponarena_weapons |= (it.m_wepset);
 559                 });
 560         }
 561         else if (s == "devall")
 562         {
 563                 g_weaponarena = 1;
 564                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 565                 FOREACH(Weapons, it != WEP_Null,
 566                 {
 567                         g_weaponarena_weapons |= (it.m_wepset);
 568                 });
 569         }
 570         else if (s == "most")
 571         {
 572                 g_weaponarena = 1;
 573                 g_weaponarena_list = "Most Weapons";
 574                 FOREACH(Weapons, it != WEP_Null, {
 575                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 576                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 577                                         g_weaponarena_weapons |= (it.m_wepset);
 578                 });
 579         }
 580         else if (s == "none")
 581         {
 582                 g_weaponarena = 1;
 583                 g_weaponarena_list = "No Weapons";
 584         }
 585         else
 586         {
 587                 g_weaponarena = 1;
 588                 t = tokenize_console(s);
 589                 g_weaponarena_list = "";
 590                 for (i = 0; i < t; ++i)
 591                 {
 592                         s = argv(i);
 593                         FOREACH(Weapons, it != WEP_Null, {
 594                                 if(it.netname == s)
 595                                 {
 596                                         g_weaponarena_weapons |= (it.m_wepset);
 597                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 598                                         break;
 599                                 }
 600                         });
 601                 }
 602                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 603         }
 604
 605         if(g_weaponarena)
 606                 g_weaponarena_random = cvar("g_weaponarena_random");
 607         else
 608                 g_weaponarena_random = 0;
 609         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 610
 611         if (g_weaponarena)
 612         {
 613                 g_weapon_stay = 0; // incompatible
 614                 start_weapons = g_weaponarena_weapons;
 615                 start_items |= IT_UNLIMITED_AMMO;
 616         }
 617         else
 618         {
 619                 FOREACH(Weapons, it != WEP_Null, {
 620                         int w = want_weapon(it, false);
 621                         WepSet s = it.m_wepset;
 622                         if(w & 1)
 623                                 start_weapons |= s;
 624                         if(w & 2)
 625                                 start_weapons_default |= s;
 626                         if(w & 4)
 627                                 start_weapons_defaultmask |= s;
 628                 });
 629         }
 630
 631         if(!cvar("g_use_ammunition"))
 632                 start_items |= IT_UNLIMITED_AMMO;
 633
 634         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 635         {
 636                 start_ammo_shells = 999;
 637                 start_ammo_nails = 999;
 638                 start_ammo_rockets = 999;
 639                 start_ammo_cells = 999;
 640                 start_ammo_plasma = 999;
 641                 start_ammo_fuel = 999;
 642         }
 643         else
 644         {
 645                 start_ammo_shells = cvar("g_start_ammo_shells");
 646                 start_ammo_nails = cvar("g_start_ammo_nails");
 647                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 648                 start_ammo_cells = cvar("g_start_ammo_cells");
 649                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 650                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 651                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 652                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 653                         "g_random_start_shells"));
 654                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 655                         "g_random_start_bullets"));
 656                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 657                         cvar("g_random_start_rockets"));
 658                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 659                         "g_random_start_cells"));
 660                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 661                         "g_random_start_plasma"));
 662         }
 663
 664         if (warmup_stage)
 665         {
 666                 warmup_start_ammo_shells = start_ammo_shells;
 667                 warmup_start_ammo_nails = start_ammo_nails;
 668                 warmup_start_ammo_rockets = start_ammo_rockets;
 669                 warmup_start_ammo_cells = start_ammo_cells;
 670                 warmup_start_ammo_plasma = start_ammo_plasma;
 671                 warmup_start_ammo_fuel = start_ammo_fuel;
 672                 warmup_start_health = start_health;
 673                 warmup_start_armorvalue = start_armorvalue;
 674                 warmup_start_weapons = start_weapons;
 675                 warmup_start_weapons_default = start_weapons_default;
 676                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 677
 678                 if (!g_weaponarena && !g_ca && !g_freezetag)
 679                 {
 680                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 681                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 682                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 683                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 684                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 685                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 686                         warmup_start_health = cvar("g_warmup_start_health");
 687                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 688                         warmup_start_weapons = '0 0 0';
 689                         warmup_start_weapons_default = '0 0 0';
 690                         warmup_start_weapons_defaultmask = '0 0 0';
 691                         FOREACH(Weapons, it != WEP_Null, {
 692                                 int w = want_weapon(it, g_warmup_allguns);
 693                                 WepSet s = (it.m_wepset);
 694                                 if(w & 1)
 695                                         warmup_start_weapons |= s;
 696                                 if(w & 2)
 697                                         warmup_start_weapons_default |= s;
 698                                 if(w & 4)
 699                                         warmup_start_weapons_defaultmask |= s;
 700                         });
 701                 }
 702         }
 703
 704         if (g_jetpack)
 705                 start_items |= ITEM_Jetpack.m_itemid;
 706
 707         MUTATOR_CALLHOOK(SetStartItems);
 708
 709         if (start_items & ITEM_Jetpack.m_itemid)
 710         {
 711                 start_items |= ITEM_JetpackRegen.m_itemid;
 712                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 713                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 714         }
 715
 716         WepSet precache_weapons = start_weapons;
 717         if (g_warmup_allguns != 1)
 718                 precache_weapons |= warmup_start_weapons;
 719         FOREACH(Weapons, it != WEP_Null, {
 720                 if(precache_weapons & (it.m_wepset))
 721                         it.wr_init(it);
 722         });
 723
 724         start_ammo_shells = max(0, start_ammo_shells);
 725         start_ammo_nails = max(0, start_ammo_nails);
 726         start_ammo_rockets = max(0, start_ammo_rockets);
 727         start_ammo_cells = max(0, start_ammo_cells);
 728         start_ammo_plasma = max(0, start_ammo_plasma);
 729         start_ammo_fuel = max(0, start_ammo_fuel);
 730         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 731                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 732         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 733                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 734         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 735                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 736         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 737                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 738         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 739                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 740
 741         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 742         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 743         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 744         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 745         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 746         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 747 }
 748
 749 void precache_playermodel(string m)
 750 {
 751         float globhandle, i, n;
 752         string f;
 753
 754         if(substring(m, -9,5) == "_lod1")
 755                 return;
 756         if(substring(m, -9,5) == "_lod2")
 757                 return;
 758         precache_model(m);
 759         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 760         if(fexists(f))
 761                 precache_model(f);
 762         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 763         if(fexists(f))
 764                 precache_model(f);
 765
 766         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 767         if (globhandle < 0)
 768                 return;
 769         n = search_getsize(globhandle);
 770         for (i = 0; i < n; ++i)
 771         {
 772                 //print(search_getfilename(globhandle, i), "\n");
 773                 f = search_getfilename(globhandle, i);
 774                 PrecachePlayerSounds(f);
 775         }
 776         search_end(globhandle);
 777 }
 778 void precache_all_playermodels(string pattern)
 779 {
 780         int globhandle = search_begin(pattern, true, false);
 781         if (globhandle < 0) return;
 782         int n = search_getsize(globhandle);
 783         for (int i = 0; i < n; ++i)
 784         {
 785                 string s = search_getfilename(globhandle, i);
 786                 precache_playermodel(s);
 787         }
 788         search_end(globhandle);
 789 }
 790
 791 void precache_playermodels(string s)
 792 {
 793         FOREACH_WORD(s, true, { precache_playermodel(it); });
 794 }
 795
 796 void precache()
 797 {
 798     // gamemode related things
 799
 800     // Precache all player models if desired
 801     if (autocvar_sv_precacheplayermodels)
 802     {
 803         PrecachePlayerSounds("sound/player/default.sounds");
 804         precache_all_playermodels("models/player/*.zym");
 805         precache_all_playermodels("models/player/*.dpm");
 806         precache_all_playermodels("models/player/*.md3");
 807         precache_all_playermodels("models/player/*.psk");
 808         precache_all_playermodels("models/player/*.iqm");
 809     }
 810
 811     if (autocvar_sv_defaultcharacter)
 812     {
 813                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 814                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 815                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 816                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 817                 precache_playermodels(autocvar_sv_defaultplayermodel);
 818     }
 819
 820 #if 0
 821     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 822
 823     if (!this.noise && this.music) // quake 3 uses the music field
 824         this.noise = this.music;
 825
 826     // plays music for the level if there is any
 827     if (this.noise)
 828     {
 829         precache_sound (this.noise);
 830         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 831     }
 832 #endif
 833 }
 834
 835
 836 void make_safe_for_remove(entity e)
 837 {
 838     if (e.initialize_entity)
 839     {
 840         entity ent, prev = NULL;
 841         for (ent = initialize_entity_first; ent; )
 842         {
 843             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 844             {
 845                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 846                 // skip it in linked list
 847                 if (prev)
 848                 {
 849                     prev.initialize_entity_next = ent.initialize_entity_next;
 850                     ent = prev.initialize_entity_next;
 851                 }
 852                 else
 853                 {
 854                     initialize_entity_first = ent.initialize_entity_next;
 855                     ent = initialize_entity_first;
 856                 }
 857             }
 858             else
 859             {
 860                 prev = ent;
 861                 ent = ent.initialize_entity_next;
 862             }
 863         }
 864     }
 865 }
 866
 867 .float remove_except_protected_forbidden;
 868 void remove_except_protected(entity e)
 869 {
 870         if(e.remove_except_protected_forbidden)
 871                 error("not allowed to remove this at this point");
 872         builtin_remove(e);
 873 }
 874
 875 void remove_unsafely(entity e)
 876 {
 877     if(e.classname == "spike")
 878         error("Removing spikes is forbidden (crylink bug), please report");
 879     builtin_remove(e);
 880 }
 881
 882 void remove_safely(entity e)
 883 {
 884     make_safe_for_remove(e);
 885     builtin_remove(e);
 886 }
 887
 888 void InitializeEntity(entity e, void(entity this) func, float order)
 889 {
 890     entity prev, cur;
 891
 892     if (!e || e.initialize_entity)
 893     {
 894         // make a proxy initializer entity
 895         entity e_old = e;
 896         e = new(initialize_entity);
 897         e.enemy = e_old;
 898     }
 899
 900     e.initialize_entity = func;
 901     e.initialize_entity_order = order;
 902
 903     cur = initialize_entity_first;
 904     prev = NULL;
 905     for (;;)
 906     {
 907         if (!cur || cur.initialize_entity_order > order)
 908         {
 909             // insert between prev and cur
 910             if (prev)
 911                 prev.initialize_entity_next = e;
 912             else
 913                 initialize_entity_first = e;
 914             e.initialize_entity_next = cur;
 915             return;
 916         }
 917         prev = cur;
 918         cur = cur.initialize_entity_next;
 919     }
 920 }
 921 void InitializeEntitiesRun()
 922 {
 923     entity startoflist = initialize_entity_first;
 924     initialize_entity_first = NULL;
 925     delete_fn = remove_except_protected;
 926     for (entity e = startoflist; e; e = e.initialize_entity_next)
 927     {
 928                 e.remove_except_protected_forbidden = 1;
 929     }
 930     for (entity e = startoflist; e; )
 931     {
 932                 e.remove_except_protected_forbidden = 0;
 933         e.initialize_entity_order = 0;
 934         entity next = e.initialize_entity_next;
 935         e.initialize_entity_next = NULL;
 936         var void(entity this) func = e.initialize_entity;
 937         e.initialize_entity = func_null;
 938         if (e.classname == "initialize_entity")
 939         {
 940             entity wrappee = e.enemy;
 941             builtin_remove(e);
 942             e = wrappee;
 943         }
 944         //dprint("Delayed initialization: ", e.classname, "\n");
 945         if (func)
 946         {
 947                 func(e);
 948         }
 949         else
 950         {
 951             eprint(e);
 952             backtrace(strcat("Null function in: ", e.classname, "\n"));
 953         }
 954         e = next;
 955     }
 956     delete_fn = remove_unsafely;
 957 }
 958
 959 .float(entity) isEliminated;
 960 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 961 {
 962         Stream out = MSG_ENTITY;
 963         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 964         serialize(byte, out, sendflags);
 965         if (sendflags & 1) {
 966                 for (int i = 1; i <= maxclients; i += 8) {
 967                         int f = 0;
 968                         entity e = edict_num(i);
 969                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 970                                 if (eliminatedPlayers.isEliminated(e)) {
 971                                         f |= BIT(b);
 972                                 }
 973                         }
 974                         serialize(byte, out, f);
 975                 }
 976         }
 977         return true;
 978 }
 979
 980 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 981 {
 982         if(eliminatedPlayers)
 983         {
 984                 backtrace("Can't spawn eliminatedPlayers again!");
 985                 return;
 986         }
 987         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 988         eliminatedPlayers.isEliminated = isEliminated_func;
 989 }
 990
 991
 992
 993
 994 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 995 {
 996         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 997                 this.projectiledeathtype |= HITTYPE_SPLASH;
 998         adaptor_think2use(this);
 999 }
1000
1001 // deferred dropping
1002 void DropToFloor_Handler(entity this)
1003 {
1004     WITHSELF(this, builtin_droptofloor());
1005     this.dropped_origin = this.origin;
1006 }
1007
1008 void droptofloor(entity this)
1009 {
1010     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1011 }
1012
1013
1014
1015 float trace_hits_box_a0, trace_hits_box_a1;
1016
1017 float trace_hits_box_1d(float end, float thmi, float thma)
1018 {
1019     if (end == 0)
1020     {
1021         // just check if x is in range
1022         if (0 < thmi)
1023             return false;
1024         if (0 > thma)
1025             return false;
1026     }
1027     else
1028     {
1029         // do the trace with respect to x
1030         // 0 -> end has to stay in thmi -> thma
1031         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1032         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1033         if (trace_hits_box_a0 > trace_hits_box_a1)
1034             return false;
1035     }
1036     return true;
1037 }
1038
1039 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1040 {
1041     end -= start;
1042     thmi -= start;
1043     thma -= start;
1044     // now it is a trace from 0 to end
1045
1046     trace_hits_box_a0 = 0;
1047     trace_hits_box_a1 = 1;
1048
1049     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1050         return false;
1051     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1052         return false;
1053     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1054         return false;
1055
1056     return true;
1057 }
1058
1059 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1060 {
1061     return trace_hits_box(start, end, thmi - ma, thma - mi);
1062 }
1063
1064 bool SUB_NoImpactCheck(entity this, entity toucher)
1065 {
1066         // zero hitcontents = this is not the real impact, but either the
1067         // mirror-impact of something hitting the projectile instead of the
1068         // projectile hitting the something, or a touchareagrid one. Neither of
1069         // these stop the projectile from moving, so...
1070         if(trace_dphitcontents == 0)
1071         {
1072                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1073                 checkclient(this);
1074         }
1075     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1076         return true;
1077     if (toucher == NULL && this.size != '0 0 0')
1078     {
1079         vector tic;
1080         tic = this.velocity * sys_frametime;
1081         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1082         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1083         if (trace_fraction >= 1)
1084         {
1085             LOG_TRACE("Odd... did not hit...?");
1086         }
1087         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1088         {
1089             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1090             return true;
1091         }
1092     }
1093
1094     return false;
1095 }
1096
1097 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1098
1099 void W_Crylink_Dequeue(entity e);
1100 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1101 {
1102         if(SUB_OwnerCheck(this, toucher))
1103                 return true;
1104         if(SUB_NoImpactCheck(this, toucher))
1105         {
1106                 if(this.classname == "nade")
1107                         return false; // no checks here
1108                 else if(this.classname == "grapplinghook")
1109                         RemoveHook(this);
1110                 else if(this.classname == "spike")
1111                 {
1112                         W_Crylink_Dequeue(this);
1113                         delete(this);
1114                 }
1115                 else
1116                         delete(this);
1117                 return true;
1118         }
1119         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1120                 UpdateCSQCProjectile(this);
1121         return false;
1122 }
1123
1124 /** engine callback */
1125 void URI_Get_Callback(float id, float status, string data)
1126 {
1127         if(url_URI_Get_Callback(id, status, data))
1128         {
1129                 // handled
1130         }
1131         else if (id == URI_GET_DISCARD)
1132         {
1133                 // discard
1134         }
1135         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1136         {
1137                 // sv_cmd curl
1138                 Curl_URI_Get_Callback(id, status, data);
1139         }
1140         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1141         {
1142                 // online ban list
1143                 OnlineBanList_URI_Get_Callback(id, status, data);
1144         }
1145         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1146         {
1147                 // handled by a mutator
1148         }
1149         else
1150         {
1151                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1152         }
1153 }
1154
1155 string uid2name(string myuid) {
1156         string s;
1157         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1158
1159         // FIXME remove this later after 0.6 release
1160         // convert old style broken records to correct style
1161         if(s == "")
1162         {
1163                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1164                 if(s != "")
1165                 {
1166                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1167                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1168                 }
1169         }
1170
1171         if(s == "")
1172                 s = "^1Unregistered Player";
1173         return s;
1174 }
1175
1176 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1177 {
1178     float m, i;
1179     vector start, org, delta, end, enddown, mstart;
1180
1181     m = e.dphitcontentsmask;
1182     e.dphitcontentsmask = goodcontents | badcontents;
1183
1184     org = boundmin;
1185     delta = boundmax - boundmin;
1186
1187     start = end = org;
1188
1189     for (i = 0; i < attempts; ++i)
1190     {
1191         start.x = org.x + random() * delta.x;
1192         start.y = org.y + random() * delta.y;
1193         start.z = org.z + random() * delta.z;
1194
1195         // rule 1: start inside world bounds, and outside
1196         // solid, and don't start from somewhere where you can
1197         // fall down to evil
1198         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1199         if (trace_fraction >= 1)
1200             continue;
1201         if (trace_startsolid)
1202             continue;
1203         if (trace_dphitcontents & badcontents)
1204             continue;
1205         if (trace_dphitq3surfaceflags & badsurfaceflags)
1206             continue;
1207
1208         // rule 2: if we are too high, lower the point
1209         if (trace_fraction * delta.z > maxaboveground)
1210             start = trace_endpos + '0 0 1' * maxaboveground;
1211         enddown = trace_endpos;
1212
1213         // rule 3: make sure we aren't outside the map. This only works
1214         // for somewhat well formed maps. A good rule of thumb is that
1215         // the map should have a convex outside hull.
1216         // these can be traceLINES as we already verified the starting box
1217         mstart = start + 0.5 * (e.mins + e.maxs);
1218         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1219         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1220             continue;
1221         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1222         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1223             continue;
1224         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1225         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1226             continue;
1227         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1228         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1229             continue;
1230         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1231         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1232             continue;
1233
1234         // rule 4: we must "see" some spawnpoint or item
1235     entity sp = NULL;
1236     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1237     {
1238         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1239         {
1240                 sp = it;
1241                 break;
1242         }
1243     });
1244         if(!sp)
1245         {
1246                 IL_EACH(g_items, checkpvs(mstart, it),
1247                 {
1248                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1249                         {
1250                                 sp = it;
1251                                 break;
1252                         }
1253                 });
1254
1255                 if(!sp)
1256                         continue;
1257         }
1258
1259         // find a random vector to "look at"
1260         end.x = org.x + random() * delta.x;
1261         end.y = org.y + random() * delta.y;
1262         end.z = org.z + random() * delta.z;
1263         end = start + normalize(end - start) * vlen(delta);
1264
1265         // rule 4: start TO end must not be too short
1266         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1267         if (trace_startsolid)
1268             continue;
1269         if (trace_fraction < minviewdistance / vlen(delta))
1270             continue;
1271
1272         // rule 5: don't want to look at sky
1273         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1274             continue;
1275
1276         // rule 6: we must not end up in trigger_hurt
1277         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1278             continue;
1279
1280         break;
1281     }
1282
1283     e.dphitcontentsmask = m;
1284
1285     if (i < attempts)
1286     {
1287         setorigin(e, start);
1288         e.angles = vectoangles(end - start);
1289         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1290         return true;
1291     }
1292     else
1293         return false;
1294 }
1295
1296 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1297 {
1298         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1299 }
1300
1301 void write_recordmarker(entity pl, float tstart, float dt)
1302 {
1303     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1304
1305     // also write a marker into demo files for demotc-race-record-extractor to find
1306     stuffcmd(pl,
1307              strcat(
1308                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1309                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1310 }
1311
1312 void attach_sameorigin(entity e, entity to, string tag)
1313 {
1314     vector org, t_forward, t_left, t_up, e_forward, e_up;
1315     float tagscale;
1316
1317     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1318     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1319     t_forward = v_forward * tagscale;
1320     t_left = v_right * -tagscale;
1321     t_up = v_up * tagscale;
1322
1323     e.origin_x = org * t_forward;
1324     e.origin_y = org * t_left;
1325     e.origin_z = org * t_up;
1326
1327     // current forward and up directions
1328     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1329                 e.angles = AnglesTransform_FromVAngles(e.angles);
1330         else
1331                 e.angles = AnglesTransform_FromAngles(e.angles);
1332     fixedmakevectors(e.angles);
1333
1334     // untransform forward, up!
1335     e_forward.x = v_forward * t_forward;
1336     e_forward.y = v_forward * t_left;
1337     e_forward.z = v_forward * t_up;
1338     e_up.x = v_up * t_forward;
1339     e_up.y = v_up * t_left;
1340     e_up.z = v_up * t_up;
1341
1342     e.angles = fixedvectoangles2(e_forward, e_up);
1343     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1344                 e.angles = AnglesTransform_ToVAngles(e.angles);
1345         else
1346                 e.angles = AnglesTransform_ToAngles(e.angles);
1347
1348     setattachment(e, to, tag);
1349     setorigin(e, e.origin);
1350 }
1351
1352 void detach_sameorigin(entity e)
1353 {
1354     vector org;
1355     org = gettaginfo(e, 0);
1356     e.angles = fixedvectoangles2(v_forward, v_up);
1357     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1358                 e.angles = AnglesTransform_ToVAngles(e.angles);
1359         else
1360                 e.angles = AnglesTransform_ToAngles(e.angles);
1361     setorigin(e, org);
1362     setattachment(e, NULL, "");
1363     setorigin(e, e.origin);
1364 }
1365
1366 void follow_sameorigin(entity e, entity to)
1367 {
1368     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1369     e.aiment = to; // make the hole follow bmodel
1370     e.punchangle = to.angles; // the original angles of bmodel
1371     e.view_ofs = e.origin - to.origin; // relative origin
1372     e.v_angle = e.angles - to.angles; // relative angles
1373 }
1374
1375 void unfollow_sameorigin(entity e)
1376 {
1377     set_movetype(e, MOVETYPE_NONE);
1378 }
1379
1380 entity gettaginfo_relative_ent;
1381 vector gettaginfo_relative(entity e, float tag)
1382 {
1383     if (!gettaginfo_relative_ent)
1384     {
1385         gettaginfo_relative_ent = spawn();
1386         gettaginfo_relative_ent.effects = EF_NODRAW;
1387     }
1388     gettaginfo_relative_ent.model = e.model;
1389     gettaginfo_relative_ent.modelindex = e.modelindex;
1390     gettaginfo_relative_ent.frame = e.frame;
1391     return gettaginfo(gettaginfo_relative_ent, tag);
1392 }
1393
1394 .string aiment_classname;
1395 .float aiment_deadflag;
1396 void SetMovetypeFollow(entity ent, entity e)
1397 {
1398         // FIXME this may not be warpzone aware
1399         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1400         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1401         ent.aiment = e; // make the hole follow bmodel
1402         ent.punchangle = e.angles; // the original angles of bmodel
1403         ent.view_ofs = ent.origin - e.origin; // relative origin
1404         ent.v_angle = ent.angles - e.angles; // relative angles
1405         ent.aiment_classname = strzone(e.classname);
1406         ent.aiment_deadflag = e.deadflag;
1407 }
1408 void UnsetMovetypeFollow(entity ent)
1409 {
1410         set_movetype(ent, MOVETYPE_FLY);
1411         PROJECTILE_MAKETRIGGER(ent);
1412         ent.aiment = NULL;
1413 }
1414 float LostMovetypeFollow(entity ent)
1415 {
1416 /*
1417         if(ent.move_movetype != MOVETYPE_FOLLOW)
1418                 if(ent.aiment)
1419                         error("???");
1420 */
1421         if(ent.aiment)
1422         {
1423                 if(ent.aiment.classname != ent.aiment_classname)
1424                         return 1;
1425                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1426                         return 1;
1427         }
1428         return 0;
1429 }
1430
1431 .bool pushable;
1432 bool isPushable(entity e)
1433 {
1434         if(e.pushable)
1435                 return true;
1436         if(IS_VEHICLE(e))
1437                 return false;
1438         if(e.iscreature)
1439                 return true;
1440         switch(e.classname)
1441         {
1442                 case "body":
1443                 case "droppedweapon":
1444                         return true;
1445                 case "bullet": // antilagged bullets can't hit this either
1446                         return false;
1447         }
1448         if (e.projectiledeathtype)
1449                 return true;
1450         return false;
1451 }