qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 float w_getbestweapon(entity e);
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 511
 512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 514
 515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 520
 521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 522         if (f > 0)
 523         {
 524                 if (s == "cl_weaponpriority")
 525                         self.switchweapon = w_getbestweapon(self);
 526                 if (s == "cl_allow_uidtracking")
 527                         PlayerStats_AddPlayer(self);
 528         }
 529 }
 530
 531 // decolorizes and team colors the player name when needed
 532 string playername(entity p)
 533 {
 534     string t;
 535     if (teamplay && !intermission_running && IS_PLAYER(p))
 536     {
 537         t = Team_ColorCode(p.team);
 538         return strcat(t, strdecolorize(p.netname));
 539     }
 540     else
 541         return p.netname;
 542 }
 543
 544 vector randompos(vector m1, vector m2)
 545 {
 546     vector v;
 547     m2 = m2 - m1;
 548     v_x = m2_x * random() + m1_x;
 549     v_y = m2_y * random() + m1_y;
 550     v_z = m2_z * random() + m1_z;
 551     return  v;
 552 }
 553
 554 //#NO AUTOCVARS START
 555
 556 float g_pickup_shells;
 557 float g_pickup_shells_max;
 558 float g_pickup_nails;
 559 float g_pickup_nails_max;
 560 float g_pickup_rockets;
 561 float g_pickup_rockets_max;
 562 float g_pickup_cells;
 563 float g_pickup_cells_max;
 564 float g_pickup_fuel;
 565 float g_pickup_fuel_jetpack;
 566 float g_pickup_fuel_max;
 567 float g_pickup_armorsmall;
 568 float g_pickup_armorsmall_max;
 569 float g_pickup_armorsmall_anyway;
 570 float g_pickup_armormedium;
 571 float g_pickup_armormedium_max;
 572 float g_pickup_armormedium_anyway;
 573 float g_pickup_armorbig;
 574 float g_pickup_armorbig_max;
 575 float g_pickup_armorbig_anyway;
 576 float g_pickup_armorlarge;
 577 float g_pickup_armorlarge_max;
 578 float g_pickup_armorlarge_anyway;
 579 float g_pickup_healthsmall;
 580 float g_pickup_healthsmall_max;
 581 float g_pickup_healthsmall_anyway;
 582 float g_pickup_healthmedium;
 583 float g_pickup_healthmedium_max;
 584 float g_pickup_healthmedium_anyway;
 585 float g_pickup_healthlarge;
 586 float g_pickup_healthlarge_max;
 587 float g_pickup_healthlarge_anyway;
 588 float g_pickup_healthmega;
 589 float g_pickup_healthmega_max;
 590 float g_pickup_healthmega_anyway;
 591 float g_pickup_ammo_anyway;
 592 float g_pickup_weapons_anyway;
 593 float g_weaponarena;
 594 WEPSET_DECLARE_A(g_weaponarena_weapons);
 595 float g_weaponarena_random;
 596 float g_weaponarena_random_with_laser;
 597 string g_weaponarena_list;
 598 float g_weaponspeedfactor;
 599 float g_weaponratefactor;
 600 float g_weapondamagefactor;
 601 float g_weaponforcefactor;
 602 float g_weaponspreadfactor;
 603
 604 WEPSET_DECLARE_A(start_weapons);
 605 WEPSET_DECLARE_A(start_weapons_default);
 606 WEPSET_DECLARE_A(start_weapons_defaultmask);
 607 float start_items;
 608 float start_ammo_shells;
 609 float start_ammo_nails;
 610 float start_ammo_rockets;
 611 float start_ammo_cells;
 612 float start_ammo_fuel;
 613 float start_health;
 614 float start_armorvalue;
 615 WEPSET_DECLARE_A(warmup_start_weapons);
 616 WEPSET_DECLARE_A(warmup_start_weapons_default);
 617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN);
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         WEPSET_CLEAR_A(start_weapons);
 680         WEPSET_CLEAR_A(start_weapons_default);
 681         WEPSET_CLEAR_A(start_weapons_defaultmask);
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         WEPSET_CLEAR_A(g_weaponarena_weapons);
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_weapon_stay = 0; // incompatible
 771                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 772                 start_items |= IT_UNLIMITED_AMMO;
 773         }
 774         else
 775         {
 776                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 777                 {
 778                         e = get_weaponinfo(i);
 779                         float w = want_weapon("g_start_weapon_", e, FALSE);
 780                         if(w & 1)
 781                                 WEPSET_OR_AW(start_weapons, i);
 782                         if(w & 2)
 783                                 WEPSET_OR_AW(start_weapons_default, i);
 784                         if(w & 4)
 785                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 786                 }
 787         }
 788
 789         if(!cvar("g_use_ammunition"))
 790                 start_items |= IT_UNLIMITED_AMMO;
 791
 792         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 793         {
 794                 start_ammo_rockets = 999;
 795                 start_ammo_shells = 999;
 796                 start_ammo_cells = 999;
 797                 start_ammo_nails = 999;
 798                 start_ammo_fuel = 999;
 799         }
 800         else
 801         {
 802                 start_ammo_shells = cvar("g_start_ammo_shells");
 803                 start_ammo_nails = cvar("g_start_ammo_nails");
 804                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 805                 start_ammo_cells = cvar("g_start_ammo_cells");
 806                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 807         }
 808
 809         if (inWarmupStage)
 810         {
 811                 warmup_start_ammo_shells = start_ammo_shells;
 812                 warmup_start_ammo_nails = start_ammo_nails;
 813                 warmup_start_ammo_rockets = start_ammo_rockets;
 814                 warmup_start_ammo_cells = start_ammo_cells;
 815                 warmup_start_ammo_fuel = start_ammo_fuel;
 816                 warmup_start_health = start_health;
 817                 warmup_start_armorvalue = start_armorvalue;
 818                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 819                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 820                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 821
 822                 if (!g_weaponarena && !g_ca)
 823                 {
 824                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 825                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 826                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 827                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 828                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 829                         warmup_start_health = cvar("g_warmup_start_health");
 830                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 831                         WEPSET_CLEAR_A(warmup_start_weapons);
 832                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 833                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 834                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 835                         {
 836                                 e = get_weaponinfo(i);
 837                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 838                                 if(w & 1)
 839                                         WEPSET_OR_AW(warmup_start_weapons, i);
 840                                 if(w & 2)
 841                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 842                                 if(w & 4)
 843                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 844                         }
 845                 }
 846         }
 847
 848         if (g_jetpack)
 849                 start_items |= IT_JETPACK;
 850
 851         MUTATOR_CALLHOOK(SetStartItems);
 852
 853         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 854         {
 855                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 856                 start_items |= IT_FUEL_REGEN;
 857                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 858                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 859         }
 860
 861         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 862         {
 863                 e = get_weaponinfo(i);
 864                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 865                         weapon_action(i, WR_PRECACHE);
 866         }
 867
 868         start_ammo_shells = max(0, start_ammo_shells);
 869         start_ammo_nails = max(0, start_ammo_nails);
 870         start_ammo_cells = max(0, start_ammo_cells);
 871         start_ammo_rockets = max(0, start_ammo_rockets);
 872         start_ammo_fuel = max(0, start_ammo_fuel);
 873
 874         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 875         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 876         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 877         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 878         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 879 }
 880
 881 float g_bugrigs;
 882 float g_bugrigs_planar_movement;
 883 float g_bugrigs_planar_movement_car_jumping;
 884 float g_bugrigs_reverse_spinning;
 885 float g_bugrigs_reverse_speeding;
 886 float g_bugrigs_reverse_stopping;
 887 float g_bugrigs_air_steering;
 888 float g_bugrigs_angle_smoothing;
 889 float g_bugrigs_friction_floor;
 890 float g_bugrigs_friction_brake;
 891 float g_bugrigs_friction_air;
 892 float g_bugrigs_accel;
 893 float g_bugrigs_speed_ref;
 894 float g_bugrigs_speed_pow;
 895 float g_bugrigs_steer;
 896
 897 float sv_autotaunt;
 898 float sv_taunt;
 899
 900 string GetGametype(); // g_world.qc
 901 void readlevelcvars(void)
 902 {
 903         // load mutators
 904         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 905                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 906
 907         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 908         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 909         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 910         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 911         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 912         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 913         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 914         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 915         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 918         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 920         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 922         CHECK_MUTATOR_ADD("g_norecoil", mutator_norecoil, 1);
 923         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 924         CHECK_MUTATOR_ADD("g_footsteps", mutator_footsteps, 1);
 925         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 926         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 927         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 928     CHECK_MUTATOR_ADD("g_riflearena", mutator_riflearena, !cvar("g_minstagib"));
 929         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 930
 931         #undef CHECK_MUTATOR_ADD
 932
 933         if(cvar("sv_allow_fullbright"))
 934                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 935
 936     g_bugrigs = cvar("g_bugrigs");
 937     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 938     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 939     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 940     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 941     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 942     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 943     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 944     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 945     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 946     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 947     g_bugrigs_accel = cvar("g_bugrigs_accel");
 948     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 949     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 950     g_bugrigs_steer = cvar("g_bugrigs_steer");
 951
 952         g_minstagib = cvar("g_minstagib");
 953
 954         sv_clones = cvar("sv_clones");
 955         sv_foginterval = cvar("sv_foginterval");
 956         g_cloaked = cvar("g_cloaked");
 957     if(g_cts)
 958         g_cloaked = 1; // always enable cloak in CTS
 959         g_grappling_hook = cvar("g_grappling_hook");
 960         g_jetpack = cvar("g_jetpack");
 961         sv_maxidle = cvar("sv_maxidle");
 962         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 963         sv_autotaunt = cvar("sv_autotaunt");
 964         sv_taunt = cvar("sv_taunt");
 965
 966         inWarmupStage = cvar("g_warmup");
 967         g_warmup_limit = cvar("g_warmup_limit");
 968         g_warmup_allguns = cvar("g_warmup_allguns");
 969         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 970
 971         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
 972                 inWarmupStage = 0; // these modes cannot work together, sorry
 973
 974         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 975         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 976         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 977         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 978         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 979         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 980         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 981         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 982         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 983         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 984         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 985         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 986         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 987         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 988
 989         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 990         g_weaponratefactor = cvar("g_weaponratefactor");
 991         g_weapondamagefactor = cvar("g_weapondamagefactor");
 992         g_weaponforcefactor = cvar("g_weaponforcefactor");
 993         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 994
 995         g_pickup_shells = cvar("g_pickup_shells");
 996         g_pickup_shells_max = cvar("g_pickup_shells_max");
 997         g_pickup_nails = cvar("g_pickup_nails");
 998         g_pickup_nails_max = cvar("g_pickup_nails_max");
 999         g_pickup_rockets = cvar("g_pickup_rockets");
1000         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1001         g_pickup_cells = cvar("g_pickup_cells");
1002         g_pickup_cells_max = cvar("g_pickup_cells_max");
1003         g_pickup_fuel = cvar("g_pickup_fuel");
1004         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1005         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1006         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1007         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1008         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1009         g_pickup_armormedium = cvar("g_pickup_armormedium");
1010         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1011         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1012         g_pickup_armorbig = cvar("g_pickup_armorbig");
1013         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1014         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1015         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1016         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1017         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1018         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1019         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1020         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1021         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1022         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1023         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1024         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1025         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1026         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1027         g_pickup_healthmega = cvar("g_pickup_healthmega");
1028         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1029         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1030
1031         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1032         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1033
1034     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1035     if(!g_weapon_stay)
1036         g_weapon_stay = cvar("g_weapon_stay");
1037
1038         if not(inWarmupStage)
1039                 game_starttime = time + cvar("g_start_delay");
1040
1041         readplayerstartcvars();
1042 }
1043
1044 //#NO AUTOCVARS END
1045
1046 // Sound functions
1047 string precache_sound (string s) = #19;
1048 float precache_sound_index (string s) = #19;
1049
1050 #define SND_VOLUME      1
1051 #define SND_ATTENUATION 2
1052 #define SND_LARGEENTITY 8
1053 #define SND_LARGESOUND  16
1054
1055 float sound_allowed(float dest, entity e)
1056 {
1057     // sounds from world may always pass
1058     for (;;)
1059     {
1060         if (e.classname == "body")
1061             e = e.enemy;
1062         else if (e.realowner && e.realowner != e)
1063             e = e.realowner;
1064         else if (e.owner && e.owner != e)
1065             e = e.owner;
1066         else
1067             break;
1068     }
1069     // sounds to self may always pass
1070     if (dest == MSG_ONE)
1071         if (e == msg_entity)
1072             return TRUE;
1073     // sounds by players can be removed
1074     if (autocvar_bot_sound_monopoly)
1075         if (IS_REAL_CLIENT(e))
1076             return FALSE;
1077     // anything else may pass
1078     return TRUE;
1079 }
1080
1081 #ifdef COMPAT_XON010_CHANNELS
1082 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1083 void sound(entity e, float chan, string samp, float vol, float atten)
1084 {
1085     if (!sound_allowed(MSG_BROADCAST, e))
1086         return;
1087     builtin_sound(e, chan, samp, vol, atten);
1088 }
1089 #else
1090 #undef sound
1091 void sound(entity e, float chan, string samp, float vol, float atten)
1092 {
1093     if (!sound_allowed(MSG_BROADCAST, e))
1094         return;
1095     sound7(e, chan, samp, vol, atten, 0, 0);
1096 }
1097 #endif
1098
1099 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1100 {
1101     float entno, idx;
1102
1103     if (!sound_allowed(dest, e))
1104         return;
1105
1106     entno = num_for_edict(e);
1107     idx = precache_sound_index(samp);
1108
1109     float sflags;
1110     sflags = 0;
1111
1112     atten = floor(atten * 64);
1113     vol = floor(vol * 255);
1114
1115     if (vol != 255)
1116         sflags |= SND_VOLUME;
1117     if (atten != 64)
1118         sflags |= SND_ATTENUATION;
1119     if (entno >= 8192 || chan < 0 || chan > 7)
1120         sflags |= SND_LARGEENTITY;
1121     if (idx >= 256)
1122         sflags |= SND_LARGESOUND;
1123
1124     WriteByte(dest, SVC_SOUND);
1125     WriteByte(dest, sflags);
1126     if (sflags & SND_VOLUME)
1127         WriteByte(dest, vol);
1128     if (sflags & SND_ATTENUATION)
1129         WriteByte(dest, atten);
1130     if (sflags & SND_LARGEENTITY)
1131     {
1132         WriteShort(dest, entno);
1133         WriteByte(dest, chan);
1134     }
1135     else
1136     {
1137         WriteShort(dest, entno * 8 + chan);
1138     }
1139     if (sflags & SND_LARGESOUND)
1140         WriteShort(dest, idx);
1141     else
1142         WriteByte(dest, idx);
1143
1144     WriteCoord(dest, o_x);
1145     WriteCoord(dest, o_y);
1146     WriteCoord(dest, o_z);
1147 }
1148 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1149 {
1150     vector o;
1151
1152     if (!sound_allowed(dest, e))
1153         return;
1154
1155     o = e.origin + 0.5 * (e.mins + e.maxs);
1156     soundtoat(dest, e, o, chan, samp, vol, atten);
1157 }
1158 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1159 {
1160     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1161 }
1162 void stopsoundto(float dest, entity e, float chan)
1163 {
1164     float entno;
1165
1166     if (!sound_allowed(dest, e))
1167         return;
1168
1169     entno = num_for_edict(e);
1170
1171     if (entno >= 8192 || chan < 0 || chan > 7)
1172     {
1173         float idx, sflags;
1174         idx = precache_sound_index("misc/null.wav");
1175         sflags = SND_LARGEENTITY;
1176         if (idx >= 256)
1177             sflags |= SND_LARGESOUND;
1178         WriteByte(dest, SVC_SOUND);
1179         WriteByte(dest, sflags);
1180         WriteShort(dest, entno);
1181         WriteByte(dest, chan);
1182         if (sflags & SND_LARGESOUND)
1183             WriteShort(dest, idx);
1184         else
1185             WriteByte(dest, idx);
1186         WriteCoord(dest, e.origin_x);
1187         WriteCoord(dest, e.origin_y);
1188         WriteCoord(dest, e.origin_z);
1189     }
1190     else
1191     {
1192         WriteByte(dest, SVC_STOPSOUND);
1193         WriteShort(dest, entno * 8 + chan);
1194     }
1195 }
1196 void stopsound(entity e, float chan)
1197 {
1198     if (!sound_allowed(MSG_BROADCAST, e))
1199         return;
1200
1201     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1202     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1203 }
1204
1205 void play2(entity e, string filename)
1206 {
1207     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1208     msg_entity = e;
1209     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1210 }
1211
1212 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1213 .float spamtime;
1214 float spamsound(entity e, float chan, string samp, float vol, float atten)
1215 {
1216     if (!sound_allowed(MSG_BROADCAST, e))
1217         return FALSE;
1218
1219     if (time > e.spamtime)
1220     {
1221         e.spamtime = time;
1222         sound(e, chan, samp, vol, atten);
1223         return TRUE;
1224     }
1225     return FALSE;
1226 }
1227
1228 void play2team(float t, string filename)
1229 {
1230     entity head;
1231
1232     if (autocvar_bot_sound_monopoly)
1233         return;
1234
1235     FOR_EACH_REALPLAYER(head)
1236     {
1237         if (head.team == t)
1238             play2(head, filename);
1239     }
1240 }
1241
1242 void play2all(string samp)
1243 {
1244     if (autocvar_bot_sound_monopoly)
1245         return;
1246
1247     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1248 }
1249
1250 void PrecachePlayerSounds(string f);
1251 void precache_playermodel(string m)
1252 {
1253         float globhandle, i, n;
1254         string f;
1255
1256         if(substring(m, -9,5) == "_lod1")
1257                 return;
1258         if(substring(m, -9,5) == "_lod2")
1259                 return;
1260         precache_model(m);
1261         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1262         if(fexists(f))
1263                 precache_model(f);
1264         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1265         if(fexists(f))
1266                 precache_model(f);
1267
1268         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1269         if (globhandle < 0)
1270                 return;
1271         n = search_getsize(globhandle);
1272         for (i = 0; i < n; ++i)
1273         {
1274                 //print(search_getfilename(globhandle, i), "\n");
1275                 f = search_getfilename(globhandle, i);
1276                 PrecachePlayerSounds(f);
1277         }
1278         search_end(globhandle);
1279 }
1280 void precache_all_playermodels(string pattern)
1281 {
1282         float globhandle, i, n;
1283         string f;
1284
1285         globhandle = search_begin(pattern, TRUE, FALSE);
1286         if (globhandle < 0)
1287                 return;
1288         n = search_getsize(globhandle);
1289         for (i = 0; i < n; ++i)
1290         {
1291                 //print(search_getfilename(globhandle, i), "\n");
1292                 f = search_getfilename(globhandle, i);
1293                 precache_playermodel(f);
1294         }
1295         search_end(globhandle);
1296 }
1297
1298 void precache()
1299 {
1300     // gamemode related things
1301     precache_model ("models/misc/chatbubble.spr");
1302
1303 #ifdef TTURRETS_ENABLED
1304     if (autocvar_g_turrets)
1305         turrets_precash();
1306 #endif
1307
1308     // Precache all player models if desired
1309     if (autocvar_sv_precacheplayermodels)
1310     {
1311         PrecachePlayerSounds("sound/player/default.sounds");
1312         precache_all_playermodels("models/player/*.zym");
1313         precache_all_playermodels("models/player/*.dpm");
1314         precache_all_playermodels("models/player/*.md3");
1315         precache_all_playermodels("models/player/*.psk");
1316         precache_all_playermodels("models/player/*.iqm");
1317     }
1318
1319     if (autocvar_sv_defaultcharacter)
1320     {
1321         string s;
1322         s = autocvar_sv_defaultplayermodel_red;
1323         if (s != "")
1324             precache_playermodel(s);
1325         s = autocvar_sv_defaultplayermodel_blue;
1326         if (s != "")
1327             precache_playermodel(s);
1328         s = autocvar_sv_defaultplayermodel_yellow;
1329         if (s != "")
1330             precache_playermodel(s);
1331         s = autocvar_sv_defaultplayermodel_pink;
1332         if (s != "")
1333             precache_playermodel(s);
1334         s = autocvar_sv_defaultplayermodel;
1335         if (s != "")
1336             precache_playermodel(s);
1337     }
1338
1339     // gore and miscellaneous sounds
1340     //precache_sound ("misc/h2ohit.wav");
1341     precache_model ("models/hook.md3");
1342     precache_sound ("misc/armorimpact.wav");
1343     precache_sound ("misc/bodyimpact1.wav");
1344     precache_sound ("misc/bodyimpact2.wav");
1345     precache_sound ("misc/gib.wav");
1346     precache_sound ("misc/gib_splat01.wav");
1347     precache_sound ("misc/gib_splat02.wav");
1348     precache_sound ("misc/gib_splat03.wav");
1349     precache_sound ("misc/gib_splat04.wav");
1350     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1351     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1352     precache_sound ("misc/null.wav");
1353     precache_sound ("misc/spawn.wav");
1354     precache_sound ("misc/talk.wav");
1355     precache_sound ("misc/teleport.wav");
1356     precache_sound ("misc/poweroff.wav");
1357     precache_sound ("player/lava.wav");
1358     precache_sound ("player/slime.wav");
1359
1360     precache_model ("models/sprites/0.spr32");
1361     precache_model ("models/sprites/1.spr32");
1362     precache_model ("models/sprites/2.spr32");
1363     precache_model ("models/sprites/3.spr32");
1364     precache_model ("models/sprites/4.spr32");
1365     precache_model ("models/sprites/5.spr32");
1366     precache_model ("models/sprites/6.spr32");
1367     precache_model ("models/sprites/7.spr32");
1368     precache_model ("models/sprites/8.spr32");
1369     precache_model ("models/sprites/9.spr32");
1370     precache_model ("models/sprites/10.spr32");
1371
1372     // common weapon precaches
1373         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1374     precache_sound ("weapons/weapon_switch.wav");
1375     precache_sound ("weapons/weaponpickup.wav");
1376     precache_sound ("weapons/unavailable.wav");
1377     precache_sound ("weapons/dryfire.wav");
1378     if (g_grappling_hook)
1379     {
1380         precache_sound ("weapons/hook_fire.wav"); // hook
1381         precache_sound ("weapons/hook_impact.wav"); // hook
1382     }
1383
1384     if(autocvar_sv_precacheweapons)
1385     {
1386         //precache weapon models/sounds
1387         float wep;
1388         wep = WEP_FIRST;
1389         while (wep <= WEP_LAST)
1390         {
1391             weapon_action(wep, WR_PRECACHE);
1392             wep = wep + 1;
1393         }
1394     }
1395
1396     precache_model("models/elaser.mdl");
1397     precache_model("models/laser.mdl");
1398     precache_model("models/ebomb.mdl");
1399
1400 #if 0
1401     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1402
1403     if (!self.noise && self.music) // quake 3 uses the music field
1404         self.noise = self.music;
1405
1406     // plays music for the level if there is any
1407     if (self.noise)
1408     {
1409         precache_sound (self.noise);
1410         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1411     }
1412 #endif
1413 }
1414
1415 // WARNING: this kills the trace globals
1416 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1417 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1418
1419 #define INITPRIO_FIRST              0
1420 #define INITPRIO_GAMETYPE           0
1421 #define INITPRIO_GAMETYPE_FALLBACK  1
1422 #define INITPRIO_FINDTARGET        10
1423 #define INITPRIO_DROPTOFLOOR       20
1424 #define INITPRIO_SETLOCATION       90
1425 #define INITPRIO_LINKDOORS         91
1426 #define INITPRIO_LAST              99
1427
1428 .void(void) initialize_entity;
1429 .float initialize_entity_order;
1430 .entity initialize_entity_next;
1431 entity initialize_entity_first;
1432
1433 void make_safe_for_remove(entity e)
1434 {
1435     if (e.initialize_entity)
1436     {
1437         entity ent, prev = world;
1438         for (ent = initialize_entity_first; ent; )
1439         {
1440             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1441             {
1442                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1443                 // skip it in linked list
1444                 if (prev)
1445                 {
1446                     prev.initialize_entity_next = ent.initialize_entity_next;
1447                     ent = prev.initialize_entity_next;
1448                 }
1449                 else
1450                 {
1451                     initialize_entity_first = ent.initialize_entity_next;
1452                     ent = initialize_entity_first;
1453                 }
1454             }
1455             else
1456             {
1457                 prev = ent;
1458                 ent = ent.initialize_entity_next;
1459             }
1460         }
1461     }
1462 }
1463
1464 void objerror(string s)
1465 {
1466     make_safe_for_remove(self);
1467     builtin_objerror(s);
1468 }
1469
1470 .float remove_except_protected_forbidden;
1471 void remove_except_protected(entity e)
1472 {
1473         if(e.remove_except_protected_forbidden)
1474                 error("not allowed to remove this at this point");
1475         builtin_remove(e);
1476 }
1477
1478 void remove_unsafely(entity e)
1479 {
1480     if(e.classname == "spike")
1481         error("Removing spikes is forbidden (crylink bug), please report");
1482     builtin_remove(e);
1483 }
1484
1485 void remove_safely(entity e)
1486 {
1487     make_safe_for_remove(e);
1488     builtin_remove(e);
1489 }
1490
1491 void InitializeEntity(entity e, void(void) func, float order)
1492 {
1493     entity prev, cur;
1494
1495     if (!e || e.initialize_entity)
1496     {
1497         // make a proxy initializer entity
1498         entity e_old;
1499         e_old = e;
1500         e = spawn();
1501         e.classname = "initialize_entity";
1502         e.enemy = e_old;
1503     }
1504
1505     e.initialize_entity = func;
1506     e.initialize_entity_order = order;
1507
1508     cur = initialize_entity_first;
1509     prev = world;
1510     for (;;)
1511     {
1512         if (!cur || cur.initialize_entity_order > order)
1513         {
1514             // insert between prev and cur
1515             if (prev)
1516                 prev.initialize_entity_next = e;
1517             else
1518                 initialize_entity_first = e;
1519             e.initialize_entity_next = cur;
1520             return;
1521         }
1522         prev = cur;
1523         cur = cur.initialize_entity_next;
1524     }
1525 }
1526 void InitializeEntitiesRun()
1527 {
1528     entity startoflist;
1529     startoflist = initialize_entity_first;
1530     initialize_entity_first = world;
1531     remove = remove_except_protected;
1532     for (self = startoflist; self; self = self.initialize_entity_next)
1533     {
1534         self.remove_except_protected_forbidden = 1;
1535     }
1536     for (self = startoflist; self; )
1537     {
1538         entity e;
1539         var void(void) func;
1540         e = self.initialize_entity_next;
1541         func = self.initialize_entity;
1542         self.initialize_entity_order = 0;
1543         self.initialize_entity = func_null;
1544         self.initialize_entity_next = world;
1545         self.remove_except_protected_forbidden = 0;
1546         if (self.classname == "initialize_entity")
1547         {
1548             entity e_old;
1549             e_old = self.enemy;
1550             builtin_remove(self);
1551             self = e_old;
1552         }
1553         //dprint("Delayed initialization: ", self.classname, "\n");
1554         if(func)
1555             func();
1556         else
1557         {
1558             eprint(self);
1559             backtrace(strcat("Null function in: ", self.classname, "\n"));
1560         }
1561         self = e;
1562     }
1563     remove = remove_unsafely;
1564 }
1565
1566 .float uncustomizeentityforclient_set;
1567 .void(void) uncustomizeentityforclient;
1568 void UncustomizeEntitiesRun()
1569 {
1570     entity oldself;
1571     oldself = self;
1572     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1573         self.uncustomizeentityforclient();
1574     self = oldself;
1575 }
1576 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1577 {
1578     e.customizeentityforclient = customizer;
1579     e.uncustomizeentityforclient = uncustomizer;
1580     e.uncustomizeentityforclient_set = !!uncustomizer;
1581 }
1582
1583 .float nottargeted;
1584 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1585
1586 void() SUB_Remove;
1587 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1588 {
1589     vector mi, ma;
1590
1591     if (e.classname == "")
1592         e.classname = "net_linked";
1593
1594     if (e.model == "" || self.modelindex == 0)
1595     {
1596         mi = e.mins;
1597         ma = e.maxs;
1598         setmodel(e, "null");
1599         setsize(e, mi, ma);
1600     }
1601
1602     e.SendEntity = sendfunc;
1603     e.SendFlags = 0xFFFFFF;
1604
1605     if (!docull)
1606         e.effects |= EF_NODEPTHTEST;
1607
1608     if (dt)
1609     {
1610         e.nextthink = time + dt;
1611         e.think = SUB_Remove;
1612     }
1613 }
1614
1615 void adaptor_think2touch()
1616 {
1617     entity o;
1618     o = other;
1619     other = world;
1620     self.touch();
1621     other = o;
1622 }
1623
1624 void adaptor_think2use()
1625 {
1626     entity o, a;
1627     o = other;
1628     a = activator;
1629     activator = world;
1630     other = world;
1631     self.use();
1632     other = o;
1633     activator = a;
1634 }
1635
1636 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1637 {
1638         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1639                 self.projectiledeathtype |= HITTYPE_SPLASH;
1640         adaptor_think2use();
1641 }
1642
1643 // deferred dropping
1644 void DropToFloor_Handler()
1645 {
1646     builtin_droptofloor();
1647     self.dropped_origin = self.origin;
1648 }
1649
1650 void droptofloor()
1651 {
1652     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1653 }
1654
1655
1656
1657 float trace_hits_box_a0, trace_hits_box_a1;
1658
1659 float trace_hits_box_1d(float end, float thmi, float thma)
1660 {
1661     if (end == 0)
1662     {
1663         // just check if x is in range
1664         if (0 < thmi)
1665             return FALSE;
1666         if (0 > thma)
1667             return FALSE;
1668     }
1669     else
1670     {
1671         // do the trace with respect to x
1672         // 0 -> end has to stay in thmi -> thma
1673         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1674         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1675         if (trace_hits_box_a0 > trace_hits_box_a1)
1676             return FALSE;
1677     }
1678     return TRUE;
1679 }
1680
1681 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1682 {
1683     end -= start;
1684     thmi -= start;
1685     thma -= start;
1686     // now it is a trace from 0 to end
1687
1688     trace_hits_box_a0 = 0;
1689     trace_hits_box_a1 = 1;
1690
1691     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1692         return FALSE;
1693     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1694         return FALSE;
1695     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1696         return FALSE;
1697
1698     return TRUE;
1699 }
1700
1701 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1702 {
1703     return trace_hits_box(start, end, thmi - ma, thma - mi);
1704 }
1705
1706 float SUB_NoImpactCheck()
1707 {
1708         // zero hitcontents = this is not the real impact, but either the
1709         // mirror-impact of something hitting the projectile instead of the
1710         // projectile hitting the something, or a touchareagrid one. Neither of
1711         // these stop the projectile from moving, so...
1712         if(trace_dphitcontents == 0)
1713         {
1714                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1715                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1716                 checkclient();
1717         }
1718     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1719         return 1;
1720     if (other == world && self.size != '0 0 0')
1721     {
1722         vector tic;
1723         tic = self.velocity * sys_frametime;
1724         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1725         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1726         if (trace_fraction >= 1)
1727         {
1728             dprint("Odd... did not hit...?\n");
1729         }
1730         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1731         {
1732             dprint("Detected and prevented the sky-grapple bug.\n");
1733             return 1;
1734         }
1735     }
1736
1737     return 0;
1738 }
1739
1740 #define SUB_OwnerCheck() (other && (other == self.owner))
1741
1742 void RemoveGrapplingHook(entity pl);
1743 void W_Crylink_Dequeue(entity e);
1744 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1745 {
1746         if(SUB_OwnerCheck())
1747                 return TRUE;
1748         if(SUB_NoImpactCheck())
1749         {
1750                 if(self.classname == "grapplinghook")
1751                         RemoveGrapplingHook(self.realowner);
1752                 else if(self.classname == "spike")
1753                 {
1754                         W_Crylink_Dequeue(self);
1755                         remove(self);
1756                 }
1757                 else
1758                         remove(self);
1759                 return TRUE;
1760         }
1761         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1762                 UpdateCSQCProjectile(self);
1763         return FALSE;
1764 }
1765 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1766
1767 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1768 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1769
1770 void URI_Get_Callback(float id, float status, string data)
1771 {
1772         if(url_URI_Get_Callback(id, status, data))
1773         {
1774                 // handled
1775         }
1776         else if (id == URI_GET_DISCARD)
1777         {
1778                 // discard
1779         }
1780         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1781         {
1782                 // sv_cmd curl
1783                 Curl_URI_Get_Callback(id, status, data);
1784         }
1785         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1786         {
1787                 // online ban list
1788                 OnlineBanList_URI_Get_Callback(id, status, data);
1789         }
1790         else
1791         {
1792                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1793         }
1794 }
1795
1796 string uid2name(string myuid) {
1797         string s;
1798         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1799
1800         // FIXME remove this later after 0.6 release
1801         // convert old style broken records to correct style
1802         if(s == "")
1803         {
1804                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1805                 if(s != "")
1806                 {
1807                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1808                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1809                 }
1810         }
1811
1812         if(s == "")
1813                 s = "^1Unregistered Player";
1814         return s;
1815 }
1816
1817 float race_readTime(string map, float pos)
1818 {
1819         string rr;
1820         if(g_cts)
1821                 rr = CTS_RECORD;
1822         else
1823                 rr = RACE_RECORD;
1824
1825         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1826 }
1827
1828 string race_readUID(string map, float pos)
1829 {
1830         string rr;
1831         if(g_cts)
1832                 rr = CTS_RECORD;
1833         else
1834                 rr = RACE_RECORD;
1835
1836         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1837 }
1838
1839 float race_readPos(string map, float t) {
1840         float i;
1841         for (i = 1; i <= RANKINGS_CNT; ++i)
1842                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1843                         return i;
1844
1845         return 0; // pos is zero if unranked
1846 }
1847
1848 void race_writeTime(string map, float t, string myuid)
1849 {
1850         string rr;
1851         if(g_cts)
1852                 rr = CTS_RECORD;
1853         else
1854                 rr = RACE_RECORD;
1855
1856         float newpos;
1857         newpos = race_readPos(map, t);
1858
1859         float i, prevpos = 0;
1860         for(i = 1; i <= RANKINGS_CNT; ++i)
1861         {
1862                 if(race_readUID(map, i) == myuid)
1863                         prevpos = i;
1864         }
1865         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1866                 for (i = prevpos; i > newpos; --i) {
1867                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1868                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1869                 }
1870         } else { // player has no ranked record yet
1871                 for (i = RANKINGS_CNT; i > newpos; --i) {
1872                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1873                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1874                 }
1875         }
1876
1877         // store new time itself
1878         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1879         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1880 }
1881
1882 string race_readName(string map, float pos)
1883 {
1884         string rr;
1885         if(g_cts)
1886                 rr = CTS_RECORD;
1887         else
1888                 rr = RACE_RECORD;
1889
1890         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1891 }
1892
1893 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1894 {
1895     float m, i;
1896     vector start, org, delta, end, enddown, mstart;
1897     entity sp;
1898
1899     m = e.dphitcontentsmask;
1900     e.dphitcontentsmask = goodcontents | badcontents;
1901
1902     org = world.mins;
1903     delta = world.maxs - world.mins;
1904
1905     start = end = org;
1906
1907     for (i = 0; i < attempts; ++i)
1908     {
1909         start_x = org_x + random() * delta_x;
1910         start_y = org_y + random() * delta_y;
1911         start_z = org_z + random() * delta_z;
1912
1913         // rule 1: start inside world bounds, and outside
1914         // solid, and don't start from somewhere where you can
1915         // fall down to evil
1916         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1917         if (trace_fraction >= 1)
1918             continue;
1919         if (trace_startsolid)
1920             continue;
1921         if (trace_dphitcontents & badcontents)
1922             continue;
1923         if (trace_dphitq3surfaceflags & badsurfaceflags)
1924             continue;
1925
1926         // rule 2: if we are too high, lower the point
1927         if (trace_fraction * delta_z > maxaboveground)
1928             start = trace_endpos + '0 0 1' * maxaboveground;
1929         enddown = trace_endpos;
1930
1931         // rule 3: make sure we aren't outside the map. This only works
1932         // for somewhat well formed maps. A good rule of thumb is that
1933         // the map should have a convex outside hull.
1934         // these can be traceLINES as we already verified the starting box
1935         mstart = start + 0.5 * (e.mins + e.maxs);
1936         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1937         if (trace_fraction >= 1)
1938             continue;
1939         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1940         if (trace_fraction >= 1)
1941             continue;
1942         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1943         if (trace_fraction >= 1)
1944             continue;
1945         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1946         if (trace_fraction >= 1)
1947             continue;
1948         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1949         if (trace_fraction >= 1)
1950             continue;
1951
1952         // rule 4: we must "see" some spawnpoint
1953         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1954                 if(checkpvs(mstart, sp))
1955                         break;
1956         if(!sp)
1957         {
1958                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1959                         if(checkpvs(mstart, sp))
1960                                 break;
1961                 if(!sp)
1962                         continue;
1963         }
1964
1965         // find a random vector to "look at"
1966         end_x = org_x + random() * delta_x;
1967         end_y = org_y + random() * delta_y;
1968         end_z = org_z + random() * delta_z;
1969         end = start + normalize(end - start) * vlen(delta);
1970
1971         // rule 4: start TO end must not be too short
1972         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1973         if (trace_startsolid)
1974             continue;
1975         if (trace_fraction < minviewdistance / vlen(delta))
1976             continue;
1977
1978         // rule 5: don't want to look at sky
1979         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1980             continue;
1981
1982         // rule 6: we must not end up in trigger_hurt
1983         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1984             continue;
1985
1986         break;
1987     }
1988
1989     e.dphitcontentsmask = m;
1990
1991     if (i < attempts)
1992     {
1993         setorigin(e, start);
1994         e.angles = vectoangles(end - start);
1995         dprint("Needed ", ftos(i + 1), " attempts\n");
1996         return TRUE;
1997     }
1998     else
1999         return FALSE;
2000 }
2001
2002 float zcurveparticles_effectno;
2003 vector zcurveparticles_start;
2004 float zcurveparticles_spd;
2005
2006 void endzcurveparticles()
2007 {
2008         if(zcurveparticles_effectno)
2009         {
2010                 // terminator
2011                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2012         }
2013         zcurveparticles_effectno = 0;
2014 }
2015
2016 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2017 {
2018         spd = bound(0, floor(spd / 16), 32767);
2019         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2020         {
2021                 endzcurveparticles();
2022                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2023                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2024                 WriteShort(MSG_BROADCAST, effectno);
2025                 WriteCoord(MSG_BROADCAST, start_x);
2026                 WriteCoord(MSG_BROADCAST, start_y);
2027                 WriteCoord(MSG_BROADCAST, start_z);
2028                 zcurveparticles_effectno = effectno;
2029                 zcurveparticles_start = start;
2030         }
2031         else
2032                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2033         WriteCoord(MSG_BROADCAST, end_x);
2034         WriteCoord(MSG_BROADCAST, end_y);
2035         WriteCoord(MSG_BROADCAST, end_z);
2036         WriteCoord(MSG_BROADCAST, end_dz);
2037         zcurveparticles_spd = spd;
2038 }
2039
2040 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2041 {
2042         float end_dz;
2043         vector vecxy, velxy;
2044
2045         vecxy = end - start;
2046         vecxy_z = 0;
2047         velxy = vel;
2048         velxy_z = 0;
2049
2050         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2051         {
2052                 endzcurveparticles();
2053                 trailparticles(world, effectno, start, end);
2054                 return;
2055         }
2056
2057         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2058         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2059 }
2060
2061 void write_recordmarker(entity pl, float tstart, float dt)
2062 {
2063     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2064
2065     // also write a marker into demo files for demotc-race-record-extractor to find
2066     stuffcmd(pl,
2067              strcat(
2068                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2069                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2070 }
2071
2072 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2073 {
2074         switch(algn)
2075         {
2076                 default:
2077                 case 3: // right
2078                         break;
2079
2080                 case 4: // left
2081                         vecs_y = -vecs_y;
2082                         break;
2083
2084                 case 1:
2085                         if(allowcenter) // 2: allow center handedness
2086                         {
2087                                 // center
2088                                 vecs_y = 0;
2089                                 vecs_z -= 2;
2090                         }
2091                         else
2092                         {
2093                                 // right
2094                         }
2095                         break;
2096
2097                 case 2:
2098                         if(allowcenter) // 2: allow center handedness
2099                         {
2100                                 // center
2101                                 vecs_y = 0;
2102                                 vecs_z -= 2;
2103                         }
2104                         else
2105                         {
2106                                 // left
2107                                 vecs_y = -vecs_y;
2108                         }
2109                         break;
2110         }
2111         return vecs;
2112 }
2113
2114 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2115 {
2116         string s;
2117         vector v;
2118
2119         if (autocvar_g_shootfromeye)
2120         {
2121                 if (visual)
2122                 {
2123                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2124                         else { vecs_y = 0; vecs_z -= 2; }
2125                 }
2126                 else
2127                 {
2128                         vecs_y = 0;
2129                         vecs_z = 0;
2130                 }
2131         }
2132         else if (autocvar_g_shootfromcenter)
2133         {
2134                 vecs_y = 0;
2135                 vecs_z -= 2;
2136         }
2137         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2138         {
2139                 v = stov(s);
2140                 if (y_is_right)
2141                         v_y = -v_y;
2142                 if (v_x != 0)
2143                         vecs_x = v_x;
2144                 vecs_y = v_y;
2145                 vecs_z = v_z;
2146         }
2147         else if (autocvar_g_shootfromclient)
2148         {
2149                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2150         }
2151         return vecs;
2152 }
2153
2154 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2155 {
2156         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2157 }
2158
2159
2160 void attach_sameorigin(entity e, entity to, string tag)
2161 {
2162     vector org, t_forward, t_left, t_up, e_forward, e_up;
2163     float tagscale;
2164
2165     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2166     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2167     t_forward = v_forward * tagscale;
2168     t_left = v_right * -tagscale;
2169     t_up = v_up * tagscale;
2170
2171     e.origin_x = org * t_forward;
2172     e.origin_y = org * t_left;
2173     e.origin_z = org * t_up;
2174
2175     // current forward and up directions
2176     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2177                 e.angles = AnglesTransform_FromVAngles(e.angles);
2178         else
2179                 e.angles = AnglesTransform_FromAngles(e.angles);
2180     fixedmakevectors(e.angles);
2181
2182     // untransform forward, up!
2183     e_forward_x = v_forward * t_forward;
2184     e_forward_y = v_forward * t_left;
2185     e_forward_z = v_forward * t_up;
2186     e_up_x = v_up * t_forward;
2187     e_up_y = v_up * t_left;
2188     e_up_z = v_up * t_up;
2189
2190     e.angles = fixedvectoangles2(e_forward, e_up);
2191     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2192                 e.angles = AnglesTransform_ToVAngles(e.angles);
2193         else
2194                 e.angles = AnglesTransform_ToAngles(e.angles);
2195
2196     setattachment(e, to, tag);
2197     setorigin(e, e.origin);
2198 }
2199
2200 void detach_sameorigin(entity e)
2201 {
2202     vector org;
2203     org = gettaginfo(e, 0);
2204     e.angles = fixedvectoangles2(v_forward, v_up);
2205     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2206                 e.angles = AnglesTransform_ToVAngles(e.angles);
2207         else
2208                 e.angles = AnglesTransform_ToAngles(e.angles);
2209     setorigin(e, org);
2210     setattachment(e, world, "");
2211     setorigin(e, e.origin);
2212 }
2213
2214 void follow_sameorigin(entity e, entity to)
2215 {
2216     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2217     e.aiment = to; // make the hole follow bmodel
2218     e.punchangle = to.angles; // the original angles of bmodel
2219     e.view_ofs = e.origin - to.origin; // relative origin
2220     e.v_angle = e.angles - to.angles; // relative angles
2221 }
2222
2223 void unfollow_sameorigin(entity e)
2224 {
2225     e.movetype = MOVETYPE_NONE;
2226 }
2227
2228 entity gettaginfo_relative_ent;
2229 vector gettaginfo_relative(entity e, float tag)
2230 {
2231     if (!gettaginfo_relative_ent)
2232     {
2233         gettaginfo_relative_ent = spawn();
2234         gettaginfo_relative_ent.effects = EF_NODRAW;
2235     }
2236     gettaginfo_relative_ent.model = e.model;
2237     gettaginfo_relative_ent.modelindex = e.modelindex;
2238     gettaginfo_relative_ent.frame = e.frame;
2239     return gettaginfo(gettaginfo_relative_ent, tag);
2240 }
2241
2242 .float scale2;
2243
2244 float modeleffect_SendEntity(entity to, float sf)
2245 {
2246         float f;
2247         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2248
2249         f = 0;
2250         if(self.velocity != '0 0 0')
2251                 f |= 1;
2252         if(self.angles != '0 0 0')
2253                 f |= 2;
2254         if(self.avelocity != '0 0 0')
2255                 f |= 4;
2256
2257         WriteByte(MSG_ENTITY, f);
2258         WriteShort(MSG_ENTITY, self.modelindex);
2259         WriteByte(MSG_ENTITY, self.skin);
2260         WriteByte(MSG_ENTITY, self.frame);
2261         WriteCoord(MSG_ENTITY, self.origin_x);
2262         WriteCoord(MSG_ENTITY, self.origin_y);
2263         WriteCoord(MSG_ENTITY, self.origin_z);
2264         if(f & 1)
2265         {
2266                 WriteCoord(MSG_ENTITY, self.velocity_x);
2267                 WriteCoord(MSG_ENTITY, self.velocity_y);
2268                 WriteCoord(MSG_ENTITY, self.velocity_z);
2269         }
2270         if(f & 2)
2271         {
2272                 WriteCoord(MSG_ENTITY, self.angles_x);
2273                 WriteCoord(MSG_ENTITY, self.angles_y);
2274                 WriteCoord(MSG_ENTITY, self.angles_z);
2275         }
2276         if(f & 4)
2277         {
2278                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2279                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2280                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2281         }
2282         WriteShort(MSG_ENTITY, self.scale * 256.0);
2283         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2284         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2285         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2286         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2287
2288         return TRUE;
2289 }
2290
2291 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2292 {
2293         entity e;
2294         float sz;
2295         e = spawn();
2296         e.classname = "modeleffect";
2297         setmodel(e, m);
2298         e.frame = f;
2299         setorigin(e, o);
2300         e.velocity = v;
2301         e.angles = ang;
2302         e.avelocity = angv;
2303         e.alpha = a;
2304         e.teleport_time = t1;
2305         e.fade_time = t2;
2306         e.skin = s;
2307         if(s0 >= 0)
2308                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2309         else
2310                 e.scale = -s0;
2311         if(s2 >= 0)
2312                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2313         else
2314                 e.scale2 = -s2;
2315         sz = max(e.scale, e.scale2);
2316         setsize(e, e.mins * sz, e.maxs * sz);
2317         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2318 }
2319
2320 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2321 {
2322         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2323 }
2324
2325 float randombit(float bits)
2326 {
2327         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2328                 return bits;
2329
2330         float n, f, b, r;
2331
2332         r = random();
2333         b = 0;
2334         n = 0;
2335
2336         for(f = 1; f <= bits; f *= 2)
2337         {
2338                 if(bits & f)
2339                 {
2340                         ++n;
2341                         r *= n;
2342                         if(r <= 1)
2343                                 b = f;
2344                         else
2345                                 r = (r - 1) / (n - 1);
2346                 }
2347         }
2348
2349         return b;
2350 }
2351
2352 float randombits(float bits, float k, float error_return)
2353 {
2354         float r;
2355         r = 0;
2356         while(k > 0 && bits != r)
2357         {
2358                 r += randombit(bits - r);
2359                 --k;
2360         }
2361         if(error_return)
2362                 if(k > 0)
2363                         return -1; // all
2364         return r;
2365 }
2366
2367 void randombit_test(float bits, float iter)
2368 {
2369         while(iter > 0)
2370         {
2371                 print(ftos(randombit(bits)), "\n");
2372                 --iter;
2373         }
2374 }
2375
2376 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2377 {
2378         if(halflifedist > 0)
2379                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2380         else if(halflifedist < 0)
2381                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2382         else
2383                 return 1;
2384 }
2385
2386
2387
2388
2389 #ifdef RELEASE
2390 #define cvar_string_normal builtin_cvar_string
2391 #define cvar_normal builtin_cvar
2392 #else
2393 string cvar_string_normal(string n)
2394 {
2395         if not(cvar_type(n) & 1)
2396                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2397         return builtin_cvar_string(n);
2398 }
2399
2400 float cvar_normal(string n)
2401 {
2402         return stof(cvar_string_normal(n));
2403 }
2404 #endif
2405 #define cvar_set_normal builtin_cvar_set
2406
2407 void defer_think()
2408 {
2409     entity oself;
2410
2411     oself           = self;
2412     self            = self.owner;
2413     oself.think     = SUB_Remove;
2414     oself.nextthink = time;
2415
2416     oself.use();
2417 }
2418
2419 /*
2420     Execute func() after time + fdelay.
2421     self when func is executed = self when defer is called
2422 */
2423 void defer(float fdelay, void() func)
2424 {
2425     entity e;
2426
2427     e           = spawn();
2428     e.owner     = self;
2429     e.use       = func;
2430     e.think     = defer_think;
2431     e.nextthink = time + fdelay;
2432 }
2433
2434 .string aiment_classname;
2435 .float aiment_deadflag;
2436 void SetMovetypeFollow(entity ent, entity e)
2437 {
2438         // FIXME this may not be warpzone aware
2439         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2440         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2441         ent.aiment = e; // make the hole follow bmodel
2442         ent.punchangle = e.angles; // the original angles of bmodel
2443         ent.view_ofs = ent.origin - e.origin; // relative origin
2444         ent.v_angle = ent.angles - e.angles; // relative angles
2445         ent.aiment_classname = strzone(e.classname);
2446         ent.aiment_deadflag = e.deadflag;
2447 }
2448 void UnsetMovetypeFollow(entity ent)
2449 {
2450         ent.movetype = MOVETYPE_FLY;
2451         PROJECTILE_MAKETRIGGER(ent);
2452         ent.aiment = world;
2453 }
2454 float LostMovetypeFollow(entity ent)
2455 {
2456 /*
2457         if(ent.movetype != MOVETYPE_FOLLOW)
2458                 if(ent.aiment)
2459                         error("???");
2460 */
2461         if(ent.aiment)
2462         {
2463                 if(ent.aiment.classname != ent.aiment_classname)
2464                         return 1;
2465                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2466                         return 1;
2467         }
2468         return 0;
2469 }
2470
2471 float isPushable(entity e)
2472 {
2473         if(e.iscreature)
2474                 return TRUE;
2475         if(e.pushable)
2476                 return TRUE;
2477         switch(e.classname)
2478         {
2479                 case "body":
2480                 case "droppedweapon":
2481                 case "keepawayball":
2482                 case "nexball_basketball":
2483                 case "nexball_football":
2484                         return TRUE;
2485                 case "bullet": // antilagged bullets can't hit this either
2486                         return FALSE;
2487         }
2488         if (e.projectiledeathtype)
2489                 return TRUE;
2490         return FALSE;
2491 }