qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 float w_getbestweapon(entity e);
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 511
 512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 514
 515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 520
 521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 522         if (f > 0)
 523         {
 524                 if (s == "cl_weaponpriority")
 525                         self.switchweapon = w_getbestweapon(self);
 526                 if (s == "cl_allow_uidtracking")
 527                         PlayerStats_AddPlayer(self);
 528         }
 529 }
 530
 531 // decolorizes and team colors the player name when needed
 532 string playername(entity p)
 533 {
 534     string t;
 535     if (teamplay && !intermission_running && IS_PLAYER(p))
 536     {
 537         t = Team_ColorCode(p.team);
 538         return strcat(t, strdecolorize(p.netname));
 539     }
 540     else
 541         return p.netname;
 542 }
 543
 544 vector randompos(vector m1, vector m2)
 545 {
 546     vector v;
 547     m2 = m2 - m1;
 548     v_x = m2_x * random() + m1_x;
 549     v_y = m2_y * random() + m1_y;
 550     v_z = m2_z * random() + m1_z;
 551     return  v;
 552 }
 553
 554 //#NO AUTOCVARS START
 555
 556 float g_pickup_shells;
 557 float g_pickup_shells_max;
 558 float g_pickup_nails;
 559 float g_pickup_nails_max;
 560 float g_pickup_rockets;
 561 float g_pickup_rockets_max;
 562 float g_pickup_cells;
 563 float g_pickup_cells_max;
 564 float g_pickup_fuel;
 565 float g_pickup_fuel_jetpack;
 566 float g_pickup_fuel_max;
 567 float g_pickup_armorsmall;
 568 float g_pickup_armorsmall_max;
 569 float g_pickup_armorsmall_anyway;
 570 float g_pickup_armormedium;
 571 float g_pickup_armormedium_max;
 572 float g_pickup_armormedium_anyway;
 573 float g_pickup_armorbig;
 574 float g_pickup_armorbig_max;
 575 float g_pickup_armorbig_anyway;
 576 float g_pickup_armorlarge;
 577 float g_pickup_armorlarge_max;
 578 float g_pickup_armorlarge_anyway;
 579 float g_pickup_healthsmall;
 580 float g_pickup_healthsmall_max;
 581 float g_pickup_healthsmall_anyway;
 582 float g_pickup_healthmedium;
 583 float g_pickup_healthmedium_max;
 584 float g_pickup_healthmedium_anyway;
 585 float g_pickup_healthlarge;
 586 float g_pickup_healthlarge_max;
 587 float g_pickup_healthlarge_anyway;
 588 float g_pickup_healthmega;
 589 float g_pickup_healthmega_max;
 590 float g_pickup_healthmega_anyway;
 591 float g_pickup_ammo_anyway;
 592 float g_pickup_weapons_anyway;
 593 float g_weaponarena;
 594 WEPSET_DECLARE_A(g_weaponarena_weapons);
 595 float g_weaponarena_random;
 596 float g_weaponarena_random_with_laser;
 597 string g_weaponarena_list;
 598 float g_weaponspeedfactor;
 599 float g_weaponratefactor;
 600 float g_weapondamagefactor;
 601 float g_weaponforcefactor;
 602 float g_weaponspreadfactor;
 603
 604 WEPSET_DECLARE_A(start_weapons);
 605 WEPSET_DECLARE_A(start_weapons_default);
 606 WEPSET_DECLARE_A(start_weapons_defaultmask);
 607 float start_items;
 608 float start_ammo_shells;
 609 float start_ammo_nails;
 610 float start_ammo_rockets;
 611 float start_ammo_cells;
 612 float start_ammo_fuel;
 613 float start_health;
 614 float start_armorvalue;
 615 WEPSET_DECLARE_A(warmup_start_weapons);
 616 WEPSET_DECLARE_A(warmup_start_weapons_default);
 617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN);
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         WEPSET_CLEAR_A(start_weapons);
 680         WEPSET_CLEAR_A(start_weapons_default);
 681         WEPSET_CLEAR_A(start_weapons_defaultmask);
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         WEPSET_CLEAR_A(g_weaponarena_weapons);
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_weapon_stay = 0; // incompatible
 771                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 772                 start_items |= IT_UNLIMITED_AMMO;
 773         }
 774         else
 775         {
 776                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 777                 {
 778                         e = get_weaponinfo(i);
 779                         float w = want_weapon("g_start_weapon_", e, FALSE);
 780                         if(w & 1)
 781                                 WEPSET_OR_AW(start_weapons, i);
 782                         if(w & 2)
 783                                 WEPSET_OR_AW(start_weapons_default, i);
 784                         if(w & 4)
 785                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 786                 }
 787         }
 788
 789         if(!cvar("g_use_ammunition"))
 790                 start_items |= IT_UNLIMITED_AMMO;
 791
 792         if(cvar("g_nexball"))
 793                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (inWarmupStage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 822                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 823                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         WEPSET_CLEAR_A(warmup_start_weapons);
 835                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 836                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 841                                 if(w & 1)
 842                                         WEPSET_OR_AW(warmup_start_weapons, i);
 843                                 if(w & 2)
 844                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 845                                 if(w & 4)
 846                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 865         {
 866                 e = get_weaponinfo(i);
 867                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 868                         weapon_action(i, WR_PRECACHE);
 869         }
 870
 871         start_ammo_shells = max(0, start_ammo_shells);
 872         start_ammo_nails = max(0, start_ammo_nails);
 873         start_ammo_cells = max(0, start_ammo_cells);
 874         start_ammo_rockets = max(0, start_ammo_rockets);
 875         start_ammo_fuel = max(0, start_ammo_fuel);
 876
 877         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 878         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 879         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 880         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 881         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 882 }
 883
 884 float g_bugrigs;
 885 float g_bugrigs_planar_movement;
 886 float g_bugrigs_planar_movement_car_jumping;
 887 float g_bugrigs_reverse_spinning;
 888 float g_bugrigs_reverse_speeding;
 889 float g_bugrigs_reverse_stopping;
 890 float g_bugrigs_air_steering;
 891 float g_bugrigs_angle_smoothing;
 892 float g_bugrigs_friction_floor;
 893 float g_bugrigs_friction_brake;
 894 float g_bugrigs_friction_air;
 895 float g_bugrigs_accel;
 896 float g_bugrigs_speed_ref;
 897 float g_bugrigs_speed_pow;
 898 float g_bugrigs_steer;
 899
 900 float sv_autotaunt;
 901 float sv_taunt;
 902
 903 string GetGametype(); // g_world.qc
 904 void readlevelcvars(void)
 905 {
 906         // load mutators
 907         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 908                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 909
 910         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 911         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 912         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 913         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 914         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 915         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 921         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 923         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 924         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 925         CHECK_MUTATOR_ADD("g_norecoil", mutator_norecoil, 1);
 926         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 927
 928         #undef CHECK_MUTATOR_ADD
 929
 930         if(cvar("sv_allow_fullbright"))
 931                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 932
 933     g_bugrigs = cvar("g_bugrigs");
 934     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 935     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 936     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 937     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 938     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 939     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 940     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 941     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 942     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 943     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 944     g_bugrigs_accel = cvar("g_bugrigs_accel");
 945     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 946     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 947     g_bugrigs_steer = cvar("g_bugrigs_steer");
 948
 949         g_minstagib = cvar("g_minstagib");
 950
 951         sv_clones = cvar("sv_clones");
 952         sv_foginterval = cvar("sv_foginterval");
 953         g_cloaked = cvar("g_cloaked");
 954     if(g_cts)
 955         g_cloaked = 1; // always enable cloak in CTS
 956         g_jump_grunt = cvar("g_jump_grunt");
 957         g_footsteps = cvar("g_footsteps");
 958         g_grappling_hook = cvar("g_grappling_hook");
 959         g_jetpack = cvar("g_jetpack");
 960         sv_maxidle = cvar("sv_maxidle");
 961         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 962         sv_autotaunt = cvar("sv_autotaunt");
 963         sv_taunt = cvar("sv_taunt");
 964
 965         inWarmupStage = cvar("g_warmup");
 966         g_warmup_limit = cvar("g_warmup_limit");
 967         g_warmup_allguns = cvar("g_warmup_allguns");
 968         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 969
 970         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
 971                 inWarmupStage = 0; // these modes cannot work together, sorry
 972
 973         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 974         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 975         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 976         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 977         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 978         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 979         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 980         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 981         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 982         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 983         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 984         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 985         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 986         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 987
 988         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 989         g_weaponratefactor = cvar("g_weaponratefactor");
 990         g_weapondamagefactor = cvar("g_weapondamagefactor");
 991         g_weaponforcefactor = cvar("g_weaponforcefactor");
 992         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 993
 994         g_pickup_shells = cvar("g_pickup_shells");
 995         g_pickup_shells_max = cvar("g_pickup_shells_max");
 996         g_pickup_nails = cvar("g_pickup_nails");
 997         g_pickup_nails_max = cvar("g_pickup_nails_max");
 998         g_pickup_rockets = cvar("g_pickup_rockets");
 999         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1000         g_pickup_cells = cvar("g_pickup_cells");
1001         g_pickup_cells_max = cvar("g_pickup_cells_max");
1002         g_pickup_fuel = cvar("g_pickup_fuel");
1003         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1004         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1005         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1006         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1007         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1008         g_pickup_armormedium = cvar("g_pickup_armormedium");
1009         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1010         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1011         g_pickup_armorbig = cvar("g_pickup_armorbig");
1012         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1013         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1014         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1015         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1016         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1017         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1018         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1019         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1020         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1021         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1022         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1023         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1024         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1025         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1026         g_pickup_healthmega = cvar("g_pickup_healthmega");
1027         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1028         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1029
1030         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1031         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1032
1033     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1034     if(!g_weapon_stay)
1035         g_weapon_stay = cvar("g_weapon_stay");
1036
1037         if not(inWarmupStage)
1038                 game_starttime = time + cvar("g_start_delay");
1039
1040         readplayerstartcvars();
1041 }
1042
1043 //#NO AUTOCVARS END
1044
1045 // Sound functions
1046 string precache_sound (string s) = #19;
1047 float precache_sound_index (string s) = #19;
1048
1049 #define SND_VOLUME      1
1050 #define SND_ATTENUATION 2
1051 #define SND_LARGEENTITY 8
1052 #define SND_LARGESOUND  16
1053
1054 float sound_allowed(float dest, entity e)
1055 {
1056     // sounds from world may always pass
1057     for (;;)
1058     {
1059         if (e.classname == "body")
1060             e = e.enemy;
1061         else if (e.realowner && e.realowner != e)
1062             e = e.realowner;
1063         else if (e.owner && e.owner != e)
1064             e = e.owner;
1065         else
1066             break;
1067     }
1068     // sounds to self may always pass
1069     if (dest == MSG_ONE)
1070         if (e == msg_entity)
1071             return TRUE;
1072     // sounds by players can be removed
1073     if (autocvar_bot_sound_monopoly)
1074         if (IS_REAL_CLIENT(e))
1075             return FALSE;
1076     // anything else may pass
1077     return TRUE;
1078 }
1079
1080 #ifdef COMPAT_XON010_CHANNELS
1081 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1082 void sound(entity e, float chan, string samp, float vol, float atten)
1083 {
1084     if (!sound_allowed(MSG_BROADCAST, e))
1085         return;
1086     builtin_sound(e, chan, samp, vol, atten);
1087 }
1088 #else
1089 #undef sound
1090 void sound(entity e, float chan, string samp, float vol, float atten)
1091 {
1092     if (!sound_allowed(MSG_BROADCAST, e))
1093         return;
1094     sound7(e, chan, samp, vol, atten, 0, 0);
1095 }
1096 #endif
1097
1098 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1099 {
1100     float entno, idx;
1101
1102     if (!sound_allowed(dest, e))
1103         return;
1104
1105     entno = num_for_edict(e);
1106     idx = precache_sound_index(samp);
1107
1108     float sflags;
1109     sflags = 0;
1110
1111     atten = floor(atten * 64);
1112     vol = floor(vol * 255);
1113
1114     if (vol != 255)
1115         sflags |= SND_VOLUME;
1116     if (atten != 64)
1117         sflags |= SND_ATTENUATION;
1118     if (entno >= 8192 || chan < 0 || chan > 7)
1119         sflags |= SND_LARGEENTITY;
1120     if (idx >= 256)
1121         sflags |= SND_LARGESOUND;
1122
1123     WriteByte(dest, SVC_SOUND);
1124     WriteByte(dest, sflags);
1125     if (sflags & SND_VOLUME)
1126         WriteByte(dest, vol);
1127     if (sflags & SND_ATTENUATION)
1128         WriteByte(dest, atten);
1129     if (sflags & SND_LARGEENTITY)
1130     {
1131         WriteShort(dest, entno);
1132         WriteByte(dest, chan);
1133     }
1134     else
1135     {
1136         WriteShort(dest, entno * 8 + chan);
1137     }
1138     if (sflags & SND_LARGESOUND)
1139         WriteShort(dest, idx);
1140     else
1141         WriteByte(dest, idx);
1142
1143     WriteCoord(dest, o_x);
1144     WriteCoord(dest, o_y);
1145     WriteCoord(dest, o_z);
1146 }
1147 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1148 {
1149     vector o;
1150
1151     if (!sound_allowed(dest, e))
1152         return;
1153
1154     o = e.origin + 0.5 * (e.mins + e.maxs);
1155     soundtoat(dest, e, o, chan, samp, vol, atten);
1156 }
1157 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1158 {
1159     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1160 }
1161 void stopsoundto(float dest, entity e, float chan)
1162 {
1163     float entno;
1164
1165     if (!sound_allowed(dest, e))
1166         return;
1167
1168     entno = num_for_edict(e);
1169
1170     if (entno >= 8192 || chan < 0 || chan > 7)
1171     {
1172         float idx, sflags;
1173         idx = precache_sound_index("misc/null.wav");
1174         sflags = SND_LARGEENTITY;
1175         if (idx >= 256)
1176             sflags |= SND_LARGESOUND;
1177         WriteByte(dest, SVC_SOUND);
1178         WriteByte(dest, sflags);
1179         WriteShort(dest, entno);
1180         WriteByte(dest, chan);
1181         if (sflags & SND_LARGESOUND)
1182             WriteShort(dest, idx);
1183         else
1184             WriteByte(dest, idx);
1185         WriteCoord(dest, e.origin_x);
1186         WriteCoord(dest, e.origin_y);
1187         WriteCoord(dest, e.origin_z);
1188     }
1189     else
1190     {
1191         WriteByte(dest, SVC_STOPSOUND);
1192         WriteShort(dest, entno * 8 + chan);
1193     }
1194 }
1195 void stopsound(entity e, float chan)
1196 {
1197     if (!sound_allowed(MSG_BROADCAST, e))
1198         return;
1199
1200     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1201     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1202 }
1203
1204 void play2(entity e, string filename)
1205 {
1206     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1207     msg_entity = e;
1208     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1209 }
1210
1211 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1212 .float spamtime;
1213 float spamsound(entity e, float chan, string samp, float vol, float atten)
1214 {
1215     if (!sound_allowed(MSG_BROADCAST, e))
1216         return FALSE;
1217
1218     if (time > e.spamtime)
1219     {
1220         e.spamtime = time;
1221         sound(e, chan, samp, vol, atten);
1222         return TRUE;
1223     }
1224     return FALSE;
1225 }
1226
1227 void play2team(float t, string filename)
1228 {
1229     entity head;
1230
1231     if (autocvar_bot_sound_monopoly)
1232         return;
1233
1234     FOR_EACH_REALPLAYER(head)
1235     {
1236         if (head.team == t)
1237             play2(head, filename);
1238     }
1239 }
1240
1241 void play2all(string samp)
1242 {
1243     if (autocvar_bot_sound_monopoly)
1244         return;
1245
1246     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1247 }
1248
1249 void PrecachePlayerSounds(string f);
1250 void precache_playermodel(string m)
1251 {
1252         float globhandle, i, n;
1253         string f;
1254
1255         if(substring(m, -9,5) == "_lod1")
1256                 return;
1257         if(substring(m, -9,5) == "_lod2")
1258                 return;
1259         precache_model(m);
1260         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1261         if(fexists(f))
1262                 precache_model(f);
1263         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1264         if(fexists(f))
1265                 precache_model(f);
1266
1267         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1268         if (globhandle < 0)
1269                 return;
1270         n = search_getsize(globhandle);
1271         for (i = 0; i < n; ++i)
1272         {
1273                 //print(search_getfilename(globhandle, i), "\n");
1274                 f = search_getfilename(globhandle, i);
1275                 PrecachePlayerSounds(f);
1276         }
1277         search_end(globhandle);
1278 }
1279 void precache_all_playermodels(string pattern)
1280 {
1281         float globhandle, i, n;
1282         string f;
1283
1284         globhandle = search_begin(pattern, TRUE, FALSE);
1285         if (globhandle < 0)
1286                 return;
1287         n = search_getsize(globhandle);
1288         for (i = 0; i < n; ++i)
1289         {
1290                 //print(search_getfilename(globhandle, i), "\n");
1291                 f = search_getfilename(globhandle, i);
1292                 precache_playermodel(f);
1293         }
1294         search_end(globhandle);
1295 }
1296
1297 void precache()
1298 {
1299     // gamemode related things
1300     precache_model ("models/misc/chatbubble.spr");
1301
1302 #ifdef TTURRETS_ENABLED
1303     if (autocvar_g_turrets)
1304         turrets_precash();
1305 #endif
1306
1307     // Precache all player models if desired
1308     if (autocvar_sv_precacheplayermodels)
1309     {
1310         PrecachePlayerSounds("sound/player/default.sounds");
1311         precache_all_playermodels("models/player/*.zym");
1312         precache_all_playermodels("models/player/*.dpm");
1313         precache_all_playermodels("models/player/*.md3");
1314         precache_all_playermodels("models/player/*.psk");
1315         precache_all_playermodels("models/player/*.iqm");
1316     }
1317
1318     if (autocvar_sv_defaultcharacter)
1319     {
1320         string s;
1321         s = autocvar_sv_defaultplayermodel_red;
1322         if (s != "")
1323             precache_playermodel(s);
1324         s = autocvar_sv_defaultplayermodel_blue;
1325         if (s != "")
1326             precache_playermodel(s);
1327         s = autocvar_sv_defaultplayermodel_yellow;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_pink;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel;
1334         if (s != "")
1335             precache_playermodel(s);
1336     }
1337
1338     if (g_footsteps)
1339     {
1340         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1341         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1342     }
1343
1344     // gore and miscellaneous sounds
1345     //precache_sound ("misc/h2ohit.wav");
1346     precache_model ("models/hook.md3");
1347     precache_sound ("misc/armorimpact.wav");
1348     precache_sound ("misc/bodyimpact1.wav");
1349     precache_sound ("misc/bodyimpact2.wav");
1350     precache_sound ("misc/gib.wav");
1351     precache_sound ("misc/gib_splat01.wav");
1352     precache_sound ("misc/gib_splat02.wav");
1353     precache_sound ("misc/gib_splat03.wav");
1354     precache_sound ("misc/gib_splat04.wav");
1355     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1356     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1357     precache_sound ("misc/null.wav");
1358     precache_sound ("misc/spawn.wav");
1359     precache_sound ("misc/talk.wav");
1360     precache_sound ("misc/teleport.wav");
1361     precache_sound ("misc/poweroff.wav");
1362     precache_sound ("player/lava.wav");
1363     precache_sound ("player/slime.wav");
1364
1365     precache_model ("models/sprites/0.spr32");
1366     precache_model ("models/sprites/1.spr32");
1367     precache_model ("models/sprites/2.spr32");
1368     precache_model ("models/sprites/3.spr32");
1369     precache_model ("models/sprites/4.spr32");
1370     precache_model ("models/sprites/5.spr32");
1371     precache_model ("models/sprites/6.spr32");
1372     precache_model ("models/sprites/7.spr32");
1373     precache_model ("models/sprites/8.spr32");
1374     precache_model ("models/sprites/9.spr32");
1375     precache_model ("models/sprites/10.spr32");
1376
1377     // common weapon precaches
1378         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1379     precache_sound ("weapons/weapon_switch.wav");
1380     precache_sound ("weapons/weaponpickup.wav");
1381     precache_sound ("weapons/unavailable.wav");
1382     precache_sound ("weapons/dryfire.wav");
1383     if (g_grappling_hook)
1384     {
1385         precache_sound ("weapons/hook_fire.wav"); // hook
1386         precache_sound ("weapons/hook_impact.wav"); // hook
1387     }
1388
1389     if(autocvar_sv_precacheweapons)
1390     {
1391         //precache weapon models/sounds
1392         float wep;
1393         wep = WEP_FIRST;
1394         while (wep <= WEP_LAST)
1395         {
1396             weapon_action(wep, WR_PRECACHE);
1397             wep = wep + 1;
1398         }
1399     }
1400
1401     precache_model("models/elaser.mdl");
1402     precache_model("models/laser.mdl");
1403     precache_model("models/ebomb.mdl");
1404
1405 #if 0
1406     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1407
1408     if (!self.noise && self.music) // quake 3 uses the music field
1409         self.noise = self.music;
1410
1411     // plays music for the level if there is any
1412     if (self.noise)
1413     {
1414         precache_sound (self.noise);
1415         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1416     }
1417 #endif
1418 }
1419
1420 // WARNING: this kills the trace globals
1421 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1422 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1423
1424 #define INITPRIO_FIRST              0
1425 #define INITPRIO_GAMETYPE           0
1426 #define INITPRIO_GAMETYPE_FALLBACK  1
1427 #define INITPRIO_FINDTARGET        10
1428 #define INITPRIO_DROPTOFLOOR       20
1429 #define INITPRIO_SETLOCATION       90
1430 #define INITPRIO_LINKDOORS         91
1431 #define INITPRIO_LAST              99
1432
1433 .void(void) initialize_entity;
1434 .float initialize_entity_order;
1435 .entity initialize_entity_next;
1436 entity initialize_entity_first;
1437
1438 void make_safe_for_remove(entity e)
1439 {
1440     if (e.initialize_entity)
1441     {
1442         entity ent, prev = world;
1443         for (ent = initialize_entity_first; ent; )
1444         {
1445             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1446             {
1447                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1448                 // skip it in linked list
1449                 if (prev)
1450                 {
1451                     prev.initialize_entity_next = ent.initialize_entity_next;
1452                     ent = prev.initialize_entity_next;
1453                 }
1454                 else
1455                 {
1456                     initialize_entity_first = ent.initialize_entity_next;
1457                     ent = initialize_entity_first;
1458                 }
1459             }
1460             else
1461             {
1462                 prev = ent;
1463                 ent = ent.initialize_entity_next;
1464             }
1465         }
1466     }
1467 }
1468
1469 void objerror(string s)
1470 {
1471     make_safe_for_remove(self);
1472     builtin_objerror(s);
1473 }
1474
1475 .float remove_except_protected_forbidden;
1476 void remove_except_protected(entity e)
1477 {
1478         if(e.remove_except_protected_forbidden)
1479                 error("not allowed to remove this at this point");
1480         builtin_remove(e);
1481 }
1482
1483 void remove_unsafely(entity e)
1484 {
1485     if(e.classname == "spike")
1486         error("Removing spikes is forbidden (crylink bug), please report");
1487     builtin_remove(e);
1488 }
1489
1490 void remove_safely(entity e)
1491 {
1492     make_safe_for_remove(e);
1493     builtin_remove(e);
1494 }
1495
1496 void InitializeEntity(entity e, void(void) func, float order)
1497 {
1498     entity prev, cur;
1499
1500     if (!e || e.initialize_entity)
1501     {
1502         // make a proxy initializer entity
1503         entity e_old;
1504         e_old = e;
1505         e = spawn();
1506         e.classname = "initialize_entity";
1507         e.enemy = e_old;
1508     }
1509
1510     e.initialize_entity = func;
1511     e.initialize_entity_order = order;
1512
1513     cur = initialize_entity_first;
1514     prev = world;
1515     for (;;)
1516     {
1517         if (!cur || cur.initialize_entity_order > order)
1518         {
1519             // insert between prev and cur
1520             if (prev)
1521                 prev.initialize_entity_next = e;
1522             else
1523                 initialize_entity_first = e;
1524             e.initialize_entity_next = cur;
1525             return;
1526         }
1527         prev = cur;
1528         cur = cur.initialize_entity_next;
1529     }
1530 }
1531 void InitializeEntitiesRun()
1532 {
1533     entity startoflist;
1534     startoflist = initialize_entity_first;
1535     initialize_entity_first = world;
1536     remove = remove_except_protected;
1537     for (self = startoflist; self; self = self.initialize_entity_next)
1538     {
1539         self.remove_except_protected_forbidden = 1;
1540     }
1541     for (self = startoflist; self; )
1542     {
1543         entity e;
1544         var void(void) func;
1545         e = self.initialize_entity_next;
1546         func = self.initialize_entity;
1547         self.initialize_entity_order = 0;
1548         self.initialize_entity = func_null;
1549         self.initialize_entity_next = world;
1550         self.remove_except_protected_forbidden = 0;
1551         if (self.classname == "initialize_entity")
1552         {
1553             entity e_old;
1554             e_old = self.enemy;
1555             builtin_remove(self);
1556             self = e_old;
1557         }
1558         //dprint("Delayed initialization: ", self.classname, "\n");
1559         if(func)
1560             func();
1561         else
1562         {
1563             eprint(self);
1564             backtrace(strcat("Null function in: ", self.classname, "\n"));
1565         }
1566         self = e;
1567     }
1568     remove = remove_unsafely;
1569 }
1570
1571 .float uncustomizeentityforclient_set;
1572 .void(void) uncustomizeentityforclient;
1573 void UncustomizeEntitiesRun()
1574 {
1575     entity oldself;
1576     oldself = self;
1577     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1578         self.uncustomizeentityforclient();
1579     self = oldself;
1580 }
1581 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1582 {
1583     e.customizeentityforclient = customizer;
1584     e.uncustomizeentityforclient = uncustomizer;
1585     e.uncustomizeentityforclient_set = !!uncustomizer;
1586 }
1587
1588 .float nottargeted;
1589 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1590
1591 void() SUB_Remove;
1592 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1593 {
1594     vector mi, ma;
1595
1596     if (e.classname == "")
1597         e.classname = "net_linked";
1598
1599     if (e.model == "" || self.modelindex == 0)
1600     {
1601         mi = e.mins;
1602         ma = e.maxs;
1603         setmodel(e, "null");
1604         setsize(e, mi, ma);
1605     }
1606
1607     e.SendEntity = sendfunc;
1608     e.SendFlags = 0xFFFFFF;
1609
1610     if (!docull)
1611         e.effects |= EF_NODEPTHTEST;
1612
1613     if (dt)
1614     {
1615         e.nextthink = time + dt;
1616         e.think = SUB_Remove;
1617     }
1618 }
1619
1620 void adaptor_think2touch()
1621 {
1622     entity o;
1623     o = other;
1624     other = world;
1625     self.touch();
1626     other = o;
1627 }
1628
1629 void adaptor_think2use()
1630 {
1631     entity o, a;
1632     o = other;
1633     a = activator;
1634     activator = world;
1635     other = world;
1636     self.use();
1637     other = o;
1638     activator = a;
1639 }
1640
1641 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1642 {
1643         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1644                 self.projectiledeathtype |= HITTYPE_SPLASH;
1645         adaptor_think2use();
1646 }
1647
1648 // deferred dropping
1649 void DropToFloor_Handler()
1650 {
1651     builtin_droptofloor();
1652     self.dropped_origin = self.origin;
1653 }
1654
1655 void droptofloor()
1656 {
1657     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1658 }
1659
1660
1661
1662 float trace_hits_box_a0, trace_hits_box_a1;
1663
1664 float trace_hits_box_1d(float end, float thmi, float thma)
1665 {
1666     if (end == 0)
1667     {
1668         // just check if x is in range
1669         if (0 < thmi)
1670             return FALSE;
1671         if (0 > thma)
1672             return FALSE;
1673     }
1674     else
1675     {
1676         // do the trace with respect to x
1677         // 0 -> end has to stay in thmi -> thma
1678         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1679         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1680         if (trace_hits_box_a0 > trace_hits_box_a1)
1681             return FALSE;
1682     }
1683     return TRUE;
1684 }
1685
1686 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1687 {
1688     end -= start;
1689     thmi -= start;
1690     thma -= start;
1691     // now it is a trace from 0 to end
1692
1693     trace_hits_box_a0 = 0;
1694     trace_hits_box_a1 = 1;
1695
1696     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1697         return FALSE;
1698     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1699         return FALSE;
1700     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1701         return FALSE;
1702
1703     return TRUE;
1704 }
1705
1706 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1707 {
1708     return trace_hits_box(start, end, thmi - ma, thma - mi);
1709 }
1710
1711 float SUB_NoImpactCheck()
1712 {
1713         // zero hitcontents = this is not the real impact, but either the
1714         // mirror-impact of something hitting the projectile instead of the
1715         // projectile hitting the something, or a touchareagrid one. Neither of
1716         // these stop the projectile from moving, so...
1717         if(trace_dphitcontents == 0)
1718         {
1719                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1720                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1721                 checkclient();
1722         }
1723     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1724         return 1;
1725     if (other == world && self.size != '0 0 0')
1726     {
1727         vector tic;
1728         tic = self.velocity * sys_frametime;
1729         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1730         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1731         if (trace_fraction >= 1)
1732         {
1733             dprint("Odd... did not hit...?\n");
1734         }
1735         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1736         {
1737             dprint("Detected and prevented the sky-grapple bug.\n");
1738             return 1;
1739         }
1740     }
1741
1742     return 0;
1743 }
1744
1745 #define SUB_OwnerCheck() (other && (other == self.owner))
1746
1747 void RemoveGrapplingHook(entity pl);
1748 void W_Crylink_Dequeue(entity e);
1749 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1750 {
1751         if(SUB_OwnerCheck())
1752                 return TRUE;
1753         if(SUB_NoImpactCheck())
1754         {
1755                 if(self.classname == "grapplinghook")
1756                         RemoveGrapplingHook(self.realowner);
1757                 else if(self.classname == "spike")
1758                 {
1759                         W_Crylink_Dequeue(self);
1760                         remove(self);
1761                 }
1762                 else
1763                         remove(self);
1764                 return TRUE;
1765         }
1766         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1767                 UpdateCSQCProjectile(self);
1768         return FALSE;
1769 }
1770 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1771
1772 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1773 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1774
1775 void URI_Get_Callback(float id, float status, string data)
1776 {
1777         if(url_URI_Get_Callback(id, status, data))
1778         {
1779                 // handled
1780         }
1781         else if (id == URI_GET_DISCARD)
1782         {
1783                 // discard
1784         }
1785         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1786         {
1787                 // sv_cmd curl
1788                 Curl_URI_Get_Callback(id, status, data);
1789         }
1790         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1791         {
1792                 // online ban list
1793                 OnlineBanList_URI_Get_Callback(id, status, data);
1794         }
1795         else
1796         {
1797                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1798         }
1799 }
1800
1801 string uid2name(string myuid) {
1802         string s;
1803         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1804
1805         // FIXME remove this later after 0.6 release
1806         // convert old style broken records to correct style
1807         if(s == "")
1808         {
1809                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1810                 if(s != "")
1811                 {
1812                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1813                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1814                 }
1815         }
1816
1817         if(s == "")
1818                 s = "^1Unregistered Player";
1819         return s;
1820 }
1821
1822 float race_readTime(string map, float pos)
1823 {
1824         string rr;
1825         if(g_cts)
1826                 rr = CTS_RECORD;
1827         else
1828                 rr = RACE_RECORD;
1829
1830         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1831 }
1832
1833 string race_readUID(string map, float pos)
1834 {
1835         string rr;
1836         if(g_cts)
1837                 rr = CTS_RECORD;
1838         else
1839                 rr = RACE_RECORD;
1840
1841         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1842 }
1843
1844 float race_readPos(string map, float t) {
1845         float i;
1846         for (i = 1; i <= RANKINGS_CNT; ++i)
1847                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1848                         return i;
1849
1850         return 0; // pos is zero if unranked
1851 }
1852
1853 void race_writeTime(string map, float t, string myuid)
1854 {
1855         string rr;
1856         if(g_cts)
1857                 rr = CTS_RECORD;
1858         else
1859                 rr = RACE_RECORD;
1860
1861         float newpos;
1862         newpos = race_readPos(map, t);
1863
1864         float i, prevpos = 0;
1865         for(i = 1; i <= RANKINGS_CNT; ++i)
1866         {
1867                 if(race_readUID(map, i) == myuid)
1868                         prevpos = i;
1869         }
1870         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1871                 for (i = prevpos; i > newpos; --i) {
1872                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1873                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1874                 }
1875         } else { // player has no ranked record yet
1876                 for (i = RANKINGS_CNT; i > newpos; --i) {
1877                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1878                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1879                 }
1880         }
1881
1882         // store new time itself
1883         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1884         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1885 }
1886
1887 string race_readName(string map, float pos)
1888 {
1889         string rr;
1890         if(g_cts)
1891                 rr = CTS_RECORD;
1892         else
1893                 rr = RACE_RECORD;
1894
1895         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1896 }
1897
1898 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1899 {
1900     float m, i;
1901     vector start, org, delta, end, enddown, mstart;
1902     entity sp;
1903
1904     m = e.dphitcontentsmask;
1905     e.dphitcontentsmask = goodcontents | badcontents;
1906
1907     org = world.mins;
1908     delta = world.maxs - world.mins;
1909
1910     start = end = org;
1911
1912     for (i = 0; i < attempts; ++i)
1913     {
1914         start_x = org_x + random() * delta_x;
1915         start_y = org_y + random() * delta_y;
1916         start_z = org_z + random() * delta_z;
1917
1918         // rule 1: start inside world bounds, and outside
1919         // solid, and don't start from somewhere where you can
1920         // fall down to evil
1921         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1922         if (trace_fraction >= 1)
1923             continue;
1924         if (trace_startsolid)
1925             continue;
1926         if (trace_dphitcontents & badcontents)
1927             continue;
1928         if (trace_dphitq3surfaceflags & badsurfaceflags)
1929             continue;
1930
1931         // rule 2: if we are too high, lower the point
1932         if (trace_fraction * delta_z > maxaboveground)
1933             start = trace_endpos + '0 0 1' * maxaboveground;
1934         enddown = trace_endpos;
1935
1936         // rule 3: make sure we aren't outside the map. This only works
1937         // for somewhat well formed maps. A good rule of thumb is that
1938         // the map should have a convex outside hull.
1939         // these can be traceLINES as we already verified the starting box
1940         mstart = start + 0.5 * (e.mins + e.maxs);
1941         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1942         if (trace_fraction >= 1)
1943             continue;
1944         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1945         if (trace_fraction >= 1)
1946             continue;
1947         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1948         if (trace_fraction >= 1)
1949             continue;
1950         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1951         if (trace_fraction >= 1)
1952             continue;
1953         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1954         if (trace_fraction >= 1)
1955             continue;
1956
1957         // rule 4: we must "see" some spawnpoint
1958         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1959                 if(checkpvs(mstart, sp))
1960                         break;
1961         if(!sp)
1962         {
1963                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1964                         if(checkpvs(mstart, sp))
1965                                 break;
1966                 if(!sp)
1967                         continue;
1968         }
1969
1970         // find a random vector to "look at"
1971         end_x = org_x + random() * delta_x;
1972         end_y = org_y + random() * delta_y;
1973         end_z = org_z + random() * delta_z;
1974         end = start + normalize(end - start) * vlen(delta);
1975
1976         // rule 4: start TO end must not be too short
1977         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1978         if (trace_startsolid)
1979             continue;
1980         if (trace_fraction < minviewdistance / vlen(delta))
1981             continue;
1982
1983         // rule 5: don't want to look at sky
1984         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1985             continue;
1986
1987         // rule 6: we must not end up in trigger_hurt
1988         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1989             continue;
1990
1991         break;
1992     }
1993
1994     e.dphitcontentsmask = m;
1995
1996     if (i < attempts)
1997     {
1998         setorigin(e, start);
1999         e.angles = vectoangles(end - start);
2000         dprint("Needed ", ftos(i + 1), " attempts\n");
2001         return TRUE;
2002     }
2003     else
2004         return FALSE;
2005 }
2006
2007 float zcurveparticles_effectno;
2008 vector zcurveparticles_start;
2009 float zcurveparticles_spd;
2010
2011 void endzcurveparticles()
2012 {
2013         if(zcurveparticles_effectno)
2014         {
2015                 // terminator
2016                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2017         }
2018         zcurveparticles_effectno = 0;
2019 }
2020
2021 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2022 {
2023         spd = bound(0, floor(spd / 16), 32767);
2024         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2025         {
2026                 endzcurveparticles();
2027                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2028                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2029                 WriteShort(MSG_BROADCAST, effectno);
2030                 WriteCoord(MSG_BROADCAST, start_x);
2031                 WriteCoord(MSG_BROADCAST, start_y);
2032                 WriteCoord(MSG_BROADCAST, start_z);
2033                 zcurveparticles_effectno = effectno;
2034                 zcurveparticles_start = start;
2035         }
2036         else
2037                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2038         WriteCoord(MSG_BROADCAST, end_x);
2039         WriteCoord(MSG_BROADCAST, end_y);
2040         WriteCoord(MSG_BROADCAST, end_z);
2041         WriteCoord(MSG_BROADCAST, end_dz);
2042         zcurveparticles_spd = spd;
2043 }
2044
2045 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2046 {
2047         float end_dz;
2048         vector vecxy, velxy;
2049
2050         vecxy = end - start;
2051         vecxy_z = 0;
2052         velxy = vel;
2053         velxy_z = 0;
2054
2055         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2056         {
2057                 endzcurveparticles();
2058                 trailparticles(world, effectno, start, end);
2059                 return;
2060         }
2061
2062         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2063         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2064 }
2065
2066 void write_recordmarker(entity pl, float tstart, float dt)
2067 {
2068     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2069
2070     // also write a marker into demo files for demotc-race-record-extractor to find
2071     stuffcmd(pl,
2072              strcat(
2073                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2074                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2075 }
2076
2077 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2078 {
2079         switch(algn)
2080         {
2081                 default:
2082                 case 3: // right
2083                         break;
2084
2085                 case 4: // left
2086                         vecs_y = -vecs_y;
2087                         break;
2088
2089                 case 1:
2090                         if(allowcenter) // 2: allow center handedness
2091                         {
2092                                 // center
2093                                 vecs_y = 0;
2094                                 vecs_z -= 2;
2095                         }
2096                         else
2097                         {
2098                                 // right
2099                         }
2100                         break;
2101
2102                 case 2:
2103                         if(allowcenter) // 2: allow center handedness
2104                         {
2105                                 // center
2106                                 vecs_y = 0;
2107                                 vecs_z -= 2;
2108                         }
2109                         else
2110                         {
2111                                 // left
2112                                 vecs_y = -vecs_y;
2113                         }
2114                         break;
2115         }
2116         return vecs;
2117 }
2118
2119 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2120 {
2121         string s;
2122         vector v;
2123
2124         if (autocvar_g_shootfromeye)
2125         {
2126                 if (visual)
2127                 {
2128                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2129                         else { vecs_y = 0; vecs_z -= 2; }
2130                 }
2131                 else
2132                 {
2133                         vecs_y = 0;
2134                         vecs_z = 0;
2135                 }
2136         }
2137         else if (autocvar_g_shootfromcenter)
2138         {
2139                 vecs_y = 0;
2140                 vecs_z -= 2;
2141         }
2142         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2143         {
2144                 v = stov(s);
2145                 if (y_is_right)
2146                         v_y = -v_y;
2147                 if (v_x != 0)
2148                         vecs_x = v_x;
2149                 vecs_y = v_y;
2150                 vecs_z = v_z;
2151         }
2152         else if (autocvar_g_shootfromclient)
2153         {
2154                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2155         }
2156         return vecs;
2157 }
2158
2159 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2160 {
2161         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2162 }
2163
2164
2165 void attach_sameorigin(entity e, entity to, string tag)
2166 {
2167     vector org, t_forward, t_left, t_up, e_forward, e_up;
2168     float tagscale;
2169
2170     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2171     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2172     t_forward = v_forward * tagscale;
2173     t_left = v_right * -tagscale;
2174     t_up = v_up * tagscale;
2175
2176     e.origin_x = org * t_forward;
2177     e.origin_y = org * t_left;
2178     e.origin_z = org * t_up;
2179
2180     // current forward and up directions
2181     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2182                 e.angles = AnglesTransform_FromVAngles(e.angles);
2183         else
2184                 e.angles = AnglesTransform_FromAngles(e.angles);
2185     fixedmakevectors(e.angles);
2186
2187     // untransform forward, up!
2188     e_forward_x = v_forward * t_forward;
2189     e_forward_y = v_forward * t_left;
2190     e_forward_z = v_forward * t_up;
2191     e_up_x = v_up * t_forward;
2192     e_up_y = v_up * t_left;
2193     e_up_z = v_up * t_up;
2194
2195     e.angles = fixedvectoangles2(e_forward, e_up);
2196     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2197                 e.angles = AnglesTransform_ToVAngles(e.angles);
2198         else
2199                 e.angles = AnglesTransform_ToAngles(e.angles);
2200
2201     setattachment(e, to, tag);
2202     setorigin(e, e.origin);
2203 }
2204
2205 void detach_sameorigin(entity e)
2206 {
2207     vector org;
2208     org = gettaginfo(e, 0);
2209     e.angles = fixedvectoangles2(v_forward, v_up);
2210     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2211                 e.angles = AnglesTransform_ToVAngles(e.angles);
2212         else
2213                 e.angles = AnglesTransform_ToAngles(e.angles);
2214     setorigin(e, org);
2215     setattachment(e, world, "");
2216     setorigin(e, e.origin);
2217 }
2218
2219 void follow_sameorigin(entity e, entity to)
2220 {
2221     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2222     e.aiment = to; // make the hole follow bmodel
2223     e.punchangle = to.angles; // the original angles of bmodel
2224     e.view_ofs = e.origin - to.origin; // relative origin
2225     e.v_angle = e.angles - to.angles; // relative angles
2226 }
2227
2228 void unfollow_sameorigin(entity e)
2229 {
2230     e.movetype = MOVETYPE_NONE;
2231 }
2232
2233 entity gettaginfo_relative_ent;
2234 vector gettaginfo_relative(entity e, float tag)
2235 {
2236     if (!gettaginfo_relative_ent)
2237     {
2238         gettaginfo_relative_ent = spawn();
2239         gettaginfo_relative_ent.effects = EF_NODRAW;
2240     }
2241     gettaginfo_relative_ent.model = e.model;
2242     gettaginfo_relative_ent.modelindex = e.modelindex;
2243     gettaginfo_relative_ent.frame = e.frame;
2244     return gettaginfo(gettaginfo_relative_ent, tag);
2245 }
2246
2247 .float scale2;
2248
2249 float modeleffect_SendEntity(entity to, float sf)
2250 {
2251         float f;
2252         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2253
2254         f = 0;
2255         if(self.velocity != '0 0 0')
2256                 f |= 1;
2257         if(self.angles != '0 0 0')
2258                 f |= 2;
2259         if(self.avelocity != '0 0 0')
2260                 f |= 4;
2261
2262         WriteByte(MSG_ENTITY, f);
2263         WriteShort(MSG_ENTITY, self.modelindex);
2264         WriteByte(MSG_ENTITY, self.skin);
2265         WriteByte(MSG_ENTITY, self.frame);
2266         WriteCoord(MSG_ENTITY, self.origin_x);
2267         WriteCoord(MSG_ENTITY, self.origin_y);
2268         WriteCoord(MSG_ENTITY, self.origin_z);
2269         if(f & 1)
2270         {
2271                 WriteCoord(MSG_ENTITY, self.velocity_x);
2272                 WriteCoord(MSG_ENTITY, self.velocity_y);
2273                 WriteCoord(MSG_ENTITY, self.velocity_z);
2274         }
2275         if(f & 2)
2276         {
2277                 WriteCoord(MSG_ENTITY, self.angles_x);
2278                 WriteCoord(MSG_ENTITY, self.angles_y);
2279                 WriteCoord(MSG_ENTITY, self.angles_z);
2280         }
2281         if(f & 4)
2282         {
2283                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2284                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2285                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2286         }
2287         WriteShort(MSG_ENTITY, self.scale * 256.0);
2288         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2289         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2290         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2291         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2292
2293         return TRUE;
2294 }
2295
2296 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2297 {
2298         entity e;
2299         float sz;
2300         e = spawn();
2301         e.classname = "modeleffect";
2302         setmodel(e, m);
2303         e.frame = f;
2304         setorigin(e, o);
2305         e.velocity = v;
2306         e.angles = ang;
2307         e.avelocity = angv;
2308         e.alpha = a;
2309         e.teleport_time = t1;
2310         e.fade_time = t2;
2311         e.skin = s;
2312         if(s0 >= 0)
2313                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2314         else
2315                 e.scale = -s0;
2316         if(s2 >= 0)
2317                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2318         else
2319                 e.scale2 = -s2;
2320         sz = max(e.scale, e.scale2);
2321         setsize(e, e.mins * sz, e.maxs * sz);
2322         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2323 }
2324
2325 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2326 {
2327         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2328 }
2329
2330 float randombit(float bits)
2331 {
2332         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2333                 return bits;
2334
2335         float n, f, b, r;
2336
2337         r = random();
2338         b = 0;
2339         n = 0;
2340
2341         for(f = 1; f <= bits; f *= 2)
2342         {
2343                 if(bits & f)
2344                 {
2345                         ++n;
2346                         r *= n;
2347                         if(r <= 1)
2348                                 b = f;
2349                         else
2350                                 r = (r - 1) / (n - 1);
2351                 }
2352         }
2353
2354         return b;
2355 }
2356
2357 float randombits(float bits, float k, float error_return)
2358 {
2359         float r;
2360         r = 0;
2361         while(k > 0 && bits != r)
2362         {
2363                 r += randombit(bits - r);
2364                 --k;
2365         }
2366         if(error_return)
2367                 if(k > 0)
2368                         return -1; // all
2369         return r;
2370 }
2371
2372 void randombit_test(float bits, float iter)
2373 {
2374         while(iter > 0)
2375         {
2376                 print(ftos(randombit(bits)), "\n");
2377                 --iter;
2378         }
2379 }
2380
2381 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2382 {
2383         if(halflifedist > 0)
2384                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2385         else if(halflifedist < 0)
2386                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2387         else
2388                 return 1;
2389 }
2390
2391
2392
2393
2394 #ifdef RELEASE
2395 #define cvar_string_normal builtin_cvar_string
2396 #define cvar_normal builtin_cvar
2397 #else
2398 string cvar_string_normal(string n)
2399 {
2400         if not(cvar_type(n) & 1)
2401                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2402         return builtin_cvar_string(n);
2403 }
2404
2405 float cvar_normal(string n)
2406 {
2407         return stof(cvar_string_normal(n));
2408 }
2409 #endif
2410 #define cvar_set_normal builtin_cvar_set
2411
2412 void defer_think()
2413 {
2414     entity oself;
2415
2416     oself           = self;
2417     self            = self.owner;
2418     oself.think     = SUB_Remove;
2419     oself.nextthink = time;
2420
2421     oself.use();
2422 }
2423
2424 /*
2425     Execute func() after time + fdelay.
2426     self when func is executed = self when defer is called
2427 */
2428 void defer(float fdelay, void() func)
2429 {
2430     entity e;
2431
2432     e           = spawn();
2433     e.owner     = self;
2434     e.use       = func;
2435     e.think     = defer_think;
2436     e.nextthink = time + fdelay;
2437 }
2438
2439 .string aiment_classname;
2440 .float aiment_deadflag;
2441 void SetMovetypeFollow(entity ent, entity e)
2442 {
2443         // FIXME this may not be warpzone aware
2444         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2445         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2446         ent.aiment = e; // make the hole follow bmodel
2447         ent.punchangle = e.angles; // the original angles of bmodel
2448         ent.view_ofs = ent.origin - e.origin; // relative origin
2449         ent.v_angle = ent.angles - e.angles; // relative angles
2450         ent.aiment_classname = strzone(e.classname);
2451         ent.aiment_deadflag = e.deadflag;
2452 }
2453 void UnsetMovetypeFollow(entity ent)
2454 {
2455         ent.movetype = MOVETYPE_FLY;
2456         PROJECTILE_MAKETRIGGER(ent);
2457         ent.aiment = world;
2458 }
2459 float LostMovetypeFollow(entity ent)
2460 {
2461 /*
2462         if(ent.movetype != MOVETYPE_FOLLOW)
2463                 if(ent.aiment)
2464                         error("???");
2465 */
2466         if(ent.aiment)
2467         {
2468                 if(ent.aiment.classname != ent.aiment_classname)
2469                         return 1;
2470                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2471                         return 1;
2472         }
2473         return 0;
2474 }
2475
2476 float isPushable(entity e)
2477 {
2478         if(e.iscreature)
2479                 return TRUE;
2480         if(e.pushable)
2481                 return TRUE;
2482         switch(e.classname)
2483         {
2484                 case "body":
2485                 case "droppedweapon":
2486                 case "keepawayball":
2487                 case "nexball_basketball":
2488                 case "nexball_football":
2489                         return TRUE;
2490                 case "bullet": // antilagged bullets can't hit this either
2491                         return FALSE;
2492         }
2493         if (e.projectiledeathtype)
2494                 return TRUE;
2495         return FALSE;
2496 }