qcsrc/server/miscfunctions.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "miscfunctions.qh"
   5         #include "../dpdefs/progsdefs.qh"
   6     #include "../dpdefs/dpextensions.qh"
   7     #include "../common/playerstats.qh"
   8     #include "../warpzonelib/anglestransform.qh"
   9     #include "../warpzonelib/server.qh"
  10     #include "../common/constants.qh"
  11     #include "../common/teams.qh"
  12     #include "../common/util.qh"
  13     #include "../common/urllib.qh"
  14     #include "../common/command/generic.qh"
  15     #include "../common/weapons/weapons.qh"
  16     #include "weapons/accuracy.qh"
  17     #include "weapons/csqcprojectile.qh"
  18     #include "weapons/selection.qh"
  19     #include "t_items.qh"
  20     #include "autocvars.qh"
  21     #include "constants.qh"
  22     #include "defs.qh"
  23     #include "../common/notifications.qh"
  24     #include "../common/deathtypes.qh"
  25     #include "mutators/mutators_include.qh"
  26     #include "tturrets/include/turrets_early.qh"
  27     #include "../common/mapinfo.qh"
  28     #include "command/common.qh"
  29     #include "../csqcmodellib/sv_model.qh"
  30     #include "ipban.qh"
  31 #endif
  32
  33 void crosshair_trace(entity pl)
  34 {
  35         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  36 }
  37 void crosshair_trace_plusvisibletriggers(entity pl)
  38 {
  39         entity first;
  40         entity e;
  41         first = findchainfloat(solid, SOLID_TRIGGER);
  42
  43         for (e = first; e; e = e.chain)
  44                 if (e.model != "")
  45                         e.solid = SOLID_BSP;
  46
  47         crosshair_trace(pl);
  48
  49         for (e = first; e; e = e.chain)
  50                 e.solid = SOLID_TRIGGER;
  51 }
  52 void WarpZone_crosshair_trace(entity pl)
  53 {
  54         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  55 }
  56
  57
  58 string admin_name(void)
  59 {
  60         if(autocvar_sv_adminnick != "")
  61                 return autocvar_sv_adminnick;
  62         else
  63                 return "SERVER ADMIN";
  64 }
  65
  66 void DistributeEvenly_Init(float amount, float totalweight)
  67 {
  68     if (DistributeEvenly_amount)
  69     {
  70         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  71         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  72     }
  73     if (totalweight == 0)
  74         DistributeEvenly_amount = 0;
  75     else
  76         DistributeEvenly_amount = amount;
  77     DistributeEvenly_totalweight = totalweight;
  78 }
  79 float DistributeEvenly_Get(float weight)
  80 {
  81     float f;
  82     if (weight <= 0)
  83         return 0;
  84     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  85     DistributeEvenly_totalweight -= weight;
  86     DistributeEvenly_amount -= f;
  87     return f;
  88 }
  89 float DistributeEvenly_GetRandomized(float weight)
  90 {
  91     float f;
  92     if (weight <= 0)
  93         return 0;
  94     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  95     DistributeEvenly_totalweight -= weight;
  96     DistributeEvenly_amount -= f;
  97     return f;
  98 }
  99
 100
 101 void GameLogEcho(string s)
 102 {
 103     string fn;
 104     float matches;
 105
 106     if (autocvar_sv_eventlog_files)
 107     {
 108         if (!logfile_open)
 109         {
 110             logfile_open = true;
 111             matches = autocvar_sv_eventlog_files_counter + 1;
 112             cvar_set("sv_eventlog_files_counter", ftos(matches));
 113             fn = ftos(matches);
 114             if (strlen(fn) < 8)
 115                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 116             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 117             logfile = fopen(fn, FILE_APPEND);
 118             fputs(logfile, ":logversion:3\n");
 119         }
 120         if (logfile >= 0)
 121         {
 122             if (autocvar_sv_eventlog_files_timestamps)
 123                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 124             else
 125                 fputs(logfile, strcat(s, "\n"));
 126         }
 127     }
 128     if (autocvar_sv_eventlog_console)
 129     {
 130         print(s, "\n");
 131     }
 132 }
 133
 134 void GameLogInit()
 135 {
 136     logfile_open = 0;
 137     // will be opened later
 138 }
 139
 140 void GameLogClose()
 141 {
 142     if (logfile_open && logfile >= 0)
 143     {
 144         fclose(logfile);
 145         logfile = -1;
 146     }
 147 }
 148
 149 entity findnearest(vector point, .string field, string value, vector axismod)
 150 {
 151     entity localhead;
 152     float i;
 153     float j;
 154     float len;
 155     vector dist;
 156
 157     float num_nearest;
 158     num_nearest = 0;
 159
 160     localhead = find(world, field, value);
 161     while (localhead)
 162     {
 163         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 164             dist = localhead.oldorigin;
 165         else
 166             dist = localhead.origin;
 167         dist = dist - point;
 168         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 169         len = vlen(dist);
 170
 171         for (i = 0; i < num_nearest; ++i)
 172         {
 173             if (len < nearest_length[i])
 174                 break;
 175         }
 176
 177         // now i tells us where to insert at
 178         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 179         if (i < NUM_NEAREST_ENTITIES)
 180         {
 181             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 182             {
 183                 nearest_length[j + 1] = nearest_length[j];
 184                 nearest_entity[j + 1] = nearest_entity[j];
 185             }
 186             nearest_length[i] = len;
 187             nearest_entity[i] = localhead;
 188             if (num_nearest < NUM_NEAREST_ENTITIES)
 189                 num_nearest = num_nearest + 1;
 190         }
 191
 192         localhead = find(localhead, field, value);
 193     }
 194
 195     // now use the first one from our list that we can see
 196     for (i = 0; i < num_nearest; ++i)
 197     {
 198         traceline(point, nearest_entity[i].origin, true, world);
 199         if (trace_fraction == 1)
 200         {
 201             if (i != 0)
 202             {
 203                 dprint("Nearest point (");
 204                 dprint(nearest_entity[0].netname);
 205                 dprint(") is not visible, using a visible one.\n");
 206             }
 207             return nearest_entity[i];
 208         }
 209     }
 210
 211     if (num_nearest == 0)
 212         return world;
 213
 214     dprint("Not seeing any location point, using nearest as fallback.\n");
 215     /* DEBUGGING CODE:
 216     dprint("Candidates were: ");
 217     for(j = 0; j < num_nearest; ++j)
 218     {
 219         if(j != 0)
 220                 dprint(", ");
 221         dprint(nearest_entity[j].netname);
 222     }
 223     dprint("\n");
 224     */
 225
 226     return nearest_entity[0];
 227 }
 228
 229 void spawnfunc_target_location()
 230 {
 231     self.classname = "target_location";
 232     // location name in netname
 233     // eventually support: count, teamgame selectors, line of sight?
 234 }
 235
 236 void spawnfunc_info_location()
 237 {
 238     self.classname = "target_location";
 239     self.message = self.netname;
 240 }
 241
 242 string NearestLocation(vector p)
 243 {
 244     entity loc;
 245     string ret;
 246     ret = "somewhere";
 247     loc = findnearest(p, classname, "target_location", '1 1 1');
 248     if (loc)
 249     {
 250         ret = loc.message;
 251     }
 252     else
 253     {
 254         loc = findnearest(p, target, "###item###", '1 1 4');
 255         if (loc)
 256             ret = loc.netname;
 257     }
 258     return ret;
 259 }
 260
 261 string formatmessage(string msg)
 262 {
 263         float p, p1, p2;
 264         float n;
 265         vector cursor;
 266         entity cursor_ent;
 267         string escape;
 268         string replacement;
 269         p = 0;
 270         n = 7;
 271
 272         WarpZone_crosshair_trace(self);
 273         cursor = trace_endpos;
 274         cursor_ent = trace_ent;
 275
 276         while (1) {
 277                 if (n < 1)
 278                         break; // too many replacements
 279
 280                 n = n - 1;
 281                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 282                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 283
 284                 if (p1 < 0)
 285                         p1 = p2;
 286
 287                 if (p2 < 0)
 288                         p2 = p1;
 289
 290                 p = min(p1, p2);
 291
 292                 if (p < 0)
 293                         break;
 294
 295                 replacement = substring(msg, p, 2);
 296                 escape = substring(msg, p + 1, 1);
 297
 298                 if (escape == "%")
 299                         replacement = "%";
 300                 else if (escape == "\\")
 301                         replacement = "\\";
 302                 else if (escape == "n")
 303                         replacement = "\n";
 304                 else if (escape == "a")
 305                         replacement = ftos(floor(self.armorvalue));
 306                 else if (escape == "h")
 307                         replacement = ftos(floor(self.health));
 308                 else if (escape == "l")
 309                         replacement = NearestLocation(self.origin);
 310                 else if (escape == "y")
 311                         replacement = NearestLocation(cursor);
 312                 else if (escape == "d")
 313                         replacement = NearestLocation(self.death_origin);
 314                 else if (escape == "w") {
 315                         float wep;
 316                         wep = self.weapon;
 317                         if (!wep)
 318                                 wep = self.switchweapon;
 319                         if (!wep)
 320                                 wep = self.cnt;
 321                         replacement = WEP_NAME(wep);
 322                 } else if (escape == "W") {
 323                         if (self.items & IT_SHELLS) replacement = "shells";
 324                         else if (self.items & IT_NAILS) replacement = "bullets";
 325                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 326                         else if (self.items & IT_CELLS) replacement = "cells";
 327                         else if (self.items & IT_PLASMA) replacement = "plasma";
 328                         else replacement = "batteries"; // ;)
 329                 } else if (escape == "x") {
 330                         replacement = cursor_ent.netname;
 331                         if (replacement == "" || !cursor_ent)
 332                                 replacement = "nothing";
 333                 } else if (escape == "s")
 334                         replacement = ftos(vlen(self.velocity - self.velocity.z * '0 0 1'));
 335                 else if (escape == "S")
 336                         replacement = ftos(vlen(self.velocity));
 337
 338                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 339                 p = p + strlen(replacement);
 340         }
 341         return msg;
 342 }
 343
 344 float boolean(float value) { // if value is 0 return false (0), otherwise return true (1)
 345         return (value == 0) ? false : true;
 346 }
 347
 348 /*
 349 =============
 350 GetCvars
 351 =============
 352 Called with:
 353   0:  sends the request
 354   >0: receives a cvar from name=argv(f) value=argv(f+1)
 355 */
 356 void GetCvars_handleString(string thisname, float f, .string field, string name)
 357 {
 358         if (f < 0)
 359         {
 360                 if (self.field)
 361                         strunzone(self.field);
 362                 self.field = string_null;
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (self.field)
 369                                 strunzone(self.field);
 370                         self.field = strzone(argv(f + 1));
 371                 }
 372         }
 373         else
 374                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 375 }
 376 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 377 {
 378         GetCvars_handleString(thisname, f, field, name);
 379         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 380                 if (thisname == name)
 381                 {
 382                         string s;
 383                         s = func(strcat1(self.field));
 384                         if (s != self.field)
 385                         {
 386                                 strunzone(self.field);
 387                                 self.field = strzone(s);
 388                         }
 389                 }
 390 }
 391 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 392 {
 393         if (f < 0)
 394         {
 395         }
 396         else if (f > 0)
 397         {
 398                 if (thisname == name)
 399                         self.field = stof(argv(f + 1));
 400         }
 401         else
 402                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 403 }
 404 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 405 {
 406         if (f < 0)
 407         {
 408         }
 409         else if (f > 0)
 410         {
 411                 if (thisname == name)
 412                 {
 413                         if(!self.field)
 414                         {
 415                                 self.field = stof(argv(f + 1));
 416                                 if(!self.field)
 417                                         self.field = -1;
 418                         }
 419                 }
 420         }
 421         else
 422         {
 423                 if(!self.field)
 424                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 425         }
 426 }
 427 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 428 {
 429         string o;
 430         o = W_FixWeaponOrder_ForceComplete(wo);
 431         if(self.weaponorder_byimpulse)
 432         {
 433                 strunzone(self.weaponorder_byimpulse);
 434                 self.weaponorder_byimpulse = string_null;
 435         }
 436         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 437         return o;
 438 }
 439 void GetCvars(float f)
 440 {
 441         string s = string_null;
 442
 443         if (f > 0)
 444                 s = strcat1(argv(f));
 445
 446         get_cvars_f = f;
 447         get_cvars_s = s;
 448
 449         MUTATOR_CALLHOOK(GetCvars);
 450
 451         Notification_GetCvars();
 452
 453         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 454         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 455         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 456         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 457         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 458         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 459         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 460         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 461         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 462         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 463         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 464         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 465         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 466         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 467         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 468         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 469         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 470         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 471         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 472         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 473         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 474         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 475         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 476         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 477
 478         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 479         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 480
 481         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 482         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 483         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 484         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 485         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 486
 487         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 488         if (f > 0)
 489         {
 490                 if (s == "cl_weaponpriority")
 491                         self.switchweapon = w_getbestweapon(self);
 492                 if (s == "cl_allow_uidtracking")
 493                         PlayerStats_GameReport_AddPlayer(self);
 494         }
 495 }
 496
 497 // decolorizes and team colors the player name when needed
 498 string playername(entity p)
 499 {
 500     string t;
 501     if (teamplay && !intermission_running && IS_PLAYER(p))
 502     {
 503         t = Team_ColorCode(p.team);
 504         return strcat(t, strdecolorize(p.netname));
 505     }
 506     else
 507         return p.netname;
 508 }
 509
 510 vector randompos(vector m1, vector m2)
 511 {
 512     vector v;
 513     m2 = m2 - m1;
 514     v.x = m2_x * random() + m1_x;
 515     v.y = m2_y * random() + m1_y;
 516     v.z = m2_z * random() + m1_z;
 517     return  v;
 518 }
 519
 520 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 521 {
 522         int i = weaponinfo.weapon;
 523         int d = 0;
 524
 525         if (!i)
 526                 return 0;
 527
 528         if (g_lms || g_ca || allguns)
 529         {
 530                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 531                         d = true;
 532                 else
 533                         d = false;
 534         }
 535         else if (g_cts)
 536                 d = (i == WEP_SHOTGUN);
 537         else if (g_nexball)
 538                 d = 0; // weapon is set a few lines later
 539         else
 540                 d = !(!weaponinfo.weaponstart);
 541
 542         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 543                 d |= (i == WEP_HOOK);
 544         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 545                 d = 0;
 546
 547         float t = weaponinfo.weaponstartoverride;
 548
 549         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 550
 551         // bit order in t:
 552         // 1: want or not
 553         // 2: is default?
 554         // 4: is set by default?
 555         if(t < 0)
 556                 t = 4 | (3 * d);
 557         else
 558                 t |= (2 * d);
 559
 560         return t;
 561 }
 562
 563 void readplayerstartcvars()
 564 {
 565         entity e;
 566         float i, j, t;
 567         string s;
 568
 569         // initialize starting values for players
 570         start_weapons = '0 0 0';
 571         start_weapons_default = '0 0 0';
 572         start_weapons_defaultmask = '0 0 0';
 573         start_items = 0;
 574         start_ammo_shells = 0;
 575         start_ammo_nails = 0;
 576         start_ammo_rockets = 0;
 577         start_ammo_cells = 0;
 578         start_ammo_plasma = 0;
 579         start_health = cvar("g_balance_health_start");
 580         start_armorvalue = cvar("g_balance_armor_start");
 581
 582         g_weaponarena = 0;
 583         g_weaponarena_weapons = '0 0 0';
 584
 585         s = cvar_string("g_weaponarena");
 586         if (s == "0" || s == "")
 587         {
 588                 if(g_ca)
 589                         s = "most";
 590         }
 591
 592         if (s == "0" || s == "")
 593         {
 594                 // no arena
 595         }
 596         else if (s == "off")
 597         {
 598                 // forcibly turn off weaponarena
 599         }
 600         else if (s == "all" || s == "1")
 601         {
 602                 g_weaponarena = 1;
 603                 g_weaponarena_list = "All Weapons";
 604                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 605                 {
 606                         e = get_weaponinfo(j);
 607                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 608                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 609                 }
 610         }
 611         else if (s == "most")
 612         {
 613                 g_weaponarena = 1;
 614                 g_weaponarena_list = "Most Weapons";
 615                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 616                 {
 617                         e = get_weaponinfo(j);
 618                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 619                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 620                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 621                 }
 622         }
 623         else if (s == "none")
 624         {
 625                 g_weaponarena = 1;
 626                 g_weaponarena_list = "No Weapons";
 627         }
 628         else
 629         {
 630                 g_weaponarena = 1;
 631                 t = tokenize_console(s);
 632                 g_weaponarena_list = "";
 633                 for (i = 0; i < t; ++i)
 634                 {
 635                         s = argv(i);
 636                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 637                         {
 638                                 e = get_weaponinfo(j);
 639                                 if (e.netname == s)
 640                                 {
 641                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 642                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 643                                         break;
 644                                 }
 645                         }
 646                         if (j > WEP_LAST)
 647                         {
 648                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 649                         }
 650                 }
 651                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 652         }
 653
 654         if(g_weaponarena)
 655                 g_weaponarena_random = cvar("g_weaponarena_random");
 656         else
 657                 g_weaponarena_random = 0;
 658         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 659
 660         if (g_weaponarena)
 661         {
 662                 g_weapon_stay = 0; // incompatible
 663                 start_weapons = g_weaponarena_weapons;
 664                 start_items |= IT_UNLIMITED_AMMO;
 665         }
 666         else
 667         {
 668                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 669                 {
 670                         e = get_weaponinfo(i);
 671                         int w = want_weapon(e, false);
 672                         if(w & 1)
 673                                 start_weapons |= WepSet_FromWeapon(i);
 674                         if(w & 2)
 675                                 start_weapons_default |= WepSet_FromWeapon(i);
 676                         if(w & 4)
 677                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 678                 }
 679         }
 680
 681         if(!cvar("g_use_ammunition"))
 682                 start_items |= IT_UNLIMITED_AMMO;
 683
 684         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 685         {
 686                 start_ammo_shells = 999;
 687                 start_ammo_nails = 999;
 688                 start_ammo_rockets = 999;
 689                 start_ammo_cells = 999;
 690                 start_ammo_plasma = 999;
 691                 start_ammo_fuel = 999;
 692         }
 693         else
 694         {
 695                 start_ammo_shells = cvar("g_start_ammo_shells");
 696                 start_ammo_nails = cvar("g_start_ammo_nails");
 697                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 698                 start_ammo_cells = cvar("g_start_ammo_cells");
 699                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 700                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 701         }
 702
 703         if (warmup_stage)
 704         {
 705                 warmup_start_ammo_shells = start_ammo_shells;
 706                 warmup_start_ammo_nails = start_ammo_nails;
 707                 warmup_start_ammo_rockets = start_ammo_rockets;
 708                 warmup_start_ammo_cells = start_ammo_cells;
 709                 warmup_start_ammo_plasma = start_ammo_plasma;
 710                 warmup_start_ammo_fuel = start_ammo_fuel;
 711                 warmup_start_health = start_health;
 712                 warmup_start_armorvalue = start_armorvalue;
 713                 warmup_start_weapons = start_weapons;
 714                 warmup_start_weapons_default = start_weapons_default;
 715                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 716
 717                 if (!g_weaponarena && !g_ca)
 718                 {
 719                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 720                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 721                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 722                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 723                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 724                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 725                         warmup_start_health = cvar("g_warmup_start_health");
 726                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 727                         warmup_start_weapons = '0 0 0';
 728                         warmup_start_weapons_default = '0 0 0';
 729                         warmup_start_weapons_defaultmask = '0 0 0';
 730                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 731                         {
 732                                 e = get_weaponinfo(i);
 733                                 int w = want_weapon(e, g_warmup_allguns);
 734                                 if(w & 1)
 735                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 736                                 if(w & 2)
 737                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 738                                 if(w & 4)
 739                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 740                         }
 741                 }
 742         }
 743
 744         if (g_jetpack)
 745                 start_items |= IT_JETPACK;
 746
 747         MUTATOR_CALLHOOK(SetStartItems);
 748
 749         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 750         {
 751                 start_items |= IT_FUEL_REGEN;
 752                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 753                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 754         }
 755
 756         WepSet precache_weapons = start_weapons;
 757         if (g_warmup_allguns != 1)
 758                 precache_weapons |= warmup_start_weapons;
 759         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 760         {
 761                 e = get_weaponinfo(i);
 762                 if(precache_weapons & WepSet_FromWeapon(i))
 763                         WEP_ACTION(i, WR_INIT);
 764         }
 765
 766         start_ammo_shells = max(0, start_ammo_shells);
 767         start_ammo_nails = max(0, start_ammo_nails);
 768         start_ammo_rockets = max(0, start_ammo_rockets);
 769         start_ammo_cells = max(0, start_ammo_cells);
 770         start_ammo_plasma = max(0, start_ammo_plasma);
 771         start_ammo_fuel = max(0, start_ammo_fuel);
 772
 773         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 774         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 775         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 776         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 777         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 778         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 779 }
 780
 781 float sound_allowed(float _dest, entity e)
 782 {
 783     // sounds from world may always pass
 784     for (;;)
 785     {
 786         if (e.classname == "body")
 787             e = e.enemy;
 788         else if (e.realowner && e.realowner != e)
 789             e = e.realowner;
 790         else if (e.owner && e.owner != e)
 791             e = e.owner;
 792         else
 793             break;
 794     }
 795     // sounds to self may always pass
 796     if (_dest == MSG_ONE)
 797         if (e == msg_entity)
 798             return true;
 799     // sounds by players can be removed
 800     if (autocvar_bot_sound_monopoly)
 801         if (IS_REAL_CLIENT(e))
 802             return false;
 803     // anything else may pass
 804     return true;
 805 }
 806
 807 #undef sound
 808 void sound(entity e, float chan, string samp, float vol, float _atten)
 809 {
 810     if (!sound_allowed(MSG_BROADCAST, e))
 811         return;
 812     sound7(e, chan, samp, vol, _atten, 0, 0);
 813 }
 814
 815 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float _atten)
 816 {
 817     float entno, idx;
 818
 819     if (!sound_allowed(_dest, e))
 820         return;
 821
 822     entno = num_for_edict(e);
 823     idx = precache_sound_index(samp);
 824
 825     float sflags;
 826     sflags = 0;
 827
 828     _atten = floor(_atten * 64);
 829     vol = floor(vol * 255);
 830
 831     if (vol != 255)
 832         sflags |= SND_VOLUME;
 833     if (_atten != 64)
 834         sflags |= SND_ATTENUATION;
 835     if (entno >= 8192 || chan < 0 || chan > 7)
 836         sflags |= SND_LARGEENTITY;
 837     if (idx >= 256)
 838         sflags |= SND_LARGESOUND;
 839
 840     WriteByte(_dest, SVC_SOUND);
 841     WriteByte(_dest, sflags);
 842     if (sflags & SND_VOLUME)
 843         WriteByte(_dest, vol);
 844     if (sflags & SND_ATTENUATION)
 845         WriteByte(_dest, _atten);
 846     if (sflags & SND_LARGEENTITY)
 847     {
 848         WriteShort(_dest, entno);
 849         WriteByte(_dest, chan);
 850     }
 851     else
 852     {
 853         WriteShort(_dest, entno * 8 + chan);
 854     }
 855     if (sflags & SND_LARGESOUND)
 856         WriteShort(_dest, idx);
 857     else
 858         WriteByte(_dest, idx);
 859
 860     WriteCoord(_dest, o.x);
 861     WriteCoord(_dest, o.y);
 862     WriteCoord(_dest, o.z);
 863 }
 864 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 865 {
 866     vector o;
 867
 868     if (!sound_allowed(_dest, e))
 869         return;
 870
 871     o = e.origin + 0.5 * (e.mins + e.maxs);
 872     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 873 }
 874 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 875 {
 876     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 877 }
 878 void stopsoundto(float _dest, entity e, float chan)
 879 {
 880     float entno;
 881
 882     if (!sound_allowed(_dest, e))
 883         return;
 884
 885     entno = num_for_edict(e);
 886
 887     if (entno >= 8192 || chan < 0 || chan > 7)
 888     {
 889         float idx, sflags;
 890         idx = precache_sound_index("misc/null.wav");
 891         sflags = SND_LARGEENTITY;
 892         if (idx >= 256)
 893             sflags |= SND_LARGESOUND;
 894         WriteByte(_dest, SVC_SOUND);
 895         WriteByte(_dest, sflags);
 896         WriteShort(_dest, entno);
 897         WriteByte(_dest, chan);
 898         if (sflags & SND_LARGESOUND)
 899             WriteShort(_dest, idx);
 900         else
 901             WriteByte(_dest, idx);
 902         WriteCoord(_dest, e.origin.x);
 903         WriteCoord(_dest, e.origin.y);
 904         WriteCoord(_dest, e.origin.z);
 905     }
 906     else
 907     {
 908         WriteByte(_dest, SVC_STOPSOUND);
 909         WriteShort(_dest, entno * 8 + chan);
 910     }
 911 }
 912 void stopsound(entity e, float chan)
 913 {
 914     if (!sound_allowed(MSG_BROADCAST, e))
 915         return;
 916
 917     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 918     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 919 }
 920
 921 void play2(entity e, string filename)
 922 {
 923     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 924     msg_entity = e;
 925     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 926 }
 927
 928 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 929 .float spamtime;
 930 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 931 {
 932     if (!sound_allowed(MSG_BROADCAST, e))
 933         return false;
 934
 935     if (time > e.spamtime)
 936     {
 937         e.spamtime = time;
 938         sound(e, chan, samp, vol, _atten);
 939         return true;
 940     }
 941     return false;
 942 }
 943
 944 void play2team(float t, string filename)
 945 {
 946     entity head;
 947
 948     if (autocvar_bot_sound_monopoly)
 949         return;
 950
 951     FOR_EACH_REALPLAYER(head)
 952     {
 953         if (head.team == t)
 954             play2(head, filename);
 955     }
 956 }
 957
 958 void play2all(string samp)
 959 {
 960     if (autocvar_bot_sound_monopoly)
 961         return;
 962
 963     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 964 }
 965
 966 void PrecachePlayerSounds(string f);
 967 void precache_playermodel(string m)
 968 {
 969         float globhandle, i, n;
 970         string f;
 971
 972         if(substring(m, -9,5) == "_lod1")
 973                 return;
 974         if(substring(m, -9,5) == "_lod2")
 975                 return;
 976         precache_model(m);
 977         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 978         if(fexists(f))
 979                 precache_model(f);
 980         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 981         if(fexists(f))
 982                 precache_model(f);
 983
 984         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 985         if (globhandle < 0)
 986                 return;
 987         n = search_getsize(globhandle);
 988         for (i = 0; i < n; ++i)
 989         {
 990                 //print(search_getfilename(globhandle, i), "\n");
 991                 f = search_getfilename(globhandle, i);
 992                 PrecachePlayerSounds(f);
 993         }
 994         search_end(globhandle);
 995 }
 996 void precache_all_playermodels(string pattern)
 997 {
 998         float globhandle, i, n;
 999         string f;
1000
1001         globhandle = search_begin(pattern, true, false);
1002         if (globhandle < 0)
1003                 return;
1004         n = search_getsize(globhandle);
1005         for (i = 0; i < n; ++i)
1006         {
1007                 //print(search_getfilename(globhandle, i), "\n");
1008                 f = search_getfilename(globhandle, i);
1009                 precache_playermodel(f);
1010         }
1011         search_end(globhandle);
1012 }
1013
1014 void precache()
1015 {
1016     // gamemode related things
1017     precache_model ("models/misc/chatbubble.spr");
1018         precache_model("models/ice/ice.md3");
1019
1020 #ifdef TTURRETS_ENABLED
1021     if (autocvar_g_turrets)
1022         turrets_precash();
1023 #endif
1024
1025     // Precache all player models if desired
1026     if (autocvar_sv_precacheplayermodels)
1027     {
1028         PrecachePlayerSounds("sound/player/default.sounds");
1029         precache_all_playermodels("models/player/*.zym");
1030         precache_all_playermodels("models/player/*.dpm");
1031         precache_all_playermodels("models/player/*.md3");
1032         precache_all_playermodels("models/player/*.psk");
1033         precache_all_playermodels("models/player/*.iqm");
1034     }
1035
1036     if (autocvar_sv_defaultcharacter)
1037     {
1038         string s;
1039         s = autocvar_sv_defaultplayermodel_red;
1040         if (s != "")
1041             precache_playermodel(s);
1042         s = autocvar_sv_defaultplayermodel_blue;
1043         if (s != "")
1044             precache_playermodel(s);
1045         s = autocvar_sv_defaultplayermodel_yellow;
1046         if (s != "")
1047             precache_playermodel(s);
1048         s = autocvar_sv_defaultplayermodel_pink;
1049         if (s != "")
1050             precache_playermodel(s);
1051         s = autocvar_sv_defaultplayermodel;
1052         if (s != "")
1053             precache_playermodel(s);
1054     }
1055
1056     if (g_footsteps)
1057     {
1058         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1059         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1060     }
1061
1062     // gore and miscellaneous sounds
1063     //precache_sound ("misc/h2ohit.wav");
1064     precache_model ("models/hook.md3");
1065     precache_sound ("misc/armorimpact.wav");
1066     precache_sound ("misc/bodyimpact1.wav");
1067     precache_sound ("misc/bodyimpact2.wav");
1068     precache_sound ("misc/gib.wav");
1069     precache_sound ("misc/gib_splat01.wav");
1070     precache_sound ("misc/gib_splat02.wav");
1071     precache_sound ("misc/gib_splat03.wav");
1072     precache_sound ("misc/gib_splat04.wav");
1073     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1074     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1075     precache_sound ("misc/null.wav");
1076     precache_sound ("misc/spawn.wav");
1077     precache_sound ("misc/talk.wav");
1078     precache_sound ("misc/teleport.wav");
1079     precache_sound ("misc/poweroff.wav");
1080     precache_sound ("player/lava.wav");
1081     precache_sound ("player/slime.wav");
1082
1083     precache_model ("models/sprites/0.spr32");
1084     precache_model ("models/sprites/1.spr32");
1085     precache_model ("models/sprites/2.spr32");
1086     precache_model ("models/sprites/3.spr32");
1087     precache_model ("models/sprites/4.spr32");
1088     precache_model ("models/sprites/5.spr32");
1089     precache_model ("models/sprites/6.spr32");
1090     precache_model ("models/sprites/7.spr32");
1091     precache_model ("models/sprites/8.spr32");
1092     precache_model ("models/sprites/9.spr32");
1093     precache_model ("models/sprites/10.spr32");
1094
1095     // common weapon precaches
1096         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1097     precache_sound ("weapons/weapon_switch.wav");
1098     precache_sound ("weapons/weaponpickup.wav");
1099     precache_sound ("weapons/unavailable.wav");
1100     precache_sound ("weapons/dryfire.wav");
1101     if (g_grappling_hook)
1102     {
1103         precache_sound ("weapons/hook_fire.wav"); // hook
1104         precache_sound ("weapons/hook_impact.wav"); // hook
1105     }
1106
1107     precache_model("models/elaser.mdl");
1108     precache_model("models/laser.mdl");
1109     precache_model("models/ebomb.mdl");
1110
1111 #if 0
1112     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1113
1114     if (!self.noise && self.music) // quake 3 uses the music field
1115         self.noise = self.music;
1116
1117     // plays music for the level if there is any
1118     if (self.noise)
1119     {
1120         precache_sound (self.noise);
1121         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1122     }
1123 #endif
1124
1125 #include "precache-for-csqc.inc"
1126 }
1127
1128
1129 void make_safe_for_remove(entity e)
1130 {
1131     if (e.initialize_entity)
1132     {
1133         entity ent, prev = world;
1134         for (ent = initialize_entity_first; ent; )
1135         {
1136             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1137             {
1138                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1139                 // skip it in linked list
1140                 if (prev)
1141                 {
1142                     prev.initialize_entity_next = ent.initialize_entity_next;
1143                     ent = prev.initialize_entity_next;
1144                 }
1145                 else
1146                 {
1147                     initialize_entity_first = ent.initialize_entity_next;
1148                     ent = initialize_entity_first;
1149                 }
1150             }
1151             else
1152             {
1153                 prev = ent;
1154                 ent = ent.initialize_entity_next;
1155             }
1156         }
1157     }
1158 }
1159
1160 void objerror(string s)
1161 {
1162     make_safe_for_remove(self);
1163     builtin_objerror(s);
1164 }
1165
1166 .float remove_except_protected_forbidden;
1167 void remove_except_protected(entity e)
1168 {
1169         if(e.remove_except_protected_forbidden)
1170                 error("not allowed to remove this at this point");
1171         builtin_remove(e);
1172 }
1173
1174 void remove_unsafely(entity e)
1175 {
1176     if(e.classname == "spike")
1177         error("Removing spikes is forbidden (crylink bug), please report");
1178     builtin_remove(e);
1179 }
1180
1181 void remove_safely(entity e)
1182 {
1183     make_safe_for_remove(e);
1184     builtin_remove(e);
1185 }
1186
1187 void InitializeEntity(entity e, void(void) func, float order)
1188 {
1189     entity prev, cur;
1190
1191     if (!e || e.initialize_entity)
1192     {
1193         // make a proxy initializer entity
1194         entity e_old;
1195         e_old = e;
1196         e = spawn();
1197         e.classname = "initialize_entity";
1198         e.enemy = e_old;
1199     }
1200
1201     e.initialize_entity = func;
1202     e.initialize_entity_order = order;
1203
1204     cur = initialize_entity_first;
1205     prev = world;
1206     for (;;)
1207     {
1208         if (!cur || cur.initialize_entity_order > order)
1209         {
1210             // insert between prev and cur
1211             if (prev)
1212                 prev.initialize_entity_next = e;
1213             else
1214                 initialize_entity_first = e;
1215             e.initialize_entity_next = cur;
1216             return;
1217         }
1218         prev = cur;
1219         cur = cur.initialize_entity_next;
1220     }
1221 }
1222 void InitializeEntitiesRun()
1223 {
1224     entity startoflist;
1225     startoflist = initialize_entity_first;
1226     initialize_entity_first = world;
1227     remove = remove_except_protected;
1228     for (self = startoflist; self; self = self.initialize_entity_next)
1229     {
1230         self.remove_except_protected_forbidden = 1;
1231     }
1232     for (self = startoflist; self; )
1233     {
1234         entity e;
1235         var void(void) func;
1236         e = self.initialize_entity_next;
1237         func = self.initialize_entity;
1238         self.initialize_entity_order = 0;
1239         self.initialize_entity = func_null;
1240         self.initialize_entity_next = world;
1241         self.remove_except_protected_forbidden = 0;
1242         if (self.classname == "initialize_entity")
1243         {
1244             entity e_old;
1245             e_old = self.enemy;
1246             builtin_remove(self);
1247             self = e_old;
1248         }
1249         //dprint("Delayed initialization: ", self.classname, "\n");
1250         if(func)
1251             func();
1252         else
1253         {
1254             eprint(self);
1255             backtrace(strcat("Null function in: ", self.classname, "\n"));
1256         }
1257         self = e;
1258     }
1259     remove = remove_unsafely;
1260 }
1261
1262 void UncustomizeEntitiesRun()
1263 {
1264     entity oldself;
1265     oldself = self;
1266     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1267         self.uncustomizeentityforclient();
1268     self = oldself;
1269 }
1270 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1271 {
1272     e.customizeentityforclient = customizer;
1273     e.uncustomizeentityforclient = uncustomizer;
1274     e.uncustomizeentityforclient_set = !!uncustomizer;
1275 }
1276
1277
1278 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1279 {
1280     vector mi, ma;
1281
1282     if (e.classname == "")
1283         e.classname = "net_linked";
1284
1285     if (e.model == "" || self.modelindex == 0)
1286     {
1287         mi = e.mins;
1288         ma = e.maxs;
1289         setmodel(e, "null");
1290         setsize(e, mi, ma);
1291     }
1292
1293     e.SendEntity = sendfunc;
1294     e.SendFlags = 0xFFFFFF;
1295
1296     if (!docull)
1297         e.effects |= EF_NODEPTHTEST;
1298
1299     if (dt)
1300     {
1301         e.nextthink = time + dt;
1302         e.think = SUB_Remove;
1303     }
1304 }
1305
1306
1307 entity eliminatedPlayers;
1308 .float(entity) isEliminated;
1309 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1310 {
1311         float i, f, b;
1312         entity e;
1313         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1314         WriteByte(MSG_ENTITY, sendflags);
1315
1316         if(sendflags & 1)
1317         {
1318                 for(i = 1; i <= maxclients; i += 8)
1319                 {
1320                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1321                         {
1322                                 if(eliminatedPlayers.isEliminated(e))
1323                                         f |= b;
1324                         }
1325                         WriteByte(MSG_ENTITY, f);
1326                 }
1327         }
1328
1329         return true;
1330 }
1331
1332 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1333 {
1334         if(eliminatedPlayers)
1335         {
1336                 backtrace("Can't spawn eliminatedPlayers again!");
1337                 return;
1338         }
1339         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1340         eliminatedPlayers.isEliminated = isEliminated_func;
1341 }
1342
1343
1344 void adaptor_think2touch()
1345 {
1346     entity o;
1347     o = other;
1348     other = world;
1349     self.touch();
1350     other = o;
1351 }
1352
1353 void adaptor_think2use()
1354 {
1355     entity o, a;
1356     o = other;
1357     a = activator;
1358     activator = world;
1359     other = world;
1360     self.use();
1361     other = o;
1362     activator = a;
1363 }
1364
1365 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1366 {
1367         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1368                 self.projectiledeathtype |= HITTYPE_SPLASH;
1369         adaptor_think2use();
1370 }
1371
1372 // deferred dropping
1373 void DropToFloor_Handler()
1374 {
1375     builtin_droptofloor();
1376     self.dropped_origin = self.origin;
1377 }
1378
1379 void droptofloor()
1380 {
1381     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1382 }
1383
1384
1385
1386 float trace_hits_box_a0, trace_hits_box_a1;
1387
1388 float trace_hits_box_1d(float end, float thmi, float thma)
1389 {
1390     if (end == 0)
1391     {
1392         // just check if x is in range
1393         if (0 < thmi)
1394             return false;
1395         if (0 > thma)
1396             return false;
1397     }
1398     else
1399     {
1400         // do the trace with respect to x
1401         // 0 -> end has to stay in thmi -> thma
1402         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1403         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1404         if (trace_hits_box_a0 > trace_hits_box_a1)
1405             return false;
1406     }
1407     return true;
1408 }
1409
1410 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1411 {
1412     end -= start;
1413     thmi -= start;
1414     thma -= start;
1415     // now it is a trace from 0 to end
1416
1417     trace_hits_box_a0 = 0;
1418     trace_hits_box_a1 = 1;
1419
1420     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1421         return false;
1422     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1423         return false;
1424     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1425         return false;
1426
1427     return true;
1428 }
1429
1430 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1431 {
1432     return trace_hits_box(start, end, thmi - ma, thma - mi);
1433 }
1434
1435 float SUB_NoImpactCheck()
1436 {
1437         // zero hitcontents = this is not the real impact, but either the
1438         // mirror-impact of something hitting the projectile instead of the
1439         // projectile hitting the something, or a touchareagrid one. Neither of
1440         // these stop the projectile from moving, so...
1441         if(trace_dphitcontents == 0)
1442         {
1443                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1444                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1445                 checkclient();
1446         }
1447     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1448         return 1;
1449     if (other == world && self.size != '0 0 0')
1450     {
1451         vector tic;
1452         tic = self.velocity * sys_frametime;
1453         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1454         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1455         if (trace_fraction >= 1)
1456         {
1457             dprint("Odd... did not hit...?\n");
1458         }
1459         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1460         {
1461             dprint("Detected and prevented the sky-grapple bug.\n");
1462             return 1;
1463         }
1464     }
1465
1466     return 0;
1467 }
1468
1469 #define SUB_OwnerCheck() (other && (other == self.owner))
1470
1471 void RemoveGrapplingHook(entity pl);
1472 void W_Crylink_Dequeue(entity e);
1473 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1474 {
1475         if(SUB_OwnerCheck())
1476                 return true;
1477         if(SUB_NoImpactCheck())
1478         {
1479                 if(self.classname == "nade")
1480                         return false; // no checks here
1481                 else if(self.classname == "grapplinghook")
1482                         RemoveGrapplingHook(self.realowner);
1483                 else if(self.classname == "spike")
1484                 {
1485                         W_Crylink_Dequeue(self);
1486                         remove(self);
1487                 }
1488                 else
1489                         remove(self);
1490                 return true;
1491         }
1492         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1493                 UpdateCSQCProjectile(self);
1494         return false;
1495 }
1496
1497
1498 void URI_Get_Callback(float id, float status, string data)
1499 {
1500         if(url_URI_Get_Callback(id, status, data))
1501         {
1502                 // handled
1503         }
1504         else if (id == URI_GET_DISCARD)
1505         {
1506                 // discard
1507         }
1508         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1509         {
1510                 // sv_cmd curl
1511                 Curl_URI_Get_Callback(id, status, data);
1512         }
1513         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1514         {
1515                 // online ban list
1516                 OnlineBanList_URI_Get_Callback(id, status, data);
1517         }
1518         else
1519         {
1520                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1521         }
1522 }
1523
1524 string uid2name(string myuid) {
1525         string s;
1526         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1527
1528         // FIXME remove this later after 0.6 release
1529         // convert old style broken records to correct style
1530         if(s == "")
1531         {
1532                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1533                 if(s != "")
1534                 {
1535                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1536                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1537                 }
1538         }
1539
1540         if(s == "")
1541                 s = "^1Unregistered Player";
1542         return s;
1543 }
1544
1545 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1546 {
1547     float m, i;
1548     vector start, org, delta, end, enddown, mstart;
1549     entity sp;
1550
1551     m = e.dphitcontentsmask;
1552     e.dphitcontentsmask = goodcontents | badcontents;
1553
1554     org = world.mins;
1555     delta = world.maxs - world.mins;
1556
1557     start = end = org;
1558
1559     for (i = 0; i < attempts; ++i)
1560     {
1561         start.x = org.x + random() * delta.x;
1562         start.y = org.y + random() * delta.y;
1563         start.z = org.z + random() * delta.z;
1564
1565         // rule 1: start inside world bounds, and outside
1566         // solid, and don't start from somewhere where you can
1567         // fall down to evil
1568         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1569         if (trace_fraction >= 1)
1570             continue;
1571         if (trace_startsolid)
1572             continue;
1573         if (trace_dphitcontents & badcontents)
1574             continue;
1575         if (trace_dphitq3surfaceflags & badsurfaceflags)
1576             continue;
1577
1578         // rule 2: if we are too high, lower the point
1579         if (trace_fraction * delta.z > maxaboveground)
1580             start = trace_endpos + '0 0 1' * maxaboveground;
1581         enddown = trace_endpos;
1582
1583         // rule 3: make sure we aren't outside the map. This only works
1584         // for somewhat well formed maps. A good rule of thumb is that
1585         // the map should have a convex outside hull.
1586         // these can be traceLINES as we already verified the starting box
1587         mstart = start + 0.5 * (e.mins + e.maxs);
1588         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1589         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1590             continue;
1591         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1592         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1593             continue;
1594         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1595         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1596             continue;
1597         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1598         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1599             continue;
1600         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1601         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1602             continue;
1603
1604         // rule 4: we must "see" some spawnpoint or item
1605         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1606                 if(checkpvs(mstart, sp))
1607                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1608                                 break;
1609         if(!sp)
1610         {
1611                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1612                         if(checkpvs(mstart, sp))
1613                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1614                                         break;
1615                 if(!sp)
1616                         continue;
1617         }
1618
1619         // find a random vector to "look at"
1620         end.x = org.x + random() * delta.x;
1621         end.y = org.y + random() * delta.y;
1622         end.z = org.z + random() * delta.z;
1623         end = start + normalize(end - start) * vlen(delta);
1624
1625         // rule 4: start TO end must not be too short
1626         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1627         if (trace_startsolid)
1628             continue;
1629         if (trace_fraction < minviewdistance / vlen(delta))
1630             continue;
1631
1632         // rule 5: don't want to look at sky
1633         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1634             continue;
1635
1636         // rule 6: we must not end up in trigger_hurt
1637         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1638             continue;
1639
1640         break;
1641     }
1642
1643     e.dphitcontentsmask = m;
1644
1645     if (i < attempts)
1646     {
1647         setorigin(e, start);
1648         e.angles = vectoangles(end - start);
1649         dprint("Needed ", ftos(i + 1), " attempts\n");
1650         return true;
1651     }
1652     else
1653         return false;
1654 }
1655
1656 void write_recordmarker(entity pl, float tstart, float dt)
1657 {
1658     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1659
1660     // also write a marker into demo files for demotc-race-record-extractor to find
1661     stuffcmd(pl,
1662              strcat(
1663                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1664                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1665 }
1666
1667 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1668 {
1669         switch(algn)
1670         {
1671                 default:
1672                 case 3: // right
1673                         break;
1674
1675                 case 4: // left
1676                         vecs.y = -vecs.y;
1677                         break;
1678
1679                 case 1:
1680                         if(allowcenter) // 2: allow center handedness
1681                         {
1682                                 // center
1683                                 vecs.y = 0;
1684                                 vecs.z -= 2;
1685                         }
1686                         else
1687                         {
1688                                 // right
1689                         }
1690                         break;
1691
1692                 case 2:
1693                         if(allowcenter) // 2: allow center handedness
1694                         {
1695                                 // center
1696                                 vecs.y = 0;
1697                                 vecs.z -= 2;
1698                         }
1699                         else
1700                         {
1701                                 // left
1702                                 vecs.y = -vecs.y;
1703                         }
1704                         break;
1705         }
1706         return vecs;
1707 }
1708
1709 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1710 {
1711         string s;
1712         vector v;
1713
1714         if (autocvar_g_shootfromeye)
1715         {
1716                 if (visual)
1717                 {
1718                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1719                         else { vecs.y = 0; vecs.z -= 2; }
1720                 }
1721                 else
1722                 {
1723                         vecs.y = 0;
1724                         vecs.z = 0;
1725                 }
1726         }
1727         else if (autocvar_g_shootfromcenter)
1728         {
1729                 vecs.y = 0;
1730                 vecs.z -= 2;
1731         }
1732         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1733         {
1734                 v = stov(s);
1735                 if (y_is_right)
1736                         v.y = -v.y;
1737                 if (v.x != 0)
1738                         vecs.x = v.x;
1739                 vecs.y = v.y;
1740                 vecs.z = v.z;
1741         }
1742         else if (autocvar_g_shootfromclient)
1743         {
1744                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1745         }
1746         return vecs;
1747 }
1748
1749 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1750 {
1751         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1752 }
1753
1754
1755 void attach_sameorigin(entity e, entity to, string tag)
1756 {
1757     vector org, t_forward, t_left, t_up, e_forward, e_up;
1758     float tagscale;
1759
1760     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1761     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1762     t_forward = v_forward * tagscale;
1763     t_left = v_right * -tagscale;
1764     t_up = v_up * tagscale;
1765
1766     e.origin_x = org * t_forward;
1767     e.origin_y = org * t_left;
1768     e.origin_z = org * t_up;
1769
1770     // current forward and up directions
1771     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1772                 e.angles = AnglesTransform_FromVAngles(e.angles);
1773         else
1774                 e.angles = AnglesTransform_FromAngles(e.angles);
1775     fixedmakevectors(e.angles);
1776
1777     // untransform forward, up!
1778     e_forward.x = v_forward * t_forward;
1779     e_forward.y = v_forward * t_left;
1780     e_forward.z = v_forward * t_up;
1781     e_up.x = v_up * t_forward;
1782     e_up.y = v_up * t_left;
1783     e_up.z = v_up * t_up;
1784
1785     e.angles = fixedvectoangles2(e_forward, e_up);
1786     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1787                 e.angles = AnglesTransform_ToVAngles(e.angles);
1788         else
1789                 e.angles = AnglesTransform_ToAngles(e.angles);
1790
1791     setattachment(e, to, tag);
1792     setorigin(e, e.origin);
1793 }
1794
1795 void detach_sameorigin(entity e)
1796 {
1797     vector org;
1798     org = gettaginfo(e, 0);
1799     e.angles = fixedvectoangles2(v_forward, v_up);
1800     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1801                 e.angles = AnglesTransform_ToVAngles(e.angles);
1802         else
1803                 e.angles = AnglesTransform_ToAngles(e.angles);
1804     setorigin(e, org);
1805     setattachment(e, world, "");
1806     setorigin(e, e.origin);
1807 }
1808
1809 void follow_sameorigin(entity e, entity to)
1810 {
1811     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1812     e.aiment = to; // make the hole follow bmodel
1813     e.punchangle = to.angles; // the original angles of bmodel
1814     e.view_ofs = e.origin - to.origin; // relative origin
1815     e.v_angle = e.angles - to.angles; // relative angles
1816 }
1817
1818 void unfollow_sameorigin(entity e)
1819 {
1820     e.movetype = MOVETYPE_NONE;
1821 }
1822
1823 entity gettaginfo_relative_ent;
1824 vector gettaginfo_relative(entity e, float tag)
1825 {
1826     if (!gettaginfo_relative_ent)
1827     {
1828         gettaginfo_relative_ent = spawn();
1829         gettaginfo_relative_ent.effects = EF_NODRAW;
1830     }
1831     gettaginfo_relative_ent.model = e.model;
1832     gettaginfo_relative_ent.modelindex = e.modelindex;
1833     gettaginfo_relative_ent.frame = e.frame;
1834     return gettaginfo(gettaginfo_relative_ent, tag);
1835 }
1836
1837 .float scale2;
1838
1839 float modeleffect_SendEntity(entity to, float sf)
1840 {
1841         float f;
1842         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1843
1844         f = 0;
1845         if(self.velocity != '0 0 0')
1846                 f |= 1;
1847         if(self.angles != '0 0 0')
1848                 f |= 2;
1849         if(self.avelocity != '0 0 0')
1850                 f |= 4;
1851
1852         WriteByte(MSG_ENTITY, f);
1853         WriteShort(MSG_ENTITY, self.modelindex);
1854         WriteByte(MSG_ENTITY, self.skin);
1855         WriteByte(MSG_ENTITY, self.frame);
1856         WriteCoord(MSG_ENTITY, self.origin.x);
1857         WriteCoord(MSG_ENTITY, self.origin.y);
1858         WriteCoord(MSG_ENTITY, self.origin.z);
1859         if(f & 1)
1860         {
1861                 WriteCoord(MSG_ENTITY, self.velocity.x);
1862                 WriteCoord(MSG_ENTITY, self.velocity.y);
1863                 WriteCoord(MSG_ENTITY, self.velocity.z);
1864         }
1865         if(f & 2)
1866         {
1867                 WriteCoord(MSG_ENTITY, self.angles.x);
1868                 WriteCoord(MSG_ENTITY, self.angles.y);
1869                 WriteCoord(MSG_ENTITY, self.angles.z);
1870         }
1871         if(f & 4)
1872         {
1873                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1874                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1875                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1876         }
1877         WriteShort(MSG_ENTITY, self.scale * 256.0);
1878         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1879         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1880         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1881         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1882
1883         return true;
1884 }
1885
1886 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1887 {
1888         entity e;
1889         float sz;
1890         e = spawn();
1891         e.classname = "modeleffect";
1892         setmodel(e, m);
1893         e.frame = f;
1894         setorigin(e, o);
1895         e.velocity = v;
1896         e.angles = ang;
1897         e.avelocity = angv;
1898         e.alpha = a;
1899         e.teleport_time = t1;
1900         e.fade_time = t2;
1901         e.skin = s;
1902         if(s0 >= 0)
1903                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1904         else
1905                 e.scale = -s0;
1906         if(s2 >= 0)
1907                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1908         else
1909                 e.scale2 = -s2;
1910         sz = max(e.scale, e.scale2);
1911         setsize(e, e.mins * sz, e.maxs * sz);
1912         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1913 }
1914
1915 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1916 {
1917         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1918 }
1919
1920 float randombit(float bits)
1921 {
1922         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1923                 return bits;
1924
1925         float n, f, b, r;
1926
1927         r = random();
1928         b = 0;
1929         n = 0;
1930
1931         for(f = 1; f <= bits; f *= 2)
1932         {
1933                 if(bits & f)
1934                 {
1935                         ++n;
1936                         r *= n;
1937                         if(r <= 1)
1938                                 b = f;
1939                         else
1940                                 r = (r - 1) / (n - 1);
1941                 }
1942         }
1943
1944         return b;
1945 }
1946
1947 float randombits(float bits, float k, float error_return)
1948 {
1949         float r;
1950         r = 0;
1951         while(k > 0 && bits != r)
1952         {
1953                 r += randombit(bits - r);
1954                 --k;
1955         }
1956         if(error_return)
1957                 if(k > 0)
1958                         return -1; // all
1959         return r;
1960 }
1961
1962 void randombit_test(float bits, float iter)
1963 {
1964         while(iter > 0)
1965         {
1966                 print(ftos(randombit(bits)), "\n");
1967                 --iter;
1968         }
1969 }
1970
1971 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1972 {
1973         if(halflifedist > 0)
1974                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1975         else if(halflifedist < 0)
1976                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1977         else
1978                 return 1;
1979 }
1980
1981
1982 void defer_think()
1983 {
1984     entity oself;
1985
1986     oself           = self;
1987     self            = self.owner;
1988     oself.think     = SUB_Remove;
1989     oself.nextthink = time;
1990
1991     oself.use();
1992 }
1993
1994 /*
1995     Execute func() after time + fdelay.
1996     self when func is executed = self when defer is called
1997 */
1998 void defer(float fdelay, void() func)
1999 {
2000     entity e;
2001
2002     e           = spawn();
2003     e.owner     = self;
2004     e.use       = func;
2005     e.think     = defer_think;
2006     e.nextthink = time + fdelay;
2007 }
2008
2009 .string aiment_classname;
2010 .float aiment_deadflag;
2011 void SetMovetypeFollow(entity ent, entity e)
2012 {
2013         // FIXME this may not be warpzone aware
2014         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2015         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2016         ent.aiment = e; // make the hole follow bmodel
2017         ent.punchangle = e.angles; // the original angles of bmodel
2018         ent.view_ofs = ent.origin - e.origin; // relative origin
2019         ent.v_angle = ent.angles - e.angles; // relative angles
2020         ent.aiment_classname = strzone(e.classname);
2021         ent.aiment_deadflag = e.deadflag;
2022 }
2023 void UnsetMovetypeFollow(entity ent)
2024 {
2025         ent.movetype = MOVETYPE_FLY;
2026         PROJECTILE_MAKETRIGGER(ent);
2027         ent.aiment = world;
2028 }
2029 float LostMovetypeFollow(entity ent)
2030 {
2031 /*
2032         if(ent.movetype != MOVETYPE_FOLLOW)
2033                 if(ent.aiment)
2034                         error("???");
2035 */
2036         if(ent.aiment)
2037         {
2038                 if(ent.aiment.classname != ent.aiment_classname)
2039                         return 1;
2040                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2041                         return 1;
2042         }
2043         return 0;
2044 }
2045
2046 float isPushable(entity e)
2047 {
2048         if(e.iscreature)
2049                 return true;
2050         if(e.pushable)
2051                 return true;
2052         switch(e.classname)
2053         {
2054                 case "body":
2055                 case "droppedweapon":
2056                 case "keepawayball":
2057                 case "nexball_basketball":
2058                 case "nexball_football":
2059                         return true;
2060                 case "bullet": // antilagged bullets can't hit this either
2061                         return false;
2062         }
2063         if (e.projectiledeathtype)
2064                 return true;
2065         return false;
2066 }