qcsrc/server/miscfunctions.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "miscfunctions.qh"
   5         #include "../dpdefs/progsdefs.qh"
   6     #include "../dpdefs/dpextensions.qh"
   7     #include "../common/playerstats.qh"
   8     #include "../warpzonelib/anglestransform.qh"
   9     #include "../warpzonelib/server.qh"
  10     #include "../common/constants.qh"
  11     #include "../common/teams.qh"
  12     #include "../common/util.qh"
  13     #include "../common/urllib.qh"
  14     #include "../common/command/generic.qh"
  15     #include "../common/weapons/weapons.qh"
  16     #include "weapons/accuracy.qh"
  17     #include "weapons/csqcprojectile.qh"
  18     #include "weapons/selection.qh"
  19     #include "t_items.qh"
  20     #include "autocvars.qh"
  21     #include "constants.qh"
  22     #include "defs.qh"
  23     #include "../common/notifications.qh"
  24     #include "../common/deathtypes.qh"
  25     #include "mutators/mutators_include.qh"
  26     #include "../common/mapinfo.qh"
  27     #include "command/common.qh"
  28     #include "../csqcmodellib/sv_model.qh"
  29     #include "ipban.qh"
  30 #endif
  31
  32 void crosshair_trace(entity pl)
  33 {
  34         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  35 }
  36 void crosshair_trace_plusvisibletriggers(entity pl)
  37 {
  38         entity first;
  39         entity e;
  40         first = findchainfloat(solid, SOLID_TRIGGER);
  41
  42         for (e = first; e; e = e.chain)
  43                 if (e.model != "")
  44                         e.solid = SOLID_BSP;
  45
  46         crosshair_trace(pl);
  47
  48         for (e = first; e; e = e.chain)
  49                 e.solid = SOLID_TRIGGER;
  50 }
  51 void WarpZone_crosshair_trace(entity pl)
  52 {
  53         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  54 }
  55
  56
  57 string admin_name(void)
  58 {
  59         if(autocvar_sv_adminnick != "")
  60                 return autocvar_sv_adminnick;
  61         else
  62                 return "SERVER ADMIN";
  63 }
  64
  65 void DistributeEvenly_Init(float amount, float totalweight)
  66 {
  67     if (DistributeEvenly_amount)
  68     {
  69         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  70         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  71     }
  72     if (totalweight == 0)
  73         DistributeEvenly_amount = 0;
  74     else
  75         DistributeEvenly_amount = amount;
  76     DistributeEvenly_totalweight = totalweight;
  77 }
  78 float DistributeEvenly_Get(float weight)
  79 {
  80     float f;
  81     if (weight <= 0)
  82         return 0;
  83     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  84     DistributeEvenly_totalweight -= weight;
  85     DistributeEvenly_amount -= f;
  86     return f;
  87 }
  88 float DistributeEvenly_GetRandomized(float weight)
  89 {
  90     float f;
  91     if (weight <= 0)
  92         return 0;
  93     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  94     DistributeEvenly_totalweight -= weight;
  95     DistributeEvenly_amount -= f;
  96     return f;
  97 }
  98
  99
 100 void GameLogEcho(string s)
 101 {
 102     string fn;
 103     float matches;
 104
 105     if (autocvar_sv_eventlog_files)
 106     {
 107         if (!logfile_open)
 108         {
 109             logfile_open = true;
 110             matches = autocvar_sv_eventlog_files_counter + 1;
 111             cvar_set("sv_eventlog_files_counter", ftos(matches));
 112             fn = ftos(matches);
 113             if (strlen(fn) < 8)
 114                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 115             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 116             logfile = fopen(fn, FILE_APPEND);
 117             fputs(logfile, ":logversion:3\n");
 118         }
 119         if (logfile >= 0)
 120         {
 121             if (autocvar_sv_eventlog_files_timestamps)
 122                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 123             else
 124                 fputs(logfile, strcat(s, "\n"));
 125         }
 126     }
 127     if (autocvar_sv_eventlog_console)
 128     {
 129         print(s, "\n");
 130     }
 131 }
 132
 133 void GameLogInit()
 134 {
 135     logfile_open = 0;
 136     // will be opened later
 137 }
 138
 139 void GameLogClose()
 140 {
 141     if (logfile_open && logfile >= 0)
 142     {
 143         fclose(logfile);
 144         logfile = -1;
 145     }
 146 }
 147
 148 entity findnearest(vector point, .string field, string value, vector axismod)
 149 {
 150     entity localhead;
 151     float i;
 152     float j;
 153     float len;
 154     vector dist;
 155
 156     float num_nearest;
 157     num_nearest = 0;
 158
 159     localhead = find(world, field, value);
 160     while (localhead)
 161     {
 162         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 163             dist = localhead.oldorigin;
 164         else
 165             dist = localhead.origin;
 166         dist = dist - point;
 167         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 168         len = vlen(dist);
 169
 170         for (i = 0; i < num_nearest; ++i)
 171         {
 172             if (len < nearest_length[i])
 173                 break;
 174         }
 175
 176         // now i tells us where to insert at
 177         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 178         if (i < NUM_NEAREST_ENTITIES)
 179         {
 180             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 181             {
 182                 nearest_length[j + 1] = nearest_length[j];
 183                 nearest_entity[j + 1] = nearest_entity[j];
 184             }
 185             nearest_length[i] = len;
 186             nearest_entity[i] = localhead;
 187             if (num_nearest < NUM_NEAREST_ENTITIES)
 188                 num_nearest = num_nearest + 1;
 189         }
 190
 191         localhead = find(localhead, field, value);
 192     }
 193
 194     // now use the first one from our list that we can see
 195     for (i = 0; i < num_nearest; ++i)
 196     {
 197         traceline(point, nearest_entity[i].origin, true, world);
 198         if (trace_fraction == 1)
 199         {
 200             if (i != 0)
 201             {
 202                 dprint("Nearest point (");
 203                 dprint(nearest_entity[0].netname);
 204                 dprint(") is not visible, using a visible one.\n");
 205             }
 206             return nearest_entity[i];
 207         }
 208     }
 209
 210     if (num_nearest == 0)
 211         return world;
 212
 213     dprint("Not seeing any location point, using nearest as fallback.\n");
 214     /* DEBUGGING CODE:
 215     dprint("Candidates were: ");
 216     for(j = 0; j < num_nearest; ++j)
 217     {
 218         if(j != 0)
 219                 dprint(", ");
 220         dprint(nearest_entity[j].netname);
 221     }
 222     dprint("\n");
 223     */
 224
 225     return nearest_entity[0];
 226 }
 227
 228 void spawnfunc_target_location()
 229 {
 230     self.classname = "target_location";
 231     // location name in netname
 232     // eventually support: count, teamgame selectors, line of sight?
 233 }
 234
 235 void spawnfunc_info_location()
 236 {
 237     self.classname = "target_location";
 238     self.message = self.netname;
 239 }
 240
 241 string NearestLocation(vector p)
 242 {
 243     entity loc;
 244     string ret;
 245     ret = "somewhere";
 246     loc = findnearest(p, classname, "target_location", '1 1 1');
 247     if (loc)
 248     {
 249         ret = loc.message;
 250     }
 251     else
 252     {
 253         loc = findnearest(p, target, "###item###", '1 1 4');
 254         if (loc)
 255             ret = loc.netname;
 256     }
 257     return ret;
 258 }
 259
 260 string formatmessage(string msg)
 261 {
 262         float p, p1, p2;
 263         float n;
 264         vector cursor;
 265         entity cursor_ent;
 266         string escape;
 267         string replacement;
 268         p = 0;
 269         n = 7;
 270
 271         WarpZone_crosshair_trace(self);
 272         cursor = trace_endpos;
 273         cursor_ent = trace_ent;
 274
 275         while (1) {
 276                 if (n < 1)
 277                         break; // too many replacements
 278
 279                 n = n - 1;
 280                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 281                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 282
 283                 if (p1 < 0)
 284                         p1 = p2;
 285
 286                 if (p2 < 0)
 287                         p2 = p1;
 288
 289                 p = min(p1, p2);
 290
 291                 if (p < 0)
 292                         break;
 293
 294                 replacement = substring(msg, p, 2);
 295                 escape = substring(msg, p + 1, 1);
 296
 297                 if (escape == "%")
 298                         replacement = "%";
 299                 else if (escape == "\\")
 300                         replacement = "\\";
 301                 else if (escape == "n")
 302                         replacement = "\n";
 303                 else if (escape == "a")
 304                         replacement = ftos(floor(self.armorvalue));
 305                 else if (escape == "h")
 306                         replacement = ftos(floor(self.health));
 307                 else if (escape == "l")
 308                         replacement = NearestLocation(self.origin);
 309                 else if (escape == "y")
 310                         replacement = NearestLocation(cursor);
 311                 else if (escape == "d")
 312                         replacement = NearestLocation(self.death_origin);
 313                 else if (escape == "w") {
 314                         float wep;
 315                         wep = self.weapon;
 316                         if (!wep)
 317                                 wep = self.switchweapon;
 318                         if (!wep)
 319                                 wep = self.cnt;
 320                         replacement = WEP_NAME(wep);
 321                 } else if (escape == "W") {
 322                         if (self.items & IT_SHELLS) replacement = "shells";
 323                         else if (self.items & IT_NAILS) replacement = "bullets";
 324                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 325                         else if (self.items & IT_CELLS) replacement = "cells";
 326                         else if (self.items & IT_PLASMA) replacement = "plasma";
 327                         else replacement = "batteries"; // ;)
 328                 } else if (escape == "x") {
 329                         replacement = cursor_ent.netname;
 330                         if (replacement == "" || !cursor_ent)
 331                                 replacement = "nothing";
 332                 } else if (escape == "s")
 333                         replacement = ftos(vlen(self.velocity - self.velocity.z * '0 0 1'));
 334                 else if (escape == "S")
 335                         replacement = ftos(vlen(self.velocity));
 336
 337                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 338                 p = p + strlen(replacement);
 339         }
 340         return msg;
 341 }
 342
 343 float boolean(float value) { // if value is 0 return false (0), otherwise return true (1)
 344         return (value == 0) ? false : true;
 345 }
 346
 347 /*
 348 =============
 349 GetCvars
 350 =============
 351 Called with:
 352   0:  sends the request
 353   >0: receives a cvar from name=argv(f) value=argv(f+1)
 354 */
 355 void GetCvars_handleString(string thisname, float f, .string field, string name)
 356 {
 357         if (f < 0)
 358         {
 359                 if (self.field)
 360                         strunzone(self.field);
 361                 self.field = string_null;
 362         }
 363         else if (f > 0)
 364         {
 365                 if (thisname == name)
 366                 {
 367                         if (self.field)
 368                                 strunzone(self.field);
 369                         self.field = strzone(argv(f + 1));
 370                 }
 371         }
 372         else
 373                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 374 }
 375 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 376 {
 377         GetCvars_handleString(thisname, f, field, name);
 378         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 379                 if (thisname == name)
 380                 {
 381                         string s;
 382                         s = func(strcat1(self.field));
 383                         if (s != self.field)
 384                         {
 385                                 strunzone(self.field);
 386                                 self.field = strzone(s);
 387                         }
 388                 }
 389 }
 390 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 391 {
 392         if (f < 0)
 393         {
 394         }
 395         else if (f > 0)
 396         {
 397                 if (thisname == name)
 398                         self.field = stof(argv(f + 1));
 399         }
 400         else
 401                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 402 }
 403 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 404 {
 405         if (f < 0)
 406         {
 407         }
 408         else if (f > 0)
 409         {
 410                 if (thisname == name)
 411                 {
 412                         if(!self.field)
 413                         {
 414                                 self.field = stof(argv(f + 1));
 415                                 if(!self.field)
 416                                         self.field = -1;
 417                         }
 418                 }
 419         }
 420         else
 421         {
 422                 if(!self.field)
 423                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 424         }
 425 }
 426 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 427 {
 428         string o;
 429         o = W_FixWeaponOrder_ForceComplete(wo);
 430         if(self.weaponorder_byimpulse)
 431         {
 432                 strunzone(self.weaponorder_byimpulse);
 433                 self.weaponorder_byimpulse = string_null;
 434         }
 435         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 436         return o;
 437 }
 438 void GetCvars(float f)
 439 {
 440         string s = string_null;
 441
 442         if (f > 0)
 443                 s = strcat1(argv(f));
 444
 445         get_cvars_f = f;
 446         get_cvars_s = s;
 447
 448         MUTATOR_CALLHOOK(GetCvars);
 449
 450         Notification_GetCvars();
 451
 452         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 453         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 454         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 455         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 456         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 457         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 458         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 459         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 460         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 461         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 462         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 463         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 464         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 465         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 466         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 467         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 468         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 469         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 470         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 471         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 472         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 473         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 474         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 475         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 476
 477         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 478         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 479
 480         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 481         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 482         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 483         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 484         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 485
 486         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 487         if (f > 0)
 488         {
 489                 if (s == "cl_weaponpriority")
 490                         self.switchweapon = w_getbestweapon(self);
 491                 if (s == "cl_allow_uidtracking")
 492                         PlayerStats_GameReport_AddPlayer(self);
 493         }
 494 }
 495
 496 // decolorizes and team colors the player name when needed
 497 string playername(entity p)
 498 {
 499     string t;
 500     if (teamplay && !intermission_running && IS_PLAYER(p))
 501     {
 502         t = Team_ColorCode(p.team);
 503         return strcat(t, strdecolorize(p.netname));
 504     }
 505     else
 506         return p.netname;
 507 }
 508
 509 vector randompos(vector m1, vector m2)
 510 {
 511     vector v;
 512     m2 = m2 - m1;
 513     v.x = m2_x * random() + m1_x;
 514     v.y = m2_y * random() + m1_y;
 515     v.z = m2_z * random() + m1_z;
 516     return  v;
 517 }
 518
 519 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 520 {
 521         int i = weaponinfo.weapon;
 522         int d = 0;
 523
 524         if (!i)
 525                 return 0;
 526
 527         if (g_lms || g_ca || allguns)
 528         {
 529                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 530                         d = true;
 531                 else
 532                         d = false;
 533         }
 534         else if (g_cts)
 535                 d = (i == WEP_SHOTGUN);
 536         else if (g_nexball)
 537                 d = 0; // weapon is set a few lines later
 538         else
 539                 d = !(!weaponinfo.weaponstart);
 540
 541         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 542                 d |= (i == WEP_HOOK);
 543         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 544                 d = 0;
 545
 546         float t = weaponinfo.weaponstartoverride;
 547
 548         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 549
 550         // bit order in t:
 551         // 1: want or not
 552         // 2: is default?
 553         // 4: is set by default?
 554         if(t < 0)
 555                 t = 4 | (3 * d);
 556         else
 557                 t |= (2 * d);
 558
 559         return t;
 560 }
 561
 562 void readplayerstartcvars()
 563 {
 564         entity e;
 565         float i, j, t;
 566         string s;
 567
 568         // initialize starting values for players
 569         start_weapons = '0 0 0';
 570         start_weapons_default = '0 0 0';
 571         start_weapons_defaultmask = '0 0 0';
 572         start_items = 0;
 573         start_ammo_shells = 0;
 574         start_ammo_nails = 0;
 575         start_ammo_rockets = 0;
 576         start_ammo_cells = 0;
 577         start_ammo_plasma = 0;
 578         start_health = cvar("g_balance_health_start");
 579         start_armorvalue = cvar("g_balance_armor_start");
 580
 581         g_weaponarena = 0;
 582         g_weaponarena_weapons = '0 0 0';
 583
 584         s = cvar_string("g_weaponarena");
 585         if (s == "0" || s == "")
 586         {
 587                 if(g_ca)
 588                         s = "most";
 589         }
 590
 591         if (s == "0" || s == "")
 592         {
 593                 // no arena
 594         }
 595         else if (s == "off")
 596         {
 597                 // forcibly turn off weaponarena
 598         }
 599         else if (s == "all" || s == "1")
 600         {
 601                 g_weaponarena = 1;
 602                 g_weaponarena_list = "All Weapons";
 603                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 604                 {
 605                         e = get_weaponinfo(j);
 606                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 607                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 608                 }
 609         }
 610         else if (s == "most")
 611         {
 612                 g_weaponarena = 1;
 613                 g_weaponarena_list = "Most Weapons";
 614                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 615                 {
 616                         e = get_weaponinfo(j);
 617                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 618                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 619                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 620                 }
 621         }
 622         else if (s == "none")
 623         {
 624                 g_weaponarena = 1;
 625                 g_weaponarena_list = "No Weapons";
 626         }
 627         else
 628         {
 629                 g_weaponarena = 1;
 630                 t = tokenize_console(s);
 631                 g_weaponarena_list = "";
 632                 for (i = 0; i < t; ++i)
 633                 {
 634                         s = argv(i);
 635                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 636                         {
 637                                 e = get_weaponinfo(j);
 638                                 if (e.netname == s)
 639                                 {
 640                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 641                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 642                                         break;
 643                                 }
 644                         }
 645                         if (j > WEP_LAST)
 646                         {
 647                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 648                         }
 649                 }
 650                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 651         }
 652
 653         if(g_weaponarena)
 654                 g_weaponarena_random = cvar("g_weaponarena_random");
 655         else
 656                 g_weaponarena_random = 0;
 657         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 658
 659         if (g_weaponarena)
 660         {
 661                 g_weapon_stay = 0; // incompatible
 662                 start_weapons = g_weaponarena_weapons;
 663                 start_items |= IT_UNLIMITED_AMMO;
 664         }
 665         else
 666         {
 667                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 668                 {
 669                         e = get_weaponinfo(i);
 670                         int w = want_weapon(e, false);
 671                         if(w & 1)
 672                                 start_weapons |= WepSet_FromWeapon(i);
 673                         if(w & 2)
 674                                 start_weapons_default |= WepSet_FromWeapon(i);
 675                         if(w & 4)
 676                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 677                 }
 678         }
 679
 680         if(!cvar("g_use_ammunition"))
 681                 start_items |= IT_UNLIMITED_AMMO;
 682
 683         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 684         {
 685                 start_ammo_shells = 999;
 686                 start_ammo_nails = 999;
 687                 start_ammo_rockets = 999;
 688                 start_ammo_cells = 999;
 689                 start_ammo_plasma = 999;
 690                 start_ammo_fuel = 999;
 691         }
 692         else
 693         {
 694                 start_ammo_shells = cvar("g_start_ammo_shells");
 695                 start_ammo_nails = cvar("g_start_ammo_nails");
 696                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 697                 start_ammo_cells = cvar("g_start_ammo_cells");
 698                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 699                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 700         }
 701
 702         if (warmup_stage)
 703         {
 704                 warmup_start_ammo_shells = start_ammo_shells;
 705                 warmup_start_ammo_nails = start_ammo_nails;
 706                 warmup_start_ammo_rockets = start_ammo_rockets;
 707                 warmup_start_ammo_cells = start_ammo_cells;
 708                 warmup_start_ammo_plasma = start_ammo_plasma;
 709                 warmup_start_ammo_fuel = start_ammo_fuel;
 710                 warmup_start_health = start_health;
 711                 warmup_start_armorvalue = start_armorvalue;
 712                 warmup_start_weapons = start_weapons;
 713                 warmup_start_weapons_default = start_weapons_default;
 714                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 715
 716                 if (!g_weaponarena && !g_ca)
 717                 {
 718                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 719                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 720                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 721                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 722                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 723                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 724                         warmup_start_health = cvar("g_warmup_start_health");
 725                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 726                         warmup_start_weapons = '0 0 0';
 727                         warmup_start_weapons_default = '0 0 0';
 728                         warmup_start_weapons_defaultmask = '0 0 0';
 729                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 730                         {
 731                                 e = get_weaponinfo(i);
 732                                 int w = want_weapon(e, g_warmup_allguns);
 733                                 if(w & 1)
 734                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 735                                 if(w & 2)
 736                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 737                                 if(w & 4)
 738                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 739                         }
 740                 }
 741         }
 742
 743         if (g_jetpack)
 744                 start_items |= IT_JETPACK;
 745
 746         MUTATOR_CALLHOOK(SetStartItems);
 747
 748         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 749         {
 750                 start_items |= IT_FUEL_REGEN;
 751                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 752                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 753         }
 754
 755         WepSet precache_weapons = start_weapons;
 756         if (g_warmup_allguns != 1)
 757                 precache_weapons |= warmup_start_weapons;
 758         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 759         {
 760                 e = get_weaponinfo(i);
 761                 if(precache_weapons & WepSet_FromWeapon(i))
 762                         WEP_ACTION(i, WR_INIT);
 763         }
 764
 765         start_ammo_shells = max(0, start_ammo_shells);
 766         start_ammo_nails = max(0, start_ammo_nails);
 767         start_ammo_rockets = max(0, start_ammo_rockets);
 768         start_ammo_cells = max(0, start_ammo_cells);
 769         start_ammo_plasma = max(0, start_ammo_plasma);
 770         start_ammo_fuel = max(0, start_ammo_fuel);
 771
 772         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 773         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 774         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 775         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 776         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 777         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 778 }
 779
 780 float sound_allowed(float _dest, entity e)
 781 {
 782     // sounds from world may always pass
 783     for (;;)
 784     {
 785         if (e.classname == "body")
 786             e = e.enemy;
 787         else if (e.realowner && e.realowner != e)
 788             e = e.realowner;
 789         else if (e.owner && e.owner != e)
 790             e = e.owner;
 791         else
 792             break;
 793     }
 794     // sounds to self may always pass
 795     if (_dest == MSG_ONE)
 796         if (e == msg_entity)
 797             return true;
 798     // sounds by players can be removed
 799     if (autocvar_bot_sound_monopoly)
 800         if (IS_REAL_CLIENT(e))
 801             return false;
 802     // anything else may pass
 803     return true;
 804 }
 805
 806 #undef sound
 807 void sound(entity e, float chan, string samp, float vol, float _atten)
 808 {
 809     if (!sound_allowed(MSG_BROADCAST, e))
 810         return;
 811     sound7(e, chan, samp, vol, _atten, 0, 0);
 812 }
 813
 814 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float _atten)
 815 {
 816     float entno, idx;
 817
 818     if (!sound_allowed(_dest, e))
 819         return;
 820
 821     entno = num_for_edict(e);
 822     idx = precache_sound_index(samp);
 823
 824     float sflags;
 825     sflags = 0;
 826
 827     _atten = floor(_atten * 64);
 828     vol = floor(vol * 255);
 829
 830     if (vol != 255)
 831         sflags |= SND_VOLUME;
 832     if (_atten != 64)
 833         sflags |= SND_ATTENUATION;
 834     if (entno >= 8192 || chan < 0 || chan > 7)
 835         sflags |= SND_LARGEENTITY;
 836     if (idx >= 256)
 837         sflags |= SND_LARGESOUND;
 838
 839     WriteByte(_dest, SVC_SOUND);
 840     WriteByte(_dest, sflags);
 841     if (sflags & SND_VOLUME)
 842         WriteByte(_dest, vol);
 843     if (sflags & SND_ATTENUATION)
 844         WriteByte(_dest, _atten);
 845     if (sflags & SND_LARGEENTITY)
 846     {
 847         WriteShort(_dest, entno);
 848         WriteByte(_dest, chan);
 849     }
 850     else
 851     {
 852         WriteShort(_dest, entno * 8 + chan);
 853     }
 854     if (sflags & SND_LARGESOUND)
 855         WriteShort(_dest, idx);
 856     else
 857         WriteByte(_dest, idx);
 858
 859     WriteCoord(_dest, o.x);
 860     WriteCoord(_dest, o.y);
 861     WriteCoord(_dest, o.z);
 862 }
 863 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 864 {
 865     vector o;
 866
 867     if (!sound_allowed(_dest, e))
 868         return;
 869
 870     o = e.origin + 0.5 * (e.mins + e.maxs);
 871     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 872 }
 873 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 874 {
 875     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 876 }
 877 void stopsoundto(float _dest, entity e, float chan)
 878 {
 879     float entno;
 880
 881     if (!sound_allowed(_dest, e))
 882         return;
 883
 884     entno = num_for_edict(e);
 885
 886     if (entno >= 8192 || chan < 0 || chan > 7)
 887     {
 888         float idx, sflags;
 889         idx = precache_sound_index("misc/null.wav");
 890         sflags = SND_LARGEENTITY;
 891         if (idx >= 256)
 892             sflags |= SND_LARGESOUND;
 893         WriteByte(_dest, SVC_SOUND);
 894         WriteByte(_dest, sflags);
 895         WriteShort(_dest, entno);
 896         WriteByte(_dest, chan);
 897         if (sflags & SND_LARGESOUND)
 898             WriteShort(_dest, idx);
 899         else
 900             WriteByte(_dest, idx);
 901         WriteCoord(_dest, e.origin.x);
 902         WriteCoord(_dest, e.origin.y);
 903         WriteCoord(_dest, e.origin.z);
 904     }
 905     else
 906     {
 907         WriteByte(_dest, SVC_STOPSOUND);
 908         WriteShort(_dest, entno * 8 + chan);
 909     }
 910 }
 911 void stopsound(entity e, float chan)
 912 {
 913     if (!sound_allowed(MSG_BROADCAST, e))
 914         return;
 915
 916     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 917     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 918 }
 919
 920 void play2(entity e, string filename)
 921 {
 922     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 923     msg_entity = e;
 924     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 925 }
 926
 927 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 928 .float spamtime;
 929 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 930 {
 931     if (!sound_allowed(MSG_BROADCAST, e))
 932         return false;
 933
 934     if (time > e.spamtime)
 935     {
 936         e.spamtime = time;
 937         sound(e, chan, samp, vol, _atten);
 938         return true;
 939     }
 940     return false;
 941 }
 942
 943 void play2team(float t, string filename)
 944 {
 945     entity head;
 946
 947     if (autocvar_bot_sound_monopoly)
 948         return;
 949
 950     FOR_EACH_REALPLAYER(head)
 951     {
 952         if (head.team == t)
 953             play2(head, filename);
 954     }
 955 }
 956
 957 void play2all(string samp)
 958 {
 959     if (autocvar_bot_sound_monopoly)
 960         return;
 961
 962     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 963 }
 964
 965 void PrecachePlayerSounds(string f);
 966 void precache_playermodel(string m)
 967 {
 968         float globhandle, i, n;
 969         string f;
 970
 971         if(substring(m, -9,5) == "_lod1")
 972                 return;
 973         if(substring(m, -9,5) == "_lod2")
 974                 return;
 975         precache_model(m);
 976         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 977         if(fexists(f))
 978                 precache_model(f);
 979         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 980         if(fexists(f))
 981                 precache_model(f);
 982
 983         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 984         if (globhandle < 0)
 985                 return;
 986         n = search_getsize(globhandle);
 987         for (i = 0; i < n; ++i)
 988         {
 989                 //print(search_getfilename(globhandle, i), "\n");
 990                 f = search_getfilename(globhandle, i);
 991                 PrecachePlayerSounds(f);
 992         }
 993         search_end(globhandle);
 994 }
 995 void precache_all_playermodels(string pattern)
 996 {
 997         float globhandle, i, n;
 998         string f;
 999
1000         globhandle = search_begin(pattern, true, false);
1001         if (globhandle < 0)
1002                 return;
1003         n = search_getsize(globhandle);
1004         for (i = 0; i < n; ++i)
1005         {
1006                 //print(search_getfilename(globhandle, i), "\n");
1007                 f = search_getfilename(globhandle, i);
1008                 precache_playermodel(f);
1009         }
1010         search_end(globhandle);
1011 }
1012
1013 void precache()
1014 {
1015     // gamemode related things
1016     precache_model ("models/misc/chatbubble.spr");
1017         precache_model("models/ice/ice.md3");
1018
1019     // Precache all player models if desired
1020     if (autocvar_sv_precacheplayermodels)
1021     {
1022         PrecachePlayerSounds("sound/player/default.sounds");
1023         precache_all_playermodels("models/player/*.zym");
1024         precache_all_playermodels("models/player/*.dpm");
1025         precache_all_playermodels("models/player/*.md3");
1026         precache_all_playermodels("models/player/*.psk");
1027         precache_all_playermodels("models/player/*.iqm");
1028     }
1029
1030     if (autocvar_sv_defaultcharacter)
1031     {
1032         string s;
1033         s = autocvar_sv_defaultplayermodel_red;
1034         if (s != "")
1035             precache_playermodel(s);
1036         s = autocvar_sv_defaultplayermodel_blue;
1037         if (s != "")
1038             precache_playermodel(s);
1039         s = autocvar_sv_defaultplayermodel_yellow;
1040         if (s != "")
1041             precache_playermodel(s);
1042         s = autocvar_sv_defaultplayermodel_pink;
1043         if (s != "")
1044             precache_playermodel(s);
1045         s = autocvar_sv_defaultplayermodel;
1046         if (s != "")
1047             precache_playermodel(s);
1048     }
1049
1050     if (g_footsteps)
1051     {
1052         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1053         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1054     }
1055
1056     // gore and miscellaneous sounds
1057     //precache_sound ("misc/h2ohit.wav");
1058     precache_model ("models/hook.md3");
1059     precache_sound ("misc/armorimpact.wav");
1060     precache_sound ("misc/bodyimpact1.wav");
1061     precache_sound ("misc/bodyimpact2.wav");
1062     precache_sound ("misc/gib.wav");
1063     precache_sound ("misc/gib_splat01.wav");
1064     precache_sound ("misc/gib_splat02.wav");
1065     precache_sound ("misc/gib_splat03.wav");
1066     precache_sound ("misc/gib_splat04.wav");
1067     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1068     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1069     precache_sound ("misc/null.wav");
1070     precache_sound ("misc/spawn.wav");
1071     precache_sound ("misc/talk.wav");
1072     precache_sound ("misc/teleport.wav");
1073     precache_sound ("misc/poweroff.wav");
1074     precache_sound ("player/lava.wav");
1075     precache_sound ("player/slime.wav");
1076
1077     precache_model ("models/sprites/0.spr32");
1078     precache_model ("models/sprites/1.spr32");
1079     precache_model ("models/sprites/2.spr32");
1080     precache_model ("models/sprites/3.spr32");
1081     precache_model ("models/sprites/4.spr32");
1082     precache_model ("models/sprites/5.spr32");
1083     precache_model ("models/sprites/6.spr32");
1084     precache_model ("models/sprites/7.spr32");
1085     precache_model ("models/sprites/8.spr32");
1086     precache_model ("models/sprites/9.spr32");
1087     precache_model ("models/sprites/10.spr32");
1088
1089     // common weapon precaches
1090         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1091     precache_sound ("weapons/weapon_switch.wav");
1092     precache_sound ("weapons/weaponpickup.wav");
1093     precache_sound ("weapons/unavailable.wav");
1094     precache_sound ("weapons/dryfire.wav");
1095     if (g_grappling_hook)
1096     {
1097         precache_sound ("weapons/hook_fire.wav"); // hook
1098         precache_sound ("weapons/hook_impact.wav"); // hook
1099     }
1100
1101     precache_model("models/elaser.mdl");
1102     precache_model("models/laser.mdl");
1103     precache_model("models/ebomb.mdl");
1104
1105 #if 0
1106     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1107
1108     if (!self.noise && self.music) // quake 3 uses the music field
1109         self.noise = self.music;
1110
1111     // plays music for the level if there is any
1112     if (self.noise)
1113     {
1114         precache_sound (self.noise);
1115         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1116     }
1117 #endif
1118
1119 #include "precache-for-csqc.inc"
1120 }
1121
1122
1123 void make_safe_for_remove(entity e)
1124 {
1125     if (e.initialize_entity)
1126     {
1127         entity ent, prev = world;
1128         for (ent = initialize_entity_first; ent; )
1129         {
1130             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1131             {
1132                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1133                 // skip it in linked list
1134                 if (prev)
1135                 {
1136                     prev.initialize_entity_next = ent.initialize_entity_next;
1137                     ent = prev.initialize_entity_next;
1138                 }
1139                 else
1140                 {
1141                     initialize_entity_first = ent.initialize_entity_next;
1142                     ent = initialize_entity_first;
1143                 }
1144             }
1145             else
1146             {
1147                 prev = ent;
1148                 ent = ent.initialize_entity_next;
1149             }
1150         }
1151     }
1152 }
1153
1154 void objerror(string s)
1155 {
1156     make_safe_for_remove(self);
1157     builtin_objerror(s);
1158 }
1159
1160 .float remove_except_protected_forbidden;
1161 void remove_except_protected(entity e)
1162 {
1163         if(e.remove_except_protected_forbidden)
1164                 error("not allowed to remove this at this point");
1165         builtin_remove(e);
1166 }
1167
1168 void remove_unsafely(entity e)
1169 {
1170     if(e.classname == "spike")
1171         error("Removing spikes is forbidden (crylink bug), please report");
1172     builtin_remove(e);
1173 }
1174
1175 void remove_safely(entity e)
1176 {
1177     make_safe_for_remove(e);
1178     builtin_remove(e);
1179 }
1180
1181 void InitializeEntity(entity e, void(void) func, float order)
1182 {
1183     entity prev, cur;
1184
1185     if (!e || e.initialize_entity)
1186     {
1187         // make a proxy initializer entity
1188         entity e_old;
1189         e_old = e;
1190         e = spawn();
1191         e.classname = "initialize_entity";
1192         e.enemy = e_old;
1193     }
1194
1195     e.initialize_entity = func;
1196     e.initialize_entity_order = order;
1197
1198     cur = initialize_entity_first;
1199     prev = world;
1200     for (;;)
1201     {
1202         if (!cur || cur.initialize_entity_order > order)
1203         {
1204             // insert between prev and cur
1205             if (prev)
1206                 prev.initialize_entity_next = e;
1207             else
1208                 initialize_entity_first = e;
1209             e.initialize_entity_next = cur;
1210             return;
1211         }
1212         prev = cur;
1213         cur = cur.initialize_entity_next;
1214     }
1215 }
1216 void InitializeEntitiesRun()
1217 {
1218     entity startoflist;
1219     startoflist = initialize_entity_first;
1220     initialize_entity_first = world;
1221     remove = remove_except_protected;
1222     for (self = startoflist; self; self = self.initialize_entity_next)
1223     {
1224         self.remove_except_protected_forbidden = 1;
1225     }
1226     for (self = startoflist; self; )
1227     {
1228         entity e;
1229         var void(void) func;
1230         e = self.initialize_entity_next;
1231         func = self.initialize_entity;
1232         self.initialize_entity_order = 0;
1233         self.initialize_entity = func_null;
1234         self.initialize_entity_next = world;
1235         self.remove_except_protected_forbidden = 0;
1236         if (self.classname == "initialize_entity")
1237         {
1238             entity e_old;
1239             e_old = self.enemy;
1240             builtin_remove(self);
1241             self = e_old;
1242         }
1243         //dprint("Delayed initialization: ", self.classname, "\n");
1244         if(func)
1245             func();
1246         else
1247         {
1248             eprint(self);
1249             backtrace(strcat("Null function in: ", self.classname, "\n"));
1250         }
1251         self = e;
1252     }
1253     remove = remove_unsafely;
1254 }
1255
1256 void UncustomizeEntitiesRun()
1257 {
1258     entity oldself;
1259     oldself = self;
1260     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1261         self.uncustomizeentityforclient();
1262     self = oldself;
1263 }
1264 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1265 {
1266     e.customizeentityforclient = customizer;
1267     e.uncustomizeentityforclient = uncustomizer;
1268     e.uncustomizeentityforclient_set = !!uncustomizer;
1269 }
1270
1271
1272 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1273 {
1274     vector mi, ma;
1275
1276     if (e.classname == "")
1277         e.classname = "net_linked";
1278
1279     if (e.model == "" || self.modelindex == 0)
1280     {
1281         mi = e.mins;
1282         ma = e.maxs;
1283         setmodel(e, "null");
1284         setsize(e, mi, ma);
1285     }
1286
1287     e.SendEntity = sendfunc;
1288     e.SendFlags = 0xFFFFFF;
1289
1290     if (!docull)
1291         e.effects |= EF_NODEPTHTEST;
1292
1293     if (dt)
1294     {
1295         e.nextthink = time + dt;
1296         e.think = SUB_Remove;
1297     }
1298 }
1299
1300
1301 entity eliminatedPlayers;
1302 .float(entity) isEliminated;
1303 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1304 {
1305         float i, f, b;
1306         entity e;
1307         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1308         WriteByte(MSG_ENTITY, sendflags);
1309
1310         if(sendflags & 1)
1311         {
1312                 for(i = 1; i <= maxclients; i += 8)
1313                 {
1314                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1315                         {
1316                                 if(eliminatedPlayers.isEliminated(e))
1317                                         f |= b;
1318                         }
1319                         WriteByte(MSG_ENTITY, f);
1320                 }
1321         }
1322
1323         return true;
1324 }
1325
1326 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1327 {
1328         if(eliminatedPlayers)
1329         {
1330                 backtrace("Can't spawn eliminatedPlayers again!");
1331                 return;
1332         }
1333         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1334         eliminatedPlayers.isEliminated = isEliminated_func;
1335 }
1336
1337
1338 void adaptor_think2touch()
1339 {
1340     entity o;
1341     o = other;
1342     other = world;
1343     self.touch();
1344     other = o;
1345 }
1346
1347 void adaptor_think2use()
1348 {
1349     entity o, a;
1350     o = other;
1351     a = activator;
1352     activator = world;
1353     other = world;
1354     self.use();
1355     other = o;
1356     activator = a;
1357 }
1358
1359 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1360 {
1361         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1362                 self.projectiledeathtype |= HITTYPE_SPLASH;
1363         adaptor_think2use();
1364 }
1365
1366 // deferred dropping
1367 void DropToFloor_Handler()
1368 {
1369     builtin_droptofloor();
1370     self.dropped_origin = self.origin;
1371 }
1372
1373 void droptofloor()
1374 {
1375     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1376 }
1377
1378
1379
1380 float trace_hits_box_a0, trace_hits_box_a1;
1381
1382 float trace_hits_box_1d(float end, float thmi, float thma)
1383 {
1384     if (end == 0)
1385     {
1386         // just check if x is in range
1387         if (0 < thmi)
1388             return false;
1389         if (0 > thma)
1390             return false;
1391     }
1392     else
1393     {
1394         // do the trace with respect to x
1395         // 0 -> end has to stay in thmi -> thma
1396         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1397         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1398         if (trace_hits_box_a0 > trace_hits_box_a1)
1399             return false;
1400     }
1401     return true;
1402 }
1403
1404 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1405 {
1406     end -= start;
1407     thmi -= start;
1408     thma -= start;
1409     // now it is a trace from 0 to end
1410
1411     trace_hits_box_a0 = 0;
1412     trace_hits_box_a1 = 1;
1413
1414     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1415         return false;
1416     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1417         return false;
1418     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1419         return false;
1420
1421     return true;
1422 }
1423
1424 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1425 {
1426     return trace_hits_box(start, end, thmi - ma, thma - mi);
1427 }
1428
1429 float SUB_NoImpactCheck()
1430 {
1431         // zero hitcontents = this is not the real impact, but either the
1432         // mirror-impact of something hitting the projectile instead of the
1433         // projectile hitting the something, or a touchareagrid one. Neither of
1434         // these stop the projectile from moving, so...
1435         if(trace_dphitcontents == 0)
1436         {
1437                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1438                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1439                 checkclient();
1440         }
1441     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1442         return 1;
1443     if (other == world && self.size != '0 0 0')
1444     {
1445         vector tic;
1446         tic = self.velocity * sys_frametime;
1447         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1448         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1449         if (trace_fraction >= 1)
1450         {
1451             dprint("Odd... did not hit...?\n");
1452         }
1453         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1454         {
1455             dprint("Detected and prevented the sky-grapple bug.\n");
1456             return 1;
1457         }
1458     }
1459
1460     return 0;
1461 }
1462
1463 #define SUB_OwnerCheck() (other && (other == self.owner))
1464
1465 void RemoveGrapplingHook(entity pl);
1466 void W_Crylink_Dequeue(entity e);
1467 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1468 {
1469         if(SUB_OwnerCheck())
1470                 return true;
1471         if(SUB_NoImpactCheck())
1472         {
1473                 if(self.classname == "nade")
1474                         return false; // no checks here
1475                 else if(self.classname == "grapplinghook")
1476                         RemoveGrapplingHook(self.realowner);
1477                 else if(self.classname == "spike")
1478                 {
1479                         W_Crylink_Dequeue(self);
1480                         remove(self);
1481                 }
1482                 else
1483                         remove(self);
1484                 return true;
1485         }
1486         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1487                 UpdateCSQCProjectile(self);
1488         return false;
1489 }
1490
1491
1492 void URI_Get_Callback(float id, float status, string data)
1493 {
1494         if(url_URI_Get_Callback(id, status, data))
1495         {
1496                 // handled
1497         }
1498         else if (id == URI_GET_DISCARD)
1499         {
1500                 // discard
1501         }
1502         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1503         {
1504                 // sv_cmd curl
1505                 Curl_URI_Get_Callback(id, status, data);
1506         }
1507         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1508         {
1509                 // online ban list
1510                 OnlineBanList_URI_Get_Callback(id, status, data);
1511         }
1512         else
1513         {
1514                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1515         }
1516 }
1517
1518 string uid2name(string myuid) {
1519         string s;
1520         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1521
1522         // FIXME remove this later after 0.6 release
1523         // convert old style broken records to correct style
1524         if(s == "")
1525         {
1526                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1527                 if(s != "")
1528                 {
1529                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1530                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1531                 }
1532         }
1533
1534         if(s == "")
1535                 s = "^1Unregistered Player";
1536         return s;
1537 }
1538
1539 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1540 {
1541     float m, i;
1542     vector start, org, delta, end, enddown, mstart;
1543     entity sp;
1544
1545     m = e.dphitcontentsmask;
1546     e.dphitcontentsmask = goodcontents | badcontents;
1547
1548     org = world.mins;
1549     delta = world.maxs - world.mins;
1550
1551     start = end = org;
1552
1553     for (i = 0; i < attempts; ++i)
1554     {
1555         start.x = org.x + random() * delta.x;
1556         start.y = org.y + random() * delta.y;
1557         start.z = org.z + random() * delta.z;
1558
1559         // rule 1: start inside world bounds, and outside
1560         // solid, and don't start from somewhere where you can
1561         // fall down to evil
1562         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1563         if (trace_fraction >= 1)
1564             continue;
1565         if (trace_startsolid)
1566             continue;
1567         if (trace_dphitcontents & badcontents)
1568             continue;
1569         if (trace_dphitq3surfaceflags & badsurfaceflags)
1570             continue;
1571
1572         // rule 2: if we are too high, lower the point
1573         if (trace_fraction * delta.z > maxaboveground)
1574             start = trace_endpos + '0 0 1' * maxaboveground;
1575         enddown = trace_endpos;
1576
1577         // rule 3: make sure we aren't outside the map. This only works
1578         // for somewhat well formed maps. A good rule of thumb is that
1579         // the map should have a convex outside hull.
1580         // these can be traceLINES as we already verified the starting box
1581         mstart = start + 0.5 * (e.mins + e.maxs);
1582         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1583         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1584             continue;
1585         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1586         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1587             continue;
1588         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1589         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1590             continue;
1591         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1592         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1593             continue;
1594         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1595         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1596             continue;
1597
1598         // rule 4: we must "see" some spawnpoint or item
1599         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1600                 if(checkpvs(mstart, sp))
1601                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1602                                 break;
1603         if(!sp)
1604         {
1605                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1606                         if(checkpvs(mstart, sp))
1607                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1608                                         break;
1609                 if(!sp)
1610                         continue;
1611         }
1612
1613         // find a random vector to "look at"
1614         end.x = org.x + random() * delta.x;
1615         end.y = org.y + random() * delta.y;
1616         end.z = org.z + random() * delta.z;
1617         end = start + normalize(end - start) * vlen(delta);
1618
1619         // rule 4: start TO end must not be too short
1620         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1621         if (trace_startsolid)
1622             continue;
1623         if (trace_fraction < minviewdistance / vlen(delta))
1624             continue;
1625
1626         // rule 5: don't want to look at sky
1627         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1628             continue;
1629
1630         // rule 6: we must not end up in trigger_hurt
1631         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1632             continue;
1633
1634         break;
1635     }
1636
1637     e.dphitcontentsmask = m;
1638
1639     if (i < attempts)
1640     {
1641         setorigin(e, start);
1642         e.angles = vectoangles(end - start);
1643         dprint("Needed ", ftos(i + 1), " attempts\n");
1644         return true;
1645     }
1646     else
1647         return false;
1648 }
1649
1650 void write_recordmarker(entity pl, float tstart, float dt)
1651 {
1652     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1653
1654     // also write a marker into demo files for demotc-race-record-extractor to find
1655     stuffcmd(pl,
1656              strcat(
1657                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1658                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1659 }
1660
1661 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1662 {
1663         switch(algn)
1664         {
1665                 default:
1666                 case 3: // right
1667                         break;
1668
1669                 case 4: // left
1670                         vecs.y = -vecs.y;
1671                         break;
1672
1673                 case 1:
1674                         if(allowcenter) // 2: allow center handedness
1675                         {
1676                                 // center
1677                                 vecs.y = 0;
1678                                 vecs.z -= 2;
1679                         }
1680                         else
1681                         {
1682                                 // right
1683                         }
1684                         break;
1685
1686                 case 2:
1687                         if(allowcenter) // 2: allow center handedness
1688                         {
1689                                 // center
1690                                 vecs.y = 0;
1691                                 vecs.z -= 2;
1692                         }
1693                         else
1694                         {
1695                                 // left
1696                                 vecs.y = -vecs.y;
1697                         }
1698                         break;
1699         }
1700         return vecs;
1701 }
1702
1703 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1704 {
1705         string s;
1706         vector v;
1707
1708         if (autocvar_g_shootfromeye)
1709         {
1710                 if (visual)
1711                 {
1712                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1713                         else { vecs.y = 0; vecs.z -= 2; }
1714                 }
1715                 else
1716                 {
1717                         vecs.y = 0;
1718                         vecs.z = 0;
1719                 }
1720         }
1721         else if (autocvar_g_shootfromcenter)
1722         {
1723                 vecs.y = 0;
1724                 vecs.z -= 2;
1725         }
1726         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1727         {
1728                 v = stov(s);
1729                 if (y_is_right)
1730                         v.y = -v.y;
1731                 if (v.x != 0)
1732                         vecs.x = v.x;
1733                 vecs.y = v.y;
1734                 vecs.z = v.z;
1735         }
1736         else if (autocvar_g_shootfromclient)
1737         {
1738                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1739         }
1740         return vecs;
1741 }
1742
1743 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1744 {
1745         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1746 }
1747
1748
1749 void attach_sameorigin(entity e, entity to, string tag)
1750 {
1751     vector org, t_forward, t_left, t_up, e_forward, e_up;
1752     float tagscale;
1753
1754     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1755     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1756     t_forward = v_forward * tagscale;
1757     t_left = v_right * -tagscale;
1758     t_up = v_up * tagscale;
1759
1760     e.origin_x = org * t_forward;
1761     e.origin_y = org * t_left;
1762     e.origin_z = org * t_up;
1763
1764     // current forward and up directions
1765     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1766                 e.angles = AnglesTransform_FromVAngles(e.angles);
1767         else
1768                 e.angles = AnglesTransform_FromAngles(e.angles);
1769     fixedmakevectors(e.angles);
1770
1771     // untransform forward, up!
1772     e_forward.x = v_forward * t_forward;
1773     e_forward.y = v_forward * t_left;
1774     e_forward.z = v_forward * t_up;
1775     e_up.x = v_up * t_forward;
1776     e_up.y = v_up * t_left;
1777     e_up.z = v_up * t_up;
1778
1779     e.angles = fixedvectoangles2(e_forward, e_up);
1780     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1781                 e.angles = AnglesTransform_ToVAngles(e.angles);
1782         else
1783                 e.angles = AnglesTransform_ToAngles(e.angles);
1784
1785     setattachment(e, to, tag);
1786     setorigin(e, e.origin);
1787 }
1788
1789 void detach_sameorigin(entity e)
1790 {
1791     vector org;
1792     org = gettaginfo(e, 0);
1793     e.angles = fixedvectoangles2(v_forward, v_up);
1794     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1795                 e.angles = AnglesTransform_ToVAngles(e.angles);
1796         else
1797                 e.angles = AnglesTransform_ToAngles(e.angles);
1798     setorigin(e, org);
1799     setattachment(e, world, "");
1800     setorigin(e, e.origin);
1801 }
1802
1803 void follow_sameorigin(entity e, entity to)
1804 {
1805     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1806     e.aiment = to; // make the hole follow bmodel
1807     e.punchangle = to.angles; // the original angles of bmodel
1808     e.view_ofs = e.origin - to.origin; // relative origin
1809     e.v_angle = e.angles - to.angles; // relative angles
1810 }
1811
1812 void unfollow_sameorigin(entity e)
1813 {
1814     e.movetype = MOVETYPE_NONE;
1815 }
1816
1817 entity gettaginfo_relative_ent;
1818 vector gettaginfo_relative(entity e, float tag)
1819 {
1820     if (!gettaginfo_relative_ent)
1821     {
1822         gettaginfo_relative_ent = spawn();
1823         gettaginfo_relative_ent.effects = EF_NODRAW;
1824     }
1825     gettaginfo_relative_ent.model = e.model;
1826     gettaginfo_relative_ent.modelindex = e.modelindex;
1827     gettaginfo_relative_ent.frame = e.frame;
1828     return gettaginfo(gettaginfo_relative_ent, tag);
1829 }
1830
1831 .float scale2;
1832
1833 float modeleffect_SendEntity(entity to, float sf)
1834 {
1835         float f;
1836         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1837
1838         f = 0;
1839         if(self.velocity != '0 0 0')
1840                 f |= 1;
1841         if(self.angles != '0 0 0')
1842                 f |= 2;
1843         if(self.avelocity != '0 0 0')
1844                 f |= 4;
1845
1846         WriteByte(MSG_ENTITY, f);
1847         WriteShort(MSG_ENTITY, self.modelindex);
1848         WriteByte(MSG_ENTITY, self.skin);
1849         WriteByte(MSG_ENTITY, self.frame);
1850         WriteCoord(MSG_ENTITY, self.origin.x);
1851         WriteCoord(MSG_ENTITY, self.origin.y);
1852         WriteCoord(MSG_ENTITY, self.origin.z);
1853         if(f & 1)
1854         {
1855                 WriteCoord(MSG_ENTITY, self.velocity.x);
1856                 WriteCoord(MSG_ENTITY, self.velocity.y);
1857                 WriteCoord(MSG_ENTITY, self.velocity.z);
1858         }
1859         if(f & 2)
1860         {
1861                 WriteCoord(MSG_ENTITY, self.angles.x);
1862                 WriteCoord(MSG_ENTITY, self.angles.y);
1863                 WriteCoord(MSG_ENTITY, self.angles.z);
1864         }
1865         if(f & 4)
1866         {
1867                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1868                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1869                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1870         }
1871         WriteShort(MSG_ENTITY, self.scale * 256.0);
1872         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1873         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1874         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1875         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1876
1877         return true;
1878 }
1879
1880 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1881 {
1882         entity e;
1883         float sz;
1884         e = spawn();
1885         e.classname = "modeleffect";
1886         setmodel(e, m);
1887         e.frame = f;
1888         setorigin(e, o);
1889         e.velocity = v;
1890         e.angles = ang;
1891         e.avelocity = angv;
1892         e.alpha = a;
1893         e.teleport_time = t1;
1894         e.fade_time = t2;
1895         e.skin = s;
1896         if(s0 >= 0)
1897                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1898         else
1899                 e.scale = -s0;
1900         if(s2 >= 0)
1901                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1902         else
1903                 e.scale2 = -s2;
1904         sz = max(e.scale, e.scale2);
1905         setsize(e, e.mins * sz, e.maxs * sz);
1906         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1907 }
1908
1909 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1910 {
1911         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1912 }
1913
1914 float randombit(float bits)
1915 {
1916         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1917                 return bits;
1918
1919         float n, f, b, r;
1920
1921         r = random();
1922         b = 0;
1923         n = 0;
1924
1925         for(f = 1; f <= bits; f *= 2)
1926         {
1927                 if(bits & f)
1928                 {
1929                         ++n;
1930                         r *= n;
1931                         if(r <= 1)
1932                                 b = f;
1933                         else
1934                                 r = (r - 1) / (n - 1);
1935                 }
1936         }
1937
1938         return b;
1939 }
1940
1941 float randombits(float bits, float k, float error_return)
1942 {
1943         float r;
1944         r = 0;
1945         while(k > 0 && bits != r)
1946         {
1947                 r += randombit(bits - r);
1948                 --k;
1949         }
1950         if(error_return)
1951                 if(k > 0)
1952                         return -1; // all
1953         return r;
1954 }
1955
1956 void randombit_test(float bits, float iter)
1957 {
1958         while(iter > 0)
1959         {
1960                 print(ftos(randombit(bits)), "\n");
1961                 --iter;
1962         }
1963 }
1964
1965 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1966 {
1967         if(halflifedist > 0)
1968                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1969         else if(halflifedist < 0)
1970                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1971         else
1972                 return 1;
1973 }
1974
1975
1976 void defer_think()
1977 {
1978     entity oself;
1979
1980     oself           = self;
1981     self            = self.owner;
1982     oself.think     = SUB_Remove;
1983     oself.nextthink = time;
1984
1985     oself.use();
1986 }
1987
1988 /*
1989     Execute func() after time + fdelay.
1990     self when func is executed = self when defer is called
1991 */
1992 void defer(float fdelay, void() func)
1993 {
1994     entity e;
1995
1996     e           = spawn();
1997     e.owner     = self;
1998     e.use       = func;
1999     e.think     = defer_think;
2000     e.nextthink = time + fdelay;
2001 }
2002
2003 .string aiment_classname;
2004 .float aiment_deadflag;
2005 void SetMovetypeFollow(entity ent, entity e)
2006 {
2007         // FIXME this may not be warpzone aware
2008         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2009         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2010         ent.aiment = e; // make the hole follow bmodel
2011         ent.punchangle = e.angles; // the original angles of bmodel
2012         ent.view_ofs = ent.origin - e.origin; // relative origin
2013         ent.v_angle = ent.angles - e.angles; // relative angles
2014         ent.aiment_classname = strzone(e.classname);
2015         ent.aiment_deadflag = e.deadflag;
2016 }
2017 void UnsetMovetypeFollow(entity ent)
2018 {
2019         ent.movetype = MOVETYPE_FLY;
2020         PROJECTILE_MAKETRIGGER(ent);
2021         ent.aiment = world;
2022 }
2023 float LostMovetypeFollow(entity ent)
2024 {
2025 /*
2026         if(ent.movetype != MOVETYPE_FOLLOW)
2027                 if(ent.aiment)
2028                         error("???");
2029 */
2030         if(ent.aiment)
2031         {
2032                 if(ent.aiment.classname != ent.aiment_classname)
2033                         return 1;
2034                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2035                         return 1;
2036         }
2037         return 0;
2038 }
2039
2040 float isPushable(entity e)
2041 {
2042         if(e.iscreature)
2043                 return true;
2044         if(e.pushable)
2045                 return true;
2046         switch(e.classname)
2047         {
2048                 case "body":
2049                 case "droppedweapon":
2050                 case "keepawayball":
2051                 case "nexball_basketball":
2052                 case "nexball_football":
2053                         return true;
2054                 case "bullet": // antilagged bullets can't hit this either
2055                         return false;
2056         }
2057         if (e.projectiledeathtype)
2058                 return true;
2059         return false;
2060 }