qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43 .bool ctrace_solidchanged;
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  47         {
  48                 if(it.model != "")
  49                 {
  50                         it.solid = SOLID_BSP;
  51                         it.ctrace_solidchanged = true;
  52                         IL_PUSH(g_ctrace_changed, it);
  53                 }
  54         });
  55
  56         crosshair_trace(pl);
  57
  58         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  59         {
  60                 it.solid = SOLID_TRIGGER;
  61                 it.ctrace_solidchanged = false;
  62         });
  63
  64         IL_CLEAR(g_ctrace_changed);
  65 }
  66 void WarpZone_crosshair_trace(entity pl)
  67 {
  68         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  69 }
  70
  71 void dedicated_print(string input)
  72 {
  73         if (server_is_dedicated) print(input);
  74 }
  75
  76 void GameLogEcho(string s)
  77 {
  78     string fn;
  79     int matches;
  80
  81     if (autocvar_sv_eventlog_files)
  82     {
  83         if (!logfile_open)
  84         {
  85             logfile_open = true;
  86             matches = autocvar_sv_eventlog_files_counter + 1;
  87             cvar_set("sv_eventlog_files_counter", itos(matches));
  88             fn = ftos(matches);
  89             if (strlen(fn) < 8)
  90                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  91             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  92             logfile = fopen(fn, FILE_APPEND);
  93             fputs(logfile, ":logversion:3\n");
  94         }
  95         if (logfile >= 0)
  96         {
  97             if (autocvar_sv_eventlog_files_timestamps)
  98                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  99             else
 100                 fputs(logfile, strcat(s, "\n"));
 101         }
 102     }
 103     if (autocvar_sv_eventlog_console)
 104     {
 105         dedicated_print(strcat(s, "\n"));
 106     }
 107 }
 108
 109 void GameLogInit()
 110 {
 111     logfile_open = 0;
 112     // will be opened later
 113 }
 114
 115 void GameLogClose()
 116 {
 117     if (logfile_open && logfile >= 0)
 118     {
 119         fclose(logfile);
 120         logfile = -1;
 121     }
 122 }
 123
 124 entity findnearest(vector point, bool checkitems, vector axismod)
 125 {
 126     vector dist;
 127     int num_nearest = 0;
 128
 129     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 130     {
 131         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 132             dist = it.oldorigin;
 133         else
 134             dist = it.origin;
 135         dist = dist - point;
 136         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 137         float len = vlen2(dist);
 138
 139         int l;
 140         for (l = 0; l < num_nearest; ++l)
 141         {
 142             if (len < nearest_length[l])
 143                 break;
 144         }
 145
 146         // now i tells us where to insert at
 147         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 148         if (l < NUM_NEAREST_ENTITIES)
 149         {
 150             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 151             {
 152                 nearest_length[j + 1] = nearest_length[j];
 153                 nearest_entity[j + 1] = nearest_entity[j];
 154             }
 155             nearest_length[l] = len;
 156             nearest_entity[l] = it;
 157             if (num_nearest < NUM_NEAREST_ENTITIES)
 158                 num_nearest = num_nearest + 1;
 159         }
 160     });
 161
 162     // now use the first one from our list that we can see
 163     for (int j = 0; j < num_nearest; ++j)
 164     {
 165         traceline(point, nearest_entity[j].origin, true, NULL);
 166         if (trace_fraction == 1)
 167         {
 168             if (j != 0)
 169                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 170             return nearest_entity[j];
 171         }
 172     }
 173
 174     if (num_nearest == 0)
 175         return NULL;
 176
 177     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 178     /* DEBUGGING CODE:
 179     dprint("Candidates were: ");
 180     for(j = 0; j < num_nearest; ++j)
 181     {
 182         if(j != 0)
 183                 dprint(", ");
 184         dprint(nearest_entity[j].netname);
 185     }
 186     dprint("\n");
 187     */
 188
 189     return nearest_entity[0];
 190 }
 191
 192 string NearestLocation(vector p)
 193 {
 194     string ret = "somewhere";
 195     entity loc = findnearest(p, false, '1 1 1');
 196     if (loc)
 197         ret = loc.message;
 198     else
 199     {
 200         loc = findnearest(p, true, '1 1 4');
 201         if (loc)
 202             ret = loc.netname;
 203     }
 204     return ret;
 205 }
 206
 207 string AmmoNameFromWeaponentity(Weapon wep)
 208 {
 209         string ammoitems = "batteries";
 210         switch (wep.ammo_type)
 211         {
 212                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 213                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 214                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 215                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 216                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 217                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 218         }
 219         return ammoitems;
 220 }
 221
 222 string formatmessage(entity this, string msg)
 223 {
 224         float p, p1, p2;
 225         float n;
 226         vector cursor;
 227         entity cursor_ent;
 228         string escape;
 229         string replacement;
 230         p = 0;
 231         n = 7;
 232
 233         WarpZone_crosshair_trace(this);
 234         cursor = trace_endpos;
 235         cursor_ent = trace_ent;
 236
 237         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 238         msg = M_ARGV(1, string);
 239
 240         while (1) {
 241                 if (n < 1)
 242                         break; // too many replacements
 243
 244                 n = n - 1;
 245                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 246                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 247
 248                 if (p1 < 0)
 249                         p1 = p2;
 250
 251                 if (p2 < 0)
 252                         p2 = p1;
 253
 254                 p = min(p1, p2);
 255
 256                 if (p < 0)
 257                         break;
 258
 259                 replacement = substring(msg, p, 2);
 260                 escape = substring(msg, p + 1, 1);
 261
 262                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 263
 264                 switch(escape)
 265                 {
 266                         case "%": replacement = "%"; break;
 267                         case "\\":replacement = "\\"; break;
 268                         case "n": replacement = "\n"; break;
 269                         case "a": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_ARMOR))); break;
 270                         case "h": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_HEALTH))); break;
 271                         case "l": replacement = NearestLocation(this.origin); break;
 272                         case "y": replacement = NearestLocation(cursor); break;
 273                         case "d": replacement = NearestLocation(this.death_origin); break;
 274                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 275                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 276                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 277                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 278                         case "S": replacement = ftos(vlen(this.velocity)); break;
 279                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 280                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 281                         default:
 282                         {
 283                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 284                                 replacement = M_ARGV(2, string);
 285                                 break;
 286                         }
 287                 }
 288
 289                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 290                 p = p + strlen(replacement);
 291         }
 292         return msg;
 293 }
 294
 295 /*
 296 =============
 297 GetCvars
 298 =============
 299 Called with:
 300   0:  sends the request
 301   >0: receives a cvar from name=argv(f) value=argv(f+1)
 302 */
 303 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 304 {
 305         if (f < 0)
 306         {
 307                 strfree(store.(field));
 308         }
 309         else if (f > 0)
 310         {
 311                 if (thisname == name)
 312                 {
 313                         strcpy(store.(field), argv(f + 1));
 314                 }
 315         }
 316         else
 317                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 318 }
 319 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 320 {
 321         GetCvars_handleString(this, store, thisname, f, field, name);
 322         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 323                 if (thisname == name)
 324                 {
 325                         string s = func(this, strcat1(store.(field)));
 326                         if (s != store.(field))
 327                         {
 328                                 strcpy(store.(field), s);
 329                         }
 330                 }
 331 }
 332 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 333 {
 334         if (f < 0)
 335         {
 336         }
 337         else if (f > 0)
 338         {
 339                 if (thisname == name)
 340                         store.(field) = stof(argv(f + 1));
 341         }
 342         else
 343                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 344 }
 345 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 346 {
 347         if (f < 0)
 348         {
 349         }
 350         else if (f > 0)
 351         {
 352                 if (thisname == name)
 353                 {
 354                         if (!store.(field))
 355                         {
 356                                 store.(field) = stof(argv(f + 1));
 357                                 if (!store.(field))
 358                                         store.(field) = -1;
 359                         }
 360                 }
 361         }
 362         else
 363         {
 364                 if (!store.(field))
 365                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 366         }
 367 }
 368 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 369 {
 370         string o = W_FixWeaponOrder_ForceComplete(wo);
 371         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 372         return o;
 373 }
 374
 375 REPLICATE(autoswitch, bool, "cl_autoswitch");
 376
 377 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 378
 379 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 380
 381 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 382
 383 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 384
 385 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 386
 387 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 388
 389 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 390
 391 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 392
 393 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 394
 395 REPLICATE(cvar_cl_physics, string, "cl_physics");
 396
 397 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 398
 399 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 400
 401 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 402
 403 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 404
 405 /**
 406  * @param f -1: cleanup, 0: request, 1: receive
 407  */
 408 void GetCvars(entity this, entity store, int f)
 409 {
 410         string s = string_null;
 411
 412         if (f > 0)
 413                 s = strcat1(argv(f));
 414
 415         get_cvars_f = f;
 416         get_cvars_s = s;
 417         MUTATOR_CALLHOOK(GetCvars);
 418
 419         Notification_GetCvars(this);
 420
 421         ReplicateVars(this, store, s, f);
 422
 423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 425         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 434
 435         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 436
 437         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 438         if (f > 0)
 439         {
 440                 if (s == "cl_weaponpriority")
 441                 {
 442                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 443                         {
 444                                 .entity weaponentity = weaponentities[slot];
 445                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 446                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 447                         }
 448                 }
 449                 if (s == "cl_allow_uidtracking")
 450                         PlayerStats_GameReport_AddPlayer(this);
 451         }
 452 }
 453
 454 // decolorizes and team colors the player name when needed
 455 string playername(entity p, bool team_colorize)
 456 {
 457     string t;
 458     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 459     {
 460         t = Team_ColorCode(p.team);
 461         return strcat(t, strdecolorize(p.netname));
 462     }
 463     else
 464         return p.netname;
 465 }
 466
 467 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 468 {
 469         int i = weaponinfo.m_id;
 470         int d = 0;
 471         bool allow_mutatorblocked = false;
 472
 473         if(!i)
 474                 return 0;
 475
 476         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 477         d = M_ARGV(1, float);
 478         allguns = M_ARGV(2, bool);
 479         allow_mutatorblocked = M_ARGV(3, bool);
 480
 481         if(allguns)
 482         {
 483                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 484                         d = true;
 485                 else
 486                         d = false;
 487         }
 488         else if(!mutator_returnvalue)
 489                 d = !(!weaponinfo.weaponstart);
 490
 491         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 492                 d = 0;
 493
 494         float t = weaponinfo.weaponstartoverride;
 495
 496         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 497
 498         // bit order in t:
 499         // 1: want or not
 500         // 2: is default?
 501         // 4: is set by default?
 502         if(t < 0)
 503                 t = 4 | (3 * d);
 504         else
 505                 t |= (2 * d);
 506
 507         return t;
 508 }
 509
 510 void readplayerstartcvars()
 511 {
 512         float i, t;
 513         string s;
 514
 515         // initialize starting values for players
 516         start_weapons = '0 0 0';
 517         start_weapons_default = '0 0 0';
 518         start_weapons_defaultmask = '0 0 0';
 519         start_items = 0;
 520         start_ammo_shells = 0;
 521         start_ammo_nails = 0;
 522         start_ammo_rockets = 0;
 523         start_ammo_cells = 0;
 524         start_ammo_plasma = 0;
 525         if (random_start_ammo == NULL)
 526         {
 527                 random_start_ammo = spawn();
 528         }
 529         start_health = cvar("g_balance_health_start");
 530         start_armorvalue = cvar("g_balance_armor_start");
 531
 532         g_weaponarena = 0;
 533         g_weaponarena_weapons = '0 0 0';
 534
 535         s = cvar_string("g_weaponarena");
 536
 537         MUTATOR_CALLHOOK(SetWeaponArena, s);
 538         s = M_ARGV(0, string);
 539
 540         if (s == "0" || s == "")
 541         {
 542                 // no arena
 543         }
 544         else if (s == "off")
 545         {
 546                 // forcibly turn off weaponarena
 547         }
 548         else if (s == "all" || s == "1")
 549         {
 550                 g_weaponarena = 1;
 551                 g_weaponarena_list = "All Weapons";
 552                 FOREACH(Weapons, it != WEP_Null, {
 553                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 554                                 g_weaponarena_weapons |= (it.m_wepset);
 555                 });
 556         }
 557         else if (s == "devall")
 558         {
 559                 g_weaponarena = 1;
 560                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 561                 FOREACH(Weapons, it != WEP_Null,
 562                 {
 563                         g_weaponarena_weapons |= (it.m_wepset);
 564                 });
 565         }
 566         else if (s == "most")
 567         {
 568                 g_weaponarena = 1;
 569                 g_weaponarena_list = "Most Weapons";
 570                 FOREACH(Weapons, it != WEP_Null, {
 571                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 572                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 573                                         g_weaponarena_weapons |= (it.m_wepset);
 574                 });
 575         }
 576         else if (s == "none")
 577         {
 578                 g_weaponarena = 1;
 579                 g_weaponarena_list = "No Weapons";
 580         }
 581         else
 582         {
 583                 g_weaponarena = 1;
 584                 t = tokenize_console(s);
 585                 g_weaponarena_list = "";
 586                 for (i = 0; i < t; ++i)
 587                 {
 588                         s = argv(i);
 589                         FOREACH(Weapons, it != WEP_Null, {
 590                                 if(it.netname == s)
 591                                 {
 592                                         g_weaponarena_weapons |= (it.m_wepset);
 593                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 594                                         break;
 595                                 }
 596                         });
 597                 }
 598                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 599         }
 600
 601         if (g_weaponarena)
 602         {
 603                 g_weapon_stay = 0; // incompatible
 604                 start_weapons = g_weaponarena_weapons;
 605                 start_items |= IT_UNLIMITED_AMMO;
 606         }
 607         else
 608         {
 609                 FOREACH(Weapons, it != WEP_Null, {
 610                         int w = want_weapon(it, false);
 611                         WepSet s = it.m_wepset;
 612                         if(w & 1)
 613                                 start_weapons |= s;
 614                         if(w & 2)
 615                                 start_weapons_default |= s;
 616                         if(w & 4)
 617                                 start_weapons_defaultmask |= s;
 618                 });
 619         }
 620
 621         if(!cvar("g_use_ammunition"))
 622                 start_items |= IT_UNLIMITED_AMMO;
 623
 624         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 625         {
 626                 start_ammo_shells = 999;
 627                 start_ammo_nails = 999;
 628                 start_ammo_rockets = 999;
 629                 start_ammo_cells = 999;
 630                 start_ammo_plasma = 999;
 631                 start_ammo_fuel = 999;
 632         }
 633         else
 634         {
 635                 start_ammo_shells = cvar("g_start_ammo_shells");
 636                 start_ammo_nails = cvar("g_start_ammo_nails");
 637                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 638                 start_ammo_cells = cvar("g_start_ammo_cells");
 639                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 640                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 641                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 642                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 643                         "g_random_start_shells"));
 644                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 645                         "g_random_start_bullets"));
 646                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 647                         cvar("g_random_start_rockets"));
 648                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 649                         "g_random_start_cells"));
 650                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 651                         "g_random_start_plasma"));
 652         }
 653
 654         if (warmup_stage)
 655         {
 656                 warmup_start_ammo_shells = start_ammo_shells;
 657                 warmup_start_ammo_nails = start_ammo_nails;
 658                 warmup_start_ammo_rockets = start_ammo_rockets;
 659                 warmup_start_ammo_cells = start_ammo_cells;
 660                 warmup_start_ammo_plasma = start_ammo_plasma;
 661                 warmup_start_ammo_fuel = start_ammo_fuel;
 662                 warmup_start_health = start_health;
 663                 warmup_start_armorvalue = start_armorvalue;
 664                 warmup_start_weapons = start_weapons;
 665                 warmup_start_weapons_default = start_weapons_default;
 666                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 667
 668                 if (!g_weaponarena && !g_ca && !g_freezetag)
 669                 {
 670                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 671                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 672                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 673                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 674                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 675                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 676                         warmup_start_health = cvar("g_warmup_start_health");
 677                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 678                         warmup_start_weapons = '0 0 0';
 679                         warmup_start_weapons_default = '0 0 0';
 680                         warmup_start_weapons_defaultmask = '0 0 0';
 681                         FOREACH(Weapons, it != WEP_Null, {
 682                                 int w = want_weapon(it, g_warmup_allguns);
 683                                 WepSet s = (it.m_wepset);
 684                                 if(w & 1)
 685                                         warmup_start_weapons |= s;
 686                                 if(w & 2)
 687                                         warmup_start_weapons_default |= s;
 688                                 if(w & 4)
 689                                         warmup_start_weapons_defaultmask |= s;
 690                         });
 691                 }
 692         }
 693
 694         if (g_jetpack)
 695                 start_items |= ITEM_Jetpack.m_itemid;
 696
 697         MUTATOR_CALLHOOK(SetStartItems);
 698
 699         if (start_items & ITEM_Jetpack.m_itemid)
 700         {
 701                 start_items |= ITEM_JetpackRegen.m_itemid;
 702                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 703                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 704         }
 705
 706         WepSet precache_weapons = start_weapons;
 707         if (g_warmup_allguns != 1)
 708                 precache_weapons |= warmup_start_weapons;
 709         FOREACH(Weapons, it != WEP_Null, {
 710                 if(precache_weapons & (it.m_wepset))
 711                         it.wr_init(it);
 712         });
 713
 714         start_ammo_shells = max(0, start_ammo_shells);
 715         start_ammo_nails = max(0, start_ammo_nails);
 716         start_ammo_rockets = max(0, start_ammo_rockets);
 717         start_ammo_cells = max(0, start_ammo_cells);
 718         start_ammo_plasma = max(0, start_ammo_plasma);
 719         start_ammo_fuel = max(0, start_ammo_fuel);
 720         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 721                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 722         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 723                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 724         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 725                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 726         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 727                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 728         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 729                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 730
 731         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 732         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 733         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 734         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 735         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 736         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 737 }
 738
 739 void precache_playermodel(string m)
 740 {
 741         float globhandle, i, n;
 742         string f;
 743
 744         if(substring(m, -9,5) == "_lod1")
 745                 return;
 746         if(substring(m, -9,5) == "_lod2")
 747                 return;
 748         precache_model(m);
 749         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 750         if(fexists(f))
 751                 precache_model(f);
 752         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 753         if(fexists(f))
 754                 precache_model(f);
 755
 756         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 757         if (globhandle < 0)
 758                 return;
 759         n = search_getsize(globhandle);
 760         for (i = 0; i < n; ++i)
 761         {
 762                 //print(search_getfilename(globhandle, i), "\n");
 763                 f = search_getfilename(globhandle, i);
 764                 PrecachePlayerSounds(f);
 765         }
 766         search_end(globhandle);
 767 }
 768 void precache_all_playermodels(string pattern)
 769 {
 770         int globhandle = search_begin(pattern, true, false);
 771         if (globhandle < 0) return;
 772         int n = search_getsize(globhandle);
 773         for (int i = 0; i < n; ++i)
 774         {
 775                 string s = search_getfilename(globhandle, i);
 776                 precache_playermodel(s);
 777         }
 778         search_end(globhandle);
 779 }
 780
 781 void precache_playermodels(string s)
 782 {
 783         FOREACH_WORD(s, true, { precache_playermodel(it); });
 784 }
 785
 786 void precache()
 787 {
 788     // gamemode related things
 789
 790     // Precache all player models if desired
 791     if (autocvar_sv_precacheplayermodels)
 792     {
 793         PrecachePlayerSounds("sound/player/default.sounds");
 794         precache_all_playermodels("models/player/*.zym");
 795         precache_all_playermodels("models/player/*.dpm");
 796         precache_all_playermodels("models/player/*.md3");
 797         precache_all_playermodels("models/player/*.psk");
 798         precache_all_playermodels("models/player/*.iqm");
 799     }
 800
 801     if (autocvar_sv_defaultcharacter)
 802     {
 803                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 804                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 805                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 806                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 807                 precache_playermodels(autocvar_sv_defaultplayermodel);
 808     }
 809
 810 #if 0
 811     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 812
 813     if (!this.noise && this.music) // quake 3 uses the music field
 814         this.noise = this.music;
 815
 816     // plays music for the level if there is any
 817     if (this.noise)
 818     {
 819         precache_sound (this.noise);
 820         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 821     }
 822 #endif
 823 }
 824
 825
 826 void make_safe_for_remove(entity e)
 827 {
 828     if (e.initialize_entity)
 829     {
 830         entity ent, prev = NULL;
 831         for (ent = initialize_entity_first; ent; )
 832         {
 833             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 834             {
 835                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 836                 // skip it in linked list
 837                 if (prev)
 838                 {
 839                     prev.initialize_entity_next = ent.initialize_entity_next;
 840                     ent = prev.initialize_entity_next;
 841                 }
 842                 else
 843                 {
 844                     initialize_entity_first = ent.initialize_entity_next;
 845                     ent = initialize_entity_first;
 846                 }
 847             }
 848             else
 849             {
 850                 prev = ent;
 851                 ent = ent.initialize_entity_next;
 852             }
 853         }
 854     }
 855 }
 856
 857 .float remove_except_protected_forbidden;
 858 void remove_except_protected(entity e)
 859 {
 860         if(e.remove_except_protected_forbidden)
 861                 error("not allowed to remove this at this point");
 862         builtin_remove(e);
 863 }
 864
 865 void remove_unsafely(entity e)
 866 {
 867     if(e.classname == "spike")
 868         error("Removing spikes is forbidden (crylink bug), please report");
 869     builtin_remove(e);
 870 }
 871
 872 void remove_safely(entity e)
 873 {
 874     make_safe_for_remove(e);
 875     builtin_remove(e);
 876 }
 877
 878 void InitializeEntity(entity e, void(entity this) func, float order)
 879 {
 880     entity prev, cur;
 881
 882     if (!e || e.initialize_entity)
 883     {
 884         // make a proxy initializer entity
 885         entity e_old = e;
 886         e = new(initialize_entity);
 887         e.enemy = e_old;
 888     }
 889
 890     e.initialize_entity = func;
 891     e.initialize_entity_order = order;
 892
 893     cur = initialize_entity_first;
 894     prev = NULL;
 895     for (;;)
 896     {
 897         if (!cur || cur.initialize_entity_order > order)
 898         {
 899             // insert between prev and cur
 900             if (prev)
 901                 prev.initialize_entity_next = e;
 902             else
 903                 initialize_entity_first = e;
 904             e.initialize_entity_next = cur;
 905             return;
 906         }
 907         prev = cur;
 908         cur = cur.initialize_entity_next;
 909     }
 910 }
 911 void InitializeEntitiesRun()
 912 {
 913     entity startoflist = initialize_entity_first;
 914     initialize_entity_first = NULL;
 915     delete_fn = remove_except_protected;
 916     for (entity e = startoflist; e; e = e.initialize_entity_next)
 917     {
 918                 e.remove_except_protected_forbidden = 1;
 919     }
 920     for (entity e = startoflist; e; )
 921     {
 922                 e.remove_except_protected_forbidden = 0;
 923         e.initialize_entity_order = 0;
 924         entity next = e.initialize_entity_next;
 925         e.initialize_entity_next = NULL;
 926         var void(entity this) func = e.initialize_entity;
 927         e.initialize_entity = func_null;
 928         if (e.classname == "initialize_entity")
 929         {
 930             entity wrappee = e.enemy;
 931             builtin_remove(e);
 932             e = wrappee;
 933         }
 934         //dprint("Delayed initialization: ", e.classname, "\n");
 935         if (func)
 936         {
 937                 func(e);
 938         }
 939         else
 940         {
 941             eprint(e);
 942             backtrace(strcat("Null function in: ", e.classname, "\n"));
 943         }
 944         e = next;
 945     }
 946     delete_fn = remove_unsafely;
 947 }
 948
 949 .float(entity) isEliminated;
 950 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 951 {
 952         Stream out = MSG_ENTITY;
 953         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 954         serialize(byte, out, sendflags);
 955         if (sendflags & 1) {
 956                 for (int i = 1; i <= maxclients; i += 8) {
 957                         int f = 0;
 958                         entity e = edict_num(i);
 959                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 960                                 if (eliminatedPlayers.isEliminated(e)) {
 961                                         f |= BIT(b);
 962                                 }
 963                         }
 964                         serialize(byte, out, f);
 965                 }
 966         }
 967         return true;
 968 }
 969
 970 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 971 {
 972         if(eliminatedPlayers)
 973         {
 974                 backtrace("Can't spawn eliminatedPlayers again!");
 975                 return;
 976         }
 977         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 978         eliminatedPlayers.isEliminated = isEliminated_func;
 979 }
 980
 981
 982
 983
 984 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 985 {
 986         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 987                 this.projectiledeathtype |= HITTYPE_SPLASH;
 988         adaptor_think2use(this);
 989 }
 990
 991 // deferred dropping
 992 void DropToFloor_Handler(entity this)
 993 {
 994     WITHSELF(this, builtin_droptofloor());
 995     this.dropped_origin = this.origin;
 996 }
 997
 998 void droptofloor(entity this)
 999 {
1000     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1001 }
1002
1003
1004
1005 float trace_hits_box_a0, trace_hits_box_a1;
1006
1007 float trace_hits_box_1d(float end, float thmi, float thma)
1008 {
1009     if (end == 0)
1010     {
1011         // just check if x is in range
1012         if (0 < thmi)
1013             return false;
1014         if (0 > thma)
1015             return false;
1016     }
1017     else
1018     {
1019         // do the trace with respect to x
1020         // 0 -> end has to stay in thmi -> thma
1021         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1022         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1023         if (trace_hits_box_a0 > trace_hits_box_a1)
1024             return false;
1025     }
1026     return true;
1027 }
1028
1029 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1030 {
1031     end -= start;
1032     thmi -= start;
1033     thma -= start;
1034     // now it is a trace from 0 to end
1035
1036     trace_hits_box_a0 = 0;
1037     trace_hits_box_a1 = 1;
1038
1039     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1040         return false;
1041     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1042         return false;
1043     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1044         return false;
1045
1046     return true;
1047 }
1048
1049 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1050 {
1051     return trace_hits_box(start, end, thmi - ma, thma - mi);
1052 }
1053
1054 bool SUB_NoImpactCheck(entity this, entity toucher)
1055 {
1056         // zero hitcontents = this is not the real impact, but either the
1057         // mirror-impact of something hitting the projectile instead of the
1058         // projectile hitting the something, or a touchareagrid one. Neither of
1059         // these stop the projectile from moving, so...
1060         if(trace_dphitcontents == 0)
1061         {
1062                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1063                 checkclient(this);
1064         }
1065     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1066         return true;
1067     if (toucher == NULL && this.size != '0 0 0')
1068     {
1069         vector tic;
1070         tic = this.velocity * sys_frametime;
1071         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1072         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1073         if (trace_fraction >= 1)
1074         {
1075             LOG_TRACE("Odd... did not hit...?");
1076         }
1077         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1078         {
1079             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1080             return true;
1081         }
1082     }
1083
1084     return false;
1085 }
1086
1087 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1088
1089 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1090 {
1091         if(SUB_OwnerCheck(this, toucher))
1092                 return true;
1093         if(SUB_NoImpactCheck(this, toucher))
1094         {
1095                 if(this.classname == "nade")
1096                         return false; // no checks here
1097                 else if(this.classname == "grapplinghook")
1098                         RemoveHook(this);
1099                 else if(this.classname == "spike")
1100                 {
1101                         W_Crylink_Dequeue(this);
1102                         delete(this);
1103                 }
1104                 else
1105                         delete(this);
1106                 return true;
1107         }
1108         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1109                 UpdateCSQCProjectile(this);
1110         return false;
1111 }
1112
1113 /** engine callback */
1114 void URI_Get_Callback(float id, float status, string data)
1115 {
1116         if(url_URI_Get_Callback(id, status, data))
1117         {
1118                 // handled
1119         }
1120         else if (id == URI_GET_DISCARD)
1121         {
1122                 // discard
1123         }
1124         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1125         {
1126                 // sv_cmd curl
1127                 Curl_URI_Get_Callback(id, status, data);
1128         }
1129         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1130         {
1131                 // online ban list
1132                 OnlineBanList_URI_Get_Callback(id, status, data);
1133         }
1134         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1135         {
1136                 // handled by a mutator
1137         }
1138         else
1139         {
1140                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1141         }
1142 }
1143
1144 string uid2name(string myuid) {
1145         string s;
1146         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1147
1148         // FIXME remove this later after 0.6 release
1149         // convert old style broken records to correct style
1150         if(s == "")
1151         {
1152                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1153                 if(s != "")
1154                 {
1155                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1156                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1157                 }
1158         }
1159
1160         if(s == "")
1161                 s = "^1Unregistered Player";
1162         return s;
1163 }
1164
1165 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1166 {
1167     float m, i;
1168     vector start, org, delta, end, enddown, mstart;
1169
1170     m = e.dphitcontentsmask;
1171     e.dphitcontentsmask = goodcontents | badcontents;
1172
1173     org = boundmin;
1174     delta = boundmax - boundmin;
1175
1176     start = end = org;
1177
1178     for (i = 0; i < attempts; ++i)
1179     {
1180         start.x = org.x + random() * delta.x;
1181         start.y = org.y + random() * delta.y;
1182         start.z = org.z + random() * delta.z;
1183
1184         // rule 1: start inside world bounds, and outside
1185         // solid, and don't start from somewhere where you can
1186         // fall down to evil
1187         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1188         if (trace_fraction >= 1)
1189             continue;
1190         if (trace_startsolid)
1191             continue;
1192         if (trace_dphitcontents & badcontents)
1193             continue;
1194         if (trace_dphitq3surfaceflags & badsurfaceflags)
1195             continue;
1196
1197         // rule 2: if we are too high, lower the point
1198         if (trace_fraction * delta.z > maxaboveground)
1199             start = trace_endpos + '0 0 1' * maxaboveground;
1200         enddown = trace_endpos;
1201
1202         // rule 3: make sure we aren't outside the map. This only works
1203         // for somewhat well formed maps. A good rule of thumb is that
1204         // the map should have a convex outside hull.
1205         // these can be traceLINES as we already verified the starting box
1206         mstart = start + 0.5 * (e.mins + e.maxs);
1207         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1208         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1209             continue;
1210         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1211         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1212             continue;
1213         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1214         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1215             continue;
1216         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1217         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1218             continue;
1219         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1220         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1221             continue;
1222
1223         // rule 4: we must "see" some spawnpoint or item
1224     entity sp = NULL;
1225     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1226     {
1227         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1228         {
1229                 sp = it;
1230                 break;
1231         }
1232     });
1233         if(!sp)
1234         {
1235                 int items_checked = 0;
1236                 IL_EACH(g_items, checkpvs(mstart, it),
1237                 {
1238                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1239                         {
1240                                 sp = it;
1241                                 break;
1242                         }
1243
1244                         ++items_checked;
1245                         if(items_checked >= attempts)
1246                                 break; // sanity
1247                 });
1248
1249                 if(!sp)
1250                         continue;
1251         }
1252
1253         // find a random vector to "look at"
1254         end.x = org.x + random() * delta.x;
1255         end.y = org.y + random() * delta.y;
1256         end.z = org.z + random() * delta.z;
1257         end = start + normalize(end - start) * vlen(delta);
1258
1259         // rule 4: start TO end must not be too short
1260         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1261         if (trace_startsolid)
1262             continue;
1263         if (trace_fraction < minviewdistance / vlen(delta))
1264             continue;
1265
1266         // rule 5: don't want to look at sky
1267         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1268             continue;
1269
1270         // rule 6: we must not end up in trigger_hurt
1271         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1272             continue;
1273
1274         break;
1275     }
1276
1277     e.dphitcontentsmask = m;
1278
1279     if (i < attempts)
1280     {
1281         setorigin(e, start);
1282         e.angles = vectoangles(end - start);
1283         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1284         return true;
1285     }
1286     else
1287         return false;
1288 }
1289
1290 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1291 {
1292         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1293 }
1294
1295 void write_recordmarker(entity pl, float tstart, float dt)
1296 {
1297     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1298
1299     // also write a marker into demo files for demotc-race-record-extractor to find
1300     stuffcmd(pl,
1301              strcat(
1302                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1303                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1304 }
1305
1306 void attach_sameorigin(entity e, entity to, string tag)
1307 {
1308     vector org, t_forward, t_left, t_up, e_forward, e_up;
1309     float tagscale;
1310
1311     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1312     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1313     t_forward = v_forward * tagscale;
1314     t_left = v_right * -tagscale;
1315     t_up = v_up * tagscale;
1316
1317     e.origin_x = org * t_forward;
1318     e.origin_y = org * t_left;
1319     e.origin_z = org * t_up;
1320
1321     // current forward and up directions
1322     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1323                 e.angles = AnglesTransform_FromVAngles(e.angles);
1324         else
1325                 e.angles = AnglesTransform_FromAngles(e.angles);
1326     fixedmakevectors(e.angles);
1327
1328     // untransform forward, up!
1329     e_forward.x = v_forward * t_forward;
1330     e_forward.y = v_forward * t_left;
1331     e_forward.z = v_forward * t_up;
1332     e_up.x = v_up * t_forward;
1333     e_up.y = v_up * t_left;
1334     e_up.z = v_up * t_up;
1335
1336     e.angles = fixedvectoangles2(e_forward, e_up);
1337     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1338                 e.angles = AnglesTransform_ToVAngles(e.angles);
1339         else
1340                 e.angles = AnglesTransform_ToAngles(e.angles);
1341
1342     setattachment(e, to, tag);
1343     setorigin(e, e.origin);
1344 }
1345
1346 void detach_sameorigin(entity e)
1347 {
1348     vector org;
1349     org = gettaginfo(e, 0);
1350     e.angles = fixedvectoangles2(v_forward, v_up);
1351     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1352                 e.angles = AnglesTransform_ToVAngles(e.angles);
1353         else
1354                 e.angles = AnglesTransform_ToAngles(e.angles);
1355     setorigin(e, org);
1356     setattachment(e, NULL, "");
1357     setorigin(e, e.origin);
1358 }
1359
1360 void follow_sameorigin(entity e, entity to)
1361 {
1362     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1363     e.aiment = to; // make the hole follow bmodel
1364     e.punchangle = to.angles; // the original angles of bmodel
1365     e.view_ofs = e.origin - to.origin; // relative origin
1366     e.v_angle = e.angles - to.angles; // relative angles
1367 }
1368
1369 void unfollow_sameorigin(entity e)
1370 {
1371     set_movetype(e, MOVETYPE_NONE);
1372 }
1373
1374 entity gettaginfo_relative_ent;
1375 vector gettaginfo_relative(entity e, float tag)
1376 {
1377     if (!gettaginfo_relative_ent)
1378     {
1379         gettaginfo_relative_ent = spawn();
1380         gettaginfo_relative_ent.effects = EF_NODRAW;
1381     }
1382     gettaginfo_relative_ent.model = e.model;
1383     gettaginfo_relative_ent.modelindex = e.modelindex;
1384     gettaginfo_relative_ent.frame = e.frame;
1385     return gettaginfo(gettaginfo_relative_ent, tag);
1386 }
1387
1388 .string aiment_classname;
1389 .float aiment_deadflag;
1390 void SetMovetypeFollow(entity ent, entity e)
1391 {
1392         // FIXME this may not be warpzone aware
1393         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1394         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1395         ent.aiment = e; // make the hole follow bmodel
1396         ent.punchangle = e.angles; // the original angles of bmodel
1397         ent.view_ofs = ent.origin - e.origin; // relative origin
1398         ent.v_angle = ent.angles - e.angles; // relative angles
1399         ent.aiment_classname = strzone(e.classname);
1400         ent.aiment_deadflag = e.deadflag;
1401 }
1402 void UnsetMovetypeFollow(entity ent)
1403 {
1404         set_movetype(ent, MOVETYPE_FLY);
1405         PROJECTILE_MAKETRIGGER(ent);
1406         ent.aiment = NULL;
1407 }
1408 float LostMovetypeFollow(entity ent)
1409 {
1410 /*
1411         if(ent.move_movetype != MOVETYPE_FOLLOW)
1412                 if(ent.aiment)
1413                         error("???");
1414 */
1415         if(ent.aiment)
1416         {
1417                 if(ent.aiment.classname != ent.aiment_classname)
1418                         return 1;
1419                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1420                         return 1;
1421         }
1422         return 0;
1423 }
1424
1425 .bool pushable;
1426 bool isPushable(entity e)
1427 {
1428         if(e.pushable)
1429                 return true;
1430         if(IS_VEHICLE(e))
1431                 return false;
1432         if(e.iscreature)
1433                 return true;
1434         if (Item_IsLoot(e))
1435         {
1436                 return true;
1437         }
1438         switch(e.classname)
1439         {
1440                 case "body":
1441                         return true;
1442                 case "bullet": // antilagged bullets can't hit this either
1443                         return false;
1444         }
1445         if (e.projectiledeathtype)
1446                 return true;
1447         return false;
1448 }