qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         float nPlayerHealth = rint(enPlayer.health);
  85         float nPlayerArmor = rint(enPlayer.armorvalue);
  86         float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         float nPlayerPing = rint(enPlayer.ping);
  88         string strPlayerPingColor;
  89         string strMessage;
  90
  91         if(nPlayerPing >= 150)
  92                 strPlayerPingColor = "^1";
  93         else
  94                 strPlayerPingColor = "^2";
  95
  96         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  97                 strMessage = strcat(strMessage, "^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  98
  99         if(autocvar_sv_fragmessage_information_ping) {
 100                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 101                         strMessage = strcat(strMessage, " ^7(^2Bot");
 102                 else
 103                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 104                 if(autocvar_sv_fragmessage_information_handicap)
 105                         if(autocvar_sv_fragmessage_information_handicap == 2)
 106                                 if(nPlayerHandicap <= 1)
 107                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 108                                 else
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 110                         else if not(nPlayerHandicap <= 1)
 111                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                 else
 113                         strMessage = strcat(strMessage, "^7)");
 114         } else if(autocvar_sv_fragmessage_information_handicap) {
 115                 if(autocvar_sv_fragmessage_information_handicap == 2)
 116                         if(nPlayerHandicap <= 1)
 117                                 strMessage = strcat(strMessage, "^7(Handicap ^2Off^7)");
 118                         else
 119                                 strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 120                 else if(nPlayerHandicap > 1)
 121                         strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122         }
 123
 124         if(strMessage) // add new line to the beginning if there is a message
 125                 strMessage = strcat("\n", strMessage);
 126
 127         return strMessage;
 128 }
 129 void bcenterprint(string s)
 130 {
 131     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 132     entity head;
 133     FOR_EACH_PLAYER(head)
 134     if (clienttype(head) == CLIENTTYPE_REAL)
 135         centerprint(head, s);
 136 }
 137
 138 void GameLogEcho(string s)
 139 {
 140     string fn;
 141     float matches;
 142
 143     if (autocvar_sv_eventlog_files)
 144     {
 145         if (!logfile_open)
 146         {
 147             logfile_open = TRUE;
 148             matches = autocvar_sv_eventlog_files_counter + 1;
 149             cvar_set("sv_eventlog_files_counter", ftos(matches));
 150             fn = ftos(matches);
 151             if (strlen(fn) < 8)
 152                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 153             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 154             logfile = fopen(fn, FILE_APPEND);
 155             fputs(logfile, ":logversion:3\n");
 156         }
 157         if (logfile >= 0)
 158         {
 159             if (autocvar_sv_eventlog_files_timestamps)
 160                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 161             else
 162                 fputs(logfile, strcat(s, "\n"));
 163         }
 164     }
 165     if (autocvar_sv_eventlog_console)
 166     {
 167         print(s, "\n");
 168     }
 169 }
 170
 171 void GameLogInit()
 172 {
 173     logfile_open = 0;
 174     // will be opened later
 175 }
 176
 177 void GameLogClose()
 178 {
 179     if (logfile_open && logfile >= 0)
 180     {
 181         fclose(logfile);
 182         logfile = -1;
 183     }
 184 }
 185
 186 vector PL_VIEW_OFS;
 187 vector PL_MIN;
 188 vector PL_MAX;
 189 vector PL_HEAD;
 190 vector PL_CROUCH_VIEW_OFS;
 191 vector PL_CROUCH_MIN;
 192 vector PL_CROUCH_MAX;
 193
 194 float spawnpoint_nag;
 195 void relocate_spawnpoint()
 196 {
 197     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 198     PL_MIN                                  = stov(autocvar_sv_player_mins);
 199     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 200     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 201     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 202     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 203     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 204
 205     // nudge off the floor
 206     setorigin(self, self.origin + '0 0 1');
 207
 208     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 209     if (trace_startsolid)
 210     {
 211         vector o;
 212         o = self.origin;
 213         self.mins = PL_MIN;
 214         self.maxs = PL_MAX;
 215         if (!move_out_of_solid(self))
 216             objerror("could not get out of solid at all!");
 217         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 218         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 219         print(" ", ftos(self.origin_y - o_y));
 220         print(" ", ftos(self.origin_z - o_z), "'\n");
 221         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 222         {
 223             if (!spawnpoint_nag)
 224                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 225             spawnpoint_nag = 1;
 226         }
 227         else
 228         {
 229             setorigin(self, o);
 230             self.mins = self.maxs = '0 0 0';
 231             objerror("player spawn point in solid, mapper sucks!\n");
 232             return;
 233         }
 234     }
 235
 236     self.use = spawnpoint_use;
 237     self.team_saved = self.team;
 238     if (!self.cnt)
 239         self.cnt = 1;
 240
 241     if (have_team_spawns != 0)
 242         if (self.team)
 243             have_team_spawns = 1;
 244     have_team_spawns_forteam[self.team] = 1;
 245
 246     if (autocvar_r_showbboxes)
 247     {
 248         // show where spawnpoints point at too
 249         makevectors(self.angles);
 250         entity e;
 251         e = spawn();
 252         e.classname = "info_player_foo";
 253         setorigin(e, self.origin + v_forward * 24);
 254         setsize(e, '-8 -8 -8', '8 8 8');
 255         e.solid = SOLID_TRIGGER;
 256     }
 257 }
 258
 259 #define strstr strstrofs
 260 /*
 261 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 262 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 263 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 264 // BE CONSTANT OR strzoneD!
 265 float strstr(string haystack, string needle, float offset)
 266 {
 267         float len, endpos;
 268         string found;
 269         len = strlen(needle);
 270         endpos = strlen(haystack) - len;
 271         while(offset <= endpos)
 272         {
 273                 found = substring(haystack, offset, len);
 274                 if(found == needle)
 275                         return offset;
 276                 offset = offset + 1;
 277         }
 278         return -1;
 279 }
 280 */
 281
 282 float NUM_NEAREST_ENTITIES = 4;
 283 entity nearest_entity[NUM_NEAREST_ENTITIES];
 284 float nearest_length[NUM_NEAREST_ENTITIES];
 285 entity findnearest(vector point, .string field, string value, vector axismod)
 286 {
 287     entity localhead;
 288     float i;
 289     float j;
 290     float len;
 291     vector dist;
 292
 293     float num_nearest;
 294     num_nearest = 0;
 295
 296     localhead = find(world, field, value);
 297     while (localhead)
 298     {
 299         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 300             dist = localhead.oldorigin;
 301         else
 302             dist = localhead.origin;
 303         dist = dist - point;
 304         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 305         len = vlen(dist);
 306
 307         for (i = 0; i < num_nearest; ++i)
 308         {
 309             if (len < nearest_length[i])
 310                 break;
 311         }
 312
 313         // now i tells us where to insert at
 314         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 315         if (i < NUM_NEAREST_ENTITIES)
 316         {
 317             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 318             {
 319                 nearest_length[j + 1] = nearest_length[j];
 320                 nearest_entity[j + 1] = nearest_entity[j];
 321             }
 322             nearest_length[i] = len;
 323             nearest_entity[i] = localhead;
 324             if (num_nearest < NUM_NEAREST_ENTITIES)
 325                 num_nearest = num_nearest + 1;
 326         }
 327
 328         localhead = find(localhead, field, value);
 329     }
 330
 331     // now use the first one from our list that we can see
 332     for (i = 0; i < num_nearest; ++i)
 333     {
 334         traceline(point, nearest_entity[i].origin, TRUE, world);
 335         if (trace_fraction == 1)
 336         {
 337             if (i != 0)
 338             {
 339                 dprint("Nearest point (");
 340                 dprint(nearest_entity[0].netname);
 341                 dprint(") is not visible, using a visible one.\n");
 342             }
 343             return nearest_entity[i];
 344         }
 345     }
 346
 347     if (num_nearest == 0)
 348         return world;
 349
 350     dprint("Not seeing any location point, using nearest as fallback.\n");
 351     /* DEBUGGING CODE:
 352     dprint("Candidates were: ");
 353     for(j = 0; j < num_nearest; ++j)
 354     {
 355         if(j != 0)
 356                 dprint(", ");
 357         dprint(nearest_entity[j].netname);
 358     }
 359     dprint("\n");
 360     */
 361
 362     return nearest_entity[0];
 363 }
 364
 365 void spawnfunc_target_location()
 366 {
 367     self.classname = "target_location";
 368     // location name in netname
 369     // eventually support: count, teamgame selectors, line of sight?
 370 };
 371
 372 void spawnfunc_info_location()
 373 {
 374     self.classname = "target_location";
 375     self.message = self.netname;
 376 };
 377
 378 string NearestLocation(vector p)
 379 {
 380     entity loc;
 381     string ret;
 382     ret = "somewhere";
 383     loc = findnearest(p, classname, "target_location", '1 1 1');
 384     if (loc)
 385     {
 386         ret = loc.message;
 387     }
 388     else
 389     {
 390         loc = findnearest(p, target, "###item###", '1 1 4');
 391         if (loc)
 392             ret = loc.netname;
 393     }
 394     return ret;
 395 }
 396
 397 string formatmessage(string msg)
 398 {
 399         float p, p1, p2;
 400         float n;
 401         vector cursor;
 402         entity cursor_ent;
 403         string escape;
 404         string replacement;
 405         p = 0;
 406         n = 7;
 407
 408         WarpZone_crosshair_trace(self);
 409         cursor = trace_endpos;
 410         cursor_ent = trace_ent;
 411
 412         while (1) {
 413                 if (n < 1)
 414                         break; // too many replacements
 415
 416                 n = n - 1;
 417                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 418                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 419
 420                 if (p1 < 0)
 421                         p1 = p2;
 422
 423                 if (p2 < 0)
 424                         p2 = p1;
 425
 426                 p = min(p1, p2);
 427
 428                 if (p < 0)
 429                         break;
 430
 431                 replacement = substring(msg, p, 2);
 432                 escape = substring(msg, p + 1, 1);
 433
 434                 if (escape == "%")
 435                         replacement = "%";
 436                 else if (escape == "\\")
 437                         replacement = "\\";
 438                 else if (escape == "n")
 439                         replacement = "\n";
 440                 else if (escape == "a")
 441                         replacement = ftos(floor(self.armorvalue));
 442                 else if (escape == "h")
 443                         replacement = ftos(floor(self.health));
 444                 else if (escape == "l")
 445                         replacement = NearestLocation(self.origin);
 446                 else if (escape == "y")
 447                         replacement = NearestLocation(cursor);
 448                 else if (escape == "d")
 449                         replacement = NearestLocation(self.death_origin);
 450                 else if (escape == "w") {
 451                         float wep;
 452                         wep = self.weapon;
 453                         if (!wep)
 454                                 wep = self.switchweapon;
 455                         if (!wep)
 456                                 wep = self.cnt;
 457                         replacement = W_Name(wep);
 458                 } else if (escape == "W") {
 459                         if (self.items & IT_SHELLS) replacement = "shells";
 460                         else if (self.items & IT_NAILS) replacement = "bullets";
 461                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 462                         else if (self.items & IT_CELLS) replacement = "cells";
 463                         else replacement = "batteries"; // ;)
 464                 } else if (escape == "x") {
 465                         replacement = cursor_ent.netname;
 466                         if (!replacement || !cursor_ent)
 467                                 replacement = "nothing";
 468                 } else if (escape == "s")
 469                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 470                 else if (escape == "S")
 471                         replacement = ftos(vlen(self.velocity));
 472
 473                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 474                 p = p + strlen(replacement);
 475         }
 476         return msg;
 477 }
 478
 479 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 480         return (value == 0) ? FALSE : TRUE;
 481 }
 482
 483 /*
 484 =============
 485 GetCvars
 486 =============
 487 Called with:
 488   0:  sends the request
 489   >0: receives a cvar from name=argv(f) value=argv(f+1)
 490 */
 491 void GetCvars_handleString(string thisname, float f, .string field, string name)
 492 {
 493         if (f < 0)
 494         {
 495                 if (self.field)
 496                         strunzone(self.field);
 497                 self.field = string_null;
 498         }
 499         else if (f > 0)
 500         {
 501                 if (thisname == name)
 502                 {
 503                         if (self.field)
 504                                 strunzone(self.field);
 505                         self.field = strzone(argv(f + 1));
 506                 }
 507         }
 508         else
 509                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 510 }
 511 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 512 {
 513         GetCvars_handleString(thisname, f, field, name);
 514         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 515                 if (thisname == name)
 516                 {
 517                         string s;
 518                         s = func(strcat1(self.field));
 519                         if (s != self.field)
 520                         {
 521                                 strunzone(self.field);
 522                                 self.field = strzone(s);
 523                         }
 524                 }
 525 }
 526 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 527 {
 528         if (f < 0)
 529         {
 530         }
 531         else if (f > 0)
 532         {
 533                 if (thisname == name)
 534                         self.field = stof(argv(f + 1));
 535         }
 536         else
 537                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 538 }
 539 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 540 {
 541         if (f < 0)
 542         {
 543         }
 544         else if (f > 0)
 545         {
 546                 if (thisname == name)
 547                 {
 548                         if(!self.field)
 549                         {
 550                                 self.field = stof(argv(f + 1));
 551                                 if(!self.field)
 552                                         self.field = -1;
 553                         }
 554                 }
 555         }
 556         else
 557         {
 558                 if(!self.field)
 559                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 560         }
 561 }
 562 float w_getbestweapon(entity e);
 563 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 564 {
 565         string o;
 566         o = W_FixWeaponOrder_ForceComplete(wo);
 567         if(self.weaponorder_byimpulse)
 568         {
 569                 strunzone(self.weaponorder_byimpulse);
 570                 self.weaponorder_byimpulse = string_null;
 571         }
 572         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 573         return o;
 574 }
 575 void GetCvars(float f)
 576 {
 577         string s;
 578
 579         if (f > 0)
 580                 s = strcat1(argv(f));
 581
 582         get_cvars_f = f;
 583         get_cvars_s = s;
 584         MUTATOR_CALLHOOK(GetCvars);
 585         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 586         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 587         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 588         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 589         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 608
 609         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 610         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 611
 612 #ifdef ALLOW_FORCEMODELS
 613         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 615 #endif
 616         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 617         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 619         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 620         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 621
 622         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 623         if (f > 0)
 624         {
 625                 if (s == "cl_weaponpriority")
 626                         self.switchweapon = w_getbestweapon(self);
 627                 if (s == "cl_allow_uidtracking")
 628                         PlayerStats_AddPlayer(self);
 629         }
 630 }
 631
 632 void backtrace(string msg)
 633 {
 634     float dev, war;
 635     dev = autocvar_developer;
 636     war = autocvar_prvm_backtraceforwarnings;
 637     cvar_set("developer", "1");
 638     cvar_set("prvm_backtraceforwarnings", "1");
 639     print("\n");
 640     print("--- CUT HERE ---\nWARNING: ");
 641     print(msg);
 642     print("\n");
 643     remove(world); // isn't there any better way to cause a backtrace?
 644     print("\n--- CUT UNTIL HERE ---\n");
 645     cvar_set("developer", ftos(dev));
 646     cvar_set("prvm_backtraceforwarnings", ftos(war));
 647 }
 648
 649 string Team_ColorCode(float teamid)
 650 {
 651     if (teamid == COLOR_TEAM1)
 652         return "^1";
 653     else if (teamid == COLOR_TEAM2)
 654         return "^4";
 655     else if (teamid == COLOR_TEAM3)
 656         return "^3";
 657     else if (teamid == COLOR_TEAM4)
 658         return "^6";
 659     else
 660         return "^7";
 661 }
 662
 663 string Team_ColorName(float t)
 664 {
 665     // fixme: Search for team entities and get their .netname's!
 666     if (t == COLOR_TEAM1)
 667         return "Red";
 668     if (t == COLOR_TEAM2)
 669         return "Blue";
 670     if (t == COLOR_TEAM3)
 671         return "Yellow";
 672     if (t == COLOR_TEAM4)
 673         return "Pink";
 674     return "Neutral";
 675 }
 676
 677 string Team_ColorNameLowerCase(float t)
 678 {
 679     // fixme: Search for team entities and get their .netname's!
 680     if (t == COLOR_TEAM1)
 681         return "red";
 682     if (t == COLOR_TEAM2)
 683         return "blue";
 684     if (t == COLOR_TEAM3)
 685         return "yellow";
 686     if (t == COLOR_TEAM4)
 687         return "pink";
 688     return "neutral";
 689 }
 690
 691 float ColourToNumber(string team_colour)
 692 {
 693         if (team_colour == "red")
 694                 return COLOR_TEAM1;
 695
 696         if (team_colour == "blue")
 697                 return COLOR_TEAM2;
 698
 699         if (team_colour == "yellow")
 700                 return COLOR_TEAM3;
 701
 702         if (team_colour == "pink")
 703                 return COLOR_TEAM4;
 704
 705         if (team_colour == "auto")
 706                 return 0;
 707
 708         return -1;
 709 }
 710
 711 float NumberToTeamNumber(float number)
 712 {
 713         if (number == 1)
 714                 return COLOR_TEAM1;
 715
 716         if (number == 2)
 717                 return COLOR_TEAM2;
 718
 719         if (number == 3)
 720                 return COLOR_TEAM3;
 721
 722         if (number == 4)
 723                 return COLOR_TEAM4;
 724
 725         return -1;
 726 }
 727
 728 // decolorizes and team colors the player name when needed
 729 string playername(entity p)
 730 {
 731     string t;
 732     if (teamplay && !intermission_running && p.classname == "player")
 733     {
 734         t = Team_ColorCode(p.team);
 735         return strcat(t, strdecolorize(p.netname));
 736     }
 737     else
 738         return p.netname;
 739 }
 740
 741 vector randompos(vector m1, vector m2)
 742 {
 743     local vector v;
 744     m2 = m2 - m1;
 745     v_x = m2_x * random() + m1_x;
 746     v_y = m2_y * random() + m1_y;
 747     v_z = m2_z * random() + m1_z;
 748     return  v;
 749 };
 750
 751 //#NO AUTOCVARS START
 752
 753 float g_pickup_shells;
 754 float g_pickup_shells_max;
 755 float g_pickup_nails;
 756 float g_pickup_nails_max;
 757 float g_pickup_rockets;
 758 float g_pickup_rockets_max;
 759 float g_pickup_cells;
 760 float g_pickup_cells_max;
 761 float g_pickup_fuel;
 762 float g_pickup_fuel_jetpack;
 763 float g_pickup_fuel_max;
 764 float g_pickup_armorsmall;
 765 float g_pickup_armorsmall_max;
 766 float g_pickup_armorsmall_anyway;
 767 float g_pickup_armormedium;
 768 float g_pickup_armormedium_max;
 769 float g_pickup_armormedium_anyway;
 770 float g_pickup_armorbig;
 771 float g_pickup_armorbig_max;
 772 float g_pickup_armorbig_anyway;
 773 float g_pickup_armorlarge;
 774 float g_pickup_armorlarge_max;
 775 float g_pickup_armorlarge_anyway;
 776 float g_pickup_healthsmall;
 777 float g_pickup_healthsmall_max;
 778 float g_pickup_healthsmall_anyway;
 779 float g_pickup_healthmedium;
 780 float g_pickup_healthmedium_max;
 781 float g_pickup_healthmedium_anyway;
 782 float g_pickup_healthlarge;
 783 float g_pickup_healthlarge_max;
 784 float g_pickup_healthlarge_anyway;
 785 float g_pickup_healthmega;
 786 float g_pickup_healthmega_max;
 787 float g_pickup_healthmega_anyway;
 788 float g_pickup_ammo_anyway;
 789 float g_pickup_weapons_anyway;
 790 float g_weaponarena;
 791 float g_weaponarena_random;
 792 float g_weaponarena_random_with_laser;
 793 string g_weaponarena_list;
 794 float g_weaponspeedfactor;
 795 float g_weaponratefactor;
 796 float g_weapondamagefactor;
 797 float g_weaponforcefactor;
 798 float g_weaponspreadfactor;
 799
 800 float start_weapons;
 801 float start_items;
 802 float start_ammo_shells;
 803 float start_ammo_nails;
 804 float start_ammo_rockets;
 805 float start_ammo_cells;
 806 float start_ammo_fuel;
 807 float start_health;
 808 float start_armorvalue;
 809 float warmup_start_weapons;
 810 float warmup_start_ammo_shells;
 811 float warmup_start_ammo_nails;
 812 float warmup_start_ammo_rockets;
 813 float warmup_start_ammo_cells;
 814 float warmup_start_ammo_fuel;
 815 float warmup_start_health;
 816 float warmup_start_armorvalue;
 817 float g_weapon_stay;
 818 float g_ghost_items;
 819
 820 entity get_weaponinfo(float w);
 821
 822 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 823 {
 824         var float i = weaponinfo.weapon;
 825
 826         if (!i)
 827                 return 0;
 828
 829         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 830
 831         if (t < 0) // "default" weapon selection
 832         {
 833                 if (g_lms || g_ca || allguns)
 834                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 835                 else if(t < -1)
 836                         t = 0;
 837                 else if (g_cts)
 838                         t = (i == WEP_SHOTGUN);
 839                 else if (g_nexball)
 840                         t = 0; // weapon is set a few lines later
 841                 else
 842                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 843                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 844                         t |= (i == WEP_HOOK);
 845         }
 846
 847         // we cannot disable porto in Nexball, we must force it
 848         if(g_nexball && i == WEP_PORTO)
 849                 t = 1;
 850
 851         return t;
 852 }
 853
 854 void readplayerstartcvars()
 855 {
 856         entity e;
 857         float i, j, t;
 858         string s;
 859
 860         // initialize starting values for players
 861         start_weapons = 0;
 862         start_items = 0;
 863         start_ammo_shells = 0;
 864         start_ammo_nails = 0;
 865         start_ammo_rockets = 0;
 866         start_ammo_cells = 0;
 867         start_health = cvar("g_balance_health_start");
 868         start_armorvalue = cvar("g_balance_armor_start");
 869
 870         g_weaponarena = 0;
 871         s = cvar_string("g_weaponarena");
 872         if (s == "0" || s == "")
 873         {
 874                 if(g_lms || g_ca)
 875                         s = "most";
 876         }
 877
 878         if (s == "0" || s == "")
 879         {
 880                 // no arena
 881         }
 882         else if (s == "off")
 883         {
 884                 // forcibly turn off weaponarena
 885         }
 886         else if (s == "all")
 887         {
 888                 g_weaponarena_list = "All Weapons";
 889                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 890                 {
 891                         e = get_weaponinfo(j);
 892                         g_weaponarena |= e.weapons;
 893                         weapon_action(e.weapon, WR_PRECACHE);
 894                 }
 895         }
 896         else if (s == "most")
 897         {
 898                 g_weaponarena_list = "Most Weapons";
 899                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 900                 {
 901                         e = get_weaponinfo(j);
 902                         if (e.spawnflags & WEP_FLAG_NORMAL)
 903                         {
 904                                 g_weaponarena |= e.weapons;
 905                                 weapon_action(e.weapon, WR_PRECACHE);
 906                         }
 907                 }
 908         }
 909         else if (s == "none")
 910         {
 911                 g_weaponarena_list = "No Weapons";
 912                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 913         }
 914         else
 915         {
 916                 t = tokenize_console(s);
 917                 g_weaponarena_list = "";
 918                 for (i = 0; i < t; ++i)
 919                 {
 920                         s = argv(i);
 921                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 922                         {
 923                                 e = get_weaponinfo(j);
 924                                 if (e.netname == s)
 925                                 {
 926                                         g_weaponarena |= e.weapons;
 927                                         weapon_action(e.weapon, WR_PRECACHE);
 928                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 929                                         break;
 930                                 }
 931                         }
 932                         if (j > WEP_LAST)
 933                         {
 934                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 935                         }
 936                 }
 937                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 938         }
 939
 940         if(g_weaponarena)
 941                 g_weaponarena_random = cvar("g_weaponarena_random");
 942         else
 943                 g_weaponarena_random = 0;
 944         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 945
 946         if (g_weaponarena)
 947         {
 948                 start_weapons = g_weaponarena;
 949                 if(!(g_lms || g_ca))
 950                         start_items |= IT_UNLIMITED_AMMO;
 951         }
 952         else if (g_minstagib)
 953         {
 954                 start_health = 100;
 955                 start_armorvalue = 0;
 956                 start_weapons = WEPBIT_MINSTANEX;
 957                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 958                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 959
 960                 if (g_minstagib_invis_alpha <= 0)
 961                         g_minstagib_invis_alpha = -1;
 962         }
 963         else
 964         {
 965                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 966                 {
 967                         e = get_weaponinfo(i);
 968                         if(want_weapon("g_start_weapon_", e, FALSE))
 969                                 start_weapons |= e.weapons;
 970                 }
 971         }
 972
 973         if(!cvar("g_use_ammunition"))
 974                 start_items |= IT_UNLIMITED_AMMO;
 975
 976         if(g_minstagib)
 977         {
 978                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 979                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 980         }
 981         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 982         {
 983                 start_ammo_rockets = 999;
 984                 start_ammo_shells = 999;
 985                 start_ammo_cells = 999;
 986                 start_ammo_nails = 999;
 987                 start_ammo_fuel = 999;
 988         }
 989         else
 990         {
 991                 if(g_lms || g_ca)
 992                 {
 993                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 994                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 995                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 996                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 997                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 998                 }
 999                 else
1000                 {
1001                         start_ammo_shells = cvar("g_start_ammo_shells");
1002                         start_ammo_nails = cvar("g_start_ammo_nails");
1003                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1004                         start_ammo_cells = cvar("g_start_ammo_cells");
1005                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1006                 }
1007         }
1008
1009         if (g_lms || g_ca)
1010         {
1011                 start_health = cvar("g_lms_start_health");
1012                 start_armorvalue = cvar("g_lms_start_armor");
1013         }
1014
1015         if (inWarmupStage)
1016         {
1017                 warmup_start_ammo_shells = start_ammo_shells;
1018                 warmup_start_ammo_nails = start_ammo_nails;
1019                 warmup_start_ammo_rockets = start_ammo_rockets;
1020                 warmup_start_ammo_cells = start_ammo_cells;
1021                 warmup_start_ammo_fuel = start_ammo_fuel;
1022                 warmup_start_health = start_health;
1023                 warmup_start_armorvalue = start_armorvalue;
1024                 warmup_start_weapons = start_weapons;
1025
1026                 if (!g_weaponarena && !g_minstagib && !g_ca)
1027                 {
1028                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1029                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1030                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1031                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1032                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1033                         warmup_start_health = cvar("g_warmup_start_health");
1034                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1035                         warmup_start_weapons = 0;
1036                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1037                         {
1038                                 e = get_weaponinfo(i);
1039                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1040                                         warmup_start_weapons |= e.weapons;
1041                         }
1042                 }
1043         }
1044
1045         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1046         {
1047                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1048                 start_items |= IT_FUEL_REGEN;
1049                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1050                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1051         }
1052
1053         if (g_jetpack)
1054                 start_items |= IT_JETPACK;
1055
1056         if (g_weapon_stay == 2)
1057         {
1058                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1059                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1060                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1061                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1062                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1063                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1064                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1065                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1066                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1067                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1068         }
1069
1070         MUTATOR_CALLHOOK(SetStartItems);
1071
1072         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1073         {
1074                 e = get_weaponinfo(i);
1075                 if(e.weapons & (start_weapons | warmup_start_weapons))
1076                         weapon_action(e.weapon, WR_PRECACHE);
1077         }
1078
1079         start_ammo_shells = max(0, start_ammo_shells);
1080         start_ammo_nails = max(0, start_ammo_nails);
1081         start_ammo_cells = max(0, start_ammo_cells);
1082         start_ammo_rockets = max(0, start_ammo_rockets);
1083         start_ammo_fuel = max(0, start_ammo_fuel);
1084
1085         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1086         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1087         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1088         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1089         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1090 }
1091
1092 float g_bugrigs;
1093 float g_bugrigs_planar_movement;
1094 float g_bugrigs_planar_movement_car_jumping;
1095 float g_bugrigs_reverse_spinning;
1096 float g_bugrigs_reverse_speeding;
1097 float g_bugrigs_reverse_stopping;
1098 float g_bugrigs_air_steering;
1099 float g_bugrigs_angle_smoothing;
1100 float g_bugrigs_friction_floor;
1101 float g_bugrigs_friction_brake;
1102 float g_bugrigs_friction_air;
1103 float g_bugrigs_accel;
1104 float g_bugrigs_speed_ref;
1105 float g_bugrigs_speed_pow;
1106 float g_bugrigs_steer;
1107
1108 float g_touchexplode;
1109 float g_touchexplode_radius;
1110 float g_touchexplode_damage;
1111 float g_touchexplode_edgedamage;
1112 float g_touchexplode_force;
1113
1114 float sv_autotaunt;
1115 float sv_taunt;
1116
1117 float sv_pitch_min;
1118 float sv_pitch_max;
1119 float sv_pitch_fixyaw;
1120
1121 string GetGametype(); // g_world.qc
1122 void readlevelcvars(void)
1123 {
1124         // first load all the mutators
1125         if(cvar("g_nix"))
1126                 MUTATOR_ADD(mutator_nix);
1127         if(cvar("g_dodging"))
1128                 MUTATOR_ADD(mutator_dodging);
1129         if(cvar("g_rocket_flying"))
1130                 MUTATOR_ADD(mutator_rocketflying);
1131         if(cvar("g_vampire"))
1132                 MUTATOR_ADD(mutator_vampire);
1133
1134         if(cvar("sv_allow_fullbright"))
1135                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1136
1137     g_bugrigs = cvar("g_bugrigs");
1138     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1139     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1140     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1141     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1142     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1143     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1144     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1145     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1146     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1147     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1148     g_bugrigs_accel = cvar("g_bugrigs_accel");
1149     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1150     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1151     g_bugrigs_steer = cvar("g_bugrigs_steer");
1152
1153     g_touchexplode = cvar("g_touchexplode");
1154     g_touchexplode_radius = cvar("g_touchexplode_radius");
1155     g_touchexplode_damage = cvar("g_touchexplode_damage");
1156     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1157     g_touchexplode_force = cvar("g_touchexplode_force");
1158
1159 #ifdef ALLOW_FORCEMODELS
1160         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1161 #endif
1162         sv_loddistance1 = cvar("sv_loddistance1");
1163         sv_loddistance2 = cvar("sv_loddistance2");
1164
1165         if(sv_loddistance2 <= sv_loddistance1)
1166                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1167
1168         sv_clones = cvar("sv_clones");
1169         sv_gentle = cvar("sv_gentle");
1170         sv_foginterval = cvar("sv_foginterval");
1171         g_cloaked = cvar("g_cloaked");
1172     if(g_cts)
1173         g_cloaked = 1; // always enable cloak in CTS
1174         g_jump_grunt = cvar("g_jump_grunt");
1175         g_footsteps = cvar("g_footsteps");
1176         g_grappling_hook = cvar("g_grappling_hook");
1177         g_jetpack = cvar("g_jetpack");
1178         g_midair = cvar("g_midair");
1179         g_minstagib = cvar("g_minstagib");
1180         g_norecoil = cvar("g_norecoil");
1181         g_bloodloss = cvar("g_bloodloss");
1182         sv_maxidle = cvar("sv_maxidle");
1183         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1184         g_ctf_reverse = cvar("g_ctf_reverse");
1185         sv_autotaunt = cvar("sv_autotaunt");
1186         sv_taunt = cvar("sv_taunt");
1187
1188         inWarmupStage = cvar("g_warmup");
1189         g_warmup_limit = cvar("g_warmup_limit");
1190         g_warmup_allguns = cvar("g_warmup_allguns");
1191         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1192
1193         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1194                 inWarmupStage = 0; // these modes cannot work together, sorry
1195
1196         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1197         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1198         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1199         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1200         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1201         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1202         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1203         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1204         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1205         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1206         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1207         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1208
1209         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1210         g_weaponratefactor = cvar("g_weaponratefactor");
1211         g_weapondamagefactor = cvar("g_weapondamagefactor");
1212         g_weaponforcefactor = cvar("g_weaponforcefactor");
1213         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1214
1215         g_pickup_shells = cvar("g_pickup_shells");
1216         g_pickup_shells_max = cvar("g_pickup_shells_max");
1217         g_pickup_nails = cvar("g_pickup_nails");
1218         g_pickup_nails_max = cvar("g_pickup_nails_max");
1219         g_pickup_rockets = cvar("g_pickup_rockets");
1220         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1221         g_pickup_cells = cvar("g_pickup_cells");
1222         g_pickup_cells_max = cvar("g_pickup_cells_max");
1223         g_pickup_fuel = cvar("g_pickup_fuel");
1224         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1225         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1226         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1227         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1228         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1229         g_pickup_armormedium = cvar("g_pickup_armormedium");
1230         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1231         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1232         g_pickup_armorbig = cvar("g_pickup_armorbig");
1233         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1234         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1235         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1236         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1237         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1238         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1239         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1240         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1241         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1242         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1243         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1244         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1245         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1246         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1247         g_pickup_healthmega = cvar("g_pickup_healthmega");
1248         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1249         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1250
1251         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1252         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1253
1254         g_pinata = cvar("g_pinata");
1255
1256     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1257     if(!g_weapon_stay)
1258         g_weapon_stay = cvar("g_weapon_stay");
1259
1260         g_ghost_items = cvar("g_ghost_items");
1261
1262         if(g_ghost_items >= 1)
1263                 g_ghost_items = 0.25; // default alpha value
1264
1265         if not(inWarmupStage && !g_ca)
1266                 game_starttime = cvar("g_start_delay");
1267
1268         sv_pitch_min = cvar("sv_pitch_min");
1269         sv_pitch_max = cvar("sv_pitch_max");
1270         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1271
1272         readplayerstartcvars();
1273 }
1274
1275 //#NO AUTOCVARS END
1276
1277 // Sound functions
1278 string precache_sound (string s) = #19;
1279 float precache_sound_index (string s) = #19;
1280
1281 #define SND_VOLUME      1
1282 #define SND_ATTENUATION 2
1283 #define SND_LARGEENTITY 8
1284 #define SND_LARGESOUND  16
1285
1286 float sound_allowed(float dest, entity e)
1287 {
1288     // sounds from world may always pass
1289     for (;;)
1290     {
1291         if (e.classname == "body")
1292             e = e.enemy;
1293         if (e.owner && e.owner != e)
1294             e = e.owner;
1295         else
1296             break;
1297     }
1298     // sounds to self may always pass
1299     if (dest == MSG_ONE)
1300         if (e == msg_entity)
1301             return TRUE;
1302     // sounds by players can be removed
1303     if (autocvar_bot_sound_monopoly)
1304         if (clienttype(e) == CLIENTTYPE_REAL)
1305             return FALSE;
1306     // anything else may pass
1307     return TRUE;
1308 }
1309
1310 #ifdef COMPAT_XON010_CHANNELS
1311 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1312 void sound(entity e, float chan, string samp, float vol, float atten)
1313 {
1314     if (!sound_allowed(MSG_BROADCAST, e))
1315         return;
1316     sound_builtin(e, chan, samp, vol, atten);
1317 }
1318 #else
1319 #undef sound
1320 void sound(entity e, float chan, string samp, float vol, float atten)
1321 {
1322     if (!sound_allowed(MSG_BROADCAST, e))
1323         return;
1324     sound7(e, chan, samp, vol, atten, 0, 0);
1325 }
1326 #endif
1327
1328 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1329 {
1330     float entno, idx;
1331
1332     if (!sound_allowed(dest, e))
1333         return;
1334
1335     entno = num_for_edict(e);
1336     idx = precache_sound_index(samp);
1337
1338     float sflags;
1339     sflags = 0;
1340
1341     atten = floor(atten * 64);
1342     vol = floor(vol * 255);
1343
1344     if (vol != 255)
1345         sflags |= SND_VOLUME;
1346     if (atten != 64)
1347         sflags |= SND_ATTENUATION;
1348     if (entno >= 8192 || chan < 0 || chan > 7)
1349         sflags |= SND_LARGEENTITY;
1350     if (idx >= 256)
1351         sflags |= SND_LARGESOUND;
1352
1353     WriteByte(dest, SVC_SOUND);
1354     WriteByte(dest, sflags);
1355     if (sflags & SND_VOLUME)
1356         WriteByte(dest, vol);
1357     if (sflags & SND_ATTENUATION)
1358         WriteByte(dest, atten);
1359     if (sflags & SND_LARGEENTITY)
1360     {
1361         WriteShort(dest, entno);
1362         WriteByte(dest, chan);
1363     }
1364     else
1365     {
1366         WriteShort(dest, entno * 8 + chan);
1367     }
1368     if (sflags & SND_LARGESOUND)
1369         WriteShort(dest, idx);
1370     else
1371         WriteByte(dest, idx);
1372
1373     WriteCoord(dest, o_x);
1374     WriteCoord(dest, o_y);
1375     WriteCoord(dest, o_z);
1376 }
1377 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1378 {
1379     vector o;
1380
1381     if (!sound_allowed(dest, e))
1382         return;
1383
1384     o = e.origin + 0.5 * (e.mins + e.maxs);
1385     soundtoat(dest, e, o, chan, samp, vol, atten);
1386 }
1387 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1388 {
1389     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1390 }
1391 void stopsoundto(float dest, entity e, float chan)
1392 {
1393     float entno;
1394
1395     if (!sound_allowed(dest, e))
1396         return;
1397
1398     entno = num_for_edict(e);
1399
1400     if (entno >= 8192 || chan < 0 || chan > 7)
1401     {
1402         float idx, sflags;
1403         idx = precache_sound_index("misc/null.wav");
1404         sflags = SND_LARGEENTITY;
1405         if (idx >= 256)
1406             sflags |= SND_LARGESOUND;
1407         WriteByte(dest, SVC_SOUND);
1408         WriteByte(dest, sflags);
1409         WriteShort(dest, entno);
1410         WriteByte(dest, chan);
1411         if (sflags & SND_LARGESOUND)
1412             WriteShort(dest, idx);
1413         else
1414             WriteByte(dest, idx);
1415         WriteCoord(dest, e.origin_x);
1416         WriteCoord(dest, e.origin_y);
1417         WriteCoord(dest, e.origin_z);
1418     }
1419     else
1420     {
1421         WriteByte(dest, SVC_STOPSOUND);
1422         WriteShort(dest, entno * 8 + chan);
1423     }
1424 }
1425 void stopsound(entity e, float chan)
1426 {
1427     if (!sound_allowed(MSG_BROADCAST, e))
1428         return;
1429
1430     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1431     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1432 }
1433
1434 void play2(entity e, string filename)
1435 {
1436     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1437     msg_entity = e;
1438     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1439 }
1440
1441 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1442 .float spamtime;
1443 float spamsound(entity e, float chan, string samp, float vol, float atten)
1444 {
1445     if (!sound_allowed(MSG_BROADCAST, e))
1446         return FALSE;
1447
1448     if (time > e.spamtime)
1449     {
1450         e.spamtime = time;
1451         sound(e, chan, samp, vol, atten);
1452         return TRUE;
1453     }
1454     return FALSE;
1455 }
1456
1457 void play2team(float t, string filename)
1458 {
1459     local entity head;
1460
1461     if (autocvar_bot_sound_monopoly)
1462         return;
1463
1464     FOR_EACH_REALPLAYER(head)
1465     {
1466         if (head.team == t)
1467             play2(head, filename);
1468     }
1469 }
1470
1471 void play2all(string samp)
1472 {
1473     if (autocvar_bot_sound_monopoly)
1474         return;
1475
1476     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1477 }
1478
1479 void PrecachePlayerSounds(string f);
1480 void precache_playermodel(string m)
1481 {
1482         float globhandle, i, n;
1483         string f;
1484
1485         if(substring(m, -9,5) == "_lod1")
1486                 return;
1487         if(substring(m, -9,5) == "_lod2")
1488                 return;
1489         precache_model(m);
1490         if(sv_loddistance1)
1491         {
1492                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1493                 if(fexists(f))
1494                         precache_model(f);
1495                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1496                 if(fexists(f))
1497                         precache_model(f);
1498         }
1499
1500         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1501         if (globhandle < 0)
1502                 return;
1503         n = search_getsize(globhandle);
1504         for (i = 0; i < n; ++i)
1505         {
1506                 //print(search_getfilename(globhandle, i), "\n");
1507                 f = search_getfilename(globhandle, i);
1508                 PrecachePlayerSounds(f);
1509         }
1510         search_end(globhandle);
1511 }
1512 void precache_all_playermodels(string pattern)
1513 {
1514         float globhandle, i, n;
1515         string f;
1516
1517         globhandle = search_begin(pattern, TRUE, FALSE);
1518         if (globhandle < 0)
1519                 return;
1520         n = search_getsize(globhandle);
1521         for (i = 0; i < n; ++i)
1522         {
1523                 //print(search_getfilename(globhandle, i), "\n");
1524                 f = search_getfilename(globhandle, i);
1525                 precache_playermodel(f);
1526         }
1527         search_end(globhandle);
1528 }
1529
1530 void precache()
1531 {
1532     // gamemode related things
1533     precache_model ("models/misc/chatbubble.spr");
1534     if (g_runematch)
1535     {
1536         precache_model ("models/runematch/curse.mdl");
1537         precache_model ("models/runematch/rune.mdl");
1538     }
1539
1540 #ifdef TTURRETS_ENABLED
1541     if (autocvar_g_turrets)
1542         turrets_precash();
1543 #endif
1544
1545     // Precache all player models if desired
1546     if (autocvar_sv_precacheplayermodels)
1547     {
1548         PrecachePlayerSounds("sound/player/default.sounds");
1549         precache_all_playermodels("models/player/*.zym");
1550         precache_all_playermodels("models/player/*.dpm");
1551         precache_all_playermodels("models/player/*.md3");
1552         precache_all_playermodels("models/player/*.psk");
1553         precache_all_playermodels("models/player/*.iqm");
1554     }
1555
1556     if (autocvar_sv_defaultcharacter)
1557     {
1558         string s;
1559         s = autocvar_sv_defaultplayermodel_red;
1560         if (s != "")
1561             precache_playermodel(s);
1562         s = autocvar_sv_defaultplayermodel_blue;
1563         if (s != "")
1564             precache_playermodel(s);
1565         s = autocvar_sv_defaultplayermodel_yellow;
1566         if (s != "")
1567             precache_playermodel(s);
1568         s = autocvar_sv_defaultplayermodel_pink;
1569         if (s != "")
1570             precache_playermodel(s);
1571         s = autocvar_sv_defaultplayermodel;
1572         if (s != "")
1573             precache_playermodel(s);
1574     }
1575
1576     if (g_footsteps)
1577     {
1578         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1579         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1580     }
1581
1582     // gore and miscellaneous sounds
1583     //precache_sound ("misc/h2ohit.wav");
1584     precache_model ("models/hook.md3");
1585     precache_sound ("misc/armorimpact.wav");
1586     precache_sound ("misc/bodyimpact1.wav");
1587     precache_sound ("misc/bodyimpact2.wav");
1588     precache_sound ("misc/gib.wav");
1589     precache_sound ("misc/gib_splat01.wav");
1590     precache_sound ("misc/gib_splat02.wav");
1591     precache_sound ("misc/gib_splat03.wav");
1592     precache_sound ("misc/gib_splat04.wav");
1593     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1594     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1595     precache_sound ("misc/null.wav");
1596     precache_sound ("misc/spawn.wav");
1597     precache_sound ("misc/talk.wav");
1598     precache_sound ("misc/teleport.wav");
1599     precache_sound ("misc/poweroff.wav");
1600     precache_sound ("player/lava.wav");
1601     precache_sound ("player/slime.wav");
1602
1603     if (g_jetpack)
1604         precache_sound ("misc/jetpack_fly.wav");
1605
1606     precache_model ("models/sprites/0.spr32");
1607     precache_model ("models/sprites/1.spr32");
1608     precache_model ("models/sprites/2.spr32");
1609     precache_model ("models/sprites/3.spr32");
1610     precache_model ("models/sprites/4.spr32");
1611     precache_model ("models/sprites/5.spr32");
1612     precache_model ("models/sprites/6.spr32");
1613     precache_model ("models/sprites/7.spr32");
1614     precache_model ("models/sprites/8.spr32");
1615     precache_model ("models/sprites/9.spr32");
1616     precache_model ("models/sprites/10.spr32");
1617
1618     // common weapon precaches
1619         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1620     precache_sound ("weapons/weapon_switch.wav");
1621     precache_sound ("weapons/weaponpickup.wav");
1622     precache_sound ("weapons/unavailable.wav");
1623     precache_sound ("weapons/dryfire.wav");
1624     if (g_grappling_hook)
1625     {
1626         precache_sound ("weapons/hook_fire.wav"); // hook
1627         precache_sound ("weapons/hook_impact.wav"); // hook
1628     }
1629
1630     if(autocvar_sv_precacheweapons)
1631     {
1632         //precache weapon models/sounds
1633         local float wep;
1634         wep = WEP_FIRST;
1635         while (wep <= WEP_LAST)
1636         {
1637             weapon_action(wep, WR_PRECACHE);
1638             wep = wep + 1;
1639         }
1640     }
1641
1642     precache_model("models/elaser.mdl");
1643     precache_model("models/laser.mdl");
1644     precache_model("models/ebomb.mdl");
1645
1646 #if 0
1647     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1648
1649     if (!self.noise && self.music) // quake 3 uses the music field
1650         self.noise = self.music;
1651
1652     // plays music for the level if there is any
1653     if (self.noise)
1654     {
1655         precache_sound (self.noise);
1656         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1657     }
1658 #endif
1659 }
1660
1661 // sorry, but using \ in macros breaks line numbers
1662 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1663 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1664 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1665
1666
1667 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1668 {
1669         if (clienttype(e) == CLIENTTYPE_REAL)
1670         {
1671                 msg_entity = e;
1672                 WRITESPECTATABLE_MSG_ONE({
1673                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1674                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1675                         WriteByte(MSG_ONE, id);
1676                         WriteString(MSG_ONE, s);
1677                         if (id != 0 && s != "")
1678                         {
1679                                 WriteByte(MSG_ONE, duration);
1680                                 WriteByte(MSG_ONE, countdown_num);
1681                         }
1682                 });
1683         }
1684 }
1685 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1686 {
1687         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1688 }
1689 // WARNING: this kills the trace globals
1690 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1691 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1692
1693 #define INITPRIO_FIRST              0
1694 #define INITPRIO_GAMETYPE           0
1695 #define INITPRIO_GAMETYPE_FALLBACK  1
1696 #define INITPRIO_FINDTARGET        10
1697 #define INITPRIO_DROPTOFLOOR       20
1698 #define INITPRIO_SETLOCATION       90
1699 #define INITPRIO_LINKDOORS         91
1700 #define INITPRIO_LAST              99
1701
1702 .void(void) initialize_entity;
1703 .float initialize_entity_order;
1704 .entity initialize_entity_next;
1705 entity initialize_entity_first;
1706
1707 void make_safe_for_remove(entity e)
1708 {
1709     if (e.initialize_entity)
1710     {
1711         entity ent, prev;
1712         for (ent = initialize_entity_first; ent; )
1713         {
1714             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1715             {
1716                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1717                 // skip it in linked list
1718                 if (prev)
1719                 {
1720                     prev.initialize_entity_next = ent.initialize_entity_next;
1721                     ent = prev.initialize_entity_next;
1722                 }
1723                 else
1724                 {
1725                     initialize_entity_first = ent.initialize_entity_next;
1726                     ent = initialize_entity_first;
1727                 }
1728             }
1729             else
1730             {
1731                 prev = ent;
1732                 ent = ent.initialize_entity_next;
1733             }
1734         }
1735     }
1736 }
1737
1738 void objerror(string s)
1739 {
1740     make_safe_for_remove(self);
1741     objerror_builtin(s);
1742 }
1743
1744 .float remove_except_protected_forbidden;
1745 void remove_except_protected(entity e)
1746 {
1747         if(e.remove_except_protected_forbidden)
1748                 error("not allowed to remove this at this point");
1749         remove_builtin(e);
1750 }
1751
1752 void remove_unsafely(entity e)
1753 {
1754     if(e.classname == "spike")
1755         error("Removing spikes is forbidden (crylink bug), please report");
1756     remove_builtin(e);
1757 }
1758
1759 void remove_safely(entity e)
1760 {
1761     make_safe_for_remove(e);
1762     remove_builtin(e);
1763 }
1764
1765 void InitializeEntity(entity e, void(void) func, float order)
1766 {
1767     entity prev, cur;
1768
1769     if (!e || e.initialize_entity)
1770     {
1771         // make a proxy initializer entity
1772         entity e_old;
1773         e_old = e;
1774         e = spawn();
1775         e.classname = "initialize_entity";
1776         e.enemy = e_old;
1777     }
1778
1779     e.initialize_entity = func;
1780     e.initialize_entity_order = order;
1781
1782     cur = initialize_entity_first;
1783     for (;;)
1784     {
1785         if (!cur || cur.initialize_entity_order > order)
1786         {
1787             // insert between prev and cur
1788             if (prev)
1789                 prev.initialize_entity_next = e;
1790             else
1791                 initialize_entity_first = e;
1792             e.initialize_entity_next = cur;
1793             return;
1794         }
1795         prev = cur;
1796         cur = cur.initialize_entity_next;
1797     }
1798 }
1799 void InitializeEntitiesRun()
1800 {
1801     entity startoflist;
1802     startoflist = initialize_entity_first;
1803     initialize_entity_first = world;
1804     remove = remove_except_protected;
1805     for (self = startoflist; self; self = self.initialize_entity_next)
1806     {
1807         self.remove_except_protected_forbidden = 1;
1808     }
1809     for (self = startoflist; self; )
1810     {
1811         entity e;
1812         var void(void) func;
1813         e = self.initialize_entity_next;
1814         func = self.initialize_entity;
1815         self.initialize_entity_order = 0;
1816         self.initialize_entity = func_null;
1817         self.initialize_entity_next = world;
1818         self.remove_except_protected_forbidden = 0;
1819         if (self.classname == "initialize_entity")
1820         {
1821             entity e_old;
1822             e_old = self.enemy;
1823             remove_builtin(self);
1824             self = e_old;
1825         }
1826         //dprint("Delayed initialization: ", self.classname, "\n");
1827         if(func != func_null)
1828             func();
1829         else
1830         {
1831             eprint(self);
1832             backtrace(strcat("Null function in: ", self.classname, "\n"));
1833         }
1834         self = e;
1835     }
1836     remove = remove_unsafely;
1837 }
1838
1839 .float uncustomizeentityforclient_set;
1840 .void(void) uncustomizeentityforclient;
1841 void(void) SUB_Nullpointer = #0;
1842 void UncustomizeEntitiesRun()
1843 {
1844     entity oldself;
1845     oldself = self;
1846     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1847         self.uncustomizeentityforclient();
1848     self = oldself;
1849 }
1850 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1851 {
1852     e.customizeentityforclient = customizer;
1853     e.uncustomizeentityforclient = uncustomizer;
1854     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1855 }
1856
1857 .float nottargeted;
1858 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1859
1860 void() SUB_Remove;
1861 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1862 {
1863     vector mi, ma;
1864
1865     if (e.classname == "")
1866         e.classname = "net_linked";
1867
1868     if (e.model == "" || self.modelindex == 0)
1869     {
1870         mi = e.mins;
1871         ma = e.maxs;
1872         setmodel(e, "null");
1873         setsize(e, mi, ma);
1874     }
1875
1876     e.SendEntity = sendfunc;
1877     e.SendFlags = 0xFFFFFF;
1878
1879     if (!docull)
1880         e.effects |= EF_NODEPTHTEST;
1881
1882     if (dt)
1883     {
1884         e.nextthink = time + dt;
1885         e.think = SUB_Remove;
1886     }
1887 }
1888
1889 void adaptor_think2touch()
1890 {
1891     entity o;
1892     o = other;
1893     other = world;
1894     self.touch();
1895     other = o;
1896 }
1897
1898 void adaptor_think2use()
1899 {
1900     entity o, a;
1901     o = other;
1902     a = activator;
1903     activator = world;
1904     other = world;
1905     self.use();
1906     other = o;
1907     activator = a;
1908 }
1909
1910 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1911 {
1912         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1913                 self.projectiledeathtype |= HITTYPE_SPLASH;
1914         adaptor_think2use();
1915 }
1916
1917 // deferred dropping
1918 void DropToFloor_Handler()
1919 {
1920     droptofloor_builtin();
1921     self.dropped_origin = self.origin;
1922 }
1923
1924 void droptofloor()
1925 {
1926     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1927 }
1928
1929
1930
1931 float trace_hits_box_a0, trace_hits_box_a1;
1932
1933 float trace_hits_box_1d(float end, float thmi, float thma)
1934 {
1935     if (end == 0)
1936     {
1937         // just check if x is in range
1938         if (0 < thmi)
1939             return FALSE;
1940         if (0 > thma)
1941             return FALSE;
1942     }
1943     else
1944     {
1945         // do the trace with respect to x
1946         // 0 -> end has to stay in thmi -> thma
1947         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1948         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1949         if (trace_hits_box_a0 > trace_hits_box_a1)
1950             return FALSE;
1951     }
1952     return TRUE;
1953 }
1954
1955 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1956 {
1957     end -= start;
1958     thmi -= start;
1959     thma -= start;
1960     // now it is a trace from 0 to end
1961
1962     trace_hits_box_a0 = 0;
1963     trace_hits_box_a1 = 1;
1964
1965     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1966         return FALSE;
1967     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1968         return FALSE;
1969     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1970         return FALSE;
1971
1972     return TRUE;
1973 }
1974
1975 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1976 {
1977     return trace_hits_box(start, end, thmi - ma, thma - mi);
1978 }
1979
1980 float SUB_NoImpactCheck()
1981 {
1982         // zero hitcontents = this is not the real impact, but either the
1983         // mirror-impact of something hitting the projectile instead of the
1984         // projectile hitting the something, or a touchareagrid one. Neither of
1985         // these stop the projectile from moving, so...
1986         if(trace_dphitcontents == 0)
1987         {
1988                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1989                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1990                 checkclient();
1991         }
1992     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1993         return 1;
1994     if (other == world && self.size != '0 0 0')
1995     {
1996         vector tic;
1997         tic = self.velocity * sys_frametime;
1998         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1999         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2000         if (trace_fraction >= 1)
2001         {
2002             dprint("Odd... did not hit...?\n");
2003         }
2004         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2005         {
2006             dprint("Detected and prevented the sky-grapple bug.\n");
2007             return 1;
2008         }
2009     }
2010
2011     return 0;
2012 }
2013
2014 #define SUB_OwnerCheck() (other && (other == self.owner))
2015
2016 void RemoveGrapplingHook(entity pl);
2017 void W_Crylink_Dequeue(entity e);
2018 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2019 {
2020         if(SUB_OwnerCheck())
2021                 return TRUE;
2022         if(SUB_NoImpactCheck())
2023         {
2024                 if(self.classname == "grapplinghook")
2025                         RemoveGrapplingHook(self.realowner);
2026                 else if(self.classname == "spike")
2027                 {
2028                         W_Crylink_Dequeue(self);
2029                         remove(self);
2030                 }
2031                 else
2032                         remove(self);
2033                 return TRUE;
2034         }
2035         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2036                 UpdateCSQCProjectile(self);
2037         return FALSE;
2038 }
2039 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2040
2041 float MAX_IPBAN_URIS           = 16;
2042
2043 float URI_GET_DISCARD          = 0;
2044 float URI_GET_IPBAN            = 1;
2045 float URI_GET_IPBAN_END        = 16;
2046
2047 void URI_Get_Callback(float id, float status, string data)
2048 {
2049     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2050     dprint(data);
2051     dprint("\nEnd of data.\n");
2052
2053     if(url_URI_Get_Callback(id, status, data))
2054     {
2055         // handled
2056     }
2057     else if (id == URI_GET_DISCARD)
2058     {
2059         // discard
2060     }
2061     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2062     {
2063         // online ban list
2064         OnlineBanList_URI_Get_Callback(id, status, data);
2065     }
2066     else
2067     {
2068         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2069     }
2070 }
2071
2072 void print_to(entity e, string s)
2073 {
2074     if (e)
2075         sprint(e, strcat(s, "\n"));
2076     else
2077         print(s, "\n");
2078 }
2079
2080 string uid2name(string myuid) {
2081         string s;
2082         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2083
2084         if(s == "")
2085                 s = "^1Unregistered Player";
2086         return s;
2087 }
2088
2089 float race_readTime(string map, float pos)
2090 {
2091         string rr;
2092         if(g_cts)
2093                 rr = CTS_RECORD;
2094         else
2095                 rr = RACE_RECORD;
2096
2097         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2098 }
2099
2100 string race_readUID(string map, float pos)
2101 {
2102         string rr;
2103         if(g_cts)
2104                 rr = CTS_RECORD;
2105         else
2106                 rr = RACE_RECORD;
2107
2108         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2109 }
2110
2111 float race_readPos(string map, float t) {
2112         float i;
2113         for (i = 1; i <= RANKINGS_CNT; ++i)
2114                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2115                         return i;
2116
2117         return 0; // pos is zero if unranked
2118 }
2119
2120 void race_writeTime(string map, float t, string myuid)
2121 {
2122         string rr;
2123         if(g_cts)
2124                 rr = CTS_RECORD;
2125         else
2126                 rr = RACE_RECORD;
2127
2128         float newpos;
2129         newpos = race_readPos(map, t);
2130
2131         float i, prevpos;
2132         for(i = 1; i <= RANKINGS_CNT; ++i)
2133         {
2134                 if(race_readUID(map, i) == myuid)
2135                         prevpos = i;
2136         }
2137         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2138                 for (i = prevpos; i > newpos; --i) {
2139                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2140                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2141                 }
2142         } else { // player has no ranked record yet
2143                 for (i = RANKINGS_CNT; i > newpos; --i) {
2144                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2145                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2146                 }
2147         }
2148
2149         // store new time itself
2150         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2151         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2152 }
2153
2154 string race_readName(string map, float pos)
2155 {
2156         string rr;
2157         if(g_cts)
2158                 rr = CTS_RECORD;
2159         else
2160                 rr = RACE_RECORD;
2161
2162         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2163 }
2164
2165 string race_placeName(float pos) {
2166         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2167         {
2168                 if(mod(pos, 10) == 1)
2169                         return strcat(ftos(pos), "st");
2170                 else if(mod(pos, 10) == 2)
2171                         return strcat(ftos(pos), "nd");
2172                 else if(mod(pos, 10) == 3)
2173                         return strcat(ftos(pos), "rd");
2174                 else
2175                         return strcat(ftos(pos), "th");
2176         }
2177         else
2178                 return strcat(ftos(pos), "th");
2179 }
2180 string getrecords(float page) // 50 records per page
2181 {
2182     float rec;
2183     string h;
2184     float r;
2185     float i;
2186     string s;
2187
2188     rec = 0;
2189
2190     s = "";
2191
2192     if (g_ctf)
2193     {
2194         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2195         {
2196             if (MapInfo_Get_ByID(i))
2197             {
2198                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2199                 if (r == 0)
2200                     continue;
2201                 // TODO: uid2name
2202                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2203                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2204                 ++rec;
2205             }
2206         }
2207     }
2208
2209     if (g_race)
2210     {
2211         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2212         {
2213             if (MapInfo_Get_ByID(i))
2214             {
2215                 r = race_readTime(MapInfo_Map_bspname, 1);
2216                 if (r == 0)
2217                     continue;
2218                 h = race_readName(MapInfo_Map_bspname, 1);
2219                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2220                 ++rec;
2221             }
2222         }
2223     }
2224
2225     if (g_cts)
2226     {
2227         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2228         {
2229             if (MapInfo_Get_ByID(i))
2230             {
2231                 r = race_readTime(MapInfo_Map_bspname, 1);
2232                 if (r == 0)
2233                     continue;
2234                 h = race_readName(MapInfo_Map_bspname, 1);
2235                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2236                 ++rec;
2237             }
2238         }
2239     }
2240
2241     MapInfo_ClearTemps();
2242
2243     if (s == "" && page == 0)
2244         return "No records are available on this server.\n";
2245     else
2246         return s;
2247 }
2248
2249 string getrankings()
2250 {
2251     string n;
2252     float t;
2253     float i;
2254     string s;
2255     string p;
2256     string map;
2257
2258     s = "";
2259
2260     map = GetMapname();
2261
2262     for (i = 1; i <= RANKINGS_CNT; ++i)
2263     {
2264         t = race_readTime(map, i);
2265         if (t == 0)
2266             continue;
2267         n = race_readName(map, i);
2268         p = race_placeName(i);
2269         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2270     }
2271
2272     MapInfo_ClearTemps();
2273
2274     if (s == "")
2275         return strcat("No records are available for the map: ", map, "\n");
2276     else
2277         return strcat("Records for ", map, ":\n", s);
2278 }
2279
2280 #define LADDER_FIRSTPOINT 100
2281 #define LADDER_CNT 10
2282         // position X still gives LADDER_FIRSTPOINT/X points
2283 #define LADDER_SIZE 30
2284         // ladder shows the top X players
2285 string top_uids[LADDER_SIZE];
2286 float top_scores[LADDER_SIZE];
2287 string getladder()
2288 {
2289     float i, j, k, uidcnt;
2290     string s, temp_s;
2291
2292     s = "";
2293     temp_s = "";
2294
2295     string rr;
2296     if(g_cts)
2297         rr = CTS_RECORD;
2298     else
2299         rr = RACE_RECORD;
2300
2301     string myuid;
2302
2303     for (k = 0; k < MapInfo_count; ++k)
2304     {
2305         if (MapInfo_Get_ByID(k))
2306         {
2307                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2308                         if(i == 0) // speed award
2309                         {
2310                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2311                                         continue;
2312
2313                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2314                         }
2315                         else // normal record, if it exists (else break)
2316                         {
2317                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2318                                         continue;
2319
2320                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2321                         }
2322
2323                         // string s contains:
2324                         // arg 0 = # of speed recs
2325                         // arg 1 = # of 1st place recs
2326                         // arg 2 = # of 2nd place recs
2327                         // ... etc
2328                         // LADDER_CNT+1 = total points
2329
2330                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2331                         if (temp_s == "")
2332                         {
2333                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2334                             ++uidcnt;
2335                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2336                             {
2337                                 if(j != LADDER_CNT + 1)
2338                                     temp_s = strcat(temp_s, "0 ");
2339                                 else
2340                                     temp_s = strcat(temp_s, "0");
2341                             }
2342                         }
2343
2344                         tokenize_console(temp_s);
2345                         s = "";
2346
2347                         if(i == 0) // speed award
2348                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2349                             {
2350                                 if(j == 0) // speed award
2351                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2352                                 else
2353                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2354                             }
2355                         else // record
2356                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2357                             {
2358                                 if(j == 0)
2359                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2360                                 else if(j == i) // wanted rec!
2361                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2362                                 else
2363                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2364                             }
2365
2366                         // total points are (by default) calculated like this:
2367                         // speedrec = floor(100 / 10) = 10 points
2368                         // 1st place = floor(100 / 1) = 100 points
2369                         // 2nd place = floor(100 / 2) = 50 points
2370                         // 3rd place = floor(100 / 3) = 33 points
2371                         // 4th place = floor(100 / 4) = 25 points
2372                         // 5th place = floor(100 / 5) = 20 points
2373                         // ... etc
2374
2375                         if(i == 0)
2376                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2377                         else
2378                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2379
2380                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2381                 }
2382         }
2383     }
2384
2385     float thiscnt;
2386     string thisuid;
2387     for (i = 0; i <= uidcnt; ++i) // for each known uid
2388     {
2389         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2390         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2391         tokenize_console(temp_s);
2392         thiscnt = stof(argv(LADDER_CNT+1));
2393
2394         if(thiscnt > top_scores[LADDER_SIZE-1])
2395         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2396         {
2397             if(thiscnt > top_scores[j])
2398             {
2399                 for (k = LADDER_SIZE-1; k >= j; --k)
2400                 {
2401                     top_uids[k] = top_uids[k-1];
2402                     top_scores[k] = top_scores[k-1];
2403                 }
2404                 top_uids[j] = thisuid;
2405                 top_scores[j] = thiscnt;
2406                 break;
2407             }
2408         }
2409     }
2410
2411     s = "^3-----------------------\n\n";
2412
2413     s = strcat(s, "Pos ^3|");
2414     s = strcat(s, " ^7Total  ^3|");
2415     for (i = 1; i <= LADDER_CNT; ++i)
2416     {
2417         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2418     }
2419     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2420
2421     s = strcat(s, "\n^3----+--------");
2422     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2423     {
2424         s = strcat(s, "+-----");
2425     }
2426 #if LADDER_CNT > 9
2427     for (i = 1; i <= LADDER_CNT - 9; ++i)
2428     {
2429         s = strcat(s, "+------");
2430     }
2431 #endif
2432
2433     s = strcat(s, "+--------------+--------------------\n");
2434
2435     for (i = 0; i < LADDER_SIZE; ++i)
2436     {
2437         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2438         tokenize_console(temp_s);
2439         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2440             continue;
2441         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2442         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2443         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2444         {
2445             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2446         }
2447 #if LADDER_CNT > 9
2448         for (j = 10; j <= LADDER_CNT; ++j)
2449         {
2450             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2451         }
2452 #endif
2453
2454         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2455         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2456     }
2457
2458     MapInfo_ClearTemps();
2459
2460     if (s == "")
2461         return "No ladder on this server!\n";
2462     else
2463         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2464 }
2465
2466
2467 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2468 {
2469     float m, i;
2470     vector start, org, delta, end, enddown, mstart;
2471     entity sp;
2472
2473     m = e.dphitcontentsmask;
2474     e.dphitcontentsmask = goodcontents | badcontents;
2475
2476     org = world.mins;
2477     delta = world.maxs - world.mins;
2478
2479     for (i = 0; i < attempts; ++i)
2480     {
2481         start_x = org_x + random() * delta_x;
2482         start_y = org_y + random() * delta_y;
2483         start_z = org_z + random() * delta_z;
2484
2485         // rule 1: start inside world bounds, and outside
2486         // solid, and don't start from somewhere where you can
2487         // fall down to evil
2488         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2489         if (trace_fraction >= 1)
2490             continue;
2491         if (trace_startsolid)
2492             continue;
2493         if (trace_dphitcontents & badcontents)
2494             continue;
2495         if (trace_dphitq3surfaceflags & badsurfaceflags)
2496             continue;
2497
2498         // rule 2: if we are too high, lower the point
2499         if (trace_fraction * delta_z > maxaboveground)
2500             start = trace_endpos + '0 0 1' * maxaboveground;
2501         enddown = trace_endpos;
2502
2503         // rule 3: make sure we aren't outside the map. This only works
2504         // for somewhat well formed maps. A good rule of thumb is that
2505         // the map should have a convex outside hull.
2506         // these can be traceLINES as we already verified the starting box
2507         mstart = start + 0.5 * (e.mins + e.maxs);
2508         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2509         if (trace_fraction >= 1)
2510             continue;
2511         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2512         if (trace_fraction >= 1)
2513             continue;
2514         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523
2524         // rule 4: we must "see" some spawnpoint
2525         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2526                 if(checkpvs(mstart, sp))
2527                         break;
2528         if(!sp)
2529         {
2530                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2531                         if(checkpvs(mstart, sp))
2532                                 break;
2533                 if(!sp)
2534                         continue;
2535         }
2536
2537         // find a random vector to "look at"
2538         end_x = org_x + random() * delta_x;
2539         end_y = org_y + random() * delta_y;
2540         end_z = org_z + random() * delta_z;
2541         end = start + normalize(end - start) * vlen(delta);
2542
2543         // rule 4: start TO end must not be too short
2544         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2545         if (trace_startsolid)
2546             continue;
2547         if (trace_fraction < minviewdistance / vlen(delta))
2548             continue;
2549
2550         // rule 5: don't want to look at sky
2551         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2552             continue;
2553
2554         // rule 6: we must not end up in trigger_hurt
2555         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2556             continue;
2557
2558         break;
2559     }
2560
2561     e.dphitcontentsmask = m;
2562
2563     if (i < attempts)
2564     {
2565         setorigin(e, start);
2566         e.angles = vectoangles(end - start);
2567         dprint("Needed ", ftos(i + 1), " attempts\n");
2568         return TRUE;
2569     }
2570     else
2571         return FALSE;
2572 }
2573
2574 float zcurveparticles_effectno;
2575 vector zcurveparticles_start;
2576 float zcurveparticles_spd;
2577
2578 void endzcurveparticles()
2579 {
2580         if(zcurveparticles_effectno)
2581         {
2582                 // terminator
2583                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2584         }
2585         zcurveparticles_effectno = 0;
2586 }
2587
2588 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2589 {
2590         spd = bound(0, floor(spd / 16), 32767);
2591         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2592         {
2593                 endzcurveparticles();
2594                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2595                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2596                 WriteShort(MSG_BROADCAST, effectno);
2597                 WriteCoord(MSG_BROADCAST, start_x);
2598                 WriteCoord(MSG_BROADCAST, start_y);
2599                 WriteCoord(MSG_BROADCAST, start_z);
2600                 zcurveparticles_effectno = effectno;
2601                 zcurveparticles_start = start;
2602         }
2603         else
2604                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2605         WriteCoord(MSG_BROADCAST, end_x);
2606         WriteCoord(MSG_BROADCAST, end_y);
2607         WriteCoord(MSG_BROADCAST, end_z);
2608         WriteCoord(MSG_BROADCAST, end_dz);
2609         zcurveparticles_spd = spd;
2610 }
2611
2612 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2613 {
2614         float end_dz;
2615         vector vecxy, velxy;
2616
2617         vecxy = end - start;
2618         vecxy_z = 0;
2619         velxy = vel;
2620         velxy_z = 0;
2621
2622         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2623         {
2624                 endzcurveparticles();
2625                 trailparticles(world, effectno, start, end);
2626                 return;
2627         }
2628
2629         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2630         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2631 }
2632
2633 void write_recordmarker(entity pl, float tstart, float dt)
2634 {
2635     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2636
2637     // also write a marker into demo files for demotc-race-record-extractor to find
2638     stuffcmd(pl,
2639              strcat(
2640                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2641                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2642 }
2643
2644 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2645 {
2646         switch(algn)
2647         {
2648                 default:
2649                 case 3: // right
2650                         break;
2651
2652                 case 4: // left
2653                         vecs_y = -vecs_y;
2654                         break;
2655
2656                 case 1:
2657                         if(allowcenter) // 2: allow center handedness
2658                         {
2659                                 // center
2660                                 vecs_y = 0;
2661                                 vecs_z -= 2;
2662                         }
2663                         else
2664                         {
2665                                 // right
2666                         }
2667                         break;
2668
2669                 case 2:
2670                         if(allowcenter) // 2: allow center handedness
2671                         {
2672                                 // center
2673                                 vecs_y = 0;
2674                                 vecs_z -= 2;
2675                         }
2676                         else
2677                         {
2678                                 // left
2679                                 vecs_y = -vecs_y;
2680                         }
2681                         break;
2682         }
2683         return vecs;
2684 }
2685
2686 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2687 {
2688         string s;
2689         vector v;
2690
2691         if (autocvar_g_shootfromeye)
2692         {
2693                 if (visual)
2694                 {
2695                         vecs_y = 0;
2696                         vecs_z -= 2;
2697                 }
2698                 else
2699                 {
2700                         vecs_y = 0;
2701                         vecs_z = 0;
2702                 }
2703         }
2704         else if (autocvar_g_shootfromcenter)
2705         {
2706                 vecs_y = 0;
2707                 vecs_z -= 2;
2708         }
2709         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2710         {
2711                 v = stov(s);
2712                 if (y_is_right)
2713                         v_y = -v_y;
2714                 if (v_x != 0)
2715                         vecs_x = v_x;
2716                 vecs_y = v_y;
2717                 vecs_z = v_z;
2718         }
2719         else if (autocvar_g_shootfromclient)
2720         {
2721                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2722         }
2723         return vecs;
2724 }
2725
2726 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2727 {
2728         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2729 }
2730
2731
2732 void attach_sameorigin(entity e, entity to, string tag)
2733 {
2734     vector org, t_forward, t_left, t_up, e_forward, e_up;
2735     vector org0, ang0;
2736     float tagscale;
2737
2738     ang0 = e.angles;
2739     org0 = e.origin;
2740
2741     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2742     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2743     t_forward = v_forward * tagscale;
2744     t_left = v_right * -tagscale;
2745     t_up = v_up * tagscale;
2746
2747     e.origin_x = org * t_forward;
2748     e.origin_y = org * t_left;
2749     e.origin_z = org * t_up;
2750
2751     // current forward and up directions
2752     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2753                 e.angles = AnglesTransform_FromVAngles(e.angles);
2754         else
2755                 e.angles = AnglesTransform_FromAngles(e.angles);
2756     fixedmakevectors(e.angles);
2757
2758     // untransform forward, up!
2759     e_forward_x = v_forward * t_forward;
2760     e_forward_y = v_forward * t_left;
2761     e_forward_z = v_forward * t_up;
2762     e_up_x = v_up * t_forward;
2763     e_up_y = v_up * t_left;
2764     e_up_z = v_up * t_up;
2765
2766     e.angles = fixedvectoangles2(e_forward, e_up);
2767     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2768                 e.angles = AnglesTransform_ToVAngles(e.angles);
2769         else
2770                 e.angles = AnglesTransform_ToAngles(e.angles);
2771
2772     setattachment(e, to, tag);
2773     setorigin(e, e.origin);
2774 }
2775
2776 void detach_sameorigin(entity e)
2777 {
2778     vector org;
2779     org = gettaginfo(e, 0);
2780     e.angles = fixedvectoangles2(v_forward, v_up);
2781     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2782                 e.angles = AnglesTransform_ToVAngles(e.angles);
2783         else
2784                 e.angles = AnglesTransform_ToAngles(e.angles);
2785     setorigin(e, org);
2786     setattachment(e, world, "");
2787     setorigin(e, e.origin);
2788 }
2789
2790 void follow_sameorigin(entity e, entity to)
2791 {
2792     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2793     e.aiment = to; // make the hole follow bmodel
2794     e.punchangle = to.angles; // the original angles of bmodel
2795     e.view_ofs = e.origin - to.origin; // relative origin
2796     e.v_angle = e.angles - to.angles; // relative angles
2797 }
2798
2799 void unfollow_sameorigin(entity e)
2800 {
2801     e.movetype = MOVETYPE_NONE;
2802 }
2803
2804 entity gettaginfo_relative_ent;
2805 vector gettaginfo_relative(entity e, float tag)
2806 {
2807     if (!gettaginfo_relative_ent)
2808     {
2809         gettaginfo_relative_ent = spawn();
2810         gettaginfo_relative_ent.effects = EF_NODRAW;
2811     }
2812     gettaginfo_relative_ent.model = e.model;
2813     gettaginfo_relative_ent.modelindex = e.modelindex;
2814     gettaginfo_relative_ent.frame = e.frame;
2815     return gettaginfo(gettaginfo_relative_ent, tag);
2816 }
2817
2818 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2819 {
2820     float p;
2821     p = pow(2, chan);
2822     if (pl.soundentity.cnt & p)
2823         return;
2824     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2825     pl.soundentity.cnt |= p;
2826 }
2827
2828 void SoundEntity_StopSound(entity pl, float chan)
2829 {
2830     float p;
2831     p = pow(2, chan);
2832     if (pl.soundentity.cnt & p)
2833     {
2834         stopsoundto(MSG_ALL, pl.soundentity, chan);
2835         pl.soundentity.cnt &~= p;
2836     }
2837 }
2838
2839 void SoundEntity_Attach(entity pl)
2840 {
2841     pl.soundentity = spawn();
2842     pl.soundentity.classname = "soundentity";
2843     pl.soundentity.owner = pl;
2844     setattachment(pl.soundentity, pl, "");
2845     setmodel(pl.soundentity, "null");
2846 }
2847
2848 void SoundEntity_Detach(entity pl)
2849 {
2850     float i;
2851     for (i = 0; i <= 7; ++i)
2852         SoundEntity_StopSound(pl, i);
2853 }
2854
2855
2856 float ParseCommandPlayerSlotTarget_firsttoken;
2857 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2858 {
2859         string s;
2860         entity e, head;
2861         float n;
2862
2863         s = string_null;
2864
2865         ParseCommandPlayerSlotTarget_firsttoken = -1;
2866
2867         if (tokens > idx)
2868         {
2869                 if (substring(argv(idx), 0, 1) == "#")
2870                 {
2871                         s = substring(argv(idx), 1, -1);
2872                         ++idx;
2873                         if (s == "") if (tokens > idx)
2874                         {
2875                                 s = argv(idx);
2876                                 ++idx;
2877                         }
2878                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2879                         n = stof(s);
2880                         if (s == ftos(n) && n > 0 && n <= maxclients)
2881                         {
2882                                 e = edict_num(n);
2883                                 if (e.flags & FL_CLIENT)
2884                                         return e;
2885                         }
2886                 }
2887                 else
2888                 {
2889                         // it must be a nick name
2890                         s = argv(idx);
2891                         ++idx;
2892                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2893
2894                         n = 0;
2895                         FOR_EACH_CLIENT(head)
2896                                 if (head.netname == s)
2897                                 {
2898                                         e = head;
2899                                         ++n;
2900                                 }
2901                         if (n == 1)
2902                                 return e;
2903
2904                         s = strdecolorize(s);
2905                         n = 0;
2906                         FOR_EACH_CLIENT(head)
2907                                 if (strdecolorize(head.netname) == s)
2908                                 {
2909                                         e = head;
2910                                         ++n;
2911                                 }
2912                         if (n == 1)
2913                                 return e;
2914                 }
2915         }
2916
2917         return world;
2918 }
2919
2920 .float scale2;
2921
2922 float modeleffect_SendEntity(entity to, float sf)
2923 {
2924         float f;
2925         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2926
2927         f = 0;
2928         if(self.velocity != '0 0 0')
2929                 f |= 1;
2930         if(self.angles != '0 0 0')
2931                 f |= 2;
2932         if(self.avelocity != '0 0 0')
2933                 f |= 4;
2934
2935         WriteByte(MSG_ENTITY, f);
2936         WriteShort(MSG_ENTITY, self.modelindex);
2937         WriteByte(MSG_ENTITY, self.skin);
2938         WriteByte(MSG_ENTITY, self.frame);
2939         WriteCoord(MSG_ENTITY, self.origin_x);
2940         WriteCoord(MSG_ENTITY, self.origin_y);
2941         WriteCoord(MSG_ENTITY, self.origin_z);
2942         if(f & 1)
2943         {
2944                 WriteCoord(MSG_ENTITY, self.velocity_x);
2945                 WriteCoord(MSG_ENTITY, self.velocity_y);
2946                 WriteCoord(MSG_ENTITY, self.velocity_z);
2947         }
2948         if(f & 2)
2949         {
2950                 WriteCoord(MSG_ENTITY, self.angles_x);
2951                 WriteCoord(MSG_ENTITY, self.angles_y);
2952                 WriteCoord(MSG_ENTITY, self.angles_z);
2953         }
2954         if(f & 4)
2955         {
2956                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2957                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2958                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2959         }
2960         WriteShort(MSG_ENTITY, self.scale * 256.0);
2961         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2962         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2963         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2964         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2965
2966         return TRUE;
2967 }
2968
2969 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2970 {
2971         entity e;
2972         float sz;
2973         e = spawn();
2974         e.classname = "modeleffect";
2975         setmodel(e, m);
2976         e.frame = f;
2977         setorigin(e, o);
2978         e.velocity = v;
2979         e.angles = ang;
2980         e.avelocity = angv;
2981         e.alpha = a;
2982         e.teleport_time = t1;
2983         e.fade_time = t2;
2984         e.skin = s;
2985         if(s0 >= 0)
2986                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2987         else
2988                 e.scale = -s0;
2989         if(s2 >= 0)
2990                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2991         else
2992                 e.scale2 = -s2;
2993         sz = max(e.scale, e.scale2);
2994         setsize(e, e.mins * sz, e.maxs * sz);
2995         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2996 }
2997
2998 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2999 {
3000         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3001 }
3002
3003 float randombit(float bits)
3004 {
3005         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3006                 return bits;
3007
3008         float n, f, b, r;
3009
3010         r = random();
3011         b = 0;
3012         n = 0;
3013
3014         for(f = 1; f <= bits; f *= 2)
3015         {
3016                 if(bits & f)
3017                 {
3018                         ++n;
3019                         r *= n;
3020                         if(r <= 1)
3021                                 b = f;
3022                         else
3023                                 r = (r - 1) / (n - 1);
3024                 }
3025         }
3026
3027         return b;
3028 }
3029
3030 float randombits(float bits, float k, float error_return)
3031 {
3032         float r;
3033         r = 0;
3034         while(k > 0 && bits != r)
3035         {
3036                 r += randombit(bits - r);
3037                 --k;
3038         }
3039         if(error_return)
3040                 if(k > 0)
3041                         return -1; // all
3042         return r;
3043 }
3044
3045 void randombit_test(float bits, float iter)
3046 {
3047         while(iter > 0)
3048         {
3049                 print(ftos(randombit(bits)), "\n");
3050                 --iter;
3051         }
3052 }
3053
3054 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3055 {
3056         if(halflifedist > 0)
3057                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3058         else if(halflifedist < 0)
3059                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3060         else
3061                 return 1;
3062 }
3063
3064
3065
3066
3067 #ifdef RELEASE
3068 #define cvar_string_normal cvar_string_builtin
3069 #define cvar_normal cvar_builtin
3070 #else
3071 string cvar_string_normal(string n)
3072 {
3073         if not(cvar_type(n) & 1)
3074                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3075         return cvar_string_builtin(n);
3076 }
3077
3078 float cvar_normal(string n)
3079 {
3080         return stof(cvar_string_normal(n));
3081 }
3082 #endif
3083 #define cvar_set_normal cvar_set_builtin
3084
3085 void defer_think()
3086 {
3087     entity oself;
3088
3089     oself           = self;
3090     self            = self.owner;
3091     oself.think     = SUB_Remove;
3092     oself.nextthink = time;
3093
3094     oself.use();
3095 }
3096
3097 /*
3098     Execute func() after time + fdelay.
3099     self when func is executed = self when defer is called
3100 */
3101 void defer(float fdelay, void() func)
3102 {
3103     entity e;
3104
3105     e           = spawn();
3106     e.owner     = self;
3107     e.use       = func;
3108     e.think     = defer_think;
3109     e.nextthink = time + fdelay;
3110 }
3111
3112 .string aiment_classname;
3113 .float aiment_deadflag;
3114 void SetMovetypeFollow(entity ent, entity e)
3115 {
3116         // FIXME this may not be warpzone aware
3117         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3118         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3119         ent.aiment = e; // make the hole follow bmodel
3120         ent.punchangle = e.angles; // the original angles of bmodel
3121         ent.view_ofs = ent.origin - e.origin; // relative origin
3122         ent.v_angle = ent.angles - e.angles; // relative angles
3123         ent.aiment_classname = strzone(e.classname);
3124         ent.aiment_deadflag = e.deadflag;
3125 }
3126 void UnsetMovetypeFollow(entity ent)
3127 {
3128         ent.movetype = MOVETYPE_FLY;
3129         PROJECTILE_MAKETRIGGER(ent);
3130         ent.aiment = world;
3131 }
3132 float LostMovetypeFollow(entity ent)
3133 {
3134 /*
3135         if(ent.movetype != MOVETYPE_FOLLOW)
3136                 if(ent.aiment)
3137                         error("???");
3138 */
3139         if(ent.aiment)
3140         {
3141                 if(ent.aiment.classname != ent.aiment_classname)
3142                         return 1;
3143                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3144                         return 1;
3145         }
3146         return 0;
3147 }
3148
3149 float isPushable(entity e)
3150 {
3151         if(e.iscreature)
3152                 return TRUE;
3153         switch(e.classname)
3154         {
3155                 case "body":
3156                 case "droppedweapon":
3157                 case "keepawayball":
3158                 case "nexball_basketball":
3159                 case "nexball_football":
3160                         return TRUE;
3161                 case "bullet": // antilagged bullets can't hit this either
3162                         return FALSE;
3163         }
3164         if (e.projectiledeathtype)
3165                 return TRUE;
3166         return FALSE;
3167 }