qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 620
 621         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 622         if (f > 0)
 623         {
 624                 if (s == "cl_weaponpriority")
 625                         self.switchweapon = w_getbestweapon(self);
 626         }
 627 }
 628
 629 float fexists(string f)
 630 {
 631     float fh;
 632     fh = fopen(f, FILE_READ);
 633     if (fh < 0)
 634         return FALSE;
 635     fclose(fh);
 636     return TRUE;
 637 }
 638
 639 void backtrace(string msg)
 640 {
 641     float dev, war;
 642     dev = autocvar_developer;
 643     war = autocvar_prvm_backtraceforwarnings;
 644     cvar_set("developer", "1");
 645     cvar_set("prvm_backtraceforwarnings", "1");
 646     print("\n");
 647     print("--- CUT HERE ---\nWARNING: ");
 648     print(msg);
 649     print("\n");
 650     remove(world); // isn't there any better way to cause a backtrace?
 651     print("\n--- CUT UNTIL HERE ---\n");
 652     cvar_set("developer", ftos(dev));
 653     cvar_set("prvm_backtraceforwarnings", ftos(war));
 654 }
 655
 656 string Team_ColorCode(float teamid)
 657 {
 658     if (teamid == COLOR_TEAM1)
 659         return "^1";
 660     else if (teamid == COLOR_TEAM2)
 661         return "^4";
 662     else if (teamid == COLOR_TEAM3)
 663         return "^3";
 664     else if (teamid == COLOR_TEAM4)
 665         return "^6";
 666     else
 667         return "^7";
 668 }
 669
 670 string Team_ColorName(float t)
 671 {
 672     // fixme: Search for team entities and get their .netname's!
 673     if (t == COLOR_TEAM1)
 674         return "Red";
 675     if (t == COLOR_TEAM2)
 676         return "Blue";
 677     if (t == COLOR_TEAM3)
 678         return "Yellow";
 679     if (t == COLOR_TEAM4)
 680         return "Pink";
 681     return "Neutral";
 682 }
 683
 684 string Team_ColorNameLowerCase(float t)
 685 {
 686     // fixme: Search for team entities and get their .netname's!
 687     if (t == COLOR_TEAM1)
 688         return "red";
 689     if (t == COLOR_TEAM2)
 690         return "blue";
 691     if (t == COLOR_TEAM3)
 692         return "yellow";
 693     if (t == COLOR_TEAM4)
 694         return "pink";
 695     return "neutral";
 696 }
 697
 698 float ColourToNumber(string team_colour)
 699 {
 700         if (team_colour == "red")
 701                 return COLOR_TEAM1;
 702
 703         if (team_colour == "blue")
 704                 return COLOR_TEAM2;
 705
 706         if (team_colour == "yellow")
 707                 return COLOR_TEAM3;
 708
 709         if (team_colour == "pink")
 710                 return COLOR_TEAM4;
 711
 712         if (team_colour == "auto")
 713                 return 0;
 714
 715         return -1;
 716 }
 717
 718 float NumberToTeamNumber(float number)
 719 {
 720         if (number == 1)
 721                 return COLOR_TEAM1;
 722
 723         if (number == 2)
 724                 return COLOR_TEAM2;
 725
 726         if (number == 3)
 727                 return COLOR_TEAM3;
 728
 729         if (number == 4)
 730                 return COLOR_TEAM4;
 731
 732         return -1;
 733 }
 734
 735 #define CENTERPRIO_POINT 1
 736 #define CENTERPRIO_SPAM 2
 737 #define CENTERPRIO_VOTE 4
 738 #define CENTERPRIO_NORMAL 5
 739 #define CENTERPRIO_SHIELDING 7
 740 #define CENTERPRIO_MAPVOTE 9
 741 #define CENTERPRIO_IDLEKICK 50
 742 #define CENTERPRIO_ADMIN 99
 743 .float centerprint_priority;
 744 .float centerprint_expires;
 745 void centerprint_atprio(entity e, float prio, string s)
 746 {
 747     if (intermission_running)
 748         if (prio < CENTERPRIO_MAPVOTE)
 749             return;
 750     if (time > e.centerprint_expires)
 751         e.centerprint_priority = 0;
 752     if (prio >= e.centerprint_priority)
 753     {
 754         e.centerprint_priority = prio;
 755         if (timeoutStatus == 2)
 756             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 757         else
 758             e.centerprint_expires = time + e.cvar_scr_centertime;
 759         centerprint_builtin(e, s);
 760     }
 761 }
 762 void centerprint_expire(entity e, float prio)
 763 {
 764     if (prio == e.centerprint_priority)
 765     {
 766         e.centerprint_priority = 0;
 767         centerprint_builtin(e, "");
 768     }
 769 }
 770 void centerprint(entity e, string s)
 771 {
 772     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 773 }
 774
 775 // decolorizes and team colors the player name when needed
 776 string playername(entity p)
 777 {
 778     string t;
 779     if (teams_matter && !intermission_running && p.classname == "player")
 780     {
 781         t = Team_ColorCode(p.team);
 782         return strcat(t, strdecolorize(p.netname));
 783     }
 784     else
 785         return p.netname;
 786 }
 787
 788 vector randompos(vector m1, vector m2)
 789 {
 790     local vector v;
 791     m2 = m2 - m1;
 792     v_x = m2_x * random() + m1_x;
 793     v_y = m2_y * random() + m1_y;
 794     v_z = m2_z * random() + m1_z;
 795     return  v;
 796 };
 797
 798 //#NO AUTOCVARS START
 799
 800 float g_pickup_shells;
 801 float g_pickup_shells_max;
 802 float g_pickup_nails;
 803 float g_pickup_nails_max;
 804 float g_pickup_rockets;
 805 float g_pickup_rockets_max;
 806 float g_pickup_cells;
 807 float g_pickup_cells_max;
 808 float g_pickup_fuel;
 809 float g_pickup_fuel_jetpack;
 810 float g_pickup_fuel_max;
 811 float g_pickup_armorsmall;
 812 float g_pickup_armorsmall_max;
 813 float g_pickup_armorsmall_anyway;
 814 float g_pickup_armormedium;
 815 float g_pickup_armormedium_max;
 816 float g_pickup_armormedium_anyway;
 817 float g_pickup_armorbig;
 818 float g_pickup_armorbig_max;
 819 float g_pickup_armorbig_anyway;
 820 float g_pickup_armorlarge;
 821 float g_pickup_armorlarge_max;
 822 float g_pickup_armorlarge_anyway;
 823 float g_pickup_healthsmall;
 824 float g_pickup_healthsmall_max;
 825 float g_pickup_healthsmall_anyway;
 826 float g_pickup_healthmedium;
 827 float g_pickup_healthmedium_max;
 828 float g_pickup_healthmedium_anyway;
 829 float g_pickup_healthlarge;
 830 float g_pickup_healthlarge_max;
 831 float g_pickup_healthlarge_anyway;
 832 float g_pickup_healthmega;
 833 float g_pickup_healthmega_max;
 834 float g_pickup_healthmega_anyway;
 835 float g_pickup_ammo_anyway;
 836 float g_pickup_weapons_anyway;
 837 float g_weaponarena;
 838 float g_weaponarena_random;
 839 float g_weaponarena_random_with_laser;
 840 string g_weaponarena_list;
 841 float g_weaponspeedfactor;
 842 float g_weaponratefactor;
 843 float g_weapondamagefactor;
 844 float g_weaponforcefactor;
 845 float g_weaponspreadfactor;
 846
 847 float start_weapons;
 848 float start_items;
 849 float start_ammo_shells;
 850 float start_ammo_nails;
 851 float start_ammo_rockets;
 852 float start_ammo_cells;
 853 float start_ammo_fuel;
 854 float start_health;
 855 float start_armorvalue;
 856 float warmup_start_weapons;
 857 float warmup_start_ammo_shells;
 858 float warmup_start_ammo_nails;
 859 float warmup_start_ammo_rockets;
 860 float warmup_start_ammo_cells;
 861 float warmup_start_ammo_fuel;
 862 float warmup_start_health;
 863 float warmup_start_armorvalue;
 864 float g_weapon_stay;
 865 float g_ghost_items;
 866
 867 entity get_weaponinfo(float w);
 868
 869 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 870 {
 871         var float i = weaponinfo.weapon;
 872
 873         if (!i)
 874                 return 0;
 875
 876         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 877
 878         if (t < 0) // "default" weapon selection
 879         {
 880                 if (g_lms || g_ca || allguns)
 881                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 882                 else if(t < -1)
 883                         t = 0;
 884                 else if (g_cts)
 885                         t = (i == WEP_SHOTGUN);
 886                 else if (g_nexball)
 887                         t = 0; // weapon is set a few lines later
 888                 else
 889                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 890                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 891                         t |= (i == WEP_HOOK);
 892         }
 893
 894         // we cannot disable porto in Nexball, we must force it
 895         if(g_nexball && i == WEP_PORTO)
 896                 t = 1;
 897
 898         return t;
 899 }
 900
 901 void readplayerstartcvars()
 902 {
 903         entity e;
 904         float i, j, t;
 905         string s;
 906
 907         // initialize starting values for players
 908         start_weapons = 0;
 909         start_items = 0;
 910         start_ammo_shells = 0;
 911         start_ammo_nails = 0;
 912         start_ammo_rockets = 0;
 913         start_ammo_cells = 0;
 914         start_health = cvar("g_balance_health_start");
 915         start_armorvalue = cvar("g_balance_armor_start");
 916
 917         g_weaponarena = 0;
 918         s = cvar_string("g_weaponarena");
 919         if (s == "0" || s == "")
 920         {
 921                 if(g_lms || g_ca)
 922                         s = "most";
 923         }
 924
 925         if (s == "off")
 926         {
 927                 // forcibly turn off weaponarena
 928         }
 929         else if (s == "all")
 930         {
 931                 g_weaponarena_list = "All Weapons";
 932                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 933                 {
 934                         e = get_weaponinfo(j);
 935                         g_weaponarena |= e.weapons;
 936                         weapon_action(e.weapon, WR_PRECACHE);
 937                 }
 938         }
 939         else if (s == "most")
 940         {
 941                 g_weaponarena_list = "Most Weapons";
 942                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 943                 {
 944                         e = get_weaponinfo(j);
 945                         if (e.spawnflags & WEP_FLAG_NORMAL)
 946                         {
 947                                 g_weaponarena |= e.weapons;
 948                                 weapon_action(e.weapon, WR_PRECACHE);
 949                         }
 950                 }
 951         }
 952         else if (s == "none")
 953         {
 954                 g_weaponarena_list = "No Weapons";
 955                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 956         }
 957         else
 958         {
 959                 t = tokenize_console(s);
 960                 g_weaponarena_list = "";
 961                 for (i = 0; i < t; ++i)
 962                 {
 963                         s = argv(i);
 964                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 965                         {
 966                                 e = get_weaponinfo(j);
 967                                 if (e.netname == s)
 968                                 {
 969                                         g_weaponarena |= e.weapons;
 970                                         weapon_action(e.weapon, WR_PRECACHE);
 971                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 972                                         break;
 973                                 }
 974                         }
 975                         if (j > WEP_LAST)
 976                         {
 977                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 978                         }
 979                 }
 980                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 981         }
 982
 983         if(g_weaponarena)
 984                 g_weaponarena_random = cvar("g_weaponarena_random");
 985         else
 986                 g_weaponarena_random = 0;
 987         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 988
 989         if (g_weaponarena)
 990         {
 991                 start_weapons = g_weaponarena;
 992                 if(!(g_lms || g_ca))
 993                         start_items |= IT_UNLIMITED_AMMO;
 994         }
 995         else if (g_minstagib)
 996         {
 997                 start_health = 100;
 998                 start_armorvalue = 0;
 999                 start_weapons = WEPBIT_MINSTANEX;
1000                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1001                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1002
1003                 if (g_minstagib_invis_alpha <= 0)
1004                         g_minstagib_invis_alpha = -1;
1005         }
1006         else
1007         {
1008                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1009                 {
1010                         e = get_weaponinfo(i);
1011                         if(want_weapon("g_start_weapon_", e, FALSE))
1012                                 start_weapons |= e.weapons;
1013                 }
1014         }
1015
1016         if(!cvar("g_use_ammunition"))
1017                 start_items |= IT_UNLIMITED_AMMO;
1018
1019         if(g_minstagib)
1020         {
1021                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1022                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1023         }
1024         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
1025         {
1026                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1027                 {
1028                         e = get_weaponinfo(j);
1029                         if(start_weapons & e.weapons)
1030                         {
1031                                 if(e.items & IT_ROCKETS)
1032                                         start_ammo_rockets = 999;
1033                                 if(e.items & IT_SHELLS)
1034                                         start_ammo_shells = 999;
1035                                 if(e.items & IT_CELLS)
1036                                         start_ammo_cells = 999;
1037                                 if(e.items & IT_NAILS)
1038                                         start_ammo_nails = 999;
1039                                 if(e.items & IT_FUEL)
1040                                         start_ammo_fuel = 999;
1041                         }
1042                 }
1043         }
1044         else
1045         {
1046                 if(g_lms || g_ca)
1047                 {
1048                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1049                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1050                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1051                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1052                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1053                 }
1054                 else
1055                 {
1056                         start_ammo_shells = cvar("g_start_ammo_shells");
1057                         start_ammo_nails = cvar("g_start_ammo_nails");
1058                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1059                         start_ammo_cells = cvar("g_start_ammo_cells");
1060                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1061                 }
1062         }
1063
1064         if (g_lms || g_ca)
1065         {
1066                 start_health = cvar("g_lms_start_health");
1067                 start_armorvalue = cvar("g_lms_start_armor");
1068         }
1069
1070         if (inWarmupStage)
1071         {
1072                 warmup_start_ammo_shells = start_ammo_shells;
1073                 warmup_start_ammo_nails = start_ammo_nails;
1074                 warmup_start_ammo_rockets = start_ammo_rockets;
1075                 warmup_start_ammo_cells = start_ammo_cells;
1076                 warmup_start_ammo_fuel = start_ammo_fuel;
1077                 warmup_start_health = start_health;
1078                 warmup_start_armorvalue = start_armorvalue;
1079                 warmup_start_weapons = start_weapons;
1080
1081                 if (!g_weaponarena && !g_minstagib && !g_ca)
1082                 {
1083                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1084                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1085                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1086                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1087                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1088                         warmup_start_health = cvar("g_warmup_start_health");
1089                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1090                         warmup_start_weapons = 0;
1091                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1092                         {
1093                                 e = get_weaponinfo(i);
1094                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1095                                         warmup_start_weapons |= e.weapons;
1096                         }
1097                 }
1098         }
1099
1100         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1101         {
1102                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1103                 start_items |= IT_FUEL_REGEN;
1104                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1105                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1106         }
1107
1108         if (g_jetpack)
1109                 start_items |= IT_JETPACK;
1110
1111         if (g_weapon_stay == 2)
1112         {
1113                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1114                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1115                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1116                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1117                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1118                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1119                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1120                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1121                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1122                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1123         }
1124
1125         MUTATOR_CALLHOOK(SetStartItems);
1126
1127         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1128         {
1129                 e = get_weaponinfo(i);
1130                 if(e.weapons & (start_weapons | warmup_start_weapons))
1131                         weapon_action(e.weapon, WR_PRECACHE);
1132         }
1133
1134         start_ammo_shells = max(0, start_ammo_shells);
1135         start_ammo_nails = max(0, start_ammo_nails);
1136         start_ammo_cells = max(0, start_ammo_cells);
1137         start_ammo_rockets = max(0, start_ammo_rockets);
1138         start_ammo_fuel = max(0, start_ammo_fuel);
1139
1140         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1141         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1142         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1143         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1144         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1145 }
1146
1147 float g_bugrigs;
1148 float g_bugrigs_planar_movement;
1149 float g_bugrigs_planar_movement_car_jumping;
1150 float g_bugrigs_reverse_spinning;
1151 float g_bugrigs_reverse_speeding;
1152 float g_bugrigs_reverse_stopping;
1153 float g_bugrigs_air_steering;
1154 float g_bugrigs_angle_smoothing;
1155 float g_bugrigs_friction_floor;
1156 float g_bugrigs_friction_brake;
1157 float g_bugrigs_friction_air;
1158 float g_bugrigs_accel;
1159 float g_bugrigs_speed_ref;
1160 float g_bugrigs_speed_pow;
1161 float g_bugrigs_steer;
1162
1163 float g_touchexplode;
1164 float g_touchexplode_radius;
1165 float g_touchexplode_damage;
1166 float g_touchexplode_edgedamage;
1167 float g_touchexplode_force;
1168
1169 float sv_autotaunt;
1170 float sv_taunt;
1171
1172 float sv_pitch_min;
1173 float sv_pitch_max;
1174 float sv_pitch_fixyaw;
1175
1176 string GetGametype(); // g_world.qc
1177 void readlevelcvars(void)
1178 {
1179         // first load all the mutators
1180         if(cvar("g_nix"))
1181                 MUTATOR_ADD(mutator_nix);
1182         if(cvar("g_dodging"))
1183                 MUTATOR_ADD(mutator_dodging);
1184         if(cvar("g_rocket_flying"))
1185                 MUTATOR_ADD(mutator_rocketflying);
1186         if(cvar("g_vampire"))
1187                 MUTATOR_ADD(mutator_vampire);
1188
1189         if(cvar("sv_allow_fullbright"))
1190                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1191
1192     g_bugrigs = cvar("g_bugrigs");
1193     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1194     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1195     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1196     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1197     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1198     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1199     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1200     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1201     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1202     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1203     g_bugrigs_accel = cvar("g_bugrigs_accel");
1204     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1205     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1206     g_bugrigs_steer = cvar("g_bugrigs_steer");
1207
1208     g_touchexplode = cvar("g_touchexplode");
1209     g_touchexplode_radius = cvar("g_touchexplode_radius");
1210     g_touchexplode_damage = cvar("g_touchexplode_damage");
1211     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1212     g_touchexplode_force = cvar("g_touchexplode_force");
1213
1214 #ifdef ALLOW_FORCEMODELS
1215         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1216 #endif
1217         sv_loddistance1 = cvar("sv_loddistance1");
1218         sv_loddistance2 = cvar("sv_loddistance2");
1219
1220         if(sv_loddistance2 <= sv_loddistance1)
1221                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1222
1223         sv_clones = cvar("sv_clones");
1224         sv_gentle = cvar("sv_gentle");
1225         sv_foginterval = cvar("sv_foginterval");
1226         g_cloaked = cvar("g_cloaked");
1227     if(g_cts)
1228         g_cloaked = 1; // always enable cloak in CTS
1229         g_jump_grunt = cvar("g_jump_grunt");
1230         g_footsteps = cvar("g_footsteps");
1231         g_grappling_hook = cvar("g_grappling_hook");
1232         g_jetpack = cvar("g_jetpack");
1233         g_midair = cvar("g_midair");
1234         g_minstagib = cvar("g_minstagib");
1235         g_norecoil = cvar("g_norecoil");
1236         g_bloodloss = cvar("g_bloodloss");
1237         sv_maxidle = cvar("sv_maxidle");
1238         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1239         sv_pogostick = cvar("sv_pogostick");
1240         g_ctf_reverse = cvar("g_ctf_reverse");
1241         sv_autotaunt = cvar("sv_autotaunt");
1242         sv_taunt = cvar("sv_taunt");
1243
1244         inWarmupStage = cvar("g_warmup");
1245         g_warmup_limit = cvar("g_warmup_limit");
1246         g_warmup_allguns = cvar("g_warmup_allguns");
1247         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1248
1249         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1250                 inWarmupStage = 0; // these modes cannot work together, sorry
1251
1252         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1253         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1254         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1255         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1256         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1257         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1258         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1259         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1260         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1261         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1262         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1263         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1264
1265         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1266         g_weaponratefactor = cvar("g_weaponratefactor");
1267         g_weapondamagefactor = cvar("g_weapondamagefactor");
1268         g_weaponforcefactor = cvar("g_weaponforcefactor");
1269         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1270
1271         g_pickup_shells = cvar("g_pickup_shells");
1272         g_pickup_shells_max = cvar("g_pickup_shells_max");
1273         g_pickup_nails = cvar("g_pickup_nails");
1274         g_pickup_nails_max = cvar("g_pickup_nails_max");
1275         g_pickup_rockets = cvar("g_pickup_rockets");
1276         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1277         g_pickup_cells = cvar("g_pickup_cells");
1278         g_pickup_cells_max = cvar("g_pickup_cells_max");
1279         g_pickup_fuel = cvar("g_pickup_fuel");
1280         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1281         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1282         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1283         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1284         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1285         g_pickup_armormedium = cvar("g_pickup_armormedium");
1286         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1287         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1288         g_pickup_armorbig = cvar("g_pickup_armorbig");
1289         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1290         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1291         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1292         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1293         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1294         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1295         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1296         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1297         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1298         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1299         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1300         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1301         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1302         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1303         g_pickup_healthmega = cvar("g_pickup_healthmega");
1304         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1305         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1306
1307         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1308         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1309
1310         g_pinata = cvar("g_pinata");
1311
1312     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1313     if(!g_weapon_stay)
1314         g_weapon_stay = cvar("g_weapon_stay");
1315
1316         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1317                 g_weapon_stay = 1;
1318
1319         g_ghost_items = cvar("g_ghost_items");
1320
1321         if(g_ghost_items >= 1)
1322                 g_ghost_items = 0.25; // default alpha value
1323
1324         if not(inWarmupStage && !g_ca)
1325                 game_starttime = cvar("g_start_delay");
1326
1327         sv_pitch_min = cvar("sv_pitch_min");
1328         sv_pitch_max = cvar("sv_pitch_max");
1329         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1330
1331         readplayerstartcvars();
1332 }
1333
1334 //#NO AUTOCVARS END
1335
1336 // Sound functions
1337 string precache_sound (string s) = #19;
1338 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1339 float precache_sound_index (string s) = #19;
1340
1341 #define SND_VOLUME      1
1342 #define SND_ATTENUATION 2
1343 #define SND_LARGEENTITY 8
1344 #define SND_LARGESOUND  16
1345
1346 float sound_allowed(float dest, entity e)
1347 {
1348     // sounds from world may always pass
1349     for (;;)
1350     {
1351         if (e.classname == "body")
1352             e = e.enemy;
1353         if (e.owner && e.owner != e)
1354             e = e.owner;
1355         else
1356             break;
1357     }
1358     // sounds to self may always pass
1359     if (dest == MSG_ONE)
1360         if (e == msg_entity)
1361             return TRUE;
1362     // sounds by players can be removed
1363     if (autocvar_bot_sound_monopoly)
1364         if (clienttype(e) == CLIENTTYPE_REAL)
1365             return FALSE;
1366     // anything else may pass
1367     return TRUE;
1368 }
1369
1370 void sound(entity e, float chan, string samp, float vol, float atten)
1371 {
1372     if (!sound_allowed(MSG_BROADCAST, e))
1373         return;
1374     sound_builtin(e, chan, samp, vol, atten);
1375 }
1376 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1377 {
1378     float entno, idx;
1379
1380     if (!sound_allowed(dest, e))
1381         return;
1382
1383     entno = num_for_edict(e);
1384     idx = precache_sound_index(samp);
1385
1386     float sflags;
1387     sflags = 0;
1388
1389     atten = floor(atten * 64);
1390     vol = floor(vol * 255);
1391
1392     if (vol != 255)
1393         sflags |= SND_VOLUME;
1394     if (atten != 64)
1395         sflags |= SND_ATTENUATION;
1396     if (entno >= 8192)
1397         sflags |= SND_LARGEENTITY;
1398     if (idx >= 256)
1399         sflags |= SND_LARGESOUND;
1400
1401     WriteByte(dest, SVC_SOUND);
1402     WriteByte(dest, sflags);
1403     if (sflags & SND_VOLUME)
1404         WriteByte(dest, vol);
1405     if (sflags & SND_ATTENUATION)
1406         WriteByte(dest, atten);
1407     if (sflags & SND_LARGEENTITY)
1408     {
1409         WriteShort(dest, entno);
1410         WriteByte(dest, chan);
1411     }
1412     else
1413     {
1414         WriteShort(dest, entno * 8 + chan);
1415     }
1416     if (sflags & SND_LARGESOUND)
1417         WriteShort(dest, idx);
1418     else
1419         WriteByte(dest, idx);
1420
1421     WriteCoord(dest, o_x);
1422     WriteCoord(dest, o_y);
1423     WriteCoord(dest, o_z);
1424 }
1425 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1426 {
1427     vector o;
1428
1429     if (!sound_allowed(dest, e))
1430         return;
1431
1432     o = e.origin + 0.5 * (e.mins + e.maxs);
1433     soundtoat(dest, e, o, chan, samp, vol, atten);
1434 }
1435 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1436 {
1437     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1438 }
1439 void stopsoundto(float dest, entity e, float chan)
1440 {
1441     float entno;
1442
1443     if (!sound_allowed(dest, e))
1444         return;
1445
1446     entno = num_for_edict(e);
1447
1448     if (entno >= 8192)
1449     {
1450         float idx, sflags;
1451         idx = precache_sound_index("misc/null.wav");
1452         sflags = SND_LARGEENTITY;
1453         if (idx >= 256)
1454             sflags |= SND_LARGESOUND;
1455         WriteByte(dest, SVC_SOUND);
1456         WriteByte(dest, sflags);
1457         WriteShort(dest, entno);
1458         WriteByte(dest, chan);
1459         if (sflags & SND_LARGESOUND)
1460             WriteShort(dest, idx);
1461         else
1462             WriteByte(dest, idx);
1463         WriteCoord(dest, e.origin_x);
1464         WriteCoord(dest, e.origin_y);
1465         WriteCoord(dest, e.origin_z);
1466     }
1467     else
1468     {
1469         WriteByte(dest, SVC_STOPSOUND);
1470         WriteShort(dest, entno * 8 + chan);
1471     }
1472 }
1473 void stopsound(entity e, float chan)
1474 {
1475     if (!sound_allowed(MSG_BROADCAST, e))
1476         return;
1477
1478     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1479     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1480 }
1481
1482 void play2(entity e, string filename)
1483 {
1484     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1485     msg_entity = e;
1486     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1487 }
1488
1489 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1490 .float spamtime;
1491 float spamsound(entity e, float chan, string samp, float vol, float atten)
1492 {
1493     if (!sound_allowed(MSG_BROADCAST, e))
1494         return FALSE;
1495
1496     if (time > e.spamtime)
1497     {
1498         e.spamtime = time;
1499         sound(e, chan, samp, vol, atten);
1500         return TRUE;
1501     }
1502     return FALSE;
1503 }
1504
1505 void play2team(float t, string filename)
1506 {
1507     local entity head;
1508
1509     if (autocvar_bot_sound_monopoly)
1510         return;
1511
1512     FOR_EACH_REALPLAYER(head)
1513     {
1514         if (head.team == t)
1515             play2(head, filename);
1516     }
1517 }
1518
1519 void play2all(string samp)
1520 {
1521     if (autocvar_bot_sound_monopoly)
1522         return;
1523
1524     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1525 }
1526
1527 void PrecachePlayerSounds(string f);
1528 void precache_playermodel(string m)
1529 {
1530         float globhandle, i, n;
1531         string f;
1532
1533         if(substring(m, -9,5) == "_lod1")
1534                 return;
1535         if(substring(m, -9,5) == "_lod2")
1536                 return;
1537         precache_model(m);
1538         if(sv_loddistance1)
1539         {
1540                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1541                 if(fexists(f))
1542                         precache_model(f);
1543                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1544                 if(fexists(f))
1545                         precache_model(f);
1546         }
1547
1548         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1549         if (globhandle < 0)
1550                 return;
1551         n = search_getsize(globhandle);
1552         for (i = 0; i < n; ++i)
1553         {
1554                 //print(search_getfilename(globhandle, i), "\n");
1555                 f = search_getfilename(globhandle, i);
1556                 PrecachePlayerSounds(f);
1557         }
1558         search_end(globhandle);
1559 }
1560 void precache_all_playermodels(string pattern)
1561 {
1562         float globhandle, i, n;
1563         string f;
1564
1565         globhandle = search_begin(pattern, TRUE, FALSE);
1566         if (globhandle < 0)
1567                 return;
1568         n = search_getsize(globhandle);
1569         for (i = 0; i < n; ++i)
1570         {
1571                 //print(search_getfilename(globhandle, i), "\n");
1572                 f = search_getfilename(globhandle, i);
1573                 precache_playermodel(f);
1574         }
1575         search_end(globhandle);
1576 }
1577
1578 void precache()
1579 {
1580     // gamemode related things
1581     precache_model ("models/misc/chatbubble.spr");
1582     precache_model ("models/misc/teambubble.spr");
1583     if (g_runematch)
1584     {
1585         precache_model ("models/runematch/curse.mdl");
1586         precache_model ("models/runematch/rune.mdl");
1587     }
1588
1589 #ifdef TTURRETS_ENABLED
1590     if (autocvar_g_turrets)
1591         turrets_precash();
1592 #endif
1593
1594     // Precache all player models if desired
1595     if (autocvar_sv_precacheplayermodels)
1596     {
1597         PrecachePlayerSounds("sound/player/default.sounds");
1598         precache_all_playermodels("models/player/*.zym");
1599         precache_all_playermodels("models/player/*.dpm");
1600         precache_all_playermodels("models/player/*.md3");
1601         precache_all_playermodels("models/player/*.psk");
1602         precache_all_playermodels("models/player/*.iqm");
1603     }
1604
1605     if (autocvar_sv_defaultcharacter)
1606     {
1607         string s;
1608         s = autocvar_sv_defaultplayermodel_red;
1609         if (s != "")
1610             precache_playermodel(s);
1611         s = autocvar_sv_defaultplayermodel_blue;
1612         if (s != "")
1613             precache_playermodel(s);
1614         s = autocvar_sv_defaultplayermodel_yellow;
1615         if (s != "")
1616             precache_playermodel(s);
1617         s = autocvar_sv_defaultplayermodel_pink;
1618         if (s != "")
1619             precache_playermodel(s);
1620         s = autocvar_sv_defaultplayermodel;
1621         if (s != "")
1622             precache_playermodel(s);
1623     }
1624
1625     if (g_footsteps)
1626     {
1627         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1628         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1629     }
1630
1631     // gore and miscellaneous sounds
1632     //precache_sound ("misc/h2ohit.wav");
1633     precache_model ("models/hook.md3");
1634     precache_sound ("misc/armorimpact.wav");
1635     precache_sound ("misc/bodyimpact1.wav");
1636     precache_sound ("misc/bodyimpact2.wav");
1637     precache_sound ("misc/gib.wav");
1638     precache_sound ("misc/gib_splat01.wav");
1639     precache_sound ("misc/gib_splat02.wav");
1640     precache_sound ("misc/gib_splat03.wav");
1641     precache_sound ("misc/gib_splat04.wav");
1642     precache_sound ("misc/hit.wav");
1643         precache_sound ("misc/typehit.wav");
1644     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1645     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1646     precache_sound ("misc/null.wav");
1647     precache_sound ("misc/spawn.wav");
1648     precache_sound ("misc/talk.wav");
1649     precache_sound ("misc/teleport.wav");
1650     precache_sound ("misc/poweroff.wav");
1651     precache_sound ("player/lava.wav");
1652     precache_sound ("player/slime.wav");
1653
1654     if (g_jetpack)
1655         precache_sound ("misc/jetpack_fly.wav");
1656
1657     precache_model ("models/sprites/0.spr32");
1658     precache_model ("models/sprites/1.spr32");
1659     precache_model ("models/sprites/2.spr32");
1660     precache_model ("models/sprites/3.spr32");
1661     precache_model ("models/sprites/4.spr32");
1662     precache_model ("models/sprites/5.spr32");
1663     precache_model ("models/sprites/6.spr32");
1664     precache_model ("models/sprites/7.spr32");
1665     precache_model ("models/sprites/8.spr32");
1666     precache_model ("models/sprites/9.spr32");
1667     precache_model ("models/sprites/10.spr32");
1668
1669     // common weapon precaches
1670     precache_sound ("weapons/weapon_switch.wav");
1671     precache_sound ("weapons/weaponpickup.wav");
1672     precache_sound ("weapons/unavailable.wav");
1673     precache_sound ("weapons/dryfire.wav");
1674     if (g_grappling_hook)
1675     {
1676         precache_sound ("weapons/hook_fire.wav"); // hook
1677         precache_sound ("weapons/hook_impact.wav"); // hook
1678     }
1679
1680     if(autocvar_sv_precacheweapons)
1681     {
1682         //precache weapon models/sounds
1683         local float wep;
1684         wep = WEP_FIRST;
1685         while (wep <= WEP_LAST)
1686         {
1687             weapon_action(wep, WR_PRECACHE);
1688             wep = wep + 1;
1689         }
1690     }
1691
1692     precache_model("models/elaser.mdl");
1693     precache_model("models/laser.mdl");
1694     precache_model("models/ebomb.mdl");
1695
1696 #if 0
1697     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1698
1699     if (!self.noise && self.music) // quake 3 uses the music field
1700         self.noise = self.music;
1701
1702     // plays music for the level if there is any
1703     if (self.noise)
1704     {
1705         precache_sound (self.noise);
1706         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1707     }
1708 #endif
1709 }
1710
1711 // sorry, but using \ in macros breaks line numbers
1712 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1713 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1714 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1715
1716 // WARNING: this kills the trace globals
1717 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1718 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1719
1720 #define INITPRIO_FIRST              0
1721 #define INITPRIO_GAMETYPE           0
1722 #define INITPRIO_GAMETYPE_FALLBACK  1
1723 #define INITPRIO_FINDTARGET        10
1724 #define INITPRIO_DROPTOFLOOR       20
1725 #define INITPRIO_SETLOCATION       90
1726 #define INITPRIO_LINKDOORS         91
1727 #define INITPRIO_LAST              99
1728
1729 .void(void) initialize_entity;
1730 .float initialize_entity_order;
1731 .entity initialize_entity_next;
1732 entity initialize_entity_first;
1733
1734 void make_safe_for_remove(entity e)
1735 {
1736     if (e.initialize_entity)
1737     {
1738         entity ent, prev;
1739         for (ent = initialize_entity_first; ent; )
1740         {
1741             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1742             {
1743                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1744                 // skip it in linked list
1745                 if (prev)
1746                 {
1747                     prev.initialize_entity_next = ent.initialize_entity_next;
1748                     ent = prev.initialize_entity_next;
1749                 }
1750                 else
1751                 {
1752                     initialize_entity_first = ent.initialize_entity_next;
1753                     ent = initialize_entity_first;
1754                 }
1755             }
1756             else
1757             {
1758                 prev = ent;
1759                 ent = ent.initialize_entity_next;
1760             }
1761         }
1762     }
1763 }
1764
1765 void objerror(string s)
1766 {
1767     make_safe_for_remove(self);
1768     objerror_builtin(s);
1769 }
1770
1771 .float remove_except_protected_forbidden;
1772 void remove_except_protected(entity e)
1773 {
1774         if(e.remove_except_protected_forbidden)
1775                 error("not allowed to remove this at this point");
1776         remove_builtin(e);
1777 }
1778
1779 void remove_unsafely(entity e)
1780 {
1781     remove_builtin(e);
1782 }
1783
1784 void remove_safely(entity e)
1785 {
1786     make_safe_for_remove(e);
1787     remove_builtin(e);
1788 }
1789
1790 void InitializeEntity(entity e, void(void) func, float order)
1791 {
1792     entity prev, cur;
1793
1794     if (!e || e.initialize_entity)
1795     {
1796         // make a proxy initializer entity
1797         entity e_old;
1798         e_old = e;
1799         e = spawn();
1800         e.classname = "initialize_entity";
1801         e.enemy = e_old;
1802     }
1803
1804     e.initialize_entity = func;
1805     e.initialize_entity_order = order;
1806
1807     cur = initialize_entity_first;
1808     for (;;)
1809     {
1810         if (!cur || cur.initialize_entity_order > order)
1811         {
1812             // insert between prev and cur
1813             if (prev)
1814                 prev.initialize_entity_next = e;
1815             else
1816                 initialize_entity_first = e;
1817             e.initialize_entity_next = cur;
1818             return;
1819         }
1820         prev = cur;
1821         cur = cur.initialize_entity_next;
1822     }
1823 }
1824 void InitializeEntitiesRun()
1825 {
1826     entity startoflist;
1827     startoflist = initialize_entity_first;
1828     initialize_entity_first = world;
1829     remove = remove_except_protected;
1830     for (self = startoflist; self; self = self.initialize_entity_next)
1831     {
1832         self.remove_except_protected_forbidden = 1;
1833     }
1834     for (self = startoflist; self; )
1835     {
1836         entity e;
1837         var void(void) func;
1838         e = self.initialize_entity_next;
1839         func = self.initialize_entity;
1840         self.initialize_entity_order = 0;
1841         self.initialize_entity = func_null;
1842         self.initialize_entity_next = world;
1843         self.remove_except_protected_forbidden = 0;
1844         if (self.classname == "initialize_entity")
1845         {
1846             entity e_old;
1847             e_old = self.enemy;
1848             remove_builtin(self);
1849             self = e_old;
1850         }
1851         //dprint("Delayed initialization: ", self.classname, "\n");
1852         if(func != func_null)
1853             func();
1854         else
1855         {
1856             eprint(self);
1857             backtrace(strcat("Null function in: ", self.classname, "\n"));
1858         }
1859         self = e;
1860     }
1861     remove = remove_unsafely;
1862 }
1863
1864 .float uncustomizeentityforclient_set;
1865 .void(void) uncustomizeentityforclient;
1866 void(void) SUB_Nullpointer = #0;
1867 void UncustomizeEntitiesRun()
1868 {
1869     entity oldself;
1870     oldself = self;
1871     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1872         self.uncustomizeentityforclient();
1873     self = oldself;
1874 }
1875 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1876 {
1877     e.customizeentityforclient = customizer;
1878     e.uncustomizeentityforclient = uncustomizer;
1879     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1880 }
1881
1882 .float nottargeted;
1883 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1884
1885 void() SUB_Remove;
1886 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1887 {
1888     vector mi, ma;
1889
1890     if (e.classname == "")
1891         e.classname = "net_linked";
1892
1893     if (e.model == "" || self.modelindex == 0)
1894     {
1895         mi = e.mins;
1896         ma = e.maxs;
1897         setmodel(e, "null");
1898         setsize(e, mi, ma);
1899     }
1900
1901     e.SendEntity = sendfunc;
1902     e.SendFlags = 0xFFFFFF;
1903
1904     if (!docull)
1905         e.effects |= EF_NODEPTHTEST;
1906
1907     if (dt)
1908     {
1909         e.nextthink = time + dt;
1910         e.think = SUB_Remove;
1911     }
1912 }
1913
1914 void adaptor_think2touch()
1915 {
1916     entity o;
1917     o = other;
1918     other = world;
1919     self.touch();
1920     other = o;
1921 }
1922
1923 void adaptor_think2use()
1924 {
1925     entity o, a;
1926     o = other;
1927     a = activator;
1928     activator = world;
1929     other = world;
1930     self.use();
1931     other = o;
1932     activator = a;
1933 }
1934
1935 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1936 {
1937         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1938                 self.projectiledeathtype |= HITTYPE_SPLASH;
1939         adaptor_think2use();
1940 }
1941
1942 // deferred dropping
1943 void DropToFloor_Handler()
1944 {
1945     droptofloor_builtin();
1946     self.dropped_origin = self.origin;
1947 }
1948
1949 void droptofloor()
1950 {
1951     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1952 }
1953
1954
1955
1956 float trace_hits_box_a0, trace_hits_box_a1;
1957
1958 float trace_hits_box_1d(float end, float thmi, float thma)
1959 {
1960     if (end == 0)
1961     {
1962         // just check if x is in range
1963         if (0 < thmi)
1964             return FALSE;
1965         if (0 > thma)
1966             return FALSE;
1967     }
1968     else
1969     {
1970         // do the trace with respect to x
1971         // 0 -> end has to stay in thmi -> thma
1972         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1973         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1974         if (trace_hits_box_a0 > trace_hits_box_a1)
1975             return FALSE;
1976     }
1977     return TRUE;
1978 }
1979
1980 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1981 {
1982     end -= start;
1983     thmi -= start;
1984     thma -= start;
1985     // now it is a trace from 0 to end
1986
1987     trace_hits_box_a0 = 0;
1988     trace_hits_box_a1 = 1;
1989
1990     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1991         return FALSE;
1992     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1993         return FALSE;
1994     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1995         return FALSE;
1996
1997     return TRUE;
1998 }
1999
2000 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
2001 {
2002     return trace_hits_box(start, end, thmi - ma, thma - mi);
2003 }
2004
2005 float SUB_NoImpactCheck()
2006 {
2007         // zero hitcontents = this is not the real impact, but either the
2008         // mirror-impact of something hitting the projectile instead of the
2009         // projectile hitting the something, or a touchareagrid one. Neither of
2010         // these stop the projectile from moving, so...
2011         if(trace_dphitcontents == 0)
2012         {
2013                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2014                 checkclient();
2015         }
2016     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2017         return 1;
2018     if (other == world && self.size != '0 0 0')
2019     {
2020         vector tic;
2021         tic = self.velocity * sys_frametime;
2022         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2023         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2024         if (trace_fraction >= 1)
2025         {
2026             dprint("Odd... did not hit...?\n");
2027         }
2028         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2029         {
2030             dprint("Detected and prevented the sky-grapple bug.\n");
2031             return 1;
2032         }
2033     }
2034
2035     return 0;
2036 }
2037
2038 #define SUB_OwnerCheck() (other && (other == self.owner))
2039
2040 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2041 {
2042         if(SUB_OwnerCheck())
2043                 return TRUE;
2044         if(SUB_NoImpactCheck())
2045         {
2046                 remove(self);
2047                 return TRUE;
2048         }
2049         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2050                 UpdateCSQCProjectileNextFrame(self);
2051         return FALSE;
2052 }
2053 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2054
2055 float MAX_IPBAN_URIS           = 16;
2056
2057 float URI_GET_DISCARD          = 0;
2058 float URI_GET_IPBAN            = 1;
2059 float URI_GET_IPBAN_END        = 16;
2060 float URI_GET_PLAYERSTATS_SENT = 17;
2061
2062 void URI_Get_Callback(float id, float status, string data)
2063 {
2064     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2065     dprint(data);
2066     dprint("\nEnd of data.\n");
2067
2068     if (id == URI_GET_DISCARD)
2069     {
2070         // discard
2071     }
2072     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2073     {
2074         // online ban list
2075         OnlineBanList_URI_Get_Callback(id, status, data);
2076     }
2077     else if (id == URI_GET_PLAYERSTATS_SENT)
2078     {
2079         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2080     }
2081     else
2082     {
2083         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2084     }
2085 }
2086
2087 void print_to(entity e, string s)
2088 {
2089     if (e)
2090         sprint(e, strcat(s, "\n"));
2091     else
2092         print(s, "\n");
2093 }
2094
2095 string uid2name(string myuid) {
2096         string s;
2097         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2098
2099         if(s == "")
2100                 s = "^1Unregistered Player";
2101         return s;
2102 }
2103
2104 float race_readTime(string map, float pos)
2105 {
2106         string rr;
2107         if(g_cts)
2108                 rr = CTS_RECORD;
2109         else
2110                 rr = RACE_RECORD;
2111
2112         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2113 }
2114
2115 string race_readUID(string map, float pos)
2116 {
2117         string rr;
2118         if(g_cts)
2119                 rr = CTS_RECORD;
2120         else
2121                 rr = RACE_RECORD;
2122
2123         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2124 }
2125
2126 float race_readPos(string map, float t) {
2127         float i;
2128         for (i = 1; i <= RANKINGS_CNT; ++i)
2129                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2130                         return i;
2131
2132         return 0; // pos is zero if unranked
2133 }
2134
2135 void race_writeTime(string map, float t, string myuid)
2136 {
2137         string rr;
2138         if(g_cts)
2139                 rr = CTS_RECORD;
2140         else
2141                 rr = RACE_RECORD;
2142
2143         float newpos;
2144         newpos = race_readPos(map, t);
2145
2146         float i, prevpos;
2147         for(i = 1; i <= RANKINGS_CNT; ++i)
2148         {
2149                 if(race_readUID(map, i) == myuid)
2150                         prevpos = i;
2151         }
2152         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2153                 for (i = prevpos; i > newpos; --i) {
2154                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2155                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2156                 }
2157         } else { // player has no ranked record yet
2158                 for (i = RANKINGS_CNT; i > newpos; --i) {
2159                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2160                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2161                 }
2162         }
2163
2164         // store new time itself
2165         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2166         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2167 }
2168
2169 string race_readName(string map, float pos)
2170 {
2171         string rr;
2172         if(g_cts)
2173                 rr = CTS_RECORD;
2174         else
2175                 rr = RACE_RECORD;
2176
2177         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2178 }
2179
2180 string race_placeName(float pos) {
2181         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2182         {
2183                 if(mod(pos, 10) == 1)
2184                         return strcat(ftos(pos), "st");
2185                 else if(mod(pos, 10) == 2)
2186                         return strcat(ftos(pos), "nd");
2187                 else if(mod(pos, 10) == 3)
2188                         return strcat(ftos(pos), "rd");
2189                 else
2190                         return strcat(ftos(pos), "th");
2191         }
2192         else
2193                 return strcat(ftos(pos), "th");
2194 }
2195 string getrecords(float page) // 50 records per page
2196 {
2197     float rec;
2198     string h;
2199     float r;
2200     float i;
2201     string s;
2202
2203     rec = 0;
2204
2205     s = "";
2206
2207     if (g_ctf)
2208     {
2209         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2210         {
2211             if (MapInfo_Get_ByID(i))
2212             {
2213                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2214                 if (r == 0)
2215                     continue;
2216                 // TODO: uid2name
2217                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2218                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2219                 ++rec;
2220             }
2221         }
2222     }
2223
2224     if (g_race)
2225     {
2226         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2227         {
2228             if (MapInfo_Get_ByID(i))
2229             {
2230                 r = race_readTime(MapInfo_Map_bspname, 1);
2231                 if (r == 0)
2232                     continue;
2233                 h = race_readName(MapInfo_Map_bspname, 1);
2234                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2235                 ++rec;
2236             }
2237         }
2238     }
2239
2240     if (g_cts)
2241     {
2242         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2243         {
2244             if (MapInfo_Get_ByID(i))
2245             {
2246                 r = race_readTime(MapInfo_Map_bspname, 1);
2247                 if (r == 0)
2248                     continue;
2249                 h = race_readName(MapInfo_Map_bspname, 1);
2250                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2251                 ++rec;
2252             }
2253         }
2254     }
2255
2256     MapInfo_ClearTemps();
2257
2258     if (s == "" && page == 0)
2259         return "No records are available on this server.\n";
2260     else
2261         return s;
2262 }
2263
2264 string getrankings()
2265 {
2266     string n;
2267     float t;
2268     float i;
2269     string s;
2270     string p;
2271     string map;
2272
2273     s = "";
2274
2275     map = GetMapname();
2276
2277     for (i = 1; i <= RANKINGS_CNT; ++i)
2278     {
2279         t = race_readTime(map, i);
2280         if (t == 0)
2281             continue;
2282         n = race_readName(map, i);
2283         p = race_placeName(i);
2284         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2285     }
2286
2287     MapInfo_ClearTemps();
2288
2289     if (s == "")
2290         return strcat("No records are available for the map: ", map, "\n");
2291     else
2292         return strcat("Records for ", map, ":\n", s);
2293 }
2294
2295 #define LADDER_FIRSTPOINT 100
2296 #define LADDER_CNT 10
2297         // position X still gives LADDER_FIRSTPOINT/X points
2298 #define LADDER_SIZE 30
2299         // ladder shows the top X players
2300 string top_uids[LADDER_SIZE];
2301 float top_scores[LADDER_SIZE];
2302 string getladder()
2303 {
2304     float i, j, k, uidcnt;
2305     string s, temp_s;
2306
2307     s = "";
2308     temp_s = "";
2309
2310     string rr;
2311     if(g_cts)
2312         rr = CTS_RECORD;
2313     else
2314         rr = RACE_RECORD;
2315
2316     string myuid;
2317
2318     for (k = 0; k < MapInfo_count; ++k)
2319     {
2320         if (MapInfo_Get_ByID(k))
2321         {
2322                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2323                         if(i == 0) // speed award
2324                         {
2325                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2326                                         continue;
2327
2328                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2329                         }
2330                         else // normal record, if it exists (else break)
2331                         {
2332                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2333                                         continue;
2334
2335                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2336                         }
2337
2338                         // string s contains:
2339                         // arg 0 = # of speed recs
2340                         // arg 1 = # of 1st place recs
2341                         // arg 2 = # of 2nd place recs
2342                         // ... etc
2343                         // LADDER_CNT+1 = total points
2344
2345                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2346                         if (temp_s == "")
2347                         {
2348                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2349                             ++uidcnt;
2350                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2351                             {
2352                                 if(j != LADDER_CNT + 1)
2353                                     temp_s = strcat(temp_s, "0 ");
2354                                 else
2355                                     temp_s = strcat(temp_s, "0");
2356                             }
2357                         }
2358
2359                         tokenize_console(temp_s);
2360                         s = "";
2361
2362                         if(i == 0) // speed award
2363                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2364                             {
2365                                 if(j == 0) // speed award
2366                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2367                                 else
2368                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2369                             }
2370                         else // record
2371                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2372                             {
2373                                 if(j == 0)
2374                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2375                                 else if(j == i) // wanted rec!
2376                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2377                                 else
2378                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2379                             }
2380
2381                         // total points are (by default) calculated like this:
2382                         // speedrec = floor(100 / 10) = 10 points
2383                         // 1st place = floor(100 / 1) = 100 points
2384                         // 2nd place = floor(100 / 2) = 50 points
2385                         // 3rd place = floor(100 / 3) = 33 points
2386                         // 4th place = floor(100 / 4) = 25 points
2387                         // 5th place = floor(100 / 5) = 20 points
2388                         // ... etc
2389
2390                         if(i == 0)
2391                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2392                         else
2393                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2394
2395                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2396                 }
2397         }
2398     }
2399
2400     float thiscnt;
2401     string thisuid;
2402     for (i = 0; i <= uidcnt; ++i) // for each known uid
2403     {
2404         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2405         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2406         tokenize_console(temp_s);
2407         thiscnt = stof(argv(LADDER_CNT+1));
2408
2409         if(thiscnt > top_scores[LADDER_SIZE-1])
2410         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2411         {
2412             if(thiscnt > top_scores[j])
2413             {
2414                 for (k = LADDER_SIZE-1; k >= j; --k)
2415                 {
2416                     top_uids[k] = top_uids[k-1];
2417                     top_scores[k] = top_scores[k-1];
2418                 }
2419                 top_uids[j] = thisuid;
2420                 top_scores[j] = thiscnt;
2421                 break;
2422             }
2423         }
2424     }
2425
2426     s = "^3-----------------------\n\n";
2427
2428     s = strcat(s, "Pos ^3|");
2429     s = strcat(s, " ^7Total  ^3|");
2430     for (i = 1; i <= LADDER_CNT; ++i)
2431     {
2432         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2433     }
2434     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2435
2436     s = strcat(s, "\n^3----+--------");
2437     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2438     {
2439         s = strcat(s, "+-----");
2440     }
2441 #if LADDER_CNT > 9
2442     for (i = 1; i <= LADDER_CNT - 9; ++i)
2443     {
2444         s = strcat(s, "+------");
2445     }
2446 #endif
2447
2448     s = strcat(s, "+--------------+--------------------\n");
2449
2450     for (i = 0; i < LADDER_SIZE; ++i)
2451     {
2452         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2453         tokenize_console(temp_s);
2454         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2455             continue;
2456         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2457         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2458         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2459         {
2460             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2461         }
2462 #if LADDER_CNT > 9
2463         for (j = 10; j <= LADDER_CNT; ++j)
2464         {
2465             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2466         }
2467 #endif
2468
2469         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2470         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2471     }
2472
2473     MapInfo_ClearTemps();
2474
2475     if (s == "")
2476         return "No ladder on this server!\n";
2477     else
2478         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2479 }
2480
2481
2482 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2483 {
2484     float m, i;
2485     vector start, org, delta, end, enddown, mstart;
2486
2487     m = e.dphitcontentsmask;
2488     e.dphitcontentsmask = goodcontents | badcontents;
2489
2490     org = world.mins;
2491     delta = world.maxs - world.mins;
2492
2493     for (i = 0; i < attempts; ++i)
2494     {
2495         start_x = org_x + random() * delta_x;
2496         start_y = org_y + random() * delta_y;
2497         start_z = org_z + random() * delta_z;
2498
2499         // rule 1: start inside world bounds, and outside
2500         // solid, and don't start from somewhere where you can
2501         // fall down to evil
2502         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2503         if (trace_fraction >= 1)
2504             continue;
2505         if (trace_startsolid)
2506             continue;
2507         if (trace_dphitcontents & badcontents)
2508             continue;
2509         if (trace_dphitq3surfaceflags & badsurfaceflags)
2510             continue;
2511
2512         // rule 2: if we are too high, lower the point
2513         if (trace_fraction * delta_z > maxaboveground)
2514             start = trace_endpos + '0 0 1' * maxaboveground;
2515         enddown = trace_endpos;
2516
2517         // rule 3: make sure we aren't outside the map. This only works
2518         // for somewhat well formed maps. A good rule of thumb is that
2519         // the map should have a convex outside hull.
2520         // these can be traceLINES as we already verified the starting box
2521         mstart = start + 0.5 * (e.mins + e.maxs);
2522         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2523         if (trace_fraction >= 1)
2524             continue;
2525         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2526         if (trace_fraction >= 1)
2527             continue;
2528         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2529         if (trace_fraction >= 1)
2530             continue;
2531         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2532         if (trace_fraction >= 1)
2533             continue;
2534         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2535         if (trace_fraction >= 1)
2536             continue;
2537
2538         // find a random vector to "look at"
2539         end_x = org_x + random() * delta_x;
2540         end_y = org_y + random() * delta_y;
2541         end_z = org_z + random() * delta_z;
2542         end = start + normalize(end - start) * vlen(delta);
2543
2544         // rule 4: start TO end must not be too short
2545         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2546         if (trace_startsolid)
2547             continue;
2548         if (trace_fraction < minviewdistance / vlen(delta))
2549             continue;
2550
2551         // rule 5: don't want to look at sky
2552         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2553             continue;
2554
2555         // rule 6: we must not end up in trigger_hurt
2556         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2557             continue;
2558
2559         break;
2560     }
2561
2562     e.dphitcontentsmask = m;
2563
2564     if (i < attempts)
2565     {
2566         setorigin(e, start);
2567         e.angles = vectoangles(end - start);
2568         dprint("Needed ", ftos(i + 1), " attempts\n");
2569         return TRUE;
2570     }
2571     else
2572         return FALSE;
2573 }
2574
2575 float zcurveparticles_effectno;
2576 vector zcurveparticles_start;
2577 float zcurveparticles_spd;
2578
2579 void endzcurveparticles()
2580 {
2581         if(zcurveparticles_effectno)
2582         {
2583                 // terminator
2584                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2585         }
2586         zcurveparticles_effectno = 0;
2587 }
2588
2589 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2590 {
2591         spd = bound(0, floor(spd / 16), 32767);
2592         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2593         {
2594                 endzcurveparticles();
2595                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2596                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2597                 WriteShort(MSG_BROADCAST, effectno);
2598                 WriteCoord(MSG_BROADCAST, start_x);
2599                 WriteCoord(MSG_BROADCAST, start_y);
2600                 WriteCoord(MSG_BROADCAST, start_z);
2601                 zcurveparticles_effectno = effectno;
2602                 zcurveparticles_start = start;
2603         }
2604         else
2605                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2606         WriteCoord(MSG_BROADCAST, end_x);
2607         WriteCoord(MSG_BROADCAST, end_y);
2608         WriteCoord(MSG_BROADCAST, end_z);
2609         WriteCoord(MSG_BROADCAST, end_dz);
2610         zcurveparticles_spd = spd;
2611 }
2612
2613 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2614 {
2615         float end_dz;
2616         vector vecxy, velxy;
2617
2618         vecxy = end - start;
2619         vecxy_z = 0;
2620         velxy = vel;
2621         velxy_z = 0;
2622
2623         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2624         {
2625                 endzcurveparticles();
2626                 trailparticles(world, effectno, start, end);
2627                 return;
2628         }
2629
2630         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2631         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2632 }
2633
2634 void write_recordmarker(entity pl, float tstart, float dt)
2635 {
2636     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2637
2638     // also write a marker into demo files for demotc-race-record-extractor to find
2639     stuffcmd(pl,
2640              strcat(
2641                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2642                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2643 }
2644
2645 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2646 {
2647         switch(algn)
2648         {
2649                 case 1: // right
2650                         break;
2651
2652                 case 2: // left
2653                         vecs_y = -vecs_y;
2654                         break;
2655
2656                 default:
2657                 case 3:
2658                         if(allowcenter) // 2: allow center handedness
2659                         {
2660                                 // center
2661                                 vecs_y = 0;
2662                                 vecs_z -= 2;
2663                         }
2664                         else
2665                         {
2666                                 // right
2667                         }
2668                         break;
2669
2670                 case 4:
2671                         if(allowcenter) // 2: allow center handedness
2672                         {
2673                                 // center
2674                                 vecs_y = 0;
2675                                 vecs_z -= 2;
2676                         }
2677                         else
2678                         {
2679                                 // left
2680                                 vecs_y = -vecs_y;
2681                         }
2682                         break;
2683         }
2684         return vecs;
2685 }
2686
2687 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2688 {
2689         string s;
2690         vector v;
2691
2692         if (autocvar_g_shootfromeye)
2693         {
2694                 if (visual)
2695                 {
2696                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2697                 }
2698                 else
2699                 {
2700                         vecs_y = 0;
2701                         vecs_z = 0;
2702                 }
2703         }
2704         else if (autocvar_g_shootfromcenter)
2705         {
2706                 if (visual)
2707                 {
2708                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2709                 }
2710                 else
2711                 {
2712                         vecs_y = 0;
2713                         vecs_z -= 2;
2714                 }
2715         }
2716         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2717         {
2718                 v = stov(s);
2719                 if (y_is_right)
2720                         v_y = -v_y;
2721                 if (v_x != 0)
2722                         vecs_x = v_x;
2723                 vecs_y = v_y;
2724                 vecs_z = v_z;
2725         }
2726         else if (autocvar_g_shootfromclient)
2727         {
2728                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2729         }
2730         return vecs;
2731 }
2732
2733 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2734 {
2735         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2736 }
2737
2738
2739 void attach_sameorigin(entity e, entity to, string tag)
2740 {
2741     vector org, t_forward, t_left, t_up, e_forward, e_up;
2742     vector org0, ang0;
2743     float tagscale;
2744
2745     ang0 = e.angles;
2746     org0 = e.origin;
2747
2748     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2749     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2750     t_forward = v_forward * tagscale;
2751     t_left = v_right * -tagscale;
2752     t_up = v_up * tagscale;
2753
2754     e.origin_x = org * t_forward;
2755     e.origin_y = org * t_left;
2756     e.origin_z = org * t_up;
2757
2758     // current forward and up directions
2759     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2760                 e.angles = AnglesTransform_FromVAngles(e.angles);
2761         else
2762                 e.angles = AnglesTransform_FromAngles(e.angles);
2763     fixedmakevectors(e.angles);
2764
2765     // untransform forward, up!
2766     e_forward_x = v_forward * t_forward;
2767     e_forward_y = v_forward * t_left;
2768     e_forward_z = v_forward * t_up;
2769     e_up_x = v_up * t_forward;
2770     e_up_y = v_up * t_left;
2771     e_up_z = v_up * t_up;
2772
2773     e.angles = fixedvectoangles2(e_forward, e_up);
2774     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2775                 e.angles = AnglesTransform_ToVAngles(e.angles);
2776         else
2777                 e.angles = AnglesTransform_ToAngles(e.angles);
2778
2779     setattachment(e, to, tag);
2780     setorigin(e, e.origin);
2781 }
2782
2783 void detach_sameorigin(entity e)
2784 {
2785     vector org;
2786     org = gettaginfo(e, 0);
2787     e.angles = fixedvectoangles2(v_forward, v_up);
2788     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2789                 e.angles = AnglesTransform_ToVAngles(e.angles);
2790         else
2791                 e.angles = AnglesTransform_ToAngles(e.angles);
2792     setorigin(e, org);
2793     setattachment(e, world, "");
2794     setorigin(e, e.origin);
2795 }
2796
2797 void follow_sameorigin(entity e, entity to)
2798 {
2799     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2800     e.aiment = to; // make the hole follow bmodel
2801     e.punchangle = to.angles; // the original angles of bmodel
2802     e.view_ofs = e.origin - to.origin; // relative origin
2803     e.v_angle = e.angles - to.angles; // relative angles
2804 }
2805
2806 void unfollow_sameorigin(entity e)
2807 {
2808     e.movetype = MOVETYPE_NONE;
2809 }
2810
2811 entity gettaginfo_relative_ent;
2812 vector gettaginfo_relative(entity e, float tag)
2813 {
2814     if (!gettaginfo_relative_ent)
2815     {
2816         gettaginfo_relative_ent = spawn();
2817         gettaginfo_relative_ent.effects = EF_NODRAW;
2818     }
2819     gettaginfo_relative_ent.model = e.model;
2820     gettaginfo_relative_ent.modelindex = e.modelindex;
2821     gettaginfo_relative_ent.frame = e.frame;
2822     return gettaginfo(gettaginfo_relative_ent, tag);
2823 }
2824
2825 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2826 {
2827     float p;
2828     p = pow(2, chan);
2829     if (pl.soundentity.cnt & p)
2830         return;
2831     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2832     pl.soundentity.cnt |= p;
2833 }
2834
2835 void SoundEntity_StopSound(entity pl, float chan)
2836 {
2837     float p;
2838     p = pow(2, chan);
2839     if (pl.soundentity.cnt & p)
2840     {
2841         stopsoundto(MSG_ALL, pl.soundentity, chan);
2842         pl.soundentity.cnt &~= p;
2843     }
2844 }
2845
2846 void SoundEntity_Attach(entity pl)
2847 {
2848     pl.soundentity = spawn();
2849     pl.soundentity.classname = "soundentity";
2850     pl.soundentity.owner = pl;
2851     setattachment(pl.soundentity, pl, "");
2852     setmodel(pl.soundentity, "null");
2853 }
2854
2855 void SoundEntity_Detach(entity pl)
2856 {
2857     float i;
2858     for (i = 0; i <= 7; ++i)
2859         SoundEntity_StopSound(pl, i);
2860 }
2861
2862
2863 float ParseCommandPlayerSlotTarget_firsttoken;
2864 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2865 {
2866         string s;
2867         entity e, head;
2868         float n;
2869
2870         s = string_null;
2871
2872         ParseCommandPlayerSlotTarget_firsttoken = -1;
2873
2874         if (tokens > idx)
2875         {
2876                 if (substring(argv(idx), 0, 1) == "#")
2877                 {
2878                         s = substring(argv(idx), 1, -1);
2879                         ++idx;
2880                         if (s == "") if (tokens > idx)
2881                         {
2882                                 s = argv(idx);
2883                                 ++idx;
2884                         }
2885                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2886                         n = stof(s);
2887                         if (s == ftos(n) && n > 0 && n <= maxclients)
2888                         {
2889                                 e = edict_num(n);
2890                                 if (e.flags & FL_CLIENT)
2891                                         return e;
2892                         }
2893                 }
2894                 else
2895                 {
2896                         // it must be a nick name
2897                         s = argv(idx);
2898                         ++idx;
2899                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2900
2901                         n = 0;
2902                         FOR_EACH_CLIENT(head)
2903                                 if (head.netname == s)
2904                                 {
2905                                         e = head;
2906                                         ++n;
2907                                 }
2908                         if (n == 1)
2909                                 return e;
2910
2911                         s = strdecolorize(s);
2912                         n = 0;
2913                         FOR_EACH_CLIENT(head)
2914                                 if (strdecolorize(head.netname) == s)
2915                                 {
2916                                         e = head;
2917                                         ++n;
2918                                 }
2919                         if (n == 1)
2920                                 return e;
2921                 }
2922         }
2923
2924         return world;
2925 }
2926
2927 .float scale2;
2928
2929 float modeleffect_SendEntity(entity to, float sf)
2930 {
2931         float f;
2932         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2933
2934         f = 0;
2935         if(self.velocity != '0 0 0')
2936                 f |= 1;
2937         if(self.angles != '0 0 0')
2938                 f |= 2;
2939         if(self.avelocity != '0 0 0')
2940                 f |= 4;
2941
2942         WriteByte(MSG_ENTITY, f);
2943         WriteShort(MSG_ENTITY, self.modelindex);
2944         WriteByte(MSG_ENTITY, self.skin);
2945         WriteByte(MSG_ENTITY, self.frame);
2946         WriteCoord(MSG_ENTITY, self.origin_x);
2947         WriteCoord(MSG_ENTITY, self.origin_y);
2948         WriteCoord(MSG_ENTITY, self.origin_z);
2949         if(f & 1)
2950         {
2951                 WriteCoord(MSG_ENTITY, self.velocity_x);
2952                 WriteCoord(MSG_ENTITY, self.velocity_y);
2953                 WriteCoord(MSG_ENTITY, self.velocity_z);
2954         }
2955         if(f & 2)
2956         {
2957                 WriteCoord(MSG_ENTITY, self.angles_x);
2958                 WriteCoord(MSG_ENTITY, self.angles_y);
2959                 WriteCoord(MSG_ENTITY, self.angles_z);
2960         }
2961         if(f & 4)
2962         {
2963                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2964                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2965                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2966         }
2967         WriteShort(MSG_ENTITY, self.scale * 256.0);
2968         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2969         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2970         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2971         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2972
2973         return TRUE;
2974 }
2975
2976 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2977 {
2978         entity e;
2979         float sz;
2980         e = spawn();
2981         e.classname = "modeleffect";
2982         setmodel(e, m);
2983         e.frame = f;
2984         setorigin(e, o);
2985         e.velocity = v;
2986         e.angles = ang;
2987         e.avelocity = angv;
2988         e.alpha = a;
2989         e.teleport_time = t1;
2990         e.fade_time = t2;
2991         e.skin = s;
2992         if(s0 >= 0)
2993                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2994         else
2995                 e.scale = -s0;
2996         if(s2 >= 0)
2997                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2998         else
2999                 e.scale2 = -s2;
3000         sz = max(e.scale, e.scale2);
3001         setsize(e, e.mins * sz, e.maxs * sz);
3002         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
3003 }
3004
3005 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
3006 {
3007         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3008 }
3009
3010 float randombit(float bits)
3011 {
3012         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3013                 return bits;
3014
3015         float n, f, b, r;
3016
3017         r = random();
3018         b = 0;
3019         n = 0;
3020
3021         for(f = 1; f <= bits; f *= 2)
3022         {
3023                 if(bits & f)
3024                 {
3025                         ++n;
3026                         r *= n;
3027                         if(r <= 1)
3028                                 b = f;
3029                         else
3030                                 r = (r - 1) / (n - 1);
3031                 }
3032         }
3033
3034         return b;
3035 }
3036
3037 float randombits(float bits, float k, float error_return)
3038 {
3039         float r;
3040         r = 0;
3041         while(k > 0 && bits != r)
3042         {
3043                 r += randombit(bits - r);
3044                 --k;
3045         }
3046         if(error_return)
3047                 if(k > 0)
3048                         return -1; // all
3049         return r;
3050 }
3051
3052 void randombit_test(float bits, float iter)
3053 {
3054         while(iter > 0)
3055         {
3056                 print(ftos(randombit(bits)), "\n");
3057                 --iter;
3058         }
3059 }
3060
3061 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3062 {
3063         if(halflifedist > 0)
3064                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3065         else if(halflifedist < 0)
3066                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3067         else
3068                 return 1;
3069 }
3070
3071
3072
3073
3074 #ifdef RELEASE
3075 #define cvar_string_normal cvar_string_builtin
3076 #define cvar_normal cvar_builtin
3077 #else
3078 string cvar_string_normal(string n)
3079 {
3080         if not(cvar_type(n) & 1)
3081                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3082         return cvar_string_builtin(n);
3083 }
3084
3085 float cvar_normal(string n)
3086 {
3087         return stof(cvar_string_normal(n));
3088 }
3089 #endif
3090 #define cvar_set_normal cvar_set_builtin
3091
3092 void defer_think()
3093 {
3094     entity oself;
3095
3096     oself           = self;
3097     self            = self.owner;
3098     oself.think     = SUB_Remove;
3099     oself.nextthink = time;
3100
3101     oself.use();
3102 }
3103
3104 /*
3105     Execute func() after time + fdelay.
3106     self when func is executed = self when defer is called
3107 */
3108 void defer(float fdelay, void() func)
3109 {
3110     entity e;
3111
3112     e           = spawn();
3113     e.owner     = self;
3114     e.use       = func;
3115     e.think     = defer_think;
3116     e.nextthink = time + fdelay;
3117 }